qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetGametype();
  59 void GotoNextMap(float reinit);
  60 void ShuffleMaplist();
  61 float(float reinit) DoNextMapOverride;
  62
  63 void SetDefaultAlpha()
  64 {
  65         if(autocvar_g_running_guns)
  66         {
  67                 default_player_alpha = -1;
  68                 default_weapon_alpha = +1;
  69         }
  70         else if(g_cloaked)
  71         {
  72                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  73                 default_weapon_alpha = default_player_alpha;
  74         }
  75         else
  76         {
  77                 default_player_alpha = autocvar_g_player_alpha;
  78                 if(default_player_alpha == 0)
  79                         default_player_alpha = 1;
  80                 default_weapon_alpha = default_player_alpha;
  81         }
  82 }
  83
  84 void fteqcc_testbugs()
  85 {
  86         float a, b;
  87
  88         if(!autocvar_developer_fteqccbugs)
  89                 return;
  90
  91         dprint("*** fteqcc test: checking for bugs...\n");
  92
  93         a = 1;
  94         b = 5;
  95         if(sqrt(a) - sqrt(b - a) == 0)
  96                 dprint("*** fteqcc test: found same-function-twice bug\n");
  97         else
  98                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  99
 100         world.cnt = -10;
 101         world.enemy = world;
 102         world.enemy.cnt += 10;
 103         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 104                 dprint("*** fteqcc test: found += bug\n");
 105         else
 106                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 107         world.cnt = 0;
 108 }
 109
 110 void GotoFirstMap()
 111 {
 112         float n;
 113         if(autocvar__sv_init)
 114         {
 115                 // cvar_set("_sv_init", "0");
 116                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 117                 // to this "init" map on a dedicated server will cause no permanent
 118                 // harm
 119                 if(autocvar_g_maplist_shuffle)
 120                         ShuffleMaplist();
 121                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 122                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 123
 124                 MapInfo_Enumerate();
 125                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 126
 127                 if(!DoNextMapOverride(1))
 128                         GotoNextMap(1);
 129
 130                 return;
 131         }
 132
 133         if(time < 5)
 134         {
 135                 self.nextthink = time;
 136         }
 137         else
 138         {
 139                 self.nextthink = time + 1;
 140                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 141         }
 142 }
 143
 144 void cvar_changes_init()
 145 {
 146         float h;
 147         string k, v, d;
 148         float n, i, adding, pureadding;
 149
 150         if(cvar_changes)
 151                 strunzone(cvar_changes);
 152         cvar_changes = string_null;
 153         if(cvar_purechanges)
 154                 strunzone(cvar_purechanges);
 155         cvar_purechanges = string_null;
 156         cvar_purechanges_count = 0;
 157
 158         h = buf_create();
 159         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 160         n = buf_getsize(h);
 161
 162         adding = TRUE;
 163         pureadding = TRUE;
 164
 165         for(i = 0; i < n; ++i)
 166         {
 167                 k = bufstr_get(h, i);
 168
 169 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 170 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 171 #define BADCVAR(p) if(k == p) continue
 172
 173                 // general excludes and namespaces for server admin used cvars
 174                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 175
 176                 // internal
 177                 BADPREFIX("csqc_");
 178                 BADPREFIX("cvar_check_");
 179                 BADCVAR("gamecfg");
 180                 BADCVAR("g_configversion");
 181                 BADCVAR("g_maplist_index");
 182                 BADCVAR("halflifebsp");
 183                 BADPREFIX("sv_world");
 184
 185                 // client
 186                 BADPREFIX("chase_");
 187                 BADPREFIX("cl_");
 188                 BADPREFIX("con_");
 189                 BADPREFIX("scoreboard_");
 190                 BADPREFIX("g_campaign");
 191                 BADPREFIX("g_waypointsprite_");
 192                 BADPREFIX("gl_");
 193                 BADPREFIX("joy");
 194                 BADPREFIX("hud_");
 195                 BADPREFIX("m_");
 196                 BADPREFIX("menu_");
 197                 BADPREFIX("net_slist_");
 198                 BADPREFIX("r_");
 199                 BADPREFIX("sbar_");
 200                 BADPREFIX("scr_");
 201                 BADPREFIX("snd_");
 202                 BADPREFIX("show");
 203                 BADPREFIX("sensitivity");
 204                 BADPREFIX("userbind");
 205                 BADPREFIX("v_");
 206                 BADPREFIX("vid_");
 207                 BADPREFIX("crosshair");
 208                 BADCVAR("mod_q3bsp_lightmapmergepower");
 209                 BADCVAR("mod_q3bsp_nolightmaps");
 210                 BADCVAR("fov");
 211                 BADCVAR("mastervolume");
 212                 BADCVAR("volume");
 213                 BADCVAR("bgmvolume");
 214
 215                 // private
 216                 BADCVAR("developer");
 217                 BADCVAR("log_dest_udp");
 218                 BADCVAR("net_address");
 219                 BADCVAR("net_address_ipv6");
 220                 BADCVAR("port");
 221                 BADCVAR("savedgamecfg");
 222                 BADCVAR("serverconfig");
 223                 BADCVAR("sv_autoscreenshot");
 224                 BADCVAR("sv_heartbeatperiod");
 225                 BADCVAR("sv_vote_master_password");
 226                 BADCVAR("sys_colortranslation");
 227                 BADCVAR("sys_specialcharactertranslation");
 228                 BADCVAR("timeformat");
 229                 BADCVAR("timestamps");
 230                 BADPREFIX("developer_");
 231                 BADPREFIX("g_ban_");
 232                 BADPREFIX("g_banned_list");
 233                 BADPREFIX("g_chat_flood_");
 234                 BADPREFIX("g_ghost_items");
 235                 BADPREFIX("g_playerstats_");
 236                 BADPREFIX("g_respawn_ghosts");
 237                 BADPREFIX("g_voice_flood_");
 238                 BADPREFIX("log_file");
 239                 BADPREFIX("rcon_");
 240                 BADPREFIX("sv_allowdownloads");
 241                 BADPREFIX("sv_autodemo");
 242                 BADPREFIX("sv_curl_");
 243                 BADPREFIX("sv_eventlog");
 244                 BADPREFIX("sv_logscores_");
 245                 BADPREFIX("sv_master");
 246                 BADPREFIX("sv_weaponstats_");
 247                 BADPREFIX("sv_waypointsprite_");
 248                 BADCVAR("rescan_pending");
 249
 250                 // these can contain player IDs, so better hide
 251                 BADPREFIX("g_forced_team_");
 252
 253                 // mapinfo
 254                 BADCVAR("fraglimit");
 255                 BADCVAR("g_assault");
 256                 BADCVAR("g_ca");
 257                 BADCVAR("g_ca_teams");
 258                 BADCVAR("g_ctf");
 259                 BADCVAR("g_cts");
 260                 BADCVAR("g_dm");
 261                 BADCVAR("g_domination");
 262                 BADCVAR("g_domination_default_teams");
 263                 BADCVAR("g_freezetag");
 264                 BADCVAR("g_freezetag_teams");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_keyhunt_teams");
 268                 BADCVAR("g_lms");
 269                 BADCVAR("g_nexball");
 270                 BADCVAR("g_onslaught");
 271                 BADCVAR("g_race");
 272                 BADCVAR("g_race_qualifying_timelimit");
 273                 BADCVAR("g_tdm");
 274                 BADCVAR("g_tdm_teams");
 275                 BADCVAR("leadlimit");
 276                 BADCVAR("nextmap");
 277                 BADCVAR("teamplay");
 278                 BADCVAR("timelimit");
 279
 280                 // long
 281                 BADCVAR("hostname");
 282                 BADCVAR("g_maplist");
 283                 BADCVAR("g_maplist_mostrecent");
 284                 BADCVAR("sv_motd");
 285
 286                 v = cvar_string(k);
 287                 d = cvar_defstring(k);
 288                 if(v == d)
 289                         continue;
 290
 291                 if(adding)
 292                 {
 293                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 294                         if(strlen(cvar_changes) > 16384)
 295                         {
 296                                 cvar_changes = "// too many settings have been changed to show them here\n";
 297                                 adding = 0;
 298                         }
 299                 }
 300
 301                 // now check if the changes are actually gameplay relevant
 302
 303                 // does nothing visible
 304                 BADCVAR("captureleadlimit_override");
 305                 BADCVAR("g_balance_kill_delay");
 306                 BADCVAR("g_ca_point_leadlimit");
 307                 BADCVAR("g_ctf_captimerecord_always");
 308                 BADCVAR("g_ctf_flag_glowtrails");
 309                 BADCVAR("g_ctf_flag_pickup_verbosename");
 310                 BADCVAR("g_domination_point_leadlimit");
 311                 BADCVAR("g_forced_respawn");
 312                 BADCVAR("g_keyhunt_point_leadlimit");
 313                 BADPREFIX("g_mod_");
 314                 BADCVAR("g_nexball_goalleadlimit");
 315                 BADCVAR("leadlimit_and_fraglimit");
 316                 BADCVAR("leadlimit_override");
 317                 BADCVAR("pausable");
 318                 BADCVAR("sv_allow_fullbright");
 319                 BADCVAR("sv_checkforpacketsduringsleep");
 320                 BADCVAR("sv_fraginfo");
 321                 BADCVAR("sv_timeout");
 322                 BADPREFIX("sv_timeout_");
 323                 BADPREFIX("crypto_");
 324                 BADPREFIX("g_chat_");
 325                 BADPREFIX("g_ctf_captimerecord_");
 326                 BADPREFIX("g_maplist_votable_");
 327                 BADPREFIX("net_");
 328                 BADPREFIX("prvm_");
 329                 BADPREFIX("skill_");
 330                 BADPREFIX("sv_cullentities_");
 331                 BADPREFIX("sv_fraginfo_");
 332                 BADPREFIX("sv_maxidle_");
 333                 BADPREFIX("sv_vote_");
 334                 BADPREFIX("timelimit_");
 335                 BADCVAR("gameversion");
 336                 BADPREFIX("gameversion_");
 337                 BADCVAR("sv_namechangetimer");
 338
 339                 // allowed changes to server admins (please sync this to server.cfg)
 340                 // vi commands:
 341                 //   :/"impure"/,$d
 342                 //   :g!,^\/\/[^ /],d
 343                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 344                 //   :%!sort
 345                 // yes, this does contain some redundant stuff, don't really care
 346                 BADCVAR("bot_config_file");
 347                 BADCVAR("bot_number");
 348                 BADCVAR("bot_prefix");
 349                 BADCVAR("bot_suffix");
 350                 BADCVAR("capturelimit_override");
 351                 BADCVAR("fraglimit_override");
 352                 BADCVAR("gametype");
 353                 BADCVAR("g_antilag");
 354                 BADCVAR("g_balance_teams");
 355                 BADCVAR("g_balance_teams_prevent_imbalance");
 356                 BADCVAR("g_balance_teams_scorefactor");
 357                 BADCVAR("g_ban_sync_trusted_servers");
 358                 BADCVAR("g_ban_sync_uri");
 359                 BADCVAR("g_ca_teams_override");
 360                 BADCVAR("g_ctf_ignore_frags");
 361                 BADCVAR("g_domination_point_limit");
 362                 BADCVAR("g_freezetag_teams_override");
 363                 BADCVAR("g_friendlyfire");
 364                 BADCVAR("g_fullbrightitems");
 365                 BADCVAR("g_fullbrightplayers");
 366                 BADCVAR("g_keyhunt_point_limit");
 367                 BADCVAR("g_keyhunt_teams_override");
 368                 BADCVAR("g_lms_lives_override");
 369                 BADCVAR("g_maplist");
 370                 BADCVAR("g_maplist_check_waypoints");
 371                 BADCVAR("g_maplist_mostrecent_count");
 372                 BADCVAR("g_maplist_shuffle");
 373                 BADCVAR("g_maplist_votable");
 374                 BADCVAR("g_maplist_votable_abstain");
 375                 BADCVAR("g_maplist_votable_nodetail");
 376                 BADCVAR("g_maplist_votable_suggestions");
 377                 BADCVAR("g_maxplayers");
 378                 BADCVAR("g_mirrordamage");
 379                 BADCVAR("g_nexball_goallimit");
 380                 BADCVAR("g_powerups");
 381                 BADCVAR("g_start_delay");
 382                 BADCVAR("g_warmup");
 383                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 384                 BADCVAR("hostname");
 385                 BADCVAR("log_file");
 386                 BADCVAR("maxplayers");
 387                 BADCVAR("minplayers");
 388                 BADCVAR("net_address");
 389                 BADCVAR("port");
 390                 BADCVAR("rcon_password");
 391                 BADCVAR("rcon_restricted_commands");
 392                 BADCVAR("rcon_restricted_password");
 393                 BADCVAR("skill");
 394                 BADCVAR("sv_adminnick");
 395                 BADCVAR("sv_autoscreenshot");
 396                 BADCVAR("sv_autotaunt");
 397                 BADCVAR("sv_curl_defaulturl");
 398                 BADCVAR("sv_defaultcharacter");
 399                 BADCVAR("sv_defaultplayercolors");
 400                 BADCVAR("sv_defaultplayermodel");
 401                 BADCVAR("sv_defaultplayerskin");
 402                 BADCVAR("sv_maxidle");
 403                 BADCVAR("sv_maxrate");
 404                 BADCVAR("sv_motd");
 405                 BADCVAR("sv_public");
 406                 BADCVAR("sv_ready_restart");
 407                 BADCVAR("sv_status_privacy");
 408                 BADCVAR("sv_taunt");
 409                 BADCVAR("sv_vote_call");
 410                 BADCVAR("sv_vote_commands");
 411                 BADCVAR("sv_vote_majority_factor");
 412                 BADCVAR("sv_vote_master");
 413                 BADCVAR("sv_vote_master_commands");
 414                 BADCVAR("sv_vote_master_password");
 415                 BADCVAR("sv_vote_simple_majority_factor");
 416                 BADCVAR("teamplay_mode");
 417                 BADCVAR("timelimit_override");
 418                 BADCVAR("g_spawnshieldtime");
 419                 BADPREFIX("g_warmup_");
 420                 BADPREFIX("sv_ready_restart_");
 421
 422                 // mutators that announce themselves properly to the server browser
 423                 BADCVAR("g_instagib");
 424                 BADCVAR("g_new_toys");
 425                 BADCVAR("g_nix");
 426                 BADCVAR("g_grappling_hook");
 427                 BADCVAR("g_jetpack");
 428
 429 #undef BADPREFIX
 430 #undef BADCVAR
 431
 432                 if(pureadding)
 433                 {
 434                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 435                         if(strlen(cvar_purechanges) > 16384)
 436                         {
 437                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 438                                 pureadding = 0;
 439                         }
 440                 }
 441                 ++cvar_purechanges_count;
 442                 // WARNING: this variable is used for the server list
 443                 // NEVER dare to skip this code!
 444                 // Hacks to intentionally appearing as "pure server" even though you DO have
 445                 // modified settings may be punished by removal from the server list.
 446                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 447                 // though.
 448         }
 449         buf_del(h);
 450         if(cvar_changes == "")
 451                 cvar_changes = "// this server runs at default server settings\n";
 452         else
 453                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 454         cvar_changes = strzone(cvar_changes);
 455         if(cvar_purechanges == "")
 456                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 457         else
 458                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 459         cvar_purechanges = strzone(cvar_purechanges);
 460 }
 461
 462 void detect_maptype()
 463 {
 464 #if 0
 465         vector o, v;
 466         float i;
 467
 468         for(;;)
 469         {
 470                 o = world.mins;
 471                 o_x += random() * (world.maxs_x - world.mins_x);
 472                 o_y += random() * (world.maxs_y - world.mins_y);
 473                 o_z += random() * (world.maxs_z - world.mins_z);
 474
 475                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 476                 if(trace_fraction == 1)
 477                         continue;
 478
 479                 v = trace_endpos;
 480
 481                 for(i = 0; i < 64; i += 4)
 482                 {
 483                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 484         if(trace_fraction == 1)
 485                 continue;
 486                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 487                 }
 488
 489                 break;
 490         }
 491 #endif
 492 }
 493
 494 entity randomseed;
 495 float RandomSeed_Send(entity to, float sf)
 496 {
 497         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 498         WriteShort(MSG_ENTITY, self.cnt);
 499         return TRUE;
 500 }
 501 void RandomSeed_Think()
 502 {
 503         self.cnt = bound(0, floor(random() * 65536), 65535);
 504         self.nextthink = time + 5;
 505
 506         self.SendFlags |= 1;
 507 }
 508 void RandomSeed_Spawn()
 509 {
 510         randomseed = spawn();
 511         randomseed.think = RandomSeed_Think;
 512         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 513
 514         entity oldself;
 515         oldself = self;
 516         self = randomseed;
 517         self.think(); // sets random seed and nextthink
 518         self = oldself;
 519 }
 520
 521 void spawnfunc___init_dedicated_server(void)
 522 {
 523         // handler for _init/_init map (only for dedicated server initialization)
 524
 525         world_initialized = -1; // don't complain
 526         cvar = cvar_normal;
 527         cvar_string = cvar_string_normal;
 528         cvar_set = cvar_set_normal;
 529
 530         remove = remove_unsafely;
 531
 532         entity e;
 533         e = spawn();
 534         e.think = GotoFirstMap;
 535         e.nextthink = time; // this is usually 1 at this point
 536
 537         e = spawn();
 538         e.classname = "info_player_deathmatch"; // safeguard against player joining
 539
 540         self.classname = "worldspawn"; // safeguard against various stuff ;)
 541
 542         // needs to be done so early because of the constants they create
 543         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 544         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 545         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 546         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 547         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 548         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 549
 550         MapInfo_Enumerate();
 551         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 552 }
 553
 554 void Map_MarkAsRecent(string m);
 555 float world_already_spawned;
 556 void Nagger_Init();
 557 void ClientInit_Spawn();
 558 void WeaponStats_Init();
 559 void WeaponStats_Shutdown();
 560 void spawnfunc_worldspawn (void)
 561 {
 562         float fd, l, i, j, n;
 563         string s;
 564
 565         cvar = cvar_normal;
 566         cvar_string = cvar_string_normal;
 567         cvar_set = cvar_set_normal;
 568
 569         if(world_already_spawned)
 570                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 571         world_already_spawned = TRUE;
 572
 573         remove = remove_safely; // during spawning, watch what you remove!
 574
 575         check_unacceptable_compiler_bugs();
 576
 577         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 578
 579         compressShortVector_init();
 580
 581         entity head;
 582         head = nextent(world);
 583         maxclients = 0;
 584         while(head)
 585         {
 586                 ++maxclients;
 587                 head = nextent(head);
 588         }
 589
 590         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 591
 592         // needs to be done so early because of the constants they create
 593         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 594         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 595         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 596         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 597         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 598         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 599
 600         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 601
 602         TemporaryDB = db_create();
 603
 604         // 0 normal
 605         lightstyle(0, "m");
 606
 607         // 1 FLICKER (first variety)
 608         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 609
 610         // 2 SLOW STRONG PULSE
 611         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 612
 613         // 3 CANDLE (first variety)
 614         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 615
 616         // 4 FAST STROBE
 617         lightstyle(4, "mamamamamama");
 618
 619         // 5 GENTLE PULSE 1
 620         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 621
 622         // 6 FLICKER (second variety)
 623         lightstyle(6, "nmonqnmomnmomomno");
 624
 625         // 7 CANDLE (second variety)
 626         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 627
 628         // 8 CANDLE (third variety)
 629         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 630
 631         // 9 SLOW STROBE (fourth variety)
 632         lightstyle(9, "aaaaaaaazzzzzzzz");
 633
 634         // 10 FLUORESCENT FLICKER
 635         lightstyle(10, "mmamammmmammamamaaamammma");
 636
 637         // 11 SLOW PULSE NOT FADE TO BLACK
 638         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 639
 640         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 641
 642         // 63 testing
 643         lightstyle(63, "a");
 644
 645         if(autocvar_g_campaign)
 646                 CampaignPreInit();
 647
 648         Map_MarkAsRecent(mapname);
 649
 650         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 651
 652         precache_model ("null"); // we need this one before InitGameplayMode
 653         InitGameplayMode();
 654         readlevelcvars();
 655         GrappleHookInit();
 656         ElectroInit();
 657         LaserInit();
 658
 659         player_count = 0;
 660         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 661         if(bot_waypoints_for_items == 1)
 662                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 663                         bot_waypoints_for_items = 0;
 664
 665         precache();
 666
 667         WaypointSprite_Init();
 668
 669         GameLogInit(); // prepare everything
 670         // NOTE for matchid:
 671         // changing the logic generating it is okay. But:
 672         // it HAS to stay <= 64 chars
 673         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 674         if(autocvar_sv_eventlog)
 675         {
 676                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 677                 matchid = strzone(s);
 678
 679                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 680                 s = ":gameinfo:mutators:LIST";
 681
 682                 ret_string = s;
 683                 MUTATOR_CALLHOOK(BuildMutatorsString);
 684                 s = ret_string;
 685
 686                 // simple, probably not good in the mutator system
 687                 if(autocvar_g_grappling_hook)
 688                         s = strcat(s, ":grappling_hook");
 689
 690                 // initialiation stuff, not good in the mutator system
 691                 if(!autocvar_g_use_ammunition)
 692                         s = strcat(s, ":no_use_ammunition");
 693
 694                 // initialiation stuff, not good in the mutator system
 695                 if(autocvar_g_pickup_items == 0)
 696                         s = strcat(s, ":no_pickup_items");
 697                 if(autocvar_g_pickup_items > 0)
 698                         s = strcat(s, ":pickup_items");
 699
 700                 // initialiation stuff, not good in the mutator system
 701                 if(autocvar_g_weaponarena != "0")
 702                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 703
 704                 // TODO to mutator system
 705                 if(autocvar_g_norecoil)
 706                         s = strcat(s, ":norecoil");
 707
 708                 // TODO to mutator system
 709                 if(autocvar_g_powerups == 0)
 710                         s = strcat(s, ":no_powerups");
 711                 if(autocvar_g_powerups > 0)
 712                         s = strcat(s, ":powerups");
 713
 714                 GameLogEcho(s);
 715                 GameLogEcho(":gameinfo:end");
 716         }
 717         else
 718                 matchid = strzone(ftos(random()));
 719
 720         cvar_set("nextmap", "");
 721
 722         SetDefaultAlpha();
 723
 724         if(autocvar_g_campaign)
 725                 CampaignPostInit();
 726
 727         fteqcc_testbugs();
 728
 729         Ban_LoadBans();
 730
 731         MapInfo_Enumerate();
 732         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 733
 734         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 735         {
 736                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 737                 if(fd != -1)
 738                 {
 739                         while((s = fgets(fd)))
 740                         {
 741                                 l = tokenize_console(s);
 742                                 if(l < 2)
 743                                         continue;
 744                                 if(argv(0) == "cd")
 745                                 {
 746                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 747                                         print("  cdtrack ", argv(2), "\n");
 748                                 }
 749                                 else if(argv(0) == "fog")
 750                                 {
 751                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 752                                         print("  \"fog\" \"", s, "\"\n");
 753                                 }
 754                                 else if(argv(0) == "set")
 755                                 {
 756                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 757                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 758                                 }
 759                                 else if(argv(0) != "//")
 760                                 {
 761                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 762                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 763                                 }
 764                         }
 765                         fclose(fd);
 766                 }
 767         }
 768
 769         WeaponStats_Init();
 770
 771         WepSet_AddStat();
 772         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 773         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 774         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 775         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 776         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 777         Nagger_Init();
 778
 779         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 780         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 781         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 782         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 783         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 784         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 785         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 786         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 787         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 788         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 789         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 790         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 791         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 792
 793         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 794         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 795
 796         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 797
 798         // freeze attacks
 799         addstat(STAT_FROZEN, AS_INT, frozen);
 800         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 801
 802         // g_movementspeed hack
 803         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 804         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 805         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 806         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 807         addstat(STAT_MOVEVARS_HIGHSPEED, AS_FLOAT, stat_movement_highspeed);
 808
 809         // jet pack
 810         addstat(STAT_JETPACK_ACCEL_SIDE, AS_FLOAT, stat_jetpack_accel_side);
 811         addstat(STAT_JETPACK_ACCEL_UP, AS_FLOAT, stat_jetpack_accel_up);
 812         addstat(STAT_JETPACK_ANTIGRAVITY, AS_FLOAT, stat_jetpack_antigravity);
 813         addstat(STAT_JETPACK_FUEL, AS_FLOAT, stat_jetpack_fuel);
 814         addstat(STAT_JETPACK_MAXSPEED_UP, AS_FLOAT, stat_jetpack_maxspeed_up);
 815         addstat(STAT_JETPACK_MAXSPEED_SIDE, AS_FLOAT, stat_jetpack_maxspeed_side);
 816
 817         // dodging
 818         addstat(STAT_DODGING_FROZEN, AS_INT, stat_dodging_frozen);
 819
 820         // secrets
 821         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 822         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 823
 824         // monsters
 825         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 826         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 827
 828         // misc
 829         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 830
 831         next_pingtime = time + 5;
 832
 833         detect_maptype();
 834
 835         // set up information replies for clients and server to use
 836         maplist_reply = strzone(getmaplist());
 837         lsmaps_reply = strzone(getlsmaps());
 838         monsterlist_reply = strzone(getmonsterlist());
 839         for(i = 0; i < 10; ++i)
 840         {
 841                 s = getrecords(i);
 842                 if (s)
 843                         records_reply[i] = strzone(s);
 844         }
 845         ladder_reply = strzone(getladder());
 846         rankings_reply = strzone(getrankings());
 847
 848         // begin other init
 849         ClientInit_Spawn();
 850         RandomSeed_Spawn();
 851         PingPLReport_Spawn();
 852
 853         CheatInit();
 854
 855         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 856
 857         // fill sv_curl_serverpackages from .serverpackage files
 858         if(autocvar_sv_curl_serverpackages_auto)
 859         {
 860                 s = "";
 861                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 862                 for(i = 0; i < n; ++i)
 863                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 864                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 865                                 s = strcat(s, " ", argv(i));
 866                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 867                 if(fd >= 0)
 868                 {
 869                         j = search_getsize(fd);
 870                         for(i = 0; i < j; ++i)
 871                                 s = strcat(s, " ", search_getfilename(fd, i));
 872                         search_end(fd);
 873                 }
 874                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 875                 if(fd >= 0)
 876                 {
 877                         j = search_getsize(fd);
 878                         for(i = 0; i < j; ++i)
 879                                 s = strcat(s, " ", search_getfilename(fd, i));
 880                         search_end(fd);
 881                 }
 882                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 883         }
 884
 885         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 886         modname = "Xonotic";
 887         // physics/balance/config changes that count as mod
 888         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 889                 modname = cvar_string("g_mod_physics");
 890         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 891                 modname = cvar_string("g_mod_balance");
 892         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 893                 modname = cvar_string("g_mod_config");
 894         // extra mutators that deserve to count as mod
 895         MUTATOR_CALLHOOK(SetModname);
 896
 897         // save it for later
 898         modname = strzone(modname);
 899
 900         WinningConditionHelper(); // set worldstatus
 901
 902         world_initialized = 1;
 903 }
 904
 905 void spawnfunc_light (void)
 906 {
 907         //makestatic (self); // Who the f___ did that?
 908         remove(self);
 909 }
 910
 911 string GetGametype()
 912 {
 913         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 914 }
 915
 916 string GetMapname()
 917 {
 918         return mapname;
 919 }
 920
 921 float Map_Count, Map_Current;
 922 string Map_Current_Name;
 923
 924 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 925 float GetMaplistPosition()
 926 {
 927         float pos, idx;
 928         string map;
 929
 930         map = GetMapname();
 931         idx = autocvar_g_maplist_index;
 932
 933         if(idx >= 0)
 934                 if(idx < Map_Count)
 935                         if(map == argv(idx))
 936                                 return idx;
 937
 938         for(pos = 0; pos < Map_Count; ++pos)
 939                 if(map == argv(pos))
 940                         return pos;
 941
 942         // resume normal maplist rotation if current map is not in g_maplist
 943         return idx;
 944 }
 945
 946 float MapHasRightSize(string map)
 947 {
 948         float fh;
 949         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 950         if(autocvar_g_maplist_check_waypoints)
 951         {
 952                 dprint("checkwp "); dprint(map);
 953                 if(!fexists(strcat("maps/", map, ".waypoints")))
 954                 {
 955                         dprint(": no waypoints\n");
 956                         return FALSE;
 957                 }
 958                 dprint(": has waypoints\n");
 959         }
 960
 961         // open map size restriction file
 962         dprint("opensize "); dprint(map);
 963         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 964         if(fh >= 0)
 965         {
 966                 float mapmin, mapmax;
 967                 dprint(": ok, ");
 968                 mapmin = stof(fgets(fh));
 969                 mapmax = stof(fgets(fh));
 970                 fclose(fh);
 971                 if(player_count < mapmin)
 972                 {
 973                         dprint("not enough\n");
 974                         return FALSE;
 975                 }
 976                 if(player_count > mapmax)
 977                 {
 978                         dprint("too many\n");
 979                         return FALSE;
 980                 }
 981                 dprint("right size\n");
 982                 return TRUE;
 983         }
 984         dprint(": not found\n");
 985         return TRUE;
 986 }
 987
 988 string Map_Filename(float position)
 989 {
 990         return strcat("maps/", argv(position), ".bsp");
 991 }
 992
 993 string strwords(string s, float w)
 994 {
 995         float endpos;
 996         for(endpos = 0; w && endpos >= 0; --w)
 997                 endpos = strstrofs(s, " ", endpos + 1);
 998         if(endpos < 0)
 999                 return s;
1000         else
1001                 return substring(s, 0, endpos);
1002 }
1003
1004 float strhasword(string s, string w)
1005 {
1006         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1007 }
1008
1009 void Map_MarkAsRecent(string m)
1010 {
1011         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1012 }
1013
1014 float Map_IsRecent(string m)
1015 {
1016         return strhasword(autocvar_g_maplist_mostrecent, m);
1017 }
1018
1019 float Map_Check(float position, float pass)
1020 {
1021         string filename;
1022         string map_next;
1023         map_next = argv(position);
1024         if(pass <= 1)
1025         {
1026                 if(Map_IsRecent(map_next))
1027                         return 0;
1028         }
1029         filename = Map_Filename(position);
1030         if(MapInfo_CheckMap(map_next))
1031         {
1032                 if(pass == 2)
1033                         return 1;
1034                 if(MapHasRightSize(map_next))
1035                         return 1;
1036                 return 0;
1037         }
1038         else
1039                 dprint( "Couldn't select '", filename, "'..\n" );
1040
1041         return 0;
1042 }
1043
1044 void Map_Goto_SetStr(string nextmapname)
1045 {
1046         if(getmapname_stored != "")
1047                 strunzone(getmapname_stored);
1048         if(nextmapname == "")
1049                 getmapname_stored = "";
1050         else
1051                 getmapname_stored = strzone(nextmapname);
1052 }
1053
1054 void Map_Goto_SetFloat(float position)
1055 {
1056         cvar_set("g_maplist_index", ftos(position));
1057         Map_Goto_SetStr(argv(position));
1058 }
1059
1060 void Map_Goto(float reinit)
1061 {
1062         MapInfo_LoadMap(getmapname_stored, reinit);
1063 }
1064
1065 // return codes of map selectors:
1066 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1067 //   -2 = permanent failure
1068 float() MaplistMethod_Iterate = // usual method
1069 {
1070         float pass, i;
1071
1072         dprint("Trying MaplistMethod_Iterate\n");
1073
1074         for(pass = 1; pass <= 2; ++pass)
1075         {
1076                 for(i = 1; i < Map_Count; ++i)
1077                 {
1078                         float mapindex;
1079                         mapindex = mod(i + Map_Current, Map_Count);
1080                         if(Map_Check(mapindex, pass))
1081                                 return mapindex;
1082                 }
1083         }
1084         return -1;
1085 }
1086
1087 float() MaplistMethod_Repeat = // fallback method
1088 {
1089         dprint("Trying MaplistMethod_Repeat\n");
1090
1091         if(Map_Check(Map_Current, 2))
1092                 return Map_Current;
1093         return -2;
1094 }
1095
1096 float() MaplistMethod_Random = // random map selection
1097 {
1098         float i, imax;
1099
1100         dprint("Trying MaplistMethod_Random\n");
1101
1102         imax = 42;
1103
1104         for(i = 0; i <= imax; ++i)
1105         {
1106                 float mapindex;
1107                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1108                 if(Map_Check(mapindex, 1))
1109                         return mapindex;
1110         }
1111         return -1;
1112 }
1113
1114 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1115 // the exponent sets a bias on the map selection:
1116 // the higher the exponent, the less likely "shortly repeated" same maps are
1117 {
1118         float i, j, imax, insertpos;
1119
1120         dprint("Trying MaplistMethod_Shuffle\n");
1121
1122         imax = 42;
1123
1124         for(i = 0; i <= imax; ++i)
1125         {
1126                 string newlist;
1127
1128                 // now reinsert this at another position
1129                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1130                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1131                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1132                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1133
1134                 // insert the current map there
1135                 newlist = "";
1136                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1137                         newlist = strcat(newlist, " ", argv(j));
1138                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1139                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1140                         newlist = strcat(newlist, " ", argv(j));
1141                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1142                 cvar_set("g_maplist", newlist);
1143                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1144
1145                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1146                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1147                 if(Map_Check(Map_Current, 1))
1148                         return Map_Current;
1149         }
1150         return -1;
1151 }
1152
1153 void Maplist_Init()
1154 {
1155         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1156         float i;
1157         for (i = 0; i < Map_Count; ++i)
1158                 if (Map_Check(i, 2))
1159                         break;
1160         if (i == Map_Count)
1161         {
1162                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1163                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1164                 if(autocvar_g_maplist_shuffle)
1165                         ShuffleMaplist();
1166                 localcmd("\nmenu_cmd sync\n");
1167                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1168         }
1169         if(Map_Count == 0)
1170                 error("empty maplist, cannot select a new map");
1171         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1172
1173         if(Map_Current_Name)
1174                 strunzone(Map_Current_Name);
1175         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1176         // this may or may not be correct, but who cares, in the worst case a map
1177         // isn't chosen in the first pass that should have been
1178 }
1179
1180 string GetNextMap()
1181 {
1182         float nextMap;
1183
1184         Maplist_Init();
1185         nextMap = -1;
1186
1187         if(nextMap == -1)
1188                 if(autocvar_g_maplist_shuffle > 0)
1189                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1190
1191         if(nextMap == -1)
1192                 if(autocvar_g_maplist_selectrandom)
1193                         nextMap = MaplistMethod_Random();
1194
1195         if(nextMap == -1)
1196                 nextMap = MaplistMethod_Iterate();
1197
1198         if(nextMap == -1)
1199                 nextMap = MaplistMethod_Repeat();
1200
1201         if(nextMap >= 0)
1202         {
1203                 Map_Goto_SetFloat(nextMap);
1204                 return getmapname_stored;
1205         }
1206
1207         return "";
1208 }
1209
1210 float DoNextMapOverride(float reinit)
1211 {
1212         if(autocvar_g_campaign)
1213         {
1214                 CampaignPostIntermission();
1215                 alreadychangedlevel = TRUE;
1216                 return TRUE;
1217         }
1218         if(autocvar_quit_when_empty)
1219         {
1220                 if(player_count <= currentbots)
1221                 {
1222                         localcmd("quit\n");
1223                         alreadychangedlevel = TRUE;
1224                         return TRUE;
1225                 }
1226         }
1227         if(autocvar_quit_and_redirect != "")
1228         {
1229                 redirection_target = strzone(autocvar_quit_and_redirect);
1230                 alreadychangedlevel = TRUE;
1231                 return TRUE;
1232         }
1233         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1234         {
1235                 localcmd("restart\n");
1236                 alreadychangedlevel = TRUE;
1237                 return TRUE;
1238         }
1239         if(autocvar_nextmap != "")
1240         {
1241                 string m;
1242                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1243                 cvar_set("nextmap",m);
1244
1245                 if(!m || gametypevote)
1246                         return FALSE;
1247                 if(autocvar_sv_vote_gametype)
1248                 {
1249                         Map_Goto_SetStr(m);
1250                         return FALSE;
1251                 }
1252
1253                 if(MapInfo_CheckMap(m))
1254                 {
1255                         Map_Goto_SetStr(m);
1256                         Map_Goto(reinit);
1257                         alreadychangedlevel = TRUE;
1258                         return TRUE;
1259                 }
1260         }
1261         if(!reinit && autocvar_lastlevel)
1262         {
1263                 cvar_settemp_restore();
1264                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1265                 alreadychangedlevel = TRUE;
1266                 return TRUE;
1267         }
1268         return FALSE;
1269 }
1270
1271 void GotoNextMap(float reinit)
1272 {
1273         //string nextmap;
1274         //float n, nummaps;
1275         //string s;
1276         if (alreadychangedlevel)
1277                 return;
1278         alreadychangedlevel = TRUE;
1279
1280         string nextMap;
1281
1282         nextMap = GetNextMap();
1283         if(nextMap == "")
1284                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1285         Map_Goto(reinit);
1286 }
1287
1288
1289 /*
1290 ============
1291 IntermissionThink
1292
1293 When the player presses attack or jump, change to the next level
1294 ============
1295 */
1296 .float autoscreenshot;
1297 void IntermissionThink()
1298 {
1299         FixIntermissionClient(self);
1300
1301         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1302         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1303
1304         if( (server_screenshot || client_screenshot)
1305                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1306         {
1307                 self.autoscreenshot = -1;
1308                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1309                 return;
1310         }
1311
1312         if (time < intermission_exittime)
1313                 return;
1314
1315         if(!mapvote_initialized)
1316                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1317                         return;
1318
1319         MapVote_Start();
1320 }
1321
1322 /*
1323 ============
1324 FindIntermission
1325
1326 Returns the entity to view from
1327 ============
1328 */
1329 /*
1330 entity FindIntermission()
1331 {
1332         local   entity spot;
1333         local   float cyc;
1334
1335 // look for info_intermission first
1336         spot = find (world, classname, "info_intermission");
1337         if (spot)
1338         {       // pick a random one
1339                 cyc = random() * 4;
1340                 while (cyc > 1)
1341                 {
1342                         spot = find (spot, classname, "info_intermission");
1343                         if (!spot)
1344                                 spot = find (spot, classname, "info_intermission");
1345                         cyc = cyc - 1;
1346                 }
1347                 return spot;
1348         }
1349
1350 // then look for the start position
1351         spot = find (world, classname, "info_player_start");
1352         if (spot)
1353                 return spot;
1354
1355 // testinfo_player_start is only found in regioned levels
1356         spot = find (world, classname, "testplayerstart");
1357         if (spot)
1358                 return spot;
1359
1360 // then look for the start position
1361         spot = find (world, classname, "info_player_deathmatch");
1362         if (spot)
1363                 return spot;
1364
1365         //objerror ("FindIntermission: no spot");
1366         return world;
1367 }
1368 */
1369
1370 /*
1371 ===============================================================================
1372
1373 RULES
1374
1375 ===============================================================================
1376 */
1377
1378 void DumpStats(float final)
1379 {
1380         float file;
1381         string s;
1382         float to_console;
1383         float to_eventlog;
1384         float to_file;
1385         float i;
1386
1387         to_console = autocvar_sv_logscores_console;
1388         to_eventlog = autocvar_sv_eventlog;
1389         to_file = autocvar_sv_logscores_file;
1390
1391         if(!final)
1392         {
1393                 to_console = TRUE; // always print printstats replies
1394                 to_eventlog = FALSE; // but never print them to the event log
1395         }
1396
1397         if(to_eventlog)
1398                 if(autocvar_sv_eventlog_console)
1399                         to_console = FALSE; // otherwise we get the output twice
1400
1401         if(final)
1402                 s = ":scores:";
1403         else
1404                 s = ":status:";
1405         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1406
1407         if(to_console)
1408                 print(s, "\n");
1409         if(to_eventlog)
1410                 GameLogEcho(s);
1411
1412         file = -1;
1413         if(to_file)
1414         {
1415                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1416                 if(file == -1)
1417                         to_file = FALSE;
1418                 else
1419                         fputs(file, strcat(s, "\n"));
1420         }
1421
1422         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1423         if(to_console)
1424                 print(s, "\n");
1425         if(to_eventlog)
1426                 GameLogEcho(s);
1427         if(to_file)
1428                 fputs(file, strcat(s, "\n"));
1429
1430         FOR_EACH_CLIENT(other)
1431         {
1432                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1433                 {
1434                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1435                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1436                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1437                                 s = strcat(s, ftos(other.team), ":");
1438                         else
1439                                 s = strcat(s, "spectator:");
1440
1441                         if(to_console)
1442                                 print(s, other.netname, "\n");
1443                         if(to_eventlog)
1444                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1445                         if(to_file)
1446                                 fputs(file, strcat(s, other.netname, "\n"));
1447                 }
1448         }
1449
1450         if(teamplay)
1451         {
1452                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1453                 if(to_console)
1454                         print(s, "\n");
1455                 if(to_eventlog)
1456                         GameLogEcho(s);
1457                 if(to_file)
1458                         fputs(file, strcat(s, "\n"));
1459
1460                 for(i = 1; i < 16; ++i)
1461                 {
1462                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1463                         s = strcat(s, ":", ftos(i));
1464                         if(to_console)
1465                                 print(s, "\n");
1466                         if(to_eventlog)
1467                                 GameLogEcho(s);
1468                         if(to_file)
1469                                 fputs(file, strcat(s, "\n"));
1470                 }
1471         }
1472
1473         if(to_console)
1474                 print(":end\n");
1475         if(to_eventlog)
1476                 GameLogEcho(":end");
1477         if(to_file)
1478         {
1479                 fputs(file, ":end\n");
1480                 fclose(file);
1481         }
1482 }
1483
1484 void FixIntermissionClient(entity e)
1485 {
1486         string s;
1487         if(!e.autoscreenshot) // initial call
1488         {
1489                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1490                 e.health = -2342;
1491                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1492                 e.solid = SOLID_NOT;
1493                 e.movetype = MOVETYPE_NONE;
1494                 e.takedamage = DAMAGE_NO;
1495                 if(e.weaponentity)
1496                 {
1497                         e.weaponentity.effects = EF_NODRAW;
1498                         if (e.weaponentity.weaponentity)
1499                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1500                 }
1501                 if(IS_REAL_CLIENT(e))
1502                 {
1503                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1504                         s = autocvar_sv_intermission_cdtrack;
1505                         if(s != "")
1506                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1507                         msg_entity = e;
1508                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1509                 }
1510         }
1511 }
1512
1513 /*
1514 go to the next level for deathmatch
1515 only called if a time or frag limit has expired
1516 */
1517 void NextLevel()
1518 {
1519         gameover = TRUE;
1520
1521         intermission_running = 1;
1522
1523 // enforce a wait time before allowing changelevel
1524         if(player_count > 0)
1525                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1526         else
1527                 intermission_exittime = -1;
1528
1529         /*
1530         WriteByte (MSG_ALL, SVC_CDTRACK);
1531         WriteByte (MSG_ALL, 3);
1532         WriteByte (MSG_ALL, 3);
1533         // done in FixIntermission
1534         */
1535
1536         //pos = FindIntermission ();
1537
1538         VoteReset();
1539
1540         DumpStats(TRUE);
1541
1542         // send statistics
1543         entity e;
1544         PlayerStats_EndMatch(1);
1545         FOR_EACH_CLIENT(e)
1546                 PlayerStats_AddGlobalInfo(e);
1547         PlayerStats_Shutdown();
1548         WeaponStats_Shutdown();
1549
1550         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1551
1552         if(autocvar_sv_eventlog)
1553                 GameLogEcho(":gameover");
1554
1555         GameLogClose();
1556
1557         FOR_EACH_PLAYER(other) {
1558                 FixIntermissionClient(other);
1559                 if(other.winning)
1560                         bprint(other.netname, " ^7wins.\n");
1561         }
1562
1563         if(autocvar_g_campaign)
1564                 CampaignPreIntermission();
1565
1566         MUTATOR_CALLHOOK(MatchEnd);
1567
1568         localcmd("\nsv_hook_gameend\n");
1569 }
1570
1571 /*
1572 ============
1573 CheckRules_Player
1574
1575 Exit deathmatch games upon conditions
1576 ============
1577 */
1578 void CheckRules_Player()
1579 {
1580         if (gameover)   // someone else quit the game already
1581                 return;
1582
1583         if(self.deadflag == DEAD_NO)
1584                 self.play_time += frametime;
1585
1586         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1587         //   (div0: and that in CheckRules_World please)
1588 }
1589
1590 float checkrules_equality;
1591 float checkrules_suddendeathwarning;
1592 float checkrules_suddendeathend;
1593 float checkrules_overtimesadded; //how many overtimes have been already added
1594
1595 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1596 const float WINNING_YES = 1; // winner found
1597 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1598 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1599
1600 float InitiateSuddenDeath()
1601 {
1602         // Check first whether normal overtimes could be added before initiating suddendeath mode
1603         // - for this timelimit_overtime needs to be >0 of course
1604         // - also check the winning condition calculated in the previous frame and only add normal overtime
1605         //   again, if at the point at which timelimit would be extended again, still no winner was found
1606         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1607         {
1608                 return 1; // need to call InitiateOvertime later
1609         }
1610         else
1611         {
1612                 if(!checkrules_suddendeathend)
1613                 {
1614                         if(autocvar_g_campaign)
1615                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1616                         else
1617                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1618                         if(g_race && !g_race_qualifying)
1619                                 race_StartCompleting();
1620                 }
1621                 return 0;
1622         }
1623 }
1624
1625 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1626 {
1627         ++checkrules_overtimesadded;
1628         //add one more overtime by simply extending the timelimit
1629         float tl;
1630         tl = autocvar_timelimit;
1631         tl += autocvar_timelimit_overtime;
1632         cvar_set("timelimit", ftos(tl));
1633
1634         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1635 }
1636
1637 float GetWinningCode(float fraglimitreached, float equality)
1638 {
1639         if(autocvar_g_campaign == 1)
1640                 if(fraglimitreached)
1641                         return WINNING_YES;
1642                 else
1643                         return WINNING_NO;
1644
1645         else
1646                 if(equality)
1647                         if(fraglimitreached)
1648                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1649                         else
1650                                 return WINNING_NEVER;
1651                 else
1652                         if(fraglimitreached)
1653                                 return WINNING_YES;
1654                         else
1655                                 return WINNING_NO;
1656 }
1657
1658 // set the .winning flag for exactly those players with a given field value
1659 void SetWinners(.float field, float value)
1660 {
1661         entity head;
1662         FOR_EACH_PLAYER(head)
1663                 head.winning = (head.field == value);
1664 }
1665
1666 // set the .winning flag for those players with a given field value
1667 void AddWinners(.float field, float value)
1668 {
1669         entity head;
1670         FOR_EACH_PLAYER(head)
1671                 if(head.field == value)
1672                         head.winning = 1;
1673 }
1674
1675 // clear the .winning flags
1676 void ClearWinners(void)
1677 {
1678         entity head;
1679         FOR_EACH_PLAYER(head)
1680                 head.winning = 0;
1681 }
1682
1683 // Onslaught winning condition:
1684 // game terminates if only one team has a working generator (or none)
1685 float WinningCondition_Onslaught()
1686 {
1687         entity head;
1688         float t1, t2, t3, t4;
1689
1690         WinningConditionHelper(); // set worldstatus
1691
1692         if(warmup_stage)
1693                 return WINNING_NO;
1694
1695         // first check if the game has ended
1696         t1 = t2 = t3 = t4 = 0;
1697         head = find(world, classname, "onslaught_generator");
1698         while (head)
1699         {
1700                 if (head.health > 0)
1701                 {
1702                         if (head.team == NUM_TEAM_1) t1 = 1;
1703                         if (head.team == NUM_TEAM_2) t2 = 1;
1704                         if (head.team == NUM_TEAM_3) t3 = 1;
1705                         if (head.team == NUM_TEAM_4) t4 = 1;
1706                 }
1707                 head = find(head, classname, "onslaught_generator");
1708         }
1709         if (t1 + t2 + t3 + t4 < 2)
1710         {
1711                 // game over, only one team remains (or none)
1712                 ClearWinners();
1713                 if (t1) SetWinners(team, NUM_TEAM_1);
1714                 if (t2) SetWinners(team, NUM_TEAM_2);
1715                 if (t3) SetWinners(team, NUM_TEAM_3);
1716                 if (t4) SetWinners(team, NUM_TEAM_4);
1717                 dprint("Have a winner, ending game.\n");
1718                 return WINNING_YES;
1719         }
1720
1721         // Two or more teams remain
1722         return WINNING_NO;
1723 }
1724
1725 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1726 // they win. Otherwise the defending team wins once the timelimit passes.
1727 void assault_new_round();
1728 float WinningCondition_Assault()
1729 {
1730         float status;
1731
1732         WinningConditionHelper(); // set worldstatus
1733
1734         status = WINNING_NO;
1735         // as the timelimit has not yet passed just assume the defending team will win
1736         if(assault_attacker_team == NUM_TEAM_1)
1737         {
1738                 SetWinners(team, NUM_TEAM_2);
1739         }
1740         else
1741         {
1742                 SetWinners(team, NUM_TEAM_1);
1743         }
1744
1745         entity ent;
1746         ent = find(world, classname, "target_assault_roundend");
1747         if(ent)
1748         {
1749                 if(ent.winning) // round end has been triggered by attacking team
1750                 {
1751                         bprint("ASSAULT: round completed...\n");
1752                         SetWinners(team, assault_attacker_team);
1753
1754                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1755
1756                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1757                         {
1758                                 status = WINNING_YES;
1759                         }
1760                         else
1761                         {
1762                                 entity oldself;
1763                                 oldself = self;
1764                                 self = ent;
1765                                 assault_new_round();
1766                                 self = oldself;
1767                         }
1768                 }
1769         }
1770
1771         return status;
1772 }
1773
1774 // LMS winning condition: game terminates if and only if there's at most one
1775 // one player who's living lives. Top two scores being equal cancels the time
1776 // limit.
1777 float WinningCondition_LMS()
1778 {
1779         entity head, head2;
1780         float have_player;
1781         float have_players;
1782         float l;
1783
1784         have_player = FALSE;
1785         have_players = FALSE;
1786         l = LMS_NewPlayerLives();
1787
1788         head = find(world, classname, "player");
1789         if(head)
1790                 have_player = TRUE;
1791         head2 = find(head, classname, "player");
1792         if(head2)
1793                 have_players = TRUE;
1794
1795         if(have_player)
1796         {
1797                 // we have at least one player
1798                 if(have_players)
1799                 {
1800                         // two or more active players - continue with the game
1801                 }
1802                 else
1803                 {
1804                         // exactly one player?
1805
1806                         ClearWinners();
1807                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1808
1809                         if(l)
1810                         {
1811                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1812                                 return WINNING_NO;
1813                         }
1814                         else
1815                         {
1816                                 // a winner!
1817                                 // and assign him his first place
1818                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1819                                 return WINNING_YES;
1820                         }
1821                 }
1822         }
1823         else
1824         {
1825                 // nobody is playing at all...
1826                 if(l)
1827                 {
1828                         // wait for players...
1829                 }
1830                 else
1831                 {
1832                         // SNAFU (maybe a draw game?)
1833                         ClearWinners();
1834                         dprint("No players, ending game.\n");
1835                         return WINNING_YES;
1836                 }
1837         }
1838
1839         // When we get here, we have at least two players who are actually LIVING,
1840         // now check if the top two players have equal score.
1841         WinningConditionHelper();
1842
1843         ClearWinners();
1844         if(WinningConditionHelper_winner)
1845                 WinningConditionHelper_winner.winning = TRUE;
1846         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1847                 return WINNING_NEVER;
1848
1849         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1850         return WINNING_NO;
1851 }
1852
1853 void ShuffleMaplist()
1854 {
1855         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1856 }
1857
1858 float leaderfrags;
1859 float WinningCondition_Scores(float limit, float leadlimit)
1860 {
1861         float limitreached;
1862
1863         // TODO make everything use THIS winning condition (except LMS)
1864         WinningConditionHelper();
1865
1866         if(teamplay)
1867         {
1868                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1869                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1870                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1871                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1872         }
1873
1874         ClearWinners();
1875         if(WinningConditionHelper_winner)
1876                 WinningConditionHelper_winner.winning = 1;
1877         if(WinningConditionHelper_winnerteam >= 0)
1878                 SetWinners(team, WinningConditionHelper_winnerteam);
1879
1880         if(WinningConditionHelper_lowerisbetter)
1881         {
1882                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1883                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1884                 limit = -limit;
1885         }
1886
1887         if(WinningConditionHelper_zeroisworst)
1888                 leadlimit = 0; // not supported in this mode
1889
1890         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1891         // these modes always score in increments of 1, thus this makes sense
1892         {
1893                 if(leaderfrags != WinningConditionHelper_topscore)
1894                 {
1895                         leaderfrags = WinningConditionHelper_topscore;
1896
1897                         if (limit)
1898                         if (leaderfrags == limit - 1)
1899                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1900                         else if (leaderfrags == limit - 2)
1901                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1902                         else if (leaderfrags == limit - 3)
1903                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1904                 }
1905         }
1906
1907         limitreached = FALSE;
1908         if(limit)
1909                 if(WinningConditionHelper_topscore >= limit)
1910                         limitreached = TRUE;
1911         if(leadlimit)
1912         {
1913                 float leadlimitreached;
1914                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1915                 if(autocvar_leadlimit_and_fraglimit)
1916                         limitreached = (limitreached && leadlimitreached);
1917                 else
1918                         limitreached = (limitreached || leadlimitreached);
1919         }
1920
1921         if(limit)
1922                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1923
1924         return GetWinningCode(
1925                 WinningConditionHelper_topscore && limitreached,
1926                 WinningConditionHelper_equality
1927         );
1928 }
1929
1930 float WinningCondition_Race(float fraglimit)
1931 {
1932         float wc;
1933         entity p;
1934         float n, c;
1935
1936         n = 0;
1937         c = 0;
1938         FOR_EACH_PLAYER(p)
1939         {
1940                 ++n;
1941                 if(p.race_completed)
1942                         ++c;
1943         }
1944         if(n && (n == c))
1945                 return WINNING_YES;
1946         wc = WinningCondition_Scores(fraglimit, 0);
1947
1948         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1949         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1950         // do NOT support equality when the laps are all raced!
1951                 return WINNING_STARTSUDDENDEATHOVERTIME;
1952         else
1953                 return WINNING_NEVER;
1954 }
1955
1956 float WinningCondition_QualifyingThenRace(float limit)
1957 {
1958         float wc;
1959         wc = WinningCondition_Scores(limit, 0);
1960
1961         // NEVER initiate overtime
1962         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1963         {
1964                 return WINNING_YES;
1965         }
1966
1967         return wc;
1968 }
1969
1970 float WinningCondition_RanOutOfSpawns()
1971 {
1972         entity head;
1973
1974         if(have_team_spawns <= 0)
1975                 return WINNING_NO;
1976
1977         if(autocvar_g_spawn_useallspawns <= 0)
1978                 return WINNING_NO;
1979
1980         if(!some_spawn_has_been_used)
1981                 return WINNING_NO;
1982
1983         team1_score = team2_score = team3_score = team4_score = 0;
1984
1985         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1986         {
1987                 if(head.team == NUM_TEAM_1)
1988                         team1_score = 1;
1989                 else if(head.team == NUM_TEAM_2)
1990                         team2_score = 1;
1991                 else if(head.team == NUM_TEAM_3)
1992                         team3_score = 1;
1993                 else if(head.team == NUM_TEAM_4)
1994                         team4_score = 1;
1995         }
1996
1997         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1998         {
1999                 if(head.team == NUM_TEAM_1)
2000                         team1_score = 1;
2001                 else if(head.team == NUM_TEAM_2)
2002                         team2_score = 1;
2003                 else if(head.team == NUM_TEAM_3)
2004                         team3_score = 1;
2005                 else if(head.team == NUM_TEAM_4)
2006                         team4_score = 1;
2007         }
2008
2009         ClearWinners();
2010         if(team1_score + team2_score + team3_score + team4_score == 0)
2011         {
2012                 checkrules_equality = TRUE;
2013                 return WINNING_YES;
2014         }
2015         else if(team1_score + team2_score + team3_score + team4_score == 1)
2016         {
2017                 float t, i;
2018                 if(team1_score)
2019                         t = NUM_TEAM_1;
2020                 else if(team2_score)
2021                         t = NUM_TEAM_2;
2022                 else if(team3_score)
2023                         t = NUM_TEAM_3;
2024                 else // if(team4_score)
2025                         t = NUM_TEAM_4;
2026                 CheckAllowedTeams(world);
2027                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2028                 {
2029                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2030                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2031                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2032                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2033                 }
2034
2035                 AddWinners(team, t);
2036                 return WINNING_YES;
2037         }
2038         else
2039                 return WINNING_NO;
2040 }
2041
2042 /*
2043 ============
2044 CheckRules_World
2045
2046 Exit deathmatch games upon conditions
2047 ============
2048 */
2049 void ReadyRestart();
2050 void CheckRules_World()
2051 {
2052         float timelimit;
2053         float fraglimit;
2054         float leadlimit;
2055
2056         VoteThink();
2057         MapVote_Think();
2058
2059         SetDefaultAlpha();
2060
2061         if (gameover)   // someone else quit the game already
2062         {
2063                 if(player_count == 0) // Nobody there? Then let's go to the next map
2064                         MapVote_Start();
2065                         // this will actually check the player count in the next frame
2066                         // again, but this shouldn't hurt
2067                 return;
2068         }
2069
2070         timelimit = autocvar_timelimit * 60;
2071         fraglimit = autocvar_fraglimit;
2072         leadlimit = autocvar_leadlimit;
2073
2074         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2075         {
2076                 if(timelimit > 0)
2077                         timelimit = 0; // timelimit is not made for warmup
2078                 if(fraglimit > 0)
2079                         fraglimit = 0; // no fraglimit for now
2080                 leadlimit = 0; // no leadlimit for now
2081         }
2082
2083         if(timelimit > 0)
2084         {
2085                 timelimit += game_starttime;
2086         }
2087         else if (timelimit < 0)
2088         {
2089                 // endmatch
2090                 NextLevel();
2091                 return;
2092         }
2093
2094         if(g_onslaught)
2095                 timelimit = 0; // ONS has its own overtime rule
2096
2097         float wantovertime;
2098         wantovertime = 0;
2099
2100         if(timelimit > game_starttime)
2101                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2102         else
2103                 game_completion_ratio = 0;
2104
2105         if(checkrules_suddendeathend)
2106         {
2107                 if(!checkrules_suddendeathwarning)
2108                 {
2109                         checkrules_suddendeathwarning = TRUE;
2110                         if(g_race && !g_race_qualifying)
2111                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2112                         else
2113                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2114                 }
2115         }
2116         else
2117         {
2118                 if (timelimit && time >= timelimit)
2119                 {
2120                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2121                         {
2122                                 float totalplayers;
2123                                 float playerswithlaps;
2124                                 float readyplayers;
2125                                 entity head;
2126                                 totalplayers = playerswithlaps = readyplayers = 0;
2127                                 FOR_EACH_PLAYER(head)
2128                                 {
2129                                         ++totalplayers;
2130                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2131                                                 ++playerswithlaps;
2132                                         if(head.ready)
2133                                                 ++readyplayers;
2134                                 }
2135
2136                                 // at least 2 of the players have completed a lap: start the RACE
2137                                 // otherwise, the players should end the qualifying on their own
2138                                 if(readyplayers || playerswithlaps >= 2)
2139                                 {
2140                                         checkrules_suddendeathend = 0;
2141                                         ReadyRestart(); // go to race
2142                                         return;
2143                                 }
2144                                 else
2145                                         wantovertime |= InitiateSuddenDeath();
2146                         }
2147                         else
2148                                 wantovertime |= InitiateSuddenDeath();
2149                 }
2150         }
2151
2152         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2153         {
2154                 NextLevel();
2155                 return;
2156         }
2157
2158         float checkrules_status;
2159         checkrules_status = WinningCondition_RanOutOfSpawns();
2160         if(checkrules_status == WINNING_YES)
2161         {
2162                 bprint("Hey! Someone ran out of spawns!\n");
2163         }
2164         else if(g_race && !g_race_qualifying && timelimit >= 0)
2165         {
2166                 checkrules_status = WinningCondition_Race(fraglimit);
2167                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2168         }
2169         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2170         {
2171                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2172                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2173         }
2174         else if(g_assault)
2175         {
2176                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2177         }
2178         else if(g_lms)
2179         {
2180                 checkrules_status = WinningCondition_LMS();
2181         }
2182         else if (g_onslaught)
2183         {
2184                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2185         }
2186         else
2187         {
2188                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2189                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2190         }
2191
2192         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2193         {
2194                 checkrules_status = WINNING_NEVER;
2195                 checkrules_overtimesadded = -1;
2196                 wantovertime |= InitiateSuddenDeath();
2197         }
2198
2199         if(checkrules_status == WINNING_NEVER)
2200                 // equality cases! Nobody wins if the overtime ends in a draw.
2201                 ClearWinners();
2202
2203         if(wantovertime)
2204         {
2205                 if(checkrules_status == WINNING_NEVER)
2206                         InitiateOvertime();
2207                 else
2208                         checkrules_status = WINNING_YES;
2209         }
2210
2211         if(checkrules_suddendeathend)
2212                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2213                         checkrules_status = WINNING_YES;
2214
2215         if(checkrules_status == WINNING_YES)
2216         {
2217                 //print("WINNING\n");
2218                 NextLevel();
2219         }
2220 }
2221
2222 string GotoMap(string m)
2223 {
2224         m = GameTypeVote_MapInfo_FixName(m);
2225         if (!m)
2226                 return "The map you suggested is not available on this server.";
2227         if (!autocvar_sv_vote_gametype)
2228         if(!MapInfo_CheckMap(m))
2229                 return "The map you suggested does not support the current game mode.";
2230         cvar_set("nextmap", m);
2231         cvar_set("timelimit", "-1");
2232         if(mapvote_initialized || alreadychangedlevel)
2233         {
2234                 if(DoNextMapOverride(0))
2235                         return "Map switch initiated.";
2236                 else
2237                         return "Hm... no. For some reason I like THIS map more.";
2238         }
2239         else
2240                 return "Map switch will happen after scoreboard.";
2241 }
2242
2243
2244 void EndFrame()
2245 {
2246         anticheat_endframe();
2247
2248         float altime;
2249         FOR_EACH_REALCLIENT(self)
2250         {
2251                 self.damage_dealt_total = 0;
2252
2253                 if(IS_SPEC(self))
2254                 {
2255                         if(self.enemy.typehitsound)
2256                                 self.typehit_time = time;
2257                         else if(self.enemy.damage_dealt)
2258                                 self.damage_dealt_total = ceil(self.enemy.damage_dealt);
2259                 }
2260                 else
2261                 {
2262                         if(self.typehitsound)
2263                                 self.typehit_time = time;
2264                         else if(self.damage_dealt)
2265                                 self.damage_dealt_total = ceil(self.damage_dealt);
2266                 }
2267         }
2268         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2269         // add 1 frametime because after this, engine SV_Physics
2270         // increases time by a frametime and then networks the frame
2271         // add another frametime because client shows everything with
2272         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2273         // needed!
2274         FOR_EACH_CLIENT(self)
2275         {
2276                 self.typehitsound = FALSE;
2277                 self.damage_dealt = 0;
2278                 antilag_record(self, altime);
2279         }
2280         FOR_EACH_MONSTER(self)
2281                 antilag_record(self, altime);
2282 }
2283
2284
2285 /*
2286  * RedirectionThink:
2287  * returns TRUE if redirecting
2288  */
2289 float redirection_timeout;
2290 float redirection_nextthink;
2291 float RedirectionThink()
2292 {
2293         float clients_found;
2294
2295         if(redirection_target == "")
2296                 return FALSE;
2297
2298         if(!redirection_timeout)
2299         {
2300                 cvar_set("sv_public", "-2");
2301                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2302                 if(redirection_target == "self")
2303                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2304                 else
2305                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2306         }
2307
2308         if(time < redirection_nextthink)
2309                 return TRUE;
2310
2311         redirection_nextthink = time + 1;
2312
2313         clients_found = 0;
2314         FOR_EACH_REALCLIENT(self)
2315         {
2316                 // TODO add timer
2317                 print("Redirecting: sending connect command to ", self.netname, "\n");
2318                 if(redirection_target == "self")
2319                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2320                 else
2321                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2322                 ++clients_found;
2323         }
2324
2325         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2326
2327         if(time > redirection_timeout || clients_found == 0)
2328                 localcmd("\nwait; wait; wait; quit\n");
2329
2330         return TRUE;
2331 }
2332
2333 void TargetMusic_RestoreGame();
2334 void RestoreGame()
2335 {
2336         // Loaded from a save game
2337         // some things then break, so let's work around them...
2338
2339         // Progs DB (capture records)
2340         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2341
2342         // Mapinfo
2343         MapInfo_Shutdown();
2344         MapInfo_Enumerate();
2345         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2346         WeaponStats_Init();
2347
2348         TargetMusic_RestoreGame();
2349 }
2350
2351 void Shutdown()
2352 {
2353         entity e;
2354
2355         gameover = 2;
2356
2357         if(world_initialized > 0)
2358         {
2359                 world_initialized = 0;
2360                 print("Saving persistent data...\n");
2361                 Ban_SaveBans();
2362
2363                 PlayerStats_EndMatch(0);
2364                 FOR_EACH_CLIENT(e)
2365                         PlayerStats_AddGlobalInfo(e);
2366                 PlayerStats_Shutdown();
2367
2368                 if(!cheatcount_total)
2369                 {
2370                         if(autocvar_sv_db_saveasdump)
2371                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2372                         else
2373                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2374                 }
2375                 if(autocvar_developer)
2376                 {
2377                         if(autocvar_sv_db_saveasdump)
2378                                 db_dump(TemporaryDB, "server-temp.db");
2379                         else
2380                                 db_save(TemporaryDB, "server-temp.db");
2381                 }
2382                 CheatShutdown(); // must be after cheatcount check
2383                 db_close(ServerProgsDB);
2384                 db_close(TemporaryDB);
2385                 print("done!\n");
2386                 // tell the bot system the game is ending now
2387                 bot_endgame();
2388
2389                 WeaponStats_Shutdown();
2390                 MapInfo_Shutdown();
2391         }
2392         else if(world_initialized == 0)
2393         {
2394                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2395         }
2396 }