qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50 float headshot;
  51 float damage_headshotbonus; // bonus multiplier for head shots, set to 0 after use
  52
  53 .float dmg_team;
  54 .float teamkill_complain;
  55 .float teamkill_soundtime;
  56 .entity teamkill_soundsource;
  57 .entity pusher;
  58 .float istypefrag;
  59 .float taunt_soundtime;
  60
  61
  62 float IsDifferentTeam(entity a, entity b)
  63 {
  64         if(teamplay)
  65         {
  66                 if(a.team == b.team)
  67                         return 0;
  68         }
  69         else
  70         {
  71                 if(a == b)
  72                         return 0;
  73         }
  74         return 1;
  75 }
  76
  77 float IsFlying(entity a)
  78 {
  79         if(a.flags & FL_ONGROUND)
  80                 return 0;
  81         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  82                 return 0;
  83         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  84         if(trace_fraction < 1)
  85                 return 0;
  86         return 1;
  87 }
  88
  89 vector GetHeadshotMins(entity targ)
  90 {
  91         return '-0.5 0 0' * PL_HEAD_x + '0 -0.5 0' * PL_HEAD_y + '0 0 1' * (targ.maxs_z - PL_HEAD_z);
  92 }
  93 vector GetHeadshotMaxs(entity targ)
  94 {
  95         return '0.5 0 0' * PL_HEAD_x + '0 0.5 0' * PL_HEAD_y + '0 0 1' * targ.maxs_z;
  96 }
  97
  98 void UpdateFrags(entity player, float f)
  99 {
 100         PlayerTeamScore_AddScore(player, f);
 101 }
 102
 103 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
 104 void W_SwitchWeapon_Force(entity e, float w);
 105 entity GiveFrags_randomweapons;
 106 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
 107 {
 108         // TODO route through PlayerScores instead
 109         if(gameover) return;
 110
 111         if(f < 0)
 112         {
 113                 if(targ == attacker)
 114                 {
 115                         // suicide
 116                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 117                 }
 118                 else
 119                 {
 120                         // teamkill
 121                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 122                 }
 123         }
 124         else
 125         {
 126                 // regular frag
 127                 PlayerScore_Add(attacker, SP_KILLS, 1);
 128                 if(targ.playerid)
 129                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 130         }
 131
 132         PlayerScore_Add(targ, SP_DEATHS, 1);
 133
 134         if(g_arena || g_ca)
 135                 if(autocvar_g_arena_roundbased)
 136                         return;
 137
 138         if(targ != attacker) // not for suicides
 139         if(g_weaponarena_random)
 140         {
 141                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 142                 float culprit;
 143                 culprit = DEATH_WEAPONOF(deathtype);
 144                 if(!culprit)
 145                         culprit = attacker.weapon;
 146                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 147                         culprit = attacker.weapon;
 148
 149                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 150                 {
 151                         // no exchange
 152                 }
 153                 else
 154                 {
 155                         if(!GiveFrags_randomweapons)
 156                         {
 157                                 GiveFrags_randomweapons = spawn();
 158                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 159                         }
 160
 161                         if(inWarmupStage)
 162                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 163                         else
 164                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 165
 166                         // all others (including the culprit): remove
 167                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 168                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 169
 170                         // among the remaining ones, choose one by random
 171                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 172
 173                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 174                         {
 175                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 176                                 WEPSET_ANDNOT_EW(attacker, culprit);
 177                         }
 178                 }
 179
 180                 // after a frag, choose another random weapon set
 181                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 182                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 183         }
 184
 185         // FIXME fix the mess this is (we have REAL points now!)
 186         entity oldself;
 187         oldself = self;
 188         self = attacker;
 189         frag_attacker = attacker;
 190         frag_target = targ;
 191         frag_score = f;
 192         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 193         {
 194                 f = frag_score;
 195                 self = oldself;
 196         }
 197         else
 198         {
 199                 self = oldself;
 200                 if(g_runematch)
 201                 {
 202                         f = RunematchHandleFrags(attacker, targ, f);
 203                 }
 204                 else if(g_lms)
 205                 {
 206                         // remove a life
 207                         float tl;
 208                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 209                         if(tl < lms_lowest_lives)
 210                                 lms_lowest_lives = tl;
 211                         if(tl <= 0)
 212                         {
 213                                 if(!lms_next_place)
 214                                         lms_next_place = player_count;
 215                                 else
 216                                         lms_next_place = min(lms_next_place, player_count);
 217                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 218                                 --lms_next_place;
 219                         }
 220                         f = 0;
 221                 }
 222         }
 223
 224         attacker.totalfrags += f;
 225
 226         if(f)
 227                 UpdateFrags(attacker, f);
 228 }
 229
 230 string Obituary_ExtraFragInfo(entity player) // Extra fragmessage information
 231 {
 232         string health_output = string_null;
 233         string ping_output = string_null;
 234         string handicap_output = string_null;
 235         string output = string_null;
 236
 237         if(autocvar_sv_fraginfo && ((autocvar_sv_fraginfo == 2) || inWarmupStage))
 238         {
 239                 // health/armor of attacker (person who killed you)
 240                 if(autocvar_sv_fraginfo_stats && (player.health >= 1))
 241                         health_output = strcat("^7(Health ^1", ftos(rint(player.health)), "^7 / Armor ^2", ftos(rint(player.armorvalue)), "^7)");
 242
 243                 // ping display
 244                 if(autocvar_sv_fraginfo_ping)
 245                         ping_output = ((clienttype(player) == CLIENTTYPE_BOT) ? "^2Bot" : strcat("Ping ", ((player.ping >= 150) ? "^1" : "^2"), ftos(rint(player.ping)), "ms"));
 246
 247                 // handicap display
 248                 if(autocvar_sv_fraginfo_handicap)
 249                 {
 250                         if(autocvar_sv_fraginfo_handicap == 2)
 251                                 handicap_output = strcat(output, strcat("Handicap ^2", ((player.cvar_cl_handicap <= 1) ? "Off" : ftos(rint(player.cvar_cl_handicap)))));
 252                         else if(player.cvar_cl_handicap) // with _handicap 1, only show this if there actually is a handicap enabled.
 253                                 handicap_output = strcat("Handicap ^2", ftos(rint(player.cvar_cl_handicap)));
 254                 }
 255
 256                 // format the string
 257                 output = strcat(health_output, (health_output ? ((ping_output || handicap_output) ? " ^7(" : "") : ((ping_output || handicap_output) ? "^7(" : "")),
 258                         ping_output, (handicap_output ? "^7 / " : ""),
 259                         handicap_output, ((ping_output || handicap_output) ? "^7)" : ""));
 260
 261                 // add new line to the beginning if there is a message
 262                 if(output) { output = strcat("\n", output); }
 263         }
 264
 265         return output;
 266 }
 267
 268 string AppendItemcodes(string s, entity player)
 269 {
 270         float w;
 271         w = player.weapon;
 272         //if(w == 0)
 273         //      w = player.switchweapon;
 274         if(w == 0)
 275                 w = player.cnt; // previous weapon!
 276         s = strcat(s, ftos(w));
 277         if(time < player.strength_finished)
 278                 s = strcat(s, "S");
 279         if(time < player.invincible_finished)
 280                 s = strcat(s, "I");
 281         if(player.flagcarried != world)
 282                 s = strcat(s, "F");
 283         if(player.BUTTON_CHAT)
 284                 s = strcat(s, "T");
 285         if(player.kh_next)
 286                 s = strcat(s, "K");
 287         if(player.runes)
 288                 s = strcat(s, "|", ftos(player.runes));
 289         return s;
 290 }
 291
 292 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 293 {
 294         string s;
 295         if(!autocvar_sv_eventlog)
 296                 return;
 297         s = strcat(":kill:", mode);
 298         s = strcat(s, ":", ftos(killer.playerid));
 299         s = strcat(s, ":", ftos(killed.playerid));
 300         s = strcat(s, ":type=", ftos(deathtype));
 301         s = strcat(s, ":items=");
 302         s = AppendItemcodes(s, killer);
 303         if(killed != killer)
 304         {
 305                 s = strcat(s, ":victimitems=");
 306                 s = AppendItemcodes(s, killed);
 307         }
 308         GameLogEcho(s);
 309 }
 310
 311 void Send_KillNotification (string s1, string s2, string s3, float msg, float type)
 312 {
 313         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
 314         WriteByte(MSG_BROADCAST, TE_CSQC_KILLNOTIFY);
 315         WriteString(MSG_BROADCAST, s1);
 316         WriteString(MSG_BROADCAST, s2);
 317         WriteString(MSG_BROADCAST, s3);
 318         WriteShort(MSG_BROADCAST, msg);
 319         WriteByte(MSG_BROADCAST, type);
 320 }
 321
 322 // Function is used to send a generic centerprint whose content CSQC gets to decide (gentle version or not in the below cases)
 323 void Send_CSQC_KillCenterprint(entity e, string s1, string s2, float msg, float type)
 324 {
 325         if (clienttype(e) == CLIENTTYPE_REAL)
 326         {
 327                 msg_entity = e;
 328                 WRITESPECTATABLE_MSG_ONE({
 329                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 330                         WriteByte(MSG_ONE, TE_CSQC_KILLCENTERPRINT);
 331                         WriteString(MSG_ONE, s1);
 332                         WriteString(MSG_ONE, s2);
 333                         WriteShort(MSG_ONE, msg);
 334                         WriteByte(MSG_ONE, type);
 335                 });
 336         }
 337 }
 338
 339 void Obituary (entity attacker, entity inflictor, entity targ, float deathtype)
 340 {
 341         string  s, a, msg;
 342         float type;
 343
 344         if (targ.classname == "player")
 345         {
 346                 s = targ.netname;
 347                 a = attacker.netname;
 348
 349                 if (targ == attacker) // suicides
 350                 {
 351                         if (deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 352                                 msg = ColoredTeamName(targ.team); // TODO: check if needed?
 353                         else
 354                                 msg = "";
 355             if(!g_cts) // no "killed your own dumb self" message in CTS
 356                 Send_CSQC_KillCenterprint(targ, msg, "", deathtype, MSG_SUICIDE);
 357
 358                         if(deathtype != DEATH_TEAMCHANGE && deathtype != DEATH_QUIET)
 359                         {
 360                                 LogDeath("suicide", deathtype, targ, targ);
 361                                 GiveFrags(attacker, targ, -1, deathtype);
 362                         }
 363
 364                         if (targ.killcount > 2)
 365                                 msg = ftos(targ.killcount);
 366                         else
 367                                 msg = "";
 368                         if(teamplay && deathtype == DEATH_MIRRORDAMAGE)
 369                         {
 370                                 if(attacker.team == COLOR_TEAM1)
 371                                         deathtype = KILL_TEAM_RED;
 372                                 else
 373                                         deathtype = KILL_TEAM_BLUE;
 374                         }
 375
 376                         Send_KillNotification(s, msg, "", deathtype, MSG_SUICIDE);
 377                 }
 378                 else if (attacker.classname == "player")
 379                 {
 380                         if(!IsDifferentTeam(attacker, targ))
 381                         {
 382                                 if(attacker.team == COLOR_TEAM1)
 383                                         type = KILL_TEAM_RED;
 384                                 else
 385                                         type = KILL_TEAM_BLUE;
 386
 387                                 GiveFrags(attacker, targ, -1, deathtype);
 388
 389                                 Send_CSQC_KillCenterprint(attacker, s, "", type, MSG_KILL);
 390
 391                                 if (targ.killcount > 2)
 392                                         msg = ftos(targ.killcount);
 393                                 else
 394                                         msg = "";
 395
 396                                 if (attacker.killcount > 2) {
 397                                         msg = ftos(attacker.killcount);
 398                                         type = KILL_TEAM_SPREE;
 399                                 }
 400                                 Send_KillNotification(a, s, msg, type, MSG_KILL);
 401
 402                                 attacker.killcount = 0;
 403
 404                                 LogDeath("tk", deathtype, attacker, targ);
 405                         }
 406                         else
 407                         {
 408                                 if (!checkrules_firstblood)
 409                                 {
 410                                         checkrules_firstblood = TRUE;
 411                                         Send_KillNotification(a, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 412                                         // TODO: make these print a newline if they dont
 413                                         Send_CSQC_KillCenterprint(attacker, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 414                                         Send_CSQC_KillCenterprint(targ, "", "", KILL_FIRST_VICTIM, MSG_KILL);
 415                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 416                                         PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 417                                 }
 418
 419                                 if(targ.istypefrag) {
 420                                         Send_CSQC_KillCenterprint(attacker, s, Obituary_ExtraFragInfo(targ), KILL_TYPEFRAG, MSG_KILL);
 421                                         Send_CSQC_KillCenterprint(targ, a, Obituary_ExtraFragInfo(attacker), KILL_TYPEFRAGGED, MSG_KILL);
 422                                 } else {
 423                                         Send_CSQC_KillCenterprint(attacker, s, Obituary_ExtraFragInfo(targ), KILL_FRAG, MSG_KILL);
 424                                         Send_CSQC_KillCenterprint(targ, a, Obituary_ExtraFragInfo(attacker), KILL_FRAGGED, MSG_KILL);
 425                                 }
 426
 427                                 attacker.taunt_soundtime = time + 1;
 428
 429                                 if (deathtype == DEATH_HURTTRIGGER && inflictor.message2 != "")
 430                                         msg = inflictor.message2;
 431                                 else if (deathtype == DEATH_CUSTOM)
 432                                         msg = deathmessage;
 433                                 else
 434                                         msg = "";
 435
 436                                 if(strstrofs(msg, "%", 0) < 0)
 437                                         msg = strcat("%s ", msg, " by %s");
 438
 439                                 Send_KillNotification(a, s, msg, deathtype, MSG_KILL);
 440
 441                                 GiveFrags(attacker, targ, 1, deathtype);
 442
 443                                 if (targ.killcount > 2) {
 444                                         Send_KillNotification(s, ftos(targ.killcount), a, KILL_END_SPREE, MSG_SPREE);
 445                                 }
 446
 447                                 attacker.killcount = attacker.killcount + 1;
 448
 449                                 if (attacker.killcount == 3)
 450                                 {
 451                                         Send_KillNotification(a, "", "", KILL_SPREE_3, MSG_SPREE);
 452                                         AnnounceTo(attacker, "03kills");
 453                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_3, 1);
 454                                 }
 455                                 else if (attacker.killcount == 5)
 456                                 {
 457                                         Send_KillNotification(a, "", "", KILL_SPREE_5, MSG_SPREE);
 458                                         AnnounceTo(attacker, "05kills");
 459                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_5, 1);
 460                                 }
 461                                 else if (attacker.killcount == 10)
 462                                 {
 463                                         Send_KillNotification(a, "", "", KILL_SPREE_10, MSG_SPREE);
 464                                         AnnounceTo(attacker, "10kills");
 465                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_10, 1);
 466                                 }
 467                                 else if (attacker.killcount == 15)
 468                                 {
 469                                         Send_KillNotification(a, "", "", KILL_SPREE_15, MSG_SPREE);
 470                                         AnnounceTo(attacker, "15kills");
 471                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_15, 1);
 472                                 }
 473                                 else if (attacker.killcount == 20)
 474                                 {
 475                                         Send_KillNotification(a, "", "", KILL_SPREE_20, MSG_SPREE);
 476                                         AnnounceTo(attacker, "20kills");
 477                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_20, 1);
 478                                 }
 479                                 else if (attacker.killcount == 25)
 480                                 {
 481                                         Send_KillNotification(a, "", "", KILL_SPREE_25, MSG_SPREE);
 482                                         AnnounceTo(attacker, "25kills");
 483                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_25, 1);
 484                                 }
 485                                 else if (attacker.killcount == 30)
 486                                 {
 487                                         Send_KillNotification(a, "", "", KILL_SPREE_30, MSG_SPREE);
 488                                         AnnounceTo(attacker, "30kills");
 489                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_30, 1);
 490                                 }
 491                                 else if (attacker.killcount > 2) {
 492                                         Send_KillNotification(a, ftos(attacker.killcount), "", KILL_SPREE, MSG_SPREE);
 493                                 }
 494                                 LogDeath("frag", deathtype, attacker, targ);
 495                         }
 496                 }
 497                 else
 498                 {
 499                         Send_CSQC_KillCenterprint(targ, "", "", deathtype, MSG_KILL_ACTION);
 500                         if (deathtype == DEATH_HURTTRIGGER && inflictor.message != "")
 501                                 msg = inflictor.message;
 502                         else if (deathtype == DEATH_CUSTOM)
 503                                 msg = deathmessage;
 504                         else
 505                                 msg = "";
 506                         if(strstrofs(msg, "%", 0) < 0)
 507                                 msg = strcat("%s ", msg);
 508
 509                         GiveFrags(targ, targ, -1, deathtype);
 510                         if(PlayerScore_Add(targ, SP_SCORE, 0) == -5) {
 511                                 AnnounceTo(targ, "botlike");
 512                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 513                         }
 514                         Send_KillNotification(s, msg, "", deathtype, MSG_KILL_ACTION);
 515
 516                         if (targ.killcount > 2)
 517                                 Send_KillNotification(s, ftos(targ.killcount), "", 0, MSG_KILL_ACTION_SPREE);
 518
 519                         LogDeath("accident", deathtype, targ, targ);
 520                 }
 521
 522                 targ.death_origin = targ.origin;
 523                 if(targ != attacker)
 524                         targ.killer_origin = attacker.origin;
 525
 526                 // FIXME: this should go in PutClientInServer
 527                 if (targ.killcount)
 528                         targ.killcount = 0;
 529         }
 530 }
 531
 532 // these are updated by each Damage call for use in button triggering and such
 533 entity damage_targ;
 534 entity damage_inflictor;
 535 entity damage_attacker;
 536
 537 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 538 {
 539         float mirrordamage;
 540         float mirrorforce;
 541         float teamdamage0;
 542         entity attacker_save;
 543         mirrordamage = 0;
 544         mirrorforce = 0;
 545
 546         if (gameover || targ.killcount == -666)
 547                 return;
 548
 549         entity oldself;
 550         oldself = self;
 551         self = targ;
 552         damage_targ = targ;
 553         damage_inflictor = inflictor;
 554         damage_attacker = attacker;
 555                 attacker_save = attacker;
 556
 557         if(targ.classname == "player")
 558                 if(targ.hook)
 559                         if(targ.hook.aiment)
 560                                 if(targ.hook.aiment == attacker)
 561                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 562
 563         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 564         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 565         {
 566                 if(targ.classname == "player")
 567                         if not(IsDifferentTeam(targ, attacker))
 568                         {
 569                                 self = oldself;
 570                                 return;
 571                         }
 572         }
 573
 574         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE || deathtype == DEATH_QUIET)
 575         {
 576                 // These are ALWAYS lethal
 577                 // No damage modification here
 578                 // Instead, prepare the victim for his death...
 579                 targ.armorvalue = 0;
 580                 targ.spawnshieldtime = 0;
 581                 targ.health = 0.9; // this is < 1
 582                 targ.flags -= targ.flags & FL_GODMODE;
 583                 damage = 100000;
 584         }
 585         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 586         {
 587                 // no processing
 588         }
 589         else
 590         {
 591                 /*
 592                 skill based bot damage? gtfo. (tZork)
 593                 if (targ.classname == "player")
 594                 if (attacker.classname == "player")
 595                 if (!targ.isbot)
 596                 if (attacker.isbot)
 597                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 598         */
 599
 600                 // nullify damage if teamplay is on
 601                 if(deathtype != DEATH_TELEFRAG)
 602                 if(attacker.classname == "player")
 603                 {
 604                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 605                         {
 606                                 damage = 0;
 607                                 force = '0 0 0';
 608                         }
 609                         else if(!IsDifferentTeam(attacker, targ))
 610                         {
 611                                 if(autocvar_teamplay_mode == 1)
 612                                         damage = 0;
 613                                 else if(attacker != targ)
 614                                 {
 615                                         if(autocvar_teamplay_mode == 3)
 616                                                 damage = 0;
 617                                         else if(autocvar_teamplay_mode == 4)
 618                                         {
 619                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 620                                                 {
 621                                                         teamdamage0 = max(attacker.dmg_team, autocvar_g_teamdamage_threshold);
 622                                                         attacker.dmg_team = attacker.dmg_team + damage;
 623                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 624                                                                 mirrordamage = autocvar_g_mirrordamage * (attacker.dmg_team - teamdamage0);
 625                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 626                                                         if(g_ca)
 627                                                                 damage = 0;
 628                                                         else
 629                                                                 damage = autocvar_g_friendlyfire * damage;
 630                                                         // mirrordamage will be used LATER
 631
 632                                                         if(autocvar_g_mirrordamage_virtual)
 633                                                         {
 634                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 635                                                                 attacker.dmg_take += v_x;
 636                                                                 attacker.dmg_save += v_y;
 637                                                                 attacker.dmg_inflictor = inflictor;
 638                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 639                                                                 mirrorforce = 0;
 640                                                         }
 641
 642                                                         if(autocvar_g_friendlyfire_virtual)
 643                                                         {
 644                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 645                                                                 targ.dmg_take += v_x;
 646                                                                 targ.dmg_save += v_y;
 647                                                                 targ.dmg_inflictor = inflictor;
 648                                                                 damage = 0;
 649                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 650                                                                         force = '0 0 0';
 651                                                         }
 652                                                 }
 653                                                 else
 654                                                         damage = 0;
 655                                         }
 656                                 }
 657                         }
 658                 }
 659
 660                 if(targ.classname == "player")
 661                 if(attacker.classname == "player")
 662                 if(attacker != targ)
 663                 {
 664                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 665                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 666                 }
 667
 668                 if not(DEATH_ISSPECIAL(deathtype))
 669                 {
 670                         damage *= g_weapondamagefactor;
 671                         mirrordamage *= g_weapondamagefactor;
 672                         force = force * g_weaponforcefactor;
 673                         mirrorforce *= g_weaponforcefactor;
 674                 }
 675
 676                 // should this be changed at all? If so, in what way?
 677                 frag_attacker = attacker;
 678                 frag_target = targ;
 679                 frag_damage = damage;
 680                 frag_force = force;
 681         frag_deathtype = deathtype;
 682                 frag_mirrordamage = mirrordamage;
 683                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 684                 damage = frag_damage;
 685                 mirrordamage = frag_mirrordamage;
 686                 force = frag_force;
 687
 688                 // apply strength multiplier
 689                 if (attacker.items & IT_STRENGTH)
 690                 {
 691                         if(targ == attacker)
 692                         {
 693                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 694                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 695                         }
 696                         else
 697                         {
 698                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 699                                 force = force * autocvar_g_balance_powerup_strength_force;
 700                         }
 701                 }
 702
 703                 // apply invincibility multiplier
 704                 if (targ.items & IT_INVINCIBLE)
 705                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 706
 707                 if (targ == attacker)
 708                 {
 709                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 710                                 damage = 0;
 711                         else
 712                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 713                 }
 714
 715                 if(g_runematch)
 716                 {
 717                         // apply strength rune
 718                         if (attacker.runes & RUNE_STRENGTH)
 719                         {
 720                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 721                                 {
 722                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 723                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 724                                 }
 725                                 else
 726                                 {
 727                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 728                                         force = force * autocvar_g_balance_rune_strength_force;
 729                                 }
 730                         }
 731                         else if (attacker.runes & CURSE_WEAK)
 732                         {
 733                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 734                                 force = force * autocvar_g_balance_curse_weak_force;
 735                         }
 736
 737                         // apply defense rune
 738                         if (targ.runes & RUNE_DEFENSE)
 739                         {
 740                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 741                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 742                                 else
 743                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 744                         }
 745                         else if (targ.runes & CURSE_VULNER)
 746                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 747                 }
 748
 749                 // count the damage
 750                 if(attacker)
 751                 if(!targ.deadflag)
 752                 if(targ.takedamage == DAMAGE_AIM)
 753                 if(targ != attacker)
 754                 {
 755                         if(damage_headshotbonus)
 756                         {
 757                                 if(targ.classname == "player")
 758                                 {
 759                                         // HEAD SHOT:
 760                                         // find height of hit on player axis
 761                                         // if above view_ofs and below maxs, and also in the middle half of the bbox, it is head shot
 762                                         vector headmins, headmaxs, org;
 763                                         org = antilag_takebackorigin(targ, time - ANTILAG_LATENCY(attacker));
 764                                         headmins = org + GetHeadshotMins(targ);
 765                                         headmaxs = org + GetHeadshotMaxs(targ);
 766                                         if(trace_hits_box(railgun_start, railgun_end, headmins, headmaxs))
 767                                         {
 768                                                 deathtype |= HITTYPE_HEADSHOT;
 769                                         }
 770                                 }
 771                                 else if(targ.classname == "turret_head")
 772                                 {
 773                                         deathtype |= HITTYPE_HEADSHOT;
 774                                 }
 775                                 if(deathtype & HITTYPE_HEADSHOT)
 776                                         if(damage_headshotbonus > 0)
 777                                                 damage *= 1 + damage_headshotbonus;
 778                         }
 779
 780                         entity victim;
 781                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 782                                 victim = targ.owner;
 783                         else
 784                                 victim = targ;
 785
 786                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 787                         {
 788                                 if(IsDifferentTeam(victim, attacker))
 789                                 {
 790                                         if(damage > 0)
 791                                         {
 792                                                 if(deathtype != DEATH_FIRE)
 793                                                 {
 794                                                         if(victim.BUTTON_CHAT)
 795                                                                 attacker.typehitsound += 1;
 796                                                         else
 797                                                                 attacker.hitsound += 1;
 798                                                 }
 799
 800                                                 damage_goodhits += 1;
 801                                                 damage_gooddamage += damage;
 802
 803                                                 if not(DEATH_ISSPECIAL(deathtype))
 804                                                 {
 805                                                         if(targ.classname == "player") // don't do this for vehicles
 806                                                         if(IsFlying(victim))
 807                                                                 yoda = 1;
 808
 809                                                         if(deathtype & HITTYPE_HEADSHOT)
 810                                                                 headshot = 1;
 811                                                 }
 812                                         }
 813                                 }
 814                                 else
 815                                 {
 816                                         if(deathtype != DEATH_FIRE)
 817                                         {
 818                                                 attacker.typehitsound += 1;
 819                                         }
 820                                         if(mirrordamage > 0)
 821                                                 if(time > attacker.teamkill_complain)
 822                                                 {
 823                                                         attacker.teamkill_complain = time + 5;
 824                                                         attacker.teamkill_soundtime = time + 0.4;
 825                                                         attacker.teamkill_soundsource = targ;
 826                                                 }
 827                                 }
 828                         }
 829                 }
 830         }
 831
 832         // apply push
 833         if (self.damageforcescale)
 834         if (vlen(force))
 835         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 836         {
 837                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 838                 if(self.movetype == MOVETYPE_PHYSICS)
 839                 {
 840                         entity farcent;
 841                         farcent = spawn();
 842                         farcent.classname = "farce";
 843                         farcent.enemy = self;
 844                         farcent.movedir = farce * 10;
 845                         if(self.mass)
 846                                 farcent.movedir = farcent.movedir * self.mass;
 847                         farcent.origin = hitloc;
 848                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 849                         farcent.nextthink = time + 0.1;
 850                         farcent.think = SUB_Remove;
 851                 }
 852                 else
 853                         self.velocity = self.velocity + farce;
 854                 self.flags &~= FL_ONGROUND;
 855                 UpdateCSQCProjectile(self);
 856         }
 857         // apply damage
 858         if (damage != 0 || (self.damageforcescale && vlen(force)))
 859         if (self.event_damage)
 860                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 861         self = oldself;
 862
 863         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 864         {
 865                 if(g_runematch)
 866                 {
 867                         if (attacker.runes & RUNE_VAMPIRE)
 868                         {
 869                         // apply vampire rune
 870                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 871                                 {
 872                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 873                                         attacker.health = bound(
 874                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 875                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 876                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 877                                 }
 878                                 else
 879                                 {
 880                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 881                                         attacker.health = bound(
 882                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 883                                                                                         // empathy won't let you gain health in the same way...
 884                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 885                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 886                                         }
 887                         }
 888                         // apply empathy curse
 889                         else if (attacker.runes & CURSE_EMPATHY)
 890                         {
 891                                 attacker.health = bound(
 892                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 893                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 894                                         attacker.health);
 895                         }
 896                 }
 897         }
 898
 899         // apply mirror damage if any
 900         if(mirrordamage > 0 || mirrorforce > 0)
 901         {
 902                 attacker = attacker_save;
 903
 904                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 905                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 906         }
 907 }
 908
 909 float RadiusDamage_running;
 910 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 911         // Returns total damage applies to creatures
 912 {
 913         entity  targ;
 914         vector  blastorigin;
 915         vector  force;
 916         float   total_damage_to_creatures;
 917         entity  next;
 918         float   tfloordmg;
 919         float   tfloorforce;
 920
 921         float stat_damagedone;
 922
 923         if(RadiusDamage_running)
 924         {
 925                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 926                 return 0;
 927         }
 928
 929         RadiusDamage_running = 1;
 930
 931         tfloordmg = autocvar_g_throughfloor_damage;
 932         tfloorforce = autocvar_g_throughfloor_force;
 933
 934         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 935         total_damage_to_creatures = 0;
 936
 937         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 938                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 939                 {
 940                         force = inflictor.velocity;
 941                         if(vlen(force) == 0)
 942                                 force = '0 0 -1';
 943                         else
 944                                 force = normalize(force);
 945                         if(forceintensity >= 0)
 946                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
 947                         else
 948                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
 949                 }
 950
 951         stat_damagedone = 0;
 952
 953         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
 954         while (targ)
 955         {
 956                 next = targ.chain;
 957                 if (targ != inflictor)
 958                         if (ignore != targ) if(targ.takedamage)
 959                         {
 960                                 vector nearest;
 961                                 vector diff;
 962                                 float power;
 963
 964                                 // LordHavoc: measure distance to nearest point on target (not origin)
 965                                 // (this guarentees 100% damage on a touch impact)
 966                                 nearest = targ.WarpZone_findradius_nearest;
 967                                 diff = targ.WarpZone_findradius_dist;
 968                                 // round up a little on the damage to ensure full damage on impacts
 969                                 // and turn the distance into a fraction of the radius
 970                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
 971                                 //bprint(" ");
 972                                 //bprint(ftos(power));
 973                                 //if (targ == attacker)
 974                                 //      print(ftos(power), "\n");
 975                                 if (power > 0)
 976                                 {
 977                                         float finaldmg;
 978                                         if (power > 1)
 979                                                 power = 1;
 980                                         finaldmg = coredamage * power + edgedamage * (1 - power);
 981                                         if (finaldmg > 0)
 982                                         {
 983                                                 float a;
 984                                                 float c;
 985                                                 vector hitloc;
 986                                                 vector myblastorigin;
 987                                                 vector center;
 988
 989                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
 990
 991                                                 // if it's a player, use the view origin as reference
 992                                                 center = CENTER_OR_VIEWOFS(targ);
 993
 994                                                 force = normalize(center - myblastorigin);
 995                                                 force = force * (finaldmg / coredamage) * forceintensity;
 996                                                 hitloc = nearest;
 997
 998                                                 if(targ != directhitentity)
 999                                                 {
1000                                                         float hits;
1001                                                         float total;
1002                                                         float hitratio;
1003                                                         float mininv_f, mininv_d;
1004
1005                                                         // test line of sight to multiple positions on box,
1006                                                         // and do damage if any of them hit
1007                                                         hits = 0;
1008
1009                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1010                                                         // so for a given max stddev:
1011                                                         // n = (1 / (2 * max stddev of hitratio))^2
1012
1013                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1014                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1015
1016                                                         if(autocvar_g_throughfloor_debug)
1017                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1018
1019                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1020
1021                                                         if(autocvar_g_throughfloor_debug)
1022                                                                 print(sprintf(" steps=%f", total));
1023
1024                                                         if (targ.classname == "player")
1025                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1026                                                         else
1027                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1028
1029                                                         if(autocvar_g_throughfloor_debug)
1030                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1031
1032                                                         for(c = 0; c < total; ++c)
1033                                                         {
1034                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1035                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1036                                                                 if (trace_fraction == 1 || trace_ent == targ)
1037                                                                 {
1038                                                                         ++hits;
1039                                                                         if (hits > 1)
1040                                                                                 hitloc = hitloc + nearest;
1041                                                                         else
1042                                                                                 hitloc = nearest;
1043                                                                 }
1044                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1045                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1046                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1047                                                         }
1048
1049                                                         nearest = hitloc * (1 / max(1, hits));
1050                                                         hitratio = (hits / total);
1051                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1052                                                         finaldmg = finaldmg * a;
1053                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1054                                                         force = force * a;
1055
1056                                                         if(autocvar_g_throughfloor_debug)
1057                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1058                                                 }
1059
1060                                                 // laser force adjustments :P
1061                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1062                                                 {
1063                                                         if (targ == attacker)
1064                                                         {
1065                                                                 vector vel;
1066
1067                                                                 float force_zscale;
1068                                                                 float force_velocitybiasramp;
1069                                                                 float force_velocitybias;
1070
1071                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1072                                                                 if(deathtype & HITTYPE_SECONDARY)
1073                                                                 {
1074                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1075                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1076                                                                 }
1077                                                                 else
1078                                                                 {
1079                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1080                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1081                                                                 }
1082
1083                                                                 vel = targ.velocity;
1084                                                                 vel_z = 0;
1085                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1086                                                                 force =
1087                                                                         vlen(force)
1088                                                                         *
1089                                                                         normalize(normalize(force) + vel);
1090
1091                                                                 force_z *= force_zscale;
1092                                                         }
1093                                                         else
1094                                                         {
1095                                                                 if(deathtype & HITTYPE_SECONDARY)
1096                                                                 {
1097                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1098                                                                 }
1099                                                                 else
1100                                                                 {
1101                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1102                                                                 }
1103                                                         }
1104                                                 }
1105
1106                                                 //if (targ == attacker)
1107                                                 //{
1108                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1109                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1110                                                 //      print(" (", ftos(a), ")\n");
1111                                                 //}
1112                                                 if(finaldmg || vlen(force))
1113                                                 {
1114                                                         if(targ.iscreature)
1115                                                         {
1116                                                                 total_damage_to_creatures += finaldmg;
1117
1118                                                                 if(accuracy_isgooddamage(attacker, targ))
1119                                                                         stat_damagedone += finaldmg;
1120                                                         }
1121
1122                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1123                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1124                                                         else
1125                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1126                                                 }
1127                                         }
1128                                 }
1129                         }
1130                 targ = next;
1131         }
1132
1133         RadiusDamage_running = 0;
1134
1135         if(!DEATH_ISSPECIAL(deathtype))
1136                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1137
1138         return total_damage_to_creatures;
1139 }
1140
1141 .float fire_damagepersec;
1142 .float fire_endtime;
1143 .float fire_deathtype;
1144 .entity fire_owner;
1145 .float fire_hitsound;
1146 .entity fire_burner;
1147
1148 void fireburner_think();
1149
1150 float Fire_IsBurning(entity e)
1151 {
1152         return (time < e.fire_endtime);
1153 }
1154
1155 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1156 {
1157         float dps;
1158         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1159
1160         if(e.classname == "player")
1161         {
1162                 if(e.deadflag)
1163                         return -1;
1164         }
1165         else
1166         {
1167                 if(!e.fire_burner)
1168                 {
1169                         // print("adding a fire burner to ", e.classname, "\n");
1170                         e.fire_burner = spawn();
1171                         e.fire_burner.classname = "fireburner";
1172                         e.fire_burner.think = fireburner_think;
1173                         e.fire_burner.nextthink = time;
1174                         e.fire_burner.owner = e;
1175                 }
1176         }
1177
1178         t = max(t, 0.1);
1179         dps = d / t;
1180         if(Fire_IsBurning(e))
1181         {
1182                 mintime = e.fire_endtime - time;
1183                 maxtime = max(mintime, t);
1184
1185                 mindps = e.fire_damagepersec;
1186                 maxdps = max(mindps, dps);
1187
1188                 if(maxtime > mintime || maxdps > mindps)
1189                 {
1190                         // Constraints:
1191
1192                         // damage we have right now
1193                         mindamage = mindps * mintime;
1194
1195                         // damage we want to get
1196                         maxdamage = mindamage + d;
1197
1198                         // but we can't exceed maxtime * maxdps!
1199                         totaldamage = min(maxdamage, maxtime * maxdps);
1200
1201                         // LEMMA:
1202                         // Look at:
1203                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1204                         // We see:
1205                         // totaldamage <= maxtime * maxdps
1206                         // ==> totaldamage / maxdps <= maxtime.
1207                         // We also see:
1208                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1209                         //                     >= min(mintime, maxtime)
1210                         // ==> totaldamage / maxdps >= mintime.
1211
1212                         /*
1213                         // how long do we damage then?
1214                         // at least as long as before
1215                         // but, never exceed maxdps
1216                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1217                         */
1218
1219                         // alternate:
1220                         // at most as long as maximum allowed
1221                         // but, never below mindps
1222                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1223
1224                         // assuming t > mintime, dps > mindps:
1225                         // we get d = t * dps = maxtime * maxdps
1226                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1227                         // totaldamage / maxdps = maxtime
1228                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1229                         // FROM THIS:
1230                         // a) totaltime = max(mintime, maxtime) = maxtime
1231                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1232
1233                         // assuming t <= mintime:
1234                         // we get maxtime = mintime
1235                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1236                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1237
1238                         // assuming dps <= mindps:
1239                         // we get mindps = maxdps.
1240                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1241                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1242                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1243
1244                         e.fire_damagepersec = totaldamage / totaltime;
1245                         e.fire_endtime = time + totaltime;
1246                         if(totaldamage > 1.2 * mindamage)
1247                         {
1248                                 e.fire_deathtype = dt;
1249                                 if(e.fire_owner != o)
1250                                 {
1251                                         e.fire_owner = o;
1252                                         e.fire_hitsound = FALSE;
1253                                 }
1254                         }
1255                         if(accuracy_isgooddamage(o, e))
1256                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1257                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1258                 }
1259                 else
1260                         return 0;
1261         }
1262         else
1263         {
1264                 e.fire_damagepersec = dps;
1265                 e.fire_endtime = time + t;
1266                 e.fire_deathtype = dt;
1267                 e.fire_owner = o;
1268                 e.fire_hitsound = FALSE;
1269                 if(accuracy_isgooddamage(o, e))
1270                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1271                 return d;
1272         }
1273 }
1274
1275 void Fire_ApplyDamage(entity e)
1276 {
1277         float t, d, hi, ty;
1278         entity o;
1279
1280         if not(Fire_IsBurning(e))
1281                 return;
1282
1283         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1284         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1285                 o = e.fire_owner;
1286
1287         // water and slime stop fire
1288         if(e.waterlevel)
1289         if(e.watertype != CONTENT_LAVA)
1290                 e.fire_endtime = 0;
1291
1292         // ice stops fire
1293         if(e.freezetag_frozen)
1294                 e.fire_endtime = 0;
1295
1296         t = min(frametime, e.fire_endtime - time);
1297         d = e.fire_damagepersec * t;
1298
1299         hi = e.fire_owner.hitsound;
1300         ty = e.fire_owner.typehitsound;
1301         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1302         if(e.fire_hitsound && e.fire_owner)
1303         {
1304                 e.fire_owner.hitsound = hi;
1305                 e.fire_owner.typehitsound = ty;
1306         }
1307         e.fire_hitsound = TRUE;
1308
1309         if not(IS_INDEPENDENT_PLAYER(e))
1310         FOR_EACH_PLAYER(other) if(e != other)
1311         {
1312                 if(other.classname == "player")
1313                 if(other.deadflag == DEAD_NO)
1314                 if not(IS_INDEPENDENT_PLAYER(other))
1315                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1316                 {
1317                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1318                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1319                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1320                 }
1321         }
1322 }
1323
1324 void Fire_ApplyEffect(entity e)
1325 {
1326         if(Fire_IsBurning(e))
1327                 e.effects |= EF_FLAME;
1328         else
1329                 e.effects &~= EF_FLAME;
1330 }
1331
1332 void fireburner_think()
1333 {
1334         // for players, this is done in the regular loop
1335         if(wasfreed(self.owner))
1336         {
1337                 remove(self);
1338                 return;
1339         }
1340         Fire_ApplyEffect(self.owner);
1341         if(!Fire_IsBurning(self.owner))
1342         {
1343                 self.owner.fire_burner = world;
1344                 remove(self);
1345                 return;
1346         }
1347         Fire_ApplyDamage(self.owner);
1348         self.nextthink = time;
1349 }