qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59
  60 float IsDifferentTeam(entity a, entity b)
  61 {
  62         if(teamplay)
  63         {
  64                 if(a.team == b.team)
  65                         return 0;
  66         }
  67         else
  68         {
  69                 if(a == b)
  70                         return 0;
  71         }
  72         return 1;
  73 }
  74
  75 float IsFlying(entity a)
  76 {
  77         if(a.flags & FL_ONGROUND)
  78                 return 0;
  79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  80                 return 0;
  81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  82         if(trace_fraction < 1)
  83                 return 0;
  84         return 1;
  85 }
  86
  87 void UpdateFrags(entity player, float f)
  88 {
  89         PlayerTeamScore_AddScore(player, f);
  90 }
  91
  92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  93 void W_SwitchWeapon_Force(entity e, float w);
  94 entity GiveFrags_randomweapons;
  95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  96 {
  97         // TODO route through PlayerScores instead
  98         if(gameover) return;
  99
 100         if(f < 0)
 101         {
 102                 if(targ == attacker)
 103                 {
 104                         // suicide
 105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 106                 }
 107                 else
 108                 {
 109                         // teamkill
 110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 111                 }
 112         }
 113         else
 114         {
 115                 // regular frag
 116                 PlayerScore_Add(attacker, SP_KILLS, 1);
 117                 if(targ.playerid)
 118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 119         }
 120
 121         PlayerScore_Add(targ, SP_DEATHS, 1);
 122
 123         if(g_arena || g_ca)
 124                 if(autocvar_g_arena_roundbased)
 125                         return;
 126
 127         if(targ != attacker) // not for suicides
 128         if(g_weaponarena_random)
 129         {
 130                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 131                 float culprit;
 132                 culprit = DEATH_WEAPONOF(deathtype);
 133                 if(!culprit)
 134                         culprit = attacker.weapon;
 135                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 136                         culprit = attacker.weapon;
 137
 138                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 139                 {
 140                         // no exchange
 141                 }
 142                 else
 143                 {
 144                         if(!GiveFrags_randomweapons)
 145                         {
 146                                 GiveFrags_randomweapons = spawn();
 147                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 148                         }
 149
 150                         if(inWarmupStage)
 151                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 152                         else
 153                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 154
 155                         // all others (including the culprit): remove
 156                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 157                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 158
 159                         // among the remaining ones, choose one by random
 160                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 161
 162                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 163                         {
 164                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 165                                 WEPSET_ANDNOT_EW(attacker, culprit);
 166                         }
 167                 }
 168
 169                 // after a frag, choose another random weapon set
 170                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 171                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 172         }
 173
 174         // FIXME fix the mess this is (we have REAL points now!)
 175         entity oldself;
 176         oldself = self;
 177         self = attacker;
 178         frag_attacker = attacker;
 179         frag_target = targ;
 180         frag_score = f;
 181         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 182         {
 183                 f = frag_score;
 184                 self = oldself;
 185         }
 186         else
 187         {
 188                 self = oldself;
 189                 if(g_runematch)
 190                 {
 191                         f = RunematchHandleFrags(attacker, targ, f);
 192                 }
 193                 else if(g_lms)
 194                 {
 195                         // remove a life
 196                         float tl;
 197                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 198                         if(tl < lms_lowest_lives)
 199                                 lms_lowest_lives = tl;
 200                         if(tl <= 0)
 201                         {
 202                                 if(!lms_next_place)
 203                                         lms_next_place = player_count;
 204                                 else
 205                                         lms_next_place = min(lms_next_place, player_count);
 206                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 207                                 --lms_next_place;
 208                         }
 209                         f = 0;
 210                 }
 211         }
 212
 213         attacker.totalfrags += f;
 214
 215         if(f)
 216                 UpdateFrags(attacker, f);
 217 }
 218
 219 /*string Obituary_ExtraFragInfo(entity player) // Extra fragmessage information
 220 {
 221         string health_output = string_null;
 222         string ping_output = string_null;
 223         string handicap_output = string_null;
 224         string output = string_null;
 225
 226         if(autocvar_sv_fraginfo && ((autocvar_sv_fraginfo == 2) || inWarmupStage))
 227         {
 228                 // health/armor of attacker (person who killed you)
 229                 if(autocvar_sv_fraginfo_stats && (player.health >= 1))
 230                         health_output = strcat("^7(Health ^1", ftos(rint(player.health)), "^7 / Armor ^2", ftos(rint(player.armorvalue)), "^7)");
 231
 232                 // ping display
 233                 if(autocvar_sv_fraginfo_ping)
 234                         ping_output = ((clienttype(player) == CLIENTTYPE_BOT) ? "^2Bot" : strcat("Ping ", ((player.ping >= 150) ? "^1" : "^2"), ftos(rint(player.ping)), "ms"));
 235
 236                 // handicap display
 237                 if(autocvar_sv_fraginfo_handicap)
 238                 {
 239                         if(autocvar_sv_fraginfo_handicap == 2)
 240                                 handicap_output = strcat(output, strcat("Handicap ^2", ((player.cvar_cl_handicap <= 1) ? "Off" : ftos(rint(player.cvar_cl_handicap)))));
 241                         else if(player.cvar_cl_handicap) // with _handicap 1, only show this if there actually is a handicap enabled.
 242                                 handicap_output = strcat("Handicap ^2", ftos(rint(player.cvar_cl_handicap)));
 243                 }
 244
 245                 // format the string
 246                 output = strcat(health_output, (health_output ? ((ping_output || handicap_output) ? " ^7(" : "") : ((ping_output || handicap_output) ? "^7(" : "")),
 247                         ping_output, (handicap_output ? "^7 / " : ""),
 248                         handicap_output, ((ping_output || handicap_output) ? "^7)" : ""));
 249
 250                 // add new line to the beginning if there is a message
 251                 if(output) { output = strcat("\n", output); }
 252         }
 253
 254         return output;
 255 }*/
 256
 257 string AppendItemcodes(string s, entity player)
 258 {
 259         float w;
 260         w = player.weapon;
 261         //if(w == 0)
 262         //      w = player.switchweapon;
 263         if(w == 0)
 264                 w = player.cnt; // previous weapon!
 265         s = strcat(s, ftos(w));
 266         if(time < player.strength_finished)
 267                 s = strcat(s, "S");
 268         if(time < player.invincible_finished)
 269                 s = strcat(s, "I");
 270         if(player.flagcarried != world)
 271                 s = strcat(s, "F");
 272         if(player.BUTTON_CHAT)
 273                 s = strcat(s, "T");
 274         if(player.kh_next)
 275                 s = strcat(s, "K");
 276         if(player.runes)
 277                 s = strcat(s, "|", ftos(player.runes));
 278         return s;
 279 }
 280
 281 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 282 {
 283         string s;
 284         if(!autocvar_sv_eventlog)
 285                 return;
 286         s = strcat(":kill:", mode);
 287         s = strcat(s, ":", ftos(killer.playerid));
 288         s = strcat(s, ":", ftos(killed.playerid));
 289         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 290         s = strcat(s, ":items=");
 291         s = AppendItemcodes(s, killer);
 292         if(killed != killer)
 293         {
 294                 s = strcat(s, ":victimitems=");
 295                 s = AppendItemcodes(s, killed);
 296         }
 297         GameLogEcho(s);
 298 }
 299
 300 #define INFO_NO_MSG 0
 301
 302 void Obituary_SpecialDeath(entity notif_target, float murder, float deathtype, string s1, string s2, float f1, float f2, float f3)
 303 {
 304         float handled = 0, hits = 0;
 305         if(DEATH_ISSPECIAL(deathtype))
 306         {
 307                 #define DEATHTYPE(name,msg_death,msg_death_by,position) \
 308                         { if(deathtype == max(0, name)) \
 309                         { \
 310                                 #if msg_death != NO_MSG \
 311                                         if not(murder) \
 312                                         { \
 313                                                 Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_DEATH, msg_death, s1, s2, "", "", f1, f2, f3, 0); \
 314                                                 Send_Notification_WOVA(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, INFO_##msg_death, s1, s2, "", "", f1, f2, f3, 0); \
 315                                                 ++handled; \
 316                                         } \
 317                                 #endif \
 318                                 #if msg_death_by != NO_MSG \
 319                                         if(murder) \
 320                                         { \
 321                                                 Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_DEATH, msg_death_by, s1, s2, "", "", f1, f2, f3, 0); \
 322                                                 Send_Notification_WOVA(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, INFO_##msg_death_by, s1, s2, "", "", f1, f2, f3, 0); \
 323                                                 ++handled; \
 324                                         } \
 325                                 #endif \
 326                                 ++hits; \
 327                         } }
 328
 329                 DEATHTYPES
 330                 #undef DEATHTYPE
 331
 332                 if not(hits)
 333                 {
 334                         backtrace("Obituary_SpecialDeath(): Unhandled deathtype- Please notify Samual!\n");
 335                 }
 336                 if not(handled)
 337                 {
 338                         dprint(sprintf("Obituary_SpecialDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification!\n", Deathtype_Name(deathtype), deathtype));
 339                         return;
 340                 }
 341         }
 342 }
 343
 344 float w_deathtype;
 345 float Obituary_WeaponDeath(entity notif_target, float murder, float deathtype, string s1, string s2, float f1, float f2)
 346 {
 347         float death_weapon = DEATH_WEAPONOF(deathtype);
 348
 349         if(death_weapon)
 350         {
 351                 w_deathtype = deathtype;
 352                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 353                 w_deathtype = FALSE;
 354
 355                 if(death_message)
 356                 {
 357                         Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_WEAPON, death_message, s1, s2, "", "", f1, f2, 0, 0);
 358                         Send_Notification_WOVA(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, msg_weapon_notifs[death_message - 1].nent_msginfo.nent_id, s1, s2, "", "", f1, f2, 0, 0);
 359                         //print(Get_Field_Value(F_INFVAL, MSG_WEAPON, death_message), "\n");
 360                 }
 361                 else { dprint(sprintf("Obituary_WeaponDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification for weapon %d!\n", Deathtype_Name(deathtype), deathtype, death_weapon)); }
 362
 363                 return TRUE;
 364         }
 365         return FALSE;
 366 }
 367
 368 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 369 {
 370         // Sanity check
 371         if not(targ.classname == STR_PLAYER) { backtrace("Obituary called on non-player?!\n"); return; }
 372
 373         // Declarations
 374         string s1 = "", s2 = "";
 375         float f1 = 0, f2 = 0, f3 = 0;
 376         float notif_firstblood = FALSE;
 377
 378         //dprint(sprintf("Obituary(): Deathtype = %s (%d), Attacker = %s, Inflictor = %s, Target = %s...\n", Deathtype_Name(deathtype), deathtype, attacker.netname, inflictor.netname, targ.netname));
 379
 380         // =======
 381         // SUICIDE
 382         // =======
 383         if(targ == attacker)
 384         {
 385                 if(DEATH_ISSPECIAL(deathtype))
 386                 {
 387                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 388                         {
 389                                 s1 = targ.netname;
 390                                 f1 = targ.team;
 391                         }
 392                         else
 393                         {
 394                                 switch(deathtype)
 395                                 {
 396                                         case DEATH_MIRRORDAMAGE:
 397                                         {
 398                                                 s1 = targ.netname;
 399                                                 f1 = targ.killcount;
 400                                                 break;
 401                                         }
 402
 403                                         default:
 404                                         {
 405                                                 s1 = targ.netname;
 406                                                 f1 = targ.killcount;
 407                                                 s2 = "";
 408                                                 f2 = f3 = 0;
 409                                                 break;
 410                                         }
 411                                 }
 412                                 LogDeath("suicide", deathtype, targ, targ);
 413                                 GiveFrags(attacker, targ, -1, deathtype);
 414                         }
 415
 416                         Obituary_SpecialDeath(targ, FALSE, deathtype, s1, s2, f1, f2, 0);
 417                 }
 418                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, "", targ.killcount, 0))
 419                 {
 420                         backtrace("SUICIDE: what the hell happened here?\n");
 421                 }
 422         }
 423
 424         // ======
 425         // MURDER
 426         // ======
 427         else if(attacker.classname == "player")
 428         {
 429                 s1 = attacker.netname;
 430                 s2 = targ.netname;
 431
 432                 if(!IsDifferentTeam(attacker, targ))
 433                 {
 434                         LogDeath("tk", deathtype, attacker, targ);
 435                         GiveFrags(attacker, targ, -1, deathtype);
 436
 437                         attacker.killcount = 0;
 438
 439                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, s2);
 440                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, s1);
 441                         Send_Notification(NOTIF_ANY, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), s2, s1, targ.killcount);
 442
 443                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 444                         // No need for specific death/weapon messages...
 445                 }
 446                 else
 447                 {
 448                         LogDeath("frag", deathtype, attacker, targ);
 449                         GiveFrags(attacker, targ, 1, deathtype);
 450
 451                         attacker.taunt_soundtime = time + 1;
 452                         attacker.killcount = attacker.killcount + 1;
 453
 454                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 455                                 case counta: \
 456                                 { \
 457                                         AnnounceTo(attacker, strcat(#countb, "kills")); \
 458                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
 459                                         break; \
 460                                 }
 461                         switch(attacker.killcount)
 462                         {
 463                                 KILL_SPREE_LIST
 464                                 default: break;
 465                         }
 466                         #undef SPREE_ITEM
 467
 468                         if(!checkrules_firstblood)
 469                         {
 470                                 checkrules_firstblood = TRUE;
 471                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 472                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 473                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 474                         }
 475
 476                         float kill_count_to_attacker;
 477                         float kill_count_to_target;
 478                         if(notif_firstblood)
 479                         {
 480                                 kill_count_to_attacker = -1;
 481                                 kill_count_to_target = -2;
 482                         }
 483                         else
 484                         {
 485                                 kill_count_to_attacker = attacker.killcount;
 486                                 kill_count_to_target = 0;
 487                         }
 488
 489                         if(targ.istypefrag)
 490                         {
 491                                 if(attacker.FRAG_VERBOSE)
 492                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 493                                 else
 494                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG, targ.netname, kill_count_to_attacker);
 495
 496                                 if(targ.FRAG_VERBOSE)
 497                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 498                                 else
 499                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED, attacker.netname, kill_count_to_target);
 500                         }
 501                         else
 502                         {
 503                                 if(attacker.FRAG_VERBOSE)
 504                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 505                                 else
 506                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG, targ.netname, kill_count_to_attacker);
 507
 508                                 if(targ.FRAG_VERBOSE)
 509                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 510                                 else
 511                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED, attacker.netname, kill_count_to_target);
 512                         }
 513
 514                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, targ.killcount, kill_count_to_attacker))
 515                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, targ.killcount, kill_count_to_attacker, 0);
 516                 }
 517         }
 518
 519         // =============
 520         // ACCIDENT/TRAP
 521         // =============
 522         else
 523         {
 524                 switch(deathtype)
 525                 {
 526                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 527                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 528                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 529                         /*case DEATH_HURTTRIGGER:
 530                         {
 531                                 s1 = targ.netname;
 532                                 s2 = inflictor.message;
 533                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 534                                 break;
 535                         }*/
 536
 537                         case DEATH_CUSTOM:
 538                         {
 539                                 s1 = targ.netname;
 540                                 s2 = deathmessage;
 541                                 f1 = targ.killcount;
 542                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 543                                 f2 = f3 = 0;
 544                                 break;
 545                         }
 546
 547                         default:
 548                         {
 549                                 s1 = targ.netname;
 550                                 f1 = targ.killcount;
 551                                 s2 = "";
 552                                 f2 = f3 = 0;
 553                                 break;
 554                         }
 555                 }
 556
 557                 LogDeath("accident", deathtype, targ, targ);
 558                 GiveFrags(targ, targ, -1, deathtype);
 559
 560                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 561                 {
 562                         AnnounceTo(targ, "botlike");
 563                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 564                 }
 565
 566                 Obituary_SpecialDeath(targ, FALSE, deathtype, s1, s2, f1, f2, f3);
 567         }
 568
 569         // Set final information for the death
 570         targ.death_origin = targ.origin;
 571         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 572         if(targ.killcount) { targ.killcount = 0; }
 573 }
 574
 575 // these are updated by each Damage call for use in button triggering and such
 576 entity damage_targ;
 577 entity damage_inflictor;
 578 entity damage_attacker;
 579
 580 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 581 {
 582         float mirrordamage;
 583         float mirrorforce;
 584         float teamdamage0;
 585         entity attacker_save;
 586         mirrordamage = 0;
 587         mirrorforce = 0;
 588
 589         if (gameover || targ.killcount == -666)
 590                 return;
 591
 592         entity oldself;
 593         oldself = self;
 594         self = targ;
 595         damage_targ = targ;
 596         damage_inflictor = inflictor;
 597         damage_attacker = attacker;
 598                 attacker_save = attacker;
 599
 600         if(targ.classname == "player")
 601                 if(targ.hook)
 602                         if(targ.hook.aiment)
 603                                 if(targ.hook.aiment == attacker)
 604                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 605
 606         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 607         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 608         {
 609                 if(targ.classname == "player")
 610                         if not(IsDifferentTeam(targ, attacker))
 611                         {
 612                                 self = oldself;
 613                                 return;
 614                         }
 615         }
 616
 617         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 618         {
 619                 // These are ALWAYS lethal
 620                 // No damage modification here
 621                 // Instead, prepare the victim for his death...
 622                 targ.armorvalue = 0;
 623                 targ.spawnshieldtime = 0;
 624                 targ.health = 0.9; // this is < 1
 625                 targ.flags -= targ.flags & FL_GODMODE;
 626                 damage = 100000;
 627         }
 628         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 629         {
 630                 // no processing
 631         }
 632         else
 633         {
 634                 /*
 635                 skill based bot damage? gtfo. (tZork)
 636                 if (targ.classname == "player")
 637                 if (attacker.classname == "player")
 638                 if (!targ.isbot)
 639                 if (attacker.isbot)
 640                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 641         */
 642
 643                 // nullify damage if teamplay is on
 644                 if(deathtype != DEATH_TELEFRAG)
 645                 if(attacker.classname == "player")
 646                 {
 647                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 648                         {
 649                                 damage = 0;
 650                                 force = '0 0 0';
 651                         }
 652                         else if(!IsDifferentTeam(attacker, targ))
 653                         {
 654                                 if(autocvar_teamplay_mode == 1)
 655                                         damage = 0;
 656                                 else if(attacker != targ)
 657                                 {
 658                                         if(autocvar_teamplay_mode == 3)
 659                                                 damage = 0;
 660                                         else if(autocvar_teamplay_mode == 4)
 661                                         {
 662                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 663                                                 {
 664                                                         teamdamage0 = max(attacker.dmg_team, autocvar_g_teamdamage_threshold);
 665                                                         attacker.dmg_team = attacker.dmg_team + damage;
 666                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 667                                                                 mirrordamage = autocvar_g_mirrordamage * (attacker.dmg_team - teamdamage0);
 668                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 669                                                         if(g_minstagib)
 670                                                         {
 671                                                                 if(autocvar_g_friendlyfire == 0)
 672                                                                         damage = 0;
 673                                                         }
 674                                                         else if(g_ca)
 675                                                                 damage = 0;
 676                                                         else
 677                                                                 damage = autocvar_g_friendlyfire * damage;
 678                                                         // mirrordamage will be used LATER
 679
 680                                                         if(autocvar_g_mirrordamage_virtual)
 681                                                         {
 682                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 683                                                                 attacker.dmg_take += v_x;
 684                                                                 attacker.dmg_save += v_y;
 685                                                                 attacker.dmg_inflictor = inflictor;
 686                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 687                                                                 mirrorforce = 0;
 688                                                         }
 689
 690                                                         if(autocvar_g_friendlyfire_virtual)
 691                                                         {
 692                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 693                                                                 targ.dmg_take += v_x;
 694                                                                 targ.dmg_save += v_y;
 695                                                                 targ.dmg_inflictor = inflictor;
 696                                                                 damage = 0;
 697                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 698                                                                         force = '0 0 0';
 699                                                         }
 700                                                 }
 701                                                 else
 702                                                         damage = 0;
 703                                         }
 704                                 }
 705                         }
 706                 }
 707
 708                 if(targ.classname == "player")
 709                 if(attacker.classname == "player")
 710                 if(attacker != targ)
 711                 {
 712                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 713                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 714                 }
 715
 716                 if(targ.classname == "player")
 717                 if (g_minstagib)
 718                 {
 719                         if ((deathtype == DEATH_FALL)  ||
 720                                 (deathtype == DEATH_DROWN) ||
 721                                 (deathtype == DEATH_SLIME) ||
 722                                 (deathtype == DEATH_LAVA)  ||
 723                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 724                         {
 725                                 self = oldself;
 726                                 return;
 727                         }
 728                         if(damage > 0)
 729                             damage = 10000;
 730                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 731                         {
 732                                 targ.armorvalue -= 1;
 733                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 734                                 damage = 0;
 735                                 targ.hitsound += 1;
 736                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 737                         }
 738                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 739                         {
 740                                 damage = 0;
 741                                 mirrordamage = 0;
 742                                 if (targ != attacker)
 743                                 {
 744                                         if ((targ.health >= 1) && (targ.classname == "player"))
 745                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 746                                         force = '0 0 0';
 747                                         // keep mirrorforce
 748                                         attacker = targ;
 749                                 }
 750                         }
 751                 }
 752
 753                 if not(DEATH_ISSPECIAL(deathtype))
 754                 {
 755                         damage *= g_weapondamagefactor;
 756                         mirrordamage *= g_weapondamagefactor;
 757                         force = force * g_weaponforcefactor;
 758                         mirrorforce *= g_weaponforcefactor;
 759                 }
 760
 761                 // should this be changed at all? If so, in what way?
 762                 frag_attacker = attacker;
 763                 frag_target = targ;
 764                 frag_damage = damage;
 765                 frag_force = force;
 766         frag_deathtype = deathtype;
 767                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 768                 damage = frag_damage;
 769                 force = frag_force;
 770
 771                 // apply strength multiplier
 772                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 773                 {
 774                         if(targ == attacker)
 775                         {
 776                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 777                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 778                         }
 779                         else
 780                         {
 781                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 782                                 force = force * autocvar_g_balance_powerup_strength_force;
 783                         }
 784                 }
 785
 786                 // apply invincibility multiplier
 787                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 788                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 789
 790                 if (targ == attacker)
 791                 {
 792                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 793                                 damage = 0;
 794                         else
 795                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 796                 }
 797
 798                 if(g_runematch)
 799                 {
 800                         // apply strength rune
 801                         if (attacker.runes & RUNE_STRENGTH)
 802                         {
 803                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 804                                 {
 805                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 806                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 807                                 }
 808                                 else
 809                                 {
 810                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 811                                         force = force * autocvar_g_balance_rune_strength_force;
 812                                 }
 813                         }
 814                         else if (attacker.runes & CURSE_WEAK)
 815                         {
 816                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 817                                 force = force * autocvar_g_balance_curse_weak_force;
 818                         }
 819
 820                         // apply defense rune
 821                         if (targ.runes & RUNE_DEFENSE)
 822                         {
 823                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 824                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 825                                 else
 826                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 827                         }
 828                         else if (targ.runes & CURSE_VULNER)
 829                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 830                 }
 831
 832                 // count the damage
 833                 if(attacker)
 834                 if(!targ.deadflag)
 835                 if(targ.takedamage == DAMAGE_AIM)
 836                 if(targ != attacker)
 837                 {
 838                         entity victim;
 839                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 840                                 victim = targ.owner;
 841                         else
 842                                 victim = targ;
 843
 844                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 845                         {
 846                                 if(IsDifferentTeam(victim, attacker))
 847                                 {
 848                                         if(damage > 0)
 849                                         {
 850                                                 if(deathtype != DEATH_FIRE)
 851                                                 {
 852                                                         if(victim.BUTTON_CHAT)
 853                                                                 attacker.typehitsound += 1;
 854                                                         else
 855                                                                 attacker.hitsound += 1;
 856                                                 }
 857
 858                                                 damage_goodhits += 1;
 859                                                 damage_gooddamage += damage;
 860
 861                                                 if not(DEATH_ISSPECIAL(deathtype))
 862                                                 {
 863                                                         if(targ.classname == "player") // don't do this for vehicles
 864                                                         if(!g_minstagib)
 865                                                         if(IsFlying(victim))
 866                                                                 yoda = 1;
 867
 868                                                         if(g_minstagib)
 869                                                         if(victim.items & IT_STRENGTH)
 870                                                                 yoda = 1;
 871                                                 }
 872                                         }
 873                                 }
 874                                 else
 875                                 {
 876                                         if(deathtype != DEATH_FIRE)
 877                                         {
 878                                                 attacker.typehitsound += 1;
 879                                         }
 880                                         if(mirrordamage > 0)
 881                                                 if(time > attacker.teamkill_complain)
 882                                                 {
 883                                                         attacker.teamkill_complain = time + 5;
 884                                                         attacker.teamkill_soundtime = time + 0.4;
 885                                                         attacker.teamkill_soundsource = targ;
 886                                                 }
 887                                 }
 888                         }
 889                 }
 890         }
 891
 892         // apply push
 893         if (self.damageforcescale)
 894         if (vlen(force))
 895         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 896         {
 897                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 898                 if(self.movetype == MOVETYPE_PHYSICS)
 899                 {
 900                         entity farcent;
 901                         farcent = spawn();
 902                         farcent.classname = "farce";
 903                         farcent.enemy = self;
 904                         farcent.movedir = farce * 10;
 905                         if(self.mass)
 906                                 farcent.movedir = farcent.movedir * self.mass;
 907                         farcent.origin = hitloc;
 908                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 909                         farcent.nextthink = time + 0.1;
 910                         farcent.think = SUB_Remove;
 911                 }
 912                 else
 913                         self.velocity = self.velocity + farce;
 914                 self.flags &~= FL_ONGROUND;
 915                 UpdateCSQCProjectile(self);
 916         }
 917         // apply damage
 918         if (damage != 0 || (self.damageforcescale && vlen(force)))
 919         if (self.event_damage)
 920                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 921         self = oldself;
 922
 923         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 924         {
 925                 if(g_runematch)
 926                 {
 927                         if (attacker.runes & RUNE_VAMPIRE)
 928                         {
 929                         // apply vampire rune
 930                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 931                                 {
 932                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 933                                         attacker.health = bound(
 934                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 935                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 936                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 937                                 }
 938                                 else
 939                                 {
 940                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 941                                         attacker.health = bound(
 942                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 943                                                                                         // empathy won't let you gain health in the same way...
 944                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 945                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 946                                         }
 947                         }
 948                         // apply empathy curse
 949                         else if (attacker.runes & CURSE_EMPATHY)
 950                         {
 951                                 attacker.health = bound(
 952                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 953                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 954                                         attacker.health);
 955                         }
 956                 }
 957         }
 958
 959         // apply mirror damage if any
 960         if(mirrordamage > 0 || mirrorforce > 0)
 961         {
 962                 attacker = attacker_save;
 963                 if(g_minstagib)
 964                 if(mirrordamage > 0)
 965                 {
 966                         // just lose extra LIVES, don't kill the player for mirror damage
 967                         if(attacker.armorvalue > 0)
 968                         {
 969                                 attacker.armorvalue = attacker.armorvalue - 1;
 970                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 971                                 attacker.hitsound += 1;
 972                         }
 973                         mirrordamage = 0;
 974                 }
 975
 976                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 977                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 978         }
 979 }
 980
 981 float RadiusDamage_running;
 982 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 983         // Returns total damage applies to creatures
 984 {
 985         entity  targ;
 986         vector  blastorigin;
 987         vector  force;
 988         float   total_damage_to_creatures;
 989         entity  next;
 990         float   tfloordmg;
 991         float   tfloorforce;
 992
 993         float stat_damagedone;
 994
 995         if(RadiusDamage_running)
 996         {
 997                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 998                 return 0;
 999         }
1000
1001         RadiusDamage_running = 1;
1002
1003         tfloordmg = autocvar_g_throughfloor_damage;
1004         tfloorforce = autocvar_g_throughfloor_force;
1005
1006         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
1007         total_damage_to_creatures = 0;
1008
1009         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
1010                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
1011                 {
1012                         force = inflictor.velocity;
1013                         if(vlen(force) == 0)
1014                                 force = '0 0 -1';
1015                         else
1016                                 force = normalize(force);
1017                         if(forceintensity >= 0)
1018                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
1019                         else
1020                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
1021                 }
1022
1023         stat_damagedone = 0;
1024
1025         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
1026         while (targ)
1027         {
1028                 next = targ.chain;
1029                 if (targ != inflictor)
1030                         if (ignore != targ) if(targ.takedamage)
1031                         {
1032                                 vector nearest;
1033                                 vector diff;
1034                                 float power;
1035
1036                                 // LordHavoc: measure distance to nearest point on target (not origin)
1037                                 // (this guarentees 100% damage on a touch impact)
1038                                 nearest = targ.WarpZone_findradius_nearest;
1039                                 diff = targ.WarpZone_findradius_dist;
1040                                 // round up a little on the damage to ensure full damage on impacts
1041                                 // and turn the distance into a fraction of the radius
1042                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1043                                 //bprint(" ");
1044                                 //bprint(ftos(power));
1045                                 //if (targ == attacker)
1046                                 //      print(ftos(power), "\n");
1047                                 if (power > 0)
1048                                 {
1049                                         float finaldmg;
1050                                         if (power > 1)
1051                                                 power = 1;
1052                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1053                                         if (finaldmg > 0)
1054                                         {
1055                                                 float a;
1056                                                 float c;
1057                                                 vector hitloc;
1058                                                 vector myblastorigin;
1059                                                 vector center;
1060
1061                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1062
1063                                                 // if it's a player, use the view origin as reference
1064                                                 center = CENTER_OR_VIEWOFS(targ);
1065
1066                                                 force = normalize(center - myblastorigin);
1067                                                 force = force * (finaldmg / coredamage) * forceintensity;
1068                                                 hitloc = nearest;
1069
1070                                                 if(targ != directhitentity)
1071                                                 {
1072                                                         float hits;
1073                                                         float total;
1074                                                         float hitratio;
1075                                                         float mininv_f, mininv_d;
1076
1077                                                         // test line of sight to multiple positions on box,
1078                                                         // and do damage if any of them hit
1079                                                         hits = 0;
1080
1081                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1082                                                         // so for a given max stddev:
1083                                                         // n = (1 / (2 * max stddev of hitratio))^2
1084
1085                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1086                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1087
1088                                                         if(autocvar_g_throughfloor_debug)
1089                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1090
1091                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1092
1093                                                         if(autocvar_g_throughfloor_debug)
1094                                                                 print(sprintf(" steps=%f", total));
1095
1096                                                         if (targ.classname == "player")
1097                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1098                                                         else
1099                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1100
1101                                                         if(autocvar_g_throughfloor_debug)
1102                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1103
1104                                                         for(c = 0; c < total; ++c)
1105                                                         {
1106                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1107                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1108                                                                 if (trace_fraction == 1 || trace_ent == targ)
1109                                                                 {
1110                                                                         ++hits;
1111                                                                         if (hits > 1)
1112                                                                                 hitloc = hitloc + nearest;
1113                                                                         else
1114                                                                                 hitloc = nearest;
1115                                                                 }
1116                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1117                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1118                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1119                                                         }
1120
1121                                                         nearest = hitloc * (1 / max(1, hits));
1122                                                         hitratio = (hits / total);
1123                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1124                                                         finaldmg = finaldmg * a;
1125                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1126                                                         force = force * a;
1127
1128                                                         if(autocvar_g_throughfloor_debug)
1129                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1130                                                 }
1131
1132                                                 // laser force adjustments :P
1133                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1134                                                 {
1135                                                         if (targ == attacker)
1136                                                         {
1137                                                                 vector vel;
1138
1139                                                                 float force_zscale;
1140                                                                 float force_velocitybiasramp;
1141                                                                 float force_velocitybias;
1142
1143                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1144                                                                 if(deathtype & HITTYPE_SECONDARY)
1145                                                                 {
1146                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1147                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1148                                                                 }
1149                                                                 else
1150                                                                 {
1151                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1152                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1153                                                                 }
1154
1155                                                                 vel = targ.velocity;
1156                                                                 vel_z = 0;
1157                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1158                                                                 force =
1159                                                                         vlen(force)
1160                                                                         *
1161                                                                         normalize(normalize(force) + vel);
1162
1163                                                                 force_z *= force_zscale;
1164                                                         }
1165                                                         else
1166                                                         {
1167                                                                 if(deathtype & HITTYPE_SECONDARY)
1168                                                                 {
1169                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1170                                                                 }
1171                                                                 else
1172                                                                 {
1173                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1174                                                                 }
1175                                                         }
1176                                                 }
1177
1178                                                 //if (targ == attacker)
1179                                                 //{
1180                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1181                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1182                                                 //      print(" (", ftos(a), ")\n");
1183                                                 //}
1184                                                 if(finaldmg || vlen(force))
1185                                                 {
1186                                                         if(targ.iscreature)
1187                                                         {
1188                                                                 total_damage_to_creatures += finaldmg;
1189
1190                                                                 if(accuracy_isgooddamage(attacker, targ))
1191                                                                         stat_damagedone += finaldmg;
1192                                                         }
1193
1194                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1195                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1196                                                         else
1197                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1198                                                 }
1199                                         }
1200                                 }
1201                         }
1202                 targ = next;
1203         }
1204
1205         RadiusDamage_running = 0;
1206
1207         if(!DEATH_ISSPECIAL(deathtype))
1208                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1209
1210         return total_damage_to_creatures;
1211 }
1212
1213 .float fire_damagepersec;
1214 .float fire_endtime;
1215 .float fire_deathtype;
1216 .entity fire_owner;
1217 .float fire_hitsound;
1218 .entity fire_burner;
1219
1220 void fireburner_think();
1221
1222 float Fire_IsBurning(entity e)
1223 {
1224         return (time < e.fire_endtime);
1225 }
1226
1227 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1228 {
1229         float dps;
1230         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1231
1232         if(e.classname == "player")
1233         {
1234                 if(e.deadflag)
1235                         return -1;
1236         }
1237         else
1238         {
1239                 if(!e.fire_burner)
1240                 {
1241                         // print("adding a fire burner to ", e.classname, "\n");
1242                         e.fire_burner = spawn();
1243                         e.fire_burner.classname = "fireburner";
1244                         e.fire_burner.think = fireburner_think;
1245                         e.fire_burner.nextthink = time;
1246                         e.fire_burner.owner = e;
1247                 }
1248         }
1249
1250         t = max(t, 0.1);
1251         dps = d / t;
1252         if(Fire_IsBurning(e))
1253         {
1254                 mintime = e.fire_endtime - time;
1255                 maxtime = max(mintime, t);
1256
1257                 mindps = e.fire_damagepersec;
1258                 maxdps = max(mindps, dps);
1259
1260                 if(maxtime > mintime || maxdps > mindps)
1261                 {
1262                         // Constraints:
1263
1264                         // damage we have right now
1265                         mindamage = mindps * mintime;
1266
1267                         // damage we want to get
1268                         maxdamage = mindamage + d;
1269
1270                         // but we can't exceed maxtime * maxdps!
1271                         totaldamage = min(maxdamage, maxtime * maxdps);
1272
1273                         // LEMMA:
1274                         // Look at:
1275                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1276                         // We see:
1277                         // totaldamage <= maxtime * maxdps
1278                         // ==> totaldamage / maxdps <= maxtime.
1279                         // We also see:
1280                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1281                         //                     >= min(mintime, maxtime)
1282                         // ==> totaldamage / maxdps >= mintime.
1283
1284                         /*
1285                         // how long do we damage then?
1286                         // at least as long as before
1287                         // but, never exceed maxdps
1288                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1289                         */
1290
1291                         // alternate:
1292                         // at most as long as maximum allowed
1293                         // but, never below mindps
1294                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1295
1296                         // assuming t > mintime, dps > mindps:
1297                         // we get d = t * dps = maxtime * maxdps
1298                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1299                         // totaldamage / maxdps = maxtime
1300                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1301                         // FROM THIS:
1302                         // a) totaltime = max(mintime, maxtime) = maxtime
1303                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1304
1305                         // assuming t <= mintime:
1306                         // we get maxtime = mintime
1307                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1308                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1309
1310                         // assuming dps <= mindps:
1311                         // we get mindps = maxdps.
1312                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1313                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1314                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1315
1316                         e.fire_damagepersec = totaldamage / totaltime;
1317                         e.fire_endtime = time + totaltime;
1318                         if(totaldamage > 1.2 * mindamage)
1319                         {
1320                                 e.fire_deathtype = dt;
1321                                 if(e.fire_owner != o)
1322                                 {
1323                                         e.fire_owner = o;
1324                                         e.fire_hitsound = FALSE;
1325                                 }
1326                         }
1327                         if(accuracy_isgooddamage(o, e))
1328                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1329                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1330                 }
1331                 else
1332                         return 0;
1333         }
1334         else
1335         {
1336                 e.fire_damagepersec = dps;
1337                 e.fire_endtime = time + t;
1338                 e.fire_deathtype = dt;
1339                 e.fire_owner = o;
1340                 e.fire_hitsound = FALSE;
1341                 if(accuracy_isgooddamage(o, e))
1342                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1343                 return d;
1344         }
1345 }
1346
1347 void Fire_ApplyDamage(entity e)
1348 {
1349         float t, d, hi, ty;
1350         entity o;
1351
1352         if not(Fire_IsBurning(e))
1353                 return;
1354
1355         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1356         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1357                 o = e.fire_owner;
1358
1359         // water and slime stop fire
1360         if(e.waterlevel)
1361         if(e.watertype != CONTENT_LAVA)
1362                 e.fire_endtime = 0;
1363
1364         // ice stops fire
1365         if(e.freezetag_frozen)
1366                 e.fire_endtime = 0;
1367
1368         t = min(frametime, e.fire_endtime - time);
1369         d = e.fire_damagepersec * t;
1370
1371         hi = e.fire_owner.hitsound;
1372         ty = e.fire_owner.typehitsound;
1373         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1374         if(e.fire_hitsound && e.fire_owner)
1375         {
1376                 e.fire_owner.hitsound = hi;
1377                 e.fire_owner.typehitsound = ty;
1378         }
1379         e.fire_hitsound = TRUE;
1380
1381         if not(IS_INDEPENDENT_PLAYER(e))
1382         FOR_EACH_PLAYER(other) if(e != other)
1383         {
1384                 if(other.classname == "player")
1385                 if(other.deadflag == DEAD_NO)
1386                 if not(IS_INDEPENDENT_PLAYER(other))
1387                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1388                 {
1389                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1390                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1391                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1392                 }
1393         }
1394 }
1395
1396 void Fire_ApplyEffect(entity e)
1397 {
1398         if(Fire_IsBurning(e))
1399                 e.effects |= EF_FLAME;
1400         else
1401                 e.effects &~= EF_FLAME;
1402 }
1403
1404 void fireburner_think()
1405 {
1406         // for players, this is done in the regular loop
1407         if(wasfreed(self.owner))
1408         {
1409                 remove(self);
1410                 return;
1411         }
1412         Fire_ApplyEffect(self.owner);
1413         if(!Fire_IsBurning(self.owner))
1414         {
1415                 self.owner.fire_burner = world;
1416                 remove(self);
1417                 return;
1418         }
1419         Fire_ApplyDamage(self.owner);
1420         self.nextthink = time;
1421 }