qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include <server/mutators/_mod.qh>
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "scores_rules.qh"
  20 #include "teamplay.qh"
  21 #include "weapons/weaponstats.qh"
  22 #include "../common/constants.qh"
  23 #include <common/net_linked.qh>
  24 #include "../common/deathtypes/all.qh"
  25 #include "../common/gamemodes/sv_rules.qh"
  26 #include "../common/mapinfo.qh"
  27 #include "../common/monsters/_mod.qh"
  28 #include "../common/monsters/sv_monsters.qh"
  29 #include "../common/vehicles/all.qh"
  30 #include "../common/notifications/all.qh"
  31 #include "../common/physics/player.qh"
  32 #include "../common/playerstats.qh"
  33 #include "../common/stats.qh"
  34 #include "../common/teams.qh"
  35 #include "../common/mapobjects/trigger/secret.qh"
  36 #include "../common/mapobjects/target/music.qh"
  37 #include "../common/util.qh"
  38 #include "../common/items/_mod.qh"
  39 #include <common/weapons/_all.qh>
  40 #include "../common/state.qh"
  41
  42 const float LATENCY_THINKRATE = 10;
  43 .float latency_sum;
  44 .float latency_cnt;
  45 .float latency_time;
  46 entity pingplreport;
  47 void PingPLReport_Think(entity this)
  48 {
  49         float delta;
  50         entity e;
  51
  52         delta = 3 / maxclients;
  53         if(delta < sys_frametime)
  54                 delta = 0;
  55         this.nextthink = time + delta;
  56
  57         e = edict_num(this.cnt + 1);
  58         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  59         {
  60                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  61                 WriteByte(MSG_BROADCAST, this.cnt);
  62                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
  63                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  64                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  65
  66                 // record latency times for clients throughout the match so we can report it to playerstats
  67                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  68                 {
  69                         CS(e).latency_sum += CS(e).ping;
  70                         CS(e).latency_cnt += 1;
  71                         CS(e).latency_time = time;
  72                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  73                 }
  74         }
  75         else
  76         {
  77                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  78                 WriteByte(MSG_BROADCAST, this.cnt);
  79                 WriteShort(MSG_BROADCAST, 0);
  80                 WriteByte(MSG_BROADCAST, 0);
  81                 WriteByte(MSG_BROADCAST, 0);
  82         }
  83         this.cnt = (this.cnt + 1) % maxclients;
  84 }
  85 void PingPLReport_Spawn()
  86 {
  87         pingplreport = new_pure(pingplreport);
  88         setthink(pingplreport, PingPLReport_Think);
  89         pingplreport.nextthink = time;
  90 }
  91
  92 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  93 string redirection_target;
  94 float world_initialized;
  95
  96 void SetDefaultAlpha()
  97 {
  98         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
  99         {
 100                 default_player_alpha = autocvar_g_player_alpha;
 101                 if(default_player_alpha == 0)
 102                         default_player_alpha = 1;
 103                 default_weapon_alpha = default_player_alpha;
 104         }
 105 }
 106
 107 void GotoFirstMap(entity this)
 108 {
 109         float n;
 110         if(autocvar__sv_init)
 111         {
 112                 // cvar_set("_sv_init", "0");
 113                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 114                 // to this "init" map on a dedicated server will cause no permanent
 115                 // harm
 116                 if(autocvar_g_maplist_shuffle)
 117                         ShuffleMaplist();
 118                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 119                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 120
 121                 MapInfo_Enumerate();
 122                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 123
 124                 if(!DoNextMapOverride(1))
 125                         GotoNextMap(1);
 126
 127                 return;
 128         }
 129
 130         if(time < 5)
 131         {
 132                 this.nextthink = time;
 133         }
 134         else
 135         {
 136                 this.nextthink = time + 1;
 137                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 138         }
 139 }
 140
 141 void cvar_changes_init()
 142 {
 143         float h;
 144         string k, v, d;
 145         float n, i, adding, pureadding;
 146
 147         strfree(cvar_changes);
 148         strfree(cvar_purechanges);
 149         cvar_purechanges_count = 0;
 150
 151         h = buf_create();
 152         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 153         n = buf_getsize(h);
 154
 155         adding = true;
 156         pureadding = true;
 157
 158         for(i = 0; i < n; ++i)
 159         {
 160                 k = bufstr_get(h, i);
 161
 162 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 163 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 164 #define BADCVAR(p) if(k == p) continue
 165
 166                 // general excludes and namespaces for server admin used cvars
 167                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 168
 169                 // internal
 170                 BADPREFIX("csqc_");
 171                 BADPREFIX("cvar_check_");
 172                 BADCVAR("gamecfg");
 173                 BADCVAR("g_configversion");
 174                 BADCVAR("halflifebsp");
 175                 BADCVAR("sv_mapformat_is_quake2");
 176                 BADCVAR("sv_mapformat_is_quake3");
 177                 BADPREFIX("sv_world");
 178
 179                 // client
 180                 BADPREFIX("chase_");
 181                 BADPREFIX("cl_");
 182                 BADPREFIX("con_");
 183                 BADPREFIX("scoreboard_");
 184                 BADPREFIX("g_campaign");
 185                 BADPREFIX("g_waypointsprite_");
 186                 BADPREFIX("gl_");
 187                 BADPREFIX("joy");
 188                 BADPREFIX("hud_");
 189                 BADPREFIX("m_");
 190                 BADPREFIX("menu_");
 191                 BADPREFIX("net_slist_");
 192                 BADPREFIX("r_");
 193                 BADPREFIX("sbar_");
 194                 BADPREFIX("scr_");
 195                 BADPREFIX("snd_");
 196                 BADPREFIX("show");
 197                 BADPREFIX("sensitivity");
 198                 BADPREFIX("userbind");
 199                 BADPREFIX("v_");
 200                 BADPREFIX("vid_");
 201                 BADPREFIX("crosshair");
 202                 BADCVAR("mod_q3bsp_lightmapmergepower");
 203                 BADCVAR("mod_q3bsp_nolightmaps");
 204                 BADCVAR("fov");
 205                 BADCVAR("mastervolume");
 206                 BADCVAR("volume");
 207                 BADCVAR("bgmvolume");
 208                 BADCVAR("in_pitch_min");
 209                 BADCVAR("in_pitch_max");
 210
 211                 // private
 212                 BADCVAR("developer");
 213                 BADCVAR("log_dest_udp");
 214                 BADCVAR("net_address");
 215                 BADCVAR("net_address_ipv6");
 216                 BADCVAR("port");
 217                 BADCVAR("savedgamecfg");
 218                 BADCVAR("serverconfig");
 219                 BADCVAR("sv_autoscreenshot");
 220                 BADCVAR("sv_heartbeatperiod");
 221                 BADCVAR("sv_vote_master_password");
 222                 BADCVAR("sys_colortranslation");
 223                 BADCVAR("sys_specialcharactertranslation");
 224                 BADCVAR("timeformat");
 225                 BADCVAR("timestamps");
 226                 BADCVAR("g_require_stats");
 227                 BADPREFIX("developer_");
 228                 BADPREFIX("g_ban_");
 229                 BADPREFIX("g_banned_list");
 230                 BADPREFIX("g_require_stats_");
 231                 BADPREFIX("g_chat_flood_");
 232                 BADPREFIX("g_ghost_items");
 233                 BADPREFIX("g_playerstats_");
 234                 BADPREFIX("g_voice_flood_");
 235                 BADPREFIX("log_file");
 236                 BADPREFIX("quit_");
 237                 BADPREFIX("rcon_");
 238                 BADPREFIX("sv_allowdownloads");
 239                 BADPREFIX("sv_autodemo");
 240                 BADPREFIX("sv_curl_");
 241                 BADPREFIX("sv_eventlog");
 242                 BADPREFIX("sv_logscores_");
 243                 BADPREFIX("sv_master");
 244                 BADPREFIX("sv_weaponstats_");
 245                 BADPREFIX("sv_waypointsprite_");
 246                 BADCVAR("rescan_pending");
 247
 248                 // these can contain player IDs, so better hide
 249                 BADPREFIX("g_forced_team_");
 250                 BADCVAR("sv_muteban_list");
 251                 BADCVAR("sv_voteban_list");
 252                 BADCVAR("sv_allow_customplayermodels_idlist");
 253                 BADCVAR("sv_allow_customplayermodels_speciallist");
 254
 255                 // mapinfo
 256                 BADCVAR("fraglimit");
 257                 BADCVAR("g_arena");
 258                 BADCVAR("g_assault");
 259                 BADCVAR("g_ca");
 260                 BADCVAR("g_ca_teams");
 261                 BADCVAR("g_conquest");
 262                 BADCVAR("g_ctf");
 263                 BADCVAR("g_cts");
 264                 BADCVAR("g_dotc");
 265                 BADCVAR("g_dm");
 266                 BADCVAR("g_domination");
 267                 BADCVAR("g_domination_default_teams");
 268                 BADCVAR("g_duel");
 269                 BADCVAR("g_duel_not_dm_maps");
 270                 BADCVAR("g_freezetag");
 271                 BADCVAR("g_freezetag_teams");
 272                 BADCVAR("g_invasion_type");
 273                 BADCVAR("g_jailbreak");
 274                 BADCVAR("g_jailbreak_teams");
 275                 BADCVAR("g_keepaway");
 276                 BADCVAR("g_keyhunt");
 277                 BADCVAR("g_keyhunt_teams");
 278                 BADCVAR("g_lms");
 279                 BADCVAR("g_nexball");
 280                 BADCVAR("g_onslaught");
 281                 BADCVAR("g_race");
 282                 BADCVAR("g_race_laps_limit");
 283                 BADCVAR("g_race_qualifying_timelimit");
 284                 BADCVAR("g_race_qualifying_timelimit_override");
 285                 BADCVAR("g_runematch");
 286                 BADCVAR("g_shootfromeye");
 287                 BADCVAR("g_snafu");
 288                 BADCVAR("g_tdm");
 289                 BADCVAR("g_tdm_on_dm_maps");
 290                 BADCVAR("g_tdm_teams");
 291                 BADCVAR("g_vip");
 292                 BADCVAR("leadlimit");
 293                 BADCVAR("nextmap");
 294                 BADCVAR("teamplay");
 295                 BADCVAR("timelimit");
 296                 BADCVAR("g_mapinfo_ignore_warnings");
 297                 BADCVAR("g_maplist_ignore_sizes");
 298                 BADCVAR("g_maplist_sizes_count_bots");
 299
 300                 // long
 301                 BADCVAR("hostname");
 302                 BADCVAR("g_maplist");
 303                 BADCVAR("g_maplist_mostrecent");
 304                 BADCVAR("sv_motd");
 305
 306                 v = cvar_string(k);
 307                 d = cvar_defstring(k);
 308                 if(v == d)
 309                         continue;
 310
 311                 if(adding)
 312                 {
 313                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 314                         if(strlen(cvar_changes) > 16384)
 315                         {
 316                                 cvar_changes = "// too many settings have been changed to show them here\n";
 317                                 adding = 0;
 318                         }
 319                 }
 320
 321                 // now check if the changes are actually gameplay relevant
 322
 323                 // does nothing gameplay relevant
 324                 BADCVAR("captureleadlimit_override");
 325                 BADCVAR("condump_stripcolors");
 326                 BADCVAR("gameversion");
 327                 BADCVAR("fs_gamedir");
 328                 BADCVAR("g_allow_oldvortexbeam");
 329                 BADCVAR("g_balance_kill_delay");
 330                 BADCVAR("g_buffs_pickup_anyway");
 331                 BADCVAR("g_buffs_randomize");
 332                 BADCVAR("g_buffs_randomize_teamplay");
 333                 BADCVAR("g_campcheck_distance");
 334                 BADCVAR("g_ca_point_leadlimit");
 335                 BADCVAR("g_ca_point_limit");
 336                 BADCVAR("g_ctf_captimerecord_always");
 337                 BADCVAR("g_ctf_flag_glowtrails");
 338                 BADCVAR("g_ctf_dynamiclights");
 339                 BADCVAR("g_ctf_flag_pickup_verbosename");
 340                 BADCVAR("g_domination_point_leadlimit");
 341                 BADCVAR("g_forced_respawn");
 342                 BADCVAR("g_freezetag_point_leadlimit");
 343                 BADCVAR("g_freezetag_point_limit");
 344                 BADCVAR("g_hats");
 345                 BADCVAR("g_invasion_point_limit");
 346                 BADCVAR("g_jump_grunt");
 347                 BADCVAR("g_keyhunt_point_leadlimit");
 348                 BADCVAR("g_nexball_goalleadlimit");
 349                 BADCVAR("g_new_toys_autoreplace");
 350                 BADCVAR("g_new_toys_use_pickupsound");
 351                 BADCVAR("g_physics_predictall");
 352                 BADCVAR("g_piggyback");
 353                 BADCVAR("g_playerclip_collisions");
 354                 BADCVAR("g_spawn_alloweffects");
 355                 BADCVAR("g_tdm_point_leadlimit");
 356                 BADCVAR("g_tdm_point_limit");
 357                 BADCVAR("leadlimit_and_fraglimit");
 358                 BADCVAR("leadlimit_override");
 359                 BADCVAR("pausable");
 360                 BADCVAR("sv_checkforpacketsduringsleep");
 361                 BADCVAR("sv_damagetext");
 362                 BADCVAR("sv_db_saveasdump");
 363                 BADCVAR("sv_intermission_cdtrack");
 364                 BADCVAR("sv_mapchange_delay");
 365                 BADCVAR("sv_minigames");
 366                 BADCVAR("sv_namechangetimer");
 367                 BADCVAR("sv_precacheplayermodels");
 368                 BADCVAR("sv_stepheight");
 369                 BADCVAR("sv_timeout");
 370                 BADCVAR("sv_weapons_modeloverride");
 371                 BADCVAR("w_prop_interval");
 372                 BADPREFIX("crypto_");
 373                 BADPREFIX("gameversion_");
 374                 BADPREFIX("g_chat_");
 375                 BADPREFIX("g_ctf_captimerecord_");
 376                 BADPREFIX("g_hats_");
 377                 BADPREFIX("g_maplist_");
 378                 BADPREFIX("g_mod_");
 379                 BADPREFIX("g_respawn_");
 380                 BADPREFIX("net_");
 381                 BADPREFIX("notification_");
 382                 BADPREFIX("prvm_");
 383                 BADPREFIX("skill_");
 384                 BADPREFIX("sv_allow_");
 385                 BADPREFIX("sv_cullentities_");
 386                 BADPREFIX("sv_maxidle_");
 387                 BADPREFIX("sv_minigames_");
 388                 BADPREFIX("sv_radio_");
 389                 BADPREFIX("sv_timeout_");
 390                 BADPREFIX("sv_vote_");
 391                 BADPREFIX("timelimit_");
 392
 393                 // allowed changes to server admins (please sync this to server.cfg)
 394                 // vi commands:
 395                 //   :/"impure"/,$d
 396                 //   :g!,^\/\/[^ /],d
 397                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 398                 //   :%!sort
 399                 // yes, this does contain some redundant stuff, don't really care
 400                 BADCVAR("bot_config_file");
 401                 BADCVAR("bot_number");
 402                 BADCVAR("bot_prefix");
 403                 BADCVAR("bot_suffix");
 404                 BADCVAR("capturelimit_override");
 405                 BADCVAR("fraglimit_override");
 406                 BADCVAR("gametype");
 407                 BADCVAR("g_antilag");
 408                 BADCVAR("g_balance_teams");
 409                 BADCVAR("g_balance_teams_prevent_imbalance");
 410                 BADCVAR("g_balance_teams_scorefactor");
 411                 BADCVAR("g_ban_sync_trusted_servers");
 412                 BADCVAR("g_ban_sync_uri");
 413                 BADCVAR("g_buffs");
 414                 BADCVAR("g_ca_teams_override");
 415                 BADCVAR("g_ctf_fullbrightflags");
 416                 BADCVAR("g_ctf_ignore_frags");
 417                 BADCVAR("g_ctf_leaderboard");
 418                 BADCVAR("g_domination_point_limit");
 419                 BADCVAR("g_domination_teams_override");
 420                 BADCVAR("g_freezetag_teams_override");
 421                 BADCVAR("g_friendlyfire");
 422                 BADCVAR("g_fullbrightitems");
 423                 BADCVAR("g_fullbrightplayers");
 424                 BADCVAR("g_keyhunt_point_limit");
 425                 BADCVAR("g_keyhunt_teams_override");
 426                 BADCVAR("g_lms_lives_override");
 427                 BADCVAR("g_maplist");
 428                 BADCVAR("g_maxplayers");
 429                 BADCVAR("g_mirrordamage");
 430                 BADCVAR("g_nexball_goallimit");
 431                 BADCVAR("g_norecoil");
 432                 BADCVAR("g_physics_clientselect");
 433                 BADCVAR("g_pinata");
 434                 BADCVAR("g_powerups");
 435                 BADCVAR("g_player_brightness");
 436                 BADCVAR("g_rocket_flying");
 437                 BADCVAR("g_rocket_flying_disabledelays");
 438                 BADCVAR("g_spawnshieldtime");
 439                 BADCVAR("g_start_delay");
 440                 BADCVAR("g_superspectate");
 441                 BADCVAR("g_tdm_teams_override");
 442                 BADCVAR("g_warmup");
 443                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 444                 BADCVAR("hostname");
 445                 BADCVAR("log_file");
 446                 BADCVAR("maxplayers");
 447                 BADCVAR("minplayers");
 448                 BADCVAR("minplayers_per_team");
 449                 BADCVAR("net_address");
 450                 BADCVAR("port");
 451                 BADCVAR("rcon_password");
 452                 BADCVAR("rcon_restricted_commands");
 453                 BADCVAR("rcon_restricted_password");
 454                 BADCVAR("skill");
 455                 BADCVAR("sv_adminnick");
 456                 BADCVAR("sv_autoscreenshot");
 457                 BADCVAR("sv_autotaunt");
 458                 BADCVAR("sv_curl_defaulturl");
 459                 BADCVAR("sv_defaultcharacter");
 460                 BADCVAR("sv_defaultcharacterskin");
 461                 BADCVAR("sv_defaultplayercolors");
 462                 BADCVAR("sv_defaultplayermodel");
 463                 BADCVAR("sv_defaultplayerskin");
 464                 BADCVAR("sv_maxidle");
 465                 BADCVAR("sv_maxrate");
 466                 BADCVAR("sv_motd");
 467                 BADCVAR("sv_public");
 468                 BADCVAR("sv_ready_restart");
 469                 BADCVAR("sv_status_privacy");
 470                 BADCVAR("sv_taunt");
 471                 BADCVAR("sv_vote_call");
 472                 BADCVAR("sv_vote_commands");
 473                 BADCVAR("sv_vote_majority_factor");
 474                 BADCVAR("sv_vote_master");
 475                 BADCVAR("sv_vote_master_commands");
 476                 BADCVAR("sv_vote_master_password");
 477                 BADCVAR("sv_vote_simple_majority_factor");
 478                 BADCVAR("teamplay_mode");
 479                 BADCVAR("timelimit_override");
 480                 BADPREFIX("g_warmup_");
 481                 BADPREFIX("sv_info_");
 482                 BADPREFIX("sv_ready_restart_");
 483
 484                 // mutators that announce themselves properly to the server browser
 485                 BADCVAR("g_instagib");
 486                 BADCVAR("g_new_toys");
 487                 BADCVAR("g_nix");
 488                 BADCVAR("g_grappling_hook");
 489                 BADCVAR("g_jetpack");
 490
 491                 // temporary for testing
 492                 // TODO remove before 0.8.3 release
 493                 BADCVAR("g_ca_weaponarena");
 494                 BADCVAR("g_freezetag_weaponarena");
 495                 BADCVAR("g_lms_weaponarena");
 496                 BADCVAR("g_ctf_stalemate_time");
 497
 498                 if(cvar_string("g_mod_balance") == "Testing")
 499                 {
 500                         // (temporary) while using the Testing balance, any weapon balance cvars are allowed to be changed
 501                         BADPREFIX("g_balance_");
 502                 }
 503
 504 #undef BADPRESUFFIX
 505 #undef BADPREFIX
 506 #undef BADCVAR
 507
 508                 if(pureadding)
 509                 {
 510                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 511                         if(strlen(cvar_purechanges) > 16384)
 512                         {
 513                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 514                                 pureadding = 0;
 515                         }
 516                 }
 517                 ++cvar_purechanges_count;
 518                 // WARNING: this variable is used for the server list
 519                 // NEVER dare to skip this code!
 520                 // Hacks to intentionally appearing as "pure server" even though you DO have
 521                 // modified settings may be punished by removal from the server list.
 522                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 523                 // though.
 524         }
 525         buf_del(h);
 526         if(cvar_changes == "")
 527                 cvar_changes = "// this server runs at default server settings\n";
 528         else
 529                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 530         cvar_changes = strzone(cvar_changes);
 531         if(cvar_purechanges == "")
 532                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 533         else
 534                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 535         cvar_purechanges = strzone(cvar_purechanges);
 536 }
 537
 538 entity randomseed;
 539 bool RandomSeed_Send(entity this, entity to, int sf)
 540 {
 541         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 542         WriteShort(MSG_ENTITY, this.cnt);
 543         return true;
 544 }
 545 void RandomSeed_Think(entity this)
 546 {
 547         this.cnt = bound(0, floor(random() * 65536), 65535);
 548         this.nextthink = time + 5;
 549
 550         this.SendFlags |= 1;
 551 }
 552 void RandomSeed_Spawn()
 553 {
 554         randomseed = new_pure(randomseed);
 555         setthink(randomseed, RandomSeed_Think);
 556         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 557
 558         getthink(randomseed)(randomseed); // sets random seed and nextthink
 559 }
 560
 561 spawnfunc(__init_dedicated_server)
 562 {
 563         // handler for _init/_init map (only for dedicated server initialization)
 564
 565         world_initialized = -1; // don't complain
 566         cvar = cvar_normal;
 567         cvar_string = cvar_string_normal;
 568         cvar_set = cvar_set_normal;
 569
 570         delete_fn = remove_unsafely;
 571
 572         entity e = spawn();
 573         setthink(e, GotoFirstMap);
 574         e.nextthink = time; // this is usually 1 at this point
 575
 576         e = new(info_player_deathmatch);  // safeguard against player joining
 577
 578     // assign reflectively to avoid "assignment to world" warning
 579     for (int i = 0, n = numentityfields(); i < n; ++i) {
 580         string k = entityfieldname(i);
 581         if (k == "classname") {
 582             // safeguard against various stuff ;)
 583             putentityfieldstring(i, this, "worldspawn");
 584             break;
 585         }
 586     }
 587
 588         // needs to be done so early because of the constants they create
 589         static_init();
 590         static_init_late();
 591         static_init_precache();
 592
 593         IL_PUSH(g_spawnpoints, e); // just incase
 594
 595         MapInfo_Enumerate();
 596         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 597 }
 598
 599 void __init_dedicated_server_shutdown() {
 600         MapInfo_Shutdown();
 601 }
 602
 603 STATIC_INIT_EARLY(maxclients)
 604 {
 605         maxclients = 0;
 606         for (entity head = nextent(NULL); head; head = nextent(head)) {
 607                 ++maxclients;
 608         }
 609 }
 610
 611 void default_delayedinit(entity this)
 612 {
 613         if(!scores_initialized)
 614                 ScoreRules_generic();
 615 }
 616
 617 void InitGameplayMode()
 618 {
 619         VoteReset();
 620
 621         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 622         get_mi_min_max(1);
 623         // assign reflectively to avoid "assignment to world" warning
 624         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
 625             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 626             if (v) {
 627             putentityfieldstring(i, world, sprintf("%v", v));
 628             if (++done == 2) break;
 629         }
 630         }
 631         // currently, NetRadiant's limit is 131072 qu for each side
 632         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 633         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 634         // in case somebody makes extremely large maps
 635         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 636
 637         MapInfo_LoadMapSettings(mapname);
 638         GameRules_teams(false);
 639
 640         if (!cvar_value_issafe(world.fog))
 641         {
 642                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 643                 world.fog = string_null;
 644         }
 645         if(MapInfo_Map_fog != "")
 646         {
 647                 if(MapInfo_Map_fog == "none")
 648                         world.fog = string_null;
 649                 else
 650                         world.fog = strzone(MapInfo_Map_fog);
 651         }
 652         clientstuff = strzone(MapInfo_Map_clientstuff);
 653
 654         MapInfo_ClearTemps();
 655
 656         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 657
 658         cache_mutatormsg = strzone("");
 659         cache_lastmutatormsg = strzone("");
 660
 661         InitializeEntity(NULL, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 662 }
 663
 664 void Map_MarkAsRecent(string m);
 665 float world_already_spawned;
 666 spawnfunc(worldspawn)
 667 {
 668         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 669
 670         bool wantrestart = false;
 671         {
 672                 if (!server_is_dedicated)
 673                 {
 674                         // force unloading of server pk3 files when starting a listen server
 675                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 676                         // restore csqc_progname too
 677                         string expect = "csprogs.dat";
 678                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 679                         cvar_set_normal("csqc_progname", expect);
 680                 }
 681                 else
 682                 {
 683                         // Try to use versioned csprogs from pk3
 684                         // Only ever use versioned csprogs.dat files on dedicated servers;
 685                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 686                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 687                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 688                         string select = "csprogs.dat";
 689                         if (fexists(pk3csprogs)) select = pk3csprogs;
 690                         if (cvar_string_normal("csqc_progname") != select)
 691                         {
 692                                 cvar_set_normal("csqc_progname", select);
 693                                 wantrestart = true;
 694                         }
 695                         // Check for updates on startup
 696                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 697                         int sentinel = fopen("progs.txt", FILE_READ);
 698                         if (sentinel >= 0)
 699                         {
 700                                 string switchversion = fgets(sentinel);
 701                                 fclose(sentinel);
 702                                 if (switchversion != "" && switchversion != WATERMARK)
 703                                 {
 704                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 705                                         // if it doesn't exist, assume either:
 706                                         //   a) the current program was overwritten
 707                                         //   b) this is a client only update
 708                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 709                                         if (fexists(newprogs))
 710                                         {
 711                                                 cvar_set_normal("sv_progs", newprogs);
 712                                                 wantrestart = true;
 713                                         }
 714                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 715                                         if (fexists(newcsprogs))
 716                                         {
 717                                                 cvar_set_normal("csqc_progname", newcsprogs);
 718                                                 wantrestart = true;
 719                                         }
 720                                 }
 721                         }
 722                 }
 723                 if (wantrestart)
 724                 {
 725                         LOG_INFO("Restart requested");
 726                         changelevel(mapname);
 727                         // let initialization continue, shutdown depends on it
 728                 }
 729         }
 730
 731         cvar = cvar_normal;
 732         cvar_string = cvar_string_normal;
 733         cvar_set = cvar_set_normal;
 734
 735         if(world_already_spawned)
 736                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 737         world_already_spawned = true;
 738
 739         delete_fn = remove_safely; // during spawning, watch what you remove!
 740
 741         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 742
 743         // needs to be done so early because of the constants they create
 744         static_init();
 745
 746         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 747
 748         TemporaryDB = db_create();
 749
 750         // 0 normal
 751         lightstyle(0, "m");
 752
 753         // 1 FLICKER (first variety)
 754         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 755
 756         // 2 SLOW STRONG PULSE
 757         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 758
 759         // 3 CANDLE (first variety)
 760         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 761
 762         // 4 FAST STROBE
 763         lightstyle(4, "mamamamamama");
 764
 765         // 5 GENTLE PULSE 1
 766         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 767
 768         // 6 FLICKER (second variety)
 769         lightstyle(6, "nmonqnmomnmomomno");
 770
 771         // 7 CANDLE (second variety)
 772         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 773
 774         // 8 CANDLE (third variety)
 775         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 776
 777         // 9 SLOW STROBE (fourth variety)
 778         lightstyle(9, "aaaaaaaazzzzzzzz");
 779
 780         // 10 FLUORESCENT FLICKER
 781         lightstyle(10, "mmamammmmammamamaaamammma");
 782
 783         // 11 SLOW PULSE NOT FADE TO BLACK
 784         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 785
 786         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 787
 788         // 63 testing
 789         lightstyle(63, "a");
 790
 791         if(autocvar_g_campaign)
 792                 CampaignPreInit();
 793
 794         Map_MarkAsRecent(mapname);
 795
 796         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 797
 798         InitGameplayMode();
 799         static_init_late();
 800         static_init_precache();
 801         readlevelcvars();
 802         GrappleHookInit();
 803
 804         GameRules_limit_fallbacks();
 805
 806         if(warmup_limit == 0)
 807                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 808
 809         player_count = 0;
 810         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 811         if(bot_waypoints_for_items == 1)
 812                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 813                         bot_waypoints_for_items = 0;
 814
 815         WaypointSprite_Init();
 816
 817         GameLogInit(); // prepare everything
 818         // NOTE for matchid:
 819         // changing the logic generating it is okay. But:
 820         // it HAS to stay <= 64 chars
 821         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 822         if(autocvar_sv_eventlog)
 823         {
 824                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 825                 matchid = strzone(s);
 826
 827                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 828                 s = ":gameinfo:mutators:LIST";
 829
 830                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 831                 s = M_ARGV(0, string);
 832
 833                 // initialiation stuff, not good in the mutator system
 834                 if(!autocvar_g_use_ammunition)
 835                         s = strcat(s, ":no_use_ammunition");
 836
 837                 // initialiation stuff, not good in the mutator system
 838                 if(autocvar_g_pickup_items == 0)
 839                         s = strcat(s, ":no_pickup_items");
 840                 if(autocvar_g_pickup_items > 0)
 841                         s = strcat(s, ":pickup_items");
 842
 843                 // initialiation stuff, not good in the mutator system
 844                 if(autocvar_g_weaponarena != "0")
 845                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 846
 847                 // TODO to mutator system
 848                 if(autocvar_g_norecoil)
 849                         s = strcat(s, ":norecoil");
 850
 851                 // TODO to mutator system
 852                 if(autocvar_g_powerups == 0)
 853                         s = strcat(s, ":no_powerups");
 854                 if(autocvar_g_powerups > 0)
 855                         s = strcat(s, ":powerups");
 856
 857                 GameLogEcho(s);
 858                 GameLogEcho(":gameinfo:end");
 859         }
 860         else
 861                 matchid = strzone(ftos(random()));
 862
 863         cvar_set("nextmap", "");
 864
 865         SetDefaultAlpha();
 866
 867         if(autocvar_g_campaign)
 868                 CampaignPostInit();
 869
 870         Ban_LoadBans();
 871
 872         MapInfo_Enumerate();
 873         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 874
 875         if(fexists(strcat("scripts/", mapname, ".arena")))
 876                 cvar_settemp("sv_q3acompat_machineshotgunswap", "1");
 877
 878         if(fexists(strcat("scripts/", mapname, ".defi")))
 879                 cvar_settemp("sv_q3defragcompat", "1");
 880
 881         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 882         {
 883                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 884                 if(fd != -1)
 885                 {
 886                         string s;
 887                         while((s = fgets(fd)))
 888                         {
 889                                 int l = tokenize_console(s);
 890                                 if(l < 2)
 891                                         continue;
 892                                 if(argv(0) == "cd")
 893                                 {
 894                                         string trackname = argv(2);
 895                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 896                                         LOG_INFO("  cdtrack ", trackname);
 897                                         if (cvar_value_issafe(trackname))
 898                                         {
 899                                                 string newstuff = strcat(clientstuff, "cd loop \"", trackname, "\"\n");
 900                                                 strcpy(clientstuff, newstuff);
 901                                         }
 902                                 }
 903                                 else if(argv(0) == "fog")
 904                                 {
 905                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 906                                         LOG_INFO("  \"fog\" \"", s, "\"");
 907                                 }
 908                                 else if(argv(0) == "set")
 909                                 {
 910                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 911                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 912                                 }
 913                                 else if(argv(0) != "//")
 914                                 {
 915                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 916                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 917                                 }
 918                         }
 919                         fclose(fd);
 920                 }
 921         }
 922
 923         WeaponStats_Init();
 924
 925         Nagger_Init();
 926
 927         next_pingtime = time + 5;
 928
 929         // set up information replies for clients and server to use
 930         maplist_reply = strzone(getmaplist());
 931         lsmaps_reply = strzone(getlsmaps());
 932         monsterlist_reply = strzone(getmonsterlist());
 933         for(int i = 0; i < 10; ++i)
 934         {
 935                 string s = getrecords(i);
 936                 if (s)
 937                         records_reply[i] = strzone(s);
 938         }
 939         ladder_reply = strzone(getladder());
 940         rankings_reply = strzone(getrankings());
 941
 942         // begin other init
 943         ClientInit_Spawn();
 944         RandomSeed_Spawn();
 945         PingPLReport_Spawn();
 946
 947         CheatInit();
 948
 949         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 950
 951         // fill sv_curl_serverpackages from .serverpackage files
 952         if (autocvar_sv_curl_serverpackages_auto)
 953         {
 954                 string s = "csprogs-" WATERMARK ".txt";
 955                 // remove automatically managed files from the list to prevent duplicates
 956                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 957                 {
 958                         string pkg = argv(i);
 959                         if (startsWith(pkg, "csprogs-")) continue;
 960                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 961                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 962                         s = cons(s, pkg);
 963                 }
 964                 // add automatically managed files to the list
 965                 #define X(match) MACRO_BEGIN \
 966                         int fd = search_begin(match, true, false); \
 967                         if (fd >= 0) \
 968                         { \
 969                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 970                                 { \
 971                                         s = cons(s, search_getfilename(fd, i)); \
 972                                 } \
 973                                 search_end(fd); \
 974                         } \
 975                 MACRO_END
 976                 X("*-serverpackage.txt");
 977                 X("*.serverpackage");
 978                 #undef X
 979                 cvar_set("sv_curl_serverpackages", s);
 980         }
 981
 982         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 983         modname = "Xonotic";
 984         // physics/balance/config changes that count as mod
 985         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 986                 modname = cvar_string("g_mod_physics");
 987         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance") && cvar_string("g_mod_balance") != "Testing")
 988                 modname = cvar_string("g_mod_balance");
 989         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 990                 modname = cvar_string("g_mod_config");
 991         // extra mutators that deserve to count as mod
 992         MUTATOR_CALLHOOK(SetModname, modname);
 993         modname = M_ARGV(0, string);
 994
 995         // save it for later
 996         modname = strzone(modname);
 997
 998         WinningConditionHelper(this); // set worldstatus
 999
1000         world_initialized = 1;
1001         __spawnfunc_spawn_all();
1002 }
1003
1004 spawnfunc(light)
1005 {
1006         //makestatic (this); // Who the f___ did that?
1007         delete(this);
1008 }
1009
1010 string GetGametype()
1011 {
1012         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
1013 }
1014
1015 string GetMapname()
1016 {
1017         return mapname;
1018 }
1019
1020 float Map_Count, Map_Current;
1021 string Map_Current_Name;
1022
1023 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
1024 int GetMaplistPosition()
1025 {
1026         string map = GetMapname();
1027         int idx = autocvar_g_maplist_index;
1028
1029         if(idx >= 0)
1030         {
1031                 if(idx < Map_Count)
1032                 {
1033                         if(map == argv(idx))
1034                         {
1035                                 return idx;
1036                         }
1037                 }
1038         }
1039
1040         for(int pos = 0; pos < Map_Count; ++pos)
1041         {
1042                 if(map == argv(pos))
1043                         return pos;
1044         }
1045
1046         // resume normal maplist rotation if current map is not in g_maplist
1047         return idx;
1048 }
1049
1050 bool MapHasRightSize(string map)
1051 {
1052         int minplayers = max(0, floor(autocvar_minplayers));
1053         if (teamplay)
1054                 minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
1055         if (autocvar_g_maplist_check_waypoints
1056                 && (currentbots || autocvar_bot_number || player_count < minplayers))
1057         {
1058                 string checkwp_msg = strcat("checkwp ", map);
1059                 if(!fexists(strcat("maps/", map, ".waypoints")))
1060                 {
1061                         LOG_TRACE(checkwp_msg, ": no waypoints");
1062                         return false;
1063                 }
1064                 LOG_TRACE(checkwp_msg, ": has waypoints");
1065         }
1066
1067         if(autocvar_g_maplist_ignore_sizes)
1068                 return true;
1069
1070         // open map size restriction file
1071         string opensize_msg = strcat("opensize ", map);
1072         float fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1073         int pcount = player_count;
1074         if(!autocvar_g_maplist_sizes_count_bots)
1075                 pcount -= currentbots;
1076         if(fh >= 0)
1077         {
1078                 opensize_msg = strcat(opensize_msg, ": ok, ");
1079                 int mapmin = stoi(fgets(fh));
1080                 int mapmax = stoi(fgets(fh));
1081                 fclose(fh);
1082                 if(pcount < mapmin)
1083                 {
1084                         LOG_TRACE(opensize_msg, "not enough");
1085                         return false;
1086                 }
1087                 if(mapmax && pcount > mapmax)
1088                 {
1089                         LOG_TRACE(opensize_msg, "too many");
1090                         return false;
1091                 }
1092                 LOG_TRACE(opensize_msg, "right size");
1093                 return true;
1094         }
1095         LOG_TRACE(opensize_msg, ": not found");
1096         return true;
1097 }
1098
1099 string Map_Filename(float position)
1100 {
1101         return strcat("maps/", argv(position), ".bsp");
1102 }
1103
1104 void Map_MarkAsRecent(string m)
1105 {
1106         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1107 }
1108
1109 float Map_IsRecent(string m)
1110 {
1111         return strhasword(autocvar_g_maplist_mostrecent, m);
1112 }
1113
1114 float Map_Check(float position, float pass)
1115 {
1116         string filename;
1117         string map_next;
1118         map_next = argv(position);
1119         if(pass <= 1)
1120         {
1121                 if(Map_IsRecent(map_next))
1122                         return 0;
1123         }
1124         filename = Map_Filename(position);
1125         if(MapInfo_CheckMap(map_next))
1126         {
1127                 if(pass == 2)
1128                         return 1;
1129                 if(MapHasRightSize(map_next))
1130                         return 1;
1131                 return 0;
1132         }
1133         else
1134                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1135
1136         return 0;
1137 }
1138
1139 void Map_Goto_SetStr(string nextmapname)
1140 {
1141         if(getmapname_stored != "")
1142                 strunzone(getmapname_stored);
1143         if(nextmapname == "")
1144                 getmapname_stored = "";
1145         else
1146                 getmapname_stored = strzone(nextmapname);
1147 }
1148
1149 void Map_Goto_SetFloat(float position)
1150 {
1151         cvar_set("g_maplist_index", ftos(position));
1152         Map_Goto_SetStr(argv(position));
1153 }
1154
1155 void Map_Goto(float reinit)
1156 {
1157         MapInfo_LoadMap(getmapname_stored, reinit);
1158 }
1159
1160 // return codes of map selectors:
1161 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1162 //   -2 = permanent failure
1163 float MaplistMethod_Iterate() // usual method
1164 {
1165         float pass, i;
1166
1167         LOG_TRACE("Trying MaplistMethod_Iterate");
1168
1169         for(pass = 1; pass <= 2; ++pass)
1170         {
1171                 for(i = 1; i < Map_Count; ++i)
1172                 {
1173                         float mapindex;
1174                         mapindex = (i + Map_Current) % Map_Count;
1175                         if(Map_Check(mapindex, pass))
1176                                 return mapindex;
1177                 }
1178         }
1179         return -1;
1180 }
1181
1182 float MaplistMethod_Repeat() // fallback method
1183 {
1184         LOG_TRACE("Trying MaplistMethod_Repeat");
1185
1186         if(Map_Check(Map_Current, 2))
1187                 return Map_Current;
1188         return -2;
1189 }
1190
1191 float MaplistMethod_Random() // random map selection
1192 {
1193         float i, imax;
1194
1195         LOG_TRACE("Trying MaplistMethod_Random");
1196
1197         imax = 42;
1198
1199         for(i = 0; i <= imax; ++i)
1200         {
1201                 float mapindex;
1202                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1203                 if(Map_Check(mapindex, 1))
1204                         return mapindex;
1205         }
1206         return -1;
1207 }
1208
1209 float MaplistMethod_Shuffle(float exponent) // more clever shuffling
1210 // the exponent sets a bias on the map selection:
1211 // the higher the exponent, the less likely "shortly repeated" same maps are
1212 {
1213         float i, j, imax, insertpos;
1214
1215         LOG_TRACE("Trying MaplistMethod_Shuffle");
1216
1217         imax = 42;
1218
1219         for(i = 0; i <= imax; ++i)
1220         {
1221                 string newlist;
1222
1223                 // now reinsert this at another position
1224                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1225                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1226                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1227                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1228
1229                 // insert the current map there
1230                 newlist = "";
1231                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1232                         newlist = strcat(newlist, " ", argv(j));
1233                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1234                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1235                         newlist = strcat(newlist, " ", argv(j));
1236                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1237                 cvar_set("g_maplist", newlist);
1238                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1239
1240                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1241                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1242                 if(Map_Check(Map_Current, 1))
1243                         return Map_Current;
1244         }
1245         return -1;
1246 }
1247
1248 void Maplist_Init()
1249 {
1250         float i = Map_Count = 0;
1251         if(autocvar_g_maplist != "")
1252         {
1253                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1254                 for (i = 0; i < Map_Count; ++i)
1255                 {
1256                         if (Map_Check(i, 2))
1257                                 break;
1258                 }
1259         }
1260
1261         if (i == Map_Count)
1262         {
1263                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1264                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1265                 if(autocvar_g_maplist_shuffle)
1266                         ShuffleMaplist();
1267                 if(!server_is_dedicated)
1268                         localcmd("\nmenu_cmd sync\n");
1269                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1270         }
1271         if(Map_Count == 0)
1272                 error("empty maplist, cannot select a new map");
1273         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1274
1275         strcpy(Map_Current_Name, argv(Map_Current)); // will be automatically freed on exit thanks to DP
1276         // this may or may not be correct, but who cares, in the worst case a map
1277         // isn't chosen in the first pass that should have been
1278 }
1279
1280 string GetNextMap()
1281 {
1282         Maplist_Init();
1283         float nextMap = -1;
1284
1285         if(nextMap == -1)
1286                 if(autocvar_g_maplist_shuffle > 0)
1287                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1288
1289         if(nextMap == -1)
1290                 if(autocvar_g_maplist_selectrandom)
1291                         nextMap = MaplistMethod_Random();
1292
1293         if(nextMap == -1)
1294                 nextMap = MaplistMethod_Iterate();
1295
1296         if(nextMap == -1)
1297                 nextMap = MaplistMethod_Repeat();
1298
1299         if(nextMap >= 0)
1300         {
1301                 Map_Goto_SetFloat(nextMap);
1302                 return getmapname_stored;
1303         }
1304
1305         return "";
1306 }
1307
1308 float DoNextMapOverride(float reinit)
1309 {
1310         if(autocvar_g_campaign)
1311         {
1312                 CampaignPostIntermission();
1313                 alreadychangedlevel = true;
1314                 return true;
1315         }
1316         if(autocvar_quit_when_empty)
1317         {
1318                 if(player_count <= currentbots)
1319                 {
1320                         localcmd("quit\n");
1321                         alreadychangedlevel = true;
1322                         return true;
1323                 }
1324         }
1325         if(autocvar_quit_and_redirect != "")
1326         {
1327                 redirection_target = strzone(autocvar_quit_and_redirect);
1328                 alreadychangedlevel = true;
1329                 return true;
1330         }
1331         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1332         {
1333                 localcmd("restart\n");
1334                 alreadychangedlevel = true;
1335                 return true;
1336         }
1337         if(autocvar_nextmap != "")
1338         {
1339                 string m;
1340                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1341                 cvar_set("nextmap",m);
1342
1343                 if(!m || gametypevote)
1344                         return false;
1345                 if(autocvar_sv_vote_gametype)
1346                 {
1347                         Map_Goto_SetStr(m);
1348                         return false;
1349                 }
1350
1351                 if(MapInfo_CheckMap(m))
1352                 {
1353                         Map_Goto_SetStr(m);
1354                         Map_Goto(reinit);
1355                         alreadychangedlevel = true;
1356                         return true;
1357                 }
1358         }
1359         if(!reinit && autocvar_lastlevel)
1360         {
1361                 cvar_settemp_restore();
1362                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1363                 alreadychangedlevel = true;
1364                 return true;
1365         }
1366         return false;
1367 }
1368
1369 void GotoNextMap(float reinit)
1370 {
1371         //string nextmap;
1372         //float n, nummaps;
1373         //string s;
1374         if (alreadychangedlevel)
1375                 return;
1376         alreadychangedlevel = true;
1377
1378         string nextMap = GetNextMap();
1379         if(nextMap == "")
1380                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1381         Map_Goto(reinit);
1382 }
1383
1384
1385 /*
1386 ============
1387 IntermissionThink
1388
1389 When the player presses attack or jump, change to the next level
1390 ============
1391 */
1392 .float autoscreenshot;
1393 void IntermissionThink(entity this)
1394 {
1395         FixIntermissionClient(this);
1396
1397         float server_screenshot = (autocvar_sv_autoscreenshot && CS(this).cvar_cl_autoscreenshot);
1398         float client_screenshot = (CS(this).cvar_cl_autoscreenshot == 2);
1399
1400         if( (server_screenshot || client_screenshot)
1401                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1402         {
1403                 this.autoscreenshot = -1;
1404                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1405                 return;
1406         }
1407
1408         if (time < intermission_exittime)
1409                 return;
1410
1411         if(!mapvote_initialized)
1412                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1413                         return;
1414
1415         MapVote_Start();
1416 }
1417
1418 /*
1419 ===============================================================================
1420
1421 RULES
1422
1423 ===============================================================================
1424 */
1425
1426 void DumpStats(float final)
1427 {
1428         float file;
1429         string s;
1430         float to_console;
1431         float to_eventlog;
1432         float to_file;
1433         float i;
1434
1435         to_console = autocvar_sv_logscores_console;
1436         to_eventlog = autocvar_sv_eventlog;
1437         to_file = autocvar_sv_logscores_file;
1438
1439         if(!final)
1440         {
1441                 to_console = true; // always print printstats replies
1442                 to_eventlog = false; // but never print them to the event log
1443         }
1444
1445         if(to_eventlog)
1446                 if(autocvar_sv_eventlog_console)
1447                         to_console = false; // otherwise we get the output twice
1448
1449         if(final)
1450                 s = ":scores:";
1451         else
1452                 s = ":status:";
1453         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1454
1455         if(to_console)
1456                 LOG_INFO(s);
1457         if(to_eventlog)
1458                 GameLogEcho(s);
1459
1460         file = -1;
1461         if(to_file)
1462         {
1463                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1464                 if(file == -1)
1465                         to_file = false;
1466                 else
1467                         fputs(file, strcat(s, "\n"));
1468         }
1469
1470         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1471         if(to_console)
1472                 LOG_INFO(s);
1473         if(to_eventlog)
1474                 GameLogEcho(s);
1475         if(to_file)
1476                 fputs(file, strcat(s, "\n"));
1477
1478         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1479                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1480                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1481                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1482                         s = strcat(s, ftos(it.team), ":");
1483                 else
1484                         s = strcat(s, "spectator:");
1485
1486                 if(to_console)
1487                         LOG_INFO(s, playername(it, false));
1488                 if(to_eventlog)
1489                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1490                 if(to_file)
1491                         fputs(file, strcat(s, playername(it, false), "\n"));
1492         });
1493
1494         if(teamplay)
1495         {
1496                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1497                 if(to_console)
1498                         LOG_INFO(s);
1499                 if(to_eventlog)
1500                         GameLogEcho(s);
1501                 if(to_file)
1502                         fputs(file, strcat(s, "\n"));
1503
1504                 for(i = 1; i < 16; ++i)
1505                 {
1506                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1507                         s = strcat(s, ":", ftos(i));
1508                         if(to_console)
1509                                 LOG_INFO(s);
1510                         if(to_eventlog)
1511                                 GameLogEcho(s);
1512                         if(to_file)
1513                                 fputs(file, strcat(s, "\n"));
1514                 }
1515         }
1516
1517         if(to_console)
1518                 LOG_INFO(":end");
1519         if(to_eventlog)
1520                 GameLogEcho(":end");
1521         if(to_file)
1522         {
1523                 fputs(file, ":end\n");
1524                 fclose(file);
1525         }
1526 }
1527
1528 void FixIntermissionClient(entity e)
1529 {
1530         if(!e.autoscreenshot) // initial call
1531         {
1532                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1533                 SetResourceExplicit(e, RES_HEALTH, -2342);
1534                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1535                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1536                 {
1537                     .entity weaponentity = weaponentities[slot];
1538                         if(e.(weaponentity))
1539                         {
1540                                 e.(weaponentity).effects = EF_NODRAW;
1541                                 if (e.(weaponentity).weaponchild)
1542                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1543                         }
1544                 }
1545                 if(IS_REAL_CLIENT(e))
1546                 {
1547                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1548                         RandomSelection_Init();
1549                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, {
1550                                 RandomSelection_AddString(it, 1, 1);
1551                         });
1552                         if (RandomSelection_chosen_string != "")
1553                         {
1554                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1555                         }
1556                         msg_entity = e;
1557                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1558                 }
1559         }
1560 }
1561
1562 /*
1563 go to the next level for deathmatch
1564 only called if a time or frag limit has expired
1565 */
1566 void NextLevel()
1567 {
1568         game_stopped = true;
1569         intermission_running = 1; // game over
1570
1571         // enforce a wait time before allowing changelevel
1572         if(player_count > 0)
1573                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1574         else
1575                 intermission_exittime = -1;
1576
1577         /*
1578         WriteByte (MSG_ALL, SVC_CDTRACK);
1579         WriteByte (MSG_ALL, 3);
1580         WriteByte (MSG_ALL, 3);
1581         // done in FixIntermission
1582         */
1583
1584         //pos = FindIntermission ();
1585
1586         VoteReset();
1587
1588         DumpStats(true);
1589
1590         // send statistics
1591         PlayerStats_GameReport(true);
1592         WeaponStats_Shutdown();
1593
1594         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1595
1596         if(autocvar_sv_eventlog)
1597                 GameLogEcho(":gameover");
1598
1599         GameLogClose();
1600
1601         FOREACH_CLIENT(IS_PLAYER(it), {
1602                 FixIntermissionClient(it);
1603                 if(it.winning)
1604                         bprint(playername(it, false), " ^7wins.\n");
1605         });
1606
1607         target_music_kill();
1608
1609         if(autocvar_g_campaign)
1610                 CampaignPreIntermission();
1611
1612         MUTATOR_CALLHOOK(MatchEnd);
1613
1614         localcmd("\nsv_hook_gameend\n");
1615 }
1616
1617
1618 float InitiateSuddenDeath()
1619 {
1620         // Check first whether normal overtimes could be added before initiating suddendeath mode
1621         // - for this timelimit_overtime needs to be >0 of course
1622         // - also check the winning condition calculated in the previous frame and only add normal overtime
1623         //   again, if at the point at which timelimit would be extended again, still no winner was found
1624         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1625                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1626                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1627         {
1628                 return 1; // need to call InitiateOvertime later
1629         }
1630         else
1631         {
1632                 if(!checkrules_suddendeathend)
1633                 {
1634                         if(autocvar_g_campaign)
1635                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1636                         else
1637                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1638                         if(g_race && !g_race_qualifying)
1639                                 race_StartCompleting();
1640                 }
1641                 return 0;
1642         }
1643 }
1644
1645 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1646 {
1647         ++checkrules_overtimesadded;
1648         //add one more overtime by simply extending the timelimit
1649         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1650         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1651 }
1652
1653 float GetWinningCode(float fraglimitreached, float equality)
1654 {
1655         if(autocvar_g_campaign == 1)
1656         {
1657                 if(fraglimitreached)
1658                         return WINNING_YES;
1659                 else
1660                         return WINNING_NO;
1661         }
1662         else
1663         {
1664                 if(equality)
1665                 {
1666                         if(fraglimitreached)
1667                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1668                         else
1669                                 return WINNING_NEVER;
1670                 }
1671                 else
1672                 {
1673                         if(fraglimitreached)
1674                                 return WINNING_YES;
1675                         else
1676                                 return WINNING_NO;
1677                 }
1678         }
1679 }
1680
1681 // set the .winning flag for exactly those players with a given field value
1682 void SetWinners(.float field, float value)
1683 {
1684         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1685 }
1686
1687 // set the .winning flag for those players with a given field value
1688 void AddWinners(.float field, float value)
1689 {
1690         FOREACH_CLIENT(IS_PLAYER(it), {
1691                 if(it.(field) == value)
1692                         it.winning = 1;
1693         });
1694 }
1695
1696 // clear the .winning flags
1697 void ClearWinners()
1698 {
1699         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1700 }
1701
1702 void ShuffleMaplist()
1703 {
1704         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1705 }
1706
1707 float leaderscore;
1708 float secondscore;
1709 int fragsleft_last;
1710 float WinningCondition_Scores(float limit, float leadlimit)
1711 {
1712         float limitreached;
1713
1714         // TODO make everything use THIS winning condition (except LMS)
1715         WinningConditionHelper(NULL);
1716
1717         if(teamplay)
1718         {
1719                 for (int i = 1; i < 5; ++i)
1720                 {
1721                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1722                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1723                 }
1724         }
1725
1726         ClearWinners();
1727         if(WinningConditionHelper_winner)
1728                 WinningConditionHelper_winner.winning = 1;
1729         if(WinningConditionHelper_winnerteam >= 0)
1730                 SetWinners(team, WinningConditionHelper_winnerteam);
1731
1732         if(WinningConditionHelper_lowerisbetter)
1733         {
1734                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1735                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1736                 limit = -limit;
1737         }
1738
1739         if(WinningConditionHelper_zeroisworst)
1740                 leadlimit = 0; // not supported in this mode
1741
1742         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1743         // these modes always score in increments of 1, thus this makes sense
1744         {
1745                 if (leaderscore != WinningConditionHelper_topscore ||
1746                         secondscore != WinningConditionHelper_secondscore)
1747                 {
1748                         int fragsleft = 0, leadingfragsleft = 0;
1749
1750                         leaderscore = WinningConditionHelper_topscore;
1751                         secondscore = WinningConditionHelper_secondscore;
1752
1753                         if (limit)
1754                                 fragsleft = limit - leaderscore;
1755                         if (leadlimit)
1756                                 leadingfragsleft = secondscore + leadlimit - leaderscore;
1757
1758                         if (autocvar_leadlimit_and_fraglimit && leadlimit)
1759                         {
1760                                 if (limit)
1761                                         fragsleft = max(leadingfragsleft, fragsleft);
1762                         }
1763                         else if (leadlimit)
1764                         {
1765                                 if (limit)
1766                                         fragsleft = min(fragsleft, leadingfragsleft);
1767                                 else
1768                                         fragsleft = leadingfragsleft;
1769                         }
1770
1771                         if (fragsleft_last != fragsleft) // do not announce same remaining frags multiple times
1772                         {
1773                                 if (fragsleft == 1)
1774                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1775                                 else if (fragsleft == 2)
1776                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1777                                 else if (fragsleft == 3)
1778                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1779
1780                                 fragsleft_last = fragsleft;
1781                         }
1782                 }
1783         }
1784
1785         limitreached = false;
1786         if (limit && WinningConditionHelper_topscore >= limit)
1787                 limitreached = true;
1788         if(leadlimit)
1789         {
1790                 float leadlimitreached;
1791                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1792                 if(autocvar_leadlimit_and_fraglimit)
1793                         limitreached = (limitreached && leadlimitreached);
1794                 else
1795                         limitreached = (limitreached || leadlimitreached);
1796         }
1797
1798         if(limit)
1799                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1800
1801         return GetWinningCode(
1802                 WinningConditionHelper_topscore && limitreached,
1803                 WinningConditionHelper_equality
1804         );
1805 }
1806
1807 float WinningCondition_RanOutOfSpawns()
1808 {
1809         if(have_team_spawns <= 0)
1810                 return WINNING_NO;
1811
1812         if(!autocvar_g_spawn_useallspawns)
1813                 return WINNING_NO;
1814
1815         if(!some_spawn_has_been_used)
1816                 return WINNING_NO;
1817
1818         for (int i = 1; i < 5; ++i)
1819         {
1820                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1821         }
1822
1823         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1824         {
1825                 if (Team_IsValidTeam(it.team))
1826                 {
1827                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1828                 }
1829         });
1830
1831         IL_EACH(g_spawnpoints, true,
1832         {
1833                 if (Team_IsValidTeam(it.team))
1834                 {
1835                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1836                 }
1837         });
1838
1839         ClearWinners();
1840         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1841         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1842         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1843         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1844         if(team1_score + team2_score + team3_score + team4_score == 0)
1845         {
1846                 checkrules_equality = true;
1847                 return WINNING_YES;
1848         }
1849         else if(team1_score + team2_score + team3_score + team4_score == 1)
1850         {
1851                 float t, i;
1852                 if(team1_score)
1853                         t = 1;
1854                 else if(team2_score)
1855                         t = 2;
1856                 else if(team3_score)
1857                         t = 3;
1858                 else // if(team4_score)
1859                         t = 4;
1860                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1861                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1862                 {
1863                         for (int j = 1; j <= NUM_TEAMS; ++j)
1864                         {
1865                                 if (t == j)
1866                                 {
1867                                         continue;
1868                                 }
1869                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1870                                 {
1871                                         continue;
1872                                 }
1873                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1874                         }
1875                 }
1876
1877                 AddWinners(team, t);
1878                 return WINNING_YES;
1879         }
1880         else
1881                 return WINNING_NO;
1882 }
1883
1884 /*
1885 ============
1886 CheckRules_World
1887
1888 Exit deathmatch games upon conditions
1889 ============
1890 */
1891 void CheckRules_World()
1892 {
1893         float timelimit;
1894         float fraglimit;
1895         float leadlimit;
1896
1897         VoteThink();
1898         MapVote_Think();
1899
1900         SetDefaultAlpha();
1901
1902         if (intermission_running) // someone else quit the game already
1903         {
1904                 if(player_count == 0) // Nobody there? Then let's go to the next map
1905                         MapVote_Start();
1906                         // this will actually check the player count in the next frame
1907                         // again, but this shouldn't hurt
1908                 return;
1909         }
1910
1911         timelimit = autocvar_timelimit * 60;
1912         fraglimit = autocvar_fraglimit;
1913         leadlimit = autocvar_leadlimit;
1914
1915         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1916         {
1917                 if(timelimit > 0)
1918                         timelimit = 0; // timelimit is not made for warmup
1919                 if(fraglimit > 0)
1920                         fraglimit = 0; // no fraglimit for now
1921                 leadlimit = 0; // no leadlimit for now
1922         }
1923
1924         if(timelimit > 0)
1925         {
1926                 timelimit += game_starttime;
1927         }
1928         else if (timelimit < 0)
1929         {
1930                 // endmatch
1931                 NextLevel();
1932                 return;
1933         }
1934
1935         float wantovertime;
1936         wantovertime = 0;
1937
1938         if(timelimit > game_starttime)
1939                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1940         else
1941                 game_completion_ratio = 0;
1942
1943         if(checkrules_suddendeathend)
1944         {
1945                 if(!checkrules_suddendeathwarning)
1946                 {
1947                         checkrules_suddendeathwarning = true;
1948                         if(g_race && !g_race_qualifying)
1949                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1950                         else
1951                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1952                 }
1953         }
1954         else
1955         {
1956                 if (timelimit && time >= timelimit)
1957                 {
1958                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1959                         {
1960                                 float totalplayers;
1961                                 float playerswithlaps;
1962                                 float readyplayers;
1963                                 totalplayers = playerswithlaps = readyplayers = 0;
1964                                 FOREACH_CLIENT(IS_PLAYER(it), {
1965                                         ++totalplayers;
1966                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1967                                                 ++playerswithlaps;
1968                                         if(it.ready)
1969                                                 ++readyplayers;
1970                                 });
1971
1972                                 // at least 2 of the players have completed a lap: start the RACE
1973                                 // otherwise, the players should end the qualifying on their own
1974                                 if(readyplayers || playerswithlaps >= 2)
1975                                 {
1976                                         checkrules_suddendeathend = 0;
1977                                         ReadyRestart(); // go to race
1978                                         return;
1979                                 }
1980                                 else
1981                                         wantovertime |= InitiateSuddenDeath();
1982                         }
1983                         else
1984                                 wantovertime |= InitiateSuddenDeath();
1985                 }
1986         }
1987
1988         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1989         {
1990                 NextLevel();
1991                 return;
1992         }
1993
1994         int checkrules_status = WinningCondition_RanOutOfSpawns();
1995         if(checkrules_status == WINNING_YES)
1996                 bprint("Hey! Someone ran out of spawns!\n");
1997         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1998                 checkrules_status = M_ARGV(0, float);
1999         else
2000                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2001
2002         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2003         {
2004                 checkrules_status = WINNING_NEVER;
2005                 checkrules_overtimesadded = -1;
2006                 wantovertime |= InitiateSuddenDeath();
2007         }
2008
2009         if(checkrules_status == WINNING_NEVER)
2010                 // equality cases! Nobody wins if the overtime ends in a draw.
2011                 ClearWinners();
2012
2013         if(wantovertime)
2014         {
2015                 if(checkrules_status == WINNING_NEVER)
2016                         InitiateOvertime();
2017                 else
2018                         checkrules_status = WINNING_YES;
2019         }
2020
2021         if(checkrules_suddendeathend)
2022                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2023                         checkrules_status = WINNING_YES;
2024
2025         if(checkrules_status == WINNING_YES)
2026         {
2027                 //print("WINNING\n");
2028                 NextLevel();
2029         }
2030 }
2031
2032 string GotoMap(string m)
2033 {
2034         m = GameTypeVote_MapInfo_FixName(m);
2035         if (!m)
2036                 return "The map you suggested is not available on this server.";
2037         if (!autocvar_sv_vote_gametype)
2038         if(!MapInfo_CheckMap(m))
2039                 return "The map you suggested does not support the current game mode.";
2040         cvar_set("nextmap", m);
2041         cvar_set("timelimit", "-1");
2042         if(mapvote_initialized || alreadychangedlevel)
2043         {
2044                 if(DoNextMapOverride(0))
2045                         return "Map switch initiated.";
2046                 else
2047                         return "Hm... no. For some reason I like THIS map more.";
2048         }
2049         else
2050                 return "Map switch will happen after scoreboard.";
2051 }
2052
2053 bool autocvar_sv_gameplayfix_multiplethinksperframe = true;
2054 void RunThink(entity this)
2055 {
2056         // don't let things stay in the past.
2057         // it is possible to start that way by a trigger with a local time.
2058         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2059                 return;
2060
2061         float oldtime = time; // do we need to save this?
2062
2063         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2064         {
2065                 time = max(oldtime, this.nextthink);
2066                 this.nextthink = 0;
2067
2068                 if(getthink(this))
2069                         getthink(this)(this);
2070                 // mods often set nextthink to time to cause a think every frame,
2071                 // we don't want to loop in that case, so exit if the new nextthink is
2072                 // <= the time the qc was told, also exit if it is past the end of the
2073                 // frame
2074                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2075                         break;
2076         }
2077
2078         time = oldtime;
2079 }
2080
2081 bool autocvar_sv_freezenonclients;
2082 bool autocvar_sv_gameplayfix_delayprojectiles = false;
2083 void Physics_Frame()
2084 {
2085         if(autocvar_sv_freezenonclients)
2086                 return;
2087
2088         IL_EACH(g_moveables, true,
2089         {
2090                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2091                         continue;
2092
2093                 //set_movetype(it, it.move_movetype);
2094                 // inline the set_movetype function, since this is called a lot
2095                 it.movetype = (it.move_qcphysics) ? MOVETYPE_NONE : it.move_movetype;
2096
2097                 if(it.move_movetype == MOVETYPE_NONE)
2098                         continue;
2099
2100                 if(it.move_qcphysics)
2101                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2102
2103                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2104                 {
2105                         // handle thinking here
2106                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2107                                 RunThink(it);
2108                 }
2109         });
2110
2111         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2112                 return;
2113
2114         IL_EACH(g_moveables, it.move_qcphysics,
2115         {
2116                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2117                         continue;
2118                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2119         });
2120 }
2121
2122 void systems_update();
2123 void EndFrame()
2124 {
2125         anticheat_endframe();
2126
2127         Physics_Frame();
2128
2129         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2130                 entity e = IS_SPEC(it) ? it.enemy : it;
2131                 if (e.typehitsound) {
2132                         STAT(TYPEHIT_TIME, it) = time;
2133                 } else if (e.killsound) {
2134                         STAT(KILL_TIME, it) = time;
2135                 } else if (e.damage_dealt) {
2136                         STAT(HIT_TIME, it) = time;
2137                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2138                 }
2139         });
2140         // add 1 frametime because after this, engine SV_Physics
2141         // increases time by a frametime and then networks the frame
2142         // add another frametime because client shows everything with
2143         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2144         // needed!
2145         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2146         FOREACH_CLIENT(true, {
2147                 it.typehitsound = false;
2148                 it.damage_dealt = 0;
2149                 it.killsound = false;
2150                 antilag_record(it, CS(it), altime);
2151         });
2152         IL_EACH(g_monsters, true,
2153         {
2154                 antilag_record(it, it, altime);
2155         });
2156         IL_EACH(g_projectiles, it.classname == "nade",
2157         {
2158                 antilag_record(it, it, altime);
2159         });
2160         systems_update();
2161         IL_ENDFRAME();
2162 }
2163
2164
2165 /*
2166  * RedirectionThink:
2167  * returns true if redirecting
2168  */
2169 float redirection_timeout;
2170 float redirection_nextthink;
2171 float RedirectionThink()
2172 {
2173         float clients_found;
2174
2175         if(redirection_target == "")
2176                 return false;
2177
2178         if(!redirection_timeout)
2179         {
2180                 cvar_set("sv_public", "-2");
2181                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2182                 if(redirection_target == "self")
2183                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2184                 else
2185                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2186         }
2187
2188         if(time < redirection_nextthink)
2189                 return true;
2190
2191         redirection_nextthink = time + 1;
2192
2193         clients_found = 0;
2194         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2195                 // TODO add timer
2196                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2197                 if(redirection_target == "self")
2198                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2199                 else
2200                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2201                 ++clients_found;
2202         });
2203
2204         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2205
2206         if(time > redirection_timeout || clients_found == 0)
2207                 localcmd("\nwait; wait; wait; quit\n");
2208
2209         return true;
2210 }
2211
2212 void RestoreGame()
2213 {
2214         // Loaded from a save game
2215         // some things then break, so let's work around them...
2216
2217         // Progs DB (capture records)
2218         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2219
2220         // Mapinfo
2221         MapInfo_Shutdown();
2222         MapInfo_Enumerate();
2223         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2224         WeaponStats_Init();
2225
2226         TargetMusic_RestoreGame();
2227 }
2228
2229 void Shutdown()
2230 {
2231         game_stopped = 2;
2232
2233         if(world_initialized > 0)
2234         {
2235                 world_initialized = 0;
2236                 LOG_TRACE("Saving persistent data...");
2237                 Ban_SaveBans();
2238
2239                 // playerstats with unfinished match
2240                 PlayerStats_GameReport(false);
2241
2242                 if(!cheatcount_total)
2243                 {
2244                         if(autocvar_sv_db_saveasdump)
2245                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2246                         else
2247                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2248                 }
2249                 if(autocvar_developer > 0)
2250                 {
2251                         if(autocvar_sv_db_saveasdump)
2252                                 db_dump(TemporaryDB, "server-temp.db");
2253                         else
2254                                 db_save(TemporaryDB, "server-temp.db");
2255                 }
2256                 CheatShutdown(); // must be after cheatcount check
2257                 db_close(ServerProgsDB);
2258                 db_close(TemporaryDB);
2259                 LOG_TRACE("Saving persistent data... done!");
2260                 // tell the bot system the game is ending now
2261                 bot_endgame();
2262
2263                 WeaponStats_Shutdown();
2264                 MapInfo_Shutdown();
2265         }
2266         else if(world_initialized == 0)
2267         {
2268                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2269         }
2270         else
2271         {
2272                 __init_dedicated_server_shutdown();
2273         }
2274 }