qcsrc/server/command/sv_cmd.qc

   1 #include "sv_cmd.qh"
   2 #include "_mod.qh"
   3
   4 #include <common/effects/all.qh>
   5
   6 #include "banning.qh"
   7 #include "cmd.qh"
   8 #include "common.qh"
   9 #include "getreplies.qh"
  10 #include "radarmap.qh"
  11
  12 #include "../anticheat.qh"
  13 #include "../campaign.qh"
  14 #include "../client.qh"
  15 #include "../player.qh"
  16 #include "../g_world.qh"
  17 #include "../ipban.qh"
  18 #include "../playerdemo.qh"
  19 #include "../teamplay.qh"
  20
  21 #include "../bot/api.qh"
  22
  23 #include "../mutators/_mod.qh"
  24
  25 #include <common/constants.qh>
  26 #include <common/net_linked.qh>
  27 #include <common/mapinfo.qh>
  28 #include <common/notifications/all.qh>
  29 #include <common/teams.qh>
  30 #include <common/util.qh>
  31
  32 #include <common/monsters/sv_monsters.qh>
  33
  34
  35 void PutObserverInServer(entity this);
  36
  37 // =====================================================
  38 //  Server side game commands code, reworked by Samual
  39 // =====================================================
  40
  41 //  used by GameCommand_make_mapinfo()
  42 void make_mapinfo_Think(entity this)
  43 {
  44         if (_MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  45         {
  46                 LOG_INFO("Done rebuiling mapinfos.");
  47                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  48                 delete(this);
  49         }
  50         else
  51         {
  52                 setthink(this, make_mapinfo_Think);
  53                 this.nextthink = time;
  54         }
  55 }
  56
  57 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  58 void changematchtime(float delta, float mi, float ma)
  59 {
  60         float cur;
  61         float update;
  62         float lim;
  63
  64         if (delta == 0) return;
  65         if (autocvar_timelimit < 0) return;
  66
  67         if (mi <= 10) mi = 10;  // at least ten sec in the future
  68         cur = time - game_starttime;
  69         if (cur > 0) mi += cur; // from current time!
  70
  71         lim = autocvar_timelimit * 60;
  72
  73         if (delta > 0)
  74         {
  75                 if (lim == 0) return; // cannot increase any further
  76                 else if (lim < ma) update = min(ma, lim + delta);
  77                 else                  // already above maximum: FAIL
  78                         return;
  79         }
  80         else
  81         {
  82                 if (lim == 0)      // infinite: try reducing to max, if we are allowed to
  83                         update = max(mi, ma);
  84                 else if (lim > mi) // above minimum: decrease
  85                         update = max(mi, lim + delta);
  86                 else               // already below minimum: FAIL
  87                         return;
  88         }
  89
  90         cvar_set("timelimit", ftos(update / 60));
  91 }
  92
  93
  94 // =======================
  95 //  Command Sub-Functions
  96 // =======================
  97
  98 void GameCommand_adminmsg(float request, float argc)
  99 {
 100         switch (request)
 101         {
 102                 case CMD_REQUEST_COMMAND:
 103                 {
 104                         entity client;
 105                         float accepted;
 106
 107                         string targets = strreplace(",", " ", argv(1));
 108                         string original_targets = strreplace(" ", ", ", targets);
 109                         string admin_message = argv(2);
 110                         float infobartime = stof(argv(3));
 111
 112                         string successful, t;
 113                         successful = string_null;
 114
 115                         if ((targets) && (admin_message))
 116                         {
 117                                 for ( ; targets; )
 118                                 {
 119                                         t = car(targets);
 120                                         targets = cdr(targets);
 121
 122                                         // Check to see if the player is a valid target
 123                                         client = GetFilteredEntity(t);
 124                                         accepted = VerifyClientEntity(client, true, false);
 125
 126                                         if (accepted <= 0)
 127                                         {
 128                                                 LOG_INFO("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : "."));
 129                                                 continue;
 130                                         }
 131
 132                                         // send the centerprint/console print or infomessage
 133                                         if (infobartime)
 134                                         {
 135                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 136                                         }
 137                                         else
 138                                         {
 139                                                 centerprint(client, strcat("^3", GetCallerName(NULL), ":\n^7", admin_message));
 140                                                 sprint(client, strcat("\{1}\{13}^3", GetCallerName(NULL), "^7: ", admin_message, "\n"));
 141                                         }
 142
 143                                         successful = strcat(successful, (successful ? ", " : ""), playername(client, false));
 144                                         LOG_TRACE("Message sent to ", playername(client, false));
 145                                         continue;
 146                                 }
 147
 148                                 if (successful) bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 149                                 else LOG_INFO("No players given (", original_targets, ") could receive the message.");
 150
 151                                 return;
 152                         }
 153                 }
 154
 155                 default:
 156                         LOG_INFO("Incorrect parameters for ^2adminmsg^7");
 157                 case CMD_REQUEST_USAGE:
 158                 {
 159                         LOG_INFO("Usage:^3 sv_cmd adminmsg clients \"message\" [infobartime]");
 160                         LOG_INFO("  'clients' is a list (separated by commas) of player entity ID's or nicknames");
 161                         LOG_INFO("  If infobartime is provided, the message will be sent to infobar.");
 162                         LOG_INFO("  Otherwise, it will just be sent as a centerprint message.");
 163                         LOG_INFO("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10");
 164                         LOG_INFO("          adminmsg 2,5 \"this message will be a centerprint\"");
 165                         return;
 166                 }
 167         }
 168 }
 169
 170 void GameCommand_allready(float request)
 171 {
 172         switch (request)
 173         {
 174                 case CMD_REQUEST_COMMAND:
 175                 {
 176                         ReadyRestart();
 177                         return;
 178                 }
 179
 180                 default:
 181                 case CMD_REQUEST_USAGE:
 182                 {
 183                         LOG_INFO("Usage:^3 sv_cmd allready");
 184                         LOG_INFO("  No arguments required.");
 185                         return;
 186                 }
 187         }
 188 }
 189
 190 void GameCommand_allspec(float request, float argc)
 191 {
 192         switch (request)
 193         {
 194                 case CMD_REQUEST_COMMAND:
 195                 {
 196                         string reason = argv(1);
 197                         int n = 0;
 198                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 199                                 if (it.caplayer) it.caplayer = 0;
 200                                 PutObserverInServer(it);
 201                                 ++n;
 202                         });
 203                         if (n)   bprint(strcat("Successfully forced all (", ftos(n), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n"));
 204                         else   LOG_INFO("No players found to spectate.");
 205                         return;
 206                 }
 207
 208                 default:
 209                 case CMD_REQUEST_USAGE:
 210                 {
 211                         LOG_INFO("Usage:^3 sv_cmd allspec [reason]");
 212                         LOG_INFO("  Where 'reason' is an optional argument for explanation of allspec command.");
 213                         LOG_INFO("See also: ^2moveplayer, shuffleteams^7");
 214                         return;
 215                 }
 216         }
 217 }
 218
 219 void GameCommand_anticheat(float request, float argc)
 220 {
 221         switch (request)
 222         {
 223                 case CMD_REQUEST_COMMAND:
 224                 {
 225                         entity client = GetIndexedEntity(argc, 1);
 226                         float accepted = VerifyClientEntity(client, false, false);
 227
 228                         if (accepted > 0)
 229                         {
 230                                 anticheat_report_to_eventlog(client);
 231                                 return;
 232                         }
 233                         else
 234                         {
 235                                 LOG_INFO("anticheat: ", GetClientErrorString(accepted, argv(1)), ".");
 236                         }
 237                 }
 238
 239                 default:
 240                         LOG_INFO("Incorrect parameters for ^2anticheat^7");
 241                 case CMD_REQUEST_USAGE:
 242                 {
 243                         LOG_INFO("Usage:^3 sv_cmd anticheat client");
 244                         LOG_INFO("  'client' is the entity number or name of the player.");
 245                         return;
 246                 }
 247         }
 248 }
 249
 250 void GameCommand_bbox(float request)
 251 {
 252         switch (request)
 253         {
 254                 case CMD_REQUEST_COMMAND:
 255                 {
 256                         vector size_min = '0 0 0';
 257                         vector size_max = '0 0 0';
 258                         tracebox('1 0 0' * world.absmin.x,
 259                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 260                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 261                                 '1 0 0' * world.absmax.x,
 262                                 MOVE_WORLDONLY,
 263                                 NULL);
 264                         size_min.x = (trace_startsolid) ? world.absmin.x : trace_endpos.x;
 265
 266                         tracebox('0 1 0' * world.absmin.y,
 267                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 268                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 269                                 '0 1 0' * world.absmax.y,
 270                                 MOVE_WORLDONLY,
 271                                 NULL);
 272                         size_min.y = (trace_startsolid) ? world.absmin.y : trace_endpos.y;
 273
 274                         tracebox('0 0 1' * world.absmin.z,
 275                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 276                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 277                                 '0 0 1' * world.absmax.z,
 278                                 MOVE_WORLDONLY,
 279                                 NULL);
 280                         size_min.z = (trace_startsolid) ? world.absmin.z : trace_endpos.z;
 281
 282                         tracebox('1 0 0' * world.absmax.x,
 283                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 284                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 285                                 '1 0 0' * world.absmin.x,
 286                                 MOVE_WORLDONLY,
 287                                 NULL);
 288                         size_max.x = (trace_startsolid) ? world.absmax.x : trace_endpos.x;
 289
 290                         tracebox('0 1 0' * world.absmax.y,
 291                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 292                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 293                                 '0 1 0' * world.absmin.y,
 294                                 MOVE_WORLDONLY,
 295                                 NULL);
 296                         size_max.y = (trace_startsolid) ? world.absmax.y : trace_endpos.y;
 297
 298                         tracebox('0 0 1' * world.absmax.z,
 299                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 300                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 301                                 '0 0 1' * world.absmin.z,
 302                                 MOVE_WORLDONLY,
 303                                 NULL);
 304                         size_max.z = (trace_startsolid) ? world.absmax.z : trace_endpos.z;
 305
 306                         LOG_INFOF("Original size: %v %v", world.absmin, world.absmax);
 307                         LOG_INFOF("Currently set size: %v %v", world.mins, world.maxs);
 308                         LOG_INFOF("Solid bounding box size: %v %v", size_min, size_max);
 309                         return;
 310                 }
 311
 312                 default:
 313                 case CMD_REQUEST_USAGE:
 314                 {
 315                         LOG_INFO("Usage:^3 sv_cmd bbox");
 316                         LOG_INFO("  No arguments required.");
 317                         LOG_INFO("See also: ^2gettaginfo, trace^7");
 318                         return;
 319                 }
 320         }
 321 }
 322
 323 void GameCommand_bot_cmd(float request, float argc, string command)
 324 {
 325         switch (request)
 326         {
 327                 case CMD_REQUEST_COMMAND:
 328                 {
 329                         entity bot;
 330
 331                         if (argv(1) == "reset")
 332                         {
 333                                 bot_resetqueues();
 334                                 return;
 335                         }
 336                         else if (argv(1) == "setbots")
 337                         {
 338                                 cvar_settemp("bot_vs_human", "0");
 339                                 cvar_settemp("minplayers", "0");
 340                                 cvar_settemp("bot_number", "0");
 341                                 bot_fixcount();
 342                                 cvar_settemp("bot_number", argv(2));
 343                                 if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count");
 344                                 return;
 345                         }
 346                         else if (argv(1) == "load" && argc == 3)
 347                         {
 348                                 float fh, i;
 349                                 string s;
 350                                 fh = fopen(argv(2), FILE_READ);
 351                                 if (fh < 0)
 352                                 {
 353                                         LOG_INFO("cannot open the file");
 354                                         return;
 355                                 }
 356
 357                                 i = 0;
 358                                 while ((s = fgets(fh)))
 359                                 {
 360                                         argc = tokenize_console(s);
 361
 362                                         if (argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 363                                         {
 364                                                 if (argv(2) == "reset")
 365                                                 {
 366                                                         bot_resetqueues();
 367                                                 }
 368                                                 else if (argv(2) == "setbots")
 369                                                 {
 370                                                         cvar_settemp("bot_vs_human", "0");
 371                                                         cvar_settemp("minplayers", "0");
 372                                                         cvar_settemp("bot_number", "0");
 373                                                         bot_fixcount();
 374                                                         cvar_settemp("bot_number", argv(3));
 375                                                         if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count");
 376                                                 }
 377                                                 else
 378                                                 {
 379                                                         if(argv(2) == "*" || argv(2) == "all")
 380                                                                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 381                                                                         bot_queuecommand(it, substring(s, argv_start_index(3), -1));
 382                                                                 });
 383                                                         else
 384                                                         {
 385                                                                 bot = find_bot_by_number(stof(argv(2)));
 386                                                                 if (bot == NULL) bot = find_bot_by_name(argv(2));
 387                                                                 if (bot) bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 388                                                         }
 389                                                 }
 390                                         }
 391                                         else
 392                                         {
 393                                                 localcmd(strcat(s, "\n"));
 394                                         }
 395
 396                                         ++i;
 397                                 }
 398                                 LOG_INFO(ftos(i), " commands read");
 399                                 fclose(fh);
 400                                 return;
 401                         }
 402                         else if (argv(1) == "help")
 403                         {
 404                                 if (argv(2)) bot_cmdhelp(argv(2));
 405                                 else bot_list_commands();
 406                                 return;
 407                         }
 408                         else if (argc >= 3)  // this comes last
 409                         {
 410                                 if(argv(1) == "*" || argv(1) == "all")
 411                                 {
 412                                         int bot_num = 0;
 413                                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 414                                                 bot_queuecommand(it, substring(command, argv_start_index(2), -1));
 415                                                 bot_num++;
 416                                         });
 417                                         if(bot_num)
 418                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to all bots (", ftos(bot_num), ")");
 419                                         return;
 420                                 }
 421                                 else
 422                                 {
 423                                         bot = find_bot_by_number(stof(argv(1)));
 424                                         if (bot == NULL) bot = find_bot_by_name(argv(1));
 425                                         if (bot)
 426                                         {
 427                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname);
 428                                                 bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 429                                                 return;
 430                                         }
 431                                         else
 432                                         {
 433                                                 LOG_INFO("Error: Can't find bot with the name or id '", argv(1), "' - Did you mistype the command?");  // don't return so that usage is shown
 434                                         }
 435                                 }
 436                         }
 437                 }
 438
 439                 default:
 440                         LOG_INFO("Incorrect parameters for ^2bot_cmd^7");
 441                 case CMD_REQUEST_USAGE:
 442                 {
 443                         LOG_INFO("Usage:^3 sv_cmd bot_cmd client command [argument]");
 444                         LOG_INFO("  'client' can be either the name of the bot or a progressive number (not the entity number!)");
 445                         LOG_INFO("           can also be '*' or 'all' to allow sending the command to all the bots");
 446                         LOG_INFO("  For full list of commands, see bot_cmd help [command].");
 447                         LOG_INFO("Examples: sv_cmd bot_cmd 1 cc \"say something\"");
 448                         LOG_INFO("          sv_cmd bot_cmd 1 presskey jump");
 449                         LOG_INFO("          sv_cmd bot_cmd * pause");
 450                         return;
 451                 }
 452         }
 453 }
 454
 455 void GameCommand_cointoss(float request, float argc)
 456 {
 457         switch (request)
 458         {
 459                 case CMD_REQUEST_COMMAND:
 460                 {
 461                         string result1 = (argv(2) ? strcat("^7", argv(1)) : "^1HEADS");
 462                         string result2 = (argv(2) ? strcat("^7", argv(2)) : "^4TAILS");
 463                         string choice = ((random() > 0.5) ? result1 : result2);
 464
 465                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, MULTI_COINTOSS, choice);
 466                         return;
 467                 }
 468
 469                 default:
 470                 case CMD_REQUEST_USAGE:
 471                 {
 472                         LOG_INFO("Usage:^3 sv_cmd cointoss [result1 result2]");
 473                         LOG_INFO("  Where 'result1' and 'result2' are user created options.");
 474                         return;
 475                 }
 476         }
 477 }
 478
 479 void GameCommand_database(float request, float argc)
 480 {
 481         switch (request)
 482         {
 483                 case CMD_REQUEST_COMMAND:
 484                 {
 485                         if (argc == 3)
 486                         {
 487                                 if (argv(1) == "save")
 488                                 {
 489                                         db_save(ServerProgsDB, argv(2));
 490                                         LOG_INFO("Copied serverprogs database to '", argv(2), "' in the data directory.");
 491                                         return;
 492                                 }
 493                                 else if (argv(1) == "dump")
 494                                 {
 495                                         db_dump(ServerProgsDB, argv(2));
 496                                         LOG_INFO("DB dumped.");  // wtf does this do?
 497                                         return;
 498                                 }
 499                                 else if (argv(1) == "load")
 500                                 {
 501                                         db_close(ServerProgsDB);
 502                                         ServerProgsDB = db_load(argv(2));
 503                                         LOG_INFO("Loaded '", argv(2), "' as new serverprogs database.");
 504                                         return;
 505                                 }
 506                         }
 507                 }
 508
 509                 default:
 510                         LOG_INFO("Incorrect parameters for ^2database^7");
 511                 case CMD_REQUEST_USAGE:
 512                 {
 513                         LOG_INFO("Usage:^3 sv_cmd database action filename");
 514                         LOG_INFO("  Where 'action' is the command to complete,");
 515                         LOG_INFO("  and 'filename' is what it acts upon.");
 516                         LOG_INFO("  Full list of commands here: \"save, dump, load.\"");
 517                         return;
 518                 }
 519         }
 520 }
 521
 522 void GameCommand_defer_clear(float request, float argc)
 523 {
 524         switch (request)
 525         {
 526                 case CMD_REQUEST_COMMAND:
 527                 {
 528                         entity client;
 529                         float accepted;
 530
 531                         if (argc >= 2)
 532                         {
 533                                 client = GetIndexedEntity(argc, 1);
 534                                 accepted = VerifyClientEntity(client, true, false);
 535
 536                                 if (accepted > 0)
 537                                 {
 538                                         stuffcmd(client, "defer clear\n");
 539                                         LOG_INFO("defer clear stuffed to ", playername(client, false));
 540                                 }
 541                                 else { LOG_INFO("defer_clear: ", GetClientErrorString(accepted, argv(1)), "."); }
 542
 543                                 return;
 544                         }
 545                 }
 546
 547                 default:
 548                         LOG_INFO("Incorrect parameters for ^2defer_clear^7");
 549                 case CMD_REQUEST_USAGE:
 550                 {
 551                         LOG_INFO("Usage:^3 sv_cmd defer_clear client");
 552                         LOG_INFO("  'client' is the entity number or name of the player.");
 553                         LOG_INFO("See also: ^2defer_clear_all^7");
 554                         return;
 555                 }
 556         }
 557 }
 558
 559 void GameCommand_defer_clear_all(float request)
 560 {
 561         switch (request)
 562         {
 563                 case CMD_REQUEST_COMMAND:
 564                 {
 565                         int n = 0;
 566                         float argc;
 567
 568                         FOREACH_CLIENT(true, {
 569                                 argc = tokenize_console(strcat("defer_clear ", ftos(etof(it))));
 570                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 571                                 ++n;
 572                         });
 573                         if (n)   LOG_INFO("Successfully stuffed defer clear to all clients (", ftos(n), ")");  // should a message be added if no players were found?
 574                         return;
 575                 }
 576
 577                 default:
 578                 case CMD_REQUEST_USAGE:
 579                 {
 580                         LOG_INFO("Usage:^3 sv_cmd defer_clear_all");
 581                         LOG_INFO("  No arguments required.");
 582                         LOG_INFO("See also: ^2defer_clear^7");
 583                         return;
 584                 }
 585         }
 586 }
 587
 588 void GameCommand_delrec(float request, float argc)  // perhaps merge later with records and printstats and such?
 589 {
 590         switch (request)
 591         {
 592                 case CMD_REQUEST_COMMAND:
 593                 {
 594                         if (argv(1))
 595                         {
 596                                 if (argv(2)) race_deleteTime(argv(2), stof(argv(1)));
 597                                 else race_deleteTime(GetMapname(), stof(argv(1)));
 598                                 return;
 599                         }
 600                 }
 601
 602                 default:
 603                         LOG_INFO("Incorrect parameters for ^2delrec^7");
 604                 case CMD_REQUEST_USAGE:
 605                 {
 606                         LOG_INFO("Usage:^3 sv_cmd delrec ranking [map]");
 607                         LOG_INFO("  'ranking' is which ranking level to clear up to, ");
 608                         LOG_INFO("  it will clear all records up to nth place.");
 609                         LOG_INFO("  if 'map' is not provided it will use current map.");
 610                         return;
 611                 }
 612         }
 613 }
 614
 615 void GameCommand_effectindexdump(float request)
 616 {
 617         switch (request)
 618         {
 619                 case CMD_REQUEST_COMMAND:
 620                 {
 621                         float fh, d;
 622                         string s;
 623
 624                         d = db_create();
 625                         LOG_INFO("begin of effects list");
 626                         db_put(d, "TE_GUNSHOT", "1");
 627                         LOG_INFO("effect TE_GUNSHOT is ", ftos(_particleeffectnum("TE_GUNSHOT")));
 628                         db_put(d, "TE_GUNSHOTQUAD", "1");
 629                         LOG_INFO("effect TE_GUNSHOTQUAD is ", ftos(_particleeffectnum("TE_GUNSHOTQUAD")));
 630                         db_put(d, "TE_SPIKE", "1");
 631                         LOG_INFO("effect TE_SPIKE is ", ftos(_particleeffectnum("TE_SPIKE")));
 632                         db_put(d, "TE_SPIKEQUAD", "1");
 633                         LOG_INFO("effect TE_SPIKEQUAD is ", ftos(_particleeffectnum("TE_SPIKEQUAD")));
 634                         db_put(d, "TE_SUPERSPIKE", "1");
 635                         LOG_INFO("effect TE_SUPERSPIKE is ", ftos(_particleeffectnum("TE_SUPERSPIKE")));
 636                         db_put(d, "TE_SUPERSPIKEQUAD", "1");
 637                         LOG_INFO("effect TE_SUPERSPIKEQUAD is ", ftos(_particleeffectnum("TE_SUPERSPIKEQUAD")));
 638                         db_put(d, "TE_WIZSPIKE", "1");
 639                         LOG_INFO("effect TE_WIZSPIKE is ", ftos(_particleeffectnum("TE_WIZSPIKE")));
 640                         db_put(d, "TE_KNIGHTSPIKE", "1");
 641                         LOG_INFO("effect TE_KNIGHTSPIKE is ", ftos(_particleeffectnum("TE_KNIGHTSPIKE")));
 642                         db_put(d, "TE_EXPLOSION", "1");
 643                         LOG_INFO("effect TE_EXPLOSION is ", ftos(_particleeffectnum("TE_EXPLOSION")));
 644                         db_put(d, "TE_EXPLOSIONQUAD", "1");
 645                         LOG_INFO("effect TE_EXPLOSIONQUAD is ", ftos(_particleeffectnum("TE_EXPLOSIONQUAD")));
 646                         db_put(d, "TE_TAREXPLOSION", "1");
 647                         LOG_INFO("effect TE_TAREXPLOSION is ", ftos(_particleeffectnum("TE_TAREXPLOSION")));
 648                         db_put(d, "TE_TELEPORT", "1");
 649                         LOG_INFO("effect TE_TELEPORT is ", ftos(_particleeffectnum("TE_TELEPORT")));
 650                         db_put(d, "TE_LAVASPLASH", "1");
 651                         LOG_INFO("effect TE_LAVASPLASH is ", ftos(_particleeffectnum("TE_LAVASPLASH")));
 652                         db_put(d, "TE_SMALLFLASH", "1");
 653                         LOG_INFO("effect TE_SMALLFLASH is ", ftos(_particleeffectnum("TE_SMALLFLASH")));
 654                         db_put(d, "TE_FLAMEJET", "1");
 655                         LOG_INFO("effect TE_FLAMEJET is ", ftos(_particleeffectnum("TE_FLAMEJET")));
 656                         db_put(d, "EF_FLAME", "1");
 657                         LOG_INFO("effect EF_FLAME is ", ftos(_particleeffectnum("EF_FLAME")));
 658                         db_put(d, "TE_BLOOD", "1");
 659                         LOG_INFO("effect TE_BLOOD is ", ftos(_particleeffectnum("TE_BLOOD")));
 660                         db_put(d, "TE_SPARK", "1");
 661                         LOG_INFO("effect TE_SPARK is ", ftos(_particleeffectnum("TE_SPARK")));
 662                         db_put(d, "TE_PLASMABURN", "1");
 663                         LOG_INFO("effect TE_PLASMABURN is ", ftos(_particleeffectnum("TE_PLASMABURN")));
 664                         db_put(d, "TE_TEI_G3", "1");
 665                         LOG_INFO("effect TE_TEI_G3 is ", ftos(_particleeffectnum("TE_TEI_G3")));
 666                         db_put(d, "TE_TEI_SMOKE", "1");
 667                         LOG_INFO("effect TE_TEI_SMOKE is ", ftos(_particleeffectnum("TE_TEI_SMOKE")));
 668                         db_put(d, "TE_TEI_BIGEXPLOSION", "1");
 669                         LOG_INFO("effect TE_TEI_BIGEXPLOSION is ", ftos(_particleeffectnum("TE_TEI_BIGEXPLOSION")));
 670                         db_put(d, "TE_TEI_PLASMAHIT", "1");
 671                         LOG_INFO("effect TE_TEI_PLASMAHIT is ", ftos(_particleeffectnum("TE_TEI_PLASMAHIT")));
 672                         db_put(d, "EF_STARDUST", "1");
 673                         LOG_INFO("effect EF_STARDUST is ", ftos(_particleeffectnum("EF_STARDUST")));
 674                         db_put(d, "TR_ROCKET", "1");
 675                         LOG_INFO("effect TR_ROCKET is ", ftos(_particleeffectnum("TR_ROCKET")));
 676                         db_put(d, "TR_GRENADE", "1");
 677                         LOG_INFO("effect TR_GRENADE is ", ftos(_particleeffectnum("TR_GRENADE")));
 678                         db_put(d, "TR_BLOOD", "1");
 679                         LOG_INFO("effect TR_BLOOD is ", ftos(_particleeffectnum("TR_BLOOD")));
 680                         db_put(d, "TR_WIZSPIKE", "1");
 681                         LOG_INFO("effect TR_WIZSPIKE is ", ftos(_particleeffectnum("TR_WIZSPIKE")));
 682                         db_put(d, "TR_SLIGHTBLOOD", "1");
 683                         LOG_INFO("effect TR_SLIGHTBLOOD is ", ftos(_particleeffectnum("TR_SLIGHTBLOOD")));
 684                         db_put(d, "TR_KNIGHTSPIKE", "1");
 685                         LOG_INFO("effect TR_KNIGHTSPIKE is ", ftos(_particleeffectnum("TR_KNIGHTSPIKE")));
 686                         db_put(d, "TR_VORESPIKE", "1");
 687                         LOG_INFO("effect TR_VORESPIKE is ", ftos(_particleeffectnum("TR_VORESPIKE")));
 688                         db_put(d, "TR_NEHAHRASMOKE", "1");
 689                         LOG_INFO("effect TR_NEHAHRASMOKE is ", ftos(_particleeffectnum("TR_NEHAHRASMOKE")));
 690                         db_put(d, "TR_NEXUIZPLASMA", "1");
 691                         LOG_INFO("effect TR_NEXUIZPLASMA is ", ftos(_particleeffectnum("TR_NEXUIZPLASMA")));
 692                         db_put(d, "TR_GLOWTRAIL", "1");
 693                         LOG_INFO("effect TR_GLOWTRAIL is ", ftos(_particleeffectnum("TR_GLOWTRAIL")));
 694                         db_put(d, "TR_SEEKER", "1");
 695                         LOG_INFO("effect TR_SEEKER is ", ftos(_particleeffectnum("TR_SEEKER")));
 696                         db_put(d, "SVC_PARTICLE", "1");
 697                         LOG_INFO("effect SVC_PARTICLE is ", ftos(_particleeffectnum("SVC_PARTICLE")));
 698
 699                         fh = fopen("effectinfo.txt", FILE_READ);
 700                         while ((s = fgets(fh)))
 701                         {
 702                                 tokenize_console(s);
 703                                 if (argv(0) == "effect")
 704                                 {
 705                                         if (db_get(d, argv(1)) != "1")
 706                                         {
 707                                                 int i = _particleeffectnum(argv(1));
 708                                                 if (i >= 0) LOG_INFO("effect ", argv(1), " is ", ftos(i));
 709                                                 db_put(d, argv(1), "1");
 710                                         }
 711                                 }
 712                         }
 713                         LOG_INFO("end of effects list");
 714
 715                         db_close(d);
 716                         return;
 717                 }
 718
 719                 default:
 720                 case CMD_REQUEST_USAGE:
 721                 {
 722                         LOG_INFO("Usage:^3 sv_cmd effectindexdump");
 723                         LOG_INFO("  No arguments required.");
 724                         return;
 725                 }
 726         }
 727 }
 728
 729 void GameCommand_extendmatchtime(float request)
 730 {
 731         switch (request)
 732         {
 733                 case CMD_REQUEST_COMMAND:
 734                 {
 735                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 736                         return;
 737                 }
 738
 739                 default:
 740                 case CMD_REQUEST_USAGE:
 741                 {
 742                         LOG_INFO("Usage:^3 sv_cmd extendmatchtime");
 743                         LOG_INFO("  No arguments required.");
 744                         LOG_INFO("See also: ^2reducematchtime^7");
 745                         return;
 746                 }
 747         }
 748 }
 749
 750 void GameCommand_gametype(float request, float argc)
 751 {
 752         switch (request)
 753         {
 754                 case CMD_REQUEST_COMMAND:
 755                 {
 756                         if (argv(1) != "")
 757                         {
 758                                 string s = argv(1);
 759                                 Gametype t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
 760
 761                                 if (t)
 762                                 {
 763                                         MapInfo_SwitchGameType(t);
 764                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 765                                         if (MapInfo_count > 0)
 766                                         {
 767                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 768                                                 if (lsmaps_reply != "")   strunzone(lsmaps_reply);
 769                                                 lsmaps_reply = strzone(getlsmaps());
 770                                                 bprint("Game type successfully switched to ", s, "\n");
 771                                         }
 772                                         else
 773                                         {
 774                                                 bprint("Cannot use this game type: no map for it found\n");
 775                                                 MapInfo_SwitchGameType(tsave);
 776                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 777                                         }
 778                                 }
 779                                 else
 780                                 {
 781                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 782                                 }
 783
 784                                 return;
 785                         }
 786                 }
 787
 788                 default:
 789                         LOG_INFO("Incorrect parameters for ^2gametype^7");
 790                 case CMD_REQUEST_USAGE:
 791                 {
 792                         LOG_INFO("Usage:^3 sv_cmd gametype mode");
 793                         LOG_INFO("  Where 'mode' is the gametype mode to switch to.");
 794                         LOG_INFO("See also: ^2gotomap^7");
 795                         return;
 796                 }
 797         }
 798 }
 799
 800 void GameCommand_gettaginfo(float request, float argc)
 801 {
 802         switch (request)
 803         {
 804                 case CMD_REQUEST_COMMAND:
 805                 {
 806                         entity tmp_entity;
 807                         float i;
 808                         vector v;
 809
 810                         if (argc >= 4)
 811                         {
 812                                 tmp_entity = spawn();
 813                                 if (argv(1) == "w")
 814                                 {
 815                                         .entity weaponentity = weaponentities[0];
 816                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 817                                 }
 818                                 else
 819                                 {
 820                                         precache_model(argv(1));
 821                                         _setmodel(tmp_entity, argv(1));
 822                                 }
 823                                 tmp_entity.frame = stof(argv(2));
 824                                 if (substring(argv(3), 0, 1) == "#") i = stof(substring(argv(3), 1, -1));
 825                                 else i = gettagindex(tmp_entity, argv(3));
 826                                 if (i)
 827                                 {
 828                                         v = gettaginfo(tmp_entity, i);
 829                                         LOG_INFOF(
 830                                             "model %s frame %s tag %s index %s parent %s",
 831                                             tmp_entity.model, ftos(tmp_entity.frame), gettaginfo_name, ftos(i), ftos(gettaginfo_parent)
 832                                         );
 833                                         LOG_INFOF(" vector = %s %s %s", ftos(v.x), ftos(v.y), ftos(v.z));
 834                                         LOG_INFOF(" offset = %s %s %s", ftos(gettaginfo_offset.x), ftos(gettaginfo_offset.y), ftos(gettaginfo_offset.z));
 835                                         LOG_INFOF(" forward = %s %s %s", ftos(gettaginfo_forward.x), ftos(gettaginfo_forward.y), ftos(gettaginfo_forward.z));
 836                                         LOG_INFOF(" right = %s %s %s", ftos(gettaginfo_right.x), ftos(gettaginfo_right.y), ftos(gettaginfo_right.z));
 837                                         LOG_INFOF(" up = %s %s %s", ftos(gettaginfo_up.x), ftos(gettaginfo_up.y), ftos(gettaginfo_up.z));
 838                                         if (argc >= 6)
 839                                         {
 840                                                 v.y = -v.y;
 841                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 842                                         }
 843                                 }
 844                                 else
 845                                 {
 846                                         LOG_INFO("bone not found");
 847                                 }
 848
 849                                 delete(tmp_entity);
 850                                 return;
 851                         }
 852                 }
 853
 854                 default:
 855                         LOG_INFO("Incorrect parameters for ^2gettaginfo^7");
 856                 case CMD_REQUEST_USAGE:
 857                 {
 858                         LOG_INFO("Usage:^3 sv_cmd gettaginfo model frame index [command one] [command two]");
 859                         LOG_INFO("See also: ^2bbox, trace^7");
 860                         return;
 861                 }
 862         }
 863 }
 864
 865 void GameCommand_animbench(float request, float argc)
 866 {
 867         switch (request)
 868         {
 869                 case CMD_REQUEST_COMMAND:
 870                 {
 871                         entity tmp_entity;
 872
 873                         if (argc >= 4)
 874                         {
 875                                 tmp_entity = spawn();
 876                                 if (argv(1) == "w")
 877                                 {
 878                                         .entity weaponentity = weaponentities[0];
 879                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 880                                 }
 881                                 else
 882                                 {
 883                                         precache_model(argv(1));
 884                                         _setmodel(tmp_entity, argv(1));
 885                                 }
 886                                 float f1 = stof(argv(2));
 887                                 float f2 = stof(argv(3));
 888                                 float t0;
 889                                 float t1 = 0;
 890                                 float t2 = 0;
 891                                 float n = 0;
 892
 893                                 while (t1 + t2 < 1)
 894                                 {
 895                                         tmp_entity.frame = f1;
 896                                         t0 = gettime(GETTIME_HIRES);
 897                                         getsurfacepoint(tmp_entity, 0, 0);
 898                                         t1 += gettime(GETTIME_HIRES) - t0;
 899                                         tmp_entity.frame = f2;
 900                                         t0 = gettime(GETTIME_HIRES);
 901                                         getsurfacepoint(tmp_entity, 0, 0);
 902                                         t2 += gettime(GETTIME_HIRES) - t0;
 903                                         n += 1;
 904                                 }
 905                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s");
 906                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s");
 907
 908                                 delete(tmp_entity);
 909                                 return;
 910                         }
 911                 }
 912
 913                 default:
 914                         LOG_INFO("Incorrect parameters for ^2gettaginfo^7");
 915                 case CMD_REQUEST_USAGE:
 916                 {
 917                         LOG_INFO("Usage:^3 sv_cmd gettaginfo model frame index [command one] [command two]");
 918                         LOG_INFO("See also: ^2bbox, trace^7");
 919                         return;
 920                 }
 921         }
 922 }
 923
 924 void GameCommand_gotomap(float request, float argc)
 925 {
 926         switch (request)
 927         {
 928                 case CMD_REQUEST_COMMAND:
 929                 {
 930                         if (argv(1))
 931                         {
 932                                 LOG_INFO(GotoMap(argv(1)));
 933                                 return;
 934                         }
 935                 }
 936
 937                 default:
 938                         LOG_INFO("Incorrect parameters for ^2gotomap^7");
 939                 case CMD_REQUEST_USAGE:
 940                 {
 941                         LOG_INFO("Usage:^3 sv_cmd gotomap map");
 942                         LOG_INFO("  Where 'map' is the *.bsp file to change to.");
 943                         LOG_INFO("See also: ^2gametype^7");
 944                         return;
 945                 }
 946         }
 947 }
 948
 949 void GameCommand_lockteams(float request)
 950 {
 951         switch (request)
 952         {
 953                 case CMD_REQUEST_COMMAND:
 954                 {
 955                         if (teamplay)
 956                         {
 957                                 lockteams = 1;
 958                                 bprint("^1The teams are now locked.\n");
 959                         }
 960                         else
 961                         {
 962                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 963                         }
 964                         return;
 965                 }
 966
 967                 default:
 968                 case CMD_REQUEST_USAGE:
 969                 {
 970                         LOG_INFO("Usage:^3 sv_cmd lockteams");
 971                         LOG_INFO("  No arguments required.");
 972                         LOG_INFO("See also: ^2unlockteams^7");
 973                         return;
 974                 }
 975         }
 976 }
 977
 978 void GameCommand_make_mapinfo(float request)
 979 {
 980         switch (request)
 981         {
 982                 case CMD_REQUEST_COMMAND:
 983                 {
 984                         entity tmp_entity;
 985
 986                         tmp_entity = new(make_mapinfo);
 987                         setthink(tmp_entity, make_mapinfo_Think);
 988                         tmp_entity.nextthink = time;
 989                         MapInfo_Enumerate();
 990                         return;
 991                 }
 992
 993                 default:
 994                 case CMD_REQUEST_USAGE:
 995                 {
 996                         LOG_INFO("Usage:^3 sv_cmd make_mapinfo");
 997                         LOG_INFO("  No arguments required.");
 998                         LOG_INFO("See also: ^2radarmap^7");
 999                         return;
1000                 }
1001         }
1002 }
1003
1004 void GameCommand_moveplayer(float request, float argc)
1005 {
1006         switch (request)
1007         {
1008                 case CMD_REQUEST_COMMAND:
1009                 {
1010                         float accepted;
1011                         entity client;
1012
1013                         string targets = strreplace(",", " ", argv(1));
1014                         string original_targets = strreplace(" ", ", ", targets);
1015                         string destination = argv(2);
1016
1017                         string successful, t;
1018                         successful = string_null;
1019
1020                         // lets see if the target(s) even actually exist.
1021                         if ((targets) && (destination))
1022                         {
1023                                 for ( ; targets; )
1024                                 {
1025                                         t = car(targets);
1026                                         targets = cdr(targets);
1027
1028                                         // Check to see if the player is a valid target
1029                                         client = GetFilteredEntity(t);
1030                                         accepted = VerifyClientEntity(client, false, false);
1031
1032                                         if (accepted <= 0)
1033                                         {
1034                                                 LOG_INFO("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : "."));
1035                                                 continue;
1036                                         }
1037
1038                                         // Where are we putting this player?
1039                                         if (destination == "spec" || destination == "spectator")
1040                                         {
1041                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1042                                                 {
1043                                                         if (client.caplayer) client.caplayer = 0;
1044                                                         PutObserverInServer(client);
1045
1046                                                         successful = strcat(successful, (successful ? ", " : ""), playername(client, false));
1047                                                 }
1048                                                 else
1049                                                 {
1050                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ") is already spectating.");
1051                                                 }
1052                                                 continue;
1053                                         }
1054                                         else
1055                                         {
1056                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1057                                                 {
1058                                                         if (teamplay)
1059                                                         {
1060                                                                 // set up
1061                                                                 float team_id;
1062                                                                 float save = client.team_forced;
1063                                                                 client.team_forced = 0;
1064
1065                                                                 // find the team to move the player to
1066                                                                 team_id = Team_ColorToTeam(destination);
1067                                                                 if (team_id == client.team)  // already on the destination team
1068                                                                 {
1069                                                                         // keep the forcing undone
1070                                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7."));
1071                                                                         continue;
1072                                                                 }
1073                                                                 else if (team_id == 0)  // auto team
1074                                                                 {
1075                                                                         CheckAllowedTeams(client);
1076                                                                         team_id = Team_NumberToTeam(FindSmallestTeam(client, false));
1077                                                                 }
1078                                                                 else
1079                                                                 {
1080                                                                         CheckAllowedTeams(client);
1081                                                                 }
1082                                                                 client.team_forced = save;
1083
1084                                                                 // Check to see if the destination team is even available
1085                                                                 switch (team_id)
1086                                                                 {
1087                                                                         case NUM_TEAM_1: if (c1 == -1) { LOG_INFO("Sorry, can't move player to red team if it doesn't exist."); return; } break;
1088                                                                         case NUM_TEAM_2: if (c2 == -1) { LOG_INFO("Sorry, can't move player to blue team if it doesn't exist."); return; } break;
1089                                                                         case NUM_TEAM_3: if (c3 == -1) { LOG_INFO("Sorry, can't move player to yellow team if it doesn't exist."); return; } break;
1090                                                                         case NUM_TEAM_4: if (c4 == -1) { LOG_INFO("Sorry, can't move player to pink team if it doesn't exist."); return; } break;
1091
1092                                                                         default: LOG_INFO("Sorry, can't move player here if team ", destination, " doesn't exist.");
1093                                                                                 return;
1094                                                                 }
1095
1096                                                                 // If so, lets continue and finally move the player
1097                                                                 client.team_forced = 0;
1098                                                                 if (MoveToTeam(client, team_id, 6))
1099                                                                 {
1100                                                                         successful = strcat(successful, (successful ? ", " : ""), playername(client, false));
1101                                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ") has been moved to the ", Team_ColoredFullName(team_id), "^7.");
1102                                                                 }
1103                                                                 else
1104                                                                 {
1105                                                                         LOG_INFO("Unable to move player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ")");
1106                                                                 }
1107                                                                 continue;
1108                                                         }
1109                                                         else
1110                                                         {
1111                                                                 LOG_INFO("Can't change teams when currently not playing a team game.");
1112                                                                 return;
1113                                                         }
1114                                                 }
1115                                                 else
1116                                                 {
1117                                                         LOG_INFO("Can't change teams if the player isn't in the game.");  // well technically we could, but should we allow that? :P
1118                                                         return;
1119                                                 }
1120                                         }
1121                                 }
1122
1123                                 if (successful) bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1124                                 else LOG_INFO("No players given (", original_targets, ") are able to move.");
1125
1126                                 return;  // still correct parameters so return to avoid usage print
1127                         }
1128                 }
1129
1130                 default:
1131                         LOG_INFO("Incorrect parameters for ^2moveplayer^7");
1132                 case CMD_REQUEST_USAGE:
1133                 {
1134                         LOG_INFO("Usage:^3 sv_cmd moveplayer clients destination");
1135                         LOG_INFO("  'clients' is a list (separated by commas) of player entity ID's or nicknames");
1136                         LOG_INFO("  'destination' is what to send the player to, be it team or spectating");
1137                         LOG_INFO("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"");
1138                         LOG_INFO("Examples: sv_cmd moveplayer 1,3,5 red 3");
1139                         LOG_INFO("          sv_cmd moveplayer 2 spec ");
1140                         LOG_INFO("See also: ^2allspec, shuffleteams^7");
1141                         return;
1142                 }
1143         }
1144 }
1145
1146 void GameCommand_nospectators(float request)
1147 {
1148         switch (request)
1149         {
1150                 case CMD_REQUEST_COMMAND:
1151                 {
1152                         blockSpectators = 1;
1153                         // give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1154                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_SPEC(it) || IS_OBSERVER(it)) && !it.caplayer, {
1155                                 if(!it.caplayer)
1156                                 {
1157                                         CS(it).spectatortime = time;
1158                                         Send_Notification(NOTIF_ONE_ONLY, it, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1159                                 }
1160                         });
1161                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1162                         return;
1163                 }
1164
1165                 default:
1166                 case CMD_REQUEST_USAGE:
1167                 {
1168                         LOG_INFO("Usage:^3 sv_cmd nospectators");
1169                         LOG_INFO("  No arguments required.");
1170                         return;
1171                 }
1172         }
1173 }
1174
1175 void GameCommand_playerdemo(float request, float argc)
1176 {
1177         switch (request)
1178         {
1179                 case CMD_REQUEST_COMMAND:
1180                 {
1181                         if (argv(2) && argv(3))
1182                         {
1183                                 entity client;
1184                                 float i, n, accepted;
1185
1186                                 switch (argv(1))
1187                                 {
1188                                         case "read":
1189                                         {
1190                                                 client = GetIndexedEntity(argc, 2);
1191                                                 accepted = VerifyClientEntity(client, false, true);
1192
1193                                                 if (accepted <= 0)
1194                                                 {
1195                                                         LOG_INFO("playerdemo: read: ", GetClientErrorString(accepted, argv(2)), ".");
1196                                                         return;
1197                                                 }
1198
1199                                                 playerdemo_open_read(client, argv(next_token));
1200                                                 return;
1201                                         }
1202
1203                                         case "write":
1204                                         {
1205                                                 client = GetIndexedEntity(argc, 2);
1206                                                 accepted = VerifyClientEntity(client, false, false);
1207
1208                                                 if (accepted <= 0)
1209                                                 {
1210                                                         LOG_INFO("playerdemo: write: ", GetClientErrorString(accepted, argv(2)), ".");
1211                                                         return;
1212                                                 }
1213
1214                                                 playerdemo_open_write(client, argv(next_token));
1215                                                 return;
1216                                         }
1217
1218                                         case "auto_read_and_write":
1219                                         {
1220                                                 n = GetFilteredNumber(argv(3));
1221                                                 cvar_set("bot_number", ftos(n));
1222
1223                                                 localcmd("wait; wait; wait\n");
1224                                                 for (i = 0; i < n; ++i)
1225                                                         localcmd("sv_cmd playerdemo read ", ftos(i + 2), " ", argv(2), ftos(i + 1), "\n");
1226                                                 localcmd("sv_cmd playerdemo write 1 ", ftos(n + 1), "\n");
1227                                                 return;
1228                                         }
1229
1230                                         case "auto_read":
1231                                         {
1232                                                 n = GetFilteredNumber(argv(3));
1233                                                 cvar_set("bot_number", ftos(n));
1234
1235                                                 localcmd("wait; wait; wait\n");
1236                                                 for (i = 0; i < n; ++i)
1237                                                         localcmd("sv_cmd playerdemo read ", ftos(i + 2), " ", argv(2), ftos(i + 1), "\n");
1238                                                 return;
1239                                         }
1240                                 }
1241                         }
1242                 }
1243
1244                 default:
1245                         LOG_INFO("Incorrect parameters for ^2playerdemo^7");
1246                 case CMD_REQUEST_USAGE:
1247                 {
1248                         LOG_INFO("Usage:^3 sv_cmd playerdemo command (entitynumber filename | entitynumber botnumber)");
1249                         LOG_INFO("  Full list of commands here: \"read, write, auto_read_and_write, auto_read.\"");
1250                         return;
1251                 }
1252         }
1253 }
1254
1255 void GameCommand_printstats(float request)
1256 {
1257         switch (request)
1258         {
1259                 case CMD_REQUEST_COMMAND:
1260                 {
1261                         DumpStats(false);
1262                         LOG_INFO("stats dumped.");
1263                         return;
1264                 }
1265
1266                 default:
1267                 case CMD_REQUEST_USAGE:
1268                 {
1269                         LOG_INFO("Usage:^3 sv_cmd printstats");
1270                         LOG_INFO("  No arguments required.");
1271                         return;
1272                 }
1273         }
1274 }
1275
1276 void GameCommand_radarmap(float request, float argc)
1277 {
1278         switch (request)
1279         {
1280                 case CMD_REQUEST_COMMAND:
1281                 {
1282                         if (RadarMap_Make(argc)) return;
1283                 }
1284
1285                 default:
1286                         LOG_INFO("Incorrect parameters for ^2radarmap^7");
1287                 case CMD_REQUEST_USAGE:
1288                 {
1289                         LOG_INFO("Usage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]");
1290                         LOG_INFO("  The quality factor Q is roughly proportional to the time taken.");
1291                         LOG_INFO("  trace supports no quality factor; its result should look like --block with infinite quality factor.");
1292                         LOG_INFO("See also: ^2make_mapinfo^7");
1293                         return;
1294                 }
1295         }
1296 }
1297
1298 void GameCommand_reducematchtime(float request)
1299 {
1300         switch (request)
1301         {
1302                 case CMD_REQUEST_COMMAND:
1303                 {
1304                         changematchtime(autocvar_timelimit_decrement * -60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1305                         return;
1306                 }
1307
1308                 default:
1309                 case CMD_REQUEST_USAGE:
1310                 {
1311                         LOG_INFO("Usage:^3 sv_cmd reducematchtime");
1312                         LOG_INFO("  No arguments required.");
1313                         LOG_INFO("See also: ^2extendmatchtime^7");
1314                         return;
1315                 }
1316         }
1317 }
1318
1319 void GameCommand_setbots(float request, float argc)
1320 {
1321         switch (request)
1322         {
1323                 case CMD_REQUEST_COMMAND:
1324                 {
1325                         if (argc >= 2)
1326                         {
1327                                 cvar_settemp("minplayers", "0");
1328                                 cvar_settemp("bot_number", argv(1));
1329                                 bot_fixcount();
1330                                 return;
1331                         }
1332                 }
1333
1334                 default:
1335                         LOG_INFO("Incorrect parameters for ^2setbots^7");
1336                 case CMD_REQUEST_USAGE:
1337                 {
1338                         LOG_INFO("Usage:^3 sv_cmd setbots botnumber");
1339                         LOG_INFO("  Where 'botnumber' is the amount of bots to set bot_number cvar to.");
1340                         LOG_INFO("See also: ^2bot_cmd^7");
1341                         return;
1342                 }
1343         }
1344 }
1345
1346 void GameCommand_shuffleteams(float request)
1347 {
1348         switch (request)
1349         {
1350                 case CMD_REQUEST_COMMAND:
1351                 {
1352                         if (!teamplay)
1353                         {
1354                                 LOG_INFO("Can't shuffle teams when currently not playing a team game.");
1355                                 return;
1356                         }
1357
1358                         FOREACH_CLIENT(IS_PLAYER(it) || it.caplayer, {
1359                                 if (it.team_forced) {
1360                                         // we could theoretically assign forced players to their teams
1361                                         // and shuffle the rest to fill the empty spots but in practise
1362                                         // either all players or none are gonna have forced teams
1363                                         LOG_INFO("Can't shuffle teams because at least one player has a forced team.");
1364                                         return;
1365                                 }
1366                         });
1367
1368                         int number_of_teams = 0;
1369                         CheckAllowedTeams(NULL);
1370                         if (c1 >= 0) number_of_teams = max(1, number_of_teams);
1371                         if (c2 >= 0) number_of_teams = max(2, number_of_teams);
1372                         if (c3 >= 0) number_of_teams = max(3, number_of_teams);
1373                         if (c4 >= 0) number_of_teams = max(4, number_of_teams);
1374
1375                         int team_index = 0;
1376                         FOREACH_CLIENT_RANDOM(IS_PLAYER(it) || it.caplayer, {
1377                                 int target_team_number = Team_NumberToTeam(team_index + 1);
1378                                 if (it.team != target_team_number) MoveToTeam(it, target_team_number, 6);
1379                                 team_index = (team_index + 1) % number_of_teams;
1380                         });
1381
1382                         bprint("Successfully shuffled the players around randomly.\n");
1383                         return;
1384                 }
1385
1386                 default:
1387                 case CMD_REQUEST_USAGE:
1388                 {
1389                         LOG_INFO("Usage:^3 sv_cmd shuffleteams");
1390                         LOG_INFO("  No arguments required.");
1391                         LOG_INFO("See also: ^2moveplayer, allspec^7");
1392                         return;
1393                 }
1394         }
1395 }
1396
1397 void GameCommand_stuffto(float request, float argc)
1398 {
1399         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1400         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1401         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1402
1403 #ifdef STUFFTO_ENABLED
1404                 switch (request)
1405                 {
1406                         case CMD_REQUEST_COMMAND:
1407                         {
1408                                 if (argv(2))
1409                                 {
1410                                         entity client = GetIndexedEntity(argc, 1);
1411                                         float accepted = VerifyClientEntity(client, true, false);
1412
1413                                         if (accepted > 0)
1414                                         {
1415                                                 stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1416                                                 LOG_INFO("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1), ").");
1417                                         }
1418                                         else
1419                                         {
1420                                                 LOG_INFO("stuffto: ", GetClientErrorString(accepted, argv(1)), ".");
1421                                         }
1422
1423                                         return;
1424                                 }
1425                         }
1426
1427                         default:
1428                                 LOG_INFO("Incorrect parameters for ^2stuffto^7");
1429                         case CMD_REQUEST_USAGE:
1430                         {
1431                                 LOG_INFO("Usage:^3 sv_cmd stuffto client \"command\"");
1432                                 LOG_INFO("  'client' is the entity number or name of the player,");
1433                                 LOG_INFO("  and 'command' is the command to be sent to that player.");
1434                                 return;
1435                         }
1436                 }
1437 #else
1438                 if (request)
1439                 {
1440                         LOG_INFO("stuffto command is not enabled on this server.");
1441                         return;
1442                 }
1443 #endif
1444 }
1445
1446 void GameCommand_trace(float request, float argc)
1447 {
1448         switch (request)
1449         {
1450                 case CMD_REQUEST_COMMAND:
1451                 {
1452                         entity e;
1453                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1454                         float i, f, safe, unsafe, dq, dqf;
1455
1456                         switch (argv(1))
1457                         {
1458                                 case "debug":
1459                                 {
1460                                         float hitcount = 0;
1461                                         LOG_INFO("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.");
1462                                         float worst_endpos_bug = 0;
1463                                         for ( ; ; )
1464                                         {
1465                                                 org = world.mins;
1466                                                 delta = world.maxs - world.mins;
1467
1468                                                 start.x = org.x + random() * delta.x;
1469                                                 start.y = org.y + random() * delta.y;
1470                                                 start.z = org.z + random() * delta.z;
1471
1472                                                 end.x = org.x + random() * delta.x;
1473                                                 end.y = org.y + random() * delta.y;
1474                                                 end.z = org.z + random() * delta.z;
1475
1476                                                 start = stov(vtos(start));
1477                                                 end = stov(vtos(end));
1478
1479                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1480                                                 if (!trace_startsolid && trace_fraction < 1)
1481                                                 {
1482                                                         p = trace_endpos;
1483                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, p, MOVE_NOMONSTERS, NULL);
1484                                                         if (trace_startsolid)
1485                                                         {
1486                                                                 rint(42);  // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1487                                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1488
1489                                                                 // how much do we need to back off?
1490                                                                 safe = 1;
1491                                                                 unsafe = 0;
1492                                                                 for ( ; ; )
1493                                                                 {
1494                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1495                                                                         tracebox(pos, PL_MIN_CONST, PL_MAX_CONST, pos, MOVE_NOMONSTERS, NULL);
1496                                                                         if (trace_startsolid)
1497                                                                         {
1498                                                                                 if ((safe + unsafe) * 0.5 == unsafe) break;
1499                                                                                 unsafe = (safe + unsafe) * 0.5;
1500                                                                         }
1501                                                                         else
1502                                                                         {
1503                                                                                 if ((safe + unsafe) * 0.5 == safe) break;
1504                                                                                 safe = (safe + unsafe) * 0.5;
1505                                                                         }
1506                                                                 }
1507
1508                                                                 LOG_INFO("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu");
1509                                                                 LOG_INFO("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu");
1510
1511                                                                 tracebox(p, PL_MIN_CONST + '0.1 0.1 0.1', PL_MAX_CONST - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, NULL);
1512                                                                 if (trace_startsolid) LOG_INFO("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1513                                                                 else LOG_INFO("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1514                                                                 if (++hitcount >= 10) break;
1515                                                         }
1516                                                         else
1517                                                         {
1518                                                                 q0 = p;
1519                                                                 dq = 0;
1520                                                                 dqf = 1;
1521                                                                 for ( ; ; )
1522                                                                 {
1523                                                                         q = p + normalize(end - p) * (dq + dqf);
1524                                                                         if (q == q0) break;
1525                                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, q, MOVE_NOMONSTERS, NULL);
1526                                                                         if (trace_startsolid) error("THIS ONE cannot happen");
1527                                                                         if (trace_fraction > 0) dq += dqf * trace_fraction;
1528                                                                         dqf *= 0.5;
1529                                                                         q0 = q;
1530                                                                 }
1531                                                                 if (dq > worst_endpos_bug)
1532                                                                 {
1533                                                                         worst_endpos_bug = dq;
1534                                                                         LOG_INFO("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1535                                                                         LOG_INFO("could go ", ftos(dq), " units further to ", vtos(q));
1536                                                                         if (++hitcount >= 10) break;
1537                                                                 }
1538                                                         }
1539                                                 }
1540                                         }
1541                                         return;
1542                                 }
1543
1544                                 case "debug2":
1545                                 {
1546                                         e = nextent(NULL);
1547                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1548                                         vv = trace_endpos;
1549                                         if (trace_fraction == 1)
1550                                         {
1551                                                 LOG_INFO("not above ground, aborting");
1552                                                 return;
1553                                         }
1554                                         f = 0;
1555                                         for (i = 0; i < 100000; ++i)
1556                                         {
1557                                                 dv = randomvec();
1558                                                 if (dv.z > 0) dv = -1 * dv;
1559                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1560                                                 if (trace_startsolid) LOG_INFO("bug 1");
1561                                                 if (trace_fraction == 1)
1562                                                 {
1563                                                         if (dv.z < f)
1564                                                         {
1565                                                                 LOG_INFO("bug 2: ", ftos(dv.x), " ", ftos(dv.y), " ", ftos(dv.z));
1566                                                                 LOG_INFO(" (", ftos(asin(dv.z / vlen(dv)) * 180 / M_PI), " degrees)");
1567                                                                 f = dv.z;
1568                                                         }
1569                                                 }
1570                                         }
1571                                         LOG_INFO("highest possible dist: ", ftos(f));
1572                                         return;
1573                                 }
1574
1575                                 case "walk":
1576                                 {
1577                                         if (argc == 4)
1578                                         {
1579                                                 e = nextent(NULL);
1580                                                 if (tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), MOVE_NORMAL)) LOG_INFO("can walk");
1581                                                 else LOG_INFO("cannot walk");
1582                                                 return;
1583                                         }
1584                                 }
1585
1586                                 case "showline":
1587                                 {
1588                                         if (argc == 4)
1589                                         {
1590                                                 vv = stov(argv(2));
1591                                                 dv = stov(argv(3));
1592                                                 traceline(vv, dv, MOVE_NORMAL, NULL);
1593                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_NEXUIZPLASMA), vv, trace_endpos);
1594                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_CRYLINKPLASMA), trace_endpos, dv);
1595                                                 return;
1596                                         }
1597                                 }
1598
1599                                         // no default case, just go straight to invalid
1600                         }
1601                 }
1602
1603                 default:
1604                         LOG_INFO("Incorrect parameters for ^2trace^7");
1605                 case CMD_REQUEST_USAGE:
1606                 {
1607                         LOG_INFO("Usage:^3 sv_cmd trace command (startpos endpos)");
1608                         LOG_INFO("  Full list of commands here: \"debug, debug2, walk, showline.\"");
1609                         LOG_INFO("See also: ^2bbox, gettaginfo^7");
1610                         return;
1611                 }
1612         }
1613 }
1614
1615 void GameCommand_unlockteams(float request)
1616 {
1617         switch (request)
1618         {
1619                 case CMD_REQUEST_COMMAND:
1620                 {
1621                         if (teamplay)
1622                         {
1623                                 lockteams = 0;
1624                                 bprint("^1The teams are now unlocked.\n");
1625                         }
1626                         else
1627                         {
1628                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1629                         }
1630                         return;
1631                 }
1632
1633                 default:
1634                 case CMD_REQUEST_USAGE:
1635                 {
1636                         LOG_INFO("Usage:^3 sv_cmd unlockteams");
1637                         LOG_INFO("  No arguments required.");
1638                         LOG_INFO("See also: ^2lockteams^7");
1639                         return;
1640                 }
1641         }
1642 }
1643
1644 void GameCommand_warp(float request, float argc)
1645 {
1646         switch (request)
1647         {
1648                 case CMD_REQUEST_COMMAND:
1649                 {
1650                         if (autocvar_g_campaign)
1651                         {
1652                                 if (argc >= 2)
1653                                 {
1654                                         CampaignLevelWarp(stof(argv(1)));
1655                                         LOG_INFO("Successfully warped to campaign level ", argv(1), ".");
1656                                 }
1657                                 else
1658                                 {
1659                                         CampaignLevelWarp(-1);
1660                                         LOG_INFO("Successfully warped to next campaign level.");
1661                                 }
1662                         }
1663                         else
1664                         {
1665                                 LOG_INFO("Not in campaign, can't level warp");
1666                         }
1667                         return;
1668                 }
1669
1670                 default:
1671                 case CMD_REQUEST_USAGE:
1672                 {
1673                         LOG_INFO("Usage:^3 sv_cmd warp [level]");
1674                         LOG_INFO("  'level' is the level to change campaign mode to.");
1675                         LOG_INFO("  if 'level' is not provided it will change to the next level.");
1676                         return;
1677                 }
1678         }
1679 }
1680
1681 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1682 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1683 void GameCommand_(float request)
1684 {
1685     switch(request)
1686     {
1687         case CMD_REQUEST_COMMAND:
1688         {
1689
1690             return;
1691         }
1692
1693         default:
1694         case CMD_REQUEST_USAGE:
1695         {
1696             print("\nUsage:^3 sv_cmd \n");
1697             print("  No arguments required.\n");
1698             return;
1699         }
1700     }
1701 }
1702 */
1703
1704
1705 // ==================================
1706 //  Macro system for server commands
1707 // ==================================
1708
1709 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1710 SERVER_COMMAND(adminmsg, "Send an admin message to a client directly") { GameCommand_adminmsg(request, arguments); }
1711 SERVER_COMMAND(allready, "Restart the server and reset the players") { GameCommand_allready(request); }
1712 SERVER_COMMAND(allspec, "Force all players to spectate") { GameCommand_allspec(request, arguments); }
1713 SERVER_COMMAND(anticheat, "Create an anticheat report for a client") { GameCommand_anticheat(request, arguments); }
1714 SERVER_COMMAND(animbench, "Benchmark model animation (LAGS)") { GameCommand_animbench(request, arguments); }
1715 SERVER_COMMAND(bbox, "Print detailed information about world size") { GameCommand_bbox(request); }
1716 SERVER_COMMAND(bot_cmd, "Control and send commands to bots") { GameCommand_bot_cmd(request, arguments, command); }
1717 SERVER_COMMAND(cointoss, "Flip a virtual coin and give random result") { GameCommand_cointoss(request, arguments); }
1718 SERVER_COMMAND(database, "Extra controls of the serverprogs database") { GameCommand_database(request, arguments); }
1719 SERVER_COMMAND(defer_clear, "Clear all queued defer commands for a specific client") { GameCommand_defer_clear(request, arguments); }
1720 SERVER_COMMAND(defer_clear_all, "Clear all queued defer commands for all clients") { GameCommand_defer_clear_all(request); }
1721 SERVER_COMMAND(delrec, "Delete race time record for a map") { GameCommand_delrec(request, arguments); }
1722 SERVER_COMMAND(effectindexdump, "Dump list of effects from code and effectinfo.txt") { GameCommand_effectindexdump(request); }
1723 SERVER_COMMAND(extendmatchtime, "Increase the timelimit value incrementally") { GameCommand_extendmatchtime(request); }
1724 SERVER_COMMAND(gametype, "Simple command to change the active gametype") { GameCommand_gametype(request, arguments); }
1725 SERVER_COMMAND(gettaginfo, "Get specific information about a weapon model") { GameCommand_gettaginfo(request, arguments); }
1726 SERVER_COMMAND(gotomap, "Simple command to switch to another map") { GameCommand_gotomap(request, arguments); }
1727 SERVER_COMMAND(lockteams, "Disable the ability for players to switch or enter teams") { GameCommand_lockteams(request); }
1728 SERVER_COMMAND(make_mapinfo, "Automatically rebuild mapinfo files") { GameCommand_make_mapinfo(request); }
1729 SERVER_COMMAND(moveplayer, "Change the team/status of a player") { GameCommand_moveplayer(request, arguments); }
1730 SERVER_COMMAND(nospectators, "Automatically remove spectators from a match") { GameCommand_nospectators(request); }
1731 SERVER_COMMAND(playerdemo, "Control the ability to save demos of players") { GameCommand_playerdemo(request, arguments); }
1732 SERVER_COMMAND(printstats, "Dump eventlog player stats and other score information") { GameCommand_printstats(request); }
1733 SERVER_COMMAND(radarmap, "Generate a radar image of the map") { GameCommand_radarmap(request, arguments); }
1734 SERVER_COMMAND(reducematchtime, "Decrease the timelimit value incrementally") { GameCommand_reducematchtime(request); }
1735 SERVER_COMMAND(setbots, "Adjust how many bots are in the match") { GameCommand_setbots(request, arguments); }
1736 SERVER_COMMAND(shuffleteams, "Randomly move players to different teams") { GameCommand_shuffleteams(request); }
1737 SERVER_COMMAND(stuffto, "Send a command to be executed on a client") { GameCommand_stuffto(request, arguments); }
1738 SERVER_COMMAND(trace, "Various debugging tools with tracing") { GameCommand_trace(request, arguments); }
1739 SERVER_COMMAND(unlockteams, "Enable the ability for players to switch or enter teams") { GameCommand_unlockteams(request); }
1740 SERVER_COMMAND(warp, "Choose different level in campaign") { GameCommand_warp(request, arguments); }
1741
1742 void GameCommand_macro_help()
1743 {
1744         FOREACH(SERVER_COMMANDS, true, { LOG_INFOF("  ^2%s^7: %s", it.m_name, it.m_description); });
1745 }
1746
1747 float GameCommand_macro_command(float argc, string command)
1748 {
1749         string c = strtolower(argv(0));
1750         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1751                 it.m_invokecmd(it, CMD_REQUEST_COMMAND, NULL, argc, command);
1752                 return true;
1753         });
1754         return false;
1755 }
1756
1757 float GameCommand_macro_usage(float argc)
1758 {
1759         string c = strtolower(argv(1));
1760         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1761                 it.m_invokecmd(it, CMD_REQUEST_USAGE, NULL, argc, "");
1762                 return true;
1763         });
1764         return false;
1765 }
1766
1767 void GameCommand_macro_write_aliases(float fh)
1768 {
1769         FOREACH(SERVER_COMMANDS, true, { CMD_Write_Alias("qc_cmd_sv", it.m_name, it.m_description); });
1770 }
1771
1772
1773 // =========================================
1774 //  Main Function Called By Engine (sv_cmd)
1775 // =========================================
1776 // If this function exists, game code handles gamecommand instead of the engine code.
1777
1778 void GameCommand(string command)
1779 {
1780         float argc = tokenize_console(command);
1781
1782         // Guide for working with argc arguments by example:
1783         // argc:   1    - 2      - 3     - 4
1784         // argv:   0    - 1      - 2     - 3
1785         // cmd     vote - master - login - password
1786
1787         if (strtolower(argv(0)) == "help")
1788         {
1789                 if (argc == 1)
1790                 {
1791                         LOG_INFO("Server console commands:");
1792                         GameCommand_macro_help();
1793
1794                         LOG_INFO("\nBanning commands:");
1795                         BanCommand_macro_help();
1796
1797                         LOG_INFO("\nCommon networked commands:");
1798                         CommonCommand_macro_help(NULL);
1799
1800                         LOG_INFO("\nGeneric commands shared by all programs:");
1801                         GenericCommand_macro_help();
1802
1803                         LOG_INFO(
1804                             "\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n"
1805                 "For help about a specific command, type sv_cmd help COMMAND"
1806             );
1807
1808                         return;
1809                 }
1810                 else if (BanCommand_macro_usage(argc))  // Instead of trying to call a command, we're going to see detailed information about it
1811                 {
1812                         return;
1813                 }
1814                 else if (CommonCommand_macro_usage(argc, NULL))  // same here, but for common commands instead
1815                 {
1816                         return;
1817                 }
1818                 else if (GenericCommand_macro_usage(argc))  // same here, but for generic commands instead
1819                 {
1820                         return;
1821                 }
1822                 else if (GameCommand_macro_usage(argc))  // finally try for normal commands too
1823                 {
1824                         return;
1825                 }
1826         }
1827         else if (MUTATOR_CALLHOOK(SV_ParseServerCommand, strtolower(argv(0)), argc, command))
1828         {
1829                 return;  // handled by a mutator
1830         }
1831         else if (BanCommand(command))
1832         {
1833                 return;  // handled by server/command/ipban.qc
1834         }
1835         else if (CommonCommand_macro_command(argc, NULL, command))
1836         {
1837                 return;  // handled by server/command/common.qc
1838         }
1839         else if (GenericCommand(command))
1840         {
1841                 return;                                        // handled by common/command/generic.qc
1842         }
1843         else if (GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1844         {
1845                 return;                                        // handled by one of the above GameCommand_* functions
1846         }
1847
1848         // nothing above caught the command, must be invalid
1849         LOG_INFO(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.");
1850 }