qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include <server/gamelog.qh>
  15 #include "ipban.qh"
  16 #include "mapvoting.qh"
  17 #include <server/mutators/_mod.qh>
  18 #include "race.qh"
  19 #include "scores.qh"
  20 #include "scores_rules.qh"
  21 #include "teamplay.qh"
  22 #include "weapons/weaponstats.qh"
  23 #include "../common/constants.qh"
  24 #include <common/net_linked.qh>
  25 #include "../common/deathtypes/all.qh"
  26 #include "../common/gamemodes/sv_rules.qh"
  27 #include "../common/mapinfo.qh"
  28 #include "../common/monsters/_mod.qh"
  29 #include "../common/monsters/sv_monsters.qh"
  30 #include "../common/vehicles/all.qh"
  31 #include "../common/notifications/all.qh"
  32 #include "../common/physics/player.qh"
  33 #include "../common/playerstats.qh"
  34 #include "../common/stats.qh"
  35 #include "../common/teams.qh"
  36 #include "../common/mapobjects/trigger/secret.qh"
  37 #include "../common/mapobjects/target/music.qh"
  38 #include "../common/util.qh"
  39 #include "../common/items/_mod.qh"
  40 #include <common/weapons/_all.qh>
  41 #include "../common/state.qh"
  42
  43 const float LATENCY_THINKRATE = 10;
  44 .float latency_sum;
  45 .float latency_cnt;
  46 .float latency_time;
  47 entity pingplreport;
  48 void PingPLReport_Think(entity this)
  49 {
  50         float delta;
  51         entity e;
  52
  53         delta = 3 / maxclients;
  54         if(delta < sys_frametime)
  55                 delta = 0;
  56         this.nextthink = time + delta;
  57
  58         e = edict_num(this.cnt + 1);
  59         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  60         {
  61                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  62                 WriteByte(MSG_BROADCAST, this.cnt);
  63                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
  64                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  65                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  66
  67                 // record latency times for clients throughout the match so we can report it to playerstats
  68                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  69                 {
  70                         CS(e).latency_sum += CS(e).ping;
  71                         CS(e).latency_cnt += 1;
  72                         CS(e).latency_time = time;
  73                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  74                 }
  75         }
  76         else
  77         {
  78                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  79                 WriteByte(MSG_BROADCAST, this.cnt);
  80                 WriteShort(MSG_BROADCAST, 0);
  81                 WriteByte(MSG_BROADCAST, 0);
  82                 WriteByte(MSG_BROADCAST, 0);
  83         }
  84         this.cnt = (this.cnt + 1) % maxclients;
  85 }
  86 void PingPLReport_Spawn()
  87 {
  88         pingplreport = new_pure(pingplreport);
  89         setthink(pingplreport, PingPLReport_Think);
  90         pingplreport.nextthink = time;
  91 }
  92
  93 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  94 string redirection_target;
  95 float world_initialized;
  96
  97 void SetDefaultAlpha()
  98 {
  99         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 100         {
 101                 default_player_alpha = autocvar_g_player_alpha;
 102                 if(default_player_alpha == 0)
 103                         default_player_alpha = 1;
 104                 default_weapon_alpha = default_player_alpha;
 105         }
 106 }
 107
 108 void GotoFirstMap(entity this)
 109 {
 110         float n;
 111         if(autocvar__sv_init)
 112         {
 113                 // cvar_set("_sv_init", "0");
 114                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 115                 // to this "init" map on a dedicated server will cause no permanent
 116                 // harm
 117                 if(autocvar_g_maplist_shuffle)
 118                         ShuffleMaplist();
 119                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 120                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 121
 122                 MapInfo_Enumerate();
 123                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 124
 125                 if(!DoNextMapOverride(1))
 126                         GotoNextMap(1);
 127
 128                 return;
 129         }
 130
 131         if(time < 5)
 132         {
 133                 this.nextthink = time;
 134         }
 135         else
 136         {
 137                 this.nextthink = time + 1;
 138                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 139         }
 140 }
 141
 142 void cvar_changes_init()
 143 {
 144         float h;
 145         string k, v, d;
 146         float n, i, adding, pureadding;
 147
 148         strfree(cvar_changes);
 149         strfree(cvar_purechanges);
 150         cvar_purechanges_count = 0;
 151
 152         h = buf_create();
 153         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 154         n = buf_getsize(h);
 155
 156         adding = true;
 157         pureadding = true;
 158
 159         for(i = 0; i < n; ++i)
 160         {
 161                 k = bufstr_get(h, i);
 162
 163 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 164 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 165 #define BADCVAR(p) if(k == p) continue
 166
 167                 // general excludes and namespaces for server admin used cvars
 168                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 169
 170                 // internal
 171                 BADPREFIX("csqc_");
 172                 BADPREFIX("cvar_check_");
 173                 BADCVAR("gamecfg");
 174                 BADCVAR("g_configversion");
 175                 BADCVAR("halflifebsp");
 176                 BADCVAR("sv_mapformat_is_quake2");
 177                 BADCVAR("sv_mapformat_is_quake3");
 178                 BADPREFIX("sv_world");
 179
 180                 // client
 181                 BADPREFIX("chase_");
 182                 BADPREFIX("cl_");
 183                 BADPREFIX("con_");
 184                 BADPREFIX("scoreboard_");
 185                 BADPREFIX("g_campaign");
 186                 BADPREFIX("g_waypointsprite_");
 187                 BADPREFIX("gl_");
 188                 BADPREFIX("joy");
 189                 BADPREFIX("hud_");
 190                 BADPREFIX("m_");
 191                 BADPREFIX("menu_");
 192                 BADPREFIX("net_slist_");
 193                 BADPREFIX("r_");
 194                 BADPREFIX("sbar_");
 195                 BADPREFIX("scr_");
 196                 BADPREFIX("snd_");
 197                 BADPREFIX("show");
 198                 BADPREFIX("sensitivity");
 199                 BADPREFIX("userbind");
 200                 BADPREFIX("v_");
 201                 BADPREFIX("vid_");
 202                 BADPREFIX("crosshair");
 203                 BADCVAR("mod_q3bsp_lightmapmergepower");
 204                 BADCVAR("mod_q3bsp_nolightmaps");
 205                 BADCVAR("fov");
 206                 BADCVAR("mastervolume");
 207                 BADCVAR("volume");
 208                 BADCVAR("bgmvolume");
 209                 BADCVAR("in_pitch_min");
 210                 BADCVAR("in_pitch_max");
 211
 212                 // private
 213                 BADCVAR("developer");
 214                 BADCVAR("log_dest_udp");
 215                 BADCVAR("net_address");
 216                 BADCVAR("net_address_ipv6");
 217                 BADCVAR("port");
 218                 BADCVAR("savedgamecfg");
 219                 BADCVAR("serverconfig");
 220                 BADCVAR("sv_autoscreenshot");
 221                 BADCVAR("sv_heartbeatperiod");
 222                 BADCVAR("sv_vote_master_password");
 223                 BADCVAR("sys_colortranslation");
 224                 BADCVAR("sys_specialcharactertranslation");
 225                 BADCVAR("timeformat");
 226                 BADCVAR("timestamps");
 227                 BADCVAR("g_require_stats");
 228                 BADPREFIX("developer_");
 229                 BADPREFIX("g_ban_");
 230                 BADPREFIX("g_banned_list");
 231                 BADPREFIX("g_require_stats_");
 232                 BADPREFIX("g_chat_flood_");
 233                 BADPREFIX("g_ghost_items");
 234                 BADPREFIX("g_playerstats_");
 235                 BADPREFIX("g_voice_flood_");
 236                 BADPREFIX("log_file");
 237                 BADPREFIX("quit_");
 238                 BADPREFIX("rcon_");
 239                 BADPREFIX("sv_allowdownloads");
 240                 BADPREFIX("sv_autodemo");
 241                 BADPREFIX("sv_curl_");
 242                 BADPREFIX("sv_eventlog");
 243                 BADPREFIX("sv_logscores_");
 244                 BADPREFIX("sv_master");
 245                 BADPREFIX("sv_weaponstats_");
 246                 BADPREFIX("sv_waypointsprite_");
 247                 BADCVAR("rescan_pending");
 248
 249                 // these can contain player IDs, so better hide
 250                 BADPREFIX("g_forced_team_");
 251                 BADCVAR("sv_muteban_list");
 252                 BADCVAR("sv_voteban_list");
 253                 BADCVAR("sv_allow_customplayermodels_idlist");
 254                 BADCVAR("sv_allow_customplayermodels_speciallist");
 255
 256                 // mapinfo
 257                 BADCVAR("fraglimit");
 258                 BADCVAR("g_arena");
 259                 BADCVAR("g_assault");
 260                 BADCVAR("g_ca");
 261                 BADCVAR("g_ca_teams");
 262                 BADCVAR("g_conquest");
 263                 BADCVAR("g_conquest_teams");
 264                 BADCVAR("g_ctf");
 265                 BADCVAR("g_cts");
 266                 BADCVAR("g_dotc");
 267                 BADCVAR("g_dm");
 268                 BADCVAR("g_domination");
 269                 BADCVAR("g_domination_default_teams");
 270                 BADCVAR("g_duel");
 271                 BADCVAR("g_duel_not_dm_maps");
 272                 BADCVAR("g_freezetag");
 273                 BADCVAR("g_freezetag_teams");
 274                 BADCVAR("g_invasion_teams");
 275                 BADCVAR("g_invasion_type");
 276                 BADCVAR("g_jailbreak");
 277                 BADCVAR("g_jailbreak_teams");
 278                 BADCVAR("g_keepaway");
 279                 BADCVAR("g_keyhunt");
 280                 BADCVAR("g_keyhunt_teams");
 281                 BADCVAR("g_lms");
 282                 BADCVAR("g_nexball");
 283                 BADCVAR("g_onslaught");
 284                 BADCVAR("g_race");
 285                 BADCVAR("g_race_laps_limit");
 286                 BADCVAR("g_race_qualifying_timelimit");
 287                 BADCVAR("g_race_qualifying_timelimit_override");
 288                 BADCVAR("g_runematch");
 289                 BADCVAR("g_shootfromeye");
 290                 BADCVAR("g_snafu");
 291                 BADCVAR("g_survival");
 292                 BADCVAR("g_survival_not_dm_maps");
 293                 BADCVAR("g_tdm");
 294                 BADCVAR("g_tdm_on_dm_maps");
 295                 BADCVAR("g_tdm_teams");
 296                 BADCVAR("g_vip");
 297                 BADCVAR("leadlimit");
 298                 BADCVAR("nextmap");
 299                 BADCVAR("teamplay");
 300                 BADCVAR("timelimit");
 301                 BADCVAR("g_mapinfo_settemp_acl");
 302                 BADCVAR("g_mapinfo_ignore_warnings");
 303                 BADCVAR("g_maplist_ignore_sizes");
 304                 BADCVAR("g_maplist_sizes_count_bots");
 305
 306                 // long
 307                 BADCVAR("hostname");
 308                 BADCVAR("g_maplist");
 309                 BADCVAR("g_maplist_mostrecent");
 310                 BADCVAR("sv_motd");
 311
 312                 v = cvar_string(k);
 313                 d = cvar_defstring(k);
 314                 if(v == d)
 315                         continue;
 316
 317                 if(adding)
 318                 {
 319                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 320                         if(strlen(cvar_changes) > 16384)
 321                         {
 322                                 cvar_changes = "// too many settings have been changed to show them here\n";
 323                                 adding = 0;
 324                         }
 325                 }
 326
 327                 // now check if the changes are actually gameplay relevant
 328
 329                 // does nothing gameplay relevant
 330                 BADCVAR("captureleadlimit_override");
 331                 BADCVAR("condump_stripcolors");
 332                 BADCVAR("gameversion");
 333                 BADCVAR("fs_gamedir");
 334                 BADCVAR("g_allow_oldvortexbeam");
 335                 BADCVAR("g_balance_kill_delay");
 336                 BADCVAR("g_buffs_pickup_anyway");
 337                 BADCVAR("g_buffs_randomize");
 338                 BADCVAR("g_buffs_randomize_teamplay");
 339                 BADCVAR("g_campcheck_distance");
 340                 BADCVAR("g_chatsounds");
 341                 BADCVAR("g_ca_point_leadlimit");
 342                 BADCVAR("g_ca_point_limit");
 343                 BADCVAR("g_ctf_captimerecord_always");
 344                 BADCVAR("g_ctf_flag_glowtrails");
 345                 BADCVAR("g_ctf_dynamiclights");
 346                 BADCVAR("g_ctf_flag_pickup_verbosename");
 347                 BADPRESUFFIX("g_ctf_flag_", "_model");
 348                 BADPRESUFFIX("g_ctf_flag_", "_skin");
 349                 BADCVAR("g_domination_point_leadlimit");
 350                 BADCVAR("g_forced_respawn");
 351                 BADCVAR("g_freezetag_point_leadlimit");
 352                 BADCVAR("g_freezetag_point_limit");
 353                 BADCVAR("g_glowtrails");
 354                 BADCVAR("g_hats");
 355                 BADCVAR("g_casings");
 356                 BADCVAR("g_invasion_point_limit");
 357                 BADCVAR("g_jump_grunt");
 358                 BADCVAR("g_keepaway_ballcarrier_effects");
 359                 BADCVAR("g_keepawayball_effects");
 360                 BADCVAR("g_keyhunt_point_leadlimit");
 361                 BADCVAR("g_nexball_goalleadlimit");
 362                 BADCVAR("g_new_toys_autoreplace");
 363                 BADCVAR("g_new_toys_use_pickupsound");
 364                 BADCVAR("g_physics_predictall");
 365                 BADCVAR("g_piggyback");
 366                 BADCVAR("g_playerclip_collisions");
 367                 BADCVAR("g_spawn_alloweffects");
 368                 BADCVAR("g_tdm_point_leadlimit");
 369                 BADCVAR("g_tdm_point_limit");
 370                 BADCVAR("leadlimit_and_fraglimit");
 371                 BADCVAR("leadlimit_override");
 372                 BADCVAR("pausable");
 373                 BADCVAR("sv_announcer");
 374                 BADCVAR("sv_checkforpacketsduringsleep");
 375                 BADCVAR("sv_damagetext");
 376                 BADCVAR("sv_db_saveasdump");
 377                 BADCVAR("sv_intermission_cdtrack");
 378                 BADCVAR("sv_mapchange_delay");
 379                 BADCVAR("sv_minigames");
 380                 BADCVAR("sv_namechangetimer");
 381                 BADCVAR("sv_precacheplayermodels");
 382                 BADCVAR("sv_radio");
 383                 BADCVAR("sv_stepheight");
 384                 BADCVAR("sv_timeout");
 385                 BADCVAR("sv_weapons_modeloverride");
 386                 BADCVAR("w_prop_interval");
 387                 BADPREFIX("chat_");
 388                 BADPREFIX("crypto_");
 389                 BADPREFIX("gameversion_");
 390                 BADPREFIX("g_chat_");
 391                 BADPREFIX("g_ctf_captimerecord_");
 392                 BADPREFIX("g_hats_");
 393                 BADPREFIX("g_maplist_");
 394                 BADPREFIX("g_mod_");
 395                 BADPREFIX("g_respawn_");
 396                 BADPREFIX("net_");
 397                 BADPREFIX("notification_");
 398                 BADPREFIX("prvm_");
 399                 BADPREFIX("skill_");
 400                 BADPREFIX("sv_allow_");
 401                 BADPREFIX("sv_cullentities_");
 402                 BADPREFIX("sv_maxidle_");
 403                 BADPREFIX("sv_minigames_");
 404                 BADPREFIX("sv_radio_");
 405                 BADPREFIX("sv_timeout_");
 406                 BADPREFIX("sv_vote_");
 407                 BADPREFIX("timelimit_");
 408
 409                 // allowed changes to server admins (please sync this to server.cfg)
 410                 // vi commands:
 411                 //   :/"impure"/,$d
 412                 //   :g!,^\/\/[^ /],d
 413                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 414                 //   :%!sort
 415                 // yes, this does contain some redundant stuff, don't really care
 416                 BADPREFIX("bot_ai_");
 417                 BADCVAR("bot_config_file");
 418                 BADCVAR("bot_number");
 419                 BADCVAR("bot_prefix");
 420                 BADCVAR("bot_suffix");
 421                 BADCVAR("capturelimit_override");
 422                 BADCVAR("fraglimit_override");
 423                 BADCVAR("gametype");
 424                 BADCVAR("g_antilag");
 425                 BADCVAR("g_balance_teams");
 426                 BADCVAR("g_balance_teams_prevent_imbalance");
 427                 BADCVAR("g_balance_teams_scorefactor");
 428                 BADCVAR("g_ban_sync_trusted_servers");
 429                 BADCVAR("g_ban_sync_uri");
 430                 BADCVAR("g_buffs");
 431                 BADCVAR("g_ca_teams_override");
 432                 BADCVAR("g_ctf_fullbrightflags");
 433                 BADCVAR("g_ctf_ignore_frags");
 434                 BADCVAR("g_ctf_leaderboard");
 435                 BADCVAR("g_domination_point_limit");
 436                 BADCVAR("g_domination_teams_override");
 437                 BADCVAR("g_freezetag_teams_override");
 438                 BADCVAR("g_friendlyfire");
 439                 BADCVAR("g_fullbrightitems");
 440                 BADCVAR("g_fullbrightplayers");
 441                 BADCVAR("g_keyhunt_point_limit");
 442                 BADCVAR("g_keyhunt_teams_override");
 443                 BADCVAR("g_lms_lives_override");
 444                 BADCVAR("g_maplist");
 445                 BADCVAR("g_maxplayers");
 446                 BADCVAR("g_mirrordamage");
 447                 BADCVAR("g_nexball_goallimit");
 448                 BADCVAR("g_norecoil");
 449                 BADCVAR("g_physics_clientselect");
 450                 BADCVAR("g_pinata");
 451                 BADCVAR("g_powerups");
 452                 BADCVAR("g_player_brightness");
 453                 BADCVAR("g_rocket_flying");
 454                 BADCVAR("g_rocket_flying_disabledelays");
 455                 BADCVAR("g_spawnshieldtime");
 456                 BADCVAR("g_start_delay");
 457                 BADCVAR("g_superspectate");
 458                 BADCVAR("g_tdm_teams_override");
 459                 BADCVAR("g_warmup");
 460                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 461                 BADCVAR("hostname");
 462                 BADCVAR("log_file");
 463                 BADCVAR("maxplayers");
 464                 BADCVAR("minplayers");
 465                 BADCVAR("minplayers_per_team");
 466                 BADCVAR("net_address");
 467                 BADCVAR("port");
 468                 BADCVAR("rcon_password");
 469                 BADCVAR("rcon_restricted_commands");
 470                 BADCVAR("rcon_restricted_password");
 471                 BADCVAR("skill");
 472                 BADCVAR("sv_adminnick");
 473                 BADCVAR("sv_autoscreenshot");
 474                 BADCVAR("sv_autotaunt");
 475                 BADCVAR("sv_curl_defaulturl");
 476                 BADCVAR("sv_defaultcharacter");
 477                 BADCVAR("sv_defaultcharacterskin");
 478                 BADCVAR("sv_defaultplayercolors");
 479                 BADCVAR("sv_defaultplayermodel");
 480                 BADCVAR("sv_defaultplayerskin");
 481                 BADCVAR("sv_maxidle");
 482                 BADCVAR("sv_maxrate");
 483                 BADCVAR("sv_motd");
 484                 BADCVAR("sv_public");
 485                 BADCVAR("sv_ready_restart");
 486                 BADCVAR("sv_status_privacy");
 487                 BADCVAR("sv_taunt");
 488                 BADCVAR("sv_vote_call");
 489                 BADCVAR("sv_vote_commands");
 490                 BADCVAR("sv_vote_majority_factor");
 491                 BADCVAR("sv_vote_master");
 492                 BADCVAR("sv_vote_master_commands");
 493                 BADCVAR("sv_vote_master_password");
 494                 BADCVAR("sv_vote_simple_majority_factor");
 495                 BADCVAR("teamplay_mode");
 496                 BADCVAR("timelimit_override");
 497                 BADPREFIX("g_warmup_");
 498                 BADPREFIX("sv_info_");
 499                 BADPREFIX("sv_ready_restart_");
 500
 501                 // mutators that announce themselves properly to the server browser
 502                 BADCVAR("g_instagib");
 503                 BADCVAR("g_new_toys");
 504                 BADCVAR("g_nix");
 505                 BADCVAR("g_grappling_hook");
 506                 BADCVAR("g_jetpack");
 507
 508                 // temporary for testing
 509                 // TODO remove before 0.8.3 release
 510                 BADCVAR("g_ca_weaponarena");
 511                 BADCVAR("g_freezetag_weaponarena");
 512                 BADCVAR("g_lms_weaponarena");
 513                 BADCVAR("g_ctf_stalemate_time");
 514
 515                 if(cvar_string("g_mod_balance") == "Testing")
 516                 {
 517                         // (temporary) while using the Testing balance, any weapon balance cvars are allowed to be changed
 518                         BADPREFIX("g_balance_");
 519                 }
 520
 521 #undef BADPRESUFFIX
 522 #undef BADPREFIX
 523 #undef BADCVAR
 524
 525                 if(pureadding)
 526                 {
 527                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 528                         if(strlen(cvar_purechanges) > 16384)
 529                         {
 530                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 531                                 pureadding = 0;
 532                         }
 533                 }
 534                 ++cvar_purechanges_count;
 535                 // WARNING: this variable is used for the server list
 536                 // NEVER dare to skip this code!
 537                 // Hacks to intentionally appearing as "pure server" even though you DO have
 538                 // modified settings may be punished by removal from the server list.
 539                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 540                 // though.
 541         }
 542         buf_del(h);
 543         if(cvar_changes == "")
 544                 cvar_changes = "// this server runs at default server settings\n";
 545         else
 546                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 547         cvar_changes = strzone(cvar_changes);
 548         if(cvar_purechanges == "")
 549                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 550         else
 551                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 552         cvar_purechanges = strzone(cvar_purechanges);
 553 }
 554
 555 entity randomseed;
 556 bool RandomSeed_Send(entity this, entity to, int sf)
 557 {
 558         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 559         WriteShort(MSG_ENTITY, this.cnt);
 560         return true;
 561 }
 562 void RandomSeed_Think(entity this)
 563 {
 564         this.cnt = bound(0, floor(random() * 65536), 65535);
 565         this.nextthink = time + 5;
 566
 567         this.SendFlags |= 1;
 568 }
 569 void RandomSeed_Spawn()
 570 {
 571         randomseed = new_pure(randomseed);
 572         setthink(randomseed, RandomSeed_Think);
 573         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 574
 575         getthink(randomseed)(randomseed); // sets random seed and nextthink
 576 }
 577
 578 spawnfunc(__init_dedicated_server)
 579 {
 580         // handler for _init/_init map (only for dedicated server initialization)
 581
 582         world_initialized = -1; // don't complain
 583
 584         delete_fn = remove_unsafely;
 585
 586         entity e = spawn();
 587         setthink(e, GotoFirstMap);
 588         e.nextthink = time; // this is usually 1 at this point
 589
 590         e = new(info_player_deathmatch);  // safeguard against player joining
 591
 592     // assign reflectively to avoid "assignment to world" warning
 593     for (int i = 0, n = numentityfields(); i < n; ++i) {
 594         string k = entityfieldname(i);
 595         if (k == "classname") {
 596             // safeguard against various stuff ;)
 597             putentityfieldstring(i, this, "worldspawn");
 598             break;
 599         }
 600     }
 601
 602         // needs to be done so early because of the constants they create
 603         static_init();
 604         static_init_late();
 605         static_init_precache();
 606
 607         IL_PUSH(g_spawnpoints, e); // just incase
 608
 609         MapInfo_Enumerate();
 610         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 611 }
 612
 613 void __init_dedicated_server_shutdown() {
 614         MapInfo_Shutdown();
 615 }
 616
 617 STATIC_INIT_EARLY(maxclients)
 618 {
 619         maxclients = 0;
 620         for (entity head = nextent(NULL); head; head = nextent(head)) {
 621                 ++maxclients;
 622         }
 623 }
 624
 625 void default_delayedinit(entity this)
 626 {
 627         if(!scores_initialized)
 628                 ScoreRules_generic();
 629 }
 630
 631 void InitGameplayMode()
 632 {
 633         VoteReset();
 634
 635         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 636         get_mi_min_max(1);
 637         // assign reflectively to avoid "assignment to world" warning
 638         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
 639             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 640             if (v) {
 641             putentityfieldstring(i, world, sprintf("%v", v));
 642             if (++done == 2) break;
 643         }
 644         }
 645         // currently, NetRadiant's limit is 131072 qu for each side
 646         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 647         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 648         // in case somebody makes extremely large maps
 649         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 650
 651         MapInfo_LoadMapSettings(mapname);
 652         GameRules_teams(false);
 653
 654         if (!cvar_value_issafe(world.fog))
 655         {
 656                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 657                 world.fog = string_null;
 658         }
 659         if(MapInfo_Map_fog != "")
 660         {
 661                 if(MapInfo_Map_fog == "none")
 662                         world.fog = string_null;
 663                 else
 664                         world.fog = strzone(MapInfo_Map_fog);
 665         }
 666         clientstuff = strzone(MapInfo_Map_clientstuff);
 667
 668         MapInfo_ClearTemps();
 669
 670         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 671
 672         cache_mutatormsg = strzone("");
 673         cache_lastmutatormsg = strzone("");
 674
 675         InitializeEntity(NULL, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 676 }
 677
 678 void Map_MarkAsRecent(string m);
 679 float world_already_spawned;
 680 spawnfunc(worldspawn)
 681 {
 682         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 683
 684         bool wantrestart = false;
 685         {
 686                 if (!server_is_dedicated)
 687                 {
 688                         // force unloading of server pk3 files when starting a listen server
 689                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 690                         // restore csqc_progname too
 691                         string expect = "csprogs.dat";
 692                         wantrestart = cvar_string("csqc_progname") != expect;
 693                         cvar_set("csqc_progname", expect);
 694                 }
 695                 else
 696                 {
 697                         // Try to use versioned csprogs from pk3
 698                         // Only ever use versioned csprogs.dat files on dedicated servers;
 699                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 700                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 701                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 702                         string select = "csprogs.dat";
 703                         if (fexists(pk3csprogs)) select = pk3csprogs;
 704                         if (cvar_string("csqc_progname") != select)
 705                         {
 706                                 cvar_set("csqc_progname", select);
 707                                 wantrestart = true;
 708                         }
 709                         // Check for updates on startup
 710                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 711                         int sentinel = fopen("progs.txt", FILE_READ);
 712                         if (sentinel >= 0)
 713                         {
 714                                 string switchversion = fgets(sentinel);
 715                                 fclose(sentinel);
 716                                 if (switchversion != "" && switchversion != WATERMARK)
 717                                 {
 718                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 719                                         // if it doesn't exist, assume either:
 720                                         //   a) the current program was overwritten
 721                                         //   b) this is a client only update
 722                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 723                                         if (fexists(newprogs))
 724                                         {
 725                                                 cvar_set("sv_progs", newprogs);
 726                                                 wantrestart = true;
 727                                         }
 728                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 729                                         if (fexists(newcsprogs))
 730                                         {
 731                                                 cvar_set("csqc_progname", newcsprogs);
 732                                                 wantrestart = true;
 733                                         }
 734                                 }
 735                         }
 736                 }
 737                 if (wantrestart)
 738                 {
 739                         LOG_INFO("Restart requested");
 740                         changelevel(mapname);
 741                         // let initialization continue, shutdown depends on it
 742                 }
 743         }
 744
 745         if(world_already_spawned)
 746                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 747         world_already_spawned = true;
 748
 749         delete_fn = remove_safely; // during spawning, watch what you remove!
 750
 751         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 752
 753         // needs to be done so early because of the constants they create
 754         static_init();
 755
 756         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 757
 758         TemporaryDB = db_create();
 759
 760         // 0 normal
 761         lightstyle(0, "m");
 762
 763         // 1 FLICKER (first variety)
 764         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 765
 766         // 2 SLOW STRONG PULSE
 767         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 768
 769         // 3 CANDLE (first variety)
 770         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 771
 772         // 4 FAST STROBE
 773         lightstyle(4, "mamamamamama");
 774
 775         // 5 GENTLE PULSE 1
 776         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 777
 778         // 6 FLICKER (second variety)
 779         lightstyle(6, "nmonqnmomnmomomno");
 780
 781         // 7 CANDLE (second variety)
 782         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 783
 784         // 8 CANDLE (third variety)
 785         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 786
 787         // 9 SLOW STROBE (fourth variety)
 788         lightstyle(9, "aaaaaaaazzzzzzzz");
 789
 790         // 10 FLUORESCENT FLICKER
 791         lightstyle(10, "mmamammmmammamamaaamammma");
 792
 793         // 11 SLOW PULSE NOT FADE TO BLACK
 794         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 795
 796         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 797
 798         // 63 testing
 799         lightstyle(63, "a");
 800
 801         if(autocvar_g_campaign)
 802                 CampaignPreInit();
 803
 804         Map_MarkAsRecent(mapname);
 805
 806         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 807
 808         InitGameplayMode();
 809         static_init_late();
 810         static_init_precache();
 811         readlevelcvars();
 812         GrappleHookInit();
 813
 814         GameRules_limit_fallbacks();
 815
 816         if(warmup_limit == 0)
 817                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 818
 819         player_count = 0;
 820         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 821         if(bot_waypoints_for_items == 1)
 822                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 823                         bot_waypoints_for_items = 0;
 824
 825         WaypointSprite_Init();
 826
 827         GameLogInit(); // prepare everything
 828         // NOTE for matchid:
 829         // changing the logic generating it is okay. But:
 830         // it HAS to stay <= 64 chars
 831         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 832         if(autocvar_sv_eventlog)
 833         {
 834                 string s = sprintf("%s.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 835                 matchid = strzone(s);
 836
 837                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 838                 s = ":gameinfo:mutators:LIST";
 839
 840                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 841                 s = M_ARGV(0, string);
 842
 843                 // initialiation stuff, not good in the mutator system
 844                 if(!autocvar_g_use_ammunition)
 845                         s = strcat(s, ":no_use_ammunition");
 846
 847                 // initialiation stuff, not good in the mutator system
 848                 if(autocvar_g_pickup_items == 0)
 849                         s = strcat(s, ":no_pickup_items");
 850                 if(autocvar_g_pickup_items > 0)
 851                         s = strcat(s, ":pickup_items");
 852
 853                 // initialiation stuff, not good in the mutator system
 854                 if(autocvar_g_weaponarena != "0")
 855                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 856
 857                 // TODO to mutator system
 858                 if(autocvar_g_norecoil)
 859                         s = strcat(s, ":norecoil");
 860
 861                 // TODO to mutator system
 862                 if(autocvar_g_powerups == 0)
 863                         s = strcat(s, ":no_powerups");
 864                 if(autocvar_g_powerups > 0)
 865                         s = strcat(s, ":powerups");
 866
 867                 GameLogEcho(s);
 868                 GameLogEcho(":gameinfo:end");
 869         }
 870         else
 871                 matchid = strzone(ftos(random()));
 872
 873         cvar_set("nextmap", "");
 874
 875         SetDefaultAlpha();
 876
 877         if(autocvar_g_campaign)
 878                 CampaignPostInit();
 879
 880         Ban_LoadBans();
 881
 882         MapInfo_Enumerate();
 883         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 884
 885         if(fexists(strcat("scripts/", mapname, ".arena")))
 886                 cvar_settemp("sv_q3acompat_machineshotgunswap", "1");
 887
 888         if(fexists(strcat("scripts/", mapname, ".defi")))
 889                 cvar_settemp("sv_q3defragcompat", "1");
 890
 891         // quake 3 music support
 892         if(world.music || world.noise)
 893         {
 894                 // prefer .music over .noise
 895                 string chosen_music;
 896                 string oldstuff;
 897                 if(world.music)
 898                         chosen_music = world.music;
 899                 else
 900                         chosen_music = world.noise;
 901                 if(
 902                         substring(chosen_music, strlen(chosen_music) - 4, 4) == ".wav"
 903                         ||
 904                         substring(chosen_music, strlen(chosen_music) - 4, 4) == ".ogg"
 905                 )
 906                         oldstuff = strcat(clientstuff, "cd loop \"", chosen_music, "\"\n");
 907                 else
 908                         oldstuff = strcat(clientstuff, "cd loop \"", chosen_music, "\"\n");
 909
 910                 strcpy(clientstuff, oldstuff);
 911         }
 912
 913         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 914         {
 915                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 916                 if(fd != -1)
 917                 {
 918                         string s;
 919                         while((s = fgets(fd)))
 920                         {
 921                                 int l = tokenize_console(s);
 922                                 if(l < 2)
 923                                         continue;
 924                                 if(argv(0) == "cd")
 925                                 {
 926                                         string trackname = argv(2);
 927                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 928                                         LOG_INFO("  cdtrack ", trackname);
 929                                         if (cvar_value_issafe(trackname))
 930                                         {
 931                                                 string newstuff = strcat(clientstuff, "cd loop \"", trackname, "\"\n");
 932                                                 strcpy(clientstuff, newstuff);
 933                                         }
 934                                 }
 935                                 else if(argv(0) == "fog")
 936                                 {
 937                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 938                                         LOG_INFO("  \"fog\" \"", s, "\"");
 939                                 }
 940                                 else if(argv(0) == "set")
 941                                 {
 942                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 943                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 944                                 }
 945                                 else if(argv(0) != "//")
 946                                 {
 947                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 948                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 949                                 }
 950                         }
 951                         fclose(fd);
 952                 }
 953         }
 954
 955         WeaponStats_Init();
 956
 957         Nagger_Init();
 958
 959         next_pingtime = time + 5;
 960
 961         // set up information replies for clients and server to use
 962         maplist_reply = strzone(getmaplist());
 963         lsmaps_reply = strzone(getlsmaps());
 964         monsterlist_reply = strzone(getmonsterlist());
 965         for(int i = 0; i < 10; ++i)
 966         {
 967                 string s = getrecords(i);
 968                 if (s)
 969                         records_reply[i] = strzone(s);
 970         }
 971         ladder_reply = strzone(getladder());
 972         rankings_reply = strzone(getrankings());
 973
 974         // begin other init
 975         ClientInit_Spawn();
 976         RandomSeed_Spawn();
 977         PingPLReport_Spawn();
 978
 979         CheatInit();
 980
 981         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 982
 983         // fill sv_curl_serverpackages from .serverpackage files
 984         if (autocvar_sv_curl_serverpackages_auto)
 985         {
 986                 string s = "csprogs-" WATERMARK ".txt";
 987                 // remove automatically managed files from the list to prevent duplicates
 988                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 989                 {
 990                         string pkg = argv(i);
 991                         if (startsWith(pkg, "csprogs-")) continue;
 992                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 993                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 994                         s = cons(s, pkg);
 995                 }
 996                 // add automatically managed files to the list
 997                 #define X(match) MACRO_BEGIN \
 998                         int fd = search_begin(match, true, false); \
 999                         if (fd >= 0) \
1000                         { \
1001                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
1002                                 { \
1003                                         s = cons(s, search_getfilename(fd, i)); \
1004                                 } \
1005                                 search_end(fd); \
1006                         } \
1007                 MACRO_END
1008                 X("*-serverpackage.txt");
1009                 X("*.serverpackage");
1010                 #undef X
1011                 cvar_set("sv_curl_serverpackages", s);
1012         }
1013
1014         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
1015         modname = "Xonotic";
1016         // physics/balance/config changes that count as mod
1017         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
1018                 modname = cvar_string("g_mod_physics");
1019         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance") && cvar_string("g_mod_balance") != "Testing")
1020                 modname = cvar_string("g_mod_balance");
1021         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
1022                 modname = cvar_string("g_mod_config");
1023         // extra mutators that deserve to count as mod
1024         MUTATOR_CALLHOOK(SetModname, modname);
1025         modname = M_ARGV(0, string);
1026
1027         // save it for later
1028         modname = strzone(modname);
1029
1030         WinningConditionHelper(this); // set worldstatus
1031
1032         world_initialized = 1;
1033         __spawnfunc_spawn_all();
1034 }
1035
1036 spawnfunc(light)
1037 {
1038         //makestatic (this); // Who the f___ did that?
1039         delete(this);
1040 }
1041
1042 string GetGametype()
1043 {
1044         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
1045 }
1046
1047 string GetMapname()
1048 {
1049         return mapname;
1050 }
1051
1052 float Map_Count, Map_Current;
1053 string Map_Current_Name;
1054
1055 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
1056 int GetMaplistPosition()
1057 {
1058         string map = GetMapname();
1059         int idx = autocvar_g_maplist_index;
1060
1061         if(idx >= 0)
1062         {
1063                 if(idx < Map_Count)
1064                 {
1065                         if(map == argv(idx))
1066                         {
1067                                 return idx;
1068                         }
1069                 }
1070         }
1071
1072         for(int pos = 0; pos < Map_Count; ++pos)
1073         {
1074                 if(map == argv(pos))
1075                         return pos;
1076         }
1077
1078         // resume normal maplist rotation if current map is not in g_maplist
1079         return idx;
1080 }
1081
1082 bool MapHasRightSize(string map)
1083 {
1084         int minplayers = max(0, floor(autocvar_minplayers));
1085         if (teamplay)
1086                 minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
1087         if (autocvar_g_maplist_check_waypoints
1088                 && (currentbots || autocvar_bot_number || player_count < minplayers))
1089         {
1090                 string checkwp_msg = strcat("checkwp ", map);
1091                 if(!fexists(strcat("maps/", map, ".waypoints")))
1092                 {
1093                         LOG_TRACE(checkwp_msg, ": no waypoints");
1094                         return false;
1095                 }
1096                 LOG_TRACE(checkwp_msg, ": has waypoints");
1097         }
1098
1099         if(autocvar_g_maplist_ignore_sizes)
1100                 return true;
1101
1102         // open map size restriction file
1103         string opensize_msg = strcat("opensize ", map);
1104         float fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1105         int player_limit = ((autocvar_g_maplist_sizes_count_maxplayers) ? GetPlayerLimit() : 0);
1106         int pcount = ((player_limit > 0) ? min(player_count, player_limit) : player_count); // bind it to the player limit so that forced spectators don't influence the limits
1107         if(!autocvar_g_maplist_sizes_count_bots)
1108                 pcount -= currentbots;
1109         if(fh >= 0)
1110         {
1111                 opensize_msg = strcat(opensize_msg, ": ok, ");
1112                 int mapmin = stoi(fgets(fh));
1113                 int mapmax = stoi(fgets(fh));
1114                 fclose(fh);
1115                 if(pcount < mapmin)
1116                 {
1117                         LOG_TRACE(opensize_msg, "not enough");
1118                         return false;
1119                 }
1120                 if(mapmax && pcount > mapmax)
1121                 {
1122                         LOG_TRACE(opensize_msg, "too many");
1123                         return false;
1124                 }
1125                 LOG_TRACE(opensize_msg, "right size");
1126                 return true;
1127         }
1128         LOG_TRACE(opensize_msg, ": not found");
1129         return true;
1130 }
1131
1132 string Map_Filename(float position)
1133 {
1134         return strcat("maps/", argv(position), ".bsp");
1135 }
1136
1137 void Map_MarkAsRecent(string m)
1138 {
1139         cvar_set("g_maplist_mostrecent", strwords(cons(m, autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1140 }
1141
1142 float Map_IsRecent(string m)
1143 {
1144         return strhasword(autocvar_g_maplist_mostrecent, m);
1145 }
1146
1147 float Map_Check(float position, float pass)
1148 {
1149         string filename;
1150         string map_next;
1151         map_next = argv(position);
1152         if(pass <= 1)
1153         {
1154                 if(Map_IsRecent(map_next))
1155                         return 0;
1156         }
1157         filename = Map_Filename(position);
1158         if(MapInfo_CheckMap(map_next))
1159         {
1160                 if(pass == 2)
1161                         return 1;
1162                 if(MapHasRightSize(map_next))
1163                         return 1;
1164                 return 0;
1165         }
1166         else
1167                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1168
1169         return 0;
1170 }
1171
1172 void Map_Goto_SetStr(string nextmapname)
1173 {
1174         if(getmapname_stored != "")
1175                 strunzone(getmapname_stored);
1176         if(nextmapname == "")
1177                 getmapname_stored = "";
1178         else
1179                 getmapname_stored = strzone(nextmapname);
1180 }
1181
1182 void Map_Goto_SetFloat(float position)
1183 {
1184         cvar_set("g_maplist_index", ftos(position));
1185         Map_Goto_SetStr(argv(position));
1186 }
1187
1188 void Map_Goto(float reinit)
1189 {
1190         MapInfo_LoadMap(getmapname_stored, reinit);
1191 }
1192
1193 // return codes of map selectors:
1194 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1195 //   -2 = permanent failure
1196 float MaplistMethod_Iterate() // usual method
1197 {
1198         float pass, i;
1199
1200         LOG_TRACE("Trying MaplistMethod_Iterate");
1201
1202         for(pass = 1; pass <= 2; ++pass)
1203         {
1204                 for(i = 1; i < Map_Count; ++i)
1205                 {
1206                         float mapindex;
1207                         mapindex = (i + Map_Current) % Map_Count;
1208                         if(Map_Check(mapindex, pass))
1209                                 return mapindex;
1210                 }
1211         }
1212         return -1;
1213 }
1214
1215 float MaplistMethod_Repeat() // fallback method
1216 {
1217         LOG_TRACE("Trying MaplistMethod_Repeat");
1218
1219         if(Map_Check(Map_Current, 2))
1220                 return Map_Current;
1221         return -2;
1222 }
1223
1224 float MaplistMethod_Random() // random map selection
1225 {
1226         float i, imax;
1227
1228         LOG_TRACE("Trying MaplistMethod_Random");
1229
1230         imax = 42;
1231
1232         for(i = 0; i <= imax; ++i)
1233         {
1234                 float mapindex;
1235                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1236                 if(Map_Check(mapindex, 1))
1237                         return mapindex;
1238         }
1239         return -1;
1240 }
1241
1242 float MaplistMethod_Shuffle(float exponent) // more clever shuffling
1243 // the exponent sets a bias on the map selection:
1244 // the higher the exponent, the less likely "shortly repeated" same maps are
1245 {
1246         float i, j, imax, insertpos;
1247
1248         LOG_TRACE("Trying MaplistMethod_Shuffle");
1249
1250         imax = 42;
1251
1252         for(i = 0; i <= imax; ++i)
1253         {
1254                 string newlist;
1255
1256                 // now reinsert this at another position
1257                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1258                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1259                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1260                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1261
1262                 // insert the current map there
1263                 newlist = "";
1264                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1265                         newlist = strcat(newlist, " ", argv(j));
1266                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1267                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1268                         newlist = strcat(newlist, " ", argv(j));
1269                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1270                 cvar_set("g_maplist", newlist);
1271                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1272
1273                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1274                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1275                 if(Map_Check(Map_Current, 1))
1276                         return Map_Current;
1277         }
1278         return -1;
1279 }
1280
1281 void Maplist_Init()
1282 {
1283         float i = Map_Count = 0;
1284         if(autocvar_g_maplist != "")
1285         {
1286                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1287                 for (i = 0; i < Map_Count; ++i)
1288                 {
1289                         if (Map_Check(i, 2))
1290                                 break;
1291                 }
1292         }
1293
1294         if (i == Map_Count)
1295         {
1296                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1297                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1298                 if(autocvar_g_maplist_shuffle)
1299                         ShuffleMaplist();
1300                 if(!server_is_dedicated)
1301                         localcmd("\nmenu_cmd sync\n");
1302                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1303         }
1304         if(Map_Count == 0)
1305                 error("empty maplist, cannot select a new map");
1306         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1307
1308         strcpy(Map_Current_Name, argv(Map_Current)); // will be automatically freed on exit thanks to DP
1309         // this may or may not be correct, but who cares, in the worst case a map
1310         // isn't chosen in the first pass that should have been
1311 }
1312
1313 string GetNextMap()
1314 {
1315         Maplist_Init();
1316         float nextMap = -1;
1317
1318         if(nextMap == -1)
1319                 if(autocvar_g_maplist_shuffle > 0)
1320                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1321
1322         if(nextMap == -1)
1323                 if(autocvar_g_maplist_selectrandom)
1324                         nextMap = MaplistMethod_Random();
1325
1326         if(nextMap == -1)
1327                 nextMap = MaplistMethod_Iterate();
1328
1329         if(nextMap == -1)
1330                 nextMap = MaplistMethod_Repeat();
1331
1332         if(nextMap >= 0)
1333         {
1334                 Map_Goto_SetFloat(nextMap);
1335                 return getmapname_stored;
1336         }
1337
1338         return "";
1339 }
1340
1341 float DoNextMapOverride(float reinit)
1342 {
1343         if(autocvar_g_campaign)
1344         {
1345                 CampaignPostIntermission();
1346                 alreadychangedlevel = true;
1347                 return true;
1348         }
1349         if(autocvar_quit_when_empty)
1350         {
1351                 if(player_count <= currentbots)
1352                 {
1353                         localcmd("quit\n");
1354                         alreadychangedlevel = true;
1355                         return true;
1356                 }
1357         }
1358         if(autocvar_quit_and_redirect != "")
1359         {
1360                 redirection_target = strzone(autocvar_quit_and_redirect);
1361                 alreadychangedlevel = true;
1362                 return true;
1363         }
1364         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1365         {
1366                 localcmd("restart\n");
1367                 alreadychangedlevel = true;
1368                 return true;
1369         }
1370         if(autocvar_nextmap != "")
1371         {
1372                 string m;
1373                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1374                 cvar_set("nextmap",m);
1375
1376                 if(!m || gametypevote)
1377                         return false;
1378                 if(autocvar_sv_vote_gametype)
1379                 {
1380                         Map_Goto_SetStr(m);
1381                         return false;
1382                 }
1383
1384                 if(MapInfo_CheckMap(m))
1385                 {
1386                         Map_Goto_SetStr(m);
1387                         Map_Goto(reinit);
1388                         alreadychangedlevel = true;
1389                         return true;
1390                 }
1391         }
1392         if(!reinit && autocvar_lastlevel)
1393         {
1394                 cvar_settemp_restore();
1395                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1396                 alreadychangedlevel = true;
1397                 return true;
1398         }
1399         return false;
1400 }
1401
1402 void GotoNextMap(float reinit)
1403 {
1404         //string nextmap;
1405         //float n, nummaps;
1406         //string s;
1407         if (alreadychangedlevel)
1408                 return;
1409         alreadychangedlevel = true;
1410
1411         string nextMap = GetNextMap();
1412         if(nextMap == "")
1413                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1414         Map_Goto(reinit);
1415 }
1416
1417
1418 /*
1419 ============
1420 IntermissionThink
1421
1422 When the player presses attack or jump, change to the next level
1423 ============
1424 */
1425 .float autoscreenshot;
1426 void IntermissionThink(entity this)
1427 {
1428         FixIntermissionClient(this);
1429
1430         float server_screenshot = (autocvar_sv_autoscreenshot && CS(this).cvar_cl_autoscreenshot);
1431         float client_screenshot = (CS(this).cvar_cl_autoscreenshot == 2);
1432
1433         if( (server_screenshot || client_screenshot)
1434                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1435         {
1436                 this.autoscreenshot = -1;
1437                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1438                 return;
1439         }
1440
1441         if (time < intermission_exittime)
1442                 return;
1443
1444         if(!mapvote_initialized)
1445                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1446                         return;
1447
1448         MapVote_Start();
1449 }
1450
1451 /*
1452 ===============================================================================
1453
1454 RULES
1455
1456 ===============================================================================
1457 */
1458
1459 void DumpStats(float final)
1460 {
1461         float file;
1462         string s;
1463         float to_console;
1464         float to_eventlog;
1465         float to_file;
1466         float i;
1467
1468         to_console = autocvar_sv_logscores_console;
1469         to_eventlog = autocvar_sv_eventlog;
1470         to_file = autocvar_sv_logscores_file;
1471
1472         if(!final)
1473         {
1474                 to_console = true; // always print printstats replies
1475                 to_eventlog = false; // but never print them to the event log
1476         }
1477
1478         if(to_eventlog)
1479                 if(autocvar_sv_eventlog_console)
1480                         to_console = false; // otherwise we get the output twice
1481
1482         if(final)
1483                 s = ":scores:";
1484         else
1485                 s = ":status:";
1486         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1487
1488         if(to_console)
1489                 LOG_INFO(s);
1490         if(to_eventlog)
1491                 GameLogEcho(s);
1492
1493         file = -1;
1494         if(to_file)
1495         {
1496                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1497                 if(file == -1)
1498                         to_file = false;
1499                 else
1500                         fputs(file, strcat(s, "\n"));
1501         }
1502
1503         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1504         if(to_console)
1505                 LOG_INFO(s);
1506         if(to_eventlog)
1507                 GameLogEcho(s);
1508         if(to_file)
1509                 fputs(file, strcat(s, "\n"));
1510
1511         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1512                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1513                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1514                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1515                         s = strcat(s, ftos(it.team), ":");
1516                 else
1517                         s = strcat(s, "spectator:");
1518
1519                 if(to_console)
1520                         LOG_INFO(s, playername(it, false));
1521                 if(to_eventlog)
1522                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1523                 if(to_file)
1524                         fputs(file, strcat(s, playername(it, false), "\n"));
1525         });
1526
1527         if(teamplay)
1528         {
1529                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1530                 if(to_console)
1531                         LOG_INFO(s);
1532                 if(to_eventlog)
1533                         GameLogEcho(s);
1534                 if(to_file)
1535                         fputs(file, strcat(s, "\n"));
1536
1537                 for(i = 1; i < 16; ++i)
1538                 {
1539                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1540                         s = strcat(s, ":", ftos(i));
1541                         if(to_console)
1542                                 LOG_INFO(s);
1543                         if(to_eventlog)
1544                                 GameLogEcho(s);
1545                         if(to_file)
1546                                 fputs(file, strcat(s, "\n"));
1547                 }
1548         }
1549
1550         if(to_console)
1551                 LOG_INFO(":end");
1552         if(to_eventlog)
1553                 GameLogEcho(":end");
1554         if(to_file)
1555         {
1556                 fputs(file, ":end\n");
1557                 fclose(file);
1558         }
1559 }
1560
1561 void FixIntermissionClient(entity e)
1562 {
1563         if(!e.autoscreenshot) // initial call
1564         {
1565                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1566                 SetResourceExplicit(e, RES_HEALTH, -2342);
1567                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1568                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1569                 {
1570                     .entity weaponentity = weaponentities[slot];
1571                         if(e.(weaponentity))
1572                         {
1573                                 e.(weaponentity).effects = EF_NODRAW;
1574                                 if (e.(weaponentity).weaponchild)
1575                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1576                         }
1577                 }
1578                 if(IS_REAL_CLIENT(e))
1579                 {
1580                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1581                         RandomSelection_Init();
1582                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, {
1583                                 RandomSelection_AddString(it, 1, 1);
1584                         });
1585                         if (RandomSelection_chosen_string != "")
1586                         {
1587                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1588                         }
1589                         msg_entity = e;
1590                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1591                 }
1592         }
1593 }
1594
1595 /*
1596 go to the next level for deathmatch
1597 only called if a time or frag limit has expired
1598 */
1599 void NextLevel()
1600 {
1601         game_stopped = true;
1602         intermission_running = 1; // game over
1603
1604         // enforce a wait time before allowing changelevel
1605         if(player_count > 0)
1606                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1607         else
1608                 intermission_exittime = -1;
1609
1610         /*
1611         WriteByte (MSG_ALL, SVC_CDTRACK);
1612         WriteByte (MSG_ALL, 3);
1613         WriteByte (MSG_ALL, 3);
1614         // done in FixIntermission
1615         */
1616
1617         //pos = FindIntermission ();
1618
1619         VoteReset();
1620
1621         DumpStats(true);
1622
1623         // send statistics
1624         PlayerStats_GameReport(true);
1625         WeaponStats_Shutdown();
1626
1627         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1628
1629         if(autocvar_sv_eventlog)
1630                 GameLogEcho(":gameover");
1631
1632         GameLogClose();
1633
1634         FOREACH_CLIENT(IS_PLAYER(it), {
1635                 FixIntermissionClient(it);
1636                 if(it.winning)
1637                         bprint(playername(it, false), " ^7wins.\n");
1638         });
1639
1640         target_music_kill();
1641
1642         if(autocvar_g_campaign)
1643                 CampaignPreIntermission();
1644
1645         MUTATOR_CALLHOOK(MatchEnd);
1646
1647         localcmd("\nsv_hook_gameend\n");
1648 }
1649
1650
1651 float InitiateSuddenDeath()
1652 {
1653         // Check first whether normal overtimes could be added before initiating suddendeath mode
1654         // - for this timelimit_overtime needs to be >0 of course
1655         // - also check the winning condition calculated in the previous frame and only add normal overtime
1656         //   again, if at the point at which timelimit would be extended again, still no winner was found
1657         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1658                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1659                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1660         {
1661                 return 1; // need to call InitiateOvertime later
1662         }
1663         else
1664         {
1665                 if(!checkrules_suddendeathend)
1666                 {
1667                         if(autocvar_g_campaign)
1668                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1669                         else
1670                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1671                         if(g_race && !g_race_qualifying)
1672                                 race_StartCompleting();
1673                 }
1674                 return 0;
1675         }
1676 }
1677
1678 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1679 {
1680         ++checkrules_overtimesadded;
1681         //add one more overtime by simply extending the timelimit
1682         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1683         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1684 }
1685
1686 float GetWinningCode(float fraglimitreached, float equality)
1687 {
1688         if(autocvar_g_campaign == 1)
1689         {
1690                 if(fraglimitreached)
1691                         return WINNING_YES;
1692                 else
1693                         return WINNING_NO;
1694         }
1695         else
1696         {
1697                 if(equality)
1698                 {
1699                         if(fraglimitreached)
1700                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1701                         else
1702                                 return WINNING_NEVER;
1703                 }
1704                 else
1705                 {
1706                         if(fraglimitreached)
1707                                 return WINNING_YES;
1708                         else
1709                                 return WINNING_NO;
1710                 }
1711         }
1712 }
1713
1714 // set the .winning flag for exactly those players with a given field value
1715 void SetWinners(.float field, float value)
1716 {
1717         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1718 }
1719
1720 // set the .winning flag for those players with a given field value
1721 void AddWinners(.float field, float value)
1722 {
1723         FOREACH_CLIENT(IS_PLAYER(it), {
1724                 if(it.(field) == value)
1725                         it.winning = 1;
1726         });
1727 }
1728
1729 // clear the .winning flags
1730 void ClearWinners()
1731 {
1732         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1733 }
1734
1735 void ShuffleMaplist()
1736 {
1737         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1738 }
1739
1740 int fragsleft_last;
1741 float WinningCondition_Scores(float limit, float leadlimit)
1742 {
1743         // TODO make everything use THIS winning condition (except LMS)
1744         WinningConditionHelper(NULL);
1745
1746         if(teamplay)
1747         {
1748                 for (int i = 1; i < 5; ++i)
1749                 {
1750                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1751                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1752                 }
1753         }
1754
1755         ClearWinners();
1756         if(WinningConditionHelper_winner)
1757                 WinningConditionHelper_winner.winning = 1;
1758         if(WinningConditionHelper_winnerteam >= 0)
1759                 SetWinners(team, WinningConditionHelper_winnerteam);
1760
1761         if(WinningConditionHelper_lowerisbetter)
1762         {
1763                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1764                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1765                 limit = -limit;
1766         }
1767
1768         if(WinningConditionHelper_zeroisworst)
1769                 leadlimit = 0; // not supported in this mode
1770
1771         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1772         {
1773                 float fragsleft;
1774                 if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1775                 {
1776                         fragsleft = 1;
1777                 }
1778                 else
1779                 {
1780                         fragsleft = FLOAT_MAX;
1781                         float leadingfragsleft = FLOAT_MAX;
1782                         if (limit)
1783                                 fragsleft = limit - WinningConditionHelper_topscore;
1784                         if (leadlimit)
1785                                 leadingfragsleft = WinningConditionHelper_secondscore + leadlimit - WinningConditionHelper_topscore;
1786
1787                         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1788                                 fragsleft = max(fragsleft, leadingfragsleft);
1789                         else
1790                                 fragsleft = min(fragsleft, leadingfragsleft);
1791                 }
1792
1793                 if (fragsleft_last != fragsleft) // do not announce same remaining frags multiple times
1794                 {
1795                         if (fragsleft == 1)
1796                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1797                         else if (fragsleft == 2)
1798                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1799                         else if (fragsleft == 3)
1800                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1801
1802                         fragsleft_last = fragsleft;
1803                 }
1804         }
1805
1806         bool fraglimit_reached = (limit && WinningConditionHelper_topscore >= limit);
1807         bool leadlimit_reached = (leadlimit && WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1808
1809         bool limit_reached;
1810         // only respect leadlimit_and_fraglimit when both limits are set or the game will never end
1811         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1812                 limit_reached = (fraglimit_reached && leadlimit_reached);
1813         else
1814                 limit_reached = (fraglimit_reached || leadlimit_reached);
1815
1816         return GetWinningCode(
1817                 WinningConditionHelper_topscore && limit_reached,
1818                 WinningConditionHelper_equality
1819         );
1820 }
1821
1822 float WinningCondition_RanOutOfSpawns()
1823 {
1824         if(have_team_spawns <= 0)
1825                 return WINNING_NO;
1826
1827         if(!autocvar_g_spawn_useallspawns)
1828                 return WINNING_NO;
1829
1830         if(!some_spawn_has_been_used)
1831                 return WINNING_NO;
1832
1833         for (int i = 1; i < 5; ++i)
1834         {
1835                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1836         }
1837
1838         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1839         {
1840                 if (Team_IsValidTeam(it.team))
1841                 {
1842                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1843                 }
1844         });
1845
1846         IL_EACH(g_spawnpoints, true,
1847         {
1848                 if (Team_IsValidTeam(it.team))
1849                 {
1850                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1851                 }
1852         });
1853
1854         ClearWinners();
1855         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1856         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1857         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1858         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1859         if(team1_score + team2_score + team3_score + team4_score == 0)
1860         {
1861                 checkrules_equality = true;
1862                 return WINNING_YES;
1863         }
1864         else if(team1_score + team2_score + team3_score + team4_score == 1)
1865         {
1866                 float t, i;
1867                 if(team1_score)
1868                         t = 1;
1869                 else if(team2_score)
1870                         t = 2;
1871                 else if(team3_score)
1872                         t = 3;
1873                 else // if(team4_score)
1874                         t = 4;
1875                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1876                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1877                 {
1878                         for (int j = 1; j <= NUM_TEAMS; ++j)
1879                         {
1880                                 if (t == j)
1881                                 {
1882                                         continue;
1883                                 }
1884                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1885                                 {
1886                                         continue;
1887                                 }
1888                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1889                         }
1890                 }
1891
1892                 AddWinners(team, t);
1893                 return WINNING_YES;
1894         }
1895         else
1896                 return WINNING_NO;
1897 }
1898
1899 /*
1900 ============
1901 CheckRules_World
1902
1903 Exit deathmatch games upon conditions
1904 ============
1905 */
1906 void CheckRules_World()
1907 {
1908         VoteThink();
1909         MapVote_Think();
1910
1911         SetDefaultAlpha();
1912
1913         if (intermission_running) // someone else quit the game already
1914         {
1915                 if(player_count == 0) // Nobody there? Then let's go to the next map
1916                         MapVote_Start();
1917                         // this will actually check the player count in the next frame
1918                         // again, but this shouldn't hurt
1919                 return;
1920         }
1921
1922         float timelimit = autocvar_timelimit * 60;
1923         float fraglimit = autocvar_fraglimit;
1924         float leadlimit = autocvar_leadlimit;
1925         if (leadlimit < 0) leadlimit = 0;
1926
1927         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1928         {
1929                 if(timelimit > 0)
1930                         timelimit = 0; // timelimit is not made for warmup
1931                 if(fraglimit > 0)
1932                         fraglimit = 0; // no fraglimit for now
1933                 leadlimit = 0; // no leadlimit for now
1934         }
1935
1936         if(timelimit > 0)
1937         {
1938                 timelimit += game_starttime;
1939         }
1940         else if (timelimit < 0)
1941         {
1942                 // endmatch
1943                 NextLevel();
1944                 return;
1945         }
1946
1947         float wantovertime;
1948         wantovertime = 0;
1949
1950         if(checkrules_suddendeathend)
1951         {
1952                 if(!checkrules_suddendeathwarning)
1953                 {
1954                         checkrules_suddendeathwarning = true;
1955                         if(g_race && !g_race_qualifying)
1956                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1957                         else
1958                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1959                 }
1960         }
1961         else
1962         {
1963                 if (timelimit && time >= timelimit)
1964                 {
1965                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1966                         {
1967                                 float totalplayers;
1968                                 float playerswithlaps;
1969                                 float readyplayers;
1970                                 totalplayers = playerswithlaps = readyplayers = 0;
1971                                 FOREACH_CLIENT(IS_PLAYER(it), {
1972                                         ++totalplayers;
1973                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1974                                                 ++playerswithlaps;
1975                                         if(it.ready)
1976                                                 ++readyplayers;
1977                                 });
1978
1979                                 // at least 2 of the players have completed a lap: start the RACE
1980                                 // otherwise, the players should end the qualifying on their own
1981                                 if(readyplayers || playerswithlaps >= 2)
1982                                 {
1983                                         checkrules_suddendeathend = 0;
1984                                         ReadyRestart(); // go to race
1985                                         return;
1986                                 }
1987                                 else
1988                                         wantovertime |= InitiateSuddenDeath();
1989                         }
1990                         else
1991                                 wantovertime |= InitiateSuddenDeath();
1992                 }
1993         }
1994
1995         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1996         {
1997                 NextLevel();
1998                 return;
1999         }
2000
2001         int checkrules_status = WinningCondition_RanOutOfSpawns();
2002         if(checkrules_status == WINNING_YES)
2003                 bprint("Hey! Someone ran out of spawns!\n");
2004         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
2005                 checkrules_status = M_ARGV(0, float);
2006         else
2007                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2008
2009         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2010         {
2011                 checkrules_status = WINNING_NEVER;
2012                 checkrules_overtimesadded = -1;
2013                 wantovertime |= InitiateSuddenDeath();
2014         }
2015
2016         if(checkrules_status == WINNING_NEVER)
2017                 // equality cases! Nobody wins if the overtime ends in a draw.
2018                 ClearWinners();
2019
2020         if(wantovertime)
2021         {
2022                 if(checkrules_status == WINNING_NEVER)
2023                         InitiateOvertime();
2024                 else
2025                         checkrules_status = WINNING_YES;
2026         }
2027
2028         if(checkrules_suddendeathend)
2029                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2030                         checkrules_status = WINNING_YES;
2031
2032         if(checkrules_status == WINNING_YES)
2033         {
2034                 //print("WINNING\n");
2035                 NextLevel();
2036         }
2037 }
2038
2039 string GotoMap(string m)
2040 {
2041         m = GameTypeVote_MapInfo_FixName(m);
2042         if (!m)
2043                 return "The map you suggested is not available on this server.";
2044         if (!autocvar_sv_vote_gametype)
2045         if(!MapInfo_CheckMap(m))
2046                 return "The map you suggested does not support the current game mode.";
2047         cvar_set("nextmap", m);
2048         cvar_set("timelimit", "-1");
2049         if(mapvote_initialized || alreadychangedlevel)
2050         {
2051                 if(DoNextMapOverride(0))
2052                         return "Map switch initiated.";
2053                 else
2054                         return "Hm... no. For some reason I like THIS map more.";
2055         }
2056         else
2057                 return "Map switch will happen after scoreboard.";
2058 }
2059
2060 bool autocvar_sv_gameplayfix_multiplethinksperframe = true;
2061 void RunThink(entity this)
2062 {
2063         // don't let things stay in the past.
2064         // it is possible to start that way by a trigger with a local time.
2065         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2066                 return;
2067
2068         float oldtime = time; // do we need to save this?
2069
2070         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2071         {
2072                 time = max(oldtime, this.nextthink);
2073                 this.nextthink = 0;
2074
2075                 if(getthink(this))
2076                         getthink(this)(this);
2077                 // mods often set nextthink to time to cause a think every frame,
2078                 // we don't want to loop in that case, so exit if the new nextthink is
2079                 // <= the time the qc was told, also exit if it is past the end of the
2080                 // frame
2081                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2082                         break;
2083         }
2084
2085         time = oldtime;
2086 }
2087
2088 bool autocvar_sv_freezenonclients;
2089 bool autocvar_sv_gameplayfix_delayprojectiles = false;
2090 void Physics_Frame()
2091 {
2092         if(autocvar_sv_freezenonclients)
2093                 return;
2094
2095         IL_EACH(g_moveables, true,
2096         {
2097                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PHYSICS)
2098                         continue;
2099
2100                 //set_movetype(it, it.move_movetype);
2101                 // inline the set_movetype function, since this is called a lot
2102                 it.movetype = (it.move_qcphysics) ? MOVETYPE_QCENTITY : it.move_movetype;
2103
2104                 if(it.move_qcphysics && it.move_movetype != MOVETYPE_NONE)
2105                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2106
2107                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2108                 {
2109                         if(it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH)
2110                                 continue; // these movetypes have no regular think function
2111                         // handle thinking here
2112                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2113                                 RunThink(it);
2114                 }
2115         });
2116
2117         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2118                 return;
2119
2120         IL_EACH(g_moveables, it.move_qcphysics,
2121         {
2122                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2123                         continue;
2124                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2125         });
2126 }
2127
2128 void systems_update();
2129 void EndFrame()
2130 {
2131         anticheat_endframe();
2132
2133         Physics_Frame();
2134
2135         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2136                 entity e = IS_SPEC(it) ? it.enemy : it;
2137                 if (e.typehitsound) {
2138                         STAT(TYPEHIT_TIME, it) = time;
2139                 } else if (e.killsound) {
2140                         STAT(KILL_TIME, it) = time;
2141                 } else if (e.damage_dealt) {
2142                         STAT(HIT_TIME, it) = time;
2143                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2144                 }
2145         });
2146         // add 1 frametime because after this, engine SV_Physics
2147         // increases time by a frametime and then networks the frame
2148         // add another frametime because client shows everything with
2149         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2150         // needed!
2151         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2152         FOREACH_CLIENT(true, {
2153                 it.typehitsound = false;
2154                 it.damage_dealt = 0;
2155                 it.killsound = false;
2156                 antilag_record(it, CS(it), altime);
2157         });
2158         IL_EACH(g_monsters, true,
2159         {
2160                 antilag_record(it, it, altime);
2161         });
2162         IL_EACH(g_projectiles, it.classname == "nade",
2163         {
2164                 antilag_record(it, it, altime);
2165         });
2166         systems_update();
2167         IL_ENDFRAME();
2168 }
2169
2170
2171 /*
2172  * RedirectionThink:
2173  * returns true if redirecting
2174  */
2175 float redirection_timeout;
2176 float redirection_nextthink;
2177 float RedirectionThink()
2178 {
2179         float clients_found;
2180
2181         if(redirection_target == "")
2182                 return false;
2183
2184         if(!redirection_timeout)
2185         {
2186                 cvar_set("sv_public", "-2");
2187                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2188                 if(redirection_target == "self")
2189                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2190                 else
2191                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2192         }
2193
2194         if(time < redirection_nextthink)
2195                 return true;
2196
2197         redirection_nextthink = time + 1;
2198
2199         clients_found = 0;
2200         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2201                 // TODO add timer
2202                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2203                 if(redirection_target == "self")
2204                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2205                 else
2206                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2207                 ++clients_found;
2208         });
2209
2210         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2211
2212         if(time > redirection_timeout || clients_found == 0)
2213                 localcmd("\nwait; wait; wait; quit\n");
2214
2215         return true;
2216 }
2217
2218 void RestoreGame()
2219 {
2220         // Loaded from a save game
2221         // some things then break, so let's work around them...
2222
2223         // Progs DB (capture records)
2224         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2225
2226         // Mapinfo
2227         MapInfo_Shutdown();
2228         MapInfo_Enumerate();
2229         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2230         WeaponStats_Init();
2231
2232         TargetMusic_RestoreGame();
2233 }
2234
2235 void Shutdown()
2236 {
2237         game_stopped = 2;
2238
2239         if(world_initialized > 0)
2240         {
2241                 world_initialized = 0;
2242
2243                 // if a timeout is active, reset the slowmo value to normal
2244                 if(timeout_status == TIMEOUT_ACTIVE)
2245                         cvar_set("slowmo", ftos(orig_slowmo));
2246
2247                 LOG_TRACE("Saving persistent data...");
2248                 Ban_SaveBans();
2249
2250                 // playerstats with unfinished match
2251                 PlayerStats_GameReport(false);
2252
2253                 if(!cheatcount_total)
2254                 {
2255                         if(autocvar_sv_db_saveasdump)
2256                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2257                         else
2258                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2259                 }
2260                 if(autocvar_developer > 0)
2261                 {
2262                         if(autocvar_sv_db_saveasdump)
2263                                 db_dump(TemporaryDB, "server-temp.db");
2264                         else
2265                                 db_save(TemporaryDB, "server-temp.db");
2266                 }
2267                 CheatShutdown(); // must be after cheatcount check
2268                 db_close(ServerProgsDB);
2269                 db_close(TemporaryDB);
2270                 LOG_TRACE("Saving persistent data... done!");
2271                 // tell the bot system the game is ending now
2272                 bot_endgame();
2273
2274                 WeaponStats_Shutdown();
2275                 MapInfo_Shutdown();
2276         }
2277         else if(world_initialized == 0)
2278         {
2279                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2280         }
2281         else
2282         {
2283                 __init_dedicated_server_shutdown();
2284         }
2285 }