qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/items/inventory.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/playerstats.qh>
  11 #include <common/stats.qh>
  12 #include <common/util.qh>
  13 #include <common/weapons/_all.qh>
  14 #include <server/campaign.qh>
  15 #include <server/client.qh>
  16 #include <server/command/banning.qh>
  17 #include <server/command/common.qh>
  18 #include <server/command/vote.qh>
  19 #include <server/damage.qh>
  20 #include <server/gamelog.qh>
  21 #include <server/intermission.qh>
  22 #include <server/mutators/_mod.qh>
  23 #include <server/race.qh>
  24 #include <server/round_handler.qh>
  25 #include <server/scores.qh>
  26 #include <server/teamplay.qh>
  27 #include <server/weapons/accuracy.qh>
  28 #include <server/world.qh>
  29
  30 // =============================================
  31 //  Server side voting code, reworked by Samual
  32 //  Last updated: December 27th, 2011
  33 // =============================================
  34
  35 //  Nagger for players to know status of voting
  36 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  37 {
  38         int nags = 0;
  39         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  40
  41         // bits:
  42         //   1 = ready
  43         //   2 = player needs to ready up
  44         //   4 = vote
  45         //   8 = player needs to vote
  46         //  16 = warmup
  47         // sendflags:
  48         //  64 = vote counts
  49         // 128 = vote string
  50
  51         if (warmup_stage)
  52         {
  53                 if (readycount)
  54                 {
  55                         nags |= BIT(0);
  56                         if (!to.ready) nags |= BIT(1);
  57                 }
  58                 nags |= BIT(4);
  59         }
  60
  61         if (vote_called)
  62         {
  63                 nags |= BIT(2);
  64                 if (to.vote_selection == 0) nags |= BIT(3);
  65                 nags |= sendflags & BIT(6);
  66                 nags |= sendflags & BIT(7);
  67         }
  68
  69         WriteByte(MSG_ENTITY, nags);
  70
  71         if (nags & BIT(6))
  72         {
  73                 WriteByte(MSG_ENTITY, vote_accept_count);
  74                 WriteByte(MSG_ENTITY, vote_reject_count);
  75                 WriteByte(MSG_ENTITY, vote_needed_overall);
  76                 WriteChar(MSG_ENTITY, to.vote_selection);
  77         }
  78
  79         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  80
  81         if (nags & BIT(0))
  82         {
  83                 for (int i = 1; i <= maxclients;)
  84                 {
  85                         int f = 0;
  86                         for (int b = 0; b < 8 && i <= maxclients; ++b, ++i)
  87                                 if (edict_num(i).ready)
  88                                         f |= BIT(b);
  89                         WriteByte(MSG_ENTITY, f);
  90                 }
  91         }
  92
  93         return true;
  94 }
  95
  96 void Nagger_Init()
  97 {
  98         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
  99 }
 100
 101 void Nagger_VoteChanged()
 102 {
 103         if (nagger) nagger.SendFlags |= BIT(7);
 104 }
 105
 106 void Nagger_VoteCountChanged()
 107 {
 108         if (nagger) nagger.SendFlags |= BIT(6);
 109 }
 110
 111 void Nagger_ReadyCounted()
 112 {
 113         if (nagger) nagger.SendFlags |= BIT(0);
 114 }
 115
 116 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 117 string OriginalCallerName()
 118 {
 119         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 120         return vote_caller_name;
 121 }
 122
 123 // =======================
 124 //  Game logic for voting
 125 // =======================
 126
 127 void VoteStop(entity stopper, bool show_name);
 128 void VoteReset(bool verbose)
 129 {
 130         if (verbose && vote_called)
 131         {
 132                 VoteStop(NULL, true);
 133                 return;
 134         }
 135
 136         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 137
 138         if (vote_called)
 139         {
 140                 strfree(vote_called_command);
 141                 strfree(vote_called_display);
 142                 strfree(vote_caller_name);
 143         }
 144
 145         vote_called = VOTE_NULL;
 146         vote_caller = NULL;
 147         vote_endtime = 0;
 148
 149         vote_parsed_command = string_null;
 150         vote_parsed_display = string_null;
 151
 152         Nagger_VoteChanged();
 153 }
 154
 155 void VoteStop(entity stopper, bool canceled)
 156 {
 157         if (canceled)
 158                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote was canceled\n");
 159         else
 160                 bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 161         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 162         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 163         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 164         VoteReset(false);
 165 }
 166
 167 void VoteAccept()
 168 {
 169         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 170
 171         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = true;
 172         else localcmd(strcat(vote_called_command, "\n"));
 173
 174         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 175
 176         VoteReset(false);
 177         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 178 }
 179
 180 void VoteReject()
 181 {
 182         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 183         VoteReset(false);
 184         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 185 }
 186
 187 void VoteTimeout()
 188 {
 189         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 190         VoteReset(false);
 191         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 192 }
 193
 194 void VoteSpam(float notvoters, float mincount, string result)
 195 {
 196         bprint(strcat(
 197                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 198                 strcat("^2:^1", ftos(vote_reject_count)),
 199                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 200                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 201                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 202
 203         if (autocvar_sv_eventlog)
 204         {
 205                 GameLogEcho(strcat(
 206                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 207                         strcat(":", ftos(vote_reject_count)),
 208                         strcat(":", ftos(vote_abstain_count)),
 209                         strcat(":", ftos(notvoters)),
 210                         strcat(":", ftos(mincount))));
 211         }
 212 }
 213
 214 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 215
 216 void VoteCount(float first_count)
 217 {
 218         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 219
 220         float vote_player_count = 0, notvoters = 0;
 221         float vote_real_player_count = 0, vote_real_accept_count = 0;
 222         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 223         float vote_needed_of_voted, final_needed_votes;
 224         float vote_factor_overall, vote_factor_of_voted;
 225
 226         Nagger_VoteCountChanged();
 227
 228         // add up all the votes from each connected client
 229         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_vote_debug, {
 230                 ++vote_player_count;
 231                 if (IS_PLAYER(it) || INGAME(it)) ++vote_real_player_count;
 232                 switch (it.vote_selection)
 233                 {
 234                         case VOTE_SELECT_REJECT:
 235                                 ++vote_reject_count;
 236                                 if (IS_PLAYER(it) || INGAME(it)) ++vote_real_reject_count;
 237                                 break;
 238                         case VOTE_SELECT_ACCEPT:
 239                                 ++vote_accept_count;
 240                                 if (IS_PLAYER(it) || INGAME(it)) ++vote_real_accept_count;
 241                                 break;
 242                         case VOTE_SELECT_ABSTAIN:
 243                                 ++vote_abstain_count;
 244                                 if (IS_PLAYER(it) || INGAME(it)) ++vote_real_abstain_count;
 245                                 break;
 246                         default: break;
 247                 }
 248         });
 249
 250         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 251         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 252         {
 253                 if (vote_caller)   vote_caller.vote_waittime = 0;
 254                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 255                 VoteReset(false);
 256                 return;
 257         }
 258
 259         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 260         if (!spectators_allowed && (vote_real_player_count > 0))
 261         {
 262                 vote_accept_count = vote_real_accept_count;
 263                 vote_reject_count = vote_real_reject_count;
 264                 vote_abstain_count = vote_real_abstain_count;
 265                 vote_player_count = vote_real_player_count;
 266         }
 267
 268         // people who have no opinion in any way :D
 269         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 270
 271         // determine the goal for the vote to be passed or rejected normally
 272         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 273         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 274
 275         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 276         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 277         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 278
 279         // are there any players at all on the server? it could be an admin vote
 280         if (vote_player_count == 0 && first_count)
 281         {
 282                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 283                 VoteAccept();
 284                 return;
 285         }
 286
 287         // since there ARE players, finally calculate the result of the vote
 288         if (vote_accept_count >= vote_needed_overall)
 289         {
 290                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 291                 VoteAccept();
 292                 return;
 293         }
 294
 295         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 296         {
 297                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 298                 VoteReject();
 299                 return;
 300         }
 301
 302         // there is not enough votes in either direction, now lets just calculate what the voters have said
 303         if (time > vote_endtime)
 304         {
 305                 final_needed_votes = vote_needed_overall;
 306
 307                 if (autocvar_sv_vote_majority_factor_of_voted)
 308                 {
 309                         if (vote_accept_count >= vote_needed_of_voted)
 310                         {
 311                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 312                                 VoteAccept();
 313                                 return;
 314                         }
 315
 316                         if (vote_accept_count + vote_reject_count > 0)
 317                         {
 318                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 319                                 VoteReject();
 320                                 return;
 321                         }
 322
 323                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 324                 }
 325
 326                 // it didn't pass or fail, so not enough votes to even make a decision.
 327                 VoteSpam(notvoters, final_needed_votes, "timeout");
 328                 VoteTimeout();
 329         }
 330 }
 331
 332 void VoteThink()
 333 {
 334         if (vote_endtime > 0)        // a vote was called
 335         {
 336                 if (time > vote_endtime) // time is up
 337                         VoteCount(false);
 338         }
 339 }
 340
 341
 342 // =======================
 343 //  Game logic for warmup
 344 // =======================
 345
 346 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 347 void reset_map(bool is_fake_round_start)
 348 {
 349         if (time <= game_starttime)
 350         {
 351                 if (game_stopped)
 352                         return;
 353
 354                 if (!is_fake_round_start)
 355                 {
 356                         Score_ClearAll();
 357                         PlayerStats_GameReport_Reset_All();
 358                 }
 359
 360                 if (round_handler_IsActive())
 361                         round_handler_Reset(game_starttime);
 362         }
 363
 364         if (shuffleteams_on_reset_map)
 365         {
 366                 shuffleteams();
 367                 shuffleteams_on_reset_map = false;
 368         }
 369
 370         FOREACH_CLIENT(true, {
 371                 if (time <= game_starttime)
 372                         accuracy_reset(it); // for spectators too because weapon accuracy is persistent
 373                 if (!IS_PLAYER(it))
 374                         continue;
 375                 if (STAT(FROZEN, it))
 376                         Unfreeze(it, false);
 377                 player_powerups_remove_all(it);
 378                 entity store = PS(it);
 379                 if (store)
 380                 {
 381                         Inventory_clear(store.inventory);
 382                         Inventory_update(store);
 383                 }
 384         });
 385
 386         MUTATOR_CALLHOOK(reset_map_global);
 387
 388         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 389         {
 390                 if(IS_CLIENT(it))
 391                         continue;
 392                 if (it.reset)
 393                 {
 394                         it.reset(it);
 395                         continue;
 396                 }
 397                 if (it.team_saved) it.team = it.team_saved;
 398                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 399         });
 400
 401         // Waypoints and assault start come LAST
 402         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 403                 if (it.reset2) it.reset2(it);
 404         });
 405
 406         // Moving the player reset code here since the player-reset depends
 407         // on spawnpoint entities which have to be reset first --blub
 408         if (!MUTATOR_CALLHOOK(reset_map_players))
 409         {
 410                 FOREACH_CLIENT(IS_PLAYER(it),
 411                 {
 412                         // PlayerScore_Clear(it);
 413                         CS(it).killcount = 0;
 414                         // stop the player from moving so that they stand still once they get respawned
 415                         it.velocity = '0 0 0';
 416                         it.avelocity = '0 0 0';
 417                         CS(it).movement = '0 0 0';
 418                         PutClientInServer(it);
 419                 });
 420         }
 421 }
 422
 423 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 424 void ReadyRestart_think(entity this)
 425 {
 426         if (!warmup_stage) // if the countdown was not aborted
 427                 reset_map(false);
 428         delete(this);
 429 }
 430
 431 // Forces a restart of the game without actually reloading the map // this is a mess...
 432 void ReadyRestart_force(bool is_fake_round_start)
 433 {
 434         if (time <= game_starttime && game_stopped)
 435                 return;
 436         if (!is_fake_round_start && !autocvar_g_campaign)
 437                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_COUNTDOWN_RESTART);
 438
 439         VoteReset(true);
 440
 441         // clear overtime, we have to decrease timelimit to its original value again.
 442         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 443                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 444         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = overtimes = 0;
 445
 446         if(warmup_stage)
 447                 game_starttime = time; // Warmup: No countdown in warmup
 448         else if (autocvar_g_campaign)
 449                 game_starttime = time + 3;
 450         else
 451                 game_starttime = time + RESTART_COUNTDOWN; // Go into match mode
 452
 453         // clear player attributes
 454         FOREACH_CLIENT(IS_PLAYER(it), {
 455                 it.alivetime = 0;
 456                 CS(it).killcount = 0;
 457         });
 458
 459         // if we're ending the warmup stage call the corresponding hook
 460         if(!is_fake_round_start && !warmup_stage)
 461                 localcmd("\nsv_hook_warmupend\n");
 462
 463         // reset the .ready status of all clients (including spectators and bots)
 464         FOREACH_CLIENT(true, { it.ready = false; });
 465         readycount = 0;
 466         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 467
 468         // lock teams with lockonrestart
 469         if (autocvar_teamplay_lockonrestart && teamplay)
 470                 lockteams = !warmup_stage;
 471
 472         // initiate the restart-countdown-announcer entity
 473         if (!is_fake_round_start && sv_ready_restart_after_countdown && !warmup_stage)
 474         {
 475                 entity restart_timer = new_pure(restart_timer);
 476                 setthink(restart_timer, ReadyRestart_think);
 477                 restart_timer.nextthink = game_starttime;
 478         }
 479
 480         // after a restart every players number of allowed timeouts gets reset, too
 481         if (autocvar_sv_timeout)
 482         {
 483                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 484         }
 485
 486         if (!sv_ready_restart_after_countdown || warmup_stage)
 487                 reset_map(is_fake_round_start);
 488
 489         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 490 }
 491
 492 void ReadyRestart(bool forceWarmupEnd)
 493 {
 494         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing)
 495         {
 496                 // NOTE: ReadyRestart support is mandatory in campaign
 497                 if (autocvar_g_campaign)
 498                         error("ReadyRestart must be supported in campaign mode!");
 499                 localcmd("restart\n"); // if ReadyRestart is denied, restart the server
 500         }
 501         else localcmd("\nsv_hook_readyrestart\n");
 502
 503         if(forceWarmupEnd || autocvar_g_campaign)
 504                 warmup_stage = 0; // forcefully end warmup and go to match stage
 505         else
 506                 warmup_stage = autocvar_g_warmup; // go into warmup if it's enabled, otherwise restart into match stage
 507
 508         ReadyRestart_force(false);
 509 }
 510
 511 /* Count the players who are ready and determine whether or not to restart the match when:
 512  * a player presses F4                      server/command/cmd.qc  ClientCommand_ready()
 513  * a player switches from players to specs  server/client.qc       PutObserverInServer()
 514  * a player joins (from specs or directly)  server/client.qc       PutPlayerInServer()
 515  * a player disconnects                     server/client.qc       ClientDisconnect()   */
 516 void ReadyCount()
 517 {
 518         // cannot reset the game while a timeout is active or pending
 519         if (timeout_status) return;
 520
 521         int total_players = 0, human_players = 0, humans_ready = 0;
 522         readycount = 0;
 523
 524         FOREACH_CLIENT(IS_PLAYER(it) || INGAME_JOINED(it), {
 525                 ++total_players;
 526                 if (it.ready) ++readycount;
 527                 if (IS_REAL_CLIENT(it))
 528                 {
 529                         ++human_players;
 530                         if (it.ready) ++humans_ready;
 531                 }
 532         });
 533
 534         Nagger_ReadyCounted();
 535
 536         // can't read warmup_stage here as it could have been set to 0 by ReadyRestart()
 537         // and we need to use this when checking if we should abort the countdown
 538         // map_minplayers can only be > 0 if g_warmup was -1 at worldspawn
 539         int minplayers = autocvar_g_warmup > 1 ? autocvar_g_warmup : map_minplayers;
 540
 541         if (total_players < minplayers)
 542         {
 543                 if (game_starttime > time) // someone bailed during countdown, back to warmup
 544                 {
 545                         warmup_stage = autocvar_g_warmup; // CAN change it AFTER calling Nagger_ReadyCounted() this frame
 546                         game_starttime = time;
 547                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, COUNTDOWN_STOP, minplayers);
 548                         if (!sv_ready_restart_after_countdown) // if we ran reset_map() at start of countdown
 549                                 FOREACH_CLIENT(IS_PLAYER(it), { GiveWarmupResources(it); });
 550                 }
 551                 if (warmup_limit > 0)
 552                         warmup_limit = -1;
 553                 return; // don't ReadyRestart if players are ready but too few
 554         }
 555         else if (minplayers && warmup_limit <= 0)
 556         {
 557                 // there's enough players now but we're still in infinite warmup
 558                 warmup_limit = cvar("g_warmup_limit");
 559                 if (warmup_limit == 0)
 560                         warmup_limit = autocvar_timelimit * 60;
 561                 if (warmup_limit > 0)
 562                         game_starttime = time;
 563                 // implicit else: g_warmup -1 && g_warmup_limit -1 means
 564                 // warmup continues until enough players AND enough RUPs (no time limit)
 565         }
 566
 567         if (humans_ready && humans_ready >= rint(human_players * bound(0.5, cvar("g_warmup_majority_factor"), 1)))
 568                 ReadyRestart(true);
 569 }
 570
 571
 572 // ======================================
 573 //  Supporting functions for VoteCommand
 574 // ======================================
 575
 576 bool Votecommand_check_assignment(entity caller, float assignment)
 577 {
 578         bool from_server = (!caller);
 579
 580         if ((assignment == VC_ASGNMNT_BOTH)
 581             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 582             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 583
 584         return false;
 585 }
 586
 587 string VoteCommand_extractcommand(string input, float startpos, int argc)
 588 {
 589         string output;
 590
 591         if ((argc - 1) < startpos) output = "";
 592         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 593
 594         return output;
 595 }
 596
 597 bool VoteCommand_checknasty(string vote_command)
 598 {
 599         return !((strstrofs(vote_command, ";", 0) >= 0)
 600             || (strstrofs(vote_command, "\n", 0) >= 0)
 601             || (strstrofs(vote_command, "\r", 0) >= 0)
 602             || (strstrofs(vote_command, "$", 0) >= 0));
 603 }
 604
 605 // NOTE: requires input to be surrounded by spaces
 606 string VoteCommand_checkreplacements(string input)
 607 {
 608         // add a space around the input so the start and end of the list is captured
 609         string output = strcat(" ", input, " ");
 610         // allow gotomap replacements
 611         output = strreplace(" map ", " gotomap ", output);
 612         output = strreplace(" chmap ", " gotomap ", output);
 613         return output;
 614 }
 615
 616 bool VoteCommand_checkinlist(string vote_command, string list)
 617 {
 618         if (vote_command == "" || list == "")
 619                 return false;
 620
 621         string l = VoteCommand_checkreplacements(list);
 622         return (strstrofs(l, VoteCommand_checkreplacements(vote_command), 0) >= 0);
 623 }
 624
 625 string ValidateMap(string validated_map, entity caller)
 626 {
 627         validated_map = MapInfo_FixName(validated_map);
 628
 629         if (!validated_map)
 630         {
 631                 print_to(caller, "This map is not available on this server.");
 632                 return string_null;
 633         }
 634
 635         if (!autocvar_sv_vote_override_mostrecent && caller)
 636         {
 637                 if (Map_IsRecent(validated_map))
 638                 {
 639                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 640                         return string_null;
 641                 }
 642         }
 643
 644         if (!MapInfo_CheckMap(validated_map))
 645         {
 646                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 647                 return string_null;
 648         }
 649
 650         return validated_map;
 651 }
 652
 653 float VoteCommand_checkargs(float startpos, int argc)
 654 {
 655         float p, q, check, minargs;
 656         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 657         string cmdrestriction = "";  // No we don't.
 658         string charlist, arg;
 659         float checkmate;
 660
 661         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 662                 cmdrestriction = cvar_string(cvarname);
 663         else
 664                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 665
 666         if (cmdrestriction == "") return true;
 667
 668         ++startpos;  // skip command name
 669
 670         // check minimum arg count
 671
 672         // 0 args: argc == startpos
 673         // 1 args: argc == startpos + 1
 674         // ...
 675
 676         minargs = stof(cmdrestriction);
 677         if (argc - startpos < minargs) return false;
 678
 679         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 680
 681         for ( ; ; )
 682         {
 683                 // we know that at any time, startpos <= argc - minargs
 684                 // so this means: argc-minargs >= startpos >= argc, thus
 685                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 686                 // have been seen already
 687
 688                 if (startpos >= argc) // all args checked? GOOD
 689                         break;
 690
 691                 if (p < 0)            // no more args? FAIL
 692                 {
 693                         // exception: exactly minargs left, this one included
 694                         if (argc - startpos == minargs) break;
 695
 696                         // otherwise fail
 697                         return false;
 698                 }
 699
 700                 // cut to next semicolon
 701                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 702                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 703                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 704
 705                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 706                 // charlist = strreplace("^^", ";", charlist);
 707
 708                 if (charlist != "")
 709                 {
 710                         // verify the arg only contains allowed chars
 711                         arg = argv(startpos);
 712                         checkmate = strlen(arg);
 713                         for (check = 0; check < checkmate; ++check)
 714                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 715                         // not allowed character
 716                         // all characters are allowed. FINE.
 717                 }
 718
 719                 ++startpos;
 720                 --minargs;
 721                 p = q;
 722         }
 723
 724         return true;
 725 }
 726
 727 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 728 {
 729         string first_command = argv(startpos);
 730         int missing_chars = argv_start_index(startpos);
 731
 732         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 733                 return 0;
 734
 735         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 736
 737         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 738
 739         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 740         {
 741                 case MUT_VOTEPARSE_CONTINUE: { break; }
 742                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 743                 case MUT_VOTEPARSE_INVALID: { return -1; }
 744                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 745         }
 746
 747         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 748         {
 749                 case "kick":
 750                 case "kickban":    // catch all kick/kickban commands
 751                 {
 752                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 753                         float accepted = VerifyClientEntity(victim, true, false);
 754
 755                         if (accepted > 0)
 756                         {
 757                                 string reason = "No reason provided";
 758                                 if(argc > next_token)
 759                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 760
 761                                 string command_arguments = reason;
 762                                 if (first_command == "kickban")
 763                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 764
 765                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 766                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 767                         }
 768                         else
 769                         {
 770                                 print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
 771                                 return 0;
 772                         }
 773
 774                         break;
 775                 }
 776
 777                 case "map":
 778                 case "chmap":
 779                 case "gotomap":  // re-direct all map selection commands to gotomap
 780                 {
 781                         vote_command = ValidateMap(argv(startpos + 1), caller);
 782                         if (!vote_command)  return -1;
 783                         vote_parsed_command = strcat("gotomap ", vote_command);
 784                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 785
 786                         break;
 787                 }
 788
 789                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 790                 // maybe fallback instead of aborting if map name is invalid?
 791                 case "nextmap":
 792                 {
 793                         vote_command = ValidateMap(argv(startpos + 1), caller);
 794                         if (!vote_command)  return -1;
 795                         vote_parsed_command = strcat("nextmap ", vote_command);
 796                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 797
 798                         break;
 799                 }
 800
 801                 case "timelimit": // include restrictions on the maximum votable time limit
 802                 {
 803                         float timelimit_vote = stof(argv(startpos + 1));
 804                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 805                         {
 806                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 807                                 return -1;
 808                         }
 809                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 810                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 811                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 812
 813                         break;
 814                 }
 815
 816                 case "restart":
 817                 {
 818                         // add a delay so that vote result can be seen and announcer can be heard
 819                         // if the vote is accepted
 820                         vote_parsed_command = strcat("defer 1 ", vote_command);
 821                         vote_parsed_display = strzone(strcat("^1", vote_command));
 822
 823                         break;
 824                 }
 825
 826                 case "allready":
 827                 {
 828                         if(!warmup_stage) {
 829                                 print_to(caller, "Game already started. Use the resetmatch command to restart the match.");
 830                                 return -1;
 831                         }
 832
 833                         vote_parsed_command = vote_command;
 834                         vote_parsed_display = strzone(strcat("^1", vote_command));
 835                         break;
 836                 }
 837
 838                 default:
 839                 {
 840                         vote_parsed_command = vote_command;
 841                         vote_parsed_display = strzone(strcat("^1", vote_command));
 842
 843                         break;
 844                 }
 845         }
 846
 847         return 1;
 848 }
 849
 850
 851 // =======================
 852 //  Command Sub-Functions
 853 // =======================
 854
 855 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 856 {
 857         switch (request)
 858         {
 859                 case CMD_REQUEST_COMMAND:
 860                 {
 861                         if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
 862                         {
 863                                 print_to(caller, "^1You are banned from voting.");
 864                                 Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBANYN);
 865                                 return;
 866                         }
 867
 868                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 869                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 870                         {
 871                                 print_to(caller, "^1You have already voted.");
 872                         }
 873
 874                         else  // everything went okay, continue changing vote
 875                         {
 876                                 print_to(caller, "^1You abstained from your vote.");
 877                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 878                                 msg_entity = caller;
 879                                 if (!autocvar_sv_vote_singlecount)
 880                                         VoteCount(false);
 881                         }
 882
 883                         return;
 884                 }
 885
 886                 default:
 887                 case CMD_REQUEST_USAGE:
 888                 {
 889                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 890                         print_to(caller, "  No arguments required.");
 891                         return;
 892                 }
 893         }
 894 }
 895
 896 void print_available_commands_to(entity caller)
 897 {
 898         print_to(caller, strcat("You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 899 }
 900
 901 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 902 {
 903         switch (request)
 904         {
 905                 case CMD_REQUEST_COMMAND:
 906                 {
 907                         float tmp_playercount = 0;
 908                         int parse_error;
 909
 910                         if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
 911                         {
 912                                 print_to(caller, "^1You are banned from calling a vote.");
 913                                 Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBAN);
 914                                 return;
 915                         }
 916
 917                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 918
 919                         if (!autocvar_sv_vote_call && caller)
 920                         {
 921                                 print_to(caller, "^1Vote calling is not allowed.");
 922                         }
 923                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 924                         {
 925                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 926                         }
 927                         else if (vote_called)
 928                         {
 929                                 print_to(caller, "^1There is already a vote called.");
 930                         }
 931                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 932                         {
 933                                 print_to(caller, "^1Only players can call a vote.");
 934                         }
 935                         else if (caller && !IS_CLIENT(caller))
 936                         {
 937                                 print_to(caller, "^1Only connected clients can vote.");
 938                         }
 939                         else if (timeout_status && vote_command != "timein")
 940                         {
 941                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 942                         }
 943                         else if (caller && (time < caller.vote_waittime))
 944                         {
 945                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 946                         }
 947                         else if (!VoteCommand_checknasty(vote_command))
 948                         {
 949                                 print_to(caller, "^1Syntax error in command.");
 950                         }
 951                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 952                         {
 953                                 if(parse_error == 0)
 954                                 {
 955                                         if (vote_called_command == "")
 956                                                 VoteCommand_call(CMD_REQUEST_USAGE, caller, argc, vote_command);
 957                                         else
 958                                                 print_to(caller, "^1This command is not acceptable or not available.");
 959                                 }
 960                         }
 961                         else  // everything went okay, continue with calling the vote
 962                         {
 963                                 vote_caller = caller;  // remember who called the vote
 964                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 965                                 vote_called = VOTE_NORMAL;
 966                                 vote_called_command = strzone(vote_parsed_command);
 967                                 vote_called_display = strzone(vote_parsed_display);
 968                                 vote_endtime = time + autocvar_sv_vote_timeout;
 969
 970                                 if (caller)
 971                                 {
 972                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 973                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 974                                         msg_entity = caller;
 975                                 }
 976
 977                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 978
 979                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 980                                 if (autocvar_sv_vote_debug)
 981                                         bprint("\{1}^2* ^3", "^6DEBUG MODE ACTIVE: bots can vote too\n"); // so servers don't forget it on
 982                                 if (autocvar_sv_eventlog)
 983                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 984                                 Nagger_VoteChanged();
 985                                 VoteCount(true);  // needed if you are the only one
 986
 987                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
 988                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 989                         }
 990
 991                         return;
 992                 }
 993
 994                 default:
 995                 case CMD_REQUEST_USAGE:
 996                 {
 997                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call <command>"));
 998                         print_to(caller, "  Where <command> is the command to request a vote upon.");
 999                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
1000                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
1001                         print_available_commands_to(caller);
1002                         print_to(caller, "Shortcuts: ^2vcall <command>, vend, vmap, vkick, ...");
1003                         return;
1004                 }
1005         }
1006 }
1007
1008 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
1009 {
1010         switch (request)
1011         {
1012                 case CMD_REQUEST_COMMAND:
1013                 {
1014                         if (autocvar_sv_vote_master)
1015                         {
1016                                 switch (strtolower(argv(2)))
1017                                 {
1018                                         case "do":
1019                                         {
1020                                                 int parse_error;
1021                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
1022
1023                                                 if (!caller.vote_master)
1024                                                         print_to(caller, "^1You do not have vote master privileges.");
1025                                                 else if (!VoteCommand_checknasty(vote_command))
1026                                                 {
1027                                                         print_to(caller, "^1Syntax error in command.");
1028                                                 }
1029                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
1030                                                 {
1031                                                         if(parse_error == 0)
1032                                                         {
1033                                                                 if (vote_called_command == "")
1034                                                                         VoteCommand_master(CMD_REQUEST_USAGE, caller, argc, vote_command);
1035                                                                 else
1036                                                                         print_to(caller, "^1This command is not acceptable or not available.");
1037                                                         }
1038                                                 }
1039                                                 else  // everything went okay, proceed with command
1040                                                 {
1041                                                         localcmd(strcat(vote_parsed_command, "\n"));
1042                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
1043                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
1044                                                         if (autocvar_sv_eventlog)
1045                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
1046                                                 }
1047
1048                                                 return;
1049                                         }
1050
1051                                         case "login":
1052                                         {
1053                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
1054                                                 else if (caller.vote_master)
1055                                                 {
1056                                                         print_to(caller, "^1You are already logged in as vote master.");
1057                                                 }
1058                                                 else if (autocvar_sv_vote_master_password != argv(3))
1059                                                 {
1060                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
1061                                                 }
1062                                                 else  // everything went okay, proceed with giving this player master privilages
1063                                                 {
1064                                                         caller.vote_master = true;
1065                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
1066                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
1067                                                         if (autocvar_sv_eventlog)
1068                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
1069                                                 }
1070
1071                                                 return;
1072                                         }
1073
1074                                         default:  // calling a vote for master
1075                                         {
1076                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
1077                                                 else if (vote_called)
1078                                                 {
1079                                                         print_to(caller, "^1There is already a vote called.");
1080                                                 }
1081                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
1082                                                 {
1083                                                         print_to(caller, "^1Only players can call a vote.");
1084                                                 }
1085                                                 else if (timeout_status)
1086                                                 {
1087                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
1088                                                 }
1089                                                 else  // everything went okay, continue with creating vote
1090                                                 {
1091                                                         vote_caller = caller;
1092                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
1093                                                         vote_called = VOTE_MASTER;
1094                                                         vote_called_command = strzone("XXX");
1095                                                         vote_called_display = strzone("^3master");
1096                                                         vote_endtime = time + autocvar_sv_vote_timeout;
1097
1098                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1099                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1100
1101                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
1102                                                         if (autocvar_sv_eventlog)
1103                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1104                                                         Nagger_VoteChanged();
1105                                                         VoteCount(true);  // needed if you are the only one
1106                                                 }
1107
1108                                                 return;
1109                                         }
1110                                 }
1111                         }
1112                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1113
1114                         return;
1115                 }
1116
1117                 default:
1118                 case CMD_REQUEST_USAGE:
1119                 {
1120                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [<action> [<command> | <password>]]"));
1121                         print_to(caller, "  If <action> is left blank, it calls a vote for you to become master.");
1122                         print_to(caller, "  Otherwise it can be either 'do' (to run <command>) or 'login' as master.");
1123                         return;
1124                 }
1125         }
1126 }
1127
1128 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1129 {
1130         switch (request)
1131         {
1132                 case CMD_REQUEST_COMMAND:
1133                 {
1134                         if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
1135                         {
1136                                 print_to(caller, "^1You are banned from voting.");
1137                                 Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBANYN);
1138                                 return;
1139                         }
1140
1141                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1142                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1143                         {
1144                                 print_to(caller, "^1You have already voted.");
1145                         }
1146                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1147                         {
1148                                 VoteStop(caller, true);
1149                         }
1150
1151                         else  // everything went okay, continue changing vote
1152                         {
1153                                 print_to(caller, "^1You rejected the vote.");
1154                                 caller.vote_selection = VOTE_SELECT_REJECT;
1155                                 msg_entity = caller;
1156                                 if (!autocvar_sv_vote_singlecount)
1157                                         VoteCount(false);
1158                         }
1159
1160                         return;
1161                 }
1162
1163                 default:
1164                 case CMD_REQUEST_USAGE:
1165                 {
1166                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1167                         print_to(caller, "  No arguments required.");
1168                         return;
1169                 }
1170         }
1171 }
1172
1173 void VoteCommand_status(int request, entity caller)  // BOTH
1174 {
1175         switch (request)
1176         {
1177                 case CMD_REQUEST_COMMAND:
1178                 {
1179                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1180                         else print_to(caller, "^1No vote called.");
1181
1182                         return;
1183                 }
1184
1185                 default:
1186                 case CMD_REQUEST_USAGE:
1187                 {
1188                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1189                         print_to(caller, "  No arguments required.");
1190                         return;
1191                 }
1192         }
1193 }
1194
1195 void VoteCommand_stop(int request, entity caller)  // BOTH
1196 {
1197         switch (request)
1198         {
1199                 case CMD_REQUEST_COMMAND:
1200                 {
1201                         if (!vote_called)   print_to(caller, "^1No vote called.");
1202                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller, false);
1203                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1204                         return;
1205                 }
1206
1207                 default:
1208                 case CMD_REQUEST_USAGE:
1209                 {
1210                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1211                         print_to(caller, "  No arguments required.");
1212                         return;
1213                 }
1214         }
1215 }
1216
1217 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1218 {
1219         switch (request)
1220         {
1221                 case CMD_REQUEST_COMMAND:
1222                 {
1223                         if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
1224                         {
1225                                 print_to(caller, "^1You are banned from voting.");
1226                                 Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBANYN);
1227                                 return;
1228                         }
1229
1230                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1231                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1232                         {
1233                                 print_to(caller, "^1You have already voted.");
1234                         }
1235                         else  // everything went okay, continue changing vote
1236                         {
1237                                 print_to(caller, "^1You accepted the vote.");
1238                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1239                                 msg_entity = caller;
1240                                 if (!autocvar_sv_vote_singlecount)
1241                                         VoteCount(false);
1242                         }
1243
1244                         return;
1245                 }
1246
1247                 default:
1248                 case CMD_REQUEST_USAGE:
1249                 {
1250                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1251                         print_to(caller, "  No arguments required.");
1252                         return;
1253                 }
1254         }
1255 }
1256
1257 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1258 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1259 void VoteCommand_(int request)
1260 {
1261     switch(request)
1262     {
1263         case CMD_REQUEST_COMMAND:
1264         {
1265
1266             return;
1267         }
1268
1269         default:
1270         case CMD_REQUEST_USAGE:
1271         {
1272             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1273             print_to(caller, "  No arguments required.");
1274             return;
1275         }
1276     }
1277 }
1278 */
1279
1280
1281 // ================================
1282 //  Macro system for vote commands
1283 // ================================
1284
1285 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1286 #define VOTE_COMMANDS(request, caller, arguments, command) \
1287         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1288         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1289         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1290         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1291         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1292         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1293         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1294         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1295         /* nothing */
1296
1297 void VoteCommand_macro_help(entity caller, int argc)
1298 {
1299         string command_origin = GetCommandPrefix(caller);
1300
1301         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1302         {
1303                 print_to(caller, "\nVoting commands:\n");
1304                 #define VOTE_COMMAND(name, function, description, assignment) \
1305                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1306
1307                 VOTE_COMMANDS(0, caller, 0, "");
1308                 #undef VOTE_COMMAND
1309
1310                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote <command>^7, where possible commands are listed above.\n"));
1311                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help <command>"));
1312                 print_available_commands_to(caller);
1313         }
1314         else  // usage for individual command
1315         {
1316                 #define VOTE_COMMAND(name, function, description, assignment) \
1317                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1318
1319                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1320                 #undef VOTE_COMMAND
1321
1322                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1323                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1324                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1325                 else if (argv(2) != "")
1326                         print_to(caller, "No documentation exists for this vote");
1327         }
1328 }
1329
1330 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1331 {
1332         #define VOTE_COMMAND(name, function, description, assignment) \
1333                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1334
1335         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1336         #undef VOTE_COMMAND
1337
1338         return false;
1339 }
1340
1341
1342 // ======================================
1343 //  Main function handling vote commands
1344 // ======================================
1345
1346 void VoteCommand(int request, entity caller, int argc, string vote_command)
1347 {
1348         // Guide for working with argc arguments by example:
1349         // argc:   1    - 2      - 3     - 4
1350         // argv:   0    - 1      - 2     - 3
1351         // cmd     vote - master - login - password
1352
1353         switch (request)
1354         {
1355                 case CMD_REQUEST_COMMAND:
1356                 {
1357                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1358                 }
1359
1360                 default:
1361                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1362                 case CMD_REQUEST_USAGE:
1363                 {
1364                         VoteCommand_macro_help(caller, argc);
1365                         return;
1366                 }
1367         }
1368 }