qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59
  60 float IsDifferentTeam(entity a, entity b)
  61 {
  62         if(teamplay)
  63         {
  64                 if(a.team == b.team)
  65                         return 0;
  66         }
  67         else
  68         {
  69                 if(a == b)
  70                         return 0;
  71         }
  72         return 1;
  73 }
  74
  75 float IsFlying(entity a)
  76 {
  77         if(a.flags & FL_ONGROUND)
  78                 return 0;
  79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  80                 return 0;
  81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  82         if(trace_fraction < 1)
  83                 return 0;
  84         return 1;
  85 }
  86
  87 void UpdateFrags(entity player, float f)
  88 {
  89         PlayerTeamScore_AddScore(player, f);
  90 }
  91
  92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  93 void W_SwitchWeapon_Force(entity e, float w);
  94 entity GiveFrags_randomweapons;
  95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  96 {
  97         // TODO route through PlayerScores instead
  98         if(gameover) return;
  99
 100         if(f < 0)
 101         {
 102                 if(targ == attacker)
 103                 {
 104                         // suicide
 105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 106                 }
 107                 else
 108                 {
 109                         // teamkill
 110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 111                 }
 112         }
 113         else
 114         {
 115                 // regular frag
 116                 PlayerScore_Add(attacker, SP_KILLS, 1);
 117                 if(targ.playerid)
 118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 119         }
 120
 121         PlayerScore_Add(targ, SP_DEATHS, 1);
 122
 123         if(g_arena || g_ca)
 124                 if(autocvar_g_arena_roundbased)
 125                         return;
 126
 127         if(targ != attacker) // not for suicides
 128         if(g_weaponarena_random)
 129         {
 130                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 131                 float culprit;
 132                 culprit = DEATH_WEAPONOF(deathtype);
 133                 if(!culprit)
 134                         culprit = attacker.weapon;
 135                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 136                         culprit = attacker.weapon;
 137
 138                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 139                 {
 140                         // no exchange
 141                 }
 142                 else
 143                 {
 144                         if(!GiveFrags_randomweapons)
 145                         {
 146                                 GiveFrags_randomweapons = spawn();
 147                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 148                         }
 149
 150                         if(inWarmupStage)
 151                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 152                         else
 153                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 154
 155                         // all others (including the culprit): remove
 156                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 157                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 158
 159                         // among the remaining ones, choose one by random
 160                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 161
 162                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 163                         {
 164                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 165                                 WEPSET_ANDNOT_EW(attacker, culprit);
 166                         }
 167                 }
 168
 169                 // after a frag, choose another random weapon set
 170                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 171                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 172         }
 173
 174         // FIXME fix the mess this is (we have REAL points now!)
 175         entity oldself;
 176         oldself = self;
 177         self = attacker;
 178         frag_attacker = attacker;
 179         frag_target = targ;
 180         frag_score = f;
 181         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 182         {
 183                 f = frag_score;
 184                 self = oldself;
 185         }
 186         else
 187         {
 188                 self = oldself;
 189                 if(g_runematch)
 190                 {
 191                         f = RunematchHandleFrags(attacker, targ, f);
 192                 }
 193                 else if(g_lms)
 194                 {
 195                         // remove a life
 196                         float tl;
 197                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 198                         if(tl < lms_lowest_lives)
 199                                 lms_lowest_lives = tl;
 200                         if(tl <= 0)
 201                         {
 202                                 if(!lms_next_place)
 203                                         lms_next_place = player_count;
 204                                 else
 205                                         lms_next_place = min(lms_next_place, player_count);
 206                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 207                                 --lms_next_place;
 208                         }
 209                         f = 0;
 210                 }
 211         }
 212
 213         attacker.totalfrags += f;
 214
 215         if(f)
 216                 UpdateFrags(attacker, f);
 217 }
 218
 219 string AppendItemcodes(string s, entity player)
 220 {
 221         float w;
 222         w = player.weapon;
 223         //if(w == 0)
 224         //      w = player.switchweapon;
 225         if(w == 0)
 226                 w = player.cnt; // previous weapon!
 227         s = strcat(s, ftos(w));
 228         if(time < player.strength_finished)
 229                 s = strcat(s, "S");
 230         if(time < player.invincible_finished)
 231                 s = strcat(s, "I");
 232         if(player.flagcarried != world)
 233                 s = strcat(s, "F");
 234         if(player.BUTTON_CHAT)
 235                 s = strcat(s, "T");
 236         if(player.kh_next)
 237                 s = strcat(s, "K");
 238         if(player.runes)
 239                 s = strcat(s, "|", ftos(player.runes));
 240         return s;
 241 }
 242
 243 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 244 {
 245         string s;
 246         if(!autocvar_sv_eventlog)
 247                 return;
 248         s = strcat(":kill:", mode);
 249         s = strcat(s, ":", ftos(killer.playerid));
 250         s = strcat(s, ":", ftos(killed.playerid));
 251         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 252         s = strcat(s, ":items=");
 253         s = AppendItemcodes(s, killer);
 254         if(killed != killer)
 255         {
 256                 s = strcat(s, ":victimitems=");
 257                 s = AppendItemcodes(s, killed);
 258         }
 259         GameLogEcho(s);
 260 }
 261
 262 #define INFO_NO_MSG 0
 263
 264 void Obituary_SpecialDeath(entity notif_target, float murder, float deathtype, string s1, string s2, string s3, float f1, float f2, float f3)
 265 {
 266         float handled = 0, hits = 0;
 267         if(DEATH_ISSPECIAL(deathtype))
 268         {
 269                 #define DEATHTYPE(name,msg_death,msg_death_by,position) \
 270                         { if(deathtype == max(0, name)) \
 271                         { \
 272                                 #if msg_death != NO_MSG \
 273                                         if not(murder) \
 274                                         { \
 275                                                 Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_DEATH, msg_death, s1, s2, s3, "", f1, f2, f3, 0); \
 276                                                 Send_Notification_WOVA(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, INFO_##msg_death, s1, s2, s3, "", f1, f2, f3, 0); \
 277                                                 ++handled; \
 278                                         } \
 279                                 #endif \
 280                                 #if msg_death_by != NO_MSG \
 281                                         if(murder) \
 282                                         { \
 283                                                 Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_DEATH, msg_death_by, s1, s2, s3, "", f1, f2, f3, 0); \
 284                                                 Send_Notification_WOVA(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, INFO_##msg_death_by, s1, s2, s3, "", f1, f2, f3, 0); \
 285                                                 ++handled; \
 286                                         } \
 287                                 #endif \
 288                                 ++hits; \
 289                         } }
 290
 291                 DEATHTYPES
 292                 #undef DEATHTYPE
 293
 294                 if not(hits)
 295                 {
 296                         backtrace("Obituary_SpecialDeath(): Unhandled deathtype- Please notify Samual!\n");
 297                 }
 298                 if not(handled)
 299                 {
 300                         dprint(sprintf("Obituary_SpecialDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification!\n", Deathtype_Name(deathtype), deathtype));
 301                         return;
 302                 }
 303         }
 304 }
 305
 306 float w_deathtype;
 307 float Obituary_WeaponDeath(entity notif_target, float murder, float deathtype, string s1, string s2, string s3, float f1, float f2)
 308 {
 309         float death_weapon = DEATH_WEAPONOF(deathtype);
 310         if(death_weapon)
 311         {
 312                 w_deathtype = deathtype;
 313                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 314                 w_deathtype = FALSE;
 315
 316                 if(death_message)
 317                 {
 318                         Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_WEAPON, death_message, s1, s2, s3, "", f1, f2, 0, 0);
 319                         Send_Notification_WOVA(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, msg_weapon_notifs[death_message - 1].nent_msginfo.nent_id, s1, s2, s3, "", f1, f2, 0, 0);
 320                         //print(Get_Field_Value(F_INFVAL, MSG_WEAPON, death_message), "\n");
 321                 }
 322                 else { dprint(sprintf("Obituary_WeaponDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification for weapon %d!\n", Deathtype_Name(deathtype), deathtype, death_weapon)); }
 323
 324                 return TRUE;
 325         }
 326         return FALSE;
 327 }
 328
 329 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 330 {
 331         // Sanity check
 332         if not(targ.classname == STR_PLAYER) { backtrace("Obituary called on non-player?!\n"); return; }
 333
 334         // Declarations
 335         float notif_firstblood = FALSE;
 336         float kill_count_to_attacker, kill_count_to_target;
 337
 338         // Set final information for the death
 339         targ.death_origin = targ.origin;
 340         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 341         string deathlocation = NearestLocation(targ.death_origin);
 342
 343         #ifdef NOTIFICATIONS_DEBUG
 344         dprint(
 345                 sprintf("Obituary(%s, %s, %s, %s = %d);\n",
 346                         attacker.netname,
 347                         inflictor.netname,
 348                         targ.netname,
 349                         Deathtype_Name(deathtype),
 350                         deathtype
 351                 )
 352         );
 353         #endif
 354
 355         // =======
 356         // SUICIDE
 357         // =======
 358         if(targ == attacker)
 359         {
 360                 if(DEATH_ISSPECIAL(deathtype))
 361                 {
 362                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 363                         {
 364                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
 365                         }
 366                         else
 367                         {
 368                                 switch(deathtype)
 369                                 {
 370                                         case DEATH_MIRRORDAMAGE:
 371                                         {
 372                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 373                                                 break;
 374                                         }
 375
 376                                         default:
 377                                         {
 378                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 379                                                 break;
 380                                         }
 381                                 }
 382                                 LogDeath("suicide", deathtype, targ, targ);
 383                                 GiveFrags(attacker, targ, -1, deathtype);
 384                         }
 385                 }
 386                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
 387                 {
 388                         backtrace("SUICIDE: what the hell happened here?\n");
 389                 }
 390         }
 391
 392         // ======
 393         // MURDER
 394         // ======
 395         else if(attacker.classname == "player")
 396         {
 397                 if(!IsDifferentTeam(attacker, targ))
 398                 {
 399                         LogDeath("tk", deathtype, attacker, targ);
 400                         GiveFrags(attacker, targ, -1, deathtype);
 401
 402                         attacker.killcount = 0;
 403
 404                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
 405                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
 406                         Send_Notification(NOTIF_ANY, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, targ.killcount);
 407
 408                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 409                         // No need for specific death/weapon messages...
 410                 }
 411                 else
 412                 {
 413                         LogDeath("frag", deathtype, attacker, targ);
 414                         GiveFrags(attacker, targ, 1, deathtype);
 415
 416                         attacker.taunt_soundtime = time + 1;
 417                         attacker.killcount = attacker.killcount + 1;
 418
 419                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 420                                 case counta: \
 421                                 { \
 422                                         AnnounceTo(attacker, strcat(#countb, "kills")); \
 423                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
 424                                         break; \
 425                                 }
 426                         switch(attacker.killcount)
 427                         {
 428                                 KILL_SPREE_LIST
 429                                 default: break;
 430                         }
 431                         #undef SPREE_ITEM
 432
 433                         if(!checkrules_firstblood)
 434                         {
 435                                 checkrules_firstblood = TRUE;
 436                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 437                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 438                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 439
 440                                 // tell spree_inf and spree_cen that this is a first-blood and first-victim event
 441                                 kill_count_to_attacker = -1;
 442                                 kill_count_to_target = -2;
 443                         }
 444                         else
 445                         {
 446                                 kill_count_to_attacker = attacker.killcount;
 447                                 kill_count_to_target = 0;
 448                         }
 449
 450                         if(targ.istypefrag)
 451                         {
 452                                 if(attacker.FRAG_VERBOSE)
 453                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 454                                 else
 455                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG, targ.netname, kill_count_to_attacker);
 456
 457                                 if(targ.FRAG_VERBOSE)
 458                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 459                                 else
 460                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED, attacker.netname, kill_count_to_target);
 461                         }
 462                         else
 463                         {
 464                                 if(attacker.FRAG_VERBOSE)
 465                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 466                                 else
 467                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG, targ.netname, kill_count_to_attacker);
 468
 469                                 if(targ.FRAG_VERBOSE)
 470                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 471                                 else
 472                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED, attacker.netname, kill_count_to_target);
 473                         }
 474
 475                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
 476                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
 477                 }
 478         }
 479
 480         // =============
 481         // ACCIDENT/TRAP
 482         // =============
 483         else
 484         {
 485                 switch(deathtype)
 486                 {
 487                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 488                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 489                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 490                         /*case DEATH_HURTTRIGGER:
 491                         {
 492                                 s1 = targ.netname;
 493                                 s2 = inflictor.message;
 494                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 495                                 break;
 496                         }*/
 497
 498                         case DEATH_CUSTOM:
 499                         {
 500                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
 501                                         targ.netname,
 502                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
 503                                         deathlocation,
 504                                         targ.killcount,
 505                                         0,
 506                                         0);
 507                                 break;
 508                         }
 509
 510                         default:
 511                         {
 512                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 513                                 break;
 514                         }
 515                 }
 516
 517                 LogDeath("accident", deathtype, targ, targ);
 518                 GiveFrags(targ, targ, -1, deathtype);
 519
 520                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 521                 {
 522                         AnnounceTo(targ, "botlike");
 523                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 524                 }
 525         }
 526
 527         // reset target kill count
 528         if(targ.killcount) { targ.killcount = 0; }
 529 }
 530
 531 // these are updated by each Damage call for use in button triggering and such
 532 entity damage_targ;
 533 entity damage_inflictor;
 534 entity damage_attacker;
 535
 536 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 537 {
 538         float mirrordamage;
 539         float mirrorforce;
 540         float complainteamdamage = 0;
 541         entity attacker_save;
 542         mirrordamage = 0;
 543         mirrorforce = 0;
 544
 545         if (gameover || targ.killcount == -666)
 546                 return;
 547
 548         entity oldself;
 549         oldself = self;
 550         self = targ;
 551         damage_targ = targ;
 552         damage_inflictor = inflictor;
 553         damage_attacker = attacker;
 554                 attacker_save = attacker;
 555
 556         if(targ.classname == "player")
 557                 if(targ.hook)
 558                         if(targ.hook.aiment)
 559                                 if(targ.hook.aiment == attacker)
 560                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 561
 562         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 563         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 564         {
 565                 if(targ.classname == "player")
 566                         if not(IsDifferentTeam(targ, attacker))
 567                         {
 568                                 self = oldself;
 569                                 return;
 570                         }
 571         }
 572
 573         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 574         {
 575                 // These are ALWAYS lethal
 576                 // No damage modification here
 577                 // Instead, prepare the victim for his death...
 578                 targ.armorvalue = 0;
 579                 targ.spawnshieldtime = 0;
 580                 targ.health = 0.9; // this is < 1
 581                 targ.flags -= targ.flags & FL_GODMODE;
 582                 damage = 100000;
 583         }
 584         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 585         {
 586                 // no processing
 587         }
 588         else
 589         {
 590                 /*
 591                 skill based bot damage? gtfo. (tZork)
 592                 if (targ.classname == "player")
 593                 if (attacker.classname == "player")
 594                 if (!targ.isbot)
 595                 if (attacker.isbot)
 596                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 597         */
 598
 599                 // nullify damage if teamplay is on
 600                 if(deathtype != DEATH_TELEFRAG)
 601                 if(attacker.classname == "player")
 602                 {
 603                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 604                         {
 605                                 damage = 0;
 606                                 force = '0 0 0';
 607                         }
 608                         else if(!IsDifferentTeam(attacker, targ))
 609                         {
 610                                 if(autocvar_teamplay_mode == 1)
 611                                         damage = 0;
 612                                 else if(attacker != targ)
 613                                 {
 614                                         if(autocvar_teamplay_mode == 3)
 615                                                 damage = 0;
 616                                         else if(autocvar_teamplay_mode == 4)
 617                                         {
 618                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 619                                                 {
 620                                                         attacker.dmg_team = attacker.dmg_team + damage;
 621                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
 622                                                         if(complainteamdamage > 0 && !g_ca) // FIXME why is g_ca ruled out here? Why not just g_mirrordamage 0 on CA servers?
 623                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
 624                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 625                                                         if(g_minstagib)
 626                                                         {
 627                                                                 if(autocvar_g_friendlyfire == 0)
 628                                                                         damage = 0;
 629                                                         }
 630                                                         else if(g_ca)
 631                                                                 damage = 0;
 632                                                         else
 633                                                                 damage = autocvar_g_friendlyfire * damage;
 634                                                         // mirrordamage will be used LATER
 635
 636                                                         if(autocvar_g_mirrordamage_virtual)
 637                                                         {
 638                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 639                                                                 attacker.dmg_take += v_x;
 640                                                                 attacker.dmg_save += v_y;
 641                                                                 attacker.dmg_inflictor = inflictor;
 642                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 643                                                                 mirrorforce = 0;
 644                                                         }
 645
 646                                                         if(autocvar_g_friendlyfire_virtual)
 647                                                         {
 648                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 649                                                                 targ.dmg_take += v_x;
 650                                                                 targ.dmg_save += v_y;
 651                                                                 targ.dmg_inflictor = inflictor;
 652                                                                 damage = 0;
 653                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 654                                                                         force = '0 0 0';
 655                                                         }
 656                                                 }
 657                                                 else
 658                                                         damage = 0;
 659                                         }
 660                                 }
 661                         }
 662                 }
 663
 664                 if(targ.classname == "player")
 665                 if(attacker.classname == "player")
 666                 if(attacker != targ)
 667                 {
 668                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 669                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 670                 }
 671
 672                 if(targ.classname == "player")
 673                 if (g_minstagib)
 674                 {
 675                         if ((deathtype == DEATH_FALL)  ||
 676                                 (deathtype == DEATH_DROWN) ||
 677                                 (deathtype == DEATH_SLIME) ||
 678                                 (deathtype == DEATH_LAVA)  ||
 679                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 680                         {
 681                                 self = oldself;
 682                                 return;
 683                         }
 684                         if(damage > 0)
 685                             damage = 10000;
 686                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 687                         {
 688                                 targ.armorvalue -= 1;
 689                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 690                                 damage = 0;
 691                                 targ.hitsound += 1;
 692                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 693                         }
 694                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 695                         {
 696                                 damage = 0;
 697                                 mirrordamage = 0;
 698                                 complainteamdamage = 0;
 699                                 if (targ != attacker)
 700                                 {
 701                                         if ((targ.health >= 1) && (targ.classname == "player"))
 702                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 703                                         force = '0 0 0';
 704                                         // keep mirrorforce
 705                                         attacker = targ;
 706                                 }
 707                         }
 708                 }
 709
 710                 if not(DEATH_ISSPECIAL(deathtype))
 711                 {
 712                         damage *= g_weapondamagefactor;
 713                         mirrordamage *= g_weapondamagefactor;
 714                         complainteamdamage *= g_weapondamagefactor;
 715                         force = force * g_weaponforcefactor;
 716                         mirrorforce *= g_weaponforcefactor;
 717                 }
 718
 719                 // should this be changed at all? If so, in what way?
 720                 frag_attacker = attacker;
 721                 frag_target = targ;
 722                 frag_damage = damage;
 723                 frag_force = force;
 724         frag_deathtype = deathtype;
 725                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 726                 damage = frag_damage;
 727                 force = frag_force;
 728
 729                 // apply strength multiplier
 730                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 731                 {
 732                         if(targ == attacker)
 733                         {
 734                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 735                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 736                         }
 737                         else
 738                         {
 739                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 740                                 force = force * autocvar_g_balance_powerup_strength_force;
 741                         }
 742                 }
 743
 744                 // apply invincibility multiplier
 745                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 746                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 747
 748                 if (targ == attacker)
 749                 {
 750                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 751                                 damage = 0;
 752                         else
 753                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 754                 }
 755
 756                 if(g_runematch)
 757                 {
 758                         // apply strength rune
 759                         if (attacker.runes & RUNE_STRENGTH)
 760                         {
 761                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 762                                 {
 763                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 764                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 765                                 }
 766                                 else
 767                                 {
 768                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 769                                         force = force * autocvar_g_balance_rune_strength_force;
 770                                 }
 771                         }
 772                         else if (attacker.runes & CURSE_WEAK)
 773                         {
 774                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 775                                 force = force * autocvar_g_balance_curse_weak_force;
 776                         }
 777
 778                         // apply defense rune
 779                         if (targ.runes & RUNE_DEFENSE)
 780                         {
 781                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 782                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 783                                 else
 784                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 785                         }
 786                         else if (targ.runes & CURSE_VULNER)
 787                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 788                 }
 789
 790                 // count the damage
 791                 if(attacker)
 792                 if(!targ.deadflag)
 793                 if(targ.takedamage == DAMAGE_AIM)
 794                 if(targ != attacker)
 795                 {
 796                         entity victim;
 797                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 798                                 victim = targ.owner;
 799                         else
 800                                 victim = targ;
 801
 802                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 803                         {
 804                                 if(IsDifferentTeam(victim, attacker))
 805                                 {
 806                                         if(damage > 0)
 807                                         {
 808                                                 if(deathtype != DEATH_FIRE)
 809                                                 {
 810                                                         if(victim.BUTTON_CHAT)
 811                                                                 attacker.typehitsound += 1;
 812                                                         else
 813                                                                 attacker.hitsound += 1;
 814                                                 }
 815
 816                                                 damage_goodhits += 1;
 817                                                 damage_gooddamage += damage;
 818
 819                                                 if not(DEATH_ISSPECIAL(deathtype))
 820                                                 {
 821                                                         if(targ.classname == "player") // don't do this for vehicles
 822                                                         if(!g_minstagib)
 823                                                         if(IsFlying(victim))
 824                                                                 yoda = 1;
 825
 826                                                         if(g_minstagib)
 827                                                         if(victim.items & IT_STRENGTH)
 828                                                                 yoda = 1;
 829                                                 }
 830                                         }
 831                                 }
 832                                 else
 833                                 {
 834                                         if(deathtype != DEATH_FIRE)
 835                                         {
 836                                                 attacker.typehitsound += 1;
 837                                         }
 838                                         if(complainteamdamage > 0)
 839                                                 if(time > attacker.teamkill_complain)
 840                                                 {
 841                                                         attacker.teamkill_complain = time + 5;
 842                                                         attacker.teamkill_soundtime = time + 0.4;
 843                                                         attacker.teamkill_soundsource = targ;
 844                                                 }
 845                                 }
 846                         }
 847                 }
 848         }
 849
 850         // apply push
 851         if (self.damageforcescale)
 852         if (vlen(force))
 853         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 854         {
 855                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 856                 if(self.movetype == MOVETYPE_PHYSICS)
 857                 {
 858                         entity farcent;
 859                         farcent = spawn();
 860                         farcent.classname = "farce";
 861                         farcent.enemy = self;
 862                         farcent.movedir = farce * 10;
 863                         if(self.mass)
 864                                 farcent.movedir = farcent.movedir * self.mass;
 865                         farcent.origin = hitloc;
 866                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 867                         farcent.nextthink = time + 0.1;
 868                         farcent.think = SUB_Remove;
 869                 }
 870                 else
 871                         self.velocity = self.velocity + farce;
 872                 self.flags &~= FL_ONGROUND;
 873                 UpdateCSQCProjectile(self);
 874         }
 875         // apply damage
 876         if (damage != 0 || (self.damageforcescale && vlen(force)))
 877         if (self.event_damage)
 878                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 879         self = oldself;
 880
 881         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 882         {
 883                 if(g_runematch)
 884                 {
 885                         if (attacker.runes & RUNE_VAMPIRE)
 886                         {
 887                         // apply vampire rune
 888                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 889                                 {
 890                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 891                                         attacker.health = bound(
 892                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 893                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 894                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 895                                 }
 896                                 else
 897                                 {
 898                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 899                                         attacker.health = bound(
 900                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 901                                                                                         // empathy won't let you gain health in the same way...
 902                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 903                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 904                                         }
 905                         }
 906                         // apply empathy curse
 907                         else if (attacker.runes & CURSE_EMPATHY)
 908                         {
 909                                 attacker.health = bound(
 910                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 911                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 912                                         attacker.health);
 913                         }
 914                 }
 915         }
 916
 917         // apply mirror damage if any
 918         if(mirrordamage > 0 || mirrorforce > 0)
 919         {
 920                 attacker = attacker_save;
 921                 if(g_minstagib)
 922                 if(mirrordamage > 0)
 923                 {
 924                         // just lose extra LIVES, don't kill the player for mirror damage
 925                         if(attacker.armorvalue > 0)
 926                         {
 927                                 attacker.armorvalue = attacker.armorvalue - 1;
 928                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 929                                 attacker.hitsound += 1;
 930                         }
 931                         mirrordamage = 0;
 932                 }
 933
 934                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 935                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 936         }
 937 }
 938
 939 float RadiusDamage_running;
 940 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 941         // Returns total damage applies to creatures
 942 {
 943         entity  targ;
 944         vector  blastorigin;
 945         vector  force;
 946         float   total_damage_to_creatures;
 947         entity  next;
 948         float   tfloordmg;
 949         float   tfloorforce;
 950
 951         float stat_damagedone;
 952
 953         if(RadiusDamage_running)
 954         {
 955                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 956                 return 0;
 957         }
 958
 959         RadiusDamage_running = 1;
 960
 961         tfloordmg = autocvar_g_throughfloor_damage;
 962         tfloorforce = autocvar_g_throughfloor_force;
 963
 964         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 965         total_damage_to_creatures = 0;
 966
 967         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 968                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 969                 {
 970                         force = inflictor.velocity;
 971                         if(vlen(force) == 0)
 972                                 force = '0 0 -1';
 973                         else
 974                                 force = normalize(force);
 975                         if(forceintensity >= 0)
 976                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
 977                         else
 978                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
 979                 }
 980
 981         stat_damagedone = 0;
 982
 983         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
 984         while (targ)
 985         {
 986                 next = targ.chain;
 987                 if (targ != inflictor)
 988                         if (ignore != targ) if(targ.takedamage)
 989                         {
 990                                 vector nearest;
 991                                 vector diff;
 992                                 float power;
 993
 994                                 // LordHavoc: measure distance to nearest point on target (not origin)
 995                                 // (this guarentees 100% damage on a touch impact)
 996                                 nearest = targ.WarpZone_findradius_nearest;
 997                                 diff = targ.WarpZone_findradius_dist;
 998                                 // round up a little on the damage to ensure full damage on impacts
 999                                 // and turn the distance into a fraction of the radius
1000                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1001                                 //bprint(" ");
1002                                 //bprint(ftos(power));
1003                                 //if (targ == attacker)
1004                                 //      print(ftos(power), "\n");
1005                                 if (power > 0)
1006                                 {
1007                                         float finaldmg;
1008                                         if (power > 1)
1009                                                 power = 1;
1010                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1011                                         if (finaldmg > 0)
1012                                         {
1013                                                 float a;
1014                                                 float c;
1015                                                 vector hitloc;
1016                                                 vector myblastorigin;
1017                                                 vector center;
1018
1019                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1020
1021                                                 // if it's a player, use the view origin as reference
1022                                                 center = CENTER_OR_VIEWOFS(targ);
1023
1024                                                 force = normalize(center - myblastorigin);
1025                                                 force = force * (finaldmg / coredamage) * forceintensity;
1026                                                 hitloc = nearest;
1027
1028                                                 if(targ != directhitentity)
1029                                                 {
1030                                                         float hits;
1031                                                         float total;
1032                                                         float hitratio;
1033                                                         float mininv_f, mininv_d;
1034
1035                                                         // test line of sight to multiple positions on box,
1036                                                         // and do damage if any of them hit
1037                                                         hits = 0;
1038
1039                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1040                                                         // so for a given max stddev:
1041                                                         // n = (1 / (2 * max stddev of hitratio))^2
1042
1043                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1044                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1045
1046                                                         if(autocvar_g_throughfloor_debug)
1047                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1048
1049                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1050
1051                                                         if(autocvar_g_throughfloor_debug)
1052                                                                 print(sprintf(" steps=%f", total));
1053
1054                                                         if (targ.classname == "player")
1055                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1056                                                         else
1057                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1058
1059                                                         if(autocvar_g_throughfloor_debug)
1060                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1061
1062                                                         for(c = 0; c < total; ++c)
1063                                                         {
1064                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1065                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1066                                                                 if (trace_fraction == 1 || trace_ent == targ)
1067                                                                 {
1068                                                                         ++hits;
1069                                                                         if (hits > 1)
1070                                                                                 hitloc = hitloc + nearest;
1071                                                                         else
1072                                                                                 hitloc = nearest;
1073                                                                 }
1074                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1075                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1076                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1077                                                         }
1078
1079                                                         nearest = hitloc * (1 / max(1, hits));
1080                                                         hitratio = (hits / total);
1081                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1082                                                         finaldmg = finaldmg * a;
1083                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1084                                                         force = force * a;
1085
1086                                                         if(autocvar_g_throughfloor_debug)
1087                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1088                                                 }
1089
1090                                                 // laser force adjustments :P
1091                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1092                                                 {
1093                                                         if (targ == attacker)
1094                                                         {
1095                                                                 vector vel;
1096
1097                                                                 float force_zscale;
1098                                                                 float force_velocitybiasramp;
1099                                                                 float force_velocitybias;
1100
1101                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1102                                                                 if(deathtype & HITTYPE_SECONDARY)
1103                                                                 {
1104                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1105                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1106                                                                 }
1107                                                                 else
1108                                                                 {
1109                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1110                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1111                                                                 }
1112
1113                                                                 vel = targ.velocity;
1114                                                                 vel_z = 0;
1115                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1116                                                                 force =
1117                                                                         vlen(force)
1118                                                                         *
1119                                                                         normalize(normalize(force) + vel);
1120
1121                                                                 force_z *= force_zscale;
1122                                                         }
1123                                                         else
1124                                                         {
1125                                                                 if(deathtype & HITTYPE_SECONDARY)
1126                                                                 {
1127                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1128                                                                 }
1129                                                                 else
1130                                                                 {
1131                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1132                                                                 }
1133                                                         }
1134                                                 }
1135
1136                                                 //if (targ == attacker)
1137                                                 //{
1138                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1139                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1140                                                 //      print(" (", ftos(a), ")\n");
1141                                                 //}
1142                                                 if(finaldmg || vlen(force))
1143                                                 {
1144                                                         if(targ.iscreature)
1145                                                         {
1146                                                                 total_damage_to_creatures += finaldmg;
1147
1148                                                                 if(accuracy_isgooddamage(attacker, targ))
1149                                                                         stat_damagedone += finaldmg;
1150                                                         }
1151
1152                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1153                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1154                                                         else
1155                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1156                                                 }
1157                                         }
1158                                 }
1159                         }
1160                 targ = next;
1161         }
1162
1163         RadiusDamage_running = 0;
1164
1165         if(!DEATH_ISSPECIAL(deathtype))
1166                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1167
1168         return total_damage_to_creatures;
1169 }
1170
1171 .float fire_damagepersec;
1172 .float fire_endtime;
1173 .float fire_deathtype;
1174 .entity fire_owner;
1175 .float fire_hitsound;
1176 .entity fire_burner;
1177
1178 void fireburner_think();
1179
1180 float Fire_IsBurning(entity e)
1181 {
1182         return (time < e.fire_endtime);
1183 }
1184
1185 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1186 {
1187         float dps;
1188         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1189
1190         if(e.classname == "player")
1191         {
1192                 if(e.deadflag)
1193                         return -1;
1194         }
1195         else
1196         {
1197                 if(!e.fire_burner)
1198                 {
1199                         // print("adding a fire burner to ", e.classname, "\n");
1200                         e.fire_burner = spawn();
1201                         e.fire_burner.classname = "fireburner";
1202                         e.fire_burner.think = fireburner_think;
1203                         e.fire_burner.nextthink = time;
1204                         e.fire_burner.owner = e;
1205                 }
1206         }
1207
1208         t = max(t, 0.1);
1209         dps = d / t;
1210         if(Fire_IsBurning(e))
1211         {
1212                 mintime = e.fire_endtime - time;
1213                 maxtime = max(mintime, t);
1214
1215                 mindps = e.fire_damagepersec;
1216                 maxdps = max(mindps, dps);
1217
1218                 if(maxtime > mintime || maxdps > mindps)
1219                 {
1220                         // Constraints:
1221
1222                         // damage we have right now
1223                         mindamage = mindps * mintime;
1224
1225                         // damage we want to get
1226                         maxdamage = mindamage + d;
1227
1228                         // but we can't exceed maxtime * maxdps!
1229                         totaldamage = min(maxdamage, maxtime * maxdps);
1230
1231                         // LEMMA:
1232                         // Look at:
1233                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1234                         // We see:
1235                         // totaldamage <= maxtime * maxdps
1236                         // ==> totaldamage / maxdps <= maxtime.
1237                         // We also see:
1238                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1239                         //                     >= min(mintime, maxtime)
1240                         // ==> totaldamage / maxdps >= mintime.
1241
1242                         /*
1243                         // how long do we damage then?
1244                         // at least as long as before
1245                         // but, never exceed maxdps
1246                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1247                         */
1248
1249                         // alternate:
1250                         // at most as long as maximum allowed
1251                         // but, never below mindps
1252                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1253
1254                         // assuming t > mintime, dps > mindps:
1255                         // we get d = t * dps = maxtime * maxdps
1256                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1257                         // totaldamage / maxdps = maxtime
1258                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1259                         // FROM THIS:
1260                         // a) totaltime = max(mintime, maxtime) = maxtime
1261                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1262
1263                         // assuming t <= mintime:
1264                         // we get maxtime = mintime
1265                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1266                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1267
1268                         // assuming dps <= mindps:
1269                         // we get mindps = maxdps.
1270                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1271                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1272                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1273
1274                         e.fire_damagepersec = totaldamage / totaltime;
1275                         e.fire_endtime = time + totaltime;
1276                         if(totaldamage > 1.2 * mindamage)
1277                         {
1278                                 e.fire_deathtype = dt;
1279                                 if(e.fire_owner != o)
1280                                 {
1281                                         e.fire_owner = o;
1282                                         e.fire_hitsound = FALSE;
1283                                 }
1284                         }
1285                         if(accuracy_isgooddamage(o, e))
1286                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1287                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1288                 }
1289                 else
1290                         return 0;
1291         }
1292         else
1293         {
1294                 e.fire_damagepersec = dps;
1295                 e.fire_endtime = time + t;
1296                 e.fire_deathtype = dt;
1297                 e.fire_owner = o;
1298                 e.fire_hitsound = FALSE;
1299                 if(accuracy_isgooddamage(o, e))
1300                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1301                 return d;
1302         }
1303 }
1304
1305 void Fire_ApplyDamage(entity e)
1306 {
1307         float t, d, hi, ty;
1308         entity o;
1309
1310         if not(Fire_IsBurning(e))
1311                 return;
1312
1313         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1314         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1315                 o = e.fire_owner;
1316
1317         // water and slime stop fire
1318         if(e.waterlevel)
1319         if(e.watertype != CONTENT_LAVA)
1320                 e.fire_endtime = 0;
1321
1322         // ice stops fire
1323         if(e.freezetag_frozen)
1324                 e.fire_endtime = 0;
1325
1326         t = min(frametime, e.fire_endtime - time);
1327         d = e.fire_damagepersec * t;
1328
1329         hi = e.fire_owner.hitsound;
1330         ty = e.fire_owner.typehitsound;
1331         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1332         if(e.fire_hitsound && e.fire_owner)
1333         {
1334                 e.fire_owner.hitsound = hi;
1335                 e.fire_owner.typehitsound = ty;
1336         }
1337         e.fire_hitsound = TRUE;
1338
1339         if not(IS_INDEPENDENT_PLAYER(e))
1340         FOR_EACH_PLAYER(other) if(e != other)
1341         {
1342                 if(other.classname == "player")
1343                 if(other.deadflag == DEAD_NO)
1344                 if not(IS_INDEPENDENT_PLAYER(other))
1345                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1346                 {
1347                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1348                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1349                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1350                 }
1351         }
1352 }
1353
1354 void Fire_ApplyEffect(entity e)
1355 {
1356         if(Fire_IsBurning(e))
1357                 e.effects |= EF_FLAME;
1358         else
1359                 e.effects &~= EF_FLAME;
1360 }
1361
1362 void fireburner_think()
1363 {
1364         // for players, this is done in the regular loop
1365         if(wasfreed(self.owner))
1366         {
1367                 remove(self);
1368                 return;
1369         }
1370         Fire_ApplyEffect(self.owner);
1371         if(!Fire_IsBurning(self.owner))
1372         {
1373                 self.owner.fire_burner = world;
1374                 remove(self);
1375                 return;
1376         }
1377         Fire_ApplyDamage(self.owner);
1378         self.nextthink = time;
1379 }