qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "handicap.qh"
  18 #include "g_hook.qh"
  19 #include "command/common.qh"
  20 #include "cheats.qh"
  21 #include "g_world.qh"
  22 #include "race.qh"
  23 #include "antilag.qh"
  24 #include "campaign.qh"
  25 #include "command/common.qh"
  26 #include "scores_rules.qh"
  27
  28 #include "bot/api.qh"
  29
  30 #include "../common/ent_cs.qh"
  31 #include "../common/wepent.qh"
  32 #include <common/state.qh>
  33
  34 #include <common/effects/qc/globalsound.qh>
  35
  36 #include "../common/triggers/func/conveyor.qh"
  37 #include "../common/triggers/teleporters.qh"
  38
  39 #include "../common/vehicles/all.qh"
  40
  41 #include "weapons/hitplot.qh"
  42 #include "weapons/weaponsystem.qh"
  43
  44 #include "../common/net_notice.qh"
  45 #include "../common/net_linked.qh"
  46 #include "../common/physics/player.qh"
  47
  48 #include "../common/items/_mod.qh"
  49
  50 #include "../common/mutators/mutator/waypoints/all.qh"
  51
  52 #include "../common/triggers/subs.qh"
  53 #include "../common/triggers/triggers.qh"
  54 #include "../common/triggers/trigger/secret.qh"
  55
  56 #include "../common/minigames/sv_minigames.qh"
  57
  58 #include "../common/items/inventory.qh"
  59
  60 #include "../common/monsters/sv_monsters.qh"
  61
  62 #include "../lib/warpzone/server.qh"
  63
  64 #include <common/mutators/mutator/overkill/okvortex.qh>
  65
  66 STATIC_METHOD(Client, Add, void(Client this, int _team))
  67 {
  68     ClientConnect(this);
  69     TRANSMUTE(Player, this);
  70     this.frame = 12; // 7
  71     this.team = _team;
  72     PutClientInServer(this);
  73 }
  74
  75 void PutObserverInServer(entity this);
  76
  77 STATIC_METHOD(Client, Remove, void(Client this))
  78 {
  79     TRANSMUTE(Observer, this);
  80     PutClientInServer(this);
  81     ClientDisconnect(this);
  82 }
  83
  84 void send_CSQC_teamnagger() {
  85         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  86 }
  87
  88 int CountSpectators(entity player, entity to)
  89 {
  90         if(!player) { return 0; } // not sure how, but best to be safe
  91
  92         int spec_count = 0;
  93
  94         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  95         {
  96                 spec_count++;
  97         });
  98
  99         return spec_count;
 100 }
 101
 102 void WriteSpectators(entity player, entity to)
 103 {
 104         if(!player) { return; } // not sure how, but best to be safe
 105
 106         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 107         {
 108                 WriteByte(MSG_ENTITY, num_for_edict(it));
 109         });
 110 }
 111
 112 bool ClientData_Send(entity this, entity to, int sf)
 113 {
 114         assert(to == this.owner, return false);
 115
 116         entity e = to;
 117         if (IS_SPEC(e)) e = e.enemy;
 118
 119         sf = 0;
 120         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 121         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 122         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 123         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 124
 125         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 126         WriteByte(MSG_ENTITY, sf);
 127
 128         if (sf & BIT(1))
 129                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 130
 131         if(sf & BIT(4))
 132         {
 133                 float specs = CountSpectators(e, to);
 134                 WriteByte(MSG_ENTITY, specs);
 135                 WriteSpectators(e, to);
 136         }
 137
 138         return true;
 139 }
 140
 141 void ClientData_Attach(entity this)
 142 {
 143         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 144         CS(this).clientdata.drawonlytoclient = this;
 145         CS(this).clientdata.owner = this;
 146 }
 147
 148 void ClientData_Detach(entity this)
 149 {
 150         delete(CS(this).clientdata);
 151         CS(this).clientdata = NULL;
 152 }
 153
 154 void ClientData_Touch(entity e)
 155 {
 156         CS(e).clientdata.SendFlags = 1;
 157
 158         // make it spectatable
 159         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, { CS(it).clientdata.SendFlags = 1; });
 160 }
 161
 162 void SetSpectatee(entity this, entity spectatee);
 163 void SetSpectatee_status(entity this, int spectatee_num);
 164
 165
 166 /*
 167 =============
 168 CheckPlayerModel
 169
 170 Checks if the argument string can be a valid playermodel.
 171 Returns a valid one in doubt.
 172 =============
 173 */
 174 string FallbackPlayerModel;
 175 string CheckPlayerModel(string plyermodel) {
 176         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 177         {
 178                 // note: we cannot summon Don Strunzone here, some player may
 179                 // still have the model string set. In case anyone manages how
 180                 // to change a cvar default, we'll have a small leak here.
 181                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 182         }
 183         // only in right path
 184         if( substring(plyermodel,0,14) != "models/player/")
 185                 return FallbackPlayerModel;
 186         // only good file extensions
 187         if(substring(plyermodel,-4,4) != ".zym")
 188         if(substring(plyermodel,-4,4) != ".dpm")
 189         if(substring(plyermodel,-4,4) != ".iqm")
 190         if(substring(plyermodel,-4,4) != ".md3")
 191         if(substring(plyermodel,-4,4) != ".psk")
 192                 return FallbackPlayerModel;
 193         // forbid the LOD models
 194         if(substring(plyermodel, -9,5) == "_lod1")
 195                 return FallbackPlayerModel;
 196         if(substring(plyermodel, -9,5) == "_lod2")
 197                 return FallbackPlayerModel;
 198         if(plyermodel != strtolower(plyermodel))
 199                 return FallbackPlayerModel;
 200         // also, restrict to server models
 201         if(autocvar_sv_servermodelsonly)
 202         {
 203                 if(!fexists(plyermodel))
 204                         return FallbackPlayerModel;
 205         }
 206         return plyermodel;
 207 }
 208
 209 void setplayermodel(entity e, string modelname)
 210 {
 211         precache_model(modelname);
 212         _setmodel(e, modelname);
 213         player_setupanimsformodel(e);
 214         if(!autocvar_g_debug_globalsounds)
 215                 UpdatePlayerSounds(e);
 216 }
 217
 218 void FixPlayermodel(entity player);
 219 /** putting a client as observer in the server */
 220 void PutObserverInServer(entity this)
 221 {
 222     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 223         PlayerState_detach(this);
 224
 225         if (IS_PLAYER(this))
 226         {
 227                 if(this.health >= 1)
 228                 {
 229                         // despawn effect
 230                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 231                 }
 232
 233                 // was a player, recount votes and ready status
 234                 if(IS_REAL_CLIENT(this))
 235                 {
 236                         if (vote_called) { VoteCount(false); }
 237                         ReadyCount();
 238                 }
 239     }
 240
 241     {
 242         entity spot = SelectSpawnPoint(this, true);
 243         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 244         this.angles = vec2(spot.angles);
 245         this.fixangle = true;
 246         // offset it so that the spectator spawns higher off the ground, looks better this way
 247         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 248         if (IS_REAL_CLIENT(this))
 249         {
 250             msg_entity = this;
 251             WriteByte(MSG_ONE, SVC_SETVIEW);
 252             WriteEntity(MSG_ONE, this);
 253         }
 254         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 255         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 256         if(!autocvar_g_debug_globalsounds)
 257         {
 258                 // needed for player sounds
 259                 this.model = "";
 260                 FixPlayermodel(this);
 261         }
 262         setmodel(this, MDL_Null);
 263         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 264         this.view_ofs = '0 0 0';
 265     }
 266
 267     RemoveGrapplingHooks(this);
 268         Portal_ClearAll(this);
 269         Unfreeze(this);
 270         SetSpectatee(this, NULL);
 271
 272         if (this.alivetime)
 273         {
 274                 if (!warmup_stage)
 275                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 276                 this.alivetime = 0;
 277         }
 278
 279         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 280
 281         WaypointSprite_PlayerDead(this);
 282
 283         if (mutator_returnvalue) {
 284             // mutator prevents resetting teams+score
 285         } else {
 286                 int oldteam = this.team;
 287                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 288                 MUTATOR_CALLHOOK(Player_ChangedTeam, this, oldteam, this.team);
 289         this.frags = FRAGS_SPECTATOR;
 290         PlayerScore_Clear(this);  // clear scores when needed
 291     }
 292
 293         if (CS(this).killcount != FRAGS_SPECTATOR)
 294         {
 295                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 296                 if(!game_stopped)
 297                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 298                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 299
 300                 if(!CS(this).just_joined)
 301                         LogTeamchange(this.playerid, -1, 4);
 302                 else
 303                         CS(this).just_joined = false;
 304         }
 305
 306         accuracy_resend(this);
 307
 308         CS(this).spectatortime = time;
 309         if(this.bot_attack)
 310                 IL_REMOVE(g_bot_targets, this);
 311         this.bot_attack = false;
 312     this.hud = HUD_NORMAL;
 313         TRANSMUTE(Observer, this);
 314         this.iscreature = false;
 315         this.teleportable = TELEPORT_SIMPLE;
 316         if(this.damagedbycontents)
 317                 IL_REMOVE(g_damagedbycontents, this);
 318         this.damagedbycontents = false;
 319         this.health = FRAGS_SPECTATOR;
 320         SetSpectatee_status(this, etof(this));
 321         this.takedamage = DAMAGE_NO;
 322         this.solid = SOLID_NOT;
 323         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 324         this.flags = FL_CLIENT | FL_NOTARGET;
 325         this.armorvalue = 666;
 326         this.effects = 0;
 327         this.armorvalue = autocvar_g_balance_armor_start;
 328         this.pauserotarmor_finished = 0;
 329         this.pauserothealth_finished = 0;
 330         this.pauseregen_finished = 0;
 331         this.damageforcescale = 0;
 332         this.death_time = 0;
 333         this.respawn_flags = 0;
 334         this.respawn_time = 0;
 335         this.stat_respawn_time = 0;
 336         this.alpha = 0;
 337         this.scale = 0;
 338         this.fade_time = 0;
 339         this.pain_frame = 0;
 340         this.pain_finished = 0;
 341         this.strength_finished = 0;
 342         this.invincible_finished = 0;
 343         this.superweapons_finished = 0;
 344         this.pushltime = 0;
 345         this.istypefrag = 0;
 346         setthink(this, func_null);
 347         this.nextthink = 0;
 348         this.deadflag = DEAD_NO;
 349         this.crouch = false;
 350         this.revive_progress = 0;
 351         this.revival_time = 0;
 352
 353         this.items = 0;
 354         this.weapons = '0 0 0';
 355         this.drawonlytoclient = this;
 356
 357         this.weaponmodel = "";
 358         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 359         {
 360                 this.weaponentities[slot] = NULL;
 361         }
 362         this.exteriorweaponentity = NULL;
 363         CS(this).killcount = FRAGS_SPECTATOR;
 364         this.velocity = '0 0 0';
 365         this.avelocity = '0 0 0';
 366         this.punchangle = '0 0 0';
 367         this.punchvector = '0 0 0';
 368         this.oldvelocity = this.velocity;
 369         this.fire_endtime = -1;
 370         this.event_damage = func_null;
 371
 372         for(int slot = 0; slot < MAX_AXH; ++slot)
 373         {
 374                 entity axh = this.(AuxiliaryXhair[slot]);
 375                 this.(AuxiliaryXhair[slot]) = NULL;
 376
 377                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 378                         delete(axh);
 379         }
 380 }
 381
 382 int player_getspecies(entity this)
 383 {
 384         get_model_parameters(this.model, this.skin);
 385         int s = get_model_parameters_species;
 386         get_model_parameters(string_null, 0);
 387         if (s < 0) return SPECIES_HUMAN;
 388         return s;
 389 }
 390
 391 .float model_randomizer;
 392 void FixPlayermodel(entity player)
 393 {
 394         string defaultmodel = "";
 395         int defaultskin = 0;
 396         if(autocvar_sv_defaultcharacter)
 397         {
 398                 if(teamplay)
 399                 {
 400                         switch(player.team)
 401                         {
 402                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 403                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 404                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 405                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 406                         }
 407                 }
 408
 409                 if(defaultmodel == "")
 410                 {
 411                         defaultmodel = autocvar_sv_defaultplayermodel;
 412                         defaultskin = autocvar_sv_defaultplayerskin;
 413                 }
 414
 415                 int n = tokenize_console(defaultmodel);
 416                 if(n > 0)
 417                 {
 418                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 419                         // However, do NOT randomize if the player-selected model is in the list.
 420                         for (int i = 0; i < n; ++i)
 421                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 422                                         defaultmodel = argv(i);
 423                 }
 424
 425                 int i = strstrofs(defaultmodel, ":", 0);
 426                 if(i >= 0)
 427                 {
 428                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 429                         defaultmodel = substring(defaultmodel, 0, i);
 430                 }
 431         }
 432         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 433         {
 434                 if(teamplay)
 435                 {
 436                         switch(player.team)
 437                         {
 438                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 439                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 440                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 441                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 442                         }
 443                 }
 444
 445                 if(!defaultskin)
 446                         defaultskin = autocvar_sv_defaultplayerskin;
 447         }
 448
 449         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 450         defaultmodel = M_ARGV(0, string);
 451         defaultskin = M_ARGV(1, int);
 452
 453         bool chmdl = false;
 454         int oldskin;
 455         if(defaultmodel != "")
 456         {
 457                 if (defaultmodel != player.model)
 458                 {
 459                         vector m1 = player.mins;
 460                         vector m2 = player.maxs;
 461                         setplayermodel (player, defaultmodel);
 462                         setsize (player, m1, m2);
 463                         chmdl = true;
 464                 }
 465
 466                 oldskin = player.skin;
 467                 player.skin = defaultskin;
 468         } else {
 469                 if (player.playermodel != player.model || player.playermodel == "")
 470                 {
 471                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 472                         vector m1 = player.mins;
 473                         vector m2 = player.maxs;
 474                         setplayermodel (player, player.playermodel);
 475                         setsize (player, m1, m2);
 476                         chmdl = true;
 477                 }
 478
 479                 if(!autocvar_sv_defaultcharacterskin)
 480                 {
 481                         oldskin = player.skin;
 482                         player.skin = stof(player.playerskin);
 483                 }
 484                 else
 485                 {
 486                         oldskin = player.skin;
 487                         player.skin = defaultskin;
 488                 }
 489         }
 490
 491         if(chmdl || oldskin != player.skin) // model or skin has changed
 492         {
 493                 player.species = player_getspecies(player); // update species
 494                 if(!autocvar_g_debug_globalsounds)
 495                         UpdatePlayerSounds(player); // update skin sounds
 496         }
 497
 498         if(!teamplay)
 499                 if(strlen(autocvar_sv_defaultplayercolors))
 500                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 501                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 502 }
 503
 504 void PutPlayerInServer(entity this)
 505 {
 506         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 507
 508         PlayerState_attach(this);
 509         accuracy_resend(this);
 510
 511         if (this.team < 0)
 512                 JoinBestTeam(this, false, true);
 513
 514         entity spot = SelectSpawnPoint(this, false);
 515         if (!spot) {
 516                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 517                 return; // spawn failed
 518         }
 519
 520         TRANSMUTE(Player, this);
 521
 522         CS(this).wasplayer = true;
 523         this.iscreature = true;
 524         this.teleportable = TELEPORT_NORMAL;
 525         if(!this.damagedbycontents)
 526                 IL_PUSH(g_damagedbycontents, this);
 527         this.damagedbycontents = true;
 528         set_movetype(this, MOVETYPE_WALK);
 529         this.solid = SOLID_SLIDEBOX;
 530         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 531         if (autocvar_g_playerclip_collisions)
 532                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 533         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 534                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 535         this.frags = FRAGS_PLAYER;
 536         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 537         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 538         if (autocvar__notarget)
 539                 this.flags |= FL_NOTARGET;
 540         this.takedamage = DAMAGE_AIM;
 541         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 542
 543         if (warmup_stage) {
 544                 this.ammo_shells = warmup_start_ammo_shells;
 545                 this.ammo_nails = warmup_start_ammo_nails;
 546                 this.ammo_rockets = warmup_start_ammo_rockets;
 547                 this.ammo_cells = warmup_start_ammo_cells;
 548                 this.ammo_plasma = warmup_start_ammo_plasma;
 549                 this.ammo_fuel = warmup_start_ammo_fuel;
 550                 this.health = warmup_start_health;
 551                 this.armorvalue = warmup_start_armorvalue;
 552                 this.weapons = WARMUP_START_WEAPONS;
 553         } else {
 554                 this.ammo_shells = start_ammo_shells;
 555                 this.ammo_nails = start_ammo_nails;
 556                 this.ammo_rockets = start_ammo_rockets;
 557                 this.ammo_cells = start_ammo_cells;
 558                 this.ammo_plasma = start_ammo_plasma;
 559                 this.ammo_fuel = start_ammo_fuel;
 560                 this.health = start_health;
 561                 this.armorvalue = start_armorvalue;
 562                 this.weapons = start_weapons;
 563                 GiveRandomWeapons(this, random_start_weapons_count,
 564                         autocvar_g_random_start_weapons, random_start_ammo);
 565         }
 566         SetSpectatee_status(this, 0);
 567
 568         PS(this).dual_weapons = '0 0 0';
 569
 570         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 571
 572         this.items = start_items;
 573
 574         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 575         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 576         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 577         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 578         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 579         // extend the pause of rotting if client was reset at the beginning of the countdown
 580         if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 581                 float f = game_starttime - time;
 582                 this.spawnshieldtime += f;
 583                 this.pauserotarmor_finished += f;
 584                 this.pauserothealth_finished += f;
 585                 this.pauseregen_finished += f;
 586         }
 587         this.damageforcescale = 2;
 588         this.death_time = 0;
 589         this.respawn_flags = 0;
 590         this.respawn_time = 0;
 591         this.stat_respawn_time = 0;
 592         this.scale = autocvar_sv_player_scale;
 593         this.fade_time = 0;
 594         this.pain_frame = 0;
 595         this.pain_finished = 0;
 596         this.pushltime = 0;
 597         setthink(this, func_null); // players have no think function
 598         this.nextthink = 0;
 599         this.dmg_team = 0;
 600         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 601
 602         this.deadflag = DEAD_NO;
 603
 604         this.angles = spot.angles;
 605         this.angles_z = 0; // never spawn tilted even if the spot says to
 606         if (IS_BOT_CLIENT(this))
 607                 this.v_angle = this.angles;
 608         this.fixangle = true; // turn this way immediately
 609         this.oldvelocity = this.velocity = '0 0 0';
 610         this.avelocity = '0 0 0';
 611         this.punchangle = '0 0 0';
 612         this.punchvector = '0 0 0';
 613
 614         this.strength_finished = 0;
 615         this.invincible_finished = 0;
 616         this.fire_endtime = -1;
 617         this.revive_progress = 0;
 618         this.revival_time = 0;
 619         this.air_finished = time + 12;
 620
 621         entity spawnevent = new_pure(spawnevent);
 622         spawnevent.owner = this;
 623         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 624
 625         // Cut off any still running player sounds.
 626         stopsound(this, CH_PLAYER_SINGLE);
 627
 628         this.model = "";
 629         FixPlayermodel(this);
 630         this.drawonlytoclient = NULL;
 631
 632         this.viewloc = NULL;
 633
 634         this.crouch = false;
 635         this.view_ofs = STAT(PL_VIEW_OFS, this);
 636         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 637         this.spawnorigin = spot.origin;
 638         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 639         // don't reset back to last position, even if new position is stuck in solid
 640         this.oldorigin = this.origin;
 641         this.lastteleporttime = time; // prevent insane speeds due to changing origin
 642         if(this.conveyor)
 643                 IL_REMOVE(g_conveyed, this);
 644         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 645         this.hud = HUD_NORMAL;
 646
 647         this.event_damage = PlayerDamage;
 648
 649         if(!this.bot_attack)
 650                 IL_PUSH(g_bot_targets, this);
 651         this.bot_attack = true;
 652         if(!this.monster_attack)
 653                 IL_PUSH(g_monster_targets, this);
 654         this.monster_attack = true;
 655         navigation_dynamicgoal_init(this, false);
 656
 657         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 658
 659         if (CS(this).killcount == FRAGS_SPECTATOR) {
 660                 PlayerScore_Clear(this);
 661                 CS(this).killcount = 0;
 662         }
 663
 664         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 665         {
 666                 .entity weaponentity = weaponentities[slot];
 667                 entity oldwep = this.(weaponentity);
 668                 CL_SpawnWeaponentity(this, weaponentity);
 669                 if(oldwep && oldwep.owner == this)
 670                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 671         }
 672         this.alpha = default_player_alpha;
 673         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 674         this.exteriorweaponentity.alpha = default_weapon_alpha;
 675
 676         this.speedrunning = false;
 677
 678         target_voicescript_clear(this);
 679
 680         // reset fields the weapons may use
 681         FOREACH(Weapons, true, {
 682                 it.wr_resetplayer(it, this);
 683                         // reload all reloadable weapons
 684                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 685                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 686                         {
 687                                 .entity weaponentity = weaponentities[slot];
 688                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 689                         }
 690                 }
 691         });
 692
 693         {
 694                 string s = spot.target;
 695                 spot.target = string_null;
 696                 SUB_UseTargets(spot, this, NULL);
 697                 spot.target = s;
 698         }
 699
 700         Unfreeze(this);
 701
 702         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 703
 704         if (autocvar_spawn_debug)
 705         {
 706                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 707                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 708         }
 709
 710         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 711         {
 712                 .entity weaponentity = weaponentities[slot];
 713                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 714                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 715                 else
 716                         this.(weaponentity).m_switchweapon = WEP_Null;
 717                 this.(weaponentity).m_weapon = WEP_Null;
 718                 this.(weaponentity).weaponname = "";
 719                 this.(weaponentity).m_switchingweapon = WEP_Null;
 720                 this.(weaponentity).cnt = -1;
 721         }
 722
 723         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 724
 725         if (!warmup_stage && !this.alivetime)
 726                 this.alivetime = time;
 727
 728         antilag_clear(this, CS(this));
 729 }
 730
 731 /** Called when a client spawns in the server */
 732 void PutClientInServer(entity this)
 733 {
 734         if (IS_BOT_CLIENT(this)) {
 735                 TRANSMUTE(Player, this);
 736         } else if (IS_REAL_CLIENT(this)) {
 737                 msg_entity = this;
 738                 WriteByte(MSG_ONE, SVC_SETVIEW);
 739                 WriteEntity(MSG_ONE, this);
 740         }
 741         if (game_stopped)
 742                 TRANSMUTE(Observer, this);
 743
 744         SetSpectatee(this, NULL);
 745
 746         // reset player keys
 747         if(PS(this))
 748                 PS(this).itemkeys = 0;
 749
 750         MUTATOR_CALLHOOK(PutClientInServer, this);
 751
 752         if (IS_OBSERVER(this)) {
 753                 PutObserverInServer(this);
 754         } else if (IS_PLAYER(this)) {
 755                 PutPlayerInServer(this);
 756         }
 757 }
 758
 759 void ClientInit_misc(entity this);
 760
 761 // TODO do we need all these fields, or should we stop autodetecting runtime
 762 // changes and just have a console command to update this?
 763 bool ClientInit_SendEntity(entity this, entity to, int sf)
 764 {
 765         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 766         return = true;
 767         msg_entity = to;
 768         // MSG_INIT replacement
 769         // TODO: make easier to use
 770         Registry_send_all();
 771         W_PROP_reload(MSG_ONE, to);
 772         ClientInit_misc(this);
 773         MUTATOR_CALLHOOK(Ent_Init);
 774 }
 775 void ClientInit_misc(entity this)
 776 {
 777         int channel = MSG_ONE;
 778         WriteHeader(channel, ENT_CLIENT_INIT);
 779         WriteByte(channel, g_nexball_meter_period * 32);
 780         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 781         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 782         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 783         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 784         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 785         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 786         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 787         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 788
 789         if(sv_foginterval && world.fog != "")
 790                 WriteString(channel, world.fog);
 791         else
 792                 WriteString(channel, "");
 793         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 794         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 795         WriteByte(channel, serverflags);
 796         WriteCoord(channel, autocvar_g_trueaim_minrange);
 797 }
 798
 799 void ClientInit_CheckUpdate(entity this)
 800 {
 801         this.nextthink = time;
 802         if(this.count != autocvar_g_balance_armor_blockpercent)
 803         {
 804                 this.count = autocvar_g_balance_armor_blockpercent;
 805                 this.SendFlags |= 1;
 806         }
 807         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 808         {
 809                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 810                 this.SendFlags |= 1;
 811         }
 812 }
 813
 814 void ClientInit_Spawn()
 815 {
 816         entity e = new_pure(clientinit);
 817         setthink(e, ClientInit_CheckUpdate);
 818         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 819
 820         ClientInit_CheckUpdate(e);
 821 }
 822
 823 /*
 824 =============
 825 SetNewParms
 826 =============
 827 */
 828 void SetNewParms ()
 829 {
 830         // initialize parms for a new player
 831         parm1 = -(86400 * 366);
 832
 833         MUTATOR_CALLHOOK(SetNewParms);
 834 }
 835
 836 /*
 837 =============
 838 SetChangeParms
 839 =============
 840 */
 841 void SetChangeParms (entity this)
 842 {
 843         // save parms for level change
 844         parm1 = CS(this).parm_idlesince - time;
 845
 846         MUTATOR_CALLHOOK(SetChangeParms);
 847 }
 848
 849 /*
 850 =============
 851 DecodeLevelParms
 852 =============
 853 */
 854 void DecodeLevelParms(entity this)
 855 {
 856         // load parms
 857         CS(this).parm_idlesince = parm1;
 858         if (CS(this).parm_idlesince == -(86400 * 366))
 859                 CS(this).parm_idlesince = time;
 860
 861         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 862         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 863
 864         MUTATOR_CALLHOOK(DecodeLevelParms);
 865 }
 866
 867 /*
 868 =============
 869 ClientKill
 870
 871 Called when a client types 'kill' in the console
 872 =============
 873 */
 874
 875 .float clientkill_nexttime;
 876 void ClientKill_Now_TeamChange(entity this)
 877 {
 878         if(this.killindicator_teamchange == -1)
 879         {
 880                 JoinBestTeam( this, false, true );
 881         }
 882         else if(this.killindicator_teamchange == -2)
 883         {
 884                 if(blockSpectators)
 885                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 886                 PutObserverInServer(this);
 887         }
 888         else
 889                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 890         this.killindicator_teamchange = 0;
 891 }
 892
 893 void ClientKill_Now(entity this)
 894 {
 895         if(this.vehicle)
 896         {
 897             vehicles_exit(this.vehicle, VHEF_RELEASE);
 898             if(!this.killindicator_teamchange)
 899             {
 900             this.vehicle_health = -1;
 901             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 902             }
 903         }
 904
 905         if(this.killindicator && !wasfreed(this.killindicator))
 906                 delete(this.killindicator);
 907
 908         this.killindicator = NULL;
 909
 910         if(this.killindicator_teamchange)
 911                 ClientKill_Now_TeamChange(this);
 912
 913         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 914         {
 915                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 916         }
 917
 918         // now I am sure the player IS dead
 919 }
 920 void KillIndicator_Think(entity this)
 921 {
 922         if (game_stopped)
 923         {
 924                 this.owner.killindicator = NULL;
 925                 delete(this);
 926                 return;
 927         }
 928
 929         if (this.owner.alpha < 0 && !this.owner.vehicle)
 930         {
 931                 this.owner.killindicator = NULL;
 932                 delete(this);
 933                 return;
 934         }
 935
 936         if(this.cnt <= 0)
 937         {
 938                 ClientKill_Now(this.owner);
 939                 return;
 940         }
 941     else if(this.health == 1) // health == 1 means that it's silent
 942     {
 943         this.nextthink = time + 1;
 944         this.cnt -= 1;
 945     }
 946         else
 947         {
 948                 if(this.cnt <= 10)
 949                         setmodel(this, MDL_NUM(this.cnt));
 950                 if(IS_REAL_CLIENT(this.owner))
 951                 {
 952                         if(this.cnt <= 10)
 953                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 954                 }
 955                 this.nextthink = time + 1;
 956                 this.cnt -= 1;
 957         }
 958 }
 959
 960 float clientkilltime;
 961 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 962 {
 963         float killtime;
 964         float starttime;
 965
 966         if (game_stopped)
 967                 return;
 968
 969         killtime = autocvar_g_balance_kill_delay;
 970
 971     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 972         return;
 973     killtime = M_ARGV(1, float);
 974
 975         this.killindicator_teamchange = targetteam;
 976
 977     if(!this.killindicator)
 978         {
 979                 if(!IS_DEAD(this))
 980                 {
 981                         killtime = max(killtime, this.clientkill_nexttime - time);
 982                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 983                 }
 984
 985                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 986                 {
 987                         ClientKill_Now(this);
 988                 }
 989                 else
 990                 {
 991                         starttime = max(time, clientkilltime);
 992
 993                         this.killindicator = spawn();
 994                         this.killindicator.owner = this;
 995                         this.killindicator.scale = 0.5;
 996                         setattachment(this.killindicator, this, "");
 997                         setorigin(this.killindicator, '0 0 52');
 998                         setthink(this.killindicator, KillIndicator_Think);
 999                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1000                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1001                         this.killindicator.cnt = ceil(killtime);
1002                         this.killindicator.count = bound(0, ceil(killtime), 10);
1003                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1004
1005                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1006                         {
1007                                 it.killindicator = spawn();
1008                                 it.killindicator.owner = it;
1009                                 it.killindicator.scale = 0.5;
1010                                 setattachment(it.killindicator, it, "");
1011                                 setorigin(it.killindicator, '0 0 52');
1012                                 setthink(it.killindicator, KillIndicator_Think);
1013                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1014                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1015                                 it.killindicator.cnt = ceil(killtime);
1016                         });
1017                         this.lip = 0;
1018                 }
1019         }
1020         if(this.killindicator)
1021         {
1022                 if(targetteam == 0) // just die
1023                 {
1024                         this.killindicator.colormod = '0 0 0';
1025                         if(IS_REAL_CLIENT(this))
1026                         if(this.killindicator.cnt > 0)
1027                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1028                 }
1029                 else if(targetteam == -1) // auto
1030                 {
1031                         this.killindicator.colormod = '0 1 0';
1032                         if(IS_REAL_CLIENT(this))
1033                         if(this.killindicator.cnt > 0)
1034                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1035                 }
1036                 else if(targetteam == -2) // spectate
1037                 {
1038                         this.killindicator.colormod = '0.5 0.5 0.5';
1039                         if(IS_REAL_CLIENT(this))
1040                         if(this.killindicator.cnt > 0)
1041                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1042                 }
1043                 else
1044                 {
1045                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1046                         if(IS_REAL_CLIENT(this))
1047                         if(this.killindicator.cnt > 0)
1048                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1049                 }
1050         }
1051
1052 }
1053
1054 void ClientKill (entity this)
1055 {
1056         if(game_stopped) return;
1057         if(this.player_blocked) return;
1058         if(STAT(FROZEN, this)) return;
1059
1060         ClientKill_TeamChange(this, 0);
1061 }
1062
1063 void FixClientCvars(entity e)
1064 {
1065         // send prediction settings to the client
1066         stuffcmd(e, "\nin_bindmap 0 0\n");
1067         if(autocvar_g_antilag == 3) // client side hitscan
1068                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1069         if(autocvar_sv_gentle)
1070                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1071
1072         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1073         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1074
1075         MUTATOR_CALLHOOK(FixClientCvars, e);
1076 }
1077
1078 bool findinlist_abbrev(string tofind, string list)
1079 {
1080         if(list == "" || tofind == "")
1081                 return false; // empty list or search, just return
1082
1083         // this function allows abbreviated strings!
1084         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1085         {
1086                 return true;
1087         });
1088
1089         return false;
1090 }
1091
1092 bool PlayerInIPList(entity p, string iplist)
1093 {
1094         // some safety checks (never allow local?)
1095         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1096                 return false;
1097
1098         return findinlist_abbrev(p.netaddress, iplist);
1099 }
1100
1101 bool PlayerInIDList(entity p, string idlist)
1102 {
1103         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1104         if(!p.crypto_idfp)
1105                 return false;
1106
1107         return findinlist_abbrev(p.crypto_idfp, idlist);
1108 }
1109
1110 bool PlayerInList(entity player, string list)
1111 {
1112         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1113 }
1114
1115 #ifdef DP_EXT_PRECONNECT
1116 /*
1117 =============
1118 ClientPreConnect
1119
1120 Called once (not at each match start) when a client begins a connection to the server
1121 =============
1122 */
1123 void ClientPreConnect(entity this)
1124 {
1125         if(autocvar_sv_eventlog)
1126         {
1127                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1128                         this.playerid,
1129                         etof(this),
1130                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1131                 ));
1132         }
1133 }
1134 #endif
1135
1136 /**
1137 =============
1138 ClientConnect
1139
1140 Called when a client connects to the server
1141 =============
1142 */
1143 void ClientConnect(entity this)
1144 {
1145         if (Ban_MaybeEnforceBanOnce(this)) return;
1146         assert(!IS_CLIENT(this), return);
1147         this.flags |= FL_CLIENT;
1148         assert(player_count >= 0, player_count = 0);
1149
1150 #ifdef WATERMARK
1151         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1152 #endif
1153         TRANSMUTE(Client, this);
1154         CS(this).version_nagtime = time + 10 + random() * 10;
1155
1156         // identify the right forced team
1157         if (autocvar_g_campaign)
1158         {
1159                 if (IS_REAL_CLIENT(this)) // only players, not bots
1160                 {
1161                         switch (autocvar_g_campaign_forceteam)
1162                         {
1163                                 case 1: this.team_forced = NUM_TEAM_1; break;
1164                                 case 2: this.team_forced = NUM_TEAM_2; break;
1165                                 case 3: this.team_forced = NUM_TEAM_3; break;
1166                                 case 4: this.team_forced = NUM_TEAM_4; break;
1167                                 default: this.team_forced = 0;
1168                         }
1169                 }
1170         }
1171         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1172         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1173         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1174         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1175         else switch (autocvar_g_forced_team_otherwise)
1176         {
1177                 default: this.team_forced = 0; break;
1178                 case "red": this.team_forced = NUM_TEAM_1; break;
1179                 case "blue": this.team_forced = NUM_TEAM_2; break;
1180                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1181                 case "pink": this.team_forced = NUM_TEAM_4; break;
1182                 case "spectate":
1183                 case "spectator":
1184                         this.team_forced = -1;
1185                         break;
1186         }
1187         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1188
1189     {
1190         int id = this.playerid;
1191         this.playerid = 0; // silent
1192             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1193             this.playerid = id;
1194     }
1195
1196         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1197                 TRANSMUTE(Observer, this);
1198         } else {
1199                 if (!teamplay || autocvar_g_balance_teams) {
1200                         TRANSMUTE(Player, this);
1201                         campaign_bots_may_start = true;
1202                 } else {
1203                         TRANSMUTE(Observer, this); // do it anyway
1204                 }
1205         }
1206
1207         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1208
1209         // always track bots, don't ask for cl_allow_uidtracking
1210         if (IS_BOT_CLIENT(this))
1211                 PlayerStats_GameReport_AddPlayer(this);
1212         else
1213                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1214
1215         if (autocvar_sv_eventlog)
1216                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1217
1218         LogTeamchange(this.playerid, this.team, 1);
1219
1220         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1221
1222         if(teamplay && IS_PLAYER(this))
1223                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1224         else
1225                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1226
1227         stuffcmd(this, clientstuff, "\n");
1228         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1229
1230         FixClientCvars(this);
1231
1232         // get version info from player
1233         stuffcmd(this, "cmd clientversion $gameversion\n");
1234
1235         // notify about available teams
1236         if (teamplay)
1237         {
1238                 CheckAllowedTeams(this);
1239                 int t = 0;
1240                 if (c1 >= 0) t |= BIT(0);
1241                 if (c2 >= 0) t |= BIT(1);
1242                 if (c3 >= 0) t |= BIT(2);
1243                 if (c4 >= 0) t |= BIT(3);
1244                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1245         }
1246         else
1247         {
1248                 stuffcmd(this, "set _teams_available 0\n");
1249         }
1250
1251         bot_relinkplayerlist();
1252
1253         CS(this).spectatortime = time;
1254         if (blockSpectators)
1255         {
1256                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1257         }
1258
1259         CS(this).jointime = time;
1260
1261         if (IS_REAL_CLIENT(this))
1262         {
1263                 if (g_weaponarena_weapons == WEPSET(TUBA))
1264                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1265         }
1266
1267         if (!sv_foginterval && world.fog != "")
1268                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1269
1270         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1271                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1272                         send_CSQC_teamnagger();
1273
1274         CSQCMODEL_AUTOINIT(this);
1275
1276         CS(this).model_randomizer = random();
1277
1278         if (IS_REAL_CLIENT(this))
1279                 sv_notice_join(this);
1280
1281         // update physics stats (players can spawn before physics runs)
1282         Physics_UpdateStats(this);
1283
1284         IL_EACH(g_initforplayer, it.init_for_player, {
1285                 it.init_for_player(it, this);
1286         });
1287
1288         Handicap_Initialize(this);
1289
1290         MUTATOR_CALLHOOK(ClientConnect, this);
1291
1292         if (IS_REAL_CLIENT(this))
1293         {
1294                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1295                 {
1296                         CS(this).motd_actived_time = -1;
1297                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1298                 }
1299         }
1300 }
1301 /*
1302 =============
1303 ClientDisconnect
1304
1305 Called when a client disconnects from the server
1306 =============
1307 */
1308 .entity chatbubbleentity;
1309 void ReadyCount();
1310 void ClientDisconnect(entity this)
1311 {
1312         assert(IS_CLIENT(this), return);
1313
1314         PlayerStats_GameReport_FinalizePlayer(this);
1315         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1316         if (CS(this).active_minigame) part_minigame(this);
1317         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1318
1319         if (autocvar_sv_eventlog)
1320                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1321
1322         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1323
1324         if(IS_SPEC(this))
1325                 SetSpectatee(this, NULL);
1326
1327     MUTATOR_CALLHOOK(ClientDisconnect, this);
1328
1329         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1330         ClientState_detach(this);
1331
1332         Portal_ClearAll(this);
1333
1334         Unfreeze(this);
1335
1336         RemoveGrapplingHooks(this);
1337
1338         // Here, everything has been done that requires this player to be a client.
1339
1340         this.flags &= ~FL_CLIENT;
1341
1342         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1343         if (this.killindicator) delete(this.killindicator);
1344
1345         WaypointSprite_PlayerGone(this);
1346
1347         bot_relinkplayerlist();
1348
1349         if (this.clientstatus) strunzone(this.clientstatus);
1350         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1351         if (this.personal) delete(this.personal);
1352
1353         this.playerid = 0;
1354         ReadyCount();
1355         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1356
1357         ONREMOVE(this);
1358 }
1359
1360 void ChatBubbleThink(entity this)
1361 {
1362         this.nextthink = time;
1363         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1364         {
1365                 if(this.owner) // but why can that ever be NULL?
1366                         this.owner.chatbubbleentity = NULL;
1367                 delete(this);
1368                 return;
1369         }
1370
1371         this.mdl = "";
1372
1373         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1374         {
1375                 if ( CS(this.owner).active_minigame )
1376                         this.mdl = "models/sprites/minigame_busy.iqm";
1377                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1378                         this.mdl = "models/misc/chatbubble.spr";
1379         }
1380
1381         if ( this.model != this.mdl )
1382                 _setmodel(this, this.mdl);
1383
1384 }
1385
1386 void UpdateChatBubble(entity this)
1387 {
1388         if (this.alpha < 0)
1389                 return;
1390         // spawn a chatbubble entity if needed
1391         if (!this.chatbubbleentity)
1392         {
1393                 this.chatbubbleentity = new(chatbubbleentity);
1394                 this.chatbubbleentity.owner = this;
1395                 this.chatbubbleentity.exteriormodeltoclient = this;
1396                 setthink(this.chatbubbleentity, ChatBubbleThink);
1397                 this.chatbubbleentity.nextthink = time;
1398                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1399                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1400                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1401                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1402                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1403                 //this.chatbubbleentity.model = "";
1404                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1405         }
1406 }
1407
1408
1409 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1410 // added to the model skins
1411 /*void UpdateColorModHack()
1412 {
1413         float c;
1414         c = this.clientcolors & 15;
1415         // LordHavoc: only bothering to support white, green, red, yellow, blue
1416              if (!teamplay) this.colormod = '0 0 0';
1417         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1418         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1419         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1420         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1421         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1422         else this.colormod = '1 1 1';
1423 }*/
1424
1425 void respawn(entity this)
1426 {
1427         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1428         {
1429                 this.solid = SOLID_NOT;
1430                 this.takedamage = DAMAGE_NO;
1431                 set_movetype(this, MOVETYPE_FLY);
1432                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1433                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1434                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1435                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1436                 if(autocvar_g_respawn_ghosts_maxtime)
1437                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1438         }
1439
1440         CopyBody(this, 1);
1441
1442         this.effects |= EF_NODRAW; // prevent another CopyBody
1443         PutClientInServer(this);
1444 }
1445
1446 void play_countdown(entity this, float finished, Sound samp)
1447 {
1448     TC(Sound, samp);
1449         if(IS_REAL_CLIENT(this))
1450                 if(floor(finished - time - frametime) != floor(finished - time))
1451                         if(finished - time < 6)
1452                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1453 }
1454
1455 void player_powerups(entity this)
1456 {
1457         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1458         int items_prev = this.items;
1459
1460         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1461                 this.modelflags |= MF_ROCKET;
1462         else
1463                 this.modelflags &= ~MF_ROCKET;
1464
1465         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1466
1467         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1468                 return;
1469
1470         Fire_ApplyDamage(this);
1471         Fire_ApplyEffect(this);
1472
1473         if (!g_instagib)
1474         {
1475                 if (this.items & ITEM_Strength.m_itemid)
1476                 {
1477                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1478                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1479                         if (time > this.strength_finished)
1480                         {
1481                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1482                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1483                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1484                         }
1485                 }
1486                 else
1487                 {
1488                         if (time < this.strength_finished)
1489                         {
1490                                 this.items = this.items | ITEM_Strength.m_itemid;
1491                                 if(!g_cts)
1492                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1493                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1494                         }
1495                 }
1496                 if (this.items & ITEM_Shield.m_itemid)
1497                 {
1498                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1499                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1500                         if (time > this.invincible_finished)
1501                         {
1502                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1503                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1504                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1505                         }
1506                 }
1507                 else
1508                 {
1509                         if (time < this.invincible_finished)
1510                         {
1511                                 this.items = this.items | ITEM_Shield.m_itemid;
1512                                 if(!g_cts)
1513                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1514                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1515                         }
1516                 }
1517                 if (this.items & IT_SUPERWEAPON)
1518                 {
1519                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1520                         {
1521                                 this.superweapons_finished = 0;
1522                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1523                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1524                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1525                         }
1526                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1527                         {
1528                                 // don't let them run out
1529                         }
1530                         else
1531                         {
1532                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1533                                 if (time > this.superweapons_finished)
1534                                 {
1535                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1536                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1537                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1538                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1539                                 }
1540                         }
1541                 }
1542                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1543                 {
1544                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1545                         {
1546                                 this.items = this.items | IT_SUPERWEAPON;
1547                                 if(!g_cts)
1548                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1549                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1550                         }
1551                         else
1552                         {
1553                                 this.superweapons_finished = 0;
1554                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1555                         }
1556                 }
1557                 else
1558                 {
1559                         this.superweapons_finished = 0;
1560                 }
1561         }
1562
1563         if(autocvar_g_nodepthtestplayers)
1564                 this.effects = this.effects | EF_NODEPTHTEST;
1565
1566         if(autocvar_g_fullbrightplayers)
1567                 this.effects = this.effects | EF_FULLBRIGHT;
1568
1569         if (time >= game_starttime)
1570         if (time < this.spawnshieldtime)
1571                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1572
1573         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1574 }
1575
1576 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1577 {
1578         if(current > stable)
1579                 return current;
1580         else if(current > stable - 0.25) // when close enough, "snap"
1581                 return stable;
1582         else
1583                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1584 }
1585
1586 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1587 {
1588         if(current < stable)
1589                 return current;
1590         else if(current < stable + 0.25) // when close enough, "snap"
1591                 return stable;
1592         else
1593                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1594 }
1595
1596 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1597 {
1598         if(current > rotstable)
1599         {
1600                 if(rotframetime > 0)
1601                 {
1602                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1603                         current = max(rotstable, current - rotlinear * rotframetime);
1604                 }
1605         }
1606         else if(current < regenstable)
1607         {
1608                 if(regenframetime > 0)
1609                 {
1610                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1611                         current = min(regenstable, current + regenlinear * regenframetime);
1612                 }
1613         }
1614
1615         if(current > limit)
1616                 current = limit;
1617
1618         return current;
1619 }
1620
1621 void player_regen(entity this)
1622 {
1623         float max_mod, regen_mod, rot_mod, limit_mod;
1624         max_mod = regen_mod = rot_mod = limit_mod = 1;
1625
1626         float regen_health = autocvar_g_balance_health_regen;
1627         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1628         float regen_health_rot = autocvar_g_balance_health_rot;
1629         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1630         float regen_health_stable = autocvar_g_balance_health_regenstable;
1631         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1632         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1633                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1634         max_mod = M_ARGV(1, float);
1635         regen_mod = M_ARGV(2, float);
1636         rot_mod = M_ARGV(3, float);
1637         limit_mod = M_ARGV(4, float);
1638         regen_health = M_ARGV(5, float);
1639         regen_health_linear = M_ARGV(6, float);
1640         regen_health_rot = M_ARGV(7, float);
1641         regen_health_rotlinear = M_ARGV(8, float);
1642         regen_health_stable = M_ARGV(9, float);
1643         regen_health_rotstable = M_ARGV(10, float);
1644
1645         if(!mutator_returnvalue)
1646         if(!STAT(FROZEN, this))
1647         {
1648                 float mina, maxa, limith, limita;
1649                 maxa = autocvar_g_balance_armor_rotstable;
1650                 mina = autocvar_g_balance_armor_regenstable;
1651                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1652                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1653
1654                 regen_health_rotstable = regen_health_rotstable * max_mod;
1655                 regen_health_stable = regen_health_stable * max_mod;
1656                 limith = limith * limit_mod;
1657                 limita = limita * limit_mod;
1658
1659                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1660                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1661         }
1662
1663         // if player rotted to death...  die!
1664         // check this outside above checks, as player may still be able to rot to death
1665         if(this.health < 1)
1666         {
1667                 if(this.vehicle)
1668                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1669                 if(this.event_damage)
1670                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1671         }
1672
1673         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1674         {
1675                 float minf, maxf, limitf;
1676
1677                 maxf = autocvar_g_balance_fuel_rotstable;
1678                 minf = autocvar_g_balance_fuel_regenstable;
1679                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1680
1681                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1682         }
1683         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1684         // TODO: Remove this hack when all code uses GivePlayerHealth and
1685         // GivePlayerArmor.
1686         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1687         {
1688                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1689         }
1690         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1691         {
1692                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1693         }
1694         // End hack.
1695 }
1696
1697 bool zoomstate_set;
1698 void SetZoomState(entity this, float newzoom)
1699 {
1700         if(newzoom != CS(this).zoomstate)
1701         {
1702                 CS(this).zoomstate = newzoom;
1703                 ClientData_Touch(this);
1704         }
1705         zoomstate_set = true;
1706 }
1707
1708 void GetPressedKeys(entity this)
1709 {
1710         MUTATOR_CALLHOOK(GetPressedKeys, this);
1711         int keys = STAT(PRESSED_KEYS, this);
1712         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1713         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1714         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1715         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1716
1717         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1718         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1719         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1720         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1721         CS(this).pressedkeys = keys; // store for other users
1722
1723         STAT(PRESSED_KEYS, this) = keys;
1724 }
1725
1726 /*
1727 ======================
1728 spectate mode routines
1729 ======================
1730 */
1731
1732 void SpectateCopy(entity this, entity spectatee)
1733 {
1734     TC(Client, this); TC(Client, spectatee);
1735
1736         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1737         PS(this) = PS(spectatee);
1738         this.armortype = spectatee.armortype;
1739         this.armorvalue = spectatee.armorvalue;
1740         this.ammo_cells = spectatee.ammo_cells;
1741         this.ammo_plasma = spectatee.ammo_plasma;
1742         this.ammo_shells = spectatee.ammo_shells;
1743         this.ammo_nails = spectatee.ammo_nails;
1744         this.ammo_rockets = spectatee.ammo_rockets;
1745         this.ammo_fuel = spectatee.ammo_fuel;
1746         this.clip_load = spectatee.clip_load;
1747         this.clip_size = spectatee.clip_size;
1748         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1749         this.health = spectatee.health;
1750         CS(this).impulse = 0;
1751         this.items = spectatee.items;
1752         this.last_pickup = spectatee.last_pickup;
1753         this.hit_time = spectatee.hit_time;
1754         this.strength_finished = spectatee.strength_finished;
1755         this.invincible_finished = spectatee.invincible_finished;
1756         this.superweapons_finished = spectatee.superweapons_finished;
1757         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1758         this.weapons = spectatee.weapons;
1759         this.vortex_charge = spectatee.vortex_charge;
1760         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1761         this.okvortex_charge = spectatee.okvortex_charge;
1762         this.okvortex_chargepool_ammo = spectatee.okvortex_chargepool_ammo;
1763         this.hagar_load = spectatee.hagar_load;
1764         this.arc_heat_percent = spectatee.arc_heat_percent;
1765         this.minelayer_mines = spectatee.minelayer_mines;
1766         this.punchangle = spectatee.punchangle;
1767         this.view_ofs = spectatee.view_ofs;
1768         this.velocity = spectatee.velocity;
1769         this.dmg_take = spectatee.dmg_take;
1770         this.dmg_save = spectatee.dmg_save;
1771         this.dmg_inflictor = spectatee.dmg_inflictor;
1772         this.v_angle = spectatee.v_angle;
1773         this.angles = spectatee.v_angle;
1774         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1775         this.revive_progress = spectatee.revive_progress;
1776         this.viewloc = spectatee.viewloc;
1777         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1778                 this.fixangle = true;
1779         setorigin(this, spectatee.origin);
1780         setsize(this, spectatee.mins, spectatee.maxs);
1781         SetZoomState(this, CS(spectatee).zoomstate);
1782
1783         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1784         {
1785                 .entity weaponentity = weaponentities[slot];
1786                 this.(weaponentity) = spectatee.(weaponentity);
1787         }
1788
1789         for(int slot = 0; slot < MAX_AXH; ++slot)
1790         {
1791                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1792         }
1793
1794     anticheat_spectatecopy(this, spectatee);
1795         this.hud = spectatee.hud;
1796         if(spectatee.vehicle)
1797     {
1798         this.angles = spectatee.v_angle;
1799
1800         //this.fixangle = false;
1801         //this.velocity = spectatee.vehicle.velocity;
1802         this.vehicle_health = spectatee.vehicle_health;
1803         this.vehicle_shield = spectatee.vehicle_shield;
1804         this.vehicle_energy = spectatee.vehicle_energy;
1805         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1806         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1807         this.vehicle_reload1 = spectatee.vehicle_reload1;
1808         this.vehicle_reload2 = spectatee.vehicle_reload2;
1809
1810         //msg_entity = this;
1811
1812        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1813             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1814            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1815            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1816
1817         //WriteByte (MSG_ONE, SVC_SETVIEW);
1818         //    WriteEntity(MSG_ONE, this);
1819         //makevectors(spectatee.v_angle);
1820         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1821     }
1822 }
1823
1824 bool SpectateUpdate(entity this)
1825 {
1826         if(!this.enemy)
1827                 return false;
1828
1829         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1830         {
1831                 SetSpectatee(this, NULL);
1832                 return false;
1833         }
1834
1835         SpectateCopy(this, this.enemy);
1836
1837         return true;
1838 }
1839
1840 bool SpectateSet(entity this)
1841 {
1842         if(!IS_PLAYER(this.enemy))
1843                 return false;
1844
1845         ClientData_Touch(this.enemy);
1846
1847         msg_entity = this;
1848         WriteByte(MSG_ONE, SVC_SETVIEW);
1849         WriteEntity(MSG_ONE, this.enemy);
1850         set_movetype(this, MOVETYPE_NONE);
1851         accuracy_resend(this);
1852
1853         if(!SpectateUpdate(this))
1854                 PutObserverInServer(this);
1855
1856         return true;
1857 }
1858
1859 void SetSpectatee_status(entity this, int spectatee_num)
1860 {
1861         int oldspectatee_status = CS(this).spectatee_status;
1862         CS(this).spectatee_status = spectatee_num;
1863
1864         if (CS(this).spectatee_status != oldspectatee_status)
1865         {
1866                 ClientData_Touch(this);
1867                 if (g_race || g_cts) race_InitSpectator();
1868         }
1869 }
1870
1871 void SetSpectatee(entity this, entity spectatee)
1872 {
1873         if(IS_BOT_CLIENT(this))
1874                 return; // bots abuse .enemy, this code is useless to them
1875
1876         entity old_spectatee = this.enemy;
1877
1878         this.enemy = spectatee;
1879
1880         // WEAPONTODO
1881         // these are required to fix the spectator bug with arc
1882         if(old_spectatee)
1883         {
1884                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1885                 {
1886                         .entity weaponentity = weaponentities[slot];
1887                         if(old_spectatee.(weaponentity).arc_beam)
1888                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1889                 }
1890         }
1891         if(this.enemy)
1892         {
1893                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1894                 {
1895                         .entity weaponentity = weaponentities[slot];
1896                         if(this.enemy.(weaponentity).arc_beam)
1897                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1898                 }
1899         }
1900
1901         if (this.enemy)
1902                 SetSpectatee_status(this, etof(this.enemy));
1903
1904         // needed to update spectator list
1905         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1906 }
1907
1908 bool Spectate(entity this, entity pl)
1909 {
1910         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1911                 return false;
1912         pl = M_ARGV(1, entity);
1913
1914         SetSpectatee(this, pl);
1915         return SpectateSet(this);
1916 }
1917
1918 bool SpectateNext(entity this)
1919 {
1920         entity ent = find(this.enemy, classname, STR_PLAYER);
1921
1922         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1923                 ent = M_ARGV(1, entity);
1924         else if (!ent)
1925                 ent = find(ent, classname, STR_PLAYER);
1926
1927         if(ent) { SetSpectatee(this, ent); }
1928
1929         return SpectateSet(this);
1930 }
1931
1932 bool SpectatePrev(entity this)
1933 {
1934         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1935         entity ent = findchain(classname, STR_PLAYER);
1936         if (!ent) // no player
1937                 return false;
1938
1939         entity first = ent;
1940         // skip players until current spectated player
1941         if(this.enemy)
1942         while(ent && ent != this.enemy)
1943                 ent = ent.chain;
1944
1945         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1946         {
1947                 case MUT_SPECPREV_FOUND:
1948                     ent = M_ARGV(1, entity);
1949                     break;
1950                 case MUT_SPECPREV_RETURN:
1951                     return true;
1952                 case MUT_SPECPREV_CONTINUE:
1953                 default:
1954                 {
1955                         if(ent.chain)
1956                                 ent = ent.chain;
1957                         else
1958                                 ent = first;
1959                         break;
1960                 }
1961         }
1962
1963         SetSpectatee(this, ent);
1964         return SpectateSet(this);
1965 }
1966
1967 /*
1968 =============
1969 ShowRespawnCountdown()
1970
1971 Update a respawn countdown display.
1972 =============
1973 */
1974 void ShowRespawnCountdown(entity this)
1975 {
1976         float number;
1977         if(!IS_DEAD(this)) // just respawned?
1978                 return;
1979         else
1980         {
1981                 number = ceil(this.respawn_time - time);
1982                 if(number <= 0)
1983                         return;
1984                 if(number <= this.respawn_countdown)
1985                 {
1986                         this.respawn_countdown = number - 1;
1987                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1988                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1989                 }
1990         }
1991 }
1992
1993 .bool team_selected;
1994 bool ShowTeamSelection(entity this)
1995 {
1996         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1997                 return false;
1998         stuffcmd(this, "menu_showteamselect\n");
1999         return true;
2000 }
2001 void Join(entity this)
2002 {
2003         TRANSMUTE(Player, this);
2004
2005         if(!this.team_selected)
2006         if(autocvar_g_campaign || autocvar_g_balance_teams)
2007                 JoinBestTeam(this, false, true);
2008
2009         if(autocvar_g_campaign)
2010                 campaign_bots_may_start = true;
2011
2012         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2013
2014         PutClientInServer(this);
2015
2016         if(IS_PLAYER(this))
2017         if(teamplay && this.team != -1)
2018                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2019         else
2020                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2021         this.team_selected = false;
2022 }
2023
2024 /**
2025  * Determines whether the player is allowed to join. This depends on cvar
2026  * g_maxplayers, if it isn't used this function always return true, otherwise
2027  * it checks whether the number of currently playing players exceeds g_maxplayers.
2028  * @return int number of free slots for players, 0 if none
2029  */
2030 int nJoinAllowed(entity this, entity ignore)
2031 {
2032         if(!ignore)
2033         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2034         // so report 0 free slots if restricted
2035         {
2036                 if(autocvar_g_forced_team_otherwise == "spectate")
2037                         return 0;
2038                 if(autocvar_g_forced_team_otherwise == "spectator")
2039                         return 0;
2040         }
2041
2042         if(this && this.team_forced < 0)
2043                 return 0; // forced spectators can never join
2044
2045         // TODO simplify this
2046         int totalClients = 0;
2047         int currentlyPlaying = 0;
2048         FOREACH_CLIENT(true, {
2049                 if(it != ignore)
2050                         ++totalClients;
2051                 if(IS_REAL_CLIENT(it))
2052                 if(IS_PLAYER(it) || it.caplayer)
2053                         ++currentlyPlaying;
2054         });
2055
2056         float free_slots = 0;
2057         if (!autocvar_g_maxplayers)
2058                 free_slots = maxclients - totalClients;
2059         else if(currentlyPlaying < autocvar_g_maxplayers)
2060                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2061
2062         static float join_prevent_msg_time = 0;
2063         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2064         {
2065                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2066                 join_prevent_msg_time = time + 3;
2067         }
2068
2069         return free_slots;
2070 }
2071
2072 /**
2073  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2074  * g_maxplayers_spectator_blocktime seconds
2075  */
2076 void checkSpectatorBlock(entity this)
2077 {
2078         if(IS_SPEC(this) || IS_OBSERVER(this))
2079         if(!this.caplayer)
2080         if(IS_REAL_CLIENT(this))
2081         {
2082                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2083                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2084                         dropclient(this);
2085                 }
2086         }
2087 }
2088
2089 void PrintWelcomeMessage(entity this)
2090 {
2091         if(CS(this).motd_actived_time == 0)
2092         {
2093                 if (autocvar_g_campaign) {
2094                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2095                                 CS(this).motd_actived_time = time;
2096                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2097                         }
2098                 } else {
2099                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2100                                 CS(this).motd_actived_time = time;
2101                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2102                         }
2103                 }
2104         }
2105         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2106         {
2107                 if (autocvar_g_campaign) {
2108                         if (PHYS_INPUT_BUTTON_INFO(this))
2109                                 CS(this).motd_actived_time = time;
2110                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2111                                 CS(this).motd_actived_time = 0;
2112                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2113                         }
2114                 } else {
2115                         if (PHYS_INPUT_BUTTON_INFO(this))
2116                                 CS(this).motd_actived_time = time;
2117                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2118                                 CS(this).motd_actived_time = 0;
2119                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2120                         }
2121                 }
2122         }
2123         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2124         {
2125                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2126                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2127                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2128                 {
2129                         // instanctly hide MOTD
2130                         CS(this).motd_actived_time = 0;
2131                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2132                 }
2133         }
2134 }
2135
2136 bool joinAllowed(entity this)
2137 {
2138         if (CS(this).version_mismatch) return false;
2139         if (!nJoinAllowed(this, this)) return false;
2140         if (teamplay && lockteams) return false;
2141         if (ShowTeamSelection(this)) return false;
2142         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2143         return true;
2144 }
2145
2146 .int items_added;
2147 bool PlayerThink(entity this)
2148 {
2149         if (game_stopped || intermission_running) {
2150                 this.modelflags &= ~MF_ROCKET;
2151                 if(intermission_running)
2152                         IntermissionThink(this);
2153                 return false;
2154         }
2155
2156         if (timeout_status == TIMEOUT_ACTIVE) {
2157         // don't allow the player to turn around while game is paused
2158                 // FIXME turn this into CSQC stuff
2159                 this.v_angle = this.lastV_angle;
2160                 this.angles = this.lastV_angle;
2161                 this.fixangle = true;
2162         }
2163
2164         if (frametime) player_powerups(this);
2165
2166         if (IS_DEAD(this)) {
2167                 if (this.personal && g_race_qualifying) {
2168                         if (time > this.respawn_time) {
2169                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2170                                 respawn(this);
2171                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2172                         }
2173                 } else {
2174                         if (frametime) player_anim(this);
2175
2176                         if (this.respawn_flags & RESPAWN_DENY)
2177                         {
2178                                 STAT(RESPAWN_TIME, this) = 0;
2179                                 return false;
2180                         }
2181
2182                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2183
2184                         switch(this.deadflag)
2185                         {
2186                                 case DEAD_DYING:
2187                                 {
2188                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2189                                                 this.deadflag = DEAD_RESPAWNING;
2190                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2191                                                 this.deadflag = DEAD_DEAD;
2192                                         break;
2193                                 }
2194                                 case DEAD_DEAD:
2195                                 {
2196                                         if (button_pressed)
2197                                                 this.deadflag = DEAD_RESPAWNABLE;
2198                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2199                                                 this.deadflag = DEAD_RESPAWNING;
2200                                         break;
2201                                 }
2202                                 case DEAD_RESPAWNABLE:
2203                                 {
2204                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2205                                                 this.deadflag = DEAD_RESPAWNING;
2206                                         break;
2207                                 }
2208                                 case DEAD_RESPAWNING:
2209                                 {
2210                                         if (time > this.respawn_time)
2211                                         {
2212                                                 this.respawn_time = time + 1; // only retry once a second
2213                                                 this.respawn_time_max = this.respawn_time;
2214                                                 respawn(this);
2215                                         }
2216                                         break;
2217                                 }
2218                         }
2219
2220                         ShowRespawnCountdown(this);
2221
2222                         if (this.respawn_flags & RESPAWN_SILENT)
2223                                 STAT(RESPAWN_TIME, this) = 0;
2224                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2225                         {
2226                                 if (time < this.respawn_time)
2227                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2228                                 else if (this.deadflag != DEAD_RESPAWNING)
2229                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2230                         }
2231                         else
2232                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2233                 }
2234
2235                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2236                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2237                         STAT(RESPAWN_TIME, this) *= -1;
2238
2239                 return false;
2240         }
2241
2242         bool have_hook = false;
2243         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2244         {
2245                 .entity weaponentity = weaponentities[slot];
2246                 if(this.(weaponentity).hook.state)
2247                 {
2248                         have_hook = true;
2249                         break;
2250                 }
2251         }
2252         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2253         if (have_hook) {
2254                 do_crouch = false;
2255         } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2256                 do_crouch = false;
2257         } else if (this.vehicle) {
2258                 do_crouch = false;
2259         } else if (STAT(FROZEN, this)) {
2260                 do_crouch = false;
2261     }
2262
2263         if (do_crouch) {
2264                 if (!this.crouch) {
2265                         this.crouch = true;
2266                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2267                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2268                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2269                 }
2270         } else if (this.crouch) {
2271         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2272         if (!trace_startsolid) {
2273             this.crouch = false;
2274             this.view_ofs = STAT(PL_VIEW_OFS, this);
2275             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2276         }
2277         }
2278
2279         FixPlayermodel(this);
2280
2281         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2282         //if(frametime)
2283         {
2284                 this.items &= ~this.items_added;
2285
2286                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2287                 {
2288                         .entity weaponentity = weaponentities[slot];
2289                         W_WeaponFrame(this, weaponentity);
2290
2291                         if(slot == 0)
2292                         {
2293                                 this.clip_load = this.(weaponentity).clip_load;
2294                                 this.clip_size = this.(weaponentity).clip_size;
2295                         }
2296                 }
2297
2298                 this.items_added = 0;
2299                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2300             this.items_added |= IT_FUEL;
2301
2302                 this.items |= this.items_added;
2303         }
2304
2305         player_regen(this);
2306
2307         // WEAPONTODO: Add a weapon request for this
2308         // rot vortex charge to the charge limit
2309         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2310         {
2311                 .entity weaponentity = weaponentities[slot];
2312                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2313                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2314         }
2315
2316         if (frametime) player_anim(this);
2317
2318         // secret status
2319         secrets_setstatus(this);
2320
2321         // monsters status
2322         monsters_setstatus(this);
2323
2324         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2325
2326         return true;
2327 }
2328
2329 void ObserverThink(entity this)
2330 {
2331         if ( CS(this).impulse )
2332         {
2333                 MinigameImpulse(this, CS(this).impulse);
2334                 CS(this).impulse = 0;
2335         }
2336
2337         if (this.flags & FL_JUMPRELEASED) {
2338                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2339                         this.flags &= ~FL_JUMPRELEASED;
2340                         this.flags |= FL_SPAWNING;
2341                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2342                         this.flags &= ~FL_JUMPRELEASED;
2343                         if(SpectateNext(this)) {
2344                                 TRANSMUTE(Spectator, this);
2345                         }
2346                 } else {
2347                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2348                         set_movetype(this, preferred_movetype);
2349                 }
2350         } else {
2351                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2352                         this.flags |= FL_JUMPRELEASED;
2353                         if(this.flags & FL_SPAWNING)
2354                         {
2355                                 this.flags &= ~FL_SPAWNING;
2356                                 Join(this);
2357                                 return;
2358                         }
2359                 }
2360         }
2361 }
2362
2363 void SpectatorThink(entity this)
2364 {
2365         if ( CS(this).impulse )
2366         {
2367                 if(MinigameImpulse(this, CS(this).impulse))
2368                         CS(this).impulse = 0;
2369
2370                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2371                 {
2372                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2373                         CS(this).impulse = 0;
2374                         return;
2375                 }
2376         }
2377
2378         if (this.flags & FL_JUMPRELEASED) {
2379                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2380                         this.flags &= ~FL_JUMPRELEASED;
2381                         this.flags |= FL_SPAWNING;
2382                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2383                         this.flags &= ~FL_JUMPRELEASED;
2384                         if(SpectateNext(this)) {
2385                                 TRANSMUTE(Spectator, this);
2386                         } else {
2387                                 TRANSMUTE(Observer, this);
2388                                 PutClientInServer(this);
2389                         }
2390                         CS(this).impulse = 0;
2391                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2392                         this.flags &= ~FL_JUMPRELEASED;
2393                         if(SpectatePrev(this)) {
2394                                 TRANSMUTE(Spectator, this);
2395                         } else {
2396                                 TRANSMUTE(Observer, this);
2397                                 PutClientInServer(this);
2398                         }
2399                         CS(this).impulse = 0;
2400                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2401                         this.flags &= ~FL_JUMPRELEASED;
2402                         TRANSMUTE(Observer, this);
2403                         PutClientInServer(this);
2404                 } else {
2405                         if(!SpectateUpdate(this))
2406                                 PutObserverInServer(this);
2407                 }
2408         } else {
2409                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2410                         this.flags |= FL_JUMPRELEASED;
2411                         if(this.flags & FL_SPAWNING)
2412                         {
2413                                 this.flags &= ~FL_SPAWNING;
2414                                 Join(this);
2415                                 return;
2416                         }
2417                 }
2418                 if(!SpectateUpdate(this))
2419                         PutObserverInServer(this);
2420         }
2421
2422         this.flags |= FL_CLIENT | FL_NOTARGET;
2423 }
2424
2425 void vehicles_enter (entity pl, entity veh);
2426 void PlayerUseKey(entity this)
2427 {
2428         if (!IS_PLAYER(this))
2429                 return;
2430
2431         if(this.vehicle)
2432         {
2433                 if(!game_stopped)
2434                 {
2435                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2436                         return;
2437                 }
2438         }
2439         else if(autocvar_g_vehicles_enter)
2440         {
2441                 if(!STAT(FROZEN, this))
2442                 if(!IS_DEAD(this))
2443                 if(!game_stopped)
2444                 {
2445                         entity head, closest_target = NULL;
2446                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2447
2448                         while(head) // find the closest acceptable target to enter
2449                         {
2450                                 if(IS_VEHICLE(head))
2451                                 if(!IS_DEAD(head))
2452                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2453                                 if(head.takedamage != DAMAGE_NO)
2454                                 {
2455                                         if(closest_target)
2456                                         {
2457                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2458                                                 { closest_target = head; }
2459                                         }
2460                                         else { closest_target = head; }
2461                                 }
2462
2463                                 head = head.chain;
2464                         }
2465
2466                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2467                 }
2468         }
2469
2470         // a use key was pressed; call handlers
2471         MUTATOR_CALLHOOK(PlayerUseKey, this);
2472 }
2473
2474
2475 /*
2476 =============
2477 PlayerPreThink
2478
2479 Called every frame for each client before the physics are run
2480 =============
2481 */
2482 .float last_vehiclecheck;
2483 void PlayerPreThink (entity this)
2484 {
2485         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2486         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2487
2488         WarpZone_PlayerPhysics_FixVAngle(this);
2489
2490         if (frametime) {
2491                 // physics frames: update anticheat stuff
2492                 anticheat_prethink(this);
2493         }
2494
2495         if (blockSpectators && frametime) {
2496                 // WORKAROUND: only use dropclient in server frames (frametime set).
2497                 // Never use it in cl_movement frames (frametime zero).
2498                 checkSpectatorBlock(this);
2499         }
2500
2501         zoomstate_set = false;
2502
2503         // Check for nameless players
2504         if (this.netname == "" || this.netname != CS(this).netname_previous)
2505         {
2506                 bool assume_unchanged = (CS(this).netname_previous == "");
2507                 if (isInvisibleString(this.netname))
2508                 {
2509                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2510                         assume_unchanged = false;
2511                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2512                 }
2513                 if (!assume_unchanged && autocvar_sv_eventlog)
2514                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2515                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2516                 CS(this).netname_previous = strzone(this.netname);
2517         }
2518
2519         // version nagging
2520         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2521         CS(this).version_nagtime = 0;
2522         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2523             // git client
2524         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2525             // git server
2526             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2527         } else {
2528             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2529             if (r < 0) { // old client
2530                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2531             } else if (r > 0) { // old server
2532                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2533             }
2534         }
2535     }
2536
2537         // GOD MODE info
2538         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2539         {
2540                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2541                 this.max_armorvalue = 0;
2542         }
2543
2544         if(IS_PLAYER(this))
2545         {
2546                 if (STAT(FROZEN, this) == 2)
2547                 {
2548                         this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2549                         this.health = max(1, this.revive_progress * start_health);
2550                         this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2551
2552                         if (this.revive_progress >= 1)
2553                                 Unfreeze(this);
2554                 }
2555                 else if (STAT(FROZEN, this) == 3)
2556                 {
2557                         this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2558                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2559
2560                         if (this.health < 1)
2561                         {
2562                                 if (this.vehicle)
2563                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2564                                 if(this.event_damage)
2565                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2566                         }
2567                         else if (this.revive_progress <= 0)
2568                                 Unfreeze(this);
2569                 }
2570         }
2571
2572         MUTATOR_CALLHOOK(PlayerPreThink, this);
2573
2574         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2575         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2576         {
2577                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2578                 {
2579                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2580                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2581                         {
2582                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2583                         }
2584                         else if(!it.owner)
2585                         {
2586                                 if(!it.team || SAME_TEAM(this, it))
2587                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2588                                 else if(autocvar_g_vehicles_steal)
2589                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2590                         }
2591                 });
2592
2593                 this.last_vehiclecheck = time + 1;
2594         }
2595
2596         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2597         {
2598                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2599                         PlayerUseKey(this);
2600                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2601         }
2602
2603         if (IS_REAL_CLIENT(this))
2604                 PrintWelcomeMessage(this);
2605
2606         if (IS_PLAYER(this)) {
2607                 if(!PlayerThink(this))
2608                         return;
2609         }
2610         else if (game_stopped || intermission_running) {
2611                 if(intermission_running)
2612                         IntermissionThink(this);
2613                 return;
2614         }
2615         else if (IS_OBSERVER(this)) {
2616                 ObserverThink(this);
2617         }
2618         else if (IS_SPEC(this)) {
2619                 SpectatorThink(this);
2620         }
2621
2622         // WEAPONTODO: Add weapon request for this
2623         if (!zoomstate_set) {
2624                 bool wep_zoomed = false;
2625                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2626                 {
2627                         .entity weaponentity = weaponentities[slot];
2628                         Weapon thiswep = this.(weaponentity).m_weapon;
2629                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2630                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2631                 }
2632                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2633     }
2634
2635         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2636         {
2637                 CS(this).teamkill_soundtime = 0;
2638
2639                 entity e = CS(this).teamkill_soundsource;
2640                 entity oldpusher = e.pusher;
2641                 e.pusher = this;
2642                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2643                 e.pusher = oldpusher;
2644         }
2645
2646         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2647                 CS(this).taunt_soundtime = 0;
2648                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2649         }
2650
2651         target_voicescript_next(this);
2652
2653         // WEAPONTODO: Move into weaponsystem somehow
2654         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2655         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2656         {
2657                 .entity weaponentity = weaponentities[slot];
2658                 if(this.(weaponentity).m_weapon == WEP_Null)
2659                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2660         }
2661 }
2662
2663 void DrownPlayer(entity this)
2664 {
2665         if(IS_DEAD(this))
2666                 return;
2667
2668         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2669         {
2670                 if(this.air_finished < time)
2671                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2672                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2673         }
2674         else if (this.air_finished < time)
2675         {       // drown!
2676                 if (this.pain_finished < time)
2677                 {
2678                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2679                         this.pain_finished = time + 0.5;
2680                 }
2681         }
2682 }
2683
2684 .bool move_qcphysics;
2685
2686 void Player_Physics(entity this)
2687 {
2688         set_movetype(this, this.move_movetype);
2689
2690         if(!this.move_qcphysics)
2691                 return;
2692
2693         if(!frametime && !CS(this).pm_frametime)
2694                 return;
2695
2696         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2697
2698         CS(this).pm_frametime = 0;
2699 }
2700
2701 /*
2702 =============
2703 PlayerPostThink
2704
2705 Called every frame for each client after the physics are run
2706 =============
2707 */
2708 void PlayerPostThink (entity this)
2709 {
2710         Player_Physics(this);
2711
2712         if (sv_maxidle > 0)
2713         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2714         if (IS_REAL_CLIENT(this))
2715         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2716         {
2717                 int totalClients = 0;
2718                 if(sv_maxidle_slots > 0)
2719                 {
2720                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2721                         {
2722                                 ++totalClients;
2723                         });
2724                 }
2725
2726                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2727                 { /* do nothing */ }
2728                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2729                 {
2730                         if (CS(this).idlekick_lasttimeleft)
2731                         {
2732                                 CS(this).idlekick_lasttimeleft = 0;
2733                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2734                         }
2735                 }
2736                 else
2737                 {
2738                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2739                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2740                                 if (!CS(this).idlekick_lasttimeleft)
2741                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2742                         }
2743                         if (timeleft <= 0) {
2744                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2745                                 dropclient(this);
2746                                 return;
2747                         }
2748                         else if (timeleft <= 10) {
2749                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2750                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2751                 }
2752                                 CS(this).idlekick_lasttimeleft = timeleft;
2753                         }
2754                 }
2755         }
2756
2757         CheatFrame(this);
2758
2759         if (game_stopped)
2760         {
2761                 this.solid = SOLID_NOT;
2762                 this.takedamage = DAMAGE_NO;
2763                 set_movetype(this, MOVETYPE_NONE);
2764         }
2765
2766         if (IS_PLAYER(this)) {
2767                 DrownPlayer(this);
2768                 UpdateChatBubble(this);
2769                 if (CS(this).impulse) ImpulseCommands(this);
2770                 if (game_stopped)
2771                 {
2772                         CSQCMODEL_AUTOUPDATE(this);
2773                         return;
2774                 }
2775                 GetPressedKeys(this);
2776         }
2777
2778         if (this.waypointsprite_attachedforcarrier) {
2779             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2780                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2781     }
2782
2783         playerdemo_write(this);
2784
2785         CSQCMODEL_AUTOUPDATE(this);
2786 }
2787
2788 // hack to copy the button fields from the client entity to the Client State
2789 void PM_UpdateButtons(entity this, entity store)
2790 {
2791         if(this.impulse)
2792                 store.impulse = this.impulse;
2793         this.impulse = 0;
2794
2795         store.button0 = this.button0;
2796         store.button2 = this.button2;
2797         store.button3 = this.button3;
2798         store.button4 = this.button4;
2799         store.button5 = this.button5;
2800         store.button6 = this.button6;
2801         store.button7 = this.button7;
2802         store.button8 = this.button8;
2803         store.button9 = this.button9;
2804         store.button10 = this.button10;
2805         store.button11 = this.button11;
2806         store.button12 = this.button12;
2807         store.button13 = this.button13;
2808         store.button14 = this.button14;
2809         store.button15 = this.button15;
2810         store.button16 = this.button16;
2811         store.buttonuse = this.buttonuse;
2812         store.buttonchat = this.buttonchat;
2813
2814         store.cursor_active = this.cursor_active;
2815         store.cursor_screen = this.cursor_screen;
2816         store.cursor_trace_start = this.cursor_trace_start;
2817         store.cursor_trace_endpos = this.cursor_trace_endpos;
2818         store.cursor_trace_ent = this.cursor_trace_ent;
2819
2820         store.ping = this.ping;
2821         store.ping_packetloss = this.ping_packetloss;
2822         store.ping_movementloss = this.ping_movementloss;
2823
2824         store.v_angle = this.v_angle;
2825         store.movement = this.movement;
2826 }