qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/items/inventory.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/playerstats.qh>
  11 #include <common/stats.qh>
  12 #include <common/util.qh>
  13 #include <common/weapons/_all.qh>
  14 #include <server/campaign.qh>
  15 #include <server/client.qh>
  16 #include <server/command/banning.qh>
  17 #include <server/command/common.qh>
  18 #include <server/command/vote.qh>
  19 #include <server/damage.qh>
  20 #include <server/gamelog.qh>
  21 #include <server/intermission.qh>
  22 #include <server/mutators/_mod.qh>
  23 #include <server/race.qh>
  24 #include <server/round_handler.qh>
  25 #include <server/scores.qh>
  26 #include <server/teamplay.qh>
  27 #include <server/weapons/accuracy.qh>
  28 #include <server/world.qh>
  29
  30 // =============================================
  31 //  Server side voting code, reworked by Samual
  32 //  Last updated: December 27th, 2011
  33 // =============================================
  34
  35 //  Nagger for players to know status of voting
  36 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  37 {
  38         int nags = 0;
  39         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  40
  41         // bits:
  42         //   1 = ready
  43         //   2 = player needs to ready up
  44         //   4 = vote
  45         //   8 = player needs to vote
  46         //  16 = warmup
  47         // sendflags:
  48         //  64 = vote counts
  49         // 128 = vote string
  50
  51         if (warmup_stage)
  52         {
  53                 if (readycount)
  54                 {
  55                         nags |= BIT(0);
  56                         if (!to.ready) nags |= BIT(1);
  57                 }
  58                 nags |= BIT(4);
  59         }
  60
  61         if (vote_called)
  62         {
  63                 nags |= BIT(2);
  64                 if (to.vote_selection == 0) nags |= BIT(3);
  65                 nags |= sendflags & BIT(6);
  66                 nags |= sendflags & BIT(7);
  67         }
  68
  69         WriteByte(MSG_ENTITY, nags);
  70
  71         if (nags & BIT(6))
  72         {
  73                 WriteByte(MSG_ENTITY, vote_accept_count);
  74                 WriteByte(MSG_ENTITY, vote_reject_count);
  75                 WriteByte(MSG_ENTITY, vote_needed_overall);
  76                 WriteChar(MSG_ENTITY, to.vote_selection);
  77         }
  78
  79         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  80
  81         if (nags & BIT(0))
  82         {
  83                 for (int i = 1; i <= maxclients;)
  84                 {
  85                         int f = 0;
  86                         for (int b = 0; b < 8 && i <= maxclients; ++b, ++i)
  87                                 if (edict_num(i).ready)
  88                                         f |= BIT(b);
  89                         WriteByte(MSG_ENTITY, f);
  90                 }
  91         }
  92
  93         return true;
  94 }
  95
  96 void Nagger_Init()
  97 {
  98         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
  99 }
 100
 101 void Nagger_VoteChanged()
 102 {
 103         if (nagger) nagger.SendFlags |= BIT(7);
 104 }
 105
 106 void Nagger_VoteCountChanged()
 107 {
 108         if (nagger) nagger.SendFlags |= BIT(6);
 109 }
 110
 111 void Nagger_ReadyCounted()
 112 {
 113         if (nagger) nagger.SendFlags |= BIT(0);
 114 }
 115
 116 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 117 string OriginalCallerName()
 118 {
 119         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 120         return vote_caller_name;
 121 }
 122
 123 // =======================
 124 //  Game logic for voting
 125 // =======================
 126
 127 void VoteStop(entity stopper, bool show_name);
 128 void VoteReset(bool verbose)
 129 {
 130         if (verbose && vote_called)
 131         {
 132                 VoteStop(NULL, true);
 133                 return;
 134         }
 135
 136         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 137
 138         if (vote_called)
 139         {
 140                 strfree(vote_called_command);
 141                 strfree(vote_called_display);
 142                 strfree(vote_caller_name);
 143         }
 144
 145         vote_called = VOTE_NULL;
 146         vote_caller = NULL;
 147         vote_endtime = 0;
 148
 149         vote_parsed_command = string_null;
 150         vote_parsed_display = string_null;
 151
 152         Nagger_VoteChanged();
 153 }
 154
 155 void VoteStop(entity stopper, bool canceled)
 156 {
 157         if (canceled)
 158                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote was canceled\n");
 159         else
 160                 bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 161         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 162         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 163         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 164         VoteReset(false);
 165 }
 166
 167 void VoteAccept()
 168 {
 169         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 170
 171         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = true;
 172         else localcmd(strcat(vote_called_command, "\n"));
 173
 174         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 175
 176         VoteReset(false);
 177         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 178 }
 179
 180 void VoteReject()
 181 {
 182         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 183         VoteReset(false);
 184         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 185 }
 186
 187 void VoteTimeout()
 188 {
 189         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 190         VoteReset(false);
 191         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 192 }
 193
 194 void VoteSpam(float notvoters, float mincount, string result)
 195 {
 196         bprint(strcat(
 197                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 198                 strcat("^2:^1", ftos(vote_reject_count)),
 199                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 200                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 201                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 202
 203         if (autocvar_sv_eventlog)
 204         {
 205                 GameLogEcho(strcat(
 206                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 207                         strcat(":", ftos(vote_reject_count)),
 208                         strcat(":", ftos(vote_abstain_count)),
 209                         strcat(":", ftos(notvoters)),
 210                         strcat(":", ftos(mincount))));
 211         }
 212 }
 213
 214 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 215
 216 void VoteCount(float first_count)
 217 {
 218         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 219
 220         float vote_player_count = 0, notvoters = 0;
 221         float vote_real_player_count = 0, vote_real_accept_count = 0;
 222         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 223         float vote_needed_of_voted, final_needed_votes;
 224         float vote_factor_overall, vote_factor_of_voted;
 225
 226         Nagger_VoteCountChanged();
 227
 228         // add up all the votes from each connected client
 229         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 230                 // z411
 231                 if(vote_target_type == VOTE_TARGET_TEAM && it.team != vote_caller.team) continue;
 232                 if(vote_target_type == VOTE_TARGET_SINGLE && it != vote_target) continue;
 233
 234                 ++vote_player_count;
 235                 if (IS_PLAYER(it) || INGAME(it)) ++vote_real_player_count;
 236                 switch (it.vote_selection)
 237                 {
 238                         case VOTE_SELECT_REJECT:
 239                                 ++vote_reject_count;
 240                                 if (IS_PLAYER(it) || INGAME(it)) ++vote_real_reject_count;
 241                                 break;
 242                         case VOTE_SELECT_ACCEPT:
 243                                 ++vote_accept_count;
 244                                 if (IS_PLAYER(it) || INGAME(it)) ++vote_real_accept_count;
 245                                 break;
 246                         case VOTE_SELECT_ABSTAIN:
 247                                 ++vote_abstain_count;
 248                                 if (IS_PLAYER(it) || INGAME(it)) ++vote_real_abstain_count;
 249                                 break;
 250                         default: break;
 251                 }
 252         });
 253
 254         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 255         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 256         {
 257                 if (vote_caller)   vote_caller.vote_waittime = 0;
 258                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 259                 VoteReset(false);
 260                 return;
 261         }
 262
 263         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 264         if (!spectators_allowed && (vote_real_player_count > 0))
 265         {
 266                 vote_accept_count = vote_real_accept_count;
 267                 vote_reject_count = vote_real_reject_count;
 268                 vote_abstain_count = vote_real_abstain_count;
 269                 vote_player_count = vote_real_player_count;
 270         }
 271
 272         // people who have no opinion in any way :D
 273         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 274
 275         // determine the goal for the vote to be passed or rejected normally
 276         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 277         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 278
 279         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 280         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 281         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 282
 283         // are there any players at all on the server? it could be an admin vote
 284         if (vote_player_count == 0 && first_count)
 285         {
 286                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 287                 VoteAccept();
 288                 return;
 289         }
 290
 291         // since there ARE players, finally calculate the result of the vote
 292         if (vote_accept_count >= vote_needed_overall)
 293         {
 294                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 295                 VoteAccept();
 296                 return;
 297         }
 298
 299         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 300         {
 301                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 302                 VoteReject();
 303                 return;
 304         }
 305
 306         // there is not enough votes in either direction, now lets just calculate what the voters have said
 307         if (time > vote_endtime)
 308         {
 309                 final_needed_votes = vote_needed_overall;
 310
 311                 if (autocvar_sv_vote_majority_factor_of_voted)
 312                 {
 313                         if (vote_accept_count >= vote_needed_of_voted)
 314                         {
 315                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 316                                 VoteAccept();
 317                                 return;
 318                         }
 319
 320                         if (vote_accept_count + vote_reject_count > 0)
 321                         {
 322                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 323                                 VoteReject();
 324                                 return;
 325                         }
 326
 327                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 328                 }
 329
 330                 // it didn't pass or fail, so not enough votes to even make a decision.
 331                 VoteSpam(notvoters, final_needed_votes, "timeout");
 332                 VoteTimeout();
 333         }
 334 }
 335
 336 void VoteThink()
 337 {
 338         if (vote_endtime > 0)        // a vote was called
 339         {
 340                 if (time > vote_endtime) // time is up
 341                         VoteCount(false);
 342         }
 343 }
 344
 345
 346 // =======================
 347 //  Game logic for warmup
 348 // =======================
 349
 350 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 351 void reset_map(bool is_fake_round_start)
 352 {
 353         if (time <= game_starttime)
 354         {
 355                 if (game_stopped)
 356                         return;
 357
 358                 if (!is_fake_round_start)
 359                 {
 360                         Score_ClearAll();
 361                         PlayerStats_GameReport_Reset_All();
 362                 }
 363
 364                 if (round_handler_IsActive())
 365                         round_handler_Reset(game_starttime);
 366         }
 367
 368         // for RJZ
 369         if (autocvar_rjz_count_shards) {
 370                 total_shards = 0;
 371                 send_TotalShardsAll();
 372         }
 373
 374         if (shuffleteams_on_reset_map)
 375         {
 376                 shuffleteams();
 377                 shuffleteams_on_reset_map = false;
 378         }
 379
 380         FOREACH_CLIENT(true, {
 381                 if (time <= game_starttime)
 382                         accuracy_reset(it); // for spectators too because weapon accuracy is persistent
 383                 if (!IS_PLAYER(it))
 384                         continue;
 385                 if (STAT(FROZEN, it))
 386                         Unfreeze(it, false);
 387                 player_powerups_remove_all(it);
 388                 entity store = PS(it);
 389                 if (store)
 390                 {
 391                         Inventory_clear(store.inventory);
 392                         Inventory_update(store);
 393                 }
 394         });
 395
 396         MUTATOR_CALLHOOK(reset_map_global);
 397
 398         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 399         {
 400                 if(IS_CLIENT(it))
 401                         continue;
 402                 if (it.reset)
 403                 {
 404                         it.reset(it);
 405                         continue;
 406                 }
 407                 if (it.team_saved) it.team = it.team_saved;
 408                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 409         });
 410
 411         // Waypoints and assault start come LAST
 412         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 413                 if (it.reset2) it.reset2(it);
 414         });
 415
 416         // Moving the player reset code here since the player-reset depends
 417         // on spawnpoint entities which have to be reset first --blub
 418         if (!MUTATOR_CALLHOOK(reset_map_players))
 419         {
 420                 FOREACH_CLIENT(IS_PLAYER(it),
 421                 {
 422                         // PlayerScore_Clear(it);
 423                         CS(it).killcount = 0;
 424                         // stop the player from moving so that they stand still once they get respawned
 425                         it.velocity = '0 0 0';
 426                         it.avelocity = '0 0 0';
 427                         CS(it).movement = '0 0 0';
 428                         PutClientInServer(it);
 429                 });
 430         }
 431 }
 432
 433 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 434 void ReadyRestart_think(entity this)
 435 {
 436         if (!warmup_stage) // if the countdown was not aborted
 437                 reset_map(false);
 438         delete(this);
 439 }
 440
 441 // Forces a restart of the game without actually reloading the map // this is a mess...
 442 void ReadyRestart_force(bool is_fake_round_start)
 443 {
 444         if (time <= game_starttime && game_stopped)
 445                 return;
 446         if (!is_fake_round_start && !autocvar_g_campaign)
 447                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_COUNTDOWN_RESTART);
 448
 449         VoteReset(true);
 450
 451         // clear overtime, we have to decrease timelimit to its original value again.
 452         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 453                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 454         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = overtimes = 0;
 455
 456         if(warmup_stage)
 457                 game_starttime = time; // Warmup: No countdown in warmup
 458         else if (autocvar_g_campaign)
 459                 game_starttime = time + 3;
 460         else
 461                 game_starttime = time + RESTART_COUNTDOWN; // Go into match mode
 462
 463         // clear player attributes
 464         FOREACH_CLIENT(IS_PLAYER(it), {
 465                 it.alivetime = 0;
 466                 CS(it).killcount = 0;
 467         });
 468
 469         // if we're ending the warmup stage call the corresponding hook
 470         if(!is_fake_round_start && !warmup_stage)
 471                 localcmd("\nsv_hook_warmupend\n");
 472
 473         // reset the .ready status of all players (also spectators)
 474         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 475                 it.ready = false;
 476                 Kill_Notification(NOTIF_ONE_ONLY, it, MSG_CENTER, CPID_MISSING_READY);
 477         });
 478         readycount = 0;
 479         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 480
 481         // lock teams with lockonrestart
 482         if (autocvar_teamplay_lockonrestart && teamplay)
 483                 lockteams = !warmup_stage;
 484
 485         // initiate the restart-countdown-announcer entity
 486         if (!is_fake_round_start && sv_ready_restart_after_countdown && !warmup_stage)
 487         {
 488                 entity restart_timer = new_pure(restart_timer);
 489                 setthink(restart_timer, ReadyRestart_think);
 490                 restart_timer.nextthink = game_starttime;
 491         }
 492
 493         // after a restart every players number of allowed timeouts gets reset, too
 494         if (autocvar_sv_timeout)
 495         {
 496                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 497         }
 498
 499         round_handler_Activate(!warmup_stage);
 500         if (!sv_ready_restart_after_countdown || warmup_stage)
 501                 reset_map(is_fake_round_start);
 502
 503         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 504 }
 505
 506 void ReadyRestart(bool forceWarmupEnd)
 507 {
 508         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing)
 509         {
 510                 // NOTE: ReadyRestart support is mandatory in campaign
 511                 if (autocvar_g_campaign)
 512                         error("ReadyRestart must be supported in campaign mode!");
 513                 localcmd("restart\n"); // if ReadyRestart is denied, restart the server
 514         }
 515         else localcmd("\nsv_hook_readyrestart\n");
 516
 517         if(forceWarmupEnd || autocvar_g_campaign)
 518                 warmup_stage = 0; // forcefully end warmup and go to match stage
 519         else
 520                 warmup_stage = autocvar_g_warmup; // go into warmup if it's enabled, otherwise restart into match stage
 521
 522         ReadyRestart_force(false);
 523 }
 524
 525 /* Count the players who are ready and determine whether or not to restart the match when:
 526  * a player presses F4                      server/command/cmd.qc  ClientCommand_ready()
 527  * a player switches from players to specs  server/client.qc       PutObserverInServer()
 528  * a player joins (from specs or directly)  server/client.qc       PutPlayerInServer()
 529  * a player disconnects                     server/client.qc       ClientDisconnect()   */
 530 void ReadyCount()
 531 {
 532         // cannot reset the game while a timeout is active or pending
 533         if (timeout_status) return;
 534
 535         int total_players = 0, human_players = 0, humans_ready = 0;
 536         readycount = 0;
 537
 538         FOREACH_CLIENT(IS_PLAYER(it) || INGAME_JOINED(it), {
 539                 ++total_players;
 540                 if (it.ready) ++readycount;
 541                 if (IS_REAL_CLIENT(it))
 542                 {
 543                         ++human_players;
 544                         if (it.ready) ++humans_ready;
 545                 }
 546         });
 547
 548         Nagger_ReadyCounted();
 549
 550         // can't read warmup_stage here as it could have been set to 0 by ReadyRestart()
 551         // and we need to use this when checking if we should abort the countdown
 552         // map_minplayers can only be > 0 if g_warmup was -1 at worldspawn
 553         int minplayers = autocvar_g_warmup > 1 ? autocvar_g_warmup : map_minplayers;
 554
 555         if (total_players < minplayers)
 556         {
 557                 if (game_starttime > time) // someone bailed during countdown, back to warmup
 558                 {
 559                         warmup_stage = autocvar_g_warmup; // CAN change it AFTER calling Nagger_ReadyCounted() this frame
 560                         game_starttime = time;
 561                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, COUNTDOWN_STOP, minplayers);
 562                         if (!sv_ready_restart_after_countdown) // if we ran reset_map() at start of countdown
 563                                 FOREACH_CLIENT(IS_PLAYER(it), { ResetPlayerResources(it); });
 564                 }
 565                 if (warmup_limit > 0)
 566                         warmup_limit = -1;
 567                 return; // don't ReadyRestart if players are ready but too few
 568         }
 569         else if (minplayers && warmup_limit <= 0)
 570         {
 571                 // there's enough players now but we're still in infinite warmup
 572                 warmup_limit = cvar("g_warmup_limit");
 573                 if (warmup_limit == 0)
 574                         warmup_limit = autocvar_timelimit * 60;
 575                 if (warmup_limit > 0)
 576                         game_starttime = time;
 577                 // implicit else: g_warmup -1 && g_warmup_limit -1 means
 578                 // warmup continues until enough players AND enough RUPs (no time limit)
 579         }
 580
 581         if (humans_ready && humans_ready >= rint(human_players * bound(0.5, cvar("g_warmup_majority_factor"), 1)))
 582                 ReadyRestart(true);
 583 }
 584
 585
 586 // ======================================
 587 //  Supporting functions for VoteCommand
 588 // ======================================
 589
 590 bool Votecommand_check_assignment(entity caller, float assignment)
 591 {
 592         bool from_server = (!caller);
 593
 594         if ((assignment == VC_ASGNMNT_BOTH)
 595             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 596             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 597
 598         return false;
 599 }
 600
 601 string VoteCommand_extractcommand(string input, float startpos, int argc)
 602 {
 603         string output;
 604
 605         if ((argc - 1) < startpos) output = "";
 606         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 607
 608         return output;
 609 }
 610
 611 bool VoteCommand_checknasty(string vote_command)
 612 {
 613         return !((strstrofs(vote_command, ";", 0) >= 0)
 614             || (strstrofs(vote_command, "\n", 0) >= 0)
 615             || (strstrofs(vote_command, "\r", 0) >= 0)
 616             || (strstrofs(vote_command, "$", 0) >= 0));
 617 }
 618
 619 // NOTE: requires input to be surrounded by spaces
 620 string VoteCommand_checkreplacements(string input)
 621 {
 622         // add a space around the input so the start and end of the list is captured
 623         string output = strcat(" ", input, " ");
 624         // allow gotomap replacements
 625         output = strreplace(" map ", " gotomap ", output);
 626         output = strreplace(" chmap ", " gotomap ", output);
 627         return output;
 628 }
 629
 630 bool VoteCommand_checkinlist(string vote_command, string list)
 631 {
 632         if (vote_command == "" || list == "")
 633                 return false;
 634
 635         string l = VoteCommand_checkreplacements(list);
 636         return (strstrofs(l, VoteCommand_checkreplacements(vote_command), 0) >= 0);
 637 }
 638
 639 string ValidateMap(string validated_map, entity caller)
 640 {
 641         validated_map = MapInfo_FixName(validated_map);
 642
 643         if (!validated_map)
 644         {
 645                 print_to(caller, "This map is not available on this server.");
 646                 return string_null;
 647         }
 648
 649         if (!autocvar_sv_vote_override_mostrecent && caller)
 650         {
 651                 if (Map_IsRecent(validated_map))
 652                 {
 653                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 654                         return string_null;
 655                 }
 656         }
 657
 658         if (!MapInfo_CheckMap(validated_map))
 659         {
 660                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 661                 return string_null;
 662         }
 663
 664         return validated_map;
 665 }
 666
 667 float VoteCommand_checkargs(float startpos, int argc)
 668 {
 669         float p, q, check, minargs;
 670         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 671         string cmdrestriction = "";  // No we don't.
 672         string charlist, arg;
 673         float checkmate;
 674
 675         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 676                 cmdrestriction = cvar_string(cvarname);
 677         else
 678                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 679
 680         if (cmdrestriction == "") return true;
 681
 682         ++startpos;  // skip command name
 683
 684         // check minimum arg count
 685
 686         // 0 args: argc == startpos
 687         // 1 args: argc == startpos + 1
 688         // ...
 689
 690         minargs = stof(cmdrestriction);
 691         if (argc - startpos < minargs) return false;
 692
 693         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 694
 695         for ( ; ; )
 696         {
 697                 // we know that at any time, startpos <= argc - minargs
 698                 // so this means: argc-minargs >= startpos >= argc, thus
 699                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 700                 // have been seen already
 701
 702                 if (startpos >= argc) // all args checked? GOOD
 703                         break;
 704
 705                 if (p < 0)            // no more args? FAIL
 706                 {
 707                         // exception: exactly minargs left, this one included
 708                         if (argc - startpos == minargs) break;
 709
 710                         // otherwise fail
 711                         return false;
 712                 }
 713
 714                 // cut to next semicolon
 715                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 716                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 717                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 718
 719                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 720                 // charlist = strreplace("^^", ";", charlist);
 721
 722                 if (charlist != "")
 723                 {
 724                         // verify the arg only contains allowed chars
 725                         arg = argv(startpos);
 726                         checkmate = strlen(arg);
 727                         for (check = 0; check < checkmate; ++check)
 728                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 729                         // not allowed character
 730                         // all characters are allowed. FINE.
 731                 }
 732
 733                 ++startpos;
 734                 --minargs;
 735                 p = q;
 736         }
 737
 738         return true;
 739 }
 740
 741 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 742 {
 743         string first_command = argv(startpos);
 744         int missing_chars = argv_start_index(startpos);
 745
 746         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 747                 return 0;
 748
 749         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 750
 751         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 752
 753         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 754         {
 755                 case MUT_VOTEPARSE_CONTINUE: { break; }
 756                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 757                 case MUT_VOTEPARSE_INVALID: { return -1; }
 758                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 759         }
 760
 761         vote_target_type = VOTE_TARGET_ALL;
 762
 763         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 764         {
 765                 case "kick":
 766                 case "kickban":    // catch all kick/kickban commands
 767                 {
 768                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 769                         float accepted = VerifyClientEntity(victim, true, false);
 770
 771                         if (accepted > 0)
 772                         {
 773                                 string reason = "No reason provided";
 774                                 if(argc > next_token)
 775                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 776
 777                                 string command_arguments = reason;
 778                                 if (first_command == "kickban")
 779                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 780
 781                                 if (first_command == "kick") // z411 : Use our kick implementation - kind of hacky...
 782                                         vote_parsed_command = strcat("defer 2 \"sv_cmd kickkick # ", ftos(etof(victim)), " ", command_arguments, "\"");
 783                                 else
 784                                         vote_parsed_command = strcat("defer 2 \"", first_command, " # ", ftos(etof(victim)), " ", command_arguments, "\"");
 785
 786                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 787                         }
 788                         else
 789                         {
 790                                 print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
 791                                 return 0;
 792                         }
 793
 794                         break;
 795                 }
 796
 797                 case "map":
 798                 case "chmap":
 799                 case "gotomap":  // re-direct all map selection commands to gotomap
 800                 {
 801                         vote_command = ValidateMap(argv(startpos + 1), caller);
 802                         if (!vote_command)  return -1;
 803                         vote_parsed_command = strcat("defer 2 \"gotomap ", vote_command, "\"");
 804                         vote_parsed_display = strzone(strcat("^1gotomap ", vote_command));
 805
 806                         break;
 807                 }
 808
 809                 // z411 team calls
 810                 case "teamname":
 811                 {
 812                         if (teamplay && Team_IsValidTeam(caller.team)) {
 813                                 vote_target_type = VOTE_TARGET_TEAM;
 814
 815                                 string tmname = strtolower(Static_Team_ColorName(caller.team));
 816                                 string newname = argv(startpos + 1);
 817
 818                                 vote_parsed_command = strcat(first_command, " ", tmname, " \"", newname, "\"");
 819                                 vote_parsed_display = strzone(strcat("^3(Team) ^1", first_command, " ^2", newname));
 820                         } else { print_to(caller, "vcall: Not in a team\n"); return 0; }
 821
 822                         break;
 823                 }
 824
 825                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 826                 // maybe fallback instead of aborting if map name is invalid?
 827                 case "nextmap":
 828                 {
 829                         vote_command = ValidateMap(argv(startpos + 1), caller);
 830                         if (!vote_command)  return -1;
 831                         vote_parsed_command = strcat("nextmap ", vote_command);
 832                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 833
 834                         break;
 835                 }
 836
 837                 case "timelimit": // include restrictions on the maximum votable time limit
 838                 {
 839                         float timelimit_vote = stof(argv(startpos + 1));
 840                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 841                         {
 842                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 843                                 return -1;
 844                         }
 845                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 846                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 847                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 848
 849                         break;
 850                 }
 851
 852                 case "gg":
 853                 case "shuffleteams":
 854                 case "endmatch":
 855                 {
 856                         // add a delay so that vote result can be seen and announcer can be heard
 857                         // if the vote is accepted
 858                         vote_parsed_command = strcat("defer 2 ", vote_command);
 859                         vote_parsed_display = strzone(strcat("^1", vote_command));
 860
 861                         break;
 862                 }
 863
 864                 case "reset":
 865                 case "restart": // re-direct all match restarting to resetmatch
 866                         vote_command = "resetmatch"; // fall-through
 867                 case "resetmatch":
 868                 {
 869                         vote_parsed_command = strcat("defer 2 ", vote_command);
 870                         vote_parsed_display = strzone(strcat("^1", vote_command));
 871
 872                         break;
 873                 }
 874
 875                 case "allready":
 876                 {
 877                         if(!warmup_stage) {
 878                                 print_to(caller, "Game already started. Use the resetmatch command to restart the match.");
 879                                 return -1;
 880                         }
 881
 882                         vote_parsed_command = strcat("defer 2 ", vote_command);
 883                         vote_parsed_display = strzone(strcat("^1", vote_command));
 884                         break;
 885                 }
 886
 887                 default:
 888                 {
 889                         vote_parsed_command = vote_command;
 890                         vote_parsed_display = strzone(strcat("^1", vote_command));
 891
 892                         break;
 893                 }
 894         }
 895
 896         return 1;
 897 }
 898
 899
 900 // =======================
 901 //  Command Sub-Functions
 902 // =======================
 903
 904 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 905 {
 906         switch (request)
 907         {
 908                 case CMD_REQUEST_COMMAND:
 909                 {
 910                         if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
 911                         {
 912                                 print_to(caller, "^1You are banned from voting.");
 913                                 Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBANYN);
 914                                 return;
 915                         }
 916
 917                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 918                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 919                         {
 920                                 print_to(caller, "^1You have already voted.");
 921                         }
 922
 923                         else  // everything went okay, continue changing vote
 924                         {
 925                                 print_to(caller, "^1You abstained from your vote.");
 926                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 927                                 msg_entity = caller;
 928                                 if (!autocvar_sv_vote_singlecount)
 929                                         VoteCount(false);
 930                         }
 931
 932                         return;
 933                 }
 934
 935                 default:
 936                 case CMD_REQUEST_USAGE:
 937                 {
 938                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 939                         print_to(caller, "  No arguments required.");
 940                         return;
 941                 }
 942         }
 943 }
 944
 945 void print_available_commands_to(entity caller)
 946 {
 947         print_to(caller, strcat("You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 948 }
 949
 950 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 951 {
 952         switch (request)
 953         {
 954                 case CMD_REQUEST_COMMAND:
 955                 {
 956                         float tmp_playercount = 0;
 957                         int parse_error;
 958
 959                         if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
 960                         {
 961                                 print_to(caller, "^1You are banned from calling a vote.");
 962                                 Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBAN);
 963                                 return;
 964                         }
 965
 966                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 967
 968                         if (!autocvar_sv_vote_call && caller)
 969                         {
 970                                 print_to(caller, "^1Vote calling is not allowed.");
 971                         }
 972                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 973                         {
 974                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 975                         }
 976                         else if (vote_called)
 977                         {
 978                                 print_to(caller, "^1There is already a vote called.");
 979                         }
 980                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 981                         {
 982                                 print_to(caller, "^1Only players can call a vote.");
 983                         }
 984                         else if (caller && !IS_CLIENT(caller))
 985                         {
 986                                 print_to(caller, "^1Only connected clients can vote.");
 987                         }
 988                         else if (timeout_status && vote_command != "timein")
 989                         {
 990                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 991                         }
 992                         else if (caller && (time < caller.vote_waittime))
 993                         {
 994                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 995                         }
 996                         else if (!VoteCommand_checknasty(vote_command))
 997                         {
 998                                 print_to(caller, "^1Syntax error in command.");
 999                         }
1000                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
1001                         {
1002                                 if(parse_error == 0)
1003                                 {
1004                                         if (vote_called_command == "")
1005                                                 VoteCommand_call(CMD_REQUEST_USAGE, caller, argc, vote_command);
1006                                         else
1007                                                 print_to(caller, "^1This command is not acceptable or not available.");
1008                                 }
1009                         }
1010                         else  // everything went okay, continue with calling the vote
1011                         {
1012                                 vote_caller = caller;  // remember who called the vote
1013                                 vote_caller_name = strzone(GetCallerName(vote_caller));
1014                                 vote_called = VOTE_NORMAL;
1015                                 vote_called_command = strzone(vote_parsed_command);
1016                                 vote_called_display = strzone(vote_parsed_display);
1017                                 vote_endtime = time + autocvar_sv_vote_timeout;
1018
1019                                 if (caller)
1020                                 {
1021                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1022                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1023                                         msg_entity = caller;
1024                                 }
1025
1026                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
1027
1028                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
1029                                 if (autocvar_sv_vote_debug)
1030                                         bprint("\{1}^2* ^3", "^6DEBUG MODE ACTIVE: bots can vote too\n"); // so servers don't forget it on
1031                                 if (autocvar_sv_eventlog)
1032                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1033                                 Nagger_VoteChanged();
1034                                 VoteCount(true);  // needed if you are the only one
1035
1036                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
1037                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
1038                         }
1039
1040                         return;
1041                 }
1042
1043                 default:
1044                 case CMD_REQUEST_USAGE:
1045                 {
1046                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call <command>"));
1047                         print_to(caller, "  Where <command> is the command to request a vote upon.");
1048                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
1049                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
1050                         print_available_commands_to(caller);
1051                         print_to(caller, "Shortcuts: ^2vcall <command>, vend, vmap, vkick, ...");
1052                         return;
1053                 }
1054         }
1055 }
1056
1057 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
1058 {
1059         switch (request)
1060         {
1061                 case CMD_REQUEST_COMMAND:
1062                 {
1063                         if (autocvar_sv_vote_master)
1064                         {
1065                                 switch (strtolower(argv(2)))
1066                                 {
1067                                         case "do":
1068                                         {
1069                                                 int parse_error;
1070                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
1071
1072                                                 if (!caller.vote_master)
1073                                                         print_to(caller, "^1You do not have vote master privileges.");
1074                                                 else if (!VoteCommand_checknasty(vote_command))
1075                                                 {
1076                                                         print_to(caller, "^1Syntax error in command.");
1077                                                 }
1078                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
1079                                                 {
1080                                                         if(parse_error == 0)
1081                                                         {
1082                                                                 if (vote_called_command == "")
1083                                                                         VoteCommand_master(CMD_REQUEST_USAGE, caller, argc, vote_command);
1084                                                                 else
1085                                                                         print_to(caller, "^1This command is not acceptable or not available.");
1086                                                         }
1087                                                 }
1088                                                 else  // everything went okay, proceed with command
1089                                                 {
1090                                                         localcmd(strcat(vote_parsed_command, "\n"));
1091                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
1092                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
1093                                                         if (autocvar_sv_eventlog)
1094                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
1095                                                 }
1096
1097                                                 return;
1098                                         }
1099
1100                                         case "login":
1101                                         {
1102                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
1103                                                 else if (caller.vote_master)
1104                                                 {
1105                                                         print_to(caller, "^1You are already logged in as vote master.");
1106                                                 }
1107                                                 else if (autocvar_sv_vote_master_password != argv(3))
1108                                                 {
1109                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
1110                                                 }
1111                                                 else  // everything went okay, proceed with giving this player master privilages
1112                                                 {
1113                                                         caller.vote_master = true;
1114                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
1115                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
1116                                                         if (autocvar_sv_eventlog)
1117                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
1118                                                 }
1119
1120                                                 return;
1121                                         }
1122
1123                                         default:  // calling a vote for master
1124                                         {
1125                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
1126                                                 else if (vote_called)
1127                                                 {
1128                                                         print_to(caller, "^1There is already a vote called.");
1129                                                 }
1130                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
1131                                                 {
1132                                                         print_to(caller, "^1Only players can call a vote.");
1133                                                 }
1134                                                 else if (timeout_status)
1135                                                 {
1136                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
1137                                                 }
1138                                                 else  // everything went okay, continue with creating vote
1139                                                 {
1140                                                         vote_caller = caller;
1141                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
1142                                                         vote_called = VOTE_MASTER;
1143                                                         vote_called_command = strzone("XXX");
1144                                                         vote_called_display = strzone("^3master");
1145                                                         vote_endtime = time + autocvar_sv_vote_timeout;
1146
1147                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1148                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1149
1150                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
1151                                                         if (autocvar_sv_eventlog)
1152                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1153                                                         Nagger_VoteChanged();
1154                                                         VoteCount(true);  // needed if you are the only one
1155                                                 }
1156
1157                                                 return;
1158                                         }
1159                                 }
1160                         }
1161                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1162
1163                         return;
1164                 }
1165
1166                 default:
1167                 case CMD_REQUEST_USAGE:
1168                 {
1169                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [<action> [<command> | <password>]]"));
1170                         print_to(caller, "  If <action> is left blank, it calls a vote for you to become master.");
1171                         print_to(caller, "  Otherwise it can be either 'do' (to run <command>) or 'login' as master.");
1172                         return;
1173                 }
1174         }
1175 }
1176
1177 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1178 {
1179         switch (request)
1180         {
1181                 case CMD_REQUEST_COMMAND:
1182                 {
1183                         if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
1184                         {
1185                                 print_to(caller, "^1You are banned from voting.");
1186                                 Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBANYN);
1187                                 return;
1188                         }
1189
1190                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1191                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1192                         {
1193                                 print_to(caller, "^1You have already voted.");
1194                         }
1195                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1196                         {
1197                                 VoteStop(caller, true);
1198                         }
1199
1200                         else  // everything went okay, continue changing vote
1201                         {
1202                                 print_to(caller, "^1You rejected the vote.");
1203                                 caller.vote_selection = VOTE_SELECT_REJECT;
1204                                 msg_entity = caller;
1205                                 if (!autocvar_sv_vote_singlecount)
1206                                         VoteCount(false);
1207                         }
1208
1209                         return;
1210                 }
1211
1212                 default:
1213                 case CMD_REQUEST_USAGE:
1214                 {
1215                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1216                         print_to(caller, "  No arguments required.");
1217                         return;
1218                 }
1219         }
1220 }
1221
1222 void VoteCommand_status(int request, entity caller)  // BOTH
1223 {
1224         switch (request)
1225         {
1226                 case CMD_REQUEST_COMMAND:
1227                 {
1228                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1229                         else print_to(caller, "^1No vote called.");
1230
1231                         return;
1232                 }
1233
1234                 default:
1235                 case CMD_REQUEST_USAGE:
1236                 {
1237                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1238                         print_to(caller, "  No arguments required.");
1239                         return;
1240                 }
1241         }
1242 }
1243
1244 void VoteCommand_stop(int request, entity caller)  // BOTH
1245 {
1246         switch (request)
1247         {
1248                 case CMD_REQUEST_COMMAND:
1249                 {
1250                         if (!vote_called)   print_to(caller, "^1No vote called.");
1251                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller, false);
1252                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1253                         return;
1254                 }
1255
1256                 default:
1257                 case CMD_REQUEST_USAGE:
1258                 {
1259                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1260                         print_to(caller, "  No arguments required.");
1261                         return;
1262                 }
1263         }
1264 }
1265
1266 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1267 {
1268         switch (request)
1269         {
1270                 case CMD_REQUEST_COMMAND:
1271                 {
1272                         if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
1273                         {
1274                                 print_to(caller, "^1You are banned from voting.");
1275                                 Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBANYN);
1276                                 return;
1277                         }
1278
1279                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1280                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1281                         {
1282                                 print_to(caller, "^1You have already voted.");
1283                         }
1284                         else  // everything went okay, continue changing vote
1285                         {
1286                                 print_to(caller, "^1You accepted the vote.");
1287                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1288                                 msg_entity = caller;
1289                                 if (!autocvar_sv_vote_singlecount)
1290                                         VoteCount(false);
1291                         }
1292
1293                         return;
1294                 }
1295
1296                 default:
1297                 case CMD_REQUEST_USAGE:
1298                 {
1299                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1300                         print_to(caller, "  No arguments required.");
1301                         return;
1302                 }
1303         }
1304 }
1305
1306 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1307 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1308 void VoteCommand_(int request)
1309 {
1310     switch(request)
1311     {
1312         case CMD_REQUEST_COMMAND:
1313         {
1314
1315             return;
1316         }
1317
1318         default:
1319         case CMD_REQUEST_USAGE:
1320         {
1321             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1322             print_to(caller, "  No arguments required.");
1323             return;
1324         }
1325     }
1326 }
1327 */
1328
1329
1330 // ================================
1331 //  Macro system for vote commands
1332 // ================================
1333
1334 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1335 #define VOTE_COMMANDS(request, caller, arguments, command) \
1336         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1337         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1338         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1339         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1340         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1341         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1342         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1343         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1344         /* nothing */
1345
1346 void VoteCommand_macro_help(entity caller, int argc)
1347 {
1348         string command_origin = GetCommandPrefix(caller);
1349
1350         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1351         {
1352                 print_to(caller, "\nVoting commands:\n");
1353                 #define VOTE_COMMAND(name, function, description, assignment) \
1354                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1355
1356                 VOTE_COMMANDS(0, caller, 0, "");
1357                 #undef VOTE_COMMAND
1358
1359                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote <command>^7, where possible commands are listed above.\n"));
1360                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help <command>"));
1361                 print_available_commands_to(caller);
1362         }
1363         else  // usage for individual command
1364         {
1365                 #define VOTE_COMMAND(name, function, description, assignment) \
1366                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1367
1368                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1369                 #undef VOTE_COMMAND
1370
1371                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1372                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1373                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1374                 else if (argv(2) != "")
1375                         print_to(caller, "No documentation exists for this vote");
1376         }
1377 }
1378
1379 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1380 {
1381         #define VOTE_COMMAND(name, function, description, assignment) \
1382                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1383
1384         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1385         #undef VOTE_COMMAND
1386
1387         return false;
1388 }
1389
1390
1391 // ======================================
1392 //  Main function handling vote commands
1393 // ======================================
1394
1395 void VoteCommand(int request, entity caller, int argc, string vote_command)
1396 {
1397         // Guide for working with argc arguments by example:
1398         // argc:   1    - 2      - 3     - 4
1399         // argv:   0    - 1      - 2     - 3
1400         // cmd     vote - master - login - password
1401
1402         switch (request)
1403         {
1404                 case CMD_REQUEST_COMMAND:
1405                 {
1406                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1407                 }
1408
1409                 default:
1410                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1411                 case CMD_REQUEST_USAGE:
1412                 {
1413                         VoteCommand_macro_help(caller, argc);
1414                         return;
1415                 }
1416         }
1417 }