qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/state.qh>
  34 #include <common/stats.qh>
  35 #include <common/vehicles/all.qh>
  36 #include <common/vehicles/sv_vehicles.qh>
  37 #include <common/viewloc.qh>
  38 #include <common/weapons/_all.qh>
  39 #include <common/weapons/weapon/vortex.qh>
  40 #include <common/wepent.qh>
  41 #include <lib/csqcmodel/sv_model.qh>
  42 #include <lib/warpzone/common.qh>
  43 #include <lib/warpzone/server.qh>
  44 #include <server/anticheat.qh>
  45 #include <server/antilag.qh>
  46 #include <server/bot/api.qh>
  47 #include <server/bot/default/cvars.qh>
  48 #include <server/campaign.qh>
  49 #include <server/chat.qh>
  50 #include <server/cheats.qh>
  51 #include <server/clientkill.qh>
  52 #include <server/command/common.qh>
  53 #include <server/command/common.qh>
  54 #include <server/command/vote.qh>
  55 #include <server/compat/quake3.qh>
  56 #include <server/damage.qh>
  57 #include <server/gamelog.qh>
  58 #include <server/handicap.qh>
  59 #include <server/hook.qh>
  60 #include <server/impulse.qh>
  61 #include <server/intermission.qh>
  62 #include <server/ipban.qh>
  63 #include <server/main.qh>
  64 #include <server/mutators/_mod.qh>
  65 #include <server/player.qh>
  66 #include <server/portals.qh>
  67 #include <server/race.qh>
  68 #include <server/resources.qh>
  69 #include <server/scores.qh>
  70 #include <server/scores_rules.qh>
  71 #include <server/spawnpoints.qh>
  72 #include <server/teamplay.qh>
  73 #include <server/weapons/accuracy.qh>
  74 #include <server/weapons/common.qh>
  75 #include <server/weapons/hitplot.qh>
  76 #include <server/weapons/selection.qh>
  77 #include <server/weapons/tracing.qh>
  78 #include <server/weapons/weaponsystem.qh>
  79 #include <server/world.qh>
  80
  81 STATIC_METHOD(Client, Add, void(Client this, int _team))
  82 {
  83     ClientConnect(this);
  84     TRANSMUTE(Player, this);
  85     this.frame = 12; // 7
  86     this.team = _team;
  87     PutClientInServer(this);
  88 }
  89
  90 STATIC_METHOD(Client, Remove, void(Client this))
  91 {
  92     TRANSMUTE(Observer, this);
  93     PutClientInServer(this);
  94     ClientDisconnect(this);
  95 }
  96
  97 void send_CSQC_teamnagger() {
  98         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  99 }
 100
 101 void send_TeamNames(int channel, entity to) {
 102         msg_entity = to;
 103
 104         WriteHeader(channel, TE_CSQC_TEAMNAMES);
 105         WriteString(channel, autocvar_g_teamnames_red);
 106         WriteString(channel, autocvar_g_teamnames_blue);
 107         WriteString(channel, autocvar_g_teamnames_yellow);
 108         WriteString(channel, autocvar_g_teamnames_pink);
 109 }
 110
 111 int CountSpectators(entity player, entity to)
 112 {
 113         if(!player) { return 0; } // not sure how, but best to be safe
 114
 115         int spec_count = 0;
 116
 117         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 118         {
 119                 spec_count++;
 120         });
 121
 122         return spec_count;
 123 }
 124
 125 void WriteSpectators(entity player, entity to)
 126 {
 127         if(!player) { return; } // not sure how, but best to be safe
 128
 129         int spec_count = 0;
 130         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 131         {
 132                 if(spec_count >= MAX_SPECTATORS)
 133                         break;
 134                 WriteByte(MSG_ENTITY, num_for_edict(it));
 135                 ++spec_count;
 136         });
 137 }
 138
 139 bool ClientData_Send(entity this, entity to, int sf)
 140 {
 141         assert(to == this.owner, return false);
 142
 143         entity e = to;
 144         if (IS_SPEC(e)) e = e.enemy;
 145
 146         sf = 0;
 147         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 148         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 149         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 150         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 151
 152         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 153         WriteByte(MSG_ENTITY, sf);
 154
 155         if (sf & BIT(1))
 156                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 157
 158         if(sf & BIT(4))
 159         {
 160                 float specs = CountSpectators(e, to);
 161                 WriteByte(MSG_ENTITY, specs);
 162                 WriteSpectators(e, to);
 163         }
 164
 165         return true;
 166 }
 167
 168 void ClientData_Attach(entity this)
 169 {
 170         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 171         CS(this).clientdata.drawonlytoclient = this;
 172         CS(this).clientdata.owner = this;
 173 }
 174
 175 void ClientData_Detach(entity this)
 176 {
 177         delete(CS(this).clientdata);
 178         CS(this).clientdata = NULL;
 179 }
 180
 181 void ClientData_Touch(entity e)
 182 {
 183         entity cd = CS(e).clientdata;
 184         if (cd) { cd.SendFlags = 1; }
 185
 186         // make it spectatable
 187         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 188         {
 189                 entity cd = CS(it).clientdata;
 190                 if (cd) { cd.SendFlags = 1; }
 191         });
 192 }
 193
 194
 195 /*
 196 =============
 197 CheckPlayerModel
 198
 199 Checks if the argument string can be a valid playermodel.
 200 Returns a valid one in doubt.
 201 =============
 202 */
 203 string FallbackPlayerModel;
 204 string CheckPlayerModel(string plyermodel) {
 205         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 206         {
 207                 // note: we cannot summon Don Strunzone here, some player may
 208                 // still have the model string set. In case anyone manages how
 209                 // to change a cvar default, we'll have a small leak here.
 210                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 211         }
 212         // only in right path
 213         if(substring(plyermodel, 0, 14) != "models/player/")
 214                 return FallbackPlayerModel;
 215         // only good file extensions
 216         if(substring(plyermodel, -4, 4) != ".iqm"
 217                 && substring(plyermodel, -4, 4) != ".zym"
 218                 && substring(plyermodel, -4, 4) != ".dpm"
 219                 && substring(plyermodel, -4, 4) != ".md3"
 220                 && substring(plyermodel, -4, 4) != ".psk")
 221         {
 222                 return FallbackPlayerModel;
 223         }
 224         // forbid the LOD models
 225         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 226                 return FallbackPlayerModel;
 227         if(plyermodel != strtolower(plyermodel))
 228                 return FallbackPlayerModel;
 229         // also, restrict to server models
 230         if(autocvar_sv_servermodelsonly)
 231         {
 232                 if(!fexists(plyermodel))
 233                         return FallbackPlayerModel;
 234         }
 235         return plyermodel;
 236 }
 237
 238 void setplayermodel(entity e, string modelname)
 239 {
 240         precache_model(modelname);
 241         _setmodel(e, modelname);
 242         player_setupanimsformodel(e);
 243         if(!autocvar_g_debug_globalsounds)
 244                 UpdatePlayerSounds(e);
 245 }
 246
 247 /** putting a client as observer in the server */
 248 void PutObserverInServer(entity this, bool is_forced)
 249 {
 250         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 251         PlayerState_detach(this);
 252
 253         if (IS_PLAYER(this))
 254         {
 255                 if(GetResource(this, RES_HEALTH) >= 1)
 256                 {
 257                         // despawn effect
 258                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 259                 }
 260
 261                 // was a player, recount votes and ready status
 262                 if(IS_REAL_CLIENT(this))
 263                 {
 264                         if (vote_called) { VoteCount(false); }
 265                         ReadyCount();
 266                 }
 267                 entcs_update_players(this);
 268         }
 269
 270         entity spot = SelectSpawnPoint(this, true);
 271         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 272         this.angles = vec2(spot.angles);
 273         this.fixangle = true;
 274         // offset it so that the spectator spawns higher off the ground, looks better this way
 275         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 276         if (IS_REAL_CLIENT(this))
 277         {
 278                 msg_entity = this;
 279                 WriteByte(MSG_ONE, SVC_SETVIEW);
 280                 WriteEntity(MSG_ONE, this);
 281         }
 282         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 283         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 284         if(!autocvar_g_debug_globalsounds)
 285         {
 286                 // needed for player sounds
 287                 this.model = "";
 288                 FixPlayermodel(this);
 289         }
 290         setmodel(this, MDL_Null);
 291         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 292         this.view_ofs = '0 0 0';
 293
 294         RemoveGrapplingHooks(this);
 295         Portal_ClearAll(this);
 296         Unfreeze(this, false);
 297         SetSpectatee(this, NULL);
 298
 299         if (this.alivetime)
 300         {
 301                 if (!warmup_stage)
 302                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 303                 this.alivetime = 0;
 304         }
 305
 306         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 307
 308         WaypointSprite_PlayerDead(this);
 309
 310         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 311                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 312
 313         accuracy_resend(this);
 314
 315         CS(this).spectatortime = time;
 316         if(this.bot_attack)
 317                 IL_REMOVE(g_bot_targets, this);
 318         this.bot_attack = false;
 319         if(this.monster_attack)
 320                 IL_REMOVE(g_monster_targets, this);
 321         this.monster_attack = false;
 322         STAT(HUD, this) = HUD_NORMAL;
 323         TRANSMUTE(Observer, this);
 324         this.iscreature = false;
 325         this.teleportable = TELEPORT_SIMPLE;
 326         if(this.damagedbycontents)
 327                 IL_REMOVE(g_damagedbycontents, this);
 328         this.damagedbycontents = false;
 329         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 330         SetSpectatee_status(this, etof(this));
 331         this.takedamage = DAMAGE_NO;
 332         this.solid = SOLID_NOT;
 333         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 334         this.flags = FL_CLIENT | FL_NOTARGET;
 335         this.effects = 0;
 336         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 337         this.pauserotarmor_finished = 0;
 338         this.pauserothealth_finished = 0;
 339         this.pauseregen_finished = 0;
 340         this.damageforcescale = 0;
 341         this.death_time = 0;
 342         this.respawn_flags = 0;
 343         this.respawn_time = 0;
 344         STAT(RESPAWN_TIME, this) = 0;
 345         this.alpha = 0;
 346         this.scale = 0;
 347         this.fade_time = 0;
 348         this.pain_finished = 0;
 349         STAT(AIR_FINISHED, this) = 0;
 350         //this.dphitcontentsmask = 0;
 351         this.dphitcontentsmask = DPCONTENTS_SOLID;
 352         if (autocvar_g_playerclip_collisions)
 353                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 354         this.pushltime = 0;
 355         this.istypefrag = 0;
 356         setthink(this, func_null);
 357         this.nextthink = 0;
 358         this.deadflag = DEAD_NO;
 359         UNSET_DUCKED(this);
 360         STAT(REVIVE_PROGRESS, this) = 0;
 361         this.revival_time = 0;
 362         this.draggable = drag_undraggable;
 363
 364         this.items = 0;
 365         STAT(WEAPONS, this) = '0 0 0';
 366         this.drawonlytoclient = this;
 367
 368         this.viewloc = NULL;
 369
 370         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 371
 372         this.weaponmodel = "";
 373         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 374         {
 375                 this.weaponentities[slot] = NULL;
 376         }
 377         this.exteriorweaponentity = NULL;
 378         CS(this).killcount = FRAGS_SPECTATOR;
 379         this.velocity = '0 0 0';
 380         this.avelocity = '0 0 0';
 381         this.punchangle = '0 0 0';
 382         this.punchvector = '0 0 0';
 383         this.oldvelocity = this.velocity;
 384         this.event_damage = func_null;
 385         this.event_heal = func_null;
 386
 387         for(int slot = 0; slot < MAX_AXH; ++slot)
 388         {
 389                 entity axh = this.(AuxiliaryXhair[slot]);
 390                 this.(AuxiliaryXhair[slot]) = NULL;
 391
 392                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 393                         delete(axh);
 394         }
 395
 396         if (mutator_returnvalue)
 397         {
 398                 // mutator prevents resetting teams+score
 399         }
 400         else
 401         {
 402                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 403                 this.frags = FRAGS_SPECTATOR;
 404         }
 405
 406         bot_relinkplayerlist();
 407
 408         if (CS(this).just_joined)
 409                 CS(this).just_joined = false;
 410
 411         // for RJZ
 412         if (autocvar_g_count_shards) {
 413                 total_shards = 0;
 414                 send_TotalShards(this);
 415         }
 416 }
 417
 418 int player_getspecies(entity this)
 419 {
 420         get_model_parameters(this.model, this.skin);
 421         int s = get_model_parameters_species;
 422         get_model_parameters(string_null, 0);
 423         if (s < 0) return SPECIES_HUMAN;
 424         return s;
 425 }
 426
 427 .float model_randomizer;
 428 void FixPlayermodel(entity player)
 429 {
 430         string defaultmodel = "";
 431         int defaultskin = 0;
 432         if(autocvar_sv_defaultcharacter)
 433         {
 434                 if(teamplay)
 435                 {
 436                         switch(player.team)
 437                         {
 438                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 439                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 440                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 441                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 442                         }
 443                 }
 444
 445                 if(defaultmodel == "")
 446                 {
 447                         defaultmodel = autocvar_sv_defaultplayermodel;
 448                         defaultskin = autocvar_sv_defaultplayerskin;
 449                 }
 450
 451                 int n = tokenize_console(defaultmodel);
 452                 if(n > 0)
 453                 {
 454                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 455                         // However, do NOT randomize if the player-selected model is in the list.
 456                         for (int i = 0; i < n; ++i)
 457                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 458                                         defaultmodel = argv(i);
 459                 }
 460
 461                 int i = strstrofs(defaultmodel, ":", 0);
 462                 if(i >= 0)
 463                 {
 464                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 465                         defaultmodel = substring(defaultmodel, 0, i);
 466                 }
 467         }
 468         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 469         {
 470                 if(teamplay)
 471                 {
 472                         switch(player.team)
 473                         {
 474                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 475                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 476                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 477                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 478                         }
 479                 }
 480
 481                 if(!defaultskin)
 482                         defaultskin = autocvar_sv_defaultplayerskin;
 483         }
 484
 485         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 486         defaultmodel = M_ARGV(0, string);
 487         defaultskin = M_ARGV(1, int);
 488
 489         bool chmdl = false;
 490         int oldskin;
 491         if(defaultmodel != "")
 492         {
 493                 if (defaultmodel != player.model)
 494                 {
 495                         vector m1 = player.mins;
 496                         vector m2 = player.maxs;
 497                         setplayermodel (player, defaultmodel);
 498                         setsize (player, m1, m2);
 499                         chmdl = true;
 500                 }
 501
 502                 oldskin = player.skin;
 503                 player.skin = defaultskin;
 504         } else {
 505                 if (player.playermodel != player.model || player.playermodel == "")
 506                 {
 507                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 508                         vector m1 = player.mins;
 509                         vector m2 = player.maxs;
 510                         setplayermodel (player, player.playermodel);
 511                         setsize (player, m1, m2);
 512                         chmdl = true;
 513                 }
 514
 515                 if(!autocvar_sv_defaultcharacterskin)
 516                 {
 517                         oldskin = player.skin;
 518                         player.skin = stof(player.playerskin);
 519                 }
 520                 else
 521                 {
 522                         oldskin = player.skin;
 523                         player.skin = defaultskin;
 524                 }
 525         }
 526
 527         if(chmdl || oldskin != player.skin) // model or skin has changed
 528         {
 529                 player.species = player_getspecies(player); // update species
 530                 if(!autocvar_g_debug_globalsounds)
 531                         UpdatePlayerSounds(player); // update skin sounds
 532         }
 533
 534         if(!teamplay)
 535                 if(strlen(autocvar_sv_defaultplayercolors))
 536                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 537                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 538 }
 539
 540 void ResetPlayerResources(entity this)
 541 {
 542         if (warmup_stage) {
 543                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 544                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 545                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 546                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 547                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 548                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 549                 SetResource(this, RES_HEALTH, warmup_start_health);
 550                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 551                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 552         } else {
 553                 SetResource(this, RES_SHELLS, start_ammo_shells);
 554                 SetResource(this, RES_BULLETS, start_ammo_nails);
 555                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 556                 SetResource(this, RES_CELLS, start_ammo_cells);
 557                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 558                 SetResource(this, RES_FUEL, start_ammo_fuel);
 559                 SetResource(this, RES_HEALTH, start_health);
 560                 SetResource(this, RES_ARMOR, start_armorvalue);
 561                 STAT(WEAPONS, this) = start_weapons;
 562                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 563                 {
 564                         GiveRandomWeapons(this, random_start_weapons_count,
 565                                 autocvar_g_random_start_weapons, random_start_ammo);
 566                 }
 567         }
 568 }
 569
 570 void PutPlayerInServer(entity this)
 571 {
 572         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 573
 574         PlayerState_attach(this);
 575         accuracy_resend(this);
 576
 577         if (this.team < 0)
 578                 TeamBalance_JoinBestTeam(this);
 579
 580         entity spot = SelectSpawnPoint(this, false);
 581         if (!spot) {
 582                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 583                 return; // spawn failed
 584         }
 585
 586         TRANSMUTE(Player, this);
 587
 588         CS(this).wasplayer = true;
 589         this.iscreature = true;
 590         this.teleportable = TELEPORT_NORMAL;
 591         if(!this.damagedbycontents)
 592                 IL_PUSH(g_damagedbycontents, this);
 593         this.damagedbycontents = true;
 594         set_movetype(this, MOVETYPE_WALK);
 595         this.solid = SOLID_SLIDEBOX;
 596         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 597         if (autocvar_g_playerclip_collisions)
 598                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 599         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 600                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 601         this.frags = FRAGS_PLAYER;
 602         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 603         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 604         if (autocvar__notarget)
 605                 this.flags |= FL_NOTARGET;
 606         this.takedamage = DAMAGE_AIM;
 607         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 608
 609         ResetPlayerResources(this);
 610
 611         SetSpectatee_status(this, 0);
 612
 613         PS(this).dual_weapons = '0 0 0';
 614
 615         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 616                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 617
 618         this.items = start_items;
 619
 620         float shieldtime = time + autocvar_g_spawnshieldtime;
 621
 622         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 623         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 624         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 625         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 626         if (!sv_ready_restart_after_countdown && time < game_starttime)
 627         {
 628                 float f = game_starttime - time;
 629                 shieldtime += f;
 630                 this.pauserotarmor_finished += f;
 631                 this.pauserothealth_finished += f;
 632                 this.pauseregen_finished += f;
 633         }
 634
 635         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 636
 637         this.damageforcescale = autocvar_g_player_damageforcescale;
 638         this.death_time = 0;
 639         this.respawn_flags = 0;
 640         this.respawn_time = 0;
 641         STAT(RESPAWN_TIME, this) = 0;
 642         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 643         this.fade_time = 0;
 644         this.pain_finished = 0;
 645         this.pushltime = 0;
 646         setthink(this, func_null); // players have no think function
 647         this.nextthink = 0;
 648         this.dmg_team = 0;
 649         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 650
 651         this.deadflag = DEAD_NO;
 652
 653         this.angles = spot.angles;
 654         this.angles_z = 0; // never spawn tilted even if the spot says to
 655         if (IS_BOT_CLIENT(this))
 656         {
 657                 this.v_angle = this.angles;
 658                 bot_aim_reset(this);
 659         }
 660         this.fixangle = true; // turn this way immediately
 661         this.oldvelocity = this.velocity = '0 0 0';
 662         this.avelocity = '0 0 0';
 663         this.punchangle = '0 0 0';
 664         this.punchvector = '0 0 0';
 665
 666         STAT(REVIVE_PROGRESS, this) = 0;
 667         this.revival_time = 0;
 668
 669         STAT(AIR_FINISHED, this) = 0;
 670         this.waterlevel = WATERLEVEL_NONE;
 671         this.watertype = CONTENT_EMPTY;
 672
 673         entity spawnevent = new_pure(spawnevent);
 674         spawnevent.owner = this;
 675         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 676
 677         // Cut off any still running player sounds.
 678         stopsound(this, CH_PLAYER_SINGLE);
 679
 680         this.model = "";
 681         FixPlayermodel(this);
 682         this.drawonlytoclient = NULL;
 683
 684         this.viewloc = NULL;
 685
 686         for(int slot = 0; slot < MAX_AXH; ++slot)
 687         {
 688                 entity axh = this.(AuxiliaryXhair[slot]);
 689                 this.(AuxiliaryXhair[slot]) = NULL;
 690
 691                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 692                         delete(axh);
 693         }
 694
 695         this.spawnpoint_targ = NULL;
 696
 697         UNSET_DUCKED(this);
 698         this.view_ofs = STAT(PL_VIEW_OFS, this);
 699         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 700         this.spawnorigin = spot.origin;
 701         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 702         // don't reset back to last position, even if new position is stuck in solid
 703         this.oldorigin = this.origin;
 704         if(this.conveyor)
 705                 IL_REMOVE(g_conveyed, this);
 706         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 707         if(this.swampslug)
 708                 IL_REMOVE(g_swamped, this);
 709         this.swampslug = NULL;
 710         this.swamp_interval = 0;
 711         if(this.ladder_entity)
 712                 IL_REMOVE(g_ladderents, this);
 713         this.ladder_entity = NULL;
 714         IL_EACH(g_counters, it.realowner == this,
 715         {
 716                 delete(it);
 717         });
 718         STAT(HUD, this) = HUD_NORMAL;
 719
 720         this.event_damage = PlayerDamage;
 721         this.event_heal = PlayerHeal;
 722
 723         this.draggable = func_null;
 724
 725         if(!this.bot_attack)
 726                 IL_PUSH(g_bot_targets, this);
 727         this.bot_attack = true;
 728         if(!this.monster_attack)
 729                 IL_PUSH(g_monster_targets, this);
 730         this.monster_attack = true;
 731         navigation_dynamicgoal_init(this, false);
 732
 733         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 734
 735         // player was spectator
 736         if (CS(this).killcount == FRAGS_SPECTATOR) {
 737                 PlayerScore_Clear(this);
 738                 CS(this).killcount = 0;
 739                 CS(this).startplaytime = time;
 740         }
 741
 742         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 743         {
 744                 .entity weaponentity = weaponentities[slot];
 745                 CL_SpawnWeaponentity(this, weaponentity);
 746         }
 747         this.alpha = default_player_alpha;
 748         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 749         this.exteriorweaponentity.alpha = default_weapon_alpha;
 750
 751         this.speedrunning = false;
 752
 753         this.counter_cnt = 0;
 754         this.fragsfilter_cnt = 0;
 755
 756         target_voicescript_clear(this);
 757
 758         // reset fields the weapons may use
 759         FOREACH(Weapons, true, {
 760                 it.wr_resetplayer(it, this);
 761                         // reload all reloadable weapons
 762                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 763                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 764                         {
 765                                 .entity weaponentity = weaponentities[slot];
 766                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 767                         }
 768                 }
 769         });
 770
 771         Unfreeze(this, false);
 772
 773         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 774
 775         {
 776                 string s = spot.target;
 777                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 778                         spot.target = string_null;
 779                 SUB_UseTargets(spot, this, NULL);
 780                 if(g_assault || g_race)
 781                         spot.target = s;
 782         }
 783
 784         if (autocvar_spawn_debug)
 785         {
 786                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 787                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 788         }
 789
 790         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 791         {
 792                 .entity weaponentity = weaponentities[slot];
 793                 entity w_ent = this.(weaponentity);
 794                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 795                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 796                 else
 797                         w_ent.m_switchweapon = WEP_Null;
 798                 w_ent.m_weapon = WEP_Null;
 799                 w_ent.weaponname = "";
 800                 w_ent.m_switchingweapon = WEP_Null;
 801                 w_ent.cnt = -1;
 802         }
 803
 804         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 805
 806         if (CS(this).impulse) ImpulseCommands(this);
 807
 808         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 809         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 810         {
 811                 .entity weaponentity = weaponentities[slot];
 812                 W_WeaponFrame(this, weaponentity);
 813         }
 814
 815         if (!warmup_stage && !this.alivetime)
 816                 this.alivetime = time;
 817
 818         antilag_clear(this, CS(this));
 819 }
 820
 821 /** Called when a client spawns in the server */
 822 void PutClientInServer(entity this)
 823 {
 824         if (IS_BOT_CLIENT(this)) {
 825                 TRANSMUTE(Player, this);
 826         } else if (IS_REAL_CLIENT(this)) {
 827                 msg_entity = this;
 828                 WriteByte(MSG_ONE, SVC_SETVIEW);
 829                 WriteEntity(MSG_ONE, this);
 830         }
 831         if (game_stopped)
 832                 TRANSMUTE(Observer, this);
 833
 834         SetSpectatee(this, NULL);
 835
 836         // reset player keys
 837         if(PS(this))
 838                 PS(this).itemkeys = 0;
 839
 840         MUTATOR_CALLHOOK(PutClientInServer, this);
 841
 842         if (IS_OBSERVER(this)) {
 843                 PutObserverInServer(this, false);
 844         } else if (IS_PLAYER(this)) {
 845                 PutPlayerInServer(this);
 846         }
 847         // send team names
 848         if(teamplay && IS_REAL_CLIENT(this))
 849                 send_TeamNames(MSG_ONE, this);
 850         bot_relinkplayerlist();
 851 }
 852
 853 // TODO do we need all these fields, or should we stop autodetecting runtime
 854 // changes and just have a console command to update this?
 855 bool ClientInit_SendEntity(entity this, entity to, int sf)
 856 {
 857         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 858         return = true;
 859         msg_entity = to;
 860         // MSG_INIT replacement
 861         // TODO: make easier to use
 862         Registry_send_all();
 863         W_PROP_reload(MSG_ONE, to);
 864         ClientInit_misc(this);
 865         MUTATOR_CALLHOOK(Ent_Init);
 866 }
 867 void ClientInit_misc(entity this)
 868 {
 869         int channel = MSG_ONE;
 870         WriteHeader(channel, ENT_CLIENT_INIT);
 871         WriteByte(channel, g_nexball_meter_period * 32);
 872         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 873         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 874         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 875         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 876         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 877         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 878         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 879         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 880
 881         if(autocvar_sv_foginterval && world.fog != "")
 882                 WriteString(channel, world.fog);
 883         else
 884                 WriteString(channel, "");
 885         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 886         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 887         WriteByte(channel, serverflags);
 888         WriteCoord(channel, autocvar_g_trueaim_minrange);
 889
 890         // z411 send full hostname
 891         WriteString(channel, (autocvar_hostname_full != "" ? autocvar_hostname_full : autocvar_hostname));
 892         WriteString(channel, autocvar_sv_motd_permanent);
 893
 894         // z411 send client countdown type
 895         WriteByte(channel, autocvar_sv_timer_countdown);
 896 }
 897
 898 void ClientInit_CheckUpdate(entity this)
 899 {
 900         this.nextthink = time;
 901         if(this.count != autocvar_g_balance_armor_blockpercent)
 902         {
 903                 this.count = autocvar_g_balance_armor_blockpercent;
 904                 this.SendFlags |= 1;
 905         }
 906         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 907         {
 908                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 909                 this.SendFlags |= 1;
 910         }
 911 }
 912
 913 void ClientInit_Spawn()
 914 {
 915         entity e = new_pure(clientinit);
 916         setthink(e, ClientInit_CheckUpdate);
 917         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 918
 919         ClientInit_CheckUpdate(e);
 920 }
 921
 922 /*
 923 =============
 924 SetNewParms
 925 =============
 926 */
 927 void SetNewParms ()
 928 {
 929         // initialize parms for a new player
 930         parm1 = -(86400 * 366);
 931
 932         MUTATOR_CALLHOOK(SetNewParms);
 933 }
 934
 935 /*
 936 =============
 937 SetChangeParms
 938 =============
 939 */
 940 void SetChangeParms (entity this)
 941 {
 942         // save parms for level change
 943         parm1 = CS(this).parm_idlesince - time;
 944
 945         MUTATOR_CALLHOOK(SetChangeParms);
 946 }
 947
 948 /*
 949 =============
 950 DecodeLevelParms
 951 =============
 952 */
 953 void DecodeLevelParms(entity this)
 954 {
 955         // load parms
 956         CS(this).parm_idlesince = parm1;
 957         if (CS(this).parm_idlesince == -(86400 * 366))
 958                 CS(this).parm_idlesince = time;
 959
 960         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 961         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 962
 963         MUTATOR_CALLHOOK(DecodeLevelParms);
 964 }
 965
 966 void FixClientCvars(entity e)
 967 {
 968         // send prediction settings to the client
 969         stuffcmd(e, "\nin_bindmap 0 0\n");
 970         if(autocvar_g_antilag == 3) // client side hitscan
 971                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 972         if(autocvar_sv_gentle)
 973                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 974
 975         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 976         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 977
 978         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 979
 980         MUTATOR_CALLHOOK(FixClientCvars, e);
 981 }
 982
 983 bool findinlist_abbrev(string tofind, string list)
 984 {
 985         if(list == "" || tofind == "")
 986                 return false; // empty list or search, just return
 987
 988         // this function allows abbreviated strings!
 989         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 990         {
 991                 return true;
 992         });
 993
 994         return false;
 995 }
 996
 997 bool PlayerInIPList(entity p, string iplist)
 998 {
 999         // some safety checks (never allow local?)
1000         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1001                 return false;
1002
1003         return findinlist_abbrev(p.netaddress, iplist);
1004 }
1005
1006 bool PlayerInIDList(entity p, string idlist)
1007 {
1008         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1009         if(!p.crypto_idfp)
1010                 return false;
1011
1012         return findinlist_abbrev(p.crypto_idfp, idlist);
1013 }
1014
1015 bool PlayerInList(entity player, string list)
1016 {
1017         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1018 }
1019
1020 #ifdef DP_EXT_PRECONNECT
1021 /*
1022 =============
1023 ClientPreConnect
1024
1025 Called once (not at each match start) when a client begins a connection to the server
1026 =============
1027 */
1028 void ClientPreConnect(entity this)
1029 {
1030         if(autocvar_sv_eventlog)
1031         {
1032                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1033                         this.playerid,
1034                         etof(this),
1035                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1036                 ));
1037         }
1038 }
1039 #endif
1040
1041 string GetClientVersionMessage(entity this)
1042 {
1043         if (CS(this).version_mismatch) {
1044                 if(CS(this).version < autocvar_gameversion) {
1045                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1046                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1047                 } else {
1048                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1049                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1050                 }
1051         } else {
1052                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1053         }
1054 }
1055
1056 string getwelcomemessage(entity this)
1057 {
1058         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1059         string modifications = M_ARGV(0, string);
1060
1061         if(g_weaponarena)
1062         {
1063                 if(g_weaponarena_random)
1064                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1065                 else
1066                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1067         }
1068         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1069                 modifications = strcat(modifications, ", No start weapons");
1070         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1071                 modifications = strcat(modifications, ", Low gravity");
1072         if(g_weapon_stay && !g_cts)
1073                 modifications = strcat(modifications, ", Weapons stay");
1074         if(autocvar_g_jetpack)
1075                 modifications = strcat(modifications, ", Jet pack");
1076         modifications = substring(modifications, 2, strlen(modifications) - 2);
1077
1078         //string versionmessage = GetClientVersionMessage(this);
1079         //string s = strcat(versionmessage, "^8\n^9", (autocvar_hostname_full ? autocvar_hostname_full : autocvar_hostname));
1080         string s = (autocvar_hostname_full != "" ? autocvar_hostname_full : autocvar_hostname);
1081
1082         s = strcat(s, "^8\n^7", gamemode_name);
1083
1084         if(modifications != "")
1085                 s = strcat(s, "^7 | ^3", modifications);
1086
1087         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1088         {
1089                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1090                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1091         }
1092
1093         if (cache_mutatormsg != "") {
1094                 s = strcat(s, "\n^8tips: ^7", cache_mutatormsg);
1095         }
1096
1097         string mutator_msg = "";
1098         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1099         mutator_msg = M_ARGV(0, string);
1100
1101         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1102
1103         string motd = autocvar_sv_motd;
1104         if (motd != "") {
1105                 s = strcat(s, "\n\n^7", strreplace("\\n", "\n", motd));
1106         }
1107
1108         // It's been a work, I want some credit for a while. Might remove later.
1109         s = strcat(s, "\n\nUsing BaI mod by z411 - bienvenidoainternet.org");
1110         return s;
1111 }
1112
1113 /**
1114 =============
1115 ClientConnect
1116
1117 Called when a client connects to the server
1118 =============
1119 */
1120 void ClientConnect(entity this)
1121 {
1122         if (Ban_MaybeEnforceBanOnce(this)) return;
1123         assert(!IS_CLIENT(this), return);
1124         this.flags |= FL_CLIENT;
1125         assert(player_count >= 0, player_count = 0);
1126
1127         TRANSMUTE(Client, this);
1128         CS(this).version_nagtime = time + 10 + random() * 10;
1129
1130         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1131
1132         bot_clientconnect(this);
1133
1134         Player_DetermineForcedTeam(this);
1135
1136         TRANSMUTE(Observer, this);
1137
1138         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1139
1140         // always track bots, don't ask for cl_allow_uidtracking
1141         if (IS_BOT_CLIENT(this))
1142                 PlayerStats_GameReport_AddPlayer(this);
1143         else
1144                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1145
1146         if (autocvar_sv_eventlog)
1147                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1148
1149         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1150
1151         stuffcmd(this, clientstuff, "\n");
1152         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1153
1154         FixClientCvars(this);
1155
1156         // get version info from player
1157         stuffcmd(this, "cmd clientversion $gameversion\n");
1158
1159         // notify about available teams
1160         if (teamplay)
1161         {
1162                 entity balance = TeamBalance_CheckAllowedTeams(this);
1163                 int t = TeamBalance_GetAllowedTeams(balance);
1164                 TeamBalance_Destroy(balance);
1165                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1166         }
1167         else
1168         {
1169                 stuffcmd(this, "set _teams_available 0\n");
1170         }
1171
1172         bot_relinkplayerlist();
1173
1174         CS(this).spectatortime = time;
1175         if (blockSpectators)
1176         {
1177                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1178         }
1179
1180         CS(this).jointime = time;
1181
1182         if (IS_REAL_CLIENT(this))
1183         {
1184                 if (g_weaponarena_weapons == WEPSET(TUBA))
1185                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1186         }
1187
1188         if (!autocvar_sv_foginterval && world.fog != "")
1189                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1190
1191         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1192                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1193                         send_CSQC_teamnagger();
1194
1195         CSQCMODEL_AUTOINIT(this);
1196
1197         CS(this).model_randomizer = random();
1198
1199         if (IS_REAL_CLIENT(this))
1200                 sv_notice_join(this);
1201
1202         this.move_qcphysics = autocvar_sv_qcphysics;
1203
1204         // update physics stats (players can spawn before physics runs)
1205         Physics_UpdateStats(this);
1206
1207         IL_EACH(g_initforplayer, it.init_for_player, {
1208                 it.init_for_player(it, this);
1209         });
1210
1211         Handicap_Initialize(this);
1212
1213         MUTATOR_CALLHOOK(ClientConnect, this);
1214
1215         if (IS_REAL_CLIENT(this))
1216         {
1217                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1218                 {
1219                         CS(this).motd_actived_time = -1;
1220                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1221                 }
1222         }
1223 }
1224 /*
1225 =============
1226 ClientDisconnect
1227
1228 Called when a client disconnects from the server
1229 =============
1230 */
1231 .entity chatbubbleentity;
1232 void player_powerups_remove_all(entity this);
1233
1234 void ClientDisconnect(entity this)
1235 {
1236         assert(IS_CLIENT(this), return);
1237
1238         PlayerStats_GameReport_FinalizePlayer(this);
1239         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1240         if (CS(this).active_minigame) part_minigame(this);
1241         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1242
1243         if (autocvar_sv_eventlog)
1244                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1245
1246         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1247
1248         if(IS_SPEC(this))
1249                 SetSpectatee(this, NULL);
1250
1251         MUTATOR_CALLHOOK(ClientDisconnect, this);
1252
1253         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1254         strfree(CS_CVAR(this).weaponorder_byimpulse);
1255         ClientState_detach(this);
1256
1257         Portal_ClearAll(this);
1258
1259         Unfreeze(this, false);
1260
1261         RemoveGrapplingHooks(this);
1262
1263         // Here, everything has been done that requires this player to be a client.
1264
1265         this.flags &= ~FL_CLIENT;
1266
1267         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1268         if (this.killindicator) delete(this.killindicator);
1269
1270         IL_EACH(g_counters, it.realowner == this,
1271         {
1272                 delete(it);
1273         });
1274
1275         WaypointSprite_PlayerGone(this);
1276
1277         bot_relinkplayerlist();
1278
1279         strfree(this.clientstatus);
1280         if (this.personal) delete(this.personal);
1281
1282         this.playerid = 0;
1283         ReadyCount();
1284         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1285
1286         player_powerups_remove_all(this); // stop powerup sound
1287
1288         ONREMOVE(this);
1289 }
1290
1291 void ChatBubbleThink(entity this)
1292 {
1293         this.nextthink = time;
1294         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1295         {
1296                 if(this.owner) // but why can that ever be NULL?
1297                         this.owner.chatbubbleentity = NULL;
1298                 delete(this);
1299                 return;
1300         }
1301
1302         this.mdl = "";
1303
1304         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1305         {
1306                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1307                         this.mdl = "models/sprites/minigame_busy.iqm";
1308                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1309                         this.mdl = "models/misc/chatbubble.spr";
1310         }
1311
1312         if ( this.model != this.mdl )
1313                 _setmodel(this, this.mdl);
1314
1315 }
1316
1317 void UpdateChatBubble(entity this)
1318 {
1319         if (this.alpha < 0)
1320                 return;
1321         // spawn a chatbubble entity if needed
1322         if (!this.chatbubbleentity)
1323         {
1324                 this.chatbubbleentity = new(chatbubbleentity);
1325                 this.chatbubbleentity.owner = this;
1326                 this.chatbubbleentity.exteriormodeltoclient = this;
1327                 setthink(this.chatbubbleentity, ChatBubbleThink);
1328                 this.chatbubbleentity.nextthink = time;
1329                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1330                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1331                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1332                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1333                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1334                 //this.chatbubbleentity.model = "";
1335                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1336         }
1337 }
1338
1339 void calculate_player_respawn_time(entity this)
1340 {
1341         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1342                 return;
1343
1344         float gametype_setting_tmp;
1345         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1346         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1347         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1348         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1349         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1350         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1351
1352         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1353         if (teamplay)
1354         {
1355                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1356                         if(it.team == this.team)
1357                                 ++pcount;
1358                 });
1359                 if (sdelay_small_count == 0)
1360                         sdelay_small_count = 1;
1361                 if (sdelay_large_count == 0)
1362                         sdelay_large_count = 1;
1363         }
1364         else
1365         {
1366                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1367                         ++pcount;
1368                 });
1369                 if (sdelay_small_count == 0)
1370                 {
1371                         if (IS_INDEPENDENT_PLAYER(this))
1372                         {
1373                                 // Players play independently. No point in requiring enemies.
1374                                 sdelay_small_count = 1;
1375                         }
1376                         else
1377                         {
1378                                 // Players play AGAINST each other. Enemies required.
1379                                 sdelay_small_count = 2;
1380                         }
1381                 }
1382                 if (sdelay_large_count == 0)
1383                 {
1384                         if (IS_INDEPENDENT_PLAYER(this))
1385                         {
1386                                 // Players play independently. No point in requiring enemies.
1387                                 sdelay_large_count = 1;
1388                         }
1389                         else
1390                         {
1391                                 // Players play AGAINST each other. Enemies required.
1392                                 sdelay_large_count = 2;
1393                         }
1394                 }
1395         }
1396
1397         float sdelay;
1398
1399         if (pcount <= sdelay_small_count)
1400                 sdelay = sdelay_small;
1401         else if (pcount >= sdelay_large_count)
1402                 sdelay = sdelay_large;
1403         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1404                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1405
1406         if(waves)
1407                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1408         else
1409                 this.respawn_time = time + sdelay;
1410
1411         if(sdelay < sdelay_max)
1412                 this.respawn_time_max = time + sdelay_max;
1413         else
1414                 this.respawn_time_max = this.respawn_time;
1415
1416         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1417                 this.respawn_countdown = 10; // first number to count down from is 10
1418         else
1419                 this.respawn_countdown = -1; // do not count down
1420
1421         if(autocvar_g_forced_respawn)
1422                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1423 }
1424
1425 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1426 // added to the model skins
1427 /*void UpdateColorModHack()
1428 {
1429         float c;
1430         c = this.clientcolors & 15;
1431         // LordHavoc: only bothering to support white, green, red, yellow, blue
1432              if (!teamplay) this.colormod = '0 0 0';
1433         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1434         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1435         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1436         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1437         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1438         else this.colormod = '1 1 1';
1439 }*/
1440
1441 void respawn(entity this)
1442 {
1443         bool damagedbycontents_prev = this.damagedbycontents;
1444         if(this.alpha >= 0)
1445         {
1446                 if(autocvar_g_respawn_ghosts)
1447                 {
1448                         this.solid = SOLID_NOT;
1449                         this.takedamage = DAMAGE_NO;
1450                         this.damagedbycontents = false;
1451                         set_movetype(this, MOVETYPE_FLY);
1452                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1453                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1454                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1455                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1456                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1457                         if(autocvar_g_respawn_ghosts_time > 0)
1458                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1459                 }
1460                 else
1461                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1462         }
1463
1464         CopyBody(this, 1);
1465         this.damagedbycontents = damagedbycontents_prev;
1466
1467         this.effects |= EF_NODRAW; // prevent another CopyBody
1468         PutClientInServer(this);
1469 }
1470
1471 void play_countdown(entity this, float finished, Sound samp)
1472 {
1473         TC(Sound, samp);
1474         if(IS_REAL_CLIENT(this))
1475                 if(floor(finished - time - frametime) != floor(finished - time))
1476                         if(finished - time < 6)
1477                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1478 }
1479
1480 void player_powerups_remove_all(entity this)
1481 {
1482         if (this.items & IT_SUPERWEAPON)
1483         {
1484                 // don't play the poweroff sound when the game restarts or the player disconnects
1485                 if (time > game_starttime + 1 && IS_CLIENT(this))
1486                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1487                 stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1488                 this.items -= (this.items & IT_SUPERWEAPON);
1489         }
1490 }
1491
1492 void player_powerups(entity this)
1493 {
1494         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1495                 this.modelflags |= MF_ROCKET;
1496         else
1497                 this.modelflags &= ~MF_ROCKET;
1498
1499         this.effects &= ~EF_NODEPTHTEST;
1500
1501         if (IS_DEAD(this))
1502                 player_powerups_remove_all(this);
1503
1504         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1505                 return;
1506
1507         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1508         int items_prev = this.items;
1509
1510         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1511         {
1512                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1513                 if (this.items & IT_SUPERWEAPON)
1514                 {
1515                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1516                         {
1517                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1518                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1519                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1520                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1521                         }
1522                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1523                         {
1524                                 // don't let them run out
1525                         }
1526                         else
1527                         {
1528                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1529                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1530                                 {
1531                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1532                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1533                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1534                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1535                                 }
1536                         }
1537                 }
1538                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1539                 {
1540                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1541                         {
1542                                 this.items = this.items | IT_SUPERWEAPON;
1543                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1544                                 {
1545                                         if(!g_cts)
1546                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1547                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1548                                 }
1549                         }
1550                         else
1551                         {
1552                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1553                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1554                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1555                         }
1556                 }
1557                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1558                 {
1559                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1560                 }
1561         }
1562
1563         if(autocvar_g_nodepthtestplayers)
1564                 this.effects = this.effects | EF_NODEPTHTEST;
1565
1566         if(autocvar_g_fullbrightplayers)
1567                 this.effects = this.effects | EF_FULLBRIGHT;
1568
1569         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1570 }
1571
1572 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1573 {
1574         if(current > stable)
1575                 return current;
1576         else if(current > stable - 0.25) // when close enough, "snap"
1577                 return stable;
1578         else
1579                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1580 }
1581
1582 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1583 {
1584         if(current < stable)
1585                 return current;
1586         else if(current < stable + 0.25) // when close enough, "snap"
1587                 return stable;
1588         else
1589                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1590 }
1591
1592 void RotRegen(entity this, int res, float limit_mod,
1593         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1594         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1595 {
1596         float old = GetResource(this, res);
1597         float current = old;
1598         if(current > rotstable)
1599         {
1600                 if(rotframetime > 0)
1601                 {
1602                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1603                         current = max(rotstable, current - rotlinear * rotframetime);
1604                 }
1605         }
1606         else if(current < regenstable)
1607         {
1608                 if(regenframetime > 0)
1609                 {
1610                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1611                         current = min(regenstable, current + regenlinear * regenframetime);
1612                 }
1613         }
1614
1615         float limit = GetResourceLimit(this, res) * limit_mod;
1616         if(current > limit)
1617                 current = limit;
1618
1619         if (current != old)
1620                 SetResource(this, res, current);
1621 }
1622
1623 void player_regen(entity this)
1624 {
1625         float max_mod, regen_mod, rot_mod, limit_mod;
1626         max_mod = regen_mod = rot_mod = limit_mod = 1;
1627
1628         float regen_health = autocvar_g_balance_health_regen;
1629         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1630         float regen_health_rot = autocvar_g_balance_health_rot;
1631         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1632         float regen_health_stable = autocvar_g_balance_health_regenstable;
1633         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1634         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1635                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1636         max_mod = M_ARGV(1, float);
1637         regen_mod = M_ARGV(2, float);
1638         rot_mod = M_ARGV(3, float);
1639         limit_mod = M_ARGV(4, float);
1640         regen_health = M_ARGV(5, float);
1641         regen_health_linear = M_ARGV(6, float);
1642         regen_health_rot = M_ARGV(7, float);
1643         regen_health_rotlinear = M_ARGV(8, float);
1644         regen_health_stable = M_ARGV(9, float);
1645         regen_health_rotstable = M_ARGV(10, float);
1646
1647         float rotstable, regenstable, rotframetime, regenframetime;
1648
1649         if(!mutator_returnvalue)
1650         if(!STAT(FROZEN, this))
1651         {
1652                 regenstable = autocvar_g_balance_armor_regenstable;
1653                 rotstable = autocvar_g_balance_armor_rotstable;
1654                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1655                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1656                 RotRegen(this, RES_ARMOR, limit_mod,
1657                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1658                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1659
1660                 // NOTE: max_mod is only applied to health
1661                 regenstable = regen_health_stable * max_mod;
1662                 rotstable = regen_health_rotstable * max_mod;
1663                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1664                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1665                 RotRegen(this, RES_HEALTH, limit_mod,
1666                         regenstable, regen_health, regen_health_linear, regenframetime,
1667                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1668         }
1669
1670         // if player rotted to death...  die!
1671         // check this outside above checks, as player may still be able to rot to death
1672         if(GetResource(this, RES_HEALTH) < 1)
1673         {
1674                 if(this.vehicle)
1675                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1676                 if(this.event_damage)
1677                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1678         }
1679
1680         if (!(this.items & IT_UNLIMITED_AMMO))
1681         {
1682                 regenstable = autocvar_g_balance_fuel_regenstable;
1683                 rotstable = autocvar_g_balance_fuel_rotstable;
1684                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1685                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1686                 RotRegen(this, RES_FUEL, 1,
1687                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1688                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1689         }
1690 }
1691
1692 bool zoomstate_set;
1693 void SetZoomState(entity this, float newzoom)
1694 {
1695         if(newzoom != CS(this).zoomstate)
1696         {
1697                 CS(this).zoomstate = newzoom;
1698                 ClientData_Touch(this);
1699         }
1700         zoomstate_set = true;
1701 }
1702
1703 void GetPressedKeys(entity this)
1704 {
1705         MUTATOR_CALLHOOK(GetPressedKeys, this);
1706         if (game_stopped)
1707         {
1708                 CS(this).pressedkeys = 0;
1709                 STAT(PRESSED_KEYS, this) = 0;
1710                 return;
1711         }
1712
1713         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1714         int keys = STAT(PRESSED_KEYS, this);
1715         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1716         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1717         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1718         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1719
1720         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1721         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1722         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1723         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1724         CS(this).pressedkeys = keys; // store for other users
1725
1726         STAT(PRESSED_KEYS, this) = keys;
1727 }
1728
1729 /*
1730 ======================
1731 spectate mode routines
1732 ======================
1733 */
1734
1735 void SpectateCopy(entity this, entity spectatee)
1736 {
1737         TC(Client, this); TC(Client, spectatee);
1738
1739         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1740         PS(this) = PS(spectatee);
1741         this.armortype = spectatee.armortype;
1742         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1743         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1744         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1745         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1746         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1747         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1748         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1749         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1750         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1751         CS(this).impulse = 0;
1752         this.disableclientprediction = 1; // no need to run prediction on a spectator
1753         this.items = spectatee.items;
1754         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1755         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1756         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1757         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1758         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1759         this.punchangle = spectatee.punchangle;
1760         this.view_ofs = spectatee.view_ofs;
1761         this.velocity = spectatee.velocity;
1762         this.dmg_take = spectatee.dmg_take;
1763         this.dmg_save = spectatee.dmg_save;
1764         this.dmg_inflictor = spectatee.dmg_inflictor;
1765         this.v_angle = spectatee.v_angle;
1766         this.angles = spectatee.v_angle;
1767         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1768         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1769         this.viewloc = spectatee.viewloc;
1770         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1771                 this.fixangle = true;
1772         setorigin(this, spectatee.origin);
1773         setsize(this, spectatee.mins, spectatee.maxs);
1774         SetZoomState(this, CS(spectatee).zoomstate);
1775
1776     anticheat_spectatecopy(this, spectatee);
1777         STAT(HUD, this) = STAT(HUD, spectatee);
1778         if(spectatee.vehicle)
1779     {
1780         this.angles = spectatee.v_angle;
1781
1782         //this.fixangle = false;
1783         //this.velocity = spectatee.vehicle.velocity;
1784         this.vehicle_health = spectatee.vehicle_health;
1785         this.vehicle_shield = spectatee.vehicle_shield;
1786         this.vehicle_energy = spectatee.vehicle_energy;
1787         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1788         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1789         this.vehicle_reload1 = spectatee.vehicle_reload1;
1790         this.vehicle_reload2 = spectatee.vehicle_reload2;
1791
1792         //msg_entity = this;
1793
1794        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1795             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1796            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1797            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1798
1799         //WriteByte (MSG_ONE, SVC_SETVIEW);
1800         //    WriteEntity(MSG_ONE, this);
1801         //makevectors(spectatee.v_angle);
1802         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1803     }
1804 }
1805
1806 bool SpectateUpdate(entity this)
1807 {
1808         if(!this.enemy)
1809                 return false;
1810
1811         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1812         {
1813                 SetSpectatee(this, NULL);
1814                 return false;
1815         }
1816
1817         SpectateCopy(this, this.enemy);
1818
1819         return true;
1820 }
1821
1822 bool SpectateSet(entity this)
1823 {
1824         if(!IS_PLAYER(this.enemy))
1825                 return false;
1826
1827         ClientData_Touch(this.enemy);
1828
1829         msg_entity = this;
1830         WriteByte(MSG_ONE, SVC_SETVIEW);
1831         WriteEntity(MSG_ONE, this.enemy);
1832         set_movetype(this, MOVETYPE_NONE);
1833         accuracy_resend(this);
1834
1835         if(!SpectateUpdate(this))
1836                 PutObserverInServer(this, false);
1837
1838         return true;
1839 }
1840
1841 void SetSpectatee_status(entity this, int spectatee_num)
1842 {
1843         int oldspectatee_status = CS(this).spectatee_status;
1844         CS(this).spectatee_status = spectatee_num;
1845
1846         if (CS(this).spectatee_status != oldspectatee_status)
1847         {
1848                 if (STAT(PRESSED_KEYS, this))
1849                 {
1850                         CS(this).pressedkeys = 0;
1851                         STAT(PRESSED_KEYS, this) = 0;
1852                 }
1853                 ClientData_Touch(this);
1854                 if (g_race || g_cts) race_InitSpectator();
1855         }
1856 }
1857
1858 void SetSpectatee(entity this, entity spectatee)
1859 {
1860         if(IS_BOT_CLIENT(this))
1861                 return; // bots abuse .enemy, this code is useless to them
1862
1863         entity old_spectatee = this.enemy;
1864
1865         this.enemy = spectatee;
1866
1867         // WEAPONTODO
1868         // these are required to fix the spectator bug with arc
1869         if(old_spectatee)
1870         {
1871                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1872                 {
1873                         .entity weaponentity = weaponentities[slot];
1874                         if(old_spectatee.(weaponentity).arc_beam)
1875                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1876                 }
1877         }
1878         if(this.enemy)
1879         {
1880                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1881                 {
1882                         .entity weaponentity = weaponentities[slot];
1883                         if(this.enemy.(weaponentity).arc_beam)
1884                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1885                 }
1886         }
1887
1888         if (this.enemy)
1889                 SetSpectatee_status(this, etof(this.enemy));
1890
1891         // needed to update spectator list
1892         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1893 }
1894
1895 bool Spectate(entity this, entity pl)
1896 {
1897         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1898                 return false;
1899         pl = M_ARGV(1, entity);
1900
1901         SetSpectatee(this, pl);
1902         return SpectateSet(this);
1903 }
1904
1905 bool SpectateNext(entity this)
1906 {
1907         entity ent = find(this.enemy, classname, STR_PLAYER);
1908
1909         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1910                 ent = M_ARGV(1, entity);
1911         else if (!ent)
1912                 ent = find(ent, classname, STR_PLAYER);
1913
1914         if(ent) { SetSpectatee(this, ent); }
1915
1916         return SpectateSet(this);
1917 }
1918
1919 bool SpectatePrev(entity this)
1920 {
1921         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1922         entity ent = findchain(classname, STR_PLAYER);
1923         if (!ent) // no player
1924                 return false;
1925
1926         entity first = ent;
1927         // skip players until current spectated player
1928         if(this.enemy)
1929         while(ent && ent != this.enemy)
1930                 ent = ent.chain;
1931
1932         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1933         {
1934                 case MUT_SPECPREV_FOUND:
1935                         ent = M_ARGV(1, entity);
1936                         break;
1937                 case MUT_SPECPREV_RETURN:
1938                         return true;
1939                 case MUT_SPECPREV_CONTINUE:
1940                 default:
1941                 {
1942                         if(ent.chain)
1943                                 ent = ent.chain;
1944                         else
1945                                 ent = first;
1946                         break;
1947                 }
1948         }
1949
1950         SetSpectatee(this, ent);
1951         return SpectateSet(this);
1952 }
1953
1954 /*
1955 =============
1956 ShowRespawnCountdown()
1957
1958 Update a respawn countdown display.
1959 =============
1960 */
1961 void ShowRespawnCountdown(entity this)
1962 {
1963         float number;
1964         if(!IS_DEAD(this)) // just respawned?
1965                 return;
1966         else
1967         {
1968                 number = ceil(this.respawn_time - time);
1969                 if(number <= 0)
1970                         return;
1971                 if(number <= this.respawn_countdown)
1972                 {
1973                         this.respawn_countdown = number - 1;
1974                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1975                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1976                 }
1977         }
1978 }
1979
1980 .bool team_selected;
1981 bool ShowTeamSelection(entity this)
1982 {
1983         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1984                 return false;
1985         stuffcmd(this, "menu_showteamselect\n");
1986         return true;
1987 }
1988 void Join(entity this)
1989 {
1990         TRANSMUTE(Player, this);
1991
1992         if(!this.team_selected)
1993         if(autocvar_g_campaign || autocvar_g_balance_teams)
1994                 TeamBalance_JoinBestTeam(this);
1995
1996         if(autocvar_g_campaign)
1997                 campaign_bots_may_start = true;
1998
1999         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2000
2001         PutClientInServer(this);
2002
2003         if(IS_PLAYER(this))
2004         if(teamplay && this.team != -1)
2005         {
2006         }
2007         else
2008                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2009         this.team_selected = false;
2010
2011         // z411
2012         // send constant ready notification
2013         if(warmup_stage)
2014                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MISSING_READY);
2015 }
2016
2017 int GetPlayerLimit()
2018 {
2019         if(g_duel)
2020                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2021         int player_limit = autocvar_g_maxplayers;
2022         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2023         player_limit = M_ARGV(0, int);
2024         return player_limit;
2025 }
2026
2027 /**
2028  * Determines whether the player is allowed to join. This depends on cvar
2029  * g_maxplayers, if it isn't used this function always return true, otherwise
2030  * it checks whether the number of currently playing players exceeds g_maxplayers.
2031  * @return int number of free slots for players, 0 if none
2032  */
2033 int nJoinAllowed(entity this, entity ignore)
2034 {
2035         if(!ignore)
2036         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2037         // so report 0 free slots if restricted
2038         {
2039                 if(autocvar_g_forced_team_otherwise == "spectate")
2040                         return 0;
2041                 if(autocvar_g_forced_team_otherwise == "spectator")
2042                         return 0;
2043         }
2044
2045         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2046                 return 0; // forced spectators can never join
2047
2048         // TODO simplify this
2049         int totalClients = 0;
2050         int currentlyPlaying = 0;
2051         FOREACH_CLIENT(true, {
2052                 if(it != ignore)
2053                         ++totalClients;
2054                 if(IS_REAL_CLIENT(it))
2055                 if(IS_PLAYER(it) || it.caplayer)
2056                         ++currentlyPlaying;
2057         });
2058
2059         int player_limit = GetPlayerLimit();
2060
2061         int free_slots = 0;
2062         if (!player_limit)
2063                 free_slots = maxclients - totalClients;
2064         else if(player_limit > 0 && currentlyPlaying < player_limit)
2065                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2066
2067         static float msg_time = 0;
2068         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2069         {
2070                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2071                 msg_time = time + 0.5;
2072         }
2073
2074         return free_slots;
2075 }
2076
2077 void PrintWelcomeMessage(entity this)
2078 {
2079         if(CS(this).motd_actived_time == 0)
2080         {
2081                 if (autocvar_g_campaign) {
2082                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2083                                 CS(this).motd_actived_time = time;
2084                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2085                         }
2086                 } else {
2087                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2088                                 CS(this).motd_actived_time = time;
2089                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2090                         }
2091                 }
2092         }
2093         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2094         {
2095                 if (autocvar_g_campaign) {
2096                         if (PHYS_INPUT_BUTTON_INFO(this))
2097                                 CS(this).motd_actived_time = time;
2098                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2099                                 CS(this).motd_actived_time = 0;
2100                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2101                         }
2102                 } else {
2103                         if (PHYS_INPUT_BUTTON_INFO(this))
2104                                 CS(this).motd_actived_time = time;
2105                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2106                                 CS(this).motd_actived_time = 0;
2107                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2108                         }
2109                 }
2110         }
2111         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2112         {
2113                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2114                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2115                 else if (CS(this).motd_actived_time == -2)
2116                 {
2117                         // instantly hide MOTD
2118                         CS(this).motd_actived_time = 0;
2119                         if (autocvar_g_campaign)
2120                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2121                         else
2122                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2123                 }
2124                 else if (IS_PLAYER(this) || IS_SPEC(this))
2125                 {
2126                         // FIXME occasionally for some reason MOTD never goes away
2127                         // delay MOTD removal a little bit in the hope it fixes this bug
2128                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2129                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2130                         else //if (CS(this).motd_actived_time < -2)
2131                                 CS(this).motd_actived_time++;
2132                 }
2133         }
2134 }
2135
2136 bool joinAllowed(entity this)
2137 {
2138         if (CS(this).version_mismatch) return false;
2139         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2140         if (!nJoinAllowed(this, this)) return false;
2141         if (teamplay && lockteams) return false;
2142         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2143         if (ShowTeamSelection(this)) return false;
2144         return true;
2145 }
2146
2147 .string shootfromfixedorigin;
2148 .bool dualwielding_prev;
2149 bool PlayerThink(entity this)
2150 {
2151         if (game_stopped || intermission_running) {
2152                 this.modelflags &= ~MF_ROCKET;
2153                 if(intermission_running)
2154                         IntermissionThink(this);
2155                 return false;
2156         }
2157
2158         if (game_timeout) {
2159         // don't allow the player to turn around while game is paused
2160                 // FIXME turn this into CSQC stuff
2161                 this.v_angle = this.lastV_angle;
2162                 this.angles = this.lastV_angle;
2163                 this.fixangle = true;
2164                 return false;
2165         }
2166
2167         if (frametime) player_powerups(this);
2168
2169         if (IS_DEAD(this)) {
2170                 if (this.personal && g_race_qualifying) {
2171                         if (time > this.respawn_time) {
2172                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2173                                 respawn(this);
2174                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2175                         }
2176                 } else {
2177                         if (frametime) player_anim(this);
2178
2179                         if (this.respawn_flags & RESPAWN_DENY)
2180                         {
2181                                 STAT(RESPAWN_TIME, this) = 0;
2182                                 return false;
2183                         }
2184
2185                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2186
2187                         switch(this.deadflag)
2188                         {
2189                                 case DEAD_DYING:
2190                                 {
2191                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2192                                                 this.deadflag = DEAD_RESPAWNING;
2193                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2194                                                 this.deadflag = DEAD_DEAD;
2195                                         break;
2196                                 }
2197                                 case DEAD_DEAD:
2198                                 {
2199                                         if (button_pressed)
2200                                                 this.deadflag = DEAD_RESPAWNABLE;
2201                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2202                                                 this.deadflag = DEAD_RESPAWNING;
2203                                         break;
2204                                 }
2205                                 case DEAD_RESPAWNABLE:
2206                                 {
2207                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2208                                                 this.deadflag = DEAD_RESPAWNING;
2209                                         break;
2210                                 }
2211                                 case DEAD_RESPAWNING:
2212                                 {
2213                                         if (time > this.respawn_time)
2214                                         {
2215                                                 this.respawn_time = time + 1; // only retry once a second
2216                                                 this.respawn_time_max = this.respawn_time;
2217                                                 respawn(this);
2218                                         }
2219                                         break;
2220                                 }
2221                         }
2222
2223                         ShowRespawnCountdown(this);
2224
2225                         if (this.respawn_flags & RESPAWN_SILENT)
2226                                 STAT(RESPAWN_TIME, this) = 0;
2227                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2228                         {
2229                                 if (time < this.respawn_time)
2230                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2231                                 else if (this.deadflag != DEAD_RESPAWNING)
2232                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2233                         }
2234                         else
2235                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2236                 }
2237
2238                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2239                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2240                         STAT(RESPAWN_TIME, this) *= -1;
2241
2242                 return false;
2243         }
2244
2245         FixPlayermodel(this);
2246
2247         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2248                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2249                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2250         }
2251
2252         // reset gun alignment when dual wielding status changes
2253         // to ensure guns are always aligned right and left
2254         bool dualwielding = W_DualWielding(this);
2255         if(this.dualwielding_prev != dualwielding)
2256         {
2257                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2258                 this.dualwielding_prev = dualwielding;
2259         }
2260
2261         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2262         //if(frametime)
2263         {
2264                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2265                 {
2266                         .entity weaponentity = weaponentities[slot];
2267                         if(WEP_CVAR(vortex, charge_always))
2268                                 W_Vortex_Charge(this, weaponentity, frametime);
2269                         W_WeaponFrame(this, weaponentity);
2270                 }
2271         }
2272
2273         if (frametime)
2274         {
2275                 // WEAPONTODO: Add a weapon request for this
2276                 // rot vortex charge to the charge limit
2277                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2278                 {
2279                         .entity weaponentity = weaponentities[slot];
2280                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2281                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2282                 }
2283
2284                 player_regen(this);
2285                 player_anim(this);
2286                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2287         }
2288
2289         monsters_setstatus(this);
2290
2291         return true;
2292 }
2293
2294 .bool would_spectate;
2295 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2296 void ObserverOrSpectatorThink(entity this)
2297 {
2298         bool is_spec = IS_SPEC(this);
2299         if ( CS(this).impulse )
2300         {
2301                 int r = MinigameImpulse(this, CS(this).impulse);
2302                 if (!is_spec || r)
2303                         CS(this).impulse = 0;
2304
2305                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2306                 {
2307                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2308                         CS(this).impulse = 0;
2309                         return;
2310                 }
2311         }
2312
2313         if (this.flags & FL_JUMPRELEASED) {
2314                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2315                         this.flags &= ~FL_JUMPRELEASED;
2316                         this.flags |= FL_SPAWNING;
2317                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2318                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2319                         this.flags &= ~FL_JUMPRELEASED;
2320                         if(SpectateNext(this)) {
2321                                 TRANSMUTE(Spectator, this);
2322                         } else if (is_spec) {
2323                                 TRANSMUTE(Observer, this);
2324                                 PutClientInServer(this);
2325                         }
2326                         else
2327                                 this.would_spectate = false; // unable to spectate anyone
2328                         if (is_spec)
2329                                 CS(this).impulse = 0;
2330                 } else if (is_spec) {
2331                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2332                                 this.flags &= ~FL_JUMPRELEASED;
2333                                 if(SpectatePrev(this)) {
2334                                         TRANSMUTE(Spectator, this);
2335                                 } else {
2336                                         TRANSMUTE(Observer, this);
2337                                         PutClientInServer(this);
2338                                 }
2339                                 CS(this).impulse = 0;
2340                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2341                                 this.would_spectate = false;
2342                                 this.flags &= ~FL_JUMPRELEASED;
2343                                 TRANSMUTE(Observer, this);
2344                                 PutClientInServer(this);
2345                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2346                                 PutObserverInServer(this, false);
2347                                 this.would_spectate = true;
2348                         }
2349                 }
2350                 else {
2351                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2352                         if (PHYS_INPUT_BUTTON_USE(this))
2353                                 wouldclip = !wouldclip;
2354                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2355                         set_movetype(this, preferred_movetype);
2356                 }
2357         } else { // jump pressed
2358                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2359                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2360                         this.flags |= FL_JUMPRELEASED;
2361                         if(this.flags & FL_SPAWNING)
2362                         {
2363                                 this.flags &= ~FL_SPAWNING;
2364                                 if(joinAllowed(this))
2365                                         Join(this);
2366                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2367                                         CS(this).autojoin_checked = -1;
2368                                 return;
2369                         }
2370                 }
2371                 if(is_spec && !SpectateUpdate(this))
2372                         PutObserverInServer(this, false);
2373         }
2374         if (is_spec)
2375                 this.flags |= FL_CLIENT | FL_NOTARGET;
2376 }
2377
2378 void PlayerUseKey(entity this)
2379 {
2380         if (!IS_PLAYER(this))
2381                 return;
2382
2383         if(this.vehicle)
2384         {
2385                 if(!game_stopped)
2386                 {
2387                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2388                         return;
2389                 }
2390         }
2391         else if(autocvar_g_vehicles_enter)
2392         {
2393                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2394                 {
2395                         entity head, closest_target = NULL;
2396                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2397
2398                         while(head) // find the closest acceptable target to enter
2399                         {
2400                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2401                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2402                                 {
2403                                         if(closest_target)
2404                                         {
2405                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2406                                                 { closest_target = head; }
2407                                         }
2408                                         else { closest_target = head; }
2409                                 }
2410
2411                                 head = head.chain;
2412                         }
2413
2414                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2415                 }
2416         }
2417
2418         // a use key was pressed; call handlers
2419         MUTATOR_CALLHOOK(PlayerUseKey, this);
2420 }
2421
2422
2423 /*
2424 =============
2425 PlayerPreThink
2426
2427 Called every frame for each client before the physics are run
2428 =============
2429 */
2430 .float last_vehiclecheck;
2431 void PlayerPreThink (entity this)
2432 {
2433         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2434         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2435
2436         WarpZone_PlayerPhysics_FixVAngle(this);
2437
2438         if (frametime) {
2439                 // physics frames: update anticheat stuff
2440                 anticheat_prethink(this);
2441
2442                 // WORKAROUND: only use dropclient in server frames (frametime set).
2443                 // Never use it in cl_movement frames (frametime zero).
2444                 if (blockSpectators && IS_REAL_CLIENT(this)
2445                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !this.caplayer
2446                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2447                 {
2448                         if (dropclient_schedule(this))
2449                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2450                 }
2451         }
2452
2453         zoomstate_set = false;
2454
2455         // Check for nameless players
2456         if (this.netname == "" || this.netname != CS(this).netname_previous)
2457         {
2458                 bool assume_unchanged = (CS(this).netname_previous == "");
2459                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2460                 {
2461                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2462                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2463                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2464                         assume_unchanged = false;
2465                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2466                 }
2467                 if (isInvisibleString(this.netname))
2468                 {
2469                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2470                         sprint(this, "Warning: invisible names are not allowed.\n");
2471                         assume_unchanged = false;
2472                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2473                 }
2474                 if (!assume_unchanged && autocvar_sv_eventlog)
2475                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2476                 strcpy(CS(this).netname_previous, this.netname);
2477         }
2478
2479         // version nagging
2480         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2481         CS(this).version_nagtime = 0;
2482         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2483             // git client
2484         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2485             // git server
2486             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2487         } else {
2488             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2489             if (r < 0) { // old client
2490                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2491             } else if (r > 0) { // old server
2492                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2493             }
2494         }
2495     }
2496
2497         // GOD MODE info
2498         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2499         {
2500                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2501                 this.max_armorvalue = 0;
2502         }
2503
2504         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2505         {
2506                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2507                 {
2508                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2509                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2510                         if (this.iceblock)
2511                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2512
2513                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2514                                 Unfreeze(this, false);
2515                 }
2516                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2517                 {
2518                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2519                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2520
2521                         if (GetResource(this, RES_HEALTH) < 1)
2522                         {
2523                                 if (this.vehicle)
2524                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2525                                 if(this.event_damage)
2526                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2527                         }
2528                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2529                                 Unfreeze(this, false);
2530                 }
2531         }
2532
2533         MUTATOR_CALLHOOK(PlayerPreThink, this);
2534
2535         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2536         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2537         {
2538                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2539                 {
2540                         if(!it.owner)
2541                         {
2542                                 if(!it.team || SAME_TEAM(this, it))
2543                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2544                                 else if(autocvar_g_vehicles_steal)
2545                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2546                         }
2547                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2548                         {
2549                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2550                         }
2551                 });
2552
2553                 this.last_vehiclecheck = time + 1;
2554         }
2555
2556         if(!CS_CVAR(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2557         {
2558                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2559                         PlayerUseKey(this);
2560                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2561         }
2562
2563         if (IS_REAL_CLIENT(this))
2564                 PrintWelcomeMessage(this);
2565
2566         if (IS_PLAYER(this)) {
2567                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2568                         error("Client can't be spawned as player on connection!");
2569                 if(!PlayerThink(this))
2570                         return;
2571         }
2572         else if (game_stopped || intermission_running) {
2573                 if(intermission_running)
2574                         IntermissionThink(this);
2575                 return;
2576         }
2577         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2578         {
2579                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2580                 CS(this).autojoin_checked = 1;
2581                 // don't do this in ClientConnect
2582                 // many things can go wrong if a client is spawned as player on connection
2583                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2584                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2585                                 && (!teamplay || autocvar_g_balance_teams)))
2586                 {
2587                         campaign_bots_may_start = true;
2588                         if(joinAllowed(this))
2589                                 Join(this);
2590                         return;
2591                 }
2592         }
2593         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2594                 ObserverOrSpectatorThink(this);
2595         }
2596
2597         // WEAPONTODO: Add weapon request for this
2598         if (!zoomstate_set) {
2599                 bool wep_zoomed = false;
2600                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2601                 {
2602                         .entity weaponentity = weaponentities[slot];
2603                         Weapon thiswep = this.(weaponentity).m_weapon;
2604                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2605                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2606                 }
2607                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2608         }
2609
2610         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2611         {
2612                 CS(this).teamkill_soundtime = 0;
2613
2614                 entity e = CS(this).teamkill_soundsource;
2615                 entity oldpusher = e.pusher;
2616                 e.pusher = this;
2617                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2618                 e.pusher = oldpusher;
2619         }
2620
2621         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2622                 CS(this).taunt_soundtime = 0;
2623                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2624         }
2625
2626         target_voicescript_next(this);
2627 }
2628
2629 void DrownPlayer(entity this)
2630 {
2631         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2632                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2633         {
2634                 STAT(AIR_FINISHED, this) = 0;
2635                 return;
2636         }
2637
2638         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2639         {
2640                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2641                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2642                 STAT(AIR_FINISHED, this) = 0;
2643         }
2644         else
2645         {
2646                 if (!STAT(AIR_FINISHED, this))
2647                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2648                 if (STAT(AIR_FINISHED, this) < time)
2649                 {       // drown!
2650                         if (this.pain_finished < time)
2651                         {
2652                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2653                                 this.pain_finished = time + 0.5;
2654                         }
2655                 }
2656         }
2657 }
2658
2659 .bool move_qcphysics;
2660
2661 void Player_Physics(entity this)
2662 {
2663         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2664
2665         if(!this.move_qcphysics)
2666                 return;
2667
2668         if(!frametime && !CS(this).pm_frametime)
2669                 return;
2670
2671         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2672
2673         CS(this).pm_frametime = 0;
2674 }
2675
2676 /*
2677 =============
2678 PlayerPostThink
2679
2680 Called every frame for each client after the physics are run
2681 =============
2682 */
2683 void PlayerPostThink (entity this)
2684 {
2685         Player_Physics(this);
2686
2687         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2688         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2689         if (IS_REAL_CLIENT(this))
2690         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2691         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2692         {
2693                 int totalClients = 0;
2694                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2695                 {
2696                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2697                         if (server_is_dedicated)
2698                         {
2699                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2700                                 {
2701                                         ++totalClients;
2702                                 });
2703                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2704                                         totalClients = 0;
2705                         }
2706                 }
2707                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2708                 {
2709                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2710                         {
2711                                 ++totalClients;
2712                         });
2713                 }
2714
2715                 if (totalClients < autocvar_sv_maxidle_minplayers)
2716                 {
2717                         // idle kick disabled
2718                         CS(this).parm_idlesince = time;
2719                 }
2720                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2721                 {
2722                         if (CS(this).idlekick_lasttimeleft)
2723                         {
2724                                 CS(this).idlekick_lasttimeleft = 0;
2725                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2726                         }
2727                 }
2728                 else
2729                 {
2730                         float maxidle_time = autocvar_sv_maxidle;
2731                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2732                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2733                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2734                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2735                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2736                         {
2737                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2738                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2739                                 else
2740                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2741                         }
2742                         if (timeleft <= 0) {
2743                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2744                                 {
2745                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2746                                         PutObserverInServer(this, true);
2747                                 }
2748                                 else
2749                                 {
2750                                         if (dropclient_schedule(this))
2751                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2752                                 }
2753                                 return;
2754                         }
2755                         else if (timeleft <= countdown_time) {
2756                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2757                                         play2(this, SND(TALK2));
2758                                 CS(this).idlekick_lasttimeleft = timeleft;
2759                         }
2760                 }
2761         }
2762
2763         CheatFrame(this);
2764
2765         if (game_stopped)
2766         {
2767                 this.solid = SOLID_NOT;
2768                 this.takedamage = DAMAGE_NO;
2769                 set_movetype(this, MOVETYPE_NONE);
2770                 CS(this).teamkill_complain = 0;
2771                 CS(this).teamkill_soundtime = 0;
2772                 CS(this).teamkill_soundsource = NULL;
2773         }
2774
2775         if (IS_PLAYER(this)) {
2776                 if(this.death_time == time && IS_DEAD(this))
2777                 {
2778                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2779                         // once all the damage events of this frame have been processed with normal size
2780                         this.maxs.z = 5;
2781                         setsize(this, this.mins, this.maxs);
2782                 }
2783                 DrownPlayer(this);
2784                 UpdateChatBubble(this);
2785                 if (CS(this).impulse) ImpulseCommands(this);
2786                 GetPressedKeys(this);
2787                 if (game_stopped)
2788                 {
2789                         CSQCMODEL_AUTOUPDATE(this);
2790                         return;
2791                 }
2792         }
2793         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2794         {
2795                 CS(this).pressedkeys = 0;
2796                 STAT(PRESSED_KEYS, this) = 0;
2797         }
2798
2799         if (this.waypointsprite_attachedforcarrier) {
2800                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2801                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2802         }
2803
2804         CSQCMODEL_AUTOUPDATE(this);
2805 }
2806
2807 // hack to copy the button fields from the client entity to the Client State
2808 void PM_UpdateButtons(entity this, entity store)
2809 {
2810         if(this.impulse)
2811                 store.impulse = this.impulse;
2812         this.impulse = 0;
2813
2814         bool typing = this.buttonchat || this.button12;
2815
2816         store.button0 = (typing) ? 0 : this.button0;
2817         //button1?!
2818         store.button2 = (typing) ? 0 : this.button2;
2819         store.button3 = (typing) ? 0 : this.button3;
2820         store.button4 = this.button4;
2821         store.button5 = (typing) ? 0 : this.button5;
2822         store.button6 = this.button6;
2823         store.button7 = this.button7;
2824         store.button8 = this.button8;
2825         store.button9 = this.button9;
2826         store.button10 = this.button10;
2827         store.button11 = this.button11;
2828         store.button12 = this.button12;
2829         store.button13 = this.button13;
2830         store.button14 = this.button14;
2831         store.button15 = this.button15;
2832         store.button16 = this.button16;
2833         store.buttonuse = this.buttonuse;
2834         store.buttonchat = this.buttonchat;
2835
2836         store.cursor_active = this.cursor_active;
2837         store.cursor_screen = this.cursor_screen;
2838         store.cursor_trace_start = this.cursor_trace_start;
2839         store.cursor_trace_endpos = this.cursor_trace_endpos;
2840         store.cursor_trace_ent = this.cursor_trace_ent;
2841
2842         store.ping = this.ping;
2843         store.ping_packetloss = this.ping_packetloss;
2844         store.ping_movementloss = this.ping_movementloss;
2845
2846         store.v_angle = this.v_angle;
2847         store.movement = this.movement;
2848 }
2849
2850 NET_HANDLE(fpsreport, bool)
2851 {
2852         int fps = ReadShort();
2853         PlayerScore_Set(sender, SP_FPS, fps);
2854         return true;
2855 }