qcsrc/server/command/cmd.qc

   1 // =========================================================
   2 //  Server side networked commands code, reworked by Samual
   3 //  Last updated: December 28th, 2011
   4 // =========================================================
   5
   6 float SV_ParseClientCommand_floodcheck()
   7 {
   8         if not(timeout_status) // not while paused
   9         {
  10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  11                 {
  12                         self.cmd_floodcount += 1;
  13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
  14                 }
  15                 else
  16                 {
  17                         self.cmd_floodtime = time;
  18                         self.cmd_floodcount = 1;
  19                 }
  20         }
  21         return TRUE; // continue, as we're not flooding yet
  22 }
  23
  24
  25 // =======================
  26 //  Command Sub-Functions
  27 // =======================
  28
  29 void ClientCommand_autoswitch(float request, float argc)
  30 {
  31         switch(request)
  32         {
  33                 case CMD_REQUEST_COMMAND:
  34                 {
  35                         if(argv(1) != "")
  36                         {
  37                                 self.autoswitch = InterpretBoolean(argv(1));
  38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  39                                 return;
  40                         }
  41                 }
  42
  43                 default:
  44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  45                 case CMD_REQUEST_USAGE:
  46                 {
  47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  49                         return;
  50                 }
  51         }
  52 }
  53
  54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  55 {
  56         switch(request)
  57         {
  58                 case CMD_REQUEST_COMMAND:
  59                 {
  60                         print(sprintf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1))));
  61                         self.checkfail = 1;
  62                         return; // never fall through to usage
  63                 }
  64
  65                 default:
  66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
  67                 case CMD_REQUEST_USAGE:
  68                 {
  69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
  70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
  71                         return;
  72                 }
  73         }
  74 }
  75
  76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
  77 {
  78         switch(request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if(argv(1) != "")
  83                         {
  84                                 if(self.flags & FL_CLIENT)
  85                                 {
  86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
  87
  88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
  89                                         {
  90                                                 self.version_mismatch = 1;
  91                                                 ClientKill_TeamChange(-2); // observe
  92                                         }
  93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
  94                                         {
  95                                                 //JoinBestTeam(self, FALSE, TRUE);
  96                                         }
  97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
  98                                         {
  99                                                 self.classname = "observer"; // really?
 100                                                 stuffcmd(self, "menu_showteamselect\n");
 101                                         }
 102                                 }
 103
 104                                 return;
 105                         }
 106                 }
 107
 108                 default:
 109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 110                 case CMD_REQUEST_USAGE:
 111                 {
 112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 114                         return;
 115                 }
 116         }
 117 }
 118
 119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 120 {
 121         switch(request)
 122         {
 123                 case CMD_REQUEST_COMMAND:
 124                 {
 125                         if(argv(1) != "")
 126                         {
 127                                 if(intermission_running)
 128                                         MapVote_SendPicture(stof(argv(1)));
 129
 130                                 return;
 131                         }
 132                 }
 133
 134                 default:
 135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 136                 case CMD_REQUEST_USAGE:
 137                 {
 138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 140                         return;
 141                 }
 142         }
 143 }
 144
 145 void ClientCommand_join(float request)
 146 {
 147         switch(request)
 148         {
 149                 case CMD_REQUEST_COMMAND:
 150                 {
 151                         if(self.flags & FL_CLIENT)
 152                         {
 153                                 if(self.classname != "player" && !lockteams && !g_arena)
 154                                 {
 155                                         if(nJoinAllowed(self))
 156                                         {
 157                                                 if(g_ca) { self.caplayer = 1; }
 158                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 159
 160                                                 self.classname = "player";
 161                                                 PlayerScore_Clear(self);
 162                                                 bprint ("^4", self.netname, "^4 is playing now\n");
 163                                                 PutClientInServer();
 164                                         }
 165                                         else
 166                                         {
 167                                                 //player may not join because of g_maxplayers is set
 168                                                 centerprint(self, PREVENT_JOIN_TEXT);
 169                                         }
 170                                 }
 171                         }
 172                         return; // never fall through to usage
 173                 }
 174
 175                 default:
 176                 case CMD_REQUEST_USAGE:
 177                 {
 178                         sprint(self, "\nUsage:^3 cmd join\n");
 179                         sprint(self, "  No arguments required.\n");
 180                         return;
 181                 }
 182         }
 183 }
 184
 185 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 186 {
 187         switch(request)
 188         {
 189                 case CMD_REQUEST_COMMAND:
 190                 {
 191                         if(self.flags & FL_CLIENT)
 192                         {
 193                                 if(inWarmupStage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 194                                 {
 195                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 196                                         {
 197                                                 if (self.ready) // toggle
 198                                                 {
 199                                                         self.ready = FALSE;
 200                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 201                                                 }
 202                                                 else
 203                                                 {
 204                                                         self.ready = TRUE;
 205                                                         bprint(self.netname, "^2 is ready\n");
 206                                                 }
 207
 208                                                 // cannot reset the game while a timeout is active!
 209                                                 if not(timeout_status)
 210                                                         ReadyCount();
 211                                         } else {
 212                                                 sprint(self, "^1Game has already been restarted\n");
 213                                         }
 214                                 }
 215                         }
 216                         return; // never fall through to usage
 217                 }
 218
 219                 default:
 220                 case CMD_REQUEST_USAGE:
 221                 {
 222                         sprint(self, "\nUsage:^3 cmd ready\n");
 223                         sprint(self, "  No arguments required.\n");
 224                         return;
 225                 }
 226         }
 227 }
 228
 229 void ClientCommand_say(float request, float argc, string command)
 230 {
 231         switch(request)
 232         {
 233                 case CMD_REQUEST_COMMAND:
 234                 {
 235                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 236                         return; // never fall through to usage
 237                 }
 238
 239                 default:
 240                 case CMD_REQUEST_USAGE:
 241                 {
 242                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 243                         sprint(self, "  Where 'message' is the string of text to say.\n");
 244                         return;
 245                 }
 246         }
 247 }
 248
 249 void ClientCommand_say_team(float request, float argc, string command)
 250 {
 251         switch(request)
 252         {
 253                 case CMD_REQUEST_COMMAND:
 254                 {
 255                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 256                         return; // never fall through to usage
 257                 }
 258
 259                 default:
 260                 case CMD_REQUEST_USAGE:
 261                 {
 262                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 263                         sprint(self, "  Where 'message' is the string of text to say.\n");
 264                         return;
 265                 }
 266         }
 267 }
 268
 269 void ClientCommand_selectteam(float request, float argc)
 270 {
 271         switch(request)
 272         {
 273                 case CMD_REQUEST_COMMAND:
 274                 {
 275                         if(argv(1) != "")
 276                         {
 277                                 if(self.flags & FL_CLIENT)
 278                                 {
 279                                         if(teamplay)
 280                                                 if not(self.team_forced > 0)
 281                                                         if not(lockteams)
 282                                                         {
 283                                                                 float selection;
 284
 285                                                                 switch(argv(1))
 286                                                                 {
 287                                                                         case "red": selection = COLOR_TEAM1; break;
 288                                                                         case "blue": selection = COLOR_TEAM2; break;
 289                                                                         case "yellow": selection = COLOR_TEAM3; break;
 290                                                                         case "pink": selection = COLOR_TEAM4; break;
 291                                                                         case "auto": selection = (-1); break;
 292
 293                                                                         default: selection = 0; break;
 294                                                                 }
 295
 296                                                                 if(selection)
 297                                                                 {
 298                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 299                                                                                 sprint(self, "^7You already are on that team.\n");
 300                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 301                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 302                                                                         else
 303                                                                                 ClientKill_TeamChange(selection);
 304                                                                 }
 305                                                         }
 306                                                         else
 307                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 308                                                 else
 309                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 310                                         else
 311                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 312                                 }
 313                                 return;
 314                         }
 315                 }
 316
 317                 default:
 318                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 319                 case CMD_REQUEST_USAGE:
 320                 {
 321                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 322                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 323                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 324                         return;
 325                 }
 326         }
 327 }
 328
 329 void ClientCommand_selfstuff(float request, string command)
 330 {
 331         switch(request)
 332         {
 333                 case CMD_REQUEST_COMMAND:
 334                 {
 335                         if(argv(1) != "")
 336                         {
 337                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 338                                 return;
 339                         }
 340                 }
 341
 342                 default:
 343                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 344                 case CMD_REQUEST_USAGE:
 345                 {
 346                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 347                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 348                         return;
 349                 }
 350         }
 351 }
 352
 353 void ClientCommand_sentcvar(float request, float argc, string command)
 354 {
 355         switch(request)
 356         {
 357                 case CMD_REQUEST_COMMAND:
 358                 {
 359                         if(argv(1) != "")
 360                         {
 361                                 //float tokens;
 362                                 string s;
 363
 364                                 if(argc == 2) // undefined cvar: use the default value on the server then
 365                                 {
 366                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 367                                         tokenize_console(s);
 368                                 }
 369
 370                                 GetCvars(1);
 371
 372                                 return;
 373                         }
 374                 }
 375
 376                 default:
 377                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 378                 case CMD_REQUEST_USAGE:
 379                 {
 380                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 381                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 382                         return;
 383                 }
 384         }
 385 }
 386
 387 void ClientCommand_spectate(float request)
 388 {
 389         switch(request)
 390         {
 391                 case CMD_REQUEST_COMMAND:
 392                 {
 393                         if(self.flags & FL_CLIENT)
 394                         {
 395                                 if(g_arena) { return; }
 396                                 if(g_lms)
 397                                 {
 398                                         if(self.lms_spectate_warning)
 399                                         {
 400                                                 // mark player as spectator
 401                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 402                                         }
 403                                         else
 404                                         {
 405                                                 self.lms_spectate_warning = 1;
 406                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 407                                                 return;
 408                                         }
 409                                 }
 410
 411                                 if(self.classname == "player" && autocvar_sv_spectate == 1)
 412                                         ClientKill_TeamChange(-2); // observe
 413
 414                                 // in CA, allow a dead player to move to spectators (without that, caplayer!=0 will be moved back to the player list)
 415                                 // note: if arena game mode is ever done properly, this needs to be removed.
 416                                 if(g_ca && self.caplayer && (self.classname == "spectator" || self.classname == "observer"))
 417                                 {
 418                                         sprint(self, "WARNING: you will spectate in the next round.\n");
 419                                         self.caplayer = 0;
 420                                 }
 421                         }
 422                         return; // never fall through to usage
 423                 }
 424
 425                 default:
 426                 case CMD_REQUEST_USAGE:
 427                 {
 428                         sprint(self, "\nUsage:^3 cmd spectate\n");
 429                         sprint(self, "  No arguments required.\n");
 430                         return;
 431                 }
 432         }
 433 }
 434
 435 void ClientCommand_suggestmap(float request, float argc)
 436 {
 437         switch(request)
 438         {
 439                 case CMD_REQUEST_COMMAND:
 440                 {
 441                         if(argv(1) != "")
 442                         {
 443                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 444                                 return;
 445                         }
 446                 }
 447
 448                 default:
 449                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 450                 case CMD_REQUEST_USAGE:
 451                 {
 452                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 453                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 454                         return;
 455                 }
 456         }
 457 }
 458
 459 void ClientCommand_tell(float request, float argc, string command)
 460 {
 461         switch(request)
 462         {
 463                 case CMD_REQUEST_COMMAND:
 464                 {
 465                         if(argc >= 3)
 466                         {
 467                                 entity tell_to = GetIndexedEntity(argc, 1);
 468                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
 469
 470                                 if(tell_accepted > 0) // the target is a real client
 471                                 {
 472                                         if(tell_to != self) // and we're allowed to send to them :D
 473                                         {
 474                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
 475                                                 return;
 476                                         }
 477                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 478                                 }
 479                                 else if(argv(1) == "#0")
 480                                 {
 481                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 482                                         return;
 483                                 }
 484                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 485                         }
 486                 }
 487
 488                 default:
 489                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 490                 case CMD_REQUEST_USAGE:
 491                 {
 492                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 493                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 494                         return;
 495                 }
 496         }
 497 }
 498
 499 void ClientCommand_voice(float request, float argc, string command)
 500 {
 501         switch(request)
 502         {
 503                 case CMD_REQUEST_COMMAND:
 504                 {
 505                         if(argv(1) != "")
 506                         {
 507                                 if(argc >= 3)
 508                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 509                                 else
 510                                         VoiceMessage(argv(1), "");
 511
 512                                 return;
 513                         }
 514                 }
 515
 516                 default:
 517                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 518                 case CMD_REQUEST_USAGE:
 519                 {
 520                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 521                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 522                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 523                         return;
 524                 }
 525         }
 526 }
 527
 528 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 529 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 530 void ClientCommand_(float request)
 531 {
 532         switch(request)
 533         {
 534                 case CMD_REQUEST_COMMAND:
 535                 {
 536
 537                         return; // never fall through to usage
 538                 }
 539
 540                 default:
 541                 case CMD_REQUEST_USAGE:
 542                 {
 543                         sprint(self, "\nUsage:^3 cmd \n");
 544                         sprint(self, "  No arguments required.\n");
 545                         return;
 546                 }
 547         }
 548 }
 549 */
 550
 551
 552 // =====================================
 553 //  Macro system for networked commands
 554 // =====================================
 555
 556 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 557 #define CLIENT_COMMANDS(request,arguments,command) \
 558         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 559         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 560         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 561         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 562         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 563         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 564         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 565         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 566         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 567         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 568         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 569         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 570         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 571         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 572         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 573         /* nothing */
 574
 575 void ClientCommand_macro_help()
 576 {
 577         #define CLIENT_COMMAND(name,function,description) \
 578                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 579
 580         CLIENT_COMMANDS(0, 0, "")
 581         #undef CLIENT_COMMAND
 582
 583         return;
 584 }
 585
 586 float ClientCommand_macro_command(float argc, string command)
 587 {
 588         #define CLIENT_COMMAND(name,function,description) \
 589                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 590
 591         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 592         #undef CLIENT_COMMAND
 593
 594         return FALSE;
 595 }
 596
 597 float ClientCommand_macro_usage(float argc)
 598 {
 599         #define CLIENT_COMMAND(name,function,description) \
 600                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 601
 602         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 603         #undef CLIENT_COMMAND
 604
 605         return FALSE;
 606 }
 607
 608 void ClientCommand_macro_write_aliases(float fh)
 609 {
 610         #define CLIENT_COMMAND(name,function,description) \
 611                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 612
 613         CLIENT_COMMANDS(0, 0, "")
 614         #undef CLIENT_COMMAND
 615
 616         return;
 617 }
 618
 619 // ======================================
 620 //  Main Function Called By Engine (cmd)
 621 // ======================================
 622 // If this function exists, server game code parses clientcommand before the engine code gets it.
 623
 624 void SV_ParseClientCommand(string command)
 625 {
 626         // if we're banned, don't even parse the command
 627         if(Ban_MaybeEnforceBanOnce(self))
 628                 return;
 629
 630         float argc = tokenize_console(command);
 631
 632         // for the mutator hook system
 633         cmd_name = strtolower(argv(0));
 634         cmd_argc = argc;
 635         cmd_string = command;
 636
 637         // Guide for working with argc arguments by example:
 638         // argc:   1    - 2      - 3     - 4
 639         // argv:   0    - 1      - 2     - 3
 640         // cmd     vote - master - login - password
 641
 642         // for floodcheck
 643         switch(strtolower(argv(0)))
 644         {
 645                 // exempt commands which are not subject to floodcheck
 646                 case "begin": break; // handled by engine in host_cmd.c
 647                 case "download": break; // handled by engine in cl_parse.c
 648                 case "mv_getpicture": break; // handled by server in this file
 649                 case "pause": break; // handled by engine in host_cmd.c
 650                 case "prespawn": break; // handled by engine in host_cmd.c
 651                 case "sentcvar": break; // handled by server in this file
 652                 case "spawn": break; // handled by engine in host_cmd.c
 653
 654                 default:
 655                         if(SV_ParseClientCommand_floodcheck())
 656                                 break; // "TRUE": continue, as we're not flooding yet
 657                         else
 658                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 659         }
 660
 661         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 662         if(argv(0) == "help")
 663         {
 664                 if(argc == 1)
 665                 {
 666                         sprint(self, "\nClient networked commands:\n");
 667                         ClientCommand_macro_help();
 668
 669                         sprint(self, "\nCommon networked commands:\n");
 670                         CommonCommand_macro_help(self);
 671
 672                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 673                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 674                         return;
 675                 }
 676                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 677                 {
 678                         return;
 679                 }
 680                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 681                 {
 682                         return;
 683                 }
 684         }
 685         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 686         {
 687                 return; // handled by a mutator
 688         }
 689         else if(CheatCommand(argc))
 690         {
 691                 return; // handled by server/cheats.qc
 692         }
 693         else if(CommonCommand_macro_command(argc, self, command))
 694         {
 695                 return; // handled by server/command/common.qc
 696         }
 697         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 698         {
 699                 return; // handled by one of the above ClientCommand_* functions
 700         }
 701         else
 702                 clientcommand(self, command);
 703 }