qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59 float IsFlying(entity a)
  60 {
  61         if(a.flags & FL_ONGROUND)
  62                 return 0;
  63         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  64                 return 0;
  65         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  66         if(trace_fraction < 1)
  67                 return 0;
  68         return 1;
  69 }
  70
  71 void UpdateFrags(entity player, float f)
  72 {
  73         PlayerTeamScore_AddScore(player, f);
  74 }
  75
  76 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  77 void W_SwitchWeapon_Force(entity e, float w);
  78 entity GiveFrags_randomweapons;
  79 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  80 {
  81         // TODO route through PlayerScores instead
  82         if(gameover) return;
  83
  84         if(f < 0)
  85         {
  86                 if(targ == attacker)
  87                 {
  88                         // suicide
  89                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
  90                 }
  91                 else
  92                 {
  93                         // teamkill
  94                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
  95                 }
  96         }
  97         else
  98         {
  99                 // regular frag
 100                 PlayerScore_Add(attacker, SP_KILLS, 1);
 101                 if(targ.playerid)
 102                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 103         }
 104
 105         PlayerScore_Add(targ, SP_DEATHS, 1);
 106
 107         if(targ != attacker) // not for suicides
 108         if(g_weaponarena_random)
 109         {
 110                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 111                 float culprit;
 112                 culprit = DEATH_WEAPONOF(deathtype);
 113                 if(!culprit)
 114                         culprit = attacker.weapon;
 115                 else if(!(attacker.weapons & WepSet_FromWeapon(culprit)))
 116                         culprit = attacker.weapon;
 117
 118                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 119                 {
 120                         // no exchange
 121                 }
 122                 else
 123                 {
 124                         if(!GiveFrags_randomweapons)
 125                         {
 126                                 GiveFrags_randomweapons = spawn();
 127                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 128                         }
 129
 130                         if(warmup_stage)
 131                                 GiveFrags_randomweapons.weapons = warmup_start_weapons;
 132                         else
 133                                 GiveFrags_randomweapons.weapons = start_weapons;
 134
 135                         // all others (including the culprit): remove
 136                         GiveFrags_randomweapons.weapons &= ~attacker.weapons;
 137                         GiveFrags_randomweapons.weapons &= ~WepSet_FromWeapon(culprit);
 138
 139                         // among the remaining ones, choose one by random
 140                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 141
 142                         if(GiveFrags_randomweapons.weapons)
 143                         {
 144                                 attacker.weapons |= GiveFrags_randomweapons.weapons;
 145                                 attacker.weapons &= ~WepSet_FromWeapon(culprit);
 146                         }
 147                 }
 148
 149                 // after a frag, choose another random weapon set
 150                 if not(attacker.weapons & WepSet_FromWeapon(attacker.weapon))
 151                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 152         }
 153
 154         // FIXME fix the mess this is (we have REAL points now!)
 155         entity oldself;
 156         oldself = self;
 157         self = attacker;
 158         frag_attacker = attacker;
 159         frag_target = targ;
 160         frag_score = f;
 161         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 162         {
 163                 f = frag_score;
 164                 self = oldself;
 165         }
 166         else
 167         {
 168                 self = oldself;
 169         }
 170
 171         attacker.totalfrags += f;
 172
 173         if(f)
 174                 UpdateFrags(attacker, f);
 175 }
 176
 177 string AppendItemcodes(string s, entity player)
 178 {
 179         float w;
 180         w = player.weapon;
 181         //if(w == 0)
 182         //      w = player.switchweapon;
 183         if(w == 0)
 184                 w = player.cnt; // previous weapon!
 185         s = strcat(s, ftos(w));
 186         if(time < player.strength_finished)
 187                 s = strcat(s, "S");
 188         if(time < player.invincible_finished)
 189                 s = strcat(s, "I");
 190         if(player.flagcarried != world)
 191                 s = strcat(s, "F");
 192         if(player.BUTTON_CHAT)
 193                 s = strcat(s, "T");
 194         if(player.kh_next)
 195                 s = strcat(s, "K");
 196         return s;
 197 }
 198
 199 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 200 {
 201         string s;
 202         if(!autocvar_sv_eventlog)
 203                 return;
 204         s = strcat(":kill:", mode);
 205         s = strcat(s, ":", ftos(killer.playerid));
 206         s = strcat(s, ":", ftos(killed.playerid));
 207         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 208         s = strcat(s, ":items=");
 209         s = AppendItemcodes(s, killer);
 210         if(killed != killer)
 211         {
 212                 s = strcat(s, ":victimitems=");
 213                 s = AppendItemcodes(s, killed);
 214         }
 215         GameLogEcho(s);
 216 }
 217
 218 void Obituary_SpecialDeath(
 219         entity notif_target,
 220         float murder,
 221         float deathtype,
 222         string s1, string s2, string s3,
 223         float f1, float f2, float f3)
 224 {
 225         if(DEATH_ISSPECIAL(deathtype))
 226         {
 227                 entity deathent = deathtypes[(deathtype - DT_FIRST)];
 228                 if not(deathent) { backtrace("Obituary_SpecialDeath: Could not find deathtype entity!\n"); return; }
 229
 230                 if(murder)
 231                 {
 232                         if(deathent.death_msgmurder)
 233                         {
 234                                 Send_Notification_WOCOVA(
 235                                         NOTIF_ONE,
 236                                         notif_target,
 237                                         MSG_MULTI,
 238                                         deathent.death_msgmurder.nent_id,
 239                                         s1, s2, s3, "",
 240                                         f1, f2, f3, 0
 241                                 );
 242                                 Send_Notification_WOCOVA(
 243                                         NOTIF_ALL_EXCEPT,
 244                                         notif_target,
 245                                         MSG_INFO,
 246                                         deathent.death_msgmurder.nent_msginfo.nent_id,
 247                                         s1, s2, s3, "",
 248                                         f1, f2, f3, 0
 249                                 );
 250                         }
 251                 }
 252                 else
 253                 {
 254                         if(deathent.death_msgself)
 255                         {
 256                                 Send_Notification_WOCOVA(
 257                                         NOTIF_ONE,
 258                                         notif_target,
 259                                         MSG_MULTI,
 260                                         deathent.death_msgself.nent_id,
 261                                         s1, s2, s3, "",
 262                                         f1, f2, f3, 0
 263                                 );
 264                                 Send_Notification_WOCOVA(
 265                                         NOTIF_ALL_EXCEPT,
 266                                         notif_target,
 267                                         MSG_INFO,
 268                                         deathent.death_msgself.nent_msginfo.nent_id,
 269                                         s1, s2, s3, "",
 270                                         f1, f2, f3, 0
 271                                 );
 272                         }
 273                 }
 274         }
 275         else { backtrace("Obituary_SpecialDeath called without a special deathtype?\n"); return; }
 276 }
 277
 278 float w_deathtype;
 279 float Obituary_WeaponDeath(
 280         entity notif_target,
 281         float murder,
 282         float deathtype,
 283         string s1, string s2, string s3,
 284         float f1, float f2)
 285 {
 286         float death_weapon = DEATH_WEAPONOF(deathtype);
 287         if(death_weapon)
 288         {
 289                 w_deathtype = deathtype;
 290                 float death_message = WEP_ACTION(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 291                 w_deathtype = FALSE;
 292
 293                 if(death_message)
 294                 {
 295                         Send_Notification_WOCOVA(
 296                                 NOTIF_ONE,
 297                                 notif_target,
 298                                 MSG_MULTI,
 299                                 death_message,
 300                                 s1, s2, s3, "",
 301                                 f1, f2, 0, 0
 302                         );
 303                         Send_Notification_WOCOVA(
 304                                 NOTIF_ALL_EXCEPT,
 305                                 notif_target,
 306                                 MSG_INFO,
 307                                 msg_multi_notifs[death_message - 1].nent_msginfo.nent_id,
 308                                 s1, s2, s3, "",
 309                                 f1, f2, 0, 0
 310                         );
 311                 }
 312                 else
 313                 {
 314                         dprint(sprintf(
 315                                 "Obituary_WeaponDeath(): ^1Deathtype ^7(%d)^1 has no notification for weapon %d!\n",
 316                                 deathtype,
 317                                 death_weapon
 318                         ));
 319                 }
 320
 321                 return TRUE;
 322         }
 323         return FALSE;
 324 }
 325
 326 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 327 {
 328         // Sanity check
 329         if not(IS_PLAYER(targ)) { backtrace("Obituary called on non-player?!\n"); return; }
 330
 331         // Declarations
 332         float notif_firstblood = FALSE;
 333         float kill_count_to_attacker, kill_count_to_target;
 334
 335         // Set final information for the death
 336         targ.death_origin = targ.origin;
 337         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 338         string deathlocation = (autocvar_notification_server_allows_location ? NearestLocation(targ.death_origin) : "");
 339
 340         #ifdef NOTIFICATIONS_DEBUG
 341         Debug_Notification(
 342                 sprintf(
 343                         "Obituary(%s, %s, %s, %s = %d);\n",
 344                         attacker.netname,
 345                         inflictor.netname,
 346                         targ.netname,
 347                         Deathtype_Name(deathtype),
 348                         deathtype
 349                 )
 350         );
 351         #endif
 352
 353         // =======
 354         // SUICIDE
 355         // =======
 356         if(targ == attacker)
 357         {
 358                 if(DEATH_ISSPECIAL(deathtype))
 359                 {
 360                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 361                         {
 362                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
 363                         }
 364                         else
 365                         {
 366                                 switch(deathtype)
 367                                 {
 368                                         case DEATH_MIRRORDAMAGE:
 369                                         {
 370                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 371                                                 break;
 372                                         }
 373
 374                                         default:
 375                                         {
 376                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 377                                                 break;
 378                                         }
 379                                 }
 380                         }
 381                 }
 382                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
 383                 {
 384                         backtrace("SUICIDE: what the hell happened here?\n");
 385                         return;
 386                 }
 387                 LogDeath("suicide", deathtype, targ, targ);
 388                 GiveFrags(attacker, targ, -1, deathtype);
 389         }
 390
 391         // ======
 392         // MURDER
 393         // ======
 394         else if(IS_PLAYER(attacker))
 395         {
 396                 if(SAME_TEAM(attacker, targ))
 397                 {
 398                         LogDeath("tk", deathtype, attacker, targ);
 399                         GiveFrags(attacker, targ, -1, deathtype);
 400
 401                         attacker.killcount = 0;
 402
 403                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
 404                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
 405                         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, deathlocation, targ.killcount);
 406
 407                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 408                         // No need for specific death/weapon messages...
 409                 }
 410                 else
 411                 {
 412                         LogDeath("frag", deathtype, attacker, targ);
 413                         GiveFrags(attacker, targ, 1, deathtype);
 414
 415                         attacker.taunt_soundtime = time + 1;
 416                         attacker.killcount = attacker.killcount + 1;
 417
 418                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 419                                 case counta: \
 420                                 { \
 421                                         Send_Notification(NOTIF_ONE, attacker, MSG_ANNCE, ANNCE_KILLSTREAK_##countb); \
 422                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
 423                                         break; \
 424                                 }
 425                         switch(attacker.killcount)
 426                         {
 427                                 KILL_SPREE_LIST
 428                                 default: break;
 429                         }
 430                         #undef SPREE_ITEM
 431
 432                         if(!checkrules_firstblood)
 433                         {
 434                                 checkrules_firstblood = TRUE;
 435                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 436                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 437                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 438
 439                                 // tell spree_inf and spree_cen that this is a first-blood and first-victim event
 440                                 kill_count_to_attacker = -1;
 441                                 kill_count_to_target = -2;
 442                         }
 443                         else
 444                         {
 445                                 kill_count_to_attacker = attacker.killcount;
 446                                 kill_count_to_target = 0;
 447                         }
 448
 449                         if(targ.istypefrag)
 450                         {
 451                                 Send_Notification(
 452                                         NOTIF_ONE,
 453                                         attacker,
 454                                         MSG_CHOICE,
 455                                         CHOICE_TYPEFRAG,
 456                                         targ.netname,
 457                                         kill_count_to_attacker,
 458                                         (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping)
 459                                 );
 460                                 Send_Notification(
 461                                         NOTIF_ONE,
 462                                         targ,
 463                                         MSG_CHOICE,
 464                                         CHOICE_TYPEFRAGGED,
 465                                         attacker.netname,
 466                                         kill_count_to_target,
 467                                         attacker.health,
 468                                         attacker.armorvalue,
 469                                         (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping)
 470                                 );
 471                         }
 472                         else
 473                         {
 474                                 Send_Notification(
 475                                         NOTIF_ONE,
 476                                         attacker,
 477                                         MSG_CHOICE,
 478                                         CHOICE_FRAG,
 479                                         targ.netname,
 480                                         kill_count_to_attacker,
 481                                         (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping)
 482                                 );
 483                                 Send_Notification(
 484                                         NOTIF_ONE,
 485                                         targ,
 486                                         MSG_CHOICE,
 487                                         CHOICE_FRAGGED,
 488                                         attacker.netname,
 489                                         kill_count_to_target,
 490                                         attacker.health,
 491                                         attacker.armorvalue,
 492                                         (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping)
 493                                 );
 494                         }
 495
 496                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
 497                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
 498                 }
 499         }
 500
 501         // =============
 502         // ACCIDENT/TRAP
 503         // =============
 504         else
 505         {
 506                 switch(deathtype)
 507                 {
 508                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 509                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 510                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 511                         /*case DEATH_HURTTRIGGER:
 512                         {
 513                                 s1 = targ.netname;
 514                                 s2 = inflictor.message;
 515                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 516                                 break;
 517                         }*/
 518
 519                         case DEATH_CUSTOM:
 520                         {
 521                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
 522                                         targ.netname,
 523                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
 524                                         deathlocation,
 525                                         targ.killcount,
 526                                         0,
 527                                         0);
 528                                 break;
 529                         }
 530
 531                         default:
 532                         {
 533                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 534                                 break;
 535                         }
 536                 }
 537
 538                 LogDeath("accident", deathtype, targ, targ);
 539                 GiveFrags(targ, targ, -1, deathtype);
 540
 541                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 542                 {
 543                         Send_Notification(NOTIF_ONE, targ, MSG_ANNCE, ANNCE_ACHIEVEMENT_BOTLIKE);
 544                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 545                 }
 546         }
 547
 548         // reset target kill count
 549         if(targ.killcount) { targ.killcount = 0; }
 550 }
 551
 552 // these are updated by each Damage call for use in button triggering and such
 553 entity damage_targ;
 554 entity damage_inflictor;
 555 entity damage_attacker;
 556
 557 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 558 {
 559         float mirrordamage;
 560         float mirrorforce;
 561         float complainteamdamage = 0;
 562         entity attacker_save;
 563         mirrordamage = 0;
 564         mirrorforce = 0;
 565
 566         if (gameover || targ.killcount == -666)
 567                 return;
 568
 569         entity oldself;
 570         oldself = self;
 571         self = targ;
 572         damage_targ = targ;
 573         damage_inflictor = inflictor;
 574         damage_attacker = attacker;
 575                 attacker_save = attacker;
 576
 577         if(IS_PLAYER(targ))
 578                 if(targ.hook)
 579                         if(targ.hook.aiment)
 580                                 if(targ.hook.aiment == attacker)
 581                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 582
 583         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 584         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 585         {
 586                 if(IS_PLAYER(targ))
 587                         if(SAME_TEAM(targ, attacker))
 588                         {
 589                                 self = oldself;
 590                                 return;
 591                         }
 592         }
 593
 594         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 595         {
 596                 // These are ALWAYS lethal
 597                 // No damage modification here
 598                 // Instead, prepare the victim for his death...
 599                 targ.armorvalue = 0;
 600                 targ.spawnshieldtime = 0;
 601                 targ.health = 0.9; // this is < 1
 602                 targ.flags -= targ.flags & FL_GODMODE;
 603                 damage = 100000;
 604         }
 605         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 606         {
 607                 // no processing
 608         }
 609         else
 610         {
 611                 // nullify damage if teamplay is on
 612                 if(deathtype != DEATH_TELEFRAG)
 613                 if(IS_PLAYER(attacker))
 614                 {
 615                         if(IS_PLAYER(targ) && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 616                         {
 617                                 damage = 0;
 618                                 force = '0 0 0';
 619                         }
 620                         else if(SAME_TEAM(attacker, targ))
 621                         {
 622                                 if(autocvar_teamplay_mode == 1)
 623                                         damage = 0;
 624                                 else if(attacker != targ)
 625                                 {
 626                                         if(autocvar_teamplay_mode == 3)
 627                                                 damage = 0;
 628                                         else if(autocvar_teamplay_mode == 4)
 629                                         {
 630                                                 if(IS_PLAYER(targ) && targ.deadflag == DEAD_NO)
 631                                                 {
 632                                                         attacker.dmg_team = attacker.dmg_team + damage;
 633                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
 634                                                         if(complainteamdamage > 0)
 635                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
 636                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 637                                                         damage = autocvar_g_friendlyfire * damage;
 638                                                         // mirrordamage will be used LATER
 639
 640                                                         if(autocvar_g_mirrordamage_virtual)
 641                                                         {
 642                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 643                                                                 attacker.dmg_take += v_x;
 644                                                                 attacker.dmg_save += v_y;
 645                                                                 attacker.dmg_inflictor = inflictor;
 646                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 647                                                                 mirrorforce = 0;
 648                                                         }
 649
 650                                                         if(autocvar_g_friendlyfire_virtual)
 651                                                         {
 652                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 653                                                                 targ.dmg_take += v_x;
 654                                                                 targ.dmg_save += v_y;
 655                                                                 targ.dmg_inflictor = inflictor;
 656                                                                 damage = 0;
 657                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 658                                                                         force = '0 0 0';
 659                                                         }
 660                                                 }
 661                                                 else
 662                                                         damage = 0;
 663                                         }
 664                                 }
 665                         }
 666                 }
 667
 668                 if not(DEATH_ISSPECIAL(deathtype))
 669                 {
 670                         damage *= g_weapondamagefactor;
 671                         mirrordamage *= g_weapondamagefactor;
 672                         complainteamdamage *= g_weapondamagefactor;
 673                         force = force * g_weaponforcefactor;
 674                         mirrorforce *= g_weaponforcefactor;
 675                 }
 676
 677                 // should this be changed at all? If so, in what way?
 678                 frag_attacker = attacker;
 679                 frag_target = targ;
 680                 frag_damage = damage;
 681                 frag_force = force;
 682         frag_deathtype = deathtype;
 683                 frag_mirrordamage = mirrordamage;
 684                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 685                 damage = frag_damage;
 686                 mirrordamage = frag_mirrordamage;
 687                 force = frag_force;
 688
 689                 if not(g_minstagib)
 690                 {
 691                         // apply strength multiplier
 692                         if (attacker.items & IT_STRENGTH)
 693                         {
 694                                 if(targ == attacker)
 695                                 {
 696                                         damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 697                                         force = force * autocvar_g_balance_powerup_strength_selfforce;
 698                                 }
 699                                 else
 700                                 {
 701                                         damage = damage * autocvar_g_balance_powerup_strength_damage;
 702                                         force = force * autocvar_g_balance_powerup_strength_force;
 703                                 }
 704                         }
 705
 706                         // apply invincibility multiplier
 707                         if (targ.items & IT_INVINCIBLE)
 708                                 damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 709                 }
 710
 711                 if (targ == attacker)
 712                 {
 713                         if(g_cts && !autocvar_g_cts_selfdamage)
 714                                 damage = 0;
 715                         else
 716                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 717                 }
 718
 719                 // count the damage
 720                 if(attacker)
 721                 if(!targ.deadflag)
 722                 if(targ.takedamage == DAMAGE_AIM)
 723                 if(targ != attacker)
 724                 {
 725                         entity victim;
 726                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 727                                 victim = targ.owner;
 728                         else
 729                                 victim = targ;
 730
 731                         if(IS_PLAYER(victim) || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 732                         {
 733                                 if(DIFF_TEAM(victim, attacker))
 734                                 {
 735                                         if(damage > 0)
 736                                         {
 737                                                 if(deathtype != DEATH_FIRE)
 738                                                 {
 739                                                         if(victim.BUTTON_CHAT)
 740                                                                 attacker.typehitsound += 1;
 741                                                         else
 742                                                                 attacker.hitsound += 1;
 743                                                 }
 744
 745                                                 damage_goodhits += 1;
 746                                                 damage_gooddamage += damage;
 747
 748                                                 if not(DEATH_ISSPECIAL(deathtype))
 749                                                 {
 750                                                         if(IS_PLAYER(targ)) // don't do this for vehicles
 751                                                         if(IsFlying(victim))
 752                                                                 yoda = 1;
 753                                                 }
 754                                         }
 755                                 }
 756                                 else
 757                                 {
 758                                         if(deathtype != DEATH_FIRE)
 759                                         {
 760                                                 attacker.typehitsound += 1;
 761                                         }
 762                                         if(complainteamdamage > 0)
 763                                                 if(time > attacker.teamkill_complain)
 764                                                 {
 765                                                         attacker.teamkill_complain = time + 5;
 766                                                         attacker.teamkill_soundtime = time + 0.4;
 767                                                         attacker.teamkill_soundsource = targ;
 768                                                 }
 769                                 }
 770                         }
 771                 }
 772         }
 773
 774         // apply push
 775         if (self.damageforcescale)
 776         if (vlen(force))
 777         if (!IS_PLAYER(self) || time >= self.spawnshieldtime)
 778         {
 779                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 780                 if(self.movetype == MOVETYPE_PHYSICS)
 781                 {
 782                         entity farcent;
 783                         farcent = spawn();
 784                         farcent.classname = "farce";
 785                         farcent.enemy = self;
 786                         farcent.movedir = farce * 10;
 787                         if(self.mass)
 788                                 farcent.movedir = farcent.movedir * self.mass;
 789                         farcent.origin = hitloc;
 790                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 791                         farcent.nextthink = time + 0.1;
 792                         farcent.think = SUB_Remove;
 793                 }
 794                 else
 795                         self.velocity = self.velocity + farce;
 796                 self.flags &= ~FL_ONGROUND;
 797                 UpdateCSQCProjectile(self);
 798         }
 799         // apply damage
 800         if (damage != 0 || (self.damageforcescale && vlen(force)))
 801         if (self.event_damage)
 802                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 803         self = oldself;
 804
 805         // apply mirror damage if any
 806         if(mirrordamage > 0 || mirrorforce > 0)
 807         {
 808                 attacker = attacker_save;
 809
 810                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 811                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 812         }
 813 }
 814
 815 float RadiusDamage_running;
 816 float RadiusDamageForSource (entity inflictor, vector inflictororigin, vector inflictorvelocity, entity attacker, float coredamage, float edgedamage, float rad, entity cantbe, entity mustbe, float inflictorselfdamage, float forceintensity, float deathtype, entity directhitentity)
 817         // Returns total damage applies to creatures
 818 {
 819         entity  targ;
 820         vector  force;
 821         float   total_damage_to_creatures;
 822         entity  next;
 823         float   tfloordmg;
 824         float   tfloorforce;
 825
 826         float stat_damagedone;
 827
 828         if(RadiusDamage_running)
 829         {
 830                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 831                 return 0;
 832         }
 833
 834         RadiusDamage_running = 1;
 835
 836         tfloordmg = autocvar_g_throughfloor_damage;
 837         tfloorforce = autocvar_g_throughfloor_force;
 838
 839         total_damage_to_creatures = 0;
 840
 841         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 842                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 843                 {
 844                         force = inflictorvelocity;
 845                         if(vlen(force) == 0)
 846                                 force = '0 0 -1';
 847                         else
 848                                 force = normalize(force);
 849                         if(forceintensity >= 0)
 850                                 Damage_DamageInfo(inflictororigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
 851                         else
 852                                 Damage_DamageInfo(inflictororigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
 853                 }
 854
 855         stat_damagedone = 0;
 856
 857         targ = WarpZone_FindRadius (inflictororigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
 858         while (targ)
 859         {
 860                 next = targ.chain;
 861                 if ((targ != inflictor) || inflictorselfdamage)
 862                 if (((cantbe != targ) && !mustbe) || (mustbe == targ))
 863                 if (targ.takedamage)
 864                 {
 865                         vector nearest;
 866                         vector diff;
 867                         float power;
 868
 869                         // LordHavoc: measure distance to nearest point on target (not origin)
 870                         // (this guarentees 100% damage on a touch impact)
 871                         nearest = targ.WarpZone_findradius_nearest;
 872                         diff = targ.WarpZone_findradius_dist;
 873                         // round up a little on the damage to ensure full damage on impacts
 874                         // and turn the distance into a fraction of the radius
 875                         power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
 876                         //bprint(" ");
 877                         //bprint(ftos(power));
 878                         //if (targ == attacker)
 879                         //      print(ftos(power), "\n");
 880                         if (power > 0)
 881                         {
 882                                 float finaldmg;
 883                                 if (power > 1)
 884                                         power = 1;
 885                                 finaldmg = coredamage * power + edgedamage * (1 - power);
 886                                 if (finaldmg > 0)
 887                                 {
 888                                         float a;
 889                                         float c;
 890                                         vector hitloc;
 891                                         vector myblastorigin;
 892                                         vector center;
 893
 894                                         myblastorigin = WarpZone_TransformOrigin(targ, inflictororigin);
 895
 896                                         // if it's a player, use the view origin as reference
 897                                         center = CENTER_OR_VIEWOFS(targ);
 898
 899                                         force = normalize(center - myblastorigin);
 900                                         force = force * (finaldmg / coredamage) * forceintensity;
 901                                         hitloc = nearest;
 902
 903                                         if(targ != directhitentity)
 904                                         {
 905                                                 float hits;
 906                                                 float total;
 907                                                 float hitratio;
 908                                                 float mininv_f, mininv_d;
 909
 910                                                 // test line of sight to multiple positions on box,
 911                                                 // and do damage if any of them hit
 912                                                 hits = 0;
 913
 914                                                 // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
 915                                                 // so for a given max stddev:
 916                                                 // n = (1 / (2 * max stddev of hitratio))^2
 917
 918                                                 mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
 919                                                 mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
 920
 921                                                 if(autocvar_g_throughfloor_debug)
 922                                                         print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
 923
 924                                                 total = 0.25 * pow(max(mininv_f, mininv_d), 2);
 925
 926                                                 if(autocvar_g_throughfloor_debug)
 927                                                         print(sprintf(" steps=%f", total));
 928
 929                                                 if (IS_PLAYER(targ))
 930                                                         total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
 931                                                 else
 932                                                         total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
 933
 934                                                 if(autocvar_g_throughfloor_debug)
 935                                                         print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
 936
 937                                                 for(c = 0; c < total; ++c)
 938                                                 {
 939                                                         //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
 940                                                         WarpZone_TraceLine(inflictororigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
 941                                                         if (trace_fraction == 1 || trace_ent == targ)
 942                                                         {
 943                                                                 ++hits;
 944                                                                 if (hits > 1)
 945                                                                         hitloc = hitloc + nearest;
 946                                                                 else
 947                                                                         hitloc = nearest;
 948                                                         }
 949                                                         nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
 950                                                         nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
 951                                                         nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
 952                                                 }
 953
 954                                                 nearest = hitloc * (1 / max(1, hits));
 955                                                 hitratio = (hits / total);
 956                                                 a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
 957                                                 finaldmg = finaldmg * a;
 958                                                 a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
 959                                                 force = force * a;
 960
 961                                                 if(autocvar_g_throughfloor_debug)
 962                                                         print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
 963                                         }
 964
 965                                         //if (targ == attacker)
 966                                         //{
 967                                         //      print("hits ", ftos(hits), " / ", ftos(total));
 968                                         //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
 969                                         //      print(" (", ftos(a), ")\n");
 970                                         //}
 971                                         if(finaldmg || vlen(force))
 972                                         {
 973                                                 if(targ.iscreature)
 974                                                 {
 975                                                         total_damage_to_creatures += finaldmg;
 976
 977                                                         if(accuracy_isgooddamage(attacker, targ))
 978                                                                 stat_damagedone += finaldmg;
 979                                                 }
 980
 981                                                 if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
 982                                                         Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
 983                                                 else
 984                                                         Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
 985                                         }
 986                                 }
 987                         }
 988                 }
 989                 targ = next;
 990         }
 991
 992         RadiusDamage_running = 0;
 993
 994         if(!DEATH_ISSPECIAL(deathtype))
 995                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
 996
 997         return total_damage_to_creatures;
 998 }
 999
1000 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity cantbe, entity mustbe, float forceintensity, float deathtype, entity directhitentity)
1001 {
1002         return RadiusDamageForSource (inflictor, (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5), inflictor.velocity, attacker, coredamage, edgedamage, rad, cantbe, mustbe, FALSE, forceintensity, deathtype, directhitentity);
1003 }
1004
1005 .float fire_damagepersec;
1006 .float fire_endtime;
1007 .float fire_deathtype;
1008 .entity fire_owner;
1009 .float fire_hitsound;
1010 .entity fire_burner;
1011
1012 void fireburner_think();
1013
1014 float Fire_IsBurning(entity e)
1015 {
1016         return (time < e.fire_endtime);
1017 }
1018
1019 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1020 {
1021         float dps;
1022         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1023
1024         if(IS_PLAYER(e))
1025         {
1026                 if(e.deadflag)
1027                         return -1;
1028         }
1029         else
1030         {
1031                 if(!e.fire_burner)
1032                 {
1033                         // print("adding a fire burner to ", e.classname, "\n");
1034                         e.fire_burner = spawn();
1035                         e.fire_burner.classname = "fireburner";
1036                         e.fire_burner.think = fireburner_think;
1037                         e.fire_burner.nextthink = time;
1038                         e.fire_burner.owner = e;
1039                 }
1040         }
1041
1042         t = max(t, 0.1);
1043         dps = d / t;
1044         if(Fire_IsBurning(e))
1045         {
1046                 mintime = e.fire_endtime - time;
1047                 maxtime = max(mintime, t);
1048
1049                 mindps = e.fire_damagepersec;
1050                 maxdps = max(mindps, dps);
1051
1052                 if(maxtime > mintime || maxdps > mindps)
1053                 {
1054                         // Constraints:
1055
1056                         // damage we have right now
1057                         mindamage = mindps * mintime;
1058
1059                         // damage we want to get
1060                         maxdamage = mindamage + d;
1061
1062                         // but we can't exceed maxtime * maxdps!
1063                         totaldamage = min(maxdamage, maxtime * maxdps);
1064
1065                         // LEMMA:
1066                         // Look at:
1067                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1068                         // We see:
1069                         // totaldamage <= maxtime * maxdps
1070                         // ==> totaldamage / maxdps <= maxtime.
1071                         // We also see:
1072                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1073                         //                     >= min(mintime, maxtime)
1074                         // ==> totaldamage / maxdps >= mintime.
1075
1076                         /*
1077                         // how long do we damage then?
1078                         // at least as long as before
1079                         // but, never exceed maxdps
1080                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1081                         */
1082
1083                         // alternate:
1084                         // at most as long as maximum allowed
1085                         // but, never below mindps
1086                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1087
1088                         // assuming t > mintime, dps > mindps:
1089                         // we get d = t * dps = maxtime * maxdps
1090                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1091                         // totaldamage / maxdps = maxtime
1092                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1093                         // FROM THIS:
1094                         // a) totaltime = max(mintime, maxtime) = maxtime
1095                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1096
1097                         // assuming t <= mintime:
1098                         // we get maxtime = mintime
1099                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1100                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1101
1102                         // assuming dps <= mindps:
1103                         // we get mindps = maxdps.
1104                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1105                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1106                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1107
1108                         e.fire_damagepersec = totaldamage / totaltime;
1109                         e.fire_endtime = time + totaltime;
1110                         if(totaldamage > 1.2 * mindamage)
1111                         {
1112                                 e.fire_deathtype = dt;
1113                                 if(e.fire_owner != o)
1114                                 {
1115                                         e.fire_owner = o;
1116                                         e.fire_hitsound = FALSE;
1117                                 }
1118                         }
1119                         if(accuracy_isgooddamage(o, e))
1120                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1121                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1122                 }
1123                 else
1124                         return 0;
1125         }
1126         else
1127         {
1128                 e.fire_damagepersec = dps;
1129                 e.fire_endtime = time + t;
1130                 e.fire_deathtype = dt;
1131                 e.fire_owner = o;
1132                 e.fire_hitsound = FALSE;
1133                 if(accuracy_isgooddamage(o, e))
1134                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1135                 return d;
1136         }
1137 }
1138
1139 void Fire_ApplyDamage(entity e)
1140 {
1141         float t, d, hi, ty;
1142         entity o;
1143
1144         if not(Fire_IsBurning(e))
1145                 return;
1146
1147         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1148         if(IS_NOT_A_CLIENT(o))
1149                 o = e.fire_owner;
1150
1151         // water and slime stop fire
1152         if(e.waterlevel)
1153         if(e.watertype != CONTENT_LAVA)
1154                 e.fire_endtime = 0;
1155
1156         // ice stops fire
1157         if(e.freezetag_frozen)
1158                 e.fire_endtime = 0;
1159
1160         t = min(frametime, e.fire_endtime - time);
1161         d = e.fire_damagepersec * t;
1162
1163         hi = e.fire_owner.hitsound;
1164         ty = e.fire_owner.typehitsound;
1165         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1166         if(e.fire_hitsound && e.fire_owner)
1167         {
1168                 e.fire_owner.hitsound = hi;
1169                 e.fire_owner.typehitsound = ty;
1170         }
1171         e.fire_hitsound = TRUE;
1172
1173         if not(IS_INDEPENDENT_PLAYER(e))
1174         FOR_EACH_PLAYER(other) if(e != other)
1175         {
1176                 if(IS_PLAYER(other))
1177                 if(other.deadflag == DEAD_NO)
1178                 if not(IS_INDEPENDENT_PLAYER(other))
1179                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1180                 {
1181                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1182                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1183                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1184                 }
1185         }
1186 }
1187
1188 void Fire_ApplyEffect(entity e)
1189 {
1190         if(Fire_IsBurning(e))
1191                 e.effects |= EF_FLAME;
1192         else
1193                 e.effects &= ~EF_FLAME;
1194 }
1195
1196 void fireburner_think()
1197 {
1198         // for players, this is done in the regular loop
1199         if(wasfreed(self.owner))
1200         {
1201                 remove(self);
1202                 return;
1203         }
1204         Fire_ApplyEffect(self.owner);
1205         if(!Fire_IsBurning(self.owner))
1206         {
1207                 self.owner.fire_burner = world;
1208                 remove(self);
1209                 return;
1210         }
1211         Fire_ApplyDamage(self.owner);
1212         self.nextthink = time;
1213 }