qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/state.qh>
  34 #include <common/stats.qh>
  35 #include <common/vehicles/all.qh>
  36 #include <common/vehicles/sv_vehicles.qh>
  37 #include <common/viewloc.qh>
  38 #include <common/weapons/_all.qh>
  39 #include <common/weapons/weapon/vortex.qh>
  40 #include <common/wepent.qh>
  41 #include <lib/csqcmodel/sv_model.qh>
  42 #include <lib/warpzone/common.qh>
  43 #include <lib/warpzone/server.qh>
  44 #include <server/anticheat.qh>
  45 #include <server/antilag.qh>
  46 #include <server/bot/api.qh>
  47 #include <server/bot/default/cvars.qh>
  48 #include <server/campaign.qh>
  49 #include <server/chat.qh>
  50 #include <server/cheats.qh>
  51 #include <server/clientkill.qh>
  52 #include <server/command/common.qh>
  53 #include <server/command/common.qh>
  54 #include <server/command/vote.qh>
  55 #include <server/compat/quake3.qh>
  56 #include <server/damage.qh>
  57 #include <server/gamelog.qh>
  58 #include <server/handicap.qh>
  59 #include <server/hook.qh>
  60 #include <server/impulse.qh>
  61 #include <server/intermission.qh>
  62 #include <server/ipban.qh>
  63 #include <server/main.qh>
  64 #include <server/mutators/_mod.qh>
  65 #include <server/player.qh>
  66 #include <server/portals.qh>
  67 #include <server/race.qh>
  68 #include <server/resources.qh>
  69 #include <server/scores.qh>
  70 #include <server/scores_rules.qh>
  71 #include <server/spawnpoints.qh>
  72 #include <server/teamplay.qh>
  73 #include <server/weapons/accuracy.qh>
  74 #include <server/weapons/common.qh>
  75 #include <server/weapons/hitplot.qh>
  76 #include <server/weapons/selection.qh>
  77 #include <server/weapons/tracing.qh>
  78 #include <server/weapons/weaponsystem.qh>
  79 #include <server/world.qh>
  80
  81 STATIC_METHOD(Client, Add, void(Client this, int _team))
  82 {
  83     ClientConnect(this);
  84     TRANSMUTE(Player, this);
  85     this.frame = 12; // 7
  86     this.team = _team;
  87     PutClientInServer(this);
  88 }
  89
  90 STATIC_METHOD(Client, Remove, void(Client this))
  91 {
  92     TRANSMUTE(Observer, this);
  93     PutClientInServer(this);
  94     ClientDisconnect(this);
  95 }
  96
  97 void send_CSQC_teamnagger() {
  98         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  99 }
 100
 101 void send_TeamNames(int channel, entity to) {
 102         msg_entity = to;
 103
 104         WriteHeader(channel, TE_CSQC_TEAMNAMES);
 105         WriteString(channel, autocvar_g_teamnames_red);
 106         WriteString(channel, autocvar_g_teamnames_blue);
 107         WriteString(channel, autocvar_g_teamnames_yellow);
 108         WriteString(channel, autocvar_g_teamnames_pink);
 109 }
 110
 111 int CountSpectators(entity player, entity to)
 112 {
 113         if(!player) { return 0; } // not sure how, but best to be safe
 114
 115         int spec_count = 0;
 116
 117         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 118         {
 119                 spec_count++;
 120         });
 121
 122         return spec_count;
 123 }
 124
 125 void WriteSpectators(entity player, entity to)
 126 {
 127         if(!player) { return; } // not sure how, but best to be safe
 128
 129         int spec_count = 0;
 130         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 131         {
 132                 if(spec_count >= MAX_SPECTATORS)
 133                         break;
 134                 WriteByte(MSG_ENTITY, num_for_edict(it));
 135                 ++spec_count;
 136         });
 137 }
 138
 139 bool ClientData_Send(entity this, entity to, int sf)
 140 {
 141         assert(to == this.owner, return false);
 142
 143         entity e = to;
 144         if (IS_SPEC(e)) e = e.enemy;
 145
 146         sf = 0;
 147         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 148         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 149         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 150         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 151
 152         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 153         WriteByte(MSG_ENTITY, sf);
 154
 155         if (sf & BIT(1))
 156                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 157
 158         if(sf & BIT(4))
 159         {
 160                 float specs = CountSpectators(e, to);
 161                 WriteByte(MSG_ENTITY, specs);
 162                 WriteSpectators(e, to);
 163         }
 164
 165         return true;
 166 }
 167
 168 void ClientData_Attach(entity this)
 169 {
 170         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 171         CS(this).clientdata.drawonlytoclient = this;
 172         CS(this).clientdata.owner = this;
 173 }
 174
 175 void ClientData_Detach(entity this)
 176 {
 177         delete(CS(this).clientdata);
 178         CS(this).clientdata = NULL;
 179 }
 180
 181 void ClientData_Touch(entity e)
 182 {
 183         entity cd = CS(e).clientdata;
 184         if (cd) { cd.SendFlags = 1; }
 185
 186         // make it spectatable
 187         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 188         {
 189                 entity cd = CS(it).clientdata;
 190                 if (cd) { cd.SendFlags = 1; }
 191         });
 192 }
 193
 194
 195 /*
 196 =============
 197 CheckPlayerModel
 198
 199 Checks if the argument string can be a valid playermodel.
 200 Returns a valid one in doubt.
 201 =============
 202 */
 203 string FallbackPlayerModel;
 204 string CheckPlayerModel(string plyermodel) {
 205         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 206         {
 207                 // note: we cannot summon Don Strunzone here, some player may
 208                 // still have the model string set. In case anyone manages how
 209                 // to change a cvar default, we'll have a small leak here.
 210                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 211         }
 212         // only in right path
 213         if(substring(plyermodel, 0, 14) != "models/player/")
 214                 return FallbackPlayerModel;
 215         // only good file extensions
 216         if(substring(plyermodel, -4, 4) != ".iqm"
 217                 && substring(plyermodel, -4, 4) != ".zym"
 218                 && substring(plyermodel, -4, 4) != ".dpm"
 219                 && substring(plyermodel, -4, 4) != ".md3"
 220                 && substring(plyermodel, -4, 4) != ".psk")
 221         {
 222                 return FallbackPlayerModel;
 223         }
 224         // forbid the LOD models
 225         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 226                 return FallbackPlayerModel;
 227         if(plyermodel != strtolower(plyermodel))
 228                 return FallbackPlayerModel;
 229         // also, restrict to server models
 230         if(autocvar_sv_servermodelsonly)
 231         {
 232                 if(!fexists(plyermodel))
 233                         return FallbackPlayerModel;
 234         }
 235         return plyermodel;
 236 }
 237
 238 void setplayermodel(entity e, string modelname)
 239 {
 240         precache_model(modelname);
 241         _setmodel(e, modelname);
 242         player_setupanimsformodel(e);
 243         if(!autocvar_g_debug_globalsounds)
 244                 UpdatePlayerSounds(e);
 245 }
 246
 247 /** putting a client as observer in the server */
 248 void PutObserverInServer(entity this, bool is_forced)
 249 {
 250         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 251         PlayerState_detach(this);
 252
 253         if (IS_PLAYER(this))
 254         {
 255                 if(GetResource(this, RES_HEALTH) >= 1)
 256                 {
 257                         // despawn effect
 258                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 259                 }
 260
 261                 // was a player, recount votes and ready status
 262                 if(IS_REAL_CLIENT(this))
 263                 {
 264                         if (vote_called) { VoteCount(false); }
 265                         ReadyCount();
 266                 }
 267                 entcs_update_players(this);
 268         }
 269
 270         entity spot = SelectSpawnPoint(this, true);
 271         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 272         this.angles = vec2(spot.angles);
 273         this.fixangle = true;
 274         // offset it so that the spectator spawns higher off the ground, looks better this way
 275         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 276         if (IS_REAL_CLIENT(this))
 277         {
 278                 msg_entity = this;
 279                 WriteByte(MSG_ONE, SVC_SETVIEW);
 280                 WriteEntity(MSG_ONE, this);
 281         }
 282         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 283         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 284         if(!autocvar_g_debug_globalsounds)
 285         {
 286                 // needed for player sounds
 287                 this.model = "";
 288                 FixPlayermodel(this);
 289         }
 290         setmodel(this, MDL_Null);
 291         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 292         this.view_ofs = '0 0 0';
 293
 294         RemoveGrapplingHooks(this);
 295         Portal_ClearAll(this);
 296         Unfreeze(this, false);
 297         SetSpectatee(this, NULL);
 298
 299         if (this.alivetime)
 300         {
 301                 if (!warmup_stage)
 302                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 303                 this.alivetime = 0;
 304         }
 305
 306         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 307
 308         WaypointSprite_PlayerDead(this);
 309
 310         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 311                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 312
 313         accuracy_resend(this);
 314
 315         CS(this).spectatortime = time;
 316         if(this.bot_attack)
 317                 IL_REMOVE(g_bot_targets, this);
 318         this.bot_attack = false;
 319         if(this.monster_attack)
 320                 IL_REMOVE(g_monster_targets, this);
 321         this.monster_attack = false;
 322         STAT(HUD, this) = HUD_NORMAL;
 323         TRANSMUTE(Observer, this);
 324         this.iscreature = false;
 325         this.teleportable = TELEPORT_SIMPLE;
 326         if(this.damagedbycontents)
 327                 IL_REMOVE(g_damagedbycontents, this);
 328         this.damagedbycontents = false;
 329         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 330         SetSpectatee_status(this, etof(this));
 331         this.takedamage = DAMAGE_NO;
 332         this.solid = SOLID_NOT;
 333         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 334         this.flags = FL_CLIENT | FL_NOTARGET;
 335         this.effects = 0;
 336         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 337         this.pauserotarmor_finished = 0;
 338         this.pauserothealth_finished = 0;
 339         this.pauseregen_finished = 0;
 340         this.damageforcescale = 0;
 341         this.death_time = 0;
 342         this.respawn_flags = 0;
 343         this.respawn_time = 0;
 344         STAT(RESPAWN_TIME, this) = 0;
 345         this.alpha = 0;
 346         this.scale = 0;
 347         this.fade_time = 0;
 348         this.pain_finished = 0;
 349         STAT(AIR_FINISHED, this) = 0;
 350         //this.dphitcontentsmask = 0;
 351         this.dphitcontentsmask = DPCONTENTS_SOLID;
 352         if (autocvar_g_playerclip_collisions)
 353                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 354         this.pushltime = 0;
 355         this.istypefrag = 0;
 356         setthink(this, func_null);
 357         this.nextthink = 0;
 358         this.deadflag = DEAD_NO;
 359         UNSET_DUCKED(this);
 360         STAT(REVIVE_PROGRESS, this) = 0;
 361         this.revival_time = 0;
 362         this.draggable = drag_undraggable;
 363
 364         this.items = 0;
 365         STAT(WEAPONS, this) = '0 0 0';
 366         this.drawonlytoclient = this;
 367
 368         this.viewloc = NULL;
 369
 370         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 371
 372         this.weaponmodel = "";
 373         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 374         {
 375                 this.weaponentities[slot] = NULL;
 376         }
 377         this.exteriorweaponentity = NULL;
 378         CS(this).killcount = FRAGS_SPECTATOR;
 379         this.velocity = '0 0 0';
 380         this.avelocity = '0 0 0';
 381         this.punchangle = '0 0 0';
 382         this.punchvector = '0 0 0';
 383         this.oldvelocity = this.velocity;
 384         this.event_damage = func_null;
 385         this.event_heal = func_null;
 386
 387         for(int slot = 0; slot < MAX_AXH; ++slot)
 388         {
 389                 entity axh = this.(AuxiliaryXhair[slot]);
 390                 this.(AuxiliaryXhair[slot]) = NULL;
 391
 392                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 393                         delete(axh);
 394         }
 395
 396         if (mutator_returnvalue)
 397         {
 398                 // mutator prevents resetting teams+score
 399         }
 400         else
 401         {
 402                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 403                 this.frags = FRAGS_SPECTATOR;
 404         }
 405
 406         bot_relinkplayerlist();
 407
 408         if (CS(this).just_joined)
 409                 CS(this).just_joined = false;
 410
 411         // for RJZ
 412         if (autocvar_g_count_shards)
 413                 send_TotalShards(this);
 414 }
 415
 416 int player_getspecies(entity this)
 417 {
 418         get_model_parameters(this.model, this.skin);
 419         int s = get_model_parameters_species;
 420         get_model_parameters(string_null, 0);
 421         if (s < 0) return SPECIES_HUMAN;
 422         return s;
 423 }
 424
 425 .float model_randomizer;
 426 void FixPlayermodel(entity player)
 427 {
 428         string defaultmodel = "";
 429         int defaultskin = 0;
 430         if(autocvar_sv_defaultcharacter)
 431         {
 432                 if(teamplay)
 433                 {
 434                         switch(player.team)
 435                         {
 436                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 437                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 438                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 439                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 440                         }
 441                 }
 442
 443                 if(defaultmodel == "")
 444                 {
 445                         defaultmodel = autocvar_sv_defaultplayermodel;
 446                         defaultskin = autocvar_sv_defaultplayerskin;
 447                 }
 448
 449                 int n = tokenize_console(defaultmodel);
 450                 if(n > 0)
 451                 {
 452                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 453                         // However, do NOT randomize if the player-selected model is in the list.
 454                         for (int i = 0; i < n; ++i)
 455                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 456                                         defaultmodel = argv(i);
 457                 }
 458
 459                 int i = strstrofs(defaultmodel, ":", 0);
 460                 if(i >= 0)
 461                 {
 462                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 463                         defaultmodel = substring(defaultmodel, 0, i);
 464                 }
 465         }
 466         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 467         {
 468                 if(teamplay)
 469                 {
 470                         switch(player.team)
 471                         {
 472                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 473                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 474                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 475                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 476                         }
 477                 }
 478
 479                 if(!defaultskin)
 480                         defaultskin = autocvar_sv_defaultplayerskin;
 481         }
 482
 483         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 484         defaultmodel = M_ARGV(0, string);
 485         defaultskin = M_ARGV(1, int);
 486
 487         bool chmdl = false;
 488         int oldskin;
 489         if(defaultmodel != "")
 490         {
 491                 if (defaultmodel != player.model)
 492                 {
 493                         vector m1 = player.mins;
 494                         vector m2 = player.maxs;
 495                         setplayermodel (player, defaultmodel);
 496                         setsize (player, m1, m2);
 497                         chmdl = true;
 498                 }
 499
 500                 oldskin = player.skin;
 501                 player.skin = defaultskin;
 502         } else {
 503                 if (player.playermodel != player.model || player.playermodel == "")
 504                 {
 505                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 506                         vector m1 = player.mins;
 507                         vector m2 = player.maxs;
 508                         setplayermodel (player, player.playermodel);
 509                         setsize (player, m1, m2);
 510                         chmdl = true;
 511                 }
 512
 513                 if(!autocvar_sv_defaultcharacterskin)
 514                 {
 515                         oldskin = player.skin;
 516                         player.skin = stof(player.playerskin);
 517                 }
 518                 else
 519                 {
 520                         oldskin = player.skin;
 521                         player.skin = defaultskin;
 522                 }
 523         }
 524
 525         if(chmdl || oldskin != player.skin) // model or skin has changed
 526         {
 527                 player.species = player_getspecies(player); // update species
 528                 if(!autocvar_g_debug_globalsounds)
 529                         UpdatePlayerSounds(player); // update skin sounds
 530         }
 531
 532         if(!teamplay)
 533                 if(strlen(autocvar_sv_defaultplayercolors))
 534                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 535                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 536 }
 537
 538 void ResetPlayerResources(entity this)
 539 {
 540         if (warmup_stage) {
 541                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 542                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 543                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 544                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 545                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 546                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 547                 SetResource(this, RES_HEALTH, warmup_start_health);
 548                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 549                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 550         } else {
 551                 SetResource(this, RES_SHELLS, start_ammo_shells);
 552                 SetResource(this, RES_BULLETS, start_ammo_nails);
 553                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 554                 SetResource(this, RES_CELLS, start_ammo_cells);
 555                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 556                 SetResource(this, RES_FUEL, start_ammo_fuel);
 557                 SetResource(this, RES_HEALTH, start_health);
 558                 SetResource(this, RES_ARMOR, start_armorvalue);
 559                 STAT(WEAPONS, this) = start_weapons;
 560                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 561                 {
 562                         GiveRandomWeapons(this, random_start_weapons_count,
 563                                 autocvar_g_random_start_weapons, random_start_ammo);
 564                 }
 565         }
 566 }
 567
 568 void PutPlayerInServer(entity this)
 569 {
 570         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 571
 572         PlayerState_attach(this);
 573         accuracy_resend(this);
 574
 575         if (this.team < 0)
 576                 TeamBalance_JoinBestTeam(this);
 577
 578         entity spot = SelectSpawnPoint(this, false);
 579         if (!spot) {
 580                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 581                 return; // spawn failed
 582         }
 583
 584         TRANSMUTE(Player, this);
 585
 586         CS(this).wasplayer = true;
 587         this.iscreature = true;
 588         this.teleportable = TELEPORT_NORMAL;
 589         if(!this.damagedbycontents)
 590                 IL_PUSH(g_damagedbycontents, this);
 591         this.damagedbycontents = true;
 592         set_movetype(this, MOVETYPE_WALK);
 593         this.solid = SOLID_SLIDEBOX;
 594         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 595         if (autocvar_g_playerclip_collisions)
 596                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 597         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 598                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 599         this.frags = FRAGS_PLAYER;
 600         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 601         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 602         if (autocvar__notarget)
 603                 this.flags |= FL_NOTARGET;
 604         this.takedamage = DAMAGE_AIM;
 605         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 606
 607         ResetPlayerResources(this);
 608
 609         SetSpectatee_status(this, 0);
 610
 611         PS(this).dual_weapons = '0 0 0';
 612
 613         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 614                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 615
 616         this.items = start_items;
 617
 618         float shieldtime = time + autocvar_g_spawnshieldtime;
 619
 620         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 621         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 622         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 623         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 624         if (!sv_ready_restart_after_countdown && time < game_starttime)
 625         {
 626                 float f = game_starttime - time;
 627                 shieldtime += f;
 628                 this.pauserotarmor_finished += f;
 629                 this.pauserothealth_finished += f;
 630                 this.pauseregen_finished += f;
 631         }
 632
 633         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 634
 635         this.damageforcescale = autocvar_g_player_damageforcescale;
 636         this.death_time = 0;
 637         this.respawn_flags = 0;
 638         this.respawn_time = 0;
 639         STAT(RESPAWN_TIME, this) = 0;
 640         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 641         this.fade_time = 0;
 642         this.pain_finished = 0;
 643         this.pushltime = 0;
 644         setthink(this, func_null); // players have no think function
 645         this.nextthink = 0;
 646         this.dmg_team = 0;
 647         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 648
 649         this.deadflag = DEAD_NO;
 650
 651         this.angles = spot.angles;
 652         this.angles_z = 0; // never spawn tilted even if the spot says to
 653         if (IS_BOT_CLIENT(this))
 654         {
 655                 this.v_angle = this.angles;
 656                 bot_aim_reset(this);
 657         }
 658         this.fixangle = true; // turn this way immediately
 659         this.oldvelocity = this.velocity = '0 0 0';
 660         this.avelocity = '0 0 0';
 661         this.punchangle = '0 0 0';
 662         this.punchvector = '0 0 0';
 663
 664         STAT(REVIVE_PROGRESS, this) = 0;
 665         this.revival_time = 0;
 666
 667         STAT(AIR_FINISHED, this) = 0;
 668         this.waterlevel = WATERLEVEL_NONE;
 669         this.watertype = CONTENT_EMPTY;
 670
 671         entity spawnevent = new_pure(spawnevent);
 672         spawnevent.owner = this;
 673         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 674
 675         // Cut off any still running player sounds.
 676         stopsound(this, CH_PLAYER_SINGLE);
 677
 678         this.model = "";
 679         FixPlayermodel(this);
 680         this.drawonlytoclient = NULL;
 681
 682         this.viewloc = NULL;
 683
 684         for(int slot = 0; slot < MAX_AXH; ++slot)
 685         {
 686                 entity axh = this.(AuxiliaryXhair[slot]);
 687                 this.(AuxiliaryXhair[slot]) = NULL;
 688
 689                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 690                         delete(axh);
 691         }
 692
 693         this.spawnpoint_targ = NULL;
 694
 695         UNSET_DUCKED(this);
 696         this.view_ofs = STAT(PL_VIEW_OFS, this);
 697         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 698         this.spawnorigin = spot.origin;
 699         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 700         // don't reset back to last position, even if new position is stuck in solid
 701         this.oldorigin = this.origin;
 702         if(this.conveyor)
 703                 IL_REMOVE(g_conveyed, this);
 704         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 705         if(this.swampslug)
 706                 IL_REMOVE(g_swamped, this);
 707         this.swampslug = NULL;
 708         this.swamp_interval = 0;
 709         if(this.ladder_entity)
 710                 IL_REMOVE(g_ladderents, this);
 711         this.ladder_entity = NULL;
 712         IL_EACH(g_counters, it.realowner == this,
 713         {
 714                 delete(it);
 715         });
 716         STAT(HUD, this) = HUD_NORMAL;
 717
 718         this.event_damage = PlayerDamage;
 719         this.event_heal = PlayerHeal;
 720
 721         this.draggable = func_null;
 722
 723         if(!this.bot_attack)
 724                 IL_PUSH(g_bot_targets, this);
 725         this.bot_attack = true;
 726         if(!this.monster_attack)
 727                 IL_PUSH(g_monster_targets, this);
 728         this.monster_attack = true;
 729         navigation_dynamicgoal_init(this, false);
 730
 731         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 732
 733         // player was spectator
 734         if (CS(this).killcount == FRAGS_SPECTATOR) {
 735                 PlayerScore_Clear(this);
 736                 CS(this).killcount = 0;
 737                 CS(this).startplaytime = time;
 738         }
 739
 740         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 741         {
 742                 .entity weaponentity = weaponentities[slot];
 743                 CL_SpawnWeaponentity(this, weaponentity);
 744         }
 745         this.alpha = default_player_alpha;
 746         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 747         this.exteriorweaponentity.alpha = default_weapon_alpha;
 748
 749         this.speedrunning = false;
 750
 751         this.counter_cnt = 0;
 752         this.fragsfilter_cnt = 0;
 753
 754         target_voicescript_clear(this);
 755
 756         // reset fields the weapons may use
 757         FOREACH(Weapons, true, {
 758                 it.wr_resetplayer(it, this);
 759                         // reload all reloadable weapons
 760                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 761                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 762                         {
 763                                 .entity weaponentity = weaponentities[slot];
 764                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 765                         }
 766                 }
 767         });
 768
 769         Unfreeze(this, false);
 770
 771         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 772
 773         {
 774                 string s = spot.target;
 775                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 776                         spot.target = string_null;
 777                 SUB_UseTargets(spot, this, NULL);
 778                 if(g_assault || g_race)
 779                         spot.target = s;
 780         }
 781
 782         if (autocvar_spawn_debug)
 783         {
 784                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 785                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 786         }
 787
 788         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 789         {
 790                 .entity weaponentity = weaponentities[slot];
 791                 entity w_ent = this.(weaponentity);
 792                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 793                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 794                 else
 795                         w_ent.m_switchweapon = WEP_Null;
 796                 w_ent.m_weapon = WEP_Null;
 797                 w_ent.weaponname = "";
 798                 w_ent.m_switchingweapon = WEP_Null;
 799                 w_ent.cnt = -1;
 800         }
 801
 802         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 803
 804         if (CS(this).impulse) ImpulseCommands(this);
 805
 806         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 807         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 808         {
 809                 .entity weaponentity = weaponentities[slot];
 810                 W_WeaponFrame(this, weaponentity);
 811         }
 812
 813         if (!warmup_stage && !this.alivetime)
 814                 this.alivetime = time;
 815
 816         antilag_clear(this, CS(this));
 817 }
 818
 819 /** Called when a client spawns in the server */
 820 void PutClientInServer(entity this)
 821 {
 822         if (IS_BOT_CLIENT(this)) {
 823                 TRANSMUTE(Player, this);
 824         } else if (IS_REAL_CLIENT(this)) {
 825                 msg_entity = this;
 826                 WriteByte(MSG_ONE, SVC_SETVIEW);
 827                 WriteEntity(MSG_ONE, this);
 828         }
 829         if (game_stopped)
 830                 TRANSMUTE(Observer, this);
 831
 832         SetSpectatee(this, NULL);
 833
 834         // reset player keys
 835         if(PS(this))
 836                 PS(this).itemkeys = 0;
 837
 838         MUTATOR_CALLHOOK(PutClientInServer, this);
 839
 840         if (IS_OBSERVER(this)) {
 841                 PutObserverInServer(this, false);
 842         } else if (IS_PLAYER(this)) {
 843                 PutPlayerInServer(this);
 844         }
 845         // send team names
 846         if(teamplay && IS_REAL_CLIENT(this))
 847                 send_TeamNames(MSG_ONE, this);
 848         bot_relinkplayerlist();
 849 }
 850
 851 // TODO do we need all these fields, or should we stop autodetecting runtime
 852 // changes and just have a console command to update this?
 853 bool ClientInit_SendEntity(entity this, entity to, int sf)
 854 {
 855         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 856         return = true;
 857         msg_entity = to;
 858         // MSG_INIT replacement
 859         // TODO: make easier to use
 860         Registry_send_all();
 861         W_PROP_reload(MSG_ONE, to);
 862         ClientInit_misc(this);
 863         MUTATOR_CALLHOOK(Ent_Init);
 864 }
 865 void ClientInit_misc(entity this)
 866 {
 867         int channel = MSG_ONE;
 868         WriteHeader(channel, ENT_CLIENT_INIT);
 869         WriteByte(channel, g_nexball_meter_period * 32);
 870         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 871         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 872         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 873         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 874         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 875         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 876         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 877         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 878
 879         if(autocvar_sv_foginterval && world.fog != "")
 880                 WriteString(channel, world.fog);
 881         else
 882                 WriteString(channel, "");
 883         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 884         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 885         WriteByte(channel, serverflags);
 886         WriteCoord(channel, autocvar_g_trueaim_minrange);
 887
 888         // z411 send full hostname
 889         WriteString(channel, (autocvar_hostname_full != "" ? autocvar_hostname_full : autocvar_hostname));
 890         WriteString(channel, autocvar_sv_motd_permanent);
 891
 892         // z411 send client countdown type
 893         WriteByte(channel, autocvar_sv_timer_countdown);
 894 }
 895
 896 void ClientInit_CheckUpdate(entity this)
 897 {
 898         this.nextthink = time;
 899         if(this.count != autocvar_g_balance_armor_blockpercent)
 900         {
 901                 this.count = autocvar_g_balance_armor_blockpercent;
 902                 this.SendFlags |= 1;
 903         }
 904         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 905         {
 906                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 907                 this.SendFlags |= 1;
 908         }
 909 }
 910
 911 void ClientInit_Spawn()
 912 {
 913         entity e = new_pure(clientinit);
 914         setthink(e, ClientInit_CheckUpdate);
 915         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 916
 917         ClientInit_CheckUpdate(e);
 918 }
 919
 920 /*
 921 =============
 922 SetNewParms
 923 =============
 924 */
 925 void SetNewParms ()
 926 {
 927         // initialize parms for a new player
 928         parm1 = -(86400 * 366);
 929
 930         MUTATOR_CALLHOOK(SetNewParms);
 931 }
 932
 933 /*
 934 =============
 935 SetChangeParms
 936 =============
 937 */
 938 void SetChangeParms (entity this)
 939 {
 940         // save parms for level change
 941         parm1 = CS(this).parm_idlesince - time;
 942
 943         MUTATOR_CALLHOOK(SetChangeParms);
 944 }
 945
 946 /*
 947 =============
 948 DecodeLevelParms
 949 =============
 950 */
 951 void DecodeLevelParms(entity this)
 952 {
 953         // load parms
 954         CS(this).parm_idlesince = parm1;
 955         if (CS(this).parm_idlesince == -(86400 * 366))
 956                 CS(this).parm_idlesince = time;
 957
 958         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 959         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 960
 961         MUTATOR_CALLHOOK(DecodeLevelParms);
 962 }
 963
 964 void FixClientCvars(entity e)
 965 {
 966         // send prediction settings to the client
 967         stuffcmd(e, "\nin_bindmap 0 0\n");
 968         if(autocvar_g_antilag == 3) // client side hitscan
 969                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 970         if(autocvar_sv_gentle)
 971                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 972
 973         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 974         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 975
 976         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 977
 978         MUTATOR_CALLHOOK(FixClientCvars, e);
 979 }
 980
 981 bool findinlist_abbrev(string tofind, string list)
 982 {
 983         if(list == "" || tofind == "")
 984                 return false; // empty list or search, just return
 985
 986         // this function allows abbreviated strings!
 987         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 988         {
 989                 return true;
 990         });
 991
 992         return false;
 993 }
 994
 995 bool PlayerInIPList(entity p, string iplist)
 996 {
 997         // some safety checks (never allow local?)
 998         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 999                 return false;
1000
1001         return findinlist_abbrev(p.netaddress, iplist);
1002 }
1003
1004 bool PlayerInIDList(entity p, string idlist)
1005 {
1006         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1007         if(!p.crypto_idfp)
1008                 return false;
1009
1010         return findinlist_abbrev(p.crypto_idfp, idlist);
1011 }
1012
1013 bool PlayerInList(entity player, string list)
1014 {
1015         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1016 }
1017
1018 #ifdef DP_EXT_PRECONNECT
1019 /*
1020 =============
1021 ClientPreConnect
1022
1023 Called once (not at each match start) when a client begins a connection to the server
1024 =============
1025 */
1026 void ClientPreConnect(entity this)
1027 {
1028         if(autocvar_sv_eventlog)
1029         {
1030                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1031                         this.playerid,
1032                         etof(this),
1033                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1034                 ));
1035         }
1036 }
1037 #endif
1038
1039 string GetClientVersionMessage(entity this)
1040 {
1041         if (CS(this).version_mismatch) {
1042                 if(CS(this).version < autocvar_gameversion) {
1043                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1044                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1045                 } else {
1046                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1047                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1048                 }
1049         } else {
1050                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1051         }
1052 }
1053
1054 string getwelcomemessage(entity this)
1055 {
1056         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1057         string modifications = M_ARGV(0, string);
1058
1059         if(g_weaponarena)
1060         {
1061                 if(g_weaponarena_random)
1062                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1063                 else
1064                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1065         }
1066         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1067                 modifications = strcat(modifications, ", No start weapons");
1068         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1069                 modifications = strcat(modifications, ", Low gravity");
1070         if(g_weapon_stay && !g_cts)
1071                 modifications = strcat(modifications, ", Weapons stay");
1072         if(autocvar_g_jetpack)
1073                 modifications = strcat(modifications, ", Jet pack");
1074         modifications = substring(modifications, 2, strlen(modifications) - 2);
1075
1076         //string versionmessage = GetClientVersionMessage(this);
1077         //string s = strcat(versionmessage, "^8\n^9", (autocvar_hostname_full ? autocvar_hostname_full : autocvar_hostname));
1078         string s = (autocvar_hostname_full != "" ? autocvar_hostname_full : autocvar_hostname);
1079
1080         s = strcat(s, "^8\n^7", gamemode_name);
1081
1082         if(modifications != "")
1083                 s = strcat(s, "^7 | ^3", modifications);
1084
1085         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1086         {
1087                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1088                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1089         }
1090
1091         if (cache_mutatormsg != "") {
1092                 s = strcat(s, "\n^8tips: ^7", cache_mutatormsg);
1093         }
1094
1095         string mutator_msg = "";
1096         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1097         mutator_msg = M_ARGV(0, string);
1098
1099         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1100
1101         string motd = autocvar_sv_motd;
1102         if (motd != "") {
1103                 s = strcat(s, "\n\n^7", strreplace("\\n", "\n", motd));
1104         }
1105
1106         // It's been a work, I want some credit for a while. Might remove later.
1107         s = strcat(s, "\n\nUsing BaI mod by z411 - bienvenidoainternet.org");
1108         return s;
1109 }
1110
1111 /**
1112 =============
1113 ClientConnect
1114
1115 Called when a client connects to the server
1116 =============
1117 */
1118 void ClientConnect(entity this)
1119 {
1120         if (Ban_MaybeEnforceBanOnce(this)) return;
1121         assert(!IS_CLIENT(this), return);
1122         this.flags |= FL_CLIENT;
1123         assert(player_count >= 0, player_count = 0);
1124
1125         TRANSMUTE(Client, this);
1126         CS(this).version_nagtime = time + 10 + random() * 10;
1127
1128         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1129
1130         bot_clientconnect(this);
1131
1132         Player_DetermineForcedTeam(this);
1133
1134         TRANSMUTE(Observer, this);
1135
1136         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1137
1138         // always track bots, don't ask for cl_allow_uidtracking
1139         if (IS_BOT_CLIENT(this))
1140                 PlayerStats_GameReport_AddPlayer(this);
1141         else
1142                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1143
1144         if (autocvar_sv_eventlog)
1145                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1146
1147         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1148
1149         stuffcmd(this, clientstuff, "\n");
1150         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1151
1152         FixClientCvars(this);
1153
1154         // get version info from player
1155         stuffcmd(this, "cmd clientversion $gameversion\n");
1156
1157         // notify about available teams
1158         if (teamplay)
1159         {
1160                 entity balance = TeamBalance_CheckAllowedTeams(this);
1161                 int t = TeamBalance_GetAllowedTeams(balance);
1162                 TeamBalance_Destroy(balance);
1163                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1164         }
1165         else
1166         {
1167                 stuffcmd(this, "set _teams_available 0\n");
1168         }
1169
1170         bot_relinkplayerlist();
1171
1172         CS(this).spectatortime = time;
1173         if (blockSpectators)
1174         {
1175                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1176         }
1177
1178         CS(this).jointime = time;
1179
1180         if (IS_REAL_CLIENT(this))
1181         {
1182                 if (g_weaponarena_weapons == WEPSET(TUBA))
1183                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1184         }
1185
1186         if (!autocvar_sv_foginterval && world.fog != "")
1187                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1188
1189         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1190                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1191                         send_CSQC_teamnagger();
1192
1193         CSQCMODEL_AUTOINIT(this);
1194
1195         CS(this).model_randomizer = random();
1196
1197         if (IS_REAL_CLIENT(this))
1198                 sv_notice_join(this);
1199
1200         this.move_qcphysics = autocvar_sv_qcphysics;
1201
1202         // update physics stats (players can spawn before physics runs)
1203         Physics_UpdateStats(this);
1204
1205         IL_EACH(g_initforplayer, it.init_for_player, {
1206                 it.init_for_player(it, this);
1207         });
1208
1209         Handicap_Initialize(this);
1210
1211         MUTATOR_CALLHOOK(ClientConnect, this);
1212
1213         if (IS_REAL_CLIENT(this))
1214         {
1215                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1216                 {
1217                         CS(this).motd_actived_time = -1;
1218                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1219                 }
1220         }
1221 }
1222 /*
1223 =============
1224 ClientDisconnect
1225
1226 Called when a client disconnects from the server
1227 =============
1228 */
1229 .entity chatbubbleentity;
1230 void player_powerups_remove_all(entity this);
1231
1232 void ClientDisconnect(entity this)
1233 {
1234         assert(IS_CLIENT(this), return);
1235
1236         PlayerStats_GameReport_FinalizePlayer(this);
1237         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1238         if (CS(this).active_minigame) part_minigame(this);
1239         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1240
1241         if (autocvar_sv_eventlog)
1242                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1243
1244         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1245
1246         if(IS_SPEC(this))
1247                 SetSpectatee(this, NULL);
1248
1249         MUTATOR_CALLHOOK(ClientDisconnect, this);
1250
1251         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1252         strfree(CS_CVAR(this).weaponorder_byimpulse);
1253         ClientState_detach(this);
1254
1255         Portal_ClearAll(this);
1256
1257         Unfreeze(this, false);
1258
1259         RemoveGrapplingHooks(this);
1260
1261         // Here, everything has been done that requires this player to be a client.
1262
1263         this.flags &= ~FL_CLIENT;
1264
1265         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1266         if (this.killindicator) delete(this.killindicator);
1267
1268         IL_EACH(g_counters, it.realowner == this,
1269         {
1270                 delete(it);
1271         });
1272
1273         WaypointSprite_PlayerGone(this);
1274
1275         bot_relinkplayerlist();
1276
1277         strfree(this.clientstatus);
1278         if (this.personal) delete(this.personal);
1279
1280         this.playerid = 0;
1281         ReadyCount();
1282         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1283
1284         player_powerups_remove_all(this); // stop powerup sound
1285
1286         ONREMOVE(this);
1287 }
1288
1289 void ChatBubbleThink(entity this)
1290 {
1291         this.nextthink = time;
1292         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1293         {
1294                 if(this.owner) // but why can that ever be NULL?
1295                         this.owner.chatbubbleentity = NULL;
1296                 delete(this);
1297                 return;
1298         }
1299
1300         this.mdl = "";
1301
1302         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1303         {
1304                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1305                         this.mdl = "models/sprites/minigame_busy.iqm";
1306                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1307                         this.mdl = "models/misc/chatbubble.spr";
1308         }
1309
1310         if ( this.model != this.mdl )
1311                 _setmodel(this, this.mdl);
1312
1313 }
1314
1315 void UpdateChatBubble(entity this)
1316 {
1317         if (this.alpha < 0)
1318                 return;
1319         // spawn a chatbubble entity if needed
1320         if (!this.chatbubbleentity)
1321         {
1322                 this.chatbubbleentity = new(chatbubbleentity);
1323                 this.chatbubbleentity.owner = this;
1324                 this.chatbubbleentity.exteriormodeltoclient = this;
1325                 setthink(this.chatbubbleentity, ChatBubbleThink);
1326                 this.chatbubbleentity.nextthink = time;
1327                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1328                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1329                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1330                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1331                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1332                 //this.chatbubbleentity.model = "";
1333                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1334         }
1335 }
1336
1337 void calculate_player_respawn_time(entity this)
1338 {
1339         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1340                 return;
1341
1342         float gametype_setting_tmp;
1343         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1344         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1345         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1346         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1347         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1348         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1349
1350         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1351         if (teamplay)
1352         {
1353                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1354                         if(it.team == this.team)
1355                                 ++pcount;
1356                 });
1357                 if (sdelay_small_count == 0)
1358                         sdelay_small_count = 1;
1359                 if (sdelay_large_count == 0)
1360                         sdelay_large_count = 1;
1361         }
1362         else
1363         {
1364                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1365                         ++pcount;
1366                 });
1367                 if (sdelay_small_count == 0)
1368                 {
1369                         if (IS_INDEPENDENT_PLAYER(this))
1370                         {
1371                                 // Players play independently. No point in requiring enemies.
1372                                 sdelay_small_count = 1;
1373                         }
1374                         else
1375                         {
1376                                 // Players play AGAINST each other. Enemies required.
1377                                 sdelay_small_count = 2;
1378                         }
1379                 }
1380                 if (sdelay_large_count == 0)
1381                 {
1382                         if (IS_INDEPENDENT_PLAYER(this))
1383                         {
1384                                 // Players play independently. No point in requiring enemies.
1385                                 sdelay_large_count = 1;
1386                         }
1387                         else
1388                         {
1389                                 // Players play AGAINST each other. Enemies required.
1390                                 sdelay_large_count = 2;
1391                         }
1392                 }
1393         }
1394
1395         float sdelay;
1396
1397         if (pcount <= sdelay_small_count)
1398                 sdelay = sdelay_small;
1399         else if (pcount >= sdelay_large_count)
1400                 sdelay = sdelay_large;
1401         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1402                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1403
1404         if(waves)
1405                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1406         else
1407                 this.respawn_time = time + sdelay;
1408
1409         if(sdelay < sdelay_max)
1410                 this.respawn_time_max = time + sdelay_max;
1411         else
1412                 this.respawn_time_max = this.respawn_time;
1413
1414         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1415                 this.respawn_countdown = 10; // first number to count down from is 10
1416         else
1417                 this.respawn_countdown = -1; // do not count down
1418
1419         if(autocvar_g_forced_respawn)
1420                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1421 }
1422
1423 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1424 // added to the model skins
1425 /*void UpdateColorModHack()
1426 {
1427         float c;
1428         c = this.clientcolors & 15;
1429         // LordHavoc: only bothering to support white, green, red, yellow, blue
1430              if (!teamplay) this.colormod = '0 0 0';
1431         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1432         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1433         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1434         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1435         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1436         else this.colormod = '1 1 1';
1437 }*/
1438
1439 void respawn(entity this)
1440 {
1441         bool damagedbycontents_prev = this.damagedbycontents;
1442         if(this.alpha >= 0)
1443         {
1444                 if(autocvar_g_respawn_ghosts)
1445                 {
1446                         this.solid = SOLID_NOT;
1447                         this.takedamage = DAMAGE_NO;
1448                         this.damagedbycontents = false;
1449                         set_movetype(this, MOVETYPE_FLY);
1450                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1451                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1452                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1453                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1454                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1455                         if(autocvar_g_respawn_ghosts_time > 0)
1456                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1457                 }
1458                 else
1459                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1460         }
1461
1462         CopyBody(this, 1);
1463         this.damagedbycontents = damagedbycontents_prev;
1464
1465         this.effects |= EF_NODRAW; // prevent another CopyBody
1466         PutClientInServer(this);
1467 }
1468
1469 void play_countdown(entity this, float finished, Sound samp)
1470 {
1471         TC(Sound, samp);
1472         if(IS_REAL_CLIENT(this))
1473                 if(floor(finished - time - frametime) != floor(finished - time))
1474                         if(finished - time < 6)
1475                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1476 }
1477
1478 void player_powerups_remove_all(entity this)
1479 {
1480         if (this.items & IT_SUPERWEAPON)
1481         {
1482                 // don't play the poweroff sound when the game restarts or the player disconnects
1483                 if (time > game_starttime + 1 && IS_CLIENT(this))
1484                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1485                 stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1486                 this.items -= (this.items & IT_SUPERWEAPON);
1487         }
1488 }
1489
1490 void player_powerups(entity this)
1491 {
1492         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1493                 this.modelflags |= MF_ROCKET;
1494         else
1495                 this.modelflags &= ~MF_ROCKET;
1496
1497         this.effects &= ~EF_NODEPTHTEST;
1498
1499         if (IS_DEAD(this))
1500                 player_powerups_remove_all(this);
1501
1502         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1503                 return;
1504
1505         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1506         int items_prev = this.items;
1507
1508         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1509         {
1510                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1511                 if (this.items & IT_SUPERWEAPON)
1512                 {
1513                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1514                         {
1515                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1516                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1517                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1518                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1519                         }
1520                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1521                         {
1522                                 // don't let them run out
1523                         }
1524                         else
1525                         {
1526                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1527                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1528                                 {
1529                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1530                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1531                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1532                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1533                                 }
1534                         }
1535                 }
1536                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1537                 {
1538                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1539                         {
1540                                 this.items = this.items | IT_SUPERWEAPON;
1541                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1542                                 {
1543                                         if(!g_cts)
1544                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1545                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1546                                 }
1547                         }
1548                         else
1549                         {
1550                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1551                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1552                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1553                         }
1554                 }
1555                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1556                 {
1557                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1558                 }
1559         }
1560
1561         if(autocvar_g_nodepthtestplayers)
1562                 this.effects = this.effects | EF_NODEPTHTEST;
1563
1564         if(autocvar_g_fullbrightplayers)
1565                 this.effects = this.effects | EF_FULLBRIGHT;
1566
1567         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1568 }
1569
1570 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1571 {
1572         if(current > stable)
1573                 return current;
1574         else if(current > stable - 0.25) // when close enough, "snap"
1575                 return stable;
1576         else
1577                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1578 }
1579
1580 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1581 {
1582         if(current < stable)
1583                 return current;
1584         else if(current < stable + 0.25) // when close enough, "snap"
1585                 return stable;
1586         else
1587                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1588 }
1589
1590 void RotRegen(entity this, int res, float limit_mod,
1591         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1592         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1593 {
1594         float old = GetResource(this, res);
1595         float current = old;
1596         if(current > rotstable)
1597         {
1598                 if(rotframetime > 0)
1599                 {
1600                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1601                         current = max(rotstable, current - rotlinear * rotframetime);
1602                 }
1603         }
1604         else if(current < regenstable)
1605         {
1606                 if(regenframetime > 0)
1607                 {
1608                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1609                         current = min(regenstable, current + regenlinear * regenframetime);
1610                 }
1611         }
1612
1613         float limit = GetResourceLimit(this, res) * limit_mod;
1614         if(current > limit)
1615                 current = limit;
1616
1617         if (current != old)
1618                 SetResource(this, res, current);
1619 }
1620
1621 void player_regen(entity this)
1622 {
1623         float max_mod, regen_mod, rot_mod, limit_mod;
1624         max_mod = regen_mod = rot_mod = limit_mod = 1;
1625
1626         float regen_health = autocvar_g_balance_health_regen;
1627         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1628         float regen_health_rot = autocvar_g_balance_health_rot;
1629         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1630         float regen_health_stable = autocvar_g_balance_health_regenstable;
1631         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1632         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1633                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1634         max_mod = M_ARGV(1, float);
1635         regen_mod = M_ARGV(2, float);
1636         rot_mod = M_ARGV(3, float);
1637         limit_mod = M_ARGV(4, float);
1638         regen_health = M_ARGV(5, float);
1639         regen_health_linear = M_ARGV(6, float);
1640         regen_health_rot = M_ARGV(7, float);
1641         regen_health_rotlinear = M_ARGV(8, float);
1642         regen_health_stable = M_ARGV(9, float);
1643         regen_health_rotstable = M_ARGV(10, float);
1644
1645         float rotstable, regenstable, rotframetime, regenframetime;
1646
1647         if(!mutator_returnvalue)
1648         if(!STAT(FROZEN, this))
1649         {
1650                 regenstable = autocvar_g_balance_armor_regenstable;
1651                 rotstable = autocvar_g_balance_armor_rotstable;
1652                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1653                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1654                 RotRegen(this, RES_ARMOR, limit_mod,
1655                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1656                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1657
1658                 // NOTE: max_mod is only applied to health
1659                 regenstable = regen_health_stable * max_mod;
1660                 rotstable = regen_health_rotstable * max_mod;
1661                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1662                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1663                 RotRegen(this, RES_HEALTH, limit_mod,
1664                         regenstable, regen_health, regen_health_linear, regenframetime,
1665                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1666         }
1667
1668         // if player rotted to death...  die!
1669         // check this outside above checks, as player may still be able to rot to death
1670         if(GetResource(this, RES_HEALTH) < 1)
1671         {
1672                 if(this.vehicle)
1673                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1674                 if(this.event_damage)
1675                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1676         }
1677
1678         if (!(this.items & IT_UNLIMITED_AMMO))
1679         {
1680                 regenstable = autocvar_g_balance_fuel_regenstable;
1681                 rotstable = autocvar_g_balance_fuel_rotstable;
1682                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1683                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1684                 RotRegen(this, RES_FUEL, 1,
1685                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1686                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1687         }
1688 }
1689
1690 bool zoomstate_set;
1691 void SetZoomState(entity this, float newzoom)
1692 {
1693         if(newzoom != CS(this).zoomstate)
1694         {
1695                 CS(this).zoomstate = newzoom;
1696                 ClientData_Touch(this);
1697         }
1698         zoomstate_set = true;
1699 }
1700
1701 void GetPressedKeys(entity this)
1702 {
1703         MUTATOR_CALLHOOK(GetPressedKeys, this);
1704         if (game_stopped)
1705         {
1706                 CS(this).pressedkeys = 0;
1707                 STAT(PRESSED_KEYS, this) = 0;
1708                 return;
1709         }
1710
1711         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1712         int keys = STAT(PRESSED_KEYS, this);
1713         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1714         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1715         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1716         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1717
1718         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1719         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1720         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1721         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1722         CS(this).pressedkeys = keys; // store for other users
1723
1724         STAT(PRESSED_KEYS, this) = keys;
1725 }
1726
1727 /*
1728 ======================
1729 spectate mode routines
1730 ======================
1731 */
1732
1733 void SpectateCopy(entity this, entity spectatee)
1734 {
1735         TC(Client, this); TC(Client, spectatee);
1736
1737         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1738         PS(this) = PS(spectatee);
1739         this.armortype = spectatee.armortype;
1740         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1741         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1742         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1743         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1744         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1745         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1746         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1747         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1748         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1749         CS(this).impulse = 0;
1750         this.disableclientprediction = 1; // no need to run prediction on a spectator
1751         this.items = spectatee.items;
1752         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1753         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1754         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1755         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1756         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1757         this.punchangle = spectatee.punchangle;
1758         this.view_ofs = spectatee.view_ofs;
1759         this.velocity = spectatee.velocity;
1760         this.dmg_take = spectatee.dmg_take;
1761         this.dmg_save = spectatee.dmg_save;
1762         this.dmg_inflictor = spectatee.dmg_inflictor;
1763         this.v_angle = spectatee.v_angle;
1764         this.angles = spectatee.v_angle;
1765         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1766         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1767         this.viewloc = spectatee.viewloc;
1768         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1769                 this.fixangle = true;
1770         setorigin(this, spectatee.origin);
1771         setsize(this, spectatee.mins, spectatee.maxs);
1772         SetZoomState(this, CS(spectatee).zoomstate);
1773
1774     anticheat_spectatecopy(this, spectatee);
1775         STAT(HUD, this) = STAT(HUD, spectatee);
1776         if(spectatee.vehicle)
1777     {
1778         this.angles = spectatee.v_angle;
1779
1780         //this.fixangle = false;
1781         //this.velocity = spectatee.vehicle.velocity;
1782         this.vehicle_health = spectatee.vehicle_health;
1783         this.vehicle_shield = spectatee.vehicle_shield;
1784         this.vehicle_energy = spectatee.vehicle_energy;
1785         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1786         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1787         this.vehicle_reload1 = spectatee.vehicle_reload1;
1788         this.vehicle_reload2 = spectatee.vehicle_reload2;
1789
1790         //msg_entity = this;
1791
1792        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1793             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1794            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1795            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1796
1797         //WriteByte (MSG_ONE, SVC_SETVIEW);
1798         //    WriteEntity(MSG_ONE, this);
1799         //makevectors(spectatee.v_angle);
1800         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1801     }
1802 }
1803
1804 bool SpectateUpdate(entity this)
1805 {
1806         if(!this.enemy)
1807                 return false;
1808
1809         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1810         {
1811                 SetSpectatee(this, NULL);
1812                 return false;
1813         }
1814
1815         SpectateCopy(this, this.enemy);
1816
1817         return true;
1818 }
1819
1820 bool SpectateSet(entity this)
1821 {
1822         if(!IS_PLAYER(this.enemy))
1823                 return false;
1824
1825         ClientData_Touch(this.enemy);
1826
1827         msg_entity = this;
1828         WriteByte(MSG_ONE, SVC_SETVIEW);
1829         WriteEntity(MSG_ONE, this.enemy);
1830         set_movetype(this, MOVETYPE_NONE);
1831         accuracy_resend(this);
1832
1833         if(!SpectateUpdate(this))
1834                 PutObserverInServer(this, false);
1835
1836         return true;
1837 }
1838
1839 void SetSpectatee_status(entity this, int spectatee_num)
1840 {
1841         int oldspectatee_status = CS(this).spectatee_status;
1842         CS(this).spectatee_status = spectatee_num;
1843
1844         if (CS(this).spectatee_status != oldspectatee_status)
1845         {
1846                 if (STAT(PRESSED_KEYS, this))
1847                 {
1848                         CS(this).pressedkeys = 0;
1849                         STAT(PRESSED_KEYS, this) = 0;
1850                 }
1851                 ClientData_Touch(this);
1852                 if (g_race || g_cts) race_InitSpectator();
1853         }
1854 }
1855
1856 void SetSpectatee(entity this, entity spectatee)
1857 {
1858         if(IS_BOT_CLIENT(this))
1859                 return; // bots abuse .enemy, this code is useless to them
1860
1861         entity old_spectatee = this.enemy;
1862
1863         this.enemy = spectatee;
1864
1865         // WEAPONTODO
1866         // these are required to fix the spectator bug with arc
1867         if(old_spectatee)
1868         {
1869                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1870                 {
1871                         .entity weaponentity = weaponentities[slot];
1872                         if(old_spectatee.(weaponentity).arc_beam)
1873                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1874                 }
1875         }
1876         if(this.enemy)
1877         {
1878                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1879                 {
1880                         .entity weaponentity = weaponentities[slot];
1881                         if(this.enemy.(weaponentity).arc_beam)
1882                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1883                 }
1884         }
1885
1886         if (this.enemy)
1887                 SetSpectatee_status(this, etof(this.enemy));
1888
1889         // needed to update spectator list
1890         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1891 }
1892
1893 bool Spectate(entity this, entity pl)
1894 {
1895         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1896                 return false;
1897         pl = M_ARGV(1, entity);
1898
1899         SetSpectatee(this, pl);
1900         return SpectateSet(this);
1901 }
1902
1903 bool SpectateNext(entity this)
1904 {
1905         entity ent = find(this.enemy, classname, STR_PLAYER);
1906
1907         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1908                 ent = M_ARGV(1, entity);
1909         else if (!ent)
1910                 ent = find(ent, classname, STR_PLAYER);
1911
1912         if(ent) { SetSpectatee(this, ent); }
1913
1914         return SpectateSet(this);
1915 }
1916
1917 bool SpectatePrev(entity this)
1918 {
1919         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1920         entity ent = findchain(classname, STR_PLAYER);
1921         if (!ent) // no player
1922                 return false;
1923
1924         entity first = ent;
1925         // skip players until current spectated player
1926         if(this.enemy)
1927         while(ent && ent != this.enemy)
1928                 ent = ent.chain;
1929
1930         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1931         {
1932                 case MUT_SPECPREV_FOUND:
1933                         ent = M_ARGV(1, entity);
1934                         break;
1935                 case MUT_SPECPREV_RETURN:
1936                         return true;
1937                 case MUT_SPECPREV_CONTINUE:
1938                 default:
1939                 {
1940                         if(ent.chain)
1941                                 ent = ent.chain;
1942                         else
1943                                 ent = first;
1944                         break;
1945                 }
1946         }
1947
1948         SetSpectatee(this, ent);
1949         return SpectateSet(this);
1950 }
1951
1952 /*
1953 =============
1954 ShowRespawnCountdown()
1955
1956 Update a respawn countdown display.
1957 =============
1958 */
1959 void ShowRespawnCountdown(entity this)
1960 {
1961         float number;
1962         if(!IS_DEAD(this)) // just respawned?
1963                 return;
1964         else
1965         {
1966                 number = ceil(this.respawn_time - time);
1967                 if(number <= 0)
1968                         return;
1969                 if(number <= this.respawn_countdown)
1970                 {
1971                         this.respawn_countdown = number - 1;
1972                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1973                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1974                 }
1975         }
1976 }
1977
1978 .bool team_selected;
1979 bool ShowTeamSelection(entity this)
1980 {
1981         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1982                 return false;
1983         stuffcmd(this, "menu_showteamselect\n");
1984         return true;
1985 }
1986 void Join(entity this)
1987 {
1988         TRANSMUTE(Player, this);
1989
1990         if(!this.team_selected)
1991         if(autocvar_g_campaign || autocvar_g_balance_teams)
1992                 TeamBalance_JoinBestTeam(this);
1993
1994         if(autocvar_g_campaign)
1995                 campaign_bots_may_start = true;
1996
1997         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1998
1999         PutClientInServer(this);
2000
2001         if(IS_PLAYER(this))
2002         if(teamplay && this.team != -1)
2003         {
2004         }
2005         else
2006                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2007         this.team_selected = false;
2008
2009         // z411
2010         // send constant ready notification
2011         if(warmup_stage)
2012                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MISSING_READY);
2013 }
2014
2015 int GetPlayerLimit()
2016 {
2017         if(g_duel)
2018                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2019         int player_limit = autocvar_g_maxplayers;
2020         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2021         player_limit = M_ARGV(0, int);
2022         return player_limit;
2023 }
2024
2025 /**
2026  * Determines whether the player is allowed to join. This depends on cvar
2027  * g_maxplayers, if it isn't used this function always return true, otherwise
2028  * it checks whether the number of currently playing players exceeds g_maxplayers.
2029  * @return int number of free slots for players, 0 if none
2030  */
2031 int nJoinAllowed(entity this, entity ignore)
2032 {
2033         if(!ignore)
2034         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2035         // so report 0 free slots if restricted
2036         {
2037                 if(autocvar_g_forced_team_otherwise == "spectate")
2038                         return 0;
2039                 if(autocvar_g_forced_team_otherwise == "spectator")
2040                         return 0;
2041         }
2042
2043         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2044                 return 0; // forced spectators can never join
2045
2046         // TODO simplify this
2047         int totalClients = 0;
2048         int currentlyPlaying = 0;
2049         FOREACH_CLIENT(true, {
2050                 if(it != ignore)
2051                         ++totalClients;
2052                 if(IS_REAL_CLIENT(it))
2053                 if(IS_PLAYER(it) || it.caplayer)
2054                         ++currentlyPlaying;
2055         });
2056
2057         int player_limit = GetPlayerLimit();
2058
2059         int free_slots = 0;
2060         if (!player_limit)
2061                 free_slots = maxclients - totalClients;
2062         else if(player_limit > 0 && currentlyPlaying < player_limit)
2063                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2064
2065         static float msg_time = 0;
2066         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2067         {
2068                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2069                 msg_time = time + 0.5;
2070         }
2071
2072         return free_slots;
2073 }
2074
2075 void PrintWelcomeMessage(entity this)
2076 {
2077         if(CS(this).motd_actived_time == 0)
2078         {
2079                 if (autocvar_g_campaign) {
2080                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2081                                 CS(this).motd_actived_time = time;
2082                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2083                         }
2084                 } else {
2085                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2086                                 CS(this).motd_actived_time = time;
2087                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2088                         }
2089                 }
2090         }
2091         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2092         {
2093                 if (autocvar_g_campaign) {
2094                         if (PHYS_INPUT_BUTTON_INFO(this))
2095                                 CS(this).motd_actived_time = time;
2096                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2097                                 CS(this).motd_actived_time = 0;
2098                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2099                         }
2100                 } else {
2101                         if (PHYS_INPUT_BUTTON_INFO(this))
2102                                 CS(this).motd_actived_time = time;
2103                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2104                                 CS(this).motd_actived_time = 0;
2105                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2106                         }
2107                 }
2108         }
2109         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2110         {
2111                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2112                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2113                 else if (CS(this).motd_actived_time == -2)
2114                 {
2115                         // instantly hide MOTD
2116                         CS(this).motd_actived_time = 0;
2117                         if (autocvar_g_campaign)
2118                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2119                         else
2120                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2121                 }
2122                 else if (IS_PLAYER(this) || IS_SPEC(this))
2123                 {
2124                         // FIXME occasionally for some reason MOTD never goes away
2125                         // delay MOTD removal a little bit in the hope it fixes this bug
2126                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2127                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2128                         else //if (CS(this).motd_actived_time < -2)
2129                                 CS(this).motd_actived_time++;
2130                 }
2131         }
2132 }
2133
2134 bool joinAllowed(entity this)
2135 {
2136         if (CS(this).version_mismatch) return false;
2137         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2138         if (!nJoinAllowed(this, this)) return false;
2139         if (teamplay && lockteams) return false;
2140         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2141         if (ShowTeamSelection(this)) return false;
2142         return true;
2143 }
2144
2145 .string shootfromfixedorigin;
2146 .bool dualwielding_prev;
2147 bool PlayerThink(entity this)
2148 {
2149         if (game_stopped || intermission_running) {
2150                 this.modelflags &= ~MF_ROCKET;
2151                 if(intermission_running)
2152                         IntermissionThink(this);
2153                 return false;
2154         }
2155
2156         if (game_timeout) {
2157         // don't allow the player to turn around while game is paused
2158                 // FIXME turn this into CSQC stuff
2159                 this.v_angle = this.lastV_angle;
2160                 this.angles = this.lastV_angle;
2161                 this.fixangle = true;
2162                 return false;
2163         }
2164
2165         if (frametime) player_powerups(this);
2166
2167         if (IS_DEAD(this)) {
2168                 if (this.personal && g_race_qualifying) {
2169                         if (time > this.respawn_time) {
2170                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2171                                 respawn(this);
2172                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2173                         }
2174                 } else {
2175                         if (frametime) player_anim(this);
2176
2177                         if (this.respawn_flags & RESPAWN_DENY)
2178                         {
2179                                 STAT(RESPAWN_TIME, this) = 0;
2180                                 return false;
2181                         }
2182
2183                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2184
2185                         switch(this.deadflag)
2186                         {
2187                                 case DEAD_DYING:
2188                                 {
2189                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2190                                                 this.deadflag = DEAD_RESPAWNING;
2191                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2192                                                 this.deadflag = DEAD_DEAD;
2193                                         break;
2194                                 }
2195                                 case DEAD_DEAD:
2196                                 {
2197                                         if (button_pressed)
2198                                                 this.deadflag = DEAD_RESPAWNABLE;
2199                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2200                                                 this.deadflag = DEAD_RESPAWNING;
2201                                         break;
2202                                 }
2203                                 case DEAD_RESPAWNABLE:
2204                                 {
2205                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2206                                                 this.deadflag = DEAD_RESPAWNING;
2207                                         break;
2208                                 }
2209                                 case DEAD_RESPAWNING:
2210                                 {
2211                                         if (time > this.respawn_time)
2212                                         {
2213                                                 this.respawn_time = time + 1; // only retry once a second
2214                                                 this.respawn_time_max = this.respawn_time;
2215                                                 respawn(this);
2216                                         }
2217                                         break;
2218                                 }
2219                         }
2220
2221                         ShowRespawnCountdown(this);
2222
2223                         if (this.respawn_flags & RESPAWN_SILENT)
2224                                 STAT(RESPAWN_TIME, this) = 0;
2225                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2226                         {
2227                                 if (time < this.respawn_time)
2228                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2229                                 else if (this.deadflag != DEAD_RESPAWNING)
2230                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2231                         }
2232                         else
2233                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2234                 }
2235
2236                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2237                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2238                         STAT(RESPAWN_TIME, this) *= -1;
2239
2240                 return false;
2241         }
2242
2243         FixPlayermodel(this);
2244
2245         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2246                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2247                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2248         }
2249
2250         // reset gun alignment when dual wielding status changes
2251         // to ensure guns are always aligned right and left
2252         bool dualwielding = W_DualWielding(this);
2253         if(this.dualwielding_prev != dualwielding)
2254         {
2255                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2256                 this.dualwielding_prev = dualwielding;
2257         }
2258
2259         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2260         //if(frametime)
2261         {
2262                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2263                 {
2264                         .entity weaponentity = weaponentities[slot];
2265                         if(WEP_CVAR(vortex, charge_always))
2266                                 W_Vortex_Charge(this, weaponentity, frametime);
2267                         W_WeaponFrame(this, weaponentity);
2268                 }
2269         }
2270
2271         if (frametime)
2272         {
2273                 // WEAPONTODO: Add a weapon request for this
2274                 // rot vortex charge to the charge limit
2275                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2276                 {
2277                         .entity weaponentity = weaponentities[slot];
2278                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2279                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2280                 }
2281
2282                 player_regen(this);
2283                 player_anim(this);
2284                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2285         }
2286
2287         monsters_setstatus(this);
2288
2289         return true;
2290 }
2291
2292 .bool would_spectate;
2293 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2294 void ObserverOrSpectatorThink(entity this)
2295 {
2296         bool is_spec = IS_SPEC(this);
2297         if ( CS(this).impulse )
2298         {
2299                 int r = MinigameImpulse(this, CS(this).impulse);
2300                 if (!is_spec || r)
2301                         CS(this).impulse = 0;
2302
2303                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2304                 {
2305                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2306                         CS(this).impulse = 0;
2307                         return;
2308                 }
2309         }
2310
2311         if (this.flags & FL_JUMPRELEASED) {
2312                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2313                         this.flags &= ~FL_JUMPRELEASED;
2314                         this.flags |= FL_SPAWNING;
2315                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2316                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2317                         this.flags &= ~FL_JUMPRELEASED;
2318                         if(SpectateNext(this)) {
2319                                 TRANSMUTE(Spectator, this);
2320                         } else if (is_spec) {
2321                                 TRANSMUTE(Observer, this);
2322                                 PutClientInServer(this);
2323                         }
2324                         else
2325                                 this.would_spectate = false; // unable to spectate anyone
2326                         if (is_spec)
2327                                 CS(this).impulse = 0;
2328                 } else if (is_spec) {
2329                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2330                                 this.flags &= ~FL_JUMPRELEASED;
2331                                 if(SpectatePrev(this)) {
2332                                         TRANSMUTE(Spectator, this);
2333                                 } else {
2334                                         TRANSMUTE(Observer, this);
2335                                         PutClientInServer(this);
2336                                 }
2337                                 CS(this).impulse = 0;
2338                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2339                                 this.would_spectate = false;
2340                                 this.flags &= ~FL_JUMPRELEASED;
2341                                 TRANSMUTE(Observer, this);
2342                                 PutClientInServer(this);
2343                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2344                                 PutObserverInServer(this, false);
2345                                 this.would_spectate = true;
2346                         }
2347                 }
2348                 else {
2349                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2350                         if (PHYS_INPUT_BUTTON_USE(this))
2351                                 wouldclip = !wouldclip;
2352                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2353                         set_movetype(this, preferred_movetype);
2354                 }
2355         } else { // jump pressed
2356                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2357                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2358                         this.flags |= FL_JUMPRELEASED;
2359                         if(this.flags & FL_SPAWNING)
2360                         {
2361                                 this.flags &= ~FL_SPAWNING;
2362                                 if(joinAllowed(this))
2363                                         Join(this);
2364                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2365                                         CS(this).autojoin_checked = -1;
2366                                 return;
2367                         }
2368                 }
2369                 if(is_spec && !SpectateUpdate(this))
2370                         PutObserverInServer(this, false);
2371         }
2372         if (is_spec)
2373                 this.flags |= FL_CLIENT | FL_NOTARGET;
2374 }
2375
2376 void PlayerUseKey(entity this)
2377 {
2378         if (!IS_PLAYER(this))
2379                 return;
2380
2381         if(this.vehicle)
2382         {
2383                 if(!game_stopped)
2384                 {
2385                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2386                         return;
2387                 }
2388         }
2389         else if(autocvar_g_vehicles_enter)
2390         {
2391                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2392                 {
2393                         entity head, closest_target = NULL;
2394                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2395
2396                         while(head) // find the closest acceptable target to enter
2397                         {
2398                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2399                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2400                                 {
2401                                         if(closest_target)
2402                                         {
2403                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2404                                                 { closest_target = head; }
2405                                         }
2406                                         else { closest_target = head; }
2407                                 }
2408
2409                                 head = head.chain;
2410                         }
2411
2412                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2413                 }
2414         }
2415
2416         // a use key was pressed; call handlers
2417         MUTATOR_CALLHOOK(PlayerUseKey, this);
2418 }
2419
2420
2421 /*
2422 =============
2423 PlayerPreThink
2424
2425 Called every frame for each client before the physics are run
2426 =============
2427 */
2428 .float last_vehiclecheck;
2429 void PlayerPreThink (entity this)
2430 {
2431         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2432         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2433
2434         WarpZone_PlayerPhysics_FixVAngle(this);
2435
2436         if (frametime) {
2437                 // physics frames: update anticheat stuff
2438                 anticheat_prethink(this);
2439
2440                 // WORKAROUND: only use dropclient in server frames (frametime set).
2441                 // Never use it in cl_movement frames (frametime zero).
2442                 if (blockSpectators && IS_REAL_CLIENT(this)
2443                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !this.caplayer
2444                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2445                 {
2446                         if (dropclient_schedule(this))
2447                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2448                 }
2449         }
2450
2451         zoomstate_set = false;
2452
2453         // Check for nameless players
2454         if (this.netname == "" || this.netname != CS(this).netname_previous)
2455         {
2456                 bool assume_unchanged = (CS(this).netname_previous == "");
2457                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2458                 {
2459                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2460                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2461                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2462                         assume_unchanged = false;
2463                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2464                 }
2465                 if (isInvisibleString(this.netname))
2466                 {
2467                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2468                         sprint(this, "Warning: invisible names are not allowed.\n");
2469                         assume_unchanged = false;
2470                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2471                 }
2472                 if (!assume_unchanged && autocvar_sv_eventlog)
2473                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2474                 strcpy(CS(this).netname_previous, this.netname);
2475         }
2476
2477         // version nagging
2478         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2479         CS(this).version_nagtime = 0;
2480         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2481             // git client
2482         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2483             // git server
2484             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2485         } else {
2486             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2487             if (r < 0) { // old client
2488                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2489             } else if (r > 0) { // old server
2490                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2491             }
2492         }
2493     }
2494
2495         // GOD MODE info
2496         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2497         {
2498                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2499                 this.max_armorvalue = 0;
2500         }
2501
2502         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2503         {
2504                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2505                 {
2506                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2507                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2508                         if (this.iceblock)
2509                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2510
2511                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2512                                 Unfreeze(this, false);
2513                 }
2514                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2515                 {
2516                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2517                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2518
2519                         if (GetResource(this, RES_HEALTH) < 1)
2520                         {
2521                                 if (this.vehicle)
2522                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2523                                 if(this.event_damage)
2524                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2525                         }
2526                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2527                                 Unfreeze(this, false);
2528                 }
2529         }
2530
2531         MUTATOR_CALLHOOK(PlayerPreThink, this);
2532
2533         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2534         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2535         {
2536                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2537                 {
2538                         if(!it.owner)
2539                         {
2540                                 if(!it.team || SAME_TEAM(this, it))
2541                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2542                                 else if(autocvar_g_vehicles_steal)
2543                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2544                         }
2545                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2546                         {
2547                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2548                         }
2549                 });
2550
2551                 this.last_vehiclecheck = time + 1;
2552         }
2553
2554         if(!CS_CVAR(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2555         {
2556                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2557                         PlayerUseKey(this);
2558                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2559         }
2560
2561         if (IS_REAL_CLIENT(this))
2562                 PrintWelcomeMessage(this);
2563
2564         if (IS_PLAYER(this)) {
2565                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2566                         error("Client can't be spawned as player on connection!");
2567                 if(!PlayerThink(this))
2568                         return;
2569         }
2570         else if (game_stopped || intermission_running) {
2571                 if(intermission_running)
2572                         IntermissionThink(this);
2573                 return;
2574         }
2575         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2576         {
2577                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2578                 CS(this).autojoin_checked = 1;
2579                 // don't do this in ClientConnect
2580                 // many things can go wrong if a client is spawned as player on connection
2581                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2582                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2583                                 && (!teamplay || autocvar_g_balance_teams)))
2584                 {
2585                         campaign_bots_may_start = true;
2586                         if(joinAllowed(this))
2587                                 Join(this);
2588                         return;
2589                 }
2590         }
2591         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2592                 ObserverOrSpectatorThink(this);
2593         }
2594
2595         // WEAPONTODO: Add weapon request for this
2596         if (!zoomstate_set) {
2597                 bool wep_zoomed = false;
2598                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2599                 {
2600                         .entity weaponentity = weaponentities[slot];
2601                         Weapon thiswep = this.(weaponentity).m_weapon;
2602                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2603                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2604                 }
2605                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2606         }
2607
2608         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2609         {
2610                 CS(this).teamkill_soundtime = 0;
2611
2612                 entity e = CS(this).teamkill_soundsource;
2613                 entity oldpusher = e.pusher;
2614                 e.pusher = this;
2615                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2616                 e.pusher = oldpusher;
2617         }
2618
2619         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2620                 CS(this).taunt_soundtime = 0;
2621                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2622         }
2623
2624         target_voicescript_next(this);
2625 }
2626
2627 void DrownPlayer(entity this)
2628 {
2629         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2630                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2631         {
2632                 STAT(AIR_FINISHED, this) = 0;
2633                 return;
2634         }
2635
2636         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2637         {
2638                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2639                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2640                 STAT(AIR_FINISHED, this) = 0;
2641         }
2642         else
2643         {
2644                 if (!STAT(AIR_FINISHED, this))
2645                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2646                 if (STAT(AIR_FINISHED, this) < time)
2647                 {       // drown!
2648                         if (this.pain_finished < time)
2649                         {
2650                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2651                                 this.pain_finished = time + 0.5;
2652                         }
2653                 }
2654         }
2655 }
2656
2657 .bool move_qcphysics;
2658
2659 void Player_Physics(entity this)
2660 {
2661         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2662
2663         if(!this.move_qcphysics)
2664                 return;
2665
2666         if(!frametime && !CS(this).pm_frametime)
2667                 return;
2668
2669         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2670
2671         CS(this).pm_frametime = 0;
2672 }
2673
2674 /*
2675 =============
2676 PlayerPostThink
2677
2678 Called every frame for each client after the physics are run
2679 =============
2680 */
2681 void PlayerPostThink (entity this)
2682 {
2683         Player_Physics(this);
2684
2685         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2686         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2687         if (IS_REAL_CLIENT(this))
2688         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2689         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2690         {
2691                 int totalClients = 0;
2692                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2693                 {
2694                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2695                         if (server_is_dedicated)
2696                         {
2697                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2698                                 {
2699                                         ++totalClients;
2700                                 });
2701                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2702                                         totalClients = 0;
2703                         }
2704                 }
2705                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2706                 {
2707                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2708                         {
2709                                 ++totalClients;
2710                         });
2711                 }
2712
2713                 if (totalClients < autocvar_sv_maxidle_minplayers)
2714                 {
2715                         // idle kick disabled
2716                         CS(this).parm_idlesince = time;
2717                 }
2718                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2719                 {
2720                         if (CS(this).idlekick_lasttimeleft)
2721                         {
2722                                 CS(this).idlekick_lasttimeleft = 0;
2723                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2724                         }
2725                 }
2726                 else
2727                 {
2728                         float maxidle_time = autocvar_sv_maxidle;
2729                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2730                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2731                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2732                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2733                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2734                         {
2735                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2736                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2737                                 else
2738                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2739                         }
2740                         if (timeleft <= 0) {
2741                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2742                                 {
2743                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2744                                         PutObserverInServer(this, true);
2745                                 }
2746                                 else
2747                                 {
2748                                         if (dropclient_schedule(this))
2749                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2750                                 }
2751                                 return;
2752                         }
2753                         else if (timeleft <= countdown_time) {
2754                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2755                                         play2(this, SND(TALK2));
2756                                 CS(this).idlekick_lasttimeleft = timeleft;
2757                         }
2758                 }
2759         }
2760
2761         CheatFrame(this);
2762
2763         if (game_stopped)
2764         {
2765                 this.solid = SOLID_NOT;
2766                 this.takedamage = DAMAGE_NO;
2767                 set_movetype(this, MOVETYPE_NONE);
2768                 CS(this).teamkill_complain = 0;
2769                 CS(this).teamkill_soundtime = 0;
2770                 CS(this).teamkill_soundsource = NULL;
2771         }
2772
2773         if (IS_PLAYER(this)) {
2774                 if(this.death_time == time && IS_DEAD(this))
2775                 {
2776                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2777                         // once all the damage events of this frame have been processed with normal size
2778                         this.maxs.z = 5;
2779                         setsize(this, this.mins, this.maxs);
2780                 }
2781                 DrownPlayer(this);
2782                 UpdateChatBubble(this);
2783                 if (CS(this).impulse) ImpulseCommands(this);
2784                 GetPressedKeys(this);
2785                 if (game_stopped)
2786                 {
2787                         CSQCMODEL_AUTOUPDATE(this);
2788                         return;
2789                 }
2790         }
2791         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2792         {
2793                 CS(this).pressedkeys = 0;
2794                 STAT(PRESSED_KEYS, this) = 0;
2795         }
2796
2797         if (this.waypointsprite_attachedforcarrier) {
2798                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2799                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2800         }
2801
2802         CSQCMODEL_AUTOUPDATE(this);
2803 }
2804
2805 // hack to copy the button fields from the client entity to the Client State
2806 void PM_UpdateButtons(entity this, entity store)
2807 {
2808         if(this.impulse)
2809                 store.impulse = this.impulse;
2810         this.impulse = 0;
2811
2812         bool typing = this.buttonchat || this.button12;
2813
2814         store.button0 = (typing) ? 0 : this.button0;
2815         //button1?!
2816         store.button2 = (typing) ? 0 : this.button2;
2817         store.button3 = (typing) ? 0 : this.button3;
2818         store.button4 = this.button4;
2819         store.button5 = (typing) ? 0 : this.button5;
2820         store.button6 = this.button6;
2821         store.button7 = this.button7;
2822         store.button8 = this.button8;
2823         store.button9 = this.button9;
2824         store.button10 = this.button10;
2825         store.button11 = this.button11;
2826         store.button12 = this.button12;
2827         store.button13 = this.button13;
2828         store.button14 = this.button14;
2829         store.button15 = this.button15;
2830         store.button16 = this.button16;
2831         store.buttonuse = this.buttonuse;
2832         store.buttonchat = this.buttonchat;
2833
2834         store.cursor_active = this.cursor_active;
2835         store.cursor_screen = this.cursor_screen;
2836         store.cursor_trace_start = this.cursor_trace_start;
2837         store.cursor_trace_endpos = this.cursor_trace_endpos;
2838         store.cursor_trace_ent = this.cursor_trace_ent;
2839
2840         store.ping = this.ping;
2841         store.ping_packetloss = this.ping_packetloss;
2842         store.ping_movementloss = this.ping_movementloss;
2843
2844         store.v_angle = this.v_angle;
2845         store.movement = this.movement;
2846 }
2847
2848 NET_HANDLE(fpsreport, bool)
2849 {
2850         int fps = ReadShort();
2851         PlayerScore_Set(sender, SP_FPS, fps);
2852         return true;
2853 }