qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         if(g_runematch)
  18         {
  19                 if(self.runes & RUNE_SPEED)
  20                 {
  21                         if(self.runes & CURSE_SLOW)
  22                                 t = t * autocvar_g_balance_rune_speed_combo_atkrate;
  23                         else
  24                                 t = t * autocvar_g_balance_rune_speed_atkrate;
  25                 }
  26                 else if(self.runes & CURSE_SLOW)
  27                 {
  28                         t = t * autocvar_g_balance_curse_slow_atkrate;
  29                 }
  30         }
  31
  32         return t;
  33 }
  34
  35 void W_SwitchWeapon_Force(entity e, float w)
  36 {
  37         e.cnt = e.switchweapon;
  38         e.switchweapon = w;
  39         e.selectweapon = w;
  40 }
  41
  42 .float antilag_debug;
  43
  44 // VorteX: static frame globals
  45 float WFRAME_DONTCHANGE = -1;
  46 float WFRAME_FIRE1 = 0;
  47 float WFRAME_FIRE2 = 1;
  48 float WFRAME_IDLE = 2;
  49 float WFRAME_RELOAD = 3;
  50 .float wframe;
  51
  52 void(float fr, float t, void() func) weapon_thinkf;
  53
  54 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  55 {
  56         vector ret;
  57         ret_x = screenright * v;
  58         ret_y = screenup * v;
  59         ret_z = screenforward * v;
  60         return ret;
  61 }
  62
  63 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  64 {
  65         float i, j, k;
  66         vector mi, ma, thisv, myv, ret;
  67
  68         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  69
  70         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  71
  72         mi = ma = targ.origin + 0.5 * (targ.mins + targ.maxs);
  73         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  74         {
  75                 thisv = targ.origin;
  76                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  77                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  78                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  79                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  80                 if(i || j || k)
  81                 {
  82                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  83                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  84                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  85                 }
  86                 else
  87                 {
  88                         // first run
  89                         mi = ma = thisv;
  90                 }
  91         }
  92
  93         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  94         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  95         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  96         ret_z = thisv_z - myv_z;
  97         return ret;
  98 }
  99
 100 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
 101 {
 102         vector hitplot;
 103         vector org;
 104         float lag;
 105
 106         if(player.hitplotfh >= 0)
 107         {
 108                 lag = ANTILAG_LATENCY(player);
 109                 if(lag < 0.001)
 110                         lag = 0;
 111                 if(clienttype(player) != CLIENTTYPE_REAL)
 112                         lag = 0; // only antilag for clients
 113
 114                 org = player.origin + player.view_ofs;
 115                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 116                 if(trace_ent.flags & FL_CLIENT)
 117                 {
 118                         antilag_takeback(trace_ent, time - lag);
 119                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 120                         antilag_restore(trace_ent);
 121                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 122                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 123                 }
 124         }
 125 }
 126
 127 vector w_shotorg;
 128 vector w_shotdir;
 129 vector w_shotend;
 130
 131 .float prevstrengthsound;
 132 .float prevstrengthsoundattempt;
 133 void W_PlayStrengthSound(entity player) // void W_PlayStrengthSound
 134 {
 135         if(MUTATOR_CALLHOOK(PlayStrengthSound))
 136                 return;
 137
 138                 if((player.items & IT_STRENGTH)
 139                         && ((time > player.prevstrengthsound + autocvar_sv_strengthsound_antispam_time) // prevent insane sound spam
 140                         || (time > player.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)))
 141                 {
 142                         sound(player, CH_TRIGGER, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 143                         player.prevstrengthsound = time;
 144                 }
 145                 player.prevstrengthsoundattempt = time;
 146 }
 147
 148 // this function calculates w_shotorg and w_shotdir based on the weapon model
 149 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 150 // make sure you call makevectors first (FIXME?)
 151 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
 152 {
 153         float nudge = 1; // added to traceline target and subtracted from result
 154         float oldsolid;
 155         vector vecs, dv;
 156         oldsolid = ent.dphitcontentsmask;
 157         if(ent.weapon == WEP_RIFLE)
 158                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 159         else
 160                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 161         if(antilag)
 162                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 163                 // passing world, because we do NOT want it to touch dphitcontentsmask
 164         else
 165                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
 166         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 167
 168         vector vf, vr, vu;
 169         vf = v_forward;
 170         vr = v_right;
 171         vu = v_up;
 172         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
 173         v_forward = vf;
 174         v_right = vr;
 175         v_up = vu;
 176
 177         // un-adjust trueaim if shotend is too close
 178         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
 179                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
 180
 181         // track max damage
 182         if(accuracy_canbegooddamage(ent))
 183                 accuracy_add(ent, ent.weapon, maxdamage, 0);
 184
 185         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 186
 187         if(ent.weaponentity.movedir_x > 0)
 188                 vecs = ent.weaponentity.movedir;
 189         else
 190                 vecs = '0 0 0';
 191
 192         dv = v_right * -vecs_y + v_up * vecs_z;
 193         w_shotorg = ent.origin + ent.view_ofs + dv;
 194
 195         // now move the shotorg forward as much as requested if possible
 196         if(antilag)
 197         {
 198                 if(ent.antilag_debug)
 199                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 200                 else
 201                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 202         }
 203         else
 204                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 205         w_shotorg = trace_endpos - v_forward * nudge;
 206         // calculate the shotdir from the chosen shotorg
 207         w_shotdir = normalize(w_shotend - w_shotorg);
 208
 209         if (antilag)
 210         if (!ent.cvar_cl_noantilag)
 211         {
 212                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
 213                 {
 214                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 215                         if (!trace_ent.takedamage)
 216                         {
 217                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 218                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 219                                 {
 220                                         entity e;
 221                                         e = trace_ent;
 222                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 223                                         if(trace_ent == e)
 224                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 225                                 }
 226                         }
 227                 }
 228                 else if(autocvar_g_antilag == 3) // client side hitscan
 229                 {
 230                         // this part MUST use prydon cursor
 231                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 232                         if (ent.cursor_trace_ent != ent)         // just to make sure
 233                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 234                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
 235                         {
 236                                 // verify that the shot would miss without antilag
 237                                 // (avoids an issue where guns would always shoot at their origin)
 238                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 239                                 if (!trace_ent.takedamage)
 240                                 {
 241                                         // verify that the shot would hit if altered
 242                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 243                                         if (trace_ent == ent.cursor_trace_ent)
 244                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 245                                         else
 246                                                 print("antilag fail\n");
 247                                 }
 248                         }
 249                 }
 250         }
 251
 252         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 253
 254         if (!g_norecoil)
 255                 ent.punchangle_x = recoil * -1;
 256
 257         if (snd != "")
 258         {
 259                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 260                 W_PlayStrengthSound(ent);
 261         }
 262
 263         // nudge w_shotend so a trace to w_shotend hits
 264         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 265 }
 266
 267 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, chan, maxdamage, MAX_SHOT_DISTANCE)
 268 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, chan, maxdamage)
 269 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 270 #define W_SetupShot(ent,antilag,recoil,snd,chan,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 271 #define W_SetupShot_Range(ent,antilag,recoil,snd,chan,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage, range)
 272
 273 float CL_Weaponentity_CustomizeEntityForClient()
 274 {
 275         self.viewmodelforclient = self.owner;
 276         if(other.classname == "spectator")
 277                 if(other.enemy == self.owner)
 278                         self.viewmodelforclient = other;
 279         return TRUE;
 280 }
 281
 282 /*
 283  * supported formats:
 284  *
 285  * 1. simple animated model, muzzle flash handling on h_ model:
 286  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 287  *      tags:
 288  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 289  *        shell = casings ejection point (must be on the right hand side of the gun)
 290  *        weapon = attachment for v_tuba.md3
 291  *    v_tuba.md3 - first and third person model
 292  *    g_tuba.md3 - pickup model
 293  *
 294  * 2. simple animated model, muzzle flash handling on v_ model:
 295  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 296  *      tags:
 297  *        weapon = attachment for v_tuba.md3
 298  *    v_tuba.md3 - first and third person model
 299  *      tags:
 300  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 301  *        shell = casings ejection point (must be on the right hand side of the gun)
 302  *    g_tuba.md3 - pickup model
 303  *
 304  * 3. fully animated model, muzzle flash handling on h_ model:
 305  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 306  *      tags:
 307  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 308  *        shell = casings ejection point (must be on the right hand side of the gun)
 309  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 310  *    v_tuba.md3 - third person model
 311  *    g_tuba.md3 - pickup model
 312  *
 313  * 4. fully animated model, muzzle flash handling on v_ model:
 314  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 315  *      tags:
 316  *        shot = muzzle end (shot origin)
 317  *        shell = casings ejection point (must be on the right hand side of the gun)
 318  *    v_tuba.md3 - third person model
 319  *      tags:
 320  *        shot = muzzle end (for muzzle flashes)
 321  *    g_tuba.md3 - pickup model
 322  */
 323
 324 // writes:
 325 //   self.origin, self.angles
 326 //   self.weaponentity
 327 //   self.movedir, self.view_ofs
 328 //   attachment stuff
 329 //   anim stuff
 330 // to free:
 331 //   call again with ""
 332 //   remove the ent
 333 void CL_WeaponEntity_SetModel(string name)
 334 {
 335         float v_shot_idx;
 336         if (name != "")
 337         {
 338                 // if there is a child entity, hide it until we're sure we use it
 339                 if (self.weaponentity)
 340                         self.weaponentity.model = "";
 341                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
 342                 v_shot_idx = gettagindex(self, "shot"); // used later
 343                 if(!v_shot_idx)
 344                         v_shot_idx = gettagindex(self, "tag_shot");
 345
 346                 setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
 347                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 348                 self.anim_fire1  = animfixfps(self, '0 1 0.01');
 349                 self.anim_fire2  = animfixfps(self, '1 1 0.01');
 350                 self.anim_idle   = animfixfps(self, '2 1 0.01');
 351                 self.anim_reload = animfixfps(self, '3 1 0.01');
 352
 353                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 354                 // if we don't, this is a "real" animated model
 355                 if(gettagindex(self, "weapon"))
 356                 {
 357                         if (!self.weaponentity)
 358                                 self.weaponentity = spawn();
 359                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 360                         setattachment(self.weaponentity, self, "weapon");
 361                 }
 362                 else if(gettagindex(self, "tag_weapon"))
 363                 {
 364                         if (!self.weaponentity)
 365                                 self.weaponentity = spawn();
 366                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 367                         setattachment(self.weaponentity, self, "tag_weapon");
 368                 }
 369                 else
 370                 {
 371                         if(self.weaponentity)
 372                                 remove(self.weaponentity);
 373                         self.weaponentity = world;
 374                 }
 375
 376                 setorigin(self,'0 0 0');
 377                 self.angles = '0 0 0';
 378                 self.frame = 0;
 379                 self.viewmodelforclient = world;
 380
 381                 float idx;
 382
 383                 if(v_shot_idx) // v_ model attached to invisible h_ model
 384                 {
 385                         self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
 386                 }
 387                 else
 388                 {
 389                         idx = gettagindex(self, "shot");
 390                         if(!idx)
 391                                 idx = gettagindex(self, "tag_shot");
 392                         if(idx)
 393                                 self.movedir = gettaginfo(self, idx);
 394                         else
 395                         {
 396                                 print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 397                                 self.movedir = '0 0 0';
 398                         }
 399                 }
 400
 401                 if(self.weaponentity) // v_ model attached to invisible h_ model
 402                 {
 403                         idx = gettagindex(self.weaponentity, "shell");
 404                         if(!idx)
 405                                 idx = gettagindex(self.weaponentity, "tag_shell");
 406                         if(idx)
 407                                 self.spawnorigin = gettaginfo(self.weaponentity, idx);
 408                 }
 409                 else
 410                         idx = 0;
 411                 if(!idx)
 412                 {
 413                         idx = gettagindex(self, "shell");
 414                         if(!idx)
 415                                 idx = gettagindex(self, "tag_shell");
 416                         if(idx)
 417                                 self.spawnorigin = gettaginfo(self, idx);
 418                         else
 419                         {
 420                                 print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 421                                 self.spawnorigin = self.movedir;
 422                         }
 423                 }
 424
 425                 if(v_shot_idx)
 426                 {
 427                         self.oldorigin = '0 0 0'; // use regular attachment
 428                 }
 429                 else
 430                 {
 431                         if(self.weaponentity)
 432                         {
 433                                 idx = gettagindex(self, "weapon");
 434                                 if(!idx)
 435                                         idx = gettagindex(self, "tag_weapon");
 436                         }
 437                         else
 438                         {
 439                                 idx = gettagindex(self, "handle");
 440                                 if(!idx)
 441                                         idx = gettagindex(self, "tag_handle");
 442                         }
 443                         if(idx)
 444                         {
 445                                 self.oldorigin = self.movedir - gettaginfo(self, idx);
 446                         }
 447                         else
 448                         {
 449                                 print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 450                                 self.oldorigin = '0 0 0'; // there is no way to recover from this
 451                         }
 452                 }
 453
 454                 self.viewmodelforclient = self.owner;
 455         }
 456         else
 457         {
 458                 self.model = "";
 459                 if(self.weaponentity)
 460                         remove(self.weaponentity);
 461                 self.weaponentity = world;
 462                 self.movedir = '0 0 0';
 463                 self.spawnorigin = '0 0 0';
 464                 self.oldorigin = '0 0 0';
 465                 self.anim_fire1  = '0 1 0.01';
 466                 self.anim_fire2  = '0 1 0.01';
 467                 self.anim_idle   = '0 1 0.01';
 468                 self.anim_reload = '0 1 0.01';
 469         }
 470
 471         self.view_ofs = '0 0 0';
 472
 473         if(self.movedir_x >= 0)
 474         {
 475                 vector v0;
 476                 v0 = self.movedir;
 477                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 478                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 479         }
 480         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 481         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 482
 483         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 484
 485         // check if an instant weapon switch occurred
 486         setorigin(self, self.view_ofs);
 487         // reset animstate now
 488         self.wframe = WFRAME_IDLE;
 489         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 490 }
 491
 492 vector CL_Weapon_GetShotOrg(float wpn)
 493 {
 494         entity wi, oldself;
 495         vector ret;
 496         wi = get_weaponinfo(wpn);
 497         oldself = self;
 498         self = spawn();
 499         CL_WeaponEntity_SetModel(wi.mdl);
 500         ret = self.movedir;
 501         CL_WeaponEntity_SetModel("");
 502         remove(self);
 503         self = oldself;
 504         return ret;
 505 }
 506
 507 void CL_Weaponentity_Think()
 508 {
 509         float tb;
 510         self.nextthink = time;
 511         if (intermission_running)
 512                 self.frame = self.anim_idle_x;
 513         if (self.owner.weaponentity != self)
 514         {
 515                 if (self.weaponentity)
 516                         remove(self.weaponentity);
 517                 remove(self);
 518                 return;
 519         }
 520         if (self.owner.deadflag != DEAD_NO)
 521         {
 522                 self.model = "";
 523                 if (self.weaponentity)
 524                         self.weaponentity.model = "";
 525                 return;
 526         }
 527         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 528         {
 529                 self.weaponname = self.owner.weaponname;
 530                 self.dmg = self.owner.modelindex;
 531                 self.deadflag = self.owner.deadflag;
 532
 533                 CL_WeaponEntity_SetModel(self.owner.weaponname);
 534         }
 535
 536         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
 537         self.effects = self.owner.effects & EFMASK_CHEAP;
 538         self.effects &~= EF_LOWPRECISION;
 539         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 540         self.effects &~= EF_TELEPORT_BIT;
 541         self.effects &~= EF_RESTARTANIM_BIT;
 542         self.effects |= tb;
 543
 544         if(self.owner.alpha == default_player_alpha)
 545                 self.alpha = default_weapon_alpha;
 546         else if(self.owner.alpha != 0)
 547                 self.alpha = self.owner.alpha;
 548         else
 549                 self.alpha = 1;
 550
 551         self.glowmod = self.owner.weaponentity_glowmod;
 552         self.colormap = self.owner.colormap;
 553         if (self.weaponentity)
 554         {
 555                 self.weaponentity.effects = self.effects;
 556                 self.weaponentity.alpha = self.alpha;
 557                 self.weaponentity.colormap = self.colormap;
 558                 self.weaponentity.glowmod = self.glowmod;
 559         }
 560
 561         self.angles = '0 0 0';
 562         float f;
 563         if (self.state == WS_RAISE && !intermission_running)
 564         {
 565                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 566                 self.angles_x = -90 * f * f;
 567         }
 568         else if (self.state == WS_DROP && !intermission_running)
 569         {
 570                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 571                 self.angles_x = -90 * f * f;
 572         }
 573         else if (self.state == WS_CLEAR)
 574         {
 575                 f = 1;
 576                 self.angles_x = -90 * f * f;
 577         }
 578 }
 579
 580 void CL_ExteriorWeaponentity_Think()
 581 {
 582         float tag_found;
 583         vector ang;
 584         self.nextthink = time;
 585         if (self.owner.exteriorweaponentity != self)
 586         {
 587                 remove(self);
 588                 return;
 589         }
 590         if (self.owner.deadflag != DEAD_NO)
 591         {
 592                 self.model = "";
 593                 return;
 594         }
 595         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 596         {
 597                 self.weaponname = self.owner.weaponname;
 598                 self.dmg = self.owner.modelindex;
 599                 self.deadflag = self.owner.deadflag;
 600                 if (self.owner.weaponname != "")
 601                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 602                 else
 603                         self.model = "";
 604
 605                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 606                 {
 607                         self.tag_index = tag_found;
 608                         self.tag_entity = self.owner;
 609                 }
 610                 else
 611                         setattachment(self, self.owner, "bip01 r hand");
 612         }
 613         self.effects = self.owner.effects;
 614         if(sv_pitch_min == sv_pitch_max)
 615                 self.effects |= EF_LOWPRECISION;
 616         else
 617                 self.effects &~= EF_LOWPRECISION;
 618         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 619         if(self.owner.alpha == default_player_alpha)
 620                 self.alpha = default_weapon_alpha;
 621         else if(self.owner.alpha != 0)
 622                 self.alpha = self.owner.alpha;
 623         else
 624                 self.alpha = 1;
 625
 626         if (!intermission_running)
 627         {
 628                 ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
 629                 ang_y = 0;
 630                 ang_z = 0;
 631
 632                 if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
 633                 {
 634                         ang_y = self.owner.v_angle_y;
 635                         makevectors(ang);
 636                         var vector v = v_forward;
 637                         var float t = self.tag_entity.frame1time;
 638                         var float f = self.tag_entity.frame;
 639                         self.tag_entity.frame1time = time;
 640                         self.tag_entity.frame = self.tag_entity.anim_idle_x;
 641                         gettaginfo(self.tag_entity, self.tag_index);
 642                         self.tag_entity.frame1time = t;
 643                         self.tag_entity.frame = f;
 644                         // untransform v according to this coordinate space
 645                         vector w;
 646                         w_x = v_forward * v;
 647                         w_y = -v_right * v;
 648                         w_z = v_up * v;
 649                         self.angles = vectoangles(w);
 650                 }
 651                 else
 652                 {
 653                         ang_x = -/* don't ask */ang_x;
 654                         self.angles = ang;
 655                 }
 656
 657                 if(autocvar_g_loituma)
 658                 {
 659                         vector modangles;
 660                         float t;
 661
 662                         t = time * autocvar_g_loituma;
 663
 664                         modangles_x = t * 360;
 665                         modangles_y = 90;
 666                         modangles_z = 0;
 667
 668                         self.angles =
 669                                 AnglesTransform_ToAngles(
 670                                         AnglesTransform_Multiply(
 671                                                 AnglesTransform_FromAngles(self.angles),
 672                                                 AnglesTransform_FromAngles(modangles)
 673                                         )
 674                                 );
 675                 }
 676         }
 677
 678         self.glowmod = self.owner.weaponentity_glowmod;
 679         self.colormap = self.owner.colormap;
 680
 681         CSQCMODEL_AUTOUPDATE();
 682 }
 683
 684 // spawning weaponentity for client
 685 void CL_SpawnWeaponentity()
 686 {
 687         self.weaponentity = spawn();
 688         self.weaponentity.classname = "weaponentity";
 689         self.weaponentity.solid = SOLID_NOT;
 690         self.weaponentity.owner = self;
 691         setmodel(self.weaponentity, ""); // precision set when changed
 692         setorigin(self.weaponentity, '0 0 0');
 693         self.weaponentity.angles = '0 0 0';
 694         self.weaponentity.viewmodelforclient = self;
 695         self.weaponentity.flags = 0;
 696         self.weaponentity.think = CL_Weaponentity_Think;
 697         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 698         self.weaponentity.nextthink = time;
 699
 700         self.exteriorweaponentity = spawn();
 701         self.exteriorweaponentity.classname = "exteriorweaponentity";
 702         self.exteriorweaponentity.solid = SOLID_NOT;
 703         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 704         self.exteriorweaponentity.owner = self;
 705         setorigin(self.exteriorweaponentity, '0 0 0');
 706         self.exteriorweaponentity.angles = '0 0 0';
 707         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 708         self.exteriorweaponentity.nextthink = time;
 709
 710         {
 711                 entity oldself = self;
 712                 self = self.exteriorweaponentity;
 713                 CSQCMODEL_AUTOINIT();
 714                 self = oldself;
 715         }
 716 }
 717
 718 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
 719 {
 720         msg_entity = e;
 721         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 722         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
 723         WriteByte(MSG_ONE, wpn);
 724         WriteString(MSG_ONE, wpnname);
 725         WriteByte(MSG_ONE, type);
 726 }
 727
 728 .float hasweapon_complain_spam;
 729
 730 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 731 {
 732         float f;
 733         entity oldself;
 734
 735         if(time < self.hasweapon_complain_spam)
 736                 complain = 0;
 737         if(complain)
 738                 self.hasweapon_complain_spam = time + 0.2;
 739
 740         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 741         {
 742                 if (complain)
 743                         sprint(self, "Invalid weapon\n");
 744                 return FALSE;
 745         }
 746         if (WEPSET_CONTAINS_EW(cl, wpn))
 747         {
 748                 if (andammo)
 749                 {
 750                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 751                         {
 752                                 f = 1;
 753                         }
 754                         else
 755                         {
 756                                 oldself = self;
 757                                 self = cl;
 758                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 759                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 760
 761                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
 762                                 entity mine;
 763                                 if(wpn == WEP_MINE_LAYER)
 764                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 765                                         f = 1;
 766
 767                                 self = oldself;
 768                         }
 769                         if (!f)
 770                         {
 771                                 if (complain)
 772                                 if(clienttype(cl) == CLIENTTYPE_REAL)
 773                                 {
 774                                         play2(cl, "weapons/unavailable.wav");
 775                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 776                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
 777                                 }
 778                                 return FALSE;
 779                         }
 780                 }
 781                 return TRUE;
 782         }
 783         if (complain)
 784         {
 785                 // DRESK - 3/16/07
 786                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 787                 if (WEPSET_CONTAINS_AW(weaponsInMap, wpn))
 788                 {
 789                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 790                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 1);
 791
 792                         if(autocvar_g_showweaponspawns)
 793                         {
 794                                 entity e;
 795                                 string s;
 796
 797                                 e = get_weaponinfo(wpn);
 798                                 s = e.model2;
 799
 800                                 for(e = world; (e = findfloat(e, weapon, wpn)); )
 801                                 {
 802                                         if(e.classname == "droppedweapon")
 803                                                 continue;
 804                                         if not(e.flags & FL_ITEM)
 805                                                 continue;
 806                                         WaypointSprite_Spawn(
 807                                                 s,
 808                                                 1, 0,
 809                                                 world, e.origin,
 810                                                 self, 0,
 811                                                 world, enemy,
 812                                                 0,
 813                                                 RADARICON_NONE, '0 0 0'
 814                                         );
 815                                 }
 816                         }
 817                 }
 818                 else
 819                 {
 820                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
 821                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
 822                 }
 823
 824                 play2(cl, "weapons/unavailable.wav");
 825         }
 826         return FALSE;
 827 }
 828
 829 // Weapon subs
 830 void w_clear()
 831 {
 832         if (self.weapon != -1)
 833         {
 834                 self.weapon = 0;
 835                 self.switchingweapon = 0;
 836         }
 837         if (self.weaponentity)
 838         {
 839                 self.weaponentity.state = WS_CLEAR;
 840                 self.weaponentity.effects = 0;
 841         }
 842 }
 843
 844 void w_ready()
 845 {
 846         if (self.weaponentity)
 847                 self.weaponentity.state = WS_READY;
 848         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
 849 }
 850
 851 // Setup weapon for client (after this raise frame will be launched)
 852 void weapon_setup(float windex)
 853 {
 854         entity e;
 855         e = get_weaponinfo(windex);
 856         self.items &~= IT_AMMO;
 857         self.items = self.items | (e.items & IT_AMMO);
 858
 859         // the two weapon entities will notice this has changed and update their models
 860         self.weapon = windex;
 861         self.switchingweapon = windex; // to make sure
 862         self.weaponname = e.mdl;
 863         self.bulletcounter = 0;
 864 }
 865
 866 // perform weapon to attack (weaponstate and attack_finished check is here)
 867 void W_SwitchToOtherWeapon(entity pl)
 868 {
 869         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
 870         float w, ww;
 871         w = pl.weapon;
 872         if(WEPSET_CONTAINS_EW(pl, w))
 873         {
 874                 WEPSET_ANDNOT_EW(pl, w);
 875                 ww = w_getbestweapon(pl);
 876                 WEPSET_OR_EW(pl, w);
 877         }
 878         else
 879                 ww = w_getbestweapon(pl);
 880         if(ww)
 881                 W_SwitchWeapon_Force(pl, ww);
 882 }
 883
 884 string PrimaryOrSecondary(float secondary)
 885 {
 886         if(secondary)
 887                 return "secondary";
 888         else
 889                 return "primary";
 890 }
 891
 892 .float prevdryfire;
 893 .float prevwarntime;
 894 float weapon_prepareattack_checkammo(float secondary)
 895 {
 896         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 897         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
 898         {
 899                 // always keep the Mine Layer if we placed mines, so that we can detonate them
 900                 entity mine;
 901                 if(self.weapon == WEP_MINE_LAYER)
 902                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 903                         return FALSE;
 904
 905                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
 906                 {
 907                         sound (self, CH_WEAPON_A, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
 908                         self.prevdryfire = time;
 909                 }
 910
 911                 if(weapon_action(self.weapon, WR_CHECKAMMO2 - secondary)) // check if the other firing mode has enough ammo
 912                 {
 913                         if(time - self.prevwarntime > 1)
 914                         {
 915                                 sprint(self, strcat("^2", W_Name(self.weapon), " ", PrimaryOrSecondary(secondary), "^7 is unable to fire, but its ^2", PrimaryOrSecondary(1 - secondary), "^7 can.\n"));
 916                         }
 917                         self.prevwarntime = time;
 918                 }
 919                 else // this weapon is totally unable to fire, switch to another one
 920                 {
 921                         W_SwitchToOtherWeapon(self);
 922                 }
 923
 924                 return FALSE;
 925         }
 926         return TRUE;
 927 }
 928 .float race_penalty;
 929 float weapon_prepareattack_check(float secondary, float attacktime)
 930 {
 931         if(!weapon_prepareattack_checkammo(secondary))
 932                 return FALSE;
 933
 934         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 935         //if all players readied up and the countdown is running
 936         if(time < game_starttime || time < self.race_penalty) {
 937                 return FALSE;
 938         }
 939
 940         if (timeout_status == TIMEOUT_ACTIVE) //don't allow the player to shoot while game is paused
 941                 return FALSE;
 942
 943         // do not even think about shooting if switching
 944         if(self.switchweapon != self.weapon)
 945                 return FALSE;
 946
 947         if(attacktime >= 0)
 948         {
 949                 // don't fire if previous attack is not finished
 950                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
 951                         return FALSE;
 952                 // don't fire while changing weapon
 953                 if (self.weaponentity.state != WS_READY)
 954                         return FALSE;
 955         }
 956
 957         return TRUE;
 958 }
 959 float weapon_prepareattack_do(float secondary, float attacktime)
 960 {
 961         self.weaponentity.state = WS_INUSE;
 962
 963         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
 964
 965         // if the weapon hasn't been firing continuously, reset the timer
 966         if(attacktime >= 0)
 967         {
 968                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
 969                 {
 970                         ATTACK_FINISHED(self) = time;
 971                         //dprint("resetting attack finished to ", ftos(time), "\n");
 972                 }
 973                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
 974         }
 975         self.bulletcounter += 1;
 976         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
 977         return TRUE;
 978 }
 979 float weapon_prepareattack(float secondary, float attacktime)
 980 {
 981         if(weapon_prepareattack_check(secondary, attacktime))
 982         {
 983                 weapon_prepareattack_do(secondary, attacktime);
 984                 return TRUE;
 985         }
 986         else
 987                 return FALSE;
 988 }
 989
 990 void weapon_thinkf(float fr, float t, void() func)
 991 {
 992         vector a;
 993         vector of, or, ou;
 994         float restartanim;
 995
 996         if(fr == WFRAME_DONTCHANGE)
 997         {
 998                 fr = self.weaponentity.wframe;
 999                 restartanim = FALSE;
1000         }
1001         else if (fr == WFRAME_IDLE)
1002                 restartanim = FALSE;
1003         else
1004                 restartanim = TRUE;
1005
1006         of = v_forward;
1007         or = v_right;
1008         ou = v_up;
1009
1010         if (self.weaponentity)
1011         {
1012                 self.weaponentity.wframe = fr;
1013                 a = '0 0 0';
1014                 if (fr == WFRAME_IDLE)
1015                         a = self.weaponentity.anim_idle;
1016                 else if (fr == WFRAME_FIRE1)
1017                         a = self.weaponentity.anim_fire1;
1018                 else if (fr == WFRAME_FIRE2)
1019                         a = self.weaponentity.anim_fire2;
1020                 else // if (fr == WFRAME_RELOAD)
1021                         a = self.weaponentity.anim_reload;
1022                 a_z *= g_weaponratefactor;
1023                 setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
1024         }
1025
1026         v_forward = of;
1027         v_right = or;
1028         v_up = ou;
1029
1030         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1031         {
1032                 backtrace("Tried to override initial weapon think function - should this really happen?");
1033         }
1034
1035         t *= W_WeaponRateFactor();
1036
1037         // VorteX: haste can be added here
1038         if (self.weapon_think == w_ready)
1039         {
1040                 self.weapon_nextthink = time;
1041                 //dprint("started firing at ", ftos(time), "\n");
1042         }
1043         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1044         {
1045                 self.weapon_nextthink = time;
1046                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1047         }
1048         self.weapon_nextthink = self.weapon_nextthink + t;
1049         self.weapon_think = func;
1050         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1051
1052         // The shoot animation looks TERRIBLE without animation blending! Yay for moonwalking while shooting!
1053         //anim = self.anim_shoot;
1054         if (restartanim)
1055         if (t)
1056         if (!self.crouch) // shoot anim stands up, this looks bad
1057         {
1058                 vector anim;
1059                 if(self.weapon == WEP_SHOTGUN && self.BUTTON_ATCK2)
1060                 {
1061                         anim = self.anim_melee;
1062                         anim_z = anim_y / (t + sys_frametime);
1063                         setanim(self, anim, FALSE, TRUE, TRUE);
1064                 }
1065                 else if (self.animstate_startframe == self.anim_idle_x) // only allow shoot anim to override idle animation until we have animation blending
1066                 {
1067                         anim = self.anim_shoot;
1068                         anim_z = anim_y / (t + sys_frametime);
1069                         setanim(self, anim, FALSE, TRUE, TRUE);
1070                 }
1071         }
1072 }
1073
1074 void weapon_boblayer1(float spd, vector org)
1075 {
1076         // VorteX: haste can be added here
1077 }
1078
1079 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
1080 {
1081         vector mdirection;
1082         float mspeed;
1083         vector outvelocity;
1084
1085         mvelocity = mvelocity * g_weaponspeedfactor;
1086
1087         mdirection = normalize(mvelocity);
1088         mspeed = vlen(mvelocity);
1089
1090         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
1091
1092         return outvelocity;
1093 }
1094
1095 void W_AttachToShotorg(entity flash, vector offset)
1096 {
1097         entity xflash;
1098         flash.owner = self;
1099         flash.angles_z = random() * 360;
1100
1101         if(gettagindex(self.weaponentity, "shot"))
1102                 setattachment(flash, self.weaponentity, "shot");
1103         else
1104                 setattachment(flash, self.weaponentity, "tag_shot");
1105         setorigin(flash, offset);
1106
1107         xflash = spawn();
1108         copyentity(flash, xflash);
1109
1110         flash.viewmodelforclient = self;
1111
1112         if(self.weaponentity.oldorigin_x > 0)
1113         {
1114                 setattachment(xflash, self.exteriorweaponentity, "");
1115                 setorigin(xflash, self.weaponentity.oldorigin + offset);
1116         }
1117         else
1118         {
1119                 if(gettagindex(self.exteriorweaponentity, "shot"))
1120                         setattachment(xflash, self.exteriorweaponentity, "shot");
1121                 else
1122                         setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1123                 setorigin(xflash, offset);
1124         }
1125 }
1126
1127 vector cliptoplane(vector v, vector p)
1128 {
1129         return v - (v * p) * p;
1130 }
1131
1132 vector solve_cubic_pq(float p, float q)
1133 {
1134         float D, u, v, a;
1135         D = q*q/4.0 + p*p*p/27.0;
1136         if(D < 0)
1137         {
1138                 // irreducibilis
1139                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1140                 u = sqrt(-4.0/3.0 * p);
1141                 // a in range 0..pi/3
1142                 // cos(a)
1143                 // cos(a + 2pi/3)
1144                 // cos(a + 4pi/3)
1145                 return
1146                         u *
1147                         (
1148                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1149                                 +
1150                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1151                                 +
1152                                 '0 0 1' * cos(a)
1153                         );
1154         }
1155         else if(D == 0)
1156         {
1157                 // simple
1158                 if(p == 0)
1159                         return '0 0 0';
1160                 u = 3*q/p;
1161                 v = -u/2;
1162                 if(u >= v)
1163                         return '1 1 0' * v + '0 0 1' * u;
1164                 else
1165                         return '0 1 1' * v + '1 0 0' * u;
1166         }
1167         else
1168         {
1169                 // cardano
1170                 u = cbrt(-q/2.0 + sqrt(D));
1171                 v = cbrt(-q/2.0 - sqrt(D));
1172                 return '1 1 1' * (u + v);
1173         }
1174 }
1175 vector solve_cubic_abcd(float a, float b, float c, float d)
1176 {
1177         // y = 3*a*x + b
1178         // x = (y - b) / 3a
1179         float p, q;
1180         vector v;
1181         p = (9*a*c - 3*b*b);
1182         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1183         v = solve_cubic_pq(p, q);
1184         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1185         if(a < 0)
1186                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1187         return v;
1188 }
1189
1190 vector findperpendicular(vector v)
1191 {
1192         vector p;
1193         p_x = v_z;
1194         p_y = -v_x;
1195         p_z = v_y;
1196         return normalize(cliptoplane(p, v));
1197 }
1198
1199 vector W_CalculateProjectileSpread(vector forward, float spread)
1200 {
1201         float sigma;
1202         vector v1 = '0 0 0', v2;
1203         float dx, dy, r;
1204         float sstyle;
1205         spread *= g_weaponspreadfactor;
1206         if(spread <= 0)
1207                 return forward;
1208         sstyle = autocvar_g_projectiles_spread_style;
1209
1210         if(sstyle == 0)
1211         {
1212                 // this is the baseline for the spread value!
1213                 // standard deviation: sqrt(2/5)
1214                 // density function: sqrt(1-r^2)
1215                 return forward + randomvec() * spread;
1216         }
1217         else if(sstyle == 1)
1218         {
1219                 // same thing, basically
1220                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1221         }
1222         else if(sstyle == 2)
1223         {
1224                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1225                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1226                 v1 = findperpendicular(forward);
1227                 v2 = cross(forward, v1);
1228                 // random point on unit circle
1229                 dx = random() * 2 * M_PI;
1230                 dy = sin(dx);
1231                 dx = cos(dx);
1232                 // radius in our dist function
1233                 r = random();
1234                 r = sqrt(r);
1235                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1236         }
1237         else if(sstyle == 3) // gauss 3d
1238         {
1239                 sigma = spread * 0.44721359549996; // match baseline stddev
1240                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1241                 v1 = forward;
1242                 v1_x += gsl_ran_gaussian(sigma);
1243                 v1_y += gsl_ran_gaussian(sigma);
1244                 v1_z += gsl_ran_gaussian(sigma);
1245                 return v1;
1246         }
1247         else if(sstyle == 4) // gauss 2d
1248         {
1249                 sigma = spread * 0.44721359549996; // match baseline stddev
1250                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1251                 v1_x = gsl_ran_gaussian(sigma);
1252                 v1_y = gsl_ran_gaussian(sigma);
1253                 v1_z = gsl_ran_gaussian(sigma);
1254                 return normalize(forward + cliptoplane(v1, forward));
1255         }
1256         else if(sstyle == 5) // 1-r
1257         {
1258                 sigma = spread * 1.154700538379252; // match baseline stddev
1259                 v1 = findperpendicular(forward);
1260                 v2 = cross(forward, v1);
1261                 // random point on unit circle
1262                 dx = random() * 2 * M_PI;
1263                 dy = sin(dx);
1264                 dx = cos(dx);
1265                 // radius in our dist function
1266                 r = random();
1267                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1268                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1269         }
1270         else if(sstyle == 6) // 1-r^2
1271         {
1272                 sigma = spread * 1.095445115010332; // match baseline stddev
1273                 v1 = findperpendicular(forward);
1274                 v2 = cross(forward, v1);
1275                 // random point on unit circle
1276                 dx = random() * 2 * M_PI;
1277                 dy = sin(dx);
1278                 dx = cos(dx);
1279                 // radius in our dist function
1280                 r = random();
1281                 r = sqrt(1 - r);
1282                 r = sqrt(1 - r);
1283                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1284         }
1285         else if(sstyle == 7) // (1-r) (2-r)
1286         {
1287                 sigma = spread * 1.224744871391589; // match baseline stddev
1288                 v1 = findperpendicular(forward);
1289                 v2 = cross(forward, v1);
1290                 // random point on unit circle
1291                 dx = random() * 2 * M_PI;
1292                 dy = sin(dx);
1293                 dx = cos(dx);
1294                 // radius in our dist function
1295                 r = random();
1296                 r = 1 - sqrt(r);
1297                 r = 1 - sqrt(r);
1298                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1299         }
1300         else
1301                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1302         return '0 0 0';
1303         /*
1304          * how to derive falloff functions:
1305          * rho(r) := (2-r) * (1-r);
1306          * a : 0;
1307          * b : 1;
1308          * rhor(r) := r * rho(r);
1309          * cr(t) := integrate(rhor(r), r, a, t);
1310          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1311          * variance : scr(b) / cr(b);
1312          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1313          * sqrt(0.4 / variance), numer;
1314          */
1315 }
1316
1317 #if 0
1318 float mspercallsum;
1319 float mspercallsstyle;
1320 float mspercallcount;
1321 #endif
1322 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
1323 {
1324         if(missile.owner == world)
1325                 error("Unowned missile");
1326
1327         dir = dir + upDir * (pUpSpeed / pSpeed);
1328         dir_z += pZSpeed / pSpeed;
1329         pSpeed *= vlen(dir);
1330         dir = normalize(dir);
1331
1332 #if 0
1333         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
1334         {
1335                 mspercallsum = mspercallcount = 0;
1336                 mspercallsstyle = autocvar_g_projectiles_spread_style;
1337         }
1338         mspercallsum -= gettime(GETTIME_HIRES);
1339 #endif
1340         dir = W_CalculateProjectileSpread(dir, spread);
1341 #if 0
1342         mspercallsum += gettime(GETTIME_HIRES);
1343         mspercallcount += 1;
1344         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1345 #endif
1346
1347         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
1348 }
1349
1350 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1351 {
1352         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
1353 }
1354
1355 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"), FALSE)
1356 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"), FALSE)
1357
1358 void W_DecreaseAmmo(.float ammo_type, float ammo_use, float ammo_reload)
1359 {
1360         if((self.items & IT_UNLIMITED_WEAPON_AMMO) && !ammo_reload)
1361                 return;
1362
1363         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
1364         if(ammo_reload)
1365         {
1366                 self.clip_load -= ammo_use;
1367                 self.(weapon_load[self.weapon]) = self.clip_load;
1368         }
1369         else
1370                 self.(self.current_ammo) -= ammo_use;
1371 }
1372
1373 // weapon reloading code
1374
1375 .float reload_ammo_amount, reload_ammo_min, reload_time;
1376 .float reload_complain;
1377 .string reload_sound;
1378
1379 void W_ReloadedAndReady()
1380 {
1381         // finish the reloading process, and do the ammo transfer
1382
1383         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
1384
1385         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
1386         if(!self.reload_ammo_min || self.items & IT_UNLIMITED_WEAPON_AMMO)
1387                 self.clip_load = self.reload_ammo_amount;
1388         else
1389         {
1390                 while(self.clip_load < self.reload_ammo_amount && self.(self.current_ammo)) // make sure we don't add more ammo than we have
1391                 {
1392                         self.clip_load += 1;
1393                         self.(self.current_ammo) -= 1;
1394                 }
1395         }
1396         self.(weapon_load[self.weapon]) = self.clip_load;
1397
1398         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1399         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1400         // so your weapon is disabled for a few seconds without reason
1401
1402         //ATTACK_FINISHED(self) -= self.reload_time - 1;
1403
1404         w_ready();
1405 }
1406
1407 void W_Reload(float sent_ammo_min, float sent_ammo_amount, float sent_time, string sent_sound)
1408 {
1409         // set global values to work with
1410
1411         self.reload_ammo_min = sent_ammo_min;
1412         self.reload_ammo_amount = sent_ammo_amount;
1413         self.reload_time = sent_time;
1414         self.reload_sound = sent_sound;
1415
1416         // check if we meet the necessary conditions to reload
1417
1418         entity e;
1419         e = get_weaponinfo(self.weapon);
1420
1421         // don't reload weapons that don't have the RELOADABLE flag
1422         if not(e.spawnflags & WEP_FLAG_RELOADABLE)
1423         {
1424                 dprint("Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
1425                 return;
1426         }
1427
1428         // return if reloading is disabled for this weapon
1429         if(!self.reload_ammo_amount)
1430                 return;
1431
1432         // our weapon is fully loaded, no need to reload
1433         if (self.clip_load >= self.reload_ammo_amount)
1434                 return;
1435
1436         // no ammo, so nothing to load
1437         if(!self.(self.current_ammo) && self.reload_ammo_min)
1438         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1439         {
1440                 if(clienttype(self) == CLIENTTYPE_REAL && self.reload_complain < time)
1441                 {
1442                         play2(self, "weapons/unavailable.wav");
1443                         sprint(self, strcat("You don't have enough ammo to reload the ^2", W_Name(self.weapon), "\n"));
1444                         self.reload_complain = time + 1;
1445                 }
1446                 // switch away if the amount of ammo is not enough to keep using this weapon
1447                 if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
1448                 {
1449                         self.clip_load = -1; // reload later
1450                         W_SwitchToOtherWeapon(self);
1451                 }
1452                 return;
1453         }
1454
1455         if (self.weaponentity)
1456         {
1457                 if (self.weaponentity.wframe == WFRAME_RELOAD)
1458                         return;
1459
1460                 // allow switching away while reloading, but this will cause a new reload!
1461                 self.weaponentity.state = WS_READY;
1462         }
1463
1464         // now begin the reloading process
1465
1466         sound (self, CH_WEAPON_SINGLE, self.reload_sound, VOL_BASE, ATTN_NORM);
1467
1468         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1469         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1470         // so your weapon is disabled for a few seconds without reason
1471
1472         //ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self)) + self.reload_time + 1;
1473
1474         weapon_thinkf(WFRAME_RELOAD, self.reload_time, W_ReloadedAndReady);
1475
1476         if(self.clip_load < 0)
1477                 self.clip_load = 0;
1478         self.old_clip_load = self.clip_load;
1479         self.clip_load = self.(weapon_load[self.weapon]) = -1;
1480 }