qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2
   3 #include <server/chat.qh>
   4 #include <server/world.qh>
   5 #include <server/miscfunctions.qh>
   6
   7 #include <common/command/_mod.qh>
   8
   9 #include "common.qh"
  10 #include "vote.qh"
  11
  12 #include "../bot/api.qh"
  13
  14 #include "../campaign.qh"
  15 #include "../cheats.qh"
  16 #include "../client.qh"
  17 #include "../clientkill.qh"
  18 #include "../player.qh"
  19 #include "../ipban.qh"
  20 #include "../mapvoting.qh"
  21 #include "../scores.qh"
  22 #include "../teamplay.qh"
  23
  24 #include <server/mutators/_mod.qh>
  25 #include <common/gamemodes/_mod.qh>
  26
  27 #ifdef SVQC
  28         #include <common/vehicles/all.qh>
  29 #endif
  30
  31 #include <common/constants.qh>
  32 #include <common/deathtypes/all.qh>
  33 #include <common/effects/all.qh>
  34 #include <common/mapinfo.qh>
  35 #include <common/notifications/all.qh>
  36 #include <common/physics/player.qh>
  37 #include <common/teams.qh>
  38 #include <common/util.qh>
  39 #include <common/mapobjects/triggers.qh>
  40
  41 #include <common/minigames/sv_minigames.qh>
  42
  43 #include <common/monsters/_mod.qh>
  44 #include <common/monsters/sv_spawn.qh>
  45 #include <common/monsters/sv_monsters.qh>
  46
  47 #include <lib/warpzone/common.qh>
  48
  49 // =========================================================
  50 //  Server side networked commands code, reworked by Samual
  51 //  Last updated: December 28th, 2011
  52 // =========================================================
  53
  54 bool SV_ParseClientCommand_floodcheck(entity this)
  55 {
  56         entity store = IS_CLIENT(this) ? CS(this) : this; // unfortunately, we need to store these on the client initially
  57
  58         if (!timeout_status)  // not while paused
  59         {
  60                 if (time <= (store.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  61                 {
  62                         store.cmd_floodcount += 1;
  63                         if (store.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
  64                 }
  65                 else
  66                 {
  67                         store.cmd_floodtime = time;
  68                         store.cmd_floodcount = 1;
  69                 }
  70         }
  71         return true;  // continue, as we're not flooding yet
  72 }
  73
  74
  75 // =======================
  76 //  Command Sub-Functions
  77 // =======================
  78
  79 void ClientCommand_autoswitch(entity caller, int request, int argc)
  80 {
  81         switch (request)
  82         {
  83                 case CMD_REQUEST_COMMAND:
  84                 {
  85                         if (argv(1) != "")
  86                         {
  87                                 CS(caller).autoswitch = InterpretBoolean(argv(1));
  88                                 sprint(caller, strcat("^1autoswitch is currently turned ", (CS(caller).autoswitch ? "on" : "off"), ".\n"));
  89                                 return;
  90                         }
  91                 }
  92
  93                 default:
  94                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
  95                 case CMD_REQUEST_USAGE:
  96                 {
  97                         sprint(caller, "\nUsage:^3 cmd autoswitch selection\n");
  98                         sprint(caller, "  Where 'selection' controls if autoswitch is on or off.\n");
  99                         return;
 100                 }
 101         }
 102 }
 103
 104 void ClientCommand_clientversion(entity caller, int request, int argc)  // internal command, used only by code
 105 {
 106         switch (request)
 107         {
 108                 case CMD_REQUEST_COMMAND:
 109                 {
 110                         if (argv(1) != "")
 111                         {
 112                                 if (IS_CLIENT(caller))
 113                                 {
 114                                         CS(caller).version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 115
 116                                         if (CS(caller).version < autocvar_gameversion_min || CS(caller).version > autocvar_gameversion_max)
 117                                         {
 118                                                 CS(caller).version_mismatch = true;
 119                                                 ClientKill_TeamChange(caller, -2);  // observe
 120                                         }
 121                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
 122                                         {
 123                                                 // JoinBestTeam(caller, false, true);
 124                                         }
 125                                         else if (teamplay && !autocvar_sv_spectate && !(Player_GetForcedTeamIndex(caller) > 0))
 126                                         {
 127                                                 TRANSMUTE(Observer, caller);  // really?
 128                                                 stuffcmd(caller, "menu_showteamselect\n");
 129                                         }
 130                                 }
 131
 132                                 return;
 133                         }
 134                 }
 135
 136                 default:
 137                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 138                 case CMD_REQUEST_USAGE:
 139                 {
 140                         sprint(caller, "\nUsage:^3 cmd clientversion version\n");
 141                         sprint(caller, "  Where 'version' is the game version reported by caller.\n");
 142                         return;
 143                 }
 144         }
 145 }
 146
 147 void ClientCommand_mv_getpicture(entity caller, int request, int argc)  // internal command, used only by code
 148 {
 149         switch (request)
 150         {
 151                 case CMD_REQUEST_COMMAND:
 152                 {
 153                         if (argv(1) != "")
 154                         {
 155                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 156
 157                                 return;
 158                         }
 159                 }
 160
 161                 default:
 162                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 163                 case CMD_REQUEST_USAGE:
 164                 {
 165                         sprint(caller, "\nUsage:^3 cmd mv_getpicture mapid\n");
 166                         sprint(caller, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 167                         return;
 168                 }
 169         }
 170 }
 171
 172 void ClientCommand_wpeditor(entity caller, int request, int argc)
 173 {
 174         switch (request)
 175         {
 176                 case CMD_REQUEST_COMMAND:
 177                 {
 178                         if (!autocvar_g_waypointeditor)
 179                         {
 180                                 sprint(caller, "ERROR: this command works only if the waypoint editor is on\n");
 181                                 return;
 182                         }
 183
 184                         if (argv(1) != "")
 185                         {
 186                                 if (argv(1) == "spawn")
 187                                 {
 188                                         string s = argv(2);
 189                                         if (!IS_PLAYER(caller))
 190                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 191                                         else
 192                                                 waypoint_spawn_fromeditor(caller, (s == "crosshair"), (s == "jump"), (s == "crouch"), (s == "support"));
 193                                         return;
 194                                 }
 195                                 else if (argv(1) == "remove")
 196                                 {
 197                                         if (!IS_PLAYER(caller))
 198                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 199                                         else
 200                                                 waypoint_remove_fromeditor(caller);
 201                                         return;
 202                                 }
 203                                 else if (argv(1) == "hardwire")
 204                                 {
 205                                         string s = argv(2);
 206                                         waypoint_start_hardwiredlink(caller, (s == "crosshair"));
 207                                         return;
 208                                 }
 209                                 else if (argv(1) == "lock")
 210                                 {
 211                                         waypoint_lock(caller);
 212                                         return;
 213                                 }
 214                                 else if (argv(1) == "unreachable")
 215                                 {
 216                                         if (!IS_PLAYER(caller))
 217                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 218                                         else
 219                                                 waypoint_unreachable(caller);
 220                                         return;
 221                                 }
 222                                 else if (argv(1) == "saveall")
 223                                 {
 224                                         waypoint_saveall();
 225                                         return;
 226                                 }
 227                                 else if (argv(1) == "relinkall")
 228                                 {
 229                                         waypoint_schedulerelinkall();
 230                                         return;
 231                                 }
 232                                 else if (argv(1) == "symaxis")
 233                                 {
 234                                         if (argv(2) == "set" || argv(2) == "get")
 235                                         {
 236                                                 waypoint_getSymmetricalAxis_cmd(caller, (argv(2) == "set"), 3);
 237                                                 return;
 238                                         }
 239                                 }
 240                                 else if (argv(1) == "symorigin")
 241                                 {
 242                                         if (argv(2) == "set" || argv(2) == "get")
 243                                         {
 244                                                 waypoint_getSymmetricalOrigin_cmd(caller, (argv(2) == "set"), 3);
 245                                                 return;
 246                                         }
 247                                 }
 248                         }
 249                 }
 250
 251                 default:
 252                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 253                 case CMD_REQUEST_USAGE:
 254                 {
 255                         sprint(caller, "\nUsage:^3 cmd wpeditor action\n");
 256                         sprint(caller, "  Where 'action' can be:\n");
 257                         sprint(caller, "   ^5spawn^7: spawns a waypoint at player's position\n");
 258                         sprint(caller, "   ^5remove^7: removes player's nearest waypoint\n");
 259                         sprint(caller, "   ^5unreachable^7: reveals waypoints and items unreachable from the current position and spawnpoints without a nearest waypoint\n");
 260                         sprint(caller, "   ^5saveall^7: saves all waypoints and links to file\n");
 261                         sprint(caller, "   ^5relinkall^7: relinks all waypoints as if they were respawned\n");
 262                         sprint(caller, "   ^5spawn crosshair^7: spawns a waypoint at crosshair's position\n");
 263                         sprint(caller, "   ^7 in general useful to create special and hardwired links with ease from existing waypoints\n");
 264                         sprint(caller, "   ^7 in particular it's the only way to create custom jumppad waypoints (spawn another waypoint to create destination))\n");
 265                         sprint(caller, "   ^5spawn jump^7: spawns a jump waypoint (place it at least 60 qu before jump start, spawn another waypoint to create destination)\n");
 266                         sprint(caller, "   ^5spawn crouch^7: spawns a crouch waypoint (it links only to very close waypoints)\n");
 267                         sprint(caller, "   ^5spawn support^7: spawns a support waypoint (spawn another waypoint to create destination from which all incoming links are removed)\n");
 268                         sprint(caller, "   ^7 useful to replace links to problematic jumppad/teleport waypoints\n");
 269                         sprint(caller, "   ^5hardwire^7: marks the nearest waypoint as origin of a new hardwired link (spawn another waypoint over an existing one to create destination)\n");
 270                         sprint(caller, "   ^5hardwire crosshair^7: marks the waypoint at crosshair instead of the nearest waypoint\n");
 271                         sprint(caller, "   ^5lock^7: locks link display of the aimed waypoint (unlocks if no waypoint is found at crosshair's position)\n");
 272                         sprint(caller, "   ^5symorigin get|set\n");
 273                         sprint(caller, "   ^5symorigin get|set p1 p2 ... pX\n");
 274                         sprint(caller, "   ^5symaxis get|set p1 p2\n");
 275                         sprint(caller, "   ^7 where p1 p2 ... pX are positions (\"x y z\", z can be omitted) that you know are perfectly symmetrical"
 276                                                                 " so you can determine origin/axis of symmetry of maps without ctf flags or where flags aren't perfectly symmetrical\n");
 277                         sprint(caller, "  See 'wpeditor_menu' for a selectable list of various commands and useful settings to edit waypoints.\n");
 278                         return;
 279                 }
 280         }
 281 }
 282
 283 void ClientCommand_join(entity caller, int request)
 284 {
 285         switch (request)
 286         {
 287                 case CMD_REQUEST_COMMAND:
 288                 {
 289                         if (!game_stopped && IS_CLIENT(caller) && !IS_PLAYER(caller))
 290                         {
 291                                 if (joinAllowed(caller))
 292                                         Join(caller);
 293                                 else if(time < CS(caller).jointime + MIN_SPEC_TIME)
 294                                         CS(caller).autojoin_checked = -1;
 295                         }
 296
 297                         return;  // never fall through to usage
 298                 }
 299
 300                 default:
 301                 case CMD_REQUEST_USAGE:
 302                 {
 303                         sprint(caller, "\nUsage:^3 cmd join\n");
 304                         sprint(caller, "  No arguments required.\n");
 305                         return;
 306                 }
 307         }
 308 }
 309
 310 void ClientCommand_kill(entity caller, int request)
 311 {
 312         switch (request)
 313         {
 314                 case CMD_REQUEST_COMMAND:
 315                 {
 316                         if(IS_SPEC(caller) || IS_OBSERVER(caller))
 317                                 return; // no point warning about this, command does nothing
 318
 319                         if(GetResource(caller, RES_HEALTH) <= 0)
 320                         {
 321                                 sprint(caller, "Can't die - you are already dead!\n");
 322                                 return;
 323                         }
 324
 325                         ClientKill(caller);
 326
 327                         return;  // never fall through to usage
 328                 }
 329
 330                 default:
 331                 case CMD_REQUEST_USAGE:
 332                 {
 333                         sprint(caller, "\nUsage:^3 cmd kill\n");
 334                         sprint(caller, "  No arguments required.\n");
 335                         return;
 336                 }
 337         }
 338 }
 339
 340 void ClientCommand_physics(entity caller, int request, int argc)
 341 {
 342         switch (request)
 343         {
 344                 case CMD_REQUEST_COMMAND:
 345                 {
 346                         string command = strtolower(argv(1));
 347
 348                         if (!autocvar_g_physics_clientselect)
 349                         {
 350                                 sprint(caller, "Client physics selection is currently disabled.\n");
 351                                 return;
 352                         }
 353
 354                         if (command == "list" || command == "help")
 355                         {
 356                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 357                                 return;
 358                         }
 359
 360                         if (Physics_Valid(command) || command == "default")
 361                         {
 362                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\n"));
 363                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 364                                 return;
 365                         }
 366                 }
 367
 368                 default:
 369                         sprint(caller, strcat("Current physics set: ^3", CS(caller).cvar_cl_physics, "\n"));
 370                 case CMD_REQUEST_USAGE:
 371                 {
 372                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 373                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 374                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 375                         return;
 376                 }
 377         }
 378 }
 379
 380 void ClientCommand_ready(entity caller, int request)  // todo: anti-spam for toggling readyness
 381 {
 382         switch (request)
 383         {
 384                 case CMD_REQUEST_COMMAND:
 385                 {
 386                         if (IS_CLIENT(caller))
 387                         {
 388                                 if (warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 389                                 {
 390                                         if (!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 391                                         {
 392                                                 if (time < game_starttime) // game is already restarting
 393                                                         return;
 394                                                 if (caller.ready)            // toggle
 395                                                 {
 396                                                         caller.ready = false;
 397                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 398                                                                 bprint(playername(caller, false), "^2 is ^1NOT^2 ready\n");
 399                                                 }
 400                                                 else
 401                                                 {
 402                                                         caller.ready = true;
 403                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 404                                                                 bprint(playername(caller, false), "^2 is ready\n");
 405                                                 }
 406
 407                                                 // cannot reset the game while a timeout is active!
 408                                                 if (!timeout_status) ReadyCount();
 409                                         }
 410                                         else
 411                                         {
 412                                                 sprint(caller, "^1Game has already been restarted\n");
 413                                         }
 414                                 }
 415                         }
 416                         return;  // never fall through to usage
 417                 }
 418
 419                 default:
 420                 case CMD_REQUEST_USAGE:
 421                 {
 422                         sprint(caller, "\nUsage:^3 cmd ready\n");
 423                         sprint(caller, "  No arguments required.\n");
 424                         return;
 425                 }
 426         }
 427 }
 428
 429 void ClientCommand_say(entity caller, int request, int argc, string command)
 430 {
 431         switch (request)
 432         {
 433                 case CMD_REQUEST_COMMAND:
 434                 {
 435                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 436                         return;  // never fall through to usage
 437                 }
 438
 439                 default:
 440                 case CMD_REQUEST_USAGE:
 441                 {
 442                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 443                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 444                         return;
 445                 }
 446         }
 447 }
 448
 449 void ClientCommand_say_team(entity caller, int request, int argc, string command)
 450 {
 451         switch (request)
 452         {
 453                 case CMD_REQUEST_COMMAND:
 454                 {
 455                         if (argc >= 2)
 456                                 Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 457                         return;  // never fall through to usage
 458                 }
 459
 460                 default:
 461                 case CMD_REQUEST_USAGE:
 462                 {
 463                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 464                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 465                         return;
 466                 }
 467         }
 468 }
 469
 470 .bool team_selected;
 471 void ClientCommand_selectteam(entity caller, int request, int argc)
 472 {
 473         switch (request)
 474         {
 475                 case CMD_REQUEST_COMMAND:
 476                 {
 477                         if (argv(1) == "")
 478                         {
 479                                 return;
 480                         }
 481                         if (!IS_CLIENT(caller))
 482                         {
 483                                 return;
 484                         }
 485                         if (!teamplay)
 486                         {
 487                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 488                                 return;
 489                         }
 490                         if (Player_GetForcedTeamIndex(caller) > 0)
 491                         {
 492                                 sprint(caller, "^7selectteam can not be used as your team is forced\n");
 493                                 return;
 494                         }
 495                         if (lockteams)
 496                         {
 497                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 498                                 return;
 499                         }
 500                         float selection;
 501                         switch (argv(1))
 502                         {
 503                                 case "red":
 504                                 {
 505                                         selection = NUM_TEAM_1;
 506                                         break;
 507                                 }
 508                                 case "blue":
 509                                 {
 510                                         selection = NUM_TEAM_2;
 511                                         break;
 512                                 }
 513                                 case "yellow":
 514                                 {
 515                                         selection = NUM_TEAM_3;
 516                                         break;
 517                                 }
 518                                 case "pink":
 519                                 {
 520                                         selection = NUM_TEAM_4;
 521                                         break;
 522                                 }
 523                                 case "auto":
 524                                 {
 525                                         selection = (-1);
 526                                         break;
 527                                 }
 528                                 default:
 529                                 {
 530                                         return;
 531                                 }
 532                         }
 533                         if (caller.team == selection && selection != -1 && !IS_DEAD(caller))
 534                         {
 535                                 sprint(caller, "^7You already are on that team.\n");
 536                                 return;
 537                         }
 538                         if (CS(caller).wasplayer && autocvar_g_changeteam_banned)
 539                         {
 540                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 541                                 return;
 542                         }
 543                         if ((selection != -1) && autocvar_g_balance_teams &&
 544                                 autocvar_g_balance_teams_prevent_imbalance)
 545                         {
 546                                 entity balance = TeamBalance_CheckAllowedTeams(caller);
 547                                 TeamBalance_GetTeamCounts(balance, caller);
 548                                 if ((Team_IndexToBit(Team_TeamToIndex(selection)) &
 549                                         TeamBalance_FindBestTeams(balance, caller, false)) == 0)
 550                                 {
 551                                         Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 552                                         TeamBalance_Destroy(balance);
 553                                         return;
 554                                 }
 555                                 TeamBalance_Destroy(balance);
 556                         }
 557                         ClientKill_TeamChange(caller, selection);
 558                         if (!IS_PLAYER(caller))
 559                         {
 560                                 caller.team_selected = true; // avoids asking again for team selection on join
 561                         }
 562                         return;
 563                 }
 564                 default:
 565                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 566                 case CMD_REQUEST_USAGE:
 567                 {
 568                         sprint(caller, "\nUsage:^3 cmd selectteam team\n");
 569                         sprint(caller, "  Where 'team' is the prefered team to try and join.\n");
 570                         sprint(caller, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 571                         return;
 572                 }
 573         }
 574 }
 575
 576 void ClientCommand_selfstuff(entity caller, int request, string command)
 577 {
 578         switch (request)
 579         {
 580                 case CMD_REQUEST_COMMAND:
 581                 {
 582                         if (argv(1) != "")
 583                         {
 584                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 585                                 return;
 586                         }
 587                 }
 588
 589                 default:
 590                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 591                 case CMD_REQUEST_USAGE:
 592                 {
 593                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 594                         sprint(caller, "  Where 'command' is the string to be stuffed to your client.\n");
 595                         return;
 596                 }
 597         }
 598 }
 599
 600 void ClientCommand_sentcvar(entity caller, int request, int argc, string command)
 601 {
 602         switch (request)
 603         {
 604                 case CMD_REQUEST_COMMAND:
 605                 {
 606                         if (argv(1) != "")
 607                         {
 608                                 // float tokens;
 609                                 string s;
 610
 611                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 612                                 {
 613                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 614                                         tokenize_console(s);
 615                                 }
 616
 617                                 GetCvars(caller, CS(caller), 1);
 618
 619                                 return;
 620                         }
 621                 }
 622
 623                 default:
 624                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 625                 case CMD_REQUEST_USAGE:
 626                 {
 627                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar>\n");
 628                         sprint(caller, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 629                         return;
 630                 }
 631         }
 632 }
 633
 634 void ClientCommand_spectate(entity caller, int request)
 635 {
 636         switch (request)
 637         {
 638                 case CMD_REQUEST_COMMAND:
 639                 {
 640                         if (!intermission_running && IS_CLIENT(caller))
 641                         {
 642                                 if(argv(1) != "")
 643                                 {
 644                                         if(IS_SPEC(caller) || IS_OBSERVER(caller))
 645                                         {
 646                                                 entity client = GetFilteredEntity(argv(1));
 647                                                 int spec_accepted = VerifyClientEntity(client, false, false);
 648                                                 if(spec_accepted > 0 && IS_PLAYER(client))
 649                                                 {
 650                                                         Spectate(caller, client);
 651                                                 }
 652                                                 else
 653                                                         sprint(caller, "can't spectate ", argv(1), "^7\n");
 654                                         }
 655                                         else
 656                                                 sprint(caller, "cmd spectate client only works when you are spectator/observer\n");
 657                                         return;
 658                                 }
 659
 660                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 661
 662                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 663
 664                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
 665                                 if (autocvar_sv_spectate == 1)
 666                                         ClientKill_TeamChange(caller, -2); // observe
 667                         }
 668                         return; // never fall through to usage
 669                 }
 670
 671                 default:
 672                 case CMD_REQUEST_USAGE:
 673                 {
 674                         sprint(caller, "\nUsage:^3 cmd spectate [client]\n");
 675                         sprint(caller, "  Where 'client' can be the player to spectate.\n");
 676                         return;
 677                 }
 678         }
 679 }
 680
 681 void ClientCommand_suggestmap(entity caller, int request, int argc)
 682 {
 683         switch (request)
 684         {
 685                 case CMD_REQUEST_COMMAND:
 686                 {
 687                         if (argv(1) != "")
 688                         {
 689                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 690                                 return;
 691                         }
 692                 }
 693
 694                 default:
 695                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 696                 case CMD_REQUEST_USAGE:
 697                 {
 698                         sprint(caller, "\nUsage:^3 cmd suggestmap map\n");
 699                         sprint(caller, "  Where 'map' is the name of the map to suggest.\n");
 700                         return;
 701                 }
 702         }
 703 }
 704
 705 void ClientCommand_tell(entity caller, int request, int argc, string command)
 706 {
 707         switch (request)
 708         {
 709                 case CMD_REQUEST_COMMAND:
 710                 {
 711                         if (argc >= 3)
 712                         {
 713                                 if(!IS_CLIENT(caller) && IS_REAL_CLIENT(caller)) // connecting
 714                                 {
 715                                         print_to(caller, "You can't ^2tell^7 a message while connecting.");
 716                                         return;
 717                                 }
 718
 719                                 entity tell_to = GetIndexedEntity(argc, 1);
 720                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 721
 722                                 if (tell_accepted > 0)   // the target is a real client
 723                                 {
 724                                         if (tell_to != caller) // and we're allowed to send to them :D
 725                                         {
 726                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 727                                                 // In this case when the player name contains utf8 chars
 728                                                 // the message gets partially trimmed in the beginning.
 729                                                 // Potentially this bug affects any substring call that uses
 730                                                 // argv_start_index and argv_end_index.
 731
 732                                                 string utf8_enable_save = cvar_string("utf8_enable");
 733                                                 cvar_set("utf8_enable", "0");
 734                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 735                                                 cvar_set("utf8_enable", utf8_enable_save);
 736
 737                                                 Say(caller, false, tell_to, msg, true);
 738                                                 return;
 739                                         }
 740                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 741                                 }
 742                                 else if (argv(1) == "#0")
 743                                 {
 744                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 745                                         return;
 746                                 }
 747                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 748                         }
 749                 }
 750
 751                 default:
 752                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 753                 case CMD_REQUEST_USAGE:
 754                 {
 755                         sprint(caller, "\nUsage:^3 cmd tell client <message>\n");
 756                         sprint(caller, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 757                         return;
 758                 }
 759         }
 760 }
 761
 762 void ClientCommand_voice(entity caller, int request, int argc, string command)
 763 {
 764         switch (request)
 765         {
 766                 case CMD_REQUEST_COMMAND:
 767                 {
 768                         if (argv(1) != "")
 769                         {
 770                                 entity e = GetVoiceMessage(argv(1));
 771                                 if (!e)
 772                                 {
 773                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 774                                         return;
 775                                 }
 776                                 if (IS_DEAD(caller))
 777                                 {
 778                                         // don't warn the caller when trying to taunt while dead, just don't play any sounds!
 779                                         // we still allow them to see warnings if it's invalid, so a dead player can find out the sounds in peace
 780                                         return;
 781                                 }
 782                                 if (IS_SPEC(caller) || IS_OBSERVER(caller))
 783                                 {
 784                                         // observers/spectators have no player model of their own to play taunts from
 785                                         // again, allow them to see warnings
 786                                         return;
 787                                 }
 788                                 string msg = "";
 789                                 if (argc >= 3)
 790                                         msg = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 791                                 VoiceMessage(caller, e, msg);
 792
 793                                 return;
 794                         }
 795                 }
 796
 797                 default:
 798                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 799                 case CMD_REQUEST_USAGE:
 800                 {
 801                         sprint(caller, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 802                         sprint(caller, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 803                         sprint(caller, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 804                         return;
 805                 }
 806         }
 807 }
 808
 809 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 810 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 811 void ClientCommand_(entity caller, int request)
 812 {
 813     switch(request)
 814     {
 815         case CMD_REQUEST_COMMAND:
 816         {
 817
 818             return; // never fall through to usage
 819         }
 820
 821         default:
 822         case CMD_REQUEST_USAGE:
 823         {
 824             sprint(caller, "\nUsage:^3 cmd \n");
 825             sprint(caller, "  No arguments required.\n");
 826             return;
 827         }
 828     }
 829 }
 830 */
 831
 832
 833 // =====================================
 834 //  Macro system for networked commands
 835 // =====================================
 836
 837 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 838 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 839         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 840         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 841         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 842         CLIENT_COMMAND("kill", ClientCommand_kill(ent, request), "Become a member of the dead") \
 843         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 844         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 845         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 846         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 847         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 848         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 849         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 850         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 851         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments, command), "New system for sending a client cvar to the server") \
 852         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 853         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 854         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 855         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 856         CLIENT_COMMAND("wpeditor", ClientCommand_wpeditor(ent, request, arguments), "Waypoint editor commands") \
 857         /* nothing */
 858
 859 void ClientCommand_macro_help(entity caller)
 860 {
 861         #define CLIENT_COMMAND(name, function, description) \
 862                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 863
 864         CLIENT_COMMANDS(NULL, 0, 0, "");
 865 #undef CLIENT_COMMAND
 866 }
 867
 868 float ClientCommand_macro_command(int argc, entity caller, string command)
 869 {
 870         #define CLIENT_COMMAND(name, function, description) \
 871                 { if (name == strtolower(argv(0))) { function; return true; } }
 872
 873         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 874 #undef CLIENT_COMMAND
 875
 876         return false;
 877 }
 878
 879 float ClientCommand_macro_usage(int argc, entity caller)
 880 {
 881         #define CLIENT_COMMAND(name, function, description) \
 882                 { if (name == strtolower(argv(1))) { function; return true; } }
 883
 884         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 885 #undef CLIENT_COMMAND
 886
 887         return false;
 888 }
 889
 890 void ClientCommand_macro_write_aliases(float fh)
 891 {
 892         #define CLIENT_COMMAND(name, function, description) \
 893                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 894
 895         CLIENT_COMMANDS(NULL, 0, 0, "");
 896 #undef CLIENT_COMMAND
 897 }
 898
 899 // ======================================
 900 //  Main Function Called By Engine (cmd)
 901 // ======================================
 902 // If this function exists, server game code parses clientcommand before the engine code gets it.
 903
 904 void SV_ParseClientCommand(entity this, string command)
 905 {
 906         // If invalid UTF-8, don't even parse it
 907         string command2 = "";
 908         float len = strlen(command);
 909         float i;
 910         for (i = 0; i < len; ++i)
 911                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 912         if (command != command2) return;
 913
 914         // if we're banned, don't even parse the command
 915         if (Ban_MaybeEnforceBanOnce(this)) return;
 916
 917         int argc = tokenize_console(command);
 918
 919         // Guide for working with argc arguments by example:
 920         // argc:   1    - 2      - 3     - 4
 921         // argv:   0    - 1      - 2     - 3
 922         // cmd     vote - master - login - password
 923
 924         // for floodcheck
 925         switch (strtolower(argv(0)))
 926         {
 927                 // exempt commands which are not subject to floodcheck
 928                 case "begin": break;                               // handled by engine in host_cmd.c
 929                 case "download": break;                            // handled by engine in cl_parse.c
 930                 case "mv_getpicture": break;                       // handled by server in this file
 931                 case "wpeditor": break;                            // handled by server in this file
 932                 case "pause": break;                               // handled by engine in host_cmd.c
 933                 case "prespawn": break;                            // handled by engine in host_cmd.c
 934                 case "sentcvar": break;                            // handled by server in this file
 935                 case "spawn": break;                               // handled by engine in host_cmd.c
 936                 case "color": case "topcolor": case "bottomcolor": if(teamplay) return; else break; // handled by engine in host_cmd.c
 937                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
 938
 939                 default:
 940                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
 941                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 942         }
 943
 944         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 945         if (argv(0) == "help")
 946         {
 947                 if (argc == 1)
 948                 {
 949                         sprint(this, "\nClient networked commands:\n");
 950                         ClientCommand_macro_help(this);
 951
 952                         sprint(this, "\nCommon networked commands:\n");
 953                         CommonCommand_macro_help(this);
 954
 955                         sprint(this, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 956                         sprint(this, "For help about a specific command, type cmd help COMMAND\n");
 957                         return;
 958                 }
 959                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
 960                 {
 961                         return;
 962                 }
 963                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
 964                 {
 965                         return;
 966                 }
 967         }
 968         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
 969         {
 970                 return;  // handled by a mutator
 971         }
 972         else if (CheatCommand(this, argc))
 973         {
 974                 return;  // handled by server/cheats.qc
 975         }
 976         else if (CommonCommand_macro_command(argc, this, command))
 977         {
 978                 return;                                          // handled by server/command/common.qc
 979         }
 980         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
 981         {
 982                 return;                                          // handled by one of the above ClientCommand_* functions
 983         }
 984         else
 985         {
 986                 clientcommand(this, command);
 987         }
 988 }