qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59 float IsFlying(entity a)
  60 {
  61         if(a.flags & FL_ONGROUND)
  62                 return 0;
  63         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  64                 return 0;
  65         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  66         if(trace_fraction < 1)
  67                 return 0;
  68         return 1;
  69 }
  70
  71 void UpdateFrags(entity player, float f)
  72 {
  73         PlayerTeamScore_AddScore(player, f);
  74 }
  75
  76 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  77 void W_SwitchWeapon_Force(entity e, float w);
  78 entity GiveFrags_randomweapons;
  79 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  80 {
  81         // TODO route through PlayerScores instead
  82         if(gameover) return;
  83
  84         if(f < 0)
  85         {
  86                 if(targ == attacker)
  87                 {
  88                         // suicide
  89                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
  90                 }
  91                 else
  92                 {
  93                         // teamkill
  94                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
  95                 }
  96         }
  97         else
  98         {
  99                 // regular frag
 100                 PlayerScore_Add(attacker, SP_KILLS, 1);
 101                 if(targ.playerid)
 102                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 103         }
 104
 105         PlayerScore_Add(targ, SP_DEATHS, 1);
 106
 107         if(targ != attacker) // not for suicides
 108         if(g_weaponarena_random)
 109         {
 110                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 111                 float culprit;
 112                 culprit = DEATH_WEAPONOF(deathtype);
 113                 if(!culprit)
 114                         culprit = attacker.weapon;
 115                 else if(!(attacker.weapons & WepSet_FromWeapon(culprit)))
 116                         culprit = attacker.weapon;
 117
 118                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 119                 {
 120                         // no exchange
 121                 }
 122                 else
 123                 {
 124                         if(!GiveFrags_randomweapons)
 125                         {
 126                                 GiveFrags_randomweapons = spawn();
 127                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 128                         }
 129
 130                         if(warmup_stage)
 131                                 GiveFrags_randomweapons.weapons = WARMUP_START_WEAPONS;
 132                         else
 133                                 GiveFrags_randomweapons.weapons = start_weapons;
 134
 135                         // all others (including the culprit): remove
 136                         GiveFrags_randomweapons.weapons &= ~attacker.weapons;
 137                         GiveFrags_randomweapons.weapons &= ~WepSet_FromWeapon(culprit);
 138
 139                         // among the remaining ones, choose one by random
 140                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 141
 142                         if(GiveFrags_randomweapons.weapons)
 143                         {
 144                                 attacker.weapons |= GiveFrags_randomweapons.weapons;
 145                                 attacker.weapons &= ~WepSet_FromWeapon(culprit);
 146                         }
 147                 }
 148
 149                 // after a frag, choose another random weapon set
 150                 if (!(attacker.weapons & WepSet_FromWeapon(attacker.weapon)))
 151                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 152         }
 153
 154         // FIXME fix the mess this is (we have REAL points now!)
 155         entity oldself;
 156         oldself = self;
 157         self = attacker;
 158         frag_attacker = attacker;
 159         frag_target = targ;
 160         frag_score = f;
 161         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 162         {
 163                 f = frag_score;
 164                 self = oldself;
 165         }
 166         else
 167         {
 168                 self = oldself;
 169         }
 170
 171         attacker.totalfrags += f;
 172
 173         if(f)
 174                 UpdateFrags(attacker, f);
 175 }
 176
 177 string AppendItemcodes(string s, entity player)
 178 {
 179         float w;
 180         w = player.weapon;
 181         //if(w == 0)
 182         //      w = player.switchweapon;
 183         if(w == 0)
 184                 w = player.cnt; // previous weapon!
 185         s = strcat(s, ftos(w));
 186         if(time < player.strength_finished)
 187                 s = strcat(s, "S");
 188         if(time < player.invincible_finished)
 189                 s = strcat(s, "I");
 190         if(player.flagcarried != world)
 191                 s = strcat(s, "F");
 192         if(player.BUTTON_CHAT)
 193                 s = strcat(s, "T");
 194         if(player.kh_next)
 195                 s = strcat(s, "K");
 196         return s;
 197 }
 198
 199 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 200 {
 201         string s;
 202         if(!autocvar_sv_eventlog)
 203                 return;
 204         s = strcat(":kill:", mode);
 205         s = strcat(s, ":", ftos(killer.playerid));
 206         s = strcat(s, ":", ftos(killed.playerid));
 207         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 208         s = strcat(s, ":items=");
 209         s = AppendItemcodes(s, killer);
 210         if(killed != killer)
 211         {
 212                 s = strcat(s, ":victimitems=");
 213                 s = AppendItemcodes(s, killed);
 214         }
 215         GameLogEcho(s);
 216 }
 217
 218 void Obituary_SpecialDeath(
 219         entity notif_target,
 220         float murder,
 221         float deathtype,
 222         string s1, string s2, string s3,
 223         float f1, float f2, float f3)
 224 {
 225         if(DEATH_ISSPECIAL(deathtype))
 226         {
 227                 entity deathent = deathtypes[(deathtype - DT_FIRST)];
 228                 if (!deathent) { backtrace("Obituary_SpecialDeath: Could not find deathtype entity!\n"); return; }
 229
 230                 if(murder)
 231                 {
 232                         if(deathent.death_msgmurder)
 233                         {
 234                                 Send_Notification_WOCOVA(
 235                                         NOTIF_ONE,
 236                                         notif_target,
 237                                         MSG_MULTI,
 238                                         deathent.death_msgmurder.nent_id,
 239                                         s1, s2, s3, "",
 240                                         f1, f2, f3, 0
 241                                 );
 242                                 Send_Notification_WOCOVA(
 243                                         NOTIF_ALL_EXCEPT,
 244                                         notif_target,
 245                                         MSG_INFO,
 246                                         deathent.death_msgmurder.nent_msginfo.nent_id,
 247                                         s1, s2, s3, "",
 248                                         f1, f2, f3, 0
 249                                 );
 250                         }
 251                 }
 252                 else
 253                 {
 254                         if(deathent.death_msgself)
 255                         {
 256                                 Send_Notification_WOCOVA(
 257                                         NOTIF_ONE,
 258                                         notif_target,
 259                                         MSG_MULTI,
 260                                         deathent.death_msgself.nent_id,
 261                                         s1, s2, s3, "",
 262                                         f1, f2, f3, 0
 263                                 );
 264                                 Send_Notification_WOCOVA(
 265                                         NOTIF_ALL_EXCEPT,
 266                                         notif_target,
 267                                         MSG_INFO,
 268                                         deathent.death_msgself.nent_msginfo.nent_id,
 269                                         s1, s2, s3, "",
 270                                         f1, f2, f3, 0
 271                                 );
 272                         }
 273                 }
 274         }
 275         else { backtrace("Obituary_SpecialDeath called without a special deathtype?\n"); return; }
 276 }
 277
 278 float w_deathtype;
 279 float Obituary_WeaponDeath(
 280         entity notif_target,
 281         float murder,
 282         float deathtype,
 283         string s1, string s2, string s3,
 284         float f1, float f2)
 285 {
 286         float death_weapon = DEATH_WEAPONOF(deathtype);
 287         if(death_weapon)
 288         {
 289                 w_deathtype = deathtype;
 290                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 291                 w_deathtype = FALSE;
 292
 293                 if(death_message)
 294                 {
 295                         Send_Notification_WOCOVA(
 296                                 NOTIF_ONE,
 297                                 notif_target,
 298                                 MSG_MULTI,
 299                                 death_message,
 300                                 s1, s2, s3, "",
 301                                 f1, f2, 0, 0
 302                         );
 303                         Send_Notification_WOCOVA(
 304                                 NOTIF_ALL_EXCEPT,
 305                                 notif_target,
 306                                 MSG_INFO,
 307                                 msg_multi_notifs[death_message - 1].nent_msginfo.nent_id,
 308                                 s1, s2, s3, "",
 309                                 f1, f2, 0, 0
 310                         );
 311                 }
 312                 else
 313                 {
 314                         dprintf(
 315                                 "Obituary_WeaponDeath(): ^1Deathtype ^7(%d)^1 has no notification for weapon %d!\n",
 316                                 deathtype,
 317                                 death_weapon
 318                         );
 319                 }
 320
 321                 return TRUE;
 322         }
 323         return FALSE;
 324 }
 325
 326 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 327 {
 328         // Sanity check
 329         if (!IS_PLAYER(targ)) { backtrace("Obituary called on non-player?!\n"); return; }
 330
 331         // Declarations
 332         float notif_firstblood = FALSE;
 333         float kill_count_to_attacker, kill_count_to_target;
 334
 335         // Set final information for the death
 336         targ.death_origin = targ.origin;
 337         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 338         string deathlocation = (autocvar_notification_server_allows_location ? NearestLocation(targ.death_origin) : "");
 339
 340         #ifdef NOTIFICATIONS_DEBUG
 341         Debug_Notification(
 342                 sprintf(
 343                         "Obituary(%s, %s, %s, %s = %d);\n",
 344                         attacker.netname,
 345                         inflictor.netname,
 346                         targ.netname,
 347                         Deathtype_Name(deathtype),
 348                         deathtype
 349                 )
 350         );
 351         #endif
 352
 353         // =======
 354         // SUICIDE
 355         // =======
 356         if(targ == attacker)
 357         {
 358                 if(DEATH_ISSPECIAL(deathtype))
 359                 {
 360                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 361                         {
 362                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
 363                         }
 364                         else
 365                         {
 366                                 switch(deathtype)
 367                                 {
 368                                         case DEATH_MIRRORDAMAGE:
 369                                         {
 370                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 371                                                 break;
 372                                         }
 373
 374                                         default:
 375                                         {
 376                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 377                                                 break;
 378                                         }
 379                                 }
 380                         }
 381                 }
 382                 else if (!Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
 383                 {
 384                         backtrace("SUICIDE: what the hell happened here?\n");
 385                         return;
 386                 }
 387                 LogDeath("suicide", deathtype, targ, targ);
 388                 GiveFrags(attacker, targ, -1, deathtype);
 389         }
 390
 391         // ======
 392         // MURDER
 393         // ======
 394         else if(IS_PLAYER(attacker))
 395         {
 396                 if(SAME_TEAM(attacker, targ))
 397                 {
 398                         LogDeath("tk", deathtype, attacker, targ);
 399                         GiveFrags(attacker, targ, -1, deathtype);
 400
 401                         attacker.killcount = 0;
 402
 403                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
 404                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
 405                         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, deathlocation, targ.killcount);
 406
 407                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 408                         // No need for specific death/weapon messages...
 409                 }
 410                 else
 411                 {
 412                         LogDeath("frag", deathtype, attacker, targ);
 413                         GiveFrags(attacker, targ, 1, deathtype);
 414
 415                         attacker.taunt_soundtime = time + 1;
 416                         attacker.killcount = attacker.killcount + 1;
 417
 418                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 419                                 case counta: \
 420                                 { \
 421                                         Send_Notification(NOTIF_ONE, attacker, MSG_ANNCE, ANNCE_KILLSTREAK_##countb); \
 422                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
 423                                         break; \
 424                                 }
 425                         switch(attacker.killcount)
 426                         {
 427                                 KILL_SPREE_LIST
 428                                 default: break;
 429                         }
 430                         #undef SPREE_ITEM
 431
 432                         if(!checkrules_firstblood)
 433                         {
 434                                 checkrules_firstblood = TRUE;
 435                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 436                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 437                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 438
 439                                 // tell spree_inf and spree_cen that this is a first-blood and first-victim event
 440                                 kill_count_to_attacker = -1;
 441                                 kill_count_to_target = -2;
 442                         }
 443                         else
 444                         {
 445                                 kill_count_to_attacker = attacker.killcount;
 446                                 kill_count_to_target = 0;
 447                         }
 448
 449                         if(targ.istypefrag)
 450                         {
 451                                 Send_Notification(
 452                                         NOTIF_ONE,
 453                                         attacker,
 454                                         MSG_CHOICE,
 455                                         CHOICE_TYPEFRAG,
 456                                         targ.netname,
 457                                         kill_count_to_attacker,
 458                                         (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping)
 459                                 );
 460                                 Send_Notification(
 461                                         NOTIF_ONE,
 462                                         targ,
 463                                         MSG_CHOICE,
 464                                         CHOICE_TYPEFRAGGED,
 465                                         attacker.netname,
 466                                         kill_count_to_target,
 467                                         attacker.health,
 468                                         attacker.armorvalue,
 469                                         (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping)
 470                                 );
 471                         }
 472                         else
 473                         {
 474                                 Send_Notification(
 475                                         NOTIF_ONE,
 476                                         attacker,
 477                                         MSG_CHOICE,
 478                                         CHOICE_FRAG,
 479                                         targ.netname,
 480                                         kill_count_to_attacker,
 481                                         (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping)
 482                                 );
 483                                 Send_Notification(
 484                                         NOTIF_ONE,
 485                                         targ,
 486                                         MSG_CHOICE,
 487                                         CHOICE_FRAGGED,
 488                                         attacker.netname,
 489                                         kill_count_to_target,
 490                                         attacker.health,
 491                                         attacker.armorvalue,
 492                                         (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping)
 493                                 );
 494                         }
 495
 496                         if (!Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
 497                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
 498                 }
 499         }
 500
 501         // =============
 502         // ACCIDENT/TRAP
 503         // =============
 504         else
 505         {
 506                 switch(deathtype)
 507                 {
 508                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 509                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 510                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 511                         /*case DEATH_HURTTRIGGER:
 512                         {
 513                                 s1 = targ.netname;
 514                                 s2 = inflictor.message;
 515                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 516                                 break;
 517                         }*/
 518
 519                         case DEATH_CUSTOM:
 520                         {
 521                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
 522                                         targ.netname,
 523                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
 524                                         deathlocation,
 525                                         targ.killcount,
 526                                         0,
 527                                         0);
 528                                 break;
 529                         }
 530
 531                         default:
 532                         {
 533                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 534                                 break;
 535                         }
 536                 }
 537
 538                 LogDeath("accident", deathtype, targ, targ);
 539                 GiveFrags(targ, targ, -1, deathtype);
 540
 541                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 542                 {
 543                         Send_Notification(NOTIF_ONE, targ, MSG_ANNCE, ANNCE_ACHIEVEMENT_BOTLIKE);
 544                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 545                 }
 546         }
 547
 548         // reset target kill count
 549         if(targ.killcount) { targ.killcount = 0; }
 550 }
 551
 552 // these are updated by each Damage call for use in button triggering and such
 553 entity damage_targ;
 554 entity damage_inflictor;
 555 entity damage_attacker;
 556
 557 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 558 {
 559         float mirrordamage;
 560         float mirrorforce;
 561         float complainteamdamage = 0;
 562         entity attacker_save;
 563         mirrordamage = 0;
 564         mirrorforce = 0;
 565
 566         if (gameover || targ.killcount == -666)
 567                 return;
 568
 569         entity oldself;
 570         oldself = self;
 571         self = targ;
 572         damage_targ = targ;
 573         damage_inflictor = inflictor;
 574         damage_attacker = attacker;
 575                 attacker_save = attacker;
 576
 577         if(IS_PLAYER(targ))
 578                 if(targ.hook)
 579                         if(targ.hook.aiment)
 580                                 if(targ.hook.aiment == attacker)
 581                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 582
 583         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 584         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 585         {
 586                 if(IS_PLAYER(targ))
 587                         if(SAME_TEAM(targ, attacker))
 588                         {
 589                                 self = oldself;
 590                                 return;
 591                         }
 592         }
 593
 594         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 595         {
 596                 // exit the vehicle before killing (fixes a crash)
 597                 if(IS_PLAYER(targ) && targ.vehicle)
 598                         vehicles_exit(VHEF_RELEASE);
 599
 600                 // These are ALWAYS lethal
 601                 // No damage modification here
 602                 // Instead, prepare the victim for his death...
 603                 targ.armorvalue = 0;
 604                 targ.spawnshieldtime = 0;
 605                 targ.health = 0.9; // this is < 1
 606                 targ.flags -= targ.flags & FL_GODMODE;
 607                 damage = 100000;
 608         }
 609         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 610         {
 611                 // no processing
 612         }
 613         else
 614         {
 615                 // nullify damage if teamplay is on
 616                 if(deathtype != DEATH_TELEFRAG)
 617                 if(IS_PLAYER(attacker))
 618                 {
 619                         if(IS_PLAYER(targ) && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 620                         {
 621                                 damage = 0;
 622                                 force = '0 0 0';
 623                         }
 624                         else if(SAME_TEAM(attacker, targ))
 625                         {
 626                                 if(autocvar_teamplay_mode == 1)
 627                                         damage = 0;
 628                                 else if(attacker != targ)
 629                                 {
 630                                         if(autocvar_teamplay_mode == 3)
 631                                                 damage = 0;
 632                                         else if(autocvar_teamplay_mode == 4)
 633                                         {
 634                                                 if(IS_PLAYER(targ) && targ.deadflag == DEAD_NO)
 635                                                 {
 636                                                         attacker.dmg_team = attacker.dmg_team + damage;
 637                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
 638                                                         if(complainteamdamage > 0)
 639                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
 640                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 641                                                         damage = autocvar_g_friendlyfire * damage;
 642                                                         // mirrordamage will be used LATER
 643
 644                                                         if(autocvar_g_mirrordamage_virtual)
 645                                                         {
 646                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, mirrordamage);
 647                                                                 attacker.dmg_take += v_x;
 648                                                                 attacker.dmg_save += v_y;
 649                                                                 attacker.dmg_inflictor = inflictor;
 650                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 651                                                                 mirrorforce = 0;
 652                                                         }
 653
 654                                                         if(autocvar_g_friendlyfire_virtual)
 655                                                         {
 656                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 657                                                                 targ.dmg_take += v_x;
 658                                                                 targ.dmg_save += v_y;
 659                                                                 targ.dmg_inflictor = inflictor;
 660                                                                 damage = 0;
 661                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 662                                                                         force = '0 0 0';
 663                                                         }
 664                                                 }
 665                                                 else
 666                                                         damage = 0;
 667                                         }
 668                                 }
 669                         }
 670                 }
 671
 672                 if (!DEATH_ISSPECIAL(deathtype))
 673                 {
 674                         damage *= g_weapondamagefactor;
 675                         mirrordamage *= g_weapondamagefactor;
 676                         complainteamdamage *= g_weapondamagefactor;
 677                         force = force * g_weaponforcefactor;
 678                         mirrorforce *= g_weaponforcefactor;
 679                 }
 680
 681                 // should this be changed at all? If so, in what way?
 682                 frag_attacker = attacker;
 683                 frag_target = targ;
 684                 frag_damage = damage;
 685                 frag_force = force;
 686                 frag_deathtype = deathtype;
 687                 frag_mirrordamage = mirrordamage;
 688                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 689                 damage = frag_damage;
 690                 mirrordamage = frag_mirrordamage;
 691                 force = frag_force;
 692
 693                 if (!g_minstagib)
 694                 {
 695                         // apply strength multiplier
 696                         if (attacker.items & IT_STRENGTH)
 697                         {
 698                                 if(targ == attacker)
 699                                 {
 700                                         damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 701                                         force = force * autocvar_g_balance_powerup_strength_selfforce;
 702                                 }
 703                                 else
 704                                 {
 705                                         damage = damage * autocvar_g_balance_powerup_strength_damage;
 706                                         force = force * autocvar_g_balance_powerup_strength_force;
 707                                 }
 708                         }
 709
 710                         // apply invincibility multiplier
 711                         if (targ.items & IT_INVINCIBLE)
 712                                 damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 713                 }
 714
 715                 if (targ == attacker)
 716                 {
 717                         if(g_cts && !autocvar_g_cts_selfdamage)
 718                                 damage = 0;
 719                         else
 720                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 721                 }
 722
 723                 // count the damage
 724                 if(attacker)
 725                 if(!targ.deadflag)
 726                 if(targ.takedamage == DAMAGE_AIM)
 727                 if(targ != attacker)
 728                 {
 729                         entity victim;
 730                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 731                                 victim = targ.owner;
 732                         else
 733                                 victim = targ;
 734
 735                         if(IS_PLAYER(victim) || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET || victim.flags & FL_MONSTER)
 736                         {
 737                                 if(DIFF_TEAM(victim, attacker))
 738                                 {
 739                                         if(damage > 0)
 740                                         {
 741                                                 if(deathtype != DEATH_FIRE)
 742                                                 {
 743                                                         if(victim.BUTTON_CHAT)
 744                                                                 attacker.typehitsound += 1;
 745                                                         else
 746                                                                 attacker.hitsound += 1;
 747                                                 }
 748
 749                                                 damage_goodhits += 1;
 750                                                 damage_gooddamage += damage;
 751
 752                                                 if (!DEATH_ISSPECIAL(deathtype))
 753                                                 {
 754                                                         if(IS_PLAYER(targ)) // don't do this for vehicles
 755                                                         if(IsFlying(victim))
 756                                                                 yoda = 1;
 757                                                 }
 758                                         }
 759                                 }
 760                                 else
 761                                 {
 762                                         if(deathtype != DEATH_FIRE)
 763                                         {
 764                                                 attacker.typehitsound += 1;
 765                                         }
 766                                         if(complainteamdamage > 0)
 767                                                 if(time > attacker.teamkill_complain)
 768                                                 {
 769                                                         attacker.teamkill_complain = time + 5;
 770                                                         attacker.teamkill_soundtime = time + 0.4;
 771                                                         attacker.teamkill_soundsource = targ;
 772                                                 }
 773                                 }
 774                         }
 775                 }
 776         }
 777
 778         // apply push
 779         if (self.damageforcescale)
 780         if (vlen(force))
 781         if (!IS_PLAYER(self) || time >= self.spawnshieldtime)
 782         {
 783                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 784                 if(self.movetype == MOVETYPE_PHYSICS)
 785                 {
 786                         entity farcent;
 787                         farcent = spawn();
 788                         farcent.classname = "farce";
 789                         farcent.enemy = self;
 790                         farcent.movedir = farce * 10;
 791                         if(self.mass)
 792                                 farcent.movedir = farcent.movedir * self.mass;
 793                         farcent.origin = hitloc;
 794                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 795                         farcent.nextthink = time + 0.1;
 796                         farcent.think = SUB_Remove;
 797                 }
 798                 else
 799                         self.velocity = self.velocity + farce;
 800                 self.flags &= ~FL_ONGROUND;
 801                 UpdateCSQCProjectile(self);
 802         }
 803         // apply damage
 804         if (damage != 0 || (self.damageforcescale && vlen(force)))
 805         if (self.event_damage)
 806                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 807         self = oldself;
 808
 809         // apply mirror damage if any
 810         if(mirrordamage > 0 || mirrorforce > 0)
 811         {
 812                 attacker = attacker_save;
 813
 814                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 815                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 816         }
 817 }
 818
 819 float RadiusDamage_running;
 820 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 821         // Returns total damage applies to creatures
 822 {
 823         entity  targ;
 824         vector  blastorigin;
 825         vector  force;
 826         float   total_damage_to_creatures;
 827         entity  next;
 828         float   tfloordmg;
 829         float   tfloorforce;
 830
 831         float stat_damagedone;
 832
 833         if(RadiusDamage_running)
 834         {
 835                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 836                 return 0;
 837         }
 838
 839         RadiusDamage_running = 1;
 840
 841         tfloordmg = autocvar_g_throughfloor_damage;
 842         tfloorforce = autocvar_g_throughfloor_force;
 843
 844         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 845         total_damage_to_creatures = 0;
 846
 847         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 848                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 849                 {
 850                         force = inflictor.velocity;
 851                         if(vlen(force) == 0)
 852                                 force = '0 0 -1';
 853                         else
 854                                 force = normalize(force);
 855                         if(forceintensity >= 0)
 856                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
 857                         else
 858                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
 859                 }
 860
 861         stat_damagedone = 0;
 862
 863         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
 864         while (targ)
 865         {
 866                 next = targ.chain;
 867                 if (targ != inflictor)
 868                         if (ignore != targ) if(targ.takedamage)
 869                         {
 870                                 vector nearest;
 871                                 vector diff;
 872                                 float power;
 873
 874                                 // LordHavoc: measure distance to nearest point on target (not origin)
 875                                 // (this guarentees 100% damage on a touch impact)
 876                                 nearest = targ.WarpZone_findradius_nearest;
 877                                 diff = targ.WarpZone_findradius_dist;
 878                                 // round up a little on the damage to ensure full damage on impacts
 879                                 // and turn the distance into a fraction of the radius
 880                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
 881                                 //bprint(" ");
 882                                 //bprint(ftos(power));
 883                                 //if (targ == attacker)
 884                                 //      print(ftos(power), "\n");
 885                                 if (power > 0)
 886                                 {
 887                                         float finaldmg;
 888                                         if (power > 1)
 889                                                 power = 1;
 890                                         finaldmg = coredamage * power + edgedamage * (1 - power);
 891                                         if (finaldmg > 0)
 892                                         {
 893                                                 float a;
 894                                                 float c;
 895                                                 vector hitloc;
 896                                                 vector myblastorigin;
 897                                                 vector center;
 898
 899                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
 900
 901                                                 // if it's a player, use the view origin as reference
 902                                                 center = CENTER_OR_VIEWOFS(targ);
 903
 904                                                 force = normalize(center - myblastorigin);
 905                                                 force = force * (finaldmg / coredamage) * forceintensity;
 906                                                 hitloc = nearest;
 907
 908                                                 if(targ != directhitentity)
 909                                                 {
 910                                                         float hits;
 911                                                         float total;
 912                                                         float hitratio;
 913                                                         float mininv_f, mininv_d;
 914
 915                                                         // test line of sight to multiple positions on box,
 916                                                         // and do damage if any of them hit
 917                                                         hits = 0;
 918
 919                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
 920                                                         // so for a given max stddev:
 921                                                         // n = (1 / (2 * max stddev of hitratio))^2
 922
 923                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
 924                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
 925
 926                                                         if(autocvar_g_throughfloor_debug)
 927                                                                 printf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f);
 928
 929                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
 930
 931                                                         if(autocvar_g_throughfloor_debug)
 932                                                                 printf(" steps=%f", total);
 933
 934                                                         if (IS_PLAYER(targ))
 935                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
 936                                                         else
 937                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
 938
 939                                                         if(autocvar_g_throughfloor_debug)
 940                                                                 printf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total)));
 941
 942                                                         for(c = 0; c < total; ++c)
 943                                                         {
 944                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
 945                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
 946                                                                 if (trace_fraction == 1 || trace_ent == targ)
 947                                                                 {
 948                                                                         ++hits;
 949                                                                         if (hits > 1)
 950                                                                                 hitloc = hitloc + nearest;
 951                                                                         else
 952                                                                                 hitloc = nearest;
 953                                                                 }
 954                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
 955                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
 956                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
 957                                                         }
 958
 959                                                         nearest = hitloc * (1 / max(1, hits));
 960                                                         hitratio = (hits / total);
 961                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
 962                                                         finaldmg = finaldmg * a;
 963                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
 964                                                         force = force * a;
 965
 966                                                         if(autocvar_g_throughfloor_debug)
 967                                                                 printf(" D=%f F=%f\n", finaldmg, vlen(force));
 968                                                 }
 969
 970                                                 // laser force adjustments :P
 971                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
 972                                                 {
 973                                                         if (targ == attacker)
 974                                                         {
 975                                                                 vector vel;
 976
 977                                                                 float force_zscale;
 978                                                                 float force_velocitybiasramp;
 979                                                                 float force_velocitybias;
 980
 981                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
 982                                                                 if(deathtype & HITTYPE_SECONDARY)
 983                                                                 {
 984                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
 985                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
 986                                                                 }
 987                                                                 else
 988                                                                 {
 989                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
 990                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
 991                                                                 }
 992
 993                                                                 vel = targ.velocity;
 994                                                                 vel_z = 0;
 995                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
 996                                                                 force =
 997                                                                         vlen(force)
 998                                                                         *
 999                                                                         normalize(normalize(force) + vel);
1000
1001                                                                 force_z *= force_zscale;
1002                                                         }
1003                                                         else
1004                                                         {
1005                                                                 if(deathtype & HITTYPE_SECONDARY)
1006                                                                 {
1007                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1008                                                                 }
1009                                                                 else
1010                                                                 {
1011                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1012                                                                 }
1013                                                         }
1014                                                 }
1015
1016                                                 //if (targ == attacker)
1017                                                 //{
1018                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1019                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1020                                                 //      print(" (", ftos(a), ")\n");
1021                                                 //}
1022                                                 if(finaldmg || vlen(force))
1023                                                 {
1024                                                         if(targ.iscreature)
1025                                                         {
1026                                                                 total_damage_to_creatures += finaldmg;
1027
1028                                                                 if(accuracy_isgooddamage(attacker, targ))
1029                                                                         stat_damagedone += finaldmg;
1030                                                         }
1031
1032                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1033                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1034                                                         else
1035                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1036                                                 }
1037                                         }
1038                                 }
1039                         }
1040                 targ = next;
1041         }
1042
1043         RadiusDamage_running = 0;
1044
1045         if(!DEATH_ISSPECIAL(deathtype))
1046                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1047
1048         return total_damage_to_creatures;
1049 }
1050
1051 .float fire_damagepersec;
1052 .float fire_endtime;
1053 .float fire_deathtype;
1054 .entity fire_owner;
1055 .float fire_hitsound;
1056 .entity fire_burner;
1057
1058 void fireburner_think();
1059
1060 float Fire_IsBurning(entity e)
1061 {
1062         return (time < e.fire_endtime);
1063 }
1064
1065 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1066 {
1067         float dps;
1068         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1069
1070         if(IS_PLAYER(e))
1071         {
1072                 if(e.deadflag)
1073                         return -1;
1074         }
1075         else
1076         {
1077                 if(!e.fire_burner)
1078                 {
1079                         // print("adding a fire burner to ", e.classname, "\n");
1080                         e.fire_burner = spawn();
1081                         e.fire_burner.classname = "fireburner";
1082                         e.fire_burner.think = fireburner_think;
1083                         e.fire_burner.nextthink = time;
1084                         e.fire_burner.owner = e;
1085                 }
1086         }
1087
1088         t = max(t, 0.1);
1089         dps = d / t;
1090         if(Fire_IsBurning(e))
1091         {
1092                 mintime = e.fire_endtime - time;
1093                 maxtime = max(mintime, t);
1094
1095                 mindps = e.fire_damagepersec;
1096                 maxdps = max(mindps, dps);
1097
1098                 if(maxtime > mintime || maxdps > mindps)
1099                 {
1100                         // Constraints:
1101
1102                         // damage we have right now
1103                         mindamage = mindps * mintime;
1104
1105                         // damage we want to get
1106                         maxdamage = mindamage + d;
1107
1108                         // but we can't exceed maxtime * maxdps!
1109                         totaldamage = min(maxdamage, maxtime * maxdps);
1110
1111                         // LEMMA:
1112                         // Look at:
1113                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1114                         // We see:
1115                         // totaldamage <= maxtime * maxdps
1116                         // ==> totaldamage / maxdps <= maxtime.
1117                         // We also see:
1118                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1119                         //                     >= min(mintime, maxtime)
1120                         // ==> totaldamage / maxdps >= mintime.
1121
1122                         /*
1123                         // how long do we damage then?
1124                         // at least as long as before
1125                         // but, never exceed maxdps
1126                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1127                         */
1128
1129                         // alternate:
1130                         // at most as long as maximum allowed
1131                         // but, never below mindps
1132                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1133
1134                         // assuming t > mintime, dps > mindps:
1135                         // we get d = t * dps = maxtime * maxdps
1136                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1137                         // totaldamage / maxdps = maxtime
1138                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1139                         // FROM THIS:
1140                         // a) totaltime = max(mintime, maxtime) = maxtime
1141                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1142
1143                         // assuming t <= mintime:
1144                         // we get maxtime = mintime
1145                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1146                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1147
1148                         // assuming dps <= mindps:
1149                         // we get mindps = maxdps.
1150                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1151                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1152                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1153
1154                         e.fire_damagepersec = totaldamage / totaltime;
1155                         e.fire_endtime = time + totaltime;
1156                         if(totaldamage > 1.2 * mindamage)
1157                         {
1158                                 e.fire_deathtype = dt;
1159                                 if(e.fire_owner != o)
1160                                 {
1161                                         e.fire_owner = o;
1162                                         e.fire_hitsound = FALSE;
1163                                 }
1164                         }
1165                         if(accuracy_isgooddamage(o, e))
1166                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1167                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1168                 }
1169                 else
1170                         return 0;
1171         }
1172         else
1173         {
1174                 e.fire_damagepersec = dps;
1175                 e.fire_endtime = time + t;
1176                 e.fire_deathtype = dt;
1177                 e.fire_owner = o;
1178                 e.fire_hitsound = FALSE;
1179                 if(accuracy_isgooddamage(o, e))
1180                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1181                 return d;
1182         }
1183 }
1184
1185 void Fire_ApplyDamage(entity e)
1186 {
1187         float t, d, hi, ty;
1188         entity o;
1189
1190         if (!Fire_IsBurning(e))
1191                 return;
1192
1193         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1194         if(IS_NOT_A_CLIENT(o))
1195                 o = e.fire_owner;
1196
1197         // water and slime stop fire
1198         if(e.waterlevel)
1199         if(e.watertype != CONTENT_LAVA)
1200                 e.fire_endtime = 0;
1201
1202         // ice stops fire
1203         if(e.freezetag_frozen)
1204                 e.fire_endtime = 0;
1205
1206         t = min(frametime, e.fire_endtime - time);
1207         d = e.fire_damagepersec * t;
1208
1209         hi = e.fire_owner.hitsound;
1210         ty = e.fire_owner.typehitsound;
1211         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1212         if(e.fire_hitsound && e.fire_owner)
1213         {
1214                 e.fire_owner.hitsound = hi;
1215                 e.fire_owner.typehitsound = ty;
1216         }
1217         e.fire_hitsound = TRUE;
1218
1219         if (!IS_INDEPENDENT_PLAYER(e))
1220         FOR_EACH_PLAYER(other) if(e != other)
1221         {
1222                 if(IS_PLAYER(other))
1223                 if(other.deadflag == DEAD_NO)
1224                 if (!IS_INDEPENDENT_PLAYER(other))
1225                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1226                 {
1227                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1228                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1229                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1230                 }
1231         }
1232 }
1233
1234 void Fire_ApplyEffect(entity e)
1235 {
1236         if(Fire_IsBurning(e))
1237                 e.effects |= EF_FLAME;
1238         else
1239                 e.effects &= ~EF_FLAME;
1240 }
1241
1242 void fireburner_think()
1243 {
1244         // for players, this is done in the regular loop
1245         if(wasfreed(self.owner))
1246         {
1247                 remove(self);
1248                 return;
1249         }
1250         Fire_ApplyEffect(self.owner);
1251         if(!Fire_IsBurning(self.owner))
1252         {
1253                 self.owner.fire_burner = world;
1254                 remove(self);
1255                 return;
1256         }
1257         Fire_ApplyDamage(self.owner);
1258         self.nextthink = time;
1259 }