qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/_mod.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/constants.qh"
  22 #include <common/net_linked.qh>
  23 #include "../common/deathtypes/all.qh"
  24 #include "../common/mapinfo.qh"
  25 #include "../common/monsters/_mod.qh"
  26 #include "../common/monsters/sv_monsters.qh"
  27 #include "../common/vehicles/all.qh"
  28 #include "../common/notifications/all.qh"
  29 #include "../common/physics/player.qh"
  30 #include "../common/playerstats.qh"
  31 #include "../common/stats.qh"
  32 #include "../common/teams.qh"
  33 #include "../common/triggers/trigger/secret.qh"
  34 #include "../common/triggers/target/music.qh"
  35 #include "../common/util.qh"
  36 #include "../common/items/_mod.qh"
  37 #include <common/weapons/_all.qh>
  38 #include "../common/state.qh"
  39
  40 const float LATENCY_THINKRATE = 10;
  41 .float latency_sum;
  42 .float latency_cnt;
  43 .float latency_time;
  44 entity pingplreport;
  45 void PingPLReport_Think(entity this)
  46 {
  47         float delta;
  48         entity e;
  49
  50         delta = 3 / maxclients;
  51         if(delta < sys_frametime)
  52                 delta = 0;
  53         this.nextthink = time + delta;
  54
  55         e = edict_num(this.cnt + 1);
  56         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  57         {
  58                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  59                 WriteByte(MSG_BROADCAST, this.cnt);
  60                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
  61                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  62                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  63
  64                 // record latency times for clients throughout the match so we can report it to playerstats
  65                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  66                 {
  67                         CS(e).latency_sum += CS(e).ping;
  68                         CS(e).latency_cnt += 1;
  69                         CS(e).latency_time = time;
  70                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  71                 }
  72         }
  73         else
  74         {
  75                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  76                 WriteByte(MSG_BROADCAST, this.cnt);
  77                 WriteShort(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79                 WriteByte(MSG_BROADCAST, 0);
  80         }
  81         this.cnt = (this.cnt + 1) % maxclients;
  82 }
  83 void PingPLReport_Spawn()
  84 {
  85         pingplreport = new_pure(pingplreport);
  86         setthink(pingplreport, PingPLReport_Think);
  87         pingplreport.nextthink = time;
  88 }
  89
  90 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  91 string redirection_target;
  92 float world_initialized;
  93
  94 string GetGametype();
  95 void ShuffleMaplist();
  96
  97 void SetDefaultAlpha()
  98 {
  99         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 100         {
 101                 default_player_alpha = autocvar_g_player_alpha;
 102                 if(default_player_alpha == 0)
 103                         default_player_alpha = 1;
 104                 default_weapon_alpha = default_player_alpha;
 105         }
 106 }
 107
 108 void GotoFirstMap(entity this)
 109 {
 110         float n;
 111         if(autocvar__sv_init)
 112         {
 113                 // cvar_set("_sv_init", "0");
 114                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 115                 // to this "init" map on a dedicated server will cause no permanent
 116                 // harm
 117                 if(autocvar_g_maplist_shuffle)
 118                         ShuffleMaplist();
 119                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 120                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 121
 122                 MapInfo_Enumerate();
 123                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 124
 125                 if(!DoNextMapOverride(1))
 126                         GotoNextMap(1);
 127
 128                 return;
 129         }
 130
 131         if(time < 5)
 132         {
 133                 this.nextthink = time;
 134         }
 135         else
 136         {
 137                 this.nextthink = time + 1;
 138                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 139         }
 140 }
 141
 142 void cvar_changes_init()
 143 {
 144         float h;
 145         string k, v, d;
 146         float n, i, adding, pureadding;
 147
 148         if(cvar_changes)
 149                 strunzone(cvar_changes);
 150         cvar_changes = string_null;
 151         if(cvar_purechanges)
 152                 strunzone(cvar_purechanges);
 153         cvar_purechanges = string_null;
 154         cvar_purechanges_count = 0;
 155
 156         h = buf_create();
 157         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 158         n = buf_getsize(h);
 159
 160         adding = true;
 161         pureadding = true;
 162
 163         for(i = 0; i < n; ++i)
 164         {
 165                 k = bufstr_get(h, i);
 166
 167 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 168 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 169 #define BADCVAR(p) if(k == p) continue
 170
 171                 // general excludes and namespaces for server admin used cvars
 172                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 173
 174                 // internal
 175                 BADPREFIX("csqc_");
 176                 BADPREFIX("cvar_check_");
 177                 BADCVAR("gamecfg");
 178                 BADCVAR("g_configversion");
 179                 BADCVAR("halflifebsp");
 180                 BADCVAR("sv_mapformat_is_quake2");
 181                 BADCVAR("sv_mapformat_is_quake3");
 182                 BADPREFIX("sv_world");
 183
 184                 // client
 185                 BADPREFIX("chase_");
 186                 BADPREFIX("cl_");
 187                 BADPREFIX("con_");
 188                 BADPREFIX("scoreboard_");
 189                 BADPREFIX("g_campaign");
 190                 BADPREFIX("g_waypointsprite_");
 191                 BADPREFIX("gl_");
 192                 BADPREFIX("joy");
 193                 BADPREFIX("hud_");
 194                 BADPREFIX("m_");
 195                 BADPREFIX("menu_");
 196                 BADPREFIX("net_slist_");
 197                 BADPREFIX("r_");
 198                 BADPREFIX("sbar_");
 199                 BADPREFIX("scr_");
 200                 BADPREFIX("snd_");
 201                 BADPREFIX("show");
 202                 BADPREFIX("sensitivity");
 203                 BADPREFIX("userbind");
 204                 BADPREFIX("v_");
 205                 BADPREFIX("vid_");
 206                 BADPREFIX("crosshair");
 207                 BADCVAR("mod_q3bsp_lightmapmergepower");
 208                 BADCVAR("mod_q3bsp_nolightmaps");
 209                 BADCVAR("fov");
 210                 BADCVAR("mastervolume");
 211                 BADCVAR("volume");
 212                 BADCVAR("bgmvolume");
 213                 BADCVAR("in_pitch_min");
 214                 BADCVAR("in_pitch_max");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("net_address");
 220                 BADCVAR("net_address_ipv6");
 221                 BADCVAR("port");
 222                 BADCVAR("savedgamecfg");
 223                 BADCVAR("serverconfig");
 224                 BADCVAR("sv_autoscreenshot");
 225                 BADCVAR("sv_heartbeatperiod");
 226                 BADCVAR("sv_vote_master_password");
 227                 BADCVAR("sys_colortranslation");
 228                 BADCVAR("sys_specialcharactertranslation");
 229                 BADCVAR("timeformat");
 230                 BADCVAR("timestamps");
 231                 BADCVAR("g_require_stats");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_require_stats_");
 236                 BADPREFIX("g_chat_flood_");
 237                 BADPREFIX("g_ghost_items");
 238                 BADPREFIX("g_playerstats_");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("log_file");
 241                 BADPREFIX("quit_");
 242                 BADPREFIX("rcon_");
 243                 BADPREFIX("sv_allowdownloads");
 244                 BADPREFIX("sv_autodemo");
 245                 BADPREFIX("sv_curl_");
 246                 BADPREFIX("sv_eventlog");
 247                 BADPREFIX("sv_logscores_");
 248                 BADPREFIX("sv_master");
 249                 BADPREFIX("sv_weaponstats_");
 250                 BADPREFIX("sv_waypointsprite_");
 251                 BADCVAR("rescan_pending");
 252
 253                 // these can contain player IDs, so better hide
 254                 BADPREFIX("g_forced_team_");
 255                 BADCVAR("sv_muteban_list");
 256                 BADCVAR("sv_allow_customplayermodels_idlist");
 257                 BADCVAR("sv_allow_customplayermodels_speciallist");
 258
 259                 // mapinfo
 260                 BADCVAR("fraglimit");
 261                 BADCVAR("g_arena");
 262                 BADCVAR("g_assault");
 263                 BADCVAR("g_ca");
 264                 BADCVAR("g_ca_teams");
 265                 BADCVAR("g_conquest");
 266                 BADCVAR("g_ctf");
 267                 BADCVAR("g_cts");
 268                 BADCVAR("g_dotc");
 269                 BADCVAR("g_dm");
 270                 BADCVAR("g_domination");
 271                 BADCVAR("g_domination_default_teams");
 272                 BADCVAR("g_freezetag");
 273                 BADCVAR("g_freezetag_teams");
 274                 BADCVAR("g_gg");
 275                 BADCVAR("g_invasion_teams");
 276                 BADCVAR("g_invasion_type");
 277                 BADCVAR("g_jailbreak");
 278                 BADCVAR("g_jailbreak_teams");
 279                 BADCVAR("g_keepaway");
 280                 BADCVAR("g_keyhunt");
 281                 BADCVAR("g_keyhunt_teams");
 282                 BADCVAR("g_lms");
 283                 BADCVAR("g_nexball");
 284                 BADCVAR("g_onslaught");
 285                 BADCVAR("g_race");
 286                 BADCVAR("g_race_laps_limit");
 287                 BADCVAR("g_race_qualifying_timelimit");
 288                 BADCVAR("g_race_qualifying_timelimit_override");
 289                 BADCVAR("g_runematch");
 290                 BADCVAR("g_snafu");
 291                 BADCVAR("g_surv"); // Lyberta: adding gamemode cvar
 292                 BADCVAR("g_tdm");
 293                 BADCVAR("g_tdm_teams");
 294                 BADCVAR("g_vip");
 295                 BADCVAR("leadlimit");
 296                 BADCVAR("nextmap");
 297                 BADCVAR("teamplay");
 298                 BADCVAR("timelimit");
 299                 BADCVAR("g_mapinfo_ignore_warnings");
 300
 301                 // long
 302                 BADCVAR("hostname");
 303                 BADCVAR("g_maplist");
 304                 BADCVAR("g_maplist_mostrecent");
 305                 BADCVAR("sv_motd");
 306
 307                 v = cvar_string(k);
 308                 d = cvar_defstring(k);
 309                 if(v == d)
 310                         continue;
 311
 312                 if(adding)
 313                 {
 314                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 315                         if(strlen(cvar_changes) > 16384)
 316                         {
 317                                 cvar_changes = "// too many settings have been changed to show them here\n";
 318                                 adding = 0;
 319                         }
 320                 }
 321
 322                 // now check if the changes are actually gameplay relevant
 323
 324                 // does nothing gameplay relevant
 325                 BADCVAR("captureleadlimit_override");
 326                 BADCVAR("condump_stripcolors");
 327                 BADCVAR("gameversion");
 328                 BADCVAR("g_allow_oldvortexbeam");
 329                 BADCVAR("g_balance_kill_delay");
 330                 BADCVAR("g_buffs_pickup_anyway");
 331                 BADCVAR("g_buffs_randomize");
 332                 BADCVAR("g_campcheck_distance");
 333                 BADCVAR("g_ca_point_leadlimit");
 334                 BADCVAR("g_ca_point_limit");
 335                 BADCVAR("g_ctf_captimerecord_always");
 336                 BADCVAR("g_ctf_flag_glowtrails");
 337                 BADCVAR("g_ctf_flag_pickup_verbosename");
 338                 BADCVAR("g_domination_point_leadlimit");
 339                 BADCVAR("g_forced_respawn");
 340                 BADCVAR("g_freezetag_point_leadlimit");
 341                 BADCVAR("g_freezetag_point_limit");
 342                 BADCVAR("g_hats");
 343                 BADCVAR("g_invasion_point_limit");
 344                 BADCVAR("g_jump_grunt");
 345                 BADCVAR("g_keyhunt_point_leadlimit");
 346                 BADCVAR("g_nexball_goalleadlimit");
 347                 BADCVAR("g_new_toys_use_pickupsound");
 348                 BADCVAR("g_physics_predictall");
 349                 BADCVAR("g_piggyback");
 350                 BADCVAR("g_playerclip_collisions");
 351                 BADCVAR("g_tdm_point_leadlimit");
 352                 BADCVAR("g_tdm_point_limit");
 353                 BADCVAR("leadlimit_and_fraglimit");
 354                 BADCVAR("leadlimit_override");
 355                 BADCVAR("pausable");
 356                 BADCVAR("sv_checkforpacketsduringsleep");
 357                 BADCVAR("sv_damagetext");
 358                 BADCVAR("sv_db_saveasdump");
 359                 BADCVAR("sv_intermission_cdtrack");
 360                 BADCVAR("sv_minigames");
 361                 BADCVAR("sv_namechangetimer");
 362                 BADCVAR("sv_precacheplayermodels");
 363                 BADCVAR("sv_stepheight");
 364                 BADCVAR("sv_timeout");
 365                 BADCVAR("sv_weapons_modeloverride");
 366                 BADPREFIX("crypto_");
 367                 BADPREFIX("gameversion_");
 368                 BADPREFIX("g_chat_");
 369                 BADPREFIX("g_ctf_captimerecord_");
 370                 BADPREFIX("g_maplist_");
 371                 BADPREFIX("g_mod_");
 372                 BADPREFIX("g_respawn_");
 373                 BADPREFIX("net_");
 374                 BADPREFIX("notification_");
 375                 BADPREFIX("prvm_");
 376                 BADPREFIX("skill_");
 377                 BADPREFIX("sv_allow_");
 378                 BADPREFIX("sv_cullentities_");
 379                 BADPREFIX("sv_maxidle_");
 380                 BADPREFIX("sv_minigames_");
 381                 BADPREFIX("sv_radio_");
 382                 BADPREFIX("sv_timeout_");
 383                 BADPREFIX("sv_vote_");
 384                 BADPREFIX("timelimit_");
 385
 386                 // allowed changes to server admins (please sync this to server.cfg)
 387                 // vi commands:
 388                 //   :/"impure"/,$d
 389                 //   :g!,^\/\/[^ /],d
 390                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 391                 //   :%!sort
 392                 // yes, this does contain some redundant stuff, don't really care
 393                 BADCVAR("bot_config_file");
 394                 BADCVAR("bot_number");
 395                 BADCVAR("bot_prefix");
 396                 BADCVAR("bot_suffix");
 397                 BADCVAR("capturelimit_override");
 398                 BADCVAR("fraglimit_override");
 399                 BADCVAR("gametype");
 400                 BADCVAR("g_antilag");
 401                 BADCVAR("g_balance_teams");
 402                 BADCVAR("g_balance_teams_prevent_imbalance");
 403                 BADCVAR("g_balance_teams_scorefactor");
 404                 BADCVAR("g_ban_sync_trusted_servers");
 405                 BADCVAR("g_ban_sync_uri");
 406                 BADCVAR("g_buffs");
 407                 BADCVAR("g_ca_teams_override");
 408                 BADCVAR("g_ctf_ignore_frags");
 409                 BADCVAR("g_ctf_leaderboard");
 410                 BADCVAR("g_domination_point_limit");
 411                 BADCVAR("g_domination_teams_override");
 412                 BADCVAR("g_freezetag_teams_override");
 413                 BADCVAR("g_friendlyfire");
 414                 BADCVAR("g_fullbrightitems");
 415                 BADCVAR("g_fullbrightplayers");
 416                 BADCVAR("g_keyhunt_point_limit");
 417                 BADCVAR("g_keyhunt_teams_override");
 418                 BADCVAR("g_lms_lives_override");
 419                 BADCVAR("g_maplist");
 420                 BADCVAR("g_maxplayers");
 421                 BADCVAR("g_mirrordamage");
 422                 BADCVAR("g_nexball_goallimit");
 423                 BADCVAR("g_norecoil");
 424                 BADCVAR("g_physics_clientselect");
 425                 BADCVAR("g_pinata");
 426                 BADCVAR("g_powerups");
 427                 BADCVAR("g_spawnshieldtime");
 428                 BADCVAR("g_start_delay");
 429                 BADCVAR("g_superspectate");
 430                 BADCVAR("g_tdm_teams_override");
 431                 BADCVAR("g_warmup");
 432                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 433                 BADCVAR("hostname");
 434                 BADCVAR("log_file");
 435                 BADCVAR("maxplayers");
 436                 BADCVAR("minplayers");
 437                 BADCVAR("net_address");
 438                 BADCVAR("port");
 439                 BADCVAR("rcon_password");
 440                 BADCVAR("rcon_restricted_commands");
 441                 BADCVAR("rcon_restricted_password");
 442                 BADCVAR("skill");
 443                 BADCVAR("sv_adminnick");
 444                 BADCVAR("sv_autoscreenshot");
 445                 BADCVAR("sv_autotaunt");
 446                 BADCVAR("sv_curl_defaulturl");
 447                 BADCVAR("sv_defaultcharacter");
 448                 BADCVAR("sv_defaultcharacterskin");
 449                 BADCVAR("sv_defaultplayercolors");
 450                 BADCVAR("sv_defaultplayermodel");
 451                 BADCVAR("sv_defaultplayerskin");
 452                 BADCVAR("sv_maxidle");
 453                 BADCVAR("sv_maxrate");
 454                 BADCVAR("sv_motd");
 455                 BADCVAR("sv_public");
 456                 BADCVAR("sv_ready_restart");
 457                 BADCVAR("sv_status_privacy");
 458                 BADCVAR("sv_taunt");
 459                 BADCVAR("sv_vote_call");
 460                 BADCVAR("sv_vote_commands");
 461                 BADCVAR("sv_vote_majority_factor");
 462                 BADCVAR("sv_vote_master");
 463                 BADCVAR("sv_vote_master_commands");
 464                 BADCVAR("sv_vote_master_password");
 465                 BADCVAR("sv_vote_simple_majority_factor");
 466                 BADCVAR("teamplay_mode");
 467                 BADCVAR("timelimit_override");
 468                 BADPREFIX("g_warmup_");
 469                 BADPREFIX("sv_info_");
 470                 BADPREFIX("sv_ready_restart_");
 471
 472                 // mutators that announce themselves properly to the server browser
 473                 BADCVAR("g_instagib");
 474                 BADCVAR("g_new_toys");
 475                 BADCVAR("g_nix");
 476                 BADCVAR("g_grappling_hook");
 477                 BADCVAR("g_jetpack");
 478
 479 #undef BADPRESUFFIX
 480 #undef BADPREFIX
 481 #undef BADCVAR
 482
 483                 if(pureadding)
 484                 {
 485                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 486                         if(strlen(cvar_purechanges) > 16384)
 487                         {
 488                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 489                                 pureadding = 0;
 490                         }
 491                 }
 492                 ++cvar_purechanges_count;
 493                 // WARNING: this variable is used for the server list
 494                 // NEVER dare to skip this code!
 495                 // Hacks to intentionally appearing as "pure server" even though you DO have
 496                 // modified settings may be punished by removal from the server list.
 497                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 498                 // though.
 499         }
 500         buf_del(h);
 501         if(cvar_changes == "")
 502                 cvar_changes = "// this server runs at default server settings\n";
 503         else
 504                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 505         cvar_changes = strzone(cvar_changes);
 506         if(cvar_purechanges == "")
 507                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 508         else
 509                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 510         cvar_purechanges = strzone(cvar_purechanges);
 511 }
 512
 513 void detect_maptype()
 514 {
 515 #if 0
 516         vector o, v;
 517         float i;
 518
 519         for (;;)
 520         {
 521                 o = world.mins;
 522                 o.x += random() * (world.maxs.x - world.mins.x);
 523                 o.y += random() * (world.maxs.y - world.mins.y);
 524                 o.z += random() * (world.maxs.z - world.mins.z);
 525
 526                 tracebox(o, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), o - '0 0 32768', MOVE_WORLDONLY, NULL);
 527                 if(trace_fraction == 1)
 528                         continue;
 529
 530                 v = trace_endpos;
 531
 532                 for(i = 0; i < 64; i += 4)
 533                 {
 534                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, NULL);
 535         if(trace_fraction == 1)
 536                 continue;
 537                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos));
 538                 }
 539
 540                 break;
 541         }
 542 #endif
 543 }
 544
 545 entity randomseed;
 546 bool RandomSeed_Send(entity this, entity to, int sf)
 547 {
 548         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 549         WriteShort(MSG_ENTITY, this.cnt);
 550         return true;
 551 }
 552 void RandomSeed_Think(entity this)
 553 {
 554         this.cnt = bound(0, floor(random() * 65536), 65535);
 555         this.nextthink = time + 5;
 556
 557         this.SendFlags |= 1;
 558 }
 559 void RandomSeed_Spawn()
 560 {
 561         randomseed = new_pure(randomseed);
 562         setthink(randomseed, RandomSeed_Think);
 563         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 564
 565         getthink(randomseed)(randomseed); // sets random seed and nextthink
 566 }
 567
 568 spawnfunc(__init_dedicated_server)
 569 {
 570         // handler for _init/_init map (only for dedicated server initialization)
 571
 572         world_initialized = -1; // don't complain
 573         cvar = cvar_normal;
 574         cvar_string = cvar_string_normal;
 575         cvar_set = cvar_set_normal;
 576
 577         delete_fn = remove_unsafely;
 578
 579         entity e = spawn();
 580         setthink(e, GotoFirstMap);
 581         e.nextthink = time; // this is usually 1 at this point
 582
 583         e = new(info_player_deathmatch);  // safeguard against player joining
 584
 585         this.classname = "worldspawn"; // safeguard against various stuff ;)
 586
 587         // needs to be done so early because of the constants they create
 588         static_init();
 589         static_init_late();
 590         static_init_precache();
 591
 592         IL_PUSH(g_spawnpoints, e); // just incase
 593
 594         MapInfo_Enumerate();
 595         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 596 }
 597
 598 void __init_dedicated_server_shutdown() {
 599         MapInfo_Shutdown();
 600 }
 601
 602 void Map_MarkAsRecent(string m);
 603 float world_already_spawned;
 604 void Nagger_Init();
 605 void ClientInit_Spawn();
 606 void WeaponStats_Init();
 607 void WeaponStats_Shutdown();
 608 spawnfunc(worldspawn)
 609 {
 610         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 611
 612     bool wantrestart = false;
 613         {
 614                 if (!server_is_dedicated)
 615                 {
 616                         // force unloading of server pk3 files when starting a listen server
 617                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 618                         // restore csqc_progname too
 619                         string expect = "csprogs.dat";
 620                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 621                         cvar_set_normal("csqc_progname", expect);
 622                 }
 623                 else
 624                 {
 625                         // Try to use versioned csprogs from pk3
 626                         // Only ever use versioned csprogs.dat files on dedicated servers;
 627                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 628                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 629                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 630                         string select = "csprogs.dat";
 631                         if (fexists(pk3csprogs)) select = pk3csprogs;
 632                         if (cvar_string_normal("csqc_progname") != select)
 633                         {
 634                                 cvar_set_normal("csqc_progname", select);
 635                                 wantrestart = true;
 636                         }
 637                         // Check for updates on startup
 638                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 639                         int sentinel = fopen("progs.txt", FILE_READ);
 640                         if (sentinel >= 0)
 641                         {
 642                                 string switchversion = fgets(sentinel);
 643                                 fclose(sentinel);
 644                                 if (switchversion != "" && switchversion != WATERMARK)
 645                                 {
 646                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 647                                         // if it doesn't exist, assume either:
 648                                         //   a) the current program was overwritten
 649                                         //   b) this is a client only update
 650                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 651                                         if (fexists(newprogs))
 652                                         {
 653                                                 cvar_set_normal("sv_progs", newprogs);
 654                                                 wantrestart = true;
 655                                         }
 656                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 657                                         if (fexists(newcsprogs))
 658                                         {
 659                                                 cvar_set_normal("csqc_progname", newcsprogs);
 660                                                 wantrestart = true;
 661                                         }
 662                                 }
 663                         }
 664                 }
 665                 if (wantrestart)
 666                 {
 667                         LOG_INFOF("Restart requested");
 668                         changelevel(mapname);
 669                         // let initialization continue, shutdown depends on it
 670                 }
 671         }
 672
 673         cvar = cvar_normal;
 674         cvar_string = cvar_string_normal;
 675         cvar_set = cvar_set_normal;
 676
 677         if(world_already_spawned)
 678                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 679         world_already_spawned = true;
 680
 681         delete_fn = remove_safely; // during spawning, watch what you remove!
 682
 683         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 684
 685         maxclients = 0;
 686         for (entity head = nextent(NULL); head; head = nextent(head))
 687         {
 688                 ++maxclients;
 689         }
 690
 691         // needs to be done so early because of the constants they create
 692         static_init();
 693
 694         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 695
 696         TemporaryDB = db_create();
 697
 698         // 0 normal
 699         lightstyle(0, "m");
 700
 701         // 1 FLICKER (first variety)
 702         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 703
 704         // 2 SLOW STRONG PULSE
 705         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 706
 707         // 3 CANDLE (first variety)
 708         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 709
 710         // 4 FAST STROBE
 711         lightstyle(4, "mamamamamama");
 712
 713         // 5 GENTLE PULSE 1
 714         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 715
 716         // 6 FLICKER (second variety)
 717         lightstyle(6, "nmonqnmomnmomomno");
 718
 719         // 7 CANDLE (second variety)
 720         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 721
 722         // 8 CANDLE (third variety)
 723         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 724
 725         // 9 SLOW STROBE (fourth variety)
 726         lightstyle(9, "aaaaaaaazzzzzzzz");
 727
 728         // 10 FLUORESCENT FLICKER
 729         lightstyle(10, "mmamammmmammamamaaamammma");
 730
 731         // 11 SLOW PULSE NOT FADE TO BLACK
 732         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 733
 734         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 735
 736         // 63 testing
 737         lightstyle(63, "a");
 738
 739         if(autocvar_g_campaign)
 740                 CampaignPreInit();
 741
 742         Map_MarkAsRecent(mapname);
 743
 744         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 745
 746         InitGameplayMode();
 747         static_init_late();
 748         static_init_precache();
 749         readlevelcvars();
 750         GrappleHookInit();
 751
 752     GameRules_limit_fallbacks();
 753
 754         if(warmup_limit == 0)
 755                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 756
 757         player_count = 0;
 758         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 759         if(bot_waypoints_for_items == 1)
 760                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 761                         bot_waypoints_for_items = 0;
 762
 763         precache();
 764
 765         WaypointSprite_Init();
 766
 767         GameLogInit(); // prepare everything
 768         // NOTE for matchid:
 769         // changing the logic generating it is okay. But:
 770         // it HAS to stay <= 64 chars
 771         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 772         if(autocvar_sv_eventlog)
 773         {
 774                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 775                 matchid = strzone(s);
 776
 777                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 778                 s = ":gameinfo:mutators:LIST";
 779
 780                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 781                 s = M_ARGV(0, string);
 782
 783                 // initialiation stuff, not good in the mutator system
 784                 if(!autocvar_g_use_ammunition)
 785                         s = strcat(s, ":no_use_ammunition");
 786
 787                 // initialiation stuff, not good in the mutator system
 788                 if(autocvar_g_pickup_items == 0)
 789                         s = strcat(s, ":no_pickup_items");
 790                 if(autocvar_g_pickup_items > 0)
 791                         s = strcat(s, ":pickup_items");
 792
 793                 // initialiation stuff, not good in the mutator system
 794                 if(autocvar_g_weaponarena != "0")
 795                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 796
 797                 // TODO to mutator system
 798                 if(autocvar_g_norecoil)
 799                         s = strcat(s, ":norecoil");
 800
 801                 // TODO to mutator system
 802                 if(autocvar_g_powerups == 0)
 803                         s = strcat(s, ":no_powerups");
 804                 if(autocvar_g_powerups > 0)
 805                         s = strcat(s, ":powerups");
 806
 807                 GameLogEcho(s);
 808                 GameLogEcho(":gameinfo:end");
 809         }
 810         else
 811                 matchid = strzone(ftos(random()));
 812
 813         cvar_set("nextmap", "");
 814
 815         SetDefaultAlpha();
 816
 817         if(autocvar_g_campaign)
 818                 CampaignPostInit();
 819
 820         Ban_LoadBans();
 821
 822         MapInfo_Enumerate();
 823         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 824
 825         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 826         {
 827                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 828                 if(fd != -1)
 829                 {
 830                         string s;
 831                         while((s = fgets(fd)))
 832                         {
 833                                 int l = tokenize_console(s);
 834                                 if(l < 2)
 835                                         continue;
 836                                 if(argv(0) == "cd")
 837                                 {
 838                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 839                                         LOG_INFO("  cdtrack ", argv(2));
 840                                 }
 841                                 else if(argv(0) == "fog")
 842                                 {
 843                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 844                                         LOG_INFO("  \"fog\" \"", s, "\"");
 845                                 }
 846                                 else if(argv(0) == "set")
 847                                 {
 848                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 849                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 850                                 }
 851                                 else if(argv(0) != "//")
 852                                 {
 853                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 854                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 855                                 }
 856                         }
 857                         fclose(fd);
 858                 }
 859         }
 860
 861         WeaponStats_Init();
 862
 863         Nagger_Init();
 864
 865         next_pingtime = time + 5;
 866
 867         detect_maptype();
 868
 869         // set up information replies for clients and server to use
 870         maplist_reply = strzone(getmaplist());
 871         lsmaps_reply = strzone(getlsmaps());
 872         monsterlist_reply = strzone(getmonsterlist());
 873         for(int i = 0; i < 10; ++i)
 874         {
 875                 string s = getrecords(i);
 876                 if (s)
 877                         records_reply[i] = strzone(s);
 878         }
 879         ladder_reply = strzone(getladder());
 880         rankings_reply = strzone(getrankings());
 881
 882         // begin other init
 883         ClientInit_Spawn();
 884         RandomSeed_Spawn();
 885         PingPLReport_Spawn();
 886
 887         CheatInit();
 888
 889         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 890
 891         // fill sv_curl_serverpackages from .serverpackage files
 892         if (autocvar_sv_curl_serverpackages_auto)
 893         {
 894                 string s = "csprogs-" WATERMARK ".txt";
 895                 // remove automatically managed files from the list to prevent duplicates
 896                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 897                 {
 898                         string pkg = argv(i);
 899                         if (startsWith(pkg, "csprogs-")) continue;
 900                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 901                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 902                         s = cons(s, pkg);
 903                 }
 904                 // add automatically managed files to the list
 905                 #define X(match) MACRO_BEGIN { \
 906                         int fd = search_begin(match, true, false); \
 907                         if (fd >= 0) \
 908                         { \
 909                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 910                                 { \
 911                                         s = cons(s, search_getfilename(fd, i)); \
 912                                 } \
 913                                 search_end(fd); \
 914                         } \
 915                 } MACRO_END
 916                 X("*-serverpackage.txt");
 917                 X("*.serverpackage");
 918                 #undef X
 919                 cvar_set("sv_curl_serverpackages", s);
 920         }
 921
 922         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 923         modname = "Xonotic";
 924         // physics/balance/config changes that count as mod
 925         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 926                 modname = cvar_string("g_mod_physics");
 927         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 928                 modname = cvar_string("g_mod_balance");
 929         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 930                 modname = cvar_string("g_mod_config");
 931         // extra mutators that deserve to count as mod
 932         MUTATOR_CALLHOOK(SetModname, modname);
 933         modname = M_ARGV(0, string);
 934
 935         // save it for later
 936         modname = strzone(modname);
 937
 938         WinningConditionHelper(this); // set worldstatus
 939
 940         world_initialized = 1;
 941 }
 942
 943 spawnfunc(light)
 944 {
 945         //makestatic (this); // Who the f___ did that?
 946         delete(this);
 947 }
 948
 949 string GetGametype()
 950 {
 951         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 952 }
 953
 954 string GetMapname()
 955 {
 956         return mapname;
 957 }
 958
 959 float Map_Count, Map_Current;
 960 string Map_Current_Name;
 961
 962 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 963 float GetMaplistPosition()
 964 {
 965         float pos, idx;
 966         string map;
 967
 968         map = GetMapname();
 969         idx = autocvar_g_maplist_index;
 970
 971         if(idx >= 0)
 972                 if(idx < Map_Count)
 973                         if(map == argv(idx))
 974                                 return idx;
 975
 976         for(pos = 0; pos < Map_Count; ++pos)
 977                 if(map == argv(pos))
 978                         return pos;
 979
 980         // resume normal maplist rotation if current map is not in g_maplist
 981         return idx;
 982 }
 983
 984 float MapHasRightSize(string map)
 985 {
 986         float fh;
 987         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 988         if(autocvar_g_maplist_check_waypoints)
 989         {
 990                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 991                 if(!fexists(strcat("maps/", map, ".waypoints")))
 992                 {
 993                         LOG_TRACE(": no waypoints");
 994                         return false;
 995                 }
 996                 LOG_TRACE(": has waypoints");
 997         }
 998
 999         // open map size restriction file
1000         LOG_TRACE("opensize "); LOG_TRACE(map);
1001         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1002         if(fh >= 0)
1003         {
1004                 float mapmin, mapmax;
1005                 LOG_TRACE(": ok, ");
1006                 mapmin = stof(fgets(fh));
1007                 mapmax = stof(fgets(fh));
1008                 fclose(fh);
1009                 if(player_count < mapmin)
1010                 {
1011                         LOG_TRACE("not enough");
1012                         return false;
1013                 }
1014                 if(player_count > mapmax)
1015                 {
1016                         LOG_TRACE("too many");
1017                         return false;
1018                 }
1019                 LOG_TRACE("right size");
1020                 return true;
1021         }
1022         LOG_TRACE(": not found");
1023         return true;
1024 }
1025
1026 string Map_Filename(float position)
1027 {
1028         return strcat("maps/", argv(position), ".bsp");
1029 }
1030
1031 void Map_MarkAsRecent(string m)
1032 {
1033         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1034 }
1035
1036 float Map_IsRecent(string m)
1037 {
1038         return strhasword(autocvar_g_maplist_mostrecent, m);
1039 }
1040
1041 float Map_Check(float position, float pass)
1042 {
1043         string filename;
1044         string map_next;
1045         map_next = argv(position);
1046         if(pass <= 1)
1047         {
1048                 if(Map_IsRecent(map_next))
1049                         return 0;
1050         }
1051         filename = Map_Filename(position);
1052         if(MapInfo_CheckMap(map_next))
1053         {
1054                 if(pass == 2)
1055                         return 1;
1056                 if(MapHasRightSize(map_next))
1057                         return 1;
1058                 return 0;
1059         }
1060         else
1061                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1062
1063         return 0;
1064 }
1065
1066 void Map_Goto_SetStr(string nextmapname)
1067 {
1068         if(getmapname_stored != "")
1069                 strunzone(getmapname_stored);
1070         if(nextmapname == "")
1071                 getmapname_stored = "";
1072         else
1073                 getmapname_stored = strzone(nextmapname);
1074 }
1075
1076 void Map_Goto_SetFloat(float position)
1077 {
1078         cvar_set("g_maplist_index", ftos(position));
1079         Map_Goto_SetStr(argv(position));
1080 }
1081
1082 void Map_Goto(float reinit)
1083 {
1084         MapInfo_LoadMap(getmapname_stored, reinit);
1085 }
1086
1087 // return codes of map selectors:
1088 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1089 //   -2 = permanent failure
1090 float() MaplistMethod_Iterate = // usual method
1091 {
1092         float pass, i;
1093
1094         LOG_TRACE("Trying MaplistMethod_Iterate");
1095
1096         for(pass = 1; pass <= 2; ++pass)
1097         {
1098                 for(i = 1; i < Map_Count; ++i)
1099                 {
1100                         float mapindex;
1101                         mapindex = (i + Map_Current) % Map_Count;
1102                         if(Map_Check(mapindex, pass))
1103                                 return mapindex;
1104                 }
1105         }
1106         return -1;
1107 }
1108
1109 float() MaplistMethod_Repeat = // fallback method
1110 {
1111         LOG_TRACE("Trying MaplistMethod_Repeat");
1112
1113         if(Map_Check(Map_Current, 2))
1114                 return Map_Current;
1115         return -2;
1116 }
1117
1118 float() MaplistMethod_Random = // random map selection
1119 {
1120         float i, imax;
1121
1122         LOG_TRACE("Trying MaplistMethod_Random");
1123
1124         imax = 42;
1125
1126         for(i = 0; i <= imax; ++i)
1127         {
1128                 float mapindex;
1129                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1130                 if(Map_Check(mapindex, 1))
1131                         return mapindex;
1132         }
1133         return -1;
1134 }
1135
1136 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1137 // the exponent sets a bias on the map selection:
1138 // the higher the exponent, the less likely "shortly repeated" same maps are
1139 {
1140         float i, j, imax, insertpos;
1141
1142         LOG_TRACE("Trying MaplistMethod_Shuffle");
1143
1144         imax = 42;
1145
1146         for(i = 0; i <= imax; ++i)
1147         {
1148                 string newlist;
1149
1150                 // now reinsert this at another position
1151                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1152                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1153                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1154                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1155
1156                 // insert the current map there
1157                 newlist = "";
1158                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1159                         newlist = strcat(newlist, " ", argv(j));
1160                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1161                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1162                         newlist = strcat(newlist, " ", argv(j));
1163                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1164                 cvar_set("g_maplist", newlist);
1165                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1166
1167                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1168                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1169                 if(Map_Check(Map_Current, 1))
1170                         return Map_Current;
1171         }
1172         return -1;
1173 }
1174
1175 void Maplist_Init()
1176 {
1177         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1178         float i;
1179         for (i = 0; i < Map_Count; ++i)
1180                 if (Map_Check(i, 2))
1181                         break;
1182         if (i == Map_Count)
1183         {
1184                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1185                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1186                 if(autocvar_g_maplist_shuffle)
1187                         ShuffleMaplist();
1188                 localcmd("\nmenu_cmd sync\n");
1189                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1190         }
1191         if(Map_Count == 0)
1192                 error("empty maplist, cannot select a new map");
1193         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1194
1195         if(Map_Current_Name)
1196                 strunzone(Map_Current_Name);
1197         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1198         // this may or may not be correct, but who cares, in the worst case a map
1199         // isn't chosen in the first pass that should have been
1200 }
1201
1202 string GetNextMap()
1203 {
1204         float nextMap;
1205
1206         Maplist_Init();
1207         nextMap = -1;
1208
1209         if(nextMap == -1)
1210                 if(autocvar_g_maplist_shuffle > 0)
1211                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1212
1213         if(nextMap == -1)
1214                 if(autocvar_g_maplist_selectrandom)
1215                         nextMap = MaplistMethod_Random();
1216
1217         if(nextMap == -1)
1218                 nextMap = MaplistMethod_Iterate();
1219
1220         if(nextMap == -1)
1221                 nextMap = MaplistMethod_Repeat();
1222
1223         if(nextMap >= 0)
1224         {
1225                 Map_Goto_SetFloat(nextMap);
1226                 return getmapname_stored;
1227         }
1228
1229         return "";
1230 }
1231
1232 float DoNextMapOverride(float reinit)
1233 {
1234         if(autocvar_g_campaign)
1235         {
1236                 CampaignPostIntermission();
1237                 alreadychangedlevel = true;
1238                 return true;
1239         }
1240         if(autocvar_quit_when_empty)
1241         {
1242                 if(player_count <= currentbots)
1243                 {
1244                         localcmd("quit\n");
1245                         alreadychangedlevel = true;
1246                         return true;
1247                 }
1248         }
1249         if(autocvar_quit_and_redirect != "")
1250         {
1251                 redirection_target = strzone(autocvar_quit_and_redirect);
1252                 alreadychangedlevel = true;
1253                 return true;
1254         }
1255         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1256         {
1257                 localcmd("restart\n");
1258                 alreadychangedlevel = true;
1259                 return true;
1260         }
1261         if(autocvar_nextmap != "")
1262         {
1263                 string m;
1264                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1265                 cvar_set("nextmap",m);
1266
1267                 if(!m || gametypevote)
1268                         return false;
1269                 if(autocvar_sv_vote_gametype)
1270                 {
1271                         Map_Goto_SetStr(m);
1272                         return false;
1273                 }
1274
1275                 if(MapInfo_CheckMap(m))
1276                 {
1277                         Map_Goto_SetStr(m);
1278                         Map_Goto(reinit);
1279                         alreadychangedlevel = true;
1280                         return true;
1281                 }
1282         }
1283         if(!reinit && autocvar_lastlevel)
1284         {
1285                 cvar_settemp_restore();
1286                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1287                 alreadychangedlevel = true;
1288                 return true;
1289         }
1290         return false;
1291 }
1292
1293 void GotoNextMap(float reinit)
1294 {
1295         //string nextmap;
1296         //float n, nummaps;
1297         //string s;
1298         if (alreadychangedlevel)
1299                 return;
1300         alreadychangedlevel = true;
1301
1302         string nextMap;
1303
1304         nextMap = GetNextMap();
1305         if(nextMap == "")
1306                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1307         Map_Goto(reinit);
1308 }
1309
1310
1311 /*
1312 ============
1313 IntermissionThink
1314
1315 When the player presses attack or jump, change to the next level
1316 ============
1317 */
1318 .float autoscreenshot;
1319 void IntermissionThink(entity this)
1320 {
1321         FixIntermissionClient(this);
1322
1323         float server_screenshot = (autocvar_sv_autoscreenshot && CS(this).cvar_cl_autoscreenshot);
1324         float client_screenshot = (CS(this).cvar_cl_autoscreenshot == 2);
1325
1326         if( (server_screenshot || client_screenshot)
1327                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1328         {
1329                 this.autoscreenshot = -1;
1330                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1331                 return;
1332         }
1333
1334         if (time < intermission_exittime)
1335                 return;
1336
1337         if(!mapvote_initialized)
1338                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1339                         return;
1340
1341         MapVote_Start();
1342 }
1343
1344 /*
1345 ============
1346 FindIntermission
1347
1348 Returns the entity to view from
1349 ============
1350 */
1351 /*
1352 entity FindIntermission()
1353 {
1354         local   entity spot;
1355         local   float cyc;
1356
1357 // look for info_intermission first
1358         spot = find(NULL, classname, "info_intermission");
1359         if (spot)
1360         {       // pick a random one
1361                 cyc = random() * 4;
1362                 while (cyc > 1)
1363                 {
1364                         spot = find(spot, classname, "info_intermission");
1365                         if (!spot)
1366                                 spot = find(spot, classname, "info_intermission");
1367                         cyc = cyc - 1;
1368                 }
1369                 return spot;
1370         }
1371
1372 // then look for the start position
1373         spot = find(NULL, classname, "info_player_start");
1374         if (spot)
1375                 return spot;
1376
1377 // testinfo_player_start is only found in regioned levels
1378         spot = find(NULL, classname, "testplayerstart");
1379         if (spot)
1380                 return spot;
1381
1382 // then look for the start position
1383         spot = find(NULL, classname, "info_player_deathmatch");
1384         if (spot)
1385                 return spot;
1386
1387         //objerror ("FindIntermission: no spot");
1388         return NULL;
1389 }
1390 */
1391
1392 /*
1393 ===============================================================================
1394
1395 RULES
1396
1397 ===============================================================================
1398 */
1399
1400 void DumpStats(float final)
1401 {
1402         float file;
1403         string s;
1404         float to_console;
1405         float to_eventlog;
1406         float to_file;
1407         float i;
1408
1409         to_console = autocvar_sv_logscores_console;
1410         to_eventlog = autocvar_sv_eventlog;
1411         to_file = autocvar_sv_logscores_file;
1412
1413         if(!final)
1414         {
1415                 to_console = true; // always print printstats replies
1416                 to_eventlog = false; // but never print them to the event log
1417         }
1418
1419         if(to_eventlog)
1420                 if(autocvar_sv_eventlog_console)
1421                         to_console = false; // otherwise we get the output twice
1422
1423         if(final)
1424                 s = ":scores:";
1425         else
1426                 s = ":status:";
1427         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1428
1429         if(to_console)
1430                 LOG_INFO(s);
1431         if(to_eventlog)
1432                 GameLogEcho(s);
1433
1434         file = -1;
1435         if(to_file)
1436         {
1437                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1438                 if(file == -1)
1439                         to_file = false;
1440                 else
1441                         fputs(file, strcat(s, "\n"));
1442         }
1443
1444         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1445         if(to_console)
1446                 LOG_INFO(s);
1447         if(to_eventlog)
1448                 GameLogEcho(s);
1449         if(to_file)
1450                 fputs(file, strcat(s, "\n"));
1451
1452         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1453                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1454                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1455                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1456                         s = strcat(s, ftos(it.team), ":");
1457                 else
1458                         s = strcat(s, "spectator:");
1459
1460                 if(to_console)
1461                         LOG_INFO(s, playername(it, false));
1462                 if(to_eventlog)
1463                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1464                 if(to_file)
1465                         fputs(file, strcat(s, playername(it, false), "\n"));
1466         });
1467
1468         if(teamplay)
1469         {
1470                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1471                 if(to_console)
1472                         LOG_INFO(s);
1473                 if(to_eventlog)
1474                         GameLogEcho(s);
1475                 if(to_file)
1476                         fputs(file, strcat(s, "\n"));
1477
1478                 for(i = 1; i < 16; ++i)
1479                 {
1480                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1481                         s = strcat(s, ":", ftos(i));
1482                         if(to_console)
1483                                 LOG_INFO(s);
1484                         if(to_eventlog)
1485                                 GameLogEcho(s);
1486                         if(to_file)
1487                                 fputs(file, strcat(s, "\n"));
1488                 }
1489         }
1490
1491         if(to_console)
1492                 LOG_INFO(":end");
1493         if(to_eventlog)
1494                 GameLogEcho(":end");
1495         if(to_file)
1496         {
1497                 fputs(file, ":end\n");
1498                 fclose(file);
1499         }
1500 }
1501
1502 void FixIntermissionClient(entity e)
1503 {
1504         if(!e.autoscreenshot) // initial call
1505         {
1506                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1507                 e.health = -2342;
1508                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1509                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1510                 {
1511                     .entity weaponentity = weaponentities[slot];
1512                         if(e.(weaponentity))
1513                         {
1514                                 e.(weaponentity).effects = EF_NODRAW;
1515                                 if (e.(weaponentity).weaponchild)
1516                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1517                         }
1518                 }
1519                 if(IS_REAL_CLIENT(e))
1520                 {
1521                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1522                         RandomSelection_Init();
1523                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, {
1524                                 RandomSelection_AddString(it, 1, 1);
1525                         });
1526                         if (RandomSelection_chosen_string != "")
1527                         {
1528                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1529                         }
1530                         msg_entity = e;
1531                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1532                 }
1533         }
1534 }
1535
1536 /*
1537 go to the next level for deathmatch
1538 only called if a time or frag limit has expired
1539 */
1540 void NextLevel()
1541 {
1542         game_stopped = true;
1543         intermission_running = 1; // game over
1544
1545         // enforce a wait time before allowing changelevel
1546         if(player_count > 0)
1547                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1548         else
1549                 intermission_exittime = -1;
1550
1551         /*
1552         WriteByte (MSG_ALL, SVC_CDTRACK);
1553         WriteByte (MSG_ALL, 3);
1554         WriteByte (MSG_ALL, 3);
1555         // done in FixIntermission
1556         */
1557
1558         //pos = FindIntermission ();
1559
1560         VoteReset();
1561
1562         DumpStats(true);
1563
1564         // send statistics
1565         PlayerStats_GameReport(true);
1566         WeaponStats_Shutdown();
1567
1568         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1569
1570         if(autocvar_sv_eventlog)
1571                 GameLogEcho(":gameover");
1572
1573         GameLogClose();
1574
1575         FOREACH_CLIENT(IS_PLAYER(it), {
1576                 FixIntermissionClient(it);
1577                 if(it.winning)
1578                         bprint(playername(it, false), " ^7wins.\n");
1579         });
1580
1581         target_music_kill();
1582
1583         if(autocvar_g_campaign)
1584                 CampaignPreIntermission();
1585
1586         MUTATOR_CALLHOOK(MatchEnd);
1587
1588         localcmd("\nsv_hook_gameend\n");
1589 }
1590
1591
1592 float InitiateSuddenDeath()
1593 {
1594         // Check first whether normal overtimes could be added before initiating suddendeath mode
1595         // - for this timelimit_overtime needs to be >0 of course
1596         // - also check the winning condition calculated in the previous frame and only add normal overtime
1597         //   again, if at the point at which timelimit would be extended again, still no winner was found
1598         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1599         {
1600                 return 1; // need to call InitiateOvertime later
1601         }
1602         else
1603         {
1604                 if(!checkrules_suddendeathend)
1605                 {
1606                         if(autocvar_g_campaign)
1607                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1608                         else
1609                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1610                         if(g_race && !g_race_qualifying)
1611                                 race_StartCompleting();
1612                 }
1613                 return 0;
1614         }
1615 }
1616
1617 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1618 {
1619         ++checkrules_overtimesadded;
1620         //add one more overtime by simply extending the timelimit
1621         float tl;
1622         tl = autocvar_timelimit;
1623         tl += autocvar_timelimit_overtime;
1624         cvar_set("timelimit", ftos(tl));
1625
1626         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1627 }
1628
1629 float GetWinningCode(float fraglimitreached, float equality)
1630 {
1631         if(autocvar_g_campaign == 1)
1632                 if(fraglimitreached)
1633                         return WINNING_YES;
1634                 else
1635                         return WINNING_NO;
1636
1637         else
1638                 if(equality)
1639                         if(fraglimitreached)
1640                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1641                         else
1642                                 return WINNING_NEVER;
1643                 else
1644                         if(fraglimitreached)
1645                                 return WINNING_YES;
1646                         else
1647                                 return WINNING_NO;
1648 }
1649
1650 // set the .winning flag for exactly those players with a given field value
1651 void SetWinners(.float field, float value)
1652 {
1653         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1654 }
1655
1656 // set the .winning flag for those players with a given field value
1657 void AddWinners(.float field, float value)
1658 {
1659         FOREACH_CLIENT(IS_PLAYER(it), {
1660                 if(it.(field) == value)
1661                         it.winning = 1;
1662         });
1663 }
1664
1665 // clear the .winning flags
1666 void ClearWinners()
1667 {
1668         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1669 }
1670
1671 void ShuffleMaplist()
1672 {
1673         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1674 }
1675
1676 float leaderfrags;
1677 float WinningCondition_Scores(float limit, float leadlimit)
1678 {
1679         float limitreached;
1680
1681         // TODO make everything use THIS winning condition (except LMS)
1682         WinningConditionHelper(NULL);
1683
1684         if(teamplay)
1685         {
1686                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1687                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1688                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1689                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1690         }
1691
1692         ClearWinners();
1693         if(WinningConditionHelper_winner)
1694                 WinningConditionHelper_winner.winning = 1;
1695         if(WinningConditionHelper_winnerteam >= 0)
1696                 SetWinners(team, WinningConditionHelper_winnerteam);
1697
1698         if(WinningConditionHelper_lowerisbetter)
1699         {
1700                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1701                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1702                 limit = -limit;
1703         }
1704
1705         if(WinningConditionHelper_zeroisworst)
1706                 leadlimit = 0; // not supported in this mode
1707
1708         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1709         // these modes always score in increments of 1, thus this makes sense
1710         {
1711                 if(leaderfrags != WinningConditionHelper_topscore)
1712                 {
1713                         leaderfrags = WinningConditionHelper_topscore;
1714
1715                         if (limit)
1716                         if (leaderfrags == limit - 1)
1717                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1718                         else if (leaderfrags == limit - 2)
1719                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1720                         else if (leaderfrags == limit - 3)
1721                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1722                 }
1723         }
1724
1725         limitreached = false;
1726         if(limit)
1727                 if(WinningConditionHelper_topscore >= limit)
1728                         limitreached = true;
1729         if(leadlimit)
1730         {
1731                 float leadlimitreached;
1732                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1733                 if(autocvar_leadlimit_and_fraglimit)
1734                         limitreached = (limitreached && leadlimitreached);
1735                 else
1736                         limitreached = (limitreached || leadlimitreached);
1737         }
1738
1739         if(limit)
1740                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1741
1742         return GetWinningCode(
1743                 WinningConditionHelper_topscore && limitreached,
1744                 WinningConditionHelper_equality
1745         );
1746 }
1747
1748 float WinningCondition_RanOutOfSpawns()
1749 {
1750         if(have_team_spawns <= 0)
1751                 return WINNING_NO;
1752
1753         if(!autocvar_g_spawn_useallspawns)
1754                 return WINNING_NO;
1755
1756         if(!some_spawn_has_been_used)
1757                 return WINNING_NO;
1758
1759         team1_score = team2_score = team3_score = team4_score = 0;
1760
1761         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), {
1762                 switch(it.team)
1763                 {
1764                         case NUM_TEAM_1: team1_score = 1; break;
1765                         case NUM_TEAM_2: team2_score = 1; break;
1766                         case NUM_TEAM_3: team3_score = 1; break;
1767                         case NUM_TEAM_4: team4_score = 1; break;
1768                 }
1769         });
1770
1771         IL_EACH(g_spawnpoints, true,
1772         {
1773                 switch(it.team)
1774                 {
1775                         case NUM_TEAM_1: team1_score = 1; break;
1776                         case NUM_TEAM_2: team2_score = 1; break;
1777                         case NUM_TEAM_3: team3_score = 1; break;
1778                         case NUM_TEAM_4: team4_score = 1; break;
1779                 }
1780         });
1781
1782         ClearWinners();
1783         if(team1_score + team2_score + team3_score + team4_score == 0)
1784         {
1785                 checkrules_equality = true;
1786                 return WINNING_YES;
1787         }
1788         else if(team1_score + team2_score + team3_score + team4_score == 1)
1789         {
1790                 float t, i;
1791                 if(team1_score)
1792                         t = NUM_TEAM_1;
1793                 else if(team2_score)
1794                         t = NUM_TEAM_2;
1795                 else if(team3_score)
1796                         t = NUM_TEAM_3;
1797                 else // if(team4_score)
1798                         t = NUM_TEAM_4;
1799                 CheckAllowedTeams(NULL);
1800                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1801                 {
1802                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1803                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1804                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1805                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1806                 }
1807
1808                 AddWinners(team, t);
1809                 return WINNING_YES;
1810         }
1811         else
1812                 return WINNING_NO;
1813 }
1814
1815 /*
1816 ============
1817 CheckRules_World
1818
1819 Exit deathmatch games upon conditions
1820 ============
1821 */
1822 void CheckRules_World()
1823 {
1824         float timelimit;
1825         float fraglimit;
1826         float leadlimit;
1827
1828         VoteThink();
1829         MapVote_Think();
1830
1831         SetDefaultAlpha();
1832
1833         if (intermission_running) // someone else quit the game already
1834         {
1835                 if(player_count == 0) // Nobody there? Then let's go to the next map
1836                         MapVote_Start();
1837                         // this will actually check the player count in the next frame
1838                         // again, but this shouldn't hurt
1839                 return;
1840         }
1841
1842         timelimit = autocvar_timelimit * 60;
1843         fraglimit = autocvar_fraglimit;
1844         leadlimit = autocvar_leadlimit;
1845
1846         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1847         {
1848                 if(timelimit > 0)
1849                         timelimit = 0; // timelimit is not made for warmup
1850                 if(fraglimit > 0)
1851                         fraglimit = 0; // no fraglimit for now
1852                 leadlimit = 0; // no leadlimit for now
1853         }
1854
1855         if(timelimit > 0)
1856         {
1857                 timelimit += game_starttime;
1858         }
1859         else if (timelimit < 0)
1860         {
1861                 // endmatch
1862                 NextLevel();
1863                 return;
1864         }
1865
1866         float wantovertime;
1867         wantovertime = 0;
1868
1869         if(timelimit > game_starttime)
1870                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1871         else
1872                 game_completion_ratio = 0;
1873
1874         if(checkrules_suddendeathend)
1875         {
1876                 if(!checkrules_suddendeathwarning)
1877                 {
1878                         checkrules_suddendeathwarning = true;
1879                         if(g_race && !g_race_qualifying)
1880                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1881                         else
1882                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1883                 }
1884         }
1885         else
1886         {
1887                 if (timelimit && time >= timelimit)
1888                 {
1889                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1890                         {
1891                                 float totalplayers;
1892                                 float playerswithlaps;
1893                                 float readyplayers;
1894                                 totalplayers = playerswithlaps = readyplayers = 0;
1895                                 FOREACH_CLIENT(IS_PLAYER(it), {
1896                                         ++totalplayers;
1897                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1898                                                 ++playerswithlaps;
1899                                         if(it.ready)
1900                                                 ++readyplayers;
1901                                 });
1902
1903                                 // at least 2 of the players have completed a lap: start the RACE
1904                                 // otherwise, the players should end the qualifying on their own
1905                                 if(readyplayers || playerswithlaps >= 2)
1906                                 {
1907                                         checkrules_suddendeathend = 0;
1908                                         ReadyRestart(); // go to race
1909                                         return;
1910                                 }
1911                                 else
1912                                         wantovertime |= InitiateSuddenDeath();
1913                         }
1914                         else
1915                                 wantovertime |= InitiateSuddenDeath();
1916                 }
1917         }
1918
1919         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1920         {
1921                 NextLevel();
1922                 return;
1923         }
1924
1925         int checkrules_status = WinningCondition_RanOutOfSpawns();
1926         if(checkrules_status == WINNING_YES)
1927                 bprint("Hey! Someone ran out of spawns!\n");
1928         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1929                 checkrules_status = M_ARGV(0, float);
1930         else
1931                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1932
1933         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1934         {
1935                 checkrules_status = WINNING_NEVER;
1936                 checkrules_overtimesadded = -1;
1937                 wantovertime |= InitiateSuddenDeath();
1938         }
1939
1940         if(checkrules_status == WINNING_NEVER)
1941                 // equality cases! Nobody wins if the overtime ends in a draw.
1942                 ClearWinners();
1943
1944         if(wantovertime)
1945         {
1946                 if(checkrules_status == WINNING_NEVER)
1947                         InitiateOvertime();
1948                 else
1949                         checkrules_status = WINNING_YES;
1950         }
1951
1952         if(checkrules_suddendeathend)
1953                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1954                         checkrules_status = WINNING_YES;
1955
1956         if(checkrules_status == WINNING_YES)
1957         {
1958                 //print("WINNING\n");
1959                 NextLevel();
1960         }
1961 }
1962
1963 string GotoMap(string m)
1964 {
1965         m = GameTypeVote_MapInfo_FixName(m);
1966         if (!m)
1967                 return "The map you suggested is not available on this server.";
1968         if (!autocvar_sv_vote_gametype)
1969         if(!MapInfo_CheckMap(m))
1970                 return "The map you suggested does not support the current game mode.";
1971         cvar_set("nextmap", m);
1972         cvar_set("timelimit", "-1");
1973         if(mapvote_initialized || alreadychangedlevel)
1974         {
1975                 if(DoNextMapOverride(0))
1976                         return "Map switch initiated.";
1977                 else
1978                         return "Hm... no. For some reason I like THIS map more.";
1979         }
1980         else
1981                 return "Map switch will happen after scoreboard.";
1982 }
1983
1984 bool autocvar_sv_gameplayfix_multiplethinksperframe;
1985 void RunThink(entity this)
1986 {
1987         // don't let things stay in the past.
1988         // it is possible to start that way by a trigger with a local time.
1989         if(this.nextthink <= 0 || this.nextthink > time + frametime)
1990                 return;
1991
1992         float oldtime = time; // do we need to save this?
1993
1994         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
1995         {
1996                 time = max(oldtime, this.nextthink);
1997                 this.nextthink = 0;
1998
1999                 if(getthink(this))
2000                         getthink(this)(this);
2001                 // mods often set nextthink to time to cause a think every frame,
2002                 // we don't want to loop in that case, so exit if the new nextthink is
2003                 // <= the time the qc was told, also exit if it is past the end of the
2004                 // frame
2005                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2006                         break;
2007         }
2008
2009         time = oldtime;
2010 }
2011
2012 bool autocvar_sv_freezenonclients;
2013 bool autocvar_sv_gameplayfix_delayprojectiles;
2014 void Physics_Frame()
2015 {
2016         if(autocvar_sv_freezenonclients)
2017                 return;
2018
2019         FOREACH_ENTITY_FLOAT(pure_data, false,
2020         {
2021                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2022                         continue;
2023
2024                 //set_movetype(it, it.move_movetype);
2025                 // inline the set_movetype function, since this is called a lot
2026                 it.movetype = (it.move_qcphysics) ? MOVETYPE_NONE : it.move_movetype;
2027
2028                 if(it.move_movetype == MOVETYPE_NONE)
2029                         continue;
2030
2031                 if(it.move_qcphysics)
2032                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2033
2034                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2035                 {
2036                         // handle thinking here
2037                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2038                                 RunThink(it);
2039                 }
2040         });
2041
2042         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2043                 return;
2044
2045         FOREACH_ENTITY_FLOAT(move_qcphysics, true,
2046         {
2047                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2048                         continue;
2049                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2050         });
2051 }
2052
2053 void systems_update();
2054 void EndFrame()
2055 {
2056         anticheat_endframe();
2057
2058         Physics_Frame();
2059
2060         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2061                 entity e = IS_SPEC(it) ? it.enemy : it;
2062                 if (e.typehitsound) {
2063                         it.typehit_time = time;
2064                 } else if (e.killsound) {
2065                         it.kill_time = time;
2066                 } else if (e.damage_dealt) {
2067                         it.hit_time = time;
2068                         it.damage_dealt_total += ceil(e.damage_dealt);
2069                 }
2070         });
2071         // add 1 frametime because after this, engine SV_Physics
2072         // increases time by a frametime and then networks the frame
2073         // add another frametime because client shows everything with
2074         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2075         // needed!
2076         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2077         FOREACH_CLIENT(true, {
2078                 it.typehitsound = false;
2079                 it.damage_dealt = 0;
2080                 it.killsound = false;
2081                 antilag_record(it, CS(it), altime);
2082         });
2083         IL_EACH(g_monsters, true,
2084         {
2085                 antilag_record(it, it, altime);
2086         });
2087         systems_update();
2088         IL_ENDFRAME();
2089 }
2090
2091
2092 /*
2093  * RedirectionThink:
2094  * returns true if redirecting
2095  */
2096 float redirection_timeout;
2097 float redirection_nextthink;
2098 float RedirectionThink()
2099 {
2100         float clients_found;
2101
2102         if(redirection_target == "")
2103                 return false;
2104
2105         if(!redirection_timeout)
2106         {
2107                 cvar_set("sv_public", "-2");
2108                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2109                 if(redirection_target == "self")
2110                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2111                 else
2112                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2113         }
2114
2115         if(time < redirection_nextthink)
2116                 return true;
2117
2118         redirection_nextthink = time + 1;
2119
2120         clients_found = 0;
2121         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2122                 // TODO add timer
2123                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2124                 if(redirection_target == "self")
2125                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2126                 else
2127                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2128                 ++clients_found;
2129         });
2130
2131         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2132
2133         if(time > redirection_timeout || clients_found == 0)
2134                 localcmd("\nwait; wait; wait; quit\n");
2135
2136         return true;
2137 }
2138
2139 void TargetMusic_RestoreGame();
2140 void RestoreGame()
2141 {
2142         // Loaded from a save game
2143         // some things then break, so let's work around them...
2144
2145         // Progs DB (capture records)
2146         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2147
2148         // Mapinfo
2149         MapInfo_Shutdown();
2150         MapInfo_Enumerate();
2151         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2152         WeaponStats_Init();
2153
2154         TargetMusic_RestoreGame();
2155 }
2156
2157 void Shutdown()
2158 {
2159         game_stopped = 2;
2160
2161         if(world_initialized > 0)
2162         {
2163                 world_initialized = 0;
2164                 LOG_TRACE("Saving persistent data...");
2165                 Ban_SaveBans();
2166
2167                 // playerstats with unfinished match
2168                 PlayerStats_GameReport(false);
2169
2170                 if(!cheatcount_total)
2171                 {
2172                         if(autocvar_sv_db_saveasdump)
2173                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2174                         else
2175                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2176                 }
2177                 if(autocvar_developer)
2178                 {
2179                         if(autocvar_sv_db_saveasdump)
2180                                 db_dump(TemporaryDB, "server-temp.db");
2181                         else
2182                                 db_save(TemporaryDB, "server-temp.db");
2183                 }
2184                 CheatShutdown(); // must be after cheatcount check
2185                 db_close(ServerProgsDB);
2186                 db_close(TemporaryDB);
2187                 LOG_TRACE("Saving persistent data... done!");
2188                 // tell the bot system the game is ending now
2189                 bot_endgame();
2190
2191                 WeaponStats_Shutdown();
2192                 MapInfo_Shutdown();
2193         }
2194         else if(world_initialized == 0)
2195         {
2196                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2197         }
2198         else
2199         {
2200                 __init_dedicated_server_shutdown();
2201         }
2202 }