qcsrc/server/command/vote.qc

   1 // =============================================
   2 //  Server side voting code, reworked by Samual
   3 //  Last updated: December 27th, 2011
   4 // =============================================
   5
   6 //  Nagger for players to know status of voting
   7 float Nagger_SendEntity(entity to, float sendflags)
   8 {
   9         float nags, i, f, b;
  10         entity e;
  11         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
  12
  13         // bits:
  14         //   1 = ready
  15         //   2 = player needs to ready up
  16         //   4 = vote
  17         //   8 = player needs to vote
  18         //  16 = warmup
  19         // sendflags:
  20         //  64 = vote counts
  21         // 128 = vote string
  22
  23         nags = 0;
  24         if(readycount)
  25         {
  26                 nags |= 1;
  27                 if(to.ready == 0)
  28                         nags |= 2;
  29         }
  30         if(vote_called)
  31         {
  32                 nags |= 4;
  33                 if(to.vote_selection == 0)
  34                         nags |= 8;
  35         }
  36         if(inWarmupStage)
  37                 nags |= 16;
  38
  39         if(sendflags & 64)
  40                 nags |= 64;
  41
  42         if(sendflags & 128)
  43                 nags |= 128;
  44
  45         if(!(nags & 4)) // no vote called? send no string
  46                 nags &~= (64 | 128);
  47
  48         WriteByte(MSG_ENTITY, nags);
  49
  50         if(nags & 64)
  51         {
  52                 WriteByte(MSG_ENTITY, vote_accept_count);
  53                 WriteByte(MSG_ENTITY, vote_reject_count);
  54                 WriteByte(MSG_ENTITY, vote_needed_overall);
  55                 WriteChar(MSG_ENTITY, to.vote_selection);
  56         }
  57
  58         if(nags & 128)
  59                 WriteString(MSG_ENTITY, vote_called_display);
  60
  61         if(nags & 1)
  62         {
  63                 for(i = 1; i <= maxclients; i += 8)
  64                 {
  65                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  66                                 if(clienttype(e) != CLIENTTYPE_REAL || e.ready)
  67                                         f |= b;
  68                         WriteByte(MSG_ENTITY, f);
  69                 }
  70         }
  71
  72         return TRUE;
  73 }
  74
  75 void Nagger_Init()
  76 {
  77         Net_LinkEntity(nagger = spawn(), FALSE, 0, Nagger_SendEntity);
  78 }
  79
  80 void Nagger_VoteChanged()
  81 {
  82         if(nagger)
  83                 nagger.SendFlags |= 128;
  84 }
  85
  86 void Nagger_VoteCountChanged()
  87 {
  88         if(nagger)
  89                 nagger.SendFlags |= 64;
  90 }
  91
  92 void Nagger_ReadyCounted()
  93 {
  94         if(nagger)
  95                 nagger.SendFlags |= 1;
  96 }
  97
  98
  99 // =======================
 100 //  Game logic for voting
 101 // =======================
 102
 103 void VoteReset()
 104 {
 105         entity tmp_player;
 106
 107         FOR_EACH_CLIENT(tmp_player) { tmp_player.vote_selection = 0; }
 108
 109         if(vote_called)
 110         {
 111                 strunzone(vote_called_command);
 112                 strunzone(vote_called_display);
 113         }
 114
 115         vote_called = VOTE_NULL;
 116         vote_caller = world;
 117         vote_endtime = 0;
 118
 119         vote_called_command = string_null;
 120         vote_called_display = string_null;
 121
 122         vote_parsed_command = string_null;
 123         vote_parsed_display = string_null;
 124
 125         Nagger_VoteChanged();
 126 }
 127
 128 void VoteStop(entity stopper)
 129 {
 130         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", GetCallerName(vote_caller), "^2's vote\n");
 131         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid))); }
 132
 133         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 134         if((vote_caller) && (stopper == vote_caller)) { vote_caller.vote_waittime = time + autocvar_sv_vote_stop; }
 135
 136         VoteReset();
 137 }
 138
 139 void VoteAccept()
 140 {
 141         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 142
 143         if((vote_called == VOTE_MASTER) && vote_caller)
 144                 vote_caller.vote_master = 1;
 145         else
 146                 localcmd(strcat(vote_called_command, "\n"));
 147
 148         if(vote_caller) { vote_caller.vote_waittime = 0; } // people like your votes, you don't need to wait to vote again
 149
 150         VoteReset();
 151         Announce("voteaccept");
 152 }
 153
 154 void VoteReject()
 155 {
 156         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 157         VoteReset();
 158         Announce("votefail");
 159 }
 160
 161 void VoteTimeout()
 162 {
 163         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 timed out\n");
 164         VoteReset();
 165         Announce("votefail");
 166 }
 167
 168 void VoteSpam(float notvoters, float mincount, string result)
 169 {
 170         bprint(strcat(
 171                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 172                 strcat("^2:^1", ftos(vote_reject_count)),
 173                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 174                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 175                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? string_null : "have to "), "vote\n"))));
 176
 177         if(autocvar_sv_eventlog)
 178         {
 179                 GameLogEcho(strcat(
 180                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 181                         strcat(":", ftos(vote_reject_count)),
 182                         strcat(":", ftos(vote_abstain_count)),
 183                         strcat(":", ftos(notvoters)),
 184                         strcat(":", ftos(mincount))));
 185         }
 186 }
 187
 188 void VoteCount()
 189 {
 190         // declarations
 191         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 192
 193         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 194                                 || ((autocvar_sv_vote_nospectators == 1) && inWarmupStage)
 195                                 || (autocvar_sv_vote_nospectators == 0));
 196
 197         float vote_player_count, is_player, notvoters;
 198         float vote_real_player_count, vote_real_accept_count;
 199         float vote_real_reject_count, vote_real_abstain_count;
 200         float vote_needed_of_voted, final_needed_votes;
 201         float vote_factor_overall, vote_factor_of_voted;
 202
 203         entity tmp_player;
 204
 205         Nagger_VoteCountChanged();
 206
 207         // add up all the votes from each connected client
 208         FOR_EACH_REALCLIENT(tmp_player)
 209         {
 210                 is_player = (tmp_player.classname == "player");
 211
 212                 ++vote_player_count;
 213                 if(is_player) { ++vote_real_player_count; }
 214
 215                 switch(tmp_player.vote_selection)
 216                 {
 217                         case VOTE_SELECT_REJECT: { ++vote_reject_count; { if(is_player) ++vote_real_reject_count; } break; }
 218                         case VOTE_SELECT_ACCEPT: { ++vote_accept_count; { if(is_player) ++vote_real_reject_count; } break; }
 219                         case VOTE_SELECT_ABSTAIN: { ++vote_abstain_count; { if(is_player) ++vote_real_abstain_count; } break; }
 220                         default: break;
 221                 }
 222         }
 223
 224         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 225         if((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 226         {
 227                 if(vote_caller) { vote_caller.vote_waittime = 0; }
 228                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 229                 VoteReset();
 230                 return;
 231         }
 232
 233         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 234         if(!spectators_allowed && (vote_real_player_count > 0))
 235         {
 236                 vote_accept_count = vote_real_accept_count;
 237                 vote_reject_count = vote_real_reject_count;
 238                 vote_abstain_count = vote_real_abstain_count;
 239                 vote_player_count = vote_real_player_count;
 240         }
 241
 242         // people who have no opinion in any way :D
 243         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 244
 245         // determine the goal for the vote to be passed or rejected normally
 246         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 247         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 248
 249         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 250         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 251         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 252
 253
 254         // finally calculate the result of the vote
 255         if(vote_accept_count >= vote_needed_overall)
 256         {
 257                 VoteSpam(notvoters, -1, "yes"); // there is enough acceptions to pass the vote
 258                 VoteAccept();
 259                 return;
 260         }
 261
 262         if(vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 263         {
 264                 VoteSpam(notvoters, -1, "no"); // there is enough rejections to deny the vote
 265                 VoteReject();
 266                 return;
 267         }
 268
 269         // there is not enough votes in either direction, now lets just calculate what the voters have said
 270         if(time > vote_endtime)
 271         {
 272                 final_needed_votes = vote_needed_overall;
 273
 274                 if(autocvar_sv_vote_majority_factor_of_voted)
 275                 {
 276                         if(vote_accept_count >= vote_needed_of_voted)
 277                         {
 278                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 279                                 VoteAccept();
 280                                 return;
 281                         }
 282
 283                         if(vote_accept_count + vote_reject_count > 0)
 284                         {
 285                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 286                                 VoteReject();
 287                                 return;
 288                         }
 289
 290                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 291                 }
 292
 293                 // it didn't pass or fail, so not enough votes to even make a decision.
 294                 VoteSpam(notvoters, final_needed_votes, "timeout");
 295                 VoteTimeout();
 296         }
 297 }
 298
 299 void VoteThink()
 300 {
 301         if(vote_endtime > 0) // a vote was called
 302         if(time > vote_endtime) // time is up
 303         {
 304                 VoteCount();
 305         }
 306
 307         return;
 308 }
 309
 310
 311 // =======================
 312 //  Game logic for warmup
 313 // =======================
 314
 315 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 316 void ReadyRestart_think()
 317 {
 318         restart_mapalreadyrestarted = 1;
 319         reset_map(TRUE);
 320         Score_ClearAll();
 321         remove(self);
 322
 323         return;
 324 }
 325
 326 // Forces a restart of the game without actually reloading the map // this is a mess...
 327 void ReadyRestart_force()
 328 {
 329         entity tmp_player, restart_timer;
 330
 331         bprint("^1Server is restarting...\n");
 332
 333         VoteReset();
 334
 335         // clear overtime, we have to decrease timelimit to its original value again.
 336         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) { cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime))); }
 337
 338         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 339
 340         readyrestart_happened = 1;
 341         game_starttime = time;
 342         if(!g_ca && !g_arena) { game_starttime += RESTART_COUNTDOWN; }
 343
 344         restart_mapalreadyrestarted = 0; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 345
 346         // disable the warmup global for the server
 347         inWarmupStage = 0; // once the game is restarted the game is in match stage
 348
 349         // reset the .ready status of all players (also spectators)
 350         FOR_EACH_CLIENTSLOT(tmp_player) { tmp_player.ready = 0; }
 351         readycount = 0;
 352         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 353
 354         // lock teams with lockonrestart
 355         if(autocvar_teamplay_lockonrestart && teamplay)
 356         {
 357                 lockteams = 1;
 358                 bprint("^1The teams are now locked.\n");
 359         }
 360
 361         //initiate the restart-countdown-announcer entity
 362         if(autocvar_sv_ready_restart_after_countdown && !g_ca && !g_arena)
 363         {
 364                 restart_timer = spawn();
 365                 restart_timer.think = ReadyRestart_think;
 366                 restart_timer.nextthink = game_starttime;
 367         }
 368
 369         // after a restart every players number of allowed timeouts gets reset, too
 370         if(autocvar_sv_timeout) { FOR_EACH_REALPLAYER(tmp_player) { tmp_player.allowed_timeouts = autocvar_sv_timeout_number; } }
 371
 372         //reset map immediately if this cvar is not set
 373         if not(autocvar_sv_ready_restart_after_countdown) { reset_map(TRUE); }
 374
 375         if(autocvar_sv_eventlog) { GameLogEcho(":restart"); }
 376 }
 377
 378 void ReadyRestart()
 379 {
 380         // no arena, assault support yet...
 381         if(g_arena | g_assault | gameover | intermission_running | race_completing)
 382                 localcmd("restart\n");
 383         else
 384                 localcmd("\nsv_hook_gamerestart\n");
 385
 386         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 387         // Otherwise scores could be manipulated during the countdown.
 388         if not(autocvar_sv_ready_restart_after_countdown) { Score_ClearAll(); }
 389
 390         ReadyRestart_force();
 391
 392         return;
 393 }
 394
 395 // Count the players who are ready and determine whether or not to restart the match
 396 void ReadyCount()
 397 {
 398         entity tmp_player;
 399         float ready_needed_factor, ready_needed_count;
 400         float t_ready, t_players;
 401
 402         FOR_EACH_REALPLAYER(tmp_player)
 403         {
 404                 ++t_players;
 405                 if(tmp_player.ready) { ++t_ready; }
 406         }
 407
 408         readycount = t_ready;
 409
 410         Nagger_ReadyCounted();
 411
 412         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 413         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 414
 415         if(readycount >= ready_needed_count)
 416         {
 417                 ReadyRestart();
 418         }
 419
 420         return;
 421 }
 422
 423
 424 // ======================================
 425 //  Supporting functions for VoteCommand
 426 // ======================================
 427
 428 float Votecommand_check_assignment(entity caller, float assignment)
 429 {
 430         float from_server = (!caller);
 431
 432         if((assignment == VC_ASGNMNT_BOTH)
 433                 || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 434                 || (from_server && assignment == VC_ASGNMNT_SERVERONLY)))
 435         {
 436                 return TRUE;
 437         }
 438
 439         return FALSE;
 440 }
 441
 442 string VoteCommand_extractcommand(string input, float startpos, float argc)
 443 {
 444         string output;
 445
 446         if((argc - 1) < startpos)
 447                 output = "";
 448         else
 449                 output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 450
 451         return output;
 452 }
 453
 454 float VoteCommand_checknasty(string vote_command)
 455 {
 456         if((strstrofs(vote_command, ";", 0) >= 0)
 457                 || (strstrofs(vote_command, "\n", 0) >= 0)
 458                 || (strstrofs(vote_command, "\r", 0) >= 0)
 459                 || (strstrofs(vote_command, "$", 0) >= 0))
 460                 return FALSE;
 461
 462         return TRUE;
 463 }
 464
 465 float VoteCommand_checkinlist(string vote_command, string list)
 466 {
 467         string l = strcat(" ", list, " ");
 468
 469         if(strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0)
 470                 return TRUE;
 471
 472         // if gotomap is allowed, chmap is too, and vice versa
 473         if(vote_command == "gotomap")
 474                 if(strstrofs(l, " chmap ", 0) >= 0)
 475                         return TRUE;
 476
 477         if(vote_command == "chmap")
 478                 if(strstrofs(l, " gotomap ", 0) >= 0)
 479                         return TRUE;
 480
 481         return FALSE;
 482 }
 483
 484 string ValidateMap(string validated_map, entity caller)
 485 {
 486         validated_map = MapInfo_FixName(validated_map);
 487
 488         if(!validated_map)
 489         {
 490                 print_to(caller, "This map is not available on this server.");
 491                 return string_null;
 492         }
 493
 494         if(!autocvar_sv_vote_override_mostrecent && caller)
 495         {
 496                 if(Map_IsRecent(validated_map))
 497                 {
 498                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 499                         return string_null;
 500                 }
 501         }
 502
 503         if(!MapInfo_CheckMap(validated_map))
 504         {
 505                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 506                 return string_null;
 507         }
 508
 509         return validated_map;
 510 }
 511
 512 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 513 {
 514         string first_command;
 515         entity victim;
 516
 517         first_command = argv(startpos);
 518
 519         if not(VoteCommand_checkinlist(first_command, vote_list))
 520                 return FALSE;
 521
 522         if(argc < startpos) // These commands won't work without arguments
 523         {
 524                 switch(first_command)
 525                 {
 526                         case "map":
 527                         case "chmap":
 528                         case "gotomap":
 529                         case "kick":
 530                         case "kickban":
 531                                 return FALSE;
 532
 533                         default: { break; }
 534                 }
 535         }
 536
 537         switch(first_command) // now go through and parse the proper commands to adjust as needed.
 538         {
 539                 case "kick":
 540                 case "kickban": // catch all kick/kickban commands
 541                 {
 542                         victim = GetIndexedEntity(argc, (startpos + 1));
 543                         if not(victim) { return FALSE; }
 544                         // TODO: figure out how kick/kickban/ban commands work and re-write this to fit around them
 545                         vote_parsed_command = vote_command;
 546                         vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", "todo");
 547
 548                         break;
 549                 }
 550
 551                 case "map":
 552                 case "chmap":
 553                 case "gotomap": // re-direct all map selection commands to gotomap
 554                 {
 555                         vote_command = ValidateMap(argv(startpos + 1), caller);
 556                         if not(vote_command) { return FALSE; }
 557                         vote_parsed_command = strcat("gotomap ", vote_command);
 558                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 559
 560                         break;
 561                 }
 562
 563                 default:
 564                 {
 565                         vote_parsed_command = vote_command;
 566                         vote_parsed_display = strzone(strcat("^1", vote_command));
 567
 568                         break;
 569                 }
 570         }
 571
 572         return TRUE;
 573 }
 574
 575
 576 // =======================
 577 //  Command Sub-Functions
 578 // =======================
 579
 580 void VoteCommand_abstain(float request, entity caller) // CLIENT ONLY
 581 {
 582         switch(request)
 583         {
 584                 case CMD_REQUEST_COMMAND:
 585                 {
 586                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 587                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 588
 589                         else // everything went okay, continue changing vote
 590                         {
 591                                 print_to(caller, "^1You abstained from your vote.");
 592                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 593                                 msg_entity = caller;
 594                                 if(!autocvar_sv_vote_singlecount) { VoteCount(); }
 595                         }
 596
 597                         return;
 598                 }
 599
 600                 default:
 601                 case CMD_REQUEST_USAGE:
 602                 {
 603                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 604                         print_to(caller, "  No arguments required.");
 605                         return;
 606                 }
 607         }
 608 }
 609
 610 void VoteCommand_call(float request, entity caller, float argc, string vote_command) // BOTH
 611 {
 612         switch(request)
 613         {
 614                 case CMD_REQUEST_COMMAND:
 615                 {
 616                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 617                                 || ((autocvar_sv_vote_nospectators == 1) && inWarmupStage)
 618                                 || (autocvar_sv_vote_nospectators == 0));
 619
 620                         float tmp_playercount;
 621                         entity tmp_player;
 622
 623                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 624
 625                         if not(autocvar_sv_vote_call || !caller) { print_to(caller, "^1Vote calling is not allowed."); }
 626                         else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 627                         else if(!spectators_allowed && (caller && (caller.classname != "player"))) { print_to(caller, "^1Only players can call a vote."); }
 628                         else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 629                         else if(caller && (time < caller.vote_waittime)) { print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote.")); }
 630                         else if not(VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 631                         else if not(VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 632
 633                         else // everything went okay, continue with calling the vote
 634                         {
 635                                 vote_caller = caller; // remember who called the vote
 636                                 vote_called = VOTE_NORMAL;
 637                                 vote_called_command = strzone(vote_parsed_command);
 638                                 vote_called_display = strzone(vote_parsed_display);
 639                                 vote_endtime = time + autocvar_sv_vote_timeout;
 640
 641                                 if(caller)
 642                                 {
 643                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 644                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 645                                         msg_entity = caller;
 646                                 }
 647
 648                                 FOR_EACH_REALCLIENT(tmp_player) { ++tmp_playercount; }
 649                                 if(tmp_playercount > 1) { Announce("votecall"); } // don't announce a "vote now" sound if player is alone
 650
 651                                 bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote for ", vote_called_display, "\n");
 652                                 if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 653                                 Nagger_VoteChanged();
 654                                 VoteCount(); // needed if you are the only one
 655                         }
 656
 657                         return;
 658                 }
 659
 660                 default:
 661                 case CMD_REQUEST_USAGE:
 662                 {
 663                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 664                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 665                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 666                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 667                         return;
 668                 }
 669         }
 670 }
 671
 672 void VoteCommand_master(float request, entity caller, float argc, string vote_command) // CLIENT ONLY
 673 {
 674         switch(request)
 675         {
 676                 case CMD_REQUEST_COMMAND:
 677                 {
 678                         if(autocvar_sv_vote_master)
 679                         {
 680                                 switch(strtolower(argv(2)))
 681                                 {
 682                                         case "do":
 683                                         {
 684                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 685
 686                                                 if not(caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 687                                                 else if not(VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 688                                                 else if not(VoteCommand_parse(caller, vote_command, autocvar_sv_vote_master_commands, 3, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 689
 690                                                 else // everything went okay, proceed with command
 691                                                 {
 692                                                         localcmd(strcat(vote_parsed_command, "\n"));
 693                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 694                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 695                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 696                                                 }
 697
 698                                                 return;
 699                                         }
 700
 701                                         case "login":
 702                                         {
 703                                                 if not(autocvar_sv_vote_master_password != "") { print_to(caller, "^1Login to vote master is not allowed."); }
 704                                                 else if(caller.vote_master) { print_to(caller, "^1You are already logged in as vote master."); }
 705                                                 else if not(autocvar_sv_vote_master_password == argv(3)) { print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller))); }
 706
 707                                                 else // everything went okay, proceed with giving this player master privilages
 708                                                 {
 709                                                         caller.vote_master = TRUE;
 710                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 711                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 712                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 713                                                 }
 714
 715                                                 return;
 716                                         }
 717
 718                                         default: // calling a vote for master
 719                                         {
 720                                                 if not(autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 721                                                 else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 722                                                 else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 723
 724                                                 else // everything went okay, continue with creating vote
 725                                                 {
 726                                                         vote_caller = caller;
 727                                                         vote_called = VOTE_MASTER;
 728                                                         vote_called_command = strzone("XXX");
 729                                                         vote_called_display = strzone("^3master");
 730                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 731
 732                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 733                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 734
 735                                                         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote to become ^3master^2.\n");
 736                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 737                                                         Nagger_VoteChanged();
 738                                                         VoteCount(); // needed if you are the only one
 739                                                 }
 740
 741                                                 return;
 742                                         }
 743                                 }
 744                         }
 745                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 746
 747                         return;
 748                 }
 749
 750                 default:
 751                 case CMD_REQUEST_USAGE:
 752                 {
 753                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 754                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 755                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 756                         return;
 757                 }
 758         }
 759 }
 760
 761 void VoteCommand_no(float request, entity caller) // CLIENT ONLY
 762 {
 763         switch(request)
 764         {
 765                 case CMD_REQUEST_COMMAND:
 766                 {
 767                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 768                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 769                         else if(((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote) { VoteStop(caller); }
 770
 771                         else // everything went okay, continue changing vote
 772                         {
 773                                 print_to(caller, "^1You rejected the vote.");
 774                                 caller.vote_selection = VOTE_SELECT_REJECT;
 775                                 msg_entity = caller;
 776                                 if(!autocvar_sv_vote_singlecount) { VoteCount(); }
 777                         }
 778
 779                         return;
 780                 }
 781
 782                 default:
 783                 case CMD_REQUEST_USAGE:
 784                 {
 785                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
 786                         print_to(caller, "  No arguments required.");
 787                         return;
 788                 }
 789         }
 790 }
 791
 792 void VoteCommand_status(float request, entity caller) // BOTH
 793 {
 794         switch(request)
 795         {
 796                 case CMD_REQUEST_COMMAND:
 797                 {
 798                         if(vote_called)
 799                                 print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", GetCallerName(vote_caller), "^7."));
 800                         else
 801                                 print_to(caller, "^1No vote called.");
 802
 803                         return;
 804                 }
 805
 806                 default:
 807                 case CMD_REQUEST_USAGE:
 808                 {
 809                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
 810                         print_to(caller, "  No arguments required.");
 811                         return;
 812                 }
 813         }
 814 }
 815
 816 void VoteCommand_stop(float request, entity caller) // BOTH
 817 {
 818         switch(request)
 819         {
 820                 case CMD_REQUEST_COMMAND:
 821                 {
 822                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 823                         else if((caller == vote_caller) || !caller || caller.vote_master) { VoteStop(caller); }
 824                         else { print_to(caller, "^1You are not allowed to stop that vote."); }
 825
 826                         return;
 827                 }
 828
 829                 default:
 830                 case CMD_REQUEST_USAGE:
 831                 {
 832                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
 833                         print_to(caller, "  No arguments required.");
 834                         return;
 835                 }
 836         }
 837 }
 838
 839 void VoteCommand_yes(float request, entity caller) // CLIENT ONLY
 840 {
 841         switch(request)
 842         {
 843                 case CMD_REQUEST_COMMAND:
 844                 {
 845                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 846                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 847
 848                         else // everything went okay, continue changing vote
 849                         {
 850                                 print_to(caller, "^1You accepted the vote.");
 851                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
 852                                 msg_entity = caller;
 853                                 if(!autocvar_sv_vote_singlecount) { VoteCount(); }
 854                         }
 855
 856                         return;
 857                 }
 858
 859                 default:
 860                 case CMD_REQUEST_USAGE:
 861                 {
 862                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
 863                         print_to(caller, "  No arguments required.");
 864                         return;
 865                 }
 866         }
 867 }
 868
 869 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 870 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 871 void VoteCommand_(float request)
 872 {
 873         switch(request)
 874         {
 875                 case CMD_REQUEST_COMMAND:
 876                 {
 877
 878                         return;
 879                 }
 880
 881                 default:
 882                 case CMD_REQUEST_USAGE:
 883                 {
 884                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
 885                         print_to(caller, "  No arguments required.");
 886                         return;
 887                 }
 888         }
 889 }
 890 */
 891
 892
 893 // ================================
 894 //  Macro system for vote commands
 895 // ================================
 896
 897 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 898 #define VOTE_COMMANDS(request,caller,arguments,command) \
 899         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
 900         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
 901         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
 902         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "TODO", VC_ASGNMNT_CLIENTONLY) \
 903         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
 904         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
 905         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
 906         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
 907         /* nothing */
 908
 909 void VoteCommand_macro_help(entity caller, float argc)
 910 {
 911         string command_origin = GetCommandPrefix(caller);
 912
 913         if(argc == 2) // help display listing all commands
 914         {
 915                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are:"));
 916
 917                 #define VOTE_COMMAND(name,function,description,assignment) \
 918                         { if(Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
 919
 920                 VOTE_COMMANDS(0, caller, 0, "")
 921                 #undef VOTE_COMMAND
 922
 923                 print_to(caller, strcat("For help about specific commands, type ", command_origin, " vote help COMMAND"));
 924                 print_to(caller, "^7You can call a vote for or execute these commands:");
 925                 print_to(caller, strcat("^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 926         }
 927         else // usage for individual command
 928         {
 929                 #define VOTE_COMMAND(name,function,description,assignment) \
 930                         { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(2))) { function; return; } } }
 931
 932                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "")
 933                 #undef VOTE_COMMAND
 934         }
 935
 936         return;
 937 }
 938
 939 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
 940 {
 941         #define VOTE_COMMAND(name,function,description,assignment) \
 942                 { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(1))) { function; return TRUE; } } }
 943
 944         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command)
 945         #undef VOTE_COMMAND
 946
 947         return FALSE;
 948 }
 949
 950
 951 // ======================================
 952 //  Main function handling vote commands
 953 // ======================================
 954
 955 void VoteCommand(float request, entity caller, float argc, string vote_command)
 956 {
 957         // Guide for working with argc arguments by example:
 958         // argc:   1    - 2      - 3     - 4
 959         // argv:   0    - 1      - 2     - 3
 960         // cmd     vote - master - login - password
 961
 962         switch(request)
 963         {
 964                 case CMD_REQUEST_COMMAND:
 965                 {
 966                         if(VoteCommand_macro_command(caller, argc, vote_command))
 967                                 return;
 968                 }
 969
 970                 default:
 971                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
 972                 case CMD_REQUEST_USAGE:
 973                 {
 974                         VoteCommand_macro_help(caller, argc);
 975                         return;
 976                 }
 977         }
 978 }