qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/items/inventory.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/playerstats.qh>
  11 #include <common/stats.qh>
  12 #include <common/util.qh>
  13 #include <common/weapons/_all.qh>
  14 #include <server/campaign.qh>
  15 #include <server/client.qh>
  16 #include <server/command/banning.qh>
  17 #include <server/command/common.qh>
  18 #include <server/command/vote.qh>
  19 #include <server/damage.qh>
  20 #include <server/gamelog.qh>
  21 #include <server/intermission.qh>
  22 #include <server/mutators/_mod.qh>
  23 #include <server/race.qh>
  24 #include <server/round_handler.qh>
  25 #include <server/scores.qh>
  26 #include <server/teamplay.qh>
  27 #include <server/weapons/accuracy.qh>
  28 #include <server/world.qh>
  29
  30 // =============================================
  31 //  Server side voting code, reworked by Samual
  32 //  Last updated: December 27th, 2011
  33 // =============================================
  34
  35 //  Nagger for players to know status of voting
  36 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  37 {
  38         int nags, i, f, b;
  39         entity e;
  40         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  41
  42         // bits:
  43         //   1 = ready
  44         //   2 = player needs to ready up
  45         //   4 = vote
  46         //   8 = player needs to vote
  47         //  16 = warmup
  48         // sendflags:
  49         //  64 = vote counts
  50         // 128 = vote string
  51
  52         nags = 0;
  53         if (readycount)
  54         {
  55                 nags |= BIT(0);
  56                 if (to.ready == 0) nags |= BIT(1);
  57         }
  58         if (vote_called)
  59         {
  60                 nags |= BIT(2);
  61                 if (to.vote_selection == 0) nags |= BIT(3);
  62         }
  63         if (warmup_stage) nags |= BIT(4);
  64
  65         if (sendflags & BIT(6)) nags |= BIT(6);
  66
  67         if (sendflags & BIT(7)) nags |= BIT(7);
  68
  69         if (!(nags & 4))  // no vote called? send no string
  70                 nags &= ~(BIT(6) | BIT(7));
  71
  72         WriteByte(MSG_ENTITY, nags);
  73
  74         if (nags & BIT(6))
  75         {
  76                 WriteByte(MSG_ENTITY, vote_accept_count);
  77                 WriteByte(MSG_ENTITY, vote_reject_count);
  78                 WriteByte(MSG_ENTITY, vote_needed_overall);
  79                 WriteChar(MSG_ENTITY, to.vote_selection);
  80         }
  81
  82         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  83
  84         if (nags & 1)
  85         {
  86                 for (i = 1; i <= maxclients; i += 8)
  87                 {
  88                         for (f = 0, e = edict_num(i), b = BIT(0); b < BIT(8); b <<= 1, e = nextent(e))
  89                                 if (!IS_REAL_CLIENT(e) || e.ready)
  90                                         f |= b;
  91                         WriteByte(MSG_ENTITY, f);
  92                 }
  93         }
  94
  95         return true;
  96 }
  97
  98 void Nagger_Init()
  99 {
 100         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
 101 }
 102
 103 void Nagger_VoteChanged()
 104 {
 105         if (nagger) nagger.SendFlags |= BIT(7);
 106 }
 107
 108 void Nagger_VoteCountChanged()
 109 {
 110         if (nagger) nagger.SendFlags |= BIT(6);
 111 }
 112
 113 void Nagger_ReadyCounted()
 114 {
 115         if (nagger) nagger.SendFlags |= BIT(0);
 116 }
 117
 118 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 119 string OriginalCallerName()
 120 {
 121         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 122         return vote_caller_name;
 123 }
 124
 125 // =======================
 126 //  Game logic for voting
 127 // =======================
 128
 129 void VoteReset()
 130 {
 131         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 132
 133         if (vote_called)
 134         {
 135                 strfree(vote_called_command);
 136                 strfree(vote_called_display);
 137                 strfree(vote_caller_name);
 138         }
 139
 140         vote_called = VOTE_NULL;
 141         vote_caller = NULL;
 142         vote_endtime = 0;
 143
 144         vote_parsed_command = string_null;
 145         vote_parsed_display = string_null;
 146
 147         Nagger_VoteChanged();
 148 }
 149
 150 void VoteStop(entity stopper)
 151 {
 152         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 153         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 154         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 155         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 156         VoteReset();
 157 }
 158
 159 void VoteAccept()
 160 {
 161         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 162
 163         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 164         else localcmd(strcat(vote_called_command, "\n"));
 165
 166         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 167
 168         VoteReset();
 169         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 170 }
 171
 172 void VoteReject()
 173 {
 174         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 175         VoteReset();
 176         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 177 }
 178
 179 void VoteTimeout()
 180 {
 181         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 182         VoteReset();
 183         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 184 }
 185
 186 void VoteSpam(float notvoters, float mincount, string result)
 187 {
 188         bprint(strcat(
 189                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 190                 strcat("^2:^1", ftos(vote_reject_count)),
 191                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 192                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 193                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 194
 195         if (autocvar_sv_eventlog)
 196         {
 197                 GameLogEcho(strcat(
 198                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 199                         strcat(":", ftos(vote_reject_count)),
 200                         strcat(":", ftos(vote_abstain_count)),
 201                         strcat(":", ftos(notvoters)),
 202                         strcat(":", ftos(mincount))));
 203         }
 204 }
 205
 206 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 207
 208 void VoteCount(float first_count)
 209 {
 210         // declarations
 211         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 212
 213         float vote_player_count = 0, notvoters = 0;
 214         float vote_real_player_count = 0, vote_real_accept_count = 0;
 215         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 216         float vote_needed_of_voted, final_needed_votes;
 217         float vote_factor_overall, vote_factor_of_voted;
 218
 219         Nagger_VoteCountChanged();
 220
 221         // add up all the votes from each connected client
 222         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 223                 ++vote_player_count;
 224                 if (IS_PLAYER(it))   ++vote_real_player_count;
 225                 switch (it.vote_selection)
 226                 {
 227                         case VOTE_SELECT_REJECT:
 228                         { ++vote_reject_count;
 229                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 230                         }
 231                         case VOTE_SELECT_ACCEPT:
 232                         { ++vote_accept_count;
 233                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 234                         }
 235                         case VOTE_SELECT_ABSTAIN:
 236                         { ++vote_abstain_count;
 237                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 238                         }
 239                         default: break;
 240                 }
 241         });
 242
 243         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 244         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 245         {
 246                 if (vote_caller)   vote_caller.vote_waittime = 0;
 247                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 248                 VoteReset();
 249                 return;
 250         }
 251
 252         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 253         if (!spectators_allowed && (vote_real_player_count > 0))
 254         {
 255                 vote_accept_count = vote_real_accept_count;
 256                 vote_reject_count = vote_real_reject_count;
 257                 vote_abstain_count = vote_real_abstain_count;
 258                 vote_player_count = vote_real_player_count;
 259         }
 260
 261         // people who have no opinion in any way :D
 262         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 263
 264         // determine the goal for the vote to be passed or rejected normally
 265         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 266         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 267
 268         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 269         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 270         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 271
 272         // are there any players at all on the server? it could be an admin vote
 273         if (vote_player_count == 0 && first_count)
 274         {
 275                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 276                 VoteAccept();
 277                 return;
 278         }
 279
 280         // since there ARE players, finally calculate the result of the vote
 281         if (vote_accept_count >= vote_needed_overall)
 282         {
 283                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 284                 VoteAccept();
 285                 return;
 286         }
 287
 288         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 289         {
 290                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 291                 VoteReject();
 292                 return;
 293         }
 294
 295         // there is not enough votes in either direction, now lets just calculate what the voters have said
 296         if (time > vote_endtime)
 297         {
 298                 final_needed_votes = vote_needed_overall;
 299
 300                 if (autocvar_sv_vote_majority_factor_of_voted)
 301                 {
 302                         if (vote_accept_count >= vote_needed_of_voted)
 303                         {
 304                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 305                                 VoteAccept();
 306                                 return;
 307                         }
 308
 309                         if (vote_accept_count + vote_reject_count > 0)
 310                         {
 311                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 312                                 VoteReject();
 313                                 return;
 314                         }
 315
 316                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 317                 }
 318
 319                 // it didn't pass or fail, so not enough votes to even make a decision.
 320                 VoteSpam(notvoters, final_needed_votes, "timeout");
 321                 VoteTimeout();
 322         }
 323 }
 324
 325 void VoteThink()
 326 {
 327         if (vote_endtime > 0)        // a vote was called
 328         {
 329                 if (time > vote_endtime) // time is up
 330                         VoteCount(false);
 331         }
 332 }
 333
 334
 335 // =======================
 336 //  Game logic for warmup
 337 // =======================
 338
 339 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 340 void reset_map(bool dorespawn, bool is_fake_round_start)
 341 {
 342         if (time <= game_starttime)
 343         {
 344                 if (game_stopped)
 345                         return;
 346
 347                 if (!is_fake_round_start)
 348                 {
 349                         Score_ClearAll();
 350                         PlayerStats_GameReport_Reset_All();
 351                 }
 352
 353                 if (round_handler_IsActive())
 354                         round_handler_Reset(game_starttime);
 355         }
 356
 357         if (shuffleteams_on_reset_map)
 358         {
 359                 shuffleteams();
 360                 shuffleteams_on_reset_map = false;
 361         }
 362
 363         FOREACH_CLIENT(true, {
 364                 if (time <= game_starttime)
 365                         accuracy_reset(it); // for spectators too because weapon accuracy is persistent
 366                 if (!IS_PLAYER(it))
 367                         continue;
 368                 if (STAT(FROZEN, it))
 369                         Unfreeze(it, false);
 370                 player_powerups_remove_all(it);
 371                 entity store = PS(it);
 372                 if (store)
 373                 {
 374                         Inventory_clear(store.inventory);
 375                         Inventory_update(store);
 376                 }
 377         });
 378
 379         MUTATOR_CALLHOOK(reset_map_global);
 380
 381         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 382         {
 383                 if(IS_CLIENT(it))
 384                         continue;
 385                 if (it.reset)
 386                 {
 387                         it.reset(it);
 388                         continue;
 389                 }
 390                 if (it.team_saved) it.team = it.team_saved;
 391                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 392         });
 393
 394         // Waypoints and assault start come LAST
 395         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 396                 if (it.reset2) it.reset2(it);
 397         });
 398
 399         // Moving the player reset code here since the player-reset depends
 400         // on spawnpoint entities which have to be reset first --blub
 401         if (dorespawn)
 402         {
 403                 if (!MUTATOR_CALLHOOK(reset_map_players))
 404                 {
 405                         FOREACH_CLIENT(IS_PLAYER(it),
 406                         {
 407                                 // PlayerScore_Clear(it);
 408                                 CS(it).killcount = 0;
 409                                 // stop the player from moving so that he stands still once he gets respawned
 410                                 it.velocity = '0 0 0';
 411                                 it.avelocity = '0 0 0';
 412                                 CS(it).movement = '0 0 0';
 413                                 PutClientInServer(it);
 414                         });
 415                 }
 416         }
 417 }
 418
 419 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 420 void ReadyRestart_think(entity this)
 421 {
 422         reset_map(true, false);
 423         delete(this);
 424 }
 425
 426 // Forces a restart of the game without actually reloading the map // this is a mess...
 427 void ReadyRestart_force(bool is_fake_round_start)
 428 {
 429         if (time <= game_starttime && game_stopped)
 430                 return;
 431         if (!is_fake_round_start)
 432                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_COUNTDOWN_RESTART);
 433
 434         VoteReset();
 435
 436         // clear overtime, we have to decrease timelimit to its original value again.
 437         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 438                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 439         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = overtimes = 0;
 440
 441         if(warmup_stage)
 442                 game_starttime = time; // Warmup: No countdown in warmup
 443         else if (autocvar_g_campaign)
 444                 game_starttime = time + 3;
 445         else
 446                 game_starttime = time + RESTART_COUNTDOWN; // Go into match mode
 447
 448         // clear player attributes
 449         FOREACH_CLIENT(IS_PLAYER(it), {
 450                 it.alivetime = 0;
 451                 CS(it).killcount = 0;
 452         });
 453
 454         // if we're ending the warmup stage call the corresponding hook
 455         if(!is_fake_round_start && !warmup_stage)
 456                 localcmd("\nsv_hook_warmupend\n");
 457
 458         // reset the .ready status of all players (also spectators)
 459         FOREACH_CLIENT(IS_REAL_CLIENT(it), { it.ready = false; });
 460         readycount = 0;
 461         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 462
 463         // lock teams with lockonrestart
 464         if (autocvar_teamplay_lockonrestart && teamplay)
 465                 lockteams = !warmup_stage;
 466
 467         // initiate the restart-countdown-announcer entity
 468         if (!is_fake_round_start && sv_ready_restart_after_countdown && !warmup_stage)
 469         {
 470                 entity restart_timer = new_pure(restart_timer);
 471                 setthink(restart_timer, ReadyRestart_think);
 472                 restart_timer.nextthink = game_starttime;
 473         }
 474
 475         // after a restart every players number of allowed timeouts gets reset, too
 476         if (autocvar_sv_timeout)
 477         {
 478                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 479         }
 480
 481         if (!sv_ready_restart_after_countdown || warmup_stage)
 482                 reset_map(true, is_fake_round_start);
 483
 484         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 485 }
 486
 487 void ReadyRestart(bool forceWarmupEnd)
 488 {
 489         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing)
 490         {
 491                 // NOTE: ReadyRestart support is mandatory in campaign
 492                 if (autocvar_g_campaign)
 493                         error("ReadyRestart must be supported in campaign mode!");
 494                 localcmd("restart\n"); // if ReadyRestart is denied, restart the server
 495         }
 496         else localcmd("\nsv_hook_readyrestart\n");
 497
 498         if(forceWarmupEnd || autocvar_g_campaign)
 499                 warmup_stage = 0; // forcefully end warmup and go to match stage
 500         else
 501                 warmup_stage = autocvar_g_warmup; // go into warmup if it's enabled, otherwise restart into match stage
 502
 503         ReadyRestart_force(false);
 504 }
 505
 506 /* Count the players who are ready and determine whether or not to restart the match when:
 507  * a player presses F4                      server/command/cmd.qc  ClientCommand_ready()
 508  * a player switches from players to specs  server/client.qc       PutObserverInServer()
 509  * a player joins (from specs or directly)  server/client.qc       PutPlayerInServer()
 510  * a player disconnects                     server/client.qc       ClientDisconnect()   */
 511 void ReadyCount()
 512 {
 513         // cannot reset the game while a timeout is active or pending
 514         if (timeout_status) return;
 515
 516         float ready_needed_factor, ready_needed_count;
 517         float t_players = 0;
 518         readycount = 0;
 519
 520         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME_JOINED(it)), {
 521                 ++t_players;
 522                 if (it.ready) ++readycount;
 523         });
 524
 525         Nagger_ReadyCounted();
 526
 527         // can't read warmup_stage here as it could have been set to 0 by ReadyRestart()
 528         // and we need to use this when checking if we should abort the countdown
 529         // map_minplayers can only be > 0 if g_warmup was -1 at worldspawn
 530         int minplayers = autocvar_g_warmup > 1 ? autocvar_g_warmup : map_minplayers;
 531
 532         if (t_players < minplayers)
 533         {
 534                 if (game_starttime > time) // someone bailed during countdown, back to warmup
 535                 {
 536                         warmup_stage = autocvar_g_warmup; // CAN change it AFTER calling Nagger_ReadyCounted() this frame
 537                         game_starttime = time;
 538                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, COUNTDOWN_STOP, minplayers);
 539                 }
 540                 if (warmup_limit > 0)
 541                         warmup_limit = -1;
 542                 return; // don't ReadyRestart if players are ready but too few
 543         }
 544         else if (minplayers && warmup_limit <= 0)
 545         {
 546                 // there's enough players now but we're still in infinite warmup
 547                 warmup_limit = cvar("g_warmup_limit");
 548                 if (warmup_limit == 0)
 549                         warmup_limit = autocvar_timelimit * 60;
 550                 if (warmup_limit > 0)
 551                         game_starttime = time;
 552                 // implicit else: g_warmup -1 && g_warmup_limit -1 means
 553                 // warmup continues until enough players AND enough RUPs (no time limit)
 554         }
 555
 556         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 1);
 557         ready_needed_count = ceil(t_players * ready_needed_factor);
 558
 559         if (readycount >= ready_needed_count) ReadyRestart(true);
 560 }
 561
 562
 563 // ======================================
 564 //  Supporting functions for VoteCommand
 565 // ======================================
 566
 567 bool Votecommand_check_assignment(entity caller, float assignment)
 568 {
 569         bool from_server = (!caller);
 570
 571         if ((assignment == VC_ASGNMNT_BOTH)
 572             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 573             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 574
 575         return false;
 576 }
 577
 578 string VoteCommand_extractcommand(string input, float startpos, int argc)
 579 {
 580         string output;
 581
 582         if ((argc - 1) < startpos) output = "";
 583         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 584
 585         return output;
 586 }
 587
 588 bool VoteCommand_checknasty(string vote_command)
 589 {
 590         return !((strstrofs(vote_command, ";", 0) >= 0)
 591             || (strstrofs(vote_command, "\n", 0) >= 0)
 592             || (strstrofs(vote_command, "\r", 0) >= 0)
 593             || (strstrofs(vote_command, "$", 0) >= 0));
 594 }
 595
 596 // NOTE: requires input to be surrounded by spaces
 597 string VoteCommand_checkreplacements(string input)
 598 {
 599         // add a space around the input so the start and end of the list is captured
 600         string output = strcat(" ", input, " ");
 601         // allow gotomap replacements
 602         output = strreplace(" map ", " gotomap ", output);
 603         output = strreplace(" chmap ", " gotomap ", output);
 604         return output;
 605 }
 606
 607 bool VoteCommand_checkinlist(string vote_command, string list)
 608 {
 609         if (vote_command == "" || list == "")
 610                 return false;
 611
 612         string l = VoteCommand_checkreplacements(list);
 613         return (strstrofs(l, VoteCommand_checkreplacements(vote_command), 0) >= 0);
 614 }
 615
 616 string ValidateMap(string validated_map, entity caller)
 617 {
 618         validated_map = MapInfo_FixName(validated_map);
 619
 620         if (!validated_map)
 621         {
 622                 print_to(caller, "This map is not available on this server.");
 623                 return string_null;
 624         }
 625
 626         if (!autocvar_sv_vote_override_mostrecent && caller)
 627         {
 628                 if (Map_IsRecent(validated_map))
 629                 {
 630                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 631                         return string_null;
 632                 }
 633         }
 634
 635         if (!MapInfo_CheckMap(validated_map))
 636         {
 637                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 638                 return string_null;
 639         }
 640
 641         return validated_map;
 642 }
 643
 644 float VoteCommand_checkargs(float startpos, int argc)
 645 {
 646         float p, q, check, minargs;
 647         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 648         string cmdrestriction = "";  // No we don't.
 649         string charlist, arg;
 650         float checkmate;
 651
 652         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 653                 cmdrestriction = cvar_string(cvarname);
 654         else
 655                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 656
 657         if (cmdrestriction == "") return true;
 658
 659         ++startpos;  // skip command name
 660
 661         // check minimum arg count
 662
 663         // 0 args: argc == startpos
 664         // 1 args: argc == startpos + 1
 665         // ...
 666
 667         minargs = stof(cmdrestriction);
 668         if (argc - startpos < minargs) return false;
 669
 670         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 671
 672         for ( ; ; )
 673         {
 674                 // we know that at any time, startpos <= argc - minargs
 675                 // so this means: argc-minargs >= startpos >= argc, thus
 676                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 677                 // have been seen already
 678
 679                 if (startpos >= argc) // all args checked? GOOD
 680                         break;
 681
 682                 if (p < 0)            // no more args? FAIL
 683                 {
 684                         // exception: exactly minargs left, this one included
 685                         if (argc - startpos == minargs) break;
 686
 687                         // otherwise fail
 688                         return false;
 689                 }
 690
 691                 // cut to next semicolon
 692                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 693                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 694                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 695
 696                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 697                 // charlist = strreplace("^^", ";", charlist);
 698
 699                 if (charlist != "")
 700                 {
 701                         // verify the arg only contains allowed chars
 702                         arg = argv(startpos);
 703                         checkmate = strlen(arg);
 704                         for (check = 0; check < checkmate; ++check)
 705                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 706                         // not allowed character
 707                         // all characters are allowed. FINE.
 708                 }
 709
 710                 ++startpos;
 711                 --minargs;
 712                 p = q;
 713         }
 714
 715         return true;
 716 }
 717
 718 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 719 {
 720         string first_command = argv(startpos);
 721         int missing_chars = argv_start_index(startpos);
 722
 723         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 724                 return 0;
 725
 726         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 727
 728         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 729
 730         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 731         {
 732                 case MUT_VOTEPARSE_CONTINUE: { break; }
 733                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 734                 case MUT_VOTEPARSE_INVALID: { return -1; }
 735                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 736         }
 737
 738         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 739         {
 740                 case "kick":
 741                 case "kickban":    // catch all kick/kickban commands
 742                 {
 743                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 744                         float accepted = VerifyClientEntity(victim, true, false);
 745
 746                         if (accepted > 0)
 747                         {
 748                                 string reason = "No reason provided";
 749                                 if(argc > next_token)
 750                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 751
 752                                 string command_arguments = reason;
 753                                 if (first_command == "kickban")
 754                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 755
 756                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 757                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 758                         }
 759                         else
 760                         {
 761                                 print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
 762                                 return 0;
 763                         }
 764
 765                         break;
 766                 }
 767
 768                 case "map":
 769                 case "chmap":
 770                 case "gotomap":  // re-direct all map selection commands to gotomap
 771                 {
 772                         vote_command = ValidateMap(argv(startpos + 1), caller);
 773                         if (!vote_command)  return -1;
 774                         vote_parsed_command = strcat("gotomap ", vote_command);
 775                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 776
 777                         break;
 778                 }
 779
 780                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 781                 // maybe fallback instead of aborting if map name is invalid?
 782                 case "nextmap":
 783                 {
 784                         vote_command = ValidateMap(argv(startpos + 1), caller);
 785                         if (!vote_command)  return -1;
 786                         vote_parsed_command = strcat("nextmap ", vote_command);
 787                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 788
 789                         break;
 790                 }
 791
 792                 case "timelimit": // include restrictions on the maximum votable time limit
 793                 {
 794                         float timelimit_vote = stof(argv(startpos + 1));
 795                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 796                         {
 797                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 798                                 return -1;
 799                         }
 800                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 801                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 802                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 803
 804                         break;
 805                 }
 806
 807                 case "restart":
 808                 {
 809                         // add a delay so that vote result can be seen and announcer can be heard
 810                         // if the vote is accepted
 811                         vote_parsed_command = strcat("defer 1 ", vote_command);
 812                         vote_parsed_display = strzone(strcat("^1", vote_command));
 813
 814                         break;
 815                 }
 816
 817                 case "allready":
 818                 {
 819                         if(!warmup_stage) {
 820                                 print_to(caller, "Game already started. Use the resetmatch command to restart the match.");
 821                                 return -1;
 822                         }
 823
 824                         vote_parsed_command = vote_command;
 825                         vote_parsed_display = strzone(strcat("^1", vote_command));
 826                         break;
 827                 }
 828
 829                 default:
 830                 {
 831                         vote_parsed_command = vote_command;
 832                         vote_parsed_display = strzone(strcat("^1", vote_command));
 833
 834                         break;
 835                 }
 836         }
 837
 838         return 1;
 839 }
 840
 841
 842 // =======================
 843 //  Command Sub-Functions
 844 // =======================
 845
 846 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 847 {
 848         switch (request)
 849         {
 850                 case CMD_REQUEST_COMMAND:
 851                 {
 852                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 853                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 854                         {
 855                                 print_to(caller, "^1You have already voted.");
 856                         }
 857
 858                         else  // everything went okay, continue changing vote
 859                         {
 860                                 print_to(caller, "^1You abstained from your vote.");
 861                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 862                                 msg_entity = caller;
 863                                 if (!autocvar_sv_vote_singlecount)
 864                                         VoteCount(false);
 865                         }
 866
 867                         return;
 868                 }
 869
 870                 default:
 871                 case CMD_REQUEST_USAGE:
 872                 {
 873                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 874                         print_to(caller, "  No arguments required.");
 875                         return;
 876                 }
 877         }
 878 }
 879
 880 void print_available_commands_to(entity caller)
 881 {
 882         print_to(caller, strcat("You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 883 }
 884
 885 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 886 {
 887         switch (request)
 888         {
 889                 case CMD_REQUEST_COMMAND:
 890                 {
 891                         float tmp_playercount = 0;
 892                         int parse_error;
 893
 894                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 895
 896                         if (!autocvar_sv_vote_call && caller)
 897                         {
 898                                 print_to(caller, "^1Vote calling is not allowed.");
 899                         }
 900                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 901                         {
 902                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 903                         }
 904                         else if (vote_called)
 905                         {
 906                                 print_to(caller, "^1There is already a vote called.");
 907                         }
 908                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 909                         {
 910                                 print_to(caller, "^1Only players can call a vote.");
 911                         }
 912                         else if (caller && !IS_CLIENT(caller))
 913                         {
 914                                 print_to(caller, "^1Only connected clients can vote.");
 915                         }
 916                         else if (timeout_status && vote_command != "timein")
 917                         {
 918                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 919                         }
 920                         else if (caller && (time < caller.vote_waittime))
 921                         {
 922                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 923                         }
 924                         else if (!VoteCommand_checknasty(vote_command))
 925                         {
 926                                 print_to(caller, "^1Syntax error in command.");
 927                         }
 928                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 929                         {
 930                                 if(parse_error == 0)
 931                                 {
 932                                         if (vote_called_command == "")
 933                                                 VoteCommand_call(CMD_REQUEST_USAGE, caller, argc, vote_command);
 934                                         else
 935                                                 print_to(caller, "^1This command is not acceptable or not available.");
 936                                 }
 937                         }
 938                         else  // everything went okay, continue with calling the vote
 939                         {
 940                                 vote_caller = caller;  // remember who called the vote
 941                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 942                                 vote_called = VOTE_NORMAL;
 943                                 vote_called_command = strzone(vote_parsed_command);
 944                                 vote_called_display = strzone(vote_parsed_display);
 945                                 vote_endtime = time + autocvar_sv_vote_timeout;
 946
 947                                 if (caller)
 948                                 {
 949                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 950                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 951                                         msg_entity = caller;
 952                                 }
 953
 954                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 955
 956                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 957                                 if (autocvar_sv_eventlog)
 958                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 959                                 Nagger_VoteChanged();
 960                                 VoteCount(true);  // needed if you are the only one
 961
 962                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
 963                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 964                         }
 965
 966                         return;
 967                 }
 968
 969                 default:
 970                 case CMD_REQUEST_USAGE:
 971                 {
 972                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call <command>"));
 973                         print_to(caller, "  Where <command> is the command to request a vote upon.");
 974                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 975                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 976                         print_available_commands_to(caller);
 977                         print_to(caller, "Shortcuts: ^2vcall <command>, vend, vmap, vkick, ...");
 978                         return;
 979                 }
 980         }
 981 }
 982
 983 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
 984 {
 985         switch (request)
 986         {
 987                 case CMD_REQUEST_COMMAND:
 988                 {
 989                         if (autocvar_sv_vote_master)
 990                         {
 991                                 switch (strtolower(argv(2)))
 992                                 {
 993                                         case "do":
 994                                         {
 995                                                 int parse_error;
 996                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 997
 998                                                 if (!caller.vote_master)
 999                                                         print_to(caller, "^1You do not have vote master privileges.");
1000                                                 else if (!VoteCommand_checknasty(vote_command))
1001                                                 {
1002                                                         print_to(caller, "^1Syntax error in command.");
1003                                                 }
1004                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
1005                                                 {
1006                                                         if(parse_error == 0)
1007                                                         {
1008                                                                 if (vote_called_command == "")
1009                                                                         VoteCommand_master(CMD_REQUEST_USAGE, caller, argc, vote_command);
1010                                                                 else
1011                                                                         print_to(caller, "^1This command is not acceptable or not available.");
1012                                                         }
1013                                                 }
1014                                                 else  // everything went okay, proceed with command
1015                                                 {
1016                                                         localcmd(strcat(vote_parsed_command, "\n"));
1017                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
1018                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
1019                                                         if (autocvar_sv_eventlog)
1020                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
1021                                                 }
1022
1023                                                 return;
1024                                         }
1025
1026                                         case "login":
1027                                         {
1028                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
1029                                                 else if (caller.vote_master)
1030                                                 {
1031                                                         print_to(caller, "^1You are already logged in as vote master.");
1032                                                 }
1033                                                 else if (autocvar_sv_vote_master_password != argv(3))
1034                                                 {
1035                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
1036                                                 }
1037                                                 else  // everything went okay, proceed with giving this player master privilages
1038                                                 {
1039                                                         caller.vote_master = true;
1040                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
1041                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
1042                                                         if (autocvar_sv_eventlog)
1043                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
1044                                                 }
1045
1046                                                 return;
1047                                         }
1048
1049                                         default:  // calling a vote for master
1050                                         {
1051                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
1052                                                 else if (vote_called)
1053                                                 {
1054                                                         print_to(caller, "^1There is already a vote called.");
1055                                                 }
1056                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
1057                                                 {
1058                                                         print_to(caller, "^1Only players can call a vote.");
1059                                                 }
1060                                                 else if (timeout_status)
1061                                                 {
1062                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
1063                                                 }
1064                                                 else  // everything went okay, continue with creating vote
1065                                                 {
1066                                                         vote_caller = caller;
1067                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
1068                                                         vote_called = VOTE_MASTER;
1069                                                         vote_called_command = strzone("XXX");
1070                                                         vote_called_display = strzone("^3master");
1071                                                         vote_endtime = time + autocvar_sv_vote_timeout;
1072
1073                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1074                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1075
1076                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
1077                                                         if (autocvar_sv_eventlog)
1078                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1079                                                         Nagger_VoteChanged();
1080                                                         VoteCount(true);  // needed if you are the only one
1081                                                 }
1082
1083                                                 return;
1084                                         }
1085                                 }
1086                         }
1087                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1088
1089                         return;
1090                 }
1091
1092                 default:
1093                 case CMD_REQUEST_USAGE:
1094                 {
1095                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [<action> [<command> | <password>]]"));
1096                         print_to(caller, "  If <action> is left blank, it calls a vote for you to become master.");
1097                         print_to(caller, "  Otherwise it can be either 'do' (to run <command>) or 'login' as master.");
1098                         return;
1099                 }
1100         }
1101 }
1102
1103 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1104 {
1105         switch (request)
1106         {
1107                 case CMD_REQUEST_COMMAND:
1108                 {
1109                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1110                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1111                         {
1112                                 print_to(caller, "^1You have already voted.");
1113                         }
1114                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1115                         {
1116                                 VoteStop(caller);
1117                         }
1118
1119                         else  // everything went okay, continue changing vote
1120                         {
1121                                 print_to(caller, "^1You rejected the vote.");
1122                                 caller.vote_selection = VOTE_SELECT_REJECT;
1123                                 msg_entity = caller;
1124                                 if (!autocvar_sv_vote_singlecount)
1125                                         VoteCount(false);
1126                         }
1127
1128                         return;
1129                 }
1130
1131                 default:
1132                 case CMD_REQUEST_USAGE:
1133                 {
1134                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1135                         print_to(caller, "  No arguments required.");
1136                         return;
1137                 }
1138         }
1139 }
1140
1141 void VoteCommand_status(int request, entity caller)  // BOTH
1142 {
1143         switch (request)
1144         {
1145                 case CMD_REQUEST_COMMAND:
1146                 {
1147                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1148                         else print_to(caller, "^1No vote called.");
1149
1150                         return;
1151                 }
1152
1153                 default:
1154                 case CMD_REQUEST_USAGE:
1155                 {
1156                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1157                         print_to(caller, "  No arguments required.");
1158                         return;
1159                 }
1160         }
1161 }
1162
1163 void VoteCommand_stop(int request, entity caller)  // BOTH
1164 {
1165         switch (request)
1166         {
1167                 case CMD_REQUEST_COMMAND:
1168                 {
1169                         if (!vote_called)   print_to(caller, "^1No vote called.");
1170                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1171                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1172                         return;
1173                 }
1174
1175                 default:
1176                 case CMD_REQUEST_USAGE:
1177                 {
1178                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1179                         print_to(caller, "  No arguments required.");
1180                         return;
1181                 }
1182         }
1183 }
1184
1185 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1186 {
1187         switch (request)
1188         {
1189                 case CMD_REQUEST_COMMAND:
1190                 {
1191                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1192                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1193                         {
1194                                 print_to(caller, "^1You have already voted.");
1195                         }
1196                         else  // everything went okay, continue changing vote
1197                         {
1198                                 print_to(caller, "^1You accepted the vote.");
1199                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1200                                 msg_entity = caller;
1201                                 if (!autocvar_sv_vote_singlecount)
1202                                         VoteCount(false);
1203                         }
1204
1205                         return;
1206                 }
1207
1208                 default:
1209                 case CMD_REQUEST_USAGE:
1210                 {
1211                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1212                         print_to(caller, "  No arguments required.");
1213                         return;
1214                 }
1215         }
1216 }
1217
1218 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1219 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1220 void VoteCommand_(int request)
1221 {
1222     switch(request)
1223     {
1224         case CMD_REQUEST_COMMAND:
1225         {
1226
1227             return;
1228         }
1229
1230         default:
1231         case CMD_REQUEST_USAGE:
1232         {
1233             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1234             print_to(caller, "  No arguments required.");
1235             return;
1236         }
1237     }
1238 }
1239 */
1240
1241
1242 // ================================
1243 //  Macro system for vote commands
1244 // ================================
1245
1246 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1247 #define VOTE_COMMANDS(request, caller, arguments, command) \
1248         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1249         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1250         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1251         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1252         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1253         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1254         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1255         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1256         /* nothing */
1257
1258 void VoteCommand_macro_help(entity caller, int argc)
1259 {
1260         string command_origin = GetCommandPrefix(caller);
1261
1262         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1263         {
1264                 print_to(caller, "\nVoting commands:\n");
1265                 #define VOTE_COMMAND(name, function, description, assignment) \
1266                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1267
1268                 VOTE_COMMANDS(0, caller, 0, "");
1269                 #undef VOTE_COMMAND
1270
1271                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote <command>^7, where possible commands are listed above.\n"));
1272                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help <command>"));
1273                 print_available_commands_to(caller);
1274         }
1275         else  // usage for individual command
1276         {
1277                 #define VOTE_COMMAND(name, function, description, assignment) \
1278                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1279
1280                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1281                 #undef VOTE_COMMAND
1282
1283                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1284                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1285                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1286                 else if (argv(2) != "")
1287                         print_to(caller, "No documentation exists for this vote");
1288         }
1289 }
1290
1291 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1292 {
1293         #define VOTE_COMMAND(name, function, description, assignment) \
1294                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1295
1296         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1297         #undef VOTE_COMMAND
1298
1299         return false;
1300 }
1301
1302
1303 // ======================================
1304 //  Main function handling vote commands
1305 // ======================================
1306
1307 void VoteCommand(int request, entity caller, int argc, string vote_command)
1308 {
1309         // Guide for working with argc arguments by example:
1310         // argc:   1    - 2      - 3     - 4
1311         // argv:   0    - 1      - 2     - 3
1312         // cmd     vote - master - login - password
1313
1314         switch (request)
1315         {
1316                 case CMD_REQUEST_COMMAND:
1317                 {
1318                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1319                 }
1320
1321                 default:
1322                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1323                 case CMD_REQUEST_USAGE:
1324                 {
1325                         VoteCommand_macro_help(caller, argc);
1326                         return;
1327                 }
1328         }
1329 }