qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "clientkill.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include "race.qh"
  24 #include "antilag.qh"
  25 #include "campaign.qh"
  26 #include "command/common.qh"
  27 #include "scores_rules.qh"
  28
  29 #include "bot/api.qh"
  30
  31 #include "../common/ent_cs.qh"
  32 #include "../common/wepent.qh"
  33 #include <common/state.qh>
  34
  35 #include "compat/quake3.qh"
  36
  37 #include <common/effects/qc/globalsound.qh>
  38
  39 #include "../common/mapobjects/func/conveyor.qh"
  40 #include "../common/mapobjects/teleporters.qh"
  41 #include "../common/mapobjects/target/spawnpoint.qh"
  42 #include <common/mapobjects/trigger/counter.qh>
  43
  44 #include "../common/vehicles/all.qh"
  45
  46 #include "weapons/hitplot.qh"
  47 #include "weapons/weaponsystem.qh"
  48
  49 #include "../common/net_notice.qh"
  50 #include "../common/net_linked.qh"
  51 #include "../common/physics/player.qh"
  52
  53 #include <common/vehicles/sv_vehicles.qh>
  54
  55 #include "../common/items/_mod.qh"
  56
  57 #include "../common/mutators/mutator/waypoints/all.qh"
  58 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  59 #include <common/gamemodes/_mod.qh>
  60
  61 #include "../common/mapobjects/subs.qh"
  62 #include "../common/mapobjects/triggers.qh"
  63 #include "../common/mapobjects/trigger/secret.qh"
  64
  65 #include "../common/minigames/sv_minigames.qh"
  66
  67 #include "../common/items/inventory.qh"
  68
  69 #include "../common/monsters/sv_monsters.qh"
  70
  71 #include "../lib/warpzone/server.qh"
  72
  73 #include <common/mutators/mutator/overkill/oknex.qh>
  74
  75 STATIC_METHOD(Client, Add, void(Client this, int _team))
  76 {
  77     ClientConnect(this);
  78     TRANSMUTE(Player, this);
  79     this.frame = 12; // 7
  80     this.team = _team;
  81     PutClientInServer(this);
  82 }
  83
  84 STATIC_METHOD(Client, Remove, void(Client this))
  85 {
  86     TRANSMUTE(Observer, this);
  87     PutClientInServer(this);
  88     ClientDisconnect(this);
  89 }
  90
  91 void send_CSQC_teamnagger() {
  92         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  93 }
  94
  95 int CountSpectators(entity player, entity to)
  96 {
  97         if(!player) { return 0; } // not sure how, but best to be safe
  98
  99         int spec_count = 0;
 100
 101         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 102         {
 103                 spec_count++;
 104         });
 105
 106         return spec_count;
 107 }
 108
 109 void WriteSpectators(entity player, entity to)
 110 {
 111         if(!player) { return; } // not sure how, but best to be safe
 112
 113         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 114         {
 115                 WriteByte(MSG_ENTITY, num_for_edict(it));
 116         });
 117 }
 118
 119 bool ClientData_Send(entity this, entity to, int sf)
 120 {
 121         assert(to == this.owner, return false);
 122
 123         entity e = to;
 124         if (IS_SPEC(e)) e = e.enemy;
 125
 126         sf = 0;
 127         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 128         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 129         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 130         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 131
 132         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 133         WriteByte(MSG_ENTITY, sf);
 134
 135         if (sf & BIT(1))
 136                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 137
 138         if(sf & BIT(4))
 139         {
 140                 float specs = CountSpectators(e, to);
 141                 WriteByte(MSG_ENTITY, specs);
 142                 WriteSpectators(e, to);
 143         }
 144
 145         return true;
 146 }
 147
 148 void ClientData_Attach(entity this)
 149 {
 150         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 151         CS(this).clientdata.drawonlytoclient = this;
 152         CS(this).clientdata.owner = this;
 153 }
 154
 155 void ClientData_Detach(entity this)
 156 {
 157         delete(CS(this).clientdata);
 158         CS(this).clientdata = NULL;
 159 }
 160
 161 void ClientData_Touch(entity e)
 162 {
 163         entity cd = CS(e).clientdata;
 164         if (cd) { cd.SendFlags = 1; }
 165
 166         // make it spectatable
 167         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 168         {
 169                 entity cd = CS(it).clientdata;
 170                 if (cd) { cd.SendFlags = 1; }
 171         });
 172 }
 173
 174
 175 /*
 176 =============
 177 CheckPlayerModel
 178
 179 Checks if the argument string can be a valid playermodel.
 180 Returns a valid one in doubt.
 181 =============
 182 */
 183 string FallbackPlayerModel;
 184 string CheckPlayerModel(string plyermodel) {
 185         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 186         {
 187                 // note: we cannot summon Don Strunzone here, some player may
 188                 // still have the model string set. In case anyone manages how
 189                 // to change a cvar default, we'll have a small leak here.
 190                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 191         }
 192         // only in right path
 193         if( substring(plyermodel,0,14) != "models/player/")
 194                 return FallbackPlayerModel;
 195         // only good file extensions
 196         if(substring(plyermodel,-4,4) != ".zym")
 197         if(substring(plyermodel,-4,4) != ".dpm")
 198         if(substring(plyermodel,-4,4) != ".iqm")
 199         if(substring(plyermodel,-4,4) != ".md3")
 200         if(substring(plyermodel,-4,4) != ".psk")
 201                 return FallbackPlayerModel;
 202         // forbid the LOD models
 203         if(substring(plyermodel, -9,5) == "_lod1")
 204                 return FallbackPlayerModel;
 205         if(substring(plyermodel, -9,5) == "_lod2")
 206                 return FallbackPlayerModel;
 207         if(plyermodel != strtolower(plyermodel))
 208                 return FallbackPlayerModel;
 209         // also, restrict to server models
 210         if(autocvar_sv_servermodelsonly)
 211         {
 212                 if(!fexists(plyermodel))
 213                         return FallbackPlayerModel;
 214         }
 215         return plyermodel;
 216 }
 217
 218 void setplayermodel(entity e, string modelname)
 219 {
 220         precache_model(modelname);
 221         _setmodel(e, modelname);
 222         player_setupanimsformodel(e);
 223         if(!autocvar_g_debug_globalsounds)
 224                 UpdatePlayerSounds(e);
 225 }
 226
 227 /** putting a client as observer in the server */
 228 void PutObserverInServer(entity this)
 229 {
 230     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 231         PlayerState_detach(this);
 232
 233         if (IS_PLAYER(this))
 234         {
 235                 if(GetResourceAmount(this, RESOURCE_HEALTH) >= 1)
 236                 {
 237                         // despawn effect
 238                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 239                 }
 240
 241                 // was a player, recount votes and ready status
 242                 if(IS_REAL_CLIENT(this))
 243                 {
 244                         if (vote_called) { VoteCount(false); }
 245                         ReadyCount();
 246                 }
 247     }
 248
 249     {
 250         entity spot = SelectSpawnPoint(this, true);
 251         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 252         this.angles = vec2(spot.angles);
 253         this.fixangle = true;
 254         // offset it so that the spectator spawns higher off the ground, looks better this way
 255         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 256         if (IS_REAL_CLIENT(this))
 257         {
 258             msg_entity = this;
 259             WriteByte(MSG_ONE, SVC_SETVIEW);
 260             WriteEntity(MSG_ONE, this);
 261         }
 262         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 263         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 264         if(!autocvar_g_debug_globalsounds)
 265         {
 266                 // needed for player sounds
 267                 this.model = "";
 268                 FixPlayermodel(this);
 269         }
 270         setmodel(this, MDL_Null);
 271         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 272         this.view_ofs = '0 0 0';
 273     }
 274
 275     RemoveGrapplingHooks(this);
 276         Portal_ClearAll(this);
 277         Unfreeze(this);
 278         SetSpectatee(this, NULL);
 279
 280         if (this.alivetime)
 281         {
 282                 if (!warmup_stage)
 283                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 284                 this.alivetime = 0;
 285         }
 286
 287         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 288
 289         WaypointSprite_PlayerDead(this);
 290
 291         if (CS(this).killcount != FRAGS_SPECTATOR)
 292         {
 293                 if(!game_stopped)
 294                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 295                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 296         }
 297
 298         accuracy_resend(this);
 299
 300         CS(this).spectatortime = time;
 301         if(this.bot_attack)
 302                 IL_REMOVE(g_bot_targets, this);
 303         this.bot_attack = false;
 304         if(this.monster_attack)
 305                 IL_REMOVE(g_monster_targets, this);
 306         this.monster_attack = false;
 307     STAT(HUD, this) = HUD_NORMAL;
 308         TRANSMUTE(Observer, this);
 309         this.iscreature = false;
 310         this.teleportable = TELEPORT_SIMPLE;
 311         if(this.damagedbycontents)
 312                 IL_REMOVE(g_damagedbycontents, this);
 313         this.damagedbycontents = false;
 314         SetResourceAmountExplicit(this, RESOURCE_HEALTH, FRAGS_SPECTATOR);
 315         SetSpectatee_status(this, etof(this));
 316         this.takedamage = DAMAGE_NO;
 317         this.solid = SOLID_NOT;
 318         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 319         this.flags = FL_CLIENT | FL_NOTARGET;
 320         this.effects = 0;
 321         SetResourceAmountExplicit(this, RESOURCE_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 322         this.pauserotarmor_finished = 0;
 323         this.pauserothealth_finished = 0;
 324         this.pauseregen_finished = 0;
 325         this.damageforcescale = 0;
 326         this.death_time = 0;
 327         this.respawn_flags = 0;
 328         this.respawn_time = 0;
 329         STAT(RESPAWN_TIME, this) = 0;
 330         this.alpha = 0;
 331         this.scale = 0;
 332         this.fade_time = 0;
 333         this.pain_frame = 0;
 334         this.pain_finished = 0;
 335         this.strength_finished = 0;
 336         this.invincible_finished = 0;
 337         this.superweapons_finished = 0;
 338         //this.dphitcontentsmask = 0;
 339         this.dphitcontentsmask = DPCONTENTS_SOLID;
 340         if (autocvar_g_playerclip_collisions)
 341                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 342         this.pushltime = 0;
 343         this.istypefrag = 0;
 344         setthink(this, func_null);
 345         this.nextthink = 0;
 346         this.deadflag = DEAD_NO;
 347         this.crouch = false;
 348         STAT(REVIVE_PROGRESS, this) = 0;
 349         this.revival_time = 0;
 350
 351         this.items = 0;
 352         STAT(WEAPONS, this) = '0 0 0';
 353         this.drawonlytoclient = this;
 354
 355         this.viewloc = NULL;
 356
 357         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 358
 359         this.weaponmodel = "";
 360         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 361         {
 362                 this.weaponentities[slot] = NULL;
 363         }
 364         this.exteriorweaponentity = NULL;
 365         CS(this).killcount = FRAGS_SPECTATOR;
 366         this.velocity = '0 0 0';
 367         this.avelocity = '0 0 0';
 368         this.punchangle = '0 0 0';
 369         this.punchvector = '0 0 0';
 370         this.oldvelocity = this.velocity;
 371         this.fire_endtime = -1;
 372         this.event_damage = func_null;
 373         this.event_heal = func_null;
 374
 375         for(int slot = 0; slot < MAX_AXH; ++slot)
 376         {
 377                 entity axh = this.(AuxiliaryXhair[slot]);
 378                 this.(AuxiliaryXhair[slot]) = NULL;
 379
 380                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 381                         delete(axh);
 382         }
 383
 384         if (mutator_returnvalue)
 385         {
 386                 // mutator prevents resetting teams+score
 387         }
 388         else
 389         {
 390                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 391                 this.frags = FRAGS_SPECTATOR;
 392     }
 393 }
 394
 395 int player_getspecies(entity this)
 396 {
 397         get_model_parameters(this.model, this.skin);
 398         int s = get_model_parameters_species;
 399         get_model_parameters(string_null, 0);
 400         if (s < 0) return SPECIES_HUMAN;
 401         return s;
 402 }
 403
 404 .float model_randomizer;
 405 void FixPlayermodel(entity player)
 406 {
 407         string defaultmodel = "";
 408         int defaultskin = 0;
 409         if(autocvar_sv_defaultcharacter)
 410         {
 411                 if(teamplay)
 412                 {
 413                         switch(player.team)
 414                         {
 415                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 416                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 417                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 418                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 419                         }
 420                 }
 421
 422                 if(defaultmodel == "")
 423                 {
 424                         defaultmodel = autocvar_sv_defaultplayermodel;
 425                         defaultskin = autocvar_sv_defaultplayerskin;
 426                 }
 427
 428                 int n = tokenize_console(defaultmodel);
 429                 if(n > 0)
 430                 {
 431                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 432                         // However, do NOT randomize if the player-selected model is in the list.
 433                         for (int i = 0; i < n; ++i)
 434                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 435                                         defaultmodel = argv(i);
 436                 }
 437
 438                 int i = strstrofs(defaultmodel, ":", 0);
 439                 if(i >= 0)
 440                 {
 441                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 442                         defaultmodel = substring(defaultmodel, 0, i);
 443                 }
 444         }
 445         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 446         {
 447                 if(teamplay)
 448                 {
 449                         switch(player.team)
 450                         {
 451                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 452                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 453                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 454                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 455                         }
 456                 }
 457
 458                 if(!defaultskin)
 459                         defaultskin = autocvar_sv_defaultplayerskin;
 460         }
 461
 462         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 463         defaultmodel = M_ARGV(0, string);
 464         defaultskin = M_ARGV(1, int);
 465
 466         bool chmdl = false;
 467         int oldskin;
 468         if(defaultmodel != "")
 469         {
 470                 if (defaultmodel != player.model)
 471                 {
 472                         vector m1 = player.mins;
 473                         vector m2 = player.maxs;
 474                         setplayermodel (player, defaultmodel);
 475                         setsize (player, m1, m2);
 476                         chmdl = true;
 477                 }
 478
 479                 oldskin = player.skin;
 480                 player.skin = defaultskin;
 481         } else {
 482                 if (player.playermodel != player.model || player.playermodel == "")
 483                 {
 484                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 485                         vector m1 = player.mins;
 486                         vector m2 = player.maxs;
 487                         setplayermodel (player, player.playermodel);
 488                         setsize (player, m1, m2);
 489                         chmdl = true;
 490                 }
 491
 492                 if(!autocvar_sv_defaultcharacterskin)
 493                 {
 494                         oldskin = player.skin;
 495                         player.skin = stof(player.playerskin);
 496                 }
 497                 else
 498                 {
 499                         oldskin = player.skin;
 500                         player.skin = defaultskin;
 501                 }
 502         }
 503
 504         if(chmdl || oldskin != player.skin) // model or skin has changed
 505         {
 506                 player.species = player_getspecies(player); // update species
 507                 if(!autocvar_g_debug_globalsounds)
 508                         UpdatePlayerSounds(player); // update skin sounds
 509         }
 510
 511         if(!teamplay)
 512                 if(strlen(autocvar_sv_defaultplayercolors))
 513                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 514                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 515 }
 516
 517 void PutPlayerInServer(entity this)
 518 {
 519         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 520
 521         PlayerState_attach(this);
 522         accuracy_resend(this);
 523
 524         if (this.team < 0)
 525                 TeamBalance_JoinBestTeam(this);
 526
 527         entity spot = SelectSpawnPoint(this, false);
 528         if (!spot) {
 529                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 530                 return; // spawn failed
 531         }
 532
 533         TRANSMUTE(Player, this);
 534
 535         CS(this).wasplayer = true;
 536         this.iscreature = true;
 537         this.teleportable = TELEPORT_NORMAL;
 538         if(!this.damagedbycontents)
 539                 IL_PUSH(g_damagedbycontents, this);
 540         this.damagedbycontents = true;
 541         set_movetype(this, MOVETYPE_WALK);
 542         this.solid = SOLID_SLIDEBOX;
 543         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 544         if (autocvar_g_playerclip_collisions)
 545                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 546         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 547                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 548         this.frags = FRAGS_PLAYER;
 549         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 550         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 551         if (autocvar__notarget)
 552                 this.flags |= FL_NOTARGET;
 553         this.takedamage = DAMAGE_AIM;
 554         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 555
 556         if (warmup_stage) {
 557                 SetResourceAmount(this, RESOURCE_SHELLS, warmup_start_ammo_shells);
 558                 SetResourceAmount(this, RESOURCE_BULLETS, warmup_start_ammo_nails);
 559                 SetResourceAmount(this, RESOURCE_ROCKETS, warmup_start_ammo_rockets);
 560                 SetResourceAmount(this, RESOURCE_CELLS, warmup_start_ammo_cells);
 561                 SetResourceAmount(this, RESOURCE_PLASMA, warmup_start_ammo_plasma);
 562                 SetResourceAmount(this, RESOURCE_FUEL, warmup_start_ammo_fuel);
 563                 SetResourceAmount(this, RESOURCE_HEALTH, warmup_start_health);
 564                 SetResourceAmount(this, RESOURCE_ARMOR, warmup_start_armorvalue);
 565                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 566         } else {
 567                 SetResourceAmount(this, RESOURCE_SHELLS, start_ammo_shells);
 568                 SetResourceAmount(this, RESOURCE_BULLETS, start_ammo_nails);
 569                 SetResourceAmount(this, RESOURCE_ROCKETS, start_ammo_rockets);
 570                 SetResourceAmount(this, RESOURCE_CELLS, start_ammo_cells);
 571                 SetResourceAmount(this, RESOURCE_PLASMA, start_ammo_plasma);
 572                 SetResourceAmount(this, RESOURCE_FUEL, start_ammo_fuel);
 573                 SetResourceAmount(this, RESOURCE_HEALTH, start_health);
 574                 SetResourceAmount(this, RESOURCE_ARMOR, start_armorvalue);
 575                 STAT(WEAPONS, this) = start_weapons;
 576                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 577                 {
 578                         GiveRandomWeapons(this, random_start_weapons_count,
 579                                 autocvar_g_random_start_weapons, random_start_ammo);
 580                 }
 581         }
 582         SetSpectatee_status(this, 0);
 583
 584         PS(this).dual_weapons = '0 0 0';
 585
 586         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 587
 588         this.items = start_items;
 589
 590         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 591         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 592         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 593         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 594         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 595         if (!sv_ready_restart_after_countdown && time < game_starttime)
 596         {
 597                 float f = game_starttime - time;
 598                 this.spawnshieldtime += f;
 599                 this.pauserotarmor_finished += f;
 600                 this.pauserothealth_finished += f;
 601                 this.pauseregen_finished += f;
 602         }
 603
 604         this.damageforcescale = 2;
 605         this.death_time = 0;
 606         this.respawn_flags = 0;
 607         this.respawn_time = 0;
 608         STAT(RESPAWN_TIME, this) = 0;
 609         this.scale = autocvar_sv_player_scale;
 610         this.fade_time = 0;
 611         this.pain_frame = 0;
 612         this.pain_finished = 0;
 613         this.pushltime = 0;
 614         setthink(this, func_null); // players have no think function
 615         this.nextthink = 0;
 616         this.dmg_team = 0;
 617         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 618
 619         this.deadflag = DEAD_NO;
 620
 621         this.angles = spot.angles;
 622         this.angles_z = 0; // never spawn tilted even if the spot says to
 623         if (IS_BOT_CLIENT(this))
 624                 this.v_angle = this.angles;
 625         this.fixangle = true; // turn this way immediately
 626         this.oldvelocity = this.velocity = '0 0 0';
 627         this.avelocity = '0 0 0';
 628         this.punchangle = '0 0 0';
 629         this.punchvector = '0 0 0';
 630
 631         this.strength_finished = 0;
 632         this.invincible_finished = 0;
 633         this.fire_endtime = -1;
 634         STAT(REVIVE_PROGRESS, this) = 0;
 635         this.revival_time = 0;
 636
 637         this.air_finished = time + 12;
 638         this.waterlevel = WATERLEVEL_NONE;
 639         this.watertype = CONTENT_EMPTY;
 640
 641         entity spawnevent = new_pure(spawnevent);
 642         spawnevent.owner = this;
 643         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 644
 645         // Cut off any still running player sounds.
 646         stopsound(this, CH_PLAYER_SINGLE);
 647
 648         this.model = "";
 649         FixPlayermodel(this);
 650         this.drawonlytoclient = NULL;
 651
 652         this.viewloc = NULL;
 653
 654         for(int slot = 0; slot < MAX_AXH; ++slot)
 655         {
 656                 entity axh = this.(AuxiliaryXhair[slot]);
 657                 this.(AuxiliaryXhair[slot]) = NULL;
 658
 659                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 660                         delete(axh);
 661         }
 662
 663         this.spawnpoint_targ = NULL;
 664
 665         this.crouch = false;
 666         this.view_ofs = STAT(PL_VIEW_OFS, this);
 667         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 668         this.spawnorigin = spot.origin;
 669         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 670         // don't reset back to last position, even if new position is stuck in solid
 671         this.oldorigin = this.origin;
 672         if(this.conveyor)
 673                 IL_REMOVE(g_conveyed, this);
 674         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 675         STAT(HUD, this) = HUD_NORMAL;
 676
 677         this.event_damage = PlayerDamage;
 678         this.event_heal = PlayerHeal;
 679
 680         if(!this.bot_attack)
 681                 IL_PUSH(g_bot_targets, this);
 682         this.bot_attack = true;
 683         if(!this.monster_attack)
 684                 IL_PUSH(g_monster_targets, this);
 685         this.monster_attack = true;
 686         navigation_dynamicgoal_init(this, false);
 687
 688         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 689
 690         // player was spectator
 691         if (CS(this).killcount == FRAGS_SPECTATOR) {
 692                 PlayerScore_Clear(this);
 693                 CS(this).killcount = 0;
 694                 CS(this).startplaytime = time;
 695         }
 696
 697         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 698         {
 699                 .entity weaponentity = weaponentities[slot];
 700                 entity oldwep = this.(weaponentity);
 701                 CL_SpawnWeaponentity(this, weaponentity);
 702                 if(oldwep && oldwep.owner == this)
 703                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 704         }
 705         this.alpha = default_player_alpha;
 706         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 707         this.exteriorweaponentity.alpha = default_weapon_alpha;
 708
 709         this.speedrunning = false;
 710
 711         this.counter_cnt = 0;
 712         this.fragsfilter_cnt = 0;
 713
 714         target_voicescript_clear(this);
 715
 716         // reset fields the weapons may use
 717         FOREACH(Weapons, true, {
 718                 it.wr_resetplayer(it, this);
 719                         // reload all reloadable weapons
 720                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 721                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 722                         {
 723                                 .entity weaponentity = weaponentities[slot];
 724                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 725                         }
 726                 }
 727         });
 728
 729         {
 730                 //string s = spot.target;
 731                 //spot.target = string_null;
 732                 SUB_UseTargets(spot, this, NULL);
 733                 //spot.target = s;
 734         }
 735
 736         Unfreeze(this);
 737
 738         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 739
 740         if (autocvar_spawn_debug)
 741         {
 742                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 743                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 744         }
 745
 746         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 747         {
 748                 .entity weaponentity = weaponentities[slot];
 749                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 750                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 751                 else
 752                         this.(weaponentity).m_switchweapon = WEP_Null;
 753                 this.(weaponentity).m_weapon = WEP_Null;
 754                 this.(weaponentity).weaponname = "";
 755                 this.(weaponentity).m_switchingweapon = WEP_Null;
 756                 this.(weaponentity).cnt = -1;
 757         }
 758
 759         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 760
 761         if (CS(this).impulse) ImpulseCommands(this);
 762
 763         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 764         {
 765                 .entity weaponentity = weaponentities[slot];
 766                 W_WeaponFrame(this, weaponentity);
 767         }
 768
 769         if (!warmup_stage && !this.alivetime)
 770                 this.alivetime = time;
 771
 772         antilag_clear(this, CS(this));
 773 }
 774
 775 /** Called when a client spawns in the server */
 776 void PutClientInServer(entity this)
 777 {
 778         if (IS_BOT_CLIENT(this)) {
 779                 TRANSMUTE(Player, this);
 780         } else if (IS_REAL_CLIENT(this)) {
 781                 msg_entity = this;
 782                 WriteByte(MSG_ONE, SVC_SETVIEW);
 783                 WriteEntity(MSG_ONE, this);
 784         }
 785         if (game_stopped)
 786                 TRANSMUTE(Observer, this);
 787
 788         SetSpectatee(this, NULL);
 789
 790         // reset player keys
 791         if(PS(this))
 792                 PS(this).itemkeys = 0;
 793
 794         MUTATOR_CALLHOOK(PutClientInServer, this);
 795
 796         if (IS_OBSERVER(this)) {
 797                 PutObserverInServer(this);
 798         } else if (IS_PLAYER(this)) {
 799                 PutPlayerInServer(this);
 800         }
 801 }
 802
 803 // TODO do we need all these fields, or should we stop autodetecting runtime
 804 // changes and just have a console command to update this?
 805 bool ClientInit_SendEntity(entity this, entity to, int sf)
 806 {
 807         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 808         return = true;
 809         msg_entity = to;
 810         // MSG_INIT replacement
 811         // TODO: make easier to use
 812         Registry_send_all();
 813         W_PROP_reload(MSG_ONE, to);
 814         ClientInit_misc(this);
 815         MUTATOR_CALLHOOK(Ent_Init);
 816 }
 817 void ClientInit_misc(entity this)
 818 {
 819         int channel = MSG_ONE;
 820         WriteHeader(channel, ENT_CLIENT_INIT);
 821         WriteByte(channel, g_nexball_meter_period * 32);
 822         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 823         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 824         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 825         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 826         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 827         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 828         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 829         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 830
 831         if(sv_foginterval && world.fog != "")
 832                 WriteString(channel, world.fog);
 833         else
 834                 WriteString(channel, "");
 835         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 836         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 837         WriteByte(channel, serverflags);
 838         WriteCoord(channel, autocvar_g_trueaim_minrange);
 839 }
 840
 841 void ClientInit_CheckUpdate(entity this)
 842 {
 843         this.nextthink = time;
 844         if(this.count != autocvar_g_balance_armor_blockpercent)
 845         {
 846                 this.count = autocvar_g_balance_armor_blockpercent;
 847                 this.SendFlags |= 1;
 848         }
 849         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 850         {
 851                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 852                 this.SendFlags |= 1;
 853         }
 854 }
 855
 856 void ClientInit_Spawn()
 857 {
 858         entity e = new_pure(clientinit);
 859         setthink(e, ClientInit_CheckUpdate);
 860         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 861
 862         ClientInit_CheckUpdate(e);
 863 }
 864
 865 /*
 866 =============
 867 SetNewParms
 868 =============
 869 */
 870 void SetNewParms ()
 871 {
 872         // initialize parms for a new player
 873         parm1 = -(86400 * 366);
 874
 875         MUTATOR_CALLHOOK(SetNewParms);
 876 }
 877
 878 /*
 879 =============
 880 SetChangeParms
 881 =============
 882 */
 883 void SetChangeParms (entity this)
 884 {
 885         // save parms for level change
 886         parm1 = CS(this).parm_idlesince - time;
 887
 888         MUTATOR_CALLHOOK(SetChangeParms);
 889 }
 890
 891 /*
 892 =============
 893 DecodeLevelParms
 894 =============
 895 */
 896 void DecodeLevelParms(entity this)
 897 {
 898         // load parms
 899         CS(this).parm_idlesince = parm1;
 900         if (CS(this).parm_idlesince == -(86400 * 366))
 901                 CS(this).parm_idlesince = time;
 902
 903         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 904         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 905
 906         MUTATOR_CALLHOOK(DecodeLevelParms);
 907 }
 908
 909 void FixClientCvars(entity e)
 910 {
 911         // send prediction settings to the client
 912         stuffcmd(e, "\nin_bindmap 0 0\n");
 913         if(autocvar_g_antilag == 3) // client side hitscan
 914                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 915         if(autocvar_sv_gentle)
 916                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 917
 918         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 919         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 920
 921         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 922
 923         MUTATOR_CALLHOOK(FixClientCvars, e);
 924 }
 925
 926 bool findinlist_abbrev(string tofind, string list)
 927 {
 928         if(list == "" || tofind == "")
 929                 return false; // empty list or search, just return
 930
 931         // this function allows abbreviated strings!
 932         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 933         {
 934                 return true;
 935         });
 936
 937         return false;
 938 }
 939
 940 bool PlayerInIPList(entity p, string iplist)
 941 {
 942         // some safety checks (never allow local?)
 943         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 944                 return false;
 945
 946         return findinlist_abbrev(p.netaddress, iplist);
 947 }
 948
 949 bool PlayerInIDList(entity p, string idlist)
 950 {
 951         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 952         if(!p.crypto_idfp)
 953                 return false;
 954
 955         return findinlist_abbrev(p.crypto_idfp, idlist);
 956 }
 957
 958 bool PlayerInList(entity player, string list)
 959 {
 960         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 961 }
 962
 963 #ifdef DP_EXT_PRECONNECT
 964 /*
 965 =============
 966 ClientPreConnect
 967
 968 Called once (not at each match start) when a client begins a connection to the server
 969 =============
 970 */
 971 void ClientPreConnect(entity this)
 972 {
 973         if(autocvar_sv_eventlog)
 974         {
 975                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 976                         this.playerid,
 977                         etof(this),
 978                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
 979                 ));
 980         }
 981 }
 982 #endif
 983
 984 string GetClientVersionMessage(entity this)
 985 {
 986         if (CS(this).version_mismatch) {
 987                 if(CS(this).version < autocvar_gameversion) {
 988                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
 989                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
 990                 } else {
 991                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
 992                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
 993                 }
 994         } else {
 995                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
 996         }
 997 }
 998
 999 string getwelcomemessage(entity this)
