qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(cvar("g_running_guns"))
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = cvar("g_player_alpha");
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!cvar("developer_fteqccbugs"))
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         local string timeStr;
 105         local entity plr;
 106         if (timeoutStatus == 1) {
 107                 if (remainingLeadTime > 0) {
 108                         //centerprint the information to every player
 109                         timeStr = getTimeoutText(0);
 110                         FOR_EACH_REALCLIENT(plr) {
 111                                 if(plr.classname == "player") {
 112                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 113                                 }
 114                         }
 115                         remainingLeadTime -= 1;
 116                         //think again in 1 second:
 117                         self.nextthink = time + 1;
 118                 }
 119                 else {
 120                         //now pause the game:
 121                         timeoutStatus = 2;
 122                         //reset all the flood variables
 123                         FOR_EACH_CLIENT(plr) {
 124                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 125                         }
 126                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 127                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 128                         FOR_EACH_REALPLAYER(plr) {
 129                                 plr.lastV_angle = plr.v_angle;
 130                         }
 131                         self.nextthink = time;
 132                 }
 133         }
 134         else if (timeoutStatus == 2) {
 135                 if (remainingTimeoutTime > 0) {
 136                         timeStr = getTimeoutText(0);
 137                         FOR_EACH_REALCLIENT(plr) {
 138                                 if(plr.classname == "player") {
 139                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 140                                 }
 141                         }
 142                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 143                                 Announce("prepareforbattle");
 144                         }
 145                         remainingTimeoutTime -= 1;
 146                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 147                 }
 148                 else {
 149                         //unpause the game again
 150                         remainingTimeoutTime = timeoutStatus = 0;
 151                         cvar_set("slowmo", ftos(orig_slowmo));
 152                         //and unlock the fixed view again once there is no timeout active anymore
 153                         FOR_EACH_REALPLAYER(plr) {
 154                                 plr.fixangle = FALSE;
 155                         }
 156                         //get rid of the countdown message
 157                         FOR_EACH_REALCLIENT(plr) {
 158                                 if(plr.classname == "player") {
 159                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 160                                 }
 161                         }
 162                         remove(self);
 163                         return;
 164                 }
 165
 166         }
 167         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 168                 FOR_EACH_REALCLIENT(plr) {
 169                         if(plr.classname == "player") {
 170                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 171                         }
 172                 }
 173                 remove(self);
 174                 return;
 175         }
 176 }
 177
 178 void GotoFirstMap()
 179 {
 180         float n;
 181         if(cvar("_sv_init"))
 182         {
 183                 // cvar_set("_sv_init", "0");
 184                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 185                 // to this "init" map on a dedicated server will cause no permanent
 186                 // harm
 187                 if(cvar("g_maplist_shuffle"))
 188                         ShuffleMaplist();
 189                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 190                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 191
 192                 MapInfo_Enumerate();
 193                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 194
 195                 if(!DoNextMapOverride())
 196                         GotoNextMap();
 197
 198                 return;
 199         }
 200
 201         if(time < 5)
 202         {
 203                 self.nextthink = time;
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 209         }
 210 }
 211
 212 void cvar_changes_init()
 213 {
 214         float h;
 215         string k, v, d;
 216         float n, i, adding, pureadding;
 217
 218         if(cvar_changes)
 219                 strunzone(cvar_changes);
 220         cvar_changes = string_null;
 221         if(cvar_purechanges)
 222                 strunzone(cvar_purechanges);
 223         cvar_purechanges = string_null;
 224         cvar_purechanges_count = 0;
 225
 226         h = buf_create();
 227         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 228         n = buf_getsize(h);
 229
 230         adding = TRUE;
 231         pureadding = TRUE;
 232
 233         for(i = 0; i < n; ++i)
 234         {
 235                 k = bufstr_get(h, i);
 236
 237 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 238 #define BADCVAR(p) if(k == p) continue
 239                 // internal
 240                 BADPREFIX("csqc_");
 241                 BADPREFIX("cvar_check_");
 242                 BADCVAR("gamecfg");
 243                 BADCVAR("g_configversion");
 244                 BADCVAR("g_maplist_index");
 245                 BADCVAR("halflifebsp");
 246                 BADPREFIX("sv_world");
 247
 248                 // client
 249                 BADPREFIX("chase_");
 250                 BADPREFIX("cl_");
 251                 BADPREFIX("con_");
 252                 BADPREFIX("scoreboard_");
 253                 BADPREFIX("g_campaign");
 254                 BADPREFIX("gl_");
 255                 BADPREFIX("joy");
 256                 BADPREFIX("hud_");
 257                 BADPREFIX("menu_");
 258                 BADPREFIX("net_slist_");
 259                 BADPREFIX("r_");
 260                 BADPREFIX("sbar_");
 261                 BADPREFIX("scr_");
 262                 BADPREFIX("snd_");
 263                 BADPREFIX("userbind");
 264                 BADPREFIX("v_");
 265                 BADPREFIX("vid_");
 266                 BADPREFIX("crosshair");
 267                 BADCVAR("mod_q3bsp_lightmapmergepower");
 268                 BADCVAR("mod_q3bsp_nolightmaps");
 269                 BADCVAR("fov");
 270                 BADCVAR("mastervolume");
 271                 BADCVAR("volume");
 272                 BADCVAR("bgmvolume");
 273
 274                 // private
 275                 BADCVAR("developer");
 276                 BADCVAR("g_banned_list");
 277                 BADCVAR("log_dest_udp");
 278                 BADCVAR("log_file");
 279                 BADCVAR("net_address");
 280                 BADCVAR("net_address_ipv6");
 281                 BADCVAR("port");
 282                 BADCVAR("savedgamecfg");
 283                 BADCVAR("serverconfig");
 284                 BADCVAR("sv_heartbeatperiod");
 285                 BADCVAR("sv_vote_master_password");
 286                 BADCVAR("sys_colortranslation");
 287                 BADCVAR("sys_specialcharactertranslation");
 288                 BADCVAR("timestamps");
 289                 BADPREFIX("developer_");
 290                 BADPREFIX("g_ban_");
 291                 BADPREFIX("g_chat_flood_");
 292                 BADPREFIX("g_voice_flood_");
 293                 BADPREFIX("rcon_");
 294                 BADPREFIX("settemp_");
 295                 BADPREFIX("sv_allowdownloads_");
 296                 BADPREFIX("sv_autodemo");
 297                 BADPREFIX("sv_curl_");
 298                 BADPREFIX("sv_eventlog");
 299                 BADPREFIX("sv_logscores_");
 300                 BADPREFIX("sv_master");
 301                 BADPREFIX("sv_weaponstats_");
 302
 303                 // these can contain player IDs, so better hide
 304                 BADCVAR("g_forced_team_red");
 305                 BADCVAR("g_forced_team_blue");
 306                 BADCVAR("g_forced_team_yellow");
 307                 BADCVAR("g_forced_team_pink");
 308
 309                 // mapinfo
 310                 BADCVAR("timelimit");
 311                 BADCVAR("fraglimit");
 312                 BADCVAR("leadlimit");
 313                 BADCVAR("g_tdm_teams");
 314                 BADCVAR("g_keyhunt_teams");
 315                 BADCVAR("g_domination_default_teams");
 316                 BADCVAR("g_race_qualifying_timelimit");
 317                 BADCVAR("g_lms");
 318                 BADCVAR("g_arena");
 319                 BADCVAR("g_ca");
 320                 BADCVAR("g_assault");
 321                 BADCVAR("g_ctf");
 322                 BADCVAR("g_dm");
 323                 BADCVAR("g_domination");
 324                 BADCVAR("g_keyhunt");
 325                 BADCVAR("g_keyhunt_teams");
 326                 BADCVAR("g_onslaught");
 327                 BADCVAR("g_race");
 328                 BADCVAR("g_cts");
 329                 BADCVAR("g_runematch");
 330                 BADCVAR("g_tdm");
 331                 BADCVAR("g_nexball");
 332                 BADCVAR("teamplay");
 333
 334                 // long
 335                 BADCVAR("hostname");
 336                 BADCVAR("g_maplist");
 337                 BADCVAR("g_maplist_mostrecent");
 338                 BADCVAR("sv_motd");
 339
 340                 v = cvar_string(k);
 341                 d = cvar_defstring(k);
 342                 if(v == d)
 343                         continue;
 344
 345                 if(adding)
 346                 {
 347                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 348                         if(strlen(cvar_changes) > 16384)
 349                         {
 350                                 cvar_changes = "// too many settings have been changed to show them here\n";
 351                                 adding = 0;
 352                         }
 353                 }
 354
 355                 // now check if the changes are actually gameplay relevant
 356
 357                 // does nothing visible
 358                 BADCVAR("captureleadlimit_override");
 359                 BADCVAR("g_arena_point_leadlimit");
 360                 BADCVAR("g_ca_point_leadlimit");
 361                 BADCVAR("g_ctf_capture_leadlimit");
 362                 BADCVAR("g_domination_point_leadlimit");
 363                 BADCVAR("g_keyhunt_point_leadlimit");
 364                 BADCVAR("g_nexball_goalleadlimit");
 365                 BADCVAR("g_runematch_point_leadlimit");
 366                 BADCVAR("leadlimit_and_fraglimit");
 367                 BADCVAR("leadlimit_override");
 368                 BADCVAR("sv_checkforpacketsduringsleep");
 369                 BADPREFIX("crypto_");
 370                 BADPREFIX("g_chat_");
 371                 BADPREFIX("net_");
 372                 BADPREFIX("prvm_");
 373                 BADPREFIX("sv_fragmessage_");
 374                 BADPREFIX("sv_vote_");
 375                 BADPREFIX("timelimit_");
 376
 377                 // allowed changes to server admins (please sync this to server.cfg)
 378                 // vi commands:
 379                 //   :/"impure"/,$d
 380                 //   :g!,^\/\/[^ /],d
 381                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 382                 //   :%!sort
 383                 // yes, this does contain some redundant stuff, don't really care
 384                 BADCVAR("bot_number");
 385                 BADCVAR("bot_prefix");
 386                 BADCVAR("bot_suffix");
 387                 BADCVAR("capturelimit_override");
 388                 BADCVAR("fraglimit_override");
 389                 BADCVAR("gametype");
 390                 BADCVAR("g_antilag");
 391                 BADCVAR("g_balance_teams");
 392                 BADCVAR("g_balance_teams_force");
 393                 BADCVAR("g_ban_sync_trusted_servers");
 394                 BADCVAR("g_ban_sync_uri");
 395                 BADCVAR("g_ctf_capture_limit");
 396                 BADCVAR("g_ctf_ignore_frags");
 397                 BADCVAR("g_ctf_win_mode");
 398                 BADCVAR("g_domination_point_limit");
 399                 BADCVAR("g_fullbrightitems");
 400                 BADCVAR("g_fullbrightplayers");
 401                 BADCVAR("g_keyhunt_point_limit");
 402                 BADCVAR("g_keyhunt_teams_override");
 403                 BADCVAR("g_lms_lives_override");
 404                 BADCVAR("g_maplist");
 405                 BADCVAR("g_maplist_check_waypoints");
 406                 BADCVAR("g_maplist_mostrecent_count");
 407                 BADCVAR("g_maplist_shuffle");
 408                 BADCVAR("g_maplist_votable");
 409                 BADCVAR("g_maplist_votable_abstain");
 410                 BADCVAR("g_maplist_votable_nodetail");
 411                 BADCVAR("g_maplist_votable_suggestions");
 412                 BADCVAR("g_minstagib");
 413                 BADCVAR("g_nexball_goallimit");
 414                 BADCVAR("g_runematch_point_limit");
 415                 BADCVAR("g_start_delay");
 416                 BADCVAR("hostname");
 417                 BADCVAR("log_file");
 418                 BADCVAR("maxplayers");
 419                 BADCVAR("minplayers");
 420                 BADCVAR("net_address");
 421                 BADCVAR("port");
 422                 BADCVAR("rcon_password");
 423                 BADCVAR("rcon_restricted_commands");
 424                 BADCVAR("rcon_restricted_password");
 425                 BADCVAR("skill");
 426                 BADCVAR("sv_adminnick");
 427                 BADCVAR("sv_autoscreenshot");
 428                 BADCVAR("sv_curl_defaulturl");
 429                 BADCVAR("sv_defaultcharacter");
 430                 BADCVAR("sv_defaultplayermodel");
 431                 BADCVAR("sv_defaultplayerskin");
 432                 BADCVAR("sv_maxidle");
 433                 BADCVAR("sv_maxrate");
 434                 BADCVAR("sv_motd");
 435                 BADCVAR("sv_public");
 436                 BADCVAR("sv_ready_restart");
 437                 BADCVAR("sv_status_privacy");
 438                 BADCVAR("sv_vote_call");
 439                 BADCVAR("sv_vote_commands");
 440                 BADCVAR("sv_vote_majority_factor");
 441                 BADCVAR("sv_vote_master");
 442                 BADCVAR("sv_vote_master_commands");
 443                 BADCVAR("sv_vote_master_password");
 444                 BADCVAR("sv_vote_simple_majority_factor");
 445                 BADCVAR("timelimit_override");
 446
 447                 if(cvar("g_minstagib"))
 448                 {
 449                         BADCVAR("g_grappling_hook");
 450                         BADCVAR("g_jetpack");
 451                 }
 452 #undef BADPREFIX
 453 #undef BADCVAR
 454
 455                 if(pureadding)
 456                 {
 457                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 458                         if(strlen(cvar_purechanges) > 16384)
 459                         {
 460                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 461                                 pureadding = 0;
 462                         }
 463                 }
 464                 ++cvar_purechanges_count;
 465                 // WARNING: this variable is used for the server list
 466                 // NEVER dare to skip this code!
 467                 // Hacks to intentionally appearing as "pure server" even though you DO have
 468                 // modified settings may be punished by removal from the server list.
 469                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 470                 // though.
 471         }
 472         buf_del(h);
 473         if(cvar_changes == "")
 474                 cvar_changes = "// this server runs at default server settings\n";
 475         else
 476                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 477         cvar_changes = strzone(cvar_changes);
 478         if(cvar_purechanges == "")
 479                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 480         else
 481                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 482         cvar_purechanges = strzone(cvar_purechanges);
 483 }
 484
 485 void detect_maptype()
 486 {
 487 #if 0
 488         vector o, v;
 489         float i;
 490
 491         for(;;)
 492         {
 493                 o = world.mins;
 494                 o_x += random() * (world.maxs_x - world.mins_x);
 495                 o_y += random() * (world.maxs_y - world.mins_y);
 496                 o_z += random() * (world.maxs_z - world.mins_z);
 497
 498                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 499                 if(trace_fraction == 1)
 500                         continue;
 501
 502                 v = trace_endpos;
 503
 504                 for(i = 0; i < 64; i += 4)
 505                 {
 506                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 507         if(trace_fraction == 1)
 508                 continue;
 509                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 510                 }
 511
 512                 break;
 513         }
 514 #endif
 515 }
 516
 517 entity randomseed;
 518 float RandomSeed_Send(entity to, float sf)
 519 {
 520         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 521         WriteShort(MSG_ENTITY, self.cnt);
 522         return TRUE;
 523 }
 524 void RandomSeed_Think()
 525 {
 526         self.cnt = bound(0, floor(random() * 65536), 65535);
 527         self.nextthink = time + 5;
 528
 529         self.SendFlags |= 1;
 530 }
 531 void RandomSeed_Spawn()
 532 {
 533         randomseed = spawn();
 534         randomseed.think = RandomSeed_Think;
 535         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 536
 537         entity oldself;
 538         oldself = self;
 539         self = randomseed;
 540         self.think(); // sets random seed and nextthink
 541         self = oldself;
 542 }
 543
 544 void spawnfunc___init_dedicated_server(void)
 545 {
 546         // handler for _init/_init map (only for dedicated server initialization)
 547
 548         world_initialized = -1; // don't complain
 549         cvar = cvar_normal;
 550         cvar_string = cvar_string_normal;
 551         cvar_set = cvar_set_normal;
 552
 553         remove = remove_unsafely;
 554
 555         entity e;
 556         e = spawn();
 557         e.think = GotoFirstMap;
 558         e.nextthink = time; // this is usually 1 at this point
 559
 560         e = spawn();
 561         e.classname = "info_player_deathmatch"; // safeguard against player joining
 562
 563         self.classname = "worldspawn"; // safeguard against various stuff ;)
 564
 565         MapInfo_Enumerate();
 566         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 567 }
 568
 569 void Map_MarkAsRecent(string m);
 570 float world_already_spawned;
 571 void RegisterWeapons();
 572 void Nagger_Init();
 573 void ClientInit_Spawn();
 574 void WeaponStats_Init();
 575 void WeaponStats_Shutdown();
 576 void spawnfunc_worldspawn (void)
 577 {
 578         float fd, l, i, j, n;
 579         string s, col;
 580
 581         cvar = cvar_normal;
 582         cvar_string = cvar_string_normal;
 583         cvar_set = cvar_set_normal;
 584
 585         if(world_already_spawned)
 586                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 587         world_already_spawned = TRUE;
 588
 589         remove = remove_safely; // during spawning, watch what you remove!
 590
 591         check_unacceptable_compiler_bugs();
 592
 593         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 594
 595         compressShortVector_init();
 596
 597         allowed_to_spawn = TRUE;
 598
 599         local entity head;
 600         head = nextent(world);
 601         maxclients = 0;
 602         while(head)
 603         {
 604                 ++maxclients;
 605                 head = nextent(head);
 606         }
 607
 608         // needs to be done so early as they would still spawn
 609         RegisterWeapons();
 610
 611         ServerProgsDB = db_load("server.db");
 612
 613         TemporaryDB = db_create();
 614
 615         /*
 616         TODO sound pack system
 617         // initialize sound pack system
 618         soundpack = cvar_string("g_soundpack");
 619         if(soundpack != "")
 620                 soundpack = strcat(soundpack, "/");
 621         soundpack = strzone(soundpack);
 622         */
 623
 624         // 0 normal
 625         lightstyle(0, "m");
 626
 627         // 1 FLICKER (first variety)
 628         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 629
 630         // 2 SLOW STRONG PULSE
 631         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 632
 633         // 3 CANDLE (first variety)
 634         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 635
 636         // 4 FAST STROBE
 637         lightstyle(4, "mamamamamama");
 638
 639         // 5 GENTLE PULSE 1
 640         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 641
 642         // 6 FLICKER (second variety)
 643         lightstyle(6, "nmonqnmomnmomomno");
 644
 645         // 7 CANDLE (second variety)
 646         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 647
 648         // 8 CANDLE (third variety)
 649         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 650
 651         // 9 SLOW STROBE (fourth variety)
 652         lightstyle(9, "aaaaaaaazzzzzzzz");
 653
 654         // 10 FLUORESCENT FLICKER
 655         lightstyle(10, "mmamammmmammamamaaamammma");
 656
 657         // 11 SLOW PULSE NOT FADE TO BLACK
 658         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 659
 660         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 661
 662         // 63 testing
 663         lightstyle(63, "a");
 664
 665         if(cvar("g_campaign"))
 666                 CampaignPreInit();
 667
 668         Map_MarkAsRecent(mapname);
 669
 670         precache_model ("null"); // we need this one before InitGameplayMode
 671         InitGameplayMode();
 672         readlevelcvars();
 673         GrappleHookInit();
 674         ElectroInit();
 675         LaserInit();
 676
 677         player_count = 0;
 678         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 679         if(bot_waypoints_for_items == 1)
 680                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 681                         bot_waypoints_for_items = 0;
 682
 683         // for setting by mapinfo
 684         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 685         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 686
 687         precache();
 688
 689         WaypointSprite_Init();
 690
 691         //if (g_domination)
 692         //      dom_init();
 693
 694         GameLogInit(); // prepare everything
 695         if(cvar("sv_eventlog"))
 696         {
 697                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 698                 s = strcat(s, ftos(random()));
 699                 matchid = strzone(s);
 700
 701                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 702                 s = ":gameinfo:mutators:LIST";
 703
 704                 ret_string = s;
 705                 MUTATOR_CALLHOOK(BuildMutatorsString);
 706                 s = ret_string;
 707
 708                 // simple, probably not good in the mutator system
 709                 if(cvar("g_grappling_hook"))
 710                         s = strcat(s, ":grappling_hook");
 711
 712                 // initialiation stuff, not good in the mutator system
 713                 if(!cvar("g_use_ammunition"))
 714                         s = strcat(s, ":no_use_ammunition");
 715
 716                 // initialiation stuff, not good in the mutator system
 717                 if(!cvar("g_pickup_items"))
 718                         s = strcat(s, ":no_pickup_items");
 719
 720                 // initialiation stuff, not good in the mutator system
 721                 if(cvar_string("g_weaponarena") != "0")
 722                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 723
 724                 // TODO to mutator system
 725                 if(cvar("g_norecoil"))
 726                         s = strcat(s, ":norecoil");
 727
 728                 // TODO to mutator system
 729                 if(cvar("g_midair"))
 730                         s = strcat(s, ":midair");
 731
 732                 // TODO to mutator system
 733                 if(cvar("g_minstagib"))
 734                         s = strcat(s, ":minstagib");
 735
 736                 GameLogEcho(s);
 737                 GameLogEcho(":gameinfo:end");
 738         }
 739         else
 740                 matchid = strzone(ftos(random()));
 741
 742         cvar_set("nextmap", "");
 743
 744         SetDefaultAlpha();
 745
 746         if(cvar("g_campaign"))
 747                 CampaignPostInit();
 748
 749         fteqcc_testbugs();
 750
 751         Ban_LoadBans();
 752
 753         MapInfo_Enumerate();
 754         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 755
 756         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 757         {
 758                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 759                 if(fd != -1)
 760                 {
 761                         while((s = fgets(fd)))
 762                         {
 763                                 l = tokenize_console(s);
 764                                 if(l < 2)
 765                                         continue;
 766                                 if(argv(0) == "cd")
 767                                 {
 768                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 769                                         print("  cdtrack ", argv(2), "\n");
 770                                 }
 771                                 else if(argv(0) == "fog")
 772                                 {
 773                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 774                                         print("  \"fog\" \"", s, "\"\n");
 775                                 }
 776                                 else if(argv(0) == "set")
 777                                 {
 778                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 779                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 780                                 }
 781                                 else if(argv(0) != "//")
 782                                 {
 783                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 784                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 785                                 }
 786                         }
 787                         fclose(fd);
 788                 }
 789         }
 790
 791         WeaponStats_Init();
 792
 793         addstat(STAT_WEAPONS, AS_INT, weapons);
 794         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 795         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 796         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 797         Nagger_Init();
 798
 799         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 800         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 801         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 802         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 803         addstat(STAT_DAMAGE_HITS, AS_INT, stat_hit);
 804         addstat(STAT_DAMAGE_FIRED, AS_INT, stat_fired);
 805         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 806         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 807         addstat(STAT_BULLETS_LOADED, AS_INT, campingrifle_bulletcounter);
 808         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 809
 810         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 811
 812         if(g_ca || g_freezetag)
 813         {
 814                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 815                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 816                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 817                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 818         }
 819         if(g_freezetag)
 820                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 821
 822         // g_movementspeed hack
 823         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 824         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 825         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 826
 827         next_pingtime = time + 5;
 828
 829         detect_maptype();
 830
 831         lsmaps_reply = "^7Maps available: ";
 832         lsnewmaps_reply = "^7Maps without a record set: ";
 833         for(i = 0, j = 0; i < MapInfo_count; ++i)
 834         {
 835                 if(MapInfo_Get_ByID(i))
 836                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 837                         {
 838                                 if(mod(i, 2))
 839                                         col = "^2";
 840                                 else
 841                                         col = "^3";
 842                                 ++j;
 843                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 844                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 845                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 846                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 847                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 848                         }
 849         }
 850         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 851         if (!g_race && !g_cts)
 852                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 853         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 854
 855         maplist_reply = "^7Maps in list: ";
 856         n = tokenize_console(cvar_string("g_maplist"));
 857         for(i = 0, j = 0; i < n; ++i)
 858         {
 859                 if(MapInfo_CheckMap(argv(i)))
 860                 {
 861                         if(mod(j, 2))
 862                                 col = "^2";
 863                         else
 864                                 col = "^3";
 865                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 866                         ++j;
 867                 }
 868         }
 869         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 870         MapInfo_ClearTemps();
 871
 872         for(i = 0; i < 10; ++i)
 873         {
 874                 records_reply[i] = strzone(getrecords(i));
 875         }
 876         if(g_cts)
 877                 ladder_reply = strzone(getladder());
 878
 879         rankings_reply = strzone(getrankings());
 880
 881         ClientInit_Spawn();
 882         RandomSeed_Spawn();
 883         PingPLReport_Spawn();
 884
 885         CheatInit();
 886
 887         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 888
 889         // fill sv_curl_serverpackages from .serverpackage files
 890         if(cvar("sv_curl_serverpackages_auto"))
 891         {
 892                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 893                 s = "";
 894                 if(fd >= 0)
 895                 {
 896                         j = search_getsize(fd);
 897                         for(i = 0; i < j; ++i)
 898                                 s = strcat(s, " ", search_getfilename(fd, i));
 899                         search_end(fd);
 900                 }
 901                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 902         }
 903
 904         world_initialized = 1;
 905 }
 906
 907 void spawnfunc_light (void)
 908 {
 909         //makestatic (self); // Who the f___ did that?
 910         remove(self);
 911 }
 912
 913 float TryFile( string pFilename )
 914 {
 915         local float lHandle;
 916         dprint("TryFile(\"", pFilename, "\")\n");
 917         lHandle = fopen( pFilename, FILE_READ );
 918         if( lHandle != -1 ) {
 919                 fclose( lHandle );
 920                 return TRUE;
 921         } else {
 922                 return FALSE;
 923         }
 924 };
 925
 926 string GetGametype()
 927 {
 928         return GametypeNameFromType(game);
 929 }
 930
 931 string getmapname_stored;
 932 string GetMapname()
 933 {
 934         return mapname;
 935 }
 936
 937 float Map_Count, Map_Current;
 938 string Map_Current_Name;
 939
 940 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 941 float GetMaplistPosition()
 942 {
 943         float pos, idx;
 944         string map;
 945
 946         map = GetMapname();
 947         idx = cvar("g_maplist_index");
 948
 949         if(idx >= 0)
 950                 if(idx < Map_Count)
 951                         if(map == argv(idx))
 952                                 return idx;
 953
 954         for(pos = 0; pos < Map_Count; ++pos)
 955                 if(map == argv(pos))
 956                         return pos;
 957
 958         // resume normal maplist rotation if current map is not in g_maplist
 959         return idx;
 960 }
 961
 962 float MapHasRightSize(string map)
 963 {
 964         float fh;
 965         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 966         if(cvar("g_maplist_check_waypoints"))
 967         {
 968                 dprint("checkwp "); dprint(map);
 969                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 970                 if(fh < 0)
 971                 {
 972                         dprint(": no waypoints\n");
 973                         return FALSE;
 974                 }
 975                 dprint(": has waypoints\n");
 976                 fclose(fh);
 977         }
 978
 979         // open map size restriction file
 980         dprint("opensize "); dprint(map);
 981         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 982         if(fh >= 0)
 983         {
 984                 float mapmin, mapmax;
 985                 dprint(": ok, ");
 986                 mapmin = stof(fgets(fh));
 987                 mapmax = stof(fgets(fh));
 988                 fclose(fh);
 989                 if(player_count < mapmin)
 990                 {
 991                         dprint("not enough\n");
 992                         return FALSE;
 993                 }
 994                 if(player_count > mapmax)
 995                 {
 996                         dprint("too many\n");
 997                         return FALSE;
 998                 }
 999                 dprint("right size\n");
1000                 return TRUE;
1001         }
1002         dprint(": not found\n");
1003         return TRUE;
1004 }
1005
1006 string Map_Filename(float position)
1007 {
1008         return strcat("maps/", argv(position), ".bsp");
1009 }
1010
1011 string strwords(string s, float w)
1012 {
1013         float endpos;
1014         for(endpos = 0; w && endpos >= 0; --w)
1015                 endpos = strstrofs(s, " ", endpos + 1);
1016         if(endpos < 0)
1017                 return s;
1018         else
1019                 return substring(s, 0, endpos);
1020 }
1021
1022 float strhasword(string s, string w)
1023 {
1024         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1025 }
1026
1027 void Map_MarkAsRecent(string m)
1028 {
1029         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
1030 }
1031
1032 float Map_IsRecent(string m)
1033 {
1034         return strhasword(cvar_string("g_maplist_mostrecent"), m);
1035 }
1036
1037 float Map_Check(float position, float pass)
1038 {
1039         string filename;
1040         string map_next;
1041         map_next = argv(position);
1042         if(pass <= 1)
1043         {
1044                 if(Map_IsRecent(map_next))
1045                         return 0;
1046         }
1047         filename = Map_Filename(position);
1048         if(MapInfo_CheckMap(map_next))
1049         {
1050                 if(pass == 2)
1051                         return 1;
1052                 if(MapHasRightSize(map_next))
1053                         return 1;
1054                 return 0;
1055         }
1056         else
1057                 dprint( "Couldn't select '", filename, "'..\n" );
1058
1059         return 0;
1060 }
1061
1062 void Map_Goto_SetStr(string nextmapname)
1063 {
1064         if(getmapname_stored != "")
1065                 strunzone(getmapname_stored);
1066         if(nextmapname == "")
1067                 getmapname_stored = "";
1068         else
1069                 getmapname_stored = strzone(nextmapname);
1070 }
1071
1072 void Map_Goto_SetFloat(float position)
1073 {
1074         cvar_set("g_maplist_index", ftos(position));
1075         Map_Goto_SetStr(argv(position));
1076 }
1077
1078 void GameResetCfg()
1079 {
1080         // settings persist, except...
1081         localcmd("\nsettemp_restore\n");
1082 };
1083
1084 void Map_Goto()
1085 {
1086         GameResetCfg();
1087         MapInfo_LoadMap(getmapname_stored);
1088 }
1089
1090 // return codes of map selectors:
1091 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1092 //   -2 = permanent failure
1093 float() MaplistMethod_Iterate = // usual method
1094 {
1095         float pass, i;
1096
1097         for(pass = 1; pass <= 2; ++pass)
1098         {
1099                 for(i = 1; i < Map_Count; ++i)
1100                 {
1101                         float mapindex;
1102                         mapindex = mod(i + Map_Current, Map_Count);
1103                         if(Map_Check(mapindex, pass))
1104                                 return mapindex;
1105                 }
1106         }
1107         return -1;
1108 }
1109
1110 float() MaplistMethod_Repeat = // fallback method
1111 {
1112         if(Map_Check(Map_Current, 2))
1113                 return Map_Current;
1114         return -2;
1115 }
1116
1117 float() MaplistMethod_Random = // random map selection
1118 {
1119         float i, imax;
1120
1121         imax = 42;
1122
1123         for(i = 0; i <= imax; ++i)
1124         {
1125                 float mapindex;
1126                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1127                 if(Map_Check(mapindex, 1))
1128                         return mapindex;
1129         }
1130         return -1;
1131 }
1132
1133 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1134 // the exponent sets a bias on the map selection:
1135 // the higher the exponent, the less likely "shortly repeated" same maps are
1136 {
1137         float i, j, imax, insertpos;
1138
1139         imax = 42;
1140
1141         for(i = 0; i <= imax; ++i)
1142         {
1143                 string newlist;
1144
1145                 // now reinsert this at another position
1146                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1147                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1148                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1149                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1150
1151                 // insert the current map there
1152                 newlist = "";
1153                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1154                         newlist = strcat(newlist, " ", argv(j));
1155                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1156                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1157                         newlist = strcat(newlist, " ", argv(j));
1158                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1159                 cvar_set("g_maplist", newlist);
1160                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1161
1162                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1163                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1164                 if(Map_Check(Map_Current, 1))
1165                         return Map_Current;
1166         }
1167         return -1;
1168 }
1169
1170 void Maplist_Init()
1171 {
1172         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1173         if(Map_Count == 0)
1174         {
1175                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1176                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1177                 if(cvar("g_maplist_shuffle"))
1178                         ShuffleMaplist();
1179                 localcmd("\nmenu_cmd sync\n");
1180                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1181         }
1182         if(Map_Count == 0)
1183                 error("empty maplist, cannot select a new map");
1184         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1185
1186         if(Map_Current_Name)
1187                 strunzone(Map_Current_Name);
1188         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1189         // this may or may not be correct, but who cares, in the worst case a map
1190         // isn't chosen in the first pass that should have been
1191 }
1192
1193 string GetNextMap()
1194 {
1195         float nextMap;
1196
1197         Maplist_Init();
1198         nextMap = -1;
1199
1200         if(nextMap == -1)
1201                 if(cvar("g_maplist_shuffle") > 0)
1202                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
1203
1204         if(nextMap == -1)
1205                 if(cvar("g_maplist_selectrandom"))
1206                         nextMap = MaplistMethod_Random();
1207
1208         if(nextMap == -1)
1209                 nextMap = MaplistMethod_Iterate();
1210
1211         if(nextMap == -1)
1212                 nextMap = MaplistMethod_Repeat();
1213
1214         if(nextMap >= 0)
1215         {
1216                 Map_Goto_SetFloat(nextMap);
1217                 return getmapname_stored;
1218         }
1219
1220         return "";
1221 };
1222
1223 float DoNextMapOverride()
1224 {
1225         if(cvar("g_campaign"))
1226         {
1227                 CampaignPostIntermission();
1228                 alreadychangedlevel = TRUE;
1229                 return TRUE;
1230         }
1231         if(cvar("quit_when_empty"))
1232         {
1233                 if(player_count <= currentbots)
1234                 {
1235                         localcmd("quit\n");
1236                         alreadychangedlevel = TRUE;
1237                         return TRUE;
1238                 }
1239         }
1240         if(cvar_string("quit_and_redirect") != "")
1241         {
1242                 redirection_target = strzone(cvar_string("quit_and_redirect"));
1243                 alreadychangedlevel = TRUE;
1244                 return TRUE;
1245         }
1246         if (cvar("samelevel")) // if samelevel is set, stay on same level
1247         {
1248                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1249                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1250                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1251                 localcmd("restart\n");
1252                 //changelevel (mapname);
1253                 alreadychangedlevel = TRUE;
1254                 return TRUE;
1255         }
1256         if(cvar_string("nextmap") != "")
1257                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1258                 {
1259                         Map_Goto_SetStr(cvar_string("nextmap"));
1260                         Map_Goto();
1261                         alreadychangedlevel = TRUE;
1262                         return TRUE;
1263                 }
1264         if(cvar("lastlevel"))
1265         {
1266                 GameResetCfg();
1267                 localcmd("set lastlevel 0\ntogglemenu\n");
1268                 alreadychangedlevel = TRUE;
1269                 return TRUE;
1270         }
1271         return FALSE;
1272 };
1273
1274 void GotoNextMap()
1275 {
1276         //local string nextmap;
1277         //local float n, nummaps;
1278         //local string s;
1279         if (alreadychangedlevel)
1280                 return;
1281         alreadychangedlevel = TRUE;
1282
1283         {
1284                 string nextMap;
1285                 float allowReset;
1286
1287                 for(allowReset = 1; allowReset >= 0; --allowReset)
1288                 {
1289                         nextMap = GetNextMap();
1290                         if(nextMap != "")
1291                                 break;
1292
1293                         if(allowReset)
1294                         {
1295                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1296                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1297                                 if(cvar("g_maplist_shuffle"))
1298                                         ShuffleMaplist();
1299                                 localcmd("\nmenu_cmd sync\n");
1300                         }
1301                         else
1302                         {
1303                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1304                         }
1305                 }
1306                 Map_Goto();
1307         }
1308 };
1309
1310
1311 /*
1312 ============
1313 IntermissionThink
1314
1315 When the player presses attack or jump, change to the next level
1316 ============
1317 */
1318 .float autoscreenshot;
1319 void() MapVote_Start;
1320 void() MapVote_Think;
1321 float mapvote_initialized;
1322 void IntermissionThink()
1323 {
1324         FixIntermissionClient(self);
1325
1326         if(cvar("sv_autoscreenshot"))
1327         if(self.autoscreenshot > 0)
1328         if(time > self.autoscreenshot)
1329         {
1330                 self.autoscreenshot = -1;
1331                 if(clienttype(self) == CLIENTTYPE_REAL)
1332                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1333                 return;
1334         }
1335
1336         if (time < intermission_exittime)
1337                 return;
1338
1339         if(!mapvote_initialized)
1340                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1341                         return;
1342
1343         MapVote_Start();
1344 };
1345
1346 /*
1347 ============
1348 FindIntermission
1349
1350 Returns the entity to view from
1351 ============
1352 */
1353 /*
1354 entity FindIntermission()
1355 {
1356         local   entity spot;
1357         local   float cyc;
1358
1359 // look for info_intermission first
1360         spot = find (world, classname, "info_intermission");
1361         if (spot)
1362         {       // pick a random one
1363                 cyc = random() * 4;
1364                 while (cyc > 1)
1365                 {
1366                         spot = find (spot, classname, "info_intermission");
1367                         if (!spot)
1368                                 spot = find (spot, classname, "info_intermission");
1369                         cyc = cyc - 1;
1370                 }
1371                 return spot;
1372         }
1373
1374 // then look for the start position
1375         spot = find (world, classname, "info_player_start");
1376         if (spot)
1377                 return spot;
1378
1379 // testinfo_player_start is only found in regioned levels
1380         spot = find (world, classname, "testplayerstart");
1381         if (spot)
1382                 return spot;
1383
1384 // then look for the start position
1385         spot = find (world, classname, "info_player_deathmatch");
1386         if (spot)
1387                 return spot;
1388
1389         //objerror ("FindIntermission: no spot");
1390         return world;
1391 };
1392 */
1393
1394 /*
1395 ===============================================================================
1396
1397 RULES
1398
1399 ===============================================================================
1400 */
1401
1402 void DumpStats(float final)
1403 {
1404         local float file;
1405         local string s;
1406         local float to_console;
1407         local float to_eventlog;
1408         local float to_file;
1409         local float i;
1410
1411         to_console = cvar("sv_logscores_console");
1412         to_eventlog = cvar("sv_eventlog");
1413         to_file = cvar("sv_logscores_file");
1414
1415         if(!final)
1416         {
1417                 to_console = TRUE; // always print printstats replies
1418                 to_eventlog = FALSE; // but never print them to the event log
1419         }
1420
1421         if(to_eventlog)
1422                 if(cvar("sv_eventlog_console"))
1423                         to_console = FALSE; // otherwise we get the output twice
1424
1425         if(final)
1426                 s = ":scores:";
1427         else
1428                 s = ":status:";
1429         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1430
1431         if(to_console)
1432                 print(s, "\n");
1433         if(to_eventlog)
1434                 GameLogEcho(s);
1435         if(to_file)
1436         {
1437                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1438                 if(file == -1)
1439                         to_file = FALSE;
1440                 else
1441                         fputs(file, strcat(s, "\n"));
1442         }
1443
1444         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1445         if(to_console)
1446                 print(s, "\n");
1447         if(to_eventlog)
1448                 GameLogEcho(s);
1449         if(to_file)
1450                 fputs(file, strcat(s, "\n"));
1451
1452         FOR_EACH_CLIENT(other)
1453         {
1454                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1455                 {
1456                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1457                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1458                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1459                                 s = strcat(s, ftos(other.team), ":");
1460                         else
1461                                 s = strcat(s, "spectator:");
1462
1463                         if(to_console)
1464                                 print(s, other.netname, "\n");
1465                         if(to_eventlog)
1466                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1467                         if(to_file)
1468                                 fputs(file, strcat(s, other.netname, "\n"));
1469                 }
1470         }
1471
1472         if(teams_matter)
1473         {
1474                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1475                 if(to_console)
1476                         print(s, "\n");
1477                 if(to_eventlog)
1478                         GameLogEcho(s);
1479                 if(to_file)
1480                         fputs(file, strcat(s, "\n"));
1481
1482                 for(i = 1; i < 16; ++i)
1483                 {
1484                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1485                         s = strcat(s, ":", ftos(i));
1486                         if(to_console)
1487                                 print(s, "\n");
1488                         if(to_eventlog)
1489                                 GameLogEcho(s);
1490                         if(to_file)
1491                                 fputs(file, strcat(s, "\n"));
1492                 }
1493         }
1494
1495         if(to_console)
1496                 print(":end\n");
1497         if(to_eventlog)
1498                 GameLogEcho(":end");
1499         if(to_file)
1500         {
1501                 fputs(file, ":end\n");
1502                 fclose(file);
1503         }
1504 }
1505
1506 void FixIntermissionClient(entity e)
1507 {
1508         string s;
1509         if(!e.autoscreenshot) // initial call
1510         {
1511                 e.angles = e.v_angle;
1512                 e.angles_x = -e.angles_x;
1513                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1514                 e.health = -2342;
1515                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1516                 e.solid = SOLID_NOT;
1517                 e.movetype = MOVETYPE_NONE;
1518                 e.takedamage = DAMAGE_NO;
1519                 if(e.weaponentity)
1520                 {
1521                         e.weaponentity.effects = EF_NODRAW;
1522                         if (e.weaponentity.weaponentity)
1523                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1524                 }
1525                 if(clienttype(e) == CLIENTTYPE_REAL)
1526                 {
1527                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1528                         s = cvar_string("sv_intermission_cdtrack");
1529                         if(s != "")
1530                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1531                         msg_entity = e;
1532                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1533                 }
1534         }
1535
1536         //e.velocity = '0 0 0';
1537         //e.fixangle = TRUE;
1538
1539         // TODO halt weapon animation
1540 }
1541
1542
1543 /*
1544 go to the next level for deathmatch
1545 only called if a time or frag limit has expired
1546 */
1547 void NextLevel()
1548 {
1549         float i;
1550
1551         gameover = TRUE;
1552
1553         intermission_running = 1;
1554
1555 // enforce a wait time before allowing changelevel
1556         if(player_count > 0)
1557                 intermission_exittime = time + cvar("sv_mapchange_delay");
1558         else
1559                 intermission_exittime = -1;
1560
1561         /*
1562         WriteByte (MSG_ALL, SVC_CDTRACK);
1563         WriteByte (MSG_ALL, 3);
1564         WriteByte (MSG_ALL, 3);
1565         // done in FixIntermission
1566         */
1567
1568         //pos = FindIntermission ();
1569
1570         VoteReset();
1571
1572         DumpStats(TRUE);
1573
1574         if(cvar("sv_eventlog"))
1575                 GameLogEcho(":gameover");
1576
1577         GameLogClose();
1578
1579 // TO DO
1580
1581 // save the stats to a text file on the client
1582 // stuffcmd(other, log_stats "stats/file_name");
1583 // bprint stats
1584 // stuffcmd(other, log_stats "");
1585 // use a filename similar to the demo name
1586         // string file_name;
1587         // file_name = strcat("\nlog_file \"stats/", strftime(TRUE, "%Y-%m-%d_%H-%M"), "_", mapname, ".txt\"");  // open the log file
1588
1589 // write a stats parser for the menu
1590
1591         if(cvar("sv_accuracy_data_send")) {
1592                 string stats_to_send;
1593
1594                 FOR_EACH_CLIENT(other) {  // make the string to send
1595                         FixIntermissionClient(other);
1596
1597                         if(other.cvar_cl_accuracy_data_share) {
1598                                 stats_to_send = strcat(stats_to_send, ":hits:", other.netname);
1599
1600                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1601                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_hit[i-1]));
1602
1603                                 stats_to_send = strcat(stats_to_send, "\n:fired:", other.netname);
1604
1605                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1606                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_fired[i-1]));
1607
1608                                 stats_to_send = strcat(stats_to_send, "\n");
1609                         }
1610                 }
1611
1612                 FOR_EACH_REALCLIENT(other) {  // only spam humans
1613                         Score_NicePrint(other);  // print the score
1614
1615                         if(other.cvar_cl_accuracy_data_receive)  // send the stats string to all the willing clients
1616                                 bprint(stats_to_send);
1617                 }
1618         } else { // ye olde message
1619                 FOR_EACH_PLAYER(other) {
1620                         FixIntermissionClient(other);
1621
1622                         if(other.winning)
1623                                 bprint(other.netname, " ^7wins.\n");
1624                 }
1625         }
1626
1627         if(cvar("g_campaign"))
1628                 CampaignPreIntermission();
1629
1630         localcmd("\nsv_hook_gameend\n");
1631 }
1632
1633 /*
1634 ============
1635 CheckRules_Player
1636
1637 Exit deathmatch games upon conditions
1638 ============
1639 */
1640 void CheckRules_Player()
1641 {
1642         if (gameover)   // someone else quit the game already
1643                 return;
1644
1645         if(self.deadflag == DEAD_NO)
1646                 self.play_time += frametime;
1647
1648         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1649         //   (div0: and that in CheckRules_World please)
1650 };
1651
1652 float checkrules_equality;
1653 float checkrules_suddendeathwarning;
1654 float checkrules_suddendeathend;
1655 float checkrules_overtimesadded; //how many overtimes have been already added
1656
1657 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1658 float WINNING_YES = 1; // winner found
1659 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1660 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1661
1662 float InitiateSuddenDeath()
1663 {
1664         // Check first whether normal overtimes could be added before initiating suddendeath mode
1665         // - for this timelimit_overtime needs to be >0 of course
1666         // - also check the winning condition calculated in the previous frame and only add normal overtime
1667         //   again, if at the point at which timelimit would be extended again, still no winner was found
1668         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && !(g_race && !g_race_qualifying))
1669         {
1670                 return 1; // need to call InitiateOvertime later
1671         }
1672         else
1673         {
1674                 if(!checkrules_suddendeathend)
1675                 {
1676                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1677                         if(g_race && !g_race_qualifying)
1678                                 race_StartCompleting();
1679                 }
1680                 return 0;
1681         }
1682 }
1683
1684 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1685 {
1686         ++checkrules_overtimesadded;
1687         //add one more overtime by simply extending the timelimit
1688         float tl;
1689         tl = cvar("timelimit");
1690         tl += cvar("timelimit_overtime");
1691         cvar_set("timelimit", ftos(tl));
1692         string minutesPlural;
1693         if (cvar("timelimit_overtime") == 1)
1694                 minutesPlural = " ^3minute";
1695         else
1696                 minutesPlural = " ^3minutes";
1697
1698         bcenterprint(
1699                 strcat(
1700                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1701                         ftos(cvar("timelimit_overtime")),
1702                         minutesPlural,
1703                         " to the game!"
1704                 )
1705         );
1706 }
1707
1708 float GetWinningCode(float fraglimitreached, float equality)
1709 {
1710         if(cvar("g_campaign") == 1)
1711                 if(fraglimitreached)
1712                         return WINNING_YES;
1713                 else
1714                         return WINNING_NO;
1715
1716         else
1717                 if(equality)
1718                         if(fraglimitreached)
1719                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1720                         else
1721                                 return WINNING_NEVER;
1722                 else
1723                         if(fraglimitreached)
1724                                 return WINNING_YES;
1725                         else
1726                                 return WINNING_NO;
1727 }
1728
1729 // set the .winning flag for exactly those players with a given field value
1730 void SetWinners(.float field, float value)
1731 {
1732         entity head;
1733         FOR_EACH_PLAYER(head)
1734                 head.winning = (head.field == value);
1735 }
1736
1737 // set the .winning flag for those players with a given field value
1738 void AddWinners(.float field, float value)
1739 {
1740         entity head;
1741         FOR_EACH_PLAYER(head)
1742                 if(head.field == value)
1743                         head.winning = 1;
1744 }
1745
1746 // clear the .winning flags
1747 void ClearWinners(void)
1748 {
1749         entity head;
1750         FOR_EACH_PLAYER(head)
1751                 head.winning = 0;
1752 }
1753
1754 // Onslaught winning condition:
1755 // game terminates if only one team has a working generator (or none)
1756 float WinningCondition_Onslaught()
1757 {
1758         entity head;
1759         local float t1, t2, t3, t4;
1760
1761         WinningConditionHelper(); // set worldstatus
1762
1763         if(inWarmupStage)
1764                 return WINNING_NO;
1765
1766         // first check if the game has ended
1767         t1 = t2 = t3 = t4 = 0;
1768         head = find(world, classname, "onslaught_generator");
1769         while (head)
1770         {
1771                 if (head.health > 0)
1772                 {
1773                         if (head.team == COLOR_TEAM1) t1 = 1;
1774                         if (head.team == COLOR_TEAM2) t2 = 1;
1775                         if (head.team == COLOR_TEAM3) t3 = 1;
1776                         if (head.team == COLOR_TEAM4) t4 = 1;
1777                 }
1778                 head = find(head, classname, "onslaught_generator");
1779         }
1780         if (t1 + t2 + t3 + t4 < 2)
1781         {
1782                 // game over, only one team remains (or none)
1783                 ClearWinners();
1784                 if (t1) SetWinners(team, COLOR_TEAM1);
1785                 if (t2) SetWinners(team, COLOR_TEAM2);
1786                 if (t3) SetWinners(team, COLOR_TEAM3);
1787                 if (t4) SetWinners(team, COLOR_TEAM4);
1788                 dprint("Have a winner, ending game.\n");
1789                 return WINNING_YES;
1790         }
1791
1792         // Two or more teams remain
1793         return WINNING_NO;
1794 }
1795
1796 float LMS_NewPlayerLives()
1797 {
1798         float fl;
1799         fl = cvar("fraglimit");
1800         if(fl == 0)
1801                 fl = 999;
1802
1803         // first player has left the game for dying too much? Nobody else can get in.
1804         if(lms_lowest_lives < 1)
1805                 return 0;
1806
1807         if(!cvar("g_lms_join_anytime"))
1808                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1809                         return 0;
1810
1811         return bound(1, lms_lowest_lives, fl);
1812 }
1813
1814 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1815 // they win. Otherwise the defending team wins once the timelimit passes.
1816 void assault_new_round();
1817 float WinningCondition_Assault()
1818 {
1819         local float status;
1820
1821         WinningConditionHelper(); // set worldstatus
1822
1823         status = WINNING_NO;
1824         // as the timelimit has not yet passed just assume the defending team will win
1825         if(assault_attacker_team == COLOR_TEAM1)
1826         {
1827                 SetWinners(team, COLOR_TEAM2);
1828         }
1829         else
1830         {
1831                 SetWinners(team, COLOR_TEAM1);
1832         }
1833
1834         local entity ent;
1835         ent = find(world, classname, "target_assault_roundend");
1836         if(ent)
1837         {
1838                 if(ent.winning) // round end has been triggered by attacking team
1839                 {
1840                         bprint("ASSAULT: round completed...\n");
1841                         SetWinners(team, assault_attacker_team);
1842
1843                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1844
1845                         if(ent.cnt == 1 || cvar("g_campaign")) // this was the second round
1846                         {
1847                                 status = WINNING_YES;
1848                         }
1849                         else
1850                         {
1851                                 local entity oldself;
1852                                 oldself = self;
1853                                 self = ent;
1854                                 assault_new_round();
1855                                 self = oldself;
1856                         }
1857                 }
1858         }
1859
1860         return status;
1861 }
1862
1863 // LMS winning condition: game terminates if and only if there's at most one
1864 // one player who's living lives. Top two scores being equal cancels the time
1865 // limit.
1866 float WinningCondition_LMS()
1867 {
1868         entity head, head2;
1869         float have_player;
1870         float have_players;
1871         float l;
1872
1873         have_player = FALSE;
1874         have_players = FALSE;
1875         l = LMS_NewPlayerLives();
1876
1877         head = find(world, classname, "player");
1878         if(head)
1879                 have_player = TRUE;
1880         head2 = find(head, classname, "player");
1881         if(head2)
1882                 have_players = TRUE;
1883
1884         if(have_player)
1885         {
1886                 // we have at least one player
1887                 if(have_players)
1888                 {
1889                         // two or more active players - continue with the game
1890                 }
1891                 else
1892                 {
1893                         // exactly one player?
1894
1895                         ClearWinners();
1896                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1897
1898                         if(l)
1899                         {
1900                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1901                                 return WINNING_NO;
1902                         }
1903                         else
1904                         {
1905                                 // a winner!
1906                                 // and assign him his first place
1907                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1908                                 return WINNING_YES;
1909                         }
1910                 }
1911         }
1912         else
1913         {
1914                 // nobody is playing at all...
1915                 if(l)
1916                 {
1917                         // wait for players...
1918                 }
1919                 else
1920                 {
1921                         // SNAFU (maybe a draw game?)
1922                         ClearWinners();
1923                         dprint("No players, ending game.\n");
1924                         return WINNING_YES;
1925                 }
1926         }
1927
1928         // When we get here, we have at least two players who are actually LIVING,
1929         // now check if the top two players have equal score.
1930         WinningConditionHelper();
1931
1932         ClearWinners();
1933         if(WinningConditionHelper_winner)
1934                 WinningConditionHelper_winner.winning = TRUE;
1935         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1936                 return WINNING_NEVER;
1937
1938         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1939         return WINNING_NO;
1940 }
1941
1942 void ShuffleMaplist()
1943 {
1944         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1945 }
1946
1947 float leaderfrags;
1948 float WinningCondition_Scores(float limit, float leadlimit)
1949 {
1950         float limitreached;
1951
1952         // TODO make everything use THIS winning condition (except LMS)
1953         WinningConditionHelper();
1954
1955         if(teams_matter)
1956         {
1957                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1958                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1959                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1960                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1961         }
1962
1963         ClearWinners();
1964         if(WinningConditionHelper_winner)
1965                 WinningConditionHelper_winner.winning = 1;
1966         if(WinningConditionHelper_winnerteam >= 0)
1967                 SetWinners(team, WinningConditionHelper_winnerteam);
1968
1969         if(WinningConditionHelper_lowerisbetter)
1970         {
1971                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1972                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1973                 limit = -limit;
1974         }
1975
1976         if(WinningConditionHelper_zeroisworst)
1977                 leadlimit = 0; // not supported in this mode
1978
1979         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1980         // these modes always score in increments of 1, thus this makes sense
1981         {
1982                 if(leaderfrags != WinningConditionHelper_topscore)
1983                 {
1984                         leaderfrags = WinningConditionHelper_topscore;
1985
1986                         if (limit)
1987                         if (leaderfrags == limit - 1)
1988                                 Announce("1fragleft");
1989                         else if (leaderfrags == limit - 2)
1990                                 Announce("2fragsleft");
1991                         else if (leaderfrags == limit - 3)
1992                                 Announce("3fragsleft");
1993                 }
1994         }
1995
1996         limitreached = FALSE;
1997         if(limit)
1998                 if(WinningConditionHelper_topscore >= limit)
1999                         limitreached = TRUE;
2000         if(leadlimit)
2001         {
2002                 float leadlimitreached;
2003                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
2004                 if(cvar("leadlimit_and_fraglimit"))
2005                         limitreached = (limitreached && leadlimitreached);
2006                 else
2007                         limitreached = (limitreached || leadlimitreached);
2008         }
2009
2010         return GetWinningCode(
2011                 WinningConditionHelper_topscore && limitreached,
2012                 WinningConditionHelper_equality
2013         );
2014 }
2015
2016 float WinningCondition_Race(float fraglimit)
2017 {
2018         float wc;
2019         entity p;
2020         float n, c;
2021
2022         n = 0;
2023         c = 0;
2024         FOR_EACH_PLAYER(p)
2025         {
2026                 ++n;
2027                 if(p.race_completed)
2028                         ++c;
2029         }
2030         if(n && (n == c))
2031                 return WINNING_YES;
2032         wc = WinningCondition_Scores(fraglimit, 0);
2033
2034         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2035         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2036         // do NOT support equality when the laps are all raced!
2037                 return WINNING_STARTSUDDENDEATHOVERTIME;
2038         else
2039                 return WINNING_NEVER;
2040         return wc;
2041 }
2042
2043 void ReadyRestart();
2044 float WinningCondition_QualifyingThenRace(float limit)
2045 {
2046         float wc;
2047         wc = WinningCondition_Scores(limit, 0);
2048
2049         // NEVER initiate overtime
2050         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2051         {
2052                 return WINNING_YES;
2053         }
2054
2055         return wc;
2056 }
2057
2058 float WinningCondition_RanOutOfSpawns()
2059 {
2060         entity head;
2061
2062         if(have_team_spawns <= 0)
2063                 return WINNING_NO;
2064
2065         if(!some_spawn_has_been_used)
2066                 return WINNING_NO;
2067
2068         team1_score = team2_score = team3_score = team4_score = 0;
2069
2070         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2071         {
2072                 if(head.team == COLOR_TEAM1)
2073                         team1_score = 1;
2074                 else if(head.team == COLOR_TEAM2)
2075                         team2_score = 1;
2076                 else if(head.team == COLOR_TEAM3)
2077                         team3_score = 1;
2078                 else if(head.team == COLOR_TEAM4)
2079                         team4_score = 1;
2080         }
2081
2082         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2083         {
2084                 if(head.team == COLOR_TEAM1)
2085                         team1_score = 1;
2086                 else if(head.team == COLOR_TEAM2)
2087                         team2_score = 1;
2088                 else if(head.team == COLOR_TEAM3)
2089                         team3_score = 1;
2090                 else if(head.team == COLOR_TEAM4)
2091                         team4_score = 1;
2092         }
2093
2094         ClearWinners();
2095         if(team1_score + team2_score + team3_score + team4_score == 0)
2096         {
2097                 checkrules_equality = TRUE;
2098                 return WINNING_YES;
2099         }
2100         else if(team1_score + team2_score + team3_score + team4_score == 1)
2101         {
2102                 float t, i;
2103                 if(team1_score) t = COLOR_TEAM1;
2104                 if(team2_score) t = COLOR_TEAM2;
2105                 if(team3_score) t = COLOR_TEAM3;
2106                 if(team4_score) t = COLOR_TEAM4;
2107                 CheckAllowedTeams(world);
2108                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2109                 {
2110                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2111                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2112                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2113                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2114                 }
2115
2116                 AddWinners(team, t);
2117                 return WINNING_YES;
2118         }
2119         else
2120                 return WINNING_NO;
2121 }
2122
2123 /*
2124 ============
2125 CheckRules_World
2126
2127 Exit deathmatch games upon conditions
2128 ============
2129 */
2130 void CheckRules_World()
2131 {
2132         float timelimit;
2133         float fraglimit;
2134         float leadlimit;
2135
2136         VoteThink();
2137         MapVote_Think();
2138
2139         SetDefaultAlpha();
2140
2141         /*
2142         MapVote_Think should now do that part
2143         if (intermission_running)
2144                 if (time >= intermission_exittime + 60)
2145                 {
2146                         if(!DoNextMapOverride())
2147                                 GotoNextMap();
2148                         return;
2149                 }
2150         */
2151
2152         if (gameover)   // someone else quit the game already
2153         {
2154                 if(player_count == 0) // Nobody there? Then let's go to the next map
2155                         MapVote_Start();
2156                         // this will actually check the player count in the next frame
2157                         // again, but this shouldn't hurt
2158                 return;
2159         }
2160
2161         timelimit = cvar("timelimit") * 60;
2162         fraglimit = cvar("fraglimit");
2163         leadlimit = cvar("leadlimit");
2164
2165         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2166         {
2167                 if(timelimit > 0)
2168                         timelimit = 0; // timelimit is not made for warmup
2169                 if(fraglimit > 0)
2170                         fraglimit = 0; // no fraglimit for now
2171                 leadlimit = 0; // no leadlimit for now
2172         }
2173
2174         if(g_onslaught)
2175                 timelimit = 0; // ONS has its own overtime rule
2176
2177         if(timelimit > 0)
2178         {
2179                 timelimit += game_starttime;
2180         }
2181         else if (timelimit < 0)
2182         {
2183                 // endmatch
2184                 NextLevel();
2185                 return;
2186         }
2187
2188         float wantovertime;
2189         wantovertime = 0;
2190
2191         if(checkrules_suddendeathend)
2192         {
2193                 if(!checkrules_suddendeathwarning)
2194                 {
2195                         checkrules_suddendeathwarning = TRUE;
2196                         if(g_race && !g_race_qualifying)
2197                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2198                         else
2199                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2200                 }
2201         }
2202         else
2203         {
2204                 if (timelimit && time >= timelimit)
2205                 {
2206                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2207                         {
2208                                 float totalplayers;
2209                                 float playerswithlaps;
2210                                 float readyplayers;
2211                                 entity head;
2212                                 totalplayers = playerswithlaps = readyplayers = 0;
2213                                 FOR_EACH_PLAYER(head)
2214                                 {
2215                                         ++totalplayers;
2216                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2217                                                 ++playerswithlaps;
2218                                         if(head.ready)
2219                                                 ++readyplayers;
2220                                 }
2221
2222                                 // at least 2 of the players have completed a lap: start the RACE
2223                                 // otherwise, the players should end the qualifying on their own
2224                                 if(readyplayers || playerswithlaps >= 2)
2225                                 {
2226                                         checkrules_suddendeathend = 0;
2227                                         ReadyRestart(); // go to race
2228                                         return;
2229                                 }
2230                                 else
2231                                         wantovertime |= InitiateSuddenDeath();
2232                         }
2233                         else
2234                                 wantovertime |= InitiateSuddenDeath();
2235                 }
2236         }
2237
2238         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2239         {
2240                 NextLevel();
2241                 return;
2242         }
2243
2244         float checkrules_status;
2245         checkrules_status = WinningCondition_RanOutOfSpawns();
2246         if(checkrules_status == WINNING_YES)
2247         {
2248                 bprint("Hey! Someone ran out of spawns!\n");
2249         }
2250         else if(g_race && !g_race_qualifying && timelimit >= 0)
2251         {
2252                 checkrules_status = WinningCondition_Race(fraglimit);
2253                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2254         }
2255         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2256         {
2257                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2258                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2259         }
2260         else if(g_assault)
2261         {
2262                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2263         }
2264         else if(g_lms)
2265         {
2266                 checkrules_status = WinningCondition_LMS();
2267         }
2268         else if (g_onslaught)
2269         {
2270                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2271         }
2272         else
2273         {
2274                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2275                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2276         }
2277
2278         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2279         {
2280                 checkrules_status = WINNING_NEVER;
2281                 checkrules_overtimesadded = -1;
2282                 wantovertime |= InitiateSuddenDeath();
2283         }
2284
2285         if(checkrules_status == WINNING_NEVER)
2286                 // equality cases! Nobody wins if the overtime ends in a draw.
2287                 ClearWinners();
2288
2289         if(wantovertime)
2290         {
2291                 if(checkrules_status == WINNING_NEVER)
2292                         InitiateOvertime();
2293                 else
2294                         checkrules_status = WINNING_YES;
2295         }
2296
2297         if(checkrules_suddendeathend)
2298                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2299                         checkrules_status = WINNING_YES;
2300
2301         if(checkrules_status == WINNING_YES)
2302         {
2303                 //print("WINNING\n");
2304                 NextLevel();
2305         }
2306 };
2307
2308 float mapvote_nextthink;
2309 float mapvote_initialized;
2310 float mapvote_keeptwotime;
2311 float mapvote_timeout;
2312 string mapvote_message;
2313 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2314 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2315 float mapvote_screenshot_dirs_count;
2316
2317 float mapvote_count;
2318 float mapvote_count_real;
2319 string mapvote_maps[MAPVOTE_COUNT];
2320 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2321 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2322 float mapvote_maps_suggested[MAPVOTE_COUNT];
2323 string mapvote_suggestions[MAPVOTE_COUNT];
2324 float mapvote_suggestion_ptr;
2325 float mapvote_maxlen;
2326 float mapvote_voters;
2327 float mapvote_votes[MAPVOTE_COUNT];
2328 float mapvote_run;
2329 float mapvote_detail;
2330 float mapvote_abstain;
2331 .float mapvote;
2332
2333 void MapVote_ClearAllVotes()
2334 {
2335         FOR_EACH_CLIENT(other)
2336                 other.mapvote = 0;
2337 }
2338
2339 string MapVote_Suggest(string m)
2340 {
2341         float i;
2342         if(m == "")
2343                 return "That's not how to use this command.";
2344         if(!cvar("g_maplist_votable_suggestions"))
2345                 return "Suggestions are not accepted on this server.";
2346         if(mapvote_initialized)
2347                 return "Can't suggest - voting is already in progress!";
2348         m = MapInfo_FixName(m);
2349         if(!m)
2350                 return "The map you suggested is not available on this server.";
2351         if(!cvar("g_maplist_votable_suggestions_override_mostrecent"))
2352                 if(Map_IsRecent(m))
2353                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2354
2355         if(!MapInfo_CheckMap(m))
2356                 return "The map you suggested does not support the current game mode.";
2357         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2358                 if(mapvote_suggestions[i] == m)
2359                         return "This map was already suggested.";
2360         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2361         {
2362                 i = floor(random() * mapvote_suggestion_ptr);
2363         }
2364         else
2365         {
2366                 i = mapvote_suggestion_ptr;
2367                 mapvote_suggestion_ptr += 1;
2368         }
2369         if(mapvote_suggestions[i] != "")
2370                 strunzone(mapvote_suggestions[i]);
2371         mapvote_suggestions[i] = strzone(m);
2372         if(cvar("sv_eventlog"))
2373                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2374         return strcat("Suggestion of ", m, " accepted.");
2375 }
2376
2377 void MapVote_AddVotable(string nextMap, float isSuggestion)
2378 {
2379         float j, i, o;
2380         string pakfile, mapfile;
2381
2382         if(nextMap == "")
2383                 return;
2384         for(j = 0; j < mapvote_count; ++j)
2385                 if(mapvote_maps[j] == nextMap)
2386                         return;
2387         if(strlen(nextMap) > mapvote_maxlen)
2388                 mapvote_maxlen = strlen(nextMap);
2389         mapvote_maps[mapvote_count] = strzone(nextMap);
2390         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2391
2392         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2393         {
2394                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2395                 pakfile = whichpack(strcat(mapfile, ".tga"));
2396                 if(pakfile == "")
2397                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2398                 if(pakfile == "")
2399                         pakfile = whichpack(strcat(mapfile, ".png"));
2400                 if(pakfile != "")
2401                         break;
2402         }
2403         if(i >= mapvote_screenshot_dirs_count)
2404                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2405         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2406                 pakfile = substring(pakfile, o, -1);
2407
2408         mapvote_maps_screenshot_dir[mapvote_count] = i;
2409         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2410
2411         mapvote_count += 1;
2412 }
2413
2414 void MapVote_Spawn();
2415 void MapVote_Init()
2416 {
2417         float i;
2418         float nmax, smax;
2419
2420         MapVote_ClearAllVotes();
2421
2422         mapvote_count = 0;
2423         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2424         mapvote_abstain = cvar("g_maplist_votable_abstain");
2425
2426         if(mapvote_abstain)
2427                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2428         else
2429                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2430         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2431
2432         // we need this for AddVotable, as that cycles through the screenshot dirs
2433         mapvote_screenshot_dirs_count = tokenize_console(cvar_string("g_maplist_votable_screenshot_dir"));
2434         if(mapvote_screenshot_dirs_count == 0)
2435                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2436         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2437         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2438                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2439
2440         if(mapvote_suggestion_ptr)
2441                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2442                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2443
2444         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2445                 MapVote_AddVotable(GetNextMap(), FALSE);
2446
2447         if(mapvote_count == 0)
2448         {
2449                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2450                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2451                 if(cvar("g_maplist_shuffle"))
2452                         ShuffleMaplist();
2453                 localcmd("\nmenu_cmd sync\n");
2454                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2455                         MapVote_AddVotable(GetNextMap(), FALSE);
2456         }
2457
2458         mapvote_count_real = mapvote_count;
2459         if(mapvote_abstain)
2460                 MapVote_AddVotable("don't care", 0);
2461
2462         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2463
2464         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2465         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2466         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2467                 mapvote_keeptwotime = 0;
2468         mapvote_message = "Choose a map and press its key!";
2469
2470         MapVote_Spawn();
2471 }
2472
2473 void MapVote_SendPicture(float id)
2474 {
2475         msg_entity = self;
2476         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2477         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2478         WriteByte(MSG_ONE, id);
2479         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2480 }
2481
2482 float GameCommand_MapVote(string cmd)
2483 {
2484         if(!intermission_running)
2485                 return FALSE;
2486
2487         if(cmd == "mv_getpic")
2488         {
2489                 MapVote_SendPicture(stof(argv(1)));
2490                 return TRUE;
2491         }
2492
2493         return FALSE;
2494 }
2495
2496 float MapVote_GetMapMask()
2497 {
2498         float mask, i, power;
2499         mask = 0;
2500         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2501                 if(mapvote_maps[i] != "")
2502                         mask |= power;
2503         return mask;
2504 }
2505
2506 entity mapvote_ent;
2507 float MapVote_SendEntity(entity to, float sf)
2508 {
2509         float i;
2510
2511         if(sf & 1)
2512                 sf &~= 2; // if we send 1, we don't need to also send 2
2513
2514         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2515         WriteByte(MSG_ENTITY, sf);
2516
2517         if(sf & 1)
2518         {
2519                 // flag 1 == initialization
2520                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2521                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2522                 WriteString(MSG_ENTITY, "");
2523                 WriteByte(MSG_ENTITY, mapvote_count);
2524                 WriteByte(MSG_ENTITY, mapvote_abstain);
2525                 WriteByte(MSG_ENTITY, mapvote_detail);
2526                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2527                 if(mapvote_count <= 8)
2528                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2529                 else
2530                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2531                 for(i = 0; i < mapvote_count; ++i)
2532                         if(mapvote_maps[i] != "")
2533                         {
2534                                 if(mapvote_abstain && i == mapvote_count - 1)
2535                                 {
2536                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2537                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2538                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2539                                 }
2540                                 else
2541                                 {
2542                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2543                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2544                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2545                                 }
2546                         }
2547         }
2548
2549         if(sf & 2)
2550         {
2551                 // flag 2 == update of mask
2552                 if(mapvote_count <= 8)
2553                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2554                 else
2555                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2556         }
2557
2558         if(sf & 4)
2559         {
2560                 if(mapvote_detail)
2561                         for(i = 0; i < mapvote_count; ++i)
2562                                 if(mapvote_maps[i] != "")
2563                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2564
2565                 WriteByte(MSG_ENTITY, to.mapvote);
2566         }
2567
2568         return TRUE;
2569 }
2570
2571 void MapVote_Spawn()
2572 {
2573         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2574 }
2575
2576 void MapVote_TouchMask()
2577 {
2578         mapvote_ent.SendFlags |= 2;
2579 }
2580
2581 void MapVote_TouchVotes(entity voter)
2582 {
2583         mapvote_ent.SendFlags |= 4;
2584 }
2585
2586 float MapVote_Finished(float mappos)
2587 {
2588         string result;
2589         float i;
2590         float didntvote;
2591
2592         if(cvar("sv_eventlog"))
2593         {
2594                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2595                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2596                 didntvote = mapvote_voters;
2597                 for(i = 0; i < mapvote_count; ++i)
2598                         if(mapvote_maps[i] != "")
2599                         {
2600                                 didntvote -= mapvote_votes[i];
2601                                 if(i != mappos)
2602                                 {
2603                                         result = strcat(result, ":", mapvote_maps[i]);
2604                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2605                                 }
2606                         }
2607                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2608
2609                 GameLogEcho(result);
2610                 if(mapvote_maps_suggested[mappos])
2611                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2612         }
2613
2614         FOR_EACH_REALCLIENT(other)
2615                 FixClientCvars(other);
2616
2617         Map_Goto_SetStr(mapvote_maps[mappos]);
2618         Map_Goto();
2619         alreadychangedlevel = TRUE;
2620         return TRUE;
2621 }
2622 void MapVote_CheckRules_1()
2623 {
2624         float i;
2625
2626         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2627         {
2628                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2629                 mapvote_votes[i] = 0;
2630         }
2631
2632         mapvote_voters = 0;
2633         FOR_EACH_REALCLIENT(other)
2634         {
2635                 ++mapvote_voters;
2636                 if(other.mapvote)
2637                 {
2638                         i = other.mapvote - 1;
2639                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2640                         mapvote_votes[i] = mapvote_votes[i] + 1;
2641                 }
2642         }
2643 }
2644
2645 float MapVote_CheckRules_2()
2646 {
2647         float i;
2648         float firstPlace, secondPlace;
2649         float firstPlaceVotes, secondPlaceVotes;
2650         float mapvote_voters_real;
2651         string result;
2652
2653         if(mapvote_count_real == 1)
2654                 return MapVote_Finished(0);
2655
2656         mapvote_voters_real = mapvote_voters;
2657         if(mapvote_abstain)
2658                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2659
2660         RandomSelection_Init();
2661         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2662                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2663         firstPlace = RandomSelection_chosen_float;
2664         firstPlaceVotes = RandomSelection_best_priority;
2665         //dprint("First place: ", ftos(firstPlace), "\n");
2666         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2667
2668         RandomSelection_Init();
2669         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2670                 if(i != firstPlace)
2671                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2672         secondPlace = RandomSelection_chosen_float;
2673         secondPlaceVotes = RandomSelection_best_priority;
2674         //dprint("Second place: ", ftos(secondPlace), "\n");
2675         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2676
2677         if(firstPlace == -1)
2678                 error("No first place in map vote... WTF?");
2679
2680         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2681                 return MapVote_Finished(firstPlace);
2682
2683         if(mapvote_keeptwotime)
2684                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2685                 {
2686                         float didntvote;
2687                         MapVote_TouchMask();
2688                         mapvote_message = "Now decide between the TOP TWO!";
2689                         mapvote_keeptwotime = 0;
2690                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2691                         result = strcat(result, ":", ftos(firstPlaceVotes));
2692                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2693                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2694                         didntvote = mapvote_voters;
2695                         for(i = 0; i < mapvote_count; ++i)
2696                                 if(mapvote_maps[i] != "")
2697                                 {
2698                                         didntvote -= mapvote_votes[i];
2699                                         if(i != firstPlace)
2700                                                 if(i != secondPlace)
2701                                                 {
2702                                                         result = strcat(result, ":", mapvote_maps[i]);
2703                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2704                                                         if(i < mapvote_count_real)
2705                                                         {
2706                                                                 strunzone(mapvote_maps[i]);
2707                                                                 mapvote_maps[i] = "";
2708                                                                 strunzone(mapvote_maps_pakfile[i]);
2709                                                                 mapvote_maps_pakfile[i] = "";
2710                                                         }
2711                                                 }
2712                                 }
2713                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2714                         if(cvar("sv_eventlog"))
2715                                 GameLogEcho(result);
2716                 }
2717
2718         return FALSE;
2719 }
2720 void MapVote_Tick()
2721 {
2722         float keeptwo;
2723         float totalvotes;
2724
2725         keeptwo = mapvote_keeptwotime;
2726         MapVote_CheckRules_1(); // count
2727         if(MapVote_CheckRules_2()) // decide
2728                 return;
2729
2730         totalvotes = 0;
2731         FOR_EACH_REALCLIENT(other)
2732         {
2733                 // hide scoreboard again
2734                 if(other.health != 2342)
2735                 {
2736                         other.health = 2342;
2737                         other.impulse = 0;
2738                         if(clienttype(other) == CLIENTTYPE_REAL)
2739                         {
2740                                 msg_entity = other;
2741                                 WriteByte(MSG_ONE, SVC_FINALE);
2742                                 WriteString(MSG_ONE, "");
2743                         }
2744                 }
2745
2746                 // clear possibly invalid votes
2747                 if(mapvote_maps[other.mapvote - 1] == "")
2748                         other.mapvote = 0;
2749                 // use impulses as new vote
2750                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2751                         if(mapvote_maps[other.impulse - 1] != "")
2752                         {
2753                                 other.mapvote = other.impulse;
2754                                 MapVote_TouchVotes(other);
2755                         }
2756                 other.impulse = 0;
2757
2758                 if(other.mapvote)
2759                         ++totalvotes;
2760         }
2761
2762         MapVote_CheckRules_1(); // just count
2763 }
2764 void MapVote_Start()
2765 {
2766         if(mapvote_run)
2767                 return;
2768
2769         MapInfo_Enumerate();
2770         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2771                 mapvote_run = TRUE;
2772 }
2773 void MapVote_Think()
2774 {
2775         if(!mapvote_run)
2776                 return;
2777
2778         if(alreadychangedlevel)
2779                 return;
2780
2781         if(time < mapvote_nextthink)
2782                 return;
2783         //dprint("tick\n");
2784
2785         mapvote_nextthink = time + 0.5;
2786
2787         if(!mapvote_initialized)
2788         {
2789                 if(cvar("rescan_pending") == 1)
2790                 {
2791                         cvar_set("rescan_pending", "2");
2792                         localcmd("fs_rescan\nrescan_pending 3\n");
2793                         return;
2794                 }
2795                 else if(cvar("rescan_pending") == 2)
2796                 {
2797                         return;
2798                 }
2799                 else if(cvar("rescan_pending") == 3)
2800                 {
2801                         // now build missing mapinfo files
2802                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2803                                 return;
2804
2805                         // we're done, start the timer
2806                         cvar_set("rescan_pending", "0");
2807                 }
2808
2809                 mapvote_initialized = TRUE;
2810                 if(DoNextMapOverride())
2811                         return;
2812                 if(!cvar("g_maplist_votable") || player_count <= 0)
2813                 {
2814                         GotoNextMap();
2815                         return;
2816                 }
2817                 MapVote_Init();
2818         }
2819
2820         MapVote_Tick();
2821 };
2822
2823 string GotoMap(string m)
2824 {
2825         if(!MapInfo_CheckMap(m))
2826                 return "The map you chose is not available on this server.";
2827         cvar_set("nextmap", m);
2828         cvar_set("timelimit", "-1");
2829         if(mapvote_initialized || alreadychangedlevel)
2830         {
2831                 if(DoNextMapOverride())
2832                         return "Map switch initiated.";
2833                 else
2834                         return "Hm... no. For some reason I like THIS map more.";
2835         }
2836         else
2837                 return "Map switch will happen after scoreboard.";
2838 }
2839
2840
2841 void EndFrame()
2842 {
2843         float altime;
2844         FOR_EACH_REALCLIENT(self)
2845         {
2846                 if(self.classname == "spectator")
2847                 {
2848                         if(self.enemy.typehitsound)
2849                                 play2(self, "misc/typehit.wav");
2850                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2851                                 play2(self, "misc/hit.wav");
2852                 }
2853                 else
2854                 {
2855                         if(self.typehitsound)
2856                                 play2(self, "misc/typehit.wav");
2857                         else if(self.hitsound && self.cvar_cl_hitsound)
2858                                 play2(self, "misc/hit.wav");
2859                 }
2860         }
2861         altime = time + frametime * (1 + cvar("g_antilag_nudge"));
2862         // add 1 frametime because after this, engine SV_Physics
2863         // increases time by a frametime and then networks the frame
2864         // add another frametime because client shows everything with
2865         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2866         // needed!
2867         FOR_EACH_CLIENT(self)
2868         {
2869                 self.hitsound = FALSE;
2870                 self.typehitsound = FALSE;
2871                 antilag_record(self, altime);
2872         }
2873 }
2874
2875
2876 /*
2877  * RedirectionThink:
2878  * returns TRUE if redirecting
2879  */
2880 float redirection_timeout;
2881 float redirection_nextthink;
2882 float RedirectionThink()
2883 {
2884         float clients_found;
2885
2886         if(redirection_target == "")
2887                 return FALSE;
2888
2889         if(!redirection_timeout)
2890         {
2891                 cvar_set("sv_public", "-2");
2892                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2893                 if(redirection_target == "self")
2894                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2895                 else
2896                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2897         }
2898
2899         if(time < redirection_nextthink)
2900                 return TRUE;
2901
2902         redirection_nextthink = time + 1;
2903
2904         clients_found = 0;
2905         FOR_EACH_REALCLIENT(self)
2906         {
2907                 print("Redirecting: sending connect command to ", self.netname, "\n");
2908                 if(redirection_target == "self")
2909                         stuffcmd(self, "\ndisconnect; reconnect\n");
2910                 else
2911                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2912                 ++clients_found;
2913         }
2914
2915         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2916
2917         if(time > redirection_timeout || clients_found == 0)
2918                 localcmd("\nwait; wait; wait; quit\n");
2919
2920         return TRUE;
2921 }
2922
2923 void TargetMusic_RestoreGame();
2924 void RestoreGame()
2925 {
2926         // Loaded from a save game
2927         // some things then break, so let's work around them...
2928
2929         // Progs DB (capture records)
2930         ServerProgsDB = db_load("server.db");
2931
2932         // Mapinfo
2933         MapInfo_Shutdown();
2934         MapInfo_Enumerate();
2935         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2936         WeaponStats_Init();
2937
2938         TargetMusic_RestoreGame();
2939 }
2940
2941 void SV_Shutdown()
2942 {
2943         if(gameover > 1) // shutting down already?
2944                 return;
2945
2946         gameover = 2; // 2 = server shutting down
2947
2948         if(world_initialized > 0)
2949         {
2950                 world_initialized = 0;
2951                 print("Saving persistent data...\n");
2952                 Ban_SaveBans();
2953                 if(!cheatcount_total)
2954                 {
2955                         if(cvar("sv_db_saveasdump"))
2956                                 db_dump(ServerProgsDB, "server.db");
2957                         else
2958                                 db_save(ServerProgsDB, "server.db");
2959                 }
2960                 if(cvar("developer"))
2961                 {
2962                         if(cvar("sv_db_saveasdump"))
2963                                 db_dump(TemporaryDB, "server-temp.db");
2964                         else
2965                                 db_save(TemporaryDB, "server-temp.db");
2966                 }
2967                 CheatShutdown(); // must be after cheatcount check
2968                 db_close(ServerProgsDB);
2969                 db_close(TemporaryDB);
2970                 print("done!\n");
2971                 // tell the bot system the game is ending now
2972                 bot_endgame();
2973
2974                 WeaponStats_Shutdown();
2975                 MapInfo_Shutdown();
2976         }
2977         else if(world_initialized == 0)
2978         {
2979                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2980         }
2981 }