qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <server/client.qh>
   4 #include <common/weapons/_all.qh>
   5 #include <common/stats.qh>
   6 #include <server/gamelog.qh>
   7 #include <server/miscfunctions.qh>
   8
   9 #include <common/command/_mod.qh>
  10 #include "vote.qh"
  11
  12 #include "common.qh"
  13
  14 #include "../damage.qh"
  15 #include <server/intermission.qh>
  16 #include "../world.qh"
  17 #include "../teamplay.qh"
  18 #include "../race.qh"
  19 #include "../round_handler.qh"
  20 #include "../scores.qh"
  21
  22 #include <server/mutators/_mod.qh>
  23 #include <common/gamemodes/_mod.qh>
  24
  25 #include <common/constants.qh>
  26 #include <common/net_linked.qh>
  27 #include <common/mapinfo.qh>
  28 #include <common/notifications/all.qh>
  29 #include <common/playerstats.qh>
  30 #include <common/util.qh>
  31
  32 // =============================================
  33 //  Server side voting code, reworked by Samual
  34 //  Last updated: December 27th, 2011
  35 // =============================================
  36
  37 //  Nagger for players to know status of voting
  38 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  39 {
  40         int nags, i, f, b;
  41         entity e;
  42         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  43
  44         // bits:
  45         //   1 = ready
  46         //   2 = player needs to ready up
  47         //   4 = vote
  48         //   8 = player needs to vote
  49         //  16 = warmup
  50         // sendflags:
  51         //  64 = vote counts
  52         // 128 = vote string
  53
  54         nags = 0;
  55         if (readycount)
  56         {
  57                 nags |= BIT(0);
  58                 if (to.ready == 0) nags |= BIT(1);
  59         }
  60         if (vote_called)
  61         {
  62                 nags |= BIT(2);
  63                 if (to.vote_selection == 0) nags |= BIT(3);
  64         }
  65         if (warmup_stage) nags |= BIT(4);
  66
  67         if (sendflags & BIT(6)) nags |= BIT(6);
  68
  69         if (sendflags & BIT(7)) nags |= BIT(7);
  70
  71         if (!(nags & 4))  // no vote called? send no string
  72                 nags &= ~(BIT(6) | BIT(7));
  73
  74         WriteByte(MSG_ENTITY, nags);
  75
  76         if (nags & BIT(6))
  77         {
  78                 WriteByte(MSG_ENTITY, vote_accept_count);
  79                 WriteByte(MSG_ENTITY, vote_reject_count);
  80                 WriteByte(MSG_ENTITY, vote_needed_overall);
  81                 WriteChar(MSG_ENTITY, to.vote_selection);
  82         }
  83
  84         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  85
  86         if (nags & 1)
  87         {
  88                 for (i = 1; i <= maxclients; i += 8)
  89                 {
  90                         for (f = 0, e = edict_num(i), b = BIT(0); b < BIT(8); b <<= 1, e = nextent(e))
  91                                 if (!IS_REAL_CLIENT(e) || e.ready)
  92                                         f |= b;
  93                         WriteByte(MSG_ENTITY, f);
  94                 }
  95         }
  96
  97         return true;
  98 }
  99
 100 void Nagger_Init()
 101 {
 102         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
 103 }
 104
 105 void Nagger_VoteChanged()
 106 {
 107         if (nagger) nagger.SendFlags |= BIT(7);
 108 }
 109
 110 void Nagger_VoteCountChanged()
 111 {
 112         if (nagger) nagger.SendFlags |= BIT(6);
 113 }
 114
 115 void Nagger_ReadyCounted()
 116 {
 117         if (nagger) nagger.SendFlags |= BIT(0);
 118 }
 119
 120 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 121 string OriginalCallerName()
 122 {
 123         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller, false);
 124         return vote_caller_name;
 125 }
 126
 127 // =======================
 128 //  Game logic for voting
 129 // =======================
 130
 131 void VoteReset()
 132 {
 133         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 134
 135         if (vote_called)
 136         {
 137                 strfree(vote_called_command);
 138                 strfree(vote_called_display);
 139                 strfree(vote_caller_name);
 140         }
 141
 142         vote_called = VOTE_NULL;
 143         vote_caller = NULL;
 144         vote_endtime = 0;
 145
 146         vote_parsed_command = string_null;
 147         vote_parsed_display = string_null;
 148
 149         Nagger_VoteChanged();
 150 }
 151
 152 void VoteStop(entity stopper)
 153 {
 154         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 155         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 156         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 157         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 158         VoteReset();
 159 }
 160
 161 void VoteAccept()
 162 {
 163         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 164
 165         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 166         else localcmd(strcat(vote_called_command, "\n"));
 167
 168         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 169
 170         VoteReset();
 171         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 172 }
 173
 174 void VoteReject()
 175 {
 176         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 177         VoteReset();
 178         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 179 }
 180
 181 void VoteTimeout()
 182 {
 183         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 184         VoteReset();
 185         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 186 }
 187
 188 void VoteSpam(float notvoters, float mincount, string result)
 189 {
 190         bprint(strcat(
 191                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 192                 strcat("^2:^1", ftos(vote_reject_count)),
 193                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 194                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 195                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 196
 197         if (autocvar_sv_eventlog)
 198         {
 199                 GameLogEcho(strcat(
 200                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 201                         strcat(":", ftos(vote_reject_count)),
 202                         strcat(":", ftos(vote_abstain_count)),
 203                         strcat(":", ftos(notvoters)),
 204                         strcat(":", ftos(mincount))));
 205         }
 206 }
 207
 208 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 209
 210 void VoteCount(float first_count)
 211 {
 212         // declarations
 213         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 214
 215         float vote_player_count = 0, notvoters = 0;
 216         float vote_real_player_count = 0, vote_real_accept_count = 0;
 217         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 218         float vote_needed_of_voted, final_needed_votes;
 219         float vote_factor_overall, vote_factor_of_voted;
 220
 221         Nagger_VoteCountChanged();
 222
 223         // add up all the votes from each connected client
 224         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 225                 ++vote_player_count;
 226                 if (IS_PLAYER(it))   ++vote_real_player_count;
 227                 switch (it.vote_selection)
 228                 {
 229                         case VOTE_SELECT_REJECT:
 230                         { ++vote_reject_count;
 231                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 232                         }
 233                         case VOTE_SELECT_ACCEPT:
 234                         { ++vote_accept_count;
 235                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 236                         }
 237                         case VOTE_SELECT_ABSTAIN:
 238                         { ++vote_abstain_count;
 239                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 240                         }
 241                         default: break;
 242                 }
 243         });
 244
 245         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 246         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 247         {
 248                 if (vote_caller)   vote_caller.vote_waittime = 0;
 249                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 250                 VoteReset();
 251                 return;
 252         }
 253
 254         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 255         if (!spectators_allowed && (vote_real_player_count > 0))
 256         {
 257                 vote_accept_count = vote_real_accept_count;
 258                 vote_reject_count = vote_real_reject_count;
 259                 vote_abstain_count = vote_real_abstain_count;
 260                 vote_player_count = vote_real_player_count;
 261         }
 262
 263         // people who have no opinion in any way :D
 264         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 265
 266         // determine the goal for the vote to be passed or rejected normally
 267         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 268         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 269
 270         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 271         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 272         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 273
 274         // are there any players at all on the server? it could be an admin vote
 275         if (vote_player_count == 0 && first_count)
 276         {
 277                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 278                 VoteAccept();
 279                 return;
 280         }
 281
 282         // since there ARE players, finally calculate the result of the vote
 283         if (vote_accept_count >= vote_needed_overall)
 284         {
 285                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 286                 VoteAccept();
 287                 return;
 288         }
 289
 290         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 291         {
 292                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 293                 VoteReject();
 294                 return;
 295         }
 296
 297         // there is not enough votes in either direction, now lets just calculate what the voters have said
 298         if (time > vote_endtime)
 299         {
 300                 final_needed_votes = vote_needed_overall;
 301
 302                 if (autocvar_sv_vote_majority_factor_of_voted)
 303                 {
 304                         if (vote_accept_count >= vote_needed_of_voted)
 305                         {
 306                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 307                                 VoteAccept();
 308                                 return;
 309                         }
 310
 311                         if (vote_accept_count + vote_reject_count > 0)
 312                         {
 313                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 314                                 VoteReject();
 315                                 return;
 316                         }
 317
 318                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 319                 }
 320
 321                 // it didn't pass or fail, so not enough votes to even make a decision.
 322                 VoteSpam(notvoters, final_needed_votes, "timeout");
 323                 VoteTimeout();
 324         }
 325 }
 326
 327 void VoteThink()
 328 {
 329         if (vote_endtime > 0)        // a vote was called
 330         {
 331                 if (time > vote_endtime) // time is up
 332                         VoteCount(false);
 333         }
 334 }
 335
 336
 337 // =======================
 338 //  Game logic for warmup
 339 // =======================
 340
 341 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 342 void reset_map(bool dorespawn)
 343 {
 344         if (time <= game_starttime)
 345         {
 346                 if (game_stopped)
 347                         return;
 348                 if (round_handler_IsActive())
 349                         round_handler_Reset(game_starttime);
 350         }
 351
 352         if (shuffleteams_on_reset_map)
 353         {
 354                 shuffleteams();
 355                 shuffleteams_on_reset_map = false;
 356         }
 357         MUTATOR_CALLHOOK(reset_map_global);
 358
 359         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 360         {
 361                 if(IS_CLIENT(it))
 362                         continue;
 363                 if (it.reset)
 364                 {
 365                         it.reset(it);
 366                         continue;
 367                 }
 368                 if (it.team_saved) it.team = it.team_saved;
 369                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 370         });
 371
 372         // Waypoints and assault start come LAST
 373         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 374                 if (it.reset2) it.reset2(it);
 375         });
 376
 377         FOREACH_CLIENT(IS_PLAYER(it) && STAT(FROZEN, it), { Unfreeze(it, false); });
 378
 379         // Moving the player reset code here since the player-reset depends
 380         // on spawnpoint entities which have to be reset first --blub
 381         if (dorespawn)
 382         {
 383                 if (!MUTATOR_CALLHOOK(reset_map_players))
 384                 {
 385                         if (restart_mapalreadyrestarted || (time < game_starttime))
 386                         {
 387                                 FOREACH_CLIENT(IS_PLAYER(it),
 388                                 {
 389                                         /*
 390                                         only reset players if a restart countdown is active
 391                                         this can either be due to cvar sv_ready_restart_after_countdown having set
 392                                         restart_mapalreadyrestarted to 1 after the countdown ended or when
 393                                         sv_ready_restart_after_countdown is not used and countdown is still running
 394                                         */
 395                                         // NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 396                                         // PlayerScore_Clear(it);
 397                                         CS(it).killcount = 0;
 398                                         // stop the player from moving so that he stands still once he gets respawned
 399                                         it.velocity = '0 0 0';
 400                                         it.avelocity = '0 0 0';
 401                                         CS(it).movement = '0 0 0';
 402                                         PutClientInServer(it);
 403                                 });
 404                         }
 405                 }
 406         }
 407 }
 408
 409 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 410 void ReadyRestart_think(entity this)
 411 {
 412         restart_mapalreadyrestarted = true;
 413         reset_map(true);
 414         Score_ClearAll();
 415         delete(this);
 416 }
 417
 418 // Forces a restart of the game without actually reloading the map // this is a mess...
 419 void ReadyRestart_force()
 420 {
 421         if (time <= game_starttime && game_stopped)
 422                 return;
 423
 424         bprint("^1Server is restarting...\n");
 425
 426         VoteReset();
 427
 428         // clear overtime, we have to decrease timelimit to its original value again.
 429         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 430                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 431         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 432
 433         readyrestart_happened = true;
 434         game_starttime = time + RESTART_COUNTDOWN;
 435
 436         // clear player attributes
 437         FOREACH_CLIENT(IS_PLAYER(it), {
 438                 it.alivetime = 0;
 439                 CS(it).killcount = 0;
 440                 float val = PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, 0);
 441                 PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, -val);
 442         });
 443
 444         restart_mapalreadyrestarted = false; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 445
 446         // disable the warmup global for the server
 447         if(warmup_stage)
 448                 localcmd("\nsv_hook_warmupend\n");
 449         warmup_stage = 0;                // once the game is restarted the game is in match stage
 450
 451         // reset the .ready status of all players (also spectators)
 452         FOREACH_CLIENT(IS_REAL_CLIENT(it), { it.ready = false; });
 453         readycount = 0;
 454         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 455
 456         // lock teams with lockonrestart
 457         if (autocvar_teamplay_lockonrestart && teamplay)
 458         {
 459                 lockteams = true;
 460                 bprint("^1The teams are now locked.\n");
 461         }
 462
 463         // initiate the restart-countdown-announcer entity
 464         if (sv_ready_restart_after_countdown)
 465         {
 466                 entity restart_timer = new_pure(restart_timer);
 467                 setthink(restart_timer, ReadyRestart_think);
 468                 restart_timer.nextthink = game_starttime;
 469         }
 470
 471         // after a restart every players number of allowed timeouts gets reset, too
 472         if (autocvar_sv_timeout)
 473         {
 474                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 475         }
 476
 477         if (!sv_ready_restart_after_countdown) reset_map(true);
 478         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 479 }
 480
 481 void ReadyRestart()
 482 {
 483         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing) localcmd("restart\n");
 484         else localcmd("\nsv_hook_readyrestart\n");
 485
 486         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 487         // Otherwise scores could be manipulated during the countdown.
 488         if (!sv_ready_restart_after_countdown) Score_ClearAll();
 489         ReadyRestart_force();
 490 }
 491
 492 // Count the players who are ready and determine whether or not to restart the match
 493 void ReadyCount()
 494 {
 495         float ready_needed_factor, ready_needed_count;
 496         float t_ready = 0, t_players = 0;
 497
 498         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || it.caplayer == 1), {
 499                 ++t_players;
 500                 if (it.ready) ++t_ready;
 501         });
 502
 503         readycount = t_ready;
 504
 505         Nagger_ReadyCounted();
 506
 507         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 508         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 509
 510         if (readycount >= ready_needed_count) ReadyRestart();
 511 }
 512
 513
 514 // ======================================
 515 //  Supporting functions for VoteCommand
 516 // ======================================
 517
 518 float Votecommand_check_assignment(entity caller, float assignment)
 519 {
 520         float from_server = (!caller);
 521
 522         if ((assignment == VC_ASGNMNT_BOTH)
 523             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 524             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 525
 526         return false;
 527 }
 528
 529 string VoteCommand_extractcommand(string input, float startpos, int argc)
 530 {
 531         string output;
 532
 533         if ((argc - 1) < startpos) output = "";
 534         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 535
 536         return output;
 537 }
 538
 539 float VoteCommand_checknasty(string vote_command)
 540 {
 541         if ((strstrofs(vote_command, ";", 0) >= 0)
 542             || (strstrofs(vote_command, "\n", 0) >= 0)
 543             || (strstrofs(vote_command, "\r", 0) >= 0)
 544             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 545
 546         return true;
 547 }
 548
 549 // NOTE: requires input to be surrounded by spaces
 550 string VoteCommand_checkreplacements(string input)
 551 {
 552         string output = input;
 553         // allow gotomap replacements
 554         output = strreplace(" map ", " gotomap ", output);
 555         output = strreplace(" chmap ", " gotomap ", output);
 556         return output;
 557 }
 558
 559 float VoteCommand_checkinlist(string vote_command, string list)
 560 {
 561         string l = VoteCommand_checkreplacements(strcat(" ", list, " "));
 562
 563         if (strstrofs(l, VoteCommand_checkreplacements(strcat(" ", vote_command, " ")), 0) >= 0) return true;
 564
 565         return false;
 566 }
 567
 568 string ValidateMap(string validated_map, entity caller)
 569 {
 570         validated_map = MapInfo_FixName(validated_map);
 571
 572         if (!validated_map)
 573         {
 574                 print_to(caller, "This map is not available on this server.");
 575                 return string_null;
 576         }
 577
 578         if (!autocvar_sv_vote_override_mostrecent && caller)
 579         {
 580                 if (Map_IsRecent(validated_map))
 581                 {
 582                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 583                         return string_null;
 584                 }
 585         }
 586
 587         if (!MapInfo_CheckMap(validated_map))
 588         {
 589                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 590                 return string_null;
 591         }
 592
 593         return validated_map;
 594 }
 595
 596 float VoteCommand_checkargs(float startpos, int argc)
 597 {
 598         float p, q, check, minargs;
 599         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 600         string cmdrestriction = "";  // No we don't.
 601         string charlist, arg;
 602         float checkmate;
 603
 604         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 605                 cmdrestriction = cvar_string(cvarname);
 606         else
 607                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 608
 609         if (cmdrestriction == "") return true;
 610
 611         ++startpos;  // skip command name
 612
 613         // check minimum arg count
 614
 615         // 0 args: argc == startpos
 616         // 1 args: argc == startpos + 1
 617         // ...
 618
 619         minargs = stof(cmdrestriction);
 620         if (argc - startpos < minargs) return false;
 621
 622         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 623
 624         for ( ; ; )
 625         {
 626                 // we know that at any time, startpos <= argc - minargs
 627                 // so this means: argc-minargs >= startpos >= argc, thus
 628                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 629                 // have been seen already
 630
 631                 if (startpos >= argc) // all args checked? GOOD
 632                         break;
 633
 634                 if (p < 0)            // no more args? FAIL
 635                 {
 636                         // exception: exactly minargs left, this one included
 637                         if (argc - startpos == minargs) break;
 638
 639                         // otherwise fail
 640                         return false;
 641                 }
 642
 643                 // cut to next semicolon
 644                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 645                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 646                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 647
 648                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 649                 // charlist = strreplace("^^", ";", charlist);
 650
 651                 if (charlist != "")
 652                 {
 653                         // verify the arg only contains allowed chars
 654                         arg = argv(startpos);
 655                         checkmate = strlen(arg);
 656                         for (check = 0; check < checkmate; ++check)
 657                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 658                         // not allowed character
 659                         // all characters are allowed. FINE.
 660                 }
 661
 662                 ++startpos;
 663                 --minargs;
 664                 p = q;
 665         }
 666
 667         return true;
 668 }
 669
 670 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 671 {
 672         string first_command = argv(startpos);
 673         int missing_chars = argv_start_index(startpos);
 674
 675         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 676                 return 0;
 677
 678         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 679
 680         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 681
 682         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 683         {
 684                 case MUT_VOTEPARSE_CONTINUE: { break; }
 685                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 686                 case MUT_VOTEPARSE_INVALID: { return -1; }
 687                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 688         }
 689
 690         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 691         {
 692                 case "kick":
 693                 case "kickban":    // catch all kick/kickban commands
 694                 {
 695                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 696                         float accepted = VerifyClientEntity(victim, true, false);
 697
 698                         if (accepted > 0)
 699                         {
 700                                 string reason = "No reason provided";
 701                                 if(argc > next_token)
 702                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 703
 704                                 string command_arguments = reason;
 705                                 if (first_command == "kickban")
 706                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 707
 708                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 709                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 710                         }
 711                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return 0; }
 712
 713                         break;
 714                 }
 715
 716                 case "map":
 717                 case "chmap":
 718                 case "gotomap":  // re-direct all map selection commands to gotomap
 719                 {
 720                         vote_command = ValidateMap(argv(startpos + 1), caller);
 721                         if (!vote_command)  return -1;
 722                         vote_parsed_command = strcat("gotomap ", vote_command);
 723                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 724
 725                         break;
 726                 }
 727
 728                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 729                 // maybe fallback instead of aborting if map name is invalid?
 730                 case "nextmap":
 731                 {
 732                         vote_command = ValidateMap(argv(startpos + 1), caller);
 733                         if (!vote_command)  return -1;
 734                         vote_parsed_command = strcat("nextmap ", vote_command);
 735                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 736
 737                         break;
 738                 }
 739
 740                 case "timelimit": // include restrictions on the maximum votable time limit
 741                 {
 742                         float timelimit_vote = stof(argv(startpos + 1));
 743                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 744                         {
 745                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 746                                 return -1;
 747                         }
 748                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 749                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 750                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 751
 752                         break;
 753                 }
 754
 755                 case "restart":
 756                 {
 757                         // add a delay so that vote result can be seen and announcer can be heard
 758                         // if the vote is accepted
 759                         vote_parsed_command = strcat("defer 1 ", vote_command);
 760                         vote_parsed_display = strzone(strcat("^1", vote_command));
 761
 762                         break;
 763                 }
 764
 765                 default:
 766                 {
 767                         vote_parsed_command = vote_command;
 768                         vote_parsed_display = strzone(strcat("^1", vote_command));
 769
 770                         break;
 771                 }
 772         }
 773
 774         return 1;
 775 }
 776
 777
 778 // =======================
 779 //  Command Sub-Functions
 780 // =======================
 781
 782 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 783 {
 784         switch (request)
 785         {
 786                 case CMD_REQUEST_COMMAND:
 787                 {
 788                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 789                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 790                         {
 791                                 print_to(caller, "^1You have already voted.");
 792                         }
 793
 794                         else  // everything went okay, continue changing vote
 795                         {
 796                                 print_to(caller, "^1You abstained from your vote.");
 797                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 798                                 msg_entity = caller;
 799                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 800
 801                         return;
 802                 }
 803
 804                 default:
 805                 case CMD_REQUEST_USAGE:
 806                 {
 807                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 808                         print_to(caller, "  No arguments required.");
 809                         return;
 810                 }
 811         }
 812 }
 813
 814 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 815 {
 816         switch (request)
 817         {
 818                 case CMD_REQUEST_COMMAND:
 819                 {
 820                         float tmp_playercount = 0;
 821                         int parse_error;
 822
 823                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 824
 825                         if (!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 826                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 827                         {
 828                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 829                         }
 830                         else if (vote_called)
 831                         {
 832                                 print_to(caller, "^1There is already a vote called.");
 833                         }
 834                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 835                         {
 836                                 print_to(caller, "^1Only players can call a vote.");
 837                         }
 838                         else if (caller && !IS_CLIENT(caller))
 839                         {
 840                                 print_to(caller, "^1Only connected clients can vote.");
 841                         }
 842                         else if (timeout_status && vote_command != "timein")
 843                         {
 844                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 845                         }
 846                         else if (caller && (time < caller.vote_waittime))
 847                         {
 848                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 849                         }
 850                         else if (!VoteCommand_checknasty(vote_command))
 851                         {
 852                                 print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 853                         }
 854                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 855                         {
 856                                 if(parse_error == 0)
 857                                         print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 858                         }
 859                         else  // everything went okay, continue with calling the vote
 860                         {
 861                                 vote_caller = caller;  // remember who called the vote
 862                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 863                                 vote_called = VOTE_NORMAL;
 864                                 vote_called_command = strzone(vote_parsed_command);
 865                                 vote_called_display = strzone(vote_parsed_display);
 866                                 vote_endtime = time + autocvar_sv_vote_timeout;
 867
 868                                 if (caller)
 869                                 {
 870                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 871                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 872                                         msg_entity = caller;
 873                                 }
 874
 875                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 876
 877                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 878                                 if (autocvar_sv_eventlog)
 879                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 880                                 Nagger_VoteChanged();
 881                                 VoteCount(true);  // needed if you are the only one
 882
 883                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
 884                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 885                         }
 886
 887                         return;
 888                 }
 889
 890                 default:
 891                 case CMD_REQUEST_USAGE:
 892                 {
 893                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 894                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 895                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 896                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 897                         return;
 898                 }
 899         }
 900 }
 901
 902 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
 903 {
 904         switch (request)
 905         {
 906                 case CMD_REQUEST_COMMAND:
 907                 {
 908                         if (autocvar_sv_vote_master)
 909                         {
 910                                 switch (strtolower(argv(2)))
 911                                 {
 912                                         case "do":
 913                                         {
 914                                                 int parse_error;
 915                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 916
 917                                                 if (!caller.vote_master)
 918                                                         print_to(caller, "^1You do not have vote master privileges.");
 919                                                 else if (!VoteCommand_checknasty(vote_command))
 920                                                 {
 921                                                         print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 922                                                 }
 923                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
 924                                                 {
 925                                                         if(parse_error == 0)
 926                                                                 print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 927                                                 }
 928                                                 else  // everything went okay, proceed with command
 929                                                 {
 930                                                         localcmd(strcat(vote_parsed_command, "\n"));
 931                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 932                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 933                                                         if (autocvar_sv_eventlog)
 934                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
 935                                                 }
 936
 937                                                 return;
 938                                         }
 939
 940                                         case "login":
 941                                         {
 942                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 943                                                 else if (caller.vote_master)
 944                                                 {
 945                                                         print_to(caller, "^1You are already logged in as vote master.");
 946                                                 }
 947                                                 else if (autocvar_sv_vote_master_password != argv(3))
 948                                                 {
 949                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 950                                                 }
 951                                                 else  // everything went okay, proceed with giving this player master privilages
 952                                                 {
 953                                                         caller.vote_master = true;
 954                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 955                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 956                                                         if (autocvar_sv_eventlog)
 957                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
 958                                                 }
 959
 960                                                 return;
 961                                         }
 962
 963                                         default:  // calling a vote for master
 964                                         {
 965                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 966                                                 else if (vote_called)
 967                                                 {
 968                                                         print_to(caller, "^1There is already a vote called.");
 969                                                 }
 970                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 971                                                 {
 972                                                         print_to(caller, "^1Only players can call a vote.");
 973                                                 }
 974                                                 else if (timeout_status)
 975                                                 {
 976                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
 977                                                 }
 978                                                 else  // everything went okay, continue with creating vote
 979                                                 {
 980                                                         vote_caller = caller;
 981                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 982                                                         vote_called = VOTE_MASTER;
 983                                                         vote_called_command = strzone("XXX");
 984                                                         vote_called_display = strzone("^3master");
 985                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 986
 987                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 988                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 989
 990                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 991                                                         if (autocvar_sv_eventlog)
 992                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 993                                                         Nagger_VoteChanged();
 994                                                         VoteCount(true);  // needed if you are the only one
 995                                                 }
 996
 997                                                 return;
 998                                         }
 999                                 }
1000                         }
1001                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1002
1003                         return;
1004                 }
1005
1006                 default:
1007                 case CMD_REQUEST_USAGE:
1008                 {
1009                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
1010                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
1011                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
1012                         return;
1013                 }
1014         }
1015 }
1016
1017 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1018 {
1019         switch (request)
1020         {
1021                 case CMD_REQUEST_COMMAND:
1022                 {
1023                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1024                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1025                         {
1026                                 print_to(caller, "^1You have already voted.");
1027                         }
1028                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1029                         {
1030                                 VoteStop(caller);
1031                         }
1032
1033                         else  // everything went okay, continue changing vote
1034                         {
1035                                 print_to(caller, "^1You rejected the vote.");
1036                                 caller.vote_selection = VOTE_SELECT_REJECT;
1037                                 msg_entity = caller;
1038                                 if (!autocvar_sv_vote_singlecount)
1039                                         VoteCount(false);
1040                         }
1041
1042                         return;
1043                 }
1044
1045                 default:
1046                 case CMD_REQUEST_USAGE:
1047                 {
1048                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1049                         print_to(caller, "  No arguments required.");
1050                         return;
1051                 }
1052         }
1053 }
1054
1055 void VoteCommand_status(int request, entity caller)  // BOTH
1056 {
1057         switch (request)
1058         {
1059                 case CMD_REQUEST_COMMAND:
1060                 {
1061                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1062                         else print_to(caller, "^1No vote called.");
1063
1064                         return;
1065                 }
1066
1067                 default:
1068                 case CMD_REQUEST_USAGE:
1069                 {
1070                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1071                         print_to(caller, "  No arguments required.");
1072                         return;
1073                 }
1074         }
1075 }
1076
1077 void VoteCommand_stop(int request, entity caller)  // BOTH
1078 {
1079         switch (request)
1080         {
1081                 case CMD_REQUEST_COMMAND:
1082                 {
1083                         if (!vote_called)   print_to(caller, "^1No vote called.");
1084                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1085                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1086                         return;
1087                 }
1088
1089                 default:
1090                 case CMD_REQUEST_USAGE:
1091                 {
1092                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1093                         print_to(caller, "  No arguments required.");
1094                         return;
1095                 }
1096         }
1097 }
1098
1099 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1100 {
1101         switch (request)
1102         {
1103                 case CMD_REQUEST_COMMAND:
1104                 {
1105                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1106                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1107                         {
1108                                 print_to(caller, "^1You have already voted.");
1109                         }
1110                         else  // everything went okay, continue changing vote
1111                         {
1112                                 print_to(caller, "^1You accepted the vote.");
1113                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1114                                 msg_entity = caller;
1115                                 if (!autocvar_sv_vote_singlecount)
1116                                         VoteCount(false);
1117                         }
1118
1119                         return;
1120                 }
1121
1122                 default:
1123                 case CMD_REQUEST_USAGE:
1124                 {
1125                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1126                         print_to(caller, "  No arguments required.");
1127                         return;
1128                 }
1129         }
1130 }
1131
1132 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1133 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1134 void VoteCommand_(int request)
1135 {
1136     switch(request)
1137     {
1138         case CMD_REQUEST_COMMAND:
1139         {
1140
1141             return;
1142         }
1143
1144         default:
1145         case CMD_REQUEST_USAGE:
1146         {
1147             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1148             print_to(caller, "  No arguments required.");
1149             return;
1150         }
1151     }
1152 }
1153 */
1154
1155
1156 // ================================
1157 //  Macro system for vote commands
1158 // ================================
1159
1160 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1161 #define VOTE_COMMANDS(request, caller, arguments, command) \
1162         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1163         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1164         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1165         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1166         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1167         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1168         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1169         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1170         /* nothing */
1171
1172 void VoteCommand_macro_help(entity caller, int argc)
1173 {
1174         string command_origin = GetCommandPrefix(caller);
1175
1176         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1177         {
1178                 print_to(caller, "\nVoting commands:\n");
1179                 #define VOTE_COMMAND(name, function, description, assignment) \
1180                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1181
1182                 VOTE_COMMANDS(0, caller, 0, "");
1183 #undef VOTE_COMMAND
1184
1185                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1186                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1187                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1188         }
1189         else  // usage for individual command
1190         {
1191                 #define VOTE_COMMAND(name, function, description, assignment) \
1192                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1193
1194                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1195 #undef VOTE_COMMAND
1196
1197                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1198                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1199                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1200                 else
1201                         print_to(caller, "No documentation exists for this vote");
1202         }
1203 }
1204
1205 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1206 {
1207         #define VOTE_COMMAND(name, function, description, assignment) \
1208                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1209
1210         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1211 #undef VOTE_COMMAND
1212
1213         return false;
1214 }
1215
1216
1217 // ======================================
1218 //  Main function handling vote commands
1219 // ======================================
1220
1221 void VoteCommand(int request, entity caller, int argc, string vote_command)
1222 {
1223         // Guide for working with argc arguments by example:
1224         // argc:   1    - 2      - 3     - 4
1225         // argv:   0    - 1      - 2     - 3
1226         // cmd     vote - master - login - password
1227
1228         switch (request)
1229         {
1230                 case CMD_REQUEST_COMMAND:
1231                 {
1232                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1233                 }
1234
1235                 default:
1236                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1237                 case CMD_REQUEST_USAGE:
1238                 {
1239                         VoteCommand_macro_help(caller, argc);
1240                         return;
1241                 }
1242         }
1243 }