qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/lms/sv_lms.qh>
  10 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  11 #include <common/items/_mod.qh>
  12 #include <common/items/inventory.qh>
  13 #include <common/mapobjects/func/conveyor.qh>
  14 #include <common/mapobjects/func/ladder.qh>
  15 #include <common/mapobjects/subs.qh>
  16 #include <common/mapobjects/target/spawnpoint.qh>
  17 #include <common/mapobjects/teleporters.qh>
  18 #include <common/mapobjects/trigger/counter.qh>
  19 #include <common/mapobjects/trigger/secret.qh>
  20 #include <common/mapobjects/trigger/swamp.qh>
  21 #include <common/mapobjects/triggers.qh>
  22 #include <common/minigames/sv_minigames.qh>
  23 #include <common/monsters/sv_monsters.qh>
  24 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  25 #include <common/mutators/mutator/nades/nades.qh>
  26 #include <common/mutators/mutator/overkill/oknex.qh>
  27 #include <common/mutators/mutator/status_effects/_mod.qh>
  28 #include <common/mutators/mutator/waypoints/all.qh>
  29 #include <common/net_linked.qh>
  30 #include <common/net_notice.qh>
  31 #include <common/notifications/all.qh>
  32 #include <common/physics/player.qh>
  33 #include <common/playerstats.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/campaign.qh>
  50 #include <server/chat.qh>
  51 #include <server/cheats.qh>
  52 #include <server/clientkill.qh>
  53 #include <server/command/common.qh>
  54 #include <server/command/common.qh>
  55 #include <server/command/vote.qh>
  56 #include <server/compat/quake3.qh>
  57 #include <server/damage.qh>
  58 #include <server/gamelog.qh>
  59 #include <server/handicap.qh>
  60 #include <server/hook.qh>
  61 #include <server/impulse.qh>
  62 #include <server/intermission.qh>
  63 #include <server/ipban.qh>
  64 #include <server/main.qh>
  65 #include <server/mutators/_mod.qh>
  66 #include <server/player.qh>
  67 #include <server/portals.qh>
  68 #include <server/race.qh>
  69 #include <server/resources.qh>
  70 #include <server/scores.qh>
  71 #include <server/scores_rules.qh>
  72 #include <server/spawnpoints.qh>
  73 #include <server/teamplay.qh>
  74 #include <server/weapons/accuracy.qh>
  75 #include <server/weapons/common.qh>
  76 #include <server/weapons/hitplot.qh>
  77 #include <server/weapons/selection.qh>
  78 #include <server/weapons/tracing.qh>
  79 #include <server/weapons/weaponsystem.qh>
  80 #include <server/world.qh>
  81
  82 STATIC_METHOD(Client, Add, void(Client this, int _team))
  83 {
  84     ClientConnect(this);
  85     TRANSMUTE(Player, this);
  86     this.frame = 12; // 7
  87     this.team = _team;
  88     PutClientInServer(this);
  89 }
  90
  91 STATIC_METHOD(Client, Remove, void(Client this))
  92 {
  93     TRANSMUTE(Observer, this);
  94     PutClientInServer(this);
  95     ClientDisconnect(this);
  96 }
  97
  98 void send_CSQC_teamnagger() {
  99         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
 100 }
 101
 102 int CountSpectators(entity player, entity to)
 103 {
 104         if(!player) { return 0; } // not sure how, but best to be safe
 105
 106         int spec_count = 0;
 107
 108         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 109         {
 110                 spec_count++;
 111         });
 112
 113         return spec_count;
 114 }
 115
 116 void WriteSpectators(entity player, entity to)
 117 {
 118         if(!player) { return; } // not sure how, but best to be safe
 119
 120         int spec_count = 0;
 121         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 122         {
 123                 if(spec_count >= MAX_SPECTATORS)
 124                         break;
 125                 WriteByte(MSG_ENTITY, num_for_edict(it));
 126                 ++spec_count;
 127         });
 128 }
 129
 130 bool ClientData_Send(entity this, entity to, int sf)
 131 {
 132         assert(to == this.owner, return false);
 133
 134         entity e = to;
 135         if (IS_SPEC(e)) e = e.enemy;
 136
 137         sf = 0;
 138         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 139         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 140         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 141         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 142
 143         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 144         WriteByte(MSG_ENTITY, sf);
 145
 146         if (sf & BIT(1))
 147                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 148
 149         if(sf & BIT(4))
 150         {
 151                 float specs = CountSpectators(e, to);
 152                 WriteByte(MSG_ENTITY, specs);
 153                 WriteSpectators(e, to);
 154         }
 155
 156         return true;
 157 }
 158
 159 void ClientData_Attach(entity this)
 160 {
 161         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 162         CS(this).clientdata.drawonlytoclient = this;
 163         CS(this).clientdata.owner = this;
 164 }
 165
 166 void ClientData_Detach(entity this)
 167 {
 168         delete(CS(this).clientdata);
 169         CS(this).clientdata = NULL;
 170 }
 171
 172 void ClientData_Touch(entity e)
 173 {
 174         entity cd = CS(e).clientdata;
 175         if (cd) { cd.SendFlags = 1; }
 176
 177         // make it spectatable
 178         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 179         {
 180                 entity cd = CS(it).clientdata;
 181                 if (cd) { cd.SendFlags = 1; }
 182         });
 183 }
 184
 185
 186 /*
 187 =============
 188 CheckPlayerModel
 189
 190 Checks if the argument string can be a valid playermodel.
 191 Returns a valid one in doubt.
 192 =============
 193 */
 194 string FallbackPlayerModel;
 195 string CheckPlayerModel(string plyermodel) {
 196         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 197         {
 198                 // note: we cannot summon Don Strunzone here, some player may
 199                 // still have the model string set. In case anyone manages how
 200                 // to change a cvar default, we'll have a small leak here.
 201                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 202         }
 203         // only in right path
 204         if(substring(plyermodel, 0, 14) != "models/player/")
 205                 return FallbackPlayerModel;
 206         // only good file extensions
 207         if(substring(plyermodel, -4, 4) != ".iqm"
 208                 && substring(plyermodel, -4, 4) != ".zym"
 209                 && substring(plyermodel, -4, 4) != ".dpm"
 210                 && substring(plyermodel, -4, 4) != ".md3"
 211                 && substring(plyermodel, -4, 4) != ".psk")
 212         {
 213                 return FallbackPlayerModel;
 214         }
 215         // forbid the LOD models
 216         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 217                 return FallbackPlayerModel;
 218         if(plyermodel != strtolower(plyermodel))
 219                 return FallbackPlayerModel;
 220         // also, restrict to server models
 221         if(autocvar_sv_servermodelsonly)
 222         {
 223                 if(!fexists(plyermodel))
 224                         return FallbackPlayerModel;
 225         }
 226         return plyermodel;
 227 }
 228
 229 void setplayermodel(entity e, string modelname)
 230 {
 231         precache_model(modelname);
 232         _setmodel(e, modelname);
 233         player_setupanimsformodel(e);
 234         if(!autocvar_g_debug_globalsounds)
 235                 UpdatePlayerSounds(e);
 236 }
 237
 238 /** putting a client as observer in the server */
 239 void PutObserverInServer(entity this)
 240 {
 241         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 242         PlayerState_detach(this);
 243
 244         if (IS_PLAYER(this))
 245         {
 246                 if(GetResource(this, RES_HEALTH) >= 1)
 247                 {
 248                         // despawn effect
 249                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 250                 }
 251
 252                 // was a player, recount votes and ready status
 253                 if(IS_REAL_CLIENT(this))
 254                 {
 255                         if (vote_called) { VoteCount(false); }
 256                         ReadyCount();
 257                 }
 258                 entcs_update_players(this);
 259         }
 260
 261         entity spot = SelectSpawnPoint(this, true);
 262         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 263         this.angles = vec2(spot.angles);
 264         this.fixangle = true;
 265         // offset it so that the spectator spawns higher off the ground, looks better this way
 266         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 267         if (IS_REAL_CLIENT(this))
 268         {
 269                 msg_entity = this;
 270                 WriteByte(MSG_ONE, SVC_SETVIEW);
 271                 WriteEntity(MSG_ONE, this);
 272         }
 273         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 274         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 275         if(!autocvar_g_debug_globalsounds)
 276         {
 277                 // needed for player sounds
 278                 this.model = "";
 279                 FixPlayermodel(this);
 280         }
 281         setmodel(this, MDL_Null);
 282         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 283         this.view_ofs = '0 0 0';
 284
 285         RemoveGrapplingHooks(this);
 286         Portal_ClearAll(this);
 287         Unfreeze(this, false);
 288         SetSpectatee(this, NULL);
 289
 290         if (this.alivetime)
 291         {
 292                 if (!warmup_stage)
 293                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 294                 this.alivetime = 0;
 295         }
 296
 297         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 298
 299         WaypointSprite_PlayerDead(this);
 300
 301         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 302                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 303
 304         accuracy_resend(this);
 305
 306         CS(this).spectatortime = time;
 307         if(this.bot_attack)
 308                 IL_REMOVE(g_bot_targets, this);
 309         this.bot_attack = false;
 310         if(this.monster_attack)
 311                 IL_REMOVE(g_monster_targets, this);
 312         this.monster_attack = false;
 313         STAT(HUD, this) = HUD_NORMAL;
 314         TRANSMUTE(Observer, this);
 315         this.iscreature = false;
 316         this.teleportable = TELEPORT_SIMPLE;
 317         if(this.damagedbycontents)
 318                 IL_REMOVE(g_damagedbycontents, this);
 319         this.damagedbycontents = false;
 320         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 321         SetSpectatee_status(this, etof(this));
 322         this.takedamage = DAMAGE_NO;
 323         this.solid = SOLID_NOT;
 324         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 325         this.flags = FL_CLIENT | FL_NOTARGET;
 326         this.effects = 0;
 327         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 328         this.pauserotarmor_finished = 0;
 329         this.pauserothealth_finished = 0;
 330         this.pauseregen_finished = 0;
 331         this.damageforcescale = 0;
 332         this.death_time = 0;
 333         this.respawn_flags = 0;
 334         this.respawn_time = 0;
 335         STAT(RESPAWN_TIME, this) = 0;
 336         this.alpha = 0;
 337         this.scale = 0;
 338         this.fade_time = 0;
 339         this.pain_finished = 0;
 340         STAT(AIR_FINISHED, this) = 0;
 341         //this.dphitcontentsmask = 0;
 342         this.dphitcontentsmask = DPCONTENTS_SOLID;
 343         if (autocvar_g_playerclip_collisions)
 344                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 345         this.pushltime = 0;
 346         this.istypefrag = 0;
 347         setthink(this, func_null);
 348         this.nextthink = 0;
 349         this.deadflag = DEAD_NO;
 350         UNSET_DUCKED(this);
 351         STAT(REVIVE_PROGRESS, this) = 0;
 352         this.revival_time = 0;
 353         this.draggable = drag_undraggable;
 354
 355         this.items = 0;
 356         STAT(WEAPONS, this) = '0 0 0';
 357         this.drawonlytoclient = this;
 358
 359         this.viewloc = NULL;
 360
 361         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 362
 363         this.weaponmodel = "";
 364         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         {
 366                 this.weaponentities[slot] = NULL;
 367         }
 368         this.exteriorweaponentity = NULL;
 369         CS(this).killcount = FRAGS_SPECTATOR;
 370         this.velocity = '0 0 0';
 371         this.avelocity = '0 0 0';
 372         this.punchangle = '0 0 0';
 373         this.punchvector = '0 0 0';
 374         this.oldvelocity = this.velocity;
 375         this.event_damage = func_null;
 376         this.event_heal = func_null;
 377
 378         for(int slot = 0; slot < MAX_AXH; ++slot)
 379         {
 380                 entity axh = this.(AuxiliaryXhair[slot]);
 381                 this.(AuxiliaryXhair[slot]) = NULL;
 382
 383                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 384                         delete(axh);
 385         }
 386
 387         if (mutator_returnvalue)
 388         {
 389                 // mutator prevents resetting teams+score
 390         }
 391         else
 392         {
 393                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 394                 this.frags = FRAGS_SPECTATOR;
 395         }
 396
 397         bot_relinkplayerlist();
 398
 399         if (CS(this).just_joined)
 400                 CS(this).just_joined = false;
 401 }
 402
 403 int player_getspecies(entity this)
 404 {
 405         get_model_parameters(this.model, this.skin);
 406         int s = get_model_parameters_species;
 407         get_model_parameters(string_null, 0);
 408         if (s < 0) return SPECIES_HUMAN;
 409         return s;
 410 }
 411
 412 .float model_randomizer;
 413 void FixPlayermodel(entity player)
 414 {
 415         string defaultmodel = "";
 416         int defaultskin = 0;
 417         if(autocvar_sv_defaultcharacter)
 418         {
 419                 if(teamplay)
 420                 {
 421                         switch(player.team)
 422                         {
 423                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 424                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 425                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 426                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 427                         }
 428                 }
 429
 430                 if(defaultmodel == "")
 431                 {
 432                         defaultmodel = autocvar_sv_defaultplayermodel;
 433                         defaultskin = autocvar_sv_defaultplayerskin;
 434                 }
 435
 436                 int n = tokenize_console(defaultmodel);
 437                 if(n > 0)
 438                 {
 439                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 440                         // However, do NOT randomize if the player-selected model is in the list.
 441                         for (int i = 0; i < n; ++i)
 442                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 443                                         defaultmodel = argv(i);
 444                 }
 445
 446                 int i = strstrofs(defaultmodel, ":", 0);
 447                 if(i >= 0)
 448                 {
 449                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 450                         defaultmodel = substring(defaultmodel, 0, i);
 451                 }
 452         }
 453         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 454         {
 455                 if(teamplay)
 456                 {
 457                         switch(player.team)
 458                         {
 459                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 460                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 461                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 462                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 463                         }
 464                 }
 465
 466                 if(!defaultskin)
 467                         defaultskin = autocvar_sv_defaultplayerskin;
 468         }
 469
 470         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 471         defaultmodel = M_ARGV(0, string);
 472         defaultskin = M_ARGV(1, int);
 473
 474         bool chmdl = false;
 475         int oldskin;
 476         if(defaultmodel != "")
 477         {
 478                 if (defaultmodel != player.model)
 479                 {
 480                         vector m1 = player.mins;
 481                         vector m2 = player.maxs;
 482                         setplayermodel (player, defaultmodel);
 483                         setsize (player, m1, m2);
 484                         chmdl = true;
 485                 }
 486
 487                 oldskin = player.skin;
 488                 player.skin = defaultskin;
 489         } else {
 490                 if (player.playermodel != player.model || player.playermodel == "")
 491                 {
 492                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 493                         vector m1 = player.mins;
 494                         vector m2 = player.maxs;
 495                         setplayermodel (player, player.playermodel);
 496                         setsize (player, m1, m2);
 497                         chmdl = true;
 498                 }
 499
 500                 if(!autocvar_sv_defaultcharacterskin)
 501                 {
 502                         oldskin = player.skin;
 503                         player.skin = stof(player.playerskin);
 504                 }
 505                 else
 506                 {
 507                         oldskin = player.skin;
 508                         player.skin = defaultskin;
 509                 }
 510         }
 511
 512         if(chmdl || oldskin != player.skin) // model or skin has changed
 513         {
 514                 player.species = player_getspecies(player); // update species
 515                 if(!autocvar_g_debug_globalsounds)
 516                         UpdatePlayerSounds(player); // update skin sounds
 517         }
 518
 519         if(!teamplay)
 520                 if(strlen(autocvar_sv_defaultplayercolors))
 521                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 522                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 523 }
 524
 525 void PutPlayerInServer(entity this)
 526 {
 527         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 528
 529         PlayerState_attach(this);
 530         accuracy_resend(this);
 531
 532         if (this.team < 0)
 533                 TeamBalance_JoinBestTeam(this);
 534
 535         entity spot = SelectSpawnPoint(this, false);
 536         if (!spot) {
 537                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 538                 return; // spawn failed
 539         }
 540
 541         TRANSMUTE(Player, this);
 542
 543         CS(this).wasplayer = true;
 544         this.iscreature = true;
 545         this.teleportable = TELEPORT_NORMAL;
 546         if(!this.damagedbycontents)
 547                 IL_PUSH(g_damagedbycontents, this);
 548         this.damagedbycontents = true;
 549         set_movetype(this, MOVETYPE_WALK);
 550         this.solid = SOLID_SLIDEBOX;
 551         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 552         if (autocvar_g_playerclip_collisions)
 553                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 554         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 555                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 556         this.frags = FRAGS_PLAYER;
 557         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 558         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 559         if (autocvar__notarget)
 560                 this.flags |= FL_NOTARGET;
 561         this.takedamage = DAMAGE_AIM;
 562         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 563
 564         if (warmup_stage) {
 565                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 566                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 567                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 568                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 569                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 570                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 571                 SetResource(this, RES_HEALTH, warmup_start_health);
 572                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 573                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 574         } else {
 575                 SetResource(this, RES_SHELLS, start_ammo_shells);
 576                 SetResource(this, RES_BULLETS, start_ammo_nails);
 577                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 578                 SetResource(this, RES_CELLS, start_ammo_cells);
 579                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 580                 SetResource(this, RES_FUEL, start_ammo_fuel);
 581                 SetResource(this, RES_HEALTH, start_health);
 582                 SetResource(this, RES_ARMOR, start_armorvalue);
 583                 STAT(WEAPONS, this) = start_weapons;
 584                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 585                 {
 586                         GiveRandomWeapons(this, random_start_weapons_count,
 587                                 autocvar_g_random_start_weapons, random_start_ammo);
 588                 }
 589         }
 590         SetSpectatee_status(this, 0);
 591
 592         PS(this).dual_weapons = '0 0 0';
 593
 594         this.items = start_items;
 595
 596         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 597         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 598         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 599         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 600         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 601         if (!sv_ready_restart_after_countdown && time < game_starttime)
 602         {
 603                 float f = game_starttime - time;
 604                 this.spawnshieldtime += f;
 605                 this.pauserotarmor_finished += f;
 606                 this.pauserothealth_finished += f;
 607                 this.pauseregen_finished += f;
 608         }
 609
 610         this.damageforcescale = autocvar_g_player_damageforcescale;
 611         this.death_time = 0;
 612         this.respawn_flags = 0;
 613         this.respawn_time = 0;
 614         STAT(RESPAWN_TIME, this) = 0;
 615         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 616         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 617         this.fade_time = 0;
 618         this.pain_finished = 0;
 619         this.pushltime = 0;
 620         setthink(this, func_null); // players have no think function
 621         this.nextthink = 0;
 622         this.dmg_team = 0;
 623         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 624
 625         this.deadflag = DEAD_NO;
 626
 627         this.angles = spot.angles;
 628         this.angles_z = 0; // never spawn tilted even if the spot says to
 629         if (IS_BOT_CLIENT(this))
 630         {
 631                 this.v_angle = this.angles;
 632                 bot_aim_reset(this);
 633         }
 634         this.fixangle = true; // turn this way immediately
 635         this.oldvelocity = this.velocity = '0 0 0';
 636         this.avelocity = '0 0 0';
 637         this.punchangle = '0 0 0';
 638         this.punchvector = '0 0 0';
 639
 640         STAT(REVIVE_PROGRESS, this) = 0;
 641         this.revival_time = 0;
 642
 643         STAT(AIR_FINISHED, this) = 0;
 644         this.waterlevel = WATERLEVEL_NONE;
 645         this.watertype = CONTENT_EMPTY;
 646
 647         entity spawnevent = new_pure(spawnevent);
 648         spawnevent.owner = this;
 649         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 650
 651         // Cut off any still running player sounds.
 652         stopsound(this, CH_PLAYER_SINGLE);
 653
 654         this.model = "";
 655         FixPlayermodel(this);
 656         this.drawonlytoclient = NULL;
 657
 658         this.viewloc = NULL;
 659
 660         for(int slot = 0; slot < MAX_AXH; ++slot)
 661         {
 662                 entity axh = this.(AuxiliaryXhair[slot]);
 663                 this.(AuxiliaryXhair[slot]) = NULL;
 664
 665                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 666                         delete(axh);
 667         }
 668
 669         this.spawnpoint_targ = NULL;
 670
 671         UNSET_DUCKED(this);
 672         this.view_ofs = STAT(PL_VIEW_OFS, this);
 673         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 674         this.spawnorigin = spot.origin;
 675         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 676         // don't reset back to last position, even if new position is stuck in solid
 677         this.oldorigin = this.origin;
 678         if(this.conveyor)
 679                 IL_REMOVE(g_conveyed, this);
 680         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 681         if(this.swampslug)
 682                 IL_REMOVE(g_swamped, this);
 683         this.swampslug = NULL;
 684         this.swamp_interval = 0;
 685         if(this.ladder_entity)
 686                 IL_REMOVE(g_ladderents, this);
 687         this.ladder_entity = NULL;
 688         IL_EACH(g_counters, it.realowner == this,
 689         {
 690                 delete(it);
 691         });
 692         STAT(HUD, this) = HUD_NORMAL;
 693
 694         this.event_damage = PlayerDamage;
 695         this.event_heal = PlayerHeal;
 696
 697         this.draggable = func_null;
 698
 699         if(!this.bot_attack)
 700                 IL_PUSH(g_bot_targets, this);
 701         this.bot_attack = true;
 702         if(!this.monster_attack)
 703                 IL_PUSH(g_monster_targets, this);
 704         this.monster_attack = true;
 705         navigation_dynamicgoal_init(this, false);
 706
 707         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 708
 709         // player was spectator
 710         if (CS(this).killcount == FRAGS_SPECTATOR) {
 711                 PlayerScore_Clear(this);
 712                 CS(this).killcount = 0;
 713                 CS(this).startplaytime = time;
 714         }
 715
 716         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 717         {
 718                 .entity weaponentity = weaponentities[slot];
 719                 CL_SpawnWeaponentity(this, weaponentity);
 720         }
 721         this.alpha = default_player_alpha;
 722         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 723         this.exteriorweaponentity.alpha = default_weapon_alpha;
 724
 725         this.speedrunning = false;
 726
 727         this.counter_cnt = 0;
 728         this.fragsfilter_cnt = 0;
 729
 730         target_voicescript_clear(this);
 731
 732         // reset fields the weapons may use
 733         FOREACH(Weapons, true, {
 734                 it.wr_resetplayer(it, this);
 735                         // reload all reloadable weapons
 736                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 737                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 738                         {
 739                                 .entity weaponentity = weaponentities[slot];
 740                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 741                         }
 742                 }
 743         });
 744
 745         Unfreeze(this, false);
 746
 747         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 748
 749         {
 750                 string s = spot.target;
 751                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 752                         spot.target = string_null;
 753                 SUB_UseTargets(spot, this, NULL);
 754                 if(g_assault || g_race)
 755                         spot.target = s;
 756         }
 757
 758         if (autocvar_spawn_debug)
 759         {
 760                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 761                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 762         }
 763
 764         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 765         {
 766                 .entity weaponentity = weaponentities[slot];
 767                 entity w_ent = this.(weaponentity);
 768                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 769                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 770                 else
 771                         w_ent.m_switchweapon = WEP_Null;
 772                 w_ent.m_weapon = WEP_Null;
 773                 w_ent.weaponname = "";
 774                 w_ent.m_switchingweapon = WEP_Null;
 775                 w_ent.cnt = -1;
 776         }
 777
 778         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 779
 780         if (CS(this).impulse) ImpulseCommands(this);
 781
 782         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 783         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 784         {
 785                 .entity weaponentity = weaponentities[slot];
 786                 W_WeaponFrame(this, weaponentity);
 787         }
 788
 789         if (!warmup_stage && !this.alivetime)
 790                 this.alivetime = time;
 791
 792         antilag_clear(this, CS(this));
 793 }
 794
 795 /** Called when a client spawns in the server */
 796 void PutClientInServer(entity this)
 797 {
 798         if (IS_BOT_CLIENT(this)) {
 799                 TRANSMUTE(Player, this);
 800         } else if (IS_REAL_CLIENT(this)) {
 801                 msg_entity = this;
 802                 WriteByte(MSG_ONE, SVC_SETVIEW);
 803                 WriteEntity(MSG_ONE, this);
 804         }
 805         if (game_stopped)
 806                 TRANSMUTE(Observer, this);
 807
 808         SetSpectatee(this, NULL);
 809
 810         // reset player keys
 811         if(PS(this))
 812                 PS(this).itemkeys = 0;
 813
 814         MUTATOR_CALLHOOK(PutClientInServer, this);
 815
 816         if (IS_OBSERVER(this)) {
 817                 PutObserverInServer(this);
 818         } else if (IS_PLAYER(this)) {
 819                 PutPlayerInServer(this);
 820         }
 821
 822         bot_relinkplayerlist();
 823 }
 824
 825 // TODO do we need all these fields, or should we stop autodetecting runtime
 826 // changes and just have a console command to update this?
 827 bool ClientInit_SendEntity(entity this, entity to, int sf)
 828 {
 829         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 830         return = true;
 831         msg_entity = to;
 832         // MSG_INIT replacement
 833         // TODO: make easier to use
 834         Registry_send_all();
 835         W_PROP_reload(MSG_ONE, to);
 836         ClientInit_misc(this);
 837         MUTATOR_CALLHOOK(Ent_Init);
 838 }
 839 void ClientInit_misc(entity this)
 840 {
 841         int channel = MSG_ONE;
 842         WriteHeader(channel, ENT_CLIENT_INIT);
 843         WriteByte(channel, g_nexball_meter_period * 32);
 844         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 845         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 846         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 847         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 848         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 849         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 850         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 851         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 852
 853         if(autocvar_sv_foginterval && world.fog != "")
 854                 WriteString(channel, world.fog);
 855         else
 856                 WriteString(channel, "");
 857         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 858         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 859         WriteByte(channel, serverflags);
 860         WriteCoord(channel, autocvar_g_trueaim_minrange);
 861 }
 862
 863 void ClientInit_CheckUpdate(entity this)
 864 {
 865         this.nextthink = time;
 866         if(this.count != autocvar_g_balance_armor_blockpercent)
 867         {
 868                 this.count = autocvar_g_balance_armor_blockpercent;
 869                 this.SendFlags |= 1;
 870         }
 871         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 872         {
 873                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 874                 this.SendFlags |= 1;
 875         }
 876 }
 877
 878 void ClientInit_Spawn()
 879 {
 880         entity e = new_pure(clientinit);
 881         setthink(e, ClientInit_CheckUpdate);
 882         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 883
 884         ClientInit_CheckUpdate(e);
 885 }
 886
 887 /*
 888 =============
 889 SetNewParms
 890 =============
 891 */
 892 void SetNewParms ()
 893 {
 894         // initialize parms for a new player
 895         parm1 = -(86400 * 366);
 896
 897         MUTATOR_CALLHOOK(SetNewParms);
 898 }
 899
 900 /*
 901 =============
 902 SetChangeParms
 903 =============
 904 */
 905 void SetChangeParms (entity this)
 906 {
 907         // save parms for level change
 908         parm1 = CS(this).parm_idlesince - time;
 909
 910         MUTATOR_CALLHOOK(SetChangeParms);
 911 }
 912
 913 /*
 914 =============
 915 DecodeLevelParms
 916 =============
 917 */
 918 void DecodeLevelParms(entity this)
 919 {
 920         // load parms
 921         CS(this).parm_idlesince = parm1;
 922         if (CS(this).parm_idlesince == -(86400 * 366))
 923                 CS(this).parm_idlesince = time;
 924
 925         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 926         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 927
 928         MUTATOR_CALLHOOK(DecodeLevelParms);
 929 }
 930
 931 void FixClientCvars(entity e)
 932 {
 933         // send prediction settings to the client
 934         stuffcmd(e, "\nin_bindmap 0 0\n");
 935         if(autocvar_g_antilag == 3) // client side hitscan
 936                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 937         if(autocvar_sv_gentle)
 938                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 939
 940         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 941         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 942
 943         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 944
 945         MUTATOR_CALLHOOK(FixClientCvars, e);
 946 }
 947
 948 bool findinlist_abbrev(string tofind, string list)
 949 {
 950         if(list == "" || tofind == "")
 951                 return false; // empty list or search, just return
 952
 953         // this function allows abbreviated strings!
 954         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 955         {
 956                 return true;
 957         });
 958
 959         return false;
 960 }
 961
 962 bool PlayerInIPList(entity p, string iplist)
 963 {
 964         // some safety checks (never allow local?)
 965         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 966                 return false;
 967
 968         return findinlist_abbrev(p.netaddress, iplist);
 969 }
 970
 971 bool PlayerInIDList(entity p, string idlist)
 972 {
 973         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 974         if(!p.crypto_idfp)
 975                 return false;
 976
 977         return findinlist_abbrev(p.crypto_idfp, idlist);
 978 }
 979
 980 bool PlayerInList(entity player, string list)
 981 {
 982         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 983 }
 984
 985 #ifdef DP_EXT_PRECONNECT
 986 /*
 987 =============
 988 ClientPreConnect
 989
 990 Called once (not at each match start) when a client begins a connection to the server
 991 =============
 992 */
 993 void ClientPreConnect(entity this)
 994 {
 995         if(autocvar_sv_eventlog)
 996         {
 997                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 998                         this.playerid,
 999                         etof(this),
1000                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1001                 ));
1002         }
1003 }
1004 #endif
1005
1006 string GetClientVersionMessage(entity this)
1007 {
1008         if (CS(this).version_mismatch) {
1009                 if(CS(this).version < autocvar_gameversion) {
1010                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1011                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1012                 } else {
1013                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1014                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1015                 }
1016         } else {
1017                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1018         }
1019 }
1020
1021 string getwelcomemessage(entity this)
1022 {
1023         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1024         string modifications = M_ARGV(0, string);
1025
1026         if(g_weaponarena)
1027         {
1028                 if(g_weaponarena_random)
1029                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1030                 else
1031                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1032         }
1033         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1034                 modifications = strcat(modifications, ", No start weapons");
1035         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1036                 modifications = strcat(modifications, ", Low gravity");
1037         if(g_weapon_stay && !g_cts)
1038                 modifications = strcat(modifications, ", Weapons stay");
1039         if(autocvar_g_jetpack)
1040                 modifications = strcat(modifications, ", Jet pack");
1041         if(autocvar_g_powerups == 0)
1042                 modifications = strcat(modifications, ", No powerups");
1043         if(autocvar_g_powerups > 0)
1044                 modifications = strcat(modifications, ", Powerups");
1045         modifications = substring(modifications, 2, strlen(modifications) - 2);
1046
1047         string versionmessage = GetClientVersionMessage(this);
1048         string s = strcat(versionmessage, "^8\n^8\nserver is ^9", autocvar_hostname, "^8\n");
1049
1050         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1051
1052         if(modifications != "")
1053                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1054
1055         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1056         {
1057                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1058                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1059         }
1060
1061         if (cache_mutatormsg != "") {
1062                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1063         }
1064
1065         string mutator_msg = "";
1066         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1067         mutator_msg = M_ARGV(0, string);
1068
1069         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1070
1071         string motd = autocvar_sv_motd;
1072         if (motd != "") {
1073                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1074         }
1075         return s;
1076 }
1077
1078 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1079
1080 /**
1081 =============
1082 ClientConnect
1083
1084 Called when a client connects to the server
1085 =============
1086 */
1087 void ClientConnect(entity this)
1088 {
1089         if (Ban_MaybeEnforceBanOnce(this)) return;
1090         assert(!IS_CLIENT(this), return);
1091         this.flags |= FL_CLIENT;
1092         assert(player_count >= 0, player_count = 0);
1093
1094         TRANSMUTE(Client, this);
1095         CS(this).version_nagtime = time + 10 + random() * 10;
1096
1097         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1098
1099         bot_clientconnect(this);
1100
1101         Player_DetermineForcedTeam(this);
1102
1103         TRANSMUTE(Observer, this);
1104
1105         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1106
1107         // always track bots, don't ask for cl_allow_uidtracking
1108         if (IS_BOT_CLIENT(this))
1109                 PlayerStats_GameReport_AddPlayer(this);
1110         else
1111                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1112
1113         if (autocvar_sv_eventlog)
1114                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1115
1116         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1117
1118         stuffcmd(this, clientstuff, "\n");
1119         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1120
1121         FixClientCvars(this);
1122
1123         // get version info from player
1124         stuffcmd(this, "cmd clientversion $gameversion\n");
1125
1126         // notify about available teams
1127         if (teamplay)
1128         {
1129                 entity balance = TeamBalance_CheckAllowedTeams(this);
1130                 int t = TeamBalance_GetAllowedTeams(balance);
1131                 TeamBalance_Destroy(balance);
1132                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1133         }
1134         else
1135         {
1136                 stuffcmd(this, "set _teams_available 0\n");
1137         }
1138
1139         bot_relinkplayerlist();
1140
1141         CS(this).spectatortime = time;
1142         if (blockSpectators)
1143         {
1144                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1145         }
1146
1147         CS(this).jointime = time;
1148
1149         if (IS_REAL_CLIENT(this))
1150         {
1151                 if (g_weaponarena_weapons == WEPSET(TUBA))
1152                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1153         }
1154
1155         if (!autocvar_sv_foginterval && world.fog != "")
1156                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1157
1158         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1159                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1160                         send_CSQC_teamnagger();
1161
1162         CSQCMODEL_AUTOINIT(this);
1163
1164         CS(this).model_randomizer = random();
1165
1166         if (IS_REAL_CLIENT(this))
1167                 sv_notice_join(this);
1168
1169         this.move_qcphysics = autocvar_sv_qcphysics;
1170
1171         // update physics stats (players can spawn before physics runs)
1172         Physics_UpdateStats(this);
1173
1174         IL_EACH(g_initforplayer, it.init_for_player, {
1175                 it.init_for_player(it, this);
1176         });
1177
1178         Handicap_Initialize(this);
1179
1180         MUTATOR_CALLHOOK(ClientConnect, this);
1181
1182         if (IS_REAL_CLIENT(this))
1183         {
1184                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1185                 {
1186                         CS(this).motd_actived_time = -1;
1187                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1188                 }
1189         }
1190 }
1191 /*
1192 =============
1193 ClientDisconnect
1194
1195 Called when a client disconnects from the server
1196 =============
1197 */
1198 .entity chatbubbleentity;
1199 void player_powerups_remove_all(entity this);
1200
1201 void ClientDisconnect(entity this)
1202 {
1203         assert(IS_CLIENT(this), return);
1204
1205         PlayerStats_GameReport_FinalizePlayer(this);
1206         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1207         if (CS(this).active_minigame) part_minigame(this);
1208         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1209
1210         if (autocvar_sv_eventlog)
1211                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1212
1213         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1214
1215         if(IS_SPEC(this))
1216                 SetSpectatee(this, NULL);
1217
1218         MUTATOR_CALLHOOK(ClientDisconnect, this);
1219
1220         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1221         strfree(CS_CVAR(this).weaponorder_byimpulse);
1222         ClientState_detach(this);
1223
1224         Portal_ClearAll(this);
1225
1226         Unfreeze(this, false);
1227
1228         RemoveGrapplingHooks(this);
1229
1230         // Here, everything has been done that requires this player to be a client.
1231
1232         this.flags &= ~FL_CLIENT;
1233
1234         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1235         if (this.killindicator) delete(this.killindicator);
1236
1237         IL_EACH(g_counters, it.realowner == this,
1238         {
1239                 delete(it);
1240         });
1241
1242         WaypointSprite_PlayerGone(this);
1243
1244         bot_relinkplayerlist();
1245
1246         strfree(this.clientstatus);
1247         if (this.personal) delete(this.personal);
1248
1249         this.playerid = 0;
1250         ReadyCount();
1251         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1252
1253         player_powerups_remove_all(this); // stop powerup sound
1254
1255         ONREMOVE(this);
1256 }
1257
1258 void ChatBubbleThink(entity this)
1259 {
1260         this.nextthink = time;
1261         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1262         {
1263                 if(this.owner) // but why can that ever be NULL?
1264                         this.owner.chatbubbleentity = NULL;
1265                 delete(this);
1266                 return;
1267         }
1268
1269         this.mdl = "";
1270
1271         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1272         {
1273                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1274                         this.mdl = "models/sprites/minigame_busy.iqm";
1275                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1276                         this.mdl = "models/misc/chatbubble.spr";
1277         }
1278
1279         if ( this.model != this.mdl )
1280                 _setmodel(this, this.mdl);
1281
1282 }
1283
1284 void UpdateChatBubble(entity this)
1285 {
1286         if (this.alpha < 0)
1287                 return;
1288         // spawn a chatbubble entity if needed
1289         if (!this.chatbubbleentity)
1290         {
1291                 this.chatbubbleentity = new(chatbubbleentity);
1292                 this.chatbubbleentity.owner = this;
1293                 this.chatbubbleentity.exteriormodeltoclient = this;
1294                 setthink(this.chatbubbleentity, ChatBubbleThink);
1295                 this.chatbubbleentity.nextthink = time;
1296                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1297                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1298                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1299                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1300                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1301                 //this.chatbubbleentity.model = "";
1302                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1303         }
1304 }
1305
1306 void calculate_player_respawn_time(entity this)
1307 {
1308         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1309                 return;
1310
1311         float gametype_setting_tmp;
1312         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1313         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1314         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1315         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1316         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1317         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1318
1319         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1320         if (teamplay)
1321         {
1322                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1323                         if(it.team == this.team)
1324                                 ++pcount;
1325                 });
1326                 if (sdelay_small_count == 0)
1327                         sdelay_small_count = 1;
1328                 if (sdelay_large_count == 0)
1329                         sdelay_large_count = 1;
1330         }
1331         else
1332         {
1333                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1334                         ++pcount;
1335                 });
1336                 if (sdelay_small_count == 0)
1337                 {
1338                         if (IS_INDEPENDENT_PLAYER(this))
1339                         {
1340                                 // Players play independently. No point in requiring enemies.
1341                                 sdelay_small_count = 1;
1342                         }
1343                         else
1344                         {
1345                                 // Players play AGAINST each other. Enemies required.
1346                                 sdelay_small_count = 2;
1347                         }
1348                 }
1349                 if (sdelay_large_count == 0)
1350                 {
1351                         if (IS_INDEPENDENT_PLAYER(this))
1352                         {
1353                                 // Players play independently. No point in requiring enemies.
1354                                 sdelay_large_count = 1;
1355                         }
1356                         else
1357                         {
1358                                 // Players play AGAINST each other. Enemies required.
1359                                 sdelay_large_count = 2;
1360                         }
1361                 }
1362         }
1363
1364         float sdelay;
1365
1366         if (pcount <= sdelay_small_count)
1367                 sdelay = sdelay_small;
1368         else if (pcount >= sdelay_large_count)
1369                 sdelay = sdelay_large;
1370         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1371                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1372
1373         if(waves)
1374                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1375         else
1376                 this.respawn_time = time + sdelay;
1377
1378         if(sdelay < sdelay_max)
1379                 this.respawn_time_max = time + sdelay_max;
1380         else
1381                 this.respawn_time_max = this.respawn_time;
1382
1383         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1384                 this.respawn_countdown = 10; // first number to count down from is 10
1385         else
1386                 this.respawn_countdown = -1; // do not count down
1387
1388         if(autocvar_g_forced_respawn)
1389                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1390 }
1391
1392 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1393 // added to the model skins
1394 /*void UpdateColorModHack()
1395 {
1396         float c;
1397         c = this.clientcolors & 15;
1398         // LordHavoc: only bothering to support white, green, red, yellow, blue
1399              if (!teamplay) this.colormod = '0 0 0';
1400         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1401         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1402         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1403         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1404         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1405         else this.colormod = '1 1 1';
1406 }*/
1407
1408 void respawn(entity this)
1409 {
1410         bool damagedbycontents_prev = this.damagedbycontents;
1411         if(this.alpha >= 0)
1412         {
1413                 if(autocvar_g_respawn_ghosts)
1414                 {
1415                         this.solid = SOLID_NOT;
1416                         this.takedamage = DAMAGE_NO;
1417                         this.damagedbycontents = false;
1418                         set_movetype(this, MOVETYPE_FLY);
1419                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1420                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1421                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1422                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1423                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1424                         if(autocvar_g_respawn_ghosts_time > 0)
1425                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1426                 }
1427                 else
1428                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1429         }
1430
1431         CopyBody(this, 1);
1432         this.damagedbycontents = damagedbycontents_prev;
1433
1434         this.effects |= EF_NODRAW; // prevent another CopyBody
1435         PutClientInServer(this);
1436 }
1437
1438 void play_countdown(entity this, float finished, Sound samp)
1439 {
1440         TC(Sound, samp);
1441         if(IS_REAL_CLIENT(this))
1442                 if(floor(finished - time - frametime) != floor(finished - time))
1443                         if(finished - time < 6)
1444                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1445 }
1446
1447 void player_powerups_remove_all(entity this)
1448 {
1449         if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1450         {
1451                 // don't play the poweroff sound when the game restarts or the player disconnects
1452                 if (time > game_starttime + 1 && IS_CLIENT(this))
1453                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1454                 stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1455                 this.items &= ~ITEM_Strength.m_itemid;
1456                 this.items &= ~ITEM_Shield.m_itemid;
1457                 this.items -= (this.items & IT_SUPERWEAPON);
1458         }
1459 }
1460
1461 void player_powerups(entity this)
1462 {
1463         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1464                 this.modelflags |= MF_ROCKET;
1465         else
1466                 this.modelflags &= ~MF_ROCKET;
1467
1468         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_NODEPTHTEST);
1469
1470         if (IS_DEAD(this))
1471                 player_powerups_remove_all(this);
1472
1473         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1474                 return;
1475
1476         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1477         int items_prev = this.items;
1478
1479         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1480         {
1481                 if (this.items & ITEM_Strength.m_itemid)
1482                 {
1483                         play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Strength, this), SND_POWEROFF);
1484                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1485                         if (time > StatusEffects_gettime(STATUSEFFECT_Strength, this))
1486                         {
1487                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1488                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1489                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1490                         }
1491                 }
1492                 else
1493                 {
1494                         if (time < StatusEffects_gettime(STATUSEFFECT_Strength, this))
1495                         {
1496                                 this.items = this.items | ITEM_Strength.m_itemid;
1497                                 if(!g_cts)
1498                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1499                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1500                         }
1501                 }
1502                 if (this.items & ITEM_Shield.m_itemid)
1503                 {
1504                         play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Shield, this), SND_POWEROFF);
1505                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1506                         if (time > StatusEffects_gettime(STATUSEFFECT_Shield, this))
1507                         {
1508                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1509                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1510                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1511                         }
1512                 }
1513                 else
1514                 {
1515                         if (time < StatusEffects_gettime(STATUSEFFECT_Shield, this))
1516                         {
1517                                 this.items = this.items | ITEM_Shield.m_itemid;
1518                                 if(!g_cts)
1519                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1520                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1521                         }
1522                 }
1523                 if (this.items & IT_SUPERWEAPON)
1524                 {
1525                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1526                         {
1527                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1528                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1529                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1530                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1531                         }
1532                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1533                         {
1534                                 // don't let them run out
1535                         }
1536                         else
1537                         {
1538                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1539                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1540                                 {
1541                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1542                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1543                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1544                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1545                                 }
1546                         }
1547                 }
1548                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1549                 {
1550                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1551                         {
1552                                 this.items = this.items | IT_SUPERWEAPON;
1553                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1554                                 {
1555                                         if(!g_cts)
1556                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1557                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1558                                 }
1559                         }
1560                         else
1561                         {
1562                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1563                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1564                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1565                         }
1566                 }
1567                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1568                 {
1569                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1570                 }
1571         }
1572
1573         if(autocvar_g_nodepthtestplayers)
1574                 this.effects = this.effects | EF_NODEPTHTEST;
1575
1576         if(autocvar_g_fullbrightplayers)
1577                 this.effects = this.effects | EF_FULLBRIGHT;
1578
1579         if (time >= game_starttime)
1580         if (time < this.spawnshieldtime)
1581                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1582
1583         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1584 }
1585
1586 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1587 {
1588         if(current > stable)
1589                 return current;
1590         else if(current > stable - 0.25) // when close enough, "snap"
1591                 return stable;
1592         else
1593                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1594 }
1595
1596 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1597 {
1598         if(current < stable)
1599                 return current;
1600         else if(current < stable + 0.25) // when close enough, "snap"
1601                 return stable;
1602         else
1603                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1604 }
1605
1606 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1607 {
1608         float old = GetResource(this, res);
1609         float current = old;
1610         if(current > rotstable)
1611         {
1612                 if(rotframetime > 0)
1613                 {
1614                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1615                         current = max(rotstable, current - rotlinear * rotframetime);
1616                 }
1617         }
1618         else if(current < regenstable)
1619         {
1620                 if(regenframetime > 0)
1621                 {
1622                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1623                         current = min(regenstable, current + regenlinear * regenframetime);
1624                 }
1625         }
1626
1627         float limit = GetResourceLimit(this, res) * limit_mod;
1628         if(current > limit)
1629                 current = limit;
1630
1631         if (current != old)
1632                 SetResource(this, res, current);
1633 }
1634
1635 void player_regen(entity this)
1636 {
1637         float max_mod, regen_mod, rot_mod, limit_mod;
1638         max_mod = regen_mod = rot_mod = limit_mod = 1;
1639
1640         float regen_health = autocvar_g_balance_health_regen;
1641         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1642         float regen_health_rot = autocvar_g_balance_health_rot;
1643         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1644         float regen_health_stable = autocvar_g_balance_health_regenstable;
1645         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1646         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1647                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1648         max_mod = M_ARGV(1, float);
1649         regen_mod = M_ARGV(2, float);
1650         rot_mod = M_ARGV(3, float);
1651         limit_mod = M_ARGV(4, float);
1652         regen_health = M_ARGV(5, float);
1653         regen_health_linear = M_ARGV(6, float);
1654         regen_health_rot = M_ARGV(7, float);
1655         regen_health_rotlinear = M_ARGV(8, float);
1656         regen_health_stable = M_ARGV(9, float);
1657         regen_health_rotstable = M_ARGV(10, float);
1658
1659         if(!mutator_returnvalue)
1660         if(!STAT(FROZEN, this))
1661         {
1662                 float maxa = autocvar_g_balance_armor_rotstable;
1663                 float mina = autocvar_g_balance_armor_regenstable;
1664
1665                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1666                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1667                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1668
1669                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1670                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1671                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1672         }
1673
1674         // if player rotted to death...  die!
1675         // check this outside above checks, as player may still be able to rot to death
1676         if(GetResource(this, RES_HEALTH) < 1)
1677         {
1678                 if(this.vehicle)
1679                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1680                 if(this.event_damage)
1681                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1682         }
1683
1684         if (!(this.items & IT_UNLIMITED_AMMO))
1685         {
1686                 float maxf = autocvar_g_balance_fuel_rotstable;
1687                 float minf = autocvar_g_balance_fuel_regenstable;
1688
1689                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1690                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1691                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1692         }
1693 }
1694
1695 bool zoomstate_set;
1696 void SetZoomState(entity this, float newzoom)
1697 {
1698         if(newzoom != CS(this).zoomstate)
1699         {
1700                 CS(this).zoomstate = newzoom;
1701                 ClientData_Touch(this);
1702         }
1703         zoomstate_set = true;
1704 }
1705
1706 void GetPressedKeys(entity this)
1707 {
1708         MUTATOR_CALLHOOK(GetPressedKeys, this);
1709         if (game_stopped)
1710         {
1711                 CS(this).pressedkeys = 0;
1712                 STAT(PRESSED_KEYS, this) = 0;
1713                 return;
1714         }
1715
1716         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1717         int keys = STAT(PRESSED_KEYS, this);
1718         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1719         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1720         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1721         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1722
1723         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1724         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1725         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1726         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1727         CS(this).pressedkeys = keys; // store for other users
1728
1729         STAT(PRESSED_KEYS, this) = keys;
1730 }
1731
1732 /*
1733 ======================
1734 spectate mode routines
1735 ======================
1736 */
1737
1738 void SpectateCopy(entity this, entity spectatee)
1739 {
1740         TC(Client, this); TC(Client, spectatee);
1741
1742         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1743         PS(this) = PS(spectatee);
1744         this.armortype = spectatee.armortype;
1745         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1746         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1747         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1748         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1749         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1750         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1751         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1752         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1753         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1754         CS(this).impulse = 0;
1755         this.disableclientprediction = 1; // no need to run prediction on a spectator
1756         this.items = spectatee.items;
1757         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1758         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1759         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1760         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1761         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1762         this.punchangle = spectatee.punchangle;
1763         this.view_ofs = spectatee.view_ofs;
1764         this.velocity = spectatee.velocity;
1765         this.dmg_take = spectatee.dmg_take;
1766         this.dmg_save = spectatee.dmg_save;
1767         this.dmg_inflictor = spectatee.dmg_inflictor;
1768         this.v_angle = spectatee.v_angle;
1769         this.angles = spectatee.v_angle;
1770         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1771         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1772         this.viewloc = spectatee.viewloc;
1773         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1774                 this.fixangle = true;
1775         setorigin(this, spectatee.origin);
1776         setsize(this, spectatee.mins, spectatee.maxs);
1777         SetZoomState(this, CS(spectatee).zoomstate);
1778
1779     anticheat_spectatecopy(this, spectatee);
1780         STAT(HUD, this) = STAT(HUD, spectatee);
1781         if(spectatee.vehicle)
1782     {
1783         this.angles = spectatee.v_angle;
1784
1785         //this.fixangle = false;
1786         //this.velocity = spectatee.vehicle.velocity;
1787         this.vehicle_health = spectatee.vehicle_health;
1788         this.vehicle_shield = spectatee.vehicle_shield;
1789         this.vehicle_energy = spectatee.vehicle_energy;
1790         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1791         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1792         this.vehicle_reload1 = spectatee.vehicle_reload1;
1793         this.vehicle_reload2 = spectatee.vehicle_reload2;
1794
1795         //msg_entity = this;
1796
1797        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1798             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1799            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1800            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1801
1802         //WriteByte (MSG_ONE, SVC_SETVIEW);
1803         //    WriteEntity(MSG_ONE, this);
1804         //makevectors(spectatee.v_angle);
1805         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1806     }
1807 }
1808
1809 bool SpectateUpdate(entity this)
1810 {
1811         if(!this.enemy)
1812                 return false;
1813
1814         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1815         {
1816                 SetSpectatee(this, NULL);
1817                 return false;
1818         }
1819
1820         SpectateCopy(this, this.enemy);
1821
1822         return true;
1823 }
1824
1825 bool SpectateSet(entity this)
1826 {
1827         if(!IS_PLAYER(this.enemy))
1828                 return false;
1829
1830         ClientData_Touch(this.enemy);
1831
1832         msg_entity = this;
1833         WriteByte(MSG_ONE, SVC_SETVIEW);
1834         WriteEntity(MSG_ONE, this.enemy);
1835         set_movetype(this, MOVETYPE_NONE);
1836         accuracy_resend(this);
1837
1838         if(!SpectateUpdate(this))
1839                 PutObserverInServer(this);
1840
1841         return true;
1842 }
1843
1844 void SetSpectatee_status(entity this, int spectatee_num)
1845 {
1846         int oldspectatee_status = CS(this).spectatee_status;
1847         CS(this).spectatee_status = spectatee_num;
1848
1849         if (CS(this).spectatee_status != oldspectatee_status)
1850         {
1851                 if (STAT(PRESSED_KEYS, this))
1852                 {
1853                         CS(this).pressedkeys = 0;
1854                         STAT(PRESSED_KEYS, this) = 0;
1855                 }
1856                 ClientData_Touch(this);
1857                 if (g_race || g_cts) race_InitSpectator();
1858         }
1859 }
1860
1861 void SetSpectatee(entity this, entity spectatee)
1862 {
1863         if(IS_BOT_CLIENT(this))
1864                 return; // bots abuse .enemy, this code is useless to them
1865
1866         entity old_spectatee = this.enemy;
1867
1868         this.enemy = spectatee;
1869
1870         // WEAPONTODO
1871         // these are required to fix the spectator bug with arc
1872         if(old_spectatee)
1873         {
1874                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1875                 {
1876                         .entity weaponentity = weaponentities[slot];
1877                         if(old_spectatee.(weaponentity).arc_beam)
1878                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1879                 }
1880         }
1881         if(this.enemy)
1882         {
1883                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1884                 {
1885                         .entity weaponentity = weaponentities[slot];
1886                         if(this.enemy.(weaponentity).arc_beam)
1887                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1888                 }
1889         }
1890
1891         if (this.enemy)
1892                 SetSpectatee_status(this, etof(this.enemy));
1893
1894         // needed to update spectator list
1895         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1896 }
1897
1898 bool Spectate(entity this, entity pl)
1899 {
1900         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1901                 return false;
1902         pl = M_ARGV(1, entity);
1903
1904         SetSpectatee(this, pl);
1905         return SpectateSet(this);
1906 }
1907
1908 bool SpectateNext(entity this)
1909 {
1910         entity ent = find(this.enemy, classname, STR_PLAYER);
1911
1912         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1913                 ent = M_ARGV(1, entity);
1914         else if (!ent)
1915                 ent = find(ent, classname, STR_PLAYER);
1916
1917         if(ent) { SetSpectatee(this, ent); }
1918
1919         return SpectateSet(this);
1920 }
1921
1922 bool SpectatePrev(entity this)
1923 {
1924         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1925         entity ent = findchain(classname, STR_PLAYER);
1926         if (!ent) // no player
1927                 return false;
1928
1929         entity first = ent;
1930         // skip players until current spectated player
1931         if(this.enemy)
1932         while(ent && ent != this.enemy)
1933                 ent = ent.chain;
1934
1935         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1936         {
1937                 case MUT_SPECPREV_FOUND:
1938                         ent = M_ARGV(1, entity);
1939                         break;
1940                 case MUT_SPECPREV_RETURN:
1941                         return true;
1942                 case MUT_SPECPREV_CONTINUE:
1943                 default:
1944                 {
1945                         if(ent.chain)
1946                                 ent = ent.chain;
1947                         else
1948                                 ent = first;
1949                         break;
1950                 }
1951         }
1952
1953         SetSpectatee(this, ent);
1954         return SpectateSet(this);
1955 }
1956
1957 /*
1958 =============
1959 ShowRespawnCountdown()
1960
1961 Update a respawn countdown display.
1962 =============
1963 */
1964 void ShowRespawnCountdown(entity this)
1965 {
1966         float number;
1967         if(!IS_DEAD(this)) // just respawned?
1968                 return;
1969         else
1970         {
1971                 number = ceil(this.respawn_time - time);
1972                 if(number <= 0)
1973                         return;
1974                 if(number <= this.respawn_countdown)
1975                 {
1976                         this.respawn_countdown = number - 1;
1977                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1978                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1979                 }
1980         }
1981 }
1982
1983 .bool team_selected;
1984 bool ShowTeamSelection(entity this)
1985 {
1986         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1987                 return false;
1988         stuffcmd(this, "menu_showteamselect\n");
1989         return true;
1990 }
1991 void Join(entity this)
1992 {
1993         TRANSMUTE(Player, this);
1994
1995         if(!this.team_selected)
1996         if(autocvar_g_campaign || autocvar_g_balance_teams)
1997                 TeamBalance_JoinBestTeam(this);
1998
1999         if(autocvar_g_campaign)
2000                 campaign_bots_may_start = true;
2001
2002         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2003
2004         PutClientInServer(this);
2005
2006         if(IS_PLAYER(this))
2007         if(teamplay && this.team != -1)
2008         {
2009         }
2010         else
2011                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2012         this.team_selected = false;
2013 }
2014
2015 int GetPlayerLimit()
2016 {
2017         if(g_duel)
2018                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2019         int player_limit = autocvar_g_maxplayers;
2020         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2021         player_limit = M_ARGV(0, int);
2022         return player_limit;
2023 }
2024
2025 /**
2026  * Determines whether the player is allowed to join. This depends on cvar
2027  * g_maxplayers, if it isn't used this function always return true, otherwise
2028  * it checks whether the number of currently playing players exceeds g_maxplayers.
2029  * @return int number of free slots for players, 0 if none
2030  */
2031 int nJoinAllowed(entity this, entity ignore)
2032 {
2033         if(!ignore)
2034         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2035         // so report 0 free slots if restricted
2036         {
2037                 if(autocvar_g_forced_team_otherwise == "spectate")
2038                         return 0;
2039                 if(autocvar_g_forced_team_otherwise == "spectator")
2040                         return 0;
2041         }
2042
2043         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2044                 return 0; // forced spectators can never join
2045
2046         // TODO simplify this
2047         int totalClients = 0;
2048         int currentlyPlaying = 0;
2049         FOREACH_CLIENT(true, {
2050                 if(it != ignore)
2051                         ++totalClients;
2052                 if(IS_REAL_CLIENT(it))
2053                 if(IS_PLAYER(it) || it.caplayer)
2054                         ++currentlyPlaying;
2055         });
2056
2057         int player_limit = GetPlayerLimit();
2058
2059         int free_slots = 0;
2060         if (!player_limit)
2061                 free_slots = maxclients - totalClients;
2062         else if(player_limit > 0 && currentlyPlaying < player_limit)
2063                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2064
2065         static float msg_time = 0;
2066         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2067         {
2068                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2069                 msg_time = time + 0.5;
2070         }
2071
2072         return free_slots;
2073 }
2074
2075 void PrintWelcomeMessage(entity this)
2076 {
2077         if(CS(this).motd_actived_time == 0)
2078         {
2079                 if (autocvar_g_campaign) {
2080                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2081                                 CS(this).motd_actived_time = time;
2082                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2083                         }
2084                 } else {
2085                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2086                                 CS(this).motd_actived_time = time;
2087                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2088                         }
2089                 }
2090         }
2091         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2092         {
2093                 if (autocvar_g_campaign) {
2094                         if (PHYS_INPUT_BUTTON_INFO(this))
2095                                 CS(this).motd_actived_time = time;
2096                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2097                                 CS(this).motd_actived_time = 0;
2098                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2099                         }
2100                 } else {
2101                         if (PHYS_INPUT_BUTTON_INFO(this))
2102                                 CS(this).motd_actived_time = time;
2103                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2104                                 CS(this).motd_actived_time = 0;
2105                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2106                         }
2107                 }
2108         }
2109         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2110         {
2111                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2112                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2113                 else if (CS(this).motd_actived_time == -2)
2114                 {
2115                         // instantly hide MOTD
2116                         CS(this).motd_actived_time = 0;
2117                         if (autocvar_g_campaign)
2118                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2119                         else
2120                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2121                 }
2122                 else if (IS_PLAYER(this) || IS_SPEC(this))
2123                 {
2124                         // FIXME occasionally for some reason MOTD never goes away
2125                         // delay MOTD removal a little bit in the hope it fixes this bug
2126                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2127                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2128                         else //if (CS(this).motd_actived_time < -2)
2129                                 CS(this).motd_actived_time++;
2130                 }
2131         }
2132 }
2133
2134 bool joinAllowed(entity this)
2135 {
2136         if (CS(this).version_mismatch) return false;
2137         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2138         if (!nJoinAllowed(this, this)) return false;
2139         if (teamplay && lockteams) return false;
2140         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2141         if (ShowTeamSelection(this)) return false;
2142         return true;
2143 }
2144
2145 .string shootfromfixedorigin;
2146 .bool dualwielding_prev;
2147 bool PlayerThink(entity this)
2148 {
2149         if (game_stopped || intermission_running) {
2150                 this.modelflags &= ~MF_ROCKET;
2151                 if(intermission_running)
2152                         IntermissionThink(this);
2153                 return false;
2154         }
2155
2156         if (timeout_status == TIMEOUT_ACTIVE) {
2157                 // don't allow the player to turn around while game is paused
2158                 // FIXME turn this into CSQC stuff
2159                 this.v_angle = this.lastV_angle;
2160                 this.angles = this.lastV_angle;
2161                 this.fixangle = true;
2162         }
2163
2164         if (frametime) player_powerups(this);
2165
2166         if (IS_DEAD(this)) {
2167                 if (this.personal && g_race_qualifying) {
2168                         if (time > this.respawn_time) {
2169                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2170                                 respawn(this);
2171                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2172                         }
2173                 } else {
2174                         if (frametime) player_anim(this);
2175
2176                         if (this.respawn_flags & RESPAWN_DENY)
2177                         {
2178                                 STAT(RESPAWN_TIME, this) = 0;
2179                                 return false;
2180                         }
2181
2182                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2183
2184                         switch(this.deadflag)
2185                         {
2186                                 case DEAD_DYING:
2187                                 {
2188                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2189                                                 this.deadflag = DEAD_RESPAWNING;
2190                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2191                                                 this.deadflag = DEAD_DEAD;
2192                                         break;
2193                                 }
2194                                 case DEAD_DEAD:
2195                                 {
2196                                         if (button_pressed)
2197                                                 this.deadflag = DEAD_RESPAWNABLE;
2198                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2199                                                 this.deadflag = DEAD_RESPAWNING;
2200                                         break;
2201                                 }
2202                                 case DEAD_RESPAWNABLE:
2203                                 {
2204                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2205                                                 this.deadflag = DEAD_RESPAWNING;
2206                                         break;
2207                                 }
2208                                 case DEAD_RESPAWNING:
2209                                 {
2210                                         if (time > this.respawn_time)
2211                                         {
2212                                                 this.respawn_time = time + 1; // only retry once a second
2213                                                 this.respawn_time_max = this.respawn_time;
2214                                                 respawn(this);
2215                                         }
2216                                         break;
2217                                 }
2218                         }
2219
2220                         ShowRespawnCountdown(this);
2221
2222                         if (this.respawn_flags & RESPAWN_SILENT)
2223                                 STAT(RESPAWN_TIME, this) = 0;
2224                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2225                         {
2226                                 if (time < this.respawn_time)
2227                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2228                                 else if (this.deadflag != DEAD_RESPAWNING)
2229                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2230                         }
2231                         else
2232                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2233                 }
2234
2235                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2236                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2237                         STAT(RESPAWN_TIME, this) *= -1;
2238
2239                 return false;
2240         }
2241
2242         FixPlayermodel(this);
2243
2244         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2245                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2246                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2247         }
2248
2249         // reset gun alignment when dual wielding status changes
2250         // to ensure guns are always aligned right and left
2251         bool dualwielding = W_DualWielding(this);
2252         if(this.dualwielding_prev != dualwielding)
2253         {
2254                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2255                 this.dualwielding_prev = dualwielding;
2256         }
2257
2258         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2259         //if(frametime)
2260         {
2261                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2262                 {
2263                         .entity weaponentity = weaponentities[slot];
2264                         if(WEP_CVAR(vortex, charge_always))
2265                                 W_Vortex_Charge(this, weaponentity, frametime);
2266                         W_WeaponFrame(this, weaponentity);
2267                 }
2268         }
2269
2270         if (frametime)
2271         {
2272                 // WEAPONTODO: Add a weapon request for this
2273                 // rot vortex charge to the charge limit
2274                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2275                 {
2276                         .entity weaponentity = weaponentities[slot];
2277                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2278                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2279                 }
2280
2281                 player_regen(this);
2282                 player_anim(this);
2283                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2284         }
2285
2286         monsters_setstatus(this);
2287
2288         return true;
2289 }
2290
2291 .bool would_spectate;
2292 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2293 void ObserverOrSpectatorThink(entity this)
2294 {
2295         bool is_spec = IS_SPEC(this);
2296         if ( CS(this).impulse )
2297         {
2298                 int r = MinigameImpulse(this, CS(this).impulse);
2299                 if (!is_spec || r)
2300                         CS(this).impulse = 0;
2301
2302                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2303                 {
2304                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2305                         CS(this).impulse = 0;
2306                         return;
2307                 }
2308         }
2309
2310         if (this.flags & FL_JUMPRELEASED) {
2311                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2312                         this.flags &= ~FL_JUMPRELEASED;
2313                         this.flags |= FL_SPAWNING;
2314                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2315                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2316                         this.flags &= ~FL_JUMPRELEASED;
2317                         if(SpectateNext(this)) {
2318                                 TRANSMUTE(Spectator, this);
2319                         } else if (is_spec) {
2320                                 TRANSMUTE(Observer, this);
2321                                 PutClientInServer(this);
2322                         }
2323                         else
2324                                 this.would_spectate = false; // unable to spectate anyone
2325                         if (is_spec)
2326                                 CS(this).impulse = 0;
2327                 } else if (is_spec) {
2328                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2329                                 this.flags &= ~FL_JUMPRELEASED;
2330                                 if(SpectatePrev(this)) {
2331                                         TRANSMUTE(Spectator, this);
2332                                 } else {
2333                                         TRANSMUTE(Observer, this);
2334                                         PutClientInServer(this);
2335                                 }
2336                                 CS(this).impulse = 0;
2337                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2338                                 this.would_spectate = false;
2339                                 this.flags &= ~FL_JUMPRELEASED;
2340                                 TRANSMUTE(Observer, this);
2341                                 PutClientInServer(this);
2342                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2343                                 PutObserverInServer(this);
2344                                 this.would_spectate = true;
2345                         }
2346                 }
2347                 else {
2348                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2349                         if (PHYS_INPUT_BUTTON_USE(this))
2350                                 wouldclip = !wouldclip;
2351                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2352                         set_movetype(this, preferred_movetype);
2353                 }
2354         } else { // jump pressed
2355                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2356                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2357                         this.flags |= FL_JUMPRELEASED;
2358                         if(this.flags & FL_SPAWNING)
2359                         {
2360                                 this.flags &= ~FL_SPAWNING;
2361                                 if(joinAllowed(this))
2362                                         Join(this);
2363                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2364                                         CS(this).autojoin_checked = -1;
2365                                 return;
2366                         }
2367                 }
2368                 if(is_spec && !SpectateUpdate(this))
2369                         PutObserverInServer(this);
2370         }
2371         if (is_spec)
2372                 this.flags |= FL_CLIENT | FL_NOTARGET;
2373 }
2374
2375 void PlayerUseKey(entity this)
2376 {
2377         if (!IS_PLAYER(this))
2378                 return;
2379
2380         if(this.vehicle)
2381         {
2382                 if(!game_stopped)
2383                 {
2384                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2385                         return;
2386                 }
2387         }
2388         else if(autocvar_g_vehicles_enter)
2389         {
2390                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2391                 {
2392                         entity head, closest_target = NULL;
2393                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2394
2395                         while(head) // find the closest acceptable target to enter
2396                         {
2397                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2398                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2399                                 {
2400                                         if(closest_target)
2401                                         {
2402                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2403                                                 { closest_target = head; }
2404                                         }
2405                                         else { closest_target = head; }
2406                                 }
2407
2408                                 head = head.chain;
2409                         }
2410
2411                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2412                 }
2413         }
2414
2415         // a use key was pressed; call handlers
2416         MUTATOR_CALLHOOK(PlayerUseKey, this);
2417 }
2418
2419
2420 /*
2421 =============
2422 PlayerPreThink
2423
2424 Called every frame for each client before the physics are run
2425 =============
2426 */
2427 .float last_vehiclecheck;
2428 void PlayerPreThink (entity this)
2429 {
2430         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2431         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2432
2433         WarpZone_PlayerPhysics_FixVAngle(this);
2434
2435         if (frametime) {
2436                 // physics frames: update anticheat stuff
2437                 anticheat_prethink(this);
2438
2439                 // WORKAROUND: only use dropclient in server frames (frametime set).
2440                 // Never use it in cl_movement frames (frametime zero).
2441                 if (blockSpectators && IS_REAL_CLIENT(this)
2442                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !this.caplayer
2443                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2444                 {
2445                         if (dropclient_schedule(this))
2446                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2447                 }
2448         }
2449
2450         zoomstate_set = false;
2451
2452         // Check for nameless players
2453         if (this.netname == "" || this.netname != CS(this).netname_previous)
2454         {
2455                 bool assume_unchanged = (CS(this).netname_previous == "");
2456                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2457                 {
2458                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2459                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2460                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2461                         assume_unchanged = false;
2462                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2463                 }
2464                 if (isInvisibleString(this.netname))
2465                 {
2466                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2467                         sprint(this, "Warning: invisible names are not allowed.\n");
2468                         assume_unchanged = false;
2469                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2470                 }
2471                 if (!assume_unchanged && autocvar_sv_eventlog)
2472                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2473                 strcpy(CS(this).netname_previous, this.netname);
2474         }
2475
2476         // version nagging
2477         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2478         CS(this).version_nagtime = 0;
2479         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2480             // git client
2481         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2482             // git server
2483             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2484         } else {
2485             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2486             if (r < 0) { // old client
2487                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2488             } else if (r > 0) { // old server
2489                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2490             }
2491         }
2492     }
2493
2494         // GOD MODE info
2495         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2496         {
2497                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2498                 this.max_armorvalue = 0;
2499         }
2500
2501         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2502         {
2503                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2504                 {
2505                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2506                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2507                         if (this.iceblock)
2508                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2509
2510                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2511                                 Unfreeze(this, false);
2512                 }
2513                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2514                 {
2515                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2516                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2517
2518                         if (GetResource(this, RES_HEALTH) < 1)
2519                         {
2520                                 if (this.vehicle)
2521                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2522                                 if(this.event_damage)
2523                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2524                         }
2525                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2526                                 Unfreeze(this, false);
2527                 }
2528         }
2529
2530         MUTATOR_CALLHOOK(PlayerPreThink, this);
2531
2532         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2533         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2534         {
2535                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2536                 {
2537                         if(!it.owner)
2538                         {
2539                                 if(!it.team || SAME_TEAM(this, it))
2540                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2541                                 else if(autocvar_g_vehicles_steal)
2542                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2543                         }
2544                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2545                         {
2546                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2547                         }
2548                 });
2549
2550                 this.last_vehiclecheck = time + 1;
2551         }
2552
2553         if(!CS_CVAR(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2554         {
2555                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2556                         PlayerUseKey(this);
2557                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2558         }
2559
2560         if (IS_REAL_CLIENT(this))
2561                 PrintWelcomeMessage(this);
2562
2563         if (IS_PLAYER(this)) {
2564                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2565                         error("Client can't be spawned as player on connection!");
2566                 if(!PlayerThink(this))
2567                         return;
2568         }
2569         else if (game_stopped || intermission_running) {
2570                 if(intermission_running)
2571                         IntermissionThink(this);
2572                 return;
2573         }
2574         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2575         {
2576                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2577                 CS(this).autojoin_checked = 1;
2578                 // don't do this in ClientConnect
2579                 // many things can go wrong if a client is spawned as player on connection
2580                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2581                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2582                                 && (!teamplay || autocvar_g_balance_teams)))
2583                 {
2584                         campaign_bots_may_start = true;
2585                         if(joinAllowed(this))
2586                                 Join(this);
2587                         return;
2588                 }
2589         }
2590         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2591                 ObserverOrSpectatorThink(this);
2592         }
2593
2594         // WEAPONTODO: Add weapon request for this
2595         if (!zoomstate_set) {
2596                 bool wep_zoomed = false;
2597                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2598                 {
2599                         .entity weaponentity = weaponentities[slot];
2600                         Weapon thiswep = this.(weaponentity).m_weapon;
2601                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2602                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2603                 }
2604                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2605         }
2606
2607         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2608         {
2609                 CS(this).teamkill_soundtime = 0;
2610
2611                 entity e = CS(this).teamkill_soundsource;
2612                 entity oldpusher = e.pusher;
2613                 e.pusher = this;
2614                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2615                 e.pusher = oldpusher;
2616         }
2617
2618         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2619                 CS(this).taunt_soundtime = 0;
2620                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2621         }
2622
2623         target_voicescript_next(this);
2624 }
2625
2626 void DrownPlayer(entity this)
2627 {
2628         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2629                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2630         {
2631                 STAT(AIR_FINISHED, this) = 0;
2632                 return;
2633         }
2634
2635         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2636         {
2637                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2638                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2639                 STAT(AIR_FINISHED, this) = 0;
2640         }
2641         else
2642         {
2643                 if (!STAT(AIR_FINISHED, this))
2644                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2645                 if (STAT(AIR_FINISHED, this) < time)
2646                 {       // drown!
2647                         if (this.pain_finished < time)
2648                         {
2649                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2650                                 this.pain_finished = time + 0.5;
2651                         }
2652                 }
2653         }
2654 }
2655
2656 .bool move_qcphysics;
2657
2658 void Player_Physics(entity this)
2659 {
2660         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2661
2662         if(!this.move_qcphysics)
2663                 return;
2664
2665         if(!frametime && !CS(this).pm_frametime)
2666                 return;
2667
2668         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2669
2670         CS(this).pm_frametime = 0;
2671 }
2672
2673 /*
2674 =============
2675 PlayerPostThink
2676
2677 Called every frame for each client after the physics are run
2678 =============
2679 */
2680 void PlayerPostThink (entity this)
2681 {
2682         Player_Physics(this);
2683
2684         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2685         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2686         if (IS_REAL_CLIENT(this))
2687         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2688         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2689         {
2690                 int totalClients = 0;
2691                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2692                 {
2693                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2694                         {
2695                                 ++totalClients;
2696                         });
2697                 }
2698
2699                 if (autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2700                 { /* do nothing */ }
2701                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2702                 {
2703                         if (CS(this).idlekick_lasttimeleft)
2704                         {
2705                                 CS(this).idlekick_lasttimeleft = 0;
2706                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2707                         }
2708                 }
2709                 else
2710                 {
2711                         float maxidle_time = autocvar_sv_maxidle;
2712                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2713                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2714                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2715                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2716                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2717                         {
2718                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2719                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2720                                 else
2721                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2722                         }
2723                         if (timeleft <= 0) {
2724                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2725                                 {
2726                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2727                                         if (this.caplayer)
2728                                                 this.caplayer = 0;
2729                                         this.lms_spectate_warning = 2; // TODO: mutator hook for players forcibly moved to spectator?
2730                                         PutObserverInServer(this);
2731                                 }
2732                                 else
2733                                 {
2734                                         if (dropclient_schedule(this))
2735                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2736                                 }
2737                                 return;
2738                         }
2739                         else if (timeleft <= countdown_time) {
2740                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2741                                         play2(this, SND(TALK2));
2742                                 CS(this).idlekick_lasttimeleft = timeleft;
2743                         }
2744                 }
2745         }
2746
2747         CheatFrame(this);
2748
2749         if (game_stopped)
2750         {
2751                 this.solid = SOLID_NOT;
2752                 this.takedamage = DAMAGE_NO;
2753                 set_movetype(this, MOVETYPE_NONE);
2754                 CS(this).teamkill_complain = 0;
2755                 CS(this).teamkill_soundtime = 0;
2756                 CS(this).teamkill_soundsource = NULL;
2757         }
2758
2759         if (IS_PLAYER(this)) {
2760                 if(this.death_time == time && IS_DEAD(this))
2761                 {
2762                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2763                         // once all the damage events of this frame have been processed with normal size
2764                         this.maxs.z = 5;
2765                         setsize(this, this.mins, this.maxs);
2766                 }
2767                 DrownPlayer(this);
2768                 UpdateChatBubble(this);
2769                 if (CS(this).impulse) ImpulseCommands(this);
2770                 GetPressedKeys(this);
2771                 if (game_stopped)
2772                 {
2773                         CSQCMODEL_AUTOUPDATE(this);
2774                         return;
2775                 }
2776         }
2777         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2778         {
2779                 CS(this).pressedkeys = 0;
2780                 STAT(PRESSED_KEYS, this) = 0;
2781         }
2782
2783         if (this.waypointsprite_attachedforcarrier) {
2784                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2785                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2786         }
2787
2788         CSQCMODEL_AUTOUPDATE(this);
2789 }
2790
2791 // hack to copy the button fields from the client entity to the Client State
2792 void PM_UpdateButtons(entity this, entity store)
2793 {
2794         if(this.impulse)
2795                 store.impulse = this.impulse;
2796         this.impulse = 0;
2797
2798         bool typing = this.buttonchat || this.button12;
2799
2800         store.button0 = (typing) ? 0 : this.button0;
2801         //button1?!
2802         store.button2 = (typing) ? 0 : this.button2;
2803         store.button3 = (typing) ? 0 : this.button3;
2804         store.button4 = this.button4;
2805         store.button5 = (typing) ? 0 : this.button5;
2806         store.button6 = this.button6;
2807         store.button7 = this.button7;
2808         store.button8 = this.button8;
2809         store.button9 = this.button9;
2810         store.button10 = this.button10;
2811         store.button11 = this.button11;
2812         store.button12 = this.button12;
2813         store.button13 = this.button13;
2814         store.button14 = this.button14;
2815         store.button15 = this.button15;
2816         store.button16 = this.button16;
2817         store.buttonuse = this.buttonuse;
2818         store.buttonchat = this.buttonchat;
2819
2820         store.cursor_active = this.cursor_active;
2821         store.cursor_screen = this.cursor_screen;
2822         store.cursor_trace_start = this.cursor_trace_start;
2823         store.cursor_trace_endpos = this.cursor_trace_endpos;
2824         store.cursor_trace_ent = this.cursor_trace_ent;
2825
2826         store.ping = this.ping;
2827         store.ping_packetloss = this.ping_packetloss;
2828         store.ping_movementloss = this.ping_movementloss;
2829
2830         store.v_angle = this.v_angle;
2831         store.movement = this.movement;
2832 }
2833
2834 NET_HANDLE(fpsreport, bool)
2835 {
2836         int fps = ReadShort();
2837         PlayerScore_Set(sender, SP_FPS, fps);
2838         return true;
2839 }