qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/items/inventory.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/playerstats.qh>
  11 #include <common/stats.qh>
  12 #include <common/util.qh>
  13 #include <common/weapons/_all.qh>
  14 #include <server/campaign.qh>
  15 #include <server/client.qh>
  16 #include <server/command/banning.qh>
  17 #include <server/command/common.qh>
  18 #include <server/command/vote.qh>
  19 #include <server/damage.qh>
  20 #include <server/gamelog.qh>
  21 #include <server/intermission.qh>
  22 #include <server/mutators/_mod.qh>
  23 #include <server/race.qh>
  24 #include <server/round_handler.qh>
  25 #include <server/scores.qh>
  26 #include <server/teamplay.qh>
  27 #include <server/weapons/accuracy.qh>
  28 #include <server/weapons/selection.qh>
  29 #include <server/world.qh>
  30
  31 // =============================================
  32 //  Server side voting code, reworked by Samual
  33 //  Last updated: December 27th, 2011
  34 // =============================================
  35
  36 //  Nagger for players to know status of voting
  37 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  38 {
  39         int nags = 0;
  40         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  41
  42         // bits:
  43         //   1 = ready
  44         //   2 = player needs to ready up
  45         //   4 = vote
  46         //   8 = player needs to vote
  47         //  16 = warmup
  48         // sendflags:
  49         //  64 = vote counts
  50         // 128 = vote string
  51
  52         if (warmup_stage)
  53         {
  54                 if (readycount)
  55                 {
  56                         nags |= BIT(0);
  57                         if (!to.ready) nags |= BIT(1);
  58                 }
  59                 nags |= BIT(4);
  60         }
  61
  62         if (vote_called)
  63         {
  64                 nags |= BIT(2);
  65                 if (to.vote_selection == 0) nags |= BIT(3);
  66                 nags |= sendflags & BIT(6);
  67                 nags |= sendflags & BIT(7);
  68         }
  69
  70         WriteByte(MSG_ENTITY, nags);
  71
  72         if (nags & BIT(6))
  73         {
  74                 WriteByte(MSG_ENTITY, vote_accept_count);
  75                 WriteByte(MSG_ENTITY, vote_reject_count);
  76                 WriteByte(MSG_ENTITY, vote_needed_overall);
  77                 WriteChar(MSG_ENTITY, to.vote_selection);
  78         }
  79
  80         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  81
  82         if (nags & BIT(0))
  83         {
  84                 for (int i = 1; i <= maxclients;)
  85                 {
  86                         int f = 0;
  87                         for (int b = 0; b < 8 && i <= maxclients; ++b, ++i)
  88                                 if (edict_num(i).ready)
  89                                         f |= BIT(b);
  90                         WriteByte(MSG_ENTITY, f);
  91                 }
  92         }
  93
  94         return true;
  95 }
  96
  97 void Nagger_Init()
  98 {
  99         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
 100 }
 101
 102 void Nagger_VoteChanged()
 103 {
 104         if (nagger) nagger.SendFlags |= BIT(7);
 105 }
 106
 107 void Nagger_VoteCountChanged()
 108 {
 109         if (nagger) nagger.SendFlags |= BIT(6);
 110 }
 111
 112 void Nagger_ReadyCounted()
 113 {
 114         if (nagger) nagger.SendFlags |= BIT(0);
 115 }
 116
 117 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 118 string OriginalCallerName()
 119 {
 120         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 121         return vote_caller_name;
 122 }
 123
 124 // =======================
 125 //  Game logic for voting
 126 // =======================
 127
 128 void VoteStop(entity stopper, bool show_name);
 129 void VoteReset(bool verbose)
 130 {
 131         if (verbose && vote_called)
 132         {
 133                 VoteStop(NULL, true);
 134                 return;
 135         }
 136
 137         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 138
 139         if (vote_called)
 140         {
 141                 strfree(vote_called_command);
 142                 strfree(vote_called_display);
 143                 strfree(vote_caller_name);
 144         }
 145
 146         vote_called = VOTE_NULL;
 147         vote_caller = NULL;
 148         vote_endtime = 0;
 149
 150         vote_parsed_command = string_null;
 151         vote_parsed_display = string_null;
 152
 153         Nagger_VoteChanged();
 154 }
 155
 156 void VoteStop(entity stopper, bool canceled)
 157 {
 158         if (canceled)
 159                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote was canceled\n");
 160         else
 161                 bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 162         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 163         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 164         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 165         VoteReset(false);
 166 }
 167
 168 void VoteAccept()
 169 {
 170         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 171
 172         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = true;
 173         else localcmd(strcat(vote_called_command, "\n"));
 174
 175         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 176
 177         VoteReset(false);
 178         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 179 }
 180
 181 void VoteReject()
 182 {
 183         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 184         VoteReset(false);
 185         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 186 }
 187
 188 void VoteTimeout()
 189 {
 190         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 191         VoteReset(false);
 192         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 193 }
 194
 195 void VoteSpam(float notvoters, float mincount, string result)
 196 {
 197         bprint(strcat(
 198                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 199                 strcat("^2:^1", ftos(vote_reject_count)),
 200                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 201                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 202                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 203
 204         if (autocvar_sv_eventlog)
 205         {
 206                 GameLogEcho(strcat(
 207                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 208                         strcat(":", ftos(vote_reject_count)),
 209                         strcat(":", ftos(vote_abstain_count)),
 210                         strcat(":", ftos(notvoters)),
 211                         strcat(":", ftos(mincount))));
 212         }
 213 }
 214
 215 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 216
 217 void VoteCount(float first_count)
 218 {
 219         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 220
 221         float vote_player_count = 0, notvoters = 0;
 222         float vote_real_player_count = 0, vote_real_accept_count = 0;
 223         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 224         float vote_needed_of_voted, final_needed_votes;
 225         float vote_factor_overall, vote_factor_of_voted;
 226
 227         Nagger_VoteCountChanged();
 228
 229         // add up all the votes from each connected client
 230         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 231                 // z411
 232                 if(vote_target_type == VOTE_TARGET_TEAM && it.team != vote_caller.team) continue;
 233                 if(vote_target_type == VOTE_TARGET_SINGLE && it != vote_target) continue;
 234
 235                 ++vote_player_count;
 236                 if (IS_PLAYER(it) || INGAME(it)) ++vote_real_player_count;
 237                 switch (it.vote_selection)
 238                 {
 239                         case VOTE_SELECT_REJECT:
 240                                 ++vote_reject_count;
 241                                 if (IS_PLAYER(it) || INGAME(it)) ++vote_real_reject_count;
 242                                 break;
 243                         case VOTE_SELECT_ACCEPT:
 244                                 ++vote_accept_count;
 245                                 if (IS_PLAYER(it) || INGAME(it)) ++vote_real_accept_count;
 246                                 break;
 247                         case VOTE_SELECT_ABSTAIN:
 248                                 ++vote_abstain_count;
 249                                 if (IS_PLAYER(it) || INGAME(it)) ++vote_real_abstain_count;
 250                                 break;
 251                         default: break;
 252                 }
 253         });
 254
 255         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 256         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 257         {
 258                 if (vote_caller)   vote_caller.vote_waittime = 0;
 259                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 260                 VoteReset(false);
 261                 return;
 262         }
 263
 264         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 265         if (!spectators_allowed && (vote_real_player_count > 0))
 266         {
 267                 vote_accept_count = vote_real_accept_count;
 268                 vote_reject_count = vote_real_reject_count;
 269                 vote_abstain_count = vote_real_abstain_count;
 270                 vote_player_count = vote_real_player_count;
 271         }
 272
 273         // people who have no opinion in any way :D
 274         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 275
 276         // determine the goal for the vote to be passed or rejected normally
 277         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 278         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 279
 280         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 281         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 282         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 283
 284         // are there any players at all on the server? it could be an admin vote
 285         if (vote_player_count == 0 && first_count)
 286         {
 287                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 288                 VoteAccept();
 289                 return;
 290         }
 291
 292         // since there ARE players, finally calculate the result of the vote
 293         if (vote_accept_count >= vote_needed_overall)
 294         {
 295                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 296                 VoteAccept();
 297                 return;
 298         }
 299
 300         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 301         {
 302                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 303                 VoteReject();
 304                 return;
 305         }
 306
 307         // there is not enough votes in either direction, now lets just calculate what the voters have said
 308         if (time > vote_endtime)
 309         {
 310                 final_needed_votes = vote_needed_overall;
 311
 312                 if (autocvar_sv_vote_majority_factor_of_voted)
 313                 {
 314                         if (vote_accept_count >= vote_needed_of_voted)
 315                         {
 316                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 317                                 VoteAccept();
 318                                 return;
 319                         }
 320
 321                         if (vote_accept_count + vote_reject_count > 0)
 322                         {
 323                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 324                                 VoteReject();
 325                                 return;
 326                         }
 327
 328                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 329                 }
 330
 331                 // it didn't pass or fail, so not enough votes to even make a decision.
 332                 VoteSpam(notvoters, final_needed_votes, "timeout");
 333                 VoteTimeout();
 334         }
 335 }
 336
 337 void VoteThink()
 338 {
 339         if (vote_endtime > 0)        // a vote was called
 340         {
 341                 if (time > vote_endtime) // time is up
 342                         VoteCount(false);
 343         }
 344 }
 345
 346
 347 // =======================
 348 //  Game logic for warmup
 349 // =======================
 350
 351 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 352 void reset_map(bool is_fake_round_start)
 353 {
 354         if (time <= game_starttime)
 355         {
 356                 if (game_stopped)
 357                         return;
 358
 359                 if (!is_fake_round_start)
 360                 {
 361                         Score_ClearAll();
 362                         PlayerStats_GameReport_Reset_All();
 363                 }
 364
 365                 if (round_handler_IsActive())
 366                         round_handler_Reset(game_starttime);
 367         }
 368
 369         // for RJZ
 370         if (autocvar_rjz_count_shards) {
 371                 total_shards = 0;
 372                 send_TotalShardsAll();
 373         }
 374
 375         if (shuffleteams_on_reset_map)
 376         {
 377                 shuffleteams();
 378                 shuffleteams_on_reset_map = false;
 379         }
 380
 381         FOREACH_CLIENT(true, {
 382                 if (time <= game_starttime)
 383                         accuracy_reset(it); // for spectators too because weapon accuracy is persistent
 384                 if (!IS_PLAYER(it))
 385                         continue;
 386                 if (STAT(FROZEN, it))
 387                         Unfreeze(it, false);
 388                 player_powerups_remove_all(it);
 389                 entity store = PS(it);
 390                 if (store)
 391                 {
 392                         Inventory_clear(store.inventory);
 393                         Inventory_update(store);
 394                 }
 395         });
 396
 397         MUTATOR_CALLHOOK(reset_map_global);
 398
 399         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 400         {
 401                 if(IS_CLIENT(it))
 402                         continue;
 403                 if (it.reset)
 404                 {
 405                         it.reset(it);
 406                         continue;
 407                 }
 408                 if (it.team_saved) it.team = it.team_saved;
 409                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 410         });
 411
 412         // Waypoints and assault start come LAST
 413         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 414                 if (it.reset2) it.reset2(it);
 415         });
 416
 417         // Moving the player reset code here since the player-reset depends
 418         // on spawnpoint entities which have to be reset first --blub
 419         if (!MUTATOR_CALLHOOK(reset_map_players))
 420         {
 421                 FOREACH_CLIENT(IS_PLAYER(it),
 422                 {
 423                         // PlayerScore_Clear(it);
 424                         CS(it).killcount = 0;
 425                         // stop the player from moving so that they stand still once they get respawned
 426                         it.velocity = '0 0 0';
 427                         it.avelocity = '0 0 0';
 428                         CS(it).movement = '0 0 0';
 429                         PutClientInServer(it);
 430
 431                         if(IS_BOT_CLIENT(it))
 432                         {
 433                                 .entity weaponentity = weaponentities[0];
 434                                 if(it.(weaponentity).m_weapon == WEP_Null)
 435                                         W_NextWeapon(it, 0, weaponentity);
 436                         }
 437                 });
 438         }
 439 }
 440
 441 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 442 void ReadyRestart_think(entity this)
 443 {
 444         if (!warmup_stage) // if the countdown was not aborted
 445                 reset_map(false);
 446         delete(this);
 447 }
 448
 449 // Forces a restart of the game without actually reloading the map // this is a mess...
 450 void ReadyRestart_force(bool is_fake_round_start)
 451 {
 452         if (time <= game_starttime && game_stopped)
 453                 return;
 454         if (!is_fake_round_start && !autocvar_g_campaign)
 455                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_COUNTDOWN_RESTART);
 456
 457         VoteReset(true);
 458
 459         // clear overtime, we have to decrease timelimit to its original value again.
 460         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 461                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 462         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = overtimes = 0;
 463
 464         if(warmup_stage)
 465                 game_starttime = time; // Warmup: No countdown in warmup
 466         else if (autocvar_g_campaign)
 467                 game_starttime = time + 3;
 468         else
 469                 game_starttime = time + RESTART_COUNTDOWN; // Go into match mode
 470
 471         // clear player attributes
 472         FOREACH_CLIENT(IS_PLAYER(it), {
 473                 it.alivetime = 0;
 474                 CS(it).killcount = 0;
 475         });
 476
 477         // if we're ending the warmup stage call the corresponding hook
 478         if(!is_fake_round_start && !warmup_stage)
 479                 localcmd("\nsv_hook_warmupend\n");
 480
 481         // reset the .ready status of all players (also spectators)
 482         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 483                 it.ready = false;
 484                 Kill_Notification(NOTIF_ONE_ONLY, it, MSG_CENTER, CPID_MISSING_READY);
 485         });
 486         readycount = 0;
 487         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 488
 489         // lock teams with lockonrestart
 490         if (autocvar_teamplay_lockonrestart && teamplay)
 491                 lockteams = !warmup_stage;
 492
 493         // initiate the restart-countdown-announcer entity
 494         if (!is_fake_round_start && sv_ready_restart_after_countdown && !warmup_stage)
 495         {
 496                 entity restart_timer = new_pure(restart_timer);
 497                 setthink(restart_timer, ReadyRestart_think);
 498                 restart_timer.nextthink = game_starttime;
 499         }
 500
 501         // after a restart every players number of allowed timeouts gets reset, too
 502         if (autocvar_sv_timeout)
 503         {
 504                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 505         }
 506
 507         round_handler_Activate(!warmup_stage);
 508         if (!sv_ready_restart_after_countdown || warmup_stage)
 509                 reset_map(is_fake_round_start);
 510
 511         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 512 }
 513
 514 void ReadyRestart(bool forceWarmupEnd)
 515 {
 516         if (MUTATOR_CALLHOOK(ReadyRestart_Deny))
 517         {
 518                 // NOTE: ReadyRestart support is mandatory in campaign
 519                 if (autocvar_g_campaign)
 520                         error("ReadyRestart must be supported in campaign mode!");
 521                 localcmd("restart\n"); // if ReadyRestart is denied, restart the server
 522         }
 523         else if (intermission_running || race_completing) // game is over, ReadyRestart no longer available
 524                 localcmd("restart\n");
 525         else
 526                 localcmd("\nsv_hook_readyrestart\n");
 527
 528         if(forceWarmupEnd || autocvar_g_campaign)
 529                 warmup_stage = 0; // forcefully end warmup and go to match stage
 530         else
 531                 warmup_stage = autocvar_g_warmup; // go into warmup if it's enabled, otherwise restart into match stage
 532
 533         ReadyRestart_force(false);
 534 }
 535
 536 /* Count the players who are ready and determine whether or not to restart the match when:
 537  * a player presses F4                      server/command/cmd.qc  ClientCommand_ready()
 538  * a player switches from players to specs  server/client.qc       PutObserverInServer()
 539  * a player joins (from specs or directly)  server/client.qc       PutPlayerInServer()
 540  * a player disconnects                     server/client.qc       ClientDisconnect()   */
 541 void ReadyCount()
 542 {
 543         // cannot reset the game while a timeout is active or pending
 544         if (timeout_status) return;
 545
 546         int total_players = 0, human_players = 0, humans_ready = 0;
 547         readycount = 0;
 548
 549         FOREACH_CLIENT(IS_PLAYER(it) || INGAME_JOINED(it), {
 550                 ++total_players;
 551                 if (it.ready) ++readycount;
 552                 if (IS_REAL_CLIENT(it))
 553                 {
 554                         ++human_players;
 555                         if (it.ready) ++humans_ready;
 556                 }
 557         });
 558
 559         Nagger_ReadyCounted();
 560
 561         // can't read warmup_stage here as it could have been set to 0 by ReadyRestart()
 562         // and we need to use this when checking if we should abort the countdown
 563         // map_minplayers can only be > 0 if g_warmup was -1 at worldspawn
 564         int minplayers = autocvar_g_warmup > 1 ? autocvar_g_warmup : map_minplayers;
 565
 566         if (total_players < minplayers)
 567         {
 568                 if (game_starttime > time) // someone bailed during countdown, back to warmup
 569                 {
 570                         warmup_stage = autocvar_g_warmup; // CAN change it AFTER calling Nagger_ReadyCounted() this frame
 571                         game_starttime = time;
 572                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, COUNTDOWN_STOP, minplayers);
 573                         if (!sv_ready_restart_after_countdown) // if we ran reset_map() at start of countdown
 574                                 FOREACH_CLIENT(IS_PLAYER(it), { ResetPlayerResources(it); });
 575                 }
 576                 if (warmup_limit > 0)
 577                         warmup_limit = -1;
 578                 return; // don't ReadyRestart if players are ready but too few
 579         }
 580         else if (minplayers && warmup_limit <= 0)
 581         {
 582                 // there's enough players now but we're still in infinite warmup
 583                 warmup_limit = cvar("g_warmup_limit");
 584                 if (warmup_limit == 0)
 585                         warmup_limit = autocvar_timelimit * 60;
 586                 if (warmup_limit > 0)
 587                         game_starttime = time;
 588                 // implicit else: g_warmup -1 && g_warmup_limit -1 means
 589                 // warmup continues until enough players AND enough RUPs (no time limit)
 590         }
 591
 592         if (humans_ready && humans_ready >= rint(human_players * bound(0.5, cvar("g_warmup_majority_factor"), 1)))
 593                 ReadyRestart(true);
 594 }
 595
 596
 597 // ======================================
 598 //  Supporting functions for VoteCommand
 599 // ======================================
 600
 601 bool Votecommand_check_assignment(entity caller, float assignment)
 602 {
 603         bool from_server = (!caller);
 604
 605         if ((assignment == VC_ASGNMNT_BOTH)
 606             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 607             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 608
 609         return false;
 610 }
 611
 612 string VoteCommand_extractcommand(string input, float startpos, int argc)
 613 {
 614         string output;
 615
 616         if ((argc - 1) < startpos) output = "";
 617         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 618
 619         return output;
 620 }
 621
 622 bool VoteCommand_checknasty(string vote_command)
 623 {
 624         return !((strstrofs(vote_command, ";", 0) >= 0)
 625             || (strstrofs(vote_command, "\n", 0) >= 0)
 626             || (strstrofs(vote_command, "\r", 0) >= 0)
 627             || (strstrofs(vote_command, "$", 0) >= 0));
 628 }
 629
 630 // NOTE: requires input to be surrounded by spaces
 631 string VoteCommand_checkreplacements(string input)
 632 {
 633         // add a space around the input so the start and end of the list is captured
 634         string output = strcat(" ", input, " ");
 635         // allow gotomap replacements
 636         output = strreplace(" map ", " gotomap ", output);
 637         output = strreplace(" chmap ", " gotomap ", output);
 638         return output;
 639 }
 640
 641 bool VoteCommand_checkinlist(string vote_command, string list)
 642 {
 643         if (vote_command == "" || list == "")
 644                 return false;
 645
 646         string l = VoteCommand_checkreplacements(list);
 647         return (strstrofs(l, VoteCommand_checkreplacements(vote_command), 0) >= 0);
 648 }
 649
 650 string ValidateMap(string validated_map, entity caller)
 651 {
 652         validated_map = MapInfo_FixName(validated_map);
 653
 654         if (!validated_map)
 655         {
 656                 print_to(caller, "This map is not available on this server.");
 657                 return string_null;
 658         }
 659
 660         if (!autocvar_sv_vote_override_mostrecent && caller)
 661         {
 662                 if (Map_IsRecent(validated_map))
 663                 {
 664                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 665                         return string_null;
 666                 }
 667         }
 668
 669         if (!MapInfo_CheckMap(validated_map))
 670         {
 671                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 672                 return string_null;
 673         }
 674
 675         return validated_map;
 676 }
 677
 678 float VoteCommand_checkargs(float startpos, int argc)
 679 {
 680         float p, q, check, minargs;
 681         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 682         string cmdrestriction = "";  // No we don't.
 683         string charlist, arg;
 684         float checkmate;
 685
 686         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 687                 cmdrestriction = cvar_string(cvarname);
 688         else
 689                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 690
 691         if (cmdrestriction == "") return true;
 692
 693         ++startpos;  // skip command name
 694
 695         // check minimum arg count
 696
 697         // 0 args: argc == startpos
 698         // 1 args: argc == startpos + 1
 699         // ...
 700
 701         minargs = stof(cmdrestriction);
 702         if (argc - startpos < minargs) return false;
 703
 704         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 705
 706         for ( ; ; )
 707         {
 708                 // we know that at any time, startpos <= argc - minargs
 709                 // so this means: argc-minargs >= startpos >= argc, thus
 710                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 711                 // have been seen already
 712
 713                 if (startpos >= argc) // all args checked? GOOD
 714                         break;
 715
 716                 if (p < 0)            // no more args? FAIL
 717                 {
 718                         // exception: exactly minargs left, this one included
 719                         if (argc - startpos == minargs) break;
 720
 721                         // otherwise fail
 722                         return false;
 723                 }
 724
 725                 // cut to next semicolon
 726                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 727                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 728                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 729
 730                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 731                 // charlist = strreplace("^^", ";", charlist);
 732
 733                 if (charlist != "")
 734                 {
 735                         // verify the arg only contains allowed chars
 736                         arg = argv(startpos);
 737                         checkmate = strlen(arg);
 738                         for (check = 0; check < checkmate; ++check)
 739                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 740                         // not allowed character
 741                         // all characters are allowed. FINE.
 742                 }
 743
 744                 ++startpos;
 745                 --minargs;
 746                 p = q;
 747         }
 748
 749         return true;
 750 }
 751
 752 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 753 {
 754         string first_command = argv(startpos);
 755         int missing_chars = argv_start_index(startpos);
 756
 757         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 758                 return 0;
 759
 760         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 761
 762         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 763
 764         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 765         {
 766                 case MUT_VOTEPARSE_CONTINUE: { break; }
 767                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 768                 case MUT_VOTEPARSE_INVALID: { return -1; }
 769                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 770         }
 771
 772         vote_target_type = VOTE_TARGET_ALL;
 773
 774         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 775         {
 776                 case "movetoauto":
 777                 case "movetored":
 778                 case "movetoblue":
 779                 case "movetoyellow":
 780                 case "movetopink":
 781                 case "movetospec":
 782                 {
 783                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 784                         float accepted = VerifyClientEntity(victim, true, false);
 785                         if (accepted > 0)
 786                         {
 787                                 vote_parsed_command = vote_command;
 788                                 vote_parsed_display = sprintf("^1%s #%d ^7%s", first_command, etof(victim), victim.netname);
 789                         }
 790                         else
 791                         {
 792                                 print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
 793                                 return 0;
 794                         }
 795
 796                         break;
 797                 }
 798
 799                 case "kick":
 800                 case "kickban":    // catch all kick/kickban commands
 801                 {
 802                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 803                         float accepted = VerifyClientEntity(victim, true, false);
 804
 805                         if (accepted > 0)
 806                         {
 807                                 string reason = "No reason provided";
 808                                 if(argc > next_token)
 809                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 810
 811                                 string command_arguments = reason;
 812                                 if (first_command == "kickban")
 813                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 814
 815                                 if (first_command == "kick") // z411 : Use our kick implementation - kind of hacky...
 816                                         vote_parsed_command = strcat("defer 2 \"sv_cmd kickkick # ", ftos(etof(victim)), " ", command_arguments, "\"");
 817                                 else
 818                                         vote_parsed_command = strcat("defer 2 \"", first_command, " # ", ftos(etof(victim)), " ", command_arguments, "\"");
 819
 820                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 821                         }
 822                         else
 823                         {
 824                                 print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
 825                                 return 0;
 826                         }
 827
 828                         break;
 829                 }
 830
 831                 case "map":
 832                 case "chmap":
 833                 case "gotomap":  // re-direct all map selection commands to gotomap
 834                 {
 835                         vote_command = ValidateMap(argv(startpos + 1), caller);
 836                         if (!vote_command)  return -1;
 837                         vote_parsed_command = strcat("defer 2 \"gotomap ", vote_command, "\"");
 838                         vote_parsed_display = strzone(strcat("^1gotomap ", vote_command));
 839
 840                         break;
 841                 }
 842
 843                 // z411 team calls
 844                 case "teamname":
 845                 {
 846                         if (teamplay && Team_IsValidTeam(caller.team)) {
 847                                 vote_target_type = VOTE_TARGET_TEAM;
 848
 849                                 string tmname = strtolower(Static_Team_ColorName(caller.team));
 850                                 string newname = argv(startpos + 1);
 851
 852                                 vote_parsed_command = strcat(first_command, " ", tmname, " \"", newname, "\"");
 853                                 vote_parsed_display = strzone(strcat("^3(Team) ^1", first_command, " ^2", newname));
 854                         } else { print_to(caller, "vcall: Not in a team\n"); return 0; }
 855
 856                         break;
 857                 }
 858
 859                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 860                 // maybe fallback instead of aborting if map name is invalid?
 861                 case "nextmap":
 862                 {
 863                         vote_command = ValidateMap(argv(startpos + 1), caller);
 864                         if (!vote_command)  return -1;
 865                         vote_parsed_command = strcat("nextmap ", vote_command);
 866                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 867
 868                         break;
 869                 }
 870
 871                 case "fraglimit": // include restrictions on the maximum votable frag limit
 872                 {
 873                         float fraglimit_vote = stof(argv(startpos + 1));
 874                         float fraglimit_min = 0;
 875                         float fraglimit_max = 999999;
 876                         if(fraglimit_vote > fraglimit_max || fraglimit_vote < fraglimit_min)
 877                         {
 878                                 print_to(caller, strcat("Invalid fraglimit vote, accepted values are between ", ftos(fraglimit_min), " and ", ftos(fraglimit_max), "."));
 879                                 return -1;
 880                         }
 881                         vote_parsed_command = strcat("fraglimit ", ftos(fraglimit_vote));
 882                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 883
 884                         break;
 885                 }
 886
 887                 case "timelimit": // include restrictions on the maximum votable time limit
 888                 {
 889                         float timelimit_vote = stof(argv(startpos + 1));
 890                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 891                         {
 892                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 893                                 return -1;
 894                         }
 895                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 896                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 897
 898                         break;
 899                 }
 900
 901                 case "gg":
 902                 case "shuffleteams":
 903                 case "endmatch":
 904                 {
 905                         // add a delay so that vote result can be seen and announcer can be heard
 906                         // if the vote is accepted
 907                         vote_parsed_command = strcat("defer 2 ", vote_command);
 908                         vote_parsed_display = strzone(strcat("^1", vote_command));
 909
 910                         break;
 911                 }
 912
 913                 case "reset":
 914                 case "restart": // re-direct all match restarting to resetmatch
 915                         vote_command = "resetmatch"; // fall-through
 916                 case "resetmatch":
 917                 {
 918                         vote_parsed_command = strcat("defer 2 ", vote_command);
 919                         vote_parsed_display = strzone(strcat("^1", vote_command));
 920
 921                         break;
 922                 }
 923
 924                 case "allready":
 925                 {
 926                         if(!warmup_stage) {
 927                                 print_to(caller, "Game already started. Use the resetmatch command to restart the match.");
 928                                 return -1;
 929                         }
 930
 931                         vote_parsed_command = strcat("defer 2 ", vote_command);
 932                         vote_parsed_display = strzone(strcat("^1", vote_command));
 933                         break;
 934                 }
 935
 936                 default:
 937                 {
 938                         vote_parsed_command = vote_command;
 939                         vote_parsed_display = strzone(strcat("^1", vote_command));
 940
 941                         break;
 942                 }
 943         }
 944
 945         return 1;
 946 }
 947
 948
 949 // =======================
 950 //  Command Sub-Functions
 951 // =======================
 952
 953 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 954 {
 955         switch (request)
 956         {
 957                 case CMD_REQUEST_COMMAND:
 958                 {
 959                         if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
 960                         {
 961                                 print_to(caller, "^1You are banned from voting.");
 962                                 Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBANYN);
 963                                 return;
 964                         }
 965
 966                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 967                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 968                         {
 969                                 print_to(caller, "^1You have already voted.");
 970                         }
 971
 972                         else  // everything went okay, continue changing vote
 973                         {
 974                                 print_to(caller, "^1You abstained from your vote.");
 975                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 976                                 msg_entity = caller;
 977                                 if (!autocvar_sv_vote_singlecount)
 978                                         VoteCount(false);
 979                         }
 980
 981                         return;
 982                 }
 983
 984                 default:
 985                 case CMD_REQUEST_USAGE:
 986                 {
 987                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 988                         print_to(caller, "  No arguments required.");
 989                         return;
 990                 }
 991         }
 992 }
 993
 994 void print_available_commands_to(entity caller)
 995 {
 996         print_to(caller, strcat("You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 997 }
 998
 999 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
1000 {
1001         switch (request)
1002         {
1003                 case CMD_REQUEST_COMMAND:
1004                 {
1005                         float tmp_playercount = 0;
1006                         int parse_error;
1007
1008                         if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
1009                         {
1010                                 print_to(caller, "^1You are banned from calling a vote.");
1011                                 Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBAN);
1012                                 return;
1013                         }
1014
1015                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
1016
1017                         if (!autocvar_sv_vote_call && caller)
1018                         {
1019                                 print_to(caller, "^1Vote calling is not allowed.");
1020                         }
1021                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
1022                         {
1023                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
1024                         }
1025                         else if (vote_called)
1026                         {
1027                                 print_to(caller, "^1There is already a vote called.");
1028                         }
1029                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
1030                         {
1031                                 print_to(caller, "^1Only players can call a vote.");
1032                         }
1033                         else if (caller && !IS_CLIENT(caller))
1034                         {
1035                                 print_to(caller, "^1Only connected clients can vote.");
1036                         }
1037                         else if (timeout_status && vote_command != "timein")
1038                         {
1039                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
1040                         }
1041                         else if (caller && (time < caller.vote_waittime))
1042                         {
1043                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
1044                         }
1045                         else if (!VoteCommand_checknasty(vote_command))
1046                         {
1047                                 print_to(caller, "^1Syntax error in command.");
1048                         }
1049                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
1050                         {
1051                                 if(parse_error == 0)
1052                                 {
1053                                         if (vote_called_command == "")
1054                                                 VoteCommand_call(CMD_REQUEST_USAGE, caller, argc, vote_command);
1055                                         else
1056                                                 print_to(caller, "^1This command is not acceptable or not available.");
1057                                 }
1058                         }
1059                         else  // everything went okay, continue with calling the vote
1060                         {
1061                                 vote_caller = caller;  // remember who called the vote
1062                                 vote_caller_name = strzone(GetCallerName(vote_caller));
1063                                 vote_called = VOTE_NORMAL;
1064                                 vote_called_command = strzone(vote_parsed_command);
1065                                 vote_called_display = strzone(vote_parsed_display);
1066                                 vote_endtime = time + autocvar_sv_vote_timeout;
1067
1068                                 if (caller)
1069                                 {
1070                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1071                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1072                                         msg_entity = caller;
1073                                 }
1074
1075                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
1076
1077                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
1078                                 if (autocvar_sv_vote_debug)
1079                                         bprint("\{1}^2* ^3", "^6DEBUG MODE ACTIVE: bots can vote too\n"); // so servers don't forget it on
1080                                 if (autocvar_sv_eventlog)
1081                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1082                                 Nagger_VoteChanged();
1083                                 VoteCount(true);  // needed if you are the only one
1084
1085                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
1086                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
1087                         }
1088
1089                         return;
1090                 }
1091
1092                 default:
1093                 case CMD_REQUEST_USAGE:
1094                 {
1095                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call <command>"));
1096                         print_to(caller, "  Where <command> is the command to request a vote upon.");
1097                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
1098                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
1099                         print_available_commands_to(caller);
1100                         print_to(caller, "Shortcuts: ^2vcall <command>, vend, vmap, vkick, ...");
1101                         return;
1102                 }
1103         }
1104 }
1105
1106 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
1107 {
1108         switch (request)
1109         {
1110                 case CMD_REQUEST_COMMAND:
1111                 {
1112                         if (autocvar_sv_vote_master)
1113                         {
1114                                 switch (strtolower(argv(2)))
1115                                 {
1116                                         case "do":
1117                                         {
1118                                                 int parse_error;
1119                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
1120
1121                                                 if (!caller.vote_master)
1122                                                         print_to(caller, "^1You do not have vote master privileges.");
1123                                                 else if (!VoteCommand_checknasty(vote_command))
1124                                                 {
1125                                                         print_to(caller, "^1Syntax error in command.");
1126                                                 }
1127                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
1128                                                 {
1129                                                         if(parse_error == 0)
1130                                                         {
1131                                                                 if (vote_called_command == "")
1132                                                                         VoteCommand_master(CMD_REQUEST_USAGE, caller, argc, vote_command);
1133                                                                 else
1134                                                                         print_to(caller, "^1This command is not acceptable or not available.");
1135                                                         }
1136                                                 }
1137                                                 else  // everything went okay, proceed with command
1138                                                 {
1139                                                         localcmd(strcat(vote_parsed_command, "\n"));
1140                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
1141                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
1142                                                         if (autocvar_sv_eventlog)
1143                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
1144                                                 }
1145
1146                                                 return;
1147                                         }
1148
1149                                         case "login":
1150                                         {
1151                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
1152                                                 else if (caller.vote_master)
1153                                                 {
1154                                                         print_to(caller, "^1You are already logged in as vote master.");
1155                                                 }
1156                                                 else if (autocvar_sv_vote_master_password != argv(3))
1157                                                 {
1158                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
1159                                                 }
1160                                                 else  // everything went okay, proceed with giving this player master privilages
1161                                                 {
1162                                                         caller.vote_master = true;
1163                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
1164                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
1165                                                         if (autocvar_sv_eventlog)
1166                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
1167                                                 }
1168
1169                                                 return;
1170                                         }
1171
1172                                         default:  // calling a vote for master
1173                                         {
1174                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
1175                                                 else if (vote_called)
1176                                                 {
1177                                                         print_to(caller, "^1There is already a vote called.");
1178                                                 }
1179                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
1180                                                 {
1181                                                         print_to(caller, "^1Only players can call a vote.");
1182                                                 }
1183                                                 else if (timeout_status)
1184                                                 {
1185                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
1186                                                 }
1187                                                 else  // everything went okay, continue with creating vote
1188                                                 {
1189                                                         vote_caller = caller;
1190                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
1191                                                         vote_called = VOTE_MASTER;
1192                                                         vote_called_command = strzone("XXX");
1193                                                         vote_called_display = strzone("^3master");
1194                                                         vote_endtime = time + autocvar_sv_vote_timeout;
1195
1196                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1197                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1198
1199                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
1200                                                         if (autocvar_sv_eventlog)
1201                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1202                                                         Nagger_VoteChanged();
1203                                                         VoteCount(true);  // needed if you are the only one
1204                                                 }
1205
1206                                                 return;
1207                                         }
1208                                 }
1209                         }
1210                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1211
1212                         return;
1213                 }
1214
1215                 default:
1216                 case CMD_REQUEST_USAGE:
1217                 {
1218                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [<action> [<command> | <password>]]"));
1219                         print_to(caller, "  If <action> is left blank, it calls a vote for you to become master.");
1220                         print_to(caller, "  Otherwise it can be either 'do' (to run <command>) or 'login' as master.");
1221                         return;
1222                 }
1223         }
1224 }
1225
1226 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1227 {
1228         switch (request)
1229         {
1230                 case CMD_REQUEST_COMMAND:
1231                 {
1232                         if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
1233                         {
1234                                 print_to(caller, "^1You are banned from voting.");
1235                                 Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBANYN);
1236                                 return;
1237                         }
1238
1239                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1240                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1241                         {
1242                                 print_to(caller, "^1You have already voted.");
1243                         }
1244                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1245                         {
1246                                 VoteStop(caller, true);
1247                         }
1248
1249                         else  // everything went okay, continue changing vote
1250                         {
1251                                 print_to(caller, "^1You rejected the vote.");
1252                                 caller.vote_selection = VOTE_SELECT_REJECT;
1253                                 msg_entity = caller;
1254                                 if (!autocvar_sv_vote_singlecount)
1255                                         VoteCount(false);
1256                         }
1257
1258                         return;
1259                 }
1260
1261                 default:
1262                 case CMD_REQUEST_USAGE:
1263                 {
1264                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1265                         print_to(caller, "  No arguments required.");
1266                         return;
1267                 }
1268         }
1269 }
1270
1271 void VoteCommand_status(int request, entity caller)  // BOTH
1272 {
1273         switch (request)
1274         {
1275                 case CMD_REQUEST_COMMAND:
1276                 {
1277                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1278                         else print_to(caller, "^1No vote called.");
1279
1280                         return;
1281                 }
1282
1283                 default:
1284                 case CMD_REQUEST_USAGE:
1285                 {
1286                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1287                         print_to(caller, "  No arguments required.");
1288                         return;
1289                 }
1290         }
1291 }
1292
1293 void VoteCommand_stop(int request, entity caller)  // BOTH
1294 {
1295         switch (request)
1296         {
1297                 case CMD_REQUEST_COMMAND:
1298                 {
1299                         if (!vote_called)   print_to(caller, "^1No vote called.");
1300                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller, false);
1301                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1302                         return;
1303                 }
1304
1305                 default:
1306                 case CMD_REQUEST_USAGE:
1307                 {
1308                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1309                         print_to(caller, "  No arguments required.");
1310                         return;
1311                 }
1312         }
1313 }
1314
1315 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1316 {
1317         switch (request)
1318         {
1319                 case CMD_REQUEST_COMMAND:
1320                 {
1321                         if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
1322                         {
1323                                 print_to(caller, "^1You are banned from voting.");
1324                                 Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBANYN);
1325                                 return;
1326                         }
1327
1328                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1329                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1330                         {
1331                                 print_to(caller, "^1You have already voted.");
1332                         }
1333                         else  // everything went okay, continue changing vote
1334                         {
1335                                 print_to(caller, "^1You accepted the vote.");
1336                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1337                                 msg_entity = caller;
1338                                 if (!autocvar_sv_vote_singlecount)
1339                                         VoteCount(false);
1340                         }
1341
1342                         return;
1343                 }
1344
1345                 default:
1346                 case CMD_REQUEST_USAGE:
1347                 {
1348                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1349                         print_to(caller, "  No arguments required.");
1350                         return;
1351                 }
1352         }
1353 }
1354
1355 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1356 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1357 void VoteCommand_(int request)
1358 {
1359     switch(request)
1360     {
1361         case CMD_REQUEST_COMMAND:
1362         {
1363
1364             return;
1365         }
1366
1367         default:
1368         case CMD_REQUEST_USAGE:
1369         {
1370             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1371             print_to(caller, "  No arguments required.");
1372             return;
1373         }
1374     }
1375 }
1376 */
1377
1378
1379 // ================================
1380 //  Macro system for vote commands
1381 // ================================
1382
1383 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1384 #define VOTE_COMMANDS(request, caller, arguments, command) \
1385         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1386         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1387         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1388         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1389         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1390         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1391         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1392         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1393         /* nothing */
1394
1395 void VoteCommand_macro_help(entity caller, int argc)
1396 {
1397         string command_origin = GetCommandPrefix(caller);
1398
1399         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1400         {
1401                 print_to(caller, "\nVoting commands:\n");
1402                 #define VOTE_COMMAND(name, function, description, assignment) \
1403                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1404
1405                 VOTE_COMMANDS(0, caller, 0, "");
1406                 #undef VOTE_COMMAND
1407
1408                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote <command>^7, where possible commands are listed above.\n"));
1409                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help <command>"));
1410                 print_available_commands_to(caller);
1411         }
1412         else  // usage for individual command
1413         {
1414                 #define VOTE_COMMAND(name, function, description, assignment) \
1415                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1416
1417                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1418                 #undef VOTE_COMMAND
1419
1420                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1421                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1422                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1423                 else if (argv(2) != "")
1424                         print_to(caller, "No documentation exists for this vote");
1425         }
1426 }
1427
1428 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1429 {
1430         #define VOTE_COMMAND(name, function, description, assignment) \
1431                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1432
1433         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1434         #undef VOTE_COMMAND
1435
1436         return false;
1437 }
1438
1439
1440 // ======================================
1441 //  Main function handling vote commands
1442 // ======================================
1443
1444 void VoteCommand(int request, entity caller, int argc, string vote_command)
1445 {
1446         // Guide for working with argc arguments by example:
1447         // argc:   1    - 2      - 3     - 4
1448         // argv:   0    - 1      - 2     - 3
1449         // cmd     vote - master - login - password
1450
1451         switch (request)
1452         {
1453                 case CMD_REQUEST_COMMAND:
1454                 {
1455                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1456                 }
1457
1458                 default:
1459                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1460                 case CMD_REQUEST_USAGE:
1461                 {
1462                         VoteCommand_macro_help(caller, argc);
1463                         return;
1464                 }
1465         }
1466 }