qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.damagedbycontents = oldself.damagedbycontents;
 156         self.angles = oldself.angles;
 157         self.avelocity = oldself.avelocity;
 158         self.classname = "body";
 159         self.damageforcescale = oldself.damageforcescale;
 160         self.effects = oldself.effects;
 161         self.glowmod = oldself.glowmod;
 162         self.event_damage = oldself.event_damage;
 163         self.animstate_startframe = oldself.animstate_startframe;
 164         self.animstate_numframes = oldself.animstate_numframes;
 165         self.animstate_framerate = oldself.animstate_framerate;
 166         self.animstate_starttime = oldself.animstate_starttime;
 167         self.animstate_endtime = oldself.animstate_endtime;
 168         self.animstate_override = oldself.animstate_override;
 169         self.animstate_looping = oldself.animstate_looping;
 170         self.dphitcontentsmask = oldself.dphitcontentsmask;
 171         self.death_time = oldself.death_time;
 172         self.frame = oldself.frame;
 173         self.pain_finished = oldself.pain_finished;
 174         self.health = oldself.health;
 175         self.armorvalue = oldself.armorvalue;
 176         self.armortype = oldself.armortype;
 177         self.model = oldself.model;
 178         self.modelindex = oldself.modelindex;
 179         self.skin = oldself.skin;
 180         self.species = oldself.species;
 181         self.movetype = oldself.movetype;
 182         self.solid = oldself.solid;
 183         self.ballistics_density = oldself.ballistics_density;
 184         self.takedamage = oldself.takedamage;
 185         self.customizeentityforclient = oldself.customizeentityforclient;
 186         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 187         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 188         if (keepvelocity == 1)
 189                 self.velocity = oldself.velocity;
 190         self.oldvelocity = self.velocity;
 191         self.alpha = oldself.alpha;
 192         self.fade_time = oldself.fade_time;
 193         self.fade_rate = oldself.fade_rate;
 194         //self.weapon = oldself.weapon;
 195         setorigin(self, oldself.origin);
 196         setsize(self, oldself.mins, oldself.maxs);
 197         self.prevorigin = oldself.origin;
 198         self.reset = SUB_Remove;
 199
 200         Drag_MoveDrag(oldself, self);
 201
 202         if(self.colormap <= maxclients && self.colormap > 0)
 203                 self.colormap = 1024 + oldself.clientcolors;
 204
 205         CSQCMODEL_AUTOINIT();
 206         self.CopyBody_nextthink = oldself.nextthink;
 207         self.CopyBody_think = oldself.think;
 208         self.nextthink = time;
 209         self.think = CopyBody_Think;
 210
 211         self = oldself;
 212 }
 213
 214 float player_getspecies()
 215 {
 216         float s;
 217         get_model_parameters(self.model, self.skin);
 218         s = get_model_parameters_species;
 219         get_model_parameters(string_null, 0);
 220         if(s < 0)
 221                 return SPECIES_HUMAN;
 222         return s;
 223 }
 224
 225 void player_setupanimsformodel()
 226 {
 227         // defaults for legacy .zym models without animinfo files
 228         self.anim_die1 = animfixfps(self, '0 1 0.5'); // 2 seconds
 229         self.anim_die2 = animfixfps(self, '1 1 0.5'); // 2 seconds
 230         self.anim_draw = animfixfps(self, '2 1 3');
 231         // self.anim_duck = '3 1 100'; // This anim is broken, use slot 3 as a new free slot in the future ;)
 232         self.anim_duckwalk = animfixfps(self, '4 1 1');
 233         self.anim_duckjump = '5 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 234         self.anim_duckidle = animfixfps(self, '6 1 1');
 235         self.anim_idle = animfixfps(self, '7 1 1');
 236         self.anim_jump = '8 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 237         self.anim_pain1 = animfixfps(self, '9 1 2'); // 0.5 seconds
 238         self.anim_pain2 = animfixfps(self, '10 1 2'); // 0.5 seconds
 239         self.anim_shoot = animfixfps(self, '11 1 5'); // analyze models and set framerate
 240         self.anim_taunt = animfixfps(self, '12 1 0.33');
 241         self.anim_run = animfixfps(self, '13 1 1');
 242         self.anim_runbackwards = animfixfps(self, '14 1 1');
 243         self.anim_strafeleft = animfixfps(self, '15 1 1');
 244         self.anim_straferight = animfixfps(self, '16 1 1');
 245         //self.anim_dead1 = animfixfps(self, '17 1 1');
 246         //self.anim_dead2 = animfixfps(self, '18 1 1');
 247         self.anim_forwardright = animfixfps(self, '19 1 1');
 248         self.anim_forwardleft = animfixfps(self, '20 1 1');
 249         self.anim_backright = animfixfps(self, '21 1 1');
 250         self.anim_backleft  = animfixfps(self, '22 1 1');
 251         self.anim_melee = animfixfps(self, '23 1 1');
 252         self.anim_duckwalkbackwards = animfixfps(self, '24 1 1');
 253         self.anim_duckwalkstrafeleft = animfixfps(self, '25 1 1');
 254         self.anim_duckwalkstraferight = animfixfps(self, '26 1 1');
 255         self.anim_duckwalkforwardright = animfixfps(self, '27 1 1');
 256         self.anim_duckwalkforwardleft = animfixfps(self, '28 1 1');
 257         self.anim_duckwalkbackright = animfixfps(self, '29 1 1');
 258         self.anim_duckwalkbackleft  = animfixfps(self, '30 1 1');
 259         // TODO introspect models for finding right "fps" value (1/duration)
 260         // reset animstate now
 261         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 262 }
 263
 264 void player_anim (void)
 265 {
 266         updateanim(self);
 267         if (self.weaponentity)
 268                 updateanim(self.weaponentity);
 269
 270         if (self.deadflag != DEAD_NO)
 271                 return;
 272
 273         if (!self.animstate_override)
 274         {
 275                 if (self.freezetag_frozen)
 276                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 277                 else if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 278                 {
 279                         if (self.crouch)
 280                         {
 281                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 282                                 {
 283                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 284                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 285                                         {
 286                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 287                                                 self.restart_jump = FALSE;
 288                                         }
 289                                 }
 290                         }
 291                         else
 292                         {
 293                 if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 294                 {
 295                     traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 296                     if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 297                     {
 298                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 299                         self.restart_jump = FALSE;
 300                     }
 301                 }
 302                         }
 303                 }
 304                 else if (self.crouch)
 305                 {
 306                         if (self.movement_x > 0 && self.movement_y == 0)
 307                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 308                         else if (self.movement_x < 0 && self.movement_y == 0)
 309                                 setanim(self, self.anim_duckwalkbackwards, TRUE, FALSE, FALSE);
 310                         else if (self.movement_x == 0 && self.movement_y > 0)
 311                                 setanim(self, self.anim_duckwalkstraferight, TRUE, FALSE, FALSE);
 312                         else if (self.movement_x == 0 && self.movement_y < 0)
 313                                 setanim(self, self.anim_duckwalkstrafeleft, TRUE, FALSE, FALSE);
 314                         else if (self.movement_x > 0 && self.movement_y > 0)
 315                                 setanim(self, self.anim_duckwalkforwardright, TRUE, FALSE, FALSE);
 316                         else if (self.movement_x > 0 && self.movement_y < 0)
 317                                 setanim(self, self.anim_duckwalkforwardleft, TRUE, FALSE, FALSE);
 318                         else if (self.movement_x < 0 && self.movement_y > 0)
 319                                 setanim(self, self.anim_duckwalkbackright, TRUE, FALSE, FALSE);
 320                         else if (self.movement_x < 0 && self.movement_y < 0)
 321                                 setanim(self, self.anim_duckwalkbackleft, TRUE, FALSE, FALSE);
 322                         else
 323                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 324                 }
 325                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 326                 {
 327                         if (self.movement_x > 0 && self.movement_y == 0)
 328                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 329                         else if (self.movement_x < 0 && self.movement_y == 0)
 330                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 331                         else if (self.movement_x == 0 && self.movement_y > 0)
 332                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 333                         else if (self.movement_x == 0 && self.movement_y < 0)
 334                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 335                         else if (self.movement_x > 0 && self.movement_y > 0)
 336                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 337                         else if (self.movement_x > 0 && self.movement_y < 0)
 338                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 339                         else if (self.movement_x < 0 && self.movement_y > 0)
 340                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 341                         else if (self.movement_x < 0 && self.movement_y < 0)
 342                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 343                         else
 344                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 345                 }
 346                 else
 347                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 348         }
 349
 350         if (self.weaponentity)
 351         if (!self.weaponentity.animstate_override)
 352                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 353 }
 354
 355 void SpawnThrownWeapon (vector org, float w)
 356 {
 357         if(g_minstagib)
 358         if(self.ammo_cells <= 0)
 359                 return;
 360
 361         if(g_pinata)
 362         {
 363                 float j;
 364                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 365                 {
 366                         if(WEPSET_CONTAINS_EW(self, j))
 367                                 if(W_IsWeaponThrowable(j))
 368                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 369                 }
 370         }
 371         else
 372         {
 373                 if(W_IsWeaponThrowable(self.weapon))
 374                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 375         }
 376 }
 377
 378 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 379 {
 380         float take, save;
 381         vector v;
 382         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 383
 384         // damage resistance (ignore most of the damage from a bullet or similar)
 385         damage = max(damage - 5, 1);
 386
 387         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 388         take = v_x;
 389         save = v_y;
 390
 391         if(sound_allowed(MSG_BROADCAST, attacker))
 392         {
 393                 if (save > 10)
 394                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 395                 else if (take > 30)
 396                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 397                 else if (take > 10)
 398                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 399         }
 400
 401         if (take > 50)
 402                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 403         if (take > 100)
 404                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 405
 406         if (!(self.flags & FL_GODMODE))
 407         {
 408                 self.armorvalue = self.armorvalue - save;
 409                 self.health = self.health - take;
 410                 // pause regeneration for 5 seconds
 411                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 412         }
 413         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 414         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 415         self.dmg_inflictor = inflictor;
 416
 417         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 418         {
 419                 // don't use any animations as a gib
 420                 self.frame = 0;
 421                 // view just above the floor
 422                 self.view_ofs = '0 0 4';
 423
 424                 Violence_GibSplash(self, 1, 1, attacker);
 425                 self.alpha = -1;
 426                 self.solid = SOLID_NOT; // restore later
 427                 self.takedamage = DAMAGE_NO; // restore later
 428         }
 429 }
 430
 431 void ClientKill_Now_TeamChange();
 432 void freezetag_CheckWinner();
 433
 434 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 435 {
 436         float take, save, waves, sdelay, dh, da, j;
 437         vector v;
 438         float valid_damage_for_weaponstats;
 439         float excess;
 440
 441         if((g_arena && numspawned < 2) || (g_ca && allowed_to_spawn) && !inWarmupStage)
 442                 return;
 443
 444         dh = max(self.health, 0);
 445         da = max(self.armorvalue, 0);
 446
 447         if(!DEATH_ISSPECIAL(deathtype))
 448         {
 449                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 450                 if(self != attacker)
 451                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 452         }
 453
 454         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 455         {
 456                 // tuba causes blood to come out of the ears
 457                 vector ear1, ear2;
 458                 vector d;
 459                 float f;
 460                 ear1 = self.origin;
 461                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 462                 ear2 = ear1;
 463                 makevectors(self.angles);
 464                 ear1 += v_right * -10;
 465                 ear2 += v_right * +10;
 466                 d = inflictor.origin - self.origin;
 467                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 468                 force = v_right * vlen(force);
 469                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 470                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 471                 if(f > 0)
 472                 {
 473                         hitloc = ear1;
 474                         force = force * -1;
 475                 }
 476                 else
 477                 {
 478                         hitloc = ear2;
 479                         // force is already good
 480                 }
 481         }
 482         else
 483                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 484
 485         if (!g_minstagib)
 486         {
 487                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 488                 take = v_x;
 489                 save = v_y;
 490         }
 491         else
 492         {
 493                 save = 0;
 494                 take = damage;
 495         }
 496
 497         frag_inflictor = inflictor;
 498         frag_attacker = attacker;
 499         frag_target = self;
 500         damage_take = take;
 501         damage_save = save;
 502         damage_force = force;
 503         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 504         take = bound(0, damage_take, self.health);
 505         save = bound(0, damage_save, self.armorvalue);
 506         excess = max(0, damage - take - save);
 507
 508         if(sound_allowed(MSG_BROADCAST, attacker))
 509         {
 510                 if (save > 10)
 511                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 512                 else if (take > 30)
 513                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 514                 else if (take > 10)
 515                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 516         }
 517
 518         if (take > 50)
 519                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 520         if (take > 100)
 521                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 522
 523         if (time >= self.spawnshieldtime)
 524         {
 525                 if (!(self.flags & FL_GODMODE))
 526                 {
 527                         self.armorvalue = self.armorvalue - save;
 528                         self.health = self.health - take;
 529                         // pause regeneration for 5 seconds
 530                         if(take)
 531                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 532
 533                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 534                         {
 535                                 self.pain_finished = time + 0.5;        //Supajoe
 536
 537                                 if(sv_gentle < 1) {
 538                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 539                                         {
 540                                                 if (!self.animstate_override)
 541                                                 {
 542                                                         if (random() > 0.5)
 543                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 544                                                         else
 545                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 546                                                 }
 547                                         }
 548
 549                                         if(sound_allowed(MSG_BROADCAST, attacker))
 550                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 551                                         if(self.health > 1)
 552                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 553                                         {
 554                                                 if(deathtype == DEATH_FALL)
 555                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 556                                                 else if(self.health > 75) // TODO make a "gentle" version?
 557                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 558                                                 else if(self.health > 50)
 559                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 560                                                 else if(self.health > 25)
 561                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 562                                                 else
 563                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 564                                         }
 565                                 }
 566
 567                                 // throw off bot aim temporarily
 568                                 float shake;
 569                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 570                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 571                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 572                         }
 573                 }
 574                 else
 575                         self.max_armorvalue += (save + take);
 576         }
 577         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 578         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 579         self.dmg_inflictor = inflictor;
 580
 581         if(attacker == self)
 582         {
 583                 // don't reset pushltime for self damage as it may be an attempt to
 584                 // escape a lava pit or similar
 585                 //self.pushltime = 0;
 586                 self.istypefrag = 0;
 587         }
 588         else if(attacker.classname == "player")
 589         {
 590                 self.pusher = attacker;
 591                 self.pushltime = time + autocvar_g_maxpushtime;
 592                 self.istypefrag = self.BUTTON_CHAT;
 593         }
 594         else if(time < self.pushltime)
 595         {
 596                 attacker = self.pusher;
 597                 self.pushltime = max(self.pushltime, time + 0.6);
 598         }
 599         else
 600         {
 601                 self.pushltime = 0;
 602                 self.istypefrag = 0;
 603         }
 604
 605         float abot, vbot, awep;
 606         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 607         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 608
 609         valid_damage_for_weaponstats = 0;
 610         awep = 0;
 611
 612         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 613         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 614         if(attacker && self != attacker)
 615         if(IsDifferentTeam(self, attacker))
 616         {
 617                 if(DEATH_ISSPECIAL(deathtype))
 618                         awep = attacker.weapon;
 619                 else
 620                         awep = DEATH_WEAPONOF(deathtype);
 621                 valid_damage_for_weaponstats = 1;
 622         }
 623
 624         if(valid_damage_for_weaponstats)
 625         {
 626                 dh = dh - max(self.health, 0);
 627                 da = da - max(self.armorvalue, 0);
 628                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 629         }
 630
 631         if (self.health < 1)
 632         {
 633                 float defer_ClientKill_Now_TeamChange;
 634                 defer_ClientKill_Now_TeamChange = FALSE;
 635
 636                 if(self.alivetime)
 637                 {
 638                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 639                         self.alivetime = 0;
 640                 }
 641
 642                 if(valid_damage_for_weaponstats)
 643                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 644
 645                 if(sv_gentle < 1) // TODO make a "gentle" version?
 646                 if(sound_allowed(MSG_BROADCAST, attacker))
 647                 {
 648                         if(deathtype == DEATH_DROWN)
 649                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 650                         else
 651                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 652                 }
 653
 654                 // get rid of kill indicator
 655                 if(self.killindicator)
 656                 {
 657                         remove(self.killindicator);
 658                         self.killindicator = world;
 659                         if(self.killindicator_teamchange)
 660                                 defer_ClientKill_Now_TeamChange = TRUE;
 661
 662                         if(self.classname == "body")
 663                         if(deathtype == DEATH_KILL)
 664                         {
 665                                 // for the lemmings fans, a small harmless explosion
 666                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 667                         }
 668                 }
 669
 670                 if(!g_freezetag)
 671                 {
 672                         // become fully visible
 673                         self.alpha = default_player_alpha;
 674                         // throw a weapon
 675                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 676                 }
 677
 678                 // print an obituary message
 679                 Obituary (attacker, inflictor, self, deathtype);
 680                 race_PreDie();
 681                 DropAllRunes(self);
 682
 683         // increment frag counter for used weapon type
 684         float w;
 685         w = DEATH_WEAPONOF(deathtype);
 686         if(WEP_VALID(w))
 687         if(accuracy_isgooddamage(attacker, self))
 688         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 689
 690                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 691                 {
 692                         PutClientInServer();
 693                         count_alive_players(); // re-count players
 694                         freezetag_CheckWinner();
 695                         return;
 696                 }
 697
 698                 frag_attacker = attacker;
 699                 frag_inflictor = inflictor;
 700                 frag_target = self;
 701                 MUTATOR_CALLHOOK(PlayerDies);
 702                 weapon_action(self.weapon, WR_PLAYERDEATH);
 703
 704                 RemoveGrapplingHook(self);
 705
 706                 if(self.flagcarried)
 707                 {
 708                         if(attacker.classname != "player")
 709                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 710                         else if(attacker.team == self.team)
 711                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 712                         else
 713                                 DropFlag(self.flagcarried, world, attacker);
 714                 }
 715                 Portal_ClearAllLater(self);
 716
 717                 if(clienttype(self) == CLIENTTYPE_REAL)
 718                 {
 719                         stuffcmd(self, "-zoom\n");
 720                         self.fixangle = TRUE;
 721                         //msg_entity = self;
 722                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 723                         //WriteAngle (MSG_ONE, self.v_angle_x);
 724                         //WriteAngle (MSG_ONE, self.v_angle_y);
 725                         //WriteAngle (MSG_ONE, 80);
 726                 }
 727
 728                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 729                         ClientKill_Now_TeamChange();
 730
 731                 if(g_arena)
 732                         Spawnqueue_Unmark(self);
 733
 734                 if(g_freezetag)
 735                         return;
 736
 737                 // when we get here, player actually dies
 738                 // clear waypoints (do this AFTER FreezeTag)
 739                 WaypointSprite_PlayerDead();
 740
 741                 // make the corpse upright (not tilted)
 742                 self.angles_x = 0;
 743                 self.angles_z = 0;
 744                 // don't spin
 745                 self.avelocity = '0 0 0';
 746                 // view from the floor
 747                 self.view_ofs = '0 0 -8';
 748                 // toss the corpse
 749                 self.movetype = MOVETYPE_TOSS;
 750                 // shootable corpse
 751                 self.solid = SOLID_CORPSE;
 752                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 753                 // don't stick to the floor
 754                 self.flags &~= FL_ONGROUND;
 755                 // dying animation
 756                 self.deadflag = DEAD_DYING;
 757                 // when to allow respawn
 758                 sdelay = 0;
 759                 waves = 0;
 760                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 761                 if(!sdelay)
 762                 {
 763                         if(g_cts)
 764                                 sdelay = 0; // no respawn delay in CTS
 765                         else
 766                                 sdelay = autocvar_g_respawn_delay;
 767                 }
 768                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 769                 if(!waves)
 770                         waves = autocvar_g_respawn_waves;
 771                 if(waves)
 772                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 773                 else
 774                         self.respawn_time = time + sdelay;
 775                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 776                         self.respawn_countdown = 10; // first number to count down from is 10
 777                 else
 778                         self.respawn_countdown = -1; // do not count down
 779                 self.death_time = time;
 780                 if (random() < 0.5)
 781                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 782                 else
 783                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 784                 if (self.maxs_z > 5)
 785                 {
 786                         self.maxs_z = 5;
 787                         setsize(self, self.mins, self.maxs);
 788                 }
 789                 // set damage function to corpse damage
 790                 self.event_damage = PlayerCorpseDamage;
 791                 // call the corpse damage function just in case it wants to gib
 792                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 793                 // set up to fade out later
 794                 SUB_SetFade (self, time + 6 + random (), 1);
 795
 796                 if(sv_gentle > 0 || autocvar_ekg) {
 797                         // remove corpse
 798                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 799                 }
 800
 801                 // reset fields the weapons may use just in case
 802                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 803                 {
 804                         weapon_action(j, WR_RESETPLAYER);
 805                         ATTACK_FINISHED_FOR(self, j) = 0;
 806                 }
 807         }
 808 }
 809
 810 .float muted; // to be used by prvm_edictset server playernumber muted 1
 811 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 812 // message "": do not say, just test flood control
 813 // return value:
 814 //   1 = accept
 815 //   0 = reject
 816 //  -1 = fake accept
 817 {
 818         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 819         float flood;
 820         var .float flood_field;
 821         entity head;
 822         float ret;
 823         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 824
 825         if(!teamsay && !privatesay)
 826                 if(substring(msgin, 0, 1) == " ")
 827                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 828
 829         msgin = formatmessage(msgin);
 830
 831         if(source.classname != "player")
 832                 colorstr = "^0"; // black for spectators
 833         else if(teamplay)
 834                 colorstr = Team_ColorCode(source.team);
 835         else
 836         {
 837                 colorstr = "";
 838                 teamsay = FALSE;
 839         }
 840
 841         if(intermission_running)
 842                 teamsay = FALSE;
 843
 844         if(msgin != "")
 845                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 846
 847         /*
 848          * using bprint solves this... me stupid
 849         // how can we prevent the message from appearing in a listen server?
 850         // for now, just give "say" back and only handle say_team
 851         if(!teamsay)
 852         {
 853                 clientcommand(self, strcat("say ", msgin));
 854                 return;
 855         }
 856         */
 857
 858         if(autocvar_g_chat_teamcolors)
 859                 namestr = playername(source);
 860         else
 861                 namestr = source.netname;
 862
 863         if(msgin != "")
 864         {
 865                 if(privatesay)
 866                 {
 867                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 868                         privatemsgprefixlen = strlen(msgstr);
 869                         msgstr = strcat(msgstr, msgin);
 870                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 871                         if(autocvar_g_chat_teamcolors)
 872                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 873                         else
 874                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 875                 }
 876                 else if(teamsay)
 877                 {
 878                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 879                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 880                 }
 881                 else
 882                 {
 883                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 884                         cmsgstr = "";
 885                 }
 886                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 887         }
 888         else
 889         {
 890                 msgstr = cmsgstr = "";
 891         }
 892
 893         fullmsgstr = msgstr;
 894         fullcmsgstr = cmsgstr;
 895
 896         // FLOOD CONTROL
 897         flood = 0;
 898         flood_field = floodcontrol_chat;
 899         if(floodcontrol)
 900         {
 901                 float flood_spl;
 902                 float flood_burst;
 903                 float flood_lmax;
 904                 float lines;
 905                 if(privatesay)
 906                 {
 907                         flood_spl = autocvar_g_chat_flood_spl_tell;
 908                         flood_burst = autocvar_g_chat_flood_burst_tell;
 909                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 910                         flood_field = floodcontrol_chattell;
 911                 }
 912                 else if(teamsay)
 913                 {
 914                         flood_spl = autocvar_g_chat_flood_spl_team;
 915                         flood_burst = autocvar_g_chat_flood_burst_team;
 916                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 917                         flood_field = floodcontrol_chatteam;
 918                 }
 919                 else
 920                 {
 921                         flood_spl = autocvar_g_chat_flood_spl;
 922                         flood_burst = autocvar_g_chat_flood_burst;
 923                         flood_lmax = autocvar_g_chat_flood_lmax;
 924                         flood_field = floodcontrol_chat;
 925                 }
 926                 flood_burst = max(0, flood_burst - 1);
 927                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 928
 929                 // do flood control for the default line size
 930                 if(msgstr != "")
 931                 {
 932                         getWrappedLine_remaining = msgstr;
 933                         msgstr = "";
 934                         lines = 0;
 935                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 936                         {
 937                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 938                                 ++lines;
 939                         }
 940                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 941
 942                         if(getWrappedLine_remaining != "")
 943                         {
 944                                 msgstr = strcat(msgstr, "\n");
 945                                 flood = 2;
 946                         }
 947
 948                         if(time >= source.flood_field)
 949                         {
 950                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 951                         }
 952                         else
 953                         {
 954                                 flood = 1;
 955                                 msgstr = fullmsgstr;
 956                         }
 957                 }
 958                 else
 959                 {
 960                         if(time >= source.flood_field)
 961                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 962                         else
 963                                 flood = 1;
 964                 }
 965
 966                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 967                         source.flood_field = flood = 0;
 968         }
 969
 970         if(flood == 2) // cannot happen for empty msgstr
 971         {
 972                 if(autocvar_g_chat_flood_notify_flooder)
 973                 {
 974                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 975                         sourcecmsgstr = "";
 976                 }
 977                 else
 978                 {
 979                         sourcemsgstr = fullmsgstr;
 980                         sourcecmsgstr = fullcmsgstr;
 981                 }
 982                 cmsgstr = "";
 983         }
 984         else
 985         {
 986                 sourcemsgstr = msgstr;
 987                 sourcecmsgstr = cmsgstr;
 988         }
 989
 990         if(!privatesay)
 991         if(source.classname != "player")
 992         {
 993                 if not(intermission_running)
 994                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
 995                                 teamsay = -1; // spectators
 996         }
 997
 998         if(flood)
 999                 print("NOTE: ", playername(source), "^7 is flooding.\n");
1000
1001         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1002         if(privatesay)
1003                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1004
1005         if(source.muted)
1006         {
1007                 // always fake the message
1008                 ret = -1;
1009         }
1010         else if(flood == 1)
1011         {
1012                 if(autocvar_g_chat_flood_notify_flooder)
1013                 {
1014                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1015                         ret = 0;
1016                 }
1017                 else
1018                         ret = -1;
1019         }
1020         else
1021         {
1022                 ret = 1;
1023         }
1024
1025         if(sourcemsgstr != "" && ret != 0)
1026         {
1027                 if(ret < 0) // faked message, because the player is muted
1028                 {
1029                         sprint(source, sourcemsgstr);
1030                         if(sourcecmsgstr != "" && !privatesay)
1031                                 centerprint(source, sourcecmsgstr);
1032                 }
1033                 else if(privatesay) // private message, between 2 people only, not sent to server console
1034                 {
1035                         sprint(source, sourcemsgstr);
1036                         sprint(privatesay, msgstr);
1037                         if(cmsgstr != "")
1038                                 centerprint(privatesay, cmsgstr);
1039                 }
1040                 else if(teamsay > 0) // team message, only sent to team mates
1041                 {
1042                         sprint(source, sourcemsgstr);
1043                         //print(msgstr); // send to server console too
1044                         if(sourcecmsgstr != "")
1045                                 centerprint(source, sourcecmsgstr);
1046                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1047                                 if(head != source)
1048                                 {
1049                                         sprint(head, msgstr);
1050                                         if(cmsgstr != "")
1051                                                 centerprint(head, cmsgstr);
1052                                 }
1053                 }
1054                 else if(teamsay < 0) // spectator message, only sent to spectators
1055                 {
1056                         sprint(source, sourcemsgstr);
1057                         //print(msgstr); // send to server console too
1058                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1059                                 if(head != source)
1060                                         sprint(head, msgstr);
1061                 }
1062                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
1063                 {
1064                         sprint(source, sourcemsgstr);
1065                         //print(msgstr); // send to server console too
1066                         FOR_EACH_REALCLIENT(head)
1067                                 if(head != source)
1068                                         sprint(head, msgstr);
1069                 }
1070                 else
1071                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
1072         }
1073
1074         return ret;
1075 }
1076
1077 float GetVoiceMessageVoiceType(string type)
1078 {
1079         if(type == "taunt")
1080                 return VOICETYPE_TAUNT;
1081         if(type == "teamshoot")
1082                 return VOICETYPE_LASTATTACKER;
1083         return VOICETYPE_TEAMRADIO;
1084 }
1085
1086 string allvoicesamples;
1087 .string GetVoiceMessageSampleField(string type)
1088 {
1089         GetPlayerSoundSampleField_notFound = 0;
1090         switch(type)
1091         {
1092 #define _VOICEMSG(m) case #m: return playersound_##m;
1093                 ALLVOICEMSGS
1094 #undef _VOICEMSG
1095         }
1096         GetPlayerSoundSampleField_notFound = 1;
1097         return playersound_taunt;
1098 }
1099
1100 .string GetPlayerSoundSampleField(string type)
1101 {
1102         GetPlayerSoundSampleField_notFound = 0;
1103         switch(type)
1104         {
1105 #define _VOICEMSG(m) case #m: return playersound_##m;
1106                 ALLPLAYERSOUNDS
1107 #undef _VOICEMSG
1108         }
1109         GetPlayerSoundSampleField_notFound = 1;
1110         return playersound_taunt;
1111 }
1112
1113 void PrecacheGlobalSound(string samplestring)
1114 {
1115         float n, i;
1116         tokenize_console(samplestring);
1117         n = stof(argv(1));
1118         if(n > 0)
1119         {
1120                 for(i = 1; i <= n; ++i)
1121                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1122         }
1123         else
1124         {
1125                 precache_sound(strcat(argv(0), ".wav"));
1126         }
1127 }
1128
1129 void PrecachePlayerSounds(string f)
1130 {
1131         float fh;
1132         string s;
1133         fh = fopen(f, FILE_READ);
1134         if(fh < 0)
1135                 return;
1136         while((s = fgets(fh)))
1137         {
1138                 if(tokenize_console(s) != 3)
1139                 {
1140                         dprint("Invalid sound info line: ", s, "\n");
1141                         continue;
1142                 }
1143                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1144         }
1145         fclose(fh);
1146
1147         if not(allvoicesamples)
1148         {
1149 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1150                 ALLVOICEMSGS
1151 #undef _VOICEMSG
1152                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1153         }
1154 }
1155
1156 void ClearPlayerSounds()
1157 {
1158 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1159         ALLPLAYERSOUNDS
1160         ALLVOICEMSGS
1161 #undef _VOICEMSG
1162 }
1163
1164 float LoadPlayerSounds(string f, float first)
1165 {
1166         float fh;
1167         string s;
1168         var .string field;
1169         fh = fopen(f, FILE_READ);
1170         if(fh < 0)
1171         {
1172                 dprint("Player sound file not found: ", f, "\n");
1173                 return 0;
1174         }
1175         while((s = fgets(fh)))
1176         {
1177                 if(tokenize_console(s) != 3)
1178                         continue;
1179                 field = GetPlayerSoundSampleField(argv(0));
1180                 if(GetPlayerSoundSampleField_notFound)
1181                         field = GetVoiceMessageSampleField(argv(0));
1182                 if(GetPlayerSoundSampleField_notFound)
1183                         continue;
1184                 if(self.field)
1185                         strunzone(self.field);
1186                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1187         }
1188         fclose(fh);
1189         return 1;
1190 }
1191
1192 .float modelindex_for_playersound;
1193 .float skin_for_playersound;
1194 void UpdatePlayerSounds()
1195 {
1196         if(self.modelindex == self.modelindex_for_playersound)
1197         if(self.skin == self.skin_for_playersound)
1198                 return;
1199         self.modelindex_for_playersound = self.modelindex;
1200         self.skin_for_playersound = self.skin;
1201         ClearPlayerSounds();
1202         LoadPlayerSounds("sound/player/default.sounds", 1);
1203         if(!autocvar_g_debug_defaultsounds)
1204                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1205                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1206 }
1207
1208 void FakeGlobalSound(string sample, float chan, float voicetype)
1209 {
1210         float n;
1211         float tauntrand;
1212
1213         if(sample == "")
1214                 return;
1215
1216         tokenize_console(sample);
1217         n = stof(argv(1));
1218         if(n > 0)
1219                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1220         else
1221                 sample = strcat(argv(0), ".wav"); // randomization
1222
1223         switch(voicetype)
1224         {
1225                 case VOICETYPE_LASTATTACKER_ONLY:
1226                         break;
1227                 case VOICETYPE_LASTATTACKER:
1228                         if(self.pusher)
1229                         {
1230                                 msg_entity = self;
1231                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1232                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1233                         }
1234                         break;
1235                 case VOICETYPE_TEAMRADIO:
1236                         msg_entity = self;
1237                         if(msg_entity.cvar_cl_voice_directional == 1)
1238                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1239                         else
1240                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1241                         break;
1242                 case VOICETYPE_AUTOTAUNT:
1243                         if(!sv_autotaunt)
1244                                 break;
1245                         if(!sv_taunt)
1246                                 break;
1247                         if(sv_gentle)
1248                                 break;
1249                         tauntrand = random();
1250                         msg_entity = self;
1251                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1252                         {
1253                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1254                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1255                                 else
1256                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1257                         }
1258                         break;
1259                 case VOICETYPE_TAUNT:
1260                         if(self.classname == "player")
1261                                 if(self.deadflag == DEAD_NO)
1262                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1263                         if(!sv_taunt)
1264                                 break;
1265                         if(sv_gentle)
1266                                 break;
1267                         msg_entity = self;
1268                         if (msg_entity.cvar_cl_voice_directional >= 1)
1269                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1270                         else
1271                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1272                         break;
1273                 case VOICETYPE_PLAYERSOUND:
1274                         msg_entity = self;
1275                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1276                         break;
1277                 default:
1278                         backtrace("Invalid voice type!");
1279                         break;
1280         }
1281 }
1282
1283 void GlobalSound(string sample, float chan, float voicetype)
1284 {
1285         float n;
1286         float tauntrand;
1287
1288         if(sample == "")
1289                 return;
1290
1291         tokenize_console(sample);
1292         n = stof(argv(1));
1293         if(n > 0)
1294                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1295         else
1296                 sample = strcat(argv(0), ".wav"); // randomization
1297
1298         switch(voicetype)
1299         {
1300                 case VOICETYPE_LASTATTACKER_ONLY:
1301                         if(self.pusher)
1302                         {
1303                                 msg_entity = self.pusher;
1304                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1305                                 {
1306                                         if(msg_entity.cvar_cl_voice_directional == 1)
1307                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1308                                         else
1309                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1310                                 }
1311                         }
1312                         break;
1313                 case VOICETYPE_LASTATTACKER:
1314                         if(self.pusher)
1315                         {
1316                                 msg_entity = self.pusher;
1317                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1318                                 {
1319                                         if(msg_entity.cvar_cl_voice_directional == 1)
1320                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1321                                         else
1322                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1323                                 }
1324                                 msg_entity = self;
1325                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1326                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1327                         }
1328                         break;
1329                 case VOICETYPE_TEAMRADIO:
1330                         FOR_EACH_REALCLIENT(msg_entity)
1331                                 if(!teamplay || msg_entity.team == self.team)
1332                                 {
1333                                         if(msg_entity.cvar_cl_voice_directional == 1)
1334                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1335                                         else
1336                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1337                                 }
1338                         break;
1339                 case VOICETYPE_AUTOTAUNT:
1340                         if(!sv_autotaunt)
1341                                 break;
1342                         if(!sv_taunt)
1343                                 break;
1344                         if(sv_gentle)
1345                                 break;
1346                         tauntrand = random();
1347                         FOR_EACH_REALCLIENT(msg_entity)
1348                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1349                                 {
1350                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1351                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1352                                         else
1353                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1354                                 }
1355                         break;
1356                 case VOICETYPE_TAUNT:
1357                         if(self.classname == "player")
1358                                 if(self.deadflag == DEAD_NO)
1359                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1360                         if(!sv_taunt)
1361                                 break;
1362                         if(sv_gentle)
1363                                 break;
1364                         FOR_EACH_REALCLIENT(msg_entity)
1365                         {
1366                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1367                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1368                                 else
1369                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1370                         }
1371                         break;
1372                 case VOICETYPE_PLAYERSOUND:
1373                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1374                         break;
1375                 default:
1376                         backtrace("Invalid voice type!");
1377                         break;
1378         }
1379 }
1380
1381 void PlayerSound(.string samplefield, float chan, float voicetype)
1382 {
1383         GlobalSound(self.samplefield, chan, voicetype);
1384 }
1385
1386 void VoiceMessage(string type, string msg)
1387 {
1388         var .string sample;
1389         float voicetype, ownteam;
1390         float flood;
1391         sample = GetVoiceMessageSampleField(type);
1392
1393         if(GetPlayerSoundSampleField_notFound)
1394         {
1395                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1396                 return;
1397         }
1398
1399         voicetype = GetVoiceMessageVoiceType(type);
1400         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1401
1402         flood = Say(self, ownteam, world, msg, 1);
1403
1404         if (flood > 0)
1405                 GlobalSound(self.sample, CH_VOICE, voicetype);
1406         else if (flood < 0)
1407                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1408 }
1409
1410 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1411 {
1412 //      show_message
1413 //      0 (00) automove centerprint, admin message
1414 //      1 (01) automove centerprint, no admin message
1415 //      2 (10) no centerprint, admin message
1416 //      3 (11) no centerprint, no admin message
1417
1418         float lockteams_backup;
1419
1420         lockteams_backup = lockteams;  // backup any team lock
1421
1422         lockteams = 0;  // disable locked teams
1423
1424         TeamchangeFrags(client);  // move the players frags
1425         SetPlayerColors(client, team_colour - 1);  // set the players colour
1426         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1427
1428         lockteams = lockteams_backup;  // restore the team lock
1429
1430         LogTeamchange(client.playerid, client.team, type);
1431
1432         if not(show_message & 1) // admin message
1433                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1434
1435         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1436 }