qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(autocvar_sv_weaponstats_file != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  12
  13 void WeaponStats_ready(entity fh, entity pass, float status)
  14 {
  15         float i, j, n, ibot, jbot, idx;
  16         vector v;
  17         string prefix, s;
  18         switch(status)
  19         {
  20                 case URL_READY_CANWRITE:
  21                         // we can write
  22                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  23                         url_fputs(fh, "#begin statsfile\n");
  24                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  25 #ifdef WATERMARK
  26                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  27 #endif
  28                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  29                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  30                         n = tokenizebyseparator(cvar_purechanges, "\n");
  31                         for(i = 0; i < n; ++i)
  32                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  33                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  34                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  35                                 {
  36                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  37                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  38                                         if(v != '0 0 0')
  39                                         {
  40                                                 //vector is: kills hits damage
  41                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  42                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  43                                         }
  44                                 }
  45                         url_fputs(fh, "#end\n\n");
  46                         url_fclose(fh);
  47                         break;
  48                 case URL_READY_CANREAD:
  49                         // url_fclose is processing, we got a response for writing the data
  50                         // this must come from HTTP
  51                         print("Got response from weapon stats server:\n");
  52                         while((s = url_fgets(fh)))
  53                                 print("  ", s, "\n");
  54                         print("End of response.\n");
  55                         url_fclose(fh);
  56                         break;
  57                 case URL_READY_CLOSED:
  58                         // url_fclose has finished
  59                         print("Weapon stats written\n");
  60                         buf_del(weaponstats_buffer);
  61                         weaponstats_buffer = -1;
  62                         break;
  63                 case URL_READY_ERROR:
  64                 default:
  65                         print("Weapon stats writing failed: ", ftos(status), "\n");
  66                         buf_del(weaponstats_buffer);
  67                         weaponstats_buffer = -1;
  68                         break;
  69         }
  70 }
  71
  72 void WeaponStats_Shutdown()
  73 {
  74         if(weaponstats_buffer < 0)
  75                 return;
  76         if(autocvar_sv_weaponstats_file != "")
  77         {
  78                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  79         }
  80         else
  81         {
  82                 buf_del(weaponstats_buffer);
  83                 weaponstats_buffer = -1;
  84         }
  85 }
  86
  87 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  88 {
  89         float idx;
  90         if(weaponstats_buffer < 0)
  91                 return;
  92         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  93                 return;
  94         if(awep > WEP_LAST || vwep > WEP_LAST)
  95                 return;
  96         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
  97         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  98 }
  99 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 100 {
 101         if(damage < 0)
 102                 error("negative damage?");
 103         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 104 }
 105 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 106 {
 107         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 108 }
 109
 110 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 111 // merged player_run and player_stand to player_anim
 112 // added death animations to player_anim
 113 // can now spawn thrown weapons from anywhere, not just from players
 114 // thrown weapons now fade out after 20 seconds
 115 // created PlayerGib function
 116 // PlayerDie no longer uses hitloc or damage
 117 // PlayerDie now supports dying animations as well as gibbing
 118 // cleaned up PlayerDie a lot
 119 // added CopyBody
 120
 121 .entity pusher;
 122 .float pushltime;
 123 .float istypefrag;
 124
 125 .float CopyBody_nextthink;
 126 .void(void) CopyBody_think;
 127 void CopyBody_Think(void)
 128 {
 129         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 130         {
 131                 self.CopyBody_think();
 132                 if(wasfreed(self))
 133                         return;
 134                 self.CopyBody_nextthink = self.nextthink;
 135                 self.CopyBody_think = self.think;
 136                 self.think = CopyBody_Think;
 137         }
 138         CSQCMODEL_AUTOUPDATE();
 139         self.nextthink = time;
 140 }
 141 void CopyBody(float keepvelocity)
 142 {
 143         entity oldself;
 144         if (self.effects & EF_NODRAW)
 145                 return;
 146         oldself = self;
 147         self = spawn();
 148         self.enemy = oldself;
 149         self.lip = oldself.lip;
 150         self.colormap = oldself.colormap;
 151         self.iscreature = oldself.iscreature;
 152         self.teleportable = oldself.teleportable;
 153         self.damagedbycontents = oldself.damagedbycontents;
 154         self.angles = oldself.angles;
 155         self.avelocity = oldself.avelocity;
 156         self.classname = "body";
 157         self.damageforcescale = oldself.damageforcescale;
 158         self.effects = oldself.effects;
 159         self.glowmod = oldself.glowmod;
 160         self.event_damage = oldself.event_damage;
 161         self.anim_state = oldself.anim_state;
 162         self.anim_time = oldself.anim_time;
 163         self.anim_lower_action = oldself.anim_lower_action;
 164         self.anim_lower_time = oldself.anim_lower_time;
 165         self.anim_upper_action = oldself.anim_upper_action;
 166         self.anim_upper_time = oldself.anim_upper_time;
 167         self.anim_implicit_state = oldself.anim_implicit_state;
 168         self.anim_implicit_time = oldself.anim_implicit_time;
 169         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
 170         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
 171         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
 172         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
 173         self.dphitcontentsmask = oldself.dphitcontentsmask;
 174         self.death_time = oldself.death_time;
 175         self.pain_finished = oldself.pain_finished;
 176         self.health = oldself.health;
 177         self.armorvalue = oldself.armorvalue;
 178         self.armortype = oldself.armortype;
 179         self.model = oldself.model;
 180         self.modelindex = oldself.modelindex;
 181         self.skin = oldself.skin;
 182         self.species = oldself.species;
 183         self.movetype = oldself.movetype;
 184         self.solid = oldself.solid;
 185         self.ballistics_density = oldself.ballistics_density;
 186         self.takedamage = oldself.takedamage;
 187         self.customizeentityforclient = oldself.customizeentityforclient;
 188         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 189         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 190         if (keepvelocity == 1)
 191                 self.velocity = oldself.velocity;
 192         self.oldvelocity = self.velocity;
 193         self.alpha = oldself.alpha;
 194         self.fade_time = oldself.fade_time;
 195         self.fade_rate = oldself.fade_rate;
 196         //self.weapon = oldself.weapon;
 197         setorigin(self, oldself.origin);
 198         setsize(self, oldself.mins, oldself.maxs);
 199         self.prevorigin = oldself.origin;
 200         self.reset = SUB_Remove;
 201
 202         Drag_MoveDrag(oldself, self);
 203
 204         if(self.colormap <= maxclients && self.colormap > 0)
 205                 self.colormap = 1024 + oldself.clientcolors;
 206
 207         CSQCMODEL_AUTOINIT();
 208         self.CopyBody_nextthink = oldself.nextthink;
 209         self.CopyBody_think = oldself.think;
 210         self.nextthink = time;
 211         self.think = CopyBody_Think;
 212         // "bake" the current animation frame for clones (they don't get clientside animation)
 213         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
 214
 215         self = oldself;
 216 }
 217
 218 float player_getspecies()
 219 {
 220         float s;
 221         get_model_parameters(self.model, self.skin);
 222         s = get_model_parameters_species;
 223         get_model_parameters(string_null, 0);
 224         if(s < 0)
 225                 return SPECIES_HUMAN;
 226         return s;
 227 }
 228
 229 void player_setupanimsformodel()
 230 {
 231         // load animation info
 232         animdecide_init(self);
 233         animdecide_setstate(self, 0, FALSE);
 234 }
 235
 236 void player_anim (void)
 237 {
 238         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 239         if(self.deadflag && !deadbits)
 240                 if(random() < 0.5)
 241                         deadbits = ANIMSTATE_DEAD1;
 242                 else
 243                         deadbits = ANIMSTATE_DEAD2;
 244         float animbits = deadbits;
 245         if(self.freezetag_frozen)
 246                 animbits |= ANIMSTATE_FROZEN;
 247         if(self.crouch)
 248                 animbits |= ANIMSTATE_DUCK;
 249         animdecide_setstate(self, animbits, FALSE);
 250         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 251
 252         if (self.weaponentity)
 253         {
 254                 updateanim(self.weaponentity);
 255                 if (!self.weaponentity.animstate_override)
 256                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 257         }
 258 }
 259
 260 void SpawnThrownWeapon (vector org, float w)
 261 {
 262         if(g_pinata)
 263         {
 264                 float j;
 265                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 266                 {
 267                         if(WEPSET_CONTAINS_EW(self, j))
 268                                 if(W_IsWeaponThrowable(j))
 269                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 270                 }
 271         }
 272         else
 273         {
 274                 if(WEPSET_CONTAINS_EW(self, self.weapon))
 275                         if(W_IsWeaponThrowable(self.weapon))
 276                                 W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 277         }
 278 }
 279
 280 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 281 {
 282         float take, save;
 283         vector v;
 284         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 285
 286         // damage resistance (ignore most of the damage from a bullet or similar)
 287         damage = max(damage - 5, 1);
 288
 289         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 290         take = v_x;
 291         save = v_y;
 292
 293         if(sound_allowed(MSG_BROADCAST, attacker))
 294         {
 295                 if (save > 10)
 296                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 297                 else if (take > 30)
 298                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 299                 else if (take > 10)
 300                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 301         }
 302
 303         if (take > 50)
 304                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 305         if (take > 100)
 306                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 307
 308         if (!(self.flags & FL_GODMODE))
 309         {
 310                 self.armorvalue = self.armorvalue - save;
 311                 self.health = self.health - take;
 312                 // pause regeneration for 5 seconds
 313                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 314         }
 315         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 316         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 317         self.dmg_inflictor = inflictor;
 318
 319         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 320         {
 321                 // don't use any animations as a gib
 322                 self.frame = 0;
 323                 // view just above the floor
 324                 self.view_ofs = '0 0 4';
 325
 326                 Violence_GibSplash(self, 1, 1, attacker);
 327                 self.alpha = -1;
 328                 self.solid = SOLID_NOT; // restore later
 329                 self.takedamage = DAMAGE_NO; // restore later
 330                 self.damagedbycontents = FALSE;
 331         }
 332 }
 333
 334 void ClientKill_Now_TeamChange();
 335
 336 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 337 {
 338         float take, save, waves, sdelay, dh, da, j;
 339         vector v;
 340         float valid_damage_for_weaponstats;
 341         float excess;
 342
 343         dh = max(self.health, 0);
 344         da = max(self.armorvalue, 0);
 345
 346         if(!DEATH_ISSPECIAL(deathtype))
 347         {
 348                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 349                 if(self != attacker)
 350                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 351         }
 352
 353         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 354         {
 355                 // tuba causes blood to come out of the ears
 356                 vector ear1, ear2;
 357                 vector d;
 358                 float f;
 359                 ear1 = self.origin;
 360                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 361                 ear2 = ear1;
 362                 makevectors(self.angles);
 363                 ear1 += v_right * -10;
 364                 ear2 += v_right * +10;
 365                 d = inflictor.origin - self.origin;
 366                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 367                 force = v_right * vlen(force);
 368                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 369                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 370                 if(f > 0)
 371                 {
 372                         hitloc = ear1;
 373                         force = force * -1;
 374                 }
 375                 else
 376                 {
 377                         hitloc = ear2;
 378                         // force is already good
 379                 }
 380         }
 381         else
 382                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 383
 384
 385         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 386         take = v_x;
 387         save = v_y;
 388
 389         if(attacker == self)
 390         {
 391                 // don't reset pushltime for self damage as it may be an attempt to
 392                 // escape a lava pit or similar
 393                 //self.pushltime = 0;
 394                 self.istypefrag = 0;
 395         }
 396         else if(IS_PLAYER(attacker))
 397         {
 398                 self.pusher = attacker;
 399                 self.pushltime = time + autocvar_g_maxpushtime;
 400                 self.istypefrag = self.BUTTON_CHAT;
 401         }
 402         else if(time < self.pushltime)
 403         {
 404                 attacker = self.pusher;
 405                 self.pushltime = max(self.pushltime, time + 0.6);
 406         }
 407         else
 408         {
 409                 self.pushltime = 0;
 410                 self.istypefrag = 0;
 411         }
 412
 413         frag_inflictor = inflictor;
 414         frag_attacker = attacker;
 415         frag_target = self;
 416         frag_damage = damage;
 417         damage_take = take;
 418         damage_save = save;
 419         damage_force = force;
 420         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 421         take = bound(0, damage_take, self.health);
 422         save = bound(0, damage_save, self.armorvalue);
 423         excess = max(0, damage - take - save);
 424
 425         if(sound_allowed(MSG_BROADCAST, attacker))
 426         {
 427                 if (save > 10)
 428                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 429                 else if (take > 30)
 430                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 431                 else if (take > 10)
 432                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 433         }
 434
 435         if (take > 50)
 436                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 437         if (take > 100)
 438                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 439
 440         if (time >= self.spawnshieldtime)
 441         {
 442                 if (!(self.flags & FL_GODMODE))
 443                 {
 444                         self.armorvalue = self.armorvalue - save;
 445                         self.health = self.health - take;
 446                         // pause regeneration for 5 seconds
 447                         if(take)
 448                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 449
 450                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 451                         {
 452                                 self.pain_finished = time + 0.5;        //Supajoe
 453
 454                                 if(autocvar_sv_gentle < 1) {
 455                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 456                                         {
 457                                                 if (!self.animstate_override)
 458                                                 {
 459                                                         if (random() > 0.5)
 460                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 461                                                         else
 462                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 463                                                 }
 464                                         }
 465
 466                                         if(sound_allowed(MSG_BROADCAST, attacker))
 467                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 468                                         if(self.health > 1)
 469                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 470                                         {
 471                                                 if(deathtype == DEATH_FALL)
 472                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 473                                                 else if(self.health > 75) // TODO make a "gentle" version?
 474                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 475                                                 else if(self.health > 50)
 476                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 477                                                 else if(self.health > 25)
 478                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 479                                                 else
 480                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 481                                         }
 482                                 }
 483
 484                                 // throw off bot aim temporarily
 485                                 float shake;
 486                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 487                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 488                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 489                         }
 490                 }
 491                 else
 492                         self.max_armorvalue += (save + take);
 493         }
 494         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 495         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 496         self.dmg_inflictor = inflictor;
 497
 498         if(g_ca && self != attacker && IS_PLAYER(attacker))
 499                 PlayerTeamScore_Add(attacker, SP_SCORE, ST_SCORE, (damage - excess) * autocvar_g_ca_damage2score_multiplier);
 500
 501         float abot, vbot, awep;
 502         abot = (IS_BOT_CLIENT(attacker));
 503         vbot = (IS_BOT_CLIENT(self));
 504
 505         valid_damage_for_weaponstats = 0;
 506         awep = 0;
 507
 508         if(vbot || IS_REAL_CLIENT(self))
 509         if(abot || IS_REAL_CLIENT(attacker))
 510         if(attacker && self != attacker)
 511         if(IsDifferentTeam(self, attacker))
 512         {
 513                 if(DEATH_ISSPECIAL(deathtype))
 514                         awep = attacker.weapon;
 515                 else
 516                         awep = DEATH_WEAPONOF(deathtype);
 517                 valid_damage_for_weaponstats = 1;
 518         }
 519
 520         if(valid_damage_for_weaponstats)
 521         {
 522                 dh = dh - max(self.health, 0);
 523                 da = da - max(self.armorvalue, 0);
 524                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 525         }
 526
 527         if (self.health < 1)
 528         {
 529                 float defer_ClientKill_Now_TeamChange;
 530                 defer_ClientKill_Now_TeamChange = FALSE;
 531
 532                 if(self.alivetime)
 533                 {
 534                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 535                         self.alivetime = 0;
 536                 }
 537
 538                 if(valid_damage_for_weaponstats)
 539                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 540
 541                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 542                 if(sound_allowed(MSG_BROADCAST, attacker))
 543                 {
 544                         if(deathtype == DEATH_DROWN)
 545                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 546                         else
 547                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 548                 }
 549
 550                 // get rid of kill indicator
 551                 if(self.killindicator)
 552                 {
 553                         remove(self.killindicator);
 554                         self.killindicator = world;
 555                         if(self.killindicator_teamchange)
 556                                 defer_ClientKill_Now_TeamChange = TRUE;
 557
 558                         if(self.classname == "body")
 559                         if(deathtype == DEATH_KILL)
 560                         {
 561                                 // for the lemmings fans, a small harmless explosion
 562                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 563                         }
 564                 }
 565
 566                 // print an obituary message
 567                 Obituary (attacker, inflictor, self, deathtype);
 568                 race_PreDie();
 569
 570         // increment frag counter for used weapon type
 571         float w;
 572         w = DEATH_WEAPONOF(deathtype);
 573         if(WEP_VALID(w))
 574         if(accuracy_isgooddamage(attacker, self))
 575         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 576
 577                 frag_attacker = attacker;
 578                 frag_inflictor = inflictor;
 579                 frag_target = self;
 580                 frag_deathtype = deathtype;
 581                 MUTATOR_CALLHOOK(PlayerDies);
 582
 583                 WEP_ACTION(self.weapon, WR_PLAYERDEATH);
 584
 585                 RemoveGrapplingHook(self);
 586
 587                 Portal_ClearAllLater(self);
 588
 589                 if(IS_REAL_CLIENT(self))
 590                 {
 591                         self.fixangle = TRUE;
 592                         //msg_entity = self;
 593                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 594                         //WriteAngle (MSG_ONE, self.v_angle_x);
 595                         //WriteAngle (MSG_ONE, self.v_angle_y);
 596                         //WriteAngle (MSG_ONE, 80);
 597                 }
 598
 599                 if(defer_ClientKill_Now_TeamChange)
 600                         ClientKill_Now_TeamChange(); // can turn player into spectator
 601
 602                 // player could have been miraculously resuscitated ;)
 603                 // e.g. players in freezetag get frozen, they don't really die
 604                 if(self.health >= 1 || !IS_PLAYER(self))
 605                         return;
 606
 607                 // when we get here, player actually dies
 608
 609                 // clear waypoints
 610                 WaypointSprite_PlayerDead();
 611                 // throw a weapon
 612                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 613
 614                 // become fully visible
 615                 self.alpha = default_player_alpha;
 616                 // make the corpse upright (not tilted)
 617                 self.angles_x = 0;
 618                 self.angles_z = 0;
 619                 // don't spin
 620                 self.avelocity = '0 0 0';
 621                 // view from the floor
 622                 self.view_ofs = '0 0 -8';
 623                 // toss the corpse
 624                 self.movetype = MOVETYPE_TOSS;
 625                 // shootable corpse
 626                 self.solid = SOLID_CORPSE;
 627                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 628                 // don't stick to the floor
 629                 self.flags &~= FL_ONGROUND;
 630                 // dying animation
 631                 self.deadflag = DEAD_DYING;
 632                 // when to allow respawn
 633                 sdelay = 0;
 634                 waves = 0;
 635                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 636                 if(!sdelay)
 637                 {
 638                         if(g_cts)
 639                                 sdelay = 0; // no respawn delay in CTS
 640                         else
 641                                 sdelay = autocvar_g_respawn_delay;
 642                 }
 643                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 644                 if(!waves)
 645                         waves = autocvar_g_respawn_waves;
 646                 if(waves)
 647                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 648                 else
 649                         self.respawn_time = time + sdelay;
 650                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 651                         self.respawn_countdown = 10; // first number to count down from is 10
 652                 else
 653                         self.respawn_countdown = -1; // do not count down
 654
 655                 if(g_cts || autocvar_g_forced_respawn)
 656                         self.respawn_flags = self.respawn_flags | RESPAWN_FORCE;
 657
 658                 self.death_time = time;
 659                 if (random() < 0.5)
 660                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 661                 else
 662                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 663                 if (self.maxs_z > 5)
 664                 {
 665                         self.maxs_z = 5;
 666                         setsize(self, self.mins, self.maxs);
 667                 }
 668                 // set damage function to corpse damage
 669                 self.event_damage = PlayerCorpseDamage;
 670                 // call the corpse damage function just in case it wants to gib
 671                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 672                 // set up to fade out later
 673                 SUB_SetFade (self, time + 6 + random (), 1);
 674
 675                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 676                         // remove corpse
 677                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 678                 }
 679
 680                 // reset fields the weapons may use just in case
 681                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 682                 {
 683                         WEP_ACTION(j, WR_RESETPLAYER);
 684                         ATTACK_FINISHED_FOR(self, j) = 0;
 685                 }
 686         }
 687 }
 688
 689 .float muted; // to be used by prvm_edictset server playernumber muted 1
 690 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 691 // message "": do not say, just test flood control
 692 // return value:
 693 //   1 = accept
 694 //   0 = reject
 695 //  -1 = fake accept
 696 {
 697         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 698         float flood;
 699         var .float flood_field;
 700         entity head;
 701         float ret;
 702         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 703
 704         if(!teamsay && !privatesay)
 705                 if(substring(msgin, 0, 1) == " ")
 706                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 707
 708         msgin = formatmessage(msgin);
 709
 710         if not(IS_PLAYER(source))
 711                 colorstr = "^0"; // black for spectators
 712         else if(teamplay)
 713                 colorstr = Team_ColorCode(source.team);
 714         else
 715         {
 716                 colorstr = "";
 717                 teamsay = FALSE;
 718         }
 719
 720         if(intermission_running)
 721                 teamsay = FALSE;
 722
 723         if(msgin != "")
 724                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 725
 726         /*
 727          * using bprint solves this... me stupid
 728         // how can we prevent the message from appearing in a listen server?
 729         // for now, just give "say" back and only handle say_team
 730         if(!teamsay)
 731         {
 732                 clientcommand(self, strcat("say ", msgin));
 733                 return;
 734         }
 735         */
 736
 737         if(autocvar_g_chat_teamcolors)
 738                 namestr = playername(source);
 739         else
 740                 namestr = source.netname;
 741
 742         if(msgin != "")
 743         {
 744                 if(privatesay)
 745                 {
 746                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 747                         privatemsgprefixlen = strlen(msgstr);
 748                         msgstr = strcat(msgstr, msgin);
 749                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 750                         if(autocvar_g_chat_teamcolors)
 751                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 752                         else
 753                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 754                 }
 755                 else if(teamsay)
 756                 {
 757                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 758                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 759                 }
 760                 else
 761                 {
 762                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 763                         cmsgstr = "";
 764                 }
 765                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 766         }
 767         else
 768         {
 769                 msgstr = cmsgstr = "";
 770         }
 771
 772         fullmsgstr = msgstr;
 773         fullcmsgstr = cmsgstr;
 774
 775         // FLOOD CONTROL
 776         flood = 0;
 777         flood_field = floodcontrol_chat;
 778         if(floodcontrol)
 779         {
 780                 float flood_spl;
 781                 float flood_burst;
 782                 float flood_lmax;
 783                 float lines;
 784                 if(privatesay)
 785                 {
 786                         flood_spl = autocvar_g_chat_flood_spl_tell;
 787                         flood_burst = autocvar_g_chat_flood_burst_tell;
 788                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 789                         flood_field = floodcontrol_chattell;
 790                 }
 791                 else if(teamsay)
 792                 {
 793                         flood_spl = autocvar_g_chat_flood_spl_team;
 794                         flood_burst = autocvar_g_chat_flood_burst_team;
 795                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 796                         flood_field = floodcontrol_chatteam;
 797                 }
 798                 else
 799                 {
 800                         flood_spl = autocvar_g_chat_flood_spl;
 801                         flood_burst = autocvar_g_chat_flood_burst;
 802                         flood_lmax = autocvar_g_chat_flood_lmax;
 803                         flood_field = floodcontrol_chat;
 804                 }
 805                 flood_burst = max(0, flood_burst - 1);
 806                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 807
 808                 // do flood control for the default line size
 809                 if(msgstr != "")
 810                 {
 811                         getWrappedLine_remaining = msgstr;
 812                         msgstr = "";
 813                         lines = 0;
 814                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 815                         {
 816                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 817                                 ++lines;
 818                         }
 819                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 820
 821                         if(getWrappedLine_remaining != "")
 822                         {
 823                                 msgstr = strcat(msgstr, "\n");
 824                                 flood = 2;
 825                         }
 826
 827                         if(time >= source.flood_field)
 828                         {
 829                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 830                         }
 831                         else
 832                         {
 833                                 flood = 1;
 834                                 msgstr = fullmsgstr;
 835                         }
 836                 }
 837                 else
 838                 {
 839                         if(time >= source.flood_field)
 840                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 841                         else
 842                                 flood = 1;
 843                 }
 844
 845                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 846                         source.flood_field = flood = 0;
 847         }
 848
 849         if(flood == 2) // cannot happen for empty msgstr
 850         {
 851                 if(autocvar_g_chat_flood_notify_flooder)
 852                 {
 853                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 854                         sourcecmsgstr = "";
 855                 }
 856                 else
 857                 {
 858                         sourcemsgstr = fullmsgstr;
 859                         sourcecmsgstr = fullcmsgstr;
 860                 }
 861                 cmsgstr = "";
 862         }
 863         else
 864         {
 865                 sourcemsgstr = msgstr;
 866                 sourcecmsgstr = cmsgstr;
 867         }
 868
 869         if(!privatesay)
 870         if not(IS_PLAYER(source))
 871         {
 872                 if not(intermission_running)
 873                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
 874                                 teamsay = -1; // spectators
 875         }
 876
 877         if(flood)
 878                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 879
 880         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 881         if(privatesay)
 882                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 883
 884         if(source.muted)
 885         {
 886                 // always fake the message
 887                 ret = -1;
 888         }
 889         else if(flood == 1)
 890         {
 891                 if(autocvar_g_chat_flood_notify_flooder)
 892                 {
 893                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 894                         ret = 0;
 895                 }
 896                 else
 897                         ret = -1;
 898         }
 899         else
 900         {
 901                 ret = 1;
 902         }
 903
 904         if(sourcemsgstr != "" && ret != 0)
 905         {
 906                 if(ret < 0) // faked message, because the player is muted
 907                 {
 908                         sprint(source, sourcemsgstr);
 909                         if(sourcecmsgstr != "" && !privatesay)
 910                                 centerprint(source, sourcecmsgstr);
 911                 }
 912                 else if(privatesay) // private message, between 2 people only
 913                 {
 914                         sprint(source, sourcemsgstr);
 915                         sprint(privatesay, msgstr);
 916                         if not(autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 917                         if(cmsgstr != "")
 918                                 centerprint(privatesay, cmsgstr);
 919                 }
 920                 else if(teamsay > 0) // team message, only sent to team mates
 921                 {
 922                         sprint(source, sourcemsgstr);
 923                         dedicated_print(msgstr); // send to server console too
 924                         if(sourcecmsgstr != "")
 925                                 centerprint(source, sourcecmsgstr);
 926                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 927                                 if(head != source)
 928                                 {
 929                                         sprint(head, msgstr);
 930                                         if(cmsgstr != "")
 931                                                 centerprint(head, cmsgstr);
 932                                 }
 933                 }
 934                 else if(teamsay < 0) // spectator message, only sent to spectators
 935                 {
 936                         sprint(source, sourcemsgstr);
 937                         dedicated_print(msgstr); // send to server console too
 938                         FOR_EACH_REALCLIENT(head) if not(IS_PLAYER(head))
 939                                 if(head != source)
 940                                         sprint(head, msgstr);
 941                 }
 942                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 943                 {
 944                         sprint(source, sourcemsgstr);
 945                         dedicated_print(msgstr); // send to server console too
 946                         FOR_EACH_REALCLIENT(head)
 947                                 if(head != source)
 948                                         sprint(head, msgstr);
 949                 }
 950                 else
 951                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 952         }
 953
 954         return ret;
 955 }
 956
 957 float GetVoiceMessageVoiceType(string type)
 958 {
 959         if(type == "taunt")
 960                 return VOICETYPE_TAUNT;
 961         if(type == "teamshoot")
 962                 return VOICETYPE_LASTATTACKER;
 963         return VOICETYPE_TEAMRADIO;
 964 }
 965
 966 string allvoicesamples;
 967 .string GetVoiceMessageSampleField(string type)
 968 {
 969         GetPlayerSoundSampleField_notFound = 0;
 970         switch(type)
 971         {
 972 #define _VOICEMSG(m) case #m: return playersound_##m;
 973                 ALLVOICEMSGS
 974 #undef _VOICEMSG
 975         }
 976         GetPlayerSoundSampleField_notFound = 1;
 977         return playersound_taunt;
 978 }
 979
 980 .string GetPlayerSoundSampleField(string type)
 981 {
 982         GetPlayerSoundSampleField_notFound = 0;
 983         switch(type)
 984         {
 985 #define _VOICEMSG(m) case #m: return playersound_##m;
 986                 ALLPLAYERSOUNDS
 987 #undef _VOICEMSG
 988         }
 989         GetPlayerSoundSampleField_notFound = 1;
 990         return playersound_taunt;
 991 }
 992
 993 void PrecacheGlobalSound(string samplestring)
 994 {
 995         float n, i;
 996         tokenize_console(samplestring);
 997         n = stof(argv(1));
 998         if(n > 0)
 999         {
1000                 for(i = 1; i <= n; ++i)
1001                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1002         }
1003         else
1004         {
1005                 precache_sound(strcat(argv(0), ".wav"));
1006         }
1007 }
1008
1009 void PrecachePlayerSounds(string f)
1010 {
1011         float fh;
1012         string s;
1013         fh = fopen(f, FILE_READ);
1014         if(fh < 0)
1015                 return;
1016         while((s = fgets(fh)))
1017         {
1018                 if(tokenize_console(s) != 3)
1019                 {
1020                         dprint("Invalid sound info line: ", s, "\n");
1021                         continue;
1022                 }
1023                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1024         }
1025         fclose(fh);
1026
1027         if not(allvoicesamples)
1028         {
1029 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1030                 ALLVOICEMSGS
1031 #undef _VOICEMSG
1032                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1033         }
1034 }
1035
1036 void ClearPlayerSounds()
1037 {
1038 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1039         ALLPLAYERSOUNDS
1040         ALLVOICEMSGS
1041 #undef _VOICEMSG
1042 }
1043
1044 float LoadPlayerSounds(string f, float first)
1045 {
1046         float fh;
1047         string s;
1048         var .string field;
1049         fh = fopen(f, FILE_READ);
1050         if(fh < 0)
1051         {
1052                 dprint("Player sound file not found: ", f, "\n");
1053                 return 0;
1054         }
1055         while((s = fgets(fh)))
1056         {
1057                 if(tokenize_console(s) != 3)
1058                         continue;
1059                 field = GetPlayerSoundSampleField(argv(0));
1060                 if(GetPlayerSoundSampleField_notFound)
1061                         field = GetVoiceMessageSampleField(argv(0));
1062                 if(GetPlayerSoundSampleField_notFound)
1063                         continue;
1064                 if(self.field)
1065                         strunzone(self.field);
1066                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1067         }
1068         fclose(fh);
1069         return 1;
1070 }
1071
1072 .float modelindex_for_playersound;
1073 .float skin_for_playersound;
1074 void UpdatePlayerSounds()
1075 {
1076         if(self.modelindex == self.modelindex_for_playersound)
1077         if(self.skin == self.skin_for_playersound)
1078                 return;
1079         self.modelindex_for_playersound = self.modelindex;
1080         self.skin_for_playersound = self.skin;
1081         ClearPlayerSounds();
1082         LoadPlayerSounds("sound/player/default.sounds", 1);
1083         if(!autocvar_g_debug_defaultsounds)
1084                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1085                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1086 }
1087
1088 void FakeGlobalSound(string sample, float chan, float voicetype)
1089 {
1090         float n;
1091         float tauntrand;
1092
1093         if(sample == "")
1094                 return;
1095
1096         tokenize_console(sample);
1097         n = stof(argv(1));
1098         if(n > 0)
1099                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1100         else
1101                 sample = strcat(argv(0), ".wav"); // randomization
1102
1103         switch(voicetype)
1104         {
1105                 case VOICETYPE_LASTATTACKER_ONLY:
1106                         break;
1107                 case VOICETYPE_LASTATTACKER:
1108                         if(self.pusher)
1109                         {
1110                                 msg_entity = self;
1111                                 if(IS_REAL_CLIENT(msg_entity))
1112                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1113                         }
1114                         break;
1115                 case VOICETYPE_TEAMRADIO:
1116                         msg_entity = self;
1117                         if(msg_entity.cvar_cl_voice_directional == 1)
1118                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1119                         else
1120                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1121                         break;
1122                 case VOICETYPE_AUTOTAUNT:
1123                         if(!sv_autotaunt)
1124                                 break;
1125                         if(!sv_taunt)
1126                                 break;
1127                         if(autocvar_sv_gentle)
1128                                 break;
1129                         tauntrand = random();
1130                         msg_entity = self;
1131                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1132                         {
1133                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1134                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1135                                 else
1136                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1137                         }
1138                         break;
1139                 case VOICETYPE_TAUNT:
1140                         if(IS_PLAYER(self))
1141                                 if(self.deadflag == DEAD_NO)
1142                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1143                         if(!sv_taunt)
1144                                 break;
1145                         if(autocvar_sv_gentle)
1146                                 break;
1147                         msg_entity = self;
1148                         if (msg_entity.cvar_cl_voice_directional >= 1)
1149                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1150                         else
1151                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1152                         break;
1153                 case VOICETYPE_PLAYERSOUND:
1154                         msg_entity = self;
1155                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1156                         break;
1157                 default:
1158                         backtrace("Invalid voice type!");
1159                         break;
1160         }
1161 }
1162
1163 void GlobalSound(string sample, float chan, float voicetype)
1164 {
1165         float n;
1166         float tauntrand;
1167
1168         if(sample == "")
1169                 return;
1170
1171         tokenize_console(sample);
1172         n = stof(argv(1));
1173         if(n > 0)
1174                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1175         else
1176                 sample = strcat(argv(0), ".wav"); // randomization
1177
1178         switch(voicetype)
1179         {
1180                 case VOICETYPE_LASTATTACKER_ONLY:
1181                         if(self.pusher)
1182                         {
1183                                 msg_entity = self.pusher;
1184                                 if(IS_REAL_CLIENT(msg_entity))
1185                                 {
1186                                         if(msg_entity.cvar_cl_voice_directional == 1)
1187                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1188                                         else
1189                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1190                                 }
1191                         }
1192                         break;
1193                 case VOICETYPE_LASTATTACKER:
1194                         if(self.pusher)
1195                         {
1196                                 msg_entity = self.pusher;
1197                                 if(IS_REAL_CLIENT(msg_entity))
1198                                 {
1199                                         if(msg_entity.cvar_cl_voice_directional == 1)
1200                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1201                                         else
1202                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1203                                 }
1204                                 msg_entity = self;
1205                                 if(IS_REAL_CLIENT(msg_entity))
1206                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1207                         }
1208                         break;
1209                 case VOICETYPE_TEAMRADIO:
1210                         FOR_EACH_REALCLIENT(msg_entity)
1211                                 if(!teamplay || msg_entity.team == self.team)
1212                                 {
1213                                         if(msg_entity.cvar_cl_voice_directional == 1)
1214                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1215                                         else
1216                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1217                                 }
1218                         break;
1219                 case VOICETYPE_AUTOTAUNT:
1220                         if(!sv_autotaunt)
1221                                 break;
1222                         if(!sv_taunt)
1223                                 break;
1224                         if(autocvar_sv_gentle)
1225                                 break;
1226                         tauntrand = random();
1227                         FOR_EACH_REALCLIENT(msg_entity)
1228                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1229                                 {
1230                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1231                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1232                                         else
1233                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1234                                 }
1235                         break;
1236                 case VOICETYPE_TAUNT:
1237                         if(IS_PLAYER(self))
1238                                 if(self.deadflag == DEAD_NO)
1239                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1240                         if(!sv_taunt)
1241                                 break;
1242                         if(autocvar_sv_gentle)
1243                                 break;
1244                         FOR_EACH_REALCLIENT(msg_entity)
1245                         {
1246                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1247                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1248                                 else
1249                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1250                         }
1251                         break;
1252                 case VOICETYPE_PLAYERSOUND:
1253                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1254                         break;
1255                 default:
1256                         backtrace("Invalid voice type!");
1257                         break;
1258         }
1259 }
1260
1261 void PlayerSound(.string samplefield, float chan, float voicetype)
1262 {
1263         GlobalSound(self.samplefield, chan, voicetype);
1264 }
1265
1266 void VoiceMessage(string type, string msg)
1267 {
1268         var .string sample;
1269         float voicetype, ownteam;
1270         float flood;
1271         sample = GetVoiceMessageSampleField(type);
1272
1273         if(GetPlayerSoundSampleField_notFound)
1274         {
1275                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1276                 return;
1277         }
1278
1279         voicetype = GetVoiceMessageVoiceType(type);
1280         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1281
1282         flood = Say(self, ownteam, world, msg, 1);
1283
1284         if (flood > 0)
1285                 GlobalSound(self.sample, CH_VOICE, voicetype);
1286         else if (flood < 0)
1287                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1288 }
1289
1290 void MoveToTeam(entity client, float team_colour, float type)
1291 {
1292         float lockteams_backup;
1293
1294         lockteams_backup = lockteams;  // backup any team lock
1295
1296         lockteams = 0;  // disable locked teams
1297
1298         TeamchangeFrags(client);  // move the players frags
1299         SetPlayerColors(client, team_colour - 1);  // set the players colour
1300         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1301
1302         lockteams = lockteams_backup;  // restore the team lock
1303
1304         LogTeamchange(client.playerid, client.team, type);
1305 }