qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50 float headshot;
  51 float damage_headshotbonus; // bonus multiplier for head shots, set to 0 after use
  52
  53 .float dmg_team;
  54 .float teamkill_complain;
  55 .float teamkill_soundtime;
  56 .entity teamkill_soundsource;
  57 .entity pusher;
  58 .float istypefrag;
  59 .float taunt_soundtime;
  60
  61
  62 float IsDifferentTeam(entity a, entity b)
  63 {
  64         if(teamplay)
  65         {
  66                 if(a.team == b.team)
  67                         return 0;
  68         }
  69         else
  70         {
  71                 if(a == b)
  72                         return 0;
  73         }
  74         return 1;
  75 }
  76
  77 float IsFlying(entity a)
  78 {
  79         if(a.flags & FL_ONGROUND)
  80                 return 0;
  81         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  82                 return 0;
  83         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  84         if(trace_fraction < 1)
  85                 return 0;
  86         return 1;
  87 }
  88
  89 vector GetHeadshotMins(entity targ)
  90 {
  91         return '-0.5 0 0' * PL_HEAD_x + '0 -0.5 0' * PL_HEAD_y + '0 0 1' * (targ.maxs_z - PL_HEAD_z);
  92 }
  93 vector GetHeadshotMaxs(entity targ)
  94 {
  95         return '0.5 0 0' * PL_HEAD_x + '0 0.5 0' * PL_HEAD_y + '0 0 1' * targ.maxs_z;
  96 }
  97
  98 void UpdateFrags(entity player, float f)
  99 {
 100         PlayerTeamScore_AddScore(player, f);
 101 }
 102
 103 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
 104 void W_SwitchWeapon_Force(entity e, float w);
 105 entity GiveFrags_randomweapons;
 106 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
 107 {
 108         // TODO route through PlayerScores instead
 109         if(gameover) return;
 110
 111         if(f < 0)
 112         {
 113                 if(targ == attacker)
 114                 {
 115                         // suicide
 116                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 117                 }
 118                 else
 119                 {
 120                         // teamkill
 121                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 122                 }
 123         }
 124         else
 125         {
 126                 // regular frag
 127                 PlayerScore_Add(attacker, SP_KILLS, 1);
 128                 if(targ.playerid)
 129                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 130         }
 131
 132         PlayerScore_Add(targ, SP_DEATHS, 1);
 133
 134         if(g_arena || g_ca)
 135                 if(autocvar_g_arena_roundbased)
 136                         return;
 137
 138         if(targ != attacker) // not for suicides
 139         if(g_weaponarena_random)
 140         {
 141                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 142                 float culprit;
 143                 culprit = DEATH_WEAPONOF(deathtype);
 144                 if(!culprit)
 145                         culprit = attacker.weapon;
 146                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 147                         culprit = attacker.weapon;
 148
 149                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 150                 {
 151                         // no exchange
 152                 }
 153                 else
 154                 {
 155                         if(!GiveFrags_randomweapons)
 156                         {
 157                                 GiveFrags_randomweapons = spawn();
 158                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 159                         }
 160
 161                         if(inWarmupStage)
 162                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 163                         else
 164                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 165
 166                         // all others (including the culprit): remove
 167                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 168                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 169
 170                         // among the remaining ones, choose one by random
 171                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 172
 173                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 174                         {
 175                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 176                                 WEPSET_ANDNOT_EW(attacker, culprit);
 177                         }
 178                 }
 179
 180                 // after a frag, choose another random weapon set
 181                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 182                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 183         }
 184
 185         // FIXME fix the mess this is (we have REAL points now!)
 186         entity oldself;
 187         oldself = self;
 188         self = attacker;
 189         frag_attacker = attacker;
 190         frag_target = targ;
 191         frag_score = f;
 192         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 193         {
 194                 f = frag_score;
 195                 self = oldself;
 196         }
 197         else
 198         {
 199                 self = oldself;
 200                 if(g_runematch)
 201                 {
 202                         f = RunematchHandleFrags(attacker, targ, f);
 203                 }
 204                 else if(g_lms)
 205                 {
 206                         // remove a life
 207                         float tl;
 208                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 209                         if(tl < lms_lowest_lives)
 210                                 lms_lowest_lives = tl;
 211                         if(tl <= 0)
 212                         {
 213                                 if(!lms_next_place)
 214                                         lms_next_place = player_count;
 215                                 else
 216                                         lms_next_place = min(lms_next_place, player_count);
 217                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 218                                 --lms_next_place;
 219                         }
 220                         f = 0;
 221                 }
 222         }
 223
 224         attacker.totalfrags += f;
 225
 226         if(f)
 227                 UpdateFrags(attacker, f);
 228 }
 229
 230 string Obituary_ExtraFragInfo(entity player) // Extra fragmessage information
 231 {
 232         string health_output = string_null;
 233         string ping_output = string_null;
 234         string handicap_output = string_null;
 235         string output = string_null;
 236
 237         if(autocvar_sv_fraginfo && ((autocvar_sv_fraginfo == 2) || inWarmupStage))
 238         {
 239                 // health/armor of attacker (person who killed you)
 240                 if(autocvar_sv_fraginfo_stats && (player.health >= 1))
 241                         health_output = strcat("^7(Health ^1", ftos(rint(player.health)), "^7 / Armor ^2", ftos(rint(player.armorvalue)), "^7)");
 242
 243                 // ping display
 244                 if(autocvar_sv_fraginfo_ping)
 245                         ping_output = ((clienttype(player) == CLIENTTYPE_BOT) ? "^2Bot" : strcat("Ping ", ((player.ping >= 150) ? "^1" : "^2"), ftos(rint(player.ping)), "ms"));
 246
 247                 // handicap display
 248                 if(autocvar_sv_fraginfo_handicap)
 249                 {
 250                         if(autocvar_sv_fraginfo_handicap == 2)
 251                                 handicap_output = strcat(output, strcat("Handicap ^2", ((player.cvar_cl_handicap <= 1) ? "Off" : ftos(rint(player.cvar_cl_handicap)))));
 252                         else if(player.cvar_cl_handicap) // with _handicap 1, only show this if there actually is a handicap enabled.
 253                                 handicap_output = strcat("Handicap ^2", ftos(rint(player.cvar_cl_handicap)));
 254                 }
 255
 256                 // format the string
 257                 output = strcat(health_output, (health_output ? ((ping_output || handicap_output) ? " ^7(" : "") : ((ping_output || handicap_output) ? "^7(" : "")),
 258                         ping_output, (handicap_output ? "^7 / " : ""),
 259                         handicap_output, ((ping_output || handicap_output) ? "^7)" : ""));
 260
 261                 // add new line to the beginning if there is a message
 262                 if(output) { output = strcat("\n", output); }
 263         }
 264
 265         return output;
 266 }
 267
 268 string AppendItemcodes(string s, entity player)
 269 {
 270         float w;
 271         w = player.weapon;
 272         //if(w == 0)
 273         //      w = player.switchweapon;
 274         if(w == 0)
 275                 w = player.cnt; // previous weapon!
 276         s = strcat(s, ftos(w));
 277         if(time < player.strength_finished)
 278                 s = strcat(s, "S");
 279         if(time < player.invincible_finished)
 280                 s = strcat(s, "I");
 281         if(player.flagcarried != world)
 282                 s = strcat(s, "F");
 283         if(player.BUTTON_CHAT)
 284                 s = strcat(s, "T");
 285         if(player.kh_next)
 286                 s = strcat(s, "K");
 287         if(player.runes)
 288                 s = strcat(s, "|", ftos(player.runes));
 289         return s;
 290 }
 291
 292 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 293 {
 294         string s;
 295         if(!autocvar_sv_eventlog)
 296                 return;
 297         s = strcat(":kill:", mode);
 298         s = strcat(s, ":", ftos(killer.playerid));
 299         s = strcat(s, ":", ftos(killed.playerid));
 300         s = strcat(s, ":type=", ftos(deathtype));
 301         s = strcat(s, ":items=");
 302         s = AppendItemcodes(s, killer);
 303         if(killed != killer)
 304         {
 305                 s = strcat(s, ":victimitems=");
 306                 s = AppendItemcodes(s, killed);
 307         }
 308         GameLogEcho(s);
 309 }
 310
 311 void Send_KillNotification (string s1, string s2, string s3, float msg, float type)
 312 {
 313         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
 314         WriteByte(MSG_BROADCAST, TE_CSQC_KILLNOTIFY);
 315         WriteString(MSG_BROADCAST, s1);
 316         WriteString(MSG_BROADCAST, s2);
 317         WriteString(MSG_BROADCAST, s3);
 318         WriteShort(MSG_BROADCAST, msg);
 319         WriteByte(MSG_BROADCAST, type);
 320 }
 321
 322 // Function is used to send a generic centerprint whose content CSQC gets to decide (gentle version or not in the below cases)
 323 void Send_CSQC_KillCenterprint(entity e, string s1, string s2, float msg, float type)
 324 {
 325         if (clienttype(e) == CLIENTTYPE_REAL)
 326         {
 327                 msg_entity = e;
 328                 WRITESPECTATABLE_MSG_ONE({
 329                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 330                         WriteByte(MSG_ONE, TE_CSQC_KILLCENTERPRINT);
 331                         WriteString(MSG_ONE, s1);
 332                         WriteString(MSG_ONE, s2);
 333                         WriteShort(MSG_ONE, msg);
 334                         WriteByte(MSG_ONE, type);
 335                 });
 336         }
 337 }
 338
 339 void Obituary (entity attacker, entity inflictor, entity targ, float deathtype)
 340 {
 341         string  s, a, msg;
 342         float type;
 343
 344         if (targ.classname == "player")
 345         {
 346                 s = targ.netname;
 347                 a = attacker.netname;
 348
 349                 if (targ == attacker) // suicides
 350                 {
 351                         if (deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 352                                 msg = ColoredTeamName(targ.team); // TODO: check if needed?
 353                         else
 354                                 msg = "";
 355             if(!g_cts) // no "killed your own dumb self" message in CTS
 356                 Send_CSQC_KillCenterprint(targ, msg, "", deathtype, MSG_SUICIDE);
 357
 358                         if(deathtype != DEATH_TEAMCHANGE && deathtype != DEATH_QUIET)
 359                         {
 360                                 LogDeath("suicide", deathtype, targ, targ);
 361                                 GiveFrags(attacker, targ, -1, deathtype);
 362                         }
 363
 364                         if (targ.killcount > 2)
 365                                 msg = ftos(targ.killcount);
 366                         else
 367                                 msg = "";
 368                         if(teamplay && deathtype == DEATH_MIRRORDAMAGE)
 369                         {
 370                                 if(attacker.team == COLOR_TEAM1)
 371                                         deathtype = KILL_TEAM_RED;
 372                                 else
 373                                         deathtype = KILL_TEAM_BLUE;
 374                         }
 375
 376                         Send_KillNotification(s, msg, "", deathtype, MSG_SUICIDE);
 377                 }
 378                 else if (attacker.classname == "player")
 379                 {
 380                         if(!IsDifferentTeam(attacker, targ))
 381                         {
 382                                 if(attacker.team == COLOR_TEAM1)
 383                                         type = KILL_TEAM_RED;
 384                                 else
 385                                         type = KILL_TEAM_BLUE;
 386
 387                                 GiveFrags(attacker, targ, -1, deathtype);
 388
 389                                 Send_CSQC_KillCenterprint(attacker, s, "", type, MSG_KILL);
 390
 391                                 if (targ.killcount > 2)
 392                                         msg = ftos(targ.killcount);
 393                                 else
 394                                         msg = "";
 395
 396                                 if (attacker.killcount > 2) {
 397                                         msg = ftos(attacker.killcount);
 398                                         type = KILL_TEAM_SPREE;
 399                                 }
 400                                 Send_KillNotification(a, s, msg, type, MSG_KILL);
 401
 402                                 attacker.killcount = 0;
 403
 404                                 LogDeath("tk", deathtype, attacker, targ);
 405                         }
 406                         else
 407                         {
 408                                 if (!checkrules_firstblood)
 409                                 {
 410                                         checkrules_firstblood = TRUE;
 411                                         Send_KillNotification(a, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 412                                         // TODO: make these print a newline if they dont
 413                                         Send_CSQC_KillCenterprint(attacker, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 414                                         Send_CSQC_KillCenterprint(targ, "", "", KILL_FIRST_VICTIM, MSG_KILL);
 415                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 416                                         PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 417                                 }
 418
 419                                 if(targ.istypefrag) {
 420                                         Send_CSQC_KillCenterprint(attacker, s, Obituary_ExtraFragInfo(targ), KILL_TYPEFRAG, MSG_KILL);
 421                                         Send_CSQC_KillCenterprint(targ, a, Obituary_ExtraFragInfo(attacker), KILL_TYPEFRAGGED, MSG_KILL);
 422                                 } else {
 423                                         Send_CSQC_KillCenterprint(attacker, s, Obituary_ExtraFragInfo(targ), KILL_FRAG, MSG_KILL);
 424                                         Send_CSQC_KillCenterprint(targ, a, Obituary_ExtraFragInfo(attacker), KILL_FRAGGED, MSG_KILL);
 425                                 }
 426
 427                                 attacker.taunt_soundtime = time + 1;
 428
 429                                 if (deathtype == DEATH_HURTTRIGGER && inflictor.message2 != "")
 430                                         msg = inflictor.message2;
 431                                 else if (deathtype == DEATH_CUSTOM)
 432                                         msg = deathmessage;
 433                                 else
 434                                         msg = "";
 435
 436                                 if(strstrofs(msg, "%", 0) < 0)
 437                                         msg = strcat("%s ", msg, " by %s");
 438
 439                                 Send_KillNotification(a, s, msg, deathtype, MSG_KILL);
 440
 441                                 GiveFrags(attacker, targ, 1, deathtype);
 442
 443                                 if (targ.killcount > 2) {
 444                                         Send_KillNotification(s, ftos(targ.killcount), a, KILL_END_SPREE, MSG_SPREE);
 445                                 }
 446
 447                                 attacker.killcount = attacker.killcount + 1;
 448
 449                                 if (attacker.killcount == 3)
 450                                 {
 451                                         Send_KillNotification(a, "", "", KILL_SPREE_3, MSG_SPREE);
 452                                         AnnounceTo(attacker, "03kills");
 453                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_3, 1);
 454                                 }
 455                                 else if (attacker.killcount == 5)
 456                                 {
 457                                         Send_KillNotification(a, "", "", KILL_SPREE_5, MSG_SPREE);
 458                                         AnnounceTo(attacker, "05kills");
 459                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_5, 1);
 460                                 }
 461                                 else if (attacker.killcount == 10)
 462                                 {
 463                                         Send_KillNotification(a, "", "", KILL_SPREE_10, MSG_SPREE);
 464                                         AnnounceTo(attacker, "10kills");
 465                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_10, 1);
 466                                 }
 467                                 else if (attacker.killcount == 15)
 468                                 {
 469                                         Send_KillNotification(a, "", "", KILL_SPREE_15, MSG_SPREE);
 470                                         AnnounceTo(attacker, "15kills");
 471                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_15, 1);
 472                                 }
 473                                 else if (attacker.killcount == 20)
 474                                 {
 475                                         Send_KillNotification(a, "", "", KILL_SPREE_20, MSG_SPREE);
 476                                         AnnounceTo(attacker, "20kills");
 477                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_20, 1);
 478                                 }
 479                                 else if (attacker.killcount == 25)
 480                                 {
 481                                         Send_KillNotification(a, "", "", KILL_SPREE_25, MSG_SPREE);
 482                                         AnnounceTo(attacker, "25kills");
 483                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_25, 1);
 484                                 }
 485                                 else if (attacker.killcount == 30)
 486                                 {
 487                                         Send_KillNotification(a, "", "", KILL_SPREE_30, MSG_SPREE);
 488                                         AnnounceTo(attacker, "30kills");
 489                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_30, 1);
 490                                 }
 491                                 else if (attacker.killcount > 2) {
 492                                         Send_KillNotification(a, ftos(attacker.killcount), "", KILL_SPREE, MSG_SPREE);
 493                                 }
 494                                 LogDeath("frag", deathtype, attacker, targ);
 495                         }
 496                 }
 497                 else
 498                 {
 499                         Send_CSQC_KillCenterprint(targ, "", "", deathtype, MSG_KILL_ACTION);
 500                         if (deathtype == DEATH_HURTTRIGGER && inflictor.message != "")
 501                                 msg = inflictor.message;
 502                         else if (deathtype == DEATH_CUSTOM)
 503                                 msg = deathmessage;
 504                         else
 505                                 msg = "";
 506                         if(strstrofs(msg, "%", 0) < 0)
 507                                 msg = strcat("%s ", msg);
 508
 509                         GiveFrags(targ, targ, -1, deathtype);
 510                         if(PlayerScore_Add(targ, SP_SCORE, 0) == -5) {
 511                                 AnnounceTo(targ, "botlike");
 512                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 513                         }
 514                         Send_KillNotification(s, msg, "", deathtype, MSG_KILL_ACTION);
 515
 516                         if (targ.killcount > 2)
 517                                 Send_KillNotification(s, ftos(targ.killcount), "", 0, MSG_KILL_ACTION_SPREE);
 518
 519                         LogDeath("accident", deathtype, targ, targ);
 520                 }
 521
 522                 targ.death_origin = targ.origin;
 523                 if(targ != attacker)
 524                         targ.killer_origin = attacker.origin;
 525
 526                 // FIXME: this should go in PutClientInServer
 527                 if (targ.killcount)
 528                         targ.killcount = 0;
 529         }
 530 }
 531
 532 // these are updated by each Damage call for use in button triggering and such
 533 entity damage_targ;
 534 entity damage_inflictor;
 535 entity damage_attacker;
 536
 537 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 538 {
 539         float mirrordamage;
 540         float mirrorforce;
 541         float teamdamage0;
 542         entity attacker_save;
 543         mirrordamage = 0;
 544         mirrorforce = 0;
 545
 546         if (gameover || targ.killcount == -666)
 547                 return;
 548
 549         entity oldself;
 550         oldself = self;
 551         self = targ;
 552         damage_targ = targ;
 553         damage_inflictor = inflictor;
 554         damage_attacker = attacker;
 555                 attacker_save = attacker;
 556
 557         if(targ.classname == "player")
 558                 if(targ.hook)
 559                         if(targ.hook.aiment)
 560                                 if(targ.hook.aiment == attacker)
 561                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 562
 563         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 564         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 565         {
 566                 if(targ.classname == "player")
 567                         if not(IsDifferentTeam(targ, attacker))
 568                         {
 569                                 self = oldself;
 570                                 return;
 571                         }
 572         }
 573
 574         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE || deathtype == DEATH_QUIET)
 575         {
 576                 // These are ALWAYS lethal
 577                 // No damage modification here
 578                 // Instead, prepare the victim for his death...
 579                 targ.armorvalue = 0;
 580                 targ.spawnshieldtime = 0;
 581                 targ.health = 0.9; // this is < 1
 582                 targ.flags -= targ.flags & FL_GODMODE;
 583                 damage = 100000;
 584         }
 585         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 586         {
 587                 // no processing
 588         }
 589         else
 590         {
 591                 /*
 592                 skill based bot damage? gtfo. (tZork)
 593                 if (targ.classname == "player")
 594                 if (attacker.classname == "player")
 595                 if (!targ.isbot)
 596                 if (attacker.isbot)
 597                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 598         */
 599
 600                 // nullify damage if teamplay is on
 601                 if(deathtype != DEATH_TELEFRAG)
 602                 if(attacker.classname == "player")
 603                 {
 604                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 605                         {
 606                                 damage = 0;
 607                                 force = '0 0 0';
 608                         }
 609                         else if(!IsDifferentTeam(attacker, targ))
 610                         {
 611                                 if(autocvar_teamplay_mode == 1)
 612                                         damage = 0;
 613                                 else if(attacker != targ)
 614                                 {
 615                                         if(autocvar_teamplay_mode == 3)
 616                                                 damage = 0;
 617                                         else if(autocvar_teamplay_mode == 4)
 618                                         {
 619                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 620                                                 {
 621                                                         teamdamage0 = max(attacker.dmg_team, autocvar_g_teamdamage_threshold);
 622                                                         attacker.dmg_team = attacker.dmg_team + damage;
 623                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 624                                                                 mirrordamage = autocvar_g_mirrordamage * (attacker.dmg_team - teamdamage0);
 625                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 626                                                         if(g_ca)
 627                                                                 damage = 0;
 628                                                         else
 629                                                                 damage = autocvar_g_friendlyfire * damage;
 630                                                         // mirrordamage will be used LATER
 631
 632                                                         if(autocvar_g_mirrordamage_virtual)
 633                                                         {
 634                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 635                                                                 attacker.dmg_take += v_x;
 636                                                                 attacker.dmg_save += v_y;
 637                                                                 attacker.dmg_inflictor = inflictor;
 638                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 639                                                                 mirrorforce = 0;
 640                                                         }
 641
 642                                                         if(autocvar_g_friendlyfire_virtual)
 643                                                         {
 644                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 645                                                                 targ.dmg_take += v_x;
 646                                                                 targ.dmg_save += v_y;
 647                                                                 targ.dmg_inflictor = inflictor;
 648                                                                 damage = 0;
 649                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 650                                                                         force = '0 0 0';
 651                                                         }
 652                                                 }
 653                                                 else
 654                                                         damage = 0;
 655                                         }
 656                                 }
 657                         }
 658                 }
 659
 660                 if(targ.classname == "player")
 661                 if(attacker.classname == "player")
 662                 if(attacker != targ)
 663                 {
 664                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 665                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 666                 }
 667
 668                 if not(DEATH_ISSPECIAL(deathtype))
 669                 {
 670                         damage *= g_weapondamagefactor;
 671                         mirrordamage *= g_weapondamagefactor;
 672                         force = force * g_weaponforcefactor;
 673                         mirrorforce *= g_weaponforcefactor;
 674                 }
 675
 676                 // should this be changed at all? If so, in what way?
 677                 frag_attacker = attacker;
 678                 frag_target = targ;
 679                 frag_damage = damage;
 680                 frag_force = force;
 681         frag_deathtype = deathtype;
 682                 frag_mirrordamage = mirrordamage;
 683                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 684                 damage = frag_damage;
 685                 mirrordamage = frag_mirrordamage;
 686                 force = frag_force;
 687
 688                 if not(g_minstagib)
 689                 {
 690                         // apply strength multiplier
 691                         if (attacker.items & IT_STRENGTH)
 692                         {
 693                                 if(targ == attacker)
 694                                 {
 695                                         damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 696                                         force = force * autocvar_g_balance_powerup_strength_selfforce;
 697                                 }
 698                                 else
 699                                 {
 700                                         damage = damage * autocvar_g_balance_powerup_strength_damage;
 701                                         force = force * autocvar_g_balance_powerup_strength_force;
 702                                 }
 703                         }
 704
 705                         // apply invincibility multiplier
 706                         if (targ.items & IT_INVINCIBLE)
 707                                 damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 708                 }
 709
 710                 if (targ == attacker)
 711                 {
 712                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 713                                 damage = 0;
 714                         else
 715                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 716                 }
 717
 718                 if(g_runematch)
 719                 {
 720                         // apply strength rune
 721                         if (attacker.runes & RUNE_STRENGTH)
 722                         {
 723                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 724                                 {
 725                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 726                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 727                                 }
 728                                 else
 729                                 {
 730                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 731                                         force = force * autocvar_g_balance_rune_strength_force;
 732                                 }
 733                         }
 734                         else if (attacker.runes & CURSE_WEAK)
 735                         {
 736                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 737                                 force = force * autocvar_g_balance_curse_weak_force;
 738                         }
 739
 740                         // apply defense rune
 741                         if (targ.runes & RUNE_DEFENSE)
 742                         {
 743                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 744                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 745                                 else
 746                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 747                         }
 748                         else if (targ.runes & CURSE_VULNER)
 749                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 750                 }
 751
 752                 // count the damage
 753                 if(attacker)
 754                 if(!targ.deadflag)
 755                 if(targ.takedamage == DAMAGE_AIM)
 756                 if(targ != attacker)
 757                 {
 758                         if(damage_headshotbonus)
 759                         {
 760                                 if(targ.classname == "player")
 761                                 {
 762                                         // HEAD SHOT:
 763                                         // find height of hit on player axis
 764                                         // if above view_ofs and below maxs, and also in the middle half of the bbox, it is head shot
 765                                         vector headmins, headmaxs, org;
 766                                         org = antilag_takebackorigin(targ, time - ANTILAG_LATENCY(attacker));
 767                                         headmins = org + GetHeadshotMins(targ);
 768                                         headmaxs = org + GetHeadshotMaxs(targ);
 769                                         if(trace_hits_box(railgun_start, railgun_end, headmins, headmaxs))
 770                                         {
 771                                                 deathtype |= HITTYPE_HEADSHOT;
 772                                         }
 773                                 }
 774                                 else if(targ.classname == "turret_head")
 775                                 {
 776                                         deathtype |= HITTYPE_HEADSHOT;
 777                                 }
 778                                 if(deathtype & HITTYPE_HEADSHOT)
 779                                         if(damage_headshotbonus > 0)
 780                                                 damage *= 1 + damage_headshotbonus;
 781                         }
 782
 783                         entity victim;
 784                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 785                                 victim = targ.owner;
 786                         else
 787                                 victim = targ;
 788
 789                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 790                         {
 791                                 if(IsDifferentTeam(victim, attacker))
 792                                 {
 793                                         if(damage > 0)
 794                                         {
 795                                                 if(deathtype != DEATH_FIRE)
 796                                                 {
 797                                                         if(victim.BUTTON_CHAT)
 798                                                                 attacker.typehitsound += 1;
 799                                                         else
 800                                                                 attacker.hitsound += 1;
 801                                                 }
 802
 803                                                 damage_goodhits += 1;
 804                                                 damage_gooddamage += damage;
 805
 806                                                 if not(DEATH_ISSPECIAL(deathtype))
 807                                                 {
 808                                                         if(targ.classname == "player") // don't do this for vehicles
 809                                                         if(IsFlying(victim))
 810                                                                 yoda = 1;
 811
 812                                                         if(deathtype & HITTYPE_HEADSHOT)
 813                                                                 headshot = 1;
 814                                                 }
 815                                         }
 816                                 }
 817                                 else
 818                                 {
 819                                         if(deathtype != DEATH_FIRE)
 820                                         {
 821                                                 attacker.typehitsound += 1;
 822                                         }
 823                                         if(mirrordamage > 0)
 824                                                 if(time > attacker.teamkill_complain)
 825                                                 {
 826                                                         attacker.teamkill_complain = time + 5;
 827                                                         attacker.teamkill_soundtime = time + 0.4;
 828                                                         attacker.teamkill_soundsource = targ;
 829                                                 }
 830                                 }
 831                         }
 832                 }
 833         }
 834
 835         // apply push
 836         if (self.damageforcescale)
 837         if (vlen(force))
 838         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 839         {
 840                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 841                 if(self.movetype == MOVETYPE_PHYSICS)
 842                 {
 843                         entity farcent;
 844                         farcent = spawn();
 845                         farcent.classname = "farce";
 846                         farcent.enemy = self;
 847                         farcent.movedir = farce * 10;
 848                         if(self.mass)
 849                                 farcent.movedir = farcent.movedir * self.mass;
 850                         farcent.origin = hitloc;
 851                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 852                         farcent.nextthink = time + 0.1;
 853                         farcent.think = SUB_Remove;
 854                 }
 855                 else
 856                         self.velocity = self.velocity + farce;
 857                 self.flags &~= FL_ONGROUND;
 858                 UpdateCSQCProjectile(self);
 859         }
 860         // apply damage
 861         if (damage != 0 || (self.damageforcescale && vlen(force)))
 862         if (self.event_damage)
 863                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 864         self = oldself;
 865
 866         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 867         {
 868                 if(g_runematch)
 869                 {
 870                         if (attacker.runes & RUNE_VAMPIRE)
 871                         {
 872                         // apply vampire rune
 873                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 874                                 {
 875                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 876                                         attacker.health = bound(
 877                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 878                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 879                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 880                                 }
 881                                 else
 882                                 {
 883                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 884                                         attacker.health = bound(
 885                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 886                                                                                         // empathy won't let you gain health in the same way...
 887                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 888                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 889                                         }
 890                         }
 891                         // apply empathy curse
 892                         else if (attacker.runes & CURSE_EMPATHY)
 893                         {
 894                                 attacker.health = bound(
 895                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 896                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 897                                         attacker.health);
 898                         }
 899                 }
 900         }
 901
 902         // apply mirror damage if any
 903         if(mirrordamage > 0 || mirrorforce > 0)
 904         {
 905                 attacker = attacker_save;
 906
 907                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 908                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 909         }
 910 }
 911
 912 float RadiusDamage_running;
 913 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 914         // Returns total damage applies to creatures
 915 {
 916         entity  targ;
 917         vector  blastorigin;
 918         vector  force;
 919         float   total_damage_to_creatures;
 920         entity  next;
 921         float   tfloordmg;
 922         float   tfloorforce;
 923
 924         float stat_damagedone;
 925
 926         if(RadiusDamage_running)
 927         {
 928                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 929                 return 0;
 930         }
 931
 932         RadiusDamage_running = 1;
 933
 934         tfloordmg = autocvar_g_throughfloor_damage;
 935         tfloorforce = autocvar_g_throughfloor_force;
 936
 937         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 938         total_damage_to_creatures = 0;
 939
 940         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 941                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 942                 {
 943                         force = inflictor.velocity;
 944                         if(vlen(force) == 0)
 945                                 force = '0 0 -1';
 946                         else
 947                                 force = normalize(force);
 948                         if(forceintensity >= 0)
 949                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
 950                         else
 951                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
 952                 }
 953
 954         stat_damagedone = 0;
 955
 956         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
 957         while (targ)
 958         {
 959                 next = targ.chain;
 960                 if (targ != inflictor)
 961                         if (ignore != targ) if(targ.takedamage)
 962                         {
 963                                 vector nearest;
 964                                 vector diff;
 965                                 float power;
 966
 967                                 // LordHavoc: measure distance to nearest point on target (not origin)
 968                                 // (this guarentees 100% damage on a touch impact)
 969                                 nearest = targ.WarpZone_findradius_nearest;
 970                                 diff = targ.WarpZone_findradius_dist;
 971                                 // round up a little on the damage to ensure full damage on impacts
 972                                 // and turn the distance into a fraction of the radius
 973                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
 974                                 //bprint(" ");
 975                                 //bprint(ftos(power));
 976                                 //if (targ == attacker)
 977                                 //      print(ftos(power), "\n");
 978                                 if (power > 0)
 979                                 {
 980                                         float finaldmg;
 981                                         if (power > 1)
 982                                                 power = 1;
 983                                         finaldmg = coredamage * power + edgedamage * (1 - power);
 984                                         if (finaldmg > 0)
 985                                         {
 986                                                 float a;
 987                                                 float c;
 988                                                 vector hitloc;
 989                                                 vector myblastorigin;
 990                                                 vector center;
 991
 992                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
 993
 994                                                 // if it's a player, use the view origin as reference
 995                                                 center = CENTER_OR_VIEWOFS(targ);
 996
 997                                                 force = normalize(center - myblastorigin);
 998                                                 force = force * (finaldmg / coredamage) * forceintensity;
 999                                                 hitloc = nearest;
1000
1001                                                 if(targ != directhitentity)
1002                                                 {
1003                                                         float hits;
1004                                                         float total;
1005                                                         float hitratio;
1006                                                         float mininv_f, mininv_d;
1007
1008                                                         // test line of sight to multiple positions on box,
1009                                                         // and do damage if any of them hit
1010                                                         hits = 0;
1011
1012                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1013                                                         // so for a given max stddev:
1014                                                         // n = (1 / (2 * max stddev of hitratio))^2
1015
1016                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1017                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1018
1019                                                         if(autocvar_g_throughfloor_debug)
1020                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1021
1022                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1023
1024                                                         if(autocvar_g_throughfloor_debug)
1025                                                                 print(sprintf(" steps=%f", total));
1026
1027                                                         if (targ.classname == "player")
1028                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1029                                                         else
1030                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1031
1032                                                         if(autocvar_g_throughfloor_debug)
1033                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1034
1035                                                         for(c = 0; c < total; ++c)
1036                                                         {
1037                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1038                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1039                                                                 if (trace_fraction == 1 || trace_ent == targ)
1040                                                                 {
1041                                                                         ++hits;
1042                                                                         if (hits > 1)
1043                                                                                 hitloc = hitloc + nearest;
1044                                                                         else
1045                                                                                 hitloc = nearest;
1046                                                                 }
1047                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1048                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1049                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1050                                                         }
1051
1052                                                         nearest = hitloc * (1 / max(1, hits));
1053                                                         hitratio = (hits / total);
1054                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1055                                                         finaldmg = finaldmg * a;
1056                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1057                                                         force = force * a;
1058
1059                                                         if(autocvar_g_throughfloor_debug)
1060                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1061                                                 }
1062
1063                                                 // laser force adjustments :P
1064                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1065                                                 {
1066                                                         if (targ == attacker)
1067                                                         {
1068                                                                 vector vel;
1069
1070                                                                 float force_zscale;
1071                                                                 float force_velocitybiasramp;
1072                                                                 float force_velocitybias;
1073
1074                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1075                                                                 if(deathtype & HITTYPE_SECONDARY)
1076                                                                 {
1077                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1078                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1079                                                                 }
1080                                                                 else
1081                                                                 {
1082                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1083                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1084                                                                 }
1085
1086                                                                 vel = targ.velocity;
1087                                                                 vel_z = 0;
1088                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1089                                                                 force =
1090                                                                         vlen(force)
1091                                                                         *
1092                                                                         normalize(normalize(force) + vel);
1093
1094                                                                 force_z *= force_zscale;
1095                                                         }
1096                                                         else
1097                                                         {
1098                                                                 if(deathtype & HITTYPE_SECONDARY)
1099                                                                 {
1100                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1101                                                                 }
1102                                                                 else
1103                                                                 {
1104                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1105                                                                 }
1106                                                         }
1107                                                 }
1108
1109                                                 //if (targ == attacker)
1110                                                 //{
1111                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1112                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1113                                                 //      print(" (", ftos(a), ")\n");
1114                                                 //}
1115                                                 if(finaldmg || vlen(force))
1116                                                 {
1117                                                         if(targ.iscreature)
1118                                                         {
1119                                                                 total_damage_to_creatures += finaldmg;
1120
1121                                                                 if(accuracy_isgooddamage(attacker, targ))
1122                                                                         stat_damagedone += finaldmg;
1123                                                         }
1124
1125                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1126                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1127                                                         else
1128                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1129                                                 }
1130                                         }
1131                                 }
1132                         }
1133                 targ = next;
1134         }
1135
1136         RadiusDamage_running = 0;
1137
1138         if(!DEATH_ISSPECIAL(deathtype))
1139                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1140
1141         return total_damage_to_creatures;
1142 }
1143
1144 .float fire_damagepersec;
1145 .float fire_endtime;
1146 .float fire_deathtype;
1147 .entity fire_owner;
1148 .float fire_hitsound;
1149 .entity fire_burner;
1150
1151 void fireburner_think();
1152
1153 float Fire_IsBurning(entity e)
1154 {
1155         return (time < e.fire_endtime);
1156 }
1157
1158 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1159 {
1160         float dps;
1161         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1162
1163         if(e.classname == "player")
1164         {
1165                 if(e.deadflag)
1166                         return -1;
1167         }
1168         else
1169         {
1170                 if(!e.fire_burner)
1171                 {
1172                         // print("adding a fire burner to ", e.classname, "\n");
1173                         e.fire_burner = spawn();
1174                         e.fire_burner.classname = "fireburner";
1175                         e.fire_burner.think = fireburner_think;
1176                         e.fire_burner.nextthink = time;
1177                         e.fire_burner.owner = e;
1178                 }
1179         }
1180
1181         t = max(t, 0.1);
1182         dps = d / t;
1183         if(Fire_IsBurning(e))
1184         {
1185                 mintime = e.fire_endtime - time;
1186                 maxtime = max(mintime, t);
1187
1188                 mindps = e.fire_damagepersec;
1189                 maxdps = max(mindps, dps);
1190
1191                 if(maxtime > mintime || maxdps > mindps)
1192                 {
1193                         // Constraints:
1194
1195                         // damage we have right now
1196                         mindamage = mindps * mintime;
1197
1198                         // damage we want to get
1199                         maxdamage = mindamage + d;
1200
1201                         // but we can't exceed maxtime * maxdps!
1202                         totaldamage = min(maxdamage, maxtime * maxdps);
1203
1204                         // LEMMA:
1205                         // Look at:
1206                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1207                         // We see:
1208                         // totaldamage <= maxtime * maxdps
1209                         // ==> totaldamage / maxdps <= maxtime.
1210                         // We also see:
1211                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1212                         //                     >= min(mintime, maxtime)
1213                         // ==> totaldamage / maxdps >= mintime.
1214
1215                         /*
1216                         // how long do we damage then?
1217                         // at least as long as before
1218                         // but, never exceed maxdps
1219                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1220                         */
1221
1222                         // alternate:
1223                         // at most as long as maximum allowed
1224                         // but, never below mindps
1225                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1226
1227                         // assuming t > mintime, dps > mindps:
1228                         // we get d = t * dps = maxtime * maxdps
1229                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1230                         // totaldamage / maxdps = maxtime
1231                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1232                         // FROM THIS:
1233                         // a) totaltime = max(mintime, maxtime) = maxtime
1234                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1235
1236                         // assuming t <= mintime:
1237                         // we get maxtime = mintime
1238                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1239                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1240
1241                         // assuming dps <= mindps:
1242                         // we get mindps = maxdps.
1243                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1244                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1245                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1246
1247                         e.fire_damagepersec = totaldamage / totaltime;
1248                         e.fire_endtime = time + totaltime;
1249                         if(totaldamage > 1.2 * mindamage)
1250                         {
1251                                 e.fire_deathtype = dt;
1252                                 if(e.fire_owner != o)
1253                                 {
1254                                         e.fire_owner = o;
1255                                         e.fire_hitsound = FALSE;
1256                                 }
1257                         }
1258                         if(accuracy_isgooddamage(o, e))
1259                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1260                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1261                 }
1262                 else
1263                         return 0;
1264         }
1265         else
1266         {
1267                 e.fire_damagepersec = dps;
1268                 e.fire_endtime = time + t;
1269                 e.fire_deathtype = dt;
1270                 e.fire_owner = o;
1271                 e.fire_hitsound = FALSE;
1272                 if(accuracy_isgooddamage(o, e))
1273                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1274                 return d;
1275         }
1276 }
1277
1278 void Fire_ApplyDamage(entity e)
1279 {
1280         float t, d, hi, ty;
1281         entity o;
1282
1283         if not(Fire_IsBurning(e))
1284                 return;
1285
1286         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1287         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1288                 o = e.fire_owner;
1289
1290         // water and slime stop fire
1291         if(e.waterlevel)
1292         if(e.watertype != CONTENT_LAVA)
1293                 e.fire_endtime = 0;
1294
1295         // ice stops fire
1296         if(e.freezetag_frozen)
1297                 e.fire_endtime = 0;
1298
1299         t = min(frametime, e.fire_endtime - time);
1300         d = e.fire_damagepersec * t;
1301
1302         hi = e.fire_owner.hitsound;
1303         ty = e.fire_owner.typehitsound;
1304         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1305         if(e.fire_hitsound && e.fire_owner)
1306         {
1307                 e.fire_owner.hitsound = hi;
1308                 e.fire_owner.typehitsound = ty;
1309         }
1310         e.fire_hitsound = TRUE;
1311
1312         if not(IS_INDEPENDENT_PLAYER(e))
1313         FOR_EACH_PLAYER(other) if(e != other)
1314         {
1315                 if(other.classname == "player")
1316                 if(other.deadflag == DEAD_NO)
1317                 if not(IS_INDEPENDENT_PLAYER(other))
1318                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1319                 {
1320                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1321                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1322                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1323                 }
1324         }
1325 }
1326
1327 void Fire_ApplyEffect(entity e)
1328 {
1329         if(Fire_IsBurning(e))
1330                 e.effects |= EF_FLAME;
1331         else
1332                 e.effects &~= EF_FLAME;
1333 }
1334
1335 void fireburner_think()
1336 {
1337         // for players, this is done in the regular loop
1338         if(wasfreed(self.owner))
1339         {
1340                 remove(self);
1341                 return;
1342         }
1343         Fire_ApplyEffect(self.owner);
1344         if(!Fire_IsBurning(self.owner))
1345         {
1346                 self.owner.fire_burner = world;
1347                 remove(self);
1348                 return;
1349         }
1350         Fire_ApplyDamage(self.owner);
1351         self.nextthink = time;
1352 }