qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap(float reinit);
  48 void ShuffleMaplist()
  49 float(float reinit) DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 void GotoFirstMap()
  99 {
 100         float n;
 101         if(autocvar__sv_init)
 102         {
 103                 // cvar_set("_sv_init", "0");
 104                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 105                 // to this "init" map on a dedicated server will cause no permanent
 106                 // harm
 107                 if(autocvar_g_maplist_shuffle)
 108                         ShuffleMaplist();
 109                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 110                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 111
 112                 MapInfo_Enumerate();
 113                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 114
 115                 if(!DoNextMapOverride(1))
 116                         GotoNextMap(1);
 117
 118                 return;
 119         }
 120
 121         if(time < 5)
 122         {
 123                 self.nextthink = time;
 124         }
 125         else
 126         {
 127                 self.nextthink = time + 1;
 128                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 129         }
 130 }
 131
 132 void cvar_changes_init()
 133 {
 134         float h;
 135         string k, v, d;
 136         float n, i, adding, pureadding;
 137
 138         if(cvar_changes)
 139                 strunzone(cvar_changes);
 140         cvar_changes = string_null;
 141         if(cvar_purechanges)
 142                 strunzone(cvar_purechanges);
 143         cvar_purechanges = string_null;
 144         cvar_purechanges_count = 0;
 145
 146         h = buf_create();
 147         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 148         n = buf_getsize(h);
 149
 150         adding = TRUE;
 151         pureadding = TRUE;
 152
 153         for(i = 0; i < n; ++i)
 154         {
 155                 k = bufstr_get(h, i);
 156
 157 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 158 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 159 #define BADCVAR(p) if(k == p) continue
 160
 161                 // general excludes and namespaces for server admin used cvars
 162                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 163
 164                 // internal
 165                 BADPREFIX("csqc_");
 166                 BADPREFIX("cvar_check_");
 167                 BADCVAR("gamecfg");
 168                 BADCVAR("g_configversion");
 169                 BADCVAR("g_maplist_index");
 170                 BADCVAR("halflifebsp");
 171                 BADPREFIX("sv_world");
 172
 173                 // client
 174                 BADPREFIX("chase_");
 175                 BADPREFIX("cl_");
 176                 BADPREFIX("con_");
 177                 BADPREFIX("scoreboard_");
 178                 BADPREFIX("g_campaign");
 179                 BADPREFIX("g_waypointsprite_");
 180                 BADPREFIX("gl_");
 181                 BADPREFIX("joy");
 182                 BADPREFIX("hud_");
 183                 BADPREFIX("m_");
 184                 BADPREFIX("menu_");
 185                 BADPREFIX("net_slist_");
 186                 BADPREFIX("r_");
 187                 BADPREFIX("sbar_");
 188                 BADPREFIX("scr_");
 189                 BADPREFIX("snd_");
 190                 BADPREFIX("show");
 191                 BADPREFIX("sensitivity");
 192                 BADPREFIX("userbind");
 193                 BADPREFIX("v_");
 194                 BADPREFIX("vid_");
 195                 BADPREFIX("crosshair");
 196                 BADCVAR("mod_q3bsp_lightmapmergepower");
 197                 BADCVAR("mod_q3bsp_nolightmaps");
 198                 BADCVAR("fov");
 199                 BADCVAR("mastervolume");
 200                 BADCVAR("volume");
 201                 BADCVAR("bgmvolume");
 202
 203                 // private
 204                 BADCVAR("developer");
 205                 BADCVAR("log_dest_udp");
 206                 BADCVAR("log_file");
 207                 BADCVAR("net_address");
 208                 BADCVAR("net_address_ipv6");
 209                 BADCVAR("port");
 210                 BADCVAR("savedgamecfg");
 211                 BADCVAR("serverconfig");
 212                 BADCVAR("sv_autoscreenshot");
 213                 BADCVAR("sv_heartbeatperiod");
 214                 BADCVAR("sv_vote_master_password");
 215                 BADCVAR("sys_colortranslation");
 216                 BADCVAR("sys_specialcharactertranslation");
 217                 BADCVAR("timeformat");
 218                 BADCVAR("timestamps");
 219                 BADPREFIX("developer_");
 220                 BADPREFIX("g_ban_");
 221                 BADPREFIX("g_banned_list");
 222                 BADPREFIX("g_chat_flood_");
 223                 BADPREFIX("g_ghost_items");
 224                 BADPREFIX("g_playerstats_");
 225                 BADPREFIX("g_respawn_ghosts");
 226                 BADPREFIX("g_voice_flood_");
 227                 BADPREFIX("rcon_");
 228                 BADPREFIX("sv_allowdownloads");
 229                 BADPREFIX("sv_autodemo");
 230                 BADPREFIX("sv_curl_");
 231                 BADPREFIX("sv_eventlog");
 232                 BADPREFIX("sv_logscores_");
 233                 BADPREFIX("sv_master");
 234                 BADPREFIX("sv_weaponstats_");
 235                 BADPREFIX("sv_waypointsprite_");
 236                 BADCVAR("rescan_pending");
 237
 238                 // these can contain player IDs, so better hide
 239                 BADPREFIX("g_forced_team_");
 240
 241                 // mapinfo
 242                 BADCVAR("fraglimit");
 243                 BADCVAR("g_arena");
 244                 BADCVAR("g_assault");
 245                 BADCVAR("g_ca");
 246                 BADCVAR("g_ctf");
 247                 BADCVAR("g_cts");
 248                 BADCVAR("g_dm");
 249                 BADCVAR("g_domination");
 250                 BADCVAR("g_domination_default_teams");
 251                 BADCVAR("g_freezetag");
 252                 BADCVAR("g_keepaway");
 253                 BADCVAR("g_keyhunt");
 254                 BADCVAR("g_keyhunt_teams");
 255                 BADCVAR("g_keyhunt_teams");
 256                 BADCVAR("g_lms");
 257                 BADCVAR("g_nexball");
 258                 BADCVAR("g_onslaught");
 259                 BADCVAR("g_race");
 260                 BADCVAR("g_race_qualifying_timelimit");
 261                 BADCVAR("g_runematch");
 262                 BADCVAR("g_tdm");
 263                 BADCVAR("g_tdm_teams");
 264                 BADCVAR("leadlimit");
 265                 BADCVAR("nextmap");
 266                 BADCVAR("teamplay");
 267                 BADCVAR("timelimit");
 268
 269                 // long
 270                 BADCVAR("hostname");
 271                 BADCVAR("g_maplist");
 272                 BADCVAR("g_maplist_mostrecent");
 273                 BADCVAR("sv_motd");
 274
 275                 v = cvar_string(k);
 276                 d = cvar_defstring(k);
 277                 if(v == d)
 278                         continue;
 279
 280                 if(adding)
 281                 {
 282                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 283                         if(strlen(cvar_changes) > 16384)
 284                         {
 285                                 cvar_changes = "// too many settings have been changed to show them here\n";
 286                                 adding = 0;
 287                         }
 288                 }
 289
 290                 // now check if the changes are actually gameplay relevant
 291
 292                 // does nothing visible
 293                 BADCVAR("captureleadlimit_override");
 294                 BADCVAR("g_arena_point_leadlimit");
 295                 BADCVAR("g_balance_kill_delay");
 296                 BADCVAR("g_ca_point_leadlimit");
 297                 BADCVAR("g_ctf_captimerecord_always");
 298                 BADCVAR("g_ctf_flag_capture_effects");
 299                 BADCVAR("g_ctf_flag_glowtrails");
 300                 BADCVAR("g_ctf_flag_pickup_effects");
 301                 BADCVAR("g_domination_point_leadlimit");
 302                 BADCVAR("g_forced_respawn");
 303                 BADCVAR("g_keyhunt_point_leadlimit");
 304                 BADPREFIX("g_mod_");
 305                 BADCVAR("g_nexball_goalleadlimit");
 306                 BADCVAR("g_runematch_point_leadlimit");
 307                 BADCVAR("leadlimit_and_fraglimit");
 308                 BADCVAR("leadlimit_override");
 309                 BADCVAR("pausable");
 310                 BADCVAR("sv_allow_fullbright");
 311                 BADCVAR("sv_checkforpacketsduringsleep");
 312                 BADCVAR("sv_fraginfo");
 313                 BADCVAR("sv_timeout");
 314                 BADPREFIX("sv_timeout_");
 315                 BADCVAR("welcome_message_time");
 316                 BADPREFIX("crypto_");
 317                 BADPREFIX("g_chat_");
 318                 BADPREFIX("g_ctf_captimerecord_");
 319                 BADPREFIX("g_maplist_votable_");
 320                 BADPREFIX("net_");
 321                 BADPREFIX("prvm_");
 322                 BADPREFIX("skill_");
 323                 BADPREFIX("sv_cullentities_");
 324                 BADPREFIX("sv_fraginfo_");
 325                 BADPREFIX("sv_maxidle_");
 326                 BADPREFIX("sv_vote_");
 327                 BADPREFIX("timelimit_");
 328                 BADCVAR("gameversion");
 329                 BADPREFIX("gameversion_");
 330                 BADCVAR("sv_namechangetimer");
 331 #ifndef NO_LEGACY_NETWORKING
 332                 BADCVAR("sv_use_csqc_players"); // transition
 333 #endif
 334
 335                 // allowed changes to server admins (please sync this to server.cfg)
 336                 // vi commands:
 337                 //   :/"impure"/,$d
 338                 //   :g!,^\/\/[^ /],d
 339                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 340                 //   :%!sort
 341                 // yes, this does contain some redundant stuff, don't really care
 342                 BADCVAR("bot_config_file");
 343                 BADCVAR("bot_number");
 344                 BADCVAR("bot_prefix");
 345                 BADCVAR("bot_suffix");
 346                 BADCVAR("capturelimit_override");
 347                 BADCVAR("fraglimit_override");
 348                 BADCVAR("gametype");
 349                 BADCVAR("g_antilag");
 350                 BADCVAR("g_balance_teams");
 351                 BADCVAR("g_ban_sync_trusted_servers");
 352                 BADCVAR("g_ban_sync_uri");
 353                 BADCVAR("g_ctf_ignore_frags");
 354                 BADCVAR("g_domination_point_limit");
 355                 BADCVAR("g_friendlyfire");
 356                 BADCVAR("g_fullbrightitems");
 357                 BADCVAR("g_fullbrightplayers");
 358                 BADCVAR("g_keyhunt_point_limit");
 359                 BADCVAR("g_keyhunt_teams_override");
 360                 BADCVAR("g_lms_lives_override");
 361                 BADCVAR("g_maplist");
 362                 BADCVAR("g_maplist_check_waypoints");
 363                 BADCVAR("g_maplist_mostrecent_count");
 364                 BADCVAR("g_maplist_shuffle");
 365                 BADCVAR("g_maplist_votable");
 366                 BADCVAR("g_maplist_votable_abstain");
 367                 BADCVAR("g_maplist_votable_nodetail");
 368                 BADCVAR("g_maplist_votable_suggestions");
 369                 BADCVAR("g_maxplayers");
 370                 BADCVAR("g_mirrordamage");
 371                 BADCVAR("g_nexball_goallimit");
 372                 BADCVAR("g_powerups");
 373                 BADCVAR("g_runematch_point_limit");
 374                 BADCVAR("g_start_delay");
 375                 BADCVAR("g_warmup");
 376                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 377                 BADCVAR("hostname");
 378                 BADCVAR("log_file");
 379                 BADCVAR("maxplayers");
 380                 BADCVAR("minplayers");
 381                 BADCVAR("net_address");
 382                 BADCVAR("port");
 383                 BADCVAR("rcon_password");
 384                 BADCVAR("rcon_restricted_commands");
 385                 BADCVAR("rcon_restricted_password");
 386                 BADCVAR("skill");
 387                 BADCVAR("sv_adminnick");
 388                 BADCVAR("sv_autoscreenshot");
 389                 BADCVAR("sv_autotaunt");
 390                 BADCVAR("sv_curl_defaulturl");
 391                 BADCVAR("sv_defaultcharacter");
 392                 BADCVAR("sv_defaultplayercolors");
 393                 BADCVAR("sv_defaultplayermodel");
 394                 BADCVAR("sv_defaultplayerskin");
 395                 BADCVAR("sv_maxidle");
 396                 BADCVAR("sv_maxrate");
 397                 BADCVAR("sv_motd");
 398                 BADCVAR("sv_public");
 399                 BADCVAR("sv_ready_restart");
 400                 BADCVAR("sv_status_privacy");
 401                 BADCVAR("sv_taunt");
 402                 BADCVAR("sv_vote_call");
 403                 BADCVAR("sv_vote_commands");
 404                 BADCVAR("sv_vote_majority_factor");
 405                 BADCVAR("sv_vote_master");
 406                 BADCVAR("sv_vote_master_commands");
 407                 BADCVAR("sv_vote_master_password");
 408                 BADCVAR("sv_vote_simple_majority_factor");
 409                 BADCVAR("sys_ticrate");
 410                 BADCVAR("teamplay_mode");
 411                 BADCVAR("timelimit_override");
 412                 BADCVAR("g_spawnshieldtime");
 413                 BADPREFIX("g_warmup_");
 414                 BADPREFIX("sv_ready_restart_");
 415
 416                 // mutators that announce themselves properly to the server browser
 417                 BADCVAR("g_minstagib");
 418                 BADCVAR("g_new_toys");
 419                 BADCVAR("g_nix");
 420
 421                 if(autocvar_g_minstagib)
 422                 {
 423                         BADCVAR("g_grappling_hook");
 424                         BADCVAR("g_jetpack");
 425                 }
 426 #undef BADPREFIX
 427 #undef BADCVAR
 428
 429                 if(pureadding)
 430                 {
 431                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 432                         if(strlen(cvar_purechanges) > 16384)
 433                         {
 434                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 435                                 pureadding = 0;
 436                         }
 437                 }
 438                 ++cvar_purechanges_count;
 439                 // WARNING: this variable is used for the server list
 440                 // NEVER dare to skip this code!
 441                 // Hacks to intentionally appearing as "pure server" even though you DO have
 442                 // modified settings may be punished by removal from the server list.
 443                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 444                 // though.
 445         }
 446         buf_del(h);
 447         if(cvar_changes == "")
 448                 cvar_changes = "// this server runs at default server settings\n";
 449         else
 450                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 451         cvar_changes = strzone(cvar_changes);
 452         if(cvar_purechanges == "")
 453                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 454         else
 455                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 456         cvar_purechanges = strzone(cvar_purechanges);
 457 }
 458
 459 void detect_maptype()
 460 {
 461 #if 0
 462         vector o, v;
 463         float i;
 464
 465         for(;;)
 466         {
 467                 o = world.mins;
 468                 o_x += random() * (world.maxs_x - world.mins_x);
 469                 o_y += random() * (world.maxs_y - world.mins_y);
 470                 o_z += random() * (world.maxs_z - world.mins_z);
 471
 472                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 473                 if(trace_fraction == 1)
 474                         continue;
 475
 476                 v = trace_endpos;
 477
 478                 for(i = 0; i < 64; i += 4)
 479                 {
 480                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 481         if(trace_fraction == 1)
 482                 continue;
 483                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 484                 }
 485
 486                 break;
 487         }
 488 #endif
 489 }
 490
 491 entity randomseed;
 492 float RandomSeed_Send(entity to, float sf)
 493 {
 494         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 495         WriteShort(MSG_ENTITY, self.cnt);
 496         return TRUE;
 497 }
 498 void RandomSeed_Think()
 499 {
 500         self.cnt = bound(0, floor(random() * 65536), 65535);
 501         self.nextthink = time + 5;
 502
 503         self.SendFlags |= 1;
 504 }
 505 void RandomSeed_Spawn()
 506 {
 507         randomseed = spawn();
 508         randomseed.think = RandomSeed_Think;
 509         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 510
 511         entity oldself;
 512         oldself = self;
 513         self = randomseed;
 514         self.think(); // sets random seed and nextthink
 515         self = oldself;
 516 }
 517
 518 void spawnfunc___init_dedicated_server(void)
 519 {
 520         // handler for _init/_init map (only for dedicated server initialization)
 521
 522         world_initialized = -1; // don't complain
 523         cvar = cvar_normal;
 524         cvar_string = cvar_string_normal;
 525         cvar_set = cvar_set_normal;
 526
 527         remove = remove_unsafely;
 528
 529         entity e;
 530         e = spawn();
 531         e.think = GotoFirstMap;
 532         e.nextthink = time; // this is usually 1 at this point
 533
 534         e = spawn();
 535         e.classname = "info_player_deathmatch"; // safeguard against player joining
 536
 537         self.classname = "worldspawn"; // safeguard against various stuff ;)
 538
 539         // needs to be done so early because of the constants they create
 540         RegisterWeapons();
 541         RegisterGametypes();
 542
 543         MapInfo_Enumerate();
 544         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 545 }
 546
 547 void Map_MarkAsRecent(string m);
 548 float world_already_spawned;
 549 void RegisterWeapons();
 550 void Nagger_Init();
 551 void ClientInit_Spawn();
 552 void WeaponStats_Init();
 553 void WeaponStats_Shutdown();
 554 void spawnfunc_worldspawn (void)
 555 {
 556         float fd, l, i, j, n;
 557         string s, col;
 558
 559         cvar = cvar_normal;
 560         cvar_string = cvar_string_normal;
 561         cvar_set = cvar_set_normal;
 562
 563         if(world_already_spawned)
 564                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 565         world_already_spawned = TRUE;
 566
 567         remove = remove_safely; // during spawning, watch what you remove!
 568
 569         check_unacceptable_compiler_bugs();
 570
 571         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 572
 573         compressShortVector_init();
 574
 575         allowed_to_spawn = TRUE;
 576
 577         entity head;
 578         head = nextent(world);
 579         maxclients = 0;
 580         while(head)
 581         {
 582                 ++maxclients;
 583                 head = nextent(head);
 584         }
 585
 586         // needs to be done so early because of the constants they create
 587         RegisterWeapons();
 588         RegisterGametypes();
 589
 590         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 591
 592         TemporaryDB = db_create();
 593
 594         // 0 normal
 595         lightstyle(0, "m");
 596
 597         // 1 FLICKER (first variety)
 598         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 599
 600         // 2 SLOW STRONG PULSE
 601         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 602
 603         // 3 CANDLE (first variety)
 604         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 605
 606         // 4 FAST STROBE
 607         lightstyle(4, "mamamamamama");
 608
 609         // 5 GENTLE PULSE 1
 610         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 611
 612         // 6 FLICKER (second variety)
 613         lightstyle(6, "nmonqnmomnmomomno");
 614
 615         // 7 CANDLE (second variety)
 616         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 617
 618         // 8 CANDLE (third variety)
 619         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 620
 621         // 9 SLOW STROBE (fourth variety)
 622         lightstyle(9, "aaaaaaaazzzzzzzz");
 623
 624         // 10 FLUORESCENT FLICKER
 625         lightstyle(10, "mmamammmmammamamaaamammma");
 626
 627         // 11 SLOW PULSE NOT FADE TO BLACK
 628         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 629
 630         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 631
 632         // 63 testing
 633         lightstyle(63, "a");
 634
 635         if(autocvar_g_campaign)
 636                 CampaignPreInit();
 637
 638         Map_MarkAsRecent(mapname);
 639
 640         precache_model ("null"); // we need this one before InitGameplayMode
 641         InitGameplayMode();
 642         readlevelcvars();
 643         GrappleHookInit();
 644         ElectroInit();
 645
 646         player_count = 0;
 647         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 648         if(bot_waypoints_for_items == 1)
 649                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 650                         bot_waypoints_for_items = 0;
 651
 652         precache();
 653
 654         WaypointSprite_Init();
 655
 656         //if (g_domination)
 657         //      dom_init();
 658
 659         GameLogInit(); // prepare everything
 660         // NOTE for matchid:
 661         // changing the logic generating it is okay. But:
 662         // it HAS to stay <= 64 chars
 663         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 664         if(autocvar_sv_eventlog)
 665         {
 666                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 667                 matchid = strzone(s);
 668
 669                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 670                 s = ":gameinfo:mutators:LIST";
 671
 672                 ret_string = s;
 673                 MUTATOR_CALLHOOK(BuildMutatorsString);
 674                 s = ret_string;
 675
 676                 // simple, probably not good in the mutator system
 677                 if(autocvar_g_grappling_hook)
 678                         s = strcat(s, ":grappling_hook");
 679
 680                 // initialiation stuff, not good in the mutator system
 681                 if(!autocvar_g_use_ammunition)
 682                         s = strcat(s, ":no_use_ammunition");
 683
 684                 // initialiation stuff, not good in the mutator system
 685                 if(autocvar_g_pickup_items == 0)
 686                         s = strcat(s, ":no_pickup_items");
 687                 if(autocvar_g_pickup_items > 0)
 688                         s = strcat(s, ":pickup_items");
 689
 690                 // initialiation stuff, not good in the mutator system
 691                 if(autocvar_g_weaponarena != "0")
 692                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 693
 694                 // TODO to mutator system
 695                 if(autocvar_g_norecoil)
 696                         s = strcat(s, ":norecoil");
 697
 698                 // TODO to mutator system
 699                 if(autocvar_g_midair)
 700                         s = strcat(s, ":midair");
 701
 702                 // TODO to mutator system
 703                 if(autocvar_g_minstagib)
 704                         s = strcat(s, ":minstagib");
 705
 706                 // TODO to mutator system
 707                 if(autocvar_g_powerups == 0)
 708                         s = strcat(s, ":no_powerups");
 709                 if(autocvar_g_powerups > 0)
 710                         s = strcat(s, ":powerups");
 711
 712                 GameLogEcho(s);
 713                 GameLogEcho(":gameinfo:end");
 714         }
 715         else
 716                 matchid = strzone(ftos(random()));
 717
 718         cvar_set("nextmap", "");
 719
 720         SetDefaultAlpha();
 721
 722         if(autocvar_g_campaign)
 723                 CampaignPostInit();
 724
 725         fteqcc_testbugs();
 726
 727         Ban_LoadBans();
 728
 729         MapInfo_Enumerate();
 730         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 731
 732         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 733         {
 734                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 735                 if(fd != -1)
 736                 {
 737                         while((s = fgets(fd)))
 738                         {
 739                                 l = tokenize_console(s);
 740                                 if(l < 2)
 741                                         continue;
 742                                 if(argv(0) == "cd")
 743                                 {
 744                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 745                                         print("  cdtrack ", argv(2), "\n");
 746                                 }
 747                                 else if(argv(0) == "fog")
 748                                 {
 749                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 750                                         print("  \"fog\" \"", s, "\"\n");
 751                                 }
 752                                 else if(argv(0) == "set")
 753                                 {
 754                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 755                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 756                                 }
 757                                 else if(argv(0) != "//")
 758                                 {
 759                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 760                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 761                                 }
 762                         }
 763                         fclose(fd);
 764                 }
 765         }
 766
 767         WeaponStats_Init();
 768
 769         WEPSET_ADDSTAT();
 770         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 771         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 772         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 773         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 774         Nagger_Init();
 775
 776         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 777         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 778         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 779         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 780         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 781         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 782         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 783         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 784         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 785         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 786         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 787         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 788         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 789
 790         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 791         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 792
 793         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 794
 795         if(g_ca || g_freezetag)
 796         {
 797                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 798                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 799                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 800                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 801         }
 802         if(g_freezetag)
 803         {
 804                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 805                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 806         }
 807
 808         // g_movementspeed hack
 809         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 810         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 811         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 812         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 813
 814         // secrets
 815         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 816         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 817
 818         next_pingtime = time + 5;
 819
 820         detect_maptype();
 821
 822         // set up information replies for clients and server to use
 823         lsmaps_reply = "^7Maps available: ";
 824         lsnewmaps_reply = "^7Maps without a record set: ";
 825         for(i = 0, j = 0; i < MapInfo_count; ++i)
 826         {
 827                 if(MapInfo_Get_ByID(i))
 828                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 829                         {
 830                                 if(mod(i, 2))
 831                                         col = "^2";
 832                                 else
 833                                         col = "^3";
 834
 835                                 ++j;
 836
 837                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 838
 839                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 840                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 841                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 842                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 843                         }
 844         }
 845
 846         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 847         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 848
 849         maplist_reply = "^7Maps in list: ";
 850         n = tokenize_console(autocvar_g_maplist);
 851         for(i = 0, j = 0; i < n; ++i)
 852         {
 853                 if(MapInfo_CheckMap(argv(i)))
 854                 {
 855                         if(mod(j, 2))
 856                                 col = "^2";
 857                         else
 858                                 col = "^3";
 859                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 860                         ++j;
 861                 }
 862         }
 863         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 864         MapInfo_ClearTemps();
 865
 866         for(i = 0; i < 10; ++i)
 867         {
 868                 records_reply[i] = strzone(getrecords(i));
 869         }
 870
 871         ladder_reply = strzone(getladder());
 872
 873         rankings_reply = strzone(getrankings());
 874
 875         // begin other init
 876         ClientInit_Spawn();
 877         RandomSeed_Spawn();
 878         PingPLReport_Spawn();
 879
 880         CheatInit();
 881
 882         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 883
 884         // fill sv_curl_serverpackages from .serverpackage files
 885         if(autocvar_sv_curl_serverpackages_auto)
 886         {
 887                 s = "";
 888                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 889                 for(i = 0; i < n; ++i)
 890                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 891                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 892                                 s = strcat(s, " ", argv(i));
 893                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 894                 if(fd >= 0)
 895                 {
 896                         j = search_getsize(fd);
 897                         for(i = 0; i < j; ++i)
 898                                 s = strcat(s, " ", search_getfilename(fd, i));
 899                         search_end(fd);
 900                 }
 901                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 902                 if(fd >= 0)
 903                 {
 904                         j = search_getsize(fd);
 905                         for(i = 0; i < j; ++i)
 906                                 s = strcat(s, " ", search_getfilename(fd, i));
 907                         search_end(fd);
 908                 }
 909                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 910         }
 911
 912         PlayerStats_Init();
 913
 914         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 915         modname = "Xonotic";
 916         // physics/balance/config changes that count as mod
 917         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 918                 modname = cvar_string("g_mod_physics");
 919         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 920                 modname = cvar_string("g_mod_balance");
 921         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 922                 modname = cvar_string("g_mod_config");
 923         // weird mutators that deserve to count as mod
 924         if(autocvar_g_minstagib)
 925                 modname = "MinstaGib";
 926         // extra mutators that deserve to count as mod
 927         MUTATOR_CALLHOOK(SetModname);
 928         // weird game types that deserve to count as mod
 929         if(g_cts)
 930                 modname = "CTS";
 931         // save it for later
 932         modname = strzone(modname);
 933
 934         WinningConditionHelper(); // set worldstatus
 935
 936         world_initialized = 1;
 937 }
 938
 939 void spawnfunc_light (void)
 940 {
 941         //makestatic (self); // Who the f___ did that?
 942         remove(self);
 943 }
 944
 945 string GetGametype()
 946 {
 947         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 948 }
 949
 950 string getmapname_stored;
 951 string GetMapname()
 952 {
 953         return mapname;
 954 }
 955
 956 float Map_Count, Map_Current;
 957 string Map_Current_Name;
 958
 959 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 960 float GetMaplistPosition()
 961 {
 962         float pos, idx;
 963         string map;
 964
 965         map = GetMapname();
 966         idx = autocvar_g_maplist_index;
 967
 968         if(idx >= 0)
 969                 if(idx < Map_Count)
 970                         if(map == argv(idx))
 971                                 return idx;
 972
 973         for(pos = 0; pos < Map_Count; ++pos)
 974                 if(map == argv(pos))
 975                         return pos;
 976
 977         // resume normal maplist rotation if current map is not in g_maplist
 978         return idx;
 979 }
 980
 981 float MapHasRightSize(string map)
 982 {
 983         float fh;
 984         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 985         if(autocvar_g_maplist_check_waypoints)
 986         {
 987                 dprint("checkwp "); dprint(map);
 988                 if(!fexists(strcat("maps/", map, ".waypoints")))
 989                 {
 990                         dprint(": no waypoints\n");
 991                         return FALSE;
 992                 }
 993                 dprint(": has waypoints\n");
 994         }
 995
 996         // open map size restriction file
 997         dprint("opensize "); dprint(map);
 998         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 999         if(fh >= 0)
1000         {
1001                 float mapmin, mapmax;
1002                 dprint(": ok, ");
1003                 mapmin = stof(fgets(fh));
1004                 mapmax = stof(fgets(fh));
1005                 fclose(fh);
1006                 if(player_count < mapmin)
1007                 {
1008                         dprint("not enough\n");
1009                         return FALSE;
1010                 }
1011                 if(player_count > mapmax)
1012                 {
1013                         dprint("too many\n");
1014                         return FALSE;
1015                 }
1016                 dprint("right size\n");
1017                 return TRUE;
1018         }
1019         dprint(": not found\n");
1020         return TRUE;
1021 }
1022
1023 string Map_Filename(float position)
1024 {
1025         return strcat("maps/", argv(position), ".bsp");
1026 }
1027
1028 string strwords(string s, float w)
1029 {
1030         float endpos;
1031         for(endpos = 0; w && endpos >= 0; --w)
1032                 endpos = strstrofs(s, " ", endpos + 1);
1033         if(endpos < 0)
1034                 return s;
1035         else
1036                 return substring(s, 0, endpos);
1037 }
1038
1039 float strhasword(string s, string w)
1040 {
1041         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1042 }
1043
1044 void Map_MarkAsRecent(string m)
1045 {
1046         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1047 }
1048
1049 float Map_IsRecent(string m)
1050 {
1051         return strhasword(autocvar_g_maplist_mostrecent, m);
1052 }
1053
1054 float Map_Check(float position, float pass)
1055 {
1056         string filename;
1057         string map_next;
1058         map_next = argv(position);
1059         if(pass <= 1)
1060         {
1061                 if(Map_IsRecent(map_next))
1062                         return 0;
1063         }
1064         filename = Map_Filename(position);
1065         if(MapInfo_CheckMap(map_next))
1066         {
1067                 if(pass == 2)
1068                         return 1;
1069                 if(MapHasRightSize(map_next))
1070                         return 1;
1071                 return 0;
1072         }
1073         else
1074                 dprint( "Couldn't select '", filename, "'..\n" );
1075
1076         return 0;
1077 }
1078
1079 void Map_Goto_SetStr(string nextmapname)
1080 {
1081         if(getmapname_stored != "")
1082                 strunzone(getmapname_stored);
1083         if(nextmapname == "")
1084                 getmapname_stored = "";
1085         else
1086                 getmapname_stored = strzone(nextmapname);
1087 }
1088
1089 void Map_Goto_SetFloat(float position)
1090 {
1091         cvar_set("g_maplist_index", ftos(position));
1092         Map_Goto_SetStr(argv(position));
1093 }
1094
1095 void Map_Goto(float reinit)
1096 {
1097         MapInfo_LoadMap(getmapname_stored, reinit);
1098 }
1099
1100 // return codes of map selectors:
1101 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1102 //   -2 = permanent failure
1103 float() MaplistMethod_Iterate = // usual method
1104 {
1105         float pass, i;
1106
1107         for(pass = 1; pass <= 2; ++pass)
1108         {
1109                 for(i = 1; i < Map_Count; ++i)
1110                 {
1111                         float mapindex;
1112                         mapindex = mod(i + Map_Current, Map_Count);
1113                         if(Map_Check(mapindex, pass))
1114                                 return mapindex;
1115                 }
1116         }
1117         return -1;
1118 }
1119
1120 float() MaplistMethod_Repeat = // fallback method
1121 {
1122         if(Map_Check(Map_Current, 2))
1123                 return Map_Current;
1124         return -2;
1125 }
1126
1127 float() MaplistMethod_Random = // random map selection
1128 {
1129         float i, imax;
1130
1131         imax = 42;
1132
1133         for(i = 0; i <= imax; ++i)
1134         {
1135                 float mapindex;
1136                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1137                 if(Map_Check(mapindex, 1))
1138                         return mapindex;
1139         }
1140         return -1;
1141 }
1142
1143 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1144 // the exponent sets a bias on the map selection:
1145 // the higher the exponent, the less likely "shortly repeated" same maps are
1146 {
1147         float i, j, imax, insertpos;
1148
1149         imax = 42;
1150
1151         for(i = 0; i <= imax; ++i)
1152         {
1153                 string newlist;
1154
1155                 // now reinsert this at another position
1156                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1157                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1158                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1159                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1160
1161                 // insert the current map there
1162                 newlist = "";
1163                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1164                         newlist = strcat(newlist, " ", argv(j));
1165                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1166                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1167                         newlist = strcat(newlist, " ", argv(j));
1168                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1169                 cvar_set("g_maplist", newlist);
1170                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1171
1172                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1173                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1174                 if(Map_Check(Map_Current, 1))
1175                         return Map_Current;
1176         }
1177         return -1;
1178 }
1179
1180 void Maplist_Init()
1181 {
1182         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1183         if(Map_Count == 0)
1184         {
1185                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1186                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1187                 if(autocvar_g_maplist_shuffle)
1188                         ShuffleMaplist();
1189                 localcmd("\nmenu_cmd sync\n");
1190                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1191         }
1192         if(Map_Count == 0)
1193                 error("empty maplist, cannot select a new map");
1194         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1195
1196         if(Map_Current_Name)
1197                 strunzone(Map_Current_Name);
1198         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1199         // this may or may not be correct, but who cares, in the worst case a map
1200         // isn't chosen in the first pass that should have been
1201 }
1202
1203 string GetNextMap()
1204 {
1205         float nextMap;
1206
1207         Maplist_Init();
1208         nextMap = -1;
1209
1210         if(nextMap == -1)
1211                 if(autocvar_g_maplist_shuffle > 0)
1212                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1213
1214         if(nextMap == -1)
1215                 if(autocvar_g_maplist_selectrandom)
1216                         nextMap = MaplistMethod_Random();
1217
1218         if(nextMap == -1)
1219                 nextMap = MaplistMethod_Iterate();
1220
1221         if(nextMap == -1)
1222                 nextMap = MaplistMethod_Repeat();
1223
1224         if(nextMap >= 0)
1225         {
1226                 Map_Goto_SetFloat(nextMap);
1227                 return getmapname_stored;
1228         }
1229
1230         return "";
1231 }
1232
1233 float DoNextMapOverride(float reinit)
1234 {
1235         if(autocvar_g_campaign)
1236         {
1237                 CampaignPostIntermission();
1238                 alreadychangedlevel = TRUE;
1239                 return TRUE;
1240         }
1241         if(autocvar_quit_when_empty)
1242         {
1243                 if(player_count <= currentbots)
1244                 {
1245                         localcmd("quit\n");
1246                         alreadychangedlevel = TRUE;
1247                         return TRUE;
1248                 }
1249         }
1250         if(autocvar_quit_and_redirect != "")
1251         {
1252                 redirection_target = strzone(autocvar_quit_and_redirect);
1253                 alreadychangedlevel = TRUE;
1254                 return TRUE;
1255         }
1256         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1257         {
1258                 localcmd("restart\n");
1259                 alreadychangedlevel = TRUE;
1260                 return TRUE;
1261         }
1262         if(autocvar_nextmap != "")
1263                 if(MapInfo_CheckMap(autocvar_nextmap))
1264                 {
1265                         Map_Goto_SetStr(autocvar_nextmap);
1266                         Map_Goto(reinit);
1267                         alreadychangedlevel = TRUE;
1268                         return TRUE;
1269                 }
1270         if(!reinit && autocvar_lastlevel)
1271         {
1272                 cvar_settemp_restore();
1273                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1274                 alreadychangedlevel = TRUE;
1275                 return TRUE;
1276         }
1277         return FALSE;
1278 }
1279
1280 void GotoNextMap(float reinit)
1281 {
1282         //string nextmap;
1283         //float n, nummaps;
1284         //string s;
1285         if (alreadychangedlevel)
1286                 return;
1287         alreadychangedlevel = TRUE;
1288
1289         {
1290                 string nextMap;
1291                 float allowReset;
1292
1293                 for(allowReset = 1; allowReset >= 0; --allowReset)
1294                 {
1295                         nextMap = GetNextMap();
1296                         if(nextMap != "")
1297                                 break;
1298
1299                         if(allowReset)
1300                         {
1301                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1302                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1303                                 if(autocvar_g_maplist_shuffle)
1304                                         ShuffleMaplist();
1305                                 localcmd("\nmenu_cmd sync\n");
1306                         }
1307                         else
1308                         {
1309                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1310                         }
1311                 }
1312                 Map_Goto(reinit);
1313         }
1314 }
1315
1316
1317 /*
1318 ============
1319 IntermissionThink
1320
1321 When the player presses attack or jump, change to the next level
1322 ============
1323 */
1324 .float autoscreenshot;
1325 void() MapVote_Start;
1326 void() MapVote_Think;
1327 float mapvote_initialized;
1328 void IntermissionThink()
1329 {
1330         FixIntermissionClient(self);
1331
1332         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1333         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1334
1335         if( (server_screenshot || client_screenshot)
1336                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1337         {
1338                 self.autoscreenshot = -1;
1339                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"", GetMapname(), strftime(FALSE, "%s"))); }
1340                 return;
1341         }
1342
1343         if (time < intermission_exittime)
1344                 return;
1345
1346         if(!mapvote_initialized)
1347                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1348                         return;
1349
1350         MapVote_Start();
1351 }
1352
1353 /*
1354 ============
1355 FindIntermission
1356
1357 Returns the entity to view from
1358 ============
1359 */
1360 /*
1361 entity FindIntermission()
1362 {
1363         local   entity spot;
1364         local   float cyc;
1365
1366 // look for info_intermission first
1367         spot = find (world, classname, "info_intermission");
1368         if (spot)
1369         {       // pick a random one
1370                 cyc = random() * 4;
1371                 while (cyc > 1)
1372                 {
1373                         spot = find (spot, classname, "info_intermission");
1374                         if (!spot)
1375                                 spot = find (spot, classname, "info_intermission");
1376                         cyc = cyc - 1;
1377                 }
1378                 return spot;
1379         }
1380
1381 // then look for the start position
1382         spot = find (world, classname, "info_player_start");
1383         if (spot)
1384                 return spot;
1385
1386 // testinfo_player_start is only found in regioned levels
1387         spot = find (world, classname, "testplayerstart");
1388         if (spot)
1389                 return spot;
1390
1391 // then look for the start position
1392         spot = find (world, classname, "info_player_deathmatch");
1393         if (spot)
1394                 return spot;
1395
1396         //objerror ("FindIntermission: no spot");
1397         return world;
1398 }
1399 */
1400
1401 /*
1402 ===============================================================================
1403
1404 RULES
1405
1406 ===============================================================================
1407 */
1408
1409 void DumpStats(float final)
1410 {
1411         float file;
1412         string s;
1413         float to_console;
1414         float to_eventlog;
1415         float to_file;
1416         float i;
1417
1418         to_console = autocvar_sv_logscores_console;
1419         to_eventlog = autocvar_sv_eventlog;
1420         to_file = autocvar_sv_logscores_file;
1421
1422         if(!final)
1423         {
1424                 to_console = TRUE; // always print printstats replies
1425                 to_eventlog = FALSE; // but never print them to the event log
1426         }
1427
1428         if(to_eventlog)
1429                 if(autocvar_sv_eventlog_console)
1430                         to_console = FALSE; // otherwise we get the output twice
1431
1432         if(final)
1433                 s = ":scores:";
1434         else
1435                 s = ":status:";
1436         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1437
1438         if(to_console)
1439                 print(s, "\n");
1440         if(to_eventlog)
1441                 GameLogEcho(s);
1442
1443         file = -1;
1444         if(to_file)
1445         {
1446                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1447                 if(file == -1)
1448                         to_file = FALSE;
1449                 else
1450                         fputs(file, strcat(s, "\n"));
1451         }
1452
1453         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1454         if(to_console)
1455                 print(s, "\n");
1456         if(to_eventlog)
1457                 GameLogEcho(s);
1458         if(to_file)
1459                 fputs(file, strcat(s, "\n"));
1460
1461         FOR_EACH_CLIENT(other)
1462         {
1463                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1464                 {
1465                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1466                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1467                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1468                                 s = strcat(s, ftos(other.team), ":");
1469                         else
1470                                 s = strcat(s, "spectator:");
1471
1472                         if(to_console)
1473                                 print(s, other.netname, "\n");
1474                         if(to_eventlog)
1475                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1476                         if(to_file)
1477                                 fputs(file, strcat(s, other.netname, "\n"));
1478                 }
1479         }
1480
1481         if(teamplay)
1482         {
1483                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1484                 if(to_console)
1485                         print(s, "\n");
1486                 if(to_eventlog)
1487                         GameLogEcho(s);
1488                 if(to_file)
1489                         fputs(file, strcat(s, "\n"));
1490
1491                 for(i = 1; i < 16; ++i)
1492                 {
1493                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1494                         s = strcat(s, ":", ftos(i));
1495                         if(to_console)
1496                                 print(s, "\n");
1497                         if(to_eventlog)
1498                                 GameLogEcho(s);
1499                         if(to_file)
1500                                 fputs(file, strcat(s, "\n"));
1501                 }
1502         }
1503
1504         if(to_console)
1505                 print(":end\n");
1506         if(to_eventlog)
1507                 GameLogEcho(":end");
1508         if(to_file)
1509         {
1510                 fputs(file, ":end\n");
1511                 fclose(file);
1512         }
1513 }
1514
1515 void FixIntermissionClient(entity e)
1516 {
1517         string s;
1518         if(!e.autoscreenshot) // initial call
1519         {
1520                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1521                 e.health = -2342;
1522                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1523                 e.solid = SOLID_NOT;
1524                 e.movetype = MOVETYPE_NONE;
1525                 e.takedamage = DAMAGE_NO;
1526                 if(e.weaponentity)
1527                 {
1528                         e.weaponentity.effects = EF_NODRAW;
1529                         if (e.weaponentity.weaponentity)
1530                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1531                 }
1532                 if(clienttype(e) == CLIENTTYPE_REAL)
1533                 {
1534                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1535                         s = autocvar_sv_intermission_cdtrack;
1536                         if(s != "")
1537                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1538                         msg_entity = e;
1539                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1540                 }
1541         }
1542 }
1543
1544 void minstagib_stop_countdown(entity e);
1545 /*
1546 go to the next level for deathmatch
1547 only called if a time or frag limit has expired
1548 */
1549 void NextLevel()
1550 {
1551         gameover = TRUE;
1552
1553         intermission_running = 1;
1554
1555 // enforce a wait time before allowing changelevel
1556         if(player_count > 0)
1557                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1558         else
1559                 intermission_exittime = -1;
1560
1561         /*
1562         WriteByte (MSG_ALL, SVC_CDTRACK);
1563         WriteByte (MSG_ALL, 3);
1564         WriteByte (MSG_ALL, 3);
1565         // done in FixIntermission
1566         */
1567
1568         //pos = FindIntermission ();
1569
1570         VoteReset();
1571
1572         DumpStats(TRUE);
1573
1574         // send statistics
1575         entity e;
1576         PlayerStats_EndMatch(1);
1577         FOR_EACH_CLIENT(e)
1578                 PlayerStats_AddGlobalInfo(e);
1579         PlayerStats_Shutdown();
1580         WeaponStats_Shutdown();
1581
1582         if(autocvar_sv_eventlog)
1583                 GameLogEcho(":gameover");
1584
1585         GameLogClose();
1586
1587         FOR_EACH_PLAYER(other) {
1588                 minstagib_stop_countdown(other);
1589                 FixIntermissionClient(other);
1590                 if(other.winning)
1591                         bprint(other.netname, " ^7wins.\n");
1592         }
1593
1594         if(autocvar_g_campaign)
1595                 CampaignPreIntermission();
1596
1597         localcmd("\nsv_hook_gameend\n");
1598 }
1599
1600 /*
1601 ============
1602 CheckRules_Player
1603
1604 Exit deathmatch games upon conditions
1605 ============
1606 */
1607 void CheckRules_Player()
1608 {
1609         if (gameover)   // someone else quit the game already
1610                 return;
1611
1612         if(self.deadflag == DEAD_NO)
1613                 self.play_time += frametime;
1614
1615         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1616         //   (div0: and that in CheckRules_World please)
1617 }
1618
1619 float checkrules_equality;
1620 float checkrules_suddendeathwarning;
1621 float checkrules_suddendeathend;
1622 float checkrules_overtimesadded; //how many overtimes have been already added
1623
1624 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1625 float WINNING_YES = 1; // winner found
1626 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1627 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1628
1629 float InitiateSuddenDeath()
1630 {
1631         // Check first whether normal overtimes could be added before initiating suddendeath mode
1632         // - for this timelimit_overtime needs to be >0 of course
1633         // - also check the winning condition calculated in the previous frame and only add normal overtime
1634         //   again, if at the point at which timelimit would be extended again, still no winner was found
1635         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1636         {
1637                 return 1; // need to call InitiateOvertime later
1638         }
1639         else
1640         {
1641                 if(!checkrules_suddendeathend)
1642                 {
1643                         if(autocvar_g_campaign)
1644                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1645                         else
1646                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1647                         if(g_race && !g_race_qualifying)
1648                                 race_StartCompleting();
1649                 }
1650                 return 0;
1651         }
1652 }
1653
1654 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1655 {
1656         ++checkrules_overtimesadded;
1657         //add one more overtime by simply extending the timelimit
1658         float tl;
1659         tl = autocvar_timelimit;
1660         tl += autocvar_timelimit_overtime;
1661         cvar_set("timelimit", ftos(tl));
1662         string minutesPlural;
1663         if (autocvar_timelimit_overtime == 1)
1664                 minutesPlural = " ^3minute";
1665         else
1666                 minutesPlural = " ^3minutes";
1667
1668         bcenterprint(
1669                 strcat(
1670                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1671                         ftos(autocvar_timelimit_overtime),
1672                         minutesPlural,
1673                         " to the game!"
1674                 )
1675         );
1676 }
1677
1678 float GetWinningCode(float fraglimitreached, float equality)
1679 {
1680         if(autocvar_g_campaign == 1)
1681                 if(fraglimitreached)
1682                         return WINNING_YES;
1683                 else
1684                         return WINNING_NO;
1685
1686         else
1687                 if(equality)
1688                         if(fraglimitreached)
1689                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1690                         else
1691                                 return WINNING_NEVER;
1692                 else
1693                         if(fraglimitreached)
1694                                 return WINNING_YES;
1695                         else
1696                                 return WINNING_NO;
1697 }
1698
1699 // set the .winning flag for exactly those players with a given field value
1700 void SetWinners(.float field, float value)
1701 {
1702         entity head;
1703         FOR_EACH_PLAYER(head)
1704                 head.winning = (head.field == value);
1705 }
1706
1707 // set the .winning flag for those players with a given field value
1708 void AddWinners(.float field, float value)
1709 {
1710         entity head;
1711         FOR_EACH_PLAYER(head)
1712                 if(head.field == value)
1713                         head.winning = 1;
1714 }
1715
1716 // clear the .winning flags
1717 void ClearWinners(void)
1718 {
1719         entity head;
1720         FOR_EACH_PLAYER(head)
1721                 head.winning = 0;
1722 }
1723
1724 // Onslaught winning condition:
1725 // game terminates if only one team has a working generator (or none)
1726 float WinningCondition_Onslaught()
1727 {
1728         entity head;
1729         float t1, t2, t3, t4;
1730
1731         WinningConditionHelper(); // set worldstatus
1732
1733         if(inWarmupStage)
1734                 return WINNING_NO;
1735
1736         // first check if the game has ended
1737         t1 = t2 = t3 = t4 = 0;
1738         head = find(world, classname, "onslaught_generator");
1739         while (head)
1740         {
1741                 if (head.health > 0)
1742                 {
1743                         if (head.team == COLOR_TEAM1) t1 = 1;
1744                         if (head.team == COLOR_TEAM2) t2 = 1;
1745                         if (head.team == COLOR_TEAM3) t3 = 1;
1746                         if (head.team == COLOR_TEAM4) t4 = 1;
1747                 }
1748                 head = find(head, classname, "onslaught_generator");
1749         }
1750         if (t1 + t2 + t3 + t4 < 2)
1751         {
1752                 // game over, only one team remains (or none)
1753                 ClearWinners();
1754                 if (t1) SetWinners(team, COLOR_TEAM1);
1755                 if (t2) SetWinners(team, COLOR_TEAM2);
1756                 if (t3) SetWinners(team, COLOR_TEAM3);
1757                 if (t4) SetWinners(team, COLOR_TEAM4);
1758                 dprint("Have a winner, ending game.\n");
1759                 return WINNING_YES;
1760         }
1761
1762         // Two or more teams remain
1763         return WINNING_NO;
1764 }
1765
1766 float LMS_NewPlayerLives()
1767 {
1768         float fl;
1769         fl = autocvar_fraglimit;
1770         if(fl == 0)
1771                 fl = 999;
1772
1773         // first player has left the game for dying too much? Nobody else can get in.
1774         if(lms_lowest_lives < 1)
1775                 return 0;
1776
1777         if(!autocvar_g_lms_join_anytime)
1778                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1779                         return 0;
1780
1781         return bound(1, lms_lowest_lives, fl);
1782 }
1783
1784 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1785 // they win. Otherwise the defending team wins once the timelimit passes.
1786 void assault_new_round();
1787 float WinningCondition_Assault()
1788 {
1789         float status;
1790
1791         WinningConditionHelper(); // set worldstatus
1792
1793         status = WINNING_NO;
1794         // as the timelimit has not yet passed just assume the defending team will win
1795         if(assault_attacker_team == COLOR_TEAM1)
1796         {
1797                 SetWinners(team, COLOR_TEAM2);
1798         }
1799         else
1800         {
1801                 SetWinners(team, COLOR_TEAM1);
1802         }
1803
1804         entity ent;
1805         ent = find(world, classname, "target_assault_roundend");
1806         if(ent)
1807         {
1808                 if(ent.winning) // round end has been triggered by attacking team
1809                 {
1810                         bprint("ASSAULT: round completed...\n");
1811                         SetWinners(team, assault_attacker_team);
1812
1813                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1814
1815                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1816                         {
1817                                 status = WINNING_YES;
1818                         }
1819                         else
1820                         {
1821                                 entity oldself;
1822                                 oldself = self;
1823                                 self = ent;
1824                                 assault_new_round();
1825                                 self = oldself;
1826                         }
1827                 }
1828         }
1829
1830         return status;
1831 }
1832
1833 // LMS winning condition: game terminates if and only if there's at most one
1834 // one player who's living lives. Top two scores being equal cancels the time
1835 // limit.
1836 float WinningCondition_LMS()
1837 {
1838         entity head, head2;
1839         float have_player;
1840         float have_players;
1841         float l;
1842
1843         have_player = FALSE;
1844         have_players = FALSE;
1845         l = LMS_NewPlayerLives();
1846
1847         head = find(world, classname, "player");
1848         if(head)
1849                 have_player = TRUE;
1850         head2 = find(head, classname, "player");
1851         if(head2)
1852                 have_players = TRUE;
1853
1854         if(have_player)
1855         {
1856                 // we have at least one player
1857                 if(have_players)
1858                 {
1859                         // two or more active players - continue with the game
1860                 }
1861                 else
1862                 {
1863                         // exactly one player?
1864
1865                         ClearWinners();
1866                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1867
1868                         if(l)
1869                         {
1870                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1871                                 return WINNING_NO;
1872                         }
1873                         else
1874                         {
1875                                 // a winner!
1876                                 // and assign him his first place
1877                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1878                                 return WINNING_YES;
1879                         }
1880                 }
1881         }
1882         else
1883         {
1884                 // nobody is playing at all...
1885                 if(l)
1886                 {
1887                         // wait for players...
1888                 }
1889                 else
1890                 {
1891                         // SNAFU (maybe a draw game?)
1892                         ClearWinners();
1893                         dprint("No players, ending game.\n");
1894                         return WINNING_YES;
1895                 }
1896         }
1897
1898         // When we get here, we have at least two players who are actually LIVING,
1899         // now check if the top two players have equal score.
1900         WinningConditionHelper();
1901
1902         ClearWinners();
1903         if(WinningConditionHelper_winner)
1904                 WinningConditionHelper_winner.winning = TRUE;
1905         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1906                 return WINNING_NEVER;
1907
1908         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1909         return WINNING_NO;
1910 }
1911
1912 void ShuffleMaplist()
1913 {
1914         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1915 }
1916
1917 float leaderfrags;
1918 float WinningCondition_Scores(float limit, float leadlimit)
1919 {
1920         float limitreached;
1921
1922         // TODO make everything use THIS winning condition (except LMS)
1923         WinningConditionHelper();
1924
1925         if(teamplay)
1926         {
1927                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1928                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1929                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1930                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1931         }
1932
1933         ClearWinners();
1934         if(WinningConditionHelper_winner)
1935                 WinningConditionHelper_winner.winning = 1;
1936         if(WinningConditionHelper_winnerteam >= 0)
1937                 SetWinners(team, WinningConditionHelper_winnerteam);
1938
1939         if(WinningConditionHelper_lowerisbetter)
1940         {
1941                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1942                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1943                 limit = -limit;
1944         }
1945
1946         if(WinningConditionHelper_zeroisworst)
1947                 leadlimit = 0; // not supported in this mode
1948
1949         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1950         // these modes always score in increments of 1, thus this makes sense
1951         {
1952                 if(leaderfrags != WinningConditionHelper_topscore)
1953                 {
1954                         leaderfrags = WinningConditionHelper_topscore;
1955
1956                         if (limit)
1957                         if (leaderfrags == limit - 1)
1958                                 Announce("1fragleft");
1959                         else if (leaderfrags == limit - 2)
1960                                 Announce("2fragsleft");
1961                         else if (leaderfrags == limit - 3)
1962                                 Announce("3fragsleft");
1963                 }
1964         }
1965
1966         limitreached = FALSE;
1967         if(limit)
1968                 if(WinningConditionHelper_topscore >= limit)
1969                         limitreached = TRUE;
1970         if(leadlimit)
1971         {
1972                 float leadlimitreached;
1973                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1974                 if(autocvar_leadlimit_and_fraglimit)
1975                         limitreached = (limitreached && leadlimitreached);
1976                 else
1977                         limitreached = (limitreached || leadlimitreached);
1978         }
1979
1980         game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / max(1, limit), 1));
1981
1982         return GetWinningCode(
1983                 WinningConditionHelper_topscore && limitreached,
1984                 WinningConditionHelper_equality
1985         );
1986 }
1987
1988 float WinningCondition_Race(float fraglimit)
1989 {
1990         float wc;
1991         entity p;
1992         float n, c;
1993
1994         n = 0;
1995         c = 0;
1996         FOR_EACH_PLAYER(p)
1997         {
1998                 ++n;
1999                 if(p.race_completed)
2000                         ++c;
2001         }
2002         if(n && (n == c))
2003                 return WINNING_YES;
2004         wc = WinningCondition_Scores(fraglimit, 0);
2005
2006         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2007         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2008         // do NOT support equality when the laps are all raced!
2009                 return WINNING_STARTSUDDENDEATHOVERTIME;
2010         else
2011                 return WINNING_NEVER;
2012         return wc;
2013 }
2014
2015 float WinningCondition_QualifyingThenRace(float limit)
2016 {
2017         float wc;
2018         wc = WinningCondition_Scores(limit, 0);
2019
2020         // NEVER initiate overtime
2021         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2022         {
2023                 return WINNING_YES;
2024         }
2025
2026         return wc;
2027 }
2028
2029 float WinningCondition_RanOutOfSpawns()
2030 {
2031         entity head;
2032
2033         if(have_team_spawns <= 0)
2034                 return WINNING_NO;
2035
2036         if(autocvar_g_spawn_useallspawns <= 0)
2037                 return WINNING_NO;
2038
2039         if(!some_spawn_has_been_used)
2040                 return WINNING_NO;
2041
2042         team1_score = team2_score = team3_score = team4_score = 0;
2043
2044         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2045         {
2046                 if(head.team == COLOR_TEAM1)
2047                         team1_score = 1;
2048                 else if(head.team == COLOR_TEAM2)
2049                         team2_score = 1;
2050                 else if(head.team == COLOR_TEAM3)
2051                         team3_score = 1;
2052                 else if(head.team == COLOR_TEAM4)
2053                         team4_score = 1;
2054         }
2055
2056         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2057         {
2058                 if(head.team == COLOR_TEAM1)
2059                         team1_score = 1;
2060                 else if(head.team == COLOR_TEAM2)
2061                         team2_score = 1;
2062                 else if(head.team == COLOR_TEAM3)
2063                         team3_score = 1;
2064                 else if(head.team == COLOR_TEAM4)
2065                         team4_score = 1;
2066         }
2067
2068         ClearWinners();
2069         if(team1_score + team2_score + team3_score + team4_score == 0)
2070         {
2071                 checkrules_equality = TRUE;
2072                 return WINNING_YES;
2073         }
2074         else if(team1_score + team2_score + team3_score + team4_score == 1)
2075         {
2076                 float t, i;
2077                 if(team1_score)
2078                         t = COLOR_TEAM1;
2079                 else if(team2_score)
2080                         t = COLOR_TEAM2;
2081                 else if(team3_score)
2082                         t = COLOR_TEAM3;
2083                 else // if(team4_score)
2084                         t = COLOR_TEAM4;
2085                 CheckAllowedTeams(world);
2086                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2087                 {
2088                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2089                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2090                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2091                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2092                 }
2093
2094                 AddWinners(team, t);
2095                 return WINNING_YES;
2096         }
2097         else
2098                 return WINNING_NO;
2099 }
2100
2101 /*
2102 ============
2103 CheckRules_World
2104
2105 Exit deathmatch games upon conditions
2106 ============
2107 */
2108 void ReadyRestart();
2109 void CheckRules_World()
2110 {
2111         float timelimit;
2112         float fraglimit;
2113         float leadlimit;
2114
2115         VoteThink();
2116         MapVote_Think();
2117
2118         SetDefaultAlpha();
2119
2120         /*
2121         MapVote_Think should now do that part
2122         if (intermission_running)
2123                 if (time >= intermission_exittime + 60)
2124                 {
2125                         if(!DoNextMapOverride())
2126                                 GotoNextMap();
2127                         return;
2128                 }
2129         */
2130
2131         if (gameover)   // someone else quit the game already
2132         {
2133                 if(player_count == 0) // Nobody there? Then let's go to the next map
2134                         MapVote_Start();
2135                         // this will actually check the player count in the next frame
2136                         // again, but this shouldn't hurt
2137                 return;
2138         }
2139
2140         timelimit = autocvar_timelimit * 60;
2141         fraglimit = autocvar_fraglimit;
2142         leadlimit = autocvar_leadlimit;
2143
2144         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2145         {
2146                 if(timelimit > 0)
2147                         timelimit = 0; // timelimit is not made for warmup
2148                 if(fraglimit > 0)
2149                         fraglimit = 0; // no fraglimit for now
2150                 leadlimit = 0; // no leadlimit for now
2151         }
2152
2153         if(timelimit > 0)
2154         {
2155                 timelimit += game_starttime;
2156         }
2157         else if (timelimit < 0)
2158         {
2159                 // endmatch
2160                 NextLevel();
2161                 return;
2162         }
2163
2164         if(g_onslaught)
2165                 timelimit = 0; // ONS has its own overtime rule
2166
2167         float wantovertime;
2168         wantovertime = 0;
2169
2170         if(timelimit > game_starttime)
2171                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2172         else
2173                 game_completion_ratio = 0;
2174
2175         if(checkrules_suddendeathend)
2176         {
2177                 if(!checkrules_suddendeathwarning)
2178                 {
2179                         checkrules_suddendeathwarning = TRUE;
2180                         if(g_race && !g_race_qualifying)
2181                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2182                         else
2183                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2184                 }
2185         }
2186         else
2187         {
2188                 if (timelimit && time >= timelimit)
2189                 {
2190                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2191                         {
2192                                 float totalplayers;
2193                                 float playerswithlaps;
2194                                 float readyplayers;
2195                                 entity head;
2196                                 totalplayers = playerswithlaps = readyplayers = 0;
2197                                 FOR_EACH_PLAYER(head)
2198                                 {
2199                                         ++totalplayers;
2200                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2201                                                 ++playerswithlaps;
2202                                         if(head.ready)
2203                                                 ++readyplayers;
2204                                 }
2205
2206                                 // at least 2 of the players have completed a lap: start the RACE
2207                                 // otherwise, the players should end the qualifying on their own
2208                                 if(readyplayers || playerswithlaps >= 2)
2209                                 {
2210                                         checkrules_suddendeathend = 0;
2211                                         ReadyRestart(); // go to race
2212                                         return;
2213                                 }
2214                                 else
2215                                         wantovertime |= InitiateSuddenDeath();
2216                         }
2217                         else
2218                                 wantovertime |= InitiateSuddenDeath();
2219                 }
2220         }
2221
2222         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2223         {
2224                 NextLevel();
2225                 return;
2226         }
2227
2228         float checkrules_status;
2229         checkrules_status = WinningCondition_RanOutOfSpawns();
2230         if(checkrules_status == WINNING_YES)
2231         {
2232                 bprint("Hey! Someone ran out of spawns!\n");
2233         }
2234         else if(g_race && !g_race_qualifying && timelimit >= 0)
2235         {
2236                 checkrules_status = WinningCondition_Race(fraglimit);
2237                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2238         }
2239         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2240         {
2241                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2242                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2243         }
2244         else if(g_assault)
2245         {
2246                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2247         }
2248         else if(g_lms)
2249         {
2250                 checkrules_status = WinningCondition_LMS();
2251         }
2252         else if (g_onslaught)
2253         {
2254                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2255         }
2256         else
2257         {
2258                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2259                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2260         }
2261
2262         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2263         {
2264                 checkrules_status = WINNING_NEVER;
2265                 checkrules_overtimesadded = -1;
2266                 wantovertime |= InitiateSuddenDeath();
2267         }
2268
2269         if(checkrules_status == WINNING_NEVER)
2270                 // equality cases! Nobody wins if the overtime ends in a draw.
2271                 ClearWinners();
2272
2273         if(wantovertime)
2274         {
2275                 if(checkrules_status == WINNING_NEVER)
2276                         InitiateOvertime();
2277                 else
2278                         checkrules_status = WINNING_YES;
2279         }
2280
2281         if(checkrules_suddendeathend)
2282                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2283                         checkrules_status = WINNING_YES;
2284
2285         if(checkrules_status == WINNING_YES)
2286         {
2287                 //print("WINNING\n");
2288                 NextLevel();
2289         }
2290 }
2291
2292 float mapvote_nextthink;
2293 float mapvote_initialized;
2294 float mapvote_keeptwotime;
2295 float mapvote_timeout;
2296 string mapvote_message;
2297 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2298 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2299 float mapvote_screenshot_dirs_count;
2300
2301 float mapvote_count;
2302 float mapvote_count_real;
2303 string mapvote_maps[MAPVOTE_COUNT];
2304 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2305 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2306 float mapvote_maps_suggested[MAPVOTE_COUNT];
2307 string mapvote_suggestions[MAPVOTE_COUNT];
2308 float mapvote_suggestion_ptr;
2309 float mapvote_voters;
2310 float mapvote_selections[MAPVOTE_COUNT];
2311 float mapvote_run;
2312 float mapvote_detail;
2313 float mapvote_abstain;
2314 .float mapvote;
2315
2316 void MapVote_ClearAllVotes()
2317 {
2318         FOR_EACH_CLIENT(other)
2319                 other.mapvote = 0;
2320 }
2321
2322 string MapVote_Suggest(string m)
2323 {
2324         float i;
2325         if(m == "")
2326                 return "That's not how to use this command.";
2327         if(!autocvar_g_maplist_votable_suggestions)
2328                 return "Suggestions are not accepted on this server.";
2329         if(mapvote_initialized)
2330                 return "Can't suggest - voting is already in progress!";
2331         m = MapInfo_FixName(m);
2332         if(!m)
2333                 return "The map you suggested is not available on this server.";
2334         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2335                 if(Map_IsRecent(m))
2336                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2337
2338         if(!MapInfo_CheckMap(m))
2339                 return "The map you suggested does not support the current game mode.";
2340         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2341                 if(mapvote_suggestions[i] == m)
2342                         return "This map was already suggested.";
2343         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2344         {
2345                 i = floor(random() * mapvote_suggestion_ptr);
2346         }
2347         else
2348         {
2349                 i = mapvote_suggestion_ptr;
2350                 mapvote_suggestion_ptr += 1;
2351         }
2352         if(mapvote_suggestions[i] != "")
2353                 strunzone(mapvote_suggestions[i]);
2354         mapvote_suggestions[i] = strzone(m);
2355         if(autocvar_sv_eventlog)
2356                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2357         return strcat("Suggestion of ", m, " accepted.");
2358 }
2359
2360 void MapVote_AddVotable(string nextMap, float isSuggestion)
2361 {
2362         float j, i, o;
2363         string pakfile, mapfile;
2364
2365         if(nextMap == "")
2366                 return;
2367         for(j = 0; j < mapvote_count; ++j)
2368                 if(mapvote_maps[j] == nextMap)
2369                         return;
2370         // suggestions might be no longer valid/allowed after gametype switch!
2371         if(isSuggestion)
2372                 if(!MapInfo_CheckMap(nextMap))
2373                         return;
2374         mapvote_maps[mapvote_count] = strzone(nextMap);
2375         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2376
2377         pakfile = string_null;
2378         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2379         {
2380                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2381                 pakfile = whichpack(strcat(mapfile, ".tga"));
2382                 if(pakfile == "")
2383                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2384                 if(pakfile == "")
2385                         pakfile = whichpack(strcat(mapfile, ".png"));
2386                 if(pakfile != "")
2387                         break;
2388         }
2389         if(i >= mapvote_screenshot_dirs_count)
2390                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2391         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2392                 pakfile = substring(pakfile, o, -1);
2393
2394         mapvote_maps_screenshot_dir[mapvote_count] = i;
2395         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2396
2397         mapvote_count += 1;
2398 }
2399
2400 void MapVote_Spawn();
2401 void MapVote_Init()
2402 {
2403         float i;
2404         float nmax, smax;
2405
2406         MapVote_ClearAllVotes();
2407
2408         mapvote_count = 0;
2409         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2410         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2411
2412         if(mapvote_abstain)
2413                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2414         else
2415                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2416         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2417
2418         // we need this for AddVotable, as that cycles through the screenshot dirs
2419         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2420         if(mapvote_screenshot_dirs_count == 0)
2421                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2422         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2423         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2424                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2425
2426         if(mapvote_suggestion_ptr)
2427                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2428                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2429
2430         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2431                 MapVote_AddVotable(GetNextMap(), FALSE);
2432
2433         if(mapvote_count == 0)
2434         {
2435                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2436                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2437                 if(autocvar_g_maplist_shuffle)
2438                         ShuffleMaplist();
2439                 localcmd("\nmenu_cmd sync\n");
2440                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2441                         MapVote_AddVotable(GetNextMap(), FALSE);
2442         }
2443
2444         mapvote_count_real = mapvote_count;
2445         if(mapvote_abstain)
2446                 MapVote_AddVotable("don't care", 0);
2447
2448         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2449
2450         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2451         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2452         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2453                 mapvote_keeptwotime = 0;
2454         mapvote_message = "Choose a map and press its key!";
2455
2456         MapVote_Spawn();
2457 }
2458
2459 void MapVote_SendPicture(float id)
2460 {
2461         msg_entity = self;
2462         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2463         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2464         WriteByte(MSG_ONE, id);
2465         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2466 }
2467
2468 float MapVote_GetMapMask()
2469 {
2470         float mask, i, power;
2471         mask = 0;
2472         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2473                 if(mapvote_maps[i] != "")
2474                         mask |= power;
2475         return mask;
2476 }
2477
2478 entity mapvote_ent;
2479 float MapVote_SendEntity(entity to, float sf)
2480 {
2481         float i;
2482
2483         if(sf & 1)
2484                 sf &~= 2; // if we send 1, we don't need to also send 2
2485
2486         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2487         WriteByte(MSG_ENTITY, sf);
2488
2489         if(sf & 1)
2490         {
2491                 // flag 1 == initialization
2492                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2493                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2494                 WriteString(MSG_ENTITY, "");
2495                 WriteByte(MSG_ENTITY, mapvote_count);
2496                 WriteByte(MSG_ENTITY, mapvote_abstain);
2497                 WriteByte(MSG_ENTITY, mapvote_detail);
2498                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2499                 if(mapvote_count <= 8)
2500                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2501                 else
2502                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2503                 for(i = 0; i < mapvote_count; ++i)
2504                         if(mapvote_maps[i] != "")
2505                         {
2506                                 if(mapvote_abstain && i == mapvote_count - 1)
2507                                 {
2508                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2509                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2510                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2511                                 }
2512                                 else
2513                                 {
2514                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2515                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2516                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2517                                 }
2518                         }
2519         }
2520
2521         if(sf & 2)
2522         {
2523                 // flag 2 == update of mask
2524                 if(mapvote_count <= 8)
2525                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2526                 else
2527                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2528         }
2529
2530         if(sf & 4)
2531         {
2532                 if(mapvote_detail)
2533                         for(i = 0; i < mapvote_count; ++i)
2534                                 if(mapvote_maps[i] != "")
2535                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2536
2537                 WriteByte(MSG_ENTITY, to.mapvote);
2538         }
2539
2540         return TRUE;
2541 }
2542
2543 void MapVote_Spawn()
2544 {
2545         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2546 }
2547
2548 void MapVote_TouchMask()
2549 {
2550         mapvote_ent.SendFlags |= 2;
2551 }
2552
2553 void MapVote_TouchVotes(entity voter)
2554 {
2555         mapvote_ent.SendFlags |= 4;
2556 }
2557
2558 float MapVote_Finished(float mappos)
2559 {
2560         string result;
2561         float i;
2562         float didntvote;
2563
2564         if(autocvar_sv_eventlog)
2565         {
2566                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2567                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2568                 didntvote = mapvote_voters;
2569                 for(i = 0; i < mapvote_count; ++i)
2570                         if(mapvote_maps[i] != "")
2571                         {
2572                                 didntvote -= mapvote_selections[i];
2573                                 if(i != mappos)
2574                                 {
2575                                         result = strcat(result, ":", mapvote_maps[i]);
2576                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2577                                 }
2578                         }
2579                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2580
2581                 GameLogEcho(result);
2582                 if(mapvote_maps_suggested[mappos])
2583                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2584         }
2585
2586         FOR_EACH_REALCLIENT(other)
2587                 FixClientCvars(other);
2588
2589         Map_Goto_SetStr(mapvote_maps[mappos]);
2590         Map_Goto(0);
2591         alreadychangedlevel = TRUE;
2592         return TRUE;
2593 }
2594 void MapVote_CheckRules_1()
2595 {
2596         float i;
2597
2598         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2599         {
2600                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2601                 mapvote_selections[i] = 0;
2602         }
2603
2604         mapvote_voters = 0;
2605         FOR_EACH_REALCLIENT(other)
2606         {
2607                 ++mapvote_voters;
2608                 if(other.mapvote)
2609                 {
2610                         i = other.mapvote - 1;
2611                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2612                         mapvote_selections[i] = mapvote_selections[i] + 1;
2613                 }
2614         }
2615 }
2616
2617 float MapVote_CheckRules_2()
2618 {
2619         float i;
2620         float firstPlace, secondPlace;
2621         float firstPlaceVotes, secondPlaceVotes;
2622         float mapvote_voters_real;
2623         string result;
2624
2625         if(mapvote_count_real == 1)
2626                 return MapVote_Finished(0);
2627
2628         mapvote_voters_real = mapvote_voters;
2629         if(mapvote_abstain)
2630                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2631
2632         RandomSelection_Init();
2633         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2634                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2635         firstPlace = RandomSelection_chosen_float;
2636         firstPlaceVotes = RandomSelection_best_priority;
2637         //dprint("First place: ", ftos(firstPlace), "\n");
2638         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2639
2640         RandomSelection_Init();
2641         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2642                 if(i != firstPlace)
2643                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2644         secondPlace = RandomSelection_chosen_float;
2645         secondPlaceVotes = RandomSelection_best_priority;
2646         //dprint("Second place: ", ftos(secondPlace), "\n");
2647         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2648
2649         if(firstPlace == -1)
2650                 error("No first place in map vote... WTF?");
2651
2652         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2653                 return MapVote_Finished(firstPlace);
2654
2655         if(mapvote_keeptwotime)
2656                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2657                 {
2658                         float didntvote;
2659                         MapVote_TouchMask();
2660                         mapvote_message = "Now decide between the TOP TWO!";
2661                         mapvote_keeptwotime = 0;
2662                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2663                         result = strcat(result, ":", ftos(firstPlaceVotes));
2664                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2665                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2666                         didntvote = mapvote_voters;
2667                         for(i = 0; i < mapvote_count; ++i)
2668                                 if(mapvote_maps[i] != "")
2669                                 {
2670                                         didntvote -= mapvote_selections[i];
2671                                         if(i != firstPlace)
2672                                                 if(i != secondPlace)
2673                                                 {
2674                                                         result = strcat(result, ":", mapvote_maps[i]);
2675                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2676                                                         if(i < mapvote_count_real)
2677                                                         {
2678                                                                 strunzone(mapvote_maps[i]);
2679                                                                 mapvote_maps[i] = "";
2680                                                                 strunzone(mapvote_maps_pakfile[i]);
2681                                                                 mapvote_maps_pakfile[i] = "";
2682                                                         }
2683                                                 }
2684                                 }
2685                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2686                         if(autocvar_sv_eventlog)
2687                                 GameLogEcho(result);
2688                 }
2689
2690         return FALSE;
2691 }
2692 void MapVote_Tick()
2693 {
2694         float keeptwo;
2695         float totalvotes;
2696
2697         keeptwo = mapvote_keeptwotime;
2698         MapVote_CheckRules_1(); // count
2699         if(MapVote_CheckRules_2()) // decide
2700                 return;
2701
2702         totalvotes = 0;
2703         FOR_EACH_REALCLIENT(other)
2704         {
2705                 // hide scoreboard again
2706                 if(other.health != 2342)
2707                 {
2708                         other.health = 2342;
2709                         other.impulse = 0;
2710                         if(clienttype(other) == CLIENTTYPE_REAL)
2711                         {
2712                                 msg_entity = other;
2713                                 WriteByte(MSG_ONE, SVC_FINALE);
2714                                 WriteString(MSG_ONE, "");
2715                         }
2716                 }
2717
2718                 // clear possibly invalid votes
2719                 if(mapvote_maps[other.mapvote - 1] == "")
2720                         other.mapvote = 0;
2721                 // use impulses as new vote
2722                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2723                         if(mapvote_maps[other.impulse - 1] != "")
2724                         {
2725                                 other.mapvote = other.impulse;
2726                                 MapVote_TouchVotes(other);
2727                         }
2728                 other.impulse = 0;
2729
2730                 if(other.mapvote)
2731                         ++totalvotes;
2732         }
2733
2734         MapVote_CheckRules_1(); // just count
2735 }
2736 void MapVote_Start()
2737 {
2738         if(mapvote_run)
2739                 return;
2740
2741         // wait for stats to be sent first
2742         if(!playerstats_waitforme)
2743                 return;
2744
2745         MapInfo_Enumerate();
2746         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2747                 mapvote_run = TRUE;
2748 }
2749 void MapVote_Think()
2750 {
2751         if(!mapvote_run)
2752                 return;
2753
2754         if(alreadychangedlevel)
2755                 return;
2756
2757         if(time < mapvote_nextthink)
2758                 return;
2759         //dprint("tick\n");
2760
2761         mapvote_nextthink = time + 0.5;
2762
2763         if(!mapvote_initialized)
2764         {
2765                 if(autocvar_rescan_pending == 1)
2766                 {
2767                         cvar_set("rescan_pending", "2");
2768                         localcmd("fs_rescan\nrescan_pending 3\n");
2769                         return;
2770                 }
2771                 else if(autocvar_rescan_pending == 2)
2772                 {
2773                         return;
2774                 }
2775                 else if(autocvar_rescan_pending == 3)
2776                 {
2777                         // now build missing mapinfo files
2778                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2779                                 return;
2780
2781                         // we're done, start the timer
2782                         cvar_set("rescan_pending", "0");
2783                 }
2784
2785                 mapvote_initialized = TRUE;
2786                 if(DoNextMapOverride(0))
2787                         return;
2788                 if(!autocvar_g_maplist_votable || player_count <= 0)
2789                 {
2790                         GotoNextMap(0);
2791                         return;
2792                 }
2793                 MapVote_Init();
2794         }
2795
2796         MapVote_Tick();
2797 }
2798
2799 string GotoMap(string m)
2800 {
2801         if(!MapInfo_CheckMap(m))
2802                 return "The map you chose is not available on this server.";
2803         cvar_set("nextmap", m);
2804         cvar_set("timelimit", "-1");
2805         if(mapvote_initialized || alreadychangedlevel)
2806         {
2807                 if(DoNextMapOverride(0))
2808                         return "Map switch initiated.";
2809                 else
2810                         return "Hm... no. For some reason I like THIS map more.";
2811         }
2812         else
2813                 return "Map switch will happen after scoreboard.";
2814 }
2815
2816
2817 void EndFrame()
2818 {
2819         float altime;
2820         FOR_EACH_REALCLIENT(self)
2821         {
2822                 if(self.classname == "spectator")
2823                 {
2824                         if(self.enemy.typehitsound)
2825                                 self.typehit_time = time;
2826                         else if(self.enemy.hitsound)
2827                                 self.hit_time = time;
2828                 }
2829                 else
2830                 {
2831                         if(self.typehitsound)
2832                                 self.typehit_time = time;
2833                         else if(self.hitsound)
2834                                 self.hit_time = time;
2835                 }
2836         }
2837         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2838         // add 1 frametime because after this, engine SV_Physics
2839         // increases time by a frametime and then networks the frame
2840         // add another frametime because client shows everything with
2841         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2842         // needed!
2843         FOR_EACH_CLIENT(self)
2844         {
2845                 self.hitsound = FALSE;
2846                 self.typehitsound = FALSE;
2847                 antilag_record(self, altime);
2848         }
2849 }
2850
2851
2852 /*
2853  * RedirectionThink:
2854  * returns TRUE if redirecting
2855  */
2856 float redirection_timeout;
2857 float redirection_nextthink;
2858 float RedirectionThink()
2859 {
2860         float clients_found;
2861
2862         if(redirection_target == "")
2863                 return FALSE;
2864
2865         if(!redirection_timeout)
2866         {
2867                 cvar_set("sv_public", "-2");
2868                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2869                 if(redirection_target == "self")
2870                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2871                 else
2872                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2873         }
2874
2875         if(time < redirection_nextthink)
2876                 return TRUE;
2877
2878         redirection_nextthink = time + 1;
2879
2880         clients_found = 0;
2881         FOR_EACH_REALCLIENT(self)
2882         {
2883                 // TODO add timer
2884                 print("Redirecting: sending connect command to ", self.netname, "\n");
2885                 if(redirection_target == "self")
2886                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2887                 else
2888                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2889                 ++clients_found;
2890         }
2891
2892         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2893
2894         if(time > redirection_timeout || clients_found == 0)
2895                 localcmd("\nwait; wait; wait; quit\n");
2896
2897         return TRUE;
2898 }
2899
2900 void TargetMusic_RestoreGame();
2901 void RestoreGame()
2902 {
2903         // Loaded from a save game
2904         // some things then break, so let's work around them...
2905
2906         // Progs DB (capture records)
2907         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2908
2909         // Mapinfo
2910         MapInfo_Shutdown();
2911         MapInfo_Enumerate();
2912         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2913         WeaponStats_Init();
2914
2915         TargetMusic_RestoreGame();
2916 }
2917
2918 void Shutdown()
2919 {
2920         entity e;
2921
2922         gameover = 2;
2923
2924         if(world_initialized > 0)
2925         {
2926                 world_initialized = 0;
2927                 print("Saving persistent data...\n");
2928                 Ban_SaveBans();
2929
2930                 PlayerStats_EndMatch(0);
2931                 FOR_EACH_CLIENT(e)
2932                         PlayerStats_AddGlobalInfo(e);
2933                 PlayerStats_Shutdown();
2934
2935                 if(!cheatcount_total)
2936                 {
2937                         if(autocvar_sv_db_saveasdump)
2938                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2939                         else
2940                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2941                 }
2942                 if(autocvar_developer)
2943                 {
2944                         if(autocvar_sv_db_saveasdump)
2945                                 db_dump(TemporaryDB, "server-temp.db");
2946                         else
2947                                 db_save(TemporaryDB, "server-temp.db");
2948                 }
2949                 CheatShutdown(); // must be after cheatcount check
2950                 db_close(ServerProgsDB);
2951                 db_close(TemporaryDB);
2952                 print("done!\n");
2953                 // tell the bot system the game is ending now
2954                 bot_endgame();
2955
2956                 WeaponStats_Shutdown();
2957                 MapInfo_Shutdown();
2958         }
2959         else if(world_initialized == 0)
2960         {
2961                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2962         }
2963 }