qcsrc/server/command/cmd.qc

   1 // =========================================================
   2 //  Server side networked commands code, reworked by Samual
   3 //  Last updated: December 28th, 2011
   4 // =========================================================
   5
   6 float SV_ParseClientCommand_floodcheck()
   7 {
   8         if (!timeout_status) // not while paused
   9         {
  10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  11                 {
  12                         self.cmd_floodcount += 1;
  13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
  14                 }
  15                 else
  16                 {
  17                         self.cmd_floodtime = time;
  18                         self.cmd_floodcount = 1;
  19                 }
  20         }
  21         return TRUE; // continue, as we're not flooding yet
  22 }
  23
  24
  25 // =======================
  26 //  Command Sub-Functions
  27 // =======================
  28
  29 void ClientCommand_autoswitch(float request, float argc)
  30 {
  31         switch(request)
  32         {
  33                 case CMD_REQUEST_COMMAND:
  34                 {
  35                         if(argv(1) != "")
  36                         {
  37                                 self.autoswitch = InterpretBoolean(argv(1));
  38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  39                                 return;
  40                         }
  41                 }
  42
  43                 default:
  44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  45                 case CMD_REQUEST_USAGE:
  46                 {
  47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  49                         return;
  50                 }
  51         }
  52 }
  53
  54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  55 {
  56         switch(request)
  57         {
  58                 case CMD_REQUEST_COMMAND:
  59                 {
  60                         printf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  61                         self.checkfail = 1;
  62                         return; // never fall through to usage
  63                 }
  64
  65                 default:
  66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
  67                 case CMD_REQUEST_USAGE:
  68                 {
  69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
  70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
  71                         return;
  72                 }
  73         }
  74 }
  75
  76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
  77 {
  78         switch(request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if(argv(1) != "")
  83                         {
  84                                 if(IS_CLIENT(self))
  85                                 {
  86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
  87
  88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
  89                                         {
  90                                                 self.version_mismatch = 1;
  91                                                 ClientKill_TeamChange(-2); // observe
  92                                         }
  93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
  94                                         {
  95                                                 //JoinBestTeam(self, FALSE, TRUE);
  96                                         }
  97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
  98                                         {
  99                                                 self.classname = "observer"; // really?
 100                                                 stuffcmd(self, "menu_showteamselect\n");
 101                                         }
 102                                 }
 103
 104                                 return;
 105                         }
 106                 }
 107
 108                 default:
 109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 110                 case CMD_REQUEST_USAGE:
 111                 {
 112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 114                         return;
 115                 }
 116         }
 117 }
 118
 119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 120 {
 121         switch(request)
 122         {
 123                 case CMD_REQUEST_COMMAND:
 124                 {
 125                         if(argv(1) != "")
 126                         {
 127                                 if(intermission_running)
 128                                         MapVote_SendPicture(stof(argv(1)));
 129
 130                                 return;
 131                         }
 132                 }
 133
 134                 default:
 135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 136                 case CMD_REQUEST_USAGE:
 137                 {
 138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 140                         return;
 141                 }
 142         }
 143 }
 144
 145 void ClientCommand_join(float request)
 146 {
 147         switch(request)
 148         {
 149                 case CMD_REQUEST_COMMAND:
 150                 {
 151                         if(IS_CLIENT(self))
 152                         {
 153                                 if(!IS_PLAYER(self) && !lockteams)
 154                                 {
 155                                         if(nJoinAllowed(self))
 156                                         {
 157                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 158
 159                                                 self.classname = "player";
 160                                                 PlayerScore_Clear(self);
 161                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
 162                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
 163                                                 PutClientInServer();
 164                                         }
 165                                         else
 166                                         {
 167                                                 //player may not join because of g_maxplayers is set
 168                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
 169                                         }
 170                                 }
 171                         }
 172                         return; // never fall through to usage
 173                 }
 174
 175                 default:
 176                 case CMD_REQUEST_USAGE:
 177                 {
 178                         sprint(self, "\nUsage:^3 cmd join\n");
 179                         sprint(self, "  No arguments required.\n");
 180                         return;
 181                 }
 182         }
 183 }
 184
 185 void ClientCommand_mobedit(float request, float argc)
 186 {
 187         switch(request)
 188         {
 189                 case CMD_REQUEST_COMMAND:
 190                 {
 191                         if(argv(1) && argv(2))
 192                         {
 193                                 makevectors(self.v_angle);
 194                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 195
 196                                 if(!autocvar_g_monsters_edit) { sprint(self, "Monster property editing is not enabled.\n"); }
 197                                 if(!(trace_ent.flags & FL_MONSTER)) { sprint(self, "You need to aim at your monster to edit its properties.\n"); }
 198                                 else if(trace_ent.realowner != self) { sprint(self, "That monster does not belong to you.\n"); }
 199                                 else // all went well, continue
 200                                 {
 201                                         switch(argv(1))
 202                                         {
 203                                                 case "skin":
 204                                                 {
 205                                                         if(trace_ent.monsterid != MON_MAGE)
 206                                                                 trace_ent.skin = stof(argv(2));
 207                                                         break;
 208                                                 }
 209                                                 case "movetarget":
 210                                                 {
 211                                                         trace_ent.monster_moveflags = stof(argv(2));
 212                                                         break;
 213                                                 }
 214                                         }
 215                                 }
 216
 217                                 return;
 218                         }
 219                 }
 220                 default:
 221                         sprint(self, "Incorrect parameters for ^2mobedit^7\n");
 222                 case CMD_REQUEST_USAGE:
 223                 {
 224                         sprint(self, "\nUsage:^3 cmd mobedit [argument]\n");
 225                         sprint(self, "  Where 'argument' can be skin or movetarget.\n");
 226                         return;
 227                 }
 228         }
 229 }
 230
 231 void ClientCommand_mobkill(float request)
 232 {
 233         switch(request)
 234         {
 235                 case CMD_REQUEST_COMMAND:
 236                 {
 237                         makevectors(self.v_angle);
 238                         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 239
 240                         if(trace_ent.flags & FL_MONSTER)
 241                         {
 242                                 if(trace_ent.realowner != self)
 243                                 {
 244                                         sprint(self, "That monster does not belong to you.\n");
 245                                         return;
 246                                 }
 247                                 sprint(self, strcat("Your pet '", trace_ent.monster_name, "' has been brutally mutilated.\n"));
 248                                 Damage (trace_ent, world, world, trace_ent.health + trace_ent.max_health + 200, DEATH_KILL, trace_ent.origin, '0 0 0');
 249                                 return;
 250                         }
 251                         else
 252                                 sprint(self, "You need to aim at your monster to kill it.\n");
 253
 254                         return;
 255                 }
 256
 257                 default:
 258                         sprint(self, "Incorrect parameters for ^2mobkill^7\n");
 259                 case CMD_REQUEST_USAGE:
 260                 {
 261                         sprint(self, "\nUsage:^3 cmd mobkill\n");
 262                         sprint(self, "  Aim at your monster to kill it.\n");
 263                         return;
 264                 }
 265         }
 266 }
 267
 268 void ClientCommand_mobspawn(float request, float argc)
 269 {
 270         switch(request)
 271         {
 272                 case CMD_REQUEST_COMMAND:
 273                 {
 274                         entity e;
 275                         string tospawn;
 276                         float moveflag;
 277
 278                         moveflag = (argv(2) ? stof(argv(2)) : 1); // follow owner if not defined
 279                         tospawn = strtolower(argv(1));
 280
 281                         if(tospawn == "list")
 282                         {
 283                                 sprint(self, monsterlist_reply);
 284                                 return;
 285                         }
 286
 287                         if(autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { sprint(self, "Monster spawning is disabled.\n"); }
 288                         else if(!IS_PLAYER(self)) { sprint(self, "You can't spawn monsters while spectating.\n"); }
 289                         else if(MUTATOR_CALLHOOK(AllowMobSpawning)) { sprint(self, "Monster spawning is currently disabled by a mutator.\n"); }
 290                         else if(!autocvar_g_monsters) { Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_MONSTERS_DISABLED); }
 291                         else if(self.vehicle) { sprint(self, "You can't spawn monsters while driving a vehicle.\n"); }
 292                         else if(autocvar_g_campaign) { sprint(self, "You can't spawn monsters in campaign mode.\n"); }
 293                         else if(self.deadflag != DEAD_NO) { sprint(self, "You can't spawn monsters while dead.\n"); }
 294                         else if(self.monstercount >= autocvar_g_monsters_max_perplayer) { sprint(self, "You have spawned too many monsters, kill some before trying to spawn any more.\n"); }
 295                         else if(totalspawned >= autocvar_g_monsters_max) { sprint(self, "The global maximum monster count has been reached, kill some before trying to spawn any more.\n"); }
 296                         else if(tospawn != "")
 297                         {
 298                                 float found = 0, i;
 299                                 entity mon;
 300
 301                                 for(i = MON_FIRST; i <= MON_LAST; ++i)
 302                                 {
 303                                         mon = get_monsterinfo(i);
 304                                         if(mon.netname == tospawn)
 305                                         {
 306                                                 found = TRUE;
 307                                                 break;
 308                                         }
 309                                 }
 310
 311                                 if(found)
 312                                 {
 313                                         self.monstercount += 1;
 314                                         totalspawned += 1;
 315
 316                                         makevectors(self.v_angle);
 317                                         WarpZone_TraceBox (CENTER_OR_VIEWOFS(self), PL_MIN, PL_MAX, CENTER_OR_VIEWOFS(self) + v_forward * 150, TRUE, self);
 318                                         //WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 150, MOVE_NORMAL, self);
 319
 320                                         e = spawnmonster(tospawn, 0, self, self, trace_endpos, FALSE, moveflag);
 321
 322                                         sprint(self, strcat("Spawned ", e.monster_name, "\n"));
 323
 324                                         return;
 325                                 }
 326                         }
 327                 }
 328
 329                 default:
 330                         sprint(self, "Incorrect parameters for ^2mobspawn^7\n");
 331                 case CMD_REQUEST_USAGE:
 332                 {
 333                         sprint(self, "\nUsage:^3 cmd mobspawn <random> <monster> [movetype]\n");
 334                         sprint(self, "  See 'cmd mobspawn list' for available monsters.\n");
 335                         sprint(self, "  Argument 'random' spawns a random monster.\n");
 336                         sprint(self, "  Monster will follow the owner if second argument is not defined.\n");
 337                         return;
 338                 }
 339         }
 340 }
 341
 342 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 343 {
 344         switch(request)
 345         {
 346                 case CMD_REQUEST_COMMAND:
 347                 {
 348                         if(IS_CLIENT(self))
 349                         {
 350                                 if(warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 351                                 {
 352                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 353                                         {
 354                                                 if(time < game_starttime) // game is already restarting
 355                                                         return;
 356                                                 if (self.ready) // toggle
 357                                                 {
 358                                                         self.ready = FALSE;
 359                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 360                                                 }
 361                                                 else
 362                                                 {
 363                                                         self.ready = TRUE;
 364                                                         bprint(self.netname, "^2 is ready\n");
 365                                                 }
 366
 367                                                 // cannot reset the game while a timeout is active!
 368                                                 if (!timeout_status)
 369                                                         ReadyCount();
 370                                         } else {
 371                                                 sprint(self, "^1Game has already been restarted\n");
 372                                         }
 373                                 }
 374                         }
 375                         return; // never fall through to usage
 376                 }
 377
 378                 default:
 379                 case CMD_REQUEST_USAGE:
 380                 {
 381                         sprint(self, "\nUsage:^3 cmd ready\n");
 382                         sprint(self, "  No arguments required.\n");
 383                         return;
 384                 }
 385         }
 386 }
 387
 388 void ClientCommand_say(float request, float argc, string command)
 389 {
 390         switch(request)
 391         {
 392                 case CMD_REQUEST_COMMAND:
 393                 {
 394                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 395                         return; // never fall through to usage
 396                 }
 397
 398                 default:
 399                 case CMD_REQUEST_USAGE:
 400                 {
 401                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 402                         sprint(self, "  Where 'message' is the string of text to say.\n");
 403                         return;
 404                 }
 405         }
 406 }
 407
 408 void ClientCommand_say_team(float request, float argc, string command)
 409 {
 410         switch(request)
 411         {
 412                 case CMD_REQUEST_COMMAND:
 413                 {
 414                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 415                         return; // never fall through to usage
 416                 }
 417
 418                 default:
 419                 case CMD_REQUEST_USAGE:
 420                 {
 421                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 422                         sprint(self, "  Where 'message' is the string of text to say.\n");
 423                         return;
 424                 }
 425         }
 426 }
 427
 428 void ClientCommand_selectteam(float request, float argc)
 429 {
 430         switch(request)
 431         {
 432                 case CMD_REQUEST_COMMAND:
 433                 {
 434                         if(argv(1) != "")
 435                         {
 436                                 if(IS_CLIENT(self))
 437                                 {
 438                                         if(teamplay)
 439                                                 if(self.team_forced <= 0)
 440                                                         if (!lockteams)
 441                                                         {
 442                                                                 float selection;
 443
 444                                                                 switch(argv(1))
 445                                                                 {
 446                                                                         case "red": selection = NUM_TEAM_1; break;
 447                                                                         case "blue": selection = NUM_TEAM_2; break;
 448                                                                         case "yellow": selection = NUM_TEAM_3; break;
 449                                                                         case "pink": selection = NUM_TEAM_4; break;
 450                                                                         case "auto": selection = (-1); break;
 451
 452                                                                         default: selection = 0; break;
 453                                                                 }
 454
 455                                                                 if(selection)
 456                                                                 {
 457                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 458                                                                                 sprint(self, "^7You already are on that team.\n");
 459                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 460                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 461                                                                         else
 462                                                                                 ClientKill_TeamChange(selection);
 463                                                                 }
 464                                                         }
 465                                                         else
 466                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 467                                                 else
 468                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 469                                         else
 470                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 471                                 }
 472                                 return;
 473                         }
 474                 }
 475
 476                 default:
 477                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 478                 case CMD_REQUEST_USAGE:
 479                 {
 480                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 481                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 482                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 483                         return;
 484                 }
 485         }
 486 }
 487
 488 void ClientCommand_selfstuff(float request, string command)
 489 {
 490         switch(request)
 491         {
 492                 case CMD_REQUEST_COMMAND:
 493                 {
 494                         if(argv(1) != "")
 495                         {
 496                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 497                                 return;
 498                         }
 499                 }
 500
 501                 default:
 502                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 503                 case CMD_REQUEST_USAGE:
 504                 {
 505                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 506                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 507                         return;
 508                 }
 509         }
 510 }
 511
 512 void ClientCommand_sentcvar(float request, float argc, string command)
 513 {
 514         switch(request)
 515         {
 516                 case CMD_REQUEST_COMMAND:
 517                 {
 518                         if(argv(1) != "")
 519                         {
 520                                 //float tokens;
 521                                 string s;
 522
 523                                 if(argc == 2) // undefined cvar: use the default value on the server then
 524                                 {
 525                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 526                                         tokenize_console(s);
 527                                 }
 528
 529                                 GetCvars(1);
 530
 531                                 return;
 532                         }
 533                 }
 534
 535                 default:
 536                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 537                 case CMD_REQUEST_USAGE:
 538                 {
 539                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 540                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 541                         return;
 542                 }
 543         }
 544 }
 545
 546 void ClientCommand_spectate(float request)
 547 {
 548         switch(request)
 549         {
 550                 case CMD_REQUEST_COMMAND:
 551                 {
 552                         if(IS_CLIENT(self))
 553                         {
 554                                 if(g_lms)
 555                                 {
 556                                         if(self.lms_spectate_warning)
 557                                         {
 558                                                 // for the forfeit message...
 559                                                 self.lms_spectate_warning = 2;
 560                                                 // mark player as spectator
 561                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 562                                         }
 563                                         else
 564                                         {
 565                                                 self.lms_spectate_warning = 1;
 566                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 567                                                 return;
 568                                         }
 569                                 }
 570
 571                                 if(IS_PLAYER(self) && autocvar_sv_spectate == 1)
 572                                         ClientKill_TeamChange(-2); // observe
 573
 574                                 // in CA, allow a dead player to move to spectators (without that, caplayer!=0 will be moved back to the player list)
 575                                 // note: if arena game mode is ever done properly, this needs to be removed.
 576                                 if(self.caplayer && (IS_SPEC(self) || IS_OBSERVER(self)))
 577                                 {
 578                                         sprint(self, "WARNING: you will spectate in the next round.\n");
 579                                         self.caplayer = 0;
 580                                 }
 581                         }
 582                         return; // never fall through to usage
 583                 }
 584
 585                 default:
 586                 case CMD_REQUEST_USAGE:
 587                 {
 588                         sprint(self, "\nUsage:^3 cmd spectate\n");
 589                         sprint(self, "  No arguments required.\n");
 590                         return;
 591                 }
 592         }
 593 }
 594
 595 void ClientCommand_suggestmap(float request, float argc)
 596 {
 597         switch(request)
 598         {
 599                 case CMD_REQUEST_COMMAND:
 600                 {
 601                         if(argv(1) != "")
 602                         {
 603                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 604                                 return;
 605                         }
 606                 }
 607
 608                 default:
 609                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 610                 case CMD_REQUEST_USAGE:
 611                 {
 612                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 613                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 614                         return;
 615                 }
 616         }
 617 }
 618
 619 void ClientCommand_tell(float request, float argc, string command)
 620 {
 621         switch(request)
 622         {
 623                 case CMD_REQUEST_COMMAND:
 624                 {
 625                         if(argc >= 3)
 626                         {
 627                                 entity tell_to = GetIndexedEntity(argc, 1);
 628                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
 629
 630                                 if(tell_accepted > 0) // the target is a real client
 631                                 {
 632                                         if(tell_to != self) // and we're allowed to send to them :D
 633                                         {
 634                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
 635                                                 return;
 636                                         }
 637                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 638                                 }
 639                                 else if(argv(1) == "#0")
 640                                 {
 641                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 642                                         return;
 643                                 }
 644                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 645                         }
 646                 }
 647
 648                 default:
 649                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 650                 case CMD_REQUEST_USAGE:
 651                 {
 652                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 653                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 654                         return;
 655                 }
 656         }
 657 }
 658
 659 void ClientCommand_voice(float request, float argc, string command)
 660 {
 661         switch(request)
 662         {
 663                 case CMD_REQUEST_COMMAND:
 664                 {
 665                         if(argv(1) != "")
 666                         {
 667                                 if(argc >= 3)
 668                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 669                                 else
 670                                         VoiceMessage(argv(1), "");
 671
 672                                 return;
 673                         }
 674                 }
 675
 676                 default:
 677                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 678                 case CMD_REQUEST_USAGE:
 679                 {
 680                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 681                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 682                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 683                         return;
 684                 }
 685         }
 686 }
 687
 688 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 689 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 690 void ClientCommand_(float request)
 691 {
 692         switch(request)
 693         {
 694                 case CMD_REQUEST_COMMAND:
 695                 {
 696
 697                         return; // never fall through to usage
 698                 }
 699
 700                 default:
 701                 case CMD_REQUEST_USAGE:
 702                 {
 703                         sprint(self, "\nUsage:^3 cmd \n");
 704                         sprint(self, "  No arguments required.\n");
 705                         return;
 706                 }
 707         }
 708 }
 709 */
 710
 711
 712 // =====================================
 713 //  Macro system for networked commands
 714 // =====================================
 715
 716 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 717 #define CLIENT_COMMANDS(request,arguments,command) \
 718         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 719         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 720         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 721         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 722         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 723         CLIENT_COMMAND("mobedit", ClientCommand_mobedit(request, arguments), "Edit your monster's properties") \
 724         CLIENT_COMMAND("mobkill", ClientCommand_mobkill(request), "Kills your monster") \
 725         CLIENT_COMMAND("mobspawn", ClientCommand_mobspawn(request, arguments), "Spawn monsters infront of yourself") \
 726         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 727         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 728         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 729         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 730         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 731         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 732         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 733         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 734         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 735         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 736         /* nothing */
 737
 738 void ClientCommand_macro_help()
 739 {
 740         #define CLIENT_COMMAND(name,function,description) \
 741                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 742
 743         CLIENT_COMMANDS(0, 0, "")
 744         #undef CLIENT_COMMAND
 745
 746         return;
 747 }
 748
 749 float ClientCommand_macro_command(float argc, string command)
 750 {
 751         #define CLIENT_COMMAND(name,function,description) \
 752                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 753
 754         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 755         #undef CLIENT_COMMAND
 756
 757         return FALSE;
 758 }
 759
 760 float ClientCommand_macro_usage(float argc)
 761 {
 762         #define CLIENT_COMMAND(name,function,description) \
 763                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 764
 765         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 766         #undef CLIENT_COMMAND
 767
 768         return FALSE;
 769 }
 770
 771 void ClientCommand_macro_write_aliases(float fh)
 772 {
 773         #define CLIENT_COMMAND(name,function,description) \
 774                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 775
 776         CLIENT_COMMANDS(0, 0, "")
 777         #undef CLIENT_COMMAND
 778
 779         return;
 780 }
 781
 782 // ======================================
 783 //  Main Function Called By Engine (cmd)
 784 // ======================================
 785 // If this function exists, server game code parses clientcommand before the engine code gets it.
 786
 787 void SV_ParseClientCommand(string command)
 788 {
 789         // if we're banned, don't even parse the command
 790         if(Ban_MaybeEnforceBanOnce(self))
 791                 return;
 792
 793         float argc = tokenize_console(command);
 794
 795         // for the mutator hook system
 796         cmd_name = strtolower(argv(0));
 797         cmd_argc = argc;
 798         cmd_string = command;
 799
 800         // Guide for working with argc arguments by example:
 801         // argc:   1    - 2      - 3     - 4
 802         // argv:   0    - 1      - 2     - 3
 803         // cmd     vote - master - login - password
 804
 805         // for floodcheck
 806         switch(strtolower(argv(0)))
 807         {
 808                 // exempt commands which are not subject to floodcheck
 809                 case "begin": break; // handled by engine in host_cmd.c
 810                 case "download": break; // handled by engine in cl_parse.c
 811                 case "mv_getpicture": break; // handled by server in this file
 812                 case "pause": break; // handled by engine in host_cmd.c
 813                 case "prespawn": break; // handled by engine in host_cmd.c
 814                 case "sentcvar": break; // handled by server in this file
 815                 case "spawn": break; // handled by engine in host_cmd.c
 816
 817                 default:
 818                         if(SV_ParseClientCommand_floodcheck())
 819                                 break; // "TRUE": continue, as we're not flooding yet
 820                         else
 821                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 822         }
 823
 824         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 825         if(argv(0) == "help")
 826         {
 827                 if(argc == 1)
 828                 {
 829                         sprint(self, "\nClient networked commands:\n");
 830                         ClientCommand_macro_help();
 831
 832                         sprint(self, "\nCommon networked commands:\n");
 833                         CommonCommand_macro_help(self);
 834
 835                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 836                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 837                         return;
 838                 }
 839                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 840                 {
 841                         return;
 842                 }
 843                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 844                 {
 845                         return;
 846                 }
 847         }
 848         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 849         {
 850                 return; // handled by a mutator
 851         }
 852         else if(CheatCommand(argc))
 853         {
 854                 return; // handled by server/cheats.qc
 855         }
 856         else if(CommonCommand_macro_command(argc, self, command))
 857         {
 858                 return; // handled by server/command/common.qc
 859         }
 860         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 861         {
 862                 return; // handled by one of the above ClientCommand_* functions
 863         }
 864         else
 865                 clientcommand(self, command);
 866 }