qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/mapinfo.qh>
   7 #include <common/net_linked.qh>
   8 #include <common/notifications/all.qh>
   9 #include <common/playerstats.qh>
  10 #include <common/stats.qh>
  11 #include <common/util.qh>
  12 #include <common/weapons/_all.qh>
  13 #include <server/client.qh>
  14 #include <server/command/banning.qh>
  15 #include <server/command/common.qh>
  16 #include <server/command/vote.qh>
  17 #include <server/damage.qh>
  18 #include <server/gamelog.qh>
  19 #include <server/intermission.qh>
  20 #include <server/mutators/_mod.qh>
  21 #include <server/race.qh>
  22 #include <server/round_handler.qh>
  23 #include <server/scores.qh>
  24 #include <server/teamplay.qh>
  25 #include <server/world.qh>
  26
  27 // =============================================
  28 //  Server side voting code, reworked by Samual
  29 //  Last updated: December 27th, 2011
  30 // =============================================
  31
  32 //  Nagger for players to know status of voting
  33 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  34 {
  35         int nags, i, f, b;
  36         entity e;
  37         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  38
  39         // bits:
  40         //   1 = ready
  41         //   2 = player needs to ready up
  42         //   4 = vote
  43         //   8 = player needs to vote
  44         //  16 = warmup
  45         // sendflags:
  46         //  64 = vote counts
  47         // 128 = vote string
  48
  49         nags = 0;
  50         if (readycount)
  51         {
  52                 nags |= BIT(0);
  53                 if (to.ready == 0) nags |= BIT(1);
  54         }
  55         if (vote_called)
  56         {
  57                 nags |= BIT(2);
  58                 if (to.vote_selection == 0) nags |= BIT(3);
  59         }
  60         if (warmup_stage) nags |= BIT(4);
  61
  62         if (sendflags & BIT(6)) nags |= BIT(6);
  63
  64         if (sendflags & BIT(7)) nags |= BIT(7);
  65
  66         if (!(nags & 4))  // no vote called? send no string
  67                 nags &= ~(BIT(6) | BIT(7));
  68
  69         WriteByte(MSG_ENTITY, nags);
  70
  71         if (nags & BIT(6))
  72         {
  73                 WriteByte(MSG_ENTITY, vote_accept_count);
  74                 WriteByte(MSG_ENTITY, vote_reject_count);
  75                 WriteByte(MSG_ENTITY, vote_needed_overall);
  76                 WriteChar(MSG_ENTITY, to.vote_selection);
  77         }
  78
  79         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  80
  81         if (nags & 1)
  82         {
  83                 for (i = 1; i <= maxclients; i += 8)
  84                 {
  85                         for (f = 0, e = edict_num(i), b = BIT(0); b < BIT(8); b <<= 1, e = nextent(e))
  86                                 if (!IS_REAL_CLIENT(e) || e.ready)
  87                                         f |= b;
  88                         WriteByte(MSG_ENTITY, f);
  89                 }
  90         }
  91
  92         return true;
  93 }
  94
  95 void Nagger_Init()
  96 {
  97         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
  98 }
  99
 100 void Nagger_VoteChanged()
 101 {
 102         if (nagger) nagger.SendFlags |= BIT(7);
 103 }
 104
 105 void Nagger_VoteCountChanged()
 106 {
 107         if (nagger) nagger.SendFlags |= BIT(6);
 108 }
 109
 110 void Nagger_ReadyCounted()
 111 {
 112         if (nagger) nagger.SendFlags |= BIT(0);
 113 }
 114
 115 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 116 string OriginalCallerName()
 117 {
 118         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 119         return vote_caller_name;
 120 }
 121
 122 // =======================
 123 //  Game logic for voting
 124 // =======================
 125
 126 void VoteReset()
 127 {
 128         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 129
 130         if (vote_called)
 131         {
 132                 strfree(vote_called_command);
 133                 strfree(vote_called_display);
 134                 strfree(vote_caller_name);
 135         }
 136
 137         vote_called = VOTE_NULL;
 138         vote_caller = NULL;
 139         vote_endtime = 0;
 140
 141         vote_parsed_command = string_null;
 142         vote_parsed_display = string_null;
 143
 144         Nagger_VoteChanged();
 145 }
 146
 147 void VoteStop(entity stopper)
 148 {
 149         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 150         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 151         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 152         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 153         VoteReset();
 154 }
 155
 156 void VoteAccept()
 157 {
 158         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 159
 160         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 161         else localcmd(strcat(vote_called_command, "\n"));
 162
 163         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 164
 165         VoteReset();
 166         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 167 }
 168
 169 void VoteReject()
 170 {
 171         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 172         VoteReset();
 173         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 174 }
 175
 176 void VoteTimeout()
 177 {
 178         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 179         VoteReset();
 180         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 181 }
 182
 183 void VoteSpam(float notvoters, float mincount, string result)
 184 {
 185         bprint(strcat(
 186                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 187                 strcat("^2:^1", ftos(vote_reject_count)),
 188                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 189                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 190                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 191
 192         if (autocvar_sv_eventlog)
 193         {
 194                 GameLogEcho(strcat(
 195                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 196                         strcat(":", ftos(vote_reject_count)),
 197                         strcat(":", ftos(vote_abstain_count)),
 198                         strcat(":", ftos(notvoters)),
 199                         strcat(":", ftos(mincount))));
 200         }
 201 }
 202
 203 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 204
 205 void VoteCount(float first_count)
 206 {
 207         // declarations
 208         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 209
 210         float vote_player_count = 0, notvoters = 0;
 211         float vote_real_player_count = 0, vote_real_accept_count = 0;
 212         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 213         float vote_needed_of_voted, final_needed_votes;
 214         float vote_factor_overall, vote_factor_of_voted;
 215
 216         Nagger_VoteCountChanged();
 217
 218         // add up all the votes from each connected client
 219         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 220                 ++vote_player_count;
 221                 if (IS_PLAYER(it))   ++vote_real_player_count;
 222                 switch (it.vote_selection)
 223                 {
 224                         case VOTE_SELECT_REJECT:
 225                         { ++vote_reject_count;
 226                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 227                         }
 228                         case VOTE_SELECT_ACCEPT:
 229                         { ++vote_accept_count;
 230                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 231                         }
 232                         case VOTE_SELECT_ABSTAIN:
 233                         { ++vote_abstain_count;
 234                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 235                         }
 236                         default: break;
 237                 }
 238         });
 239
 240         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 241         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 242         {
 243                 if (vote_caller)   vote_caller.vote_waittime = 0;
 244                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 245                 VoteReset();
 246                 return;
 247         }
 248
 249         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 250         if (!spectators_allowed && (vote_real_player_count > 0))
 251         {
 252                 vote_accept_count = vote_real_accept_count;
 253                 vote_reject_count = vote_real_reject_count;
 254                 vote_abstain_count = vote_real_abstain_count;
 255                 vote_player_count = vote_real_player_count;
 256         }
 257
 258         // people who have no opinion in any way :D
 259         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 260
 261         // determine the goal for the vote to be passed or rejected normally
 262         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 263         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 264
 265         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 266         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 267         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 268
 269         // are there any players at all on the server? it could be an admin vote
 270         if (vote_player_count == 0 && first_count)
 271         {
 272                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 273                 VoteAccept();
 274                 return;
 275         }
 276
 277         // since there ARE players, finally calculate the result of the vote
 278         if (vote_accept_count >= vote_needed_overall)
 279         {
 280                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 281                 VoteAccept();
 282                 return;
 283         }
 284
 285         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 286         {
 287                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 288                 VoteReject();
 289                 return;
 290         }
 291
 292         // there is not enough votes in either direction, now lets just calculate what the voters have said
 293         if (time > vote_endtime)
 294         {
 295                 final_needed_votes = vote_needed_overall;
 296
 297                 if (autocvar_sv_vote_majority_factor_of_voted)
 298                 {
 299                         if (vote_accept_count >= vote_needed_of_voted)
 300                         {
 301                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 302                                 VoteAccept();
 303                                 return;
 304                         }
 305
 306                         if (vote_accept_count + vote_reject_count > 0)
 307                         {
 308                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 309                                 VoteReject();
 310                                 return;
 311                         }
 312
 313                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 314                 }
 315
 316                 // it didn't pass or fail, so not enough votes to even make a decision.
 317                 VoteSpam(notvoters, final_needed_votes, "timeout");
 318                 VoteTimeout();
 319         }
 320 }
 321
 322 void VoteThink()
 323 {
 324         if (vote_endtime > 0)        // a vote was called
 325         {
 326                 if (time > vote_endtime) // time is up
 327                         VoteCount(false);
 328         }
 329 }
 330
 331
 332 // =======================
 333 //  Game logic for warmup
 334 // =======================
 335
 336 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 337 void reset_map(bool dorespawn)
 338 {
 339         if (time <= game_starttime)
 340         {
 341                 if (game_stopped)
 342                         return;
 343                 if (round_handler_IsActive())
 344                         round_handler_Reset(game_starttime);
 345         }
 346
 347         if (shuffleteams_on_reset_map)
 348         {
 349                 shuffleteams();
 350                 shuffleteams_on_reset_map = false;
 351         }
 352
 353         FOREACH_CLIENT(IS_PLAYER(it),
 354         {
 355                 entity store = PS(it);
 356                 if (store)
 357                 {
 358                         Inventory_clear(store.inventory);
 359                         Inventory_update(store);
 360                 }
 361         });
 362
 363         MUTATOR_CALLHOOK(reset_map_global);
 364
 365         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 366         {
 367                 if(IS_CLIENT(it))
 368                         continue;
 369                 if (it.reset)
 370                 {
 371                         it.reset(it);
 372                         continue;
 373                 }
 374                 if (it.team_saved) it.team = it.team_saved;
 375                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 376         });
 377
 378         // Waypoints and assault start come LAST
 379         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 380                 if (it.reset2) it.reset2(it);
 381         });
 382
 383         FOREACH_CLIENT(IS_PLAYER(it) && STAT(FROZEN, it), { Unfreeze(it, false); });
 384
 385         // Moving the player reset code here since the player-reset depends
 386         // on spawnpoint entities which have to be reset first --blub
 387         if (dorespawn)
 388         {
 389                 if (!MUTATOR_CALLHOOK(reset_map_players))
 390                 {
 391                         if (restart_mapalreadyrestarted || (time < game_starttime))
 392                         {
 393                                 FOREACH_CLIENT(IS_PLAYER(it),
 394                                 {
 395                                         /*
 396                                         only reset players if a restart countdown is active
 397                                         this can either be due to cvar sv_ready_restart_after_countdown having set
 398                                         restart_mapalreadyrestarted to 1 after the countdown ended or when
 399                                         sv_ready_restart_after_countdown is not used and countdown is still running
 400                                         */
 401                                         // NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 402                                         // PlayerScore_Clear(it);
 403                                         CS(it).killcount = 0;
 404                                         // stop the player from moving so that he stands still once he gets respawned
 405                                         it.velocity = '0 0 0';
 406                                         it.avelocity = '0 0 0';
 407                                         CS(it).movement = '0 0 0';
 408                                         PutClientInServer(it);
 409                                 });
 410                         }
 411                 }
 412         }
 413 }
 414
 415 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 416 void ReadyRestart_think(entity this)
 417 {
 418         restart_mapalreadyrestarted = true;
 419         reset_map(true);
 420         Score_ClearAll();
 421         delete(this);
 422 }
 423
 424 // Forces a restart of the game without actually reloading the map // this is a mess...
 425 void ReadyRestart_force()
 426 {
 427         if (time <= game_starttime && game_stopped)
 428                 return;
 429
 430         bprint("^1Server is restarting...\n");
 431
 432         VoteReset();
 433
 434         // clear overtime, we have to decrease timelimit to its original value again.
 435         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 436                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 437         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 438
 439         readyrestart_happened = true;
 440         game_starttime = time + RESTART_COUNTDOWN;
 441
 442         // clear player attributes
 443         FOREACH_CLIENT(IS_PLAYER(it), {
 444                 it.alivetime = 0;
 445                 CS(it).killcount = 0;
 446                 float val = PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, 0);
 447                 PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, -val);
 448         });
 449
 450         restart_mapalreadyrestarted = false; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 451
 452         // disable the warmup global for the server
 453         if(warmup_stage)
 454                 localcmd("\nsv_hook_warmupend\n");
 455         warmup_stage = 0;                // once the game is restarted the game is in match stage
 456
 457         // reset the .ready status of all players (also spectators)
 458         FOREACH_CLIENT(IS_REAL_CLIENT(it), { it.ready = false; });
 459         readycount = 0;
 460         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 461
 462         // lock teams with lockonrestart
 463         if (autocvar_teamplay_lockonrestart && teamplay)
 464         {
 465                 lockteams = true;
 466                 bprint("^1The teams are now locked.\n");
 467         }
 468
 469         // initiate the restart-countdown-announcer entity
 470         if (sv_ready_restart_after_countdown)
 471         {
 472                 entity restart_timer = new_pure(restart_timer);
 473                 setthink(restart_timer, ReadyRestart_think);
 474                 restart_timer.nextthink = game_starttime;
 475         }
 476
 477         // after a restart every players number of allowed timeouts gets reset, too
 478         if (autocvar_sv_timeout)
 479         {
 480                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 481         }
 482
 483         if (!sv_ready_restart_after_countdown) reset_map(true);
 484         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 485 }
 486
 487 void ReadyRestart()
 488 {
 489         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing) localcmd("restart\n");
 490         else localcmd("\nsv_hook_readyrestart\n");
 491
 492         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 493         // Otherwise scores could be manipulated during the countdown.
 494         if (!sv_ready_restart_after_countdown) Score_ClearAll();
 495         ReadyRestart_force();
 496 }
 497
 498 // Count the players who are ready and determine whether or not to restart the match
 499 void ReadyCount()
 500 {
 501         float ready_needed_factor, ready_needed_count;
 502         float t_ready = 0, t_players = 0;
 503
 504         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || it.caplayer == 1), {
 505                 ++t_players;
 506                 if (it.ready) ++t_ready;
 507         });
 508
 509         readycount = t_ready;
 510
 511         Nagger_ReadyCounted();
 512
 513         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 514         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 515
 516         if (readycount >= ready_needed_count) ReadyRestart();
 517 }
 518
 519
 520 // ======================================
 521 //  Supporting functions for VoteCommand
 522 // ======================================
 523
 524 float Votecommand_check_assignment(entity caller, float assignment)
 525 {
 526         float from_server = (!caller);
 527
 528         if ((assignment == VC_ASGNMNT_BOTH)
 529             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 530             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 531
 532         return false;
 533 }
 534
 535 string VoteCommand_extractcommand(string input, float startpos, int argc)
 536 {
 537         string output;
 538
 539         if ((argc - 1) < startpos) output = "";
 540         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 541
 542         return output;
 543 }
 544
 545 float VoteCommand_checknasty(string vote_command)
 546 {
 547         if ((strstrofs(vote_command, ";", 0) >= 0)
 548             || (strstrofs(vote_command, "\n", 0) >= 0)
 549             || (strstrofs(vote_command, "\r", 0) >= 0)
 550             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 551
 552         return true;
 553 }
 554
 555 // NOTE: requires input to be surrounded by spaces
 556 string VoteCommand_checkreplacements(string input)
 557 {
 558         string output = input;
 559         // allow gotomap replacements
 560         output = strreplace(" map ", " gotomap ", output);
 561         output = strreplace(" chmap ", " gotomap ", output);
 562         return output;
 563 }
 564
 565 float VoteCommand_checkinlist(string vote_command, string list)
 566 {
 567         string l = VoteCommand_checkreplacements(strcat(" ", list, " "));
 568
 569         if (strstrofs(l, VoteCommand_checkreplacements(strcat(" ", vote_command, " ")), 0) >= 0) return true;
 570
 571         return false;
 572 }
 573
 574 string ValidateMap(string validated_map, entity caller)
 575 {
 576         validated_map = MapInfo_FixName(validated_map);
 577
 578         if (!validated_map)
 579         {
 580                 print_to(caller, "This map is not available on this server.");
 581                 return string_null;
 582         }
 583
 584         if (!autocvar_sv_vote_override_mostrecent && caller)
 585         {
 586                 if (Map_IsRecent(validated_map))
 587                 {
 588                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 589                         return string_null;
 590                 }
 591         }
 592
 593         if (!MapInfo_CheckMap(validated_map))
 594         {
 595                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 596                 return string_null;
 597         }
 598
 599         return validated_map;
 600 }
 601
 602 float VoteCommand_checkargs(float startpos, int argc)
 603 {
 604         float p, q, check, minargs;
 605         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 606         string cmdrestriction = "";  // No we don't.
 607         string charlist, arg;
 608         float checkmate;
 609
 610         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 611                 cmdrestriction = cvar_string(cvarname);
 612         else
 613                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 614
 615         if (cmdrestriction == "") return true;
 616
 617         ++startpos;  // skip command name
 618
 619         // check minimum arg count
 620
 621         // 0 args: argc == startpos
 622         // 1 args: argc == startpos + 1
 623         // ...
 624
 625         minargs = stof(cmdrestriction);
 626         if (argc - startpos < minargs) return false;
 627
 628         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 629
 630         for ( ; ; )
 631         {
 632                 // we know that at any time, startpos <= argc - minargs
 633                 // so this means: argc-minargs >= startpos >= argc, thus
 634                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 635                 // have been seen already
 636
 637                 if (startpos >= argc) // all args checked? GOOD
 638                         break;
 639
 640                 if (p < 0)            // no more args? FAIL
 641                 {
 642                         // exception: exactly minargs left, this one included
 643                         if (argc - startpos == minargs) break;
 644
 645                         // otherwise fail
 646                         return false;
 647                 }
 648
 649                 // cut to next semicolon
 650                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 651                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 652                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 653
 654                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 655                 // charlist = strreplace("^^", ";", charlist);
 656
 657                 if (charlist != "")
 658                 {
 659                         // verify the arg only contains allowed chars
 660                         arg = argv(startpos);
 661                         checkmate = strlen(arg);
 662                         for (check = 0; check < checkmate; ++check)
 663                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 664                         // not allowed character
 665                         // all characters are allowed. FINE.
 666                 }
 667
 668                 ++startpos;
 669                 --minargs;
 670                 p = q;
 671         }
 672
 673         return true;
 674 }
 675
 676 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 677 {
 678         string first_command = argv(startpos);
 679         int missing_chars = argv_start_index(startpos);
 680
 681         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 682                 return 0;
 683
 684         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 685
 686         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 687
 688         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 689         {
 690                 case MUT_VOTEPARSE_CONTINUE: { break; }
 691                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 692                 case MUT_VOTEPARSE_INVALID: { return -1; }
 693                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 694         }
 695
 696         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 697         {
 698                 case "kick":
 699                 case "kickban":    // catch all kick/kickban commands
 700                 {
 701                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 702                         float accepted = VerifyClientEntity(victim, true, false);
 703
 704                         if (accepted > 0)
 705                         {
 706                                 string reason = "No reason provided";
 707                                 if(argc > next_token)
 708                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 709
 710                                 string command_arguments = reason;
 711                                 if (first_command == "kickban")
 712                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 713
 714                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 715                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 716                         }
 717                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return 0; }
 718
 719                         break;
 720                 }
 721
 722                 case "map":
 723                 case "chmap":
 724                 case "gotomap":  // re-direct all map selection commands to gotomap
 725                 {
 726                         vote_command = ValidateMap(argv(startpos + 1), caller);
 727                         if (!vote_command)  return -1;
 728                         vote_parsed_command = strcat("gotomap ", vote_command);
 729                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 730
 731                         break;
 732                 }
 733
 734                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 735                 // maybe fallback instead of aborting if map name is invalid?
 736                 case "nextmap":
 737                 {
 738                         vote_command = ValidateMap(argv(startpos + 1), caller);
 739                         if (!vote_command)  return -1;
 740                         vote_parsed_command = strcat("nextmap ", vote_command);
 741                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 742
 743                         break;
 744                 }
 745
 746                 case "timelimit": // include restrictions on the maximum votable time limit
 747                 {
 748                         float timelimit_vote = stof(argv(startpos + 1));
 749                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 750                         {
 751                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 752                                 return -1;
 753                         }
 754                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 755                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 756                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 757
 758                         break;
 759                 }
 760
 761                 case "restart":
 762                 {
 763                         // add a delay so that vote result can be seen and announcer can be heard
 764                         // if the vote is accepted
 765                         vote_parsed_command = strcat("defer 1 ", vote_command);
 766                         vote_parsed_display = strzone(strcat("^1", vote_command));
 767
 768                         break;
 769                 }
 770
 771                 default:
 772                 {
 773                         vote_parsed_command = vote_command;
 774                         vote_parsed_display = strzone(strcat("^1", vote_command));
 775
 776                         break;
 777                 }
 778         }
 779
 780         return 1;
 781 }
 782
 783
 784 // =======================
 785 //  Command Sub-Functions
 786 // =======================
 787
 788 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 789 {
 790         switch (request)
 791         {
 792                 case CMD_REQUEST_COMMAND:
 793                 {
 794                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 795                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 796                         {
 797                                 print_to(caller, "^1You have already voted.");
 798                         }
 799
 800                         else  // everything went okay, continue changing vote
 801                         {
 802                                 print_to(caller, "^1You abstained from your vote.");
 803                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 804                                 msg_entity = caller;
 805                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 806
 807                         return;
 808                 }
 809
 810                 default:
 811                 case CMD_REQUEST_USAGE:
 812                 {
 813                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 814                         print_to(caller, "  No arguments required.");
 815                         return;
 816                 }
 817         }
 818 }
 819
 820 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 821 {
 822         switch (request)
 823         {
 824                 case CMD_REQUEST_COMMAND:
 825                 {
 826                         float tmp_playercount = 0;
 827                         int parse_error;
 828
 829                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 830
 831                         if (!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 832                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 833                         {
 834                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 835                         }
 836                         else if (vote_called)
 837                         {
 838                                 print_to(caller, "^1There is already a vote called.");
 839                         }
 840                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 841                         {
 842                                 print_to(caller, "^1Only players can call a vote.");
 843                         }
 844                         else if (caller && !IS_CLIENT(caller))
 845                         {
 846                                 print_to(caller, "^1Only connected clients can vote.");
 847                         }
 848                         else if (timeout_status && vote_command != "timein")
 849                         {
 850                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 851                         }
 852                         else if (caller && (time < caller.vote_waittime))
 853                         {
 854                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 855                         }
 856                         else if (!VoteCommand_checknasty(vote_command))
 857                         {
 858                                 print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 859                         }
 860                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 861                         {
 862                                 if(parse_error == 0)
 863                                         print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 864                         }
 865                         else  // everything went okay, continue with calling the vote
 866                         {
 867                                 vote_caller = caller;  // remember who called the vote
 868                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 869                                 vote_called = VOTE_NORMAL;
 870                                 vote_called_command = strzone(vote_parsed_command);
 871                                 vote_called_display = strzone(vote_parsed_display);
 872                                 vote_endtime = time + autocvar_sv_vote_timeout;
 873
 874                                 if (caller)
 875                                 {
 876                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 877                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 878                                         msg_entity = caller;
 879                                 }
 880
 881                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 882
 883                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 884                                 if (autocvar_sv_eventlog)
 885                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 886                                 Nagger_VoteChanged();
 887                                 VoteCount(true);  // needed if you are the only one
 888
 889                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
 890                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 891                         }
 892
 893                         return;
 894                 }
 895
 896                 default:
 897                 case CMD_REQUEST_USAGE:
 898                 {
 899                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 900                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 901                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 902                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 903                         return;
 904                 }
 905         }
 906 }
 907
 908 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
 909 {
 910         switch (request)
 911         {
 912                 case CMD_REQUEST_COMMAND:
 913                 {
 914                         if (autocvar_sv_vote_master)
 915                         {
 916                                 switch (strtolower(argv(2)))
 917                                 {
 918                                         case "do":
 919                                         {
 920                                                 int parse_error;
 921                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 922
 923                                                 if (!caller.vote_master)
 924                                                         print_to(caller, "^1You do not have vote master privileges.");
 925                                                 else if (!VoteCommand_checknasty(vote_command))
 926                                                 {
 927                                                         print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 928                                                 }
 929                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
 930                                                 {
 931                                                         if(parse_error == 0)
 932                                                                 print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 933                                                 }
 934                                                 else  // everything went okay, proceed with command
 935                                                 {
 936                                                         localcmd(strcat(vote_parsed_command, "\n"));
 937                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 938                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 939                                                         if (autocvar_sv_eventlog)
 940                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
 941                                                 }
 942
 943                                                 return;
 944                                         }
 945
 946                                         case "login":
 947                                         {
 948                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 949                                                 else if (caller.vote_master)
 950                                                 {
 951                                                         print_to(caller, "^1You are already logged in as vote master.");
 952                                                 }
 953                                                 else if (autocvar_sv_vote_master_password != argv(3))
 954                                                 {
 955                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 956                                                 }
 957                                                 else  // everything went okay, proceed with giving this player master privilages
 958                                                 {
 959                                                         caller.vote_master = true;
 960                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 961                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 962                                                         if (autocvar_sv_eventlog)
 963                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
 964                                                 }
 965
 966                                                 return;
 967                                         }
 968
 969                                         default:  // calling a vote for master
 970                                         {
 971                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 972                                                 else if (vote_called)
 973                                                 {
 974                                                         print_to(caller, "^1There is already a vote called.");
 975                                                 }
 976                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 977                                                 {
 978                                                         print_to(caller, "^1Only players can call a vote.");
 979                                                 }
 980                                                 else if (timeout_status)
 981                                                 {
 982                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
 983                                                 }
 984                                                 else  // everything went okay, continue with creating vote
 985                                                 {
 986                                                         vote_caller = caller;
 987                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 988                                                         vote_called = VOTE_MASTER;
 989                                                         vote_called_command = strzone("XXX");
 990                                                         vote_called_display = strzone("^3master");
 991                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 992
 993                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 994                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 995
 996                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 997                                                         if (autocvar_sv_eventlog)
 998                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 999                                                         Nagger_VoteChanged();
1000                                                         VoteCount(true);  // needed if you are the only one
1001                                                 }
1002
1003                                                 return;
1004                                         }
1005                                 }
1006                         }
1007                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1008
1009                         return;
1010                 }
1011
1012                 default:
1013                 case CMD_REQUEST_USAGE:
1014                 {
1015                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
1016                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
1017                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
1018                         return;
1019                 }
1020         }
1021 }
1022
1023 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1024 {
1025         switch (request)
1026         {
1027                 case CMD_REQUEST_COMMAND:
1028                 {
1029                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1030                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1031                         {
1032                                 print_to(caller, "^1You have already voted.");
1033                         }
1034                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1035                         {
1036                                 VoteStop(caller);
1037                         }
1038
1039                         else  // everything went okay, continue changing vote
1040                         {
1041                                 print_to(caller, "^1You rejected the vote.");
1042                                 caller.vote_selection = VOTE_SELECT_REJECT;
1043                                 msg_entity = caller;
1044                                 if (!autocvar_sv_vote_singlecount)
1045                                         VoteCount(false);
1046                         }
1047
1048                         return;
1049                 }
1050
1051                 default:
1052                 case CMD_REQUEST_USAGE:
1053                 {
1054                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1055                         print_to(caller, "  No arguments required.");
1056                         return;
1057                 }
1058         }
1059 }
1060
1061 void VoteCommand_status(int request, entity caller)  // BOTH
1062 {
1063         switch (request)
1064         {
1065                 case CMD_REQUEST_COMMAND:
1066                 {
1067                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1068                         else print_to(caller, "^1No vote called.");
1069
1070                         return;
1071                 }
1072
1073                 default:
1074                 case CMD_REQUEST_USAGE:
1075                 {
1076                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1077                         print_to(caller, "  No arguments required.");
1078                         return;
1079                 }
1080         }
1081 }
1082
1083 void VoteCommand_stop(int request, entity caller)  // BOTH
1084 {
1085         switch (request)
1086         {
1087                 case CMD_REQUEST_COMMAND:
1088                 {
1089                         if (!vote_called)   print_to(caller, "^1No vote called.");
1090                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1091                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1092                         return;
1093                 }
1094
1095                 default:
1096                 case CMD_REQUEST_USAGE:
1097                 {
1098                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1099                         print_to(caller, "  No arguments required.");
1100                         return;
1101                 }
1102         }
1103 }
1104
1105 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1106 {
1107         switch (request)
1108         {
1109                 case CMD_REQUEST_COMMAND:
1110                 {
1111                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1112                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1113                         {
1114                                 print_to(caller, "^1You have already voted.");
1115                         }
1116                         else  // everything went okay, continue changing vote
1117                         {
1118                                 print_to(caller, "^1You accepted the vote.");
1119                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1120                                 msg_entity = caller;
1121                                 if (!autocvar_sv_vote_singlecount)
1122                                         VoteCount(false);
1123                         }
1124
1125                         return;
1126                 }
1127
1128                 default:
1129                 case CMD_REQUEST_USAGE:
1130                 {
1131                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1132                         print_to(caller, "  No arguments required.");
1133                         return;
1134                 }
1135         }
1136 }
1137
1138 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1139 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1140 void VoteCommand_(int request)
1141 {
1142     switch(request)
1143     {
1144         case CMD_REQUEST_COMMAND:
1145         {
1146
1147             return;
1148         }
1149
1150         default:
1151         case CMD_REQUEST_USAGE:
1152         {
1153             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1154             print_to(caller, "  No arguments required.");
1155             return;
1156         }
1157     }
1158 }
1159 */
1160
1161
1162 // ================================
1163 //  Macro system for vote commands
1164 // ================================
1165
1166 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1167 #define VOTE_COMMANDS(request, caller, arguments, command) \
1168         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1169         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1170         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1171         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1172         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1173         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1174         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1175         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1176         /* nothing */
1177
1178 void VoteCommand_macro_help(entity caller, int argc)
1179 {
1180         string command_origin = GetCommandPrefix(caller);
1181
1182         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1183         {
1184                 print_to(caller, "\nVoting commands:\n");
1185                 #define VOTE_COMMAND(name, function, description, assignment) \
1186                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1187
1188                 VOTE_COMMANDS(0, caller, 0, "");
1189 #undef VOTE_COMMAND
1190
1191                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1192                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1193                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1194         }
1195         else  // usage for individual command
1196         {
1197                 #define VOTE_COMMAND(name, function, description, assignment) \
1198                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1199
1200                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1201 #undef VOTE_COMMAND
1202
1203                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1204                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1205                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1206                 else
1207                         print_to(caller, "No documentation exists for this vote");
1208         }
1209 }
1210
1211 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1212 {
1213         #define VOTE_COMMAND(name, function, description, assignment) \
1214                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1215
1216         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1217 #undef VOTE_COMMAND
1218
1219         return false;
1220 }
1221
1222
1223 // ======================================
1224 //  Main function handling vote commands
1225 // ======================================
1226
1227 void VoteCommand(int request, entity caller, int argc, string vote_command)
1228 {
1229         // Guide for working with argc arguments by example:
1230         // argc:   1    - 2      - 3     - 4
1231         // argv:   0    - 1      - 2     - 3
1232         // cmd     vote - master - login - password
1233
1234         switch (request)
1235         {
1236                 case CMD_REQUEST_COMMAND:
1237                 {
1238                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1239                 }
1240
1241                 default:
1242                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1243                 case CMD_REQUEST_USAGE:
1244                 {
1245                         VoteCommand_macro_help(caller, argc);
1246                         return;
1247                 }
1248         }
1249 }