qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/state.qh>
  34 #include <common/stats.qh>
  35 #include <common/vehicles/all.qh>
  36 #include <common/vehicles/sv_vehicles.qh>
  37 #include <common/viewloc.qh>
  38 #include <common/weapons/_all.qh>
  39 #include <common/weapons/weapon/vortex.qh>
  40 #include <common/wepent.qh>
  41 #include <lib/csqcmodel/sv_model.qh>
  42 #include <lib/warpzone/common.qh>
  43 #include <lib/warpzone/server.qh>
  44 #include <server/anticheat.qh>
  45 #include <server/antilag.qh>
  46 #include <server/bot/api.qh>
  47 #include <server/bot/default/cvars.qh>
  48 #include <server/campaign.qh>
  49 #include <server/chat.qh>
  50 #include <server/cheats.qh>
  51 #include <server/clientkill.qh>
  52 #include <server/command/common.qh>
  53 #include <server/command/common.qh>
  54 #include <server/command/vote.qh>
  55 #include <server/compat/quake3.qh>
  56 #include <server/damage.qh>
  57 #include <server/gamelog.qh>
  58 #include <server/handicap.qh>
  59 #include <server/hook.qh>
  60 #include <server/impulse.qh>
  61 #include <server/intermission.qh>
  62 #include <server/ipban.qh>
  63 #include <server/main.qh>
  64 #include <server/mutators/_mod.qh>
  65 #include <server/player.qh>
  66 #include <server/portals.qh>
  67 #include <server/race.qh>
  68 #include <server/resources.qh>
  69 #include <server/scores.qh>
  70 #include <server/scores_rules.qh>
  71 #include <server/spawnpoints.qh>
  72 #include <server/teamplay.qh>
  73 #include <server/weapons/accuracy.qh>
  74 #include <server/weapons/common.qh>
  75 #include <server/weapons/hitplot.qh>
  76 #include <server/weapons/selection.qh>
  77 #include <server/weapons/tracing.qh>
  78 #include <server/weapons/weaponsystem.qh>
  79 #include <server/world.qh>
  80
  81 STATIC_METHOD(Client, Add, void(Client this, int _team))
  82 {
  83     ClientConnect(this);
  84     TRANSMUTE(Player, this);
  85     this.frame = 12; // 7
  86     this.team = _team;
  87     PutClientInServer(this);
  88 }
  89
  90 STATIC_METHOD(Client, Remove, void(Client this))
  91 {
  92     TRANSMUTE(Observer, this);
  93     PutClientInServer(this);
  94     ClientDisconnect(this);
  95 }
  96
  97 void send_CSQC_teamnagger() {
  98         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  99 }
 100
 101 int CountSpectators(entity player, entity to)
 102 {
 103         if(!player) { return 0; } // not sure how, but best to be safe
 104
 105         int spec_count = 0;
 106
 107         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 108         {
 109                 spec_count++;
 110         });
 111
 112         return spec_count;
 113 }
 114
 115 void WriteSpectators(entity player, entity to)
 116 {
 117         if(!player) { return; } // not sure how, but best to be safe
 118
 119         int spec_count = 0;
 120         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 121         {
 122                 if(spec_count >= MAX_SPECTATORS)
 123                         break;
 124                 WriteByte(MSG_ENTITY, num_for_edict(it));
 125                 ++spec_count;
 126         });
 127 }
 128
 129 bool ClientData_Send(entity this, entity to, int sf)
 130 {
 131         assert(to == this.owner, return false);
 132
 133         entity e = to;
 134         if (IS_SPEC(e)) e = e.enemy;
 135
 136         sf = 0;
 137         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 138         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 139         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 140         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 141
 142         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 143         WriteByte(MSG_ENTITY, sf);
 144
 145         if (sf & BIT(1))
 146                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 147
 148         if(sf & BIT(4))
 149         {
 150                 float specs = CountSpectators(e, to);
 151                 WriteByte(MSG_ENTITY, specs);
 152                 WriteSpectators(e, to);
 153         }
 154
 155         return true;
 156 }
 157
 158 void ClientData_Attach(entity this)
 159 {
 160         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 161         CS(this).clientdata.drawonlytoclient = this;
 162         CS(this).clientdata.owner = this;
 163 }
 164
 165 void ClientData_Detach(entity this)
 166 {
 167         delete(CS(this).clientdata);
 168         CS(this).clientdata = NULL;
 169 }
 170
 171 void ClientData_Touch(entity e)
 172 {
 173         entity cd = CS(e).clientdata;
 174         if (cd) { cd.SendFlags = 1; }
 175
 176         // make it spectatable
 177         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 178         {
 179                 entity cd = CS(it).clientdata;
 180                 if (cd) { cd.SendFlags = 1; }
 181         });
 182 }
 183
 184
 185 /*
 186 =============
 187 CheckPlayerModel
 188
 189 Checks if the argument string can be a valid playermodel.
 190 Returns a valid one in doubt.
 191 =============
 192 */
 193 string FallbackPlayerModel;
 194 string CheckPlayerModel(string plyermodel) {
 195         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 196         {
 197                 // note: we cannot summon Don Strunzone here, some player may
 198                 // still have the model string set. In case anyone manages how
 199                 // to change a cvar default, we'll have a small leak here.
 200                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 201         }
 202         // only in right path
 203         if(substring(plyermodel, 0, 14) != "models/player/")
 204                 return FallbackPlayerModel;
 205         // only good file extensions
 206         if(substring(plyermodel, -4, 4) != ".iqm"
 207                 && substring(plyermodel, -4, 4) != ".zym"
 208                 && substring(plyermodel, -4, 4) != ".dpm"
 209                 && substring(plyermodel, -4, 4) != ".md3"
 210                 && substring(plyermodel, -4, 4) != ".psk")
 211         {
 212                 return FallbackPlayerModel;
 213         }
 214         // forbid the LOD models
 215         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 216                 return FallbackPlayerModel;
 217         if(plyermodel != strtolower(plyermodel))
 218                 return FallbackPlayerModel;
 219         // also, restrict to server models
 220         if(autocvar_sv_servermodelsonly)
 221         {
 222                 if(!fexists(plyermodel))
 223                         return FallbackPlayerModel;
 224         }
 225         return plyermodel;
 226 }
 227
 228 void setplayermodel(entity e, string modelname)
 229 {
 230         precache_model(modelname);
 231         _setmodel(e, modelname);
 232         player_setupanimsformodel(e);
 233         if(!autocvar_g_debug_globalsounds)
 234                 UpdatePlayerSounds(e);
 235 }
 236
 237 bool SpectateNext(entity this);
 238
 239 /** putting a client as observer in the server */
 240 void PutObserverInServer(entity this, bool is_forced)
 241 {
 242         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 243         PlayerState_detach(this);
 244
 245         if (IS_PLAYER(this))
 246         {
 247                 if(GetResource(this, RES_HEALTH) >= 1)
 248                 {
 249                         // despawn effect
 250                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 251                 }
 252
 253                 // was a player, recount votes and ready status
 254                 if(IS_REAL_CLIENT(this))
 255                 {
 256                         if (vote_called) { VoteCount(false); }
 257                         ReadyCount();
 258                 }
 259                 entcs_update_players(this);
 260         }
 261
 262         entity spot = SelectSpawnPoint(this, true);
 263         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 264         this.angles = vec2(spot.angles);
 265         this.fixangle = true;
 266         // offset it so that the spectator spawns higher off the ground, looks better this way
 267         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 268         if (IS_REAL_CLIENT(this))
 269         {
 270                 msg_entity = this;
 271                 WriteByte(MSG_ONE, SVC_SETVIEW);
 272                 WriteEntity(MSG_ONE, this);
 273         }
 274         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 275         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 276         if(!autocvar_g_debug_globalsounds)
 277         {
 278                 // needed for player sounds
 279                 this.model = "";
 280                 FixPlayermodel(this);
 281         }
 282         setmodel(this, MDL_Null);
 283         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 284         this.view_ofs = '0 0 0';
 285
 286         RemoveGrapplingHooks(this);
 287         Portal_ClearAll(this);
 288         Unfreeze(this, false);
 289         SetSpectatee(this, NULL);
 290
 291         if (this.alivetime)
 292         {
 293                 if (!warmup_stage)
 294                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 295                 this.alivetime = 0;
 296         }
 297
 298         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 299
 300         WaypointSprite_PlayerDead(this);
 301
 302         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 303                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 304
 305         accuracy_resend(this);
 306
 307         CS(this).spectatortime = time;
 308         if(this.bot_attack)
 309                 IL_REMOVE(g_bot_targets, this);
 310         this.bot_attack = false;
 311         if(this.monster_attack)
 312                 IL_REMOVE(g_monster_targets, this);
 313         this.monster_attack = false;
 314         STAT(HUD, this) = HUD_NORMAL;
 315         TRANSMUTE(Observer, this);
 316         this.iscreature = false;
 317         this.teleportable = TELEPORT_SIMPLE;
 318         if(this.damagedbycontents)
 319                 IL_REMOVE(g_damagedbycontents, this);
 320         this.damagedbycontents = false;
 321         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 322         SetSpectatee_status(this, etof(this));
 323         this.takedamage = DAMAGE_NO;
 324         this.solid = SOLID_NOT;
 325         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 326         this.flags = FL_CLIENT | FL_NOTARGET;
 327         this.effects = 0;
 328         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 329         this.pauserotarmor_finished = 0;
 330         this.pauserothealth_finished = 0;
 331         this.pauseregen_finished = 0;
 332         this.damageforcescale = 0;
 333         this.death_time = 0;
 334         this.respawn_flags = 0;
 335         this.respawn_time = 0;
 336         STAT(RESPAWN_TIME, this) = 0;
 337         this.alpha = 0;
 338         this.scale = 0;
 339         this.fade_time = 0;
 340         this.pain_finished = 0;
 341         STAT(AIR_FINISHED, this) = 0;
 342         //this.dphitcontentsmask = 0;
 343         this.dphitcontentsmask = DPCONTENTS_SOLID;
 344         if (autocvar_g_playerclip_collisions)
 345                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 346         this.pushltime = 0;
 347         this.istypefrag = 0;
 348         setthink(this, func_null);
 349         this.nextthink = 0;
 350         this.deadflag = DEAD_NO;
 351         UNSET_DUCKED(this);
 352         STAT(REVIVE_PROGRESS, this) = 0;
 353         this.revival_time = 0;
 354         this.draggable = drag_undraggable;
 355
 356         this.items = 0;
 357         STAT(WEAPONS, this) = '0 0 0';
 358         this.drawonlytoclient = this;
 359
 360         this.viewloc = NULL;
 361
 362         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 363
 364         this.weaponmodel = "";
 365         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 366         {
 367                 this.weaponentities[slot] = NULL;
 368         }
 369         this.exteriorweaponentity = NULL;
 370         CS(this).killcount = FRAGS_SPECTATOR;
 371         this.velocity = '0 0 0';
 372         this.avelocity = '0 0 0';
 373         this.punchangle = '0 0 0';
 374         this.punchvector = '0 0 0';
 375         this.oldvelocity = this.velocity;
 376         this.event_damage = func_null;
 377         this.event_heal = func_null;
 378
 379         for(int slot = 0; slot < MAX_AXH; ++slot)
 380         {
 381                 entity axh = this.(AuxiliaryXhair[slot]);
 382                 this.(AuxiliaryXhair[slot]) = NULL;
 383
 384                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 385                         delete(axh);
 386         }
 387
 388         if (mutator_returnvalue)
 389         {
 390                 // mutator prevents resetting teams+score
 391         }
 392         else
 393         {
 394                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 395                 this.frags = FRAGS_SPECTATOR;
 396         }
 397
 398         bot_relinkplayerlist();
 399
 400         if (CS(this).just_joined)
 401                 CS(this).just_joined = false;
 402
 403         // force members of alive squads to spectate another squadmate
 404         if(IS_REAL_CLIENT(this) && IN_SQUAD(this) && !this.br_squad.br_squad_dead)
 405         {
 406                 SpectateNext(this);
 407                 TRANSMUTE(Spectator, this);
 408         }
 409 }
 410
 411 int player_getspecies(entity this)
 412 {
 413         get_model_parameters(this.model, this.skin);
 414         int s = get_model_parameters_species;
 415         get_model_parameters(string_null, 0);
 416         if (s < 0) return SPECIES_HUMAN;
 417         return s;
 418 }
 419
 420 .float model_randomizer;
 421 void FixPlayermodel(entity player)
 422 {
 423         string defaultmodel = "";
 424         int defaultskin = 0;
 425         if(autocvar_sv_defaultcharacter)
 426         {
 427                 if(teamplay)
 428                 {
 429                         switch(player.team)
 430                         {
 431                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 432                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 433                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 434                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 435                         }
 436                 }
 437
 438                 if(defaultmodel == "")
 439                 {
 440                         defaultmodel = autocvar_sv_defaultplayermodel;
 441                         defaultskin = autocvar_sv_defaultplayerskin;
 442                 }
 443
 444                 int n = tokenize_console(defaultmodel);
 445                 if(n > 0)
 446                 {
 447                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 448                         // However, do NOT randomize if the player-selected model is in the list.
 449                         for (int i = 0; i < n; ++i)
 450                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 451                                         defaultmodel = argv(i);
 452                 }
 453
 454                 int i = strstrofs(defaultmodel, ":", 0);
 455                 if(i >= 0)
 456                 {
 457                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 458                         defaultmodel = substring(defaultmodel, 0, i);
 459                 }
 460         }
 461         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 462         {
 463                 if(teamplay)
 464                 {
 465                         switch(player.team)
 466                         {
 467                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 468                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 469                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 470                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 471                         }
 472                 }
 473
 474                 if(!defaultskin)
 475                         defaultskin = autocvar_sv_defaultplayerskin;
 476         }
 477
 478         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 479         defaultmodel = M_ARGV(0, string);
 480         defaultskin = M_ARGV(1, int);
 481
 482         bool chmdl = false;
 483         int oldskin;
 484         if(defaultmodel != "")
 485         {
 486                 if (defaultmodel != player.model)
 487                 {
 488                         vector m1 = player.mins;
 489                         vector m2 = player.maxs;
 490                         setplayermodel (player, defaultmodel);
 491                         setsize (player, m1, m2);
 492                         chmdl = true;
 493                 }
 494
 495                 oldskin = player.skin;
 496                 player.skin = defaultskin;
 497         } else {
 498                 if (player.playermodel != player.model || player.playermodel == "")
 499                 {
 500                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 501                         vector m1 = player.mins;
 502                         vector m2 = player.maxs;
 503                         setplayermodel (player, player.playermodel);
 504                         setsize (player, m1, m2);
 505                         chmdl = true;
 506                 }
 507
 508                 if(!autocvar_sv_defaultcharacterskin)
 509                 {
 510                         oldskin = player.skin;
 511                         player.skin = stof(player.playerskin);
 512                 }
 513                 else
 514                 {
 515                         oldskin = player.skin;
 516                         player.skin = defaultskin;
 517                 }
 518         }
 519
 520         if(chmdl || oldskin != player.skin) // model or skin has changed
 521         {
 522                 player.species = player_getspecies(player); // update species
 523                 if(!autocvar_g_debug_globalsounds)
 524                         UpdatePlayerSounds(player); // update skin sounds
 525         }
 526
 527         if(!teamplay)
 528                 if(strlen(autocvar_sv_defaultplayercolors))
 529                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 530                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 531 }
 532
 533 void PutPlayerInServer(entity this)
 534 {
 535         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 536
 537         PlayerState_attach(this);
 538         accuracy_resend(this);
 539
 540         if (this.team < 0)
 541                 TeamBalance_JoinBestTeam(this);
 542
 543         entity spot = SelectSpawnPoint(this, false);
 544         if (!spot) {
 545                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 546                 return; // spawn failed
 547         }
 548
 549         TRANSMUTE(Player, this);
 550
 551         CS(this).wasplayer = true;
 552         this.iscreature = true;
 553         this.teleportable = TELEPORT_NORMAL;
 554         if(!this.damagedbycontents)
 555                 IL_PUSH(g_damagedbycontents, this);
 556         this.damagedbycontents = true;
 557         set_movetype(this, MOVETYPE_WALK);
 558         this.solid = SOLID_SLIDEBOX;
 559         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 560         if (autocvar_g_playerclip_collisions)
 561                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 562         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 563                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 564         this.frags = FRAGS_PLAYER;
 565         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 566         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 567         if (autocvar__notarget)
 568                 this.flags |= FL_NOTARGET;
 569         this.takedamage = DAMAGE_AIM;
 570         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 571
 572         if (warmup_stage) {
 573                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 574                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 575                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 576                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 577                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 578                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 579                 SetResource(this, RES_HEALTH, warmup_start_health);
 580                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 581                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 582         } else {
 583                 SetResource(this, RES_SHELLS, start_ammo_shells);
 584                 SetResource(this, RES_BULLETS, start_ammo_nails);
 585                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 586                 SetResource(this, RES_CELLS, start_ammo_cells);
 587                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 588                 SetResource(this, RES_FUEL, start_ammo_fuel);
 589                 SetResource(this, RES_HEALTH, start_health);
 590                 SetResource(this, RES_ARMOR, start_armorvalue);
 591                 STAT(WEAPONS, this) = start_weapons;
 592                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 593                 {
 594                         GiveRandomWeapons(this, random_start_weapons_count,
 595                                 autocvar_g_random_start_weapons, random_start_ammo);
 596                 }
 597         }
 598         SetSpectatee_status(this, 0);
 599
 600         PS(this).dual_weapons = '0 0 0';
 601
 602         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 603                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 604
 605         this.items = start_items;
 606
 607         float shieldtime = time + autocvar_g_spawnshieldtime;
 608
 609         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 610         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 611         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 612         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 613         if (!sv_ready_restart_after_countdown && time < game_starttime)
 614         {
 615                 float f = game_starttime - time;
 616                 shieldtime += f;
 617                 this.pauserotarmor_finished += f;
 618                 this.pauserothealth_finished += f;
 619                 this.pauseregen_finished += f;
 620         }
 621
 622         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 623
 624         this.damageforcescale = autocvar_g_player_damageforcescale;
 625         this.death_time = 0;
 626         this.respawn_flags = 0;
 627         this.respawn_time = 0;
 628         STAT(RESPAWN_TIME, this) = 0;
 629         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 630         this.fade_time = 0;
 631         this.pain_finished = 0;
 632         this.pushltime = 0;
 633         setthink(this, func_null); // players have no think function
 634         this.nextthink = 0;
 635         this.dmg_team = 0;
 636         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 637
 638         this.deadflag = DEAD_NO;
 639
 640         this.angles = spot.angles;
 641         this.angles_z = 0; // never spawn tilted even if the spot says to
 642         if (IS_BOT_CLIENT(this))
 643         {
 644                 this.v_angle = this.angles;
 645                 bot_aim_reset(this);
 646         }
 647         this.fixangle = true; // turn this way immediately
 648         this.oldvelocity = this.velocity = '0 0 0';
 649         this.avelocity = '0 0 0';
 650         this.punchangle = '0 0 0';
 651         this.punchvector = '0 0 0';
 652
 653         STAT(REVIVE_PROGRESS, this) = 0;
 654         this.revival_time = 0;
 655
 656         STAT(AIR_FINISHED, this) = 0;
 657         this.waterlevel = WATERLEVEL_NONE;
 658         this.watertype = CONTENT_EMPTY;
 659
 660         if(STAT(DROP, this) != DROP_TRANSPORT)
 661         {
 662                 entity spawnevent = new_pure(spawnevent);
 663                 spawnevent.owner = this;
 664                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 665         }
 666
 667         // Cut off any still running player sounds.
 668         stopsound(this, CH_PLAYER_SINGLE);
 669
 670         this.model = "";
 671         FixPlayermodel(this);
 672         this.drawonlytoclient = NULL;
 673
 674         this.viewloc = NULL;
 675
 676         for(int slot = 0; slot < MAX_AXH; ++slot)
 677         {
 678                 entity axh = this.(AuxiliaryXhair[slot]);
 679                 this.(AuxiliaryXhair[slot]) = NULL;
 680
 681                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 682                         delete(axh);
 683         }
 684
 685         this.spawnpoint_targ = NULL;
 686
 687         UNSET_DUCKED(this);
 688         this.view_ofs = STAT(PL_VIEW_OFS, this);
 689         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 690         this.spawnorigin = spot.origin;
 691         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 692         // don't reset back to last position, even if new position is stuck in solid
 693         this.oldorigin = this.origin;
 694         if(this.conveyor)
 695                 IL_REMOVE(g_conveyed, this);
 696         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 697         if(this.swampslug)
 698                 IL_REMOVE(g_swamped, this);
 699         this.swampslug = NULL;
 700         this.swamp_interval = 0;
 701         if(this.ladder_entity)
 702                 IL_REMOVE(g_ladderents, this);
 703         this.ladder_entity = NULL;
 704         IL_EACH(g_counters, it.realowner == this,
 705         {
 706                 delete(it);
 707         });
 708         STAT(HUD, this) = HUD_NORMAL;
 709
 710         this.event_damage = PlayerDamage;
 711         this.event_heal = PlayerHeal;
 712
 713         this.draggable = func_null;
 714
 715         if(!this.bot_attack)
 716                 IL_PUSH(g_bot_targets, this);
 717         this.bot_attack = true;
 718         if(!this.monster_attack)
 719                 IL_PUSH(g_monster_targets, this);
 720         this.monster_attack = true;
 721         navigation_dynamicgoal_init(this, false);
 722
 723         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 724
 725         // player was spectator
 726         if (CS(this).killcount == FRAGS_SPECTATOR) {
 727                 PlayerScore_Clear(this);
 728                 CS(this).killcount = 0;
 729                 CS(this).startplaytime = time;
 730         }
 731
 732         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 733         {
 734                 .entity weaponentity = weaponentities[slot];
 735                 CL_SpawnWeaponentity(this, weaponentity);
 736         }
 737         this.alpha = default_player_alpha;
 738         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 739         this.exteriorweaponentity.alpha = default_weapon_alpha;
 740
 741         this.speedrunning = false;
 742
 743         this.counter_cnt = 0;
 744         this.fragsfilter_cnt = 0;
 745
 746         target_voicescript_clear(this);
 747
 748         // reset fields the weapons may use
 749         FOREACH(Weapons, true, {
 750                 it.wr_resetplayer(it, this);
 751                         // reload all reloadable weapons
 752                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 753                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 754                         {
 755                                 .entity weaponentity = weaponentities[slot];
 756                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 757                         }
 758                 }
 759         });
 760
 761         Unfreeze(this, false);
 762
 763         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 764
 765         {
 766                 string s = spot.target;
 767                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 768                         spot.target = string_null;
 769                 SUB_UseTargets(spot, this, NULL);
 770                 if(g_assault || g_race)
 771                         spot.target = s;
 772         }
 773
 774         if (autocvar_spawn_debug)
 775         {
 776                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 777                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 778         }
 779
 780         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 781         {
 782                 .entity weaponentity = weaponentities[slot];
 783                 entity w_ent = this.(weaponentity);
 784                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 785                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 786                 else
 787                         w_ent.m_switchweapon = WEP_Null;
 788                 w_ent.m_weapon = WEP_Null;
 789                 w_ent.weaponname = "";
 790                 w_ent.m_switchingweapon = WEP_Null;
 791                 w_ent.cnt = -1;
 792         }
 793
 794         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 795
 796         if (CS(this).impulse) ImpulseCommands(this);
 797
 798         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 799         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 800         {
 801                 .entity weaponentity = weaponentities[slot];
 802                 W_WeaponFrame(this, weaponentity);
 803         }
 804
 805         if (!warmup_stage && !this.alivetime)
 806                 this.alivetime = time;
 807
 808         antilag_clear(this, CS(this));
 809 }
 810
 811 /** Called when a client spawns in the server */
 812 void PutClientInServer(entity this)
 813 {
 814         if (IS_BOT_CLIENT(this)) {
 815                 TRANSMUTE(Player, this);
 816         } else if (IS_REAL_CLIENT(this)) {
 817                 msg_entity = this;
 818                 WriteByte(MSG_ONE, SVC_SETVIEW);
 819                 WriteEntity(MSG_ONE, this);
 820         }
 821         if (game_stopped)
 822                 TRANSMUTE(Observer, this);
 823
 824         SetSpectatee(this, NULL);
 825
 826         // reset player keys
 827         if(PS(this))
 828                 PS(this).itemkeys = 0;
 829
 830         MUTATOR_CALLHOOK(PutClientInServer, this);
 831
 832         if (IS_OBSERVER(this)) {
 833                 PutObserverInServer(this, false);
 834         } else if (IS_PLAYER(this)) {
 835                 PutPlayerInServer(this);
 836         }
 837
 838         bot_relinkplayerlist();
 839 }
 840
 841 // TODO do we need all these fields, or should we stop autodetecting runtime
 842 // changes and just have a console command to update this?
 843 bool ClientInit_SendEntity(entity this, entity to, int sf)
 844 {
 845         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 846         return = true;
 847         msg_entity = to;
 848         // MSG_INIT replacement
 849         // TODO: make easier to use
 850         Registry_send_all();
 851         W_PROP_reload(MSG_ONE, to);
 852         ClientInit_misc(this);
 853         MUTATOR_CALLHOOK(Ent_Init);
 854 }
 855 void ClientInit_misc(entity this)
 856 {
 857         int channel = MSG_ONE;
 858         WriteHeader(channel, ENT_CLIENT_INIT);
 859         WriteByte(channel, g_nexball_meter_period * 32);
 860         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 861         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 862         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 863         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 864         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 865         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 866         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 867         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 868
 869         if(autocvar_sv_foginterval && world.fog != "")
 870                 WriteString(channel, world.fog);
 871         else
 872                 WriteString(channel, "");
 873         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 874         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 875         WriteByte(channel, serverflags);
 876         WriteCoord(channel, autocvar_g_trueaim_minrange);
 877 }
 878
 879 void ClientInit_CheckUpdate(entity this)
 880 {
 881         this.nextthink = time;
 882         if(this.count != autocvar_g_balance_armor_blockpercent)
 883         {
 884                 this.count = autocvar_g_balance_armor_blockpercent;
 885                 this.SendFlags |= 1;
 886         }
 887         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 888         {
 889                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 890                 this.SendFlags |= 1;
 891         }
 892 }
 893
 894 void ClientInit_Spawn()
 895 {
 896         entity e = new_pure(clientinit);
 897         setthink(e, ClientInit_CheckUpdate);
 898         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 899
 900         ClientInit_CheckUpdate(e);
 901 }
 902
 903 /*
 904 =============
 905 SetNewParms
 906 =============
 907 */
 908 void SetNewParms ()
 909 {
 910         // initialize parms for a new player
 911         parm1 = -(86400 * 366);
 912
 913         MUTATOR_CALLHOOK(SetNewParms);
 914 }
 915
 916 /*
 917 =============
 918 SetChangeParms
 919 =============
 920 */
 921 void SetChangeParms (entity this)
 922 {
 923         // save parms for level change
 924         parm1 = CS(this).parm_idlesince - time;
 925
 926         MUTATOR_CALLHOOK(SetChangeParms);
 927 }
 928
 929 /*
 930 =============
 931 DecodeLevelParms
 932 =============
 933 */
 934 void DecodeLevelParms(entity this)
 935 {
 936         // load parms
 937         CS(this).parm_idlesince = parm1;
 938         if (CS(this).parm_idlesince == -(86400 * 366))
 939                 CS(this).parm_idlesince = time;
 940
 941         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 942         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 943
 944         MUTATOR_CALLHOOK(DecodeLevelParms);
 945 }
 946
 947 void FixClientCvars(entity e)
 948 {
 949         // send prediction settings to the client
 950         stuffcmd(e, "\nin_bindmap 0 0\n");
 951         if(autocvar_g_antilag == 3) // client side hitscan
 952                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 953         if(autocvar_sv_gentle)
 954                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 955
 956         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 957         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 958
 959         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 960
 961         MUTATOR_CALLHOOK(FixClientCvars, e);
 962 }
 963
 964 bool findinlist_abbrev(string tofind, string list)
 965 {
 966         if(list == "" || tofind == "")
 967                 return false; // empty list or search, just return
 968
 969         // this function allows abbreviated strings!
 970         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 971         {
 972                 return true;
 973         });
 974
 975         return false;
 976 }
 977
 978 bool PlayerInIPList(entity p, string iplist)
 979 {
 980         // some safety checks (never allow local?)
 981         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 982                 return false;
 983
 984         return findinlist_abbrev(p.netaddress, iplist);
 985 }
 986
 987 bool PlayerInIDList(entity p, string idlist)
 988 {
 989         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 990         if(!p.crypto_idfp)
 991                 return false;
 992
 993         return findinlist_abbrev(p.crypto_idfp, idlist);
 994 }
 995
 996 bool PlayerInList(entity player, string list)
 997 {
 998         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 999 }
