qcsrc/server/command/vote.qc

   1 // =============================================
   2 //  Server side voting code, reworked by Samual
   3 //  Last updated: December 14th, 2011
   4 // =============================================
   5
   6 //  Nagger for players to know status of voting
   7 float Nagger_SendEntity(entity to, float sendflags)
   8 {
   9         float nags, i, f, b;
  10         entity e;
  11         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
  12
  13         // bits:
  14         //   1 = ready
  15         //   2 = player needs to ready up
  16         //   4 = vote
  17         //   8 = player needs to vote
  18         //  16 = warmup
  19         // sendflags:
  20         //  64 = vote counts
  21         // 128 = vote string
  22
  23         nags = 0;
  24         if(readycount)
  25         {
  26                 nags |= 1;
  27                 if(to.ready == 0)
  28                         nags |= 2;
  29         }
  30         if(vote_called)
  31         {
  32                 nags |= 4;
  33                 if(to.vote_selection == 0)
  34                         nags |= 8;
  35         }
  36         if(inWarmupStage)
  37                 nags |= 16;
  38
  39         if(sendflags & 64)
  40                 nags |= 64;
  41
  42         if(sendflags & 128)
  43                 nags |= 128;
  44
  45         if(!(nags & 4)) // no vote called? send no string
  46                 nags &~= (64 | 128);
  47
  48         WriteByte(MSG_ENTITY, nags);
  49
  50         if(nags & 64)
  51         {
  52                 WriteByte(MSG_ENTITY, vote_accept_count);
  53                 WriteByte(MSG_ENTITY, vote_reject_count);
  54                 WriteByte(MSG_ENTITY, vote_needed_overall);
  55                 WriteChar(MSG_ENTITY, to.vote_selection);
  56         }
  57
  58         if(nags & 128)
  59                 WriteString(MSG_ENTITY, vote_called_display);
  60
  61         if(nags & 1)
  62         {
  63                 for(i = 1; i <= maxclients; i += 8)
  64                 {
  65                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  66                                 if(clienttype(e) != CLIENTTYPE_REAL || e.ready)
  67                                         f |= b;
  68                         WriteByte(MSG_ENTITY, f);
  69                 }
  70         }
  71
  72         return TRUE;
  73 }
  74
  75 void Nagger_Init()
  76 {
  77         Net_LinkEntity(nagger = spawn(), FALSE, 0, Nagger_SendEntity);
  78 }
  79
  80 void Nagger_VoteChanged()
  81 {
  82         if(nagger)
  83                 nagger.SendFlags |= 128;
  84 }
  85
  86 void Nagger_VoteCountChanged()
  87 {
  88         if(nagger)
  89                 nagger.SendFlags |= 64;
  90 }
  91
  92 void Nagger_ReadyCounted()
  93 {
  94         if(nagger)
  95                 nagger.SendFlags |= 1;
  96 }
  97
  98
  99 // =======================
 100 //  Game logic for voting
 101 // =======================
 102
 103 void VoteReset()
 104 {
 105         entity tmp_player;
 106
 107         FOR_EACH_CLIENT(tmp_player) { tmp_player.vote_selection = 0; }
 108
 109         if(vote_called)
 110         {
 111                 strunzone(vote_called_command);
 112                 strunzone(vote_called_display);
 113         }
 114
 115         vote_called = VOTE_NULL;
 116         vote_endtime = 0;
 117         vote_called_command = string_null;
 118         vote_called_display = string_null;
 119
 120         vote_parsed_command = string_null;
 121         vote_parsed_display = string_null;
 122
 123         Nagger_VoteChanged();
 124 }
 125
 126 void VoteStop(entity stopper)
 127 {
 128         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", GetCallerName(vote_caller), "^2's vote\n");
 129         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid))); }
 130
 131         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 132         if((vote_caller) && (stopper == vote_caller)) { vote_caller.vote_waittime = time + autocvar_sv_vote_stop; }
 133
 134         VoteReset();
 135 }
 136
 137 void VoteAccept()
 138 {
 139         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 140
 141         if((vote_called == VOTE_MASTER) && vote_caller)
 142                 vote_caller.vote_master = 1;
 143         else
 144                 localcmd(strcat(vote_called_command, "\n"));
 145
 146         if(vote_caller) { vote_caller.vote_waittime = 0; } // people like your votes, you don't need to wait to vote again
 147
 148         VoteReset();
 149         Announce("voteaccept");
 150 }
 151
 152 void VoteReject()
 153 {
 154         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 155         VoteReset();
 156         Announce("votefail");
 157 }
 158
 159 void VoteTimeout()
 160 {
 161         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 timed out\n");
 162         VoteReset();
 163         Announce("votefail");
 164 }
 165
 166 void VoteSpam(float notvoters, float mincount, string result)
 167 {
 168         bprint(strcat(
 169                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 170                 strcat("^2:^1", ftos(vote_reject_count)),
 171                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 172                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 173                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? string_null : "have to "), "vote\n"))));
 174
 175         if(autocvar_sv_eventlog)
 176         {
 177                 GameLogEcho(strcat(
 178                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 179                         strcat(":", ftos(vote_reject_count)),
 180                         strcat(":", ftos(vote_abstain_count)),
 181                         strcat(":", ftos(notvoters)),
 182                         strcat(":", ftos(mincount))));
 183         }
 184 }
 185
 186 void VoteCount()
 187 {
 188         // declarations
 189         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 190
 191         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 192                                 || ((autocvar_sv_vote_nospectators == 1) && inWarmupStage)
 193                                 || (autocvar_sv_vote_nospectators == 0));
 194
 195         float vote_player_count, is_player, notvoters;
 196         float vote_real_player_count, vote_real_accept_count;
 197         float vote_real_reject_count, vote_real_abstain_count;
 198         float vote_needed_of_voted, final_needed_votes;
 199         float vote_factor_overall, vote_factor_of_voted;
 200
 201         entity tmp_player;
 202
 203         Nagger_VoteCountChanged();
 204
 205         // add up all the votes from each connected client
 206         FOR_EACH_REALCLIENT(tmp_player)
 207         {
 208                 is_player = (tmp_player.classname == "player");
 209
 210                 ++vote_player_count;
 211                 if(is_player) { ++vote_real_player_count; }
 212
 213                 switch(tmp_player.vote_selection)
 214                 {
 215                         case VOTE_SELECT_REJECT: { ++vote_reject_count; { if(is_player) ++vote_real_reject_count; } break; }
 216                         case VOTE_SELECT_ACCEPT: { ++vote_accept_count; { if(is_player) ++vote_real_reject_count; } break; }
 217                         case VOTE_SELECT_ABSTAIN: { ++vote_abstain_count; { if(is_player) ++vote_real_abstain_count; } break; }
 218                         default: break;
 219                 }
 220         }
 221
 222         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 223         if((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 224         {
 225                 if(vote_caller) { vote_caller.vote_waittime = 0; }
 226                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 227                 VoteReset();
 228                 return;
 229         }
 230
 231         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 232         if(!spectators_allowed && (vote_real_player_count > 0))
 233         {
 234                 vote_accept_count = vote_real_accept_count;
 235                 vote_reject_count = vote_real_reject_count;
 236                 vote_abstain_count = vote_real_abstain_count;
 237                 vote_player_count = vote_real_player_count;
 238         }
 239
 240         // people who have no opinion in any way :D
 241         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 242
 243         // determine the goal for the vote to be passed or rejected normally
 244         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 245         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 246
 247         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 248         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 249         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 250
 251
 252         // finally calculate the result of the vote
 253         if(vote_accept_count >= vote_needed_overall)
 254         {
 255                 VoteSpam(notvoters, -1, "yes"); // there is enough acceptions to pass the vote
 256                 VoteAccept();
 257                 return;
 258         }
 259
 260         if(vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 261         {
 262                 VoteSpam(notvoters, -1, "no"); // there is enough rejections to deny the vote
 263                 VoteReject();
 264                 return;
 265         }
 266
 267         // there is not enough votes in either direction, now lets just calculate what the voters have said
 268         if(time > vote_endtime)
 269         {
 270                 final_needed_votes = vote_needed_overall;
 271
 272                 if(autocvar_sv_vote_majority_factor_of_voted)
 273                 {
 274                         if(vote_accept_count >= vote_needed_of_voted)
 275                         {
 276                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 277                                 VoteAccept();
 278                                 return;
 279                         }
 280
 281                         if(vote_accept_count + vote_reject_count > 0)
 282                         {
 283                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 284                                 VoteReject();
 285                                 return;
 286                         }
 287
 288                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 289                 }
 290
 291                 // it didn't pass or fail, so not enough votes to even make a decision.
 292                 VoteSpam(notvoters, final_needed_votes, "timeout");
 293                 VoteTimeout();
 294         }
 295 }
 296
 297 void VoteThink()
 298 {
 299         if(vote_endtime > 0) // a vote was called
 300         if(time > vote_endtime) // time is up
 301         {
 302                 VoteCount();
 303         }
 304
 305         return;
 306 }
 307
 308
 309 // =======================
 310 //  Game logic for warmup
 311 // =======================
 312
 313 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 314 void ReadyRestart_think()
 315 {
 316         restart_mapalreadyrestarted = 1;
 317         reset_map(TRUE);
 318         Score_ClearAll();
 319         remove(self);
 320
 321         return;
 322 }
 323
 324 // Forces a restart of the game without actually reloading the map // this is a mess...
 325 void ReadyRestart_force()
 326 {
 327         entity tmp_player, restart_timer;
 328
 329         bprint("^1Server is restarting...\n");
 330
 331         VoteReset();
 332
 333         // clear overtime, we have to decrease timelimit to its original value again.
 334         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) { cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime))); }
 335
 336         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 337
 338         readyrestart_happened = 1;
 339         game_starttime = time;
 340         if(!g_ca && !g_arena) { game_starttime += RESTART_COUNTDOWN; }
 341
 342         restart_mapalreadyrestarted = 0; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 343
 344         // disable the warmup global for the server
 345         inWarmupStage = 0; // once the game is restarted the game is in match stage
 346
 347         // reset the .ready status of all players (also spectators)
 348         FOR_EACH_CLIENTSLOT(tmp_player) { tmp_player.ready = 0; }
 349         readycount = 0;
 350         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 351
 352         // lock teams with lockonrestart
 353         if(autocvar_teamplay_lockonrestart && teamplay)
 354         {
 355                 lockteams = 1;
 356                 bprint("^1The teams are now locked.\n");
 357         }
 358
 359         //initiate the restart-countdown-announcer entity
 360         if(autocvar_sv_ready_restart_after_countdown && !g_ca && !g_arena)
 361         {
 362                 restart_timer = spawn();
 363                 restart_timer.think = ReadyRestart_think;
 364                 restart_timer.nextthink = game_starttime;
 365         }
 366
 367         // after a restart every players number of allowed timeouts gets reset, too
 368         if(autocvar_sv_timeout) { FOR_EACH_REALPLAYER(tmp_player) { tmp_player.allowedTimeouts = autocvar_sv_timeout_number; } }
 369
 370         //reset map immediately if this cvar is not set
 371         if not(autocvar_sv_ready_restart_after_countdown) { reset_map(TRUE); }
 372
 373         if(autocvar_sv_eventlog) { GameLogEcho(":restart"); }
 374 }
 375
 376 void ReadyRestart()
 377 {
 378         // no arena, assault support yet...
 379         if(g_arena | g_assault | gameover | intermission_running | race_completing)
 380                 localcmd("restart\n");
 381         else
 382                 localcmd("\nsv_hook_gamerestart\n");
 383
 384         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 385         // Otherwise scores could be manipulated during the countdown.
 386         if not(autocvar_sv_ready_restart_after_countdown) { Score_ClearAll(); }
 387
 388         ReadyRestart_force();
 389
 390         return;
 391 }
 392
 393 // Count the players who are ready and determine whether or not to restart the match
 394 void ReadyCount()
 395 {
 396         entity tmp_player;
 397         float ready_needed_factor, ready_needed_count;
 398         float t_ready, t_players;
 399
 400         FOR_EACH_REALPLAYER(tmp_player)
 401         {
 402                 ++t_players;
 403                 if(tmp_player.ready) { ++t_ready; }
 404         }
 405
 406         readycount = t_ready;
 407
 408         Nagger_ReadyCounted();
 409
 410         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 411         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 412
 413         if(readycount >= ready_needed_count)
 414         {
 415                 ReadyRestart();
 416         }
 417
 418         return;
 419 }
 420
 421
 422 // ======================================
 423 //  Supporting functions for VoteCommand
 424 // ======================================
 425
 426 float Votecommand_check_assignment(entity caller, float assignment)
 427 {
 428         float from_server = (!caller);
 429
 430         if((assignment == VC_ASGNMNT_BOTH)
 431                 || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 432                 || (from_server && assignment == VC_ASGNMNT_SERVERONLY)))
 433         {
 434                 return TRUE;
 435         }
 436
 437         return FALSE;
 438 }
 439
 440 string VoteCommand_extractcommand(string input, float startpos, float argc)
 441 {
 442         string output;
 443
 444         if((argc - 1) < startpos)
 445                 output = "";
 446         else
 447                 output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 448
 449         print("VoteCommand_parse: '", output, "'. \n");
 450         return output;
 451 }
 452
 453 float VoteCommand_checknasty(string vote_command)
 454 {
 455         if((strstrofs(vote_command, ";", 0) >= 0)
 456                 || (strstrofs(vote_command, "\n", 0) >= 0)
 457                 || (strstrofs(vote_command, "\r", 0) >= 0)
 458                 || (strstrofs(vote_command, "$", 0) >= 0))
 459                 return FALSE;
 460
 461         return TRUE;
 462 }
 463
 464 float VoteCommand_checkinlist(string vote_command, string list)
 465 {
 466         string l = strcat(" ", list, " ");
 467
 468         if(strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0)
 469                 return TRUE;
 470
 471         // if gotomap is allowed, chmap is too, and vice versa
 472         if(vote_command == "gotomap")
 473                 if(strstrofs(l, " chmap ", 0) >= 0)
 474                         return TRUE;
 475
 476         if(vote_command == "chmap")
 477                 if(strstrofs(l, " gotomap ", 0) >= 0)
 478                         return TRUE;
 479
 480         return FALSE;
 481 }
 482
 483 string ValidateMap(string validated_map, entity caller)
 484 {
 485         validated_map = MapInfo_FixName(validated_map);
 486
 487         if(!validated_map)
 488         {
 489                 print_to(caller, "This map is not available on this server.");
 490                 return string_null;
 491         }
 492
 493         if(!autocvar_sv_vote_override_mostrecent && caller)
 494         {
 495                 if(Map_IsRecent(validated_map))
 496                 {
 497                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 498                         return string_null;
 499                 }
 500         }
 501
 502         if(!MapInfo_CheckMap(validated_map))
 503         {
 504                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 505                 return string_null;
 506         }
 507
 508         return validated_map;
 509 }
 510
 511 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 512 {
 513         string first_command;
 514         entity victim;
 515
 516         first_command = argv(startpos);
 517
 518         if not(VoteCommand_checkinlist(vote_command, vote_list))
 519                 return FALSE;
 520
 521         if((argc - 1) < startpos) // These commands won't work without arguments
 522         {
 523                 switch(first_command)
 524                 {
 525                         case "map":
 526                         case "chmap":
 527                         case "gotomap":
 528                         case "kick":
 529                         case "kickban":
 530                                 return FALSE;
 531
 532                         default: { break; }
 533                 }
 534         }
 535
 536         switch(first_command) // now go through and parse the proper commands to adjust as needed.
 537         {
 538                 case "kick":
 539                 case "kickban": // catch all kick/kickban commands
 540                 {
 541                         victim = edict_num(GetFilteredNumber(substring(vote_command, argv_start_index(startpos + 1), argv_end_index(-1) - argv_start_index(startpos + 1))));
 542                         if not(victim) { return FALSE; }
 543                         // TODO: figure out how kick/kickban/ban commands work and re-write this to fit around them
 544                         vote_parsed_command = vote_command;
 545                         vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", "todo");
 546
 547                         break;
 548                 }
 549
 550                 case "map":
 551                 case "chmap":
 552                 case "gotomap": // re-direct all map selection commands to gotomap
 553                 {
 554                         vote_command = ValidateMap(substring(vote_command, argv_start_index(startpos + 1), argv_end_index(-1) - argv_start_index(startpos + 1)), caller);
 555                         if not(vote_command) { return FALSE; }
 556                         vote_parsed_command = strcat("gotomap ", vote_command);
 557                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 558
 559                         break;
 560                 }
 561
 562                 default:
 563                 {
 564                         vote_parsed_command = vote_command;
 565                         vote_parsed_display = strzone(strcat("^1", vote_command));
 566
 567                         break;
 568                 }
 569         }
 570
 571         return TRUE;
 572 }
 573
 574
 575 // =======================
 576 //  Command Sub-Functions
 577 // =======================
 578
 579 void VoteCommand_abstain(float request, entity caller) // CLIENT ONLY
 580 {
 581         switch(request)
 582         {
 583                 case CMD_REQUEST_COMMAND:
 584                 {
 585                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 586                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 587
 588                         else // everything went okay, continue changing vote
 589                         {
 590                                 print_to(caller, "^1You abstained from your vote.");
 591                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 592                                 msg_entity = caller;
 593                                 if(!autocvar_sv_vote_singlecount) { VoteCount(); }
 594                         }
 595
 596                         return;
 597                 }
 598
 599                 default:
 600                 case CMD_REQUEST_USAGE:
 601                 {
 602                         print("\nUsage:^3 vote abstain\n");
 603                         print("  No arguments required.\n");
 604                         return;
 605                 }
 606         }
 607 }
 608
 609 void VoteCommand_call(float request, entity caller, float argc, string vote_command) // BOTH
 610 {
 611         switch(request)
 612         {
 613                 case CMD_REQUEST_COMMAND:
 614                 {
 615                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 616                                 || ((autocvar_sv_vote_nospectators == 1) && inWarmupStage)
 617                                 || (autocvar_sv_vote_nospectators == 0));
 618
 619                         float tmp_playercount;
 620                         entity tmp_player;
 621
 622                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 623
 624                         if not(autocvar_sv_vote_call || !caller) { print_to(caller, "^1Vote calling is not allowed."); }
 625                         else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 626                         else if(!spectators_allowed && (caller && (caller.classname != "player"))) { print_to(caller, "^1Only players can call a vote."); }
 627                         else if(timeoutStatus) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 628                         else if(caller && (time < caller.vote_waittime)) { print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote.")); }
 629                         else if not(VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 630                         else if not(VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 631
 632                         else // everything went okay, continue with calling the vote // TODO: fixes to make this more compatible with sv_cmd
 633                         {
 634                                 vote_caller = caller; // remember who called the vote
 635                                 vote_called = VOTE_NORMAL;
 636                                 vote_called_command = strzone(vote_parsed_command);
 637                                 vote_called_display = strzone(vote_parsed_display);
 638                                 vote_endtime = time + autocvar_sv_vote_timeout;
 639
 640                                 if(caller)
 641                                 {
 642                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 643                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 644                                         msg_entity = caller; // todo: what is this for?
 645                                 }
 646
 647                                 FOR_EACH_REALCLIENT(tmp_player) { ++tmp_playercount; }
 648                                 if(tmp_playercount > 1) { Announce("votecall"); } // don't announce a "vote now" sound if player is alone
 649
 650                                 bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote for ", vote_called_display, "\n");
 651                                 if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 652                                 Nagger_VoteChanged();
 653                                 VoteCount(); // needed if you are the only one
 654                         }
 655
 656                         return;
 657                 }
 658
 659                 default:
 660                 case CMD_REQUEST_USAGE:
 661                 {
 662                         print("\nUsage:^3 vote call\n");
 663                         print("  TODO.\n");
 664                         return;
 665                 }
 666         }
 667 }
 668
 669 void VoteCommand_master(float request, entity caller, float argc, string vote_command) // CLIENT ONLY
 670 {
 671         switch(request)
 672         {
 673                 case CMD_REQUEST_COMMAND:
 674                 {
 675                         if(autocvar_sv_vote_master)
 676                         {
 677                                 switch(strtolower(argv(2)))
 678                                 {
 679                                         case "do":
 680                                         {
 681                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 682
 683                                                 if not(caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 684                                                 else if not(VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 685                                                 else if not(VoteCommand_parse(caller, vote_command, autocvar_sv_vote_master_commands, 3, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 686
 687                                                 else // everything went okay, proceed with command
 688                                                 {
 689                                                         localcmd(strcat(vote_parsed_command, "\n"));
 690                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 691                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 692                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 693                                                 }
 694
 695                                                 return;
 696                                         }
 697
 698                                         case "login":
 699                                         {
 700                                                 if not(autocvar_sv_vote_master_password != "") { print_to(caller, "^1Login to vote master is not allowed."); }
 701                                                 else if(caller.vote_master) { print_to(caller, "^1You are already logged in as vote master."); }
 702                                                 else if not(autocvar_sv_vote_master_password == argv(3)) { print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller))); }
 703
 704                                                 else // everything went okay, proceed with giving this player master privilages
 705                                                 {
 706                                                         caller.vote_master = TRUE;
 707                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 708                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 709                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 710                                                 }
 711
 712                                                 return;
 713                                         }
 714
 715                                         default: // calling a vote for master
 716                                         {
 717                                                 if not(autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 718                                                 else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 719
 720                                                 else // everything went okay, continue with creating vote
 721                                                 {
 722                                                         vote_caller = caller;
 723                                                         vote_called = VOTE_MASTER;
 724                                                         vote_called_command = strzone("XXX");
 725                                                         vote_called_display = strzone("^3master");
 726                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 727
 728                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 729                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 730
 731                                                         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote to become ^3master^2.\n");
 732                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 733                                                         Nagger_VoteChanged();
 734                                                         VoteCount(); // needed if you are the only one
 735                                                 }
 736
 737                                                 return;
 738                                         }
 739                                 }
 740                         }
 741                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 742
 743                         return;
 744                 }
 745
 746                 default:
 747                 case CMD_REQUEST_USAGE:
 748                 {
 749                         print("\nUsage:^3 vote master action [arguments]\n");
 750                         print("  TODO.\n");
 751                         return;
 752                 }
 753         }
 754 }
 755
 756 void VoteCommand_no(float request, entity caller) // CLIENT ONLY
 757 {
 758         switch(request)
 759         {
 760                 case CMD_REQUEST_COMMAND:
 761                 {
 762                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 763                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 764
 765                         else // everything went okay, continue changing vote
 766                         {
 767                                 print_to(caller, "^1You rejected the vote.");
 768                                 caller.vote_selection = VOTE_SELECT_REJECT;
 769                                 msg_entity = caller;
 770                                 if(!autocvar_sv_vote_singlecount) { VoteCount(); }
 771                         }
 772
 773                         return;
 774                 }
 775
 776                 default:
 777                 case CMD_REQUEST_USAGE:
 778                 {
 779                         print("\nUsage:^3 vote no\n");
 780                         print("  No arguments required.\n");
 781                         return;
 782                 }
 783         }
 784 }
 785
 786 void VoteCommand_status(float request, entity caller) // BOTH
 787 {
 788         switch(request)
 789         {
 790                 case CMD_REQUEST_COMMAND:
 791                 {
 792                         if(vote_called)
 793                                 print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", GetCallerName(vote_caller), "^7."));
 794                         else
 795                                 print_to(caller, "^1No vote called.");
 796
 797                         return;
 798                 }
 799
 800                 default:
 801                 case CMD_REQUEST_USAGE:
 802                 {
 803                         print("\nUsage:^3 vote status\n");
 804                         print("  No arguments required.\n");
 805                         return;
 806                 }
 807         }
 808 }
 809
 810 void VoteCommand_stop(float request, entity caller) // BOTH
 811 {
 812         switch(request)
 813         {
 814                 case CMD_REQUEST_COMMAND:
 815                 {
 816                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 817                         else if((caller == vote_caller) || !caller || caller.vote_master) { VoteStop(caller); }
 818                         else { print_to(caller, "^1You are not allowed to stop that vote."); }
 819
 820                         return;
 821                 }
 822
 823                 default:
 824                 case CMD_REQUEST_USAGE:
 825                 {
 826                         print("\nUsage:^3 vote stop\n");
 827                         print("  No arguments required.\n");
 828                         return;
 829                 }
 830         }
 831 }
 832
 833 void VoteCommand_yes(float request, entity caller) // CLIENT ONLY
 834 {
 835         switch(request)
 836         {
 837                 case CMD_REQUEST_COMMAND:
 838                 {
 839                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 840                         if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 841
 842                         else // everything went okay, continue changing vote
 843                         {
 844                                 print_to(caller, "^1You accepted the vote.");
 845                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
 846                                 msg_entity = caller;
 847                                 if(!autocvar_sv_vote_singlecount) { VoteCount(); }
 848                         }
 849
 850                         return;
 851                 }
 852
 853                 default:
 854                 case CMD_REQUEST_USAGE:
 855                 {
 856                         print("\nUsage:^3 vote yes\n");
 857                         print("  No arguments required.\n");
 858                         return;
 859                 }
 860         }
 861 }
 862
 863 /* use this when creating a new command, making sure to place it in alphabetical order.
 864 void VoteCommand_(float request)
 865 {
 866         switch(request)
 867         {
 868                 case CMD_REQUEST_COMMAND:
 869                 {
 870
 871                         return;
 872                 }
 873
 874                 default:
 875                 case CMD_REQUEST_USAGE:
 876                 {
 877                         print("\nUsage:^3 vote \n");
 878                         print("  No arguments required.\n");
 879                         return;
 880                 }
 881         }
 882 }
 883 */
 884
 885
 886 // ================================
 887 //  Macro system for vote commands
 888 // ================================
 889
 890 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 891 #define VOTE_COMMANDS(request,caller,arguments,command) \
 892         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
 893         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
 894         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
 895         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "", VC_ASGNMNT_CLIENTONLY) \
 896         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
 897         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
 898         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
 899         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
 900         /* nothing */
 901
 902 void VoteCommand_macro_help(entity caller, float argc)
 903 {
 904         string command_origin = GetCommandPrefix(caller);
 905
 906         if(argc == 2) // help display listing all commands
 907         {
 908                 print("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are:\n");
 909
 910                 #define VOTE_COMMAND(name,function,description,assignment) \
 911                         { if(Votecommand_check_assignment(caller, assignment)) { print("  ^2", name, "^7: ", description, "\n"); } }
 912
 913                 VOTE_COMMANDS(0, caller, 0, "")
 914                 #undef VOTE_COMMAND
 915
 916                 print("For help about specific commands, type ", command_origin, " vote help COMMAND\n");
 917         }
 918         else // usage for individual command
 919         {
 920                 #define VOTE_COMMAND(name,function,description,assignment) \
 921                         { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(2))) { function; return; } } }
 922
 923                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "")
 924                 #undef VOTE_COMMAND
 925         }
 926
 927         return;
 928 }
 929
 930 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
 931 {
 932         #define VOTE_COMMAND(name,function,description,assignment) \
 933                 { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(1))) { function; return TRUE; } } }
 934
 935         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command)
 936         #undef VOTE_COMMAND
 937
 938         return FALSE;
 939 }
 940
 941
 942 // ======================================
 943 //  Main function handling vote commands
 944 // ======================================
 945
 946 void VoteCommand(float request, entity caller, float argc, string vote_command)
 947 {
 948         // Guide for working with argc arguments by example:
 949         // argc:   1    - 2      - 3     - 4
 950         // argv:   0    - 1      - 2     - 3
 951         // cmd     vote - master - login - password
 952
 953         switch(request)
 954         {
 955                 case CMD_REQUEST_COMMAND:
 956                 {
 957                         if(VoteCommand_macro_command(caller, argc, vote_command))
 958                                 return;
 959                 }
 960
 961                 default:
 962                         print_to(caller, strcat("Unknown vote command", ((argv(1) != "") ? strcat(" \"", argv(1), "\"") : ""), ". For a list of supported commands, try ", GetCommandPrefix(caller), " help.\n"));
 963                 case CMD_REQUEST_USAGE:
 964                 {
 965                         VoteCommand_macro_help(caller, argc);
 966                         return;
 967                 }
 968         }
 969 }
 970
 971 // =======================
 972 //  Game logic for voting
 973 // =======================
 974
 975 void VoteHelp(entity e) {
 976         string vmasterdis;
 977         if(!autocvar_sv_vote_master) {
 978                 vmasterdis = " ^1(disabled)";
 979         }
 980
 981         string vlogindis;
 982         if("" == autocvar_sv_vote_master_password) {
 983                 vlogindis = " ^1(disabled)";
 984         }
 985
 986         string vcalldis;
 987         if(!autocvar_sv_vote_call) {
 988                 vcalldis = " ^1(disabled)";
 989         }
 990
 991         print_to(e, "^7You can use voting with \"^2cmd vote help^7\" \"^2cmd vote status^7\" \"^2cmd vote call ^3COMMAND ARGUMENTS^7\" \"^2cmd vote stop^7\" \"^2cmd vote master^7\" \"^2cmd vote login^7\" \"^2cmd vote do ^3COMMAND ARGUMENTS^7\" \"^2cmd vote yes^7\" \"^2cmd vote no^7\" \"^2cmd vote abstain^7\" \"^2cmd vote dontcare^7\".");
 992         print_to(e, "^7Or if your version is up to date you can use these aliases \"^2vhelp^7\" \"^2vstatus^7\" \"^2vcall ^3COMMAND ARGUMENTS^7\" \"^2vstop^7\" \"^2vmaster^7\" \"^2vlogin^7\" \"^2vdo ^3COMMAND ARGUMENTS^7\" \"^2vyes^7\" \"^2vno^7\" \"^2abstain^7\" \"^2vdontcare^7\".");
 993         print_to(e, "^7\"^2help^7\" shows this info.");
 994         print_to(e, "^7\"^2status^7\" shows if there is a vote called and who called it.");
 995         print_to(e, strcat("^7\"^2call^7\" is used to call a vote. See the list of allowed commands.", vcalldis, "^7"));
 996         print_to(e, "^7\"^2stop^7\" can be used by the vote caller or an admin to stop a vote and maybe correct it.");
 997         print_to(e, strcat("^7\"^2master^7\" call a vote to become master who can execute commands without a vote", vmasterdis, "^7"));
 998         print_to(e, strcat("^7\"^2login^7\" login to become master who can execute commands without a vote.", vlogindis, "^7"));
 999         print_to(e, "^7\"^2do^7\" executes a command if you are a master. See the list of allowed commands.");
1000         print_to(e, "^7\"^2yes^7\", \"^2no^7\", \"^2abstain^7\" and \"^2dontcare^7\" to make your vote.");
1001         print_to(e, "^7If enough of the players vote yes the vote is accepted.");
1002         print_to(e, "^7If enough of the players vote no the vote is rejected.");
1003         print_to(e, strcat("^7If neither the vote will timeout after ", ftos(autocvar_sv_vote_timeout), "^7 seconds."));
1004         print_to(e, "^7You can call a vote for or execute these commands:");
1005         print_to(e, strcat("^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1006 }