qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/resources/sv_resources.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/bot/default/waypoints.qh>
  50 #include <server/campaign.qh>
  51 #include <server/chat.qh>
  52 #include <server/cheats.qh>
  53 #include <server/clientkill.qh>
  54 #include <server/command/common.qh>
  55 #include <server/command/common.qh>
  56 #include <server/command/vote.qh>
  57 #include <server/compat/quake3.qh>
  58 #include <server/damage.qh>
  59 #include <server/gamelog.qh>
  60 #include <server/handicap.qh>
  61 #include <server/hook.qh>
  62 #include <server/impulse.qh>
  63 #include <server/intermission.qh>
  64 #include <server/ipban.qh>
  65 #include <server/main.qh>
  66 #include <server/mutators/_mod.qh>
  67 #include <server/player.qh>
  68 #include <server/portals.qh>
  69 #include <server/race.qh>
  70 #include <server/scores.qh>
  71 #include <server/scores_rules.qh>
  72 #include <server/spawnpoints.qh>
  73 #include <server/teamplay.qh>
  74 #include <server/weapons/accuracy.qh>
  75 #include <server/weapons/common.qh>
  76 #include <server/weapons/hitplot.qh>
  77 #include <server/weapons/selection.qh>
  78 #include <server/weapons/tracing.qh>
  79 #include <server/weapons/weaponsystem.qh>
  80 #include <server/world.qh>
  81
  82 STATIC_METHOD(Client, Add, void(Client this, int _team))
  83 {
  84     ClientConnect(this);
  85     TRANSMUTE(Player, this);
  86     this.frame = 12; // 7
  87     this.team = _team;
  88     PutClientInServer(this);
  89 }
  90
  91 STATIC_METHOD(Client, Remove, void(Client this))
  92 {
  93     TRANSMUTE(Observer, this);
  94     PutClientInServer(this);
  95     ClientDisconnect(this);
  96 }
  97
  98 void send_CSQC_teamnagger() {
  99         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
 100 }
 101
 102 int CountSpectators(entity player, entity to)
 103 {
 104         if(!player) { return 0; } // not sure how, but best to be safe
 105
 106         int spec_count = 0;
 107
 108         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 109         {
 110                 spec_count++;
 111         });
 112
 113         return spec_count;
 114 }
 115
 116 void WriteSpectators(entity player, entity to)
 117 {
 118         if(!player) { return; } // not sure how, but best to be safe
 119
 120         int spec_count = 0;
 121         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 122         {
 123                 if(spec_count >= MAX_SPECTATORS)
 124                         break;
 125                 WriteByte(MSG_ENTITY, num_for_edict(it));
 126                 ++spec_count;
 127         });
 128 }
 129
 130 bool ClientData_Send(entity this, entity to, int sf)
 131 {
 132         assert(to == this.owner, return false);
 133
 134         entity e = to;
 135         if (IS_SPEC(e)) e = e.enemy;
 136
 137         sf = 0;
 138         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 139         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 140         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 141         if (observe_blocked_if_eliminated && INGAME(to))
 142                                         sf |= BIT(3); // observing blocked
 143         if (autocvar_sv_showspectators == 1 || (autocvar_sv_showspectators && IS_SPEC(to)))
 144                                         sf |= BIT(4); // show spectators
 145
 146         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 147         WriteByte(MSG_ENTITY, sf);
 148
 149         if (sf & BIT(1))
 150                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 151
 152         if(sf & BIT(4))
 153         {
 154                 float specs = CountSpectators(e, to);
 155                 WriteByte(MSG_ENTITY, specs);
 156                 WriteSpectators(e, to);
 157         }
 158
 159         return true;
 160 }
 161
 162 void ClientData_Attach(entity this)
 163 {
 164         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 165         CS(this).clientdata.drawonlytoclient = this;
 166         CS(this).clientdata.owner = this;
 167 }
 168
 169 void ClientData_Detach(entity this)
 170 {
 171         delete(CS(this).clientdata);
 172         CS(this).clientdata = NULL;
 173 }
 174
 175 void ClientData_Touch(entity e)
 176 {
 177         entity cd = CS(e).clientdata;
 178         if (cd) { cd.SendFlags = 1; }
 179
 180         // make it spectatable
 181         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 182         {
 183                 entity cd = CS(it).clientdata;
 184                 if (cd) { cd.SendFlags = 1; }
 185         });
 186 }
 187
 188
 189 /*
 190 =============
 191 CheckPlayerModel
 192
 193 Checks if the argument string can be a valid playermodel.
 194 Returns a valid one in doubt.
 195 =============
 196 */
 197 string FallbackPlayerModel;
 198 string CheckPlayerModel(string plyermodel) {
 199         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 200         {
 201                 // note: we cannot summon Don Strunzone here, some player may
 202                 // still have the model string set. In case anyone manages how
 203                 // to change a cvar default, we'll have a small leak here.
 204                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 205         }
 206         // only in right path
 207         if(substring(plyermodel, 0, 14) != "models/player/")
 208                 return FallbackPlayerModel;
 209         // only good file extensions
 210         if(substring(plyermodel, -4, 4) != ".iqm"
 211                 && substring(plyermodel, -4, 4) != ".zym"
 212                 && substring(plyermodel, -4, 4) != ".dpm"
 213                 && substring(plyermodel, -4, 4) != ".md3"
 214                 && substring(plyermodel, -4, 4) != ".psk")
 215         {
 216                 return FallbackPlayerModel;
 217         }
 218         // forbid the LOD models
 219         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 220                 return FallbackPlayerModel;
 221         if(plyermodel != strtolower(plyermodel))
 222                 return FallbackPlayerModel;
 223         // also, restrict to server models
 224         if(autocvar_sv_servermodelsonly)
 225         {
 226                 if(!fexists(plyermodel))
 227                         return FallbackPlayerModel;
 228         }
 229         return plyermodel;
 230 }
 231
 232 void setplayermodel(entity e, string modelname)
 233 {
 234         precache_model(modelname);
 235         _setmodel(e, modelname);
 236         player_setupanimsformodel(e);
 237         if(!autocvar_g_debug_globalsounds)
 238                 UpdatePlayerSounds(e);
 239 }
 240
 241 /** putting a client as observer in the server */
 242 void PutObserverInServer(entity this, bool is_forced, bool use_spawnpoint)
 243 {
 244         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 245         bool recount_ready = false;
 246         PlayerState_detach(this);
 247
 248         if (IS_PLAYER(this))
 249         {
 250                 if(GetResource(this, RES_HEALTH) >= 1)
 251                 {
 252                         // despawn effect
 253                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 254                 }
 255
 256                 // was a player, recount votes and ready status
 257                 if(IS_REAL_CLIENT(this))
 258                 {
 259                         if (vote_called) { VoteCount(false); }
 260                         this.ready = false;
 261                         if (warmup_stage || game_starttime > time) recount_ready = true;
 262                 }
 263                 entcs_update_players(this);
 264         }
 265
 266         if (use_spawnpoint)
 267         {
 268                 entity spot = SelectSpawnPoint(this, true);
 269                 if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 270                 this.angles = vec2(spot.angles);
 271                 // offset it so that the spectator spawns higher off the ground, looks better this way
 272                 setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 273         }
 274         else // change origin to restore previous view origin
 275                 setorigin(this, this.origin + STAT(PL_VIEW_OFS, this) - STAT(PL_CROUCH_VIEW_OFS, this));
 276         this.fixangle = true;
 277
 278         if (IS_REAL_CLIENT(this))
 279         {
 280                 msg_entity = this;
 281                 WriteByte(MSG_ONE, SVC_SETVIEW);
 282                 WriteEntity(MSG_ONE, this);
 283         }
 284         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 285         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 286         if(!autocvar_g_debug_globalsounds)
 287         {
 288                 // needed for player sounds
 289                 this.model = "";
 290                 FixPlayermodel(this);
 291         }
 292         setmodel(this, MDL_Null);
 293         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 294         this.view_ofs = '0 0 0';
 295
 296         RemoveGrapplingHooks(this);
 297         Portal_ClearAll(this);
 298         Unfreeze(this, false);
 299         SetSpectatee(this, NULL);
 300
 301         if (this.alivetime)
 302         {
 303                 if (!warmup_stage)
 304                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 305                 this.alivetime = 0;
 306         }
 307
 308         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 309
 310         TRANSMUTE(Observer, this);
 311
 312         if(recount_ready) ReadyCount(); // FIXME: please add comment about why this is delayed
 313
 314         WaypointSprite_PlayerDead(this);
 315         accuracy_resend(this);
 316
 317         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 318                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 319
 320         CS(this).spectatortime = time;
 321         if(this.bot_attack)
 322                 IL_REMOVE(g_bot_targets, this);
 323         this.bot_attack = false;
 324         if(this.monster_attack)
 325                 IL_REMOVE(g_monster_targets, this);
 326         this.monster_attack = false;
 327         STAT(HUD, this) = HUD_NORMAL;
 328         this.iscreature = false;
 329         this.teleportable = TELEPORT_SIMPLE;
 330         if(this.damagedbycontents)
 331                 IL_REMOVE(g_damagedbycontents, this);
 332         this.damagedbycontents = false;
 333         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 334         SetSpectatee_status(this, etof(this));
 335         this.takedamage = DAMAGE_NO;
 336         this.solid = SOLID_NOT;
 337         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 338         this.flags = FL_CLIENT | FL_NOTARGET;
 339         this.effects = 0;
 340         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 341         this.pauserotarmor_finished = 0;
 342         this.pauserothealth_finished = 0;
 343         this.pauseregen_finished = 0;
 344         this.damageforcescale = 0;
 345         this.death_time = 0;
 346         this.respawn_flags = 0;
 347         this.respawn_time = 0;
 348         STAT(RESPAWN_TIME, this) = 0;
 349         this.alpha = 0;
 350         this.scale = 0;
 351         this.fade_time = 0;
 352         this.pain_finished = 0;
 353         STAT(AIR_FINISHED, this) = 0;
 354         //this.dphitcontentsmask = 0;
 355         this.dphitcontentsmask = DPCONTENTS_SOLID;
 356         if (autocvar_g_playerclip_collisions)
 357                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 358         this.pushltime = 0;
 359         this.istypefrag = 0;
 360         setthink(this, func_null);
 361         this.nextthink = 0;
 362         this.deadflag = DEAD_NO;
 363         UNSET_DUCKED(this);
 364         STAT(REVIVE_PROGRESS, this) = 0;
 365         this.revival_time = 0;
 366         this.draggable = drag_undraggable;
 367
 368         player_powerups_remove_all(this);
 369         this.items = 0;
 370         STAT(WEAPONS, this) = '0 0 0';
 371         this.drawonlytoclient = this;
 372
 373         this.viewloc = NULL;
 374
 375         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 376
 377         this.weaponmodel = "";
 378         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 379         {
 380                 this.weaponentities[slot] = NULL;
 381         }
 382         this.exteriorweaponentity = NULL;
 383         CS(this).killcount = FRAGS_SPECTATOR;
 384         this.velocity = '0 0 0';
 385         this.avelocity = '0 0 0';
 386         this.punchangle = '0 0 0';
 387         this.punchvector = '0 0 0';
 388         this.oldvelocity = this.velocity;
 389         this.event_damage = func_null;
 390         this.event_heal = func_null;
 391
 392         for(int slot = 0; slot < MAX_AXH; ++slot)
 393         {
 394                 entity axh = this.(AuxiliaryXhair[slot]);
 395                 this.(AuxiliaryXhair[slot]) = NULL;
 396
 397                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 398                         delete(axh);
 399         }
 400
 401         if (mutator_returnvalue)
 402         {
 403                 // mutator prevents resetting teams+score
 404         }
 405         else
 406         {
 407                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR); // clears scores too in game modes without teams
 408                 this.frags = FRAGS_SPECTATOR;
 409         }
 410
 411         bot_relinkplayerlist();
 412
 413         if (CS(this).just_joined)
 414                 CS(this).just_joined = false;
 415 }
 416
 417 int player_getspecies(entity this)
 418 {
 419         get_model_parameters(this.model, this.skin);
 420         int s = get_model_parameters_species;
 421         get_model_parameters(string_null, 0);
 422         if (s < 0) return SPECIES_HUMAN;
 423         return s;
 424 }
 425
 426 .float model_randomizer;
 427 void FixPlayermodel(entity player)
 428 {
 429         string defaultmodel = "";
 430         int defaultskin = 0;
 431         if(autocvar_sv_defaultcharacter)
 432         {
 433                 if(teamplay)
 434                 {
 435                         switch(player.team)
 436                         {
 437                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 438                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 439                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 440                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 441                         }
 442                 }
 443
 444                 if(defaultmodel == "")
 445                 {
 446                         defaultmodel = autocvar_sv_defaultplayermodel;
 447                         defaultskin = autocvar_sv_defaultplayerskin;
 448                 }
 449
 450                 int n = tokenize_console(defaultmodel);
 451                 if(n > 0)
 452                 {
 453                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 454                         // However, do NOT randomize if the player-selected model is in the list.
 455                         for (int i = 0; i < n; ++i)
 456                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 457                                         defaultmodel = argv(i);
 458                 }
 459
 460                 int i = strstrofs(defaultmodel, ":", 0);
 461                 if(i >= 0)
 462                 {
 463                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 464                         defaultmodel = substring(defaultmodel, 0, i);
 465                 }
 466         }
 467         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 468         {
 469                 if(teamplay)
 470                 {
 471                         switch(player.team)
 472                         {
 473                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 474                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 475                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 476                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 477                         }
 478                 }
 479
 480                 if(!defaultskin)
 481                         defaultskin = autocvar_sv_defaultplayerskin;
 482         }
 483
 484         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 485         defaultmodel = M_ARGV(0, string);
 486         defaultskin = M_ARGV(1, int);
 487
 488         bool chmdl = false;
 489         int oldskin;
 490         if(defaultmodel != "")
 491         {
 492                 if (defaultmodel != player.model)
 493                 {
 494                         vector m1 = player.mins;
 495                         vector m2 = player.maxs;
 496                         setplayermodel (player, defaultmodel);
 497                         setsize (player, m1, m2);
 498                         chmdl = true;
 499                 }
 500
 501                 oldskin = player.skin;
 502                 player.skin = defaultskin;
 503         } else {
 504                 if (player.playermodel != player.model || player.playermodel == "")
 505                 {
 506                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 507                         vector m1 = player.mins;
 508                         vector m2 = player.maxs;
 509                         setplayermodel (player, player.playermodel);
 510                         setsize (player, m1, m2);
 511                         chmdl = true;
 512                 }
 513
 514                 if(!autocvar_sv_defaultcharacterskin)
 515                 {
 516                         oldskin = player.skin;
 517                         player.skin = stof(player.playerskin);
 518                 }
 519                 else
 520                 {
 521                         oldskin = player.skin;
 522                         player.skin = defaultskin;
 523                 }
 524         }
 525
 526         if(chmdl || oldskin != player.skin) // model or skin has changed
 527         {
 528                 player.species = player_getspecies(player); // update species
 529                 if(!autocvar_g_debug_globalsounds)
 530                         UpdatePlayerSounds(player); // update skin sounds
 531         }
 532
 533         if(!teamplay)
 534                 if(strlen(autocvar_sv_defaultplayercolors))
 535                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 536                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 537 }
 538
 539 void GiveWarmupResources(entity this)
 540 {
 541         SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 542         SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 543         SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 544         SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 545         SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 546         SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 547         SetResource(this, RES_HEALTH, warmup_start_health);
 548         SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 549         STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 550 }
 551
 552 void PutPlayerInServer(entity this)
 553 {
 554         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 555
 556         PlayerState_attach(this);
 557         accuracy_resend(this);
 558
 559         if (teamplay && this.bot_forced_team)
 560                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 561
 562         if (this.team < 0)
 563                 TeamBalance_JoinBestTeam(this);
 564
 565         entity spot = SelectSpawnPoint(this, false);
 566         if (!spot) {
 567                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 568                 return; // spawn failed
 569         }
 570
 571         TRANSMUTE(Player, this);
 572
 573         CS(this).wasplayer = true;
 574         this.iscreature = true;
 575         this.teleportable = TELEPORT_NORMAL;
 576         if(!this.damagedbycontents)
 577                 IL_PUSH(g_damagedbycontents, this);
 578         this.damagedbycontents = true;
 579         set_movetype(this, MOVETYPE_WALK);
 580         this.solid = SOLID_SLIDEBOX;
 581         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 582         if (autocvar_g_playerclip_collisions)
 583                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 584         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 585                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 586         this.frags = FRAGS_PLAYER;
 587         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 588         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 589         if (autocvar__notarget)
 590                 this.flags |= FL_NOTARGET;
 591         this.takedamage = DAMAGE_AIM;
 592         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 593
 594         if (warmup_stage)
 595                 GiveWarmupResources(this);
 596         else
 597         {
 598                 SetResource(this, RES_SHELLS, start_ammo_shells);
 599                 SetResource(this, RES_BULLETS, start_ammo_nails);
 600                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 601                 SetResource(this, RES_CELLS, start_ammo_cells);
 602                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 603                 SetResource(this, RES_FUEL, start_ammo_fuel);
 604                 SetResource(this, RES_HEALTH, start_health);
 605                 SetResource(this, RES_ARMOR, start_armorvalue);
 606                 STAT(WEAPONS, this) = start_weapons;
 607                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 608                 {
 609                         GiveRandomWeapons(this, random_start_weapons_count,
 610                                 autocvar_g_random_start_weapons, random_start_ammo);
 611                 }
 612         }
 613         SetSpectatee_status(this, 0);
 614
 615         PS(this).dual_weapons = '0 0 0';
 616
 617         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 618                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 619
 620         this.items = start_items;
 621
 622         float shieldtime = time + autocvar_g_spawnshieldtime;
 623
 624         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 625         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 626         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 627         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 628         if (!sv_ready_restart_after_countdown && time < game_starttime)
 629         {
 630                 float f = game_starttime - time;
 631                 shieldtime += f;
 632                 this.pauserotarmor_finished += f;
 633                 this.pauserothealth_finished += f;
 634                 this.pauseregen_finished += f;
 635         }
 636
 637         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 638
 639         this.damageforcescale = autocvar_g_player_damageforcescale;
 640         this.death_time = 0;
 641         this.respawn_flags = 0;
 642         this.respawn_time = 0;
 643         STAT(RESPAWN_TIME, this) = 0;
 644         // DP model scaling uses 1/16 accuracy and 13/16 is closest to 56/69
 645         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.8125 : autocvar_sv_player_scale);
 646         this.fade_time = 0;
 647         this.pain_finished = 0;
 648         this.pushltime = 0;
 649         setthink(this, func_null); // players have no think function
 650         this.nextthink = 0;
 651         this.dmg_team = 0;
 652         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 653
 654         this.deadflag = DEAD_NO;
 655
 656         this.angles = spot.angles;
 657         this.angles_z = 0; // never spawn tilted even if the spot says to
 658         if (IS_BOT_CLIENT(this))
 659         {
 660                 this.v_angle = this.angles;
 661                 bot_aim_reset(this);
 662         }
 663         this.fixangle = true; // turn this way immediately
 664         this.oldvelocity = this.velocity = '0 0 0';
 665         this.avelocity = '0 0 0';
 666         this.punchangle = '0 0 0';
 667         this.punchvector = '0 0 0';
 668
 669         STAT(REVIVE_PROGRESS, this) = 0;
 670         this.revival_time = 0;
 671
 672         STAT(AIR_FINISHED, this) = 0;
 673         this.waterlevel = WATERLEVEL_NONE;
 674         this.watertype = CONTENT_EMPTY;
 675
 676         entity spawnevent = new_pure(spawnevent);
 677         spawnevent.owner = this;
 678         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 679
 680         // Cut off any still running player sounds.
 681         stopsound(this, CH_PLAYER_SINGLE);
 682
 683         this.model = "";
 684         FixPlayermodel(this);
 685         this.drawonlytoclient = NULL;
 686
 687         this.viewloc = NULL;
 688
 689         for(int slot = 0; slot < MAX_AXH; ++slot)
 690         {
 691                 entity axh = this.(AuxiliaryXhair[slot]);
 692                 this.(AuxiliaryXhair[slot]) = NULL;
 693
 694                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 695                         delete(axh);
 696         }
 697
 698         this.spawnpoint_targ = NULL;
 699
 700         UNSET_DUCKED(this);
 701         this.view_ofs = STAT(PL_VIEW_OFS, this);
 702         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 703         this.spawnorigin = spot.origin;
 704         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 705         // don't reset back to last position, even if new position is stuck in solid
 706         this.oldorigin = this.origin;
 707         if(this.conveyor)
 708                 IL_REMOVE(g_conveyed, this);
 709         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 710         if(this.swampslug)
 711                 IL_REMOVE(g_swamped, this);
 712         this.swampslug = NULL;
 713         this.swamp_interval = 0;
 714         if(this.ladder_entity)
 715                 IL_REMOVE(g_ladderents, this);
 716         this.ladder_entity = NULL;
 717         IL_EACH(g_counters, it.realowner == this,
 718         {
 719                 delete(it);
 720         });
 721         STAT(HUD, this) = HUD_NORMAL;
 722
 723         this.event_damage = PlayerDamage;
 724         this.event_heal = PlayerHeal;
 725
 726         this.draggable = func_null;
 727
 728         if(!this.bot_attack)
 729                 IL_PUSH(g_bot_targets, this);
 730         this.bot_attack = true;
 731         if(!this.monster_attack)
 732                 IL_PUSH(g_monster_targets, this);
 733         this.monster_attack = true;
 734         navigation_dynamicgoal_init(this, false);
 735
 736         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 737
 738         // player was spectator
 739         if (CS(this).killcount == FRAGS_SPECTATOR) {
 740                 PlayerScore_Clear(this);
 741                 CS(this).killcount = 0;
 742                 CS(this).startplaytime = time;
 743         }
 744
 745         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 746         {
 747                 .entity weaponentity = weaponentities[slot];
 748                 CL_SpawnWeaponentity(this, weaponentity);
 749         }
 750         this.alpha = default_player_alpha;
 751         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 752         this.exteriorweaponentity.alpha = default_weapon_alpha;
 753
 754         this.speedrunning = false;
 755
 756         this.counter_cnt = 0;
 757         this.fragsfilter_cnt = 0;
 758
 759         target_voicescript_clear(this);
 760
 761         // reset fields the weapons may use
 762         FOREACH(Weapons, true, {
 763                 it.wr_resetplayer(it, this);
 764                         // reload all reloadable weapons
 765                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 766                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 767                         {
 768                                 .entity weaponentity = weaponentities[slot];
 769                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 770                         }
 771                 }
 772         });
 773
 774         Unfreeze(this, false);
 775
 776         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 777         {
 778                 string s = spot.target;
 779                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 780                         spot.target = string_null;
 781                 SUB_UseTargets(spot, this, NULL);
 782                 if(g_assault || g_race)
 783                         spot.target = s;
 784         }
 785
 786         if (autocvar_spawn_debug)
 787         {
 788                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 789                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 790         }
 791
 792         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 793         {
 794                 .entity weaponentity = weaponentities[slot];
 795                 entity w_ent = this.(weaponentity);
 796                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 797                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 798                 else
 799                         w_ent.m_switchweapon = WEP_Null;
 800                 w_ent.m_weapon = WEP_Null;
 801                 w_ent.weaponname = "";
 802                 w_ent.m_switchingweapon = WEP_Null;
 803                 w_ent.cnt = -1;
 804         }
 805
 806         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 807
 808         if (CS(this).impulse) ImpulseCommands(this);
 809
 810         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 811         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 812         {
 813                 .entity weaponentity = weaponentities[slot];
 814                 W_WeaponFrame(this, weaponentity);
 815         }
 816
 817         if (!warmup_stage && !this.alivetime)
 818                 this.alivetime = time;
 819
 820         antilag_clear(this, CS(this));
 821
 822         if (warmup_stage < 0 || warmup_stage > 1)
 823                 ReadyCount();
 824 }
 825
 826 /** Called when a client spawns in the server */
 827 void PutClientInServer(entity this)
 828 {
 829         if (IS_REAL_CLIENT(this)) {
 830                 msg_entity = this;
 831                 WriteByte(MSG_ONE, SVC_SETVIEW);
 832                 WriteEntity(MSG_ONE, this);
 833         }
 834         if (game_stopped)
 835                 TRANSMUTE(Observer, this);
 836
 837         bool use_spawnpoint = (!this.enemy); // check this.enemy here since SetSpectatee will clear it
 838         SetSpectatee(this, NULL);
 839
 840         // reset player keys
 841         if(PS(this))
 842                 PS(this).itemkeys = 0;
 843
 844         MUTATOR_CALLHOOK(PutClientInServer, this);
 845
 846         if (IS_OBSERVER(this)) {
 847                 PutObserverInServer(this, false, use_spawnpoint);
 848         } else if (IS_PLAYER(this)) {
 849                 PutPlayerInServer(this);
 850         }
 851
 852         bot_relinkplayerlist();
 853 }
 854
 855 // TODO do we need all these fields, or should we stop autodetecting runtime
 856 // changes and just have a console command to update this?
 857 bool ClientInit_SendEntity(entity this, entity to, int sf)
 858 {
 859         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 860         return = true;
 861         msg_entity = to;
 862         // MSG_INIT replacement
 863         // TODO: make easier to use
 864         Registry_send_all();
 865         W_PROP_reload(MSG_ONE, to);
 866         ClientInit_misc(this);
 867         MUTATOR_CALLHOOK(Ent_Init);
 868 }
 869 void ClientInit_misc(entity this)
 870 {
 871         int channel = MSG_ONE;
 872         WriteHeader(channel, ENT_CLIENT_INIT);
 873         WriteByte(channel, g_nexball_meter_period * 32);
 874         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 875         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 876         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 877         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 878         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 879         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 880         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 881         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 882
 883         if(autocvar_sv_foginterval && world.fog != "")
 884                 WriteString(channel, world.fog);
 885         else
 886                 WriteString(channel, "");
 887         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 888         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 889         WriteByte(channel, serverflags);
 890         WriteCoord(channel, autocvar_g_trueaim_minrange);
 891 }
 892
 893 void ClientInit_CheckUpdate(entity this)
 894 {
 895         this.nextthink = time;
 896         if(this.count != autocvar_g_balance_armor_blockpercent)
 897         {
 898                 this.count = autocvar_g_balance_armor_blockpercent;
 899                 this.SendFlags |= 1;
 900         }
 901         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 902         {
 903                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 904                 this.SendFlags |= 1;
 905         }
 906 }
 907
 908 void ClientInit_Spawn()
 909 {
 910         entity e = new_pure(clientinit);
 911         setthink(e, ClientInit_CheckUpdate);
 912         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 913
 914         ClientInit_CheckUpdate(e);
 915 }
 916
 917 /*
 918 =============
 919 SetNewParms
 920 =============
 921 */
 922 void SetNewParms ()
 923 {
 924         // initialize parms for a new player
 925         parm1 = -(86400 * 366);
 926
 927         MUTATOR_CALLHOOK(SetNewParms);
 928 }
 929
 930 /*
 931 =============
 932 SetChangeParms
 933 =============
 934 */
 935 void SetChangeParms (entity this)
 936 {
 937         // save parms for level change
 938         parm1 = CS(this).parm_idlesince - time;
 939
 940         MUTATOR_CALLHOOK(SetChangeParms);
 941 }
 942
 943 /*
 944 =============
 945 DecodeLevelParms
 946 =============
 947 */
 948 void DecodeLevelParms(entity this)
 949 {
 950         // load parms
 951         CS(this).parm_idlesince = parm1;
 952         if (CS(this).parm_idlesince == -(86400 * 366))
 953                 CS(this).parm_idlesince = time;
 954
 955         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 956         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 957
 958         MUTATOR_CALLHOOK(DecodeLevelParms);
 959 }
 960
 961 void FixClientCvars(entity e)
 962 {
 963         // send prediction settings to the client
 964         if(autocvar_g_antilag == 3) // client side hitscan
 965                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 966         if(autocvar_sv_gentle)
 967                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 968
 969         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 970         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 971
 972         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 973
 974         MUTATOR_CALLHOOK(FixClientCvars, e);
 975 }
 976
 977 bool findinlist_abbrev(string tofind, string list)
 978 {
 979         if(list == "" || tofind == "")
 980                 return false; // empty list or search, just return
 981
 982         // this function allows abbreviated strings!
 983         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 984         {
 985                 return true;
 986         });
 987
 988         return false;
 989 }
 990
 991 bool PlayerInIPList(entity p, string iplist)
 992 {
 993         // some safety checks (never allow local?)
 994         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 995                 return false;
 996
 997         return findinlist_abbrev(p.netaddress, iplist);
 998 }
 999