1000
1001 #ifdef DP_EXT_PRECONNECT
1002 /*
1003 =============
1004 ClientPreConnect
1005
1006 Called once (not at each match start) when a client begins a connection to the server
1007 =============
1008 */
1009 void ClientPreConnect(entity this)
1010 {
1011         if(autocvar_sv_eventlog)
1012         {
1013                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1014                         this.playerid,
1015                         etof(this),
1016                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1017                 ));
1018         }
1019 }
1020 #endif
1021
1022 string GetClientVersionMessage(entity this)
1023 {
1024         if (CS(this).version_mismatch) {
1025                 if(CS(this).version < autocvar_gameversion) {
1026                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1027                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1028                 } else {
1029                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1030                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1031                 }
1032         } else {
1033                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1034         }
1035 }
1036
1037 string getwelcomemessage(entity this)
1038 {
1039         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1040         string modifications = M_ARGV(0, string);
1041
1042         if(g_weaponarena)
1043         {
1044                 if(g_weaponarena_random)
1045                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1046                 else
1047                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1048         }
1049         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1050                 modifications = strcat(modifications, ", No start weapons");
1051         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1052                 modifications = strcat(modifications, ", Low gravity");
1053         if(g_weapon_stay && !g_cts)
1054                 modifications = strcat(modifications, ", Weapons stay");
1055         if(autocvar_g_jetpack)
1056                 modifications = strcat(modifications, ", Jet pack");
1057         modifications = substring(modifications, 2, strlen(modifications) - 2);
1058
1059         string versionmessage = GetClientVersionMessage(this);
1060         string s = strcat(versionmessage, "^8\n^8\nserver is ^9", autocvar_hostname, "^8\n");
1061
1062         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1063
1064         if(modifications != "")
1065                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1066
1067         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1068         {
1069                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1070                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1071         }
1072
1073         if (cache_mutatormsg != "") {
1074                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1075         }
1076
1077         string mutator_msg = "";
1078         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1079         mutator_msg = M_ARGV(0, string);
1080
1081         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1082
1083         string motd = autocvar_sv_motd;
1084         if (motd != "") {
1085                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1086         }
1087         return s;
1088 }
1089
1090 /**
1091 =============
1092 ClientConnect
1093
1094 Called when a client connects to the server
1095 =============
1096 */
1097 void ClientConnect(entity this)
1098 {
1099         if (Ban_MaybeEnforceBanOnce(this)) return;
1100         assert(!IS_CLIENT(this), return);
1101         this.flags |= FL_CLIENT;
1102         assert(player_count >= 0, player_count = 0);
1103
1104         TRANSMUTE(Client, this);
1105         CS(this).version_nagtime = time + 10 + random() * 10;
1106
1107         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1108
1109         bot_clientconnect(this);
1110
1111         Player_DetermineForcedTeam(this);
1112
1113         TRANSMUTE(Observer, this);
1114
1115         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1116
1117         // always track bots, don't ask for cl_allow_uidtracking
1118         if (IS_BOT_CLIENT(this))
1119                 PlayerStats_GameReport_AddPlayer(this);
1120         else
1121                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1122
1123         if (autocvar_sv_eventlog)
1124                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1125
1126         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1127
1128         stuffcmd(this, clientstuff, "\n");
1129         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1130
1131         FixClientCvars(this);
1132
1133         // get version info from player
1134         stuffcmd(this, "cmd clientversion $gameversion\n");
1135
1136         // notify about available teams
1137         if (teamplay)
1138         {
1139                 entity balance = TeamBalance_CheckAllowedTeams(this);
1140                 int t = TeamBalance_GetAllowedTeams(balance);
1141                 TeamBalance_Destroy(balance);
1142                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1143         }
1144         else
1145         {
1146                 stuffcmd(this, "set _teams_available 0\n");
1147         }
1148
1149         bot_relinkplayerlist();
1150
1151         CS(this).spectatortime = time;
1152         if (blockSpectators)
1153         {
1154                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1155         }
1156
1157         CS(this).jointime = time;
1158
1159         if (IS_REAL_CLIENT(this))
1160         {
1161                 if (g_weaponarena_weapons == WEPSET(TUBA))
1162                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1163         }
1164
1165         if (!autocvar_sv_foginterval && world.fog != "")
1166                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1167
1168         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1169                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1170                         send_CSQC_teamnagger();
1171
1172         CSQCMODEL_AUTOINIT(this);
1173
1174         CS(this).model_randomizer = random();
1175
1176         if (IS_REAL_CLIENT(this))
1177                 sv_notice_join(this);
1178
1179         this.move_qcphysics = autocvar_sv_qcphysics;
1180
1181         // update physics stats (players can spawn before physics runs)
1182         Physics_UpdateStats(this);
1183
1184         IL_EACH(g_initforplayer, it.init_for_player, {
1185                 it.init_for_player(it, this);
1186         });
1187
1188         Handicap_Initialize(this);
1189
1190         MUTATOR_CALLHOOK(ClientConnect, this);
1191
1192         if (IS_REAL_CLIENT(this))
1193         {
1194                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1195                 {
1196                         CS(this).motd_actived_time = -1;
1197                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1198                 }
1199         }
1200 }
1201 /*
1202 =============
1203 ClientDisconnect
1204
1205 Called when a client disconnects from the server
1206 =============
1207 */
1208 .entity chatbubbleentity;
1209 void player_powerups_remove_all(entity this);
1210
1211 void ClientDisconnect(entity this)
1212 {
1213         assert(IS_CLIENT(this), return);
1214
1215         PlayerStats_GameReport_FinalizePlayer(this);
1216         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1217         if (CS(this).active_minigame) part_minigame(this);
1218         if (IS_PLAYER(this) && (STAT(DROP, this) != DROP_TRANSPORT)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1219
1220         if (autocvar_sv_eventlog)
1221                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1222
1223         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1224
1225         if(IS_SPEC(this))
1226                 SetSpectatee(this, NULL);
1227
1228         MUTATOR_CALLHOOK(ClientDisconnect, this);
1229
1230         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1231         strfree(CS_CVAR(this).weaponorder_byimpulse);
1232         ClientState_detach(this);
1233
1234         Portal_ClearAll(this);
1235
1236         Unfreeze(this, false);
1237
1238         RemoveGrapplingHooks(this);
1239
1240         // Here, everything has been done that requires this player to be a client.
1241
1242         this.flags &= ~FL_CLIENT;
1243
1244         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1245         if (this.killindicator) delete(this.killindicator);
1246
1247         IL_EACH(g_counters, it.realowner == this,
1248         {
1249                 delete(it);
1250         });
1251
1252         WaypointSprite_PlayerGone(this);
1253
1254         bot_relinkplayerlist();
1255
1256         strfree(this.clientstatus);
1257         if (this.personal) delete(this.personal);
1258
1259         this.playerid = 0;
1260         ReadyCount();
1261         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1262
1263         player_powerups_remove_all(this); // stop powerup sound
1264
1265         ONREMOVE(this);
1266 }
1267
1268 void ChatBubbleThink(entity this)
1269 {
1270         this.nextthink = time;
1271         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1272         {
1273                 if(this.owner) // but why can that ever be NULL?
1274                         this.owner.chatbubbleentity = NULL;
1275                 delete(this);
1276                 return;
1277         }
1278
1279         this.mdl = "";
1280
1281         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1282         {
1283                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1284                         this.mdl = "models/sprites/minigame_busy.iqm";
1285                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1286                         this.mdl = "models/misc/chatbubble.spr";
1287         }
1288
1289         if ( this.model != this.mdl )
1290                 _setmodel(this, this.mdl);
1291
1292 }
1293
1294 void UpdateChatBubble(entity this)
1295 {
1296         if (this.alpha < 0)
1297                 return;
1298         // spawn a chatbubble entity if needed
1299         if (!this.chatbubbleentity)
1300         {
1301                 this.chatbubbleentity = new(chatbubbleentity);
1302                 this.chatbubbleentity.owner = this;
1303                 this.chatbubbleentity.exteriormodeltoclient = this;
1304                 setthink(this.chatbubbleentity, ChatBubbleThink);
1305                 this.chatbubbleentity.nextthink = time;
1306                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1307                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1308                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1309                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1310                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1311                 //this.chatbubbleentity.model = "";
1312                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1313         }
1314 }
1315
1316 void calculate_player_respawn_time(entity this)
1317 {
1318         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1319                 return;
1320
1321         float gametype_setting_tmp;
1322         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1323         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1324         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1325         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1326         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1327         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1328
1329         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1330         if (teamplay)
1331         {
1332                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1333                         if(it.team == this.team)
1334                                 ++pcount;
1335                 });
1336                 if (sdelay_small_count == 0)
1337                         sdelay_small_count = 1;
1338                 if (sdelay_large_count == 0)
1339                         sdelay_large_count = 1;
1340         }
1341         else
1342         {
1343                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1344                         ++pcount;
1345                 });
1346                 if (sdelay_small_count == 0)
1347                 {
1348                         if (IS_INDEPENDENT_PLAYER(this))
1349                         {
1350                                 // Players play independently. No point in requiring enemies.
1351                                 sdelay_small_count = 1;
1352                         }
1353                         else
1354                         {
1355                                 // Players play AGAINST each other. Enemies required.
1356                                 sdelay_small_count = 2;
1357                         }
1358                 }
1359                 if (sdelay_large_count == 0)
1360                 {
1361                         if (IS_INDEPENDENT_PLAYER(this))
1362                         {
1363                                 // Players play independently. No point in requiring enemies.
1364                                 sdelay_large_count = 1;
1365                         }
1366                         else
1367                         {
1368                                 // Players play AGAINST each other. Enemies required.
1369                                 sdelay_large_count = 2;
1370                         }
1371                 }
1372         }
1373
1374         float sdelay;
1375
1376         if (pcount <= sdelay_small_count)
1377                 sdelay = sdelay_small;
1378         else if (pcount >= sdelay_large_count)
1379                 sdelay = sdelay_large;
1380         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1381                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1382
1383         if(waves)
1384                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1385         else
1386                 this.respawn_time = time + sdelay;
1387
1388         if(sdelay < sdelay_max)
1389                 this.respawn_time_max = time + sdelay_max;
1390         else
1391                 this.respawn_time_max = this.respawn_time;
1392
1393         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1394                 this.respawn_countdown = 10; // first number to count down from is 10
1395         else
1396                 this.respawn_countdown = -1; // do not count down
1397
1398         if(autocvar_g_forced_respawn)
1399                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1400 }
1401
1402 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1403 // added to the model skins
1404 /*void UpdateColorModHack()
1405 {
1406         float c;
1407         c = this.clientcolors & 15;
1408         // LordHavoc: only bothering to support white, green, red, yellow, blue
1409              if (!teamplay) this.colormod = '0 0 0';
1410         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1411         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1412         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1413         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1414         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1415         else this.colormod = '1 1 1';
1416 }*/
1417
1418 void respawn(entity this)
1419 {
1420         bool damagedbycontents_prev = this.damagedbycontents;
1421         if(this.alpha >= 0)
1422         {
1423                 if(autocvar_g_respawn_ghosts)
1424                 {
1425                         this.solid = SOLID_NOT;
1426                         this.takedamage = DAMAGE_NO;
1427                         this.damagedbycontents = false;
1428                         set_movetype(this, MOVETYPE_FLY);
1429                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1430                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1431                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1432                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1433                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1434                         if(autocvar_g_respawn_ghosts_time > 0)
1435                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1436                 }
1437                 else
1438                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1439         }
1440
1441         CopyBody(this, 1);
1442         this.damagedbycontents = damagedbycontents_prev;
1443
1444         this.effects |= EF_NODRAW; // prevent another CopyBody
1445         PutClientInServer(this);
1446 }
1447
1448 void play_countdown(entity this, float finished, Sound samp)
1449 {
1450         TC(Sound, samp);
1451         if(IS_REAL_CLIENT(this))
1452                 if(floor(finished - time - frametime) != floor(finished - time))
1453                         if(finished - time < 6)
1454                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1455 }
1456
1457 void player_powerups_remove_all(entity this)
1458 {
1459         if (this.items & IT_SUPERWEAPON)
1460         {
1461                 // don't play the poweroff sound when the game restarts or the player disconnects
1462                 if (time > game_starttime + 1 && IS_CLIENT(this))
1463                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1464                 stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1465                 this.items -= (this.items & IT_SUPERWEAPON);
1466         }
1467 }
1468
1469 void player_powerups(entity this)
1470 {
1471         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1472                 this.modelflags |= MF_ROCKET;
1473         else
1474                 this.modelflags &= ~MF_ROCKET;
1475
1476         this.effects &= ~EF_NODEPTHTEST;
1477
1478         if (IS_DEAD(this))
1479                 player_powerups_remove_all(this);
1480
1481         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1482                 return;
1483
1484         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1485         int items_prev = this.items;
1486
1487         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1488         {
1489                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1490                 if (this.items & IT_SUPERWEAPON)
1491                 {
1492                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1493                         {
1494                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1495                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1496                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1497                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1498                         }
1499                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1500                         {
1501                                 // don't let them run out
1502                         }
1503                         else
1504                         {
1505                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1506                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1507                                 {
1508                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1509                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1510                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1511                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1512                                 }
1513                         }
1514                 }
1515                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1516                 {
1517                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1518                         {
1519                                 this.items = this.items | IT_SUPERWEAPON;
1520                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1521                                 {
1522                                         if(!g_cts)
1523                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1524                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1525                                 }
1526                         }
1527                         else
1528                         {
1529                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1530                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1531                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1532                         }
1533                 }
1534                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1535                 {
1536                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1537                 }
1538         }
1539
1540         if(autocvar_g_nodepthtestplayers)
1541                 this.effects = this.effects | EF_NODEPTHTEST;
1542
1543         if(autocvar_g_fullbrightplayers)
1544                 this.effects = this.effects | EF_FULLBRIGHT;
1545
1546         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1547 }
1548
1549 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1550 {
1551         if(current > stable)
1552                 return current;
1553         else if(current > stable - 0.25) // when close enough, "snap"
1554                 return stable;
1555         else
1556                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1557 }
1558
1559 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1560 {
1561         if(current < stable)
1562                 return current;
1563         else if(current < stable + 0.25) // when close enough, "snap"
1564                 return stable;
1565         else
1566                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1567 }
1568
1569 void RotRegen(entity this, int res, float limit_mod,
1570         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1571         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1572 {
1573         float old = GetResource(this, res);
1574         float current = old;
1575         if(current > rotstable)
1576         {
1577                 if(rotframetime > 0)
1578                 {
1579                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1580                         current = max(rotstable, current - rotlinear * rotframetime);
1581                 }
1582         }
1583         else if(current < regenstable)
1584         {
1585                 if(regenframetime > 0)
1586                 {
1587                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1588                         current = min(regenstable, current + regenlinear * regenframetime);
1589                 }
1590         }
1591
1592         float limit = GetResourceLimit(this, res) * limit_mod;
1593         if(current > limit)
1594                 current = limit;
1595
1596         if (current != old)
1597                 SetResource(this, res, current);
1598 }
1599
1600 void player_regen(entity this)
1601 {
1602         float max_mod, regen_mod, rot_mod, limit_mod;
1603         max_mod = regen_mod = rot_mod = limit_mod = 1;
1604
1605         float regen_health = autocvar_g_balance_health_regen;
1606         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1607         float regen_health_rot = autocvar_g_balance_health_rot;
1608         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1609         float regen_health_stable = autocvar_g_balance_health_regenstable;
1610         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1611         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1612                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1613         max_mod = M_ARGV(1, float);
1614         regen_mod = M_ARGV(2, float);
1615         rot_mod = M_ARGV(3, float);
1616         limit_mod = M_ARGV(4, float);
1617         regen_health = M_ARGV(5, float);
1618         regen_health_linear = M_ARGV(6, float);
1619         regen_health_rot = M_ARGV(7, float);
1620         regen_health_rotlinear = M_ARGV(8, float);
1621         regen_health_stable = M_ARGV(9, float);
1622         regen_health_rotstable = M_ARGV(10, float);
1623
1624         float rotstable, regenstable, rotframetime, regenframetime;
1625
1626         if(!mutator_returnvalue)
1627         if(!STAT(FROZEN, this))
1628         {
1629                 regenstable = autocvar_g_balance_armor_regenstable;
1630                 rotstable = autocvar_g_balance_armor_rotstable;
1631                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1632                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1633                 RotRegen(this, RES_ARMOR, limit_mod,
1634                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1635                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1636
1637                 // NOTE: max_mod is only applied to health
1638                 regenstable = regen_health_stable * max_mod;
1639                 rotstable = regen_health_rotstable * max_mod;
1640                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1641                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1642                 RotRegen(this, RES_HEALTH, limit_mod,
1643                         regenstable, regen_health, regen_health_linear, regenframetime,
1644                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1645         }
1646
1647         // if player rotted to death...  die!
1648         // check this outside above checks, as player may still be able to rot to death
1649         if(GetResource(this, RES_HEALTH) < 1)
1650         {
1651                 if(this.vehicle)
1652                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1653                 if(this.event_damage)
1654                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1655         }
1656
1657         if (!(this.items & IT_UNLIMITED_AMMO))
1658         {
1659                 regenstable = autocvar_g_balance_fuel_regenstable;
1660                 rotstable = autocvar_g_balance_fuel_rotstable;
1661                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1662                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1663                 RotRegen(this, RES_FUEL, 1,
1664                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1665                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1666         }
1667 }
1668
1669 bool zoomstate_set;
1670 void SetZoomState(entity this, float newzoom)
1671 {
1672         if(newzoom != CS(this).zoomstate)
1673         {
1674                 CS(this).zoomstate = newzoom;
1675                 ClientData_Touch(this);
1676         }
1677         zoomstate_set = true;
1678 }
1679
1680 void GetPressedKeys(entity this)
1681 {
1682         MUTATOR_CALLHOOK(GetPressedKeys, this);
1683         if (game_stopped)
1684         {
1685                 CS(this).pressedkeys = 0;
1686                 STAT(PRESSED_KEYS, this) = 0;
1687                 return;
1688         }
1689
1690         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1691         int keys = STAT(PRESSED_KEYS, this);
1692         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1693         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1694         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1695         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1696
1697         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1698         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1699         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1700         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1701         CS(this).pressedkeys = keys; // store for other users
1702
1703         STAT(PRESSED_KEYS, this) = keys;
1704 }
1705
1706 /*
1707 ======================
1708 spectate mode routines
1709 ======================
1710 */
1711
1712 void SpectateCopy(entity this, entity spectatee)
1713 {
1714         TC(Client, this); TC(Client, spectatee);
1715
1716         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1717         PS(this) = PS(spectatee);
1718         this.armortype = spectatee.armortype;
1719         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1720         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1721         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1722         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1723         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1724         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1725         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1726         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1727         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1728         CS(this).impulse = 0;
1729         this.disableclientprediction = 1; // no need to run prediction on a spectator
1730         this.items = spectatee.items;
1731         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1732         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1733         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1734         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1735         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1736         this.punchangle = spectatee.punchangle;
1737         this.view_ofs = spectatee.view_ofs;
1738         this.velocity = spectatee.velocity;
1739         this.dmg_take = spectatee.dmg_take;
1740         this.dmg_save = spectatee.dmg_save;
1741         this.dmg_inflictor = spectatee.dmg_inflictor;
1742         this.v_angle = spectatee.v_angle;
1743         this.angles = spectatee.v_angle;
1744         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1745         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1746         this.viewloc = spectatee.viewloc;
1747         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1748                 this.fixangle = true;
1749         setorigin(this, spectatee.origin);
1750         setsize(this, spectatee.mins, spectatee.maxs);
1751         SetZoomState(this, CS(spectatee).zoomstate);
1752
1753     anticheat_spectatecopy(this, spectatee);
1754         STAT(HUD, this) = STAT(HUD, spectatee);
1755         if(spectatee.vehicle)
1756     {
1757         this.angles = spectatee.v_angle;
1758
1759         //this.fixangle = false;
1760         //this.velocity = spectatee.vehicle.velocity;
1761         this.vehicle_health = spectatee.vehicle_health;
1762         this.vehicle_shield = spectatee.vehicle_shield;
1763         this.vehicle_energy = spectatee.vehicle_energy;
1764         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1765         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1766         this.vehicle_reload1 = spectatee.vehicle_reload1;
1767         this.vehicle_reload2 = spectatee.vehicle_reload2;
1768
1769         //msg_entity = this;
1770
1771        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1772             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1773            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1774            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1775
1776         //WriteByte (MSG_ONE, SVC_SETVIEW);
1777         //    WriteEntity(MSG_ONE, this);
1778         //makevectors(spectatee.v_angle);
1779         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1780     }
1781 }
1782
1783 bool SpectateUpdate(entity this)
1784 {
1785         if(!this.enemy)
1786                 return false;
1787
1788         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1789         {
1790                 SetSpectatee(this, NULL);
1791                 return false;
1792         }
1793
1794         SpectateCopy(this, this.enemy);
1795
1796         return true;
1797 }
1798
1799 bool SpectateSet(entity this)
1800 {
1801         if(!IS_PLAYER(this.enemy))
1802                 return false;
1803
1804         ClientData_Touch(this.enemy);
1805
1806         msg_entity = this;
1807         WriteByte(MSG_ONE, SVC_SETVIEW);
1808         WriteEntity(MSG_ONE, this.enemy);
1809         set_movetype(this, MOVETYPE_NONE);
1810         accuracy_resend(this);
1811
1812         if(!SpectateUpdate(this))
1813                 PutObserverInServer(this, false);
1814
1815         return true;
1816 }
1817
1818 void SetSpectatee_status(entity this, int spectatee_num)
1819 {
1820         int oldspectatee_status = CS(this).spectatee_status;
1821         CS(this).spectatee_status = spectatee_num;
1822
1823         if (CS(this).spectatee_status != oldspectatee_status)
1824         {
1825                 if (STAT(PRESSED_KEYS, this))
1826                 {
1827                         CS(this).pressedkeys = 0;
1828                         STAT(PRESSED_KEYS, this) = 0;
1829                 }
1830                 ClientData_Touch(this);
1831                 if (g_race || g_cts) race_InitSpectator();
1832         }
1833 }
1834
1835 void SetSpectatee(entity this, entity spectatee)
1836 {
1837         if(IS_BOT_CLIENT(this))
1838                 return; // bots abuse .enemy, this code is useless to them
1839
1840         entity old_spectatee = this.enemy;
1841
1842         this.enemy = spectatee;
1843
1844         // WEAPONTODO
1845         // these are required to fix the spectator bug with arc
1846         if(old_spectatee)
1847         {
1848                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1849                 {
1850                         .entity weaponentity = weaponentities[slot];
1851                         if(old_spectatee.(weaponentity).arc_beam)
1852                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1853                 }
1854         }
1855         if(this.enemy)
1856         {
1857                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1858                 {
1859                         .entity weaponentity = weaponentities[slot];
1860                         if(this.enemy.(weaponentity).arc_beam)
1861                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1862                 }
1863         }
1864
1865         if (this.enemy)
1866                 SetSpectatee_status(this, etof(this.enemy));
1867
1868         // needed to update spectator list
1869         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1870 }
1871
1872 bool Spectate(entity this, entity pl)
1873 {
1874         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1875                 return false;
1876         pl = M_ARGV(1, entity);
1877
1878         SetSpectatee(this, pl);
1879         return SpectateSet(this);
1880 }
1881
1882 bool SpectateNext(entity this)
1883 {
1884         entity ent = find(this.enemy, classname, STR_PLAYER);
1885
1886         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1887                 ent = M_ARGV(1, entity);
1888         else if (!ent)
1889                 ent = find(ent, classname, STR_PLAYER);
1890
1891         if(ent) { SetSpectatee(this, ent); }
1892
1893         return SpectateSet(this);
1894 }
1895
1896 bool SpectatePrev(entity this)
1897 {
1898         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1899         entity ent = findchain(classname, STR_PLAYER);
1900         if (!ent) // no player
1901                 return false;
1902
1903         entity first = ent;
1904         // skip players until current spectated player
1905         if(this.enemy)
1906         while(ent && ent != this.enemy)
1907                 ent = ent.chain;
1908
1909         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1910         {
1911                 case MUT_SPECPREV_FOUND:
1912                         ent = M_ARGV(1, entity);
1913                         break;
1914                 case MUT_SPECPREV_RETURN:
1915                         return true;
1916                 case MUT_SPECPREV_CONTINUE:
1917                 default:
1918                 {
1919                         if(ent.chain)
1920                                 ent = ent.chain;
1921                         else
1922                                 ent = first;
1923                         break;
1924                 }
1925         }
1926
1927         SetSpectatee(this, ent);
1928         return SpectateSet(this);
1929 }
1930
1931 /*
1932 =============
1933 ShowRespawnCountdown()
1934
1935 Update a respawn countdown display.
1936 =============
1937 */
1938 void ShowRespawnCountdown(entity this)
1939 {
1940         float number;
1941         if(!IS_DEAD(this)) // just respawned?
1942                 return;
1943         else
1944         {
1945                 number = ceil(this.respawn_time - time);
1946                 if(number <= 0)
1947                         return;
1948                 if(number <= this.respawn_countdown)
1949                 {
1950                         this.respawn_countdown = number - 1;
1951                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1952                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1953                 }
1954         }
1955 }
1956
1957 .bool team_selected;
1958 bool ShowTeamSelection(entity this)
1959 {
1960         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1961                 return false;
1962         stuffcmd(this, "menu_showteamselect\n");
1963         return true;
1964 }
1965 void Join(entity this)
1966 {
1967         TRANSMUTE(Player, this);
1968
1969         if(!this.team_selected)
1970         if(autocvar_g_campaign || autocvar_g_balance_teams)
1971                 TeamBalance_JoinBestTeam(this);
1972
1973         if(autocvar_g_campaign)
1974                 campaign_bots_may_start = true;
1975
1976         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1977
1978         PutClientInServer(this);
1979
1980         if(IS_PLAYER(this))
1981         if(teamplay && this.team != -1)
1982         {
1983         }
1984         else
1985                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1986         this.team_selected = false;
1987 }
1988
1989 int GetPlayerLimit()
1990 {
1991         if(g_duel)
1992                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1993         int player_limit = autocvar_g_maxplayers;
1994         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1995         player_limit = M_ARGV(0, int);
1996         return player_limit;
1997 }
1998
1999 /**
2000  * Determines whether the player is allowed to join. This depends on cvar
2001  * g_maxplayers, if it isn't used this function always return true, otherwise
2002  * it checks whether the number of currently playing players exceeds g_maxplayers.
2003  * @return int number of free slots for players, 0 if none
2004  */
2005 int nJoinAllowed(entity this, entity ignore)
2006 {
2007         if(!ignore)
2008         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2009         // so report 0 free slots if restricted
2010         {
2011                 if(autocvar_g_forced_team_otherwise == "spectate")
2012                         return 0;
2013                 if(autocvar_g_forced_team_otherwise == "spectator")
2014                         return 0;
2015         }
2016
2017         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2018                 return 0; // forced spectators can never join
2019
2020         // TODO simplify this
2021         int totalClients = 0;
2022         int currentlyPlaying = 0;
2023         FOREACH_CLIENT(true, {
2024                 if(it != ignore)
2025                         ++totalClients;
2026                 if(IS_REAL_CLIENT(it))
2027                 if(IS_PLAYER(it) || it.caplayer)
2028                         ++currentlyPlaying;
2029         });
2030
2031         int player_limit = GetPlayerLimit();
2032
2033         int free_slots = 0;
2034         if (!player_limit)
2035                 free_slots = maxclients - totalClients;
2036         else if(player_limit > 0 && currentlyPlaying < player_limit)
2037                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2038
2039         static float msg_time = 0;
2040         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2041         {
2042                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2043                 msg_time = time + 0.5;
2044         }
2045
2046         return free_slots;
2047 }
2048
2049 void PrintWelcomeMessage(entity this)
2050 {
2051         if(CS(this).motd_actived_time == 0)
2052         {
2053                 if (autocvar_g_campaign) {
2054                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2055                                 CS(this).motd_actived_time = time;
2056                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2057                         }
2058                 } else {
2059                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2060                                 CS(this).motd_actived_time = time;
2061                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2062                         }
2063                 }
2064         }
2065         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2066         {
2067                 if (autocvar_g_campaign) {
2068                         if (PHYS_INPUT_BUTTON_INFO(this))
2069                                 CS(this).motd_actived_time = time;
2070                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2071                                 CS(this).motd_actived_time = 0;
2072                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2073                         }
2074                 } else {
2075                         if (PHYS_INPUT_BUTTON_INFO(this))
2076                                 CS(this).motd_actived_time = time;
2077                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2078                                 CS(this).motd_actived_time = 0;
2079                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2080                         }
2081                 }
2082         }
2083         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2084         {
2085                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2086                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2087                 else if (CS(this).motd_actived_time == -2)
2088                 {
2089                         // instantly hide MOTD
2090                         CS(this).motd_actived_time = 0;
2091                         if (autocvar_g_campaign)
2092                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2093                         else
2094                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2095                 }
2096                 else if (IS_PLAYER(this) || IS_SPEC(this))
2097                 {
2098                         // FIXME occasionally for some reason MOTD never goes away
2099                         // delay MOTD removal a little bit in the hope it fixes this bug
2100                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2101                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2102                         else //if (CS(this).motd_actived_time < -2)
2103                                 CS(this).motd_actived_time++;
2104                 }
2105         }
2106 }
2107
2108 bool joinAllowed(entity this)
2109 {
2110         if (CS(this).version_mismatch) return false;
2111         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2112         if (!nJoinAllowed(this, this)) return false;
2113         if (teamplay && lockteams) return false;
2114         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2115         if (ShowTeamSelection(this)) return false;
2116         return true;
2117 }
2118
2119 .string shootfromfixedorigin;
2120 .bool dualwielding_prev;
2121 bool PlayerThink(entity this)
2122 {
2123         if (game_stopped || intermission_running) {
2124                 this.modelflags &= ~MF_ROCKET;
2125                 if(intermission_running)
2126                         IntermissionThink(this);
2127                 return false;
2128         }
2129
2130         if (timeout_status == TIMEOUT_ACTIVE) {
2131                 // don't allow the player to turn around while game is paused
2132                 // FIXME turn this into CSQC stuff
2133                 this.v_angle = this.lastV_angle;
2134                 this.angles = this.lastV_angle;
2135                 this.fixangle = true;
2136         }
2137
2138         if (frametime) player_powerups(this);
2139
2140         if (IS_DEAD(this)) {
2141                 if (this.personal && g_race_qualifying) {
2142                         if (time > this.respawn_time) {
2143                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2144                                 respawn(this);
2145                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2146                         }
2147                 } else {
2148                         if (frametime) player_anim(this);
2149
2150                         if (this.respawn_flags & RESPAWN_DENY)
2151                         {
2152                                 STAT(RESPAWN_TIME, this) = 0;
2153                                 return false;
2154                         }
2155
2156                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2157
2158                         switch(this.deadflag)
2159                         {
2160                                 case DEAD_DYING:
2161                                 {
2162                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2163                                                 this.deadflag = DEAD_RESPAWNING;
2164                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2165                                                 this.deadflag = DEAD_DEAD;
2166                                         break;
2167                                 }
2168                                 case DEAD_DEAD:
2169                                 {
2170                                         if (button_pressed)
2171                                                 this.deadflag = DEAD_RESPAWNABLE;
2172                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2173                                                 this.deadflag = DEAD_RESPAWNING;
2174                                         break;
2175                                 }
2176                                 case DEAD_RESPAWNABLE:
2177                                 {
2178                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2179                                                 this.deadflag = DEAD_RESPAWNING;
2180                                         break;
2181                                 }
2182                                 case DEAD_RESPAWNING:
2183                                 {
2184                                         if (time > this.respawn_time)
2185                                         {
2186                                                 this.respawn_time = time + 1; // only retry once a second
2187                                                 this.respawn_time_max = this.respawn_time;
2188                                                 respawn(this);
2189                                         }
2190                                         break;
2191                                 }
2192                         }
2193
2194                         ShowRespawnCountdown(this);
2195
2196                         if (this.respawn_flags & RESPAWN_SILENT)
2197                                 STAT(RESPAWN_TIME, this) = 0;
2198                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2199                         {
2200                                 if (time < this.respawn_time)
2201                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2202                                 else if (this.deadflag != DEAD_RESPAWNING)
2203                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2204                         }
2205                         else
2206                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2207                 }
2208
2209                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2210                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2211                         STAT(RESPAWN_TIME, this) *= -1;
2212
2213                 return false;
2214         }
2215
2216         FixPlayermodel(this);
2217
2218         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2219                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2220                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2221         }
2222
2223         // reset gun alignment when dual wielding status changes
2224         // to ensure guns are always aligned right and left
2225         bool dualwielding = W_DualWielding(this);
2226         if(this.dualwielding_prev != dualwielding)
2227         {
2228                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2229                 this.dualwielding_prev = dualwielding;
2230         }
2231
2232         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2233         //if(frametime)
2234         {
2235                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2236                 {
2237                         .entity weaponentity = weaponentities[slot];
2238                         if(WEP_CVAR(vortex, charge_always))
2239                                 W_Vortex_Charge(this, weaponentity, frametime);
2240                         W_WeaponFrame(this, weaponentity);
2241                 }
2242         }
2243
2244         if (frametime)
2245         {
2246                 // WEAPONTODO: Add a weapon request for this
2247                 // rot vortex charge to the charge limit
2248                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2249                 {
2250                         .entity weaponentity = weaponentities[slot];
2251                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2252                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2253                 }
2254
2255                 player_regen(this);
2256                 player_anim(this);
2257                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2258         }
2259
2260         monsters_setstatus(this);
2261
2262         return true;
2263 }
2264
2265 .bool would_spectate;
2266 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2267 void ObserverOrSpectatorThink(entity this)
2268 {
2269         bool is_spec = IS_SPEC(this);
2270         if ( CS(this).impulse )
2271         {
2272                 int r = MinigameImpulse(this, CS(this).impulse);
2273                 if (!is_spec || r)
2274                         CS(this).impulse = 0;
2275
2276                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2277                 {
2278                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2279                         CS(this).impulse = 0;
2280                         return;
2281                 }
2282         }
2283
2284         if (this.flags & FL_JUMPRELEASED) {
2285                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2286                         this.flags &= ~FL_JUMPRELEASED;
2287                         this.flags |= FL_SPAWNING;
2288                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2289                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2290                         this.flags &= ~FL_JUMPRELEASED;
2291                         if(SpectateNext(this)) {
2292                                 TRANSMUTE(Spectator, this);
2293                         } else if (is_spec) {
2294                                 TRANSMUTE(Observer, this);
2295                                 PutClientInServer(this);
2296                         }
2297                         else
2298                                 this.would_spectate = false; // unable to spectate anyone
2299                         if (is_spec)
2300                                 CS(this).impulse = 0;
2301                 } else if (is_spec) {
2302                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2303                                 this.flags &= ~FL_JUMPRELEASED;
2304                                 if(SpectatePrev(this)) {
2305                                         TRANSMUTE(Spectator, this);
2306                                 } else {
2307                                         TRANSMUTE(Observer, this);
2308                                         PutClientInServer(this);
2309                                 }
2310                                 CS(this).impulse = 0;
2311                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2312                                 this.would_spectate = false;
2313                                 this.flags &= ~FL_JUMPRELEASED;
2314                                 TRANSMUTE(Observer, this);
2315                                 PutClientInServer(this);
2316                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2317                                 PutObserverInServer(this, false);
2318                                 this.would_spectate = true;
2319                         }
2320                 }
2321                 else {
2322                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2323                         if (PHYS_INPUT_BUTTON_USE(this))
2324                                 wouldclip = !wouldclip;
2325                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2326                         set_movetype(this, preferred_movetype);
2327                 }
2328         } else { // jump pressed
2329                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2330                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2331                         this.flags |= FL_JUMPRELEASED;
2332                         if(this.flags & FL_SPAWNING)
2333                         {
2334                                 this.flags &= ~FL_SPAWNING;
2335                                 if(joinAllowed(this))
2336                                         Join(this);
2337                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2338                                         CS(this).autojoin_checked = -1;
2339                                 return;
2340                         }
2341                 }
2342                 if(is_spec && !SpectateUpdate(this))
2343                         PutObserverInServer(this, false);
2344         }
2345         if (is_spec)
2346                 this.flags |= FL_CLIENT | FL_NOTARGET;
2347 }
2348
2349 void PlayerUseKey(entity this)
2350 {
2351         if (!IS_PLAYER(this))
2352                 return;
2353
2354         if(this.vehicle)
2355         {
2356                 if(!game_stopped)
2357                 {
2358                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2359                         return;
2360                 }
2361         }
2362         else if(autocvar_g_vehicles_enter)
2363         {
2364                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2365                 {
2366                         entity head, closest_target = NULL;
2367                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2368
2369                         while(head) // find the closest acceptable target to enter
2370                         {
2371                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2372                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2373                                 {
2374                                         if(closest_target)
2375                                         {
2376                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2377                                                 { closest_target = head; }
2378                                         }
2379                                         else { closest_target = head; }
2380                                 }
2381
2382                                 head = head.chain;
2383                         }
2384
2385                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2386                 }
2387         }
2388
2389         // a use key was pressed; call handlers
2390         MUTATOR_CALLHOOK(PlayerUseKey, this);
2391 }
2392
2393
2394 /*
2395 =============
2396 PlayerPreThink
2397
2398 Called every frame for each client before the physics are run
2399 =============
2400 */
2401 .float last_vehiclecheck;
2402 void PlayerPreThink (entity this)
2403 {
2404         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2405         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2406
2407         WarpZone_PlayerPhysics_FixVAngle(this);
2408
2409         if (frametime) {
2410                 // physics frames: update anticheat stuff
2411                 anticheat_prethink(this);
2412
2413                 // WORKAROUND: only use dropclient in server frames (frametime set).
2414                 // Never use it in cl_movement frames (frametime zero).
2415                 if (blockSpectators && IS_REAL_CLIENT(this)
2416                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !this.caplayer
2417                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2418                 {
2419                         if (dropclient_schedule(this))
2420                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2421                 }
2422         }
2423
2424         zoomstate_set = false;
2425
2426         // Check for nameless players
2427         if (this.netname == "" || this.netname != CS(this).netname_previous)
2428         {
2429                 bool assume_unchanged = (CS(this).netname_previous == "");
2430                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2431                 {
2432                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2433                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2434                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2435                         assume_unchanged = false;
2436                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2437                 }
2438                 if (isInvisibleString(this.netname))
2439                 {
2440                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2441                         sprint(this, "Warning: invisible names are not allowed.\n");
2442                         assume_unchanged = false;
2443                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2444                 }
2445                 if (!assume_unchanged && autocvar_sv_eventlog)
2446                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2447                 strcpy(CS(this).netname_previous, this.netname);
2448         }
2449
2450         // version nagging
2451         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2452         CS(this).version_nagtime = 0;
2453         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2454             // git client
2455         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2456             // git server
2457             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2458         } else {
2459             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2460             if (r < 0) { // old client
2461                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2462             } else if (r > 0) { // old server
2463                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2464             }
2465         }
2466     }
2467
2468         // GOD MODE info
2469         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2470         {
2471                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2472                 this.max_armorvalue = 0;
2473         }
2474
2475         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2476         {
2477                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2478                 {
2479                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2480                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2481                         if (this.iceblock)
2482                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2483
2484                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2485                                 Unfreeze(this, false);
2486                 }
2487                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2488                 {
2489                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2490                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2491
2492                         if (GetResource(this, RES_HEALTH) < 1)
2493                         {
2494                                 if (this.vehicle)
2495                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2496                                 if(this.event_damage)
2497                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2498                         }
2499                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2500                                 Unfreeze(this, false);
2501                 }
2502         }
2503
2504         MUTATOR_CALLHOOK(PlayerPreThink, this);
2505
2506         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2507         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2508         {
2509                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2510                 {
2511                         if(!it.owner)
2512                         {
2513                                 if(!it.team || SAME_TEAM(this, it))
2514                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2515                                 else if(autocvar_g_vehicles_steal)
2516                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2517                         }
2518                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2519                         {
2520                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2521                         }
2522                 });
2523
2524                 this.last_vehiclecheck = time + 1;
2525         }
2526
2527         if(!CS_CVAR(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2528         {
2529                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2530                         PlayerUseKey(this);
2531                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2532         }
2533
2534         if (IS_REAL_CLIENT(this))
2535                 PrintWelcomeMessage(this);
2536
2537         if (IS_PLAYER(this)) {
2538                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2539                         error("Client can't be spawned as player on connection!");
2540                 if(!PlayerThink(this))
2541                         return;
2542         }
2543         else if (game_stopped || intermission_running) {
2544                 if(intermission_running)
2545                         IntermissionThink(this);
2546                 return;
2547         }
2548         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2549         {
2550                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2551                 CS(this).autojoin_checked = 1;
2552                 // don't do this in ClientConnect
2553                 // many things can go wrong if a client is spawned as player on connection
2554                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2555                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2556                                 && (!teamplay || autocvar_g_balance_teams)))
2557                 {
2558                         campaign_bots_may_start = true;
2559                         if(joinAllowed(this))
2560                                 Join(this);
2561                         return;
2562                 }
2563         }
2564         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2565                 ObserverOrSpectatorThink(this);
2566         }
2567
2568         // WEAPONTODO: Add weapon request for this
2569         if (!zoomstate_set) {
2570                 bool wep_zoomed = false;
2571                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2572                 {
2573                         .entity weaponentity = weaponentities[slot];
2574                         Weapon thiswep = this.(weaponentity).m_weapon;
2575                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2576                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2577                 }
2578                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2579         }
2580
2581         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2582         {
2583                 CS(this).teamkill_soundtime = 0;
2584
2585                 entity e = CS(this).teamkill_soundsource;
2586                 entity oldpusher = e.pusher;
2587                 e.pusher = this;
2588                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2589                 e.pusher = oldpusher;
2590         }
2591
2592         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2593                 CS(this).taunt_soundtime = 0;
2594                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2595         }
2596
2597         target_voicescript_next(this);
2598 }
2599
2600 void DrownPlayer(entity this)
2601 {
2602         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2603                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2604         {
2605                 STAT(AIR_FINISHED, this) = 0;
2606                 return;
2607         }
2608
2609         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2610         {
2611                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2612                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2613                 STAT(AIR_FINISHED, this) = 0;
2614         }
2615         else
2616         {
2617                 if (!STAT(AIR_FINISHED, this))
2618                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2619                 if (STAT(AIR_FINISHED, this) < time)
2620                 {       // drown!
2621                         if (this.pain_finished < time)
2622                         {
2623                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2624                                 this.pain_finished = time + 0.5;
2625                         }
2626                 }
2627         }
2628 }
2629
2630 .bool move_qcphysics;
2631
2632 void Player_Physics(entity this)
2633 {
2634         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2635
2636         if(!this.move_qcphysics)
2637                 return;
2638
2639         if(!frametime && !CS(this).pm_frametime)
2640                 return;
2641
2642         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2643
2644         CS(this).pm_frametime = 0;
2645 }
2646
2647 /*
2648 =============
2649 PlayerPostThink
2650
2651 Called every frame for each client after the physics are run
2652 =============
2653 */
2654 void PlayerPostThink (entity this)
2655 {
2656         Player_Physics(this);
2657
2658         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2659         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2660         if (IS_REAL_CLIENT(this))
2661         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2662         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2663         {
2664                 int totalClients = 0;
2665                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2666                 {
2667                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2668                         if (server_is_dedicated)
2669                         {
2670                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2671                                 {
2672                                         ++totalClients;
2673                                 });
2674                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2675                                         totalClients = 0;
2676                         }
2677                 }
2678                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2679                 {
2680                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2681                         {
2682                                 ++totalClients;
2683                         });
2684                 }
2685
2686                 if (totalClients < autocvar_sv_maxidle_minplayers)
2687                 {
2688                         // idle kick disabled
2689                         CS(this).parm_idlesince = time;
2690                 }
2691                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2692                 {
2693                         if (CS(this).idlekick_lasttimeleft)
2694                         {
2695                                 CS(this).idlekick_lasttimeleft = 0;
2696                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2697                         }
2698                 }
2699                 else
2700                 {
2701                         float maxidle_time = autocvar_sv_maxidle;
2702                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2703                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2704                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2705                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2706                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2707                         {
2708                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2709                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2710                                 else
2711                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2712                         }
2713                         if (timeleft <= 0) {
2714                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2715                                 {
2716                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2717                                         PutObserverInServer(this, true);
2718                                 }
2719                                 else
2720                                 {
2721                                         if (dropclient_schedule(this))
2722                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2723                                 }
2724                                 return;
2725                         }
2726                         else if (timeleft <= countdown_time) {
2727                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2728                                         play2(this, SND(TALK2));
2729                                 CS(this).idlekick_lasttimeleft = timeleft;
2730                         }
2731                 }
2732         }
2733
2734         CheatFrame(this);
2735
2736         if (game_stopped)
2737         {
2738                 this.solid = SOLID_NOT;
2739                 this.takedamage = DAMAGE_NO;
2740                 set_movetype(this, MOVETYPE_NONE);
2741                 CS(this).teamkill_complain = 0;
2742                 CS(this).teamkill_soundtime = 0;
2743                 CS(this).teamkill_soundsource = NULL;
2744         }
2745
2746         if (IS_PLAYER(this)) {
2747                 if(this.death_time == time && IS_DEAD(this))
2748                 {
2749                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2750                         // once all the damage events of this frame have been processed with normal size
2751                         this.maxs.z = 5;
2752                         setsize(this, this.mins, this.maxs);
2753                 }
2754                 DrownPlayer(this);
2755                 UpdateChatBubble(this);
2756                 if (CS(this).impulse) ImpulseCommands(this);
2757                 GetPressedKeys(this);
2758                 if (game_stopped)
2759                 {
2760                         CSQCMODEL_AUTOUPDATE(this);
2761                         return;
2762                 }
2763         }
2764         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2765         {
2766                 CS(this).pressedkeys = 0;
2767                 STAT(PRESSED_KEYS, this) = 0;
2768         }
2769
2770         if (this.waypointsprite_attachedforcarrier) {
2771                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2772                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2773         }
2774
2775         CSQCMODEL_AUTOUPDATE(this);
2776 }
2777
2778 // hack to copy the button fields from the client entity to the Client State
2779 void PM_UpdateButtons(entity this, entity store)
2780 {
2781         if(this.impulse)
2782                 store.impulse = this.impulse;
2783         this.impulse = 0;
2784
2785         bool typing = this.buttonchat || this.button12;
2786
2787         store.button0 = (typing) ? 0 : this.button0;
2788         //button1?!
2789         store.button2 = (typing) ? 0 : this.button2;
2790         store.button3 = (typing) ? 0 : this.button3;
2791         store.button4 = this.button4;
2792         store.button5 = (typing) ? 0 : this.button5;
2793         store.button6 = this.button6;
2794         store.button7 = this.button7;
2795         store.button8 = this.button8;
2796         store.button9 = this.button9;
2797         store.button10 = this.button10;
2798         store.button11 = this.button11;
2799         store.button12 = this.button12;
2800         store.button13 = this.button13;
2801         store.button14 = this.button14;
2802         store.button15 = this.button15;
2803         store.button16 = this.button16;
2804         store.buttonuse = this.buttonuse;
2805         store.buttonchat = this.buttonchat;
2806
2807         store.cursor_active = this.cursor_active;
2808         store.cursor_screen = this.cursor_screen;
2809         store.cursor_trace_start = this.cursor_trace_start;
2810         store.cursor_trace_endpos = this.cursor_trace_endpos;
2811         store.cursor_trace_ent = this.cursor_trace_ent;
2812
2813         store.ping = this.ping;
2814         store.ping_packetloss = this.ping_packetloss;
2815         store.ping_movementloss = this.ping_movementloss;
2816
2817         store.v_angle = this.v_angle;
2818         store.movement = this.movement;
2819 }
2820
2821 NET_HANDLE(fpsreport, bool)
2822 {
2823         int fps = ReadShort();
2824         PlayerScore_Set(sender, SP_FPS, fps);
2825         return true;
2826 }