qcsrc/server/cl_physics.qc

   1 .float race_penalty;
   2 .float restart_jump;
   3
   4 .float ladder_time;
   5 .entity ladder_entity;
   6 .float gravity;
   7 .float swamp_slowdown;
   8 .float lastflags;
   9 .float lastground;
  10 .float wasFlying;
  11 .float spectatorspeed;
  12
  13 // client side physics
  14 float Physics_Valid(string thecvar)
  15 {
  16         if(!autocvar_g_physics_clientselect) { return FALSE; }
  17
  18         string l = strcat(" ", autocvar_g_physics_clientselect_options, " ");
  19
  20         if(strstrofs(l, strcat(" ", thecvar, " "), 0) >= 0)
  21                 return TRUE;
  22
  23         return FALSE;
  24 }
  25
  26 float Physics_ClientOption(entity pl, string option)
  27 {
  28         if(Physics_Valid(pl.cvar_cl_physics) && (cvar_type(sprintf("g_physics_%s_%s", pl.cvar_cl_physics, option)) & 1))
  29                 return cvar(sprintf("g_physics_%s_%s", pl.cvar_cl_physics, option));
  30         else
  31                 return cvar(strcat("sv_", option));
  32 }
  33
  34 /*
  35 =============
  36 PlayerJump
  37
  38 When you press the jump key
  39 returns TRUE if handled
  40 =============
  41 */
  42 float PlayerJump (void)
  43 {
  44         if(self.frozen)
  45                 return TRUE; // no jumping in freezetag when frozen
  46
  47         if(self.player_blocked)
  48                 return TRUE; // no jumping while blocked
  49
  50         float doublejump = FALSE;
  51         float mjumpheight = self.stat_sv_jumpvelocity;
  52
  53         player_multijump = doublejump;
  54         player_jumpheight = mjumpheight;
  55         if(MUTATOR_CALLHOOK(PlayerJump))
  56                 return TRUE;
  57
  58         doublejump = player_multijump;
  59         mjumpheight = player_jumpheight;
  60
  61         if (autocvar_sv_doublejump)
  62         {
  63                 tracebox(self.origin + '0 0 0.01', self.mins, self.maxs, self.origin - '0 0 0.01', MOVE_NORMAL, self);
  64                 if (trace_fraction < 1 && trace_plane_normal_z > 0.7)
  65                 {
  66                         doublejump = TRUE;
  67
  68                         // we MUST clip velocity here!
  69                         float f;
  70                         f = self.velocity * trace_plane_normal;
  71                         if(f < 0)
  72                                 self.velocity -= f * trace_plane_normal;
  73                 }
  74         }
  75
  76         if (self.waterlevel >= WATERLEVEL_SWIMMING)
  77         {
  78                 self.velocity_z = self.stat_sv_maxspeed * 0.7;
  79                 return TRUE;
  80         }
  81
  82         if (!doublejump)
  83                 if (!(self.flags & FL_ONGROUND))
  84                         return !(self.flags & FL_JUMPRELEASED);
  85
  86         if(self.cvar_cl_movement_track_canjump)
  87                 if (!(self.flags & FL_JUMPRELEASED))
  88                         return TRUE;
  89
  90         // sv_jumpspeedcap_min/sv_jumpspeedcap_max act as baseline
  91         // velocity bounds.  Final velocity is bound between (jumpheight *
  92         // min + jumpheight) and (jumpheight * max + jumpheight);
  93
  94         if(autocvar_sv_jumpspeedcap_min != "")
  95         {
  96                 float minjumpspeed;
  97
  98                 minjumpspeed = mjumpheight * stof(autocvar_sv_jumpspeedcap_min);
  99
 100                 if (self.velocity_z < minjumpspeed)
 101                         mjumpheight += minjumpspeed - self.velocity_z;
 102         }
 103
 104         if(autocvar_sv_jumpspeedcap_max != "")
 105         {
 106                 // don't do jump speedcaps on ramps to preserve old xonotic ramjump style
 107                 tracebox(self.origin + '0 0 0.01', self.mins, self.maxs, self.origin - '0 0 0.01', MOVE_NORMAL, self);
 108
 109                 if(!(trace_fraction < 1 && trace_plane_normal_z < 0.98 && autocvar_sv_jumpspeedcap_max_disable_on_ramps))
 110                 {
 111                         float maxjumpspeed;
 112
 113                         maxjumpspeed = mjumpheight * stof(autocvar_sv_jumpspeedcap_max);
 114
 115                         if (self.velocity_z > maxjumpspeed)
 116                                 mjumpheight -= self.velocity_z - maxjumpspeed;
 117                 }
 118         }
 119
 120         if(!(self.lastflags & FL_ONGROUND))
 121         {
 122                 if(autocvar_speedmeter)
 123                         dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 124                 if(self.lastground < time - 0.3)
 125                 {
 126                         self.velocity_x *= (1 - autocvar_sv_friction_on_land);
 127                         self.velocity_y *= (1 - autocvar_sv_friction_on_land);
 128                 }
 129                 if(self.jumppadcount > 1)
 130                         dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 131                 self.jumppadcount = 0;
 132         }
 133
 134         self.velocity_z = self.velocity_z + mjumpheight;
 135         self.oldvelocity_z = self.velocity_z;
 136
 137         self.flags &= ~FL_ONGROUND;
 138         self.flags &= ~FL_JUMPRELEASED;
 139
 140         animdecide_setaction(self, ANIMACTION_JUMP, TRUE);
 141
 142         if(autocvar_g_jump_grunt)
 143                 PlayerSound(playersound_jump, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 144
 145         self.restart_jump = -1; // restart jump anim next time
 146         // value -1 is used to not use the teleport bit (workaround for tiny hitch when re-jumping)
 147         return TRUE;
 148 }
 149 void CheckWaterJump()
 150 {
 151         vector start, end;
 152
 153 // check for a jump-out-of-water
 154         makevectors (self.angles);
 155         start = self.origin;
 156         start_z = start_z + 8;
 157         v_forward_z = 0;
 158         normalize(v_forward);
 159         end = start + v_forward*24;
 160         traceline (start, end, TRUE, self);
 161         if (trace_fraction < 1)
 162         {       // solid at waist
 163                 start_z = start_z + self.maxs_z - 8;
 164                 end = start + v_forward*24;
 165                 self.movedir = trace_plane_normal * -50;
 166                 traceline (start, end, TRUE, self);
 167                 if (trace_fraction == 1)
 168                 {       // open at eye level
 169                         self.flags |= FL_WATERJUMP;
 170                         self.velocity_z = 225;
 171                         self.flags &= ~FL_JUMPRELEASED;
 172                         self.teleport_time = time + 2;  // safety net
 173                         return;
 174                 }
 175         }
 176 }
 177
 178 .float jetpack_stopped;
 179 // Hack: shouldn't need to know about this
 180 .float multijump_count;
 181 void CheckPlayerJump()
 182 {
 183         float was_flying = self.items & IT_USING_JETPACK;
 184
 185         if (self.cvar_cl_jetpack_jump < 2)
 186                 self.items &= ~IT_USING_JETPACK;
 187
 188         if (self.BUTTON_JUMP || self.BUTTON_JETPACK)
 189         {
 190                 float air_jump = !PlayerJump() || self.multijump_count > 0; // PlayerJump() has important side effects
 191                 float activate = self.cvar_cl_jetpack_jump && air_jump && self.BUTTON_JUMP || self.BUTTON_JETPACK;
 192                 float has_fuel = !autocvar_g_jetpack_fuel || self.ammo_fuel || self.items & IT_UNLIMITED_WEAPON_AMMO;
 193                 if (self.jetpack_stopped) { }
 194                 else if (!has_fuel)
 195                 {
 196                         if (was_flying) // TODO: ran out of fuel message
 197                                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_JETPACK_NOFUEL);
 198                         else
 199                                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_JETPACK_NOFUEL);
 200                         self.jetpack_stopped = TRUE;
 201                         self.items &= ~IT_USING_JETPACK;
 202                 }
 203                 else if (activate && !self.frozen)
 204                         self.items |= IT_USING_JETPACK;
 205         }
 206         else
 207         {
 208                 self.jetpack_stopped = FALSE;
 209                 self.items &= ~IT_USING_JETPACK;
 210         }
 211         if (!self.BUTTON_JUMP)
 212                 self.flags |= FL_JUMPRELEASED;
 213
 214         if (self.waterlevel == WATERLEVEL_SWIMMING)
 215                 CheckWaterJump ();
 216 }
 217
 218 float racecar_angle(float forward, float down)
 219 {
 220         float ret, angle_mult;
 221
 222         if(forward < 0)
 223         {
 224                 forward = -forward;
 225                 down = -down;
 226         }
 227
 228         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 229
 230         angle_mult = forward / (800 + forward);
 231
 232         if(ret > 180)
 233                 return ret * angle_mult + 360 * (1 - angle_mult);
 234         else
 235                 return ret * angle_mult;
 236 }
 237
 238 void RaceCarPhysics()
 239 {
 240         // using this move type for "big rigs"
 241         // the engine does not push the entity!
 242
 243         float accel, steer, f, myspeed, steerfactor;
 244         vector angles_save, rigvel;
 245
 246         angles_save = self.angles;
 247         accel = bound(-1, self.movement_x / self.stat_sv_maxspeed, 1);
 248         steer = bound(-1, self.movement_y / self.stat_sv_maxspeed, 1);
 249
 250         if(g_bugrigs_reverse_speeding)
 251         {
 252                 if(accel < 0)
 253                 {
 254                         // back accel is DIGITAL
 255                         // to prevent speedhack
 256                         if(accel < -0.5)
 257                                 accel = -1;
 258                         else
 259                                 accel = 0;
 260                 }
 261         }
 262
 263         self.angles_x = 0;
 264         self.angles_z = 0;
 265         makevectors(self.angles); // new forward direction!
 266
 267         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 268         {
 269                 float upspeed, accelfactor;
 270
 271                 myspeed = self.velocity * v_forward;
 272                 upspeed = self.velocity * v_up;
 273
 274                 // responsiveness factor for steering and acceleration
 275                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 276                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 277
 278                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 279                         steerfactor = -myspeed * g_bugrigs_steer;
 280                 else
 281                         steerfactor = -myspeed * f * g_bugrigs_steer;
 282
 283                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 284                         accelfactor = g_bugrigs_accel;
 285                 else
 286                         accelfactor = f * g_bugrigs_accel;
 287                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 288
 289                 if(accel < 0)
 290                 {
 291                         if(myspeed > 0)
 292                         {
 293                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 294                         }
 295                         else
 296                         {
 297                                 if(!g_bugrigs_reverse_speeding)
 298                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 299                         }
 300                 }
 301                 else
 302                 {
 303                         if(myspeed >= 0)
 304                         {
 305                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 306                         }
 307                         else
 308                         {
 309                                 if(g_bugrigs_reverse_stopping)
 310                                         myspeed = 0;
 311                                 else
 312                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 313                         }
 314                 }
 315                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 316                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 317
 318                 self.angles_y += steer * frametime * steerfactor; // apply steering
 319                 makevectors(self.angles); // new forward direction!
 320
 321                 myspeed += accel * accelfactor * frametime;
 322
 323                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 324         }
 325         else
 326         {
 327                 myspeed = vlen(self.velocity);
 328
 329                 // responsiveness factor for steering and acceleration
 330                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 331                 steerfactor = -myspeed * f;
 332                 self.angles_y += steer * frametime * steerfactor; // apply steering
 333
 334                 rigvel = self.velocity;
 335                 makevectors(self.angles); // new forward direction!
 336         }
 337
 338         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
 339         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 340         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 341         //MAXIMA: solve(total_acceleration(v) = 0, v);
 342
 343         if(g_bugrigs_planar_movement)
 344         {
 345                 vector rigvel_xy, neworigin, up;
 346                 float mt;
 347
 348                 rigvel_z -= frametime * autocvar_sv_gravity; // 4x gravity plays better
 349                 rigvel_xy = vec2(rigvel);
 350
 351                 if(g_bugrigs_planar_movement_car_jumping)
 352                         mt = MOVE_NORMAL;
 353                 else
 354                         mt = MOVE_NOMONSTERS;
 355
 356                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 357                 up = trace_endpos - self.origin;
 358
 359                 // BUG RIGS: align the move to the surface instead of doing collision testing
 360                 // can we move?
 361                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 362
 363                 // align to surface
 364                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 365
 366                 if(trace_fraction < 0.5)
 367                 {
 368                         trace_fraction = 1;
 369                         neworigin = self.origin;
 370                 }
 371                 else
 372                         neworigin = trace_endpos;
 373
 374                 if(trace_fraction < 1)
 375                 {
 376                         // now set angles_x so that the car points parallel to the surface
 377                         self.angles = vectoangles(
 378                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 379                                         +
 380                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 381                                         +
 382                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 383                                         );
 384                         self.flags |= FL_ONGROUND;
 385                 }
 386                 else
 387                 {
 388                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 389                         self.flags &= ~FL_ONGROUND;
 390                 }
 391
 392                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 393                 self.movetype = MOVETYPE_NOCLIP;
 394         }
 395         else
 396         {
 397                 rigvel_z -= frametime * autocvar_sv_gravity; // 4x gravity plays better
 398                 self.velocity = rigvel;
 399                 self.movetype = MOVETYPE_FLY;
 400         }
 401
 402         trace_fraction = 1;
 403         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 404         if(trace_fraction != 1)
 405         {
 406                 self.angles = vectoangles2(
 407                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 408                                 +
 409                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 410                                 +
 411                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 412                                 trace_plane_normal
 413                                 );
 414         }
 415         else
 416         {
 417                 vector vel_local;
 418
 419                 vel_local_x = v_forward * self.velocity;
 420                 vel_local_y = v_right * self.velocity;
 421                 vel_local_z = v_up * self.velocity;
 422
 423                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 424                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 425         }
 426
 427         // smooth the angles
 428         vector vf1, vu1, smoothangles;
 429         makevectors(self.angles);
 430         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 431         if(f == 0)
 432                 f = 1;
 433         vf1 = v_forward * f;
 434         vu1 = v_up * f;
 435         makevectors(angles_save);
 436         vf1 = vf1 + v_forward * (1 - f);
 437         vu1 = vu1 + v_up * (1 - f);
 438         smoothangles = vectoangles2(vf1, vu1);
 439         self.angles_x = -smoothangles_x;
 440         self.angles_z =  smoothangles_z;
 441 }
 442
 443 float IsMoveInDirection(vector mv, float angle) // key mix factor
 444 {
 445         if(mv_x == 0 && mv_y == 0)
 446                 return 0; // avoid division by zero
 447         angle -= RAD2DEG * atan2(mv_y, mv_x);
 448         angle = remainder(angle, 360) / 45;
 449         if(angle >  1)
 450                 return 0;
 451         if(angle < -1)
 452                 return 0;
 453         return 1 - fabs(angle);
 454 }
 455
 456 float GeomLerp(float a, float lerp, float b)
 457 {
 458         if(a == 0)
 459         {
 460                 if(lerp < 1)
 461                         return 0;
 462                 else
 463                         return b;
 464         }
 465         if(b == 0)
 466         {
 467                 if(lerp > 0)
 468                         return 0;
 469                 else
 470                         return a;
 471         }
 472         return a * pow(fabs(b / a), lerp);
 473 }
 474
 475 void CPM_PM_Aircontrol(vector wishdir, float wishspeed)
 476 {
 477         float zspeed, xyspeed, dot, k;
 478
 479 #if 0
 480         // this doesn't play well with analog input
 481         if(self.movement_x == 0 || self.movement_y != 0)
 482                 return; // can't control movement if not moving forward or backward
 483         k = 32;
 484 #else
 485         k = 32 * (2 * IsMoveInDirection(self.movement, 0) - 1);
 486         if(k <= 0)
 487                 return;
 488 #endif
 489
 490         k *= bound(0, wishspeed / self.stat_sv_maxairspeed, 1);
 491
 492         zspeed = self.velocity_z;
 493         self.velocity_z = 0;
 494         xyspeed = vlen(self.velocity); self.velocity = normalize(self.velocity);
 495
 496         dot = self.velocity * wishdir;
 497
 498         if(dot > 0) // we can't change direction while slowing down
 499         {
 500                 k *= pow(dot, self.stat_sv_aircontrol_power)*frametime;
 501                 xyspeed = max(0, xyspeed - self.stat_sv_aircontrol_penalty * sqrt(max(0, 1 - dot*dot)) * k/32);
 502                 k *= self.stat_sv_aircontrol;
 503                 self.velocity = normalize(self.velocity * xyspeed + wishdir * k);
 504         }
 505
 506         self.velocity = self.velocity * xyspeed;
 507         self.velocity_z = zspeed;
 508 }
 509
 510 float AdjustAirAccelQW(float accelqw, float factor)
 511 {
 512         return copysign(bound(0.000001, 1 - (1 - fabs(accelqw)) * factor, 1), accelqw);
 513 }
 514
 515 // example config for alternate speed clamping:
 516 //   sv_airaccel_qw 0.8
 517 //   sv_airaccel_sideways_friction 0
 518 //   prvm_globalset server speedclamp_mode 1
 519 //     (or 2)
 520 void PM_Accelerate(vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float stretchfactor, float sidefric, float speedlimit)
 521 {
 522         float vel_straight;
 523         float vel_z;
 524         vector vel_perpend;
 525         float step;
 526
 527         vector vel_xy;
 528         float vel_xy_current;
 529         float vel_xy_backward, vel_xy_forward;
 530         float speedclamp;
 531
 532         if(stretchfactor > 0)
 533                 speedclamp = stretchfactor;
 534         else if(accelqw < 0)
 535                 speedclamp = 1; // full clamping, no stretch
 536         else
 537                 speedclamp = -1; // no clamping
 538
 539         if(accelqw < 0)
 540                 accelqw = -accelqw;
 541
 542         if(autocvar_sv_gameplayfix_q2airaccelerate)
 543                 wishspeed0 = wishspeed;
 544
 545         vel_straight = self.velocity * wishdir;
 546         vel_z = self.velocity_z;
 547         vel_xy = vec2(self.velocity);
 548         vel_perpend = vel_xy - vel_straight * wishdir;
 549
 550         step = accel * frametime * wishspeed0;
 551
 552         vel_xy_current  = vlen(vel_xy);
 553         if(speedlimit)
 554                 accelqw = AdjustAirAccelQW(accelqw, (speedlimit - bound(wishspeed, vel_xy_current, speedlimit)) / max(1, speedlimit - wishspeed));
 555         vel_xy_forward  = vel_xy_current + bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
 556         vel_xy_backward = vel_xy_current - bound(0, wishspeed + vel_xy_current, step) * accelqw - step * (1 - accelqw);
 557         if(vel_xy_backward < 0)
 558                 vel_xy_backward = 0; // not that it REALLY occurs that this would cause wrong behaviour afterwards
 559
 560         vel_straight = vel_straight + bound(0, wishspeed - vel_straight, step) * accelqw + step * (1 - accelqw);
 561
 562         if(sidefric < 0 && (vel_perpend*vel_perpend))
 563                 // negative: only apply so much sideways friction to stay below the speed you could get by "braking"
 564         {
 565                 float f, fminimum;
 566                 f = max(0, 1 + frametime * wishspeed * sidefric);
 567                 fminimum = (vel_xy_backward*vel_xy_backward - vel_straight*vel_straight) / (vel_perpend*vel_perpend);
 568                 // this cannot be > 1
 569                 if(fminimum <= 0)
 570                         vel_perpend = vel_perpend * max(0, f);
 571                 else
 572                 {
 573                         fminimum = sqrt(fminimum);
 574                         vel_perpend = vel_perpend * max(fminimum, f);
 575                 }
 576         }
 577         else
 578                 vel_perpend = vel_perpend * max(0, 1 - frametime * wishspeed * sidefric);
 579
 580         vel_xy = vel_straight * wishdir + vel_perpend;
 581
 582         if(speedclamp >= 0)
 583         {
 584                 float vel_xy_preclamp;
 585                 vel_xy_preclamp = vlen(vel_xy);
 586                 if(vel_xy_preclamp > 0) // prevent division by zero
 587                 {
 588                         vel_xy_current += (vel_xy_forward - vel_xy_current) * speedclamp;
 589                         if(vel_xy_current < vel_xy_preclamp)
 590                                 vel_xy = vel_xy * (vel_xy_current / vel_xy_preclamp);
 591                 }
 592         }
 593
 594         self.velocity = vel_xy + vel_z * '0 0 1';
 595 }
 596
 597 void PM_AirAccelerate(vector wishdir, float wishspeed)
 598 {
 599         vector curvel, wishvel, acceldir, curdir;
 600         float addspeed, accelspeed, curspeed, f;
 601         float dot;
 602
 603         if(wishspeed == 0)
 604                 return;
 605
 606         curvel = self.velocity;
 607         curvel_z = 0;
 608         curspeed = vlen(curvel);
 609
 610         if(wishspeed > curspeed * 1.01)
 611         {
 612                 wishspeed = min(wishspeed, curspeed + self.stat_sv_warsowbunny_airforwardaccel * self.stat_sv_maxspeed * frametime);
 613         }
 614         else
 615         {
 616                 f = max(0, (self.stat_sv_warsowbunny_topspeed - curspeed) / (self.stat_sv_warsowbunny_topspeed - self.stat_sv_maxspeed));
 617                 wishspeed = max(curspeed, self.stat_sv_maxspeed) + self.stat_sv_warsowbunny_accel * f * self.stat_sv_maxspeed * frametime;
 618         }
 619         wishvel = wishdir * wishspeed;
 620         acceldir = wishvel - curvel;
 621         addspeed = vlen(acceldir);
 622         acceldir = normalize(acceldir);
 623
 624         accelspeed = min(addspeed, self.stat_sv_warsowbunny_turnaccel * self.stat_sv_maxspeed * frametime);
 625
 626         if(self.stat_sv_warsowbunny_backtosideratio < 1)
 627         {
 628                 curdir = normalize(curvel);
 629                 dot = acceldir * curdir;
 630                 if(dot < 0)
 631                         acceldir = acceldir - (1 - self.stat_sv_warsowbunny_backtosideratio) * dot * curdir;
 632         }
 633
 634         self.velocity += accelspeed * acceldir;
 635 }
 636
 637 .vector movement_old;
 638 .float buttons_old;
 639 .vector v_angle_old;
 640 .string lastclassname;
 641
 642 .float() PlayerPhysplug;
 643
 644 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 645 .float specialcommand_pos;
 646 void SpecialCommand()
 647 {
 648 #ifdef TETRIS
 649         TetrisImpulse();
 650 #else
 651         if(!CheatImpulse(99))
 652                 print("A hollow voice says \"Plugh\".\n");
 653 #endif
 654 }
 655
 656 float speedaward_speed;
 657 string speedaward_holder;
 658 string speedaward_uid;
 659 void race_send_speedaward(float msg)
 660 {
 661         // send the best speed of the round
 662         WriteByte(msg, SVC_TEMPENTITY);
 663         WriteByte(msg, TE_CSQC_RACE);
 664         WriteByte(msg, RACE_NET_SPEED_AWARD);
 665         WriteInt24_t(msg, floor(speedaward_speed+0.5));
 666         WriteString(msg, speedaward_holder);
 667 }
 668
 669 float speedaward_alltimebest;
 670 string speedaward_alltimebest_holder;
 671 string speedaward_alltimebest_uid;
 672 void race_send_speedaward_alltimebest(float msg)
 673 {
 674         // send the best speed
 675         WriteByte(msg, SVC_TEMPENTITY);
 676         WriteByte(msg, TE_CSQC_RACE);
 677         WriteByte(msg, RACE_NET_SPEED_AWARD_BEST);
 678         WriteInt24_t(msg, floor(speedaward_alltimebest+0.5));
 679         WriteString(msg, speedaward_alltimebest_holder);
 680 }
 681
 682 string GetMapname(void);
 683 float speedaward_lastupdate;
 684 float speedaward_lastsent;
 685 void SV_PlayerPhysics()
 686 {
 687         vector wishvel, wishdir, v;
 688         float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, buttons;
 689         string temps;
 690         float buttons_prev;
 691         float not_allowed_to_move;
 692         string c;
 693
 694         WarpZone_PlayerPhysics_FixVAngle();
 695
 696         maxspd_mod = 1;
 697         if(self.ballcarried)
 698                 if(g_keepaway)
 699                         maxspd_mod *= autocvar_g_keepaway_ballcarrier_highspeed;
 700
 701         maxspd_mod *= autocvar_g_movement_highspeed;
 702
 703         // fix physics stats for g_movement_highspeed
 704         // TODO maybe rather use maxairspeed? needs testing
 705         self.stat_sv_airaccel_qw = AdjustAirAccelQW(Physics_ClientOption(self, "airaccel_qw"), maxspd_mod);
 706         if(Physics_ClientOption(self, "airstrafeaccel_qw"))
 707                 self.stat_sv_airstrafeaccel_qw = AdjustAirAccelQW(Physics_ClientOption(self, "airstrafeaccel_qw"), maxspd_mod);
 708         else
 709                 self.stat_sv_airstrafeaccel_qw = 0;
 710         self.stat_sv_airspeedlimit_nonqw = Physics_ClientOption(self, "airspeedlimit_nonqw") * maxspd_mod;
 711         self.stat_sv_maxspeed = Physics_ClientOption(self, "maxspeed") * maxspd_mod; // also slow walking
 712
 713         // fix some new settings
 714         self.stat_sv_airaccel_qw_stretchfactor = Physics_ClientOption(self, "airaccel_qw_stretchfactor");
 715         self.stat_sv_maxairstrafespeed = Physics_ClientOption(self, "maxairstrafespeed");
 716         self.stat_sv_maxairspeed = Physics_ClientOption(self, "maxairspeed");
 717         self.stat_sv_airstrafeaccelerate = Physics_ClientOption(self, "airstrafeaccelerate");
 718         self.stat_sv_warsowbunny_turnaccel = Physics_ClientOption(self, "warsowbunny_turnaccel");
 719         self.stat_sv_airaccel_sideways_friction = Physics_ClientOption(self, "airaccel_sideways_friction");
 720         self.stat_sv_aircontrol = Physics_ClientOption(self, "aircontrol");
 721         self.stat_sv_aircontrol_power = Physics_ClientOption(self, "aircontrol_power");
 722         self.stat_sv_aircontrol_penalty = Physics_ClientOption(self, "aircontrol_penalty");
 723         self.stat_sv_warsowbunny_airforwardaccel = Physics_ClientOption(self, "warsowbunny_airforwardaccel");
 724         self.stat_sv_warsowbunny_topspeed = Physics_ClientOption(self, "warsowbunny_topspeed");
 725         self.stat_sv_warsowbunny_accel = Physics_ClientOption(self, "warsowbunny_accel");
 726         self.stat_sv_warsowbunny_backtosideratio = Physics_ClientOption(self, "warsowbunny_backtosideratio");
 727         self.stat_sv_friction = Physics_ClientOption(self, "friction");
 728         self.stat_sv_accelerate = Physics_ClientOption(self, "accelerate");
 729         self.stat_sv_stopspeed = Physics_ClientOption(self, "stopspeed");
 730         self.stat_sv_airaccelerate = Physics_ClientOption(self, "airaccelerate");
 731         self.stat_sv_airstopaccelerate = Physics_ClientOption(self, "airstopaccelerate");
 732         self.stat_sv_jumpvelocity = Physics_ClientOption(self, "jumpvelocity");
 733
 734     if(self.PlayerPhysplug)
 735         if(self.PlayerPhysplug())
 736             return;
 737
 738         self.race_movetime_frac += frametime;
 739         f = floor(self.race_movetime_frac);
 740         self.race_movetime_frac -= f;
 741         self.race_movetime_count += f;
 742         self.race_movetime = self.race_movetime_frac + self.race_movetime_count;
 743
 744         anticheat_physics();
 745
 746         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE + 128 * (self.movement_x < 0) + 256 * (self.movement_x > 0) + 512 * (self.movement_y < 0) + 1024 * (self.movement_y > 0);
 747
 748         if(!buttons)
 749                 c = "x";
 750         else if(buttons == 1)
 751                 c = "1";
 752         else if(buttons == 2)
 753                 c = " ";
 754         else if(buttons == 128)
 755                 c = "s";
 756         else if(buttons == 256)
 757                 c = "w";
 758         else if(buttons == 512)
 759                 c = "a";
 760         else if(buttons == 1024)
 761                 c = "d";
 762         else
 763                 c = "?";
 764
 765         if(c == substring(specialcommand, self.specialcommand_pos, 1))
 766         {
 767                 self.specialcommand_pos += 1;
 768                 if(self.specialcommand_pos >= strlen(specialcommand))
 769                 {
 770                         self.specialcommand_pos = 0;
 771                         SpecialCommand();
 772                         return;
 773                 }
 774         }
 775         else if(self.specialcommand_pos && (c != substring(specialcommand, self.specialcommand_pos - 1, 1)))
 776                 self.specialcommand_pos = 0;
 777
 778         if(sv_maxidle > 0)
 779         {
 780                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 781                         self.parm_idlesince = time;
 782         }
 783         buttons_prev = self.buttons_old;
 784         self.buttons_old = buttons;
 785         self.movement_old = self.movement;
 786         self.v_angle_old = self.v_angle;
 787
 788         if(time < self.nickspamtime)
 789         if(self.nickspamcount >= autocvar_g_nick_flood_penalty_yellow)
 790         {
 791                 // slight annoyance for nick change scripts
 792                 self.movement = -1 * self.movement;
 793                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = self.BUTTON_ZOOM = self.BUTTON_CROUCH = self.BUTTON_HOOK = self.BUTTON_USE = 0;
 794
 795                 if(self.nickspamcount >= autocvar_g_nick_flood_penalty_red) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 796                 {
 797                         self.angles_x = random() * 360;
 798                         self.angles_y = random() * 360;
 799                         // at least I'm not forcing retardedview by also assigning to angles_z
 800                         self.fixangle = TRUE;
 801                 }
 802         }
 803
 804         if (self.punchangle != '0 0 0')
 805         {
 806                 f = vlen(self.punchangle) - 10 * frametime;
 807                 if (f > 0)
 808                         self.punchangle = normalize(self.punchangle) * f;
 809                 else
 810                         self.punchangle = '0 0 0';
 811         }
 812
 813         if (self.punchvector != '0 0 0')
 814         {
 815                 f = vlen(self.punchvector) - 30 * frametime;
 816                 if (f > 0)
 817                         self.punchvector = normalize(self.punchvector) * f;
 818                 else
 819                         self.punchvector = '0 0 0';
 820         }
 821
 822         if (IS_BOT_CLIENT(self))
 823         {
 824                 if(playerdemo_read())
 825                         return;
 826                 bot_think();
 827         }
 828
 829         if(IS_PLAYER(self))
 830         {
 831                 if(self.race_penalty)
 832                         if(time > self.race_penalty)
 833                                 self.race_penalty = 0;
 834
 835                 not_allowed_to_move = 0;
 836                 if(self.race_penalty)
 837                         not_allowed_to_move = 1;
 838                 if(!autocvar_sv_ready_restart_after_countdown)
 839                 if(time < game_starttime)
 840                         not_allowed_to_move = 1;
 841
 842                 if(not_allowed_to_move)
 843                 {
 844                         self.velocity = '0 0 0';
 845                         self.movetype = MOVETYPE_NONE;
 846                         self.disableclientprediction = 2;
 847                 }
 848                 else if(self.disableclientprediction == 2)
 849                 {
 850                         if(self.movetype == MOVETYPE_NONE)
 851                                 self.movetype = MOVETYPE_WALK;
 852                         self.disableclientprediction = 0;
 853                 }
 854         }
 855
 856         if (self.movetype == MOVETYPE_NONE)
 857                 return;
 858
 859         // when we get here, disableclientprediction cannot be 2
 860         self.disableclientprediction = 0;
 861         if(time < self.ladder_time)
 862                 self.disableclientprediction = 1;
 863
 864         if(time < self.spider_slowness)
 865         {
 866                 self.stat_sv_maxspeed *= 0.5; // half speed while slow from spider
 867                 self.stat_sv_airspeedlimit_nonqw *= 0.5;
 868         }
 869
 870         if(self.frozen)
 871         {
 872                 if(autocvar_sv_dodging_frozen && IS_REAL_CLIENT(self))
 873                 {
 874                         self.movement_x = bound(-5, self.movement_x, 5);
 875                         self.movement_y = bound(-5, self.movement_y, 5);
 876                         self.movement_z = bound(-5, self.movement_z, 5);
 877                 }
 878                 else
 879                         self.movement = '0 0 0';
 880                 self.disableclientprediction = 1;
 881
 882                 vector midpoint = ((self.absmin + self.absmax) * 0.5);
 883                 if(pointcontents(midpoint) == CONTENT_WATER)
 884                 {
 885                         self.velocity = self.velocity * 0.5;
 886
 887                         if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 888                                 { self.velocity_z = 200; }
 889                 }
 890         }
 891
 892         MUTATOR_CALLHOOK(PlayerPhysics);
 893
 894         if(self.player_blocked)
 895         {
 896                 self.movement = '0 0 0';
 897                 self.disableclientprediction = 1;
 898         }
 899
 900         maxspd_mod = 1;
 901
 902         swampspd_mod = 1;
 903         if(self.in_swamp) {
 904                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 905         }
 906
 907         // conveyors: first fix velocity
 908         if(self.conveyor.state)
 909                 self.velocity -= self.conveyor.movedir;
 910
 911         if (!IS_PLAYER(self))
 912         {
 913                 maxspd_mod = autocvar_sv_spectator_speed_multiplier;
 914                 if(!self.spectatorspeed)
 915                         self.spectatorspeed = maxspd_mod;
 916                 if(self.impulse && self.impulse <= 19 || (self.impulse >= 200 && self.impulse <= 209) || (self.impulse >= 220 && self.impulse <= 229))
 917                 {
 918                         if(self.lastclassname != "player")
 919                         {
 920                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209))
 921                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 922                                 else if(self.impulse == 11)
 923                                         self.spectatorspeed = maxspd_mod;
 924                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229))
 925                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 926                                 else if(self.impulse >= 1 && self.impulse <= 9)
 927                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 928                         } // otherwise just clear
 929                         self.impulse = 0;
 930                 }
 931                 maxspd_mod = self.spectatorspeed;
 932         }
 933
 934         spd = max(self.stat_sv_maxspeed, self.stat_sv_maxairspeed) * maxspd_mod * swampspd_mod;
 935         if(self.speed != spd)
 936         {
 937                 self.speed = spd;
 938                 temps = ftos(spd);
 939                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 940                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 941                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 942                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 943         }
 944
 945         maxspd_mod *= swampspd_mod; // only one common speed modder please!
 946         swampspd_mod = 1;
 947
 948         // if dead, behave differently
 949         if (self.deadflag)
 950                 goto end;
 951
 952         if (!self.fixangle && !g_bugrigs)
 953         {
 954                 self.angles_x = 0;
 955                 self.angles_y = self.v_angle_y;
 956                 self.angles_z = 0;
 957         }
 958
 959         if(self.flags & FL_ONGROUND)
 960         if(IS_PLAYER(self)) // no fall sounds for observers thank you very much
 961         if(self.wasFlying)
 962         {
 963                 self.wasFlying = 0;
 964
 965                 if(self.waterlevel < WATERLEVEL_SWIMMING)
 966                 if(time >= self.ladder_time)
 967                 if (!self.hook)
 968                 {
 969                         self.nextstep = time + 0.3 + random() * 0.1;
 970                         trace_dphitq3surfaceflags = 0;
 971                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 972                         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS))
 973                         {
 974                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 975                                         GlobalSound(globalsound_metalfall, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 976                                 else
 977                                         GlobalSound(globalsound_fall, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 978                         }
 979                 }
 980         }
 981
 982         if(IsFlying(self))
 983                 self.wasFlying = 1;
 984
 985         if(IS_PLAYER(self))
 986                 CheckPlayerJump();
 987
 988         if (self.flags & FL_WATERJUMP )
 989         {
 990                 self.velocity_x = self.movedir_x;
 991                 self.velocity_y = self.movedir_y;
 992                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
 993                 {
 994                         self.flags &= ~FL_WATERJUMP;
 995                         self.teleport_time = 0;
 996                 }
 997         }
 998         else if (g_bugrigs && IS_PLAYER(self))
 999         {
1000                 RaceCarPhysics();
1001         }
1002         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY || self.movetype == MOVETYPE_FLY_WORLDONLY)
1003         {
1004                 // noclipping or flying
1005                 self.flags &= ~FL_ONGROUND;
1006
1007                 self.velocity = self.velocity * (1 - frametime * self.stat_sv_friction);
1008                 makevectors(self.v_angle);
1009                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
1010                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
1011                 // acceleration
1012                 wishdir = normalize(wishvel);
1013                 wishspeed = vlen(wishvel);
1014                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1015                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1016                 if (time >= self.teleport_time)
1017                         PM_Accelerate(wishdir, wishspeed, wishspeed, self.stat_sv_accelerate*maxspd_mod, 1, 0, 0, 0);
1018         }
1019         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
1020         {
1021                 // swimming
1022                 self.flags &= ~FL_ONGROUND;
1023
1024                 makevectors(self.v_angle);
1025                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
1026                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
1027                 if (wishvel == '0 0 0')
1028                         wishvel = '0 0 -60'; // drift towards bottom
1029
1030                 wishdir = normalize(wishvel);
1031                 wishspeed = vlen(wishvel);
1032                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1033                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1034                 wishspeed = wishspeed * 0.7;
1035
1036                 // water friction
1037                 self.velocity = self.velocity * (1 - frametime * self.stat_sv_friction);
1038
1039                 // water acceleration
1040                 PM_Accelerate(wishdir, wishspeed, wishspeed, self.stat_sv_accelerate*maxspd_mod, 1, 0, 0, 0);
1041         }
1042         else if (time < self.ladder_time)
1043         {
1044                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
1045                 self.flags &= ~FL_ONGROUND;
1046
1047                 float g;
1048                 g = autocvar_sv_gravity * frametime;
1049                 if(self.gravity)
1050                         g *= self.gravity;
1051                 if(autocvar_sv_gameplayfix_gravityunaffectedbyticrate)
1052                 {
1053                         g *= 0.5;
1054                         self.velocity_z += g;
1055                 }
1056
1057                 self.velocity = self.velocity * (1 - frametime * self.stat_sv_friction);
1058                 makevectors(self.v_angle);
1059                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
1060                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
1061                 self.velocity_z += g;
1062                 if (self.ladder_entity.classname == "func_water")
1063                 {
1064                         f = vlen(wishvel);
1065                         if (f > self.ladder_entity.speed)
1066                                 wishvel = wishvel * (self.ladder_entity.speed / f);
1067
1068                         self.watertype = self.ladder_entity.skin;
1069                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
1070                         if ((self.origin_z + self.view_ofs_z) < f)
1071                                 self.waterlevel = WATERLEVEL_SUBMERGED;
1072                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
1073                                 self.waterlevel = WATERLEVEL_SWIMMING;
1074                         else if ((self.origin_z + self.mins_z + 1) < f)
1075                                 self.waterlevel = WATERLEVEL_WETFEET;
1076                         else
1077                         {
1078                                 self.waterlevel = WATERLEVEL_NONE;
1079                                 self.watertype = CONTENT_EMPTY;
1080                         }
1081                 }
1082                 // acceleration
1083                 wishdir = normalize(wishvel);
1084                 wishspeed = vlen(wishvel);
1085                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1086                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1087                 if (time >= self.teleport_time)
1088                 {
1089                         // water acceleration
1090                         PM_Accelerate(wishdir, wishspeed, wishspeed, self.stat_sv_accelerate*maxspd_mod, 1, 0, 0, 0);
1091                 }
1092         }
1093         else if (self.items & IT_USING_JETPACK)
1094         {
1095                 //makevectors(self.v_angle_y * '0 1 0');
1096                 makevectors(self.v_angle);
1097                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1098                 // add remaining speed as Z component
1099                 maxairspd = self.stat_sv_maxairspeed*max(1, maxspd_mod);
1100                 // fix speedhacks :P
1101                 wishvel = normalize(wishvel) * min(vlen(wishvel) / maxairspd, 1);
1102                 // add the unused velocity as up component
1103                 wishvel_z = 0;
1104
1105                 // if(self.BUTTON_JUMP)
1106                         wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
1107
1108                 // it is now normalized, so...
1109                 float a_side, a_up, a_add, a_diff;
1110                 a_side = autocvar_g_jetpack_acceleration_side;
1111                 a_up = autocvar_g_jetpack_acceleration_up;
1112                 a_add = autocvar_g_jetpack_antigravity * autocvar_sv_gravity;
1113
1114                 wishvel_x *= a_side;
1115                 wishvel_y *= a_side;
1116                 wishvel_z *= a_up;
1117                 wishvel_z += a_add;
1118
1119                 float best;
1120                 best = 0;
1121                 //////////////////////////////////////////////////////////////////////////////////////
1122                 // finding the maximum over all vectors of above form
1123                 // with wishvel having an absolute value of 1
1124                 //////////////////////////////////////////////////////////////////////////////////////
1125                 // we're finding the maximum over
1126                 //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
1127                 // for z in the range from -1 to 1
1128                 //////////////////////////////////////////////////////////////////////////////////////
1129                 // maximum is EITHER attained at the single extreme point:
1130                 a_diff = a_side * a_side - a_up * a_up;
1131                 if(a_diff != 0)
1132                 {
1133                         f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
1134                         if(f > -1 && f < 1) // can it be attained?
1135                         {
1136                                 best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
1137                                 //print("middle\n");
1138                         }
1139                 }
1140                 // OR attained at z = 1:
1141                 f = (a_up + a_add) * (a_up + a_add);
1142                 if(f > best)
1143                 {
1144                         best = f;
1145                         //print("top\n");
1146                 }
1147                 // OR attained at z = -1:
1148                 f = (a_up - a_add) * (a_up - a_add);
1149                 if(f > best)
1150                 {
1151                         best = f;
1152                         //print("bottom\n");
1153                 }
1154                 best = sqrt(best);
1155                 //////////////////////////////////////////////////////////////////////////////////////
1156
1157                 //print("best possible acceleration: ", ftos(best), "\n");
1158
1159                 float fxy, fz;
1160                 fxy = bound(0, 1 - (self.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / autocvar_g_jetpack_maxspeed_side, 1);
1161                 if(wishvel_z - autocvar_sv_gravity > 0)
1162                         fz = bound(0, 1 - self.velocity_z / autocvar_g_jetpack_maxspeed_up, 1);
1163                 else
1164                         fz = bound(0, 1 + self.velocity_z / autocvar_g_jetpack_maxspeed_up, 1);
1165
1166                 wishvel_x *= fxy;
1167                 wishvel_y *= fxy;
1168                 wishvel_z = (wishvel_z - autocvar_sv_gravity) * fz + autocvar_sv_gravity;
1169
1170                 float fvel;
1171                 fvel = min(1, vlen(wishvel) / best);
1172                 if(autocvar_g_jetpack_fuel && !(self.items & IT_UNLIMITED_WEAPON_AMMO))
1173                         f = min(1, self.ammo_fuel / (autocvar_g_jetpack_fuel * frametime * fvel));
1174                 else
1175                         f = 1;
1176
1177                 //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
1178
1179                 if (f > 0 && wishvel != '0 0 0')
1180                 {
1181                         self.velocity = self.velocity + wishvel * f * frametime;
1182                         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1183                                 self.ammo_fuel -= autocvar_g_jetpack_fuel * frametime * fvel * f;
1184                         self.flags &= ~FL_ONGROUND;
1185                         self.items |= IT_USING_JETPACK;
1186
1187                         // jetpack also inhibits health regeneration, but only for 1 second
1188                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
1189                 }
1190         }
1191         else if (self.flags & FL_ONGROUND)
1192         {
1193                 // we get here if we ran out of ammo
1194                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32) && self.ammo_fuel < 0.01)
1195                         Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_JETPACK_NOFUEL);
1196
1197                 // walking
1198                 makevectors(self.v_angle_y * '0 1 0');
1199                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1200
1201                 if(!(self.lastflags & FL_ONGROUND))
1202                 {
1203                         if(autocvar_speedmeter)
1204                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
1205                         if(self.lastground < time - 0.3)
1206                                 self.velocity = self.velocity * (1 - autocvar_sv_friction_on_land);
1207                         if(self.jumppadcount > 1)
1208                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
1209                         self.jumppadcount = 0;
1210                 }
1211
1212                 v = self.velocity;
1213                 v_z = 0;
1214                 f = vlen(v);
1215                 if(f > 0)
1216                 {
1217                         if (f < self.stat_sv_stopspeed)
1218                                 f = 1 - frametime * (self.stat_sv_stopspeed / f) * self.stat_sv_friction;
1219                         else
1220                                 f = 1 - frametime * self.stat_sv_friction;
1221                         if (f > 0)
1222                                 self.velocity = self.velocity * f;
1223                         else
1224                                 self.velocity = '0 0 0';
1225                         /*
1226                            Mathematical analysis time!
1227
1228                            Our goal is to invert this mess.
1229
1230                            For the two cases we get:
1231                                 v = v0 * (1 - frametime * (autocvar_sv_stopspeed / v0) * autocvar_sv_friction)
1232                                   = v0 - frametime * autocvar_sv_stopspeed * autocvar_sv_friction
1233                                 v0 = v + frametime * autocvar_sv_stopspeed * autocvar_sv_friction
1234                            and
1235                                 v = v0 * (1 - frametime * autocvar_sv_friction)
1236                                 v0 = v / (1 - frametime * autocvar_sv_friction)
1237
1238                            These cases would be chosen ONLY if:
1239                                 v0 < autocvar_sv_stopspeed
1240                                 v + frametime * autocvar_sv_stopspeed * autocvar_sv_friction < autocvar_sv_stopspeed
1241                                 v < autocvar_sv_stopspeed * (1 - frametime * autocvar_sv_friction)
1242                            and, respectively:
1243                                 v0 >= autocvar_sv_stopspeed
1244                                 v / (1 - frametime * autocvar_sv_friction) >= autocvar_sv_stopspeed
1245                                 v >= autocvar_sv_stopspeed * (1 - frametime * autocvar_sv_friction)
1246                          */
1247                 }
1248
1249                 // acceleration
1250                 wishdir = normalize(wishvel);
1251                 wishspeed = vlen(wishvel);
1252                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1253                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1254                 if (self.crouch)
1255                         wishspeed = wishspeed * 0.5;
1256                 if (time >= self.teleport_time)
1257                         PM_Accelerate(wishdir, wishspeed, wishspeed, self.stat_sv_accelerate*maxspd_mod, 1, 0, 0, 0);
1258         }
1259         else
1260         {
1261                 float wishspeed0;
1262                 // we get here if we ran out of ammo
1263                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32) && self.ammo_fuel < 0.01)
1264                         Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_JETPACK_NOFUEL);
1265
1266                 if(maxspd_mod < 1)
1267                 {
1268                         maxairspd = self.stat_sv_maxairspeed*maxspd_mod;
1269                         airaccel = self.stat_sv_airaccelerate*maxspd_mod;
1270                 }
1271                 else
1272                 {
1273                         maxairspd = self.stat_sv_maxairspeed;
1274                         airaccel = self.stat_sv_airaccelerate;
1275                 }
1276                 // airborn
1277                 makevectors(self.v_angle_y * '0 1 0');
1278                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1279                 // acceleration
1280                 wishdir = normalize(wishvel);
1281                 wishspeed = wishspeed0 = vlen(wishvel);
1282                 if (wishspeed0 > self.stat_sv_maxspeed*maxspd_mod)
1283                         wishspeed0 = self.stat_sv_maxspeed*maxspd_mod;
1284                 if (wishspeed > maxairspd)
1285                         wishspeed = maxairspd;
1286                 if (self.crouch)
1287                         wishspeed = wishspeed * 0.5;
1288                 if (time >= self.teleport_time)
1289                 {
1290                         float accelerating;
1291                         float wishspeed2;
1292                         float airaccelqw;
1293                         float strafity;
1294
1295                         airaccelqw = self.stat_sv_airaccel_qw;
1296                         accelerating = (self.velocity * wishdir > 0);
1297                         wishspeed2 = wishspeed;
1298
1299                         // CPM
1300                         if(self.stat_sv_airstopaccelerate)
1301                         {
1302                                 vector curdir;
1303                                 curdir = self.velocity;
1304                                 curdir_z = 0;
1305                                 curdir = normalize(curdir);
1306                                 airaccel = airaccel + (self.stat_sv_airstopaccelerate*maxspd_mod - airaccel) * max(0, -(curdir * wishdir));
1307                         }
1308                         // note that for straight forward jumping:
1309                         // step = accel * frametime * wishspeed0;
1310                         // accel  = bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
1311                         // -->
1312                         // dv/dt = accel * maxspeed (when slow)
1313                         // dv/dt = accel * maxspeed * (1 - accelqw) (when fast)
1314                         // log dv/dt = logaccel + logmaxspeed (when slow)
1315                         // log dv/dt = logaccel + logmaxspeed + log(1 - accelqw) (when fast)
1316                         strafity = IsMoveInDirection(self.movement, -90) + IsMoveInDirection(self.movement, +90); // if one is nonzero, other is always zero
1317                         if(self.stat_sv_maxairstrafespeed)
1318                                 wishspeed = min(wishspeed, GeomLerp(self.stat_sv_maxairspeed*maxspd_mod, strafity, self.stat_sv_maxairstrafespeed*maxspd_mod));
1319                         if(self.stat_sv_airstrafeaccelerate)
1320                                 airaccel = GeomLerp(airaccel, strafity, self.stat_sv_airstrafeaccelerate*maxspd_mod);
1321                         if(self.stat_sv_airstrafeaccel_qw)
1322                                 airaccelqw = copysign(1-GeomLerp(1-fabs(self.stat_sv_airaccel_qw), strafity, 1-fabs(self.stat_sv_airstrafeaccel_qw)), ((strafity > 0.5) ? self.stat_sv_airstrafeaccel_qw : self.stat_sv_airaccel_qw));
1323                         // !CPM
1324
1325                         if(self.stat_sv_warsowbunny_turnaccel && accelerating && self.movement_y == 0 && self.movement_x != 0)
1326                                 PM_AirAccelerate(wishdir, wishspeed);
1327                         else
1328                                 PM_Accelerate(wishdir, wishspeed, wishspeed0, airaccel, airaccelqw, self.stat_sv_airaccel_qw_stretchfactor, self.stat_sv_airaccel_sideways_friction / maxairspd, self.stat_sv_airspeedlimit_nonqw);
1329
1330                         if(self.stat_sv_aircontrol)
1331                                 CPM_PM_Aircontrol(wishdir, wishspeed2);
1332                 }
1333         }
1334
1335         if((g_cts || g_race) && !IS_OBSERVER(self))
1336         {
1337                 if(vlen(self.velocity - self.velocity_z * '0 0 1') > speedaward_speed)
1338                 {
1339                         speedaward_speed = vlen(self.velocity - self.velocity_z * '0 0 1');
1340                         speedaward_holder = self.netname;
1341                         speedaward_uid = self.crypto_idfp;
1342                         speedaward_lastupdate = time;
1343                 }
1344                 if(speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1)
1345                 {
1346                         string rr = (g_cts) ? CTS_RECORD : RACE_RECORD;
1347                         race_send_speedaward(MSG_ALL);
1348                         speedaward_lastsent = speedaward_speed;
1349                         if (speedaward_speed > speedaward_alltimebest && speedaward_uid != "")
1350                         {
1351                                 speedaward_alltimebest = speedaward_speed;
1352                                 speedaward_alltimebest_holder = speedaward_holder;
1353                                 speedaward_alltimebest_uid = speedaward_uid;
1354                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
1355                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp"), speedaward_alltimebest_uid);
1356                                 race_send_speedaward_alltimebest(MSG_ALL);
1357                         }
1358                 }
1359         }
1360
1361         // WEAPONTODO
1362         float xyspeed;
1363         xyspeed = vlen('1 0 0' * self.velocity_x + '0 1 0' * self.velocity_y);
1364         if(self.weapon == WEP_VORTEX && WEP_CVAR(vortex, charge) && WEP_CVAR(vortex, charge_velocity_rate) && xyspeed > WEP_CVAR(vortex, charge_minspeed))
1365         {
1366                 // add a maximum of charge_velocity_rate when going fast (f = 1), gradually increasing from minspeed (f = 0) to maxspeed
1367                 xyspeed = min(xyspeed, WEP_CVAR(vortex, charge_maxspeed));
1368                 f = (xyspeed - WEP_CVAR(vortex, charge_minspeed)) / (WEP_CVAR(vortex, charge_maxspeed) - WEP_CVAR(vortex, charge_minspeed));
1369                 // add the extra charge
1370                 self.vortex_charge = min(1, self.vortex_charge + WEP_CVAR(vortex, charge_velocity_rate) * f * frametime);
1371         }
1372 :end
1373         if(self.flags & FL_ONGROUND)
1374                 self.lastground = time;
1375
1376         // conveyors: then break velocity again
1377         if(self.conveyor.state)
1378                 self.velocity += self.conveyor.movedir;
1379
1380         self.lastflags = self.flags;
1381         self.lastclassname = self.classname;
1382 }