qcsrc/server/cl_player.qc

   1 .entity pusher;
   2 .float pushltime;
   3 .float istypefrag;
   4
   5 .float CopyBody_nextthink;
   6 .void(void) CopyBody_think;
   7 void CopyBody_Think(void)
   8 {
   9         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
  10         {
  11                 self.CopyBody_think();
  12                 if(wasfreed(self))
  13                         return;
  14                 self.CopyBody_nextthink = self.nextthink;
  15                 self.CopyBody_think = self.think;
  16                 self.think = CopyBody_Think;
  17         }
  18         CSQCMODEL_AUTOUPDATE();
  19         self.nextthink = time;
  20 }
  21 void CopyBody(float keepvelocity)
  22 {
  23         entity oldself;
  24         if (self.effects & EF_NODRAW)
  25                 return;
  26         oldself = self;
  27         self = spawn();
  28         self.enemy = oldself;
  29         self.lip = oldself.lip;
  30         self.colormap = oldself.colormap;
  31         self.iscreature = oldself.iscreature;
  32         self.teleportable = oldself.teleportable;
  33         self.damagedbycontents = oldself.damagedbycontents;
  34         self.angles = oldself.angles;
  35         self.v_angle = oldself.v_angle;
  36         self.avelocity = oldself.avelocity;
  37         self.classname = "body";
  38         self.damageforcescale = oldself.damageforcescale;
  39         self.effects = oldself.effects;
  40         self.glowmod = oldself.glowmod;
  41         self.event_damage = oldself.event_damage;
  42         self.anim_state = oldself.anim_state;
  43         self.anim_time = oldself.anim_time;
  44         self.anim_lower_action = oldself.anim_lower_action;
  45         self.anim_lower_time = oldself.anim_lower_time;
  46         self.anim_upper_action = oldself.anim_upper_action;
  47         self.anim_upper_time = oldself.anim_upper_time;
  48         self.anim_implicit_state = oldself.anim_implicit_state;
  49         self.anim_implicit_time = oldself.anim_implicit_time;
  50         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
  51         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
  52         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
  53         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
  54         self.dphitcontentsmask = oldself.dphitcontentsmask;
  55         self.death_time = oldself.death_time;
  56         self.pain_finished = oldself.pain_finished;
  57         self.health = oldself.health;
  58         self.armorvalue = oldself.armorvalue;
  59         self.armortype = oldself.armortype;
  60         self.model = oldself.model;
  61         self.modelindex = oldself.modelindex;
  62         self.skin = oldself.skin;
  63         self.species = oldself.species;
  64         self.movetype = oldself.movetype;
  65         self.solid = oldself.solid;
  66         self.ballistics_density = oldself.ballistics_density;
  67         self.takedamage = oldself.takedamage;
  68         self.customizeentityforclient = oldself.customizeentityforclient;
  69         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
  70         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
  71         if (keepvelocity == 1)
  72                 self.velocity = oldself.velocity;
  73         self.oldvelocity = self.velocity;
  74         self.alpha = oldself.alpha;
  75         self.fade_time = oldself.fade_time;
  76         self.fade_rate = oldself.fade_rate;
  77         //self.weapon = oldself.weapon;
  78         setorigin(self, oldself.origin);
  79         setsize(self, oldself.mins, oldself.maxs);
  80         self.prevorigin = oldself.origin;
  81         self.reset = SUB_Remove;
  82
  83         Drag_MoveDrag(oldself, self);
  84
  85         if(self.colormap <= maxclients && self.colormap > 0)
  86                 self.colormap = 1024 + oldself.clientcolors;
  87
  88         CSQCMODEL_AUTOINIT();
  89         self.CopyBody_nextthink = oldself.nextthink;
  90         self.CopyBody_think = oldself.think;
  91         self.nextthink = time;
  92         self.think = CopyBody_Think;
  93         // "bake" the current animation frame for clones (they don't get clientside animation)
  94         animdecide_load_if_needed(self);
  95         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
  96
  97         self = oldself;
  98 }
  99
 100 float player_getspecies()
 101 {
 102         float s;
 103         get_model_parameters(self.model, self.skin);
 104         s = get_model_parameters_species;
 105         get_model_parameters(string_null, 0);
 106         if(s < 0)
 107                 return SPECIES_HUMAN;
 108         return s;
 109 }
 110
 111 void player_setupanimsformodel()
 112 {
 113         // load animation info
 114         animdecide_load_if_needed(self);
 115         animdecide_setstate(self, 0, FALSE);
 116 }
 117
 118 void player_anim (void)
 119 {
 120         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 121         if(self.deadflag) {
 122                 if (!deadbits) {
 123                         // Decide on which death animation to use.
 124                         if(random() < 0.5)
 125                                 deadbits = ANIMSTATE_DEAD1;
 126                         else
 127                                 deadbits = ANIMSTATE_DEAD2;
 128                 }
 129         } else {
 130                 // Clear a previous death animation.
 131                 deadbits = 0;
 132         }
 133         float animbits = deadbits;
 134         if(self.frozen)
 135                 animbits |= ANIMSTATE_FROZEN;
 136         if(self.crouch)
 137                 animbits |= ANIMSTATE_DUCK;
 138         animdecide_setstate(self, animbits, FALSE);
 139         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 140
 141         if (self.weaponentity)
 142         {
 143                 updateanim(self.weaponentity);
 144                 if (!self.weaponentity.animstate_override)
 145                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 146         }
 147 }
 148
 149 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 150 {
 151         float take, save;
 152         vector v;
 153         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 154
 155         // damage resistance (ignore most of the damage from a bullet or similar)
 156         damage = max(damage - 5, 1);
 157
 158         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 159         take = v_x;
 160         save = v_y;
 161
 162         if(sound_allowed(MSG_BROADCAST, attacker))
 163         {
 164                 if (save > 10)
 165                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 166                 else if (take > 30)
 167                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 168                 else if (take > 10)
 169                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);
 170         }
 171
 172         if (take > 50)
 173                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 174         if (take > 100)
 175                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 176
 177         self.armorvalue = self.armorvalue - save;
 178         self.health = self.health - take;
 179         // pause regeneration for 5 seconds
 180         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 181
 182         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 183         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 184         self.dmg_inflictor = inflictor;
 185
 186         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 187         {
 188                 // don't use any animations as a gib
 189                 self.frame = 0;
 190                 // view just above the floor
 191                 self.view_ofs = '0 0 4';
 192
 193                 Violence_GibSplash(self, 1, 1, attacker);
 194                 self.alpha = -1;
 195                 self.solid = SOLID_NOT; // restore later
 196                 self.takedamage = DAMAGE_NO; // restore later
 197                 self.damagedbycontents = FALSE;
 198         }
 199 }
 200
 201 // g_<gametype>_str:
 202 // If 0, default is used.
 203 // If <0, 0 is used.
 204 // Otherwise, g_str (default value) is used.
 205 // For consistency, negative values there are mapped to zero too.
 206 #define GAMETYPE_DEFAULTED_SETTING(str) \
 207         ((gametype_setting_tmp = cvar(strcat("g_", GetGametype(), "_" #str))), \
 208          (gametype_setting_tmp < 0) ? 0 : \
 209          (gametype_setting_tmp == 0) ? max(0, autocvar_g_##str) : \
 210          gametype_setting_tmp)
 211
 212
 213 void calculate_player_respawn_time()
 214 {
 215         if(g_ca)
 216                 return;
 217
 218         float gametype_setting_tmp;
 219         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
 220         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
 221         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
 222         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
 223         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
 224         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
 225
 226         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
 227         entity pl;
 228         if (teamplay)
 229         {
 230                 FOR_EACH_PLAYER(pl)
 231                         if (pl != self)
 232                                 if (pl.team == self.team)
 233                                         ++pcount;
 234                 if (sdelay_small_count == 0)
 235                         sdelay_small_count = 1;
 236                 if (sdelay_large_count == 0)
 237                         sdelay_large_count = 1;
 238         }
 239         else
 240         {
 241                 FOR_EACH_PLAYER(pl)
 242                         if (pl != self)
 243                                 ++pcount;
 244                 if (sdelay_small_count == 0)
 245                 {
 246                         if (g_cts)
 247                         {
 248                                 // Players play independently. No point in requiring enemies.
 249                                 sdelay_small_count = 1;
 250                         }
 251                         else
 252                         {
 253                                 // Players play AGAINST each other. Enemies required.
 254                                 sdelay_small_count = 2;
 255                         }
 256                 }
 257                 if (sdelay_large_count == 0)
 258                 {
 259                         if (g_cts)
 260                         {
 261                                 // Players play independently. No point in requiring enemies.
 262                                 sdelay_large_count = 1;
 263                         }
 264                         else
 265                         {
 266                                 // Players play AGAINST each other. Enemies required.
 267                                 sdelay_large_count = 2;
 268                         }
 269                 }
 270         }
 271
 272         float sdelay;
 273
 274         if (pcount <= sdelay_small_count)
 275                 sdelay = sdelay_small;
 276         else if (pcount >= sdelay_large_count)
 277                 sdelay = sdelay_large;
 278         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
 279                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
 280
 281         if(waves)
 282                 self.respawn_time = ceil((time + sdelay) / waves) * waves;
 283         else
 284                 self.respawn_time = time + sdelay;
 285
 286         if(sdelay < sdelay_max)
 287                 self.respawn_time_max = time + sdelay_max;
 288         else
 289                 self.respawn_time_max = self.respawn_time;
 290
 291         if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 292                 self.respawn_countdown = 10; // first number to count down from is 10
 293         else
 294                 self.respawn_countdown = -1; // do not count down
 295
 296         if(autocvar_g_forced_respawn)
 297                 self.respawn_flags = self.respawn_flags | RESPAWN_FORCE;
 298 }
 299
 300 void ClientKill_Now_TeamChange();
 301
 302 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 303 {
 304         float take, save, dh, da, j;
 305         vector v;
 306         float valid_damage_for_weaponstats;
 307         float excess;
 308
 309         dh = max(self.health, 0);
 310         da = max(self.armorvalue, 0);
 311
 312         if(!DEATH_ISSPECIAL(deathtype))
 313         {
 314                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 315                 if(self != attacker)
 316                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 317         }
 318
 319         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 320         {
 321                 // tuba causes blood to come out of the ears
 322                 vector ear1, ear2;
 323                 vector d;
 324                 float f;
 325                 ear1 = self.origin;
 326                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 327                 ear2 = ear1;
 328                 makevectors(self.angles);
 329                 ear1 += v_right * -10;
 330                 ear2 += v_right * +10;
 331                 d = inflictor.origin - self.origin;
 332                 if (d)
 333                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 334                 else
 335                         f = 0;  // Assum ecenter.
 336                 force = v_right * vlen(force);
 337                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 338                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 339                 if(f > 0)
 340                 {
 341                         hitloc = ear1;
 342                         force = force * -1;
 343                 }
 344                 else
 345                 {
 346                         hitloc = ear2;
 347                         // force is already good
 348                 }
 349         }
 350         else
 351                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 352
 353
 354         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 355         take = v_x;
 356         save = v_y;
 357
 358         if(attacker == self)
 359         {
 360                 // don't reset pushltime for self damage as it may be an attempt to
 361                 // escape a lava pit or similar
 362                 //self.pushltime = 0;
 363                 self.istypefrag = 0;
 364         }
 365         else if(IS_PLAYER(attacker))
 366         {
 367                 self.pusher = attacker;
 368                 self.pushltime = time + autocvar_g_maxpushtime;
 369                 self.istypefrag = self.BUTTON_CHAT;
 370         }
 371         else if(time < self.pushltime)
 372         {
 373                 attacker = self.pusher;
 374                 self.pushltime = max(self.pushltime, time + 0.6);
 375         }
 376         else
 377         {
 378                 self.pushltime = 0;
 379                 self.istypefrag = 0;
 380         }
 381
 382         frag_inflictor = inflictor;
 383         frag_attacker = attacker;
 384         frag_target = self;
 385         frag_damage = damage;
 386         damage_take = take;
 387         damage_save = save;
 388         damage_force = force;
 389         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 390         take = bound(0, damage_take, self.health);
 391         save = bound(0, damage_save, self.armorvalue);
 392         excess = max(0, damage - take - save);
 393
 394         if(sound_allowed(MSG_BROADCAST, attacker))
 395         {
 396                 if (save > 10)
 397                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 398                 else if (take > 30)
 399                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 400                 else if (take > 10)
 401                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 402         }
 403
 404         if (take > 50)
 405                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 406         if (take > 100)
 407                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 408
 409         if (time >= self.spawnshieldtime)
 410         {
 411                 if (!(self.flags & FL_GODMODE))
 412                 {
 413                         self.armorvalue = self.armorvalue - save;
 414                         self.health = self.health - take;
 415                         // pause regeneration for 5 seconds
 416                         if(take)
 417                                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 418
 419                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 420                         {
 421                                 self.pain_finished = time + 0.5;        //Supajoe
 422
 423                                 if(autocvar_sv_gentle < 1) {
 424                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 425                                         {
 426                                                 if (!self.animstate_override)
 427                                                 {
 428                                                         if (random() > 0.5)
 429                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 430                                                         else
 431                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 432                                                 }
 433                                         }
 434
 435                                         if(sound_allowed(MSG_BROADCAST, attacker))
 436                                         if((self.health < 2 * WEP_CVAR_PRI(blaster, damage) * autocvar_g_balance_selfdamagepercent + 1) || !((get_weaponinfo(DEATH_WEAPONOF(deathtype))).spawnflags & WEP_FLAG_CANCLIMB) || attacker != self) // WEAPONTODO: create separate limit for pain notification with laser
 437                                         if(self.health > 1)
 438                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 439                                         {
 440                                                 if(deathtype == DEATH_FALL)
 441                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 442                                                 else if(self.health > 75) // TODO make a "gentle" version?
 443                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 444                                                 else if(self.health > 50)
 445                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 446                                                 else if(self.health > 25)
 447                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 448                                                 else
 449                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 450                                         }
 451                                 }
 452                         }
 453
 454                         // throw off bot aim temporarily
 455                         float shake;
 456                         if(IS_BOT_CLIENT(self) && self.health >= 1)
 457                         {
 458                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 459                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 460                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 461                                 self.v_angle_x = bound(-90, self.v_angle_x, 90);
 462                         }
 463                 }
 464                 else
 465                         self.max_armorvalue += (save + take);
 466         }
 467         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 468         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 469         self.dmg_inflictor = inflictor;
 470
 471         float abot, vbot, awep;
 472         abot = (IS_BOT_CLIENT(attacker));
 473         vbot = (IS_BOT_CLIENT(self));
 474
 475         valid_damage_for_weaponstats = 0;
 476         awep = 0;
 477
 478         if(vbot || IS_REAL_CLIENT(self))
 479         if(abot || IS_REAL_CLIENT(attacker))
 480         if(attacker && self != attacker)
 481         if(DIFF_TEAM(self, attacker))
 482         {
 483                 if(DEATH_ISSPECIAL(deathtype))
 484                         awep = attacker.weapon;
 485                 else
 486                         awep = DEATH_WEAPONOF(deathtype);
 487                 valid_damage_for_weaponstats = 1;
 488         }
 489
 490         if(valid_damage_for_weaponstats)
 491         {
 492                 dh = dh - max(self.health, 0);
 493                 da = da - max(self.armorvalue, 0);
 494                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 495         }
 496
 497         if (self.health < 1)
 498         {
 499                 float defer_ClientKill_Now_TeamChange;
 500                 defer_ClientKill_Now_TeamChange = FALSE;
 501
 502                 if(self.alivetime)
 503                 {
 504                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 505                         self.alivetime = 0;
 506                 }
 507
 508                 if(valid_damage_for_weaponstats)
 509                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 510
 511                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 512                 if(sound_allowed(MSG_BROADCAST, attacker))
 513                 {
 514                         if(deathtype == DEATH_DROWN)
 515                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 516                         else
 517                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 518                 }
 519
 520                 // get rid of kill indicator
 521                 if(self.killindicator)
 522                 {
 523                         remove(self.killindicator);
 524                         self.killindicator = world;
 525                         if(self.killindicator_teamchange)
 526                                 defer_ClientKill_Now_TeamChange = TRUE;
 527
 528                         if(self.classname == "body")
 529                         if(deathtype == DEATH_KILL)
 530                         {
 531                                 // for the lemmings fans, a small harmless explosion
 532                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 533                         }
 534                 }
 535
 536                 // print an obituary message
 537                 if(self.classname != "body")
 538                         Obituary (attacker, inflictor, self, deathtype);
 539
 540         // increment frag counter for used weapon type
 541         float w;
 542         w = DEATH_WEAPONOF(deathtype);
 543         if(WEP_VALID(w))
 544         if(accuracy_isgooddamage(attacker, self))
 545         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 546
 547                 frag_attacker = attacker;
 548                 frag_inflictor = inflictor;
 549                 frag_target = self;
 550                 frag_deathtype = deathtype;
 551                 MUTATOR_CALLHOOK(PlayerDies);
 552
 553                 WEP_ACTION(self.weapon, WR_PLAYERDEATH);
 554
 555                 RemoveGrapplingHook(self);
 556
 557                 Portal_ClearAllLater(self);
 558
 559                 self.fixangle = TRUE;
 560
 561                 if(defer_ClientKill_Now_TeamChange)
 562                         ClientKill_Now_TeamChange(); // can turn player into spectator
 563
 564                 // player could have been miraculously resuscitated ;)
 565                 // e.g. players in freezetag get frozen, they don't really die
 566                 if(self.health >= 1 || !(IS_PLAYER(self) || self.classname == "body"))
 567                         return;
 568
 569                 // when we get here, player actually dies
 570
 571                 Unfreeze(self); // remove any icy remains
 572                 self.health = 0; // Unfreeze resets health, so we need to set it back
 573
 574                 // clear waypoints
 575                 WaypointSprite_PlayerDead();
 576                 // throw a weapon
 577                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 578
 579                 // become fully visible
 580                 self.alpha = default_player_alpha;
 581                 // make the corpse upright (not tilted)
 582                 self.angles_x = 0;
 583                 self.angles_z = 0;
 584                 // don't spin
 585                 self.avelocity = '0 0 0';
 586                 // view from the floor
 587                 self.view_ofs = '0 0 -8';
 588                 // toss the corpse
 589                 self.movetype = MOVETYPE_TOSS;
 590                 // shootable corpse
 591                 self.solid = SOLID_CORPSE;
 592                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 593                 // don't stick to the floor
 594                 self.flags &= ~FL_ONGROUND;
 595                 // dying animation
 596                 self.deadflag = DEAD_DYING;
 597
 598                 // when to allow respawn
 599                 calculate_player_respawn_time();
 600
 601                 self.death_time = time;
 602                 if (random() < 0.5)
 603                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 604                 else
 605                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 606                 if (self.maxs_z > 5)
 607                 {
 608                         self.maxs_z = 5;
 609                         setsize(self, self.mins, self.maxs);
 610                 }
 611                 // set damage function to corpse damage
 612                 self.event_damage = PlayerCorpseDamage;
 613                 // call the corpse damage function just in case it wants to gib
 614                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 615
 616                 // set up to fade out later
 617                 SUB_SetFade (self, time + 6 + random (), 1);
 618                 // reset body think wrapper broken by SUB_SetFade
 619                 if(self.classname == "body" && self.think != CopyBody_Think) {
 620                         self.CopyBody_think = self.think;
 621                         self.CopyBody_nextthink = self.nextthink;
 622                         self.think = CopyBody_Think;
 623                         self.nextthink = time;
 624                 }
 625
 626                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 627                         // remove corpse
 628                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 629                 }
 630
 631                 // reset fields the weapons may use just in case
 632                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 633                 {
 634                         WEP_ACTION(j, WR_RESETPLAYER);
 635                         ATTACK_FINISHED_FOR(self, j) = 0;
 636                 }
 637         }
 638 }
 639
 640 .float muted; // to be used by prvm_edictset server playernumber muted 1
 641 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 642 // message "": do not say, just test flood control
 643 // return value:
 644 //   1 = accept
 645 //   0 = reject
 646 //  -1 = fake accept
 647 {
 648         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, colorprefix;
 649         float flood;
 650         var .float flood_field;
 651         entity head;
 652         float ret;
 653         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 654
 655         if(!teamsay && !privatesay)
 656                 if(substring(msgin, 0, 1) == " ")
 657                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 658
 659         msgin = formatmessage(msgin);
 660
 661         if (!IS_PLAYER(source))
 662                 colorstr = "^0"; // black for spectators
 663         else if(teamplay)
 664                 colorstr = Team_ColorCode(source.team);
 665         else
 666         {
 667                 colorstr = "";
 668                 teamsay = FALSE;
 669         }
 670
 671         if(intermission_running)
 672                 teamsay = FALSE;
 673
 674         if(msgin != "")
 675                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 676
 677         /*
 678          * using bprint solves this... me stupid
 679         // how can we prevent the message from appearing in a listen server?
 680         // for now, just give "say" back and only handle say_team
 681         if(!teamsay)
 682         {
 683                 clientcommand(self, strcat("say ", msgin));
 684                 return;
 685         }
 686         */
 687
 688         if(autocvar_g_chat_teamcolors)
 689                 namestr = playername(source);
 690         else
 691                 namestr = source.netname;
 692
 693         if(strdecolorize(namestr) == namestr)
 694                 colorprefix = "^3";
 695         else
 696                 colorprefix = "^7";
 697
 698         if(msgin != "")
 699         {
 700                 if(privatesay)
 701                 {
 702                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
 703                         privatemsgprefixlen = strlen(msgstr);
 704                         msgstr = strcat(msgstr, msgin);
 705                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
 706                         if(autocvar_g_chat_teamcolors)
 707                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 708                         else
 709                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 710                 }
 711                 else if(teamsay)
 712                 {
 713                         msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
 714                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
 715                 }
 716                 else
 717                 {
 718                         msgstr = strcat("\{1}", colorprefix, namestr, "^7: ", msgin);
 719                         cmsgstr = "";
 720                 }
 721                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 722         }
 723         else
 724         {
 725                 msgstr = cmsgstr = "";
 726         }
 727
 728         fullmsgstr = msgstr;
 729         fullcmsgstr = cmsgstr;
 730
 731         // FLOOD CONTROL
 732         flood = 0;
 733         flood_field = floodcontrol_chat;
 734         if(floodcontrol)
 735         {
 736                 float flood_spl;
 737                 float flood_burst;
 738                 float flood_lmax;
 739                 float lines;
 740                 if(privatesay)
 741                 {
 742                         flood_spl = autocvar_g_chat_flood_spl_tell;
 743                         flood_burst = autocvar_g_chat_flood_burst_tell;
 744                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 745                         flood_field = floodcontrol_chattell;
 746                 }
 747                 else if(teamsay)
 748                 {
 749                         flood_spl = autocvar_g_chat_flood_spl_team;
 750                         flood_burst = autocvar_g_chat_flood_burst_team;
 751                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 752                         flood_field = floodcontrol_chatteam;
 753                 }
 754                 else
 755                 {
 756                         flood_spl = autocvar_g_chat_flood_spl;
 757                         flood_burst = autocvar_g_chat_flood_burst;
 758                         flood_lmax = autocvar_g_chat_flood_lmax;
 759                         flood_field = floodcontrol_chat;
 760                 }
 761                 flood_burst = max(0, flood_burst - 1);
 762                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 763
 764                 // do flood control for the default line size
 765                 if(msgstr != "")
 766                 {
 767                         getWrappedLine_remaining = msgstr;
 768                         msgstr = "";
 769                         lines = 0;
 770                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 771                         {
 772                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 773                                 ++lines;
 774                         }
 775                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 776
 777                         if(getWrappedLine_remaining != "")
 778                         {
 779                                 msgstr = strcat(msgstr, "\n");
 780                                 flood = 2;
 781                         }
 782
 783                         if(time >= source.flood_field)
 784                         {
 785                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 786                         }
 787                         else
 788                         {
 789                                 flood = 1;
 790                                 msgstr = fullmsgstr;
 791                         }
 792                 }
 793                 else
 794                 {
 795                         if(time >= source.flood_field)
 796                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 797                         else
 798                                 flood = 1;
 799                 }
 800
 801                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 802                         source.flood_field = flood = 0;
 803         }
 804
 805         if(flood == 2) // cannot happen for empty msgstr
 806         {
 807                 if(autocvar_g_chat_flood_notify_flooder)
 808                 {
 809                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 810                         sourcecmsgstr = "";
 811                 }
 812                 else
 813                 {
 814                         sourcemsgstr = fullmsgstr;
 815                         sourcecmsgstr = fullcmsgstr;
 816                 }
 817                 cmsgstr = "";
 818         }
 819         else
 820         {
 821                 sourcemsgstr = msgstr;
 822                 sourcecmsgstr = cmsgstr;
 823         }
 824
 825         if(!privatesay)
 826         if (!IS_PLAYER(source))
 827         {
 828                 if (!intermission_running)
 829                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(warmup_stage || gameover)))
 830                                 teamsay = -1; // spectators
 831         }
 832
 833         if(flood)
 834                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 835
 836         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 837         if(privatesay)
 838                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 839
 840         if(source.muted)
 841         {
 842                 // always fake the message
 843                 ret = -1;
 844         }
 845         else if(flood == 1)
 846         {
 847                 if(autocvar_g_chat_flood_notify_flooder)
 848                 {
 849                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 850                         ret = 0;
 851                 }
 852                 else
 853                         ret = -1;
 854         }
 855         else
 856         {
 857                 ret = 1;
 858         }
 859
 860         if(sourcemsgstr != "" && ret != 0)
 861         {
 862                 if(ret < 0) // faked message, because the player is muted
 863                 {
 864                         sprint(source, sourcemsgstr);
 865                         if(sourcecmsgstr != "" && !privatesay)
 866                                 centerprint(source, sourcecmsgstr);
 867                 }
 868                 else if(privatesay) // private message, between 2 people only
 869                 {
 870                         sprint(source, sourcemsgstr);
 871                         sprint(privatesay, msgstr);
 872                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 873                         if(cmsgstr != "")
 874                                 centerprint(privatesay, cmsgstr);
 875                 }
 876                 else if(teamsay > 0) // team message, only sent to team mates
 877                 {
 878                         sprint(source, sourcemsgstr);
 879                         dedicated_print(msgstr); // send to server console too
 880                         if(sourcecmsgstr != "")
 881                                 centerprint(source, sourcecmsgstr);
 882                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 883                                 if(head != source)
 884                                 {
 885                                         sprint(head, msgstr);
 886                                         if(cmsgstr != "")
 887                                                 centerprint(head, cmsgstr);
 888                                 }
 889                 }
 890                 else if(teamsay < 0) // spectator message, only sent to spectators
 891                 {
 892                         sprint(source, sourcemsgstr);
 893                         dedicated_print(msgstr); // send to server console too
 894                         FOR_EACH_REALCLIENT(head) if (!IS_PLAYER(head))
 895                                 if(head != source)
 896                                         sprint(head, msgstr);
 897                 }
 898                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 899                 {
 900                         sprint(source, sourcemsgstr);
 901                         dedicated_print(msgstr); // send to server console too
 902                         FOR_EACH_REALCLIENT(head)
 903                                 if(head != source)
 904                                         sprint(head, msgstr);
 905                 }
 906                 else
 907                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 908         }
 909
 910         return ret;
 911 }
 912
 913 float GetVoiceMessageVoiceType(string type)
 914 {
 915         if(type == "taunt")
 916                 return VOICETYPE_TAUNT;
 917         if(type == "teamshoot")
 918                 return VOICETYPE_LASTATTACKER;
 919         return VOICETYPE_TEAMRADIO;
 920 }
 921
 922 string allvoicesamples;
 923 .string GetVoiceMessageSampleField(string type)
 924 {
 925         GetPlayerSoundSampleField_notFound = 0;
 926         switch(type)
 927         {
 928 #define _VOICEMSG(m) case #m: return playersound_##m;
 929                 ALLVOICEMSGS
 930 #undef _VOICEMSG
 931         }
 932         GetPlayerSoundSampleField_notFound = 1;
 933         return playersound_taunt;
 934 }
 935
 936 .string GetPlayerSoundSampleField(string type)
 937 {
 938         GetPlayerSoundSampleField_notFound = 0;
 939         switch(type)
 940         {
 941 #define _VOICEMSG(m) case #m: return playersound_##m;
 942                 ALLPLAYERSOUNDS
 943 #undef _VOICEMSG
 944         }
 945         GetPlayerSoundSampleField_notFound = 1;
 946         return playersound_taunt;
 947 }
 948
 949 void PrecacheGlobalSound(string samplestring)
 950 {
 951         float n, i;
 952         tokenize_console(samplestring);
 953         n = stof(argv(1));
 954         if(n > 0)
 955         {
 956                 for(i = 1; i <= n; ++i)
 957                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
 958         }
 959         else
 960         {
 961                 precache_sound(strcat(argv(0), ".wav"));
 962         }
 963 }
 964
 965 void PrecachePlayerSounds(string f)
 966 {
 967         float fh;
 968         string s;
 969         fh = fopen(f, FILE_READ);
 970         if(fh < 0)
 971                 return;
 972         while((s = fgets(fh)))
 973         {
 974                 if(tokenize_console(s) != 3)
 975                 {
 976                         dprint("Invalid sound info line: ", s, "\n");
 977                         continue;
 978                 }
 979                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 980         }
 981         fclose(fh);
 982
 983         if (!allvoicesamples)
 984         {
 985 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
 986                 ALLVOICEMSGS
 987 #undef _VOICEMSG
 988                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
 989         }
 990 }
 991
 992 void ClearPlayerSounds()
 993 {
 994 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
 995         ALLPLAYERSOUNDS
 996         ALLVOICEMSGS
 997 #undef _VOICEMSG
 998 }
 999
1000 float LoadPlayerSounds(string f, float first)
1001 {
1002         float fh;
1003         string s;
1004         var .string field;
1005         fh = fopen(f, FILE_READ);
1006         if(fh < 0)
1007         {
1008                 dprint("Player sound file not found: ", f, "\n");
1009                 return 0;
1010         }
1011         while((s = fgets(fh)))
1012         {
1013                 if(tokenize_console(s) != 3)
1014                         continue;
1015                 field = GetPlayerSoundSampleField(argv(0));
1016                 if(GetPlayerSoundSampleField_notFound)
1017                         field = GetVoiceMessageSampleField(argv(0));
1018                 if(GetPlayerSoundSampleField_notFound)
1019                         continue;
1020                 if(self.field)
1021                         strunzone(self.field);
1022                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1023         }
1024         fclose(fh);
1025         return 1;
1026 }
1027
1028 .float modelindex_for_playersound;
1029 .float skin_for_playersound;
1030 void UpdatePlayerSounds()
1031 {
1032         if(self.modelindex == self.modelindex_for_playersound)
1033         if(self.skin == self.skin_for_playersound)
1034                 return;
1035         self.modelindex_for_playersound = self.modelindex;
1036         self.skin_for_playersound = self.skin;
1037         ClearPlayerSounds();
1038         LoadPlayerSounds("sound/player/default.sounds", 1);
1039         if(!autocvar_g_debug_defaultsounds)
1040                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1041                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1042 }
1043
1044 void FakeGlobalSound(string sample, float chan, float voicetype)
1045 {
1046         float n;
1047         float tauntrand;
1048
1049         if(sample == "")
1050                 return;
1051
1052         tokenize_console(sample);
1053         n = stof(argv(1));
1054         if(n > 0)
1055                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1056         else
1057                 sample = strcat(argv(0), ".wav"); // randomization
1058
1059         switch(voicetype)
1060         {
1061                 case VOICETYPE_LASTATTACKER_ONLY:
1062                         break;
1063                 case VOICETYPE_LASTATTACKER:
1064                         if(self.pusher)
1065                         {
1066                                 msg_entity = self;
1067                                 if(IS_REAL_CLIENT(msg_entity))
1068                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1069                         }
1070                         break;
1071                 case VOICETYPE_TEAMRADIO:
1072                         msg_entity = self;
1073                         if(msg_entity.cvar_cl_voice_directional == 1)
1074                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1075                         else
1076                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1077                         break;
1078                 case VOICETYPE_AUTOTAUNT:
1079                         if(!sv_autotaunt)
1080                                 break;
1081                         if(!sv_taunt)
1082                                 break;
1083                         if(autocvar_sv_gentle)
1084                                 break;
1085                         tauntrand = random();
1086                         msg_entity = self;
1087                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1088                         {
1089                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1090                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1091                                 else
1092                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1093                         }
1094                         break;
1095                 case VOICETYPE_TAUNT:
1096                         if(IS_PLAYER(self))
1097                                 if(self.deadflag == DEAD_NO)
1098                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1099                         if(!sv_taunt)
1100                                 break;
1101                         if(autocvar_sv_gentle)
1102                                 break;
1103                         msg_entity = self;
1104                         if (msg_entity.cvar_cl_voice_directional >= 1)
1105                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1106                         else
1107                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1108                         break;
1109                 case VOICETYPE_PLAYERSOUND:
1110                         msg_entity = self;
1111                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NORM);
1112                         break;
1113                 default:
1114                         backtrace("Invalid voice type!");
1115                         break;
1116         }
1117 }
1118
1119 void GlobalSound(string sample, float chan, float voicetype)
1120 {
1121         float n;
1122         float tauntrand;
1123
1124         if(sample == "")
1125                 return;
1126
1127         tokenize_console(sample);
1128         n = stof(argv(1));
1129         if(n > 0)
1130                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1131         else
1132                 sample = strcat(argv(0), ".wav"); // randomization
1133
1134         switch(voicetype)
1135         {
1136                 case VOICETYPE_LASTATTACKER_ONLY:
1137                         if(self.pusher)
1138                         {
1139                                 msg_entity = self.pusher;
1140                                 if(IS_REAL_CLIENT(msg_entity))
1141                                 {
1142                                         if(msg_entity.cvar_cl_voice_directional == 1)
1143                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1144                                         else
1145                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1146                                 }
1147                         }
1148                         break;
1149                 case VOICETYPE_LASTATTACKER:
1150                         if(self.pusher)
1151                         {
1152                                 msg_entity = self.pusher;
1153                                 if(IS_REAL_CLIENT(msg_entity))
1154                                 {
1155                                         if(msg_entity.cvar_cl_voice_directional == 1)
1156                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1157                                         else
1158                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1159                                 }
1160                                 msg_entity = self;
1161                                 if(IS_REAL_CLIENT(msg_entity))
1162                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1163                         }
1164                         break;
1165                 case VOICETYPE_TEAMRADIO:
1166                         FOR_EACH_REALCLIENT(msg_entity)
1167                                 if(!teamplay || msg_entity.team == self.team)
1168                                 {
1169                                         if(msg_entity.cvar_cl_voice_directional == 1)
1170                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1171                                         else
1172                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1173                                 }
1174                         break;
1175                 case VOICETYPE_AUTOTAUNT:
1176                         if(!sv_autotaunt)
1177                                 break;
1178                         if(!sv_taunt)
1179                                 break;
1180                         if(autocvar_sv_gentle)
1181                                 break;
1182                         tauntrand = random();
1183                         FOR_EACH_REALCLIENT(msg_entity)
1184                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1185                                 {
1186                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1187                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1188                                         else
1189                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1190                                 }
1191                         break;
1192                 case VOICETYPE_TAUNT:
1193                         if(IS_PLAYER(self))
1194                                 if(self.deadflag == DEAD_NO)
1195                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1196                         if(!sv_taunt)
1197                                 break;
1198                         if(autocvar_sv_gentle)
1199                                 break;
1200                         FOR_EACH_REALCLIENT(msg_entity)
1201                         {
1202                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1203                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1204                                 else
1205                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1206                         }
1207                         break;
1208                 case VOICETYPE_PLAYERSOUND:
1209                         sound(self, chan, sample, VOL_BASE, ATTEN_NORM);
1210                         break;
1211                 default:
1212                         backtrace("Invalid voice type!");
1213                         break;
1214         }
1215 }
1216
1217 void PlayerSound(.string samplefield, float chan, float voicetype)
1218 {
1219         GlobalSound(self.samplefield, chan, voicetype);
1220 }
1221
1222 void VoiceMessage(string type, string msg)
1223 {
1224         var .string sample;
1225         float voicetype, ownteam;
1226         float flood;
1227         sample = GetVoiceMessageSampleField(type);
1228
1229         if(GetPlayerSoundSampleField_notFound)
1230         {
1231                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1232                 return;
1233         }
1234
1235         voicetype = GetVoiceMessageVoiceType(type);
1236         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1237
1238         flood = Say(self, ownteam, world, msg, 1);
1239
1240         if(IS_SPEC(self) || IS_OBSERVER(self) || flood < 0)
1241                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1242         else if (flood > 0)
1243                 GlobalSound(self.sample, CH_VOICE, voicetype);
1244 }
1245
1246 void MoveToTeam(entity client, float team_colour, float type)
1247 {
1248         float lockteams_backup;
1249
1250         lockteams_backup = lockteams;  // backup any team lock
1251
1252         lockteams = 0;  // disable locked teams
1253
1254         TeamchangeFrags(client);  // move the players frags
1255         SetPlayerColors(client, team_colour - 1);  // set the players colour
1256         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1257
1258         lockteams = lockteams_backup;  // restore the team lock
1259
1260         LogTeamchange(client.playerid, client.team, type);
1261 }