1000 bool PlayerInIDList(entity p, string idlist)
1001 {
1002         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1003         if(!p.crypto_idfp)
1004                 return false;
1005
1006         return findinlist_abbrev(p.crypto_idfp, idlist);
1007 }
1008
1009 bool PlayerInList(entity player, string list)
1010 {
1011         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1012 }
1013
1014 #ifdef DP_EXT_PRECONNECT
1015 /*
1016 =============
1017 ClientPreConnect
1018
1019 Called once (not at each match start) when a client begins a connection to the server
1020 =============
1021 */
1022 void ClientPreConnect(entity this)
1023 {
1024         if(autocvar_sv_eventlog)
1025         {
1026                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1027                         this.playerid,
1028                         etof(this),
1029                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1030                 ));
1031         }
1032 }
1033 #endif
1034
1035 // NOTE csqc uses the active mutators list sent by this function
1036 // to understand which mutators are enabled
1037 // also note that they aren't all registered mutators, e.g. jetpack, low gravity
1038 void SendWelcomeMessage(entity this, int msg_type)
1039 {
1040         WriteByte(msg_type, boolean(autocvar_g_campaign));
1041         if (boolean(autocvar_g_campaign))
1042         {
1043                 WriteString(msg_type, Campaign_GetTitle());
1044                 WriteByte(msg_type, Campaign_GetLevelNum());
1045                 WriteString(msg_type, Campaign_GetMessage());
1046                 return;
1047         }
1048         WriteString(msg_type, autocvar_hostname);
1049         WriteString(msg_type, autocvar_g_xonoticversion);
1050         WriteByte(msg_type, CS(this).version_mismatch);
1051         WriteByte(msg_type, (CS(this).version < autocvar_gameversion));
1052         WriteByte(msg_type, autocvar_g_warmup > 1 ? autocvar_g_warmup : map_minplayers);
1053         WriteByte(msg_type, GetPlayerLimit());
1054
1055         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1056         string modifications = M_ARGV(0, string);
1057
1058         if (!g_weaponarena && cvar("g_balance_blaster_weaponstartoverride") == 0)
1059                 modifications = strcat(modifications, ", No start weapons");
1060         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1061                 modifications = strcat(modifications, ", Low gravity");
1062         if(g_weapon_stay && !g_cts)
1063                 modifications = strcat(modifications, ", Weapons stay");
1064         if(autocvar_g_jetpack)
1065                 modifications = strcat(modifications, ", Jetpack");
1066         modifications = substring(modifications, 2, strlen(modifications) - 2);
1067
1068         WriteString(msg_type, modifications);
1069
1070         WriteString(msg_type, g_weaponarena_list);
1071
1072         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1073         {
1074                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1075                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1076         }
1077
1078         WriteString(msg_type, cache_mutatormsg);
1079
1080         WriteString(msg_type, strreplace("\\n", "\n", autocvar_sv_motd));
1081 }
1082
1083 /**
1084 =============
1085 ClientConnect
1086
1087 Called when a client connects to the server
1088 =============
1089 */
1090 void ClientConnect(entity this)
1091 {
1092         if (Ban_MaybeEnforceBanOnce(this)) return;
1093         assert(!IS_CLIENT(this), return);
1094         this.flags |= FL_CLIENT;
1095         assert(player_count >= 0, player_count = 0);
1096
1097         TRANSMUTE(Client, this);
1098         CS(this).version_nagtime = time + 10 + random() * 10;
1099
1100         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1101
1102         bot_clientconnect(this);
1103
1104         Player_DetermineForcedTeam(this);
1105
1106         TRANSMUTE(Observer, this);
1107
1108         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1109
1110         // always track bots, don't ask for cl_allow_uidtracking
1111         if (IS_BOT_CLIENT(this))
1112                 PlayerStats_GameReport_AddPlayer(this);
1113         else
1114                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1115
1116         if (autocvar_sv_eventlog)
1117                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1118
1119         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1120
1121         stuffcmd(this, clientstuff, "\n");
1122         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1123
1124         FixClientCvars(this);
1125
1126         // get version info from player
1127         stuffcmd(this, "cmd clientversion $gameversion\n");
1128
1129         // notify about available teams
1130         if (teamplay)
1131         {
1132                 entity balance = TeamBalance_CheckAllowedTeams(this);
1133                 int t = TeamBalance_GetAllowedTeams(balance);
1134                 TeamBalance_Destroy(balance);
1135                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1136         }
1137         else
1138         {
1139                 stuffcmd(this, "set _teams_available 0\n");
1140         }
1141
1142         bot_relinkplayerlist();
1143
1144         CS(this).spectatortime = time;
1145         if (blockSpectators)
1146         {
1147                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1148         }
1149
1150         CS(this).jointime = time;
1151
1152         if (IS_REAL_CLIENT(this))
1153         {
1154                 if (g_weaponarena_weapons == WEPSET(TUBA))
1155                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1156                 // quickmenu file must be put in a subfolder with an unique name
1157                 // to reduce chances of overriding custom client quickmenus
1158                 if (waypointeditor_enabled)
1159                         stuffcmd(this, sprintf("cl_cmd settemp _hud_panel_quickmenu_file_from_server %s\n", "wpeditor.txt"));
1160                 else if (autocvar_sv_quickmenu_file != "" && strstrofs(autocvar_sv_quickmenu_file, "/", 0) && fexists(autocvar_sv_quickmenu_file))
1161                         stuffcmd(this, sprintf("cl_cmd settemp _hud_panel_quickmenu_file_from_server %s\n", autocvar_sv_quickmenu_file));
1162         }
1163
1164         if (!autocvar_sv_foginterval && world.fog != "")
1165                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1166
1167         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AVAILABLE_TEAMS == 2))
1168                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1169                         send_CSQC_teamnagger();
1170
1171         CSQCMODEL_AUTOINIT(this);
1172
1173         CS(this).model_randomizer = random();
1174
1175         if (IS_REAL_CLIENT(this))
1176                 sv_notice_join(this);
1177
1178         this.move_qcphysics = true;
1179
1180         // update physics stats (players can spawn before physics runs)
1181         Physics_UpdateStats(this);
1182
1183         IL_EACH(g_initforplayer, it.init_for_player, {
1184                 it.init_for_player(it, this);
1185         });
1186
1187         Handicap_Initialize(this);
1188
1189         MUTATOR_CALLHOOK(ClientConnect, this);
1190
1191         if (player_count == 1)
1192         {
1193                 if (autocvar_sv_autopause && server_is_dedicated)
1194                         setpause(0);
1195                 localcmd("\nsv_hook_firstjoin\n");
1196         }
1197 }
1198 /*
1199 =============
1200 ClientDisconnect
1201
1202 Called when a client disconnects from the server
1203 =============
1204 */
1205 .entity chatbubbleentity;
1206 void player_powerups_remove_all(entity this);
1207
1208 void ClientDisconnect(entity this)
1209 {
1210         assert(IS_CLIENT(this), return);
1211
1212         PlayerStats_GameReport_FinalizePlayer(this);
1213         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1214         if (CS(this).active_minigame) part_minigame(this);
1215         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1216
1217         if (autocvar_sv_eventlog)
1218                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1219
1220         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1221
1222         if(IS_SPEC(this))
1223                 SetSpectatee(this, NULL);
1224
1225         MUTATOR_CALLHOOK(ClientDisconnect, this);
1226
1227         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1228         strfree(CS_CVAR(this).weaponorder_byimpulse);
1229         ClientState_detach(this);
1230
1231         Portal_ClearAll(this);
1232
1233         Unfreeze(this, false);
1234
1235         RemoveGrapplingHooks(this);
1236
1237         // Here, everything has been done that requires this player to be a client.
1238
1239         this.flags &= ~FL_CLIENT;
1240
1241         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1242         if (this.killindicator) delete(this.killindicator);
1243
1244         IL_EACH(g_counters, it.realowner == this,
1245         {
1246                 delete(it);
1247         });
1248
1249         WaypointSprite_PlayerGone(this);
1250
1251         bot_relinkplayerlist();
1252
1253         strfree(this.clientstatus);
1254         if (this.personal) delete(this.personal);
1255
1256         this.playerid = 0;
1257         if (warmup_stage || game_starttime > time) ReadyCount();
1258         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1259
1260         player_powerups_remove_all(this); // stop powerup sound
1261
1262         ONREMOVE(this);
1263
1264         if (player_count == 0)
1265                 localcmd("\nsv_hook_lastleave\n");
1266 }
1267
1268 void ChatBubbleThink(entity this)
1269 {
1270         this.nextthink = time;
1271         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1272         {
1273                 if(this.owner) // but why can that ever be NULL?
1274                         this.owner.chatbubbleentity = NULL;
1275                 delete(this);
1276                 return;
1277         }
1278
1279         this.mdl = "";
1280
1281         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1282         {
1283                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1284                         this.mdl = "models/sprites/minigame_busy.iqm";
1285                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1286                         this.mdl = "models/misc/chatbubble.spr";
1287         }
1288
1289         if ( this.model != this.mdl )
1290                 _setmodel(this, this.mdl);
1291
1292 }
1293
1294 void UpdateChatBubble(entity this)
1295 {
1296         if (this.alpha < 0)
1297                 return;
1298         // spawn a chatbubble entity if needed
1299         if (!this.chatbubbleentity)
1300         {
1301                 this.chatbubbleentity = new(chatbubbleentity);
1302                 this.chatbubbleentity.owner = this;
1303                 this.chatbubbleentity.exteriormodeltoclient = this;
1304                 setthink(this.chatbubbleentity, ChatBubbleThink);
1305                 this.chatbubbleentity.nextthink = time;
1306                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1307                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1308                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1309                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1310                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1311                 //this.chatbubbleentity.model = "";
1312                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1313         }
1314 }
1315
1316 void calculate_player_respawn_time(entity this)
1317 {
1318         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1319                 return;
1320
1321         float gametype_setting_tmp;
1322         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1323         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1324         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1325         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1326         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1327         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1328
1329         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1330         if (teamplay)
1331         {
1332                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1333                         if(it.team == this.team)
1334                                 ++pcount;
1335                 });
1336                 if (sdelay_small_count == 0)
1337                         sdelay_small_count = 1;
1338                 if (sdelay_large_count == 0)
1339                         sdelay_large_count = 1;
1340         }
1341         else
1342         {
1343                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1344                         ++pcount;
1345                 });
1346                 if (sdelay_small_count == 0)
1347                 {
1348                         if (IS_INDEPENDENT_PLAYER(this))
1349                         {
1350                                 // Players play independently. No point in requiring enemies.
1351                                 sdelay_small_count = 1;
1352                         }
1353                         else
1354                         {
1355                                 // Players play AGAINST each other. Enemies required.
1356                                 sdelay_small_count = 2;
1357                         }
1358                 }
1359                 if (sdelay_large_count == 0)
1360                 {
1361                         if (IS_INDEPENDENT_PLAYER(this))
1362                         {
1363                                 // Players play independently. No point in requiring enemies.
1364                                 sdelay_large_count = 1;
1365                         }
1366                         else
1367                         {
1368                                 // Players play AGAINST each other. Enemies required.
1369                                 sdelay_large_count = 2;
1370                         }
1371                 }
1372         }
1373
1374         float sdelay;
1375
1376         if (pcount <= sdelay_small_count)
1377                 sdelay = sdelay_small;
1378         else if (pcount >= sdelay_large_count)
1379                 sdelay = sdelay_large;
1380         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1381                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1382
1383         if(waves)
1384                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1385         else
1386                 this.respawn_time = time + sdelay;
1387
1388         if(sdelay < sdelay_max)
1389                 this.respawn_time_max = time + sdelay_max;
1390         else
1391                 this.respawn_time_max = this.respawn_time;
1392
1393         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1394                 this.respawn_countdown = 10; // first number to count down from is 10
1395         else
1396                 this.respawn_countdown = -1; // do not count down
1397
1398         if(autocvar_g_forced_respawn)
1399                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1400 }
1401
1402 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1403 // added to the model skins
1404 /*void UpdateColorModHack()
1405 {
1406         float c;
1407         c = this.clientcolors & 15;
1408         // LordHavoc: only bothering to support white, green, red, yellow, blue
1409              if (!teamplay) this.colormod = '0 0 0';
1410         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1411         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1412         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1413         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1414         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1415         else this.colormod = '1 1 1';
1416 }*/
1417
1418 void respawn(entity this)
1419 {
1420         bool damagedbycontents_prev = this.damagedbycontents;
1421         if(this.alpha >= 0)
1422         {
1423                 if(autocvar_g_respawn_ghosts)
1424                 {
1425                         this.solid = SOLID_NOT;
1426                         this.takedamage = DAMAGE_NO;
1427                         this.damagedbycontents = false;
1428                         set_movetype(this, MOVETYPE_FLY);
1429                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1430                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1431                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1432                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1433                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1434                         if(autocvar_g_respawn_ghosts_time > 0)
1435                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1436                 }
1437                 else
1438                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1439         }
1440
1441         CopyBody(this, 1);
1442         this.damagedbycontents = damagedbycontents_prev;
1443
1444         this.effects |= EF_NODRAW; // prevent another CopyBody
1445         PutClientInServer(this);
1446 }
1447
1448 void play_countdown(entity this, float finished, Sound samp)
1449 {
1450         TC(Sound, samp);
1451         float time_left = finished - time;
1452         if(IS_REAL_CLIENT(this) && time_left < 6 && floor(time_left - frametime) != floor(time_left))
1453                 sound(this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1454 }
1455
1456 // it removes special powerups not handled by StatusEffects
1457 void player_powerups_remove_all(entity this)
1458 {
1459         if (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1460         {
1461                 // don't play the poweroff sound when the game restarts or the player disconnects
1462                 if (time > game_starttime + 1 && IS_CLIENT(this)
1463                         && !(start_items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS)))
1464                 {
1465                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1466                 }
1467                 if (this.items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1468                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1469                 this.items -= (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS));
1470         }
1471 }
1472
1473 void player_powerups(entity this)
1474 {
1475         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1476                 this.modelflags |= MF_ROCKET;
1477         else
1478                 this.modelflags &= ~MF_ROCKET;
1479
1480         this.effects &= ~EF_NODEPTHTEST;
1481
1482         if (IS_DEAD(this))
1483                 player_powerups_remove_all(this);
1484
1485         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1486                 return;
1487
1488         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1489         int items_prev = this.items;
1490
1491         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1492         {
1493                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1494                 if (this.items & IT_SUPERWEAPON)
1495                 {
1496                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1497                         {
1498                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1499                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1500                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1501                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1502                         }
1503                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1504                         {
1505                                 // don't let them run out
1506                         }
1507                         else
1508                         {
1509                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1510                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1511                                 {
1512                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1513                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1514                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1515                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1516                                 }
1517                         }
1518                 }
1519                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1520                 {
1521                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1522                         {
1523                                 this.items = this.items | IT_SUPERWEAPON;
1524                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1525                                 {
1526                                         if(!g_cts)
1527                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1528                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1529                                 }
1530                         }
1531                         else
1532                         {
1533                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1534                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1535                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1536                         }
1537                 }
1538                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1539                 {
1540                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1541                 }
1542         }
1543
1544         if(autocvar_g_nodepthtestplayers)
1545                 this.effects = this.effects | EF_NODEPTHTEST;
1546
1547         if(autocvar_g_fullbrightplayers)
1548                 this.effects = this.effects | EF_FULLBRIGHT;
1549
1550         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1551 }
1552
1553 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1554 {
1555         if(current > stable)
1556                 return current;
1557         else if(current > stable - 0.25) // when close enough, "snap"
1558                 return stable;
1559         else
1560                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1561 }
1562
1563 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1564 {
1565         if(current < stable)
1566                 return current;
1567         else if(current < stable + 0.25) // when close enough, "snap"
1568                 return stable;
1569         else
1570                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1571 }
1572
1573 void RotRegen(entity this, Resource res, float limit_mod,
1574         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1575         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1576 {
1577         float old = GetResource(this, res);
1578         float current = old;
1579         if(current > rotstable)
1580         {
1581                 if(rotframetime > 0)
1582                 {
1583                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1584                         current = max(rotstable, current - rotlinear * rotframetime);
1585                 }
1586         }
1587         else if(current < regenstable)
1588         {
1589                 if(regenframetime > 0)
1590                 {
1591                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1592                         current = min(regenstable, current + regenlinear * regenframetime);
1593                 }
1594         }
1595
1596         float limit = GetResourceLimit(this, res) * limit_mod;
1597         if(current > limit)
1598                 current = limit;
1599
1600         if (current != old)
1601                 SetResource(this, res, current);
1602 }
1603
1604 void player_regen(entity this)
1605 {
1606         float max_mod, regen_mod, rot_mod, limit_mod;
1607         max_mod = regen_mod = rot_mod = limit_mod = 1;
1608
1609         float regen_health = autocvar_g_balance_health_regen;
1610         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1611         float regen_health_rot = autocvar_g_balance_health_rot;
1612         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1613         float regen_health_stable = autocvar_g_balance_health_regenstable;
1614         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1615         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1616                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1617         max_mod = M_ARGV(1, float);
1618         regen_mod = M_ARGV(2, float);
1619         rot_mod = M_ARGV(3, float);
1620         limit_mod = M_ARGV(4, float);
1621         regen_health = M_ARGV(5, float);
1622         regen_health_linear = M_ARGV(6, float);
1623         regen_health_rot = M_ARGV(7, float);
1624         regen_health_rotlinear = M_ARGV(8, float);
1625         regen_health_stable = M_ARGV(9, float);
1626         regen_health_rotstable = M_ARGV(10, float);
1627
1628         float rotstable, regenstable, rotframetime, regenframetime;
1629
1630         if(!mutator_returnvalue)
1631         if(!STAT(FROZEN, this))
1632         {
1633                 regenstable = autocvar_g_balance_armor_regenstable;
1634                 rotstable = autocvar_g_balance_armor_rotstable;
1635                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1636                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1637                 RotRegen(this, RES_ARMOR, limit_mod,
1638                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1639                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1640
1641                 // NOTE: max_mod is only applied to health
1642                 regenstable = regen_health_stable * max_mod;
1643                 rotstable = regen_health_rotstable * max_mod;
1644                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1645                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1646                 RotRegen(this, RES_HEALTH, limit_mod,
1647                         regenstable, regen_health, regen_health_linear, regenframetime,
1648                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1649         }
1650
1651         // if player rotted to death...  die!
1652         // check this outside above checks, as player may still be able to rot to death
1653         if(GetResource(this, RES_HEALTH) < 1)
1654         {
1655                 if(this.vehicle)
1656                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1657                 if(this.event_damage)
1658                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1659         }
1660
1661         if (!(this.items & IT_UNLIMITED_AMMO))
1662         {
1663                 regenstable = autocvar_g_balance_fuel_regenstable;
1664                 rotstable = autocvar_g_balance_fuel_rotstable;
1665                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1666                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1667                 RotRegen(this, RES_FUEL, 1,
1668                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1669                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1670         }
1671 }
1672
1673 bool zoomstate_set;
1674 void SetZoomState(entity this, float newzoom)
1675 {
1676         if(newzoom != CS(this).zoomstate)
1677         {
1678                 CS(this).zoomstate = newzoom;
1679                 ClientData_Touch(this);
1680         }
1681         zoomstate_set = true;
1682 }
1683
1684 void GetPressedKeys(entity this)
1685 {
1686         MUTATOR_CALLHOOK(GetPressedKeys, this);
1687         if (game_stopped)
1688         {
1689                 CS(this).pressedkeys = 0;
1690                 STAT(PRESSED_KEYS, this) = 0;
1691                 return;
1692         }
1693
1694         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1695         int keys = STAT(PRESSED_KEYS, this);
1696         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1697         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1698         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1699         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1700
1701         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1702         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1703         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1704         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1705         CS(this).pressedkeys = keys; // store for other users
1706
1707         STAT(PRESSED_KEYS, this) = keys;
1708 }
1709
1710 /*
1711 ======================
1712 spectate mode routines
1713 ======================
1714 */
1715
1716 void SpectateCopy(entity this, entity spectatee)
1717 {
1718         TC(Client, this); TC(Client, spectatee);
1719
1720         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1721         PS(this) = PS(spectatee);
1722         this.armortype = spectatee.armortype;
1723         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1724         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1725         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1726         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1727         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1728         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1729         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1730         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1731         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1732         CS(this).impulse = 0;
1733         this.disableclientprediction = 1; // no need to run prediction on a spectator
1734         this.items = spectatee.items;
1735         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1736         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1737         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1738         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1739         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1740         this.punchangle = spectatee.punchangle;
1741         this.view_ofs = spectatee.view_ofs;
1742         this.velocity = spectatee.velocity;
1743         this.dmg_take = spectatee.dmg_take;
1744         this.dmg_save = spectatee.dmg_save;
1745         this.dmg_inflictor = spectatee.dmg_inflictor;
1746         this.v_angle = spectatee.v_angle;
1747         this.angles = spectatee.v_angle;
1748         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1749         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1750         this.viewloc = spectatee.viewloc;
1751         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1752                 this.fixangle = true;
1753         setorigin(this, spectatee.origin);
1754         setsize(this, spectatee.mins, spectatee.maxs);
1755         SetZoomState(this, CS(spectatee).zoomstate);
1756
1757     anticheat_spectatecopy(this, spectatee);
1758         STAT(HUD, this) = STAT(HUD, spectatee);
1759         if(spectatee.vehicle)
1760     {
1761         this.angles = spectatee.v_angle;
1762
1763         //this.fixangle = false;
1764         //this.velocity = spectatee.vehicle.velocity;
1765         this.vehicle_health = spectatee.vehicle_health;
1766         this.vehicle_shield = spectatee.vehicle_shield;
1767         this.vehicle_energy = spectatee.vehicle_energy;
1768         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1769         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1770         this.vehicle_reload1 = spectatee.vehicle_reload1;
1771         this.vehicle_reload2 = spectatee.vehicle_reload2;
1772
1773         //msg_entity = this;
1774
1775        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1776             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1777            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1778            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1779
1780         //WriteByte (MSG_ONE, SVC_SETVIEW);
1781         //    WriteEntity(MSG_ONE, this);
1782         //makevectors(spectatee.v_angle);
1783         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1784     }
1785 }
1786
1787 bool SpectateUpdate(entity this)
1788 {
1789         if(!this.enemy)
1790                 return false;
1791
1792         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1793         {
1794                 SetSpectatee(this, NULL);
1795                 return false;
1796         }
1797
1798         SpectateCopy(this, this.enemy);
1799
1800         return true;
1801 }
1802
1803 bool SpectateSet(entity this)
1804 {
1805         if(!IS_PLAYER(this.enemy))
1806                 return false;
1807
1808         ClientData_Touch(this.enemy);
1809
1810         msg_entity = this;
1811         WriteByte(MSG_ONE, SVC_SETVIEW);
1812         WriteEntity(MSG_ONE, this.enemy);
1813         set_movetype(this, MOVETYPE_NONE);
1814         accuracy_resend(this);
1815
1816         if(!SpectateUpdate(this))
1817                 PutObserverInServer(this, false, true);
1818
1819         return true;
1820 }
1821
1822 void SetSpectatee_status(entity this, int spectatee_num)
1823 {
1824         int oldspectatee_status = CS(this).spectatee_status;
1825         CS(this).spectatee_status = spectatee_num;
1826
1827         if (CS(this).spectatee_status != oldspectatee_status)
1828         {
1829                 if (STAT(PRESSED_KEYS, this))
1830                 {
1831                         CS(this).pressedkeys = 0;
1832                         STAT(PRESSED_KEYS, this) = 0;
1833                 }
1834                 ClientData_Touch(this);
1835                 if (g_race || g_cts) race_InitSpectator();
1836         }
1837 }
1838
1839 void SetSpectatee(entity this, entity spectatee)
1840 {
1841         if(IS_BOT_CLIENT(this))
1842                 return; // bots abuse .enemy, this code is useless to them
1843
1844         entity old_spectatee = this.enemy;
1845
1846         this.enemy = spectatee;
1847
1848         // WEAPONTODO
1849         // these are required to fix the spectator bug with arc
1850         if(old_spectatee)
1851         {
1852                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1853                 {
1854                         .entity weaponentity = weaponentities[slot];
1855                         if(old_spectatee.(weaponentity).arc_beam)
1856                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1857                 }
1858         }
1859         if(spectatee)
1860         {
1861                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1862                 {
1863                         .entity weaponentity = weaponentities[slot];
1864                         if(spectatee.(weaponentity).arc_beam)
1865                                 spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1866                 }
1867         }
1868
1869         if (spectatee)
1870                 SetSpectatee_status(this, etof(spectatee));
1871
1872         // needed to update spectator list
1873         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1874 }
1875
1876 bool Spectate(entity this, entity pl)
1877 {
1878         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1879                 return false;
1880         pl = M_ARGV(1, entity);
1881
1882         SetSpectatee(this, pl);
1883         return SpectateSet(this);
1884 }
1885
1886 bool SpectateNext(entity this)
1887 {
1888         entity ent = find(this.enemy, classname, STR_PLAYER);
1889
1890         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1891                 ent = M_ARGV(1, entity);
1892         else if (!ent)
1893                 ent = find(ent, classname, STR_PLAYER);
1894
1895         if(ent) { SetSpectatee(this, ent); }
1896
1897         return SpectateSet(this);
1898 }
1899
1900 bool SpectatePrev(entity this)
1901 {
1902         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1903         entity ent = findchain(classname, STR_PLAYER);
1904         if (!ent) // no player
1905                 return false;
1906
1907         entity first = ent;
1908         // skip players until current spectated player
1909         if(this.enemy)
1910         while(ent && ent != this.enemy)
1911                 ent = ent.chain;
1912
1913         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1914         {
1915                 case MUT_SPECPREV_FOUND:
1916                         ent = M_ARGV(1, entity);
1917                         break;
1918                 case MUT_SPECPREV_RETURN:
1919                         return true;
1920                 case MUT_SPECPREV_CONTINUE:
1921                 default:
1922                 {
1923                         if(ent.chain)
1924                                 ent = ent.chain;
1925                         else
1926                                 ent = first;
1927                         break;
1928                 }
1929         }
1930
1931         SetSpectatee(this, ent);
1932         return SpectateSet(this);
1933 }
1934
1935 /*
1936 =============
1937 ShowRespawnCountdown()
1938
1939 Update a respawn countdown display.
1940 =============
1941 */
1942 void ShowRespawnCountdown(entity this)
1943 {
1944         float number;
1945         if(!IS_DEAD(this)) // just respawned?
1946                 return;
1947         else
1948         {
1949                 number = ceil(this.respawn_time - time);
1950                 if(number <= 0)
1951                         return;
1952                 if(number <= this.respawn_countdown)
1953                 {
1954                         this.respawn_countdown = number - 1;
1955                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1956                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1957                 }
1958         }
1959 }
1960
1961 .bool team_selected;
1962 bool ShowTeamSelection(entity this)
1963 {
1964         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1965                 return false;
1966         if (frametime) // once per frame is more than enough
1967                 stuffcmd(this, "_scoreboard_team_selection 1\n");
1968         return true;
1969 }
1970 void Join(entity this)
1971 {
1972         if (autocvar_g_campaign && !campaign_bots_may_start && !game_stopped && time >= game_starttime)
1973                 ReadyRestart(true);
1974
1975         TRANSMUTE(Player, this);
1976
1977         if(!this.team_selected)
1978         if(autocvar_g_campaign || autocvar_g_balance_teams)
1979                 TeamBalance_JoinBestTeam(this);
1980
1981         if(autocvar_g_campaign)
1982                 campaign_bots_may_start = true;
1983
1984         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1985
1986         PutClientInServer(this);
1987
1988         if(IS_PLAYER(this))
1989         if(teamplay && this.team != -1)
1990         {
1991         }
1992         else
1993                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1994         this.team_selected = false;
1995 }
1996
1997 int GetPlayerLimit()
1998 {
1999         if(g_duel)
2000                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2001         // don't return map_maxplayers during intermission as it would interfere with MapHasRightSize()
2002         int player_limit = (autocvar_g_maxplayers >= 0 || intermission_running) ? autocvar_g_maxplayers : map_maxplayers;
2003         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2004         player_limit = M_ARGV(0, int);
2005         return player_limit < maxclients ? player_limit : 0;
2006 }
2007
2008 /**
2009  * Determines whether the player is allowed to join. This depends on cvar
2010  * g_maxplayers, if it isn't used this function always return true, otherwise
2011  * it checks whether the number of currently playing players exceeds g_maxplayers.
2012  * @return int number of free slots for players, 0 if none
2013  */
2014 int nJoinAllowed(entity this, entity ignore)
2015 {
2016         if(!ignore)
2017         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2018         // so report 0 free slots if restricted
2019         {
2020                 if(autocvar_g_forced_team_otherwise == "spectate")
2021                         return 0;
2022                 if(autocvar_g_forced_team_otherwise == "spectator")
2023                         return 0;
2024         }
2025
2026         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2027                 return 0; // forced spectators can never join
2028
2029         // TODO simplify this
2030         int totalClients = 0;
2031         int currentlyPlaying = 0;
2032         FOREACH_CLIENT(true, {
2033                 if(it != ignore)
2034                         ++totalClients;
2035                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2036                         ++currentlyPlaying;
2037         });
2038
2039         int player_limit = GetPlayerLimit();
2040
2041         int free_slots = 0;
2042         if (!player_limit)
2043                 free_slots = maxclients - totalClients;
2044         else if(player_limit > 0 && currentlyPlaying < player_limit)
2045                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2046
2047         static float msg_time = 0;
2048         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2049         {
2050                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT, player_limit);
2051                 msg_time = time + 0.5;
2052         }
2053
2054         return free_slots;
2055 }
2056
2057 bool joinAllowed(entity this)
2058 {
2059         if (CS(this).version_mismatch) return false;
2060         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2061         if (!nJoinAllowed(this, this)) return false;
2062         if (teamplay && lockteams) return false;
2063         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2064         if (ShowTeamSelection(this)) return false;
2065         return true;
2066 }
2067
2068 .string shootfromfixedorigin;
2069 .bool dualwielding_prev;
2070 bool PlayerThink(entity this)
2071 {
2072         if (game_stopped || intermission_running) {
2073                 this.modelflags &= ~MF_ROCKET;
2074                 if(intermission_running)
2075                         IntermissionThink(this);
2076                 return false;
2077         }
2078
2079         if (timeout_status == TIMEOUT_ACTIVE) {
2080                 // don't allow the player to turn around while game is paused
2081                 // FIXME turn this into CSQC stuff
2082                 this.v_angle = this.lastV_angle;
2083                 this.angles = this.lastV_angle;
2084                 this.fixangle = true;
2085         }
2086
2087         if (frametime) player_powerups(this);
2088
2089         if (IS_DEAD(this)) {
2090                 if (this.personal && g_race_qualifying) {
2091                         if (time > this.respawn_time) {
2092                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2093                                 respawn(this);
2094                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2095                         }
2096                 } else {
2097                         if (frametime) player_anim(this);
2098
2099                         if (this.respawn_flags & RESPAWN_DENY)
2100                         {
2101                                 STAT(RESPAWN_TIME, this) = 0;
2102                                 return false;
2103                         }
2104
2105                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2106
2107                         switch(this.deadflag)
2108                         {
2109                                 case DEAD_DYING:
2110                                 {
2111                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2112                                                 this.deadflag = DEAD_RESPAWNING;
2113                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2114                                                 this.deadflag = DEAD_DEAD;
2115                                         break;
2116                                 }
2117                                 case DEAD_DEAD:
2118                                 {
2119                                         if (button_pressed)
2120                                                 this.deadflag = DEAD_RESPAWNABLE;
2121                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2122                                                 this.deadflag = DEAD_RESPAWNING;
2123                                         break;
2124                                 }
2125                                 case DEAD_RESPAWNABLE:
2126                                 {
2127                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2128                                                 this.deadflag = DEAD_RESPAWNING;
2129                                         break;
2130                                 }
2131                                 case DEAD_RESPAWNING:
2132                                 {
2133                                         if (time > this.respawn_time)
2134                                         {
2135                                                 this.respawn_time = time + 1; // only retry once a second
2136                                                 this.respawn_time_max = this.respawn_time;
2137                                                 respawn(this);
2138                                         }
2139                                         break;
2140                                 }
2141                         }
2142
2143                         ShowRespawnCountdown(this);
2144
2145                         if (this.respawn_flags & RESPAWN_SILENT)
2146                                 STAT(RESPAWN_TIME, this) = 0;
2147                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2148                         {
2149                                 if (time < this.respawn_time)
2150                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2151                                 else if (this.deadflag != DEAD_RESPAWNING)
2152                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2153                         }
2154                         else
2155                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2156                 }
2157
2158                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2159                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2160                         STAT(RESPAWN_TIME, this) *= -1;
2161
2162                 return false;
2163         }
2164
2165         FixPlayermodel(this);
2166
2167         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2168                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2169                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2170         }
2171
2172         // reset gun alignment when dual wielding status changes
2173         // to ensure guns are always aligned right and left
2174         bool dualwielding = W_DualWielding(this);
2175         if(this.dualwielding_prev != dualwielding)
2176         {
2177                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2178                 this.dualwielding_prev = dualwielding;
2179         }
2180
2181         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2182         //if(frametime)
2183         {
2184                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2185                 {
2186                         .entity weaponentity = weaponentities[slot];
2187                         if(WEP_CVAR(vortex, charge_always))
2188                                 W_Vortex_Charge(this, weaponentity, frametime);
2189                         W_WeaponFrame(this, weaponentity);
2190                 }
2191         }
2192
2193         if (frametime)
2194         {
2195                 // WEAPONTODO: Add a weapon request for this
2196                 // rot vortex charge to the charge limit
2197                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2198                 {
2199                         .entity weaponentity = weaponentities[slot];
2200                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2201                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2202                 }
2203
2204                 player_regen(this);
2205                 player_anim(this);
2206                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2207         }
2208
2209         monsters_setstatus(this);
2210
2211         return true;
2212 }
2213
2214 .bool would_spectate;
2215 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2216 void ObserverOrSpectatorThink(entity this)
2217 {
2218         bool is_spec = IS_SPEC(this);
2219         if ( CS(this).impulse )
2220         {
2221                 int r = MinigameImpulse(this, CS(this).impulse);
2222                 if (!is_spec || r)
2223                         CS(this).impulse = 0;
2224
2225                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2226                 {
2227                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2228                         CS(this).impulse = 0;
2229                         return;
2230                 }
2231         }
2232
2233         if (IS_BOT_CLIENT(this) && !CS(this).autojoin_checked)
2234         {
2235                 CS(this).autojoin_checked = true;
2236                 TRANSMUTE(Player, this);
2237                 PutClientInServer(this);
2238                 return;
2239         }
2240
2241         if (this.flags & FL_JUMPRELEASED) {
2242                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2243                         this.flags &= ~FL_JUMPRELEASED;
2244                         this.flags |= FL_SPAWNING;
2245                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2246                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2247                         this.flags &= ~FL_JUMPRELEASED;
2248                         if(SpectateNext(this)) {
2249                                 TRANSMUTE(Spectator, this);
2250                         } else if (is_spec) {
2251                                 TRANSMUTE(Observer, this);
2252                                 PutClientInServer(this);
2253                         }
2254                         else
2255                                 this.would_spectate = false; // unable to spectate anyone
2256                         if (is_spec)
2257                                 CS(this).impulse = 0;
2258                 } else if (is_spec) {
2259                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2260                                 this.flags &= ~FL_JUMPRELEASED;
2261                                 if(SpectatePrev(this)) {
2262                                         TRANSMUTE(Spectator, this);
2263                                 } else {
2264                                         TRANSMUTE(Observer, this);
2265                                         PutClientInServer(this);
2266                                 }
2267                                 CS(this).impulse = 0;
2268                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2269                                 if(!observe_blocked_if_eliminated || !INGAME(this)) {
2270                                         this.would_spectate = false;
2271                                         this.flags &= ~FL_JUMPRELEASED;
2272                                         TRANSMUTE(Observer, this);
2273                                         PutClientInServer(this);
2274                                 }
2275                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2276                                 PutObserverInServer(this, false, true);
2277                                 this.would_spectate = true;
2278                         }
2279                 }
2280                 else {
2281                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2282                         if (PHYS_INPUT_BUTTON_USE(this))
2283                                 wouldclip = !wouldclip;
2284                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2285                         set_movetype(this, preferred_movetype);
2286                 }
2287         } else { // jump pressed
2288                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2289                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2290                         this.flags |= FL_JUMPRELEASED;
2291                         if(this.flags & FL_SPAWNING)
2292                         {
2293                                 this.flags &= ~FL_SPAWNING;
2294                                 if(joinAllowed(this))
2295                                         Join(this);
2296                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2297                                         CS(this).autojoin_checked = -1;
2298                                 return;
2299                         }
2300                 }
2301                 if(is_spec && !SpectateUpdate(this))
2302                         PutObserverInServer(this, false, true);
2303         }
2304         if (is_spec)
2305                 this.flags |= FL_CLIENT | FL_NOTARGET;
2306 }
2307
2308 void PlayerUseKey(entity this)
2309 {
2310         if (!IS_PLAYER(this))
2311                 return;
2312
2313         if(this.vehicle)
2314         {
2315                 if(!game_stopped)
2316                 {
2317                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2318                         return;
2319                 }
2320         }
2321         else if(autocvar_g_vehicles_enter)
2322         {
2323                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2324                 {
2325                         entity head, closest_target = NULL;
2326                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2327
2328                         while(head) // find the closest acceptable target to enter
2329                         {
2330                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2331                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2332                                 {
2333                                         if(closest_target)
2334                                         {
2335                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2336                                                 { closest_target = head; }
2337                                         }
2338                                         else { closest_target = head; }
2339                                 }
2340
2341                                 head = head.chain;
2342                         }
2343
2344                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2345                 }
2346         }
2347
2348         // a use key was pressed; call handlers
2349         MUTATOR_CALLHOOK(PlayerUseKey, this);
2350 }
2351
2352
2353 /*
2354 =============
2355 PlayerPreThink
2356
2357 Called every frame for each client before the physics are run
2358 =============
2359 */
2360 .float last_vehiclecheck;
2361 void PlayerPreThink (entity this)
2362 {
2363         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2364         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2365
2366         WarpZone_PlayerPhysics_FixVAngle(this);
2367
2368         if (frametime) {
2369                 // physics frames: update anticheat stuff
2370                 anticheat_prethink(this);
2371
2372                 // WORKAROUND: only use dropclient in server frames (frametime set).
2373                 // Never use it in cl_movement frames (frametime zero).
2374                 if (blockSpectators && IS_REAL_CLIENT(this)
2375                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2376                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2377                 {
2378                         if (dropclient_schedule(this))
2379                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2380                 }
2381         }
2382
2383         zoomstate_set = false;
2384
2385         // Check for nameless players
2386         if (this.netname == "" || this.netname != CS(this).netname_previous)
2387         {
2388                 bool assume_unchanged = (CS(this).netname_previous == "");
2389                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2390                 {
2391                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2392                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2393                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2394                         assume_unchanged = false;
2395                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2396                 }
2397                 if (isInvisibleString(this.netname))
2398                 {
2399                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2400                         sprint(this, "Warning: invisible names are not allowed.\n");
2401                         assume_unchanged = false;
2402                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2403                 }
2404                 if (!assume_unchanged && autocvar_sv_eventlog)
2405                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2406                 strcpy(CS(this).netname_previous, this.netname);
2407         }
2408
2409         // version nagging
2410         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2411         CS(this).version_nagtime = 0;
2412         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2413             // git client
2414         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2415             // git server
2416             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2417         } else {
2418             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2419             if (r < 0) { // old client
2420                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2421             } else if (r > 0) { // old server
2422                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2423             }
2424         }
2425     }
2426
2427         // GOD MODE info
2428         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2429         {
2430                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2431                 this.max_armorvalue = 0;
2432         }
2433
2434         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2435         {
2436                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2437                 {
2438                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2439                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2440                         if (this.iceblock)
2441                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2442
2443                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2444                                 Unfreeze(this, false);
2445                 }
2446                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2447                 {
2448                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2449                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2450
2451                         if (GetResource(this, RES_HEALTH) < 1)
2452                         {
2453                                 if (this.vehicle)
2454                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2455                                 if(this.event_damage)
2456                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2457                         }
2458                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2459                                 Unfreeze(this, false);
2460                 }
2461         }
2462
2463         MUTATOR_CALLHOOK(PlayerPreThink, this);
2464
2465         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2466         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2467         {
2468                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2469                 {
2470                         if(!it.owner)
2471                         {
2472                                 if(!it.team || SAME_TEAM(this, it))
2473                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2474                                 else if(autocvar_g_vehicles_steal)
2475                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2476                         }
2477                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2478                         {
2479                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2480                         }
2481                 });
2482
2483                 this.last_vehiclecheck = time + 1;
2484         }
2485
2486         if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2487                 PlayerUseKey(this);
2488         CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2489
2490         if (IS_PLAYER(this)) {
2491                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2492                         error("Client can't be spawned as player on connection!");
2493                 if(!PlayerThink(this))
2494                         return;
2495         }
2496         else if (game_stopped || intermission_running) {
2497                 if(intermission_running)
2498                         IntermissionThink(this);
2499                 return;
2500         }
2501         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2502         {
2503                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2504                 CS(this).autojoin_checked = 1;
2505                 // don't do this in ClientConnect
2506                 // many things can go wrong if a client is spawned as player on connection
2507                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2508                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2509                                 && (!teamplay || autocvar_g_balance_teams)))
2510                 {
2511                         if(joinAllowed(this))
2512                                 Join(this);
2513                         return;
2514                 }
2515         }
2516         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2517                 ObserverOrSpectatorThink(this);
2518         }
2519
2520         // WEAPONTODO: Add weapon request for this
2521         if (!zoomstate_set) {
2522                 bool wep_zoomed = false;
2523                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2524                 {
2525                         .entity weaponentity = weaponentities[slot];
2526                         Weapon thiswep = this.(weaponentity).m_weapon;
2527                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2528                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2529                 }
2530                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2531         }
2532
2533         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2534         {
2535                 CS(this).teamkill_soundtime = 0;
2536
2537                 entity e = CS(this).teamkill_soundsource;
2538                 entity oldpusher = e.pusher;
2539                 e.pusher = this;
2540                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2541                 e.pusher = oldpusher;
2542         }
2543
2544         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2545                 CS(this).taunt_soundtime = 0;
2546                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2547         }
2548
2549         target_voicescript_next(this);
2550 }
2551
2552 void DrownPlayer(entity this)
2553 {
2554         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2555                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2556         {
2557                 STAT(AIR_FINISHED, this) = 0;
2558                 return;
2559         }
2560
2561         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2562         {
2563                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2564                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2565                 STAT(AIR_FINISHED, this) = 0;
2566         }
2567         else
2568         {
2569                 if (!STAT(AIR_FINISHED, this))
2570                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2571                 if (STAT(AIR_FINISHED, this) < time)
2572                 {       // drown!
2573                         if (this.pain_finished < time)
2574                         {
2575                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2576                                 this.pain_finished = time + 0.5;
2577                         }
2578                 }
2579         }
2580 }
2581
2582 .bool move_qcphysics;
2583
2584 void Player_Physics(entity this)
2585 {
2586         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2587
2588         if(!this.move_qcphysics)
2589                 return;
2590
2591         if(!frametime && !CS(this).pm_frametime)
2592                 return;
2593
2594         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2595
2596         CS(this).pm_frametime = 0;
2597 }
2598
2599 /*
2600 =============
2601 PlayerPostThink
2602
2603 Called every frame for each client after the physics are run
2604 =============
2605 */
2606 void PlayerPostThink (entity this)
2607 {
2608         Player_Physics(this);
2609
2610         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2611         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2612         if (IS_REAL_CLIENT(this))
2613         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2614         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2615         {
2616                 int totalClients = 0;
2617                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2618                 {
2619                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2620                         if (server_is_dedicated)
2621                         {
2622                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2623                                 {
2624                                         ++totalClients;
2625                                 });
2626                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2627                                         totalClients = 0;
2628                         }
2629                 }
2630                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2631                 {
2632                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2633                         {
2634                                 ++totalClients;
2635                         });
2636                 }
2637
2638                 if (totalClients < autocvar_sv_maxidle_minplayers)
2639                 {
2640                         // idle kick disabled
2641                         CS(this).parm_idlesince = time;
2642                 }
2643                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2644                 {
2645                         if (CS(this).idlekick_lasttimeleft)
2646                         {
2647                                 CS(this).idlekick_lasttimeleft = 0;
2648                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2649                         }
2650                 }
2651                 else
2652                 {
2653                         float maxidle_time = autocvar_sv_maxidle;
2654                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2655                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2656                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2657                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2658                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2659                         {
2660                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2661                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2662                                 else
2663                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2664                         }
2665                         if (timeleft <= 0) {
2666                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2667                                 {
2668                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2669                                         PutObserverInServer(this, true, true);
2670                                 }
2671                                 else
2672                                 {
2673                                         if (dropclient_schedule(this))
2674                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2675                                 }
2676                                 return;
2677                         }
2678                         else if (timeleft <= countdown_time) {
2679                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2680                                         play2(this, SND(TALK2));
2681                                 CS(this).idlekick_lasttimeleft = timeleft;
2682                         }
2683                 }
2684         }
2685
2686         CheatFrame(this);
2687
2688         if (game_stopped)
2689         {
2690                 this.solid = SOLID_NOT;
2691                 this.takedamage = DAMAGE_NO;
2692                 set_movetype(this, MOVETYPE_NONE);
2693                 CS(this).teamkill_complain = 0;
2694                 CS(this).teamkill_soundtime = 0;
2695                 CS(this).teamkill_soundsource = NULL;
2696         }
2697
2698         if (IS_PLAYER(this)) {
2699                 if(this.death_time == time && IS_DEAD(this))
2700                 {
2701                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2702                         // once all the damage events of this frame have been processed with normal size
2703                         this.maxs.z = 5;
2704                         setsize(this, this.mins, this.maxs);
2705                 }
2706                 DrownPlayer(this);
2707                 UpdateChatBubble(this);
2708                 if (CS(this).impulse) ImpulseCommands(this);
2709                 GetPressedKeys(this);
2710                 if (game_stopped)
2711                 {
2712                         CSQCMODEL_AUTOUPDATE(this);
2713                         return;
2714                 }
2715         }
2716         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2717         {
2718                 CS(this).pressedkeys = 0;
2719                 STAT(PRESSED_KEYS, this) = 0;
2720         }
2721
2722         if (this.waypointsprite_attachedforcarrier) {
2723                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2724                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2725         }
2726
2727         CSQCMODEL_AUTOUPDATE(this);
2728 }
2729
2730 // hack to copy the button fields from the client entity to the Client State
2731 void PM_UpdateButtons(entity this, entity store)
2732 {
2733         if(this.impulse)
2734                 store.impulse = this.impulse;
2735         this.impulse = 0;
2736
2737         bool typing = this.buttonchat || this.button12;
2738
2739         store.button0 = (typing) ? 0 : this.button0;
2740         //button1?!
2741         store.button2 = (typing) ? 0 : this.button2;
2742         store.button3 = (typing) ? 0 : this.button3;
2743         store.button4 = this.button4;
2744         store.button5 = (typing) ? 0 : this.button5;
2745         store.button6 = this.button6;
2746         store.button7 = this.button7;
2747         store.button8 = this.button8;
2748         store.button9 = this.button9;
2749         store.button10 = this.button10;
2750         store.button11 = this.button11;
2751         store.button12 = this.button12;
2752         store.button13 = this.button13;
2753         store.button14 = this.button14;
2754         store.button15 = this.button15;
2755         store.button16 = this.button16;
2756         store.buttonuse = this.buttonuse;
2757         store.buttonchat = this.buttonchat;
2758
2759         store.cursor_active = this.cursor_active;
2760         store.cursor_screen = this.cursor_screen;
2761         store.cursor_trace_start = this.cursor_trace_start;
2762         store.cursor_trace_endpos = this.cursor_trace_endpos;
2763         store.cursor_trace_ent = this.cursor_trace_ent;
2764
2765         store.ping = this.ping;
2766         store.ping_packetloss = this.ping_packetloss;
2767         store.ping_movementloss = this.ping_movementloss;
2768
2769         store.v_angle = this.v_angle;
2770         store.movement = this.movement;
2771 }
2772
2773 NET_HANDLE(fpsreport, bool)
2774 {
2775         int fps = ReadShort();
2776         PlayerScore_Set(sender, SP_FPS, fps);
2777         return true;
2778 }