qcsrc/server/g_hook.qc

   1 #include "g_hook.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "weapons/common.qh"
   7 #include "weapons/csqcprojectile.qh"
   8 #include "weapons/weaponsystem.qh"
   9 #include "weapons/selection.qh"
  10 #include "weapons/tracing.qh"
  11 #include "player.qh"
  12 #include "command/common.qh"
  13 #include "round_handler.qh"
  14 #include "../common/state.qh"
  15 #include "../common/physics/player.qh"
  16 #include "../common/vehicles/all.qh"
  17 #include "../common/constants.qh"
  18 #include "../common/util.qh"
  19 #include <common/net_linked.qh>
  20 #include <common/weapons/_all.qh>
  21 #include "../lib/warpzone/common.qh"
  22 #include "../lib/warpzone/server.qh"
  23
  24 .int state;
  25
  26 /*============================================
  27
  28       Wazat's Xonotic Grappling Hook
  29
  30         Contact: Wazat1@gmail.com
  31
  32
  33 Installation instructions:
  34 --------------------------
  35
  36 1. Place hook.c in your gamec source directory with the other source files.
  37
  38 2. Add this line to the bottom of progs.src:
  39
  40 gamec/hook.c
  41
  42 3. Open defs.h and add these lines to the very bottom:
  43
  44 // Wazat's grappling hook
  45 .entity         hook;
  46 void GrapplingHookFrame();
  47 void RemoveGrapplingHook(entity pl);
  48 void SetGrappleHookBindings();
  49 // hook impulses
  50 const float GRAPHOOK_FIRE               = 20;
  51 const float GRAPHOOK_RELEASE            = 21;
  52 // (note: you can change the hook impulse #'s to whatever you please)
  53
  54 4. Open client.c and add this to the top of PutClientInServer():
  55
  56         RemoveGrapplingHook(this); // Wazat's Grappling Hook
  57
  58 5. Find ClientConnect() (in client.c) and add these lines to the bottom:
  59
  60         // Wazat's grappling hook
  61         SetGrappleHookBindings();
  62
  63 6. Still in client.c, find PlayerPreThink and add this line just above the call to W_WeaponFrame:
  64
  65         GrapplingHookFrame();
  66
  67 7. Build and test the mod.  You'll want to bind a key to "+hook" like this:
  68 bind ctrl "+hook"
  69
  70 And you should be done!
  71
  72
  73 ============================================*/
  74
  75 .float hook_length;
  76
  77 void RemoveGrapplingHooks(entity pl)
  78 {
  79         if(pl.move_movetype == MOVETYPE_FLY)
  80                 set_movetype(pl, MOVETYPE_WALK);
  81
  82         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  83     {
  84         .entity weaponentity = weaponentities[slot];
  85         if(!pl.(weaponentity))
  86                 continue; // continue incase other slots exist?
  87         if(pl.(weaponentity).hook)
  88                 delete(pl.(weaponentity).hook);
  89         pl.(weaponentity).hook = NULL;
  90     }
  91
  92         //pl.disableclientprediction = false;
  93 }
  94
  95 void RemoveHook(entity this)
  96 {
  97         entity player = this.realowner;
  98     .entity weaponentity = this.weaponentity_fld;
  99
 100     if(player.(weaponentity).hook == this)
 101         player.(weaponentity).hook = NULL;
 102
 103     if(player.move_movetype == MOVETYPE_FLY)
 104         set_movetype(player, MOVETYPE_WALK);
 105     delete(this);
 106 }
 107
 108 void GrapplingHookReset(entity this)
 109 {
 110         RemoveHook(this);
 111 }
 112
 113 void GrapplingHookThink(entity this);
 114 void GrapplingHook_Stop(entity this)
 115 {
 116         Send_Effect(EFFECT_HOOK_IMPACT, this.origin, '0 0 0', 1);
 117         sound (this, CH_SHOTS, SND_HOOK_IMPACT, VOL_BASE, ATTEN_NORM);
 118
 119         this.state = 1;
 120         setthink(this, GrapplingHookThink);
 121         this.nextthink = time;
 122         settouch(this, func_null);
 123         this.velocity = '0 0 0';
 124         set_movetype(this, MOVETYPE_NONE);
 125         this.hook_length = -1;
 126 }
 127
 128 .vector hook_start, hook_end;
 129 bool GrapplingHookSend(entity this, entity to, int sf)
 130 {
 131         WriteHeader(MSG_ENTITY, ENT_CLIENT_HOOK);
 132         sf = sf & 0x7F;
 133         if(sound_allowed(MSG_BROADCAST, this.realowner))
 134                 sf |= 0x80;
 135         WriteByte(MSG_ENTITY, sf);
 136         if(sf & 1)
 137         {
 138                 WriteByte(MSG_ENTITY, etof(this.realowner));
 139                 WriteByte(MSG_ENTITY, weaponslot(this.weaponentity_fld));
 140         }
 141         if(sf & 2)
 142         {
 143                 WriteVector(MSG_ENTITY, this.hook_start);
 144         }
 145         if(sf & 4)
 146         {
 147                 WriteVector(MSG_ENTITY, this.hook_end);
 148         }
 149         return true;
 150 }
 151
 152 int autocvar_g_grappling_hook_tarzan;
 153
 154 void GrapplingHookThink(entity this)
 155 {
 156         float spd, dist, minlength, pullspeed, ropestretch, ropeairfriction, rubberforce, newlength, rubberforce_overstretch;
 157         vector dir, org, end, v0, dv, v, myorg, vs;
 158         .entity weaponentity = this.weaponentity_fld;
 159         if(this.realowner.(weaponentity).hook != this)  // how did that happen?
 160         {
 161                 error("Owner lost the hook!\n");
 162                 return;
 163         }
 164         if(LostMovetypeFollow(this) || game_stopped || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || ((this.aiment.flags & FL_PROJECTILE) && this.aiment.classname != "nade"))
 165         {
 166                 RemoveHook(this);
 167                 return;
 168         }
 169         if(this.aiment)
 170                 WarpZone_RefSys_AddIncrementally(this, this.aiment);
 171
 172         this.nextthink = time;
 173
 174         int s = W_GunAlign(this.realowner.(weaponentity), STAT(GUNALIGN, this.realowner)) - 1;
 175         vs = hook_shotorigin[s];
 176
 177         makevectors(this.realowner.v_angle);
 178         org = this.realowner.origin + this.realowner.view_ofs + v_forward * vs.x + v_right * -vs.y + v_up * vs.z;
 179         myorg = WarpZone_RefSys_TransformOrigin(this.realowner, this, org);
 180
 181         if(this.hook_length < 0)
 182                 this.hook_length = vlen(myorg - this.origin);
 183
 184         int tarzan = autocvar_g_grappling_hook_tarzan;
 185         entity pull_entity = this.realowner;
 186         float velocity_multiplier = 1;
 187         MUTATOR_CALLHOOK(GrappleHookThink, this, tarzan, pull_entity, velocity_multiplier);
 188         tarzan = M_ARGV(1, int);
 189         pull_entity = M_ARGV(2, entity);
 190         velocity_multiplier = M_ARGV(3, float);
 191
 192         if(this.state == 1)
 193         {
 194                 pullspeed = autocvar_g_balance_grapplehook_speed_pull;//2000;
 195                 // speed the rope is pulled with
 196
 197                 rubberforce = autocvar_g_balance_grapplehook_force_rubber;//2000;
 198                 // force the rope will use if it is stretched
 199
 200                 rubberforce_overstretch = autocvar_g_balance_grapplehook_force_rubber_overstretch;//1000;
 201                 // force the rope will use if it is stretched
 202
 203                 minlength = autocvar_g_balance_grapplehook_length_min;//100;
 204                 // minimal rope length
 205                 // if the rope goes below this length, it isn't pulled any more
 206
 207                 ropestretch = autocvar_g_balance_grapplehook_stretch;//400;
 208                 // if the rope is stretched by more than this amount, more rope is
 209                 // given to you again
 210
 211                 ropeairfriction = autocvar_g_balance_grapplehook_airfriction;//0.2
 212                 // while hanging on the rope, this friction component will help you a
 213                 // bit to control the rope
 214
 215                 bool frozen_pulling = (autocvar_g_grappling_hook_tarzan >= 2 && autocvar_g_balance_grapplehook_pull_frozen);
 216
 217                 dir = this.origin - myorg;
 218                 dist = vlen(dir);
 219                 dir = normalize(dir);
 220
 221                 if(tarzan)
 222                 {
 223                         v = v0 = WarpZone_RefSys_TransformVelocity(pull_entity, this, pull_entity.velocity);
 224
 225                         // first pull the rope...
 226                         if(this.realowner.(weaponentity).hook_state & HOOK_PULLING)
 227                         {
 228                                 newlength = this.hook_length;
 229                                 newlength = max(newlength - pullspeed * frametime, minlength);
 230
 231                                 if(newlength < dist - ropestretch) // overstretched?
 232                                 {
 233                                         newlength = dist - ropestretch;
 234                                         if(v * dir < 0) // only if not already moving in hook direction
 235                                                 v = v + frametime * dir * rubberforce_overstretch;
 236                                 }
 237
 238                                 this.hook_length = newlength;
 239                         }
 240
 241                         if(pull_entity.move_movetype == MOVETYPE_FLY)
 242                                 set_movetype(pull_entity, MOVETYPE_WALK);
 243
 244                         if(this.realowner.(weaponentity).hook_state & HOOK_RELEASING)
 245                         {
 246                                 newlength = dist;
 247                                 this.hook_length = newlength;
 248                         }
 249                         else
 250                         {
 251                                 // then pull the player
 252                                 spd = bound(0, (dist - this.hook_length) / ropestretch, 1);
 253                                 v = v * (1 - frametime * ropeairfriction);
 254                                 v = v + frametime * dir * spd * rubberforce;
 255
 256                                 dv = ((v - v0) * dir) * dir;
 257                                 if(tarzan >= 2)
 258                                 {
 259                                         if(this.aiment.move_movetype == MOVETYPE_WALK || this.aiment.classname == "nade")
 260                                         {
 261                                                 entity aim_ent = ((IS_VEHICLE(this.aiment) && this.aiment.owner) ? this.aiment.owner : this.aiment);
 262                                                 v = v - dv * 0.5;
 263                                                 if((frozen_pulling && STAT(FROZEN, this.aiment)) || !frozen_pulling)
 264                                                 {
 265                                                         this.aiment.velocity = this.aiment.velocity - dv * 0.5;
 266                                                         UNSET_ONGROUND(this.aiment);
 267                                                         if(this.aiment.flags & FL_PROJECTILE)
 268                                                                 UpdateCSQCProjectile(this.aiment);
 269                                                 }
 270                                                 if(this.aiment.classname == "nade")
 271                                                         this.aiment.nextthink = time + autocvar_g_balance_grapplehook_nade_time; // set time after letting go?
 272                                                 aim_ent.pusher = this.realowner;
 273                                                 aim_ent.pushltime = time + autocvar_g_maxpushtime;
 274                                                 aim_ent.istypefrag = PHYS_INPUT_BUTTON_CHAT(aim_ent);
 275                                         }
 276                                 }
 277
 278                                 UNSET_ONGROUND(pull_entity);
 279                         }
 280
 281                         if(!frozen_pulling && !(this.aiment.flags & FL_PROJECTILE))
 282                                 pull_entity.velocity = WarpZone_RefSys_TransformVelocity(this, pull_entity, v * velocity_multiplier);
 283
 284                         if(frozen_pulling && autocvar_g_balance_grapplehook_pull_frozen == 2 && !STAT(FROZEN, this.aiment))
 285                         {
 286                                 RemoveHook(this);
 287                                 return;
 288                         }
 289                 }
 290                 else
 291                 {
 292                         end = this.origin - dir*50;
 293                         dist = vlen(end - myorg);
 294                         if(dist < 200)
 295                                 spd = dist * (pullspeed / 200);
 296                         else
 297                                 spd = pullspeed;
 298                         if(spd < 50)
 299                                 spd = 0;
 300                         this.realowner.velocity = dir*spd;
 301                         set_movetype(this.realowner, MOVETYPE_FLY);
 302
 303                         UNSET_ONGROUND(this.realowner);
 304                 }
 305         }
 306
 307         makevectors(this.angles.x * '-1 0 0' + this.angles.y * '0 1 0');
 308         myorg = WarpZone_RefSys_TransformOrigin(this, this.realowner, this.origin); // + v_forward * (-9);
 309
 310         if(myorg != this.hook_start)
 311         {
 312                 this.SendFlags |= 2;
 313                 this.hook_start = myorg;
 314         }
 315         if(org != this.hook_end)
 316         {
 317                 this.SendFlags |= 4;
 318                 this.hook_end = org;
 319         }
 320 }
 321
 322 void GrapplingHookTouch(entity this, entity toucher)
 323 {
 324         if(toucher.move_movetype == MOVETYPE_FOLLOW)
 325                 return;
 326         PROJECTILE_TOUCH(this, toucher);
 327
 328         GrapplingHook_Stop(this);
 329
 330         if(toucher)
 331                 if(toucher.move_movetype != MOVETYPE_NONE)
 332                 {
 333                         SetMovetypeFollow(this, toucher);
 334                         WarpZone_RefSys_BeginAddingIncrementally(this, this.aiment);
 335                 }
 336
 337         //this.realowner.disableclientprediction = true;
 338 }
 339
 340 void GrapplingHook_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 341 {
 342         if(this.health <= 0)
 343                 return;
 344
 345         if (!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1)) // no exceptions
 346                 return; // g_balance_projectiledamage says to halt
 347
 348         this.health = this.health - damage;
 349
 350         if (this.health <= 0)
 351         {
 352                 if(attacker != this.realowner)
 353                 {
 354                         this.realowner.pusher = attacker;
 355                         this.realowner.pushltime = time + autocvar_g_maxpushtime;
 356                         this.realowner.istypefrag = PHYS_INPUT_BUTTON_CHAT(this.realowner);
 357                 }
 358                 RemoveHook(this);
 359         }
 360 }
 361
 362 void FireGrapplingHook(entity actor, .entity weaponentity)
 363 {
 364         if(forbidWeaponUse(actor)) return;
 365         if(actor.vehicle) return;
 366
 367         makevectors(actor.v_angle);
 368
 369         int s = W_GunAlign(actor.(weaponentity), STAT(GUNALIGN, actor)) - 1;
 370         vector vs = hook_shotorigin[s];
 371
 372         // UGLY WORKAROUND: play this on CH_WEAPON_B so it can't cut off fire sounds
 373         sound (actor, CH_WEAPON_B, SND_HOOK_FIRE, VOL_BASE, ATTEN_NORM);
 374         vector org = actor.origin + actor.view_ofs + v_forward * vs.x + v_right * -vs.y + v_up * vs.z;
 375
 376         tracebox(actor.origin + actor.view_ofs, '-3 -3 -3', '3 3 3', org, MOVE_NORMAL, actor);
 377         org = trace_endpos;
 378
 379         Send_Effect(EFFECT_HOOK_MUZZLEFLASH, org, '0 0 0', 1);
 380
 381         entity missile = WarpZone_RefSys_SpawnSameRefSys(actor);
 382         missile.owner = missile.realowner = actor;
 383         actor.(weaponentity).hook = missile;
 384         missile.weaponentity_fld = weaponentity;
 385         missile.reset = GrapplingHookReset;
 386         missile.classname = "grapplinghook";
 387         missile.flags = FL_PROJECTILE;
 388         IL_PUSH(g_projectiles, missile);
 389         IL_PUSH(g_bot_dodge, missile);
 390
 391         set_movetype(missile, ((autocvar_g_balance_grapplehook_gravity) ? MOVETYPE_TOSS : MOVETYPE_FLY));
 392         PROJECTILE_MAKETRIGGER(missile);
 393
 394         //setmodel (missile, MDL_HOOK); // precision set below
 395         setsize (missile, '-3 -3 -3', '3 3 3');
 396         setorigin(missile, org);
 397
 398         missile.state = 0; // not latched onto anything
 399
 400         W_SetupProjVelocity_Explicit(missile, v_forward, v_up, autocvar_g_balance_grapplehook_speed_fly, 0, 0, 0, false);
 401
 402         missile.angles = vectoangles (missile.velocity);
 403         //missile.glow_color = 250; // 244, 250
 404         //missile.glow_size = 120;
 405         settouch(missile, GrapplingHookTouch);
 406         setthink(missile, GrapplingHookThink);
 407         missile.nextthink = time;
 408
 409         missile.effects = /*EF_FULLBRIGHT | EF_ADDITIVE |*/ EF_LOWPRECISION;
 410
 411         missile.health = autocvar_g_balance_grapplehook_health;//120
 412         missile.event_damage = GrapplingHook_Damage;
 413         missile.takedamage = DAMAGE_AIM;
 414         missile.damageforcescale = 0;
 415         missile.damagedbycontents = (autocvar_g_balance_grapplehook_damagedbycontents);
 416         if(missile.damagedbycontents)
 417                 IL_PUSH(g_damagedbycontents, missile);
 418
 419         missile.hook_start = missile.hook_end = missile.origin;
 420
 421         Net_LinkEntity(missile, false, 0, GrapplingHookSend);
 422 }
 423
 424 void GrappleHookInit()
 425 {
 426         if(g_grappling_hook)
 427         {
 428                 hook_shotorigin[0] = '8 8 -12';
 429                 hook_shotorigin[1] = '8 8 -12';
 430                 hook_shotorigin[2] = '8 8 -12';
 431                 hook_shotorigin[3] = '8 8 -12';
 432         }
 433         else
 434         {
 435                 Weapon w = WEP_HOOK;
 436                 w.wr_init(w);
 437                 hook_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_HOOK.m_id), false, false, 1);
 438                 hook_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_HOOK.m_id), false, false, 2);
 439                 hook_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_HOOK.m_id), false, false, 3);
 440                 hook_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_HOOK.m_id), false, false, 4);
 441         }
 442 }