1000 {
1001         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1002         string modifications = M_ARGV(0, string);
1003
1004         if(g_weaponarena)
1005         {
1006                 if(g_weaponarena_random)
1007                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1008                 else
1009                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1010         }
1011         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1012                 modifications = strcat(modifications, ", No start weapons");
1013         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1014                 modifications = strcat(modifications, ", Low gravity");
1015         if(g_weapon_stay && !g_cts)
1016                 modifications = strcat(modifications, ", Weapons stay");
1017         if(g_jetpack)
1018                 modifications = strcat(modifications, ", Jet pack");
1019         if(autocvar_g_powerups == 0)
1020                 modifications = strcat(modifications, ", No powerups");
1021         if(autocvar_g_powerups > 0)
1022                 modifications = strcat(modifications, ", Powerups");
1023         modifications = substring(modifications, 2, strlen(modifications) - 2);
1024
1025         string versionmessage = GetClientVersionMessage(this);
1026         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1027
1028         if(modifications != "")
1029                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1030
1031         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1032         {
1033                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1034                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1035         }
1036
1037         if (cache_mutatormsg != "") {
1038                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1039         }
1040
1041         string mutator_msg = "";
1042         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1043         mutator_msg = M_ARGV(0, string);
1044
1045         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1046
1047         string motd = autocvar_sv_motd;
1048         if (motd != "") {
1049                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1050         }
1051         return s;
1052 }
1053
1054 /**
1055 =============
1056 ClientConnect
1057
1058 Called when a client connects to the server
1059 =============
1060 */
1061 void ClientConnect(entity this)
1062 {
1063         if (Ban_MaybeEnforceBanOnce(this)) return;
1064         assert(!IS_CLIENT(this), return);
1065         this.flags |= FL_CLIENT;
1066         assert(player_count >= 0, player_count = 0);
1067
1068 #ifdef WATERMARK
1069         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1070 #endif
1071         TRANSMUTE(Client, this);
1072         CS(this).version_nagtime = time + 10 + random() * 10;
1073
1074         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1075
1076         bot_clientconnect(this);
1077
1078         Player_DetermineForcedTeam(this);
1079
1080         TRANSMUTE(Observer, this);
1081
1082         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1083
1084         // always track bots, don't ask for cl_allow_uidtracking
1085         if (IS_BOT_CLIENT(this))
1086                 PlayerStats_GameReport_AddPlayer(this);
1087         else
1088                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1089
1090         if (autocvar_sv_eventlog)
1091                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1092
1093         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1094
1095         stuffcmd(this, clientstuff, "\n");
1096         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1097
1098         FixClientCvars(this);
1099
1100         // get version info from player
1101         stuffcmd(this, "cmd clientversion $gameversion\n");
1102
1103         // notify about available teams
1104         if (teamplay)
1105         {
1106                 entity balance = TeamBalance_CheckAllowedTeams(this);
1107                 int t = TeamBalance_GetAllowedTeams(balance);
1108                 TeamBalance_Destroy(balance);
1109                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1110         }
1111         else
1112         {
1113                 stuffcmd(this, "set _teams_available 0\n");
1114         }
1115
1116         bot_relinkplayerlist();
1117
1118         CS(this).spectatortime = time;
1119         if (blockSpectators)
1120         {
1121                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1122         }
1123
1124         CS(this).jointime = time;
1125
1126         if (IS_REAL_CLIENT(this))
1127         {
1128                 if (g_weaponarena_weapons == WEPSET(TUBA))
1129                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1130         }
1131
1132         if (!sv_foginterval && world.fog != "")
1133                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1134
1135         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1136                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1137                         send_CSQC_teamnagger();
1138
1139         CSQCMODEL_AUTOINIT(this);
1140
1141         CS(this).model_randomizer = random();
1142
1143         if (IS_REAL_CLIENT(this))
1144                 sv_notice_join(this);
1145
1146         this.move_qcphysics = true;
1147
1148         // update physics stats (players can spawn before physics runs)
1149         Physics_UpdateStats(this);
1150
1151         IL_EACH(g_initforplayer, it.init_for_player, {
1152                 it.init_for_player(it, this);
1153         });
1154
1155         Handicap_Initialize(this);
1156
1157         MUTATOR_CALLHOOK(ClientConnect, this);
1158
1159         if (IS_REAL_CLIENT(this))
1160         {
1161                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1162                 {
1163                         CS(this).motd_actived_time = -1;
1164                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1165                 }
1166         }
1167 }
1168 /*
1169 =============
1170 ClientDisconnect
1171
1172 Called when a client disconnects from the server
1173 =============
1174 */
1175 .entity chatbubbleentity;
1176 void ClientDisconnect(entity this)
1177 {
1178         assert(IS_CLIENT(this), return);
1179
1180         PlayerStats_GameReport_FinalizePlayer(this);
1181         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1182         if (CS(this).active_minigame) part_minigame(this);
1183         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1184
1185         if (autocvar_sv_eventlog)
1186                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1187
1188         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1189
1190         if(IS_SPEC(this))
1191                 SetSpectatee(this, NULL);
1192
1193     MUTATOR_CALLHOOK(ClientDisconnect, this);
1194
1195         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1196         strfree(CS(this).weaponorder_byimpulse);
1197         ClientState_detach(this);
1198
1199         Portal_ClearAll(this);
1200
1201         Unfreeze(this);
1202
1203         RemoveGrapplingHooks(this);
1204
1205         // Here, everything has been done that requires this player to be a client.
1206
1207         this.flags &= ~FL_CLIENT;
1208
1209         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1210         if (this.killindicator) delete(this.killindicator);
1211
1212         WaypointSprite_PlayerGone(this);
1213
1214         bot_relinkplayerlist();
1215
1216         strfree(this.clientstatus);
1217         if (this.personal) delete(this.personal);
1218
1219         this.playerid = 0;
1220         ReadyCount();
1221         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1222
1223         ONREMOVE(this);
1224 }
1225
1226 void ChatBubbleThink(entity this)
1227 {
1228         this.nextthink = time;
1229         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1230         {
1231                 if(this.owner) // but why can that ever be NULL?
1232                         this.owner.chatbubbleentity = NULL;
1233                 delete(this);
1234                 return;
1235         }
1236
1237         this.mdl = "";
1238
1239         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1240         {
1241                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1242                         this.mdl = "models/sprites/minigame_busy.iqm";
1243                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1244                         this.mdl = "models/misc/chatbubble.spr";
1245         }
1246
1247         if ( this.model != this.mdl )
1248                 _setmodel(this, this.mdl);
1249
1250 }
1251
1252 void UpdateChatBubble(entity this)
1253 {
1254         if (this.alpha < 0)
1255                 return;
1256         // spawn a chatbubble entity if needed
1257         if (!this.chatbubbleentity)
1258         {
1259                 this.chatbubbleentity = new(chatbubbleentity);
1260                 this.chatbubbleentity.owner = this;
1261                 this.chatbubbleentity.exteriormodeltoclient = this;
1262                 setthink(this.chatbubbleentity, ChatBubbleThink);
1263                 this.chatbubbleentity.nextthink = time;
1264                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1265                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1266                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1267                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1268                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1269                 //this.chatbubbleentity.model = "";
1270                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1271         }
1272 }
1273
1274
1275 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1276 // added to the model skins
1277 /*void UpdateColorModHack()
1278 {
1279         float c;
1280         c = this.clientcolors & 15;
1281         // LordHavoc: only bothering to support white, green, red, yellow, blue
1282              if (!teamplay) this.colormod = '0 0 0';
1283         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1284         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1285         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1286         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1287         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1288         else this.colormod = '1 1 1';
1289 }*/
1290
1291 void respawn(entity this)
1292 {
1293         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1294         {
1295                 this.solid = SOLID_NOT;
1296                 this.takedamage = DAMAGE_NO;
1297                 set_movetype(this, MOVETYPE_FLY);
1298                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1299                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1300                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1301                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1302                 if(autocvar_g_respawn_ghosts_maxtime)
1303                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1304         }
1305
1306         CopyBody(this, 1);
1307
1308         this.effects |= EF_NODRAW; // prevent another CopyBody
1309         PutClientInServer(this);
1310 }
1311
1312 void PrintToChat(entity client, string text)
1313 {
1314         text = strcat("\{1}^7", text, "\n");
1315         sprint(client, text);
1316 }
1317
1318 void DebugPrintToChat(entity client, string text)
1319 {
1320         if (autocvar_developer)
1321         {
1322                 PrintToChat(client, text);
1323         }
1324 }
1325
1326 void PrintToChatAll(string text)
1327 {
1328         text = strcat("\{1}^7", text, "\n");
1329         bprint(text);
1330 }
1331
1332 void DebugPrintToChatAll(string text)
1333 {
1334         if (autocvar_developer)
1335         {
1336                 PrintToChatAll(text);
1337         }
1338 }
1339
1340 void PrintToChatTeam(int team_num, string text)
1341 {
1342         text = strcat("\{1}^7", text, "\n");
1343         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1344         {
1345                 if (it.team == team_num)
1346                 {
1347                         sprint(it, text);
1348                 }
1349         });
1350 }
1351
1352 void DebugPrintToChatTeam(int team_num, string text)
1353 {
1354         if (autocvar_developer)
1355         {
1356                 PrintToChatTeam(team_num, text);
1357         }
1358 }
1359
1360 void play_countdown(entity this, float finished, Sound samp)
1361 {
1362         TC(Sound, samp);
1363         if(IS_REAL_CLIENT(this))
1364                 if(floor(finished - time - frametime) != floor(finished - time))
1365                         if(finished - time < 6)
1366                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1367 }
1368
1369 void player_powerups(entity this)
1370 {
1371         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1372         int items_prev = this.items;
1373
1374         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1375                 this.modelflags |= MF_ROCKET;
1376         else
1377                 this.modelflags &= ~MF_ROCKET;
1378
1379         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1380
1381         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1382                 return;
1383
1384         Fire_ApplyDamage(this);
1385         Fire_ApplyEffect(this);
1386
1387         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1388         {
1389                 if (this.items & ITEM_Strength.m_itemid)
1390                 {
1391                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1392                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1393                         if (time > this.strength_finished)
1394                         {
1395                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1396                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1397                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1398                         }
1399                 }
1400                 else
1401                 {
1402                         if (time < this.strength_finished)
1403                         {
1404                                 this.items = this.items | ITEM_Strength.m_itemid;
1405                                 if(!g_cts)
1406                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1407                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1408                         }
1409                 }
1410                 if (this.items & ITEM_Shield.m_itemid)
1411                 {
1412                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1413                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1414                         if (time > this.invincible_finished)
1415                         {
1416                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1417                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1418                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1419                         }
1420                 }
1421                 else
1422                 {
1423                         if (time < this.invincible_finished)
1424                         {
1425                                 this.items = this.items | ITEM_Shield.m_itemid;
1426                                 if(!g_cts)
1427                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1428                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1429                         }
1430                 }
1431                 if (this.items & IT_SUPERWEAPON)
1432                 {
1433                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1434                         {
1435                                 this.superweapons_finished = 0;
1436                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1437                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1438                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1439                         }
1440                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1441                         {
1442                                 // don't let them run out
1443                         }
1444                         else
1445                         {
1446                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1447                                 if (time > this.superweapons_finished)
1448                                 {
1449                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1450                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1451                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1452                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1453                                 }
1454                         }
1455                 }
1456                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1457                 {
1458                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1459                         {
1460                                 this.items = this.items | IT_SUPERWEAPON;
1461                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1462                                 {
1463                                         if(!g_cts)
1464                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1465                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1466                                 }
1467                         }
1468                         else
1469                         {
1470                                 this.superweapons_finished = 0;
1471                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1472                         }
1473                 }
1474                 else
1475                 {
1476                         this.superweapons_finished = 0;
1477                 }
1478         }
1479
1480         if(autocvar_g_nodepthtestplayers)
1481                 this.effects = this.effects | EF_NODEPTHTEST;
1482
1483         if(autocvar_g_fullbrightplayers)
1484                 this.effects = this.effects | EF_FULLBRIGHT;
1485
1486         if (time >= game_starttime)
1487         if (time < this.spawnshieldtime)
1488                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1489
1490         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1491 }
1492
1493 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1494 {
1495         if(current > stable)
1496                 return current;
1497         else if(current > stable - 0.25) // when close enough, "snap"
1498                 return stable;
1499         else
1500                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1501 }
1502
1503 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1504 {
1505         if(current < stable)
1506                 return current;
1507         else if(current < stable + 0.25) // when close enough, "snap"
1508                 return stable;
1509         else
1510                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1511 }
1512
1513 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1514 {
1515         if(current > rotstable)
1516         {
1517                 if(rotframetime > 0)
1518                 {
1519                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1520                         current = max(rotstable, current - rotlinear * rotframetime);
1521                 }
1522         }
1523         else if(current < regenstable)
1524         {
1525                 if(regenframetime > 0)
1526                 {
1527                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1528                         current = min(regenstable, current + regenlinear * regenframetime);
1529                 }
1530         }
1531
1532         if(current > limit)
1533                 current = limit;
1534
1535         return current;
1536 }
1537
1538 void player_regen(entity this)
1539 {
1540         float max_mod, regen_mod, rot_mod, limit_mod;
1541         max_mod = regen_mod = rot_mod = limit_mod = 1;
1542
1543         float regen_health = autocvar_g_balance_health_regen;
1544         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1545         float regen_health_rot = autocvar_g_balance_health_rot;
1546         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1547         float regen_health_stable = autocvar_g_balance_health_regenstable;
1548         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1549         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1550                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1551         max_mod = M_ARGV(1, float);
1552         regen_mod = M_ARGV(2, float);
1553         rot_mod = M_ARGV(3, float);
1554         limit_mod = M_ARGV(4, float);
1555         regen_health = M_ARGV(5, float);
1556         regen_health_linear = M_ARGV(6, float);
1557         regen_health_rot = M_ARGV(7, float);
1558         regen_health_rotlinear = M_ARGV(8, float);
1559         regen_health_stable = M_ARGV(9, float);
1560         regen_health_rotstable = M_ARGV(10, float);
1561
1562         if(!mutator_returnvalue)
1563         if(!STAT(FROZEN, this))
1564         {
1565                 float mina, maxa, limith, limita;
1566                 maxa = autocvar_g_balance_armor_rotstable;
1567                 mina = autocvar_g_balance_armor_regenstable;
1568                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1569                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1570
1571                 regen_health_rotstable = regen_health_rotstable * max_mod;
1572                 regen_health_stable = regen_health_stable * max_mod;
1573                 limith = limith * limit_mod;
1574                 limita = limita * limit_mod;
1575
1576                 SetResourceAmount(this, RESOURCE_ARMOR, CalcRotRegen(GetResourceAmount(this, RESOURCE_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1577                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1578                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1579                 SetResourceAmount(this, RESOURCE_HEALTH, CalcRotRegen(GetResourceAmount(this, RESOURCE_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1580                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1581                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1582         }
1583
1584         // if player rotted to death...  die!
1585         // check this outside above checks, as player may still be able to rot to death
1586         if(GetResourceAmount(this, RESOURCE_HEALTH) < 1)
1587         {
1588                 if(this.vehicle)
1589                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1590                 if(this.event_damage)
1591                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1592         }
1593
1594         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1595         {
1596                 float minf, maxf, limitf;
1597
1598                 maxf = autocvar_g_balance_fuel_rotstable;
1599                 minf = autocvar_g_balance_fuel_regenstable;
1600                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1601
1602                 SetResourceAmount(this, RESOURCE_FUEL, CalcRotRegen(GetResourceAmount(this, RESOURCE_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1603                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1604                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1605         }
1606 }
1607
1608 bool zoomstate_set;
1609 void SetZoomState(entity this, float newzoom)
1610 {
1611         if(newzoom != CS(this).zoomstate)
1612         {
1613                 CS(this).zoomstate = newzoom;
1614                 ClientData_Touch(this);
1615         }
1616         zoomstate_set = true;
1617 }
1618
1619 void GetPressedKeys(entity this)
1620 {
1621         MUTATOR_CALLHOOK(GetPressedKeys, this);
1622         int keys = STAT(PRESSED_KEYS, this);
1623         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1624         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1625         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1626         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1627
1628         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1629         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1630         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1631         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1632         CS(this).pressedkeys = keys; // store for other users
1633
1634         STAT(PRESSED_KEYS, this) = keys;
1635 }
1636
1637 /*
1638 ======================
1639 spectate mode routines
1640 ======================
1641 */
1642
1643 void SpectateCopy(entity this, entity spectatee)
1644 {
1645         TC(Client, this); TC(Client, spectatee);
1646
1647         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1648         PS(this) = PS(spectatee);
1649         this.armortype = spectatee.armortype;
1650         SetResourceAmountExplicit(this, RESOURCE_ARMOR, GetResourceAmount(spectatee, RESOURCE_ARMOR));
1651         SetResourceAmountExplicit(this, RESOURCE_CELLS, GetResourceAmount(spectatee, RESOURCE_CELLS));
1652         SetResourceAmountExplicit(this, RESOURCE_PLASMA, GetResourceAmount(spectatee, RESOURCE_PLASMA));
1653         SetResourceAmountExplicit(this, RESOURCE_SHELLS, GetResourceAmount(spectatee, RESOURCE_SHELLS));
1654         SetResourceAmountExplicit(this, RESOURCE_BULLETS, GetResourceAmount(spectatee, RESOURCE_BULLETS));
1655         SetResourceAmountExplicit(this, RESOURCE_ROCKETS, GetResourceAmount(spectatee, RESOURCE_ROCKETS));
1656         SetResourceAmountExplicit(this, RESOURCE_FUEL, GetResourceAmount(spectatee, RESOURCE_FUEL));
1657         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1658         SetResourceAmountExplicit(this, RESOURCE_HEALTH, GetResourceAmount(spectatee, RESOURCE_HEALTH));
1659         CS(this).impulse = 0;
1660         this.items = spectatee.items;
1661         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1662         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1663         this.strength_finished = spectatee.strength_finished;
1664         this.invincible_finished = spectatee.invincible_finished;
1665         this.superweapons_finished = spectatee.superweapons_finished;
1666         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1667         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1668         this.punchangle = spectatee.punchangle;
1669         this.view_ofs = spectatee.view_ofs;
1670         this.velocity = spectatee.velocity;
1671         this.dmg_take = spectatee.dmg_take;
1672         this.dmg_save = spectatee.dmg_save;
1673         this.dmg_inflictor = spectatee.dmg_inflictor;
1674         this.v_angle = spectatee.v_angle;
1675         this.angles = spectatee.v_angle;
1676         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1677         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1678         this.viewloc = spectatee.viewloc;
1679         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1680                 this.fixangle = true;
1681         setorigin(this, spectatee.origin);
1682         setsize(this, spectatee.mins, spectatee.maxs);
1683         SetZoomState(this, CS(spectatee).zoomstate);
1684
1685     anticheat_spectatecopy(this, spectatee);
1686         STAT(HUD, this) = STAT(HUD, spectatee);
1687         if(spectatee.vehicle)
1688     {
1689         this.angles = spectatee.v_angle;
1690
1691         //this.fixangle = false;
1692         //this.velocity = spectatee.vehicle.velocity;
1693         this.vehicle_health = spectatee.vehicle_health;
1694         this.vehicle_shield = spectatee.vehicle_shield;
1695         this.vehicle_energy = spectatee.vehicle_energy;
1696         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1697         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1698         this.vehicle_reload1 = spectatee.vehicle_reload1;
1699         this.vehicle_reload2 = spectatee.vehicle_reload2;
1700
1701         //msg_entity = this;
1702
1703        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1704             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1705            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1706            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1707
1708         //WriteByte (MSG_ONE, SVC_SETVIEW);
1709         //    WriteEntity(MSG_ONE, this);
1710         //makevectors(spectatee.v_angle);
1711         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1712     }
1713 }
1714
1715 bool SpectateUpdate(entity this)
1716 {
1717         if(!this.enemy)
1718                 return false;
1719
1720         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1721         {
1722                 SetSpectatee(this, NULL);
1723                 return false;
1724         }
1725
1726         SpectateCopy(this, this.enemy);
1727
1728         return true;
1729 }
1730
1731 bool SpectateSet(entity this)
1732 {
1733         if(!IS_PLAYER(this.enemy))
1734                 return false;
1735
1736         ClientData_Touch(this.enemy);
1737
1738         msg_entity = this;
1739         WriteByte(MSG_ONE, SVC_SETVIEW);
1740         WriteEntity(MSG_ONE, this.enemy);
1741         set_movetype(this, MOVETYPE_NONE);
1742         accuracy_resend(this);
1743
1744         if(!SpectateUpdate(this))
1745                 PutObserverInServer(this);
1746
1747         return true;
1748 }
1749
1750 void SetSpectatee_status(entity this, int spectatee_num)
1751 {
1752         int oldspectatee_status = CS(this).spectatee_status;
1753         CS(this).spectatee_status = spectatee_num;
1754
1755         if (CS(this).spectatee_status != oldspectatee_status)
1756         {
1757                 ClientData_Touch(this);
1758                 if (g_race || g_cts) race_InitSpectator();
1759         }
1760 }
1761
1762 void SetSpectatee(entity this, entity spectatee)
1763 {
1764         if(IS_BOT_CLIENT(this))
1765                 return; // bots abuse .enemy, this code is useless to them
1766
1767         entity old_spectatee = this.enemy;
1768
1769         this.enemy = spectatee;
1770
1771         // WEAPONTODO
1772         // these are required to fix the spectator bug with arc
1773         if(old_spectatee)
1774         {
1775                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1776                 {
1777                         .entity weaponentity = weaponentities[slot];
1778                         if(old_spectatee.(weaponentity).arc_beam)
1779                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1780                 }
1781         }
1782         if(this.enemy)
1783         {
1784                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1785                 {
1786                         .entity weaponentity = weaponentities[slot];
1787                         if(this.enemy.(weaponentity).arc_beam)
1788                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1789                 }
1790         }
1791
1792         if (this.enemy)
1793                 SetSpectatee_status(this, etof(this.enemy));
1794
1795         // needed to update spectator list
1796         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1797 }
1798
1799 bool Spectate(entity this, entity pl)
1800 {
1801         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1802                 return false;
1803         pl = M_ARGV(1, entity);
1804
1805         SetSpectatee(this, pl);
1806         return SpectateSet(this);
1807 }
1808
1809 bool SpectateNext(entity this)
1810 {
1811         entity ent = find(this.enemy, classname, STR_PLAYER);
1812
1813         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1814                 ent = M_ARGV(1, entity);
1815         else if (!ent)
1816                 ent = find(ent, classname, STR_PLAYER);
1817
1818         if(ent) { SetSpectatee(this, ent); }
1819
1820         return SpectateSet(this);
1821 }
1822
1823 bool SpectatePrev(entity this)
1824 {
1825         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1826         entity ent = findchain(classname, STR_PLAYER);
1827         if (!ent) // no player
1828                 return false;
1829
1830         entity first = ent;
1831         // skip players until current spectated player
1832         if(this.enemy)
1833         while(ent && ent != this.enemy)
1834                 ent = ent.chain;
1835
1836         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1837         {
1838                 case MUT_SPECPREV_FOUND:
1839                     ent = M_ARGV(1, entity);
1840                     break;
1841                 case MUT_SPECPREV_RETURN:
1842                     return true;
1843                 case MUT_SPECPREV_CONTINUE:
1844                 default:
1845                 {
1846                         if(ent.chain)
1847                                 ent = ent.chain;
1848                         else
1849                                 ent = first;
1850                         break;
1851                 }
1852         }
1853
1854         SetSpectatee(this, ent);
1855         return SpectateSet(this);
1856 }
1857
1858 /*
1859 =============
1860 ShowRespawnCountdown()
1861
1862 Update a respawn countdown display.
1863 =============
1864 */
1865 void ShowRespawnCountdown(entity this)
1866 {
1867         float number;
1868         if(!IS_DEAD(this)) // just respawned?
1869                 return;
1870         else
1871         {
1872                 number = ceil(this.respawn_time - time);
1873                 if(number <= 0)
1874                         return;
1875                 if(number <= this.respawn_countdown)
1876                 {
1877                         this.respawn_countdown = number - 1;
1878                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1879                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1880                 }
1881         }
1882 }
1883
1884 .bool team_selected;
1885 bool ShowTeamSelection(entity this)
1886 {
1887         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1888                 return false;
1889         stuffcmd(this, "menu_showteamselect\n");
1890         return true;
1891 }
1892 void Join(entity this)
1893 {
1894         TRANSMUTE(Player, this);
1895
1896         if(!this.team_selected)
1897         if(autocvar_g_campaign || autocvar_g_balance_teams)
1898                 TeamBalance_JoinBestTeam(this);
1899
1900         if(autocvar_g_campaign)
1901                 campaign_bots_may_start = true;
1902
1903         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1904
1905         PutClientInServer(this);
1906
1907         if(IS_PLAYER(this))
1908         if(teamplay && this.team != -1)
1909         {
1910         }
1911         else
1912                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1913         this.team_selected = false;
1914 }
1915
1916 /**
1917  * Determines whether the player is allowed to join. This depends on cvar
1918  * g_maxplayers, if it isn't used this function always return true, otherwise
1919  * it checks whether the number of currently playing players exceeds g_maxplayers.
1920  * @return int number of free slots for players, 0 if none
1921  */
1922 int nJoinAllowed(entity this, entity ignore)
1923 {
1924         if(!ignore)
1925         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1926         // so report 0 free slots if restricted
1927         {
1928                 if(autocvar_g_forced_team_otherwise == "spectate")
1929                         return 0;
1930                 if(autocvar_g_forced_team_otherwise == "spectator")
1931                         return 0;
1932         }
1933
1934         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1935                 return 0; // forced spectators can never join
1936
1937         // TODO simplify this
1938         int totalClients = 0;
1939         int currentlyPlaying = 0;
1940         FOREACH_CLIENT(true, {
1941                 if(it != ignore)
1942                         ++totalClients;
1943                 if(IS_REAL_CLIENT(it))
1944                 if(IS_PLAYER(it) || it.caplayer)
1945                         ++currentlyPlaying;
1946         });
1947
1948         float free_slots = 0;
1949         if (!autocvar_g_maxplayers)
1950                 free_slots = maxclients - totalClients;
1951         else if(currentlyPlaying < autocvar_g_maxplayers)
1952                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1953
1954         static float join_prevent_msg_time = 0;
1955         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1956         {
1957                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1958                 join_prevent_msg_time = time + 3;
1959         }
1960
1961         return free_slots;
1962 }
1963
1964 /**
1965  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1966  * g_maxplayers_spectator_blocktime seconds
1967  */
1968 void checkSpectatorBlock(entity this)
1969 {
1970         if(IS_SPEC(this) || IS_OBSERVER(this))
1971         if(!this.caplayer)
1972         if(IS_REAL_CLIENT(this))
1973         {
1974                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1975                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1976                         dropclient(this);
1977                 }
1978         }
1979 }
1980
1981 void PrintWelcomeMessage(entity this)
1982 {
1983         if(CS(this).motd_actived_time == 0)
1984         {
1985                 if (autocvar_g_campaign) {
1986                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1987                                 CS(this).motd_actived_time = time;
1988                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1989                         }
1990                 } else {
1991                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1992                                 CS(this).motd_actived_time = time;
1993                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1994                         }
1995                 }
1996         }
1997         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
1998         {
1999                 if (autocvar_g_campaign) {
2000                         if (PHYS_INPUT_BUTTON_INFO(this))
2001                                 CS(this).motd_actived_time = time;
2002                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2003                                 CS(this).motd_actived_time = 0;
2004                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2005                         }
2006                 } else {
2007                         if (PHYS_INPUT_BUTTON_INFO(this))
2008                                 CS(this).motd_actived_time = time;
2009                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2010                                 CS(this).motd_actived_time = 0;
2011                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2012                         }
2013                 }
2014         }
2015         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2016         {
2017                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2018                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2019                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2020                 {
2021                         // instanctly hide MOTD
2022                         CS(this).motd_actived_time = 0;
2023                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2024                 }
2025         }
2026 }
2027
2028 const int MIN_SPEC_TIME = 1;
2029 bool joinAllowed(entity this)
2030 {
2031         if (CS(this).version_mismatch) return false;
2032         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2033         if (!nJoinAllowed(this, this)) return false;
2034         if (teamplay && lockteams) return false;
2035         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2036         if (ShowTeamSelection(this)) return false;
2037         return true;
2038 }
2039
2040 .int items_added;
2041 .string shootfromfixedorigin;
2042 bool PlayerThink(entity this)
2043 {
2044         if (game_stopped || intermission_running) {
2045                 this.modelflags &= ~MF_ROCKET;
2046                 if(intermission_running)
2047                         IntermissionThink(this);
2048                 return false;
2049         }
2050
2051         if (timeout_status == TIMEOUT_ACTIVE) {
2052         // don't allow the player to turn around while game is paused
2053                 // FIXME turn this into CSQC stuff
2054                 this.v_angle = this.lastV_angle;
2055                 this.angles = this.lastV_angle;
2056                 this.fixangle = true;
2057         }
2058
2059         if (frametime) player_powerups(this);
2060
2061         if (IS_DEAD(this)) {
2062                 if (this.personal && g_race_qualifying) {
2063                         if (time > this.respawn_time) {
2064                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2065                                 respawn(this);
2066                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2067                         }
2068                 } else {
2069                         if (frametime) player_anim(this);
2070
2071                         if (this.respawn_flags & RESPAWN_DENY)
2072                         {
2073                                 STAT(RESPAWN_TIME, this) = 0;
2074                                 return false;
2075                         }
2076
2077                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2078
2079                         switch(this.deadflag)
2080                         {
2081                                 case DEAD_DYING:
2082                                 {
2083                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2084                                                 this.deadflag = DEAD_RESPAWNING;
2085                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2086                                                 this.deadflag = DEAD_DEAD;
2087                                         break;
2088                                 }
2089                                 case DEAD_DEAD:
2090                                 {
2091                                         if (button_pressed)
2092                                                 this.deadflag = DEAD_RESPAWNABLE;
2093                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2094                                                 this.deadflag = DEAD_RESPAWNING;
2095                                         break;
2096                                 }
2097                                 case DEAD_RESPAWNABLE:
2098                                 {
2099                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2100                                                 this.deadflag = DEAD_RESPAWNING;
2101                                         break;
2102                                 }
2103                                 case DEAD_RESPAWNING:
2104                                 {
2105                                         if (time > this.respawn_time)
2106                                         {
2107                                                 this.respawn_time = time + 1; // only retry once a second
2108                                                 this.respawn_time_max = this.respawn_time;
2109                                                 respawn(this);
2110                                         }
2111                                         break;
2112                                 }
2113                         }
2114
2115                         ShowRespawnCountdown(this);
2116
2117                         if (this.respawn_flags & RESPAWN_SILENT)
2118                                 STAT(RESPAWN_TIME, this) = 0;
2119                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2120                         {
2121                                 if (time < this.respawn_time)
2122                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2123                                 else if (this.deadflag != DEAD_RESPAWNING)
2124                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2125                         }
2126                         else
2127                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2128                 }
2129
2130                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2131                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2132                         STAT(RESPAWN_TIME, this) *= -1;
2133
2134                 return false;
2135         }
2136
2137         FixPlayermodel(this);
2138
2139         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2140                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2141                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2142         }
2143
2144         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2145         //if(frametime)
2146         {
2147                 this.items &= ~this.items_added;
2148
2149                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2150                 {
2151                         .entity weaponentity = weaponentities[slot];
2152                         W_WeaponFrame(this, weaponentity);
2153                 }
2154
2155                 this.items_added = 0;
2156                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResourceAmount(this, RESOURCE_FUEL) >= 0.01))
2157             this.items_added |= IT_FUEL;
2158
2159                 this.items |= this.items_added;
2160         }
2161
2162         player_regen(this);
2163
2164         // WEAPONTODO: Add a weapon request for this
2165         // rot vortex charge to the charge limit
2166         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2167         {
2168                 .entity weaponentity = weaponentities[slot];
2169                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2170                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2171         }
2172
2173         if (frametime) player_anim(this);
2174
2175         // secret status
2176         secrets_setstatus(this);
2177
2178         // monsters status
2179         monsters_setstatus(this);
2180
2181         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2182
2183         return true;
2184 }
2185
2186 .bool would_spectate;
2187 void ObserverThink(entity this)
2188 {
2189         if ( CS(this).impulse )
2190         {
2191                 MinigameImpulse(this, CS(this).impulse);
2192                 CS(this).impulse = 0;
2193         }
2194
2195         if (this.flags & FL_JUMPRELEASED) {
2196                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2197                         this.flags &= ~FL_JUMPRELEASED;
2198                         this.flags |= FL_SPAWNING;
2199                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2200                         this.flags &= ~FL_JUMPRELEASED;
2201                         if(SpectateNext(this)) {
2202                                 TRANSMUTE(Spectator, this);
2203                         }
2204                 } else {
2205                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2206                         set_movetype(this, preferred_movetype);
2207                 }
2208         } else {
2209                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2210                         this.flags |= FL_JUMPRELEASED;
2211                         if(this.flags & FL_SPAWNING)
2212                         {
2213                                 this.flags &= ~FL_SPAWNING;
2214                                 Join(this);
2215                                 return;
2216                         }
2217                 }
2218         }
2219 }
2220
2221 void SpectatorThink(entity this)
2222 {
2223         if ( CS(this).impulse )
2224         {
2225                 if(MinigameImpulse(this, CS(this).impulse))
2226                         CS(this).impulse = 0;
2227
2228                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2229                 {
2230                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2231                         CS(this).impulse = 0;
2232                         return;
2233                 }
2234         }
2235
2236         if (this.flags & FL_JUMPRELEASED) {
2237                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2238                         this.flags &= ~FL_JUMPRELEASED;
2239                         this.flags |= FL_SPAWNING;
2240                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2241                         this.flags &= ~FL_JUMPRELEASED;
2242                         if(SpectateNext(this)) {
2243                                 TRANSMUTE(Spectator, this);
2244                         } else {
2245                                 TRANSMUTE(Observer, this);
2246                                 PutClientInServer(this);
2247                         }
2248                         CS(this).impulse = 0;
2249                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2250                         this.flags &= ~FL_JUMPRELEASED;
2251                         if(SpectatePrev(this)) {
2252                                 TRANSMUTE(Spectator, this);
2253                         } else {
2254                                 TRANSMUTE(Observer, this);
2255                                 PutClientInServer(this);
2256                         }
2257                         CS(this).impulse = 0;
2258                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2259                         this.would_spectate = false;
2260                         this.flags &= ~FL_JUMPRELEASED;
2261                         TRANSMUTE(Observer, this);
2262                         PutClientInServer(this);
2263                 } else {
2264                         if(!SpectateUpdate(this))
2265                         {
2266                                 if(!SpectateNext(this))
2267                                 {
2268                                         PutObserverInServer(this);
2269                                         this.would_spectate = true;
2270                                 }
2271                         }
2272                 }
2273         } else {
2274                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2275                         this.flags |= FL_JUMPRELEASED;
2276                         if(this.flags & FL_SPAWNING)
2277                         {
2278                                 this.flags &= ~FL_SPAWNING;
2279                                 Join(this);
2280                                 return;
2281                         }
2282                 }
2283                 if(!SpectateUpdate(this))
2284                         PutObserverInServer(this);
2285         }
2286
2287         this.flags |= FL_CLIENT | FL_NOTARGET;
2288 }
2289
2290 void PlayerUseKey(entity this)
2291 {
2292         if (!IS_PLAYER(this))
2293                 return;
2294
2295         if(this.vehicle)
2296         {
2297                 if(!game_stopped)
2298                 {
2299                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2300                         return;
2301                 }
2302         }
2303         else if(autocvar_g_vehicles_enter)
2304         {
2305                 if(!STAT(FROZEN, this))
2306                 if(!IS_DEAD(this))
2307                 if(!game_stopped)
2308                 {
2309                         entity head, closest_target = NULL;
2310                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2311
2312                         while(head) // find the closest acceptable target to enter
2313                         {
2314                                 if(IS_VEHICLE(head))
2315                                 if(!IS_DEAD(head))
2316                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2317                                 if(head.takedamage != DAMAGE_NO)
2318                                 {
2319                                         if(closest_target)
2320                                         {
2321                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2322                                                 { closest_target = head; }
2323                                         }
2324                                         else { closest_target = head; }
2325                                 }
2326
2327                                 head = head.chain;
2328                         }
2329
2330                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2331                 }
2332         }
2333
2334         // a use key was pressed; call handlers
2335         MUTATOR_CALLHOOK(PlayerUseKey, this);
2336 }
2337
2338
2339 /*
2340 =============
2341 PlayerPreThink
2342
2343 Called every frame for each client before the physics are run
2344 =============
2345 */
2346 .float last_vehiclecheck;
2347 void PlayerPreThink (entity this)
2348 {
2349         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2350         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2351
2352         WarpZone_PlayerPhysics_FixVAngle(this);
2353
2354         if (frametime) {
2355                 // physics frames: update anticheat stuff
2356                 anticheat_prethink(this);
2357         }
2358
2359         if (blockSpectators && frametime) {
2360                 // WORKAROUND: only use dropclient in server frames (frametime set).
2361                 // Never use it in cl_movement frames (frametime zero).
2362                 checkSpectatorBlock(this);
2363         }
2364
2365         zoomstate_set = false;
2366
2367         // Check for nameless players
2368         if (this.netname == "" || this.netname != CS(this).netname_previous)
2369         {
2370                 bool assume_unchanged = (CS(this).netname_previous == "");
2371                 if (isInvisibleString(this.netname))
2372                 {
2373                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2374                         assume_unchanged = false;
2375                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2376                 }
2377                 if (!assume_unchanged && autocvar_sv_eventlog)
2378                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2379                 strcpy(CS(this).netname_previous, this.netname);
2380         }
2381
2382         // version nagging
2383         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2384         CS(this).version_nagtime = 0;
2385         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2386             // git client
2387         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2388             // git server
2389             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2390         } else {
2391             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2392             if (r < 0) { // old client
2393                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2394             } else if (r > 0) { // old server
2395                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2396             }
2397         }
2398     }
2399
2400         // GOD MODE info
2401         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2402         {
2403                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2404                 this.max_armorvalue = 0;
2405         }
2406
2407         if(IS_PLAYER(this))
2408         {
2409                 if (STAT(FROZEN, this) == 2)
2410                 {
2411                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2412                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2413                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2414
2415                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2416                                 Unfreeze(this);
2417                 }
2418                 else if (STAT(FROZEN, this) == 3)
2419                 {
2420                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2421                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2422
2423                         if (GetResourceAmount(this, RESOURCE_HEALTH) < 1)
2424                         {
2425                                 if (this.vehicle)
2426                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2427                                 if(this.event_damage)
2428                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2429                         }
2430                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2431                                 Unfreeze(this);
2432                 }
2433         }
2434
2435         MUTATOR_CALLHOOK(PlayerPreThink, this);
2436
2437         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2438         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2439         {
2440                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2441                 {
2442                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2443                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2444                         {
2445                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2446                         }
2447                         else if(!it.owner)
2448                         {
2449                                 if(!it.team || SAME_TEAM(this, it))
2450                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2451                                 else if(autocvar_g_vehicles_steal)
2452                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2453                         }
2454                 });
2455
2456                 this.last_vehiclecheck = time + 1;
2457         }
2458
2459         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2460         {
2461                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2462                         PlayerUseKey(this);
2463                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2464         }
2465
2466         if (IS_REAL_CLIENT(this))
2467                 PrintWelcomeMessage(this);
2468
2469         if (IS_PLAYER(this)) {
2470                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2471                         error("Client can't be spawned as player on connection!");
2472                 if(!PlayerThink(this))
2473                         return;
2474         }
2475         else if (game_stopped || intermission_running) {
2476                 if(intermission_running)
2477                         IntermissionThink(this);
2478                 return;
2479         }
2480         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2481         {
2482                 CS(this).autojoin_checked = true;
2483                 // don't do this in ClientConnect
2484                 // many things can go wrong if a client is spawned as player on connection
2485                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2486                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2487                                 && (!teamplay || autocvar_g_balance_teams)))
2488                 {
2489                         campaign_bots_may_start = true;
2490                         Join(this);
2491                         return;
2492                 }
2493         }
2494         else if (IS_OBSERVER(this)) {
2495                 ObserverThink(this);
2496         }
2497         else if (IS_SPEC(this)) {
2498                 SpectatorThink(this);
2499         }
2500
2501         // WEAPONTODO: Add weapon request for this
2502         if (!zoomstate_set) {
2503                 bool wep_zoomed = false;
2504                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2505                 {
2506                         .entity weaponentity = weaponentities[slot];
2507                         Weapon thiswep = this.(weaponentity).m_weapon;
2508                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2509                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2510                 }
2511                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2512     }
2513
2514         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2515         {
2516                 CS(this).teamkill_soundtime = 0;
2517
2518                 entity e = CS(this).teamkill_soundsource;
2519                 entity oldpusher = e.pusher;
2520                 e.pusher = this;
2521                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2522                 e.pusher = oldpusher;
2523         }
2524
2525         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2526                 CS(this).taunt_soundtime = 0;
2527                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2528         }
2529
2530         target_voicescript_next(this);
2531
2532         // WEAPONTODO: Move into weaponsystem somehow
2533         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2534         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2535         {
2536                 .entity weaponentity = weaponentities[slot];
2537                 if(this.(weaponentity).m_weapon == WEP_Null)
2538                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2539         }
2540 }
2541
2542 void DrownPlayer(entity this)
2543 {
2544         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2545                 return;
2546
2547         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2548         {
2549                 if(this.air_finished < time)
2550                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2551                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2552         }
2553         else if (this.air_finished < time)
2554         {       // drown!
2555                 if (this.pain_finished < time)
2556                 {
2557                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2558                         this.pain_finished = time + 0.5;
2559                 }
2560         }
2561 }
2562
2563 .bool move_qcphysics;
2564
2565 void Player_Physics(entity this)
2566 {
2567         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2568
2569         if(!this.move_qcphysics)
2570                 return;
2571
2572         if(!frametime && !CS(this).pm_frametime)
2573                 return;
2574
2575         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2576
2577         CS(this).pm_frametime = 0;
2578 }
2579
2580 /*
2581 =============
2582 PlayerPostThink
2583
2584 Called every frame for each client after the physics are run
2585 =============
2586 */
2587 void PlayerPostThink (entity this)
2588 {
2589         Player_Physics(this);
2590
2591         if (sv_maxidle > 0)
2592         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2593         if (IS_REAL_CLIENT(this))
2594         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2595         {
2596                 int totalClients = 0;
2597                 if(sv_maxidle_slots > 0)
2598                 {
2599                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2600                         {
2601                                 ++totalClients;
2602                         });
2603                 }
2604
2605                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2606                 { /* do nothing */ }
2607                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2608                 {
2609                         if (CS(this).idlekick_lasttimeleft)
2610                         {
2611                                 CS(this).idlekick_lasttimeleft = 0;
2612                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2613                         }
2614                 }
2615                 else
2616                 {
2617                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2618                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2619                                 if (!CS(this).idlekick_lasttimeleft)
2620                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2621                         }
2622                         if (timeleft <= 0) {
2623                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2624                                 dropclient(this);
2625                                 return;
2626                         }
2627                         else if (timeleft <= 10) {
2628                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2629                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2630                 }
2631                                 CS(this).idlekick_lasttimeleft = timeleft;
2632                         }
2633                 }
2634         }
2635
2636         CheatFrame(this);
2637
2638         if (game_stopped)
2639         {
2640                 this.solid = SOLID_NOT;
2641                 this.takedamage = DAMAGE_NO;
2642                 set_movetype(this, MOVETYPE_NONE);
2643         }
2644
2645         if (IS_PLAYER(this)) {
2646                 if(this.death_time == time && IS_DEAD(this))
2647                 {
2648                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2649                         // once all the damage events of this frame have been processed with normal size
2650                         this.maxs.z = 5;
2651                         setsize(this, this.mins, this.maxs);
2652                 }
2653                 DrownPlayer(this);
2654                 UpdateChatBubble(this);
2655                 if (CS(this).impulse) ImpulseCommands(this);
2656                 if (game_stopped)
2657                 {
2658                         CSQCMODEL_AUTOUPDATE(this);
2659                         return;
2660                 }
2661                 GetPressedKeys(this);
2662         }
2663
2664         if (this.waypointsprite_attachedforcarrier) {
2665             vector v = healtharmor_maxdamage(GetResourceAmount(this, RESOURCE_HEALTH), GetResourceAmount(this, RESOURCE_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2666                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2667     }
2668
2669         CSQCMODEL_AUTOUPDATE(this);
2670 }
2671
2672 // hack to copy the button fields from the client entity to the Client State
2673 void PM_UpdateButtons(entity this, entity store)
2674 {
2675         if(this.impulse)
2676                 store.impulse = this.impulse;
2677         this.impulse = 0;
2678
2679         bool typing = this.buttonchat || this.button14;
2680
2681         store.button0 = (typing) ? 0 : this.button0;
2682         //button1?!
2683         store.button2 = (typing) ? 0 : this.button2;
2684         store.button3 = (typing) ? 0 : this.button3;
2685         store.button4 = this.button4;
2686         store.button5 = (typing) ? 0 : this.button5;
2687         store.button6 = this.button6;
2688         store.button7 = this.button7;
2689         store.button8 = this.button8;
2690         store.button9 = this.button9;
2691         store.button10 = this.button10;
2692         store.button11 = this.button11;
2693         store.button12 = this.button12;
2694         store.button13 = this.button13;
2695         store.button14 = this.button14;
2696         store.button15 = this.button15;
2697         store.button16 = this.button16;
2698         store.buttonuse = this.buttonuse;
2699         store.buttonchat = this.buttonchat;
2700
2701         store.cursor_active = this.cursor_active;
2702         store.cursor_screen = this.cursor_screen;
2703         store.cursor_trace_start = this.cursor_trace_start;
2704         store.cursor_trace_endpos = this.cursor_trace_endpos;
2705         store.cursor_trace_ent = this.cursor_trace_ent;
2706
2707         store.ping = this.ping;
2708         store.ping_packetloss = this.ping_packetloss;
2709         store.ping_movementloss = this.ping_movementloss;
2710
2711         store.v_angle = this.v_angle;
2712         store.movement = (typing) ? '0 0 0' : this.movement;
2713 }
2714
2715 NET_HANDLE(fpsreport, bool)
2716 {
2717         int fps = ReadShort();
2718         PlayerScore_Set(sender, SP_FPS, fps);
2719         return true;
2720 }