qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/overkill/oknex.qh>
  25 #include <common/mutators/mutator/waypoints/all.qh>
  26 #include <common/net_linked.qh>
  27 #include <common/net_notice.qh>
  28 #include <common/notifications/all.qh>
  29 #include <common/physics/player.qh>
  30 #include <common/playerstats.qh>
  31 #include <common/state.qh>
  32 #include <common/stats.qh>
  33 #include <common/vehicles/all.qh>
  34 #include <common/vehicles/sv_vehicles.qh>
  35 #include <common/viewloc.qh>
  36 #include <common/weapons/_all.qh>
  37 #include <common/weapons/weapon/vortex.qh>
  38 #include <common/wepent.qh>
  39 #include <lib/csqcmodel/sv_model.qh>
  40 #include <lib/warpzone/common.qh>
  41 #include <lib/warpzone/server.qh>
  42 #include <server/anticheat.qh>
  43 #include <server/antilag.qh>
  44 #include <server/bot/api.qh>
  45 #include <server/campaign.qh>
  46 #include <server/chat.qh>
  47 #include <server/cheats.qh>
  48 #include <server/clientkill.qh>
  49 #include <server/command/common.qh>
  50 #include <server/command/common.qh>
  51 #include <server/command/vote.qh>
  52 #include <server/compat/quake3.qh>
  53 #include <server/damage.qh>
  54 #include <server/gamelog.qh>
  55 #include <server/handicap.qh>
  56 #include <server/hook.qh>
  57 #include <server/impulse.qh>
  58 #include <server/intermission.qh>
  59 #include <server/ipban.qh>
  60 #include <server/main.qh>
  61 #include <server/mutators/_mod.qh>
  62 #include <server/player.qh>
  63 #include <server/portals.qh>
  64 #include <server/race.qh>
  65 #include <server/resources.qh>
  66 #include <server/scores.qh>
  67 #include <server/scores_rules.qh>
  68 #include <server/spawnpoints.qh>
  69 #include <server/teamplay.qh>
  70 #include <server/weapons/accuracy.qh>
  71 #include <server/weapons/common.qh>
  72 #include <server/weapons/hitplot.qh>
  73 #include <server/weapons/selection.qh>
  74 #include <server/weapons/weaponsystem.qh>
  75 #include <server/world.qh>
  76
  77 STATIC_METHOD(Client, Add, void(Client this, int _team))
  78 {
  79     ClientConnect(this);
  80     TRANSMUTE(Player, this);
  81     this.frame = 12; // 7
  82     this.team = _team;
  83     PutClientInServer(this);
  84 }
  85
  86 STATIC_METHOD(Client, Remove, void(Client this))
  87 {
  88     TRANSMUTE(Observer, this);
  89     PutClientInServer(this);
  90     ClientDisconnect(this);
  91 }
  92
  93 void send_CSQC_teamnagger() {
  94         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  95 }
  96
  97 void send_TeamNames(int channel, entity to) {
  98         msg_entity = to;
  99
 100         WriteHeader(channel, TE_CSQC_TEAMNAMES);
 101         WriteString(channel, autocvar_g_teamnames_red);
 102         WriteString(channel, autocvar_g_teamnames_blue);
 103         WriteString(channel, autocvar_g_teamnames_yellow);
 104         WriteString(channel, autocvar_g_teamnames_pink);
 105 }
 106
 107 int CountSpectators(entity player, entity to)
 108 {
 109         if(!player) { return 0; } // not sure how, but best to be safe
 110
 111         int spec_count = 0;
 112
 113         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 114         {
 115                 spec_count++;
 116         });
 117
 118         return spec_count;
 119 }
 120
 121 void WriteSpectators(entity player, entity to)
 122 {
 123         if(!player) { return; } // not sure how, but best to be safe
 124
 125         int spec_count = 0;
 126         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 127         {
 128                 if(spec_count >= MAX_SPECTATORS)
 129                         break;
 130                 WriteByte(MSG_ENTITY, num_for_edict(it));
 131                 ++spec_count;
 132         });
 133 }
 134
 135 bool ClientData_Send(entity this, entity to, int sf)
 136 {
 137         assert(to == this.owner, return false);
 138
 139         entity e = to;
 140         if (IS_SPEC(e)) e = e.enemy;
 141
 142         sf = 0;
 143         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 144         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 145         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 146         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 147
 148         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 149         WriteByte(MSG_ENTITY, sf);
 150
 151         if (sf & BIT(1))
 152                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 153
 154         if(sf & BIT(4))
 155         {
 156                 float specs = CountSpectators(e, to);
 157                 WriteByte(MSG_ENTITY, specs);
 158                 WriteSpectators(e, to);
 159         }
 160
 161         return true;
 162 }
 163
 164 void ClientData_Attach(entity this)
 165 {
 166         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 167         CS(this).clientdata.drawonlytoclient = this;
 168         CS(this).clientdata.owner = this;
 169 }
 170
 171 void ClientData_Detach(entity this)
 172 {
 173         delete(CS(this).clientdata);
 174         CS(this).clientdata = NULL;
 175 }
 176
 177 void ClientData_Touch(entity e)
 178 {
 179         entity cd = CS(e).clientdata;
 180         if (cd) { cd.SendFlags = 1; }
 181
 182         // make it spectatable
 183         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 184         {
 185                 entity cd = CS(it).clientdata;
 186                 if (cd) { cd.SendFlags = 1; }
 187         });
 188 }
 189
 190
 191 /*
 192 =============
 193 CheckPlayerModel
 194
 195 Checks if the argument string can be a valid playermodel.
 196 Returns a valid one in doubt.
 197 =============
 198 */
 199 string FallbackPlayerModel;
 200 string CheckPlayerModel(string plyermodel) {
 201         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 202         {
 203                 // note: we cannot summon Don Strunzone here, some player may
 204                 // still have the model string set. In case anyone manages how
 205                 // to change a cvar default, we'll have a small leak here.
 206                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 207         }
 208         // only in right path
 209         if( substring(plyermodel,0,14) != "models/player/")
 210                 return FallbackPlayerModel;
 211         // only good file extensions
 212         if(substring(plyermodel,-4,4) != ".zym")
 213         if(substring(plyermodel,-4,4) != ".dpm")
 214         if(substring(plyermodel,-4,4) != ".iqm")
 215         if(substring(plyermodel,-4,4) != ".md3")
 216         if(substring(plyermodel,-4,4) != ".psk")
 217                 return FallbackPlayerModel;
 218         // forbid the LOD models
 219         if(substring(plyermodel, -9,5) == "_lod1")
 220                 return FallbackPlayerModel;
 221         if(substring(plyermodel, -9,5) == "_lod2")
 222                 return FallbackPlayerModel;
 223         if(plyermodel != strtolower(plyermodel))
 224                 return FallbackPlayerModel;
 225         // also, restrict to server models
 226         if(autocvar_sv_servermodelsonly)
 227         {
 228                 if(!fexists(plyermodel))
 229                         return FallbackPlayerModel;
 230         }
 231         return plyermodel;
 232 }
 233
 234 void setplayermodel(entity e, string modelname)
 235 {
 236         precache_model(modelname);
 237         _setmodel(e, modelname);
 238         player_setupanimsformodel(e);
 239         if(!autocvar_g_debug_globalsounds)
 240                 UpdatePlayerSounds(e);
 241 }
 242
 243 /** putting a client as observer in the server */
 244 void PutObserverInServer(entity this)
 245 {
 246         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 247         PlayerState_detach(this);
 248
 249         if (IS_PLAYER(this))
 250         {
 251                 if(GetResource(this, RES_HEALTH) >= 1)
 252                 {
 253                         // despawn effect
 254                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 255                 }
 256
 257                 // was a player, recount votes and ready status
 258                 if(IS_REAL_CLIENT(this))
 259                 {
 260                         if (vote_called) { VoteCount(false); }
 261                         ReadyCount();
 262                 }
 263         }
 264
 265         entity spot = SelectSpawnPoint(this, true);
 266         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 267         this.angles = vec2(spot.angles);
 268         this.fixangle = true;
 269         // offset it so that the spectator spawns higher off the ground, looks better this way
 270         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 271         if (IS_REAL_CLIENT(this))
 272         {
 273                 msg_entity = this;
 274                 WriteByte(MSG_ONE, SVC_SETVIEW);
 275                 WriteEntity(MSG_ONE, this);
 276         }
 277         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 278         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 279         if(!autocvar_g_debug_globalsounds)
 280         {
 281                 // needed for player sounds
 282                 this.model = "";
 283                 FixPlayermodel(this);
 284         }
 285         setmodel(this, MDL_Null);
 286         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 287         this.view_ofs = '0 0 0';
 288
 289         RemoveGrapplingHooks(this);
 290         Portal_ClearAll(this);
 291         Unfreeze(this, false);
 292         SetSpectatee(this, NULL);
 293
 294         if (this.alivetime)
 295         {
 296                 if (!warmup_stage)
 297                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 298                 this.alivetime = 0;
 299         }
 300
 301         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 302
 303         WaypointSprite_PlayerDead(this);
 304
 305         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 306                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 307
 308         accuracy_resend(this);
 309
 310         CS(this).spectatortime = time;
 311         if(this.bot_attack)
 312                 IL_REMOVE(g_bot_targets, this);
 313         this.bot_attack = false;
 314         if(this.monster_attack)
 315                 IL_REMOVE(g_monster_targets, this);
 316         this.monster_attack = false;
 317         STAT(HUD, this) = HUD_NORMAL;
 318         TRANSMUTE(Observer, this);
 319         this.iscreature = false;
 320         this.teleportable = TELEPORT_SIMPLE;
 321         if(this.damagedbycontents)
 322                 IL_REMOVE(g_damagedbycontents, this);
 323         this.damagedbycontents = false;
 324         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 325         SetSpectatee_status(this, etof(this));
 326         this.takedamage = DAMAGE_NO;
 327         this.solid = SOLID_NOT;
 328         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 329         this.flags = FL_CLIENT | FL_NOTARGET;
 330         this.effects = 0;
 331         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 332         this.pauserotarmor_finished = 0;
 333         this.pauserothealth_finished = 0;
 334         this.pauseregen_finished = 0;
 335         this.damageforcescale = 0;
 336         this.death_time = 0;
 337         this.respawn_flags = 0;
 338         this.respawn_time = 0;
 339         STAT(RESPAWN_TIME, this) = 0;
 340         this.alpha = 0;
 341         this.scale = 0;
 342         this.fade_time = 0;
 343         this.pain_finished = 0;
 344         STAT(STRENGTH_FINISHED, this) = 0;
 345         STAT(INVINCIBLE_FINISHED, this) = 0;
 346         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 347         STAT(AIR_FINISHED, this) = 0;
 348         //this.dphitcontentsmask = 0;
 349         this.dphitcontentsmask = DPCONTENTS_SOLID;
 350         if (autocvar_g_playerclip_collisions)
 351                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 352         this.pushltime = 0;
 353         this.istypefrag = 0;
 354         setthink(this, func_null);
 355         this.nextthink = 0;
 356         this.deadflag = DEAD_NO;
 357         UNSET_DUCKED(this);
 358         STAT(REVIVE_PROGRESS, this) = 0;
 359         this.revival_time = 0;
 360         this.draggable = drag_undraggable;
 361
 362         this.items = 0;
 363         STAT(WEAPONS, this) = '0 0 0';
 364         this.drawonlytoclient = this;
 365
 366         this.viewloc = NULL;
 367
 368         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 369
 370         this.weaponmodel = "";
 371         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 372         {
 373                 this.weaponentities[slot] = NULL;
 374         }
 375         this.exteriorweaponentity = NULL;
 376         CS(this).killcount = FRAGS_SPECTATOR;
 377         this.velocity = '0 0 0';
 378         this.avelocity = '0 0 0';
 379         this.punchangle = '0 0 0';
 380         this.punchvector = '0 0 0';
 381         this.oldvelocity = this.velocity;
 382         this.fire_endtime = -1;
 383         this.event_damage = func_null;
 384         this.event_heal = func_null;
 385
 386         for(int slot = 0; slot < MAX_AXH; ++slot)
 387         {
 388                 entity axh = this.(AuxiliaryXhair[slot]);
 389                 this.(AuxiliaryXhair[slot]) = NULL;
 390
 391                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 392                         delete(axh);
 393         }
 394
 395         if (mutator_returnvalue)
 396         {
 397                 // mutator prevents resetting teams+score
 398         }
 399         else
 400         {
 401                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 402                 this.frags = FRAGS_SPECTATOR;
 403         }
 404         if (CS(this).just_joined)
 405                 CS(this).just_joined = false;
 406 }
 407
 408 int player_getspecies(entity this)
 409 {
 410         get_model_parameters(this.model, this.skin);
 411         int s = get_model_parameters_species;
 412         get_model_parameters(string_null, 0);
 413         if (s < 0) return SPECIES_HUMAN;
 414         return s;
 415 }
 416
 417 .float model_randomizer;
 418 void FixPlayermodel(entity player)
 419 {
 420         string defaultmodel = "";
 421         int defaultskin = 0;
 422         if(autocvar_sv_defaultcharacter)
 423         {
 424                 if(teamplay)
 425                 {
 426                         switch(player.team)
 427                         {
 428                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 429                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 430                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 431                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 432                         }
 433                 }
 434
 435                 if(defaultmodel == "")
 436                 {
 437                         defaultmodel = autocvar_sv_defaultplayermodel;
 438                         defaultskin = autocvar_sv_defaultplayerskin;
 439                 }
 440
 441                 int n = tokenize_console(defaultmodel);
 442                 if(n > 0)
 443                 {
 444                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 445                         // However, do NOT randomize if the player-selected model is in the list.
 446                         for (int i = 0; i < n; ++i)
 447                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 448                                         defaultmodel = argv(i);
 449                 }
 450
 451                 int i = strstrofs(defaultmodel, ":", 0);
 452                 if(i >= 0)
 453                 {
 454                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 455                         defaultmodel = substring(defaultmodel, 0, i);
 456                 }
 457         }
 458         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 459         {
 460                 if(teamplay)
 461                 {
 462                         switch(player.team)
 463                         {
 464                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 465                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 466                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 467                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 468                         }
 469                 }
 470
 471                 if(!defaultskin)
 472                         defaultskin = autocvar_sv_defaultplayerskin;
 473         }
 474
 475         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 476         defaultmodel = M_ARGV(0, string);
 477         defaultskin = M_ARGV(1, int);
 478
 479         bool chmdl = false;
 480         int oldskin;
 481         if(defaultmodel != "")
 482         {
 483                 if (defaultmodel != player.model)
 484                 {
 485                         vector m1 = player.mins;
 486                         vector m2 = player.maxs;
 487                         setplayermodel (player, defaultmodel);
 488                         setsize (player, m1, m2);
 489                         chmdl = true;
 490                 }
 491
 492                 oldskin = player.skin;
 493                 player.skin = defaultskin;
 494         } else {
 495                 if (player.playermodel != player.model || player.playermodel == "")
 496                 {
 497                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 498                         vector m1 = player.mins;
 499                         vector m2 = player.maxs;
 500                         setplayermodel (player, player.playermodel);
 501                         setsize (player, m1, m2);
 502                         chmdl = true;
 503                 }
 504
 505                 if(!autocvar_sv_defaultcharacterskin)
 506                 {
 507                         oldskin = player.skin;
 508                         player.skin = stof(player.playerskin);
 509                 }
 510                 else
 511                 {
 512                         oldskin = player.skin;
 513                         player.skin = defaultskin;
 514                 }
 515         }
 516
 517         if(chmdl || oldskin != player.skin) // model or skin has changed
 518         {
 519                 player.species = player_getspecies(player); // update species
 520                 if(!autocvar_g_debug_globalsounds)
 521                         UpdatePlayerSounds(player); // update skin sounds
 522         }
 523
 524         if(!teamplay)
 525                 if(strlen(autocvar_sv_defaultplayercolors))
 526                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 527                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 528 }
 529
 530 void ResetPlayerResources(entity this)
 531 {
 532         if (warmup_stage) {
 533                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 534                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 535                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 536                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 537                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 538                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 539                 SetResource(this, RES_HEALTH, warmup_start_health);
 540                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 541                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 542         } else {
 543                 SetResource(this, RES_SHELLS, start_ammo_shells);
 544                 SetResource(this, RES_BULLETS, start_ammo_nails);
 545                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 546                 SetResource(this, RES_CELLS, start_ammo_cells);
 547                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 548                 SetResource(this, RES_FUEL, start_ammo_fuel);
 549                 SetResource(this, RES_HEALTH, start_health);
 550                 SetResource(this, RES_ARMOR, start_armorvalue);
 551                 STAT(WEAPONS, this) = start_weapons;
 552                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 553                 {
 554                         GiveRandomWeapons(this, random_start_weapons_count,
 555                                 autocvar_g_random_start_weapons, random_start_ammo);
 556                 }
 557         }
 558 }
 559
 560 void PutPlayerInServer(entity this)
 561 {
 562         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 563
 564         PlayerState_attach(this);
 565         accuracy_resend(this);
 566
 567         if (this.team < 0)
 568                 TeamBalance_JoinBestTeam(this);
 569
 570         entity spot = SelectSpawnPoint(this, false);
 571         if (!spot) {
 572                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 573                 return; // spawn failed
 574         }
 575
 576         TRANSMUTE(Player, this);
 577
 578         CS(this).wasplayer = true;
 579         this.iscreature = true;
 580         this.teleportable = TELEPORT_NORMAL;
 581         if(!this.damagedbycontents)
 582                 IL_PUSH(g_damagedbycontents, this);
 583         this.damagedbycontents = true;
 584         set_movetype(this, MOVETYPE_WALK);
 585         this.solid = SOLID_SLIDEBOX;
 586         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 587         if (autocvar_g_playerclip_collisions)
 588                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 589         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 590                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 591         this.frags = FRAGS_PLAYER;
 592         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 593         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 594         if (autocvar__notarget)
 595                 this.flags |= FL_NOTARGET;
 596         this.takedamage = DAMAGE_AIM;
 597         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 598
 599         ResetPlayerResources(this);
 600
 601         SetSpectatee_status(this, 0);
 602
 603         PS(this).dual_weapons = '0 0 0';
 604
 605         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 606
 607         this.items = start_items;
 608
 609         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 610         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 611         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 612         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 613         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 614         if (!sv_ready_restart_after_countdown && time < game_starttime)
 615         {
 616                 float f = game_starttime - time;
 617                 this.spawnshieldtime += f;
 618                 this.pauserotarmor_finished += f;
 619                 this.pauserothealth_finished += f;
 620                 this.pauseregen_finished += f;
 621         }
 622
 623         this.damageforcescale = autocvar_g_player_damageforcescale;
 624         this.death_time = 0;
 625         this.respawn_flags = 0;
 626         this.respawn_time = 0;
 627         STAT(RESPAWN_TIME, this) = 0;
 628         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 629         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 630         this.fade_time = 0;
 631         this.pain_finished = 0;
 632         this.pushltime = 0;
 633         setthink(this, func_null); // players have no think function
 634         this.nextthink = 0;
 635         this.dmg_team = 0;
 636         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 637
 638         this.deadflag = DEAD_NO;
 639
 640         this.angles = spot.angles;
 641         this.angles_z = 0; // never spawn tilted even if the spot says to
 642         if (IS_BOT_CLIENT(this))
 643         {
 644                 this.v_angle = this.angles;
 645                 bot_aim_reset(this);
 646         }
 647         this.fixangle = true; // turn this way immediately
 648         this.oldvelocity = this.velocity = '0 0 0';
 649         this.avelocity = '0 0 0';
 650         this.punchangle = '0 0 0';
 651         this.punchvector = '0 0 0';
 652
 653         STAT(STRENGTH_FINISHED, this) = 0;
 654         STAT(INVINCIBLE_FINISHED, this) = 0;
 655         this.fire_endtime = -1;
 656         STAT(REVIVE_PROGRESS, this) = 0;
 657         this.revival_time = 0;
 658
 659         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 660         STAT(BUFFS, this) = 0;
 661         STAT(BUFF_TIME, this) = 0;
 662
 663         STAT(AIR_FINISHED, this) = 0;
 664         this.waterlevel = WATERLEVEL_NONE;
 665         this.watertype = CONTENT_EMPTY;
 666
 667         entity spawnevent = new_pure(spawnevent);
 668         spawnevent.owner = this;
 669         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 670
 671         // Cut off any still running player sounds.
 672         stopsound(this, CH_PLAYER_SINGLE);
 673
 674         this.model = "";
 675         FixPlayermodel(this);
 676         this.drawonlytoclient = NULL;
 677
 678         this.viewloc = NULL;
 679
 680         for(int slot = 0; slot < MAX_AXH; ++slot)
 681         {
 682                 entity axh = this.(AuxiliaryXhair[slot]);
 683                 this.(AuxiliaryXhair[slot]) = NULL;
 684
 685                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 686                         delete(axh);
 687         }
 688
 689         this.spawnpoint_targ = NULL;
 690
 691         UNSET_DUCKED(this);
 692         this.view_ofs = STAT(PL_VIEW_OFS, this);
 693         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 694         this.spawnorigin = spot.origin;
 695         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 696         // don't reset back to last position, even if new position is stuck in solid
 697         this.oldorigin = this.origin;
 698         if(this.conveyor)
 699                 IL_REMOVE(g_conveyed, this);
 700         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 701         if(this.swampslug)
 702                 IL_REMOVE(g_swamped, this);
 703         this.swampslug = NULL;
 704         this.swamp_interval = 0;
 705         if(this.ladder_entity)
 706                 IL_REMOVE(g_ladderents, this);
 707         this.ladder_entity = NULL;
 708         IL_EACH(g_counters, it.realowner == this,
 709         {
 710                 delete(it);
 711         });
 712         STAT(HUD, this) = HUD_NORMAL;
 713
 714         this.event_damage = PlayerDamage;
 715         this.event_heal = PlayerHeal;
 716
 717         this.draggable = func_null;
 718
 719         if(!this.bot_attack)
 720                 IL_PUSH(g_bot_targets, this);
 721         this.bot_attack = true;
 722         if(!this.monster_attack)
 723                 IL_PUSH(g_monster_targets, this);
 724         this.monster_attack = true;
 725         navigation_dynamicgoal_init(this, false);
 726
 727         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 728
 729         // player was spectator
 730         if (CS(this).killcount == FRAGS_SPECTATOR) {
 731                 PlayerScore_Clear(this);
 732                 CS(this).killcount = 0;
 733                 CS(this).startplaytime = time;
 734         }
 735
 736         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 737         {
 738                 .entity weaponentity = weaponentities[slot];
 739                 CL_SpawnWeaponentity(this, weaponentity);
 740         }
 741         this.alpha = default_player_alpha;
 742         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 743         this.exteriorweaponentity.alpha = default_weapon_alpha;
 744
 745         this.speedrunning = false;
 746
 747         this.counter_cnt = 0;
 748         this.fragsfilter_cnt = 0;
 749
 750         target_voicescript_clear(this);
 751
 752         // reset fields the weapons may use
 753         FOREACH(Weapons, true, {
 754                 it.wr_resetplayer(it, this);
 755                         // reload all reloadable weapons
 756                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 757                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 758                         {
 759                                 .entity weaponentity = weaponentities[slot];
 760                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 761                         }
 762                 }
 763         });
 764
 765         {
 766                 string s = spot.target;
 767                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 768                         spot.target = string_null;
 769                 SUB_UseTargets(spot, this, NULL);
 770                 if(g_assault || g_race)
 771                         spot.target = s;
 772         }
 773
 774         Unfreeze(this, false);
 775
 776         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 777
 778         if (autocvar_spawn_debug)
 779         {
 780                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 781                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 782         }
 783
 784         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 785         {
 786                 .entity weaponentity = weaponentities[slot];
 787                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 788                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 789                 else
 790                         this.(weaponentity).m_switchweapon = WEP_Null;
 791                 this.(weaponentity).m_weapon = WEP_Null;
 792                 this.(weaponentity).weaponname = "";
 793                 this.(weaponentity).m_switchingweapon = WEP_Null;
 794                 this.(weaponentity).cnt = -1;
 795         }
 796
 797         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 798
 799         if (CS(this).impulse) ImpulseCommands(this);
 800
 801         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
 802         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 803         {
 804                 .entity weaponentity = weaponentities[slot];
 805                 W_WeaponFrame(this, weaponentity);
 806         }
 807
 808         if (!warmup_stage && !this.alivetime)
 809                 this.alivetime = time;
 810
 811         antilag_clear(this, CS(this));
 812 }
 813
 814 /** Called when a client spawns in the server */
 815 void PutClientInServer(entity this)
 816 {
 817         if (IS_BOT_CLIENT(this)) {
 818                 TRANSMUTE(Player, this);
 819         } else if (IS_REAL_CLIENT(this)) {
 820                 msg_entity = this;
 821                 WriteByte(MSG_ONE, SVC_SETVIEW);
 822                 WriteEntity(MSG_ONE, this);
 823         }
 824         if (game_stopped)
 825                 TRANSMUTE(Observer, this);
 826
 827         SetSpectatee(this, NULL);
 828
 829         // reset player keys
 830         if(PS(this))
 831                 PS(this).itemkeys = 0;
 832
 833         MUTATOR_CALLHOOK(PutClientInServer, this);
 834
 835         if (IS_OBSERVER(this)) {
 836                 PutObserverInServer(this);
 837         } else if (IS_PLAYER(this)) {
 838                 PutPlayerInServer(this);
 839         }
 840
 841         // send team names
 842         if(teamplay && IS_REAL_CLIENT(this))
 843                 send_TeamNames(MSG_ONE, this);
 844 }
 845
 846 // TODO do we need all these fields, or should we stop autodetecting runtime
 847 // changes and just have a console command to update this?
 848 bool ClientInit_SendEntity(entity this, entity to, int sf)
 849 {
 850         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 851         return = true;
 852         msg_entity = to;
 853         // MSG_INIT replacement
 854         // TODO: make easier to use
 855         Registry_send_all();
 856         W_PROP_reload(MSG_ONE, to);
 857         ClientInit_misc(this);
 858         MUTATOR_CALLHOOK(Ent_Init);
 859 }
 860 void ClientInit_misc(entity this)
 861 {
 862         int channel = MSG_ONE;
 863         WriteHeader(channel, ENT_CLIENT_INIT);
 864         WriteByte(channel, g_nexball_meter_period * 32);
 865         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 866         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 867         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 868         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 869         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 870         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 871         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 872         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 873
 874         if(autocvar_sv_foginterval && world.fog != "")
 875                 WriteString(channel, world.fog);
 876         else
 877                 WriteString(channel, "");
 878         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 879         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 880         WriteByte(channel, serverflags);
 881         WriteCoord(channel, autocvar_g_trueaim_minrange);
 882
 883         // z411 send full hostname
 884         WriteString(channel, (autocvar_hostname_full ? autocvar_hostname_full : autocvar_hostname));
 885 }
 886
 887 void ClientInit_CheckUpdate(entity this)
 888 {
 889         this.nextthink = time;
 890         if(this.count != autocvar_g_balance_armor_blockpercent)
 891         {
 892                 this.count = autocvar_g_balance_armor_blockpercent;
 893                 this.SendFlags |= 1;
 894         }
 895         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 896         {
 897                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 898                 this.SendFlags |= 1;
 899         }
 900 }
 901
 902 void ClientInit_Spawn()
 903 {
 904         entity e = new_pure(clientinit);
 905         setthink(e, ClientInit_CheckUpdate);
 906         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 907
 908         ClientInit_CheckUpdate(e);
 909 }
 910
 911 /*
 912 =============
 913 SetNewParms
 914 =============
 915 */
 916 void SetNewParms ()
 917 {
 918         // initialize parms for a new player
 919         parm1 = -(86400 * 366);
 920
 921         MUTATOR_CALLHOOK(SetNewParms);
 922 }
 923
 924 /*
 925 =============
 926 SetChangeParms
 927 =============
 928 */
 929 void SetChangeParms (entity this)
 930 {
 931         // save parms for level change
 932         parm1 = CS(this).parm_idlesince - time;
 933
 934         MUTATOR_CALLHOOK(SetChangeParms);
 935 }
 936
 937 /*
 938 =============
 939 DecodeLevelParms
 940 =============
 941 */
 942 void DecodeLevelParms(entity this)
 943 {
 944         // load parms
 945         CS(this).parm_idlesince = parm1;
 946         if (CS(this).parm_idlesince == -(86400 * 366))
 947                 CS(this).parm_idlesince = time;
 948
 949         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 950         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 951
 952         MUTATOR_CALLHOOK(DecodeLevelParms);
 953 }
 954
 955 void FixClientCvars(entity e)
 956 {
 957         // send prediction settings to the client
 958         stuffcmd(e, "\nin_bindmap 0 0\n");
 959         if(autocvar_g_antilag == 3) // client side hitscan
 960                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 961         if(autocvar_sv_gentle)
 962                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 963
 964         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 965         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 966
 967         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 968
 969         MUTATOR_CALLHOOK(FixClientCvars, e);
 970 }
 971
 972 bool findinlist_abbrev(string tofind, string list)
 973 {
 974         if(list == "" || tofind == "")
 975                 return false; // empty list or search, just return
 976
 977         // this function allows abbreviated strings!
 978         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 979         {
 980                 return true;
 981         });
 982
 983         return false;
 984 }
 985
 986 bool PlayerInIPList(entity p, string iplist)
 987 {
 988         // some safety checks (never allow local?)
 989         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 990                 return false;
 991
 992         return findinlist_abbrev(p.netaddress, iplist);
 993 }
 994
 995 bool PlayerInIDList(entity p, string idlist)
 996 {
 997         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 998         if(!p.crypto_idfp)
 999                 return false;
1000
1001         return findinlist_abbrev(p.crypto_idfp, idlist);
1002 }
1003
1004 bool PlayerInList(entity player, string list)
1005 {
1006         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1007 }
1008
1009 #ifdef DP_EXT_PRECONNECT
1010 /*
1011 =============
1012 ClientPreConnect
1013
1014 Called once (not at each match start) when a client begins a connection to the server
1015 =============
1016 */
1017 void ClientPreConnect(entity this)
1018 {
1019         if(autocvar_sv_eventlog)
1020         {
1021                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1022                         this.playerid,
1023                         etof(this),
1024                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1025                 ));
1026         }
1027 }
1028 #endif
1029
1030 string GetClientVersionMessage(entity this)
1031 {
1032         if (CS(this).version_mismatch) {
1033                 if(CS(this).version < autocvar_gameversion) {
1034                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1035                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1036                 } else {
1037                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1038                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1039                 }
1040         } else {
1041                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1042         }
1043 }
1044
1045 string getwelcomemessage(entity this)
1046 {
1047         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1048         string modifications = M_ARGV(0, string);
1049
1050         if(g_weaponarena)
1051         {
1052                 if(g_weaponarena_random)
1053                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1054                 else
1055                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1056         }
1057         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1058                 modifications = strcat(modifications, ", No start weapons");
1059         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1060                 modifications = strcat(modifications, ", Low gravity");
1061         if(g_weapon_stay && !g_cts)
1062                 modifications = strcat(modifications, ", Weapons stay");
1063         if(autocvar_g_jetpack)
1064                 modifications = strcat(modifications, ", Jet pack");
1065         if(autocvar_g_powerups == 0)
1066                 modifications = strcat(modifications, ", No powerups");
1067         if(autocvar_g_powerups > 0)
1068                 modifications = strcat(modifications, ", Powerups");
1069         modifications = substring(modifications, 2, strlen(modifications) - 2);
1070
1071         //string versionmessage = GetClientVersionMessage(this);
1072         //string s = strcat(versionmessage, "^8\n^9", (autocvar_hostname_full ? autocvar_hostname_full : autocvar_hostname));
1073         string s = (autocvar_hostname_full ? autocvar_hostname_full : autocvar_hostname);
1074
1075         s = strcat(s, "^8\n^7", gamemode_name);
1076
1077         if(modifications != "")
1078                 s = strcat(s, "^7 | ^3", modifications);
1079
1080         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1081         {
1082                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1083                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1084         }
1085
1086         if (cache_mutatormsg != "") {
1087                 s = strcat(s, "\n^8tips: ^7", cache_mutatormsg);
1088         }
1089
1090         string mutator_msg = "";
1091         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1092         mutator_msg = M_ARGV(0, string);
1093
1094         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1095
1096         string motd = autocvar_sv_motd;
1097         if (motd != "") {
1098                 s = strcat(s, "\n\n^7", strreplace("\\n", "\n", motd));
1099         }
1100         return s;
1101 }
1102
1103 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1104
1105 /**
1106 =============
1107 ClientConnect
1108
1109 Called when a client connects to the server
1110 =============
1111 */
1112 void ClientConnect(entity this)
1113 {
1114         if (Ban_MaybeEnforceBanOnce(this)) return;
1115         assert(!IS_CLIENT(this), return);
1116         this.flags |= FL_CLIENT;
1117         assert(player_count >= 0, player_count = 0);
1118
1119         TRANSMUTE(Client, this);
1120         CS(this).version_nagtime = time + 10 + random() * 10;
1121
1122         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1123
1124         bot_clientconnect(this);
1125
1126         Player_DetermineForcedTeam(this);
1127
1128         TRANSMUTE(Observer, this);
1129
1130         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1131
1132         // always track bots, don't ask for cl_allow_uidtracking
1133         if (IS_BOT_CLIENT(this))
1134                 PlayerStats_GameReport_AddPlayer(this);
1135         else
1136                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1137
1138         if (autocvar_sv_eventlog)
1139                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1140
1141         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1142
1143         stuffcmd(this, clientstuff, "\n");
1144         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1145
1146         FixClientCvars(this);
1147
1148         // get version info from player
1149         stuffcmd(this, "cmd clientversion $gameversion\n");
1150
1151         // notify about available teams
1152         if (teamplay)
1153         {
1154                 entity balance = TeamBalance_CheckAllowedTeams(this);
1155                 int t = TeamBalance_GetAllowedTeams(balance);
1156                 TeamBalance_Destroy(balance);
1157                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1158         }
1159         else
1160         {
1161                 stuffcmd(this, "set _teams_available 0\n");
1162         }
1163
1164         bot_relinkplayerlist();
1165
1166         CS(this).spectatortime = time;
1167         if (blockSpectators)
1168         {
1169                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1170         }
1171
1172         CS(this).jointime = time;
1173
1174         if (IS_REAL_CLIENT(this))
1175         {
1176                 if (g_weaponarena_weapons == WEPSET(TUBA))
1177                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1178         }
1179
1180         if (!autocvar_sv_foginterval && world.fog != "")
1181                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1182
1183         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1184                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1185                         send_CSQC_teamnagger();
1186
1187         CSQCMODEL_AUTOINIT(this);
1188
1189         CS(this).model_randomizer = random();
1190
1191         if (IS_REAL_CLIENT(this))
1192                 sv_notice_join(this);
1193
1194         this.move_qcphysics = autocvar_sv_qcphysics;
1195
1196         // update physics stats (players can spawn before physics runs)
1197         Physics_UpdateStats(this);
1198
1199         IL_EACH(g_initforplayer, it.init_for_player, {
1200                 it.init_for_player(it, this);
1201         });
1202
1203         Handicap_Initialize(this);
1204
1205         MUTATOR_CALLHOOK(ClientConnect, this);
1206
1207         if (IS_REAL_CLIENT(this))
1208         {
1209                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1210                 {
1211                         CS(this).motd_actived_time = -1;
1212                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1213                 }
1214         }
1215 }
1216 /*
1217 =============
1218 ClientDisconnect
1219
1220 Called when a client disconnects from the server
1221 =============
1222 */
1223 .entity chatbubbleentity;
1224 void ClientDisconnect(entity this)
1225 {
1226         assert(IS_CLIENT(this), return);
1227
1228         PlayerStats_GameReport_FinalizePlayer(this);
1229         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1230         if (CS(this).active_minigame) part_minigame(this);
1231         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1232
1233         if (autocvar_sv_eventlog)
1234                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1235
1236         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1237
1238         if(IS_SPEC(this))
1239                 SetSpectatee(this, NULL);
1240
1241         MUTATOR_CALLHOOK(ClientDisconnect, this);
1242
1243         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1244         strfree(CS(this).weaponorder_byimpulse);
1245         ClientState_detach(this);
1246
1247         Portal_ClearAll(this);
1248
1249         Unfreeze(this, false);
1250
1251         RemoveGrapplingHooks(this);
1252
1253         // Here, everything has been done that requires this player to be a client.
1254
1255         this.flags &= ~FL_CLIENT;
1256
1257         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1258         if (this.killindicator) delete(this.killindicator);
1259
1260         IL_EACH(g_counters, it.realowner == this,
1261         {
1262                 delete(it);
1263         });
1264
1265         WaypointSprite_PlayerGone(this);
1266
1267         bot_relinkplayerlist();
1268
1269         strfree(this.clientstatus);
1270         if (this.personal) delete(this.personal);
1271
1272         this.playerid = 0;
1273         ReadyCount();
1274         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1275
1276         ONREMOVE(this);
1277 }
1278
1279 void ChatBubbleThink(entity this)
1280 {
1281         this.nextthink = time;
1282         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1283         {
1284                 if(this.owner) // but why can that ever be NULL?
1285                         this.owner.chatbubbleentity = NULL;
1286                 delete(this);
1287                 return;
1288         }
1289
1290         this.mdl = "";
1291
1292         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1293         {
1294                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1295                         this.mdl = "models/sprites/minigame_busy.iqm";
1296                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1297                         this.mdl = "models/misc/chatbubble.spr";
1298         }
1299
1300         if ( this.model != this.mdl )
1301                 _setmodel(this, this.mdl);
1302
1303 }
1304
1305 void UpdateChatBubble(entity this)
1306 {
1307         if (this.alpha < 0)
1308                 return;
1309         // spawn a chatbubble entity if needed
1310         if (!this.chatbubbleentity)
1311         {
1312                 this.chatbubbleentity = new(chatbubbleentity);
1313                 this.chatbubbleentity.owner = this;
1314                 this.chatbubbleentity.exteriormodeltoclient = this;
1315                 setthink(this.chatbubbleentity, ChatBubbleThink);
1316                 this.chatbubbleentity.nextthink = time;
1317                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1318                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1319                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1320                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1321                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1322                 //this.chatbubbleentity.model = "";
1323                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1324         }
1325 }
1326
1327 void calculate_player_respawn_time(entity this)
1328 {
1329         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1330                 return;
1331
1332         float gametype_setting_tmp;
1333         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1334         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1335         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1336         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1337         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1338         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1339
1340         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1341         if (teamplay)
1342         {
1343                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1344                         if(it.team == this.team)
1345                                 ++pcount;
1346                 });
1347                 if (sdelay_small_count == 0)
1348                         sdelay_small_count = 1;
1349                 if (sdelay_large_count == 0)
1350                         sdelay_large_count = 1;
1351         }
1352         else
1353         {
1354                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1355                         ++pcount;
1356                 });
1357                 if (sdelay_small_count == 0)
1358                 {
1359                         if (IS_INDEPENDENT_PLAYER(this))
1360                         {
1361                                 // Players play independently. No point in requiring enemies.
1362                                 sdelay_small_count = 1;
1363                         }
1364                         else
1365                         {
1366                                 // Players play AGAINST each other. Enemies required.
1367                                 sdelay_small_count = 2;
1368                         }
1369                 }
1370                 if (sdelay_large_count == 0)
1371                 {
1372                         if (IS_INDEPENDENT_PLAYER(this))
1373                         {
1374                                 // Players play independently. No point in requiring enemies.
1375                                 sdelay_large_count = 1;
1376                         }
1377                         else
1378                         {
1379                                 // Players play AGAINST each other. Enemies required.
1380                                 sdelay_large_count = 2;
1381                         }
1382                 }
1383         }
1384
1385         float sdelay;
1386
1387         if (pcount <= sdelay_small_count)
1388                 sdelay = sdelay_small;
1389         else if (pcount >= sdelay_large_count)
1390                 sdelay = sdelay_large;
1391         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1392                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1393
1394         if(waves)
1395                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1396         else
1397                 this.respawn_time = time + sdelay;
1398
1399         if(sdelay < sdelay_max)
1400                 this.respawn_time_max = time + sdelay_max;
1401         else
1402                 this.respawn_time_max = this.respawn_time;
1403
1404         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1405                 this.respawn_countdown = 10; // first number to count down from is 10
1406         else
1407                 this.respawn_countdown = -1; // do not count down
1408
1409         if(autocvar_g_forced_respawn)
1410                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1411 }
1412
1413 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1414 // added to the model skins
1415 /*void UpdateColorModHack()
1416 {
1417         float c;
1418         c = this.clientcolors & 15;
1419         // LordHavoc: only bothering to support white, green, red, yellow, blue
1420              if (!teamplay) this.colormod = '0 0 0';
1421         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1422         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1423         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1424         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1425         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1426         else this.colormod = '1 1 1';
1427 }*/
1428
1429 void respawn(entity this)
1430 {
1431         bool damagedbycontents_prev = this.damagedbycontents;
1432         if(this.alpha >= 0)
1433         {
1434                 if(autocvar_g_respawn_ghosts)
1435                 {
1436                         this.solid = SOLID_NOT;
1437                         this.takedamage = DAMAGE_NO;
1438                         this.damagedbycontents = false;
1439                         set_movetype(this, MOVETYPE_FLY);
1440                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1441                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1442                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1443                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1444                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1445                         if(autocvar_g_respawn_ghosts_time > 0)
1446                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1447                 }
1448                 else
1449                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1450         }
1451
1452         CopyBody(this, 1);
1453         this.damagedbycontents = damagedbycontents_prev;
1454
1455         this.effects |= EF_NODRAW; // prevent another CopyBody
1456         PutClientInServer(this);
1457 }
1458
1459 void play_countdown(entity this, float finished, Sound samp)
1460 {
1461         TC(Sound, samp);
1462         if(IS_REAL_CLIENT(this))
1463                 if(floor(finished - time - frametime) != floor(finished - time))
1464                         if(finished - time < 6)
1465                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1466 }
1467
1468 void player_powerups(entity this)
1469 {
1470         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1471                 this.modelflags |= MF_ROCKET;
1472         else
1473                 this.modelflags &= ~MF_ROCKET;
1474
1475         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1476
1477         if (IS_DEAD(this))
1478         {
1479                 if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1480                 {
1481                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1482                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1483                         this.items &= ~ITEM_Strength.m_itemid;
1484                         this.items &= ~ITEM_Shield.m_itemid;
1485                         this.items -= (this.items & IT_SUPERWEAPON);
1486                 }
1487         }
1488
1489         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1490                 return;
1491
1492         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1493         int items_prev = this.items;
1494
1495         Fire_ApplyDamage(this);
1496         Fire_ApplyEffect(this);
1497
1498         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1499         {
1500                 if (this.items & ITEM_Strength.m_itemid)
1501                 {
1502                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1503                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1504                         if (time > STAT(STRENGTH_FINISHED, this))
1505                         {
1506                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1507                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1508                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1509                         }
1510                 }
1511                 else
1512                 {
1513                         if (time < STAT(STRENGTH_FINISHED, this))
1514                         {
1515                                 this.items = this.items | ITEM_Strength.m_itemid;
1516                                 if(!g_cts)
1517                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1518                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1519                         }
1520                 }
1521                 if (this.items & ITEM_Shield.m_itemid)
1522                 {
1523                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1524                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1525                         if (time > STAT(INVINCIBLE_FINISHED, this))
1526                         {
1527                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1528                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1529                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1530                         }
1531                 }
1532                 else
1533                 {
1534                         if (time < STAT(INVINCIBLE_FINISHED, this))
1535                         {
1536                                 this.items = this.items | ITEM_Shield.m_itemid;
1537                                 if(!g_cts)
1538                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1539                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1540                         }
1541                 }
1542                 if (this.items & IT_SUPERWEAPON)
1543                 {
1544                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1545                         {
1546                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1547                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1548                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1549                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1550                         }
1551                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1552                         {
1553                                 // don't let them run out
1554                         }
1555                         else
1556                         {
1557                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1558                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1559                                 {
1560                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1561                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1562                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1563                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1564                                 }
1565                         }
1566                 }
1567                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1568                 {
1569                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1570                         {
1571                                 this.items = this.items | IT_SUPERWEAPON;
1572                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1573                                 {
1574                                         if(!g_cts)
1575                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1576                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1577                                 }
1578                         }
1579                         else
1580                         {
1581                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1582                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1583                         }
1584                 }
1585                 else
1586                 {
1587                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1588                 }
1589         }
1590
1591         if(autocvar_g_nodepthtestplayers)
1592                 this.effects = this.effects | EF_NODEPTHTEST;
1593
1594         if(autocvar_g_fullbrightplayers)
1595                 this.effects = this.effects | EF_FULLBRIGHT;
1596
1597         if (time >= game_starttime)
1598         if (time < this.spawnshieldtime)
1599                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1600
1601         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1602 }
1603
1604 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1605 {
1606         if(current > stable)
1607                 return current;
1608         else if(current > stable - 0.25) // when close enough, "snap"
1609                 return stable;
1610         else
1611                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1612 }
1613
1614 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1615 {
1616         if(current < stable)
1617                 return current;
1618         else if(current < stable + 0.25) // when close enough, "snap"
1619                 return stable;
1620         else
1621                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1622 }
1623
1624 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1625 {
1626         float old = GetResource(this, res);
1627         float current = old;
1628         if(current > rotstable)
1629         {
1630                 if(rotframetime > 0)
1631                 {
1632                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1633                         current = max(rotstable, current - rotlinear * rotframetime);
1634                 }
1635         }
1636         else if(current < regenstable)
1637         {
1638                 if(regenframetime > 0)
1639                 {
1640                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1641                         current = min(regenstable, current + regenlinear * regenframetime);
1642                 }
1643         }
1644
1645         float limit = GetResourceLimit(this, res) * limit_mod;
1646         if(current > limit)
1647                 current = limit;
1648
1649         if (current != old)
1650                 SetResource(this, res, current);
1651 }
1652
1653 void player_regen(entity this)
1654 {
1655         float max_mod, regen_mod, rot_mod, limit_mod;
1656         max_mod = regen_mod = rot_mod = limit_mod = 1;
1657
1658         float regen_health = autocvar_g_balance_health_regen;
1659         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1660         float regen_health_rot = autocvar_g_balance_health_rot;
1661         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1662         float regen_health_stable = autocvar_g_balance_health_regenstable;
1663         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1664         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1665                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1666         max_mod = M_ARGV(1, float);
1667         regen_mod = M_ARGV(2, float);
1668         rot_mod = M_ARGV(3, float);
1669         limit_mod = M_ARGV(4, float);
1670         regen_health = M_ARGV(5, float);
1671         regen_health_linear = M_ARGV(6, float);
1672         regen_health_rot = M_ARGV(7, float);
1673         regen_health_rotlinear = M_ARGV(8, float);
1674         regen_health_stable = M_ARGV(9, float);
1675         regen_health_rotstable = M_ARGV(10, float);
1676
1677         if(!mutator_returnvalue)
1678         if(!STAT(FROZEN, this))
1679         {
1680                 float maxa = autocvar_g_balance_armor_rotstable;
1681                 float mina = autocvar_g_balance_armor_regenstable;
1682
1683                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1684                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1685                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1686
1687                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1688                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1689                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1690         }
1691
1692         // if player rotted to death...  die!
1693         // check this outside above checks, as player may still be able to rot to death
1694         if(GetResource(this, RES_HEALTH) < 1)
1695         {
1696                 if(this.vehicle)
1697                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1698                 if(this.event_damage)
1699                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1700         }
1701
1702         if (!(this.items & IT_UNLIMITED_AMMO))
1703         {
1704                 float maxf = autocvar_g_balance_fuel_rotstable;
1705                 float minf = autocvar_g_balance_fuel_regenstable;
1706
1707                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1708                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1709                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1710         }
1711 }
1712
1713 bool zoomstate_set;
1714 void SetZoomState(entity this, float newzoom)
1715 {
1716         if(newzoom != CS(this).zoomstate)
1717         {
1718                 CS(this).zoomstate = newzoom;
1719                 ClientData_Touch(this);
1720         }
1721         zoomstate_set = true;
1722 }
1723
1724 void GetPressedKeys(entity this)
1725 {
1726         MUTATOR_CALLHOOK(GetPressedKeys, this);
1727         int keys = STAT(PRESSED_KEYS, this);
1728         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1729         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1730         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1731         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1732
1733         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1734         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1735         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1736         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1737         CS(this).pressedkeys = keys; // store for other users
1738
1739         STAT(PRESSED_KEYS, this) = keys;
1740 }
1741
1742 /*
1743 ======================
1744 spectate mode routines
1745 ======================
1746 */
1747
1748 void SpectateCopy(entity this, entity spectatee)
1749 {
1750         TC(Client, this); TC(Client, spectatee);
1751
1752         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1753         PS(this) = PS(spectatee);
1754         this.armortype = spectatee.armortype;
1755         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1756         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1757         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1758         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1759         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1760         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1761         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1762         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1763         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1764         CS(this).impulse = 0;
1765         this.disableclientprediction = 1; // no need to run prediction on a spectator
1766         this.items = spectatee.items;
1767         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1768         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1769         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1770         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1771         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1772         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1773         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1774         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1775         this.punchangle = spectatee.punchangle;
1776         this.view_ofs = spectatee.view_ofs;
1777         this.velocity = spectatee.velocity;
1778         this.dmg_take = spectatee.dmg_take;
1779         this.dmg_save = spectatee.dmg_save;
1780         this.dmg_inflictor = spectatee.dmg_inflictor;
1781         this.v_angle = spectatee.v_angle;
1782         this.angles = spectatee.v_angle;
1783         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1784         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1785         this.viewloc = spectatee.viewloc;
1786         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1787                 this.fixangle = true;
1788         setorigin(this, spectatee.origin);
1789         setsize(this, spectatee.mins, spectatee.maxs);
1790         SetZoomState(this, CS(spectatee).zoomstate);
1791
1792     anticheat_spectatecopy(this, spectatee);
1793         STAT(HUD, this) = STAT(HUD, spectatee);
1794         if(spectatee.vehicle)
1795     {
1796         this.angles = spectatee.v_angle;
1797
1798         //this.fixangle = false;
1799         //this.velocity = spectatee.vehicle.velocity;
1800         this.vehicle_health = spectatee.vehicle_health;
1801         this.vehicle_shield = spectatee.vehicle_shield;
1802         this.vehicle_energy = spectatee.vehicle_energy;
1803         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1804         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1805         this.vehicle_reload1 = spectatee.vehicle_reload1;
1806         this.vehicle_reload2 = spectatee.vehicle_reload2;
1807
1808         //msg_entity = this;
1809
1810        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1811             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1812            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1813            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1814
1815         //WriteByte (MSG_ONE, SVC_SETVIEW);
1816         //    WriteEntity(MSG_ONE, this);
1817         //makevectors(spectatee.v_angle);
1818         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1819     }
1820 }
1821
1822 bool SpectateUpdate(entity this)
1823 {
1824         if(!this.enemy)
1825                 return false;
1826
1827         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1828         {
1829                 SetSpectatee(this, NULL);
1830                 return false;
1831         }
1832
1833         SpectateCopy(this, this.enemy);
1834
1835         return true;
1836 }
1837
1838 bool SpectateSet(entity this)
1839 {
1840         if(!IS_PLAYER(this.enemy))
1841                 return false;
1842
1843         ClientData_Touch(this.enemy);
1844
1845         msg_entity = this;
1846         WriteByte(MSG_ONE, SVC_SETVIEW);
1847         WriteEntity(MSG_ONE, this.enemy);
1848         set_movetype(this, MOVETYPE_NONE);
1849         accuracy_resend(this);
1850
1851         if(!SpectateUpdate(this))
1852                 PutObserverInServer(this);
1853
1854         return true;
1855 }
1856
1857 void SetSpectatee_status(entity this, int spectatee_num)
1858 {
1859         int oldspectatee_status = CS(this).spectatee_status;
1860         CS(this).spectatee_status = spectatee_num;
1861
1862         if (CS(this).spectatee_status != oldspectatee_status)
1863         {
1864                 if (STAT(PRESSED_KEYS, this))
1865                 {
1866                         CS(this).pressedkeys = 0;
1867                         STAT(PRESSED_KEYS, this) = 0;
1868                 }
1869                 ClientData_Touch(this);
1870                 if (g_race || g_cts) race_InitSpectator();
1871         }
1872 }
1873
1874 void SetSpectatee(entity this, entity spectatee)
1875 {
1876         if(IS_BOT_CLIENT(this))
1877                 return; // bots abuse .enemy, this code is useless to them
1878
1879         entity old_spectatee = this.enemy;
1880
1881         this.enemy = spectatee;
1882
1883         // WEAPONTODO
1884         // these are required to fix the spectator bug with arc
1885         if(old_spectatee)
1886         {
1887                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1888                 {
1889                         .entity weaponentity = weaponentities[slot];
1890                         if(old_spectatee.(weaponentity).arc_beam)
1891                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1892                 }
1893         }
1894         if(this.enemy)
1895         {
1896                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1897                 {
1898                         .entity weaponentity = weaponentities[slot];
1899                         if(this.enemy.(weaponentity).arc_beam)
1900                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1901                 }
1902         }
1903
1904         if (this.enemy)
1905                 SetSpectatee_status(this, etof(this.enemy));
1906
1907         // needed to update spectator list
1908         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1909 }
1910
1911 bool Spectate(entity this, entity pl)
1912 {
1913         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1914                 return false;
1915         pl = M_ARGV(1, entity);
1916
1917         SetSpectatee(this, pl);
1918         return SpectateSet(this);
1919 }
1920
1921 bool SpectateNext(entity this)
1922 {
1923         entity ent = find(this.enemy, classname, STR_PLAYER);
1924
1925         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1926                 ent = M_ARGV(1, entity);
1927         else if (!ent)
1928                 ent = find(ent, classname, STR_PLAYER);
1929
1930         if(ent) { SetSpectatee(this, ent); }
1931
1932         return SpectateSet(this);
1933 }
1934
1935 bool SpectatePrev(entity this)
1936 {
1937         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1938         entity ent = findchain(classname, STR_PLAYER);
1939         if (!ent) // no player
1940                 return false;
1941
1942         entity first = ent;
1943         // skip players until current spectated player
1944         if(this.enemy)
1945         while(ent && ent != this.enemy)
1946                 ent = ent.chain;
1947
1948         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1949         {
1950                 case MUT_SPECPREV_FOUND:
1951                         ent = M_ARGV(1, entity);
1952                         break;
1953                 case MUT_SPECPREV_RETURN:
1954                         return true;
1955                 case MUT_SPECPREV_CONTINUE:
1956                 default:
1957                 {
1958                         if(ent.chain)
1959                                 ent = ent.chain;
1960                         else
1961                                 ent = first;
1962                         break;
1963                 }
1964         }
1965
1966         SetSpectatee(this, ent);
1967         return SpectateSet(this);
1968 }
1969
1970 /*
1971 =============
1972 ShowRespawnCountdown()
1973
1974 Update a respawn countdown display.
1975 =============
1976 */
1977 void ShowRespawnCountdown(entity this)
1978 {
1979         float number;
1980         if(!IS_DEAD(this)) // just respawned?
1981                 return;
1982         else
1983         {
1984                 number = ceil(this.respawn_time - time);
1985                 if(number <= 0)
1986                         return;
1987                 if(number <= this.respawn_countdown)
1988                 {
1989                         this.respawn_countdown = number - 1;
1990                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1991                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1992                 }
1993         }
1994 }
1995
1996 .bool team_selected;
1997 bool ShowTeamSelection(entity this)
1998 {
1999         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
2000                 return false;
2001         stuffcmd(this, "menu_showteamselect\n");
2002         return true;
2003 }
2004 void Join(entity this)
2005 {
2006         TRANSMUTE(Player, this);
2007
2008         if(!this.team_selected)
2009         if(autocvar_g_campaign || autocvar_g_balance_teams)
2010                 TeamBalance_JoinBestTeam(this);
2011
2012         if(autocvar_g_campaign)
2013                 campaign_bots_may_start = true;
2014
2015         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2016
2017         PutClientInServer(this);
2018
2019         if(IS_PLAYER(this))
2020         if(teamplay && this.team != -1)
2021         {
2022         }
2023         else
2024                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2025         this.team_selected = false;
2026
2027         // z411
2028         // send constant ready notification
2029         if(warmup_stage)
2030                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MISSING_READY);
2031 }
2032
2033 int GetPlayerLimit()
2034 {
2035         if(g_duel)
2036                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2037         int player_limit = autocvar_g_maxplayers;
2038         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2039         player_limit = M_ARGV(0, int);
2040         return player_limit;
2041 }
2042
2043 /**
2044  * Determines whether the player is allowed to join. This depends on cvar
2045  * g_maxplayers, if it isn't used this function always return true, otherwise
2046  * it checks whether the number of currently playing players exceeds g_maxplayers.
2047  * @return int number of free slots for players, 0 if none
2048  */
2049 int nJoinAllowed(entity this, entity ignore)
2050 {
2051         if(!ignore)
2052         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2053         // so report 0 free slots if restricted
2054         {
2055                 if(autocvar_g_forced_team_otherwise == "spectate")
2056                         return 0;
2057                 if(autocvar_g_forced_team_otherwise == "spectator")
2058                         return 0;
2059         }
2060
2061         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2062                 return 0; // forced spectators can never join
2063
2064         // TODO simplify this
2065         int totalClients = 0;
2066         int currentlyPlaying = 0;
2067         FOREACH_CLIENT(true, {
2068                 if(it != ignore)
2069                         ++totalClients;
2070                 if(IS_REAL_CLIENT(it))
2071                 if(IS_PLAYER(it) || it.caplayer)
2072                         ++currentlyPlaying;
2073         });
2074
2075         int player_limit = GetPlayerLimit();
2076
2077         int free_slots = 0;
2078         if (!player_limit)
2079                 free_slots = maxclients - totalClients;
2080         else if(player_limit > 0 && currentlyPlaying < player_limit)
2081                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2082
2083         static float msg_time = 0;
2084         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2085         {
2086                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2087                 msg_time = time + 0.5;
2088         }
2089
2090         return free_slots;
2091 }
2092
2093 /**
2094  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2095  * g_maxplayers_spectator_blocktime seconds
2096  */
2097 void checkSpectatorBlock(entity this)
2098 {
2099         if(IS_SPEC(this) || IS_OBSERVER(this))
2100         if(!this.caplayer)
2101         if(IS_REAL_CLIENT(this))
2102         {
2103                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2104                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2105                         dropclient(this);
2106                 }
2107         }
2108 }
2109
2110 void PrintWelcomeMessage(entity this)
2111 {
2112         if(CS(this).motd_actived_time == 0)
2113         {
2114                 if (autocvar_g_campaign) {
2115                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2116                                 CS(this).motd_actived_time = time;
2117                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2118                         }
2119                 } else {
2120                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2121                                 CS(this).motd_actived_time = time;
2122                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2123                         }
2124                 }
2125         }
2126         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2127         {
2128                 if (autocvar_g_campaign) {
2129                         if (PHYS_INPUT_BUTTON_INFO(this))
2130                                 CS(this).motd_actived_time = time;
2131                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2132                                 CS(this).motd_actived_time = 0;
2133                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2134                         }
2135                 } else {
2136                         if (PHYS_INPUT_BUTTON_INFO(this))
2137                                 CS(this).motd_actived_time = time;
2138                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2139                                 CS(this).motd_actived_time = 0;
2140                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2141                         }
2142                 }
2143         }
2144         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2145         {
2146                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2147                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2148                 else if (CS(this).motd_actived_time == -2)
2149                 {
2150                         // instantly hide MOTD
2151                         CS(this).motd_actived_time = 0;
2152                         if (autocvar_g_campaign)
2153                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2154                         else
2155                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2156                 }
2157                 else if (IS_PLAYER(this) || IS_SPEC(this))
2158                 {
2159                         // FIXME occasionally for some reason MOTD never goes away
2160                         // delay MOTD removal a little bit in the hope it fixes this bug
2161                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2162                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2163                         else //if (CS(this).motd_actived_time < -2)
2164                                 CS(this).motd_actived_time++;
2165                 }
2166         }
2167 }
2168
2169 bool joinAllowed(entity this)
2170 {
2171         if (CS(this).version_mismatch) return false;
2172         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2173         if (!nJoinAllowed(this, this)) return false;
2174         if (teamplay && lockteams) return false;
2175         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2176         if (ShowTeamSelection(this)) return false;
2177         return true;
2178 }
2179
2180 .string shootfromfixedorigin;
2181 .bool dualwielding_prev;
2182 bool PlayerThink(entity this)
2183 {
2184         if (game_stopped || intermission_running) {
2185                 this.modelflags &= ~MF_ROCKET;
2186                 if(intermission_running)
2187                         IntermissionThink(this);
2188                 return false;
2189         }
2190
2191         if (game_timeout) {
2192         // don't allow the player to turn around while game is paused
2193                 // FIXME turn this into CSQC stuff
2194                 this.v_angle = this.lastV_angle;
2195                 this.angles = this.lastV_angle;
2196                 this.fixangle = true;
2197                 return false;
2198         }
2199
2200         if (frametime) player_powerups(this);
2201
2202         if (IS_DEAD(this)) {
2203                 if (this.personal && g_race_qualifying) {
2204                         if (time > this.respawn_time) {
2205                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2206                                 respawn(this);
2207                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2208                         }
2209                 } else {
2210                         if (frametime) player_anim(this);
2211
2212                         if (this.respawn_flags & RESPAWN_DENY)
2213                         {
2214                                 STAT(RESPAWN_TIME, this) = 0;
2215                                 return false;
2216                         }
2217
2218                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2219
2220                         switch(this.deadflag)
2221                         {
2222                                 case DEAD_DYING:
2223                                 {
2224                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2225                                                 this.deadflag = DEAD_RESPAWNING;
2226                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2227                                                 this.deadflag = DEAD_DEAD;
2228                                         break;
2229                                 }
2230                                 case DEAD_DEAD:
2231                                 {
2232                                         if (button_pressed)
2233                                                 this.deadflag = DEAD_RESPAWNABLE;
2234                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2235                                                 this.deadflag = DEAD_RESPAWNING;
2236                                         break;
2237                                 }
2238                                 case DEAD_RESPAWNABLE:
2239                                 {
2240                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2241                                                 this.deadflag = DEAD_RESPAWNING;
2242                                         break;
2243                                 }
2244                                 case DEAD_RESPAWNING:
2245                                 {
2246                                         if (time > this.respawn_time)
2247                                         {
2248                                                 this.respawn_time = time + 1; // only retry once a second
2249                                                 this.respawn_time_max = this.respawn_time;
2250                                                 respawn(this);
2251                                         }
2252                                         break;
2253                                 }
2254                         }
2255
2256                         ShowRespawnCountdown(this);
2257
2258                         if (this.respawn_flags & RESPAWN_SILENT)
2259                                 STAT(RESPAWN_TIME, this) = 0;
2260                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2261                         {
2262                                 if (time < this.respawn_time)
2263                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2264                                 else if (this.deadflag != DEAD_RESPAWNING)
2265                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2266                         }
2267                         else
2268                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2269                 }
2270
2271                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2272                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2273                         STAT(RESPAWN_TIME, this) *= -1;
2274
2275                 return false;
2276         }
2277
2278         FixPlayermodel(this);
2279
2280         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2281                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2282                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2283         }
2284
2285         // reset gun alignment when dual wielding status changes
2286         // to ensure guns are always aligned right and left
2287         bool dualwielding = W_DualWielding(this);
2288         if(this.dualwielding_prev != dualwielding)
2289         {
2290                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2291                 this.dualwielding_prev = dualwielding;
2292         }
2293
2294         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2295         //if(frametime)
2296         {
2297                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2298                 {
2299                         .entity weaponentity = weaponentities[slot];
2300                         if(WEP_CVAR(vortex, charge_always))
2301                                 W_Vortex_Charge(this, weaponentity, frametime);
2302                         W_WeaponFrame(this, weaponentity);
2303                 }
2304         }
2305
2306         if (frametime)
2307         {
2308                 // WEAPONTODO: Add a weapon request for this
2309                 // rot vortex charge to the charge limit
2310                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2311                 {
2312                         .entity weaponentity = weaponentities[slot];
2313                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2314                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2315                 }
2316
2317                 player_regen(this);
2318                 player_anim(this);
2319                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2320         }
2321
2322         monsters_setstatus(this);
2323
2324         return true;
2325 }
2326
2327 .bool would_spectate;
2328 void ObserverOrSpectatorThink(entity this)
2329 {
2330         bool is_spec = IS_SPEC(this);
2331         if ( CS(this).impulse )
2332         {
2333                 int r = MinigameImpulse(this, CS(this).impulse);
2334                 if (!is_spec || r)
2335                         CS(this).impulse = 0;
2336
2337                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2338                 {
2339                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2340                         CS(this).impulse = 0;
2341                         return;
2342                 }
2343         }
2344
2345         if (this.flags & FL_JUMPRELEASED) {
2346                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2347                         this.flags &= ~FL_JUMPRELEASED;
2348                         this.flags |= FL_SPAWNING;
2349                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2350                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2351                         this.flags &= ~FL_JUMPRELEASED;
2352                         if(SpectateNext(this)) {
2353                                 TRANSMUTE(Spectator, this);
2354                         } else if (is_spec) {
2355                                 TRANSMUTE(Observer, this);
2356                                 PutClientInServer(this);
2357                         }
2358                         if (is_spec)
2359                                 CS(this).impulse = 0;
2360                 } else if (is_spec) {
2361                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2362                                 this.flags &= ~FL_JUMPRELEASED;
2363                                 if(SpectatePrev(this)) {
2364                                         TRANSMUTE(Spectator, this);
2365                                 } else {
2366                                         TRANSMUTE(Observer, this);
2367                                         PutClientInServer(this);
2368                                 }
2369                                 CS(this).impulse = 0;
2370                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2371                                 this.would_spectate = false;
2372                                 this.flags &= ~FL_JUMPRELEASED;
2373                                 TRANSMUTE(Observer, this);
2374                                 PutClientInServer(this);
2375                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2376                                 PutObserverInServer(this);
2377                                 this.would_spectate = true;
2378                         }
2379                 }
2380                 else {
2381                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2382                         set_movetype(this, preferred_movetype);
2383                 }
2384         } else {
2385                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2386                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2387                         this.flags |= FL_JUMPRELEASED;
2388                         if(this.flags & FL_SPAWNING)
2389                         {
2390                                 this.flags &= ~FL_SPAWNING;
2391                                 if(joinAllowed(this))
2392                                         Join(this);
2393                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2394                                         CS(this).autojoin_checked = -1;
2395                                 return;
2396                         }
2397                 }
2398                 if(is_spec && !SpectateUpdate(this))
2399                         PutObserverInServer(this);
2400         }
2401         if (is_spec)
2402                 this.flags |= FL_CLIENT | FL_NOTARGET;
2403 }
2404
2405 void PlayerUseKey(entity this)
2406 {
2407         if (!IS_PLAYER(this))
2408                 return;
2409
2410         if(this.vehicle)
2411         {
2412                 if(!game_stopped)
2413                 {
2414                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2415                         return;
2416                 }
2417         }
2418         else if(autocvar_g_vehicles_enter)
2419         {
2420                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2421                 {
2422                         entity head, closest_target = NULL;
2423                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2424
2425                         while(head) // find the closest acceptable target to enter
2426                         {
2427                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2428                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2429                                 {
2430                                         if(closest_target)
2431                                         {
2432                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2433                                                 { closest_target = head; }
2434                                         }
2435                                         else { closest_target = head; }
2436                                 }
2437
2438                                 head = head.chain;
2439                         }
2440
2441                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2442                 }
2443         }
2444
2445         // a use key was pressed; call handlers
2446         MUTATOR_CALLHOOK(PlayerUseKey, this);
2447 }
2448
2449
2450 /*
2451 =============
2452 PlayerPreThink
2453
2454 Called every frame for each client before the physics are run
2455 =============
2456 */
2457 .float last_vehiclecheck;
2458 void PlayerPreThink (entity this)
2459 {
2460         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2461         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2462
2463         WarpZone_PlayerPhysics_FixVAngle(this);
2464
2465         if (frametime) {
2466                 // physics frames: update anticheat stuff
2467                 anticheat_prethink(this);
2468         }
2469
2470         if (blockSpectators && frametime) {
2471                 // WORKAROUND: only use dropclient in server frames (frametime set).
2472                 // Never use it in cl_movement frames (frametime zero).
2473                 checkSpectatorBlock(this);
2474         }
2475
2476         zoomstate_set = false;
2477
2478         // Check for nameless players
2479         if (this.netname == "" || this.netname != CS(this).netname_previous)
2480         {
2481                 bool assume_unchanged = (CS(this).netname_previous == "");
2482                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2483                 {
2484                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2485                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2486                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2487                         assume_unchanged = false;
2488                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2489                 }
2490                 if (isInvisibleString(this.netname))
2491                 {
2492                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2493                         sprint(this, "Warning: invisible names are not allowed.\n");
2494                         assume_unchanged = false;
2495                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2496                 }
2497                 if (!assume_unchanged && autocvar_sv_eventlog)
2498                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2499                 strcpy(CS(this).netname_previous, this.netname);
2500         }
2501
2502         // version nagging
2503         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2504         CS(this).version_nagtime = 0;
2505         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2506             // git client
2507         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2508             // git server
2509             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2510         } else {
2511             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2512             if (r < 0) { // old client
2513                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2514             } else if (r > 0) { // old server
2515                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2516             }
2517         }
2518     }
2519
2520         // GOD MODE info
2521         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2522         {
2523                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2524                 this.max_armorvalue = 0;
2525         }
2526
2527         if (frametime && IS_PLAYER(this))
2528         {
2529                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2530                 {
2531                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2532                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2533                         if (this.iceblock)
2534                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2535
2536                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2537                                 Unfreeze(this, false);
2538                 }
2539                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2540                 {
2541                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2542                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2543
2544                         if (GetResource(this, RES_HEALTH) < 1)
2545                         {
2546                                 if (this.vehicle)
2547                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2548                                 if(this.event_damage)
2549                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2550                         }
2551                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2552                                 Unfreeze(this, false);
2553                 }
2554         }
2555
2556         MUTATOR_CALLHOOK(PlayerPreThink, this);
2557
2558         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2559         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2560         {
2561                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2562                 {
2563                         if(!it.owner)
2564                         {
2565                                 if(!it.team || SAME_TEAM(this, it))
2566                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2567                                 else if(autocvar_g_vehicles_steal)
2568                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2569                         }
2570                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2571                         {
2572                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2573                         }
2574                 });
2575
2576                 this.last_vehiclecheck = time + 1;
2577         }
2578
2579         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2580         {
2581                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2582                         PlayerUseKey(this);
2583                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2584         }
2585
2586         if (IS_REAL_CLIENT(this))
2587                 PrintWelcomeMessage(this);
2588
2589         if (IS_PLAYER(this)) {
2590                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2591                         error("Client can't be spawned as player on connection!");
2592                 if(!PlayerThink(this))
2593                         return;
2594         }
2595         else if (game_stopped || intermission_running) {
2596                 if(intermission_running)
2597                         IntermissionThink(this);
2598                 return;
2599         }
2600         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2601         {
2602                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2603                 CS(this).autojoin_checked = 1;
2604                 // don't do this in ClientConnect
2605                 // many things can go wrong if a client is spawned as player on connection
2606                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2607                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2608                                 && (!teamplay || autocvar_g_balance_teams)))
2609                 {
2610                         campaign_bots_may_start = true;
2611                         if(joinAllowed(this))
2612                                 Join(this);
2613                         return;
2614                 }
2615         }
2616         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2617                 ObserverOrSpectatorThink(this);
2618         }
2619
2620         // WEAPONTODO: Add weapon request for this
2621         if (!zoomstate_set) {
2622                 bool wep_zoomed = false;
2623                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2624                 {
2625                         .entity weaponentity = weaponentities[slot];
2626                         Weapon thiswep = this.(weaponentity).m_weapon;
2627                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2628                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2629                 }
2630                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2631         }
2632
2633         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2634         {
2635                 CS(this).teamkill_soundtime = 0;
2636
2637                 entity e = CS(this).teamkill_soundsource;
2638                 entity oldpusher = e.pusher;
2639                 e.pusher = this;
2640                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2641                 e.pusher = oldpusher;
2642         }
2643
2644         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2645                 CS(this).taunt_soundtime = 0;
2646                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2647         }
2648
2649         target_voicescript_next(this);
2650
2651         // WEAPONTODO: Move into weaponsystem somehow
2652         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2653         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2654         {
2655                 .entity weaponentity = weaponentities[slot];
2656                 if(this.(weaponentity).m_weapon == WEP_Null)
2657                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2658         }
2659 }
2660
2661 void DrownPlayer(entity this)
2662 {
2663         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2664                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2665         {
2666                 STAT(AIR_FINISHED, this) = 0;
2667                 return;
2668         }
2669
2670         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2671         {
2672                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2673                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2674                 STAT(AIR_FINISHED, this) = 0;
2675         }
2676         else
2677         {
2678                 if (!STAT(AIR_FINISHED, this))
2679                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2680                 if (STAT(AIR_FINISHED, this) < time)
2681                 {       // drown!
2682                         if (this.pain_finished < time)
2683                         {
2684                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2685                                 this.pain_finished = time + 0.5;
2686                         }
2687                 }
2688         }
2689 }
2690
2691 .bool move_qcphysics;
2692
2693 void Player_Physics(entity this)
2694 {
2695         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2696
2697         if(!this.move_qcphysics)
2698                 return;
2699
2700         if(!frametime && !CS(this).pm_frametime)
2701                 return;
2702
2703         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2704
2705         CS(this).pm_frametime = 0;
2706 }
2707
2708 /*
2709 =============
2710 PlayerPostThink
2711
2712 Called every frame for each client after the physics are run
2713 =============
2714 */
2715 void PlayerPostThink (entity this)
2716 {
2717         Player_Physics(this);
2718
2719         if (autocvar_sv_maxidle > 0)
2720         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2721         if (IS_REAL_CLIENT(this))
2722         if (IS_PLAYER(this) || autocvar_sv_maxidle_spectatorsareidle)
2723         {
2724                 int totalClients = 0;
2725                 if(autocvar_sv_maxidle_slots > 0)
2726                 {
2727                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2728                         {
2729                                 ++totalClients;
2730                         });
2731                 }
2732
2733                 if (autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2734                 { /* do nothing */ }
2735                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2736                 {
2737                         if (CS(this).idlekick_lasttimeleft)
2738                         {
2739                                 CS(this).idlekick_lasttimeleft = 0;
2740                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2741                         }
2742                 }
2743                 else
2744                 {
2745                         float timeleft = ceil(autocvar_sv_maxidle - (time - CS(this).parm_idlesince));
2746                         if (timeleft == min(10, autocvar_sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2747                                 if (!CS(this).idlekick_lasttimeleft)
2748                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2749                         }
2750                         if (timeleft <= 0) {
2751                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2752                                 dropclient(this);
2753                                 return;
2754                         }
2755                         else if (timeleft <= 10) {
2756                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2757                                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2758                                 CS(this).idlekick_lasttimeleft = timeleft;
2759                         }
2760                 }
2761         }
2762
2763         CheatFrame(this);
2764
2765         if (game_stopped)
2766         {
2767                 this.solid = SOLID_NOT;
2768                 this.takedamage = DAMAGE_NO;
2769                 set_movetype(this, MOVETYPE_NONE);
2770                 CS(this).teamkill_complain = 0;
2771                 CS(this).teamkill_soundtime = 0;
2772                 CS(this).teamkill_soundsource = NULL;
2773         }
2774
2775         if (IS_PLAYER(this)) {
2776                 if(this.death_time == time && IS_DEAD(this))
2777                 {
2778                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2779                         // once all the damage events of this frame have been processed with normal size
2780                         this.maxs.z = 5;
2781                         setsize(this, this.mins, this.maxs);
2782                 }
2783                 DrownPlayer(this);
2784                 UpdateChatBubble(this);
2785                 if (CS(this).impulse) ImpulseCommands(this);
2786                 if (game_stopped)
2787                 {
2788                         CSQCMODEL_AUTOUPDATE(this);
2789                         return;
2790                 }
2791                 GetPressedKeys(this);
2792         }
2793         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2794         {
2795                 CS(this).pressedkeys = 0;
2796                 STAT(PRESSED_KEYS, this) = 0;
2797         }
2798
2799         if (this.waypointsprite_attachedforcarrier) {
2800                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2801                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2802         }
2803
2804         CSQCMODEL_AUTOUPDATE(this);
2805 }
2806
2807 // hack to copy the button fields from the client entity to the Client State
2808 void PM_UpdateButtons(entity this, entity store)
2809 {
2810         if(this.impulse)
2811                 store.impulse = this.impulse;
2812         this.impulse = 0;
2813
2814         bool typing = this.buttonchat || this.button12;
2815
2816         store.button0 = (typing) ? 0 : this.button0;
2817         //button1?!
2818         store.button2 = (typing) ? 0 : this.button2;
2819         store.button3 = (typing) ? 0 : this.button3;
2820         store.button4 = this.button4;
2821         store.button5 = (typing) ? 0 : this.button5;
2822         store.button6 = this.button6;
2823         store.button7 = this.button7;
2824         store.button8 = this.button8;
2825         store.button9 = this.button9;
2826         store.button10 = this.button10;
2827         store.button11 = this.button11;
2828         store.button12 = this.button12;
2829         store.button13 = this.button13;
2830         store.button14 = this.button14;
2831         store.button15 = this.button15;
2832         store.button16 = this.button16;
2833         store.buttonuse = this.buttonuse;
2834         store.buttonchat = this.buttonchat;
2835
2836         store.cursor_active = this.cursor_active;
2837         store.cursor_screen = this.cursor_screen;
2838         store.cursor_trace_start = this.cursor_trace_start;
2839         store.cursor_trace_endpos = this.cursor_trace_endpos;
2840         store.cursor_trace_ent = this.cursor_trace_ent;
2841
2842         store.ping = this.ping;
2843         store.ping_packetloss = this.ping_packetloss;
2844         store.ping_movementloss = this.ping_movementloss;
2845
2846         store.v_angle = this.v_angle;
2847         store.movement = this.movement;
2848 }
2849
2850 NET_HANDLE(fpsreport, bool)
2851 {
2852         int fps = ReadShort();
2853         PlayerScore_Set(sender, SP_FPS, fps);
2854         return true;
2855 }