qcsrc/server/command/cmd.qc

   1 // =========================================================
   2 //  Server side networked commands code, reworked by Samual
   3 //  Last updated: December 28th, 2011
   4 // =========================================================
   5
   6 float SV_ParseClientCommand_floodcheck()
   7 {
   8         if not(timeout_status) // not while paused
   9         {
  10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  11                 {
  12                         self.cmd_floodcount += 1;
  13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
  14                 }
  15                 else
  16                 {
  17                         self.cmd_floodtime = time;
  18                         self.cmd_floodcount = 1;
  19                 }
  20         }
  21         return TRUE; // continue, as we're not flooding yet
  22 }
  23
  24
  25 // =======================
  26 //  Command Sub-Functions
  27 // =======================
  28
  29 void ClientCommand_autoswitch(float request, float argc)
  30 {
  31         switch(request)
  32         {
  33                 case CMD_REQUEST_COMMAND:
  34                 {
  35                         if(argv(1) != "")
  36                         {
  37                                 self.autoswitch = InterpretBoolean(argv(1));
  38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  39                                 return;
  40                         }
  41                 }
  42
  43                 default:
  44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  45                 case CMD_REQUEST_USAGE:
  46                 {
  47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  49                         return;
  50                 }
  51         }
  52 }
  53
  54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  55 {
  56         switch(request)
  57         {
  58                 case CMD_REQUEST_COMMAND:
  59                 {
  60                         print(sprintf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1))));
  61                         self.checkfail = 1;
  62                         return; // never fall through to usage
  63                 }
  64
  65                 default:
  66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
  67                 case CMD_REQUEST_USAGE:
  68                 {
  69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
  70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
  71                         return;
  72                 }
  73         }
  74 }
  75
  76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
  77 {
  78         switch(request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if(argv(1) != "")
  83                         {
  84                                 if(self.flags & FL_CLIENT)
  85                                 {
  86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
  87
  88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
  89                                         {
  90                                                 self.version_mismatch = 1;
  91                                                 ClientKill_TeamChange(-2); // observe
  92                                         }
  93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
  94                                         {
  95                                                 //JoinBestTeam(self, FALSE, TRUE);
  96                                         }
  97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
  98                                         {
  99                                                 self.classname = "observer"; // really?
 100                                                 stuffcmd(self, "menu_showteamselect\n");
 101                                         }
 102                                 }
 103
 104                                 return;
 105                         }
 106                 }
 107
 108                 default:
 109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 110                 case CMD_REQUEST_USAGE:
 111                 {
 112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 114                         return;
 115                 }
 116         }
 117 }
 118
 119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 120 {
 121         switch(request)
 122         {
 123                 case CMD_REQUEST_COMMAND:
 124                 {
 125                         if(argv(1) != "")
 126                         {
 127                                 if(intermission_running)
 128                                         MapVote_SendPicture(stof(argv(1)));
 129
 130                                 return;
 131                         }
 132                 }
 133
 134                 default:
 135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 136                 case CMD_REQUEST_USAGE:
 137                 {
 138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 140                         return;
 141                 }
 142         }
 143 }
 144
 145 void ClientCommand_join(float request)
 146 {
 147         switch(request)
 148         {
 149                 case CMD_REQUEST_COMMAND:
 150                 {
 151                         if(self.flags & FL_CLIENT)
 152                         {
 153                                 if(self.classname != "player" && !lockteams && !g_arena)
 154                                 {
 155                                         if(nJoinAllowed(self))
 156                                         {
 157                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 158
 159                                                 self.classname = "player";
 160                                                 PlayerScore_Clear(self);
 161                                                 bprint ("^4", self.netname, "^4 is playing now\n");
 162                                                 PutClientInServer();
 163                                         }
 164                                         else
 165                                         {
 166                                                 //player may not join because of g_maxplayers is set
 167                                                 centerprint(self, PREVENT_JOIN_TEXT);
 168                                         }
 169                                 }
 170                         }
 171                         return; // never fall through to usage
 172                 }
 173
 174                 default:
 175                 case CMD_REQUEST_USAGE:
 176                 {
 177                         sprint(self, "\nUsage:^3 cmd join\n");
 178                         sprint(self, "  No arguments required.\n");
 179                         return;
 180                 }
 181         }
 182 }
 183
 184 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 185 {
 186         switch(request)
 187         {
 188                 case CMD_REQUEST_COMMAND:
 189                 {
 190                         if(self.flags & FL_CLIENT)
 191                         {
 192                                 if(inWarmupStage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 193                                 {
 194                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 195                                         {
 196                                                 if (self.ready) // toggle
 197                                                 {
 198                                                         self.ready = FALSE;
 199                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 200                                                 }
 201                                                 else
 202                                                 {
 203                                                         self.ready = TRUE;
 204                                                         bprint(self.netname, "^2 is ready\n");
 205                                                 }
 206
 207                                                 // cannot reset the game while a timeout is active!
 208                                                 if not(timeout_status)
 209                                                         ReadyCount();
 210                                         } else {
 211                                                 sprint(self, "^1Game has already been restarted\n");
 212                                         }
 213                                 }
 214                         }
 215                         return; // never fall through to usage
 216                 }
 217
 218                 default:
 219                 case CMD_REQUEST_USAGE:
 220                 {
 221                         sprint(self, "\nUsage:^3 cmd ready\n");
 222                         sprint(self, "  No arguments required.\n");
 223                         return;
 224                 }
 225         }
 226 }
 227
 228 void ClientCommand_say(float request, float argc, string command)
 229 {
 230         switch(request)
 231         {
 232                 case CMD_REQUEST_COMMAND:
 233                 {
 234                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 235                         return; // never fall through to usage
 236                 }
 237
 238                 default:
 239                 case CMD_REQUEST_USAGE:
 240                 {
 241                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 242                         sprint(self, "  Where 'message' is the string of text to say.\n");
 243                         return;
 244                 }
 245         }
 246 }
 247
 248 void ClientCommand_say_team(float request, float argc, string command)
 249 {
 250         switch(request)
 251         {
 252                 case CMD_REQUEST_COMMAND:
 253                 {
 254                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 255                         return; // never fall through to usage
 256                 }
 257
 258                 default:
 259                 case CMD_REQUEST_USAGE:
 260                 {
 261                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 262                         sprint(self, "  Where 'message' is the string of text to say.\n");
 263                         return;
 264                 }
 265         }
 266 }
 267
 268 void ClientCommand_selectteam(float request, float argc)
 269 {
 270         switch(request)
 271         {
 272                 case CMD_REQUEST_COMMAND:
 273                 {
 274                         if(argv(1) != "")
 275                         {
 276                                 if(self.flags & FL_CLIENT)
 277                                 {
 278                                         if(teamplay)
 279                                                 if not(self.team_forced > 0)
 280                                                         if not(lockteams)
 281                                                         {
 282                                                                 float selection;
 283
 284                                                                 switch(argv(1))
 285                                                                 {
 286                                                                         case "red": selection = COLOR_TEAM1; break;
 287                                                                         case "blue": selection = COLOR_TEAM2; break;
 288                                                                         case "yellow": selection = COLOR_TEAM3; break;
 289                                                                         case "pink": selection = COLOR_TEAM4; break;
 290                                                                         case "auto": selection = (-1); break;
 291
 292                                                                         default: selection = 0; break;
 293                                                                 }
 294
 295                                                                 if(selection)
 296                                                                 {
 297                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 298                                                                                 sprint(self, "^7You already are on that team.\n");
 299                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 300                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 301                                                                         else
 302                                                                                 ClientKill_TeamChange(selection);
 303                                                                 }
 304                                                         }
 305                                                         else
 306                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 307                                                 else
 308                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 309                                         else
 310                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 311                                 }
 312                                 return;
 313                         }
 314                 }
 315
 316                 default:
 317                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 318                 case CMD_REQUEST_USAGE:
 319                 {
 320                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 321                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 322                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 323                         return;
 324                 }
 325         }
 326 }
 327
 328 void ClientCommand_selfstuff(float request, string command)
 329 {
 330         switch(request)
 331         {
 332                 case CMD_REQUEST_COMMAND:
 333                 {
 334                         if(argv(1) != "")
 335                         {
 336                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 337                                 return;
 338                         }
 339                 }
 340
 341                 default:
 342                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 343                 case CMD_REQUEST_USAGE:
 344                 {
 345                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 346                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 347                         return;
 348                 }
 349         }
 350 }
 351
 352 void ClientCommand_sentcvar(float request, float argc, string command)
 353 {
 354         switch(request)
 355         {
 356                 case CMD_REQUEST_COMMAND:
 357                 {
 358                         if(argv(1) != "")
 359                         {
 360                                 //float tokens;
 361                                 string s;
 362
 363                                 if(argc == 2) // undefined cvar: use the default value on the server then
 364                                 {
 365                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 366                                         tokenize_console(s);
 367                                 }
 368
 369                                 GetCvars(1);
 370
 371                                 return;
 372                         }
 373                 }
 374
 375                 default:
 376                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 377                 case CMD_REQUEST_USAGE:
 378                 {
 379                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 380                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 381                         return;
 382                 }
 383         }
 384 }
 385
 386 void ClientCommand_spectate(float request)
 387 {
 388         switch(request)
 389         {
 390                 case CMD_REQUEST_COMMAND:
 391                 {
 392                         if(self.flags & FL_CLIENT)
 393                         {
 394                                 if(g_arena) { return; }
 395                                 if(g_lms)
 396                                 {
 397                                         if(self.lms_spectate_warning)
 398                                         {
 399                                                 // mark player as spectator
 400                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 401                                         }
 402                                         else
 403                                         {
 404                                                 self.lms_spectate_warning = 1;
 405                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 406                                                 return;
 407                                         }
 408                                 }
 409
 410                                 if(self.classname == "player" && autocvar_sv_spectate == 1)
 411                                         ClientKill_TeamChange(-2); // observe
 412
 413                                 // in CA, allow a dead player to move to spectators (without that, caplayer!=0 will be moved back to the player list)
 414                                 // note: if arena game mode is ever done properly, this needs to be removed.
 415                                 if(g_ca && self.caplayer && (self.classname == "spectator" || self.classname == "observer"))
 416                                 {
 417                                         sprint(self, "WARNING: you will spectate in the next round.\n");
 418                                         self.caplayer = 0;
 419                                 }
 420                         }
 421                         return; // never fall through to usage
 422                 }
 423
 424                 default:
 425                 case CMD_REQUEST_USAGE:
 426                 {
 427                         sprint(self, "\nUsage:^3 cmd spectate\n");
 428                         sprint(self, "  No arguments required.\n");
 429                         return;
 430                 }
 431         }
 432 }
 433
 434 void ClientCommand_suggestmap(float request, float argc)
 435 {
 436         switch(request)
 437         {
 438                 case CMD_REQUEST_COMMAND:
 439                 {
 440                         if(argv(1) != "")
 441                         {
 442                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 443                                 return;
 444                         }
 445                 }
 446
 447                 default:
 448                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 449                 case CMD_REQUEST_USAGE:
 450                 {
 451                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 452                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 453                         return;
 454                 }
 455         }
 456 }
 457
 458 void ClientCommand_tell(float request, float argc, string command)
 459 {
 460         switch(request)
 461         {
 462                 case CMD_REQUEST_COMMAND:
 463                 {
 464                         if(argc >= 3)
 465                         {
 466                                 entity tell_to = GetIndexedEntity(argc, 1);
 467                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
 468
 469                                 if(tell_accepted > 0) // the target is a real client
 470                                 {
 471                                         if(tell_to != self) // and we're allowed to send to them :D
 472                                         {
 473                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
 474                                                 return;
 475                                         }
 476                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 477                                 }
 478                                 else if(argv(1) == "#0")
 479                                 {
 480                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 481                                         return;
 482                                 }
 483                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 484                         }
 485                 }
 486
 487                 default:
 488                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 489                 case CMD_REQUEST_USAGE:
 490                 {
 491                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 492                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 493                         return;
 494                 }
 495         }
 496 }
 497
 498 void ClientCommand_voice(float request, float argc, string command)
 499 {
 500         switch(request)
 501         {
 502                 case CMD_REQUEST_COMMAND:
 503                 {
 504                         if(argv(1) != "")
 505                         {
 506                                 if(argc >= 3)
 507                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 508                                 else
 509                                         VoiceMessage(argv(1), "");
 510
 511                                 return;
 512                         }
 513                 }
 514
 515                 default:
 516                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 517                 case CMD_REQUEST_USAGE:
 518                 {
 519                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 520                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 521                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 522                         return;
 523                 }
 524         }
 525 }
 526
 527 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 528 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 529 void ClientCommand_(float request)
 530 {
 531         switch(request)
 532         {
 533                 case CMD_REQUEST_COMMAND:
 534                 {
 535
 536                         return; // never fall through to usage
 537                 }
 538
 539                 default:
 540                 case CMD_REQUEST_USAGE:
 541                 {
 542                         sprint(self, "\nUsage:^3 cmd \n");
 543                         sprint(self, "  No arguments required.\n");
 544                         return;
 545                 }
 546         }
 547 }
 548 */
 549
 550
 551 // =====================================
 552 //  Macro system for networked commands
 553 // =====================================
 554
 555 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 556 #define CLIENT_COMMANDS(request,arguments,command) \
 557         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 558         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 559         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 560         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 561         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 562         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 563         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 564         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 565         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 566         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 567         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 568         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 569         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 570         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 571         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 572         /* nothing */
 573
 574 void ClientCommand_macro_help()
 575 {
 576         #define CLIENT_COMMAND(name,function,description) \
 577                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 578
 579         CLIENT_COMMANDS(0, 0, "")
 580         #undef CLIENT_COMMAND
 581
 582         return;
 583 }
 584
 585 float ClientCommand_macro_command(float argc, string command)
 586 {
 587         #define CLIENT_COMMAND(name,function,description) \
 588                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 589
 590         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 591         #undef CLIENT_COMMAND
 592
 593         return FALSE;
 594 }
 595
 596 float ClientCommand_macro_usage(float argc)
 597 {
 598         #define CLIENT_COMMAND(name,function,description) \
 599                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 600
 601         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 602         #undef CLIENT_COMMAND
 603
 604         return FALSE;
 605 }
 606
 607 void ClientCommand_macro_write_aliases(float fh)
 608 {
 609         #define CLIENT_COMMAND(name,function,description) \
 610                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 611
 612         CLIENT_COMMANDS(0, 0, "")
 613         #undef CLIENT_COMMAND
 614
 615         return;
 616 }
 617
 618 // ======================================
 619 //  Main Function Called By Engine (cmd)
 620 // ======================================
 621 // If this function exists, server game code parses clientcommand before the engine code gets it.
 622
 623 void SV_ParseClientCommand(string command)
 624 {
 625         // if we're banned, don't even parse the command
 626         if(Ban_MaybeEnforceBanOnce(self))
 627                 return;
 628
 629         float argc = tokenize_console(command);
 630
 631         // for the mutator hook system
 632         cmd_name = strtolower(argv(0));
 633         cmd_argc = argc;
 634         cmd_string = command;
 635
 636         // Guide for working with argc arguments by example:
 637         // argc:   1    - 2      - 3     - 4
 638         // argv:   0    - 1      - 2     - 3
 639         // cmd     vote - master - login - password
 640
 641         // for floodcheck
 642         switch(strtolower(argv(0)))
 643         {
 644                 // exempt commands which are not subject to floodcheck
 645                 case "begin": break; // handled by engine in host_cmd.c
 646                 case "download": break; // handled by engine in cl_parse.c
 647                 case "mv_getpicture": break; // handled by server in this file
 648                 case "pause": break; // handled by engine in host_cmd.c
 649                 case "prespawn": break; // handled by engine in host_cmd.c
 650                 case "sentcvar": break; // handled by server in this file
 651                 case "spawn": break; // handled by engine in host_cmd.c
 652
 653                 default:
 654                         if(SV_ParseClientCommand_floodcheck())
 655                                 break; // "TRUE": continue, as we're not flooding yet
 656                         else
 657                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 658         }
 659
 660         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 661         if(argv(0) == "help")
 662         {
 663                 if(argc == 1)
 664                 {
 665                         sprint(self, "\nClient networked commands:\n");
 666                         ClientCommand_macro_help();
 667
 668                         sprint(self, "\nCommon networked commands:\n");
 669                         CommonCommand_macro_help(self);
 670
 671                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 672                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 673                         return;
 674                 }
 675                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 676                 {
 677                         return;
 678                 }
 679                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 680                 {
 681                         return;
 682                 }
 683         }
 684         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 685         {
 686                 return; // handled by a mutator
 687         }
 688         else if(CheatCommand(argc))
 689         {
 690                 return; // handled by server/cheats.qc
 691         }
 692         else if(CommonCommand_macro_command(argc, self, command))
 693         {
 694                 return; // handled by server/command/common.qc
 695         }
 696         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 697         {
 698                 return; // handled by one of the above ClientCommand_* functions
 699         }
 700         else
 701                 clientcommand(self, command);
 702 }