qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/mapinfo.qh>
   7 #include <common/net_linked.qh>
   8 #include <common/notifications/all.qh>
   9 #include <common/playerstats.qh>
  10 #include <common/stats.qh>
  11 #include <common/util.qh>
  12 #include <common/weapons/_all.qh>
  13 #include <server/client.qh>
  14 #include <server/command/banning.qh>
  15 #include <server/command/common.qh>
  16 #include <server/command/vote.qh>
  17 #include <server/damage.qh>
  18 #include <server/gamelog.qh>
  19 #include <server/intermission.qh>
  20 #include <server/mutators/_mod.qh>
  21 #include <server/race.qh>
  22 #include <server/round_handler.qh>
  23 #include <server/scores.qh>
  24 #include <server/teamplay.qh>
  25 #include <server/world.qh>
  26
  27 // =============================================
  28 //  Server side voting code, reworked by Samual
  29 //  Last updated: December 27th, 2011
  30 // =============================================
  31
  32 //  Nagger for players to know status of voting
  33 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  34 {
  35         int nags, i, f, b;
  36         entity e;
  37         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  38
  39         // bits:
  40         //   1 = ready
  41         //   2 = player needs to ready up
  42         //   4 = vote
  43         //   8 = player needs to vote
  44         //  16 = warmup
  45         // sendflags:
  46         //  64 = vote counts
  47         // 128 = vote string
  48
  49         nags = 0;
  50         if (readycount)
  51         {
  52                 nags |= BIT(0);
  53                 if (to.ready == 0) nags |= BIT(1);
  54         }
  55         if (vote_called)
  56         {
  57                 nags |= BIT(2);
  58                 if (to.vote_selection == 0) nags |= BIT(3);
  59         }
  60         if (warmup_stage) nags |= BIT(4);
  61
  62         if (sendflags & BIT(6)) nags |= BIT(6);
  63
  64         if (sendflags & BIT(7)) nags |= BIT(7);
  65
  66         if (!(nags & 4))  // no vote called? send no string
  67                 nags &= ~(BIT(6) | BIT(7));
  68
  69         WriteByte(MSG_ENTITY, nags);
  70
  71         if (nags & BIT(6))
  72         {
  73                 WriteByte(MSG_ENTITY, vote_accept_count);
  74                 WriteByte(MSG_ENTITY, vote_reject_count);
  75                 WriteByte(MSG_ENTITY, vote_needed_overall);
  76                 WriteChar(MSG_ENTITY, to.vote_selection);
  77         }
  78
  79         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  80
  81         if (nags & 1)
  82         {
  83                 for (i = 1; i <= maxclients; i += 8)
  84                 {
  85                         for (f = 0, e = edict_num(i), b = BIT(0); b < BIT(8); b <<= 1, e = nextent(e))
  86                                 if (!IS_REAL_CLIENT(e) || e.ready)
  87                                         f |= b;
  88                         WriteByte(MSG_ENTITY, f);
  89                 }
  90         }
  91
  92         return true;
  93 }
  94
  95 void Nagger_Init()
  96 {
  97         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
  98 }
  99
 100 void Nagger_VoteChanged()
 101 {
 102         if (nagger) nagger.SendFlags |= BIT(7);
 103 }
 104
 105 void Nagger_VoteCountChanged()
 106 {
 107         if (nagger) nagger.SendFlags |= BIT(6);
 108 }
 109
 110 void Nagger_ReadyCounted()
 111 {
 112         if (nagger) nagger.SendFlags |= BIT(0);
 113 }
 114
 115 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 116 string OriginalCallerName()
 117 {
 118         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 119         return vote_caller_name;
 120 }
 121
 122 // =======================
 123 //  Game logic for voting
 124 // =======================
 125
 126 void VoteReset()
 127 {
 128         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 129
 130         if (vote_called)
 131         {
 132                 strfree(vote_called_command);
 133                 strfree(vote_called_display);
 134                 strfree(vote_caller_name);
 135         }
 136
 137         vote_called = VOTE_NULL;
 138         vote_caller = NULL;
 139         vote_endtime = 0;
 140
 141         vote_parsed_command = string_null;
 142         vote_parsed_display = string_null;
 143
 144         Nagger_VoteChanged();
 145 }
 146
 147 void VoteStop(entity stopper)
 148 {
 149         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 150         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 151         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 152         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 153         VoteReset();
 154 }
 155
 156 void VoteAccept()
 157 {
 158         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 159
 160         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 161         else localcmd(strcat(vote_called_command, "\n"));
 162
 163         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 164
 165         VoteReset();
 166         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 167 }
 168
 169 void VoteReject()
 170 {
 171         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 172         VoteReset();
 173         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 174 }
 175
 176 void VoteTimeout()
 177 {
 178         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 179         VoteReset();
 180         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 181 }
 182
 183 void VoteSpam(float notvoters, float mincount, string result)
 184 {
 185         bprint(strcat(
 186                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 187                 strcat("^2:^1", ftos(vote_reject_count)),
 188                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 189                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 190                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 191
 192         if (autocvar_sv_eventlog)
 193         {
 194                 GameLogEcho(strcat(
 195                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 196                         strcat(":", ftos(vote_reject_count)),
 197                         strcat(":", ftos(vote_abstain_count)),
 198                         strcat(":", ftos(notvoters)),
 199                         strcat(":", ftos(mincount))));
 200         }
 201 }
 202
 203 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 204
 205 void VoteCount(float first_count)
 206 {
 207         // declarations
 208         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 209
 210         float vote_player_count = 0, notvoters = 0;
 211         float vote_real_player_count = 0, vote_real_accept_count = 0;
 212         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 213         float vote_needed_of_voted, final_needed_votes;
 214         float vote_factor_overall, vote_factor_of_voted;
 215
 216         Nagger_VoteCountChanged();
 217
 218         // add up all the votes from each connected client
 219         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 220                 ++vote_player_count;
 221                 if (IS_PLAYER(it))   ++vote_real_player_count;
 222                 switch (it.vote_selection)
 223                 {
 224                         case VOTE_SELECT_REJECT:
 225                         { ++vote_reject_count;
 226                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 227                         }
 228                         case VOTE_SELECT_ACCEPT:
 229                         { ++vote_accept_count;
 230                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 231                         }
 232                         case VOTE_SELECT_ABSTAIN:
 233                         { ++vote_abstain_count;
 234                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 235                         }
 236                         default: break;
 237                 }
 238         });
 239
 240         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 241         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 242         {
 243                 if (vote_caller)   vote_caller.vote_waittime = 0;
 244                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 245                 VoteReset();
 246                 return;
 247         }
 248
 249         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 250         if (!spectators_allowed && (vote_real_player_count > 0))
 251         {
 252                 vote_accept_count = vote_real_accept_count;
 253                 vote_reject_count = vote_real_reject_count;
 254                 vote_abstain_count = vote_real_abstain_count;
 255                 vote_player_count = vote_real_player_count;
 256         }
 257
 258         // people who have no opinion in any way :D
 259         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 260
 261         // determine the goal for the vote to be passed or rejected normally
 262         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 263         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 264
 265         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 266         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 267         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 268
 269         // are there any players at all on the server? it could be an admin vote
 270         if (vote_player_count == 0 && first_count)
 271         {
 272                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 273                 VoteAccept();
 274                 return;
 275         }
 276
 277         // since there ARE players, finally calculate the result of the vote
 278         if (vote_accept_count >= vote_needed_overall)
 279         {
 280                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 281                 VoteAccept();
 282                 return;
 283         }
 284
 285         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 286         {
 287                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 288                 VoteReject();
 289                 return;
 290         }
 291
 292         // there is not enough votes in either direction, now lets just calculate what the voters have said
 293         if (time > vote_endtime)
 294         {
 295                 final_needed_votes = vote_needed_overall;
 296
 297                 if (autocvar_sv_vote_majority_factor_of_voted)
 298                 {
 299                         if (vote_accept_count >= vote_needed_of_voted)
 300                         {
 301                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 302                                 VoteAccept();
 303                                 return;
 304                         }
 305
 306                         if (vote_accept_count + vote_reject_count > 0)
 307                         {
 308                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 309                                 VoteReject();
 310                                 return;
 311                         }
 312
 313                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 314                 }
 315
 316                 // it didn't pass or fail, so not enough votes to even make a decision.
 317                 VoteSpam(notvoters, final_needed_votes, "timeout");
 318                 VoteTimeout();
 319         }
 320 }
 321
 322 void VoteThink()
 323 {
 324         if (vote_endtime > 0)        // a vote was called
 325         {
 326                 if (time > vote_endtime) // time is up
 327                         VoteCount(false);
 328         }
 329 }
 330
 331
 332 // =======================
 333 //  Game logic for warmup
 334 // =======================
 335
 336 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 337 void reset_map(bool dorespawn)
 338 {
 339         if (time <= game_starttime)
 340         {
 341                 if (game_stopped)
 342                         return;
 343                 if (round_handler_IsActive())
 344                         round_handler_Reset(game_starttime);
 345         }
 346
 347         if (shuffleteams_on_reset_map)
 348         {
 349                 shuffleteams();
 350                 shuffleteams_on_reset_map = false;
 351         }
 352
 353         FOREACH_CLIENT(IS_PLAYER(it),
 354         {
 355                 entity store = PS(it);
 356                 if (store)
 357                 {
 358                         for (int j = 0; j < REGISTRY_COUNT(Items); j++)
 359                                 store.inventory.inv_items[j] = 0;
 360                         Inventory_update(store);
 361                 }
 362         });
 363
 364         MUTATOR_CALLHOOK(reset_map_global);
 365
 366         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 367         {
 368                 if(IS_CLIENT(it))
 369                         continue;
 370                 if (it.reset)
 371                 {
 372                         it.reset(it);
 373                         continue;
 374                 }
 375                 if (it.team_saved) it.team = it.team_saved;
 376                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 377         });
 378
 379         // Waypoints and assault start come LAST
 380         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 381                 if (it.reset2) it.reset2(it);
 382         });
 383
 384         FOREACH_CLIENT(IS_PLAYER(it) && STAT(FROZEN, it), { Unfreeze(it, false); });
 385
 386         // Moving the player reset code here since the player-reset depends
 387         // on spawnpoint entities which have to be reset first --blub
 388         if (dorespawn)
 389         {
 390                 if (!MUTATOR_CALLHOOK(reset_map_players))
 391                 {
 392                         if (restart_mapalreadyrestarted || (time < game_starttime))
 393                         {
 394                                 FOREACH_CLIENT(IS_PLAYER(it),
 395                                 {
 396                                         /*
 397                                         only reset players if a restart countdown is active
 398                                         this can either be due to cvar sv_ready_restart_after_countdown having set
 399                                         restart_mapalreadyrestarted to 1 after the countdown ended or when
 400                                         sv_ready_restart_after_countdown is not used and countdown is still running
 401                                         */
 402                                         // NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 403                                         // PlayerScore_Clear(it);
 404                                         CS(it).killcount = 0;
 405                                         // stop the player from moving so that he stands still once he gets respawned
 406                                         it.velocity = '0 0 0';
 407                                         it.avelocity = '0 0 0';
 408                                         CS(it).movement = '0 0 0';
 409                                         PutClientInServer(it);
 410                                 });
 411                         }
 412                 }
 413         }
 414 }
 415
 416 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 417 void ReadyRestart_think(entity this)
 418 {
 419         restart_mapalreadyrestarted = true;
 420         reset_map(true);
 421         Score_ClearAll();
 422         delete(this);
 423 }
 424
 425 // Forces a restart of the game without actually reloading the map // this is a mess...
 426 void ReadyRestart_force()
 427 {
 428         if (time <= game_starttime && game_stopped)
 429                 return;
 430
 431         bprint("^1Server is restarting...\n");
 432
 433         VoteReset();
 434
 435         // clear overtime, we have to decrease timelimit to its original value again.
 436         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 437                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 438         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 439
 440         readyrestart_happened = true;
 441         game_starttime = time + RESTART_COUNTDOWN;
 442
 443         // clear player attributes
 444         FOREACH_CLIENT(IS_PLAYER(it), {
 445                 it.alivetime = 0;
 446                 CS(it).killcount = 0;
 447                 float val = PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, 0);
 448                 PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, -val);
 449         });
 450
 451         restart_mapalreadyrestarted = false; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 452
 453         // disable the warmup global for the server
 454         if(warmup_stage)
 455                 localcmd("\nsv_hook_warmupend\n");
 456         warmup_stage = 0;                // once the game is restarted the game is in match stage
 457
 458         // reset the .ready status of all players (also spectators)
 459         FOREACH_CLIENT(IS_REAL_CLIENT(it), { it.ready = false; });
 460         readycount = 0;
 461         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 462
 463         // lock teams with lockonrestart
 464         if (autocvar_teamplay_lockonrestart && teamplay)
 465         {
 466                 lockteams = true;
 467                 bprint("^1The teams are now locked.\n");
 468         }
 469
 470         // initiate the restart-countdown-announcer entity
 471         if (sv_ready_restart_after_countdown)
 472         {
 473                 entity restart_timer = new_pure(restart_timer);
 474                 setthink(restart_timer, ReadyRestart_think);
 475                 restart_timer.nextthink = game_starttime;
 476         }
 477
 478         // after a restart every players number of allowed timeouts gets reset, too
 479         if (autocvar_sv_timeout)
 480         {
 481                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 482         }
 483
 484         if (!sv_ready_restart_after_countdown) reset_map(true);
 485         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 486 }
 487
 488 void ReadyRestart()
 489 {
 490         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing) localcmd("restart\n");
 491         else localcmd("\nsv_hook_readyrestart\n");
 492
 493         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 494         // Otherwise scores could be manipulated during the countdown.
 495         if (!sv_ready_restart_after_countdown) Score_ClearAll();
 496         ReadyRestart_force();
 497 }
 498
 499 // Count the players who are ready and determine whether or not to restart the match
 500 void ReadyCount()
 501 {
 502         float ready_needed_factor, ready_needed_count;
 503         float t_ready = 0, t_players = 0;
 504
 505         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || it.caplayer == 1), {
 506                 ++t_players;
 507                 if (it.ready) ++t_ready;
 508         });
 509
 510         readycount = t_ready;
 511
 512         Nagger_ReadyCounted();
 513
 514         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 515         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 516
 517         if (readycount >= ready_needed_count) ReadyRestart();
 518 }
 519
 520
 521 // ======================================
 522 //  Supporting functions for VoteCommand
 523 // ======================================
 524
 525 float Votecommand_check_assignment(entity caller, float assignment)
 526 {
 527         float from_server = (!caller);
 528
 529         if ((assignment == VC_ASGNMNT_BOTH)
 530             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 531             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 532
 533         return false;
 534 }
 535
 536 string VoteCommand_extractcommand(string input, float startpos, int argc)
 537 {
 538         string output;
 539
 540         if ((argc - 1) < startpos) output = "";
 541         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 542
 543         return output;
 544 }
 545
 546 float VoteCommand_checknasty(string vote_command)
 547 {
 548         if ((strstrofs(vote_command, ";", 0) >= 0)
 549             || (strstrofs(vote_command, "\n", 0) >= 0)
 550             || (strstrofs(vote_command, "\r", 0) >= 0)
 551             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 552
 553         return true;
 554 }
 555
 556 // NOTE: requires input to be surrounded by spaces
 557 string VoteCommand_checkreplacements(string input)
 558 {
 559         string output = input;
 560         // allow gotomap replacements
 561         output = strreplace(" map ", " gotomap ", output);
 562         output = strreplace(" chmap ", " gotomap ", output);
 563         return output;
 564 }
 565
 566 float VoteCommand_checkinlist(string vote_command, string list)
 567 {
 568         string l = VoteCommand_checkreplacements(strcat(" ", list, " "));
 569
 570         if (strstrofs(l, VoteCommand_checkreplacements(strcat(" ", vote_command, " ")), 0) >= 0) return true;
 571
 572         return false;
 573 }
 574
 575 string ValidateMap(string validated_map, entity caller)
 576 {
 577         validated_map = MapInfo_FixName(validated_map);
 578
 579         if (!validated_map)
 580         {
 581                 print_to(caller, "This map is not available on this server.");
 582                 return string_null;
 583         }
 584
 585         if (!autocvar_sv_vote_override_mostrecent && caller)
 586         {
 587                 if (Map_IsRecent(validated_map))
 588                 {
 589                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 590                         return string_null;
 591                 }
 592         }
 593
 594         if (!MapInfo_CheckMap(validated_map))
 595         {
 596                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 597                 return string_null;
 598         }
 599
 600         return validated_map;
 601 }
 602
 603 float VoteCommand_checkargs(float startpos, int argc)
 604 {
 605         float p, q, check, minargs;
 606         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 607         string cmdrestriction = "";  // No we don't.
 608         string charlist, arg;
 609         float checkmate;
 610
 611         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 612                 cmdrestriction = cvar_string(cvarname);
 613         else
 614                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 615
 616         if (cmdrestriction == "") return true;
 617
 618         ++startpos;  // skip command name
 619
 620         // check minimum arg count
 621
 622         // 0 args: argc == startpos
 623         // 1 args: argc == startpos + 1
 624         // ...
 625
 626         minargs = stof(cmdrestriction);
 627         if (argc - startpos < minargs) return false;
 628
 629         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 630
 631         for ( ; ; )
 632         {
 633                 // we know that at any time, startpos <= argc - minargs
 634                 // so this means: argc-minargs >= startpos >= argc, thus
 635                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 636                 // have been seen already
 637
 638                 if (startpos >= argc) // all args checked? GOOD
 639                         break;
 640
 641                 if (p < 0)            // no more args? FAIL
 642                 {
 643                         // exception: exactly minargs left, this one included
 644                         if (argc - startpos == minargs) break;
 645
 646                         // otherwise fail
 647                         return false;
 648                 }
 649
 650                 // cut to next semicolon
 651                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 652                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 653                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 654
 655                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 656                 // charlist = strreplace("^^", ";", charlist);
 657
 658                 if (charlist != "")
 659                 {
 660                         // verify the arg only contains allowed chars
 661                         arg = argv(startpos);
 662                         checkmate = strlen(arg);
 663                         for (check = 0; check < checkmate; ++check)
 664                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 665                         // not allowed character
 666                         // all characters are allowed. FINE.
 667                 }
 668
 669                 ++startpos;
 670                 --minargs;
 671                 p = q;
 672         }
 673
 674         return true;
 675 }
 676
 677 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 678 {
 679         string first_command = argv(startpos);
 680         int missing_chars = argv_start_index(startpos);
 681
 682         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 683                 return 0;
 684
 685         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 686
 687         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 688
 689         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 690         {
 691                 case MUT_VOTEPARSE_CONTINUE: { break; }
 692                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 693                 case MUT_VOTEPARSE_INVALID: { return -1; }
 694                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 695         }
 696
 697         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 698         {
 699                 case "kick":
 700                 case "kickban":    // catch all kick/kickban commands
 701                 {
 702                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 703                         float accepted = VerifyClientEntity(victim, true, false);
 704
 705                         if (accepted > 0)
 706                         {
 707                                 string reason = "No reason provided";
 708                                 if(argc > next_token)
 709                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 710
 711                                 string command_arguments = reason;
 712                                 if (first_command == "kickban")
 713                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 714
 715                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 716                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 717                         }
 718                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return 0; }
 719
 720                         break;
 721                 }
 722
 723                 case "map":
 724                 case "chmap":
 725                 case "gotomap":  // re-direct all map selection commands to gotomap
 726                 {
 727                         vote_command = ValidateMap(argv(startpos + 1), caller);
 728                         if (!vote_command)  return -1;
 729                         vote_parsed_command = strcat("gotomap ", vote_command);
 730                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 731
 732                         break;
 733                 }
 734
 735                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 736                 // maybe fallback instead of aborting if map name is invalid?
 737                 case "nextmap":
 738                 {
 739                         vote_command = ValidateMap(argv(startpos + 1), caller);
 740                         if (!vote_command)  return -1;
 741                         vote_parsed_command = strcat("nextmap ", vote_command);
 742                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 743
 744                         break;
 745                 }
 746
 747                 case "timelimit": // include restrictions on the maximum votable time limit
 748                 {
 749                         float timelimit_vote = stof(argv(startpos + 1));
 750                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 751                         {
 752                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 753                                 return -1;
 754                         }
 755                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 756                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 757                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 758
 759                         break;
 760                 }
 761
 762                 case "restart":
 763                 {
 764                         // add a delay so that vote result can be seen and announcer can be heard
 765                         // if the vote is accepted
 766                         vote_parsed_command = strcat("defer 1 ", vote_command);
 767                         vote_parsed_display = strzone(strcat("^1", vote_command));
 768
 769                         break;
 770                 }
 771
 772                 default:
 773                 {
 774                         vote_parsed_command = vote_command;
 775                         vote_parsed_display = strzone(strcat("^1", vote_command));
 776
 777                         break;
 778                 }
 779         }
 780
 781         return 1;
 782 }
 783
 784
 785 // =======================
 786 //  Command Sub-Functions
 787 // =======================
 788
 789 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 790 {
 791         switch (request)
 792         {
 793                 case CMD_REQUEST_COMMAND:
 794                 {
 795                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 796                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 797                         {
 798                                 print_to(caller, "^1You have already voted.");
 799                         }
 800
 801                         else  // everything went okay, continue changing vote
 802                         {
 803                                 print_to(caller, "^1You abstained from your vote.");
 804                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 805                                 msg_entity = caller;
 806                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 807
 808                         return;
 809                 }
 810
 811                 default:
 812                 case CMD_REQUEST_USAGE:
 813                 {
 814                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 815                         print_to(caller, "  No arguments required.");
 816                         return;
 817                 }
 818         }
 819 }
 820
 821 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 822 {
 823         switch (request)
 824         {
 825                 case CMD_REQUEST_COMMAND:
 826                 {
 827                         float tmp_playercount = 0;
 828                         int parse_error;
 829
 830                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 831
 832                         if (!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 833                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 834                         {
 835                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 836                         }
 837                         else if (vote_called)
 838                         {
 839                                 print_to(caller, "^1There is already a vote called.");
 840                         }
 841                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 842                         {
 843                                 print_to(caller, "^1Only players can call a vote.");
 844                         }
 845                         else if (caller && !IS_CLIENT(caller))
 846                         {
 847                                 print_to(caller, "^1Only connected clients can vote.");
 848                         }
 849                         else if (timeout_status && vote_command != "timein")
 850                         {
 851                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 852                         }
 853                         else if (caller && (time < caller.vote_waittime))
 854                         {
 855                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 856                         }
 857                         else if (!VoteCommand_checknasty(vote_command))
 858                         {
 859                                 print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 860                         }
 861                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 862                         {
 863                                 if(parse_error == 0)
 864                                         print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 865                         }
 866                         else  // everything went okay, continue with calling the vote
 867                         {
 868                                 vote_caller = caller;  // remember who called the vote
 869                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 870                                 vote_called = VOTE_NORMAL;
 871                                 vote_called_command = strzone(vote_parsed_command);
 872                                 vote_called_display = strzone(vote_parsed_display);
 873                                 vote_endtime = time + autocvar_sv_vote_timeout;
 874
 875                                 if (caller)
 876                                 {
 877                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 878                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 879                                         msg_entity = caller;
 880                                 }
 881
 882                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 883
 884                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 885                                 if (autocvar_sv_eventlog)
 886                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 887                                 Nagger_VoteChanged();
 888                                 VoteCount(true);  // needed if you are the only one
 889
 890                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
 891                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 892                         }
 893
 894                         return;
 895                 }
 896
 897                 default:
 898                 case CMD_REQUEST_USAGE:
 899                 {
 900                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 901                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 902                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 903                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 904                         return;
 905                 }
 906         }
 907 }
 908
 909 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
 910 {
 911         switch (request)
 912         {
 913                 case CMD_REQUEST_COMMAND:
 914                 {
 915                         if (autocvar_sv_vote_master)
 916                         {
 917                                 switch (strtolower(argv(2)))
 918                                 {
 919                                         case "do":
 920                                         {
 921                                                 int parse_error;
 922                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 923
 924                                                 if (!caller.vote_master)
 925                                                         print_to(caller, "^1You do not have vote master privileges.");
 926                                                 else if (!VoteCommand_checknasty(vote_command))
 927                                                 {
 928                                                         print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 929                                                 }
 930                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
 931                                                 {
 932                                                         if(parse_error == 0)
 933                                                                 print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 934                                                 }
 935                                                 else  // everything went okay, proceed with command
 936                                                 {
 937                                                         localcmd(strcat(vote_parsed_command, "\n"));
 938                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 939                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 940                                                         if (autocvar_sv_eventlog)
 941                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
 942                                                 }
 943
 944                                                 return;
 945                                         }
 946
 947                                         case "login":
 948                                         {
 949                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 950                                                 else if (caller.vote_master)
 951                                                 {
 952                                                         print_to(caller, "^1You are already logged in as vote master.");
 953                                                 }
 954                                                 else if (autocvar_sv_vote_master_password != argv(3))
 955                                                 {
 956                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 957                                                 }
 958                                                 else  // everything went okay, proceed with giving this player master privilages
 959                                                 {
 960                                                         caller.vote_master = true;
 961                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 962                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 963                                                         if (autocvar_sv_eventlog)
 964                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
 965                                                 }
 966
 967                                                 return;
 968                                         }
 969
 970                                         default:  // calling a vote for master
 971                                         {
 972                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 973                                                 else if (vote_called)
 974                                                 {
 975                                                         print_to(caller, "^1There is already a vote called.");
 976                                                 }
 977                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 978                                                 {
 979                                                         print_to(caller, "^1Only players can call a vote.");
 980                                                 }
 981                                                 else if (timeout_status)
 982                                                 {
 983                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
 984                                                 }
 985                                                 else  // everything went okay, continue with creating vote
 986                                                 {
 987                                                         vote_caller = caller;
 988                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 989                                                         vote_called = VOTE_MASTER;
 990                                                         vote_called_command = strzone("XXX");
 991                                                         vote_called_display = strzone("^3master");
 992                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 993
 994                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 995                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 996
 997                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 998                                                         if (autocvar_sv_eventlog)
 999                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1000                                                         Nagger_VoteChanged();
1001                                                         VoteCount(true);  // needed if you are the only one
1002                                                 }
1003
1004                                                 return;
1005                                         }
1006                                 }
1007                         }
1008                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1009
1010                         return;
1011                 }
1012
1013                 default:
1014                 case CMD_REQUEST_USAGE:
1015                 {
1016                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
1017                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
1018                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
1019                         return;
1020                 }
1021         }
1022 }
1023
1024 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1025 {
1026         switch (request)
1027         {
1028                 case CMD_REQUEST_COMMAND:
1029                 {
1030                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1031                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1032                         {
1033                                 print_to(caller, "^1You have already voted.");
1034                         }
1035                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1036                         {
1037                                 VoteStop(caller);
1038                         }
1039
1040                         else  // everything went okay, continue changing vote
1041                         {
1042                                 print_to(caller, "^1You rejected the vote.");
1043                                 caller.vote_selection = VOTE_SELECT_REJECT;
1044                                 msg_entity = caller;
1045                                 if (!autocvar_sv_vote_singlecount)
1046                                         VoteCount(false);
1047                         }
1048
1049                         return;
1050                 }
1051
1052                 default:
1053                 case CMD_REQUEST_USAGE:
1054                 {
1055                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1056                         print_to(caller, "  No arguments required.");
1057                         return;
1058                 }
1059         }
1060 }
1061
1062 void VoteCommand_status(int request, entity caller)  // BOTH
1063 {
1064         switch (request)
1065         {
1066                 case CMD_REQUEST_COMMAND:
1067                 {
1068                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1069                         else print_to(caller, "^1No vote called.");
1070
1071                         return;
1072                 }
1073
1074                 default:
1075                 case CMD_REQUEST_USAGE:
1076                 {
1077                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1078                         print_to(caller, "  No arguments required.");
1079                         return;
1080                 }
1081         }
1082 }
1083
1084 void VoteCommand_stop(int request, entity caller)  // BOTH
1085 {
1086         switch (request)
1087         {
1088                 case CMD_REQUEST_COMMAND:
1089                 {
1090                         if (!vote_called)   print_to(caller, "^1No vote called.");
1091                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1092                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1093                         return;
1094                 }
1095
1096                 default:
1097                 case CMD_REQUEST_USAGE:
1098                 {
1099                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1100                         print_to(caller, "  No arguments required.");
1101                         return;
1102                 }
1103         }
1104 }
1105
1106 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1107 {
1108         switch (request)
1109         {
1110                 case CMD_REQUEST_COMMAND:
1111                 {
1112                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1113                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1114                         {
1115                                 print_to(caller, "^1You have already voted.");
1116                         }
1117                         else  // everything went okay, continue changing vote
1118                         {
1119                                 print_to(caller, "^1You accepted the vote.");
1120                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1121                                 msg_entity = caller;
1122                                 if (!autocvar_sv_vote_singlecount)
1123                                         VoteCount(false);
1124                         }
1125
1126                         return;
1127                 }
1128
1129                 default:
1130                 case CMD_REQUEST_USAGE:
1131                 {
1132                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1133                         print_to(caller, "  No arguments required.");
1134                         return;
1135                 }
1136         }
1137 }
1138
1139 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1140 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1141 void VoteCommand_(int request)
1142 {
1143     switch(request)
1144     {
1145         case CMD_REQUEST_COMMAND:
1146         {
1147
1148             return;
1149         }
1150
1151         default:
1152         case CMD_REQUEST_USAGE:
1153         {
1154             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1155             print_to(caller, "  No arguments required.");
1156             return;
1157         }
1158     }
1159 }
1160 */
1161
1162
1163 // ================================
1164 //  Macro system for vote commands
1165 // ================================
1166
1167 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1168 #define VOTE_COMMANDS(request, caller, arguments, command) \
1169         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1170         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1171         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1172         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1173         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1174         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1175         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1176         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1177         /* nothing */
1178
1179 void VoteCommand_macro_help(entity caller, int argc)
1180 {
1181         string command_origin = GetCommandPrefix(caller);
1182
1183         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1184         {
1185                 print_to(caller, "\nVoting commands:\n");
1186                 #define VOTE_COMMAND(name, function, description, assignment) \
1187                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1188
1189                 VOTE_COMMANDS(0, caller, 0, "");
1190 #undef VOTE_COMMAND
1191
1192                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1193                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1194                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1195         }
1196         else  // usage for individual command
1197         {
1198                 #define VOTE_COMMAND(name, function, description, assignment) \
1199                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1200
1201                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1202 #undef VOTE_COMMAND
1203
1204                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1205                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1206                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1207                 else
1208                         print_to(caller, "No documentation exists for this vote");
1209         }
1210 }
1211
1212 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1213 {
1214         #define VOTE_COMMAND(name, function, description, assignment) \
1215                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1216
1217         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1218 #undef VOTE_COMMAND
1219
1220         return false;
1221 }
1222
1223
1224 // ======================================
1225 //  Main function handling vote commands
1226 // ======================================
1227
1228 void VoteCommand(int request, entity caller, int argc, string vote_command)
1229 {
1230         // Guide for working with argc arguments by example:
1231         // argc:   1    - 2      - 3     - 4
1232         // argv:   0    - 1      - 2     - 3
1233         // cmd     vote - master - login - password
1234
1235         switch (request)
1236         {
1237                 case CMD_REQUEST_COMMAND:
1238                 {
1239                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1240                 }
1241
1242                 default:
1243                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1244                 case CMD_REQUEST_USAGE:
1245                 {
1246                         VoteCommand_macro_help(caller, argc);
1247                         return;
1248                 }
1249         }
1250 }