qcsrc/server/command/vote.qc

   1 // =============================================
   2 //  Server side voting code, reworked by Samual
   3 //  Last updated: December 27th, 2011
   4 // =============================================
   5
   6 //  Nagger for players to know status of voting
   7 float Nagger_SendEntity(entity to, float sendflags)
   8 {
   9         float nags, i, f, b;
  10         entity e;
  11         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
  12
  13         // bits:
  14         //   1 = ready
  15         //   2 = player needs to ready up
  16         //   4 = vote
  17         //   8 = player needs to vote
  18         //  16 = warmup
  19         // sendflags:
  20         //  64 = vote counts
  21         // 128 = vote string
  22
  23         nags = 0;
  24         if(readycount)
  25         {
  26                 nags |= 1;
  27                 if(to.ready == 0)
  28                         nags |= 2;
  29         }
  30         if(vote_called)
  31         {
  32                 nags |= 4;
  33                 if(to.vote_selection == 0)
  34                         nags |= 8;
  35         }
  36         if(inWarmupStage)
  37                 nags |= 16;
  38
  39         if(sendflags & 64)
  40                 nags |= 64;
  41
  42         if(sendflags & 128)
  43                 nags |= 128;
  44
  45         if(!(nags & 4)) // no vote called? send no string
  46                 nags &~= (64 | 128);
  47
  48         WriteByte(MSG_ENTITY, nags);
  49
  50         if(nags & 64)
  51         {
  52                 WriteByte(MSG_ENTITY, vote_accept_count);
  53                 WriteByte(MSG_ENTITY, vote_reject_count);
  54                 WriteByte(MSG_ENTITY, vote_needed_overall);
  55                 WriteChar(MSG_ENTITY, to.vote_selection);
  56         }
  57
  58         if(nags & 128)
  59                 WriteString(MSG_ENTITY, vote_called_display);
  60
  61         if(nags & 1)
  62         {
  63                 for(i = 1; i <= maxclients; i += 8)
  64                 {
  65                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  66                                 if(clienttype(e) != CLIENTTYPE_REAL || e.ready)
  67                                         f |= b;
  68                         WriteByte(MSG_ENTITY, f);
  69                 }
  70         }
  71
  72         return TRUE;
  73 }
  74
  75 void Nagger_Init()
  76 {
  77         Net_LinkEntity(nagger = spawn(), FALSE, 0, Nagger_SendEntity);
  78 }
  79
  80 void Nagger_VoteChanged()
  81 {
  82         if(nagger)
  83                 nagger.SendFlags |= 128;
  84 }
  85
  86 void Nagger_VoteCountChanged()
  87 {
  88         if(nagger)
  89                 nagger.SendFlags |= 64;
  90 }
  91
  92 void Nagger_ReadyCounted()
  93 {
  94         if(nagger)
  95                 nagger.SendFlags |= 1;
  96 }
  97
  98
  99 // =======================
 100 //  Game logic for voting
 101 // =======================
 102
 103 void VoteReset()
 104 {
 105         entity tmp_player;
 106
 107         FOR_EACH_CLIENT(tmp_player) { tmp_player.vote_selection = 0; }
 108
 109         if(vote_called)
 110         {
 111                 strunzone(vote_called_command);
 112                 strunzone(vote_called_display);
 113         }
 114
 115         vote_called = VOTE_NULL;
 116         vote_caller = world;
 117         vote_endtime = 0;
 118
 119         vote_called_command = string_null;
 120         vote_called_display = string_null;
 121
 122         vote_parsed_command = string_null;
 123         vote_parsed_display = string_null;
 124
 125         Nagger_VoteChanged();
 126 }
 127
 128 void VoteStop(entity stopper)
 129 {
 130         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", GetCallerName(vote_caller), "^2's vote\n");
 131         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid))); }
 132
 133         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 134         if((vote_caller) && (stopper == vote_caller)) { vote_caller.vote_waittime = time + autocvar_sv_vote_stop; }
 135
 136         VoteReset();
 137 }
 138
 139 void VoteAccept()
 140 {
 141         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 142
 143         if((vote_called == VOTE_MASTER) && vote_caller)
 144                 vote_caller.vote_master = 1;
 145         else
 146                 localcmd(strcat(vote_called_command, "\n"));
 147
 148         if(vote_caller) { vote_caller.vote_waittime = 0; } // people like your votes, you don't need to wait to vote again
 149
 150         VoteReset();
 151         Announce("voteaccept");
 152 }
 153
 154 void VoteReject()
 155 {
 156         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 157         VoteReset();
 158         Announce("votefail");
 159 }
 160
 161 void VoteTimeout()
 162 {
 163         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 timed out\n");
 164         VoteReset();
 165         Announce("votefail");
 166 }
 167
 168 void VoteSpam(float notvoters, float mincount, string result)
 169 {
 170         bprint(strcat(
 171                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 172                 strcat("^2:^1", ftos(vote_reject_count)),
 173                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 174                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 175                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? string_null : "have to "), "vote\n"))));
 176
 177         if(autocvar_sv_eventlog)
 178         {
 179                 GameLogEcho(strcat(
 180                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 181                         strcat(":", ftos(vote_reject_count)),
 182                         strcat(":", ftos(vote_abstain_count)),
 183                         strcat(":", ftos(notvoters)),
 184                         strcat(":", ftos(mincount))));
 185         }
 186 }
 187
 188 void VoteCount(float first_count)
 189 {
 190         // declarations
 191         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 192
 193         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 194                                 || ((autocvar_sv_vote_nospectators == 1) && (inWarmupStage || gameover))
 195                                 || (autocvar_sv_vote_nospectators == 0));
 196
 197         float vote_player_count = 0, is_player, notvoters = 0;
 198         float vote_real_player_count = 0, vote_real_accept_count = 0;
 199         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 200         float vote_needed_of_voted, final_needed_votes;
 201         float vote_factor_overall, vote_factor_of_voted;
 202
 203         entity tmp_player;
 204
 205         Nagger_VoteCountChanged();
 206
 207         // add up all the votes from each connected client
 208         FOR_EACH_REALCLIENT(tmp_player)
 209         {
 210                 is_player = (tmp_player.classname == "player");
 211
 212                 ++vote_player_count;
 213                 if(is_player) { ++vote_real_player_count; }
 214
 215                 switch(tmp_player.vote_selection)
 216                 {
 217                         case VOTE_SELECT_REJECT: { ++vote_reject_count; { if(is_player) ++vote_real_reject_count; } break; }
 218                         case VOTE_SELECT_ACCEPT: { ++vote_accept_count; { if(is_player) ++vote_real_reject_count; } break; }
 219                         case VOTE_SELECT_ABSTAIN: { ++vote_abstain_count; { if(is_player) ++vote_real_abstain_count; } break; }
 220                         default: break;
 221                 }
 222         }
 223
 224         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 225         if((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 226         {
 227                 if(vote_caller) { vote_caller.vote_waittime = 0; }
 228                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 229                 VoteReset();
 230                 return;
 231         }
 232
 233         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 234         if(!spectators_allowed && (vote_real_player_count > 0))
 235         {
 236                 vote_accept_count = vote_real_accept_count;
 237                 vote_reject_count = vote_real_reject_count;
 238                 vote_abstain_count = vote_real_abstain_count;
 239                 vote_player_count = vote_real_player_count;
 240         }
 241
 242         // people who have no opinion in any way :D
 243         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 244
 245         // determine the goal for the vote to be passed or rejected normally
 246         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 247         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 248
 249         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 250         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 251         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 252
 253         // are there any players at all on the server? it could be an admin vote
 254         if(vote_player_count == 0 && first_count)
 255         {
 256                 VoteSpam(0, -1, "yes"); // no players at all, just accept it
 257                 VoteAccept();
 258                 return;
 259         }
 260
 261         // since there ARE players, finally calculate the result of the vote
 262         if(vote_accept_count >= vote_needed_overall)
 263         {
 264                 VoteSpam(notvoters, -1, "yes"); // there is enough acceptions to pass the vote
 265                 VoteAccept();
 266                 return;
 267         }
 268
 269         if(vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 270         {
 271                 VoteSpam(notvoters, -1, "no"); // there is enough rejections to deny the vote
 272                 VoteReject();
 273                 return;
 274         }
 275
 276         // there is not enough votes in either direction, now lets just calculate what the voters have said
 277         if(time > vote_endtime)
 278         {
 279                 final_needed_votes = vote_needed_overall;
 280
 281                 if(autocvar_sv_vote_majority_factor_of_voted)
 282                 {
 283                         if(vote_accept_count >= vote_needed_of_voted)
 284                         {
 285                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 286                                 VoteAccept();
 287                                 return;
 288                         }
 289
 290                         if(vote_accept_count + vote_reject_count > 0)
 291                         {
 292                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 293                                 VoteReject();
 294                                 return;
 295                         }
 296
 297                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 298                 }
 299
 300                 // it didn't pass or fail, so not enough votes to even make a decision.
 301                 VoteSpam(notvoters, final_needed_votes, "timeout");
 302                 VoteTimeout();
 303         }
 304 }
 305
 306 void VoteThink()
 307 {
 308         if(vote_endtime > 0) // a vote was called
 309         if(time > vote_endtime) // time is up
 310         {
 311                 VoteCount(FALSE);
 312         }
 313
 314         return;
 315 }
 316
 317
 318 // =======================
 319 //  Game logic for warmup
 320 // =======================
 321
 322 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 323 void ReadyRestart_think()
 324 {
 325         restart_mapalreadyrestarted = 1;
 326         reset_map(TRUE);
 327         Score_ClearAll();
 328         remove(self);
 329
 330         return;
 331 }
 332
 333 // Forces a restart of the game without actually reloading the map // this is a mess...
 334 void ReadyRestart_force()
 335 {
 336         entity tmp_player, restart_timer;
 337
 338         bprint("^1Server is restarting...\n");
 339
 340         VoteReset();
 341
 342         // clear overtime, we have to decrease timelimit to its original value again.
 343         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) { cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime))); }
 344
 345         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 346
 347         readyrestart_happened = 1;
 348         game_starttime = time;
 349         if(!g_ca && !g_arena) { game_starttime += RESTART_COUNTDOWN; }
 350
 351         restart_mapalreadyrestarted = 0; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 352
 353         // disable the warmup global for the server
 354         inWarmupStage = 0; // once the game is restarted the game is in match stage
 355
 356         // reset the .ready status of all players (also spectators)
 357         FOR_EACH_CLIENTSLOT(tmp_player) { tmp_player.ready = 0; }
 358         readycount = 0;
 359         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 360
 361         // lock teams with lockonrestart
 362         if(autocvar_teamplay_lockonrestart && teamplay)
 363         {
 364                 lockteams = 1;
 365                 bprint("^1The teams are now locked.\n");
 366         }
 367
 368         //initiate the restart-countdown-announcer entity
 369         if(autocvar_sv_ready_restart_after_countdown && !g_ca && !g_arena)
 370         {
 371                 restart_timer = spawn();
 372                 restart_timer.think = ReadyRestart_think;
 373                 restart_timer.nextthink = game_starttime;
 374         }
 375
 376         // after a restart every players number of allowed timeouts gets reset, too
 377         if(autocvar_sv_timeout) { FOR_EACH_REALPLAYER(tmp_player) { tmp_player.allowed_timeouts = autocvar_sv_timeout_number; } }
 378
 379         //reset map immediately if this cvar is not set
 380         if not(autocvar_sv_ready_restart_after_countdown) { reset_map(TRUE); }
 381
 382         if(autocvar_sv_eventlog) { GameLogEcho(":restart"); }
 383 }
 384
 385 void ReadyRestart()
 386 {
 387         // no arena, assault support yet...
 388         if(g_arena | g_assault | gameover | intermission_running | race_completing)
 389                 localcmd("restart\n");
 390         else
 391                 localcmd("\nsv_hook_gamerestart\n");
 392
 393         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 394         // Otherwise scores could be manipulated during the countdown.
 395         if not(autocvar_sv_ready_restart_after_countdown) { Score_ClearAll(); }
 396
 397         ReadyRestart_force();
 398
 399         return;
 400 }
 401
 402 // Count the players who are ready and determine whether or not to restart the match
 403 void ReadyCount()
 404 {
 405         entity tmp_player;
 406         float ready_needed_factor, ready_needed_count;
 407         float t_ready = 0, t_players = 0;
 408
 409         FOR_EACH_REALPLAYER(tmp_player)
 410         {
 411                 ++t_players;
 412                 if(tmp_player.ready) { ++t_ready; }
 413         }
 414
 415         readycount = t_ready;
 416
 417         Nagger_ReadyCounted();
 418
 419         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 420         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 421
 422         if(readycount >= ready_needed_count)
 423         {
 424                 ReadyRestart();
 425         }
 426
 427         return;
 428 }
 429
 430
 431 // ======================================
 432 //  Supporting functions for VoteCommand
 433 // ======================================
 434
 435 float Votecommand_check_assignment(entity caller, float assignment)
 436 {
 437         float from_server = (!caller);
 438
 439         if((assignment == VC_ASGNMNT_BOTH)
 440                 || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 441                 || (from_server && assignment == VC_ASGNMNT_SERVERONLY)))
 442         {
 443                 return TRUE;
 444         }
 445
 446         return FALSE;
 447 }
 448
 449 string VoteCommand_extractcommand(string input, float startpos, float argc)
 450 {
 451         string output;
 452
 453         if((argc - 1) < startpos)
 454                 output = "";
 455         else
 456                 output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 457
 458         return output;
 459 }
 460
 461 float VoteCommand_checknasty(string vote_command)
 462 {
 463         if((strstrofs(vote_command, ";", 0) >= 0)
 464                 || (strstrofs(vote_command, "\n", 0) >= 0)
 465                 || (strstrofs(vote_command, "\r", 0) >= 0)
 466                 || (strstrofs(vote_command, "$", 0) >= 0))
 467                 return FALSE;
 468
 469         return TRUE;
 470 }
 471
 472 float VoteCommand_checkinlist(string vote_command, string list)
 473 {
 474         string l = strcat(" ", list, " ");
 475
 476         if(strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0)
 477                 return TRUE;
 478
 479         return FALSE;
 480 }
 481
 482 string ValidateMap(string validated_map, entity caller)
 483 {
 484         validated_map = MapInfo_FixName(validated_map);
 485
 486         if(!validated_map)
 487         {
 488                 print_to(caller, "This map is not available on this server.");
 489                 return string_null;
 490         }
 491
 492         if(!autocvar_sv_vote_override_mostrecent && caller)
 493         {
 494                 if(Map_IsRecent(validated_map))
 495                 {
 496                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 497                         return string_null;
 498                 }
 499         }
 500
 501         if(!MapInfo_CheckMap(validated_map))
 502         {
 503                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 504                 return string_null;
 505         }
 506
 507         return validated_map;
 508 }
 509
 510 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 511 {
 512         string first_command;
 513
 514         first_command = argv(startpos);
 515
 516         if not(VoteCommand_checkinlist(first_command, vote_list))
 517                 return FALSE;
 518
 519         if(argc < startpos) // These commands won't work without arguments
 520         {
 521                 switch(first_command)
 522                 {
 523                         case "map":
 524                         case "chmap":
 525                         case "gotomap":
 526                         case "kick":
 527                         case "kickban":
 528                                 return FALSE;
 529
 530                         default: { break; }
 531                 }
 532         }
 533
 534         switch(first_command) // now go through and parse the proper commands to adjust as needed.
 535         {
 536                 case "kick":
 537                 case "kickban": // catch all kick/kickban commands
 538                 {
 539                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 540                         float accepted = VerifyClientEntity(victim, TRUE, FALSE);
 541
 542                         if(accepted > 0)
 543                         {
 544                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)) : "No reason provided");
 545                                 string command_arguments;
 546
 547                                 if(first_command == "kickban")
 548                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 549                                 else
 550                                         command_arguments = reason;
 551
 552                                 vote_parsed_command = strcat(first_command, " # ", ftos(num_for_edict(victim)), " ", command_arguments);
 553                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 554                         }
 555                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return FALSE; }
 556
 557                         break;
 558                 }
 559
 560                 case "map":
 561                 case "chmap":
 562                 case "gotomap": // re-direct all map selection commands to gotomap
 563                 {
 564                         vote_command = ValidateMap(argv(startpos + 1), caller);
 565                         if not(vote_command) { return FALSE; }
 566                         vote_parsed_command = strcat("gotomap ", vote_command);
 567                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 568
 569                         break;
 570                 }
 571
 572                 default:
 573                 {
 574                         vote_parsed_command = vote_command;
 575                         vote_parsed_display = strzone(strcat("^1", vote_command));
 576
 577                         break;
 578                 }
 579         }
 580
 581         return TRUE;
 582 }
 583
 584
 585 // =======================
 586 //  Command Sub-Functions
 587 // =======================
 588
 589 void VoteCommand_abstain(float request, entity caller) // CLIENT ONLY
 590 {
 591         switch(request)
 592         {
 593                 case CMD_REQUEST_COMMAND:
 594                 {
 595                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 596                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 597
 598                         else // everything went okay, continue changing vote
 599                         {
 600                                 print_to(caller, "^1You abstained from your vote.");
 601                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 602                                 msg_entity = caller;
 603                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
 604                         }
 605
 606                         return;
 607                 }
 608
 609                 default:
 610                 case CMD_REQUEST_USAGE:
 611                 {
 612                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 613                         print_to(caller, "  No arguments required.");
 614                         return;
 615                 }
 616         }
 617 }
 618
 619 void VoteCommand_call(float request, entity caller, float argc, string vote_command) // BOTH
 620 {
 621         switch(request)
 622         {
 623                 case CMD_REQUEST_COMMAND:
 624                 {
 625                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 626                                 || ((autocvar_sv_vote_nospectators == 1) && inWarmupStage)
 627                                 || (autocvar_sv_vote_nospectators == 0));
 628
 629                         float tmp_playercount = 0;
 630                         entity tmp_player;
 631
 632                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 633
 634                         if not(autocvar_sv_vote_call || !caller) { print_to(caller, "^1Vote calling is not allowed."); }
 635                         else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 636                         else if(!spectators_allowed && (caller && (caller.classname != "player"))) { print_to(caller, "^1Only players can call a vote."); }
 637                         else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 638                         else if(caller && (time < caller.vote_waittime)) { print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote.")); }
 639                         else if not(VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 640                         else if not(VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 641
 642                         else // everything went okay, continue with calling the vote
 643                         {
 644                                 vote_caller = caller; // remember who called the vote
 645                                 vote_called = VOTE_NORMAL;
 646                                 vote_called_command = strzone(vote_parsed_command);
 647                                 vote_called_display = strzone(vote_parsed_display);
 648                                 vote_endtime = time + autocvar_sv_vote_timeout;
 649
 650                                 if(caller)
 651                                 {
 652                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 653                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 654                                         msg_entity = caller;
 655                                 }
 656
 657                                 FOR_EACH_REALCLIENT(tmp_player) { ++tmp_playercount; }
 658                                 if(tmp_playercount > 1) { Announce("votecall"); } // don't announce a "vote now" sound if player is alone
 659
 660                                 bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote for ", vote_called_display, "\n");
 661                                 if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 662                                 Nagger_VoteChanged();
 663                                 VoteCount(TRUE); // needed if you are the only one
 664                         }
 665
 666                         return;
 667                 }
 668
 669                 default:
 670                 case CMD_REQUEST_USAGE:
 671                 {
 672                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 673                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 674                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 675                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 676                         return;
 677                 }
 678         }
 679 }
 680
 681 void VoteCommand_master(float request, entity caller, float argc, string vote_command) // CLIENT ONLY
 682 {
 683         switch(request)
 684         {
 685                 case CMD_REQUEST_COMMAND:
 686                 {
 687                         if(autocvar_sv_vote_master)
 688                         {
 689                                 switch(strtolower(argv(2)))
 690                                 {
 691                                         case "do":
 692                                         {
 693                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 694
 695                                                 if not(caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 696                                                 else if not(VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 697                                                 else if not(VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 698
 699                                                 else // everything went okay, proceed with command
 700                                                 {
 701                                                         localcmd(strcat(vote_parsed_command, "\n"));
 702                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 703                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 704                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 705                                                 }
 706
 707                                                 return;
 708                                         }
 709
 710                                         case "login":
 711                                         {
 712                                                 if not(autocvar_sv_vote_master_password != "") { print_to(caller, "^1Login to vote master is not allowed."); }
 713                                                 else if(caller.vote_master) { print_to(caller, "^1You are already logged in as vote master."); }
 714                                                 else if not(autocvar_sv_vote_master_password == argv(3)) { print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller))); }
 715
 716                                                 else // everything went okay, proceed with giving this player master privilages
 717                                                 {
 718                                                         caller.vote_master = TRUE;
 719                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 720                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 721                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 722                                                 }
 723
 724                                                 return;
 725                                         }
 726
 727                                         default: // calling a vote for master
 728                                         {
 729                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 730                                                         || ((autocvar_sv_vote_nospectators == 1) && inWarmupStage)
 731                                                         || (autocvar_sv_vote_nospectators == 0));
 732
 733                                                 if not(autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 734                                                 else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 735                                                 else if(!spectators_allowed && (caller && (caller.classname != "player"))) { print_to(caller, "^1Only players can call a vote."); }
 736                                                 else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 737
 738                                                 else // everything went okay, continue with creating vote
 739                                                 {
 740                                                         vote_caller = caller;
 741                                                         vote_called = VOTE_MASTER;
 742                                                         vote_called_command = strzone("XXX");
 743                                                         vote_called_display = strzone("^3master");
 744                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 745
 746                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 747                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 748
 749                                                         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote to become ^3master^2.\n");
 750                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 751                                                         Nagger_VoteChanged();
 752                                                         VoteCount(TRUE); // needed if you are the only one
 753                                                 }
 754
 755                                                 return;
 756                                         }
 757                                 }
 758                         }
 759                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 760
 761                         return;
 762                 }
 763
 764                 default:
 765                 case CMD_REQUEST_USAGE:
 766                 {
 767                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 768                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 769                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 770                         return;
 771                 }
 772         }
 773 }
 774
 775 void VoteCommand_no(float request, entity caller) // CLIENT ONLY
 776 {
 777         switch(request)
 778         {
 779                 case CMD_REQUEST_COMMAND:
 780                 {
 781                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 782                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 783                         else if(((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote) { VoteStop(caller); }
 784
 785                         else // everything went okay, continue changing vote
 786                         {
 787                                 print_to(caller, "^1You rejected the vote.");
 788                                 caller.vote_selection = VOTE_SELECT_REJECT;
 789                                 msg_entity = caller;
 790                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
 791                         }
 792
 793                         return;
 794                 }
 795
 796                 default:
 797                 case CMD_REQUEST_USAGE:
 798                 {
 799                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
 800                         print_to(caller, "  No arguments required.");
 801                         return;
 802                 }
 803         }
 804 }
 805
 806 void VoteCommand_status(float request, entity caller) // BOTH
 807 {
 808         switch(request)
 809         {
 810                 case CMD_REQUEST_COMMAND:
 811                 {
 812                         if(vote_called)
 813                                 print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", GetCallerName(vote_caller), "^7."));
 814                         else
 815                                 print_to(caller, "^1No vote called.");
 816
 817                         return;
 818                 }
 819
 820                 default:
 821                 case CMD_REQUEST_USAGE:
 822                 {
 823                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
 824                         print_to(caller, "  No arguments required.");
 825                         return;
 826                 }
 827         }
 828 }
 829
 830 void VoteCommand_stop(float request, entity caller) // BOTH
 831 {
 832         switch(request)
 833         {
 834                 case CMD_REQUEST_COMMAND:
 835                 {
 836                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 837                         else if((caller == vote_caller) || !caller || caller.vote_master) { VoteStop(caller); }
 838                         else { print_to(caller, "^1You are not allowed to stop that vote."); }
 839
 840                         return;
 841                 }
 842
 843                 default:
 844                 case CMD_REQUEST_USAGE:
 845                 {
 846                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
 847                         print_to(caller, "  No arguments required.");
 848                         return;
 849                 }
 850         }
 851 }
 852
 853 void VoteCommand_yes(float request, entity caller) // CLIENT ONLY
 854 {
 855         switch(request)
 856         {
 857                 case CMD_REQUEST_COMMAND:
 858                 {
 859                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 860                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 861
 862                         else // everything went okay, continue changing vote
 863                         {
 864                                 print_to(caller, "^1You accepted the vote.");
 865                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
 866                                 msg_entity = caller;
 867                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
 868                         }
 869
 870                         return;
 871                 }
 872
 873                 default:
 874                 case CMD_REQUEST_USAGE:
 875                 {
 876                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
 877                         print_to(caller, "  No arguments required.");
 878                         return;
 879                 }
 880         }
 881 }
 882
 883 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 884 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 885 void VoteCommand_(float request)
 886 {
 887         switch(request)
 888         {
 889                 case CMD_REQUEST_COMMAND:
 890                 {
 891
 892                         return;
 893                 }
 894
 895                 default:
 896                 case CMD_REQUEST_USAGE:
 897                 {
 898                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
 899                         print_to(caller, "  No arguments required.");
 900                         return;
 901                 }
 902         }
 903 }
 904 */
 905
 906
 907 // ================================
 908 //  Macro system for vote commands
 909 // ================================
 910
 911 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 912 #define VOTE_COMMANDS(request,caller,arguments,command) \
 913         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
 914         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
 915         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
 916         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
 917         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
 918         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
 919         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
 920         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
 921         /* nothing */
 922
 923 void VoteCommand_macro_help(entity caller, float argc)
 924 {
 925         string command_origin = GetCommandPrefix(caller);
 926
 927         if(argc == 2) // help display listing all commands
 928         {
 929                 print_to(caller, "\nVoting commands:\n");
 930                 #define VOTE_COMMAND(name,function,description,assignment) \
 931                         { if(Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
 932
 933                 VOTE_COMMANDS(0, caller, 0, "")
 934                 #undef VOTE_COMMAND
 935
 936                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
 937                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
 938                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 939         }
 940         else // usage for individual command
 941         {
 942                 #define VOTE_COMMAND(name,function,description,assignment) \
 943                         { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(2))) { function; return; } } }
 944
 945                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "")
 946                 #undef VOTE_COMMAND
 947         }
 948
 949         return;
 950 }
 951
 952 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
 953 {
 954         #define VOTE_COMMAND(name,function,description,assignment) \
 955                 { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(1))) { function; return TRUE; } } }
 956
 957         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command)
 958         #undef VOTE_COMMAND
 959
 960         return FALSE;
 961 }
 962
 963
 964 // ======================================
 965 //  Main function handling vote commands
 966 // ======================================
 967
 968 void VoteCommand(float request, entity caller, float argc, string vote_command)
 969 {
 970         // Guide for working with argc arguments by example:
 971         // argc:   1    - 2      - 3     - 4
 972         // argv:   0    - 1      - 2     - 3
 973         // cmd     vote - master - login - password
 974
 975         switch(request)
 976         {
 977                 case CMD_REQUEST_COMMAND:
 978                 {
 979                         if(VoteCommand_macro_command(caller, argc, vote_command))
 980                                 return;
 981                 }
 982
 983                 default:
 984                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
 985                 case CMD_REQUEST_USAGE:
 986                 {
 987                         VoteCommand_macro_help(caller, argc);
 988                         return;
 989                 }
 990         }
 991 }