qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         entity plr;
 105         if (timeoutStatus == 1) {
 106                 if (remainingLeadTime > 0) {
 107                         //centerprint the information to every player
 108                         FOR_EACH_REALCLIENT(plr) {
 109                                 if(plr.classname == "player") {
 110                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout begins in %d seconds!", 1, remainingLeadTime);
 111                                 }
 112                         }
 113                         remainingLeadTime -= 1;
 114                         //think again in 1 second:
 115                         self.nextthink = time + 1;
 116                 }
 117                 else {
 118                         //now pause the game:
 119                         timeoutStatus = 2;
 120                         //reset all the flood variables
 121                         FOR_EACH_CLIENT(plr) {
 122                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 123                         }
 124                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 125                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 126                         FOR_EACH_REALPLAYER(plr) {
 127                                 plr.lastV_angle = plr.v_angle;
 128                         }
 129                         self.nextthink = time;
 130                 }
 131         }
 132         else if (timeoutStatus == 2) {
 133                 if (remainingTimeoutTime > 0) {
 134                         FOR_EACH_REALCLIENT(plr) {
 135                                 if(plr.classname == "player") {
 136                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout ends in %d seconds!", 1, remainingTimeoutTime);
 137                                 }
 138                         }
 139                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 140                                 Announce("prepareforbattle");
 141                         }
 142                         remainingTimeoutTime -= 1;
 143                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 144                 }
 145                 else {
 146                         //unpause the game again
 147                         remainingTimeoutTime = timeoutStatus = 0;
 148                         cvar_set("slowmo", ftos(orig_slowmo));
 149                         //and unlock the fixed view again once there is no timeout active anymore
 150                         FOR_EACH_REALPLAYER(plr) {
 151                                 plr.fixangle = FALSE;
 152                         }
 153                         //get rid of the countdown message
 154                         FOR_EACH_REALCLIENT(plr) {
 155                                 if(plr.classname == "player") {
 156                                         Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 157                                 }
 158                         }
 159                         remove(self);
 160                         return;
 161                 }
 162
 163         }
 164         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 165                 FOR_EACH_REALCLIENT(plr) {
 166                         if(plr.classname == "player") {
 167                                 Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 168                         }
 169                 }
 170                 remove(self);
 171                 return;
 172         }
 173 }
 174
 175 void GotoFirstMap()
 176 {
 177         float n;
 178         if(autocvar__sv_init)
 179         {
 180                 // cvar_set("_sv_init", "0");
 181                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 182                 // to this "init" map on a dedicated server will cause no permanent
 183                 // harm
 184                 if(autocvar_g_maplist_shuffle)
 185                         ShuffleMaplist();
 186                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 187                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 188
 189                 MapInfo_Enumerate();
 190                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 191
 192                 if(!DoNextMapOverride())
 193                         GotoNextMap();
 194
 195                 return;
 196         }
 197
 198         if(time < 5)
 199         {
 200                 self.nextthink = time;
 201         }
 202         else
 203         {
 204                 self.nextthink = time + 1;
 205                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 206         }
 207 }
 208
 209 void cvar_changes_init()
 210 {
 211         float h;
 212         string k, v, d;
 213         float n, i, adding, pureadding;
 214
 215         if(cvar_changes)
 216                 strunzone(cvar_changes);
 217         cvar_changes = string_null;
 218         if(cvar_purechanges)
 219                 strunzone(cvar_purechanges);
 220         cvar_purechanges = string_null;
 221         cvar_purechanges_count = 0;
 222
 223         h = buf_create();
 224         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 225         n = buf_getsize(h);
 226
 227         adding = TRUE;
 228         pureadding = TRUE;
 229
 230         for(i = 0; i < n; ++i)
 231         {
 232                 k = bufstr_get(h, i);
 233
 234 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 235 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 236 #define BADCVAR(p) if(k == p) continue
 237
 238                 // general excludes and namespaces for server admin used cvars
 239                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 240
 241                 // internal
 242                 BADPREFIX("csqc_");
 243                 BADPREFIX("cvar_check_");
 244                 BADCVAR("gamecfg");
 245                 BADCVAR("g_configversion");
 246                 BADCVAR("g_maplist_index");
 247                 BADCVAR("halflifebsp");
 248                 BADPREFIX("sv_world");
 249
 250                 // client
 251                 BADPREFIX("chase_");
 252                 BADPREFIX("cl_");
 253                 BADPREFIX("con_");
 254                 BADPREFIX("scoreboard_");
 255                 BADPREFIX("g_campaign");
 256                 BADPREFIX("g_waypointsprite_");
 257                 BADPREFIX("gl_");
 258                 BADPREFIX("joy");
 259                 BADPREFIX("hud_");
 260                 BADPREFIX("m_");
 261                 BADPREFIX("menu_");
 262                 BADPREFIX("net_slist_");
 263                 BADPREFIX("r_");
 264                 BADPREFIX("sbar_");
 265                 BADPREFIX("scr_");
 266                 BADPREFIX("snd_");
 267                 BADPREFIX("show");
 268                 BADPREFIX("sensitivity");
 269                 BADPREFIX("userbind");
 270                 BADPREFIX("v_");
 271                 BADPREFIX("vid_");
 272                 BADPREFIX("crosshair");
 273                 BADCVAR("mod_q3bsp_lightmapmergepower");
 274                 BADCVAR("mod_q3bsp_nolightmaps");
 275                 BADCVAR("fov");
 276                 BADCVAR("mastervolume");
 277                 BADCVAR("volume");
 278                 BADCVAR("bgmvolume");
 279
 280                 // private
 281                 BADCVAR("developer");
 282                 BADCVAR("log_dest_udp");
 283                 BADCVAR("log_file");
 284                 BADCVAR("net_address");
 285                 BADCVAR("net_address_ipv6");
 286                 BADCVAR("port");
 287                 BADCVAR("savedgamecfg");
 288                 BADCVAR("serverconfig");
 289                 BADCVAR("sv_autoscreenshot");
 290                 BADCVAR("sv_heartbeatperiod");
 291                 BADCVAR("sv_vote_master_password");
 292                 BADCVAR("sys_colortranslation");
 293                 BADCVAR("sys_specialcharactertranslation");
 294                 BADCVAR("timeformat");
 295                 BADCVAR("timestamps");
 296                 BADPREFIX("developer_");
 297                 BADPREFIX("g_ban_");
 298                 BADPREFIX("g_banned_list");
 299                 BADPREFIX("g_chat_flood_");
 300                 BADPREFIX("g_playerstats_");
 301                 BADPREFIX("g_voice_flood_");
 302                 BADPREFIX("rcon_");
 303                 BADPREFIX("settemp_");
 304                 BADPREFIX("sv_allowdownloads_");
 305                 BADPREFIX("sv_autodemo");
 306                 BADPREFIX("sv_curl_");
 307                 BADPREFIX("sv_eventlog");
 308                 BADPREFIX("sv_logscores_");
 309                 BADPREFIX("sv_master");
 310                 BADPREFIX("sv_weaponstats_");
 311                 BADPREFIX("sv_waypointsprite_");
 312                 BADCVAR("rescan_pending");
 313
 314                 // these can contain player IDs, so better hide
 315                 BADPREFIX("g_forced_team_");
 316
 317                 // mapinfo
 318                 BADCVAR("fraglimit");
 319                 BADCVAR("g_arena");
 320                 BADCVAR("g_assault");
 321                 BADCVAR("g_ca");
 322                 BADCVAR("g_ctf");
 323                 BADCVAR("g_cts");
 324                 BADCVAR("g_dm");
 325                 BADCVAR("g_domination");
 326                 BADCVAR("g_domination_default_teams");
 327                 BADCVAR("g_freezetag");
 328                 BADCVAR("g_keepaway");
 329                 BADCVAR("g_keyhunt");
 330                 BADCVAR("g_keyhunt_teams");
 331                 BADCVAR("g_keyhunt_teams");
 332                 BADCVAR("g_lms");
 333                 BADCVAR("g_nexball");
 334                 BADCVAR("g_onslaught");
 335                 BADCVAR("g_race");
 336                 BADCVAR("g_race_qualifying_timelimit");
 337                 BADCVAR("g_runematch");
 338                 BADCVAR("g_tdm");
 339                 BADCVAR("g_tdm_teams");
 340                 BADCVAR("leadlimit");
 341                 BADCVAR("nextmap");
 342                 BADCVAR("teamplay");
 343                 BADCVAR("timelimit");
 344
 345                 // long
 346                 BADCVAR("hostname");
 347                 BADCVAR("g_maplist");
 348                 BADCVAR("g_maplist_mostrecent");
 349                 BADCVAR("sv_motd");
 350
 351                 v = cvar_string(k);
 352                 d = cvar_defstring(k);
 353                 if(v == d)
 354                         continue;
 355
 356                 if(adding)
 357                 {
 358                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 359                         if(strlen(cvar_changes) > 16384)
 360                         {
 361                                 cvar_changes = "// too many settings have been changed to show them here\n";
 362                                 adding = 0;
 363                         }
 364                 }
 365
 366                 // now check if the changes are actually gameplay relevant
 367
 368                 // does nothing visible
 369                 BADCVAR("captureleadlimit_override");
 370                 BADCVAR("g_arena_point_leadlimit");
 371                 BADCVAR("g_balance_kill_delay");
 372                 BADCVAR("g_ca_point_leadlimit");
 373                 BADCVAR("g_ctf_captimerecord_always");
 374                 BADCVAR("g_ctf_capture_leadlimit");
 375                 BADCVAR("g_ctf_flag_capture_effects");
 376                 BADCVAR("g_ctf_flag_glowtrails");
 377                 BADCVAR("g_ctf_flag_pickup_effects");
 378                 BADCVAR("g_domination_point_leadlimit");
 379                 BADCVAR("g_forced_respawn");
 380                 BADCVAR("g_keyhunt_point_leadlimit");
 381                 BADCVAR("g_nexball_goalleadlimit");
 382                 BADCVAR("g_runematch_point_leadlimit");
 383                 BADCVAR("leadlimit_and_fraglimit");
 384                 BADCVAR("leadlimit_override");
 385                 BADCVAR("pausable");
 386                 BADCVAR("sv_allow_fullbright");
 387                 BADCVAR("sv_checkforpacketsduringsleep");
 388                 BADCVAR("sv_timeout");
 389                 BADCVAR("welcome_message_time");
 390                 BADPREFIX("crypto_");
 391                 BADPREFIX("g_chat_");
 392                 BADPREFIX("g_ctf_captimerecord_");
 393                 BADPREFIX("g_maplist_votable_");
 394                 BADPREFIX("net_");
 395                 BADPREFIX("prvm_");
 396                 BADPREFIX("skill_");
 397                 BADPREFIX("sv_cullentities_");
 398                 BADPREFIX("sv_fraginfo_");
 399                 BADPREFIX("sv_maxidle_");
 400                 BADPREFIX("sv_vote_");
 401                 BADPREFIX("timelimit_");
 402                 BADCVAR("gameversion");
 403                 BADPREFIX("gameversion_");
 404                 BADCVAR("sv_namechangetimer");
 405
 406                 // allowed changes to server admins (please sync this to server.cfg)
 407                 // vi commands:
 408                 //   :/"impure"/,$d
 409                 //   :g!,^\/\/[^ /],d
 410                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 411                 //   :%!sort
 412                 // yes, this does contain some redundant stuff, don't really care
 413                 BADCVAR("bot_number");
 414                 BADCVAR("bot_prefix");
 415                 BADCVAR("bot_suffix");
 416                 BADCVAR("bot_config_file");
 417                 BADCVAR("capturelimit_override");
 418                 BADCVAR("fraglimit_override");
 419                 BADCVAR("gametype");
 420                 BADCVAR("g_antilag");
 421                 BADCVAR("g_balance_teams");
 422                 BADCVAR("g_balance_teams_force");
 423                 BADCVAR("g_ban_sync_trusted_servers");
 424                 BADCVAR("g_ban_sync_uri");
 425                 BADCVAR("g_ctf_capture_limit");
 426                 BADCVAR("g_ctf_ignore_frags");
 427                 BADCVAR("g_ctf_win_mode");
 428                 BADCVAR("g_domination_point_limit");
 429                 BADCVAR("g_friendlyfire");
 430                 BADCVAR("g_fullbrightitems");
 431                 BADCVAR("g_fullbrightplayers");
 432                 BADCVAR("g_keyhunt_point_limit");
 433                 BADCVAR("g_keyhunt_teams_override");
 434                 BADCVAR("g_lms_lives_override");
 435                 BADCVAR("g_maplist");
 436                 BADCVAR("g_maplist_check_waypoints");
 437                 BADCVAR("g_maplist_mostrecent_count");
 438                 BADCVAR("g_maplist_shuffle");
 439                 BADCVAR("g_maplist_votable");
 440                 BADCVAR("g_maplist_votable_abstain");
 441                 BADCVAR("g_maplist_votable_nodetail");
 442                 BADCVAR("g_maplist_votable_suggestions");
 443                 BADCVAR("g_maxplayers");
 444                 BADCVAR("g_minstagib");
 445                 BADCVAR("g_mirrordamage");
 446                 BADCVAR("g_nexball_goallimit");
 447                 BADCVAR("g_runematch_point_limit");
 448                 BADCVAR("g_start_delay");
 449                 BADCVAR("g_warmup");
 450                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 451                 BADCVAR("hostname");
 452                 BADCVAR("log_file");
 453                 BADCVAR("maxplayers");
 454                 BADCVAR("minplayers");
 455                 BADCVAR("net_address");
 456                 BADCVAR("port");
 457                 BADCVAR("rcon_password");
 458                 BADCVAR("rcon_restricted_commands");
 459                 BADCVAR("rcon_restricted_password");
 460                 BADCVAR("skill");
 461                 BADCVAR("sv_adminnick");
 462                 BADCVAR("sv_autoscreenshot");
 463                 BADCVAR("sv_curl_defaulturl");
 464                 BADCVAR("sv_defaultcharacter");
 465                 BADCVAR("sv_defaultplayercolors");
 466                 BADCVAR("sv_defaultplayermodel");
 467                 BADCVAR("sv_defaultplayerskin");
 468                 BADCVAR("sv_maxidle");
 469                 BADCVAR("sv_maxrate");
 470                 BADCVAR("sv_motd");
 471                 BADCVAR("sv_public");
 472                 BADCVAR("sv_ready_restart");
 473                 BADCVAR("sv_status_privacy");
 474                 BADCVAR("sv_vote_call");
 475                 BADCVAR("sv_vote_commands");
 476                 BADCVAR("sv_vote_majority_factor");
 477                 BADCVAR("sv_vote_master");
 478                 BADCVAR("sv_vote_master_commands");
 479                 BADCVAR("sv_vote_master_password");
 480                 BADCVAR("sv_vote_simple_majority_factor");
 481                 BADCVAR("sys_ticrate");
 482                 BADCVAR("teamplay_mode");
 483                 BADCVAR("timelimit_override");
 484                 BADPREFIX("g_warmup_");
 485
 486                 if(autocvar_g_minstagib)
 487                 {
 488                         BADCVAR("g_grappling_hook");
 489                         BADCVAR("g_jetpack");
 490                 }
 491 #undef BADPREFIX
 492 #undef BADCVAR
 493
 494                 if(pureadding)
 495                 {
 496                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 497                         if(strlen(cvar_purechanges) > 16384)
 498                         {
 499                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 500                                 pureadding = 0;
 501                         }
 502                 }
 503                 ++cvar_purechanges_count;
 504                 // WARNING: this variable is used for the server list
 505                 // NEVER dare to skip this code!
 506                 // Hacks to intentionally appearing as "pure server" even though you DO have
 507                 // modified settings may be punished by removal from the server list.
 508                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 509                 // though.
 510         }
 511         buf_del(h);
 512         if(cvar_changes == "")
 513                 cvar_changes = "// this server runs at default server settings\n";
 514         else
 515                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 516         cvar_changes = strzone(cvar_changes);
 517         if(cvar_purechanges == "")
 518                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 519         else
 520                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 521         cvar_purechanges = strzone(cvar_purechanges);
 522 }
 523
 524 void detect_maptype()
 525 {
 526 #if 0
 527         vector o, v;
 528         float i;
 529
 530         for(;;)
 531         {
 532                 o = world.mins;
 533                 o_x += random() * (world.maxs_x - world.mins_x);
 534                 o_y += random() * (world.maxs_y - world.mins_y);
 535                 o_z += random() * (world.maxs_z - world.mins_z);
 536
 537                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 538                 if(trace_fraction == 1)
 539                         continue;
 540
 541                 v = trace_endpos;
 542
 543                 for(i = 0; i < 64; i += 4)
 544                 {
 545                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 546         if(trace_fraction == 1)
 547                 continue;
 548                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 549                 }
 550
 551                 break;
 552         }
 553 #endif
 554 }
 555
 556 entity randomseed;
 557 float RandomSeed_Send(entity to, float sf)
 558 {
 559         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 560         WriteShort(MSG_ENTITY, self.cnt);
 561         return TRUE;
 562 }
 563 void RandomSeed_Think()
 564 {
 565         self.cnt = bound(0, floor(random() * 65536), 65535);
 566         self.nextthink = time + 5;
 567
 568         self.SendFlags |= 1;
 569 }
 570 void RandomSeed_Spawn()
 571 {
 572         randomseed = spawn();
 573         randomseed.think = RandomSeed_Think;
 574         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 575
 576         entity oldself;
 577         oldself = self;
 578         self = randomseed;
 579         self.think(); // sets random seed and nextthink
 580         self = oldself;
 581 }
 582
 583 void spawnfunc___init_dedicated_server(void)
 584 {
 585         // handler for _init/_init map (only for dedicated server initialization)
 586
 587         world_initialized = -1; // don't complain
 588         cvar = cvar_normal;
 589         cvar_string = cvar_string_normal;
 590         cvar_set = cvar_set_normal;
 591
 592         remove = remove_unsafely;
 593
 594         entity e;
 595         e = spawn();
 596         e.think = GotoFirstMap;
 597         e.nextthink = time; // this is usually 1 at this point
 598
 599         e = spawn();
 600         e.classname = "info_player_deathmatch"; // safeguard against player joining
 601
 602         self.classname = "worldspawn"; // safeguard against various stuff ;)
 603
 604         MapInfo_Enumerate();
 605         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 606 }
 607
 608 void Map_MarkAsRecent(string m);
 609 float world_already_spawned;
 610 void RegisterWeapons();
 611 void Nagger_Init();
 612 void ClientInit_Spawn();
 613 void WeaponStats_Init();
 614 void WeaponStats_Shutdown();
 615 void spawnfunc_worldspawn (void)
 616 {
 617         float fd, l, i, j, n;
 618         string s, col;
 619
 620         cvar = cvar_normal;
 621         cvar_string = cvar_string_normal;
 622         cvar_set = cvar_set_normal;
 623
 624         if(world_already_spawned)
 625                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 626         world_already_spawned = TRUE;
 627
 628         remove = remove_safely; // during spawning, watch what you remove!
 629
 630         check_unacceptable_compiler_bugs();
 631
 632         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 633
 634         compressShortVector_init();
 635
 636         allowed_to_spawn = TRUE;
 637
 638         entity head;
 639         head = nextent(world);
 640         maxclients = 0;
 641         while(head)
 642         {
 643                 ++maxclients;
 644                 head = nextent(head);
 645         }
 646
 647         // needs to be done so early as they would still spawn
 648         RegisterWeapons();
 649
 650         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 651
 652         TemporaryDB = db_create();
 653
 654         // 0 normal
 655         lightstyle(0, "m");
 656
 657         // 1 FLICKER (first variety)
 658         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 659
 660         // 2 SLOW STRONG PULSE
 661         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 662
 663         // 3 CANDLE (first variety)
 664         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 665
 666         // 4 FAST STROBE
 667         lightstyle(4, "mamamamamama");
 668
 669         // 5 GENTLE PULSE 1
 670         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 671
 672         // 6 FLICKER (second variety)
 673         lightstyle(6, "nmonqnmomnmomomno");
 674
 675         // 7 CANDLE (second variety)
 676         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 677
 678         // 8 CANDLE (third variety)
 679         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 680
 681         // 9 SLOW STROBE (fourth variety)
 682         lightstyle(9, "aaaaaaaazzzzzzzz");
 683
 684         // 10 FLUORESCENT FLICKER
 685         lightstyle(10, "mmamammmmammamamaaamammma");
 686
 687         // 11 SLOW PULSE NOT FADE TO BLACK
 688         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 689
 690         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 691
 692         // 63 testing
 693         lightstyle(63, "a");
 694
 695         if(autocvar_g_campaign)
 696                 CampaignPreInit();
 697
 698         Map_MarkAsRecent(mapname);
 699
 700         precache_model ("null"); // we need this one before InitGameplayMode
 701         InitGameplayMode();
 702         readlevelcvars();
 703         GrappleHookInit();
 704         ElectroInit();
 705         LaserInit();
 706
 707         player_count = 0;
 708         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 709         if(bot_waypoints_for_items == 1)
 710                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 711                         bot_waypoints_for_items = 0;
 712
 713         precache();
 714
 715         WaypointSprite_Init();
 716
 717         //if (g_domination)
 718         //      dom_init();
 719
 720         GameLogInit(); // prepare everything
 721         // NOTE for matchid:
 722         // changing the logic generating it is okay. But:
 723         // it HAS to stay <= 64 chars
 724         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 725         if(autocvar_sv_eventlog)
 726         {
 727                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 728                 matchid = strzone(s);
 729
 730                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 731                 s = ":gameinfo:mutators:LIST";
 732
 733                 ret_string = s;
 734                 MUTATOR_CALLHOOK(BuildMutatorsString);
 735                 s = ret_string;
 736
 737                 // simple, probably not good in the mutator system
 738                 if(autocvar_g_grappling_hook)
 739                         s = strcat(s, ":grappling_hook");
 740
 741                 // initialiation stuff, not good in the mutator system
 742                 if(!autocvar_g_use_ammunition)
 743                         s = strcat(s, ":no_use_ammunition");
 744
 745                 // initialiation stuff, not good in the mutator system
 746                 if(!autocvar_g_pickup_items)
 747                         s = strcat(s, ":no_pickup_items");
 748
 749                 // initialiation stuff, not good in the mutator system
 750                 if(autocvar_g_weaponarena != "0")
 751                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 752
 753                 // TODO to mutator system
 754                 if(autocvar_g_norecoil)
 755                         s = strcat(s, ":norecoil");
 756
 757                 // TODO to mutator system
 758                 if(autocvar_g_midair)
 759                         s = strcat(s, ":midair");
 760
 761                 // TODO to mutator system
 762                 if(autocvar_g_minstagib)
 763                         s = strcat(s, ":minstagib");
 764
 765                 GameLogEcho(s);
 766                 GameLogEcho(":gameinfo:end");
 767         }
 768         else
 769                 matchid = strzone(ftos(random()));
 770
 771         cvar_set("nextmap", "");
 772
 773         SetDefaultAlpha();
 774
 775         if(autocvar_g_campaign)
 776                 CampaignPostInit();
 777
 778         fteqcc_testbugs();
 779
 780         Ban_LoadBans();
 781
 782         MapInfo_Enumerate();
 783         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 784
 785         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 786         {
 787                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 788                 if(fd != -1)
 789                 {
 790                         while((s = fgets(fd)))
 791                         {
 792                                 l = tokenize_console(s);
 793                                 if(l < 2)
 794                                         continue;
 795                                 if(argv(0) == "cd")
 796                                 {
 797                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 798                                         print("  cdtrack ", argv(2), "\n");
 799                                 }
 800                                 else if(argv(0) == "fog")
 801                                 {
 802                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 803                                         print("  \"fog\" \"", s, "\"\n");
 804                                 }
 805                                 else if(argv(0) == "set")
 806                                 {
 807                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 808                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 809                                 }
 810                                 else if(argv(0) != "//")
 811                                 {
 812                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 813                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 814                                 }
 815                         }
 816                         fclose(fd);
 817                 }
 818         }
 819
 820         WeaponStats_Init();
 821
 822         addstat(STAT_WEAPONS, AS_INT, weapons);
 823         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 824         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 825         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 826         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 827         Nagger_Init();
 828
 829         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 830         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 831         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 832         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 833         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 834         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 835         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 836         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 837         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 838         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 839         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 840         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 841
 842         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 843         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 844
 845         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 846
 847         if(g_ca || g_freezetag)
 848         {
 849                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 850                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 851                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 852                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 853         }
 854         if(g_freezetag)
 855         {
 856                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 857                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 858         }
 859
 860         // g_movementspeed hack
 861         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 862         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 863         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 864         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 865
 866         // secrets
 867         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 868         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 869
 870         next_pingtime = time + 5;
 871
 872         detect_maptype();
 873
 874         lsmaps_reply = "^7Maps available: ";
 875         lsnewmaps_reply = "^7Maps without a record set: ";
 876         for(i = 0, j = 0; i < MapInfo_count; ++i)
 877         {
 878                 if(MapInfo_Get_ByID(i))
 879                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 880                         {
 881                                 if(mod(i, 2))
 882                                         col = "^2";
 883                                 else
 884                                         col = "^3";
 885                                 ++j;
 886                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 887                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 888                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 889                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 890                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 891                         }
 892         }
 893         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 894         if (!g_race && !g_cts)
 895                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 896         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 897
 898         maplist_reply = "^7Maps in list: ";
 899         n = tokenize_console(autocvar_g_maplist);
 900         for(i = 0, j = 0; i < n; ++i)
 901         {
 902                 if(MapInfo_CheckMap(argv(i)))
 903                 {
 904                         if(mod(j, 2))
 905                                 col = "^2";
 906                         else
 907                                 col = "^3";
 908                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 909                         ++j;
 910                 }
 911         }
 912         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 913         MapInfo_ClearTemps();
 914
 915         for(i = 0; i < 10; ++i)
 916         {
 917                 records_reply[i] = strzone(getrecords(i));
 918         }
 919         if(g_cts)
 920                 ladder_reply = strzone(getladder());
 921
 922         rankings_reply = strzone(getrankings());
 923
 924         ClientInit_Spawn();
 925         RandomSeed_Spawn();
 926         PingPLReport_Spawn();
 927
 928         CheatInit();
 929
 930         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 931
 932         // fill sv_curl_serverpackages from .serverpackage files
 933         if(autocvar_sv_curl_serverpackages_auto)
 934         {
 935                 s = "";
 936                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 937                 for(i = 0; i < n; ++i)
 938                         if(substring(argv(i), -14, -1) != ".serverpackage")
 939                                 s = strcat(s, " ", argv(i));
 940                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 941                 if(fd >= 0)
 942                 {
 943                         j = search_getsize(fd);
 944                         for(i = 0; i < j; ++i)
 945                                 s = strcat(s, " ", search_getfilename(fd, i));
 946                         search_end(fd);
 947                 }
 948                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 949         }
 950
 951         PlayerStats_Init();
 952
 953         world_initialized = 1;
 954 }
 955
 956 void spawnfunc_light (void)
 957 {
 958         //makestatic (self); // Who the f___ did that?
 959         remove(self);
 960 }
 961
 962 string GetGametype()
 963 {
 964         return GametypeNameFromType(game);
 965 }
 966
 967 string getmapname_stored;
 968 string GetMapname()
 969 {
 970         return mapname;
 971 }
 972
 973 float Map_Count, Map_Current;
 974 string Map_Current_Name;
 975
 976 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 977 float GetMaplistPosition()
 978 {
 979         float pos, idx;
 980         string map;
 981
 982         map = GetMapname();
 983         idx = autocvar_g_maplist_index;
 984
 985         if(idx >= 0)
 986                 if(idx < Map_Count)
 987                         if(map == argv(idx))
 988                                 return idx;
 989
 990         for(pos = 0; pos < Map_Count; ++pos)
 991                 if(map == argv(pos))
 992                         return pos;
 993
 994         // resume normal maplist rotation if current map is not in g_maplist
 995         return idx;
 996 }
 997
 998 float MapHasRightSize(string map)
 999 {
1000         float fh;
1001         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1002         if(autocvar_g_maplist_check_waypoints)
1003         {
1004                 dprint("checkwp "); dprint(map);
1005                 if(!fexists(strcat("maps/", map, ".waypoints")))
1006                 {
1007                         dprint(": no waypoints\n");
1008                         return FALSE;
1009                 }
1010                 dprint(": has waypoints\n");
1011         }
1012
1013         // open map size restriction file
1014         dprint("opensize "); dprint(map);
1015         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1016         if(fh >= 0)
1017         {
1018                 float mapmin, mapmax;
1019                 dprint(": ok, ");
1020                 mapmin = stof(fgets(fh));
1021                 mapmax = stof(fgets(fh));
1022                 fclose(fh);
1023                 if(player_count < mapmin)
1024                 {
1025                         dprint("not enough\n");
1026                         return FALSE;
1027                 }
1028                 if(player_count > mapmax)
1029                 {
1030                         dprint("too many\n");
1031                         return FALSE;
1032                 }
1033                 dprint("right size\n");
1034                 return TRUE;
1035         }
1036         dprint(": not found\n");
1037         return TRUE;
1038 }
1039
1040 string Map_Filename(float position)
1041 {
1042         return strcat("maps/", argv(position), ".bsp");
1043 }
1044
1045 string strwords(string s, float w)
1046 {
1047         float endpos;
1048         for(endpos = 0; w && endpos >= 0; --w)
1049                 endpos = strstrofs(s, " ", endpos + 1);
1050         if(endpos < 0)
1051                 return s;
1052         else
1053                 return substring(s, 0, endpos);
1054 }
1055
1056 float strhasword(string s, string w)
1057 {
1058         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1059 }
1060
1061 void Map_MarkAsRecent(string m)
1062 {
1063         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1064 }
1065
1066 float Map_IsRecent(string m)
1067 {
1068         return strhasword(autocvar_g_maplist_mostrecent, m);
1069 }
1070
1071 float Map_Check(float position, float pass)
1072 {
1073         string filename;
1074         string map_next;
1075         map_next = argv(position);
1076         if(pass <= 1)
1077         {
1078                 if(Map_IsRecent(map_next))
1079                         return 0;
1080         }
1081         filename = Map_Filename(position);
1082         if(MapInfo_CheckMap(map_next))
1083         {
1084                 if(pass == 2)
1085                         return 1;
1086                 if(MapHasRightSize(map_next))
1087                         return 1;
1088                 return 0;
1089         }
1090         else
1091                 dprint( "Couldn't select '", filename, "'..\n" );
1092
1093         return 0;
1094 }
1095
1096 void Map_Goto_SetStr(string nextmapname)
1097 {
1098         if(getmapname_stored != "")
1099                 strunzone(getmapname_stored);
1100         if(nextmapname == "")
1101                 getmapname_stored = "";
1102         else
1103                 getmapname_stored = strzone(nextmapname);
1104 }
1105
1106 void Map_Goto_SetFloat(float position)
1107 {
1108         cvar_set("g_maplist_index", ftos(position));
1109         Map_Goto_SetStr(argv(position));
1110 }
1111
1112 void GameResetCfg()
1113 {
1114         // settings persist, except...
1115         localcmd("\nsettemp_restore\n");
1116 }
1117
1118 void Map_Goto()
1119 {
1120         GameResetCfg();
1121         MapInfo_LoadMap(getmapname_stored);
1122 }
1123
1124 // return codes of map selectors:
1125 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1126 //   -2 = permanent failure
1127 float() MaplistMethod_Iterate = // usual method
1128 {
1129         float pass, i;
1130
1131         for(pass = 1; pass <= 2; ++pass)
1132         {
1133                 for(i = 1; i < Map_Count; ++i)
1134                 {
1135                         float mapindex;
1136                         mapindex = mod(i + Map_Current, Map_Count);
1137                         if(Map_Check(mapindex, pass))
1138                                 return mapindex;
1139                 }
1140         }
1141         return -1;
1142 }
1143
1144 float() MaplistMethod_Repeat = // fallback method
1145 {
1146         if(Map_Check(Map_Current, 2))
1147                 return Map_Current;
1148         return -2;
1149 }
1150
1151 float() MaplistMethod_Random = // random map selection
1152 {
1153         float i, imax;
1154
1155         imax = 42;
1156
1157         for(i = 0; i <= imax; ++i)
1158         {
1159                 float mapindex;
1160                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1161                 if(Map_Check(mapindex, 1))
1162                         return mapindex;
1163         }
1164         return -1;
1165 }
1166
1167 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1168 // the exponent sets a bias on the map selection:
1169 // the higher the exponent, the less likely "shortly repeated" same maps are
1170 {
1171         float i, j, imax, insertpos;
1172
1173         imax = 42;
1174
1175         for(i = 0; i <= imax; ++i)
1176         {
1177                 string newlist;
1178
1179                 // now reinsert this at another position
1180                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1181                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1182                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1183                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1184
1185                 // insert the current map there
1186                 newlist = "";
1187                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1188                         newlist = strcat(newlist, " ", argv(j));
1189                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1190                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1191                         newlist = strcat(newlist, " ", argv(j));
1192                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1193                 cvar_set("g_maplist", newlist);
1194                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1195
1196                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1197                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1198                 if(Map_Check(Map_Current, 1))
1199                         return Map_Current;
1200         }
1201         return -1;
1202 }
1203
1204 void Maplist_Init()
1205 {
1206         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1207         if(Map_Count == 0)
1208         {
1209                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1210                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1211                 if(autocvar_g_maplist_shuffle)
1212                         ShuffleMaplist();
1213                 localcmd("\nmenu_cmd sync\n");
1214                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1215         }
1216         if(Map_Count == 0)
1217                 error("empty maplist, cannot select a new map");
1218         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1219
1220         if(Map_Current_Name)
1221                 strunzone(Map_Current_Name);
1222         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1223         // this may or may not be correct, but who cares, in the worst case a map
1224         // isn't chosen in the first pass that should have been
1225 }
1226
1227 string GetNextMap()
1228 {
1229         float nextMap;
1230
1231         Maplist_Init();
1232         nextMap = -1;
1233
1234         if(nextMap == -1)
1235                 if(autocvar_g_maplist_shuffle > 0)
1236                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1237
1238         if(nextMap == -1)
1239                 if(autocvar_g_maplist_selectrandom)
1240                         nextMap = MaplistMethod_Random();
1241
1242         if(nextMap == -1)
1243                 nextMap = MaplistMethod_Iterate();
1244
1245         if(nextMap == -1)
1246                 nextMap = MaplistMethod_Repeat();
1247
1248         if(nextMap >= 0)
1249         {
1250                 Map_Goto_SetFloat(nextMap);
1251                 return getmapname_stored;
1252         }
1253
1254         return "";
1255 }
1256
1257 float DoNextMapOverride()
1258 {
1259         if(autocvar_g_campaign)
1260         {
1261                 CampaignPostIntermission();
1262                 alreadychangedlevel = TRUE;
1263                 return TRUE;
1264         }
1265         if(autocvar_quit_when_empty)
1266         {
1267                 if(player_count <= currentbots)
1268                 {
1269                         localcmd("quit\n");
1270                         alreadychangedlevel = TRUE;
1271                         return TRUE;
1272                 }
1273         }
1274         if(autocvar_quit_and_redirect != "")
1275         {
1276                 redirection_target = strzone(autocvar_quit_and_redirect);
1277                 alreadychangedlevel = TRUE;
1278                 return TRUE;
1279         }
1280         if (autocvar_samelevel) // if samelevel is set, stay on same level
1281         {
1282                 localcmd("restart\n");
1283                 alreadychangedlevel = TRUE;
1284                 return TRUE;
1285         }
1286         if(autocvar_nextmap != "")
1287                 if(MapInfo_CheckMap(autocvar_nextmap))
1288                 {
1289                         Map_Goto_SetStr(autocvar_nextmap);
1290                         Map_Goto();
1291                         alreadychangedlevel = TRUE;
1292                         return TRUE;
1293                 }
1294         if(autocvar_lastlevel)
1295         {
1296                 GameResetCfg();
1297                 localcmd("set lastlevel 0\ntogglemenu\n");
1298                 alreadychangedlevel = TRUE;
1299                 return TRUE;
1300         }
1301         return FALSE;
1302 }
1303
1304 void GotoNextMap()
1305 {
1306         //string nextmap;
1307         //float n, nummaps;
1308         //string s;
1309         if (alreadychangedlevel)
1310                 return;
1311         alreadychangedlevel = TRUE;
1312
1313         {
1314                 string nextMap;
1315                 float allowReset;
1316
1317                 for(allowReset = 1; allowReset >= 0; --allowReset)
1318                 {
1319                         nextMap = GetNextMap();
1320                         if(nextMap != "")
1321                                 break;
1322
1323                         if(allowReset)
1324                         {
1325                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1326                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1327                                 if(autocvar_g_maplist_shuffle)
1328                                         ShuffleMaplist();
1329                                 localcmd("\nmenu_cmd sync\n");
1330                         }
1331                         else
1332                         {
1333                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1334                         }
1335                 }
1336                 Map_Goto();
1337         }
1338 }
1339
1340
1341 /*
1342 ============
1343 IntermissionThink
1344
1345 When the player presses attack or jump, change to the next level
1346 ============
1347 */
1348 .float autoscreenshot;
1349 void() MapVote_Start;
1350 void() MapVote_Think;
1351 float mapvote_initialized;
1352 void IntermissionThink()
1353 {
1354         FixIntermissionClient(self);
1355
1356         if( (autocvar_sv_autoscreenshot || self.cvar_cl_autoscreenshot)
1357                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1358         {
1359                 self.autoscreenshot = -1;
1360                 if(clienttype(self) == CLIENTTYPE_REAL)
1361                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1362                 return;
1363         }
1364
1365         if (time < intermission_exittime)
1366                 return;
1367
1368         if(!mapvote_initialized)
1369                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1370                         return;
1371
1372         MapVote_Start();
1373 }
1374
1375 /*
1376 ============
1377 FindIntermission
1378
1379 Returns the entity to view from
1380 ============
1381 */
1382 /*
1383 entity FindIntermission()
1384 {
1385         local   entity spot;
1386         local   float cyc;
1387
1388 // look for info_intermission first
1389         spot = find (world, classname, "info_intermission");
1390         if (spot)
1391         {       // pick a random one
1392                 cyc = random() * 4;
1393                 while (cyc > 1)
1394                 {
1395                         spot = find (spot, classname, "info_intermission");
1396                         if (!spot)
1397                                 spot = find (spot, classname, "info_intermission");
1398                         cyc = cyc - 1;
1399                 }
1400                 return spot;
1401         }
1402
1403 // then look for the start position
1404         spot = find (world, classname, "info_player_start");
1405         if (spot)
1406                 return spot;
1407
1408 // testinfo_player_start is only found in regioned levels
1409         spot = find (world, classname, "testplayerstart");
1410         if (spot)
1411                 return spot;
1412
1413 // then look for the start position
1414         spot = find (world, classname, "info_player_deathmatch");
1415         if (spot)
1416                 return spot;
1417
1418         //objerror ("FindIntermission: no spot");
1419         return world;
1420 }
1421 */
1422
1423 /*
1424 ===============================================================================
1425
1426 RULES
1427
1428 ===============================================================================
1429 */
1430
1431 void DumpStats(float final)
1432 {
1433         float file;
1434         string s;
1435         float to_console;
1436         float to_eventlog;
1437         float to_file;
1438         float i;
1439
1440         to_console = autocvar_sv_logscores_console;
1441         to_eventlog = autocvar_sv_eventlog;
1442         to_file = autocvar_sv_logscores_file;
1443
1444         if(!final)
1445         {
1446                 to_console = TRUE; // always print printstats replies
1447                 to_eventlog = FALSE; // but never print them to the event log
1448         }
1449
1450         if(to_eventlog)
1451                 if(autocvar_sv_eventlog_console)
1452                         to_console = FALSE; // otherwise we get the output twice
1453
1454         if(final)
1455                 s = ":scores:";
1456         else
1457                 s = ":status:";
1458         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1459
1460         if(to_console)
1461                 print(s, "\n");
1462         if(to_eventlog)
1463                 GameLogEcho(s);
1464         if(to_file)
1465         {
1466                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1467                 if(file == -1)
1468                         to_file = FALSE;
1469                 else
1470                         fputs(file, strcat(s, "\n"));
1471         }
1472
1473         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1474         if(to_console)
1475                 print(s, "\n");
1476         if(to_eventlog)
1477                 GameLogEcho(s);
1478         if(to_file)
1479                 fputs(file, strcat(s, "\n"));
1480
1481         FOR_EACH_CLIENT(other)
1482         {
1483                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1484                 {
1485                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1486                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1487                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1488                                 s = strcat(s, ftos(other.team), ":");
1489                         else
1490                                 s = strcat(s, "spectator:");
1491
1492                         if(to_console)
1493                                 print(s, other.netname, "\n");
1494                         if(to_eventlog)
1495                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1496                         if(to_file)
1497                                 fputs(file, strcat(s, other.netname, "\n"));
1498                 }
1499         }
1500
1501         if(teamplay)
1502         {
1503                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1504                 if(to_console)
1505                         print(s, "\n");
1506                 if(to_eventlog)
1507                         GameLogEcho(s);
1508                 if(to_file)
1509                         fputs(file, strcat(s, "\n"));
1510
1511                 for(i = 1; i < 16; ++i)
1512                 {
1513                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1514                         s = strcat(s, ":", ftos(i));
1515                         if(to_console)
1516                                 print(s, "\n");
1517                         if(to_eventlog)
1518                                 GameLogEcho(s);
1519                         if(to_file)
1520                                 fputs(file, strcat(s, "\n"));
1521                 }
1522         }
1523
1524         if(to_console)
1525                 print(":end\n");
1526         if(to_eventlog)
1527                 GameLogEcho(":end");
1528         if(to_file)
1529         {
1530                 fputs(file, ":end\n");
1531                 fclose(file);
1532         }
1533 }
1534
1535 void FixIntermissionClient(entity e)
1536 {
1537         string s;
1538         if(!e.autoscreenshot) // initial call
1539         {
1540                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1541                 e.health = -2342;
1542                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1543                 e.solid = SOLID_NOT;
1544                 e.movetype = MOVETYPE_NONE;
1545                 e.takedamage = DAMAGE_NO;
1546                 if(e.weaponentity)
1547                 {
1548                         e.weaponentity.effects = EF_NODRAW;
1549                         if (e.weaponentity.weaponentity)
1550                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1551                 }
1552                 if(clienttype(e) == CLIENTTYPE_REAL)
1553                 {
1554                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1555                         s = autocvar_sv_intermission_cdtrack;
1556                         if(s != "")
1557                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1558                         msg_entity = e;
1559                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1560                 }
1561         }
1562 }
1563
1564 void minstagib_stop_countdown(entity e);
1565 /*
1566 go to the next level for deathmatch
1567 only called if a time or frag limit has expired
1568 */
1569 void NextLevel()
1570 {
1571         gameover = TRUE;
1572
1573         intermission_running = 1;
1574
1575 // enforce a wait time before allowing changelevel
1576         if(player_count > 0)
1577                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1578         else
1579                 intermission_exittime = -1;
1580
1581         /*
1582         WriteByte (MSG_ALL, SVC_CDTRACK);
1583         WriteByte (MSG_ALL, 3);
1584         WriteByte (MSG_ALL, 3);
1585         // done in FixIntermission
1586         */
1587
1588         //pos = FindIntermission ();
1589
1590         VoteReset();
1591
1592         DumpStats(TRUE);
1593
1594         // send statistics
1595         entity e;
1596         PlayerStats_EndMatch(1);
1597         FOR_EACH_CLIENT(e)
1598                 PlayerStats_AddGlobalInfo(e);
1599         PlayerStats_Shutdown();
1600         WeaponStats_Shutdown();
1601
1602         if(autocvar_sv_eventlog)
1603                 GameLogEcho(":gameover");
1604
1605         GameLogClose();
1606
1607         FOR_EACH_PLAYER(other) {
1608                 minstagib_stop_countdown(other);
1609                 FixIntermissionClient(other);
1610                 if(other.winning)
1611                         bprint(other.netname, " ^7wins.\n");
1612         }
1613
1614         if(autocvar_g_campaign)
1615                 CampaignPreIntermission();
1616
1617         localcmd("\nsv_hook_gameend\n");
1618 }
1619
1620 /*
1621 ============
1622 CheckRules_Player
1623
1624 Exit deathmatch games upon conditions
1625 ============
1626 */
1627 void CheckRules_Player()
1628 {
1629         if (gameover)   // someone else quit the game already
1630                 return;
1631
1632         if(self.deadflag == DEAD_NO)
1633                 self.play_time += frametime;
1634
1635         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1636         //   (div0: and that in CheckRules_World please)
1637 }
1638
1639 float checkrules_equality;
1640 float checkrules_suddendeathwarning;
1641 float checkrules_suddendeathend;
1642 float checkrules_overtimesadded; //how many overtimes have been already added
1643
1644 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1645 float WINNING_YES = 1; // winner found
1646 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1647 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1648
1649 float InitiateSuddenDeath()
1650 {
1651         // Check first whether normal overtimes could be added before initiating suddendeath mode
1652         // - for this timelimit_overtime needs to be >0 of course
1653         // - also check the winning condition calculated in the previous frame and only add normal overtime
1654         //   again, if at the point at which timelimit would be extended again, still no winner was found
1655         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1656         {
1657                 return 1; // need to call InitiateOvertime later
1658         }
1659         else
1660         {
1661                 if(!checkrules_suddendeathend)
1662                 {
1663                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1664                         if(g_race && !g_race_qualifying)
1665                                 race_StartCompleting();
1666                 }
1667                 return 0;
1668         }
1669 }
1670
1671 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1672 {
1673         ++checkrules_overtimesadded;
1674         //add one more overtime by simply extending the timelimit
1675         float tl;
1676         tl = autocvar_timelimit;
1677         tl += autocvar_timelimit_overtime;
1678         cvar_set("timelimit", ftos(tl));
1679         string minutesPlural;
1680         if (autocvar_timelimit_overtime == 1)
1681                 minutesPlural = " ^3minute";
1682         else
1683                 minutesPlural = " ^3minutes";
1684
1685         bcenterprint(
1686                 strcat(
1687                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1688                         ftos(autocvar_timelimit_overtime),
1689                         minutesPlural,
1690                         " to the game!"
1691                 )
1692         );
1693 }
1694
1695 float GetWinningCode(float fraglimitreached, float equality)
1696 {
1697         if(autocvar_g_campaign == 1)
1698                 if(fraglimitreached)
1699                         return WINNING_YES;
1700                 else
1701                         return WINNING_NO;
1702
1703         else
1704                 if(equality)
1705                         if(fraglimitreached)
1706                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1707                         else
1708                                 return WINNING_NEVER;
1709                 else
1710                         if(fraglimitreached)
1711                                 return WINNING_YES;
1712                         else
1713                                 return WINNING_NO;
1714 }
1715
1716 // set the .winning flag for exactly those players with a given field value
1717 void SetWinners(.float field, float value)
1718 {
1719         entity head;
1720         FOR_EACH_PLAYER(head)
1721                 head.winning = (head.field == value);
1722 }
1723
1724 // set the .winning flag for those players with a given field value
1725 void AddWinners(.float field, float value)
1726 {
1727         entity head;
1728         FOR_EACH_PLAYER(head)
1729                 if(head.field == value)
1730                         head.winning = 1;
1731 }
1732
1733 // clear the .winning flags
1734 void ClearWinners(void)
1735 {
1736         entity head;
1737         FOR_EACH_PLAYER(head)
1738                 head.winning = 0;
1739 }
1740
1741 // Onslaught winning condition:
1742 // game terminates if only one team has a working generator (or none)
1743 float WinningCondition_Onslaught()
1744 {
1745         entity head;
1746         float t1, t2, t3, t4;
1747
1748         WinningConditionHelper(); // set worldstatus
1749
1750         if(inWarmupStage)
1751                 return WINNING_NO;
1752
1753         // first check if the game has ended
1754         t1 = t2 = t3 = t4 = 0;
1755         head = find(world, classname, "onslaught_generator");
1756         while (head)
1757         {
1758                 if (head.health > 0)
1759                 {
1760                         if (head.team == COLOR_TEAM1) t1 = 1;
1761                         if (head.team == COLOR_TEAM2) t2 = 1;
1762                         if (head.team == COLOR_TEAM3) t3 = 1;
1763                         if (head.team == COLOR_TEAM4) t4 = 1;
1764                 }
1765                 head = find(head, classname, "onslaught_generator");
1766         }
1767         if (t1 + t2 + t3 + t4 < 2)
1768         {
1769                 // game over, only one team remains (or none)
1770                 ClearWinners();
1771                 if (t1) SetWinners(team, COLOR_TEAM1);
1772                 if (t2) SetWinners(team, COLOR_TEAM2);
1773                 if (t3) SetWinners(team, COLOR_TEAM3);
1774                 if (t4) SetWinners(team, COLOR_TEAM4);
1775                 dprint("Have a winner, ending game.\n");
1776                 return WINNING_YES;
1777         }
1778
1779         // Two or more teams remain
1780         return WINNING_NO;
1781 }
1782
1783 float LMS_NewPlayerLives()
1784 {
1785         float fl;
1786         fl = autocvar_fraglimit;
1787         if(fl == 0)
1788                 fl = 999;
1789
1790         // first player has left the game for dying too much? Nobody else can get in.
1791         if(lms_lowest_lives < 1)
1792                 return 0;
1793
1794         if(!autocvar_g_lms_join_anytime)
1795                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1796                         return 0;
1797
1798         return bound(1, lms_lowest_lives, fl);
1799 }
1800
1801 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1802 // they win. Otherwise the defending team wins once the timelimit passes.
1803 void assault_new_round();
1804 float WinningCondition_Assault()
1805 {
1806         float status;
1807
1808         WinningConditionHelper(); // set worldstatus
1809
1810         status = WINNING_NO;
1811         // as the timelimit has not yet passed just assume the defending team will win
1812         if(assault_attacker_team == COLOR_TEAM1)
1813         {
1814                 SetWinners(team, COLOR_TEAM2);
1815         }
1816         else
1817         {
1818                 SetWinners(team, COLOR_TEAM1);
1819         }
1820
1821         entity ent;
1822         ent = find(world, classname, "target_assault_roundend");
1823         if(ent)
1824         {
1825                 if(ent.winning) // round end has been triggered by attacking team
1826                 {
1827                         bprint("ASSAULT: round completed...\n");
1828                         SetWinners(team, assault_attacker_team);
1829
1830                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1831
1832                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1833                         {
1834                                 status = WINNING_YES;
1835                         }
1836                         else
1837                         {
1838                                 entity oldself;
1839                                 oldself = self;
1840                                 self = ent;
1841                                 assault_new_round();
1842                                 self = oldself;
1843                         }
1844                 }
1845         }
1846
1847         return status;
1848 }
1849
1850 // LMS winning condition: game terminates if and only if there's at most one
1851 // one player who's living lives. Top two scores being equal cancels the time
1852 // limit.
1853 float WinningCondition_LMS()
1854 {
1855         entity head, head2;
1856         float have_player;
1857         float have_players;
1858         float l;
1859
1860         have_player = FALSE;
1861         have_players = FALSE;
1862         l = LMS_NewPlayerLives();
1863
1864         head = find(world, classname, "player");
1865         if(head)
1866                 have_player = TRUE;
1867         head2 = find(head, classname, "player");
1868         if(head2)
1869                 have_players = TRUE;
1870
1871         if(have_player)
1872         {
1873                 // we have at least one player
1874                 if(have_players)
1875                 {
1876                         // two or more active players - continue with the game
1877                 }
1878                 else
1879                 {
1880                         // exactly one player?
1881
1882                         ClearWinners();
1883                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1884
1885                         if(l)
1886                         {
1887                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1888                                 return WINNING_NO;
1889                         }
1890                         else
1891                         {
1892                                 // a winner!
1893                                 // and assign him his first place
1894                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1895                                 return WINNING_YES;
1896                         }
1897                 }
1898         }
1899         else
1900         {
1901                 // nobody is playing at all...
1902                 if(l)
1903                 {
1904                         // wait for players...
1905                 }
1906                 else
1907                 {
1908                         // SNAFU (maybe a draw game?)
1909                         ClearWinners();
1910                         dprint("No players, ending game.\n");
1911                         return WINNING_YES;
1912                 }
1913         }
1914
1915         // When we get here, we have at least two players who are actually LIVING,
1916         // now check if the top two players have equal score.
1917         WinningConditionHelper();
1918
1919         ClearWinners();
1920         if(WinningConditionHelper_winner)
1921                 WinningConditionHelper_winner.winning = TRUE;
1922         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1923                 return WINNING_NEVER;
1924
1925         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1926         return WINNING_NO;
1927 }
1928
1929 void ShuffleMaplist()
1930 {
1931         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1932 }
1933
1934 float leaderfrags;
1935 float WinningCondition_Scores(float limit, float leadlimit)
1936 {
1937         float limitreached;
1938
1939         // TODO make everything use THIS winning condition (except LMS)
1940         WinningConditionHelper();
1941
1942         if(teamplay)
1943         {
1944                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1945                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1946                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1947                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1948         }
1949
1950         ClearWinners();
1951         if(WinningConditionHelper_winner)
1952                 WinningConditionHelper_winner.winning = 1;
1953         if(WinningConditionHelper_winnerteam >= 0)
1954                 SetWinners(team, WinningConditionHelper_winnerteam);
1955
1956         if(WinningConditionHelper_lowerisbetter)
1957         {
1958                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1959                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1960                 limit = -limit;
1961         }
1962
1963         if(WinningConditionHelper_zeroisworst)
1964                 leadlimit = 0; // not supported in this mode
1965
1966         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1967         // these modes always score in increments of 1, thus this makes sense
1968         {
1969                 if(leaderfrags != WinningConditionHelper_topscore)
1970                 {
1971                         leaderfrags = WinningConditionHelper_topscore;
1972
1973                         if (limit)
1974                         if (leaderfrags == limit - 1)
1975                                 Announce("1fragleft");
1976                         else if (leaderfrags == limit - 2)
1977                                 Announce("2fragsleft");
1978                         else if (leaderfrags == limit - 3)
1979                                 Announce("3fragsleft");
1980                 }
1981         }
1982
1983         limitreached = FALSE;
1984         if(limit)
1985                 if(WinningConditionHelper_topscore >= limit)
1986                         limitreached = TRUE;
1987         if(leadlimit)
1988         {
1989                 float leadlimitreached;
1990                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1991                 if(autocvar_leadlimit_and_fraglimit)
1992                         limitreached = (limitreached && leadlimitreached);
1993                 else
1994                         limitreached = (limitreached || leadlimitreached);
1995         }
1996
1997         return GetWinningCode(
1998                 WinningConditionHelper_topscore && limitreached,
1999                 WinningConditionHelper_equality
2000         );
2001 }
2002
2003 float WinningCondition_Race(float fraglimit)
2004 {
2005         float wc;
2006         entity p;
2007         float n, c;
2008
2009         n = 0;
2010         c = 0;
2011         FOR_EACH_PLAYER(p)
2012         {
2013                 ++n;
2014                 if(p.race_completed)
2015                         ++c;
2016         }
2017         if(n && (n == c))
2018                 return WINNING_YES;
2019         wc = WinningCondition_Scores(fraglimit, 0);
2020
2021         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2022         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2023         // do NOT support equality when the laps are all raced!
2024                 return WINNING_STARTSUDDENDEATHOVERTIME;
2025         else
2026                 return WINNING_NEVER;
2027         return wc;
2028 }
2029
2030 void ReadyRestart();
2031 float WinningCondition_QualifyingThenRace(float limit)
2032 {
2033         float wc;
2034         wc = WinningCondition_Scores(limit, 0);
2035
2036         // NEVER initiate overtime
2037         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2038         {
2039                 return WINNING_YES;
2040         }
2041
2042         return wc;
2043 }
2044
2045 float WinningCondition_RanOutOfSpawns()
2046 {
2047         entity head;
2048
2049         if(have_team_spawns <= 0)
2050                 return WINNING_NO;
2051
2052         if(autocvar_g_spawn_useallspawns <= 0)
2053                 return WINNING_NO;
2054
2055         if(!some_spawn_has_been_used)
2056                 return WINNING_NO;
2057
2058         team1_score = team2_score = team3_score = team4_score = 0;
2059
2060         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2061         {
2062                 if(head.team == COLOR_TEAM1)
2063                         team1_score = 1;
2064                 else if(head.team == COLOR_TEAM2)
2065                         team2_score = 1;
2066                 else if(head.team == COLOR_TEAM3)
2067                         team3_score = 1;
2068                 else if(head.team == COLOR_TEAM4)
2069                         team4_score = 1;
2070         }
2071
2072         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2073         {
2074                 if(head.team == COLOR_TEAM1)
2075                         team1_score = 1;
2076                 else if(head.team == COLOR_TEAM2)
2077                         team2_score = 1;
2078                 else if(head.team == COLOR_TEAM3)
2079                         team3_score = 1;
2080                 else if(head.team == COLOR_TEAM4)
2081                         team4_score = 1;
2082         }
2083
2084         ClearWinners();
2085         if(team1_score + team2_score + team3_score + team4_score == 0)
2086         {
2087                 checkrules_equality = TRUE;
2088                 return WINNING_YES;
2089         }
2090         else if(team1_score + team2_score + team3_score + team4_score == 1)
2091         {
2092                 float t, i;
2093                 if(team1_score) t = COLOR_TEAM1;
2094                 if(team2_score) t = COLOR_TEAM2;
2095                 if(team3_score) t = COLOR_TEAM3;
2096                 if(team4_score) t = COLOR_TEAM4;
2097                 CheckAllowedTeams(world);
2098                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2099                 {
2100                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2101                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2102                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2103                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2104                 }
2105
2106                 AddWinners(team, t);
2107                 return WINNING_YES;
2108         }
2109         else
2110                 return WINNING_NO;
2111 }
2112
2113 /*
2114 ============
2115 CheckRules_World
2116
2117 Exit deathmatch games upon conditions
2118 ============
2119 */
2120 void CheckRules_World()
2121 {
2122         float timelimit;
2123         float fraglimit;
2124         float leadlimit;
2125
2126         VoteThink();
2127         MapVote_Think();
2128
2129         SetDefaultAlpha();
2130
2131         /*
2132         MapVote_Think should now do that part
2133         if (intermission_running)
2134                 if (time >= intermission_exittime + 60)
2135                 {
2136                         if(!DoNextMapOverride())
2137                                 GotoNextMap();
2138                         return;
2139                 }
2140         */
2141
2142         if (gameover)   // someone else quit the game already
2143         {
2144                 if(player_count == 0) // Nobody there? Then let's go to the next map
2145                         MapVote_Start();
2146                         // this will actually check the player count in the next frame
2147                         // again, but this shouldn't hurt
2148                 return;
2149         }
2150
2151         timelimit = autocvar_timelimit * 60;
2152         fraglimit = autocvar_fraglimit;
2153         leadlimit = autocvar_leadlimit;
2154
2155         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2156         {
2157                 if(timelimit > 0)
2158                         timelimit = 0; // timelimit is not made for warmup
2159                 if(fraglimit > 0)
2160                         fraglimit = 0; // no fraglimit for now
2161                 leadlimit = 0; // no leadlimit for now
2162         }
2163
2164         if(g_onslaught)
2165                 timelimit = 0; // ONS has its own overtime rule
2166
2167         if(timelimit > 0)
2168         {
2169                 timelimit += game_starttime;
2170         }
2171         else if (timelimit < 0)
2172         {
2173                 // endmatch
2174                 NextLevel();
2175                 return;
2176         }
2177
2178         float wantovertime;
2179         wantovertime = 0;
2180
2181         if(checkrules_suddendeathend)
2182         {
2183                 if(!checkrules_suddendeathwarning)
2184                 {
2185                         checkrules_suddendeathwarning = TRUE;
2186                         if(g_race && !g_race_qualifying)
2187                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2188                         else
2189                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2190                 }
2191         }
2192         else
2193         {
2194                 if (timelimit && time >= timelimit)
2195                 {
2196                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2197                         {
2198                                 float totalplayers;
2199                                 float playerswithlaps;
2200                                 float readyplayers;
2201                                 entity head;
2202                                 totalplayers = playerswithlaps = readyplayers = 0;
2203                                 FOR_EACH_PLAYER(head)
2204                                 {
2205                                         ++totalplayers;
2206                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2207                                                 ++playerswithlaps;
2208                                         if(head.ready)
2209                                                 ++readyplayers;
2210                                 }
2211
2212                                 // at least 2 of the players have completed a lap: start the RACE
2213                                 // otherwise, the players should end the qualifying on their own
2214                                 if(readyplayers || playerswithlaps >= 2)
2215                                 {
2216                                         checkrules_suddendeathend = 0;
2217                                         ReadyRestart(); // go to race
2218                                         return;
2219                                 }
2220                                 else
2221                                         wantovertime |= InitiateSuddenDeath();
2222                         }
2223                         else
2224                                 wantovertime |= InitiateSuddenDeath();
2225                 }
2226         }
2227
2228         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2229         {
2230                 NextLevel();
2231                 return;
2232         }
2233
2234         float checkrules_status;
2235         checkrules_status = WinningCondition_RanOutOfSpawns();
2236         if(checkrules_status == WINNING_YES)
2237         {
2238                 bprint("Hey! Someone ran out of spawns!\n");
2239         }
2240         else if(g_race && !g_race_qualifying && timelimit >= 0)
2241         {
2242                 checkrules_status = WinningCondition_Race(fraglimit);
2243                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2244         }
2245         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2246         {
2247                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2248                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2249         }
2250         else if(g_assault)
2251         {
2252                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2253         }
2254         else if(g_lms)
2255         {
2256                 checkrules_status = WinningCondition_LMS();
2257         }
2258         else if (g_onslaught)
2259         {
2260                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2261         }
2262         else
2263         {
2264                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2265                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2266         }
2267
2268         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2269         {
2270                 checkrules_status = WINNING_NEVER;
2271                 checkrules_overtimesadded = -1;
2272                 wantovertime |= InitiateSuddenDeath();
2273         }
2274
2275         if(checkrules_status == WINNING_NEVER)
2276                 // equality cases! Nobody wins if the overtime ends in a draw.
2277                 ClearWinners();
2278
2279         if(wantovertime)
2280         {
2281                 if(checkrules_status == WINNING_NEVER)
2282                         InitiateOvertime();
2283                 else
2284                         checkrules_status = WINNING_YES;
2285         }
2286
2287         if(checkrules_suddendeathend)
2288                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2289                         checkrules_status = WINNING_YES;
2290
2291         if(checkrules_status == WINNING_YES)
2292         {
2293                 //print("WINNING\n");
2294                 NextLevel();
2295         }
2296 }
2297
2298 float mapvote_nextthink;
2299 float mapvote_initialized;
2300 float mapvote_keeptwotime;
2301 float mapvote_timeout;
2302 string mapvote_message;
2303 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2304 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2305 float mapvote_screenshot_dirs_count;
2306
2307 float mapvote_count;
2308 float mapvote_count_real;
2309 string mapvote_maps[MAPVOTE_COUNT];
2310 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2311 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2312 float mapvote_maps_suggested[MAPVOTE_COUNT];
2313 string mapvote_suggestions[MAPVOTE_COUNT];
2314 float mapvote_suggestion_ptr;
2315 float mapvote_voters;
2316 float mapvote_votes[MAPVOTE_COUNT];
2317 float mapvote_run;
2318 float mapvote_detail;
2319 float mapvote_abstain;
2320 .float mapvote;
2321
2322 void MapVote_ClearAllVotes()
2323 {
2324         FOR_EACH_CLIENT(other)
2325                 other.mapvote = 0;
2326 }
2327
2328 string MapVote_Suggest(string m)
2329 {
2330         float i;
2331         if(m == "")
2332                 return "That's not how to use this command.";
2333         if(!autocvar_g_maplist_votable_suggestions)
2334                 return "Suggestions are not accepted on this server.";
2335         if(mapvote_initialized)
2336                 return "Can't suggest - voting is already in progress!";
2337         m = MapInfo_FixName(m);
2338         if(!m)
2339                 return "The map you suggested is not available on this server.";
2340         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2341                 if(Map_IsRecent(m))
2342                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2343
2344         if(!MapInfo_CheckMap(m))
2345                 return "The map you suggested does not support the current game mode.";
2346         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2347                 if(mapvote_suggestions[i] == m)
2348                         return "This map was already suggested.";
2349         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2350         {
2351                 i = floor(random() * mapvote_suggestion_ptr);
2352         }
2353         else
2354         {
2355                 i = mapvote_suggestion_ptr;
2356                 mapvote_suggestion_ptr += 1;
2357         }
2358         if(mapvote_suggestions[i] != "")
2359                 strunzone(mapvote_suggestions[i]);
2360         mapvote_suggestions[i] = strzone(m);
2361         if(autocvar_sv_eventlog)
2362                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2363         return strcat("Suggestion of ", m, " accepted.");
2364 }
2365
2366 void MapVote_AddVotable(string nextMap, float isSuggestion)
2367 {
2368         float j, i, o;
2369         string pakfile, mapfile;
2370
2371         if(nextMap == "")
2372                 return;
2373         for(j = 0; j < mapvote_count; ++j)
2374                 if(mapvote_maps[j] == nextMap)
2375                         return;
2376         // suggestions might be no longer valid/allowed after gametype switch!
2377         if(isSuggestion)
2378                 if(!MapInfo_CheckMap(nextMap))
2379                         return;
2380         mapvote_maps[mapvote_count] = strzone(nextMap);
2381         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2382
2383         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2384         {
2385                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2386                 pakfile = whichpack(strcat(mapfile, ".tga"));
2387                 if(pakfile == "")
2388                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2389                 if(pakfile == "")
2390                         pakfile = whichpack(strcat(mapfile, ".png"));
2391                 if(pakfile != "")
2392                         break;
2393         }
2394         if(i >= mapvote_screenshot_dirs_count)
2395                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2396         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2397                 pakfile = substring(pakfile, o, -1);
2398
2399         mapvote_maps_screenshot_dir[mapvote_count] = i;
2400         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2401
2402         mapvote_count += 1;
2403 }
2404
2405 void MapVote_Spawn();
2406 void MapVote_Init()
2407 {
2408         float i;
2409         float nmax, smax;
2410
2411         MapVote_ClearAllVotes();
2412
2413         mapvote_count = 0;
2414         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2415         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2416
2417         if(mapvote_abstain)
2418                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2419         else
2420                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2421         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2422
2423         // we need this for AddVotable, as that cycles through the screenshot dirs
2424         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2425         if(mapvote_screenshot_dirs_count == 0)
2426                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2427         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2428         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2429                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2430
2431         if(mapvote_suggestion_ptr)
2432                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2433                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2434
2435         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2436                 MapVote_AddVotable(GetNextMap(), FALSE);
2437
2438         if(mapvote_count == 0)
2439         {
2440                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2441                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2442                 if(autocvar_g_maplist_shuffle)
2443                         ShuffleMaplist();
2444                 localcmd("\nmenu_cmd sync\n");
2445                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2446                         MapVote_AddVotable(GetNextMap(), FALSE);
2447         }
2448
2449         mapvote_count_real = mapvote_count;
2450         if(mapvote_abstain)
2451                 MapVote_AddVotable("don't care", 0);
2452
2453         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2454
2455         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2456         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2457         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2458                 mapvote_keeptwotime = 0;
2459         mapvote_message = "Choose a map and press its key!";
2460
2461         MapVote_Spawn();
2462 }
2463
2464 void MapVote_SendPicture(float id)
2465 {
2466         msg_entity = self;
2467         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2468         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2469         WriteByte(MSG_ONE, id);
2470         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2471 }
2472
2473 float GameCommand_MapVote(string cmd)
2474 {
2475         if(!intermission_running)
2476                 return FALSE;
2477
2478         if(cmd == "mv_getpic")
2479         {
2480                 MapVote_SendPicture(stof(argv(1)));
2481                 return TRUE;
2482         }
2483
2484         return FALSE;
2485 }
2486
2487 float MapVote_GetMapMask()
2488 {
2489         float mask, i, power;
2490         mask = 0;
2491         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2492                 if(mapvote_maps[i] != "")
2493                         mask |= power;
2494         return mask;
2495 }
2496
2497 entity mapvote_ent;
2498 float MapVote_SendEntity(entity to, float sf)
2499 {
2500         float i;
2501
2502         if(sf & 1)
2503                 sf &~= 2; // if we send 1, we don't need to also send 2
2504
2505         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2506         WriteByte(MSG_ENTITY, sf);
2507
2508         if(sf & 1)
2509         {
2510                 // flag 1 == initialization
2511                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2512                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2513                 WriteString(MSG_ENTITY, "");
2514                 WriteByte(MSG_ENTITY, mapvote_count);
2515                 WriteByte(MSG_ENTITY, mapvote_abstain);
2516                 WriteByte(MSG_ENTITY, mapvote_detail);
2517                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2518                 if(mapvote_count <= 8)
2519                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2520                 else
2521                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2522                 for(i = 0; i < mapvote_count; ++i)
2523                         if(mapvote_maps[i] != "")
2524                         {
2525                                 if(mapvote_abstain && i == mapvote_count - 1)
2526                                 {
2527                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2528                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2529                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2530                                 }
2531                                 else
2532                                 {
2533                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2534                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2535                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2536                                 }
2537                         }
2538         }
2539
2540         if(sf & 2)
2541         {
2542                 // flag 2 == update of mask
2543                 if(mapvote_count <= 8)
2544                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2545                 else
2546                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2547         }
2548
2549         if(sf & 4)
2550         {
2551                 if(mapvote_detail)
2552                         for(i = 0; i < mapvote_count; ++i)
2553                                 if(mapvote_maps[i] != "")
2554                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2555
2556                 WriteByte(MSG_ENTITY, to.mapvote);
2557         }
2558
2559         return TRUE;
2560 }
2561
2562 void MapVote_Spawn()
2563 {
2564         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2565 }
2566
2567 void MapVote_TouchMask()
2568 {
2569         mapvote_ent.SendFlags |= 2;
2570 }
2571
2572 void MapVote_TouchVotes(entity voter)
2573 {
2574         mapvote_ent.SendFlags |= 4;
2575 }
2576
2577 float MapVote_Finished(float mappos)
2578 {
2579         string result;
2580         float i;
2581         float didntvote;
2582
2583         if(autocvar_sv_eventlog)
2584         {
2585                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2586                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2587                 didntvote = mapvote_voters;
2588                 for(i = 0; i < mapvote_count; ++i)
2589                         if(mapvote_maps[i] != "")
2590                         {
2591                                 didntvote -= mapvote_votes[i];
2592                                 if(i != mappos)
2593                                 {
2594                                         result = strcat(result, ":", mapvote_maps[i]);
2595                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2596                                 }
2597                         }
2598                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2599
2600                 GameLogEcho(result);
2601                 if(mapvote_maps_suggested[mappos])
2602                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2603         }
2604
2605         FOR_EACH_REALCLIENT(other)
2606                 FixClientCvars(other);
2607
2608         Map_Goto_SetStr(mapvote_maps[mappos]);
2609         Map_Goto();
2610         alreadychangedlevel = TRUE;
2611         return TRUE;
2612 }
2613 void MapVote_CheckRules_1()
2614 {
2615         float i;
2616
2617         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2618         {
2619                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2620                 mapvote_votes[i] = 0;
2621         }
2622
2623         mapvote_voters = 0;
2624         FOR_EACH_REALCLIENT(other)
2625         {
2626                 ++mapvote_voters;
2627                 if(other.mapvote)
2628                 {
2629                         i = other.mapvote - 1;
2630                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2631                         mapvote_votes[i] = mapvote_votes[i] + 1;
2632                 }
2633         }
2634 }
2635
2636 float MapVote_CheckRules_2()
2637 {
2638         float i;
2639         float firstPlace, secondPlace;
2640         float firstPlaceVotes, secondPlaceVotes;
2641         float mapvote_voters_real;
2642         string result;
2643
2644         if(mapvote_count_real == 1)
2645                 return MapVote_Finished(0);
2646
2647         mapvote_voters_real = mapvote_voters;
2648         if(mapvote_abstain)
2649                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2650
2651         RandomSelection_Init();
2652         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2653                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2654         firstPlace = RandomSelection_chosen_float;
2655         firstPlaceVotes = RandomSelection_best_priority;
2656         //dprint("First place: ", ftos(firstPlace), "\n");
2657         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2658
2659         RandomSelection_Init();
2660         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2661                 if(i != firstPlace)
2662                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2663         secondPlace = RandomSelection_chosen_float;
2664         secondPlaceVotes = RandomSelection_best_priority;
2665         //dprint("Second place: ", ftos(secondPlace), "\n");
2666         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2667
2668         if(firstPlace == -1)
2669                 error("No first place in map vote... WTF?");
2670
2671         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2672                 return MapVote_Finished(firstPlace);
2673
2674         if(mapvote_keeptwotime)
2675                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2676                 {
2677                         float didntvote;
2678                         MapVote_TouchMask();
2679                         mapvote_message = "Now decide between the TOP TWO!";
2680                         mapvote_keeptwotime = 0;
2681                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2682                         result = strcat(result, ":", ftos(firstPlaceVotes));
2683                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2684                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2685                         didntvote = mapvote_voters;
2686                         for(i = 0; i < mapvote_count; ++i)
2687                                 if(mapvote_maps[i] != "")
2688                                 {
2689                                         didntvote -= mapvote_votes[i];
2690                                         if(i != firstPlace)
2691                                                 if(i != secondPlace)
2692                                                 {
2693                                                         result = strcat(result, ":", mapvote_maps[i]);
2694                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2695                                                         if(i < mapvote_count_real)
2696                                                         {
2697                                                                 strunzone(mapvote_maps[i]);
2698                                                                 mapvote_maps[i] = "";
2699                                                                 strunzone(mapvote_maps_pakfile[i]);
2700                                                                 mapvote_maps_pakfile[i] = "";
2701                                                         }
2702                                                 }
2703                                 }
2704                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2705                         if(autocvar_sv_eventlog)
2706                                 GameLogEcho(result);
2707                 }
2708
2709         return FALSE;
2710 }
2711 void MapVote_Tick()
2712 {
2713         float keeptwo;
2714         float totalvotes;
2715
2716         keeptwo = mapvote_keeptwotime;
2717         MapVote_CheckRules_1(); // count
2718         if(MapVote_CheckRules_2()) // decide
2719                 return;
2720
2721         totalvotes = 0;
2722         FOR_EACH_REALCLIENT(other)
2723         {
2724                 // hide scoreboard again
2725                 if(other.health != 2342)
2726                 {
2727                         other.health = 2342;
2728                         other.impulse = 0;
2729                         if(clienttype(other) == CLIENTTYPE_REAL)
2730                         {
2731                                 msg_entity = other;
2732                                 WriteByte(MSG_ONE, SVC_FINALE);
2733                                 WriteString(MSG_ONE, "");
2734                         }
2735                 }
2736
2737                 // clear possibly invalid votes
2738                 if(mapvote_maps[other.mapvote - 1] == "")
2739                         other.mapvote = 0;
2740                 // use impulses as new vote
2741                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2742                         if(mapvote_maps[other.impulse - 1] != "")
2743                         {
2744                                 other.mapvote = other.impulse;
2745                                 MapVote_TouchVotes(other);
2746                         }
2747                 other.impulse = 0;
2748
2749                 if(other.mapvote)
2750                         ++totalvotes;
2751         }
2752
2753         MapVote_CheckRules_1(); // just count
2754 }
2755 void MapVote_Start()
2756 {
2757         if(mapvote_run)
2758                 return;
2759
2760         // wait for stats to be sent first
2761         if(!playerstats_waitforme)
2762                 return;
2763
2764         MapInfo_Enumerate();
2765         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2766                 mapvote_run = TRUE;
2767 }
2768 void MapVote_Think()
2769 {
2770         if(!mapvote_run)
2771                 return;
2772
2773         if(alreadychangedlevel)
2774                 return;
2775
2776         if(time < mapvote_nextthink)
2777                 return;
2778         //dprint("tick\n");
2779
2780         mapvote_nextthink = time + 0.5;
2781
2782         if(!mapvote_initialized)
2783         {
2784                 if(autocvar_rescan_pending == 1)
2785                 {
2786                         cvar_set("rescan_pending", "2");
2787                         localcmd("fs_rescan\nrescan_pending 3\n");
2788                         return;
2789                 }
2790                 else if(autocvar_rescan_pending == 2)
2791                 {
2792                         return;
2793                 }
2794                 else if(autocvar_rescan_pending == 3)
2795                 {
2796                         // now build missing mapinfo files
2797                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2798                                 return;
2799
2800                         // we're done, start the timer
2801                         cvar_set("rescan_pending", "0");
2802                 }
2803
2804                 mapvote_initialized = TRUE;
2805                 if(DoNextMapOverride())
2806                         return;
2807                 if(!autocvar_g_maplist_votable || player_count <= 0)
2808                 {
2809                         GotoNextMap();
2810                         return;
2811                 }
2812                 MapVote_Init();
2813         }
2814
2815         MapVote_Tick();
2816 }
2817
2818 string GotoMap(string m)
2819 {
2820         if(!MapInfo_CheckMap(m))
2821                 return "The map you chose is not available on this server.";
2822         cvar_set("nextmap", m);
2823         cvar_set("timelimit", "-1");
2824         if(mapvote_initialized || alreadychangedlevel)
2825         {
2826                 if(DoNextMapOverride())
2827                         return "Map switch initiated.";
2828                 else
2829                         return "Hm... no. For some reason I like THIS map more.";
2830         }
2831         else
2832                 return "Map switch will happen after scoreboard.";
2833 }
2834
2835
2836 void EndFrame()
2837 {
2838         float altime;
2839         FOR_EACH_REALCLIENT(self)
2840         {
2841                 if(self.classname == "spectator")
2842                 {
2843                         if(self.enemy.typehitsound)
2844                                 self.typehit_time = time;
2845                         else if(self.enemy.hitsound)
2846                                 self.hit_time = time;
2847                 }
2848                 else
2849                 {
2850                         if(self.typehitsound)
2851                                 self.typehit_time = time;
2852                         else if(self.hitsound)
2853                                 self.hit_time = time;
2854                 }
2855         }
2856         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2857         // add 1 frametime because after this, engine SV_Physics
2858         // increases time by a frametime and then networks the frame
2859         // add another frametime because client shows everything with
2860         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2861         // needed!
2862         FOR_EACH_CLIENT(self)
2863         {
2864                 self.hitsound = FALSE;
2865                 self.typehitsound = FALSE;
2866                 antilag_record(self, altime);
2867         }
2868 }
2869
2870
2871 /*
2872  * RedirectionThink:
2873  * returns TRUE if redirecting
2874  */
2875 float redirection_timeout;
2876 float redirection_nextthink;
2877 float RedirectionThink()
2878 {
2879         float clients_found;
2880
2881         if(redirection_target == "")
2882                 return FALSE;
2883
2884         if(!redirection_timeout)
2885         {
2886                 cvar_set("sv_public", "-2");
2887                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2888                 if(redirection_target == "self")
2889                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2890                 else
2891                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2892         }
2893
2894         if(time < redirection_nextthink)
2895                 return TRUE;
2896
2897         redirection_nextthink = time + 1;
2898
2899         clients_found = 0;
2900         FOR_EACH_REALCLIENT(self)
2901         {
2902                 print("Redirecting: sending connect command to ", self.netname, "\n");
2903                 if(redirection_target == "self")
2904                         stuffcmd(self, "\ndisconnect; reconnect\n");
2905                 else
2906                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2907                 ++clients_found;
2908         }
2909
2910         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2911
2912         if(time > redirection_timeout || clients_found == 0)
2913                 localcmd("\nwait; wait; wait; quit\n");
2914
2915         return TRUE;
2916 }
2917
2918 void TargetMusic_RestoreGame();
2919 void RestoreGame()
2920 {
2921         // Loaded from a save game
2922         // some things then break, so let's work around them...
2923
2924         // Progs DB (capture records)
2925         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2926
2927         // Mapinfo
2928         MapInfo_Shutdown();
2929         MapInfo_Enumerate();
2930         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2931         WeaponStats_Init();
2932
2933         TargetMusic_RestoreGame();
2934 }
2935
2936 void SV_Shutdown()
2937 {
2938         entity e;
2939
2940         if(gameover > 1) // shutting down already?
2941                 return;
2942
2943         gameover = 2; // 2 = server shutting down
2944
2945         if(world_initialized > 0)
2946         {
2947                 world_initialized = 0;
2948                 print("Saving persistent data...\n");
2949                 Ban_SaveBans();
2950
2951                 PlayerStats_EndMatch(0);
2952                 FOR_EACH_CLIENT(e)
2953                         PlayerStats_AddGlobalInfo(e);
2954                 PlayerStats_Shutdown();
2955
2956                 if(!cheatcount_total)
2957                 {
2958                         if(autocvar_sv_db_saveasdump)
2959                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2960                         else
2961                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2962                 }
2963                 if(autocvar_developer)
2964                 {
2965                         if(autocvar_sv_db_saveasdump)
2966                                 db_dump(TemporaryDB, "server-temp.db");
2967                         else
2968                                 db_save(TemporaryDB, "server-temp.db");
2969                 }
2970                 CheatShutdown(); // must be after cheatcount check
2971                 db_close(ServerProgsDB);
2972                 db_close(TemporaryDB);
2973                 print("done!\n");
2974                 // tell the bot system the game is ending now
2975                 bot_endgame();
2976
2977                 WeaponStats_Shutdown();
2978                 MapInfo_Shutdown();
2979         }
2980         else if(world_initialized == 0)
2981         {
2982                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2983         }
2984 }