qcsrc/server/cl_physics.qc

   1 .float race_penalty;
   2 .float restart_jump;
   3
   4 .float ladder_time;
   5 .entity ladder_entity;
   6 .float gravity;
   7 .float swamp_slowdown;
   8 .float lastflags;
   9 .float lastground;
  10 .float wasFlying;
  11 .float spectatorspeed;
  12
  13 // client side physics
  14 float Physics_Valid(string thecvar)
  15 {
  16         if(!autocvar_g_physics_clientselect) { return FALSE; }
  17
  18         string l = strcat(" ", autocvar_g_physics_clientselect_options, " ");
  19
  20         if(strstrofs(l, strcat(" ", thecvar, " "), 0) >= 0)
  21                 return TRUE;
  22
  23         return FALSE;
  24 }
  25
  26 float Physics_ClientOption(entity pl, string option)
  27 {
  28         if(Physics_Valid(pl.cvar_cl_physics) && (cvar_type(sprintf("g_physics_%s_%s", pl.cvar_cl_physics, option)) & 1))
  29                 return cvar(sprintf("g_physics_%s_%s", pl.cvar_cl_physics, option));
  30         else
  31                 return cvar(strcat("sv_", option));
  32 }
  33
  34 /*
  35 =============
  36 PlayerJump
  37
  38 When you press the jump key
  39 =============
  40 */
  41 void PlayerJump (void)
  42 {
  43         if(self.frozen)
  44                 return; // no jumping in freezetag when frozen
  45
  46         if(self.player_blocked)
  47                 return; // no jumping while blocked
  48
  49         float doublejump = FALSE;
  50         float mjumpheight = self.stat_sv_jumpvelocity;
  51
  52         player_multijump = doublejump;
  53         player_jumpheight = mjumpheight;
  54         if(MUTATOR_CALLHOOK(PlayerJump))
  55                 return;
  56
  57         doublejump = player_multijump;
  58         mjumpheight = player_jumpheight;
  59
  60         if (autocvar_sv_doublejump)
  61         {
  62                 tracebox(self.origin + '0 0 0.01', self.mins, self.maxs, self.origin - '0 0 0.01', MOVE_NORMAL, self);
  63                 if (trace_fraction < 1 && trace_plane_normal_z > 0.7)
  64                 {
  65                         doublejump = TRUE;
  66
  67                         // we MUST clip velocity here!
  68                         float f;
  69                         f = self.velocity * trace_plane_normal;
  70                         if(f < 0)
  71                                 self.velocity -= f * trace_plane_normal;
  72                 }
  73         }
  74
  75         if (self.waterlevel >= WATERLEVEL_SWIMMING)
  76         {
  77                 self.velocity_z = self.stat_sv_maxspeed * 0.7;
  78                 return;
  79         }
  80
  81         if (!doublejump)
  82                 if (!(self.flags & FL_ONGROUND))
  83                         return;
  84
  85         if(self.cvar_cl_movement_track_canjump)
  86                 if (!(self.flags & FL_JUMPRELEASED))
  87                         return;
  88
  89         // sv_jumpspeedcap_min/sv_jumpspeedcap_max act as baseline
  90         // velocity bounds.  Final velocity is bound between (jumpheight *
  91         // min + jumpheight) and (jumpheight * max + jumpheight);
  92
  93         if(autocvar_sv_jumpspeedcap_min != "")
  94         {
  95                 float minjumpspeed;
  96
  97                 minjumpspeed = mjumpheight * stof(autocvar_sv_jumpspeedcap_min);
  98
  99                 if (self.velocity_z < minjumpspeed)
 100                         mjumpheight += minjumpspeed - self.velocity_z;
 101         }
 102
 103         if(autocvar_sv_jumpspeedcap_max != "")
 104         {
 105                 // don't do jump speedcaps on ramps to preserve old xonotic ramjump style
 106                 tracebox(self.origin + '0 0 0.01', self.mins, self.maxs, self.origin - '0 0 0.01', MOVE_NORMAL, self);
 107
 108                 if(!(trace_fraction < 1 && trace_plane_normal_z < 0.98 && autocvar_sv_jumpspeedcap_max_disable_on_ramps))
 109                 {
 110                         float maxjumpspeed;
 111
 112                         maxjumpspeed = mjumpheight * stof(autocvar_sv_jumpspeedcap_max);
 113
 114                         if (self.velocity_z > maxjumpspeed)
 115                                 mjumpheight -= self.velocity_z - maxjumpspeed;
 116                 }
 117         }
 118
 119         if(!(self.lastflags & FL_ONGROUND))
 120         {
 121                 if(autocvar_speedmeter)
 122                         dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 123                 if(self.lastground < time - 0.3)
 124                 {
 125                         self.velocity_x *= (1 - autocvar_sv_friction_on_land);
 126                         self.velocity_y *= (1 - autocvar_sv_friction_on_land);
 127                 }
 128                 if(self.jumppadcount > 1)
 129                         dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 130                 self.jumppadcount = 0;
 131         }
 132
 133         self.velocity_z = self.velocity_z + mjumpheight;
 134         self.oldvelocity_z = self.velocity_z;
 135
 136         self.flags &= ~FL_ONGROUND;
 137         self.flags &= ~FL_JUMPRELEASED;
 138
 139         animdecide_setaction(self, ANIMACTION_JUMP, TRUE);
 140
 141         if(autocvar_g_jump_grunt)
 142                 PlayerSound(playersound_jump, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 143
 144         self.restart_jump = -1; // restart jump anim next time
 145         // value -1 is used to not use the teleport bit (workaround for tiny hitch when re-jumping)
 146 }
 147 void CheckWaterJump()
 148 {
 149         vector start, end;
 150
 151 // check for a jump-out-of-water
 152         makevectors (self.angles);
 153         start = self.origin;
 154         start_z = start_z + 8;
 155         v_forward_z = 0;
 156         normalize(v_forward);
 157         end = start + v_forward*24;
 158         traceline (start, end, TRUE, self);
 159         if (trace_fraction < 1)
 160         {       // solid at waist
 161                 start_z = start_z + self.maxs_z - 8;
 162                 end = start + v_forward*24;
 163                 self.movedir = trace_plane_normal * -50;
 164                 traceline (start, end, TRUE, self);
 165                 if (trace_fraction == 1)
 166                 {       // open at eye level
 167                         self.flags |= FL_WATERJUMP;
 168                         self.velocity_z = 225;
 169                         self.flags &= ~FL_JUMPRELEASED;
 170                         self.teleport_time = time + 2;  // safety net
 171                         return;
 172                 }
 173         }
 174 }
 175 void CheckPlayerJump()
 176 {
 177         if (self.BUTTON_JUMP)
 178                 PlayerJump ();
 179         else
 180                 self.flags |= FL_JUMPRELEASED;
 181
 182         if (self.waterlevel == WATERLEVEL_SWIMMING)
 183                 CheckWaterJump ();
 184 }
 185
 186 float racecar_angle(float forward, float down)
 187 {
 188         float ret, angle_mult;
 189
 190         if(forward < 0)
 191         {
 192                 forward = -forward;
 193                 down = -down;
 194         }
 195
 196         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 197
 198         angle_mult = forward / (800 + forward);
 199
 200         if(ret > 180)
 201                 return ret * angle_mult + 360 * (1 - angle_mult);
 202         else
 203                 return ret * angle_mult;
 204 }
 205
 206 void RaceCarPhysics()
 207 {
 208         // using this move type for "big rigs"
 209         // the engine does not push the entity!
 210
 211         float accel, steer, f, myspeed, steerfactor;
 212         vector angles_save, rigvel;
 213
 214         angles_save = self.angles;
 215         accel = bound(-1, self.movement_x / self.stat_sv_maxspeed, 1);
 216         steer = bound(-1, self.movement_y / self.stat_sv_maxspeed, 1);
 217
 218         if(g_bugrigs_reverse_speeding)
 219         {
 220                 if(accel < 0)
 221                 {
 222                         // back accel is DIGITAL
 223                         // to prevent speedhack
 224                         if(accel < -0.5)
 225                                 accel = -1;
 226                         else
 227                                 accel = 0;
 228                 }
 229         }
 230
 231         self.angles_x = 0;
 232         self.angles_z = 0;
 233         makevectors(self.angles); // new forward direction!
 234
 235         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 236         {
 237                 float upspeed, accelfactor;
 238
 239                 myspeed = self.velocity * v_forward;
 240                 upspeed = self.velocity * v_up;
 241
 242                 // responsiveness factor for steering and acceleration
 243                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 244                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 245
 246                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 247                         steerfactor = -myspeed * g_bugrigs_steer;
 248                 else
 249                         steerfactor = -myspeed * f * g_bugrigs_steer;
 250
 251                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 252                         accelfactor = g_bugrigs_accel;
 253                 else
 254                         accelfactor = f * g_bugrigs_accel;
 255                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 256
 257                 if(accel < 0)
 258                 {
 259                         if(myspeed > 0)
 260                         {
 261                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 262                         }
 263                         else
 264                         {
 265                                 if(!g_bugrigs_reverse_speeding)
 266                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 267                         }
 268                 }
 269                 else
 270                 {
 271                         if(myspeed >= 0)
 272                         {
 273                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 274                         }
 275                         else
 276                         {
 277                                 if(g_bugrigs_reverse_stopping)
 278                                         myspeed = 0;
 279                                 else
 280                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 281                         }
 282                 }
 283                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 284                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 285
 286                 self.angles_y += steer * frametime * steerfactor; // apply steering
 287                 makevectors(self.angles); // new forward direction!
 288
 289                 myspeed += accel * accelfactor * frametime;
 290
 291                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 292         }
 293         else
 294         {
 295                 myspeed = vlen(self.velocity);
 296
 297                 // responsiveness factor for steering and acceleration
 298                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 299                 steerfactor = -myspeed * f;
 300                 self.angles_y += steer * frametime * steerfactor; // apply steering
 301
 302                 rigvel = self.velocity;
 303                 makevectors(self.angles); // new forward direction!
 304         }
 305
 306         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
 307         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 308         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 309         //MAXIMA: solve(total_acceleration(v) = 0, v);
 310
 311         if(g_bugrigs_planar_movement)
 312         {
 313                 vector rigvel_xy, neworigin, up;
 314                 float mt;
 315
 316                 rigvel_z -= frametime * autocvar_sv_gravity; // 4x gravity plays better
 317                 rigvel_xy = vec2(rigvel);
 318
 319                 if(g_bugrigs_planar_movement_car_jumping)
 320                         mt = MOVE_NORMAL;
 321                 else
 322                         mt = MOVE_NOMONSTERS;
 323
 324                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 325                 up = trace_endpos - self.origin;
 326
 327                 // BUG RIGS: align the move to the surface instead of doing collision testing
 328                 // can we move?
 329                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 330
 331                 // align to surface
 332                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 333
 334                 if(trace_fraction < 0.5)
 335                 {
 336                         trace_fraction = 1;
 337                         neworigin = self.origin;
 338                 }
 339                 else
 340                         neworigin = trace_endpos;
 341
 342                 if(trace_fraction < 1)
 343                 {
 344                         // now set angles_x so that the car points parallel to the surface
 345                         self.angles = vectoangles(
 346                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 347                                         +
 348                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 349                                         +
 350                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 351                                         );
 352                         self.flags |= FL_ONGROUND;
 353                 }
 354                 else
 355                 {
 356                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 357                         self.flags &= ~FL_ONGROUND;
 358                 }
 359
 360                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 361                 self.movetype = MOVETYPE_NOCLIP;
 362         }
 363         else
 364         {
 365                 rigvel_z -= frametime * autocvar_sv_gravity; // 4x gravity plays better
 366                 self.velocity = rigvel;
 367                 self.movetype = MOVETYPE_FLY;
 368         }
 369
 370         trace_fraction = 1;
 371         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 372         if(trace_fraction != 1)
 373         {
 374                 self.angles = vectoangles2(
 375                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 376                                 +
 377                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 378                                 +
 379                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 380                                 trace_plane_normal
 381                                 );
 382         }
 383         else
 384         {
 385                 vector vel_local;
 386
 387                 vel_local_x = v_forward * self.velocity;
 388                 vel_local_y = v_right * self.velocity;
 389                 vel_local_z = v_up * self.velocity;
 390
 391                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 392                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 393         }
 394
 395         // smooth the angles
 396         vector vf1, vu1, smoothangles;
 397         makevectors(self.angles);
 398         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 399         if(f == 0)
 400                 f = 1;
 401         vf1 = v_forward * f;
 402         vu1 = v_up * f;
 403         makevectors(angles_save);
 404         vf1 = vf1 + v_forward * (1 - f);
 405         vu1 = vu1 + v_up * (1 - f);
 406         smoothangles = vectoangles2(vf1, vu1);
 407         self.angles_x = -smoothangles_x;
 408         self.angles_z =  smoothangles_z;
 409 }
 410
 411 float IsMoveInDirection(vector mv, float angle) // key mix factor
 412 {
 413         if(mv_x == 0 && mv_y == 0)
 414                 return 0; // avoid division by zero
 415         angle -= RAD2DEG * atan2(mv_y, mv_x);
 416         angle = remainder(angle, 360) / 45;
 417         if(angle >  1)
 418                 return 0;
 419         if(angle < -1)
 420                 return 0;
 421         return 1 - fabs(angle);
 422 }
 423
 424 float GeomLerp(float a, float lerp, float b)
 425 {
 426         if(a == 0)
 427         {
 428                 if(lerp < 1)
 429                         return 0;
 430                 else
 431                         return b;
 432         }
 433         if(b == 0)
 434         {
 435                 if(lerp > 0)
 436                         return 0;
 437                 else
 438                         return a;
 439         }
 440         return a * pow(fabs(b / a), lerp);
 441 }
 442
 443 void CPM_PM_Aircontrol(vector wishdir, float wishspeed)
 444 {
 445         float zspeed, xyspeed, dot, k;
 446
 447 #if 0
 448         // this doesn't play well with analog input
 449         if(self.movement_x == 0 || self.movement_y != 0)
 450                 return; // can't control movement if not moving forward or backward
 451         k = 32;
 452 #else
 453         k = 32 * (2 * IsMoveInDirection(self.movement, 0) - 1);
 454         if(k <= 0)
 455                 return;
 456 #endif
 457
 458         k *= bound(0, wishspeed / self.stat_sv_maxairspeed, 1);
 459
 460         zspeed = self.velocity_z;
 461         self.velocity_z = 0;
 462         xyspeed = vlen(self.velocity); self.velocity = normalize(self.velocity);
 463
 464         dot = self.velocity * wishdir;
 465
 466         if(dot > 0) // we can't change direction while slowing down
 467         {
 468                 k *= pow(dot, self.stat_sv_aircontrol_power)*frametime;
 469                 xyspeed = max(0, xyspeed - self.stat_sv_aircontrol_penalty * sqrt(max(0, 1 - dot*dot)) * k/32);
 470                 k *= self.stat_sv_aircontrol;
 471                 self.velocity = normalize(self.velocity * xyspeed + wishdir * k);
 472         }
 473
 474         self.velocity = self.velocity * xyspeed;
 475         self.velocity_z = zspeed;
 476 }
 477
 478 float AdjustAirAccelQW(float accelqw, float factor)
 479 {
 480         return copysign(bound(0.000001, 1 - (1 - fabs(accelqw)) * factor, 1), accelqw);
 481 }
 482
 483 // example config for alternate speed clamping:
 484 //   sv_airaccel_qw 0.8
 485 //   sv_airaccel_sideways_friction 0
 486 //   prvm_globalset server speedclamp_mode 1
 487 //     (or 2)
 488 void PM_Accelerate(vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float stretchfactor, float sidefric, float speedlimit)
 489 {
 490         float vel_straight;
 491         float vel_z;
 492         vector vel_perpend;
 493         float step;
 494
 495         vector vel_xy;
 496         float vel_xy_current;
 497         float vel_xy_backward, vel_xy_forward;
 498         float speedclamp;
 499
 500         if(stretchfactor > 0)
 501                 speedclamp = stretchfactor;
 502         else if(accelqw < 0)
 503                 speedclamp = 1; // full clamping, no stretch
 504         else
 505                 speedclamp = -1; // no clamping
 506
 507         if(accelqw < 0)
 508                 accelqw = -accelqw;
 509
 510         if(autocvar_sv_gameplayfix_q2airaccelerate)
 511                 wishspeed0 = wishspeed;
 512
 513         vel_straight = self.velocity * wishdir;
 514         vel_z = self.velocity_z;
 515         vel_xy = vec2(self.velocity);
 516         vel_perpend = vel_xy - vel_straight * wishdir;
 517
 518         step = accel * frametime * wishspeed0;
 519
 520         vel_xy_current  = vlen(vel_xy);
 521         if(speedlimit)
 522                 accelqw = AdjustAirAccelQW(accelqw, (speedlimit - bound(wishspeed, vel_xy_current, speedlimit)) / max(1, speedlimit - wishspeed));
 523         vel_xy_forward  = vel_xy_current + bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
 524         vel_xy_backward = vel_xy_current - bound(0, wishspeed + vel_xy_current, step) * accelqw - step * (1 - accelqw);
 525         if(vel_xy_backward < 0)
 526                 vel_xy_backward = 0; // not that it REALLY occurs that this would cause wrong behaviour afterwards
 527
 528         vel_straight = vel_straight + bound(0, wishspeed - vel_straight, step) * accelqw + step * (1 - accelqw);
 529
 530         if(sidefric < 0 && (vel_perpend*vel_perpend))
 531                 // negative: only apply so much sideways friction to stay below the speed you could get by "braking"
 532         {
 533                 float f, fminimum;
 534                 f = max(0, 1 + frametime * wishspeed * sidefric);
 535                 fminimum = (vel_xy_backward*vel_xy_backward - vel_straight*vel_straight) / (vel_perpend*vel_perpend);
 536                 // this cannot be > 1
 537                 if(fminimum <= 0)
 538                         vel_perpend = vel_perpend * max(0, f);
 539                 else
 540                 {
 541                         fminimum = sqrt(fminimum);
 542                         vel_perpend = vel_perpend * max(fminimum, f);
 543                 }
 544         }
 545         else
 546                 vel_perpend = vel_perpend * max(0, 1 - frametime * wishspeed * sidefric);
 547
 548         vel_xy = vel_straight * wishdir + vel_perpend;
 549
 550         if(speedclamp >= 0)
 551         {
 552                 float vel_xy_preclamp;
 553                 vel_xy_preclamp = vlen(vel_xy);
 554                 if(vel_xy_preclamp > 0) // prevent division by zero
 555                 {
 556                         vel_xy_current += (vel_xy_forward - vel_xy_current) * speedclamp;
 557                         if(vel_xy_current < vel_xy_preclamp)
 558                                 vel_xy = vel_xy * (vel_xy_current / vel_xy_preclamp);
 559                 }
 560         }
 561
 562         self.velocity = vel_xy + vel_z * '0 0 1';
 563 }
 564
 565 void PM_AirAccelerate(vector wishdir, float wishspeed)
 566 {
 567         vector curvel, wishvel, acceldir, curdir;
 568         float addspeed, accelspeed, curspeed, f;
 569         float dot;
 570
 571         if(wishspeed == 0)
 572                 return;
 573
 574         curvel = self.velocity;
 575         curvel_z = 0;
 576         curspeed = vlen(curvel);
 577
 578         if(wishspeed > curspeed * 1.01)
 579         {
 580                 wishspeed = min(wishspeed, curspeed + self.stat_sv_warsowbunny_airforwardaccel * self.stat_sv_maxspeed * frametime);
 581         }
 582         else
 583         {
 584                 f = max(0, (self.stat_sv_warsowbunny_topspeed - curspeed) / (self.stat_sv_warsowbunny_topspeed - self.stat_sv_maxspeed));
 585                 wishspeed = max(curspeed, self.stat_sv_maxspeed) + self.stat_sv_warsowbunny_accel * f * self.stat_sv_maxspeed * frametime;
 586         }
 587         wishvel = wishdir * wishspeed;
 588         acceldir = wishvel - curvel;
 589         addspeed = vlen(acceldir);
 590         acceldir = normalize(acceldir);
 591
 592         accelspeed = min(addspeed, self.stat_sv_warsowbunny_turnaccel * self.stat_sv_maxspeed * frametime);
 593
 594         if(self.stat_sv_warsowbunny_backtosideratio < 1)
 595         {
 596                 curdir = normalize(curvel);
 597                 dot = acceldir * curdir;
 598                 if(dot < 0)
 599                         acceldir = acceldir - (1 - self.stat_sv_warsowbunny_backtosideratio) * dot * curdir;
 600         }
 601
 602         self.velocity += accelspeed * acceldir;
 603 }
 604
 605 .vector movement_old;
 606 .float buttons_old;
 607 .vector v_angle_old;
 608 .string lastclassname;
 609
 610 .float() PlayerPhysplug;
 611
 612 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 613 .float specialcommand_pos;
 614 void SpecialCommand()
 615 {
 616 #ifdef TETRIS
 617         TetrisImpulse();
 618 #else
 619         if(!CheatImpulse(99))
 620                 print("A hollow voice says \"Plugh\".\n");
 621 #endif
 622 }
 623
 624 float speedaward_speed;
 625 string speedaward_holder;
 626 string speedaward_uid;
 627 void race_send_speedaward(float msg)
 628 {
 629         // send the best speed of the round
 630         WriteByte(msg, SVC_TEMPENTITY);
 631         WriteByte(msg, TE_CSQC_RACE);
 632         WriteByte(msg, RACE_NET_SPEED_AWARD);
 633         WriteInt24_t(msg, floor(speedaward_speed+0.5));
 634         WriteString(msg, speedaward_holder);
 635 }
 636
 637 float speedaward_alltimebest;
 638 string speedaward_alltimebest_holder;
 639 string speedaward_alltimebest_uid;
 640 void race_send_speedaward_alltimebest(float msg)
 641 {
 642         // send the best speed
 643         WriteByte(msg, SVC_TEMPENTITY);
 644         WriteByte(msg, TE_CSQC_RACE);
 645         WriteByte(msg, RACE_NET_SPEED_AWARD_BEST);
 646         WriteInt24_t(msg, floor(speedaward_alltimebest+0.5));
 647         WriteString(msg, speedaward_alltimebest_holder);
 648 }
 649
 650 string GetMapname(void);
 651 float speedaward_lastupdate;
 652 float speedaward_lastsent;
 653 void SV_PlayerPhysics()
 654 {
 655         vector wishvel, wishdir, v;
 656         float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, buttons;
 657         string temps;
 658         float buttons_prev;
 659         float not_allowed_to_move;
 660         string c;
 661
 662         WarpZone_PlayerPhysics_FixVAngle();
 663
 664         maxspd_mod = 1;
 665         if(self.ballcarried)
 666                 if(g_keepaway)
 667                         maxspd_mod *= autocvar_g_keepaway_ballcarrier_highspeed;
 668
 669         maxspd_mod *= autocvar_g_movement_highspeed;
 670
 671         // fix physics stats for g_movement_highspeed
 672         // TODO maybe rather use maxairspeed? needs testing
 673         self.stat_sv_airaccel_qw = AdjustAirAccelQW(Physics_ClientOption(self, "airaccel_qw"), maxspd_mod);
 674         if(Physics_ClientOption(self, "airstrafeaccel_qw"))
 675                 self.stat_sv_airstrafeaccel_qw = AdjustAirAccelQW(Physics_ClientOption(self, "airstrafeaccel_qw"), maxspd_mod);
 676         else
 677                 self.stat_sv_airstrafeaccel_qw = 0;
 678         self.stat_sv_airspeedlimit_nonqw = Physics_ClientOption(self, "airspeedlimit_nonqw") * maxspd_mod;
 679         self.stat_sv_maxspeed = Physics_ClientOption(self, "maxspeed") * maxspd_mod; // also slow walking
 680
 681         // fix some new settings
 682         self.stat_sv_airaccel_qw_stretchfactor = Physics_ClientOption(self, "airaccel_qw_stretchfactor");
 683         self.stat_sv_maxairstrafespeed = Physics_ClientOption(self, "maxairstrafespeed");
 684         self.stat_sv_maxairspeed = Physics_ClientOption(self, "maxairspeed");
 685         self.stat_sv_airstrafeaccelerate = Physics_ClientOption(self, "airstrafeaccelerate");
 686         self.stat_sv_warsowbunny_turnaccel = Physics_ClientOption(self, "warsowbunny_turnaccel");
 687         self.stat_sv_airaccel_sideways_friction = Physics_ClientOption(self, "airaccel_sideways_friction");
 688         self.stat_sv_aircontrol = Physics_ClientOption(self, "aircontrol");
 689         self.stat_sv_aircontrol_power = Physics_ClientOption(self, "aircontrol_power");
 690         self.stat_sv_aircontrol_penalty = Physics_ClientOption(self, "aircontrol_penalty");
 691         self.stat_sv_warsowbunny_airforwardaccel = Physics_ClientOption(self, "warsowbunny_airforwardaccel");
 692         self.stat_sv_warsowbunny_topspeed = Physics_ClientOption(self, "warsowbunny_topspeed");
 693         self.stat_sv_warsowbunny_accel = Physics_ClientOption(self, "warsowbunny_accel");
 694         self.stat_sv_warsowbunny_backtosideratio = Physics_ClientOption(self, "warsowbunny_backtosideratio");
 695         self.stat_sv_friction = Physics_ClientOption(self, "friction");
 696         self.stat_sv_accelerate = Physics_ClientOption(self, "accelerate");
 697         self.stat_sv_stopspeed = Physics_ClientOption(self, "stopspeed");
 698         self.stat_sv_airaccelerate = Physics_ClientOption(self, "airaccelerate");
 699         self.stat_sv_airstopaccelerate = Physics_ClientOption(self, "airstopaccelerate");
 700         self.stat_sv_jumpvelocity = Physics_ClientOption(self, "jumpvelocity");
 701
 702     if(self.PlayerPhysplug)
 703         if(self.PlayerPhysplug())
 704             return;
 705
 706         self.race_movetime_frac += frametime;
 707         f = floor(self.race_movetime_frac);
 708         self.race_movetime_frac -= f;
 709         self.race_movetime_count += f;
 710         self.race_movetime = self.race_movetime_frac + self.race_movetime_count;
 711
 712         anticheat_physics();
 713
 714         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE + 128 * (self.movement_x < 0) + 256 * (self.movement_x > 0) + 512 * (self.movement_y < 0) + 1024 * (self.movement_y > 0);
 715
 716         if(!buttons)
 717                 c = "x";
 718         else if(buttons == 1)
 719                 c = "1";
 720         else if(buttons == 2)
 721                 c = " ";
 722         else if(buttons == 128)
 723                 c = "s";
 724         else if(buttons == 256)
 725                 c = "w";
 726         else if(buttons == 512)
 727                 c = "a";
 728         else if(buttons == 1024)
 729                 c = "d";
 730         else
 731                 c = "?";
 732
 733         if(c == substring(specialcommand, self.specialcommand_pos, 1))
 734         {
 735                 self.specialcommand_pos += 1;
 736                 if(self.specialcommand_pos >= strlen(specialcommand))
 737                 {
 738                         self.specialcommand_pos = 0;
 739                         SpecialCommand();
 740                         return;
 741                 }
 742         }
 743         else if(self.specialcommand_pos && (c != substring(specialcommand, self.specialcommand_pos - 1, 1)))
 744                 self.specialcommand_pos = 0;
 745
 746         if(sv_maxidle > 0)
 747         {
 748                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 749                         self.parm_idlesince = time;
 750         }
 751         buttons_prev = self.buttons_old;
 752         self.buttons_old = buttons;
 753         self.movement_old = self.movement;
 754         self.v_angle_old = self.v_angle;
 755
 756         if(time < self.nickspamtime)
 757         if(self.nickspamcount >= autocvar_g_nick_flood_penalty_yellow)
 758         {
 759                 // slight annoyance for nick change scripts
 760                 self.movement = -1 * self.movement;
 761                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = self.BUTTON_ZOOM = self.BUTTON_CROUCH = self.BUTTON_HOOK = self.BUTTON_USE = 0;
 762
 763                 if(self.nickspamcount >= autocvar_g_nick_flood_penalty_red) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 764                 {
 765                         self.angles_x = random() * 360;
 766                         self.angles_y = random() * 360;
 767                         // at least I'm not forcing retardedview by also assigning to angles_z
 768                         self.fixangle = TRUE;
 769                 }
 770         }
 771
 772         if (self.punchangle != '0 0 0')
 773         {
 774                 f = vlen(self.punchangle) - 10 * frametime;
 775                 if (f > 0)
 776                         self.punchangle = normalize(self.punchangle) * f;
 777                 else
 778                         self.punchangle = '0 0 0';
 779         }
 780
 781         if (self.punchvector != '0 0 0')
 782         {
 783                 f = vlen(self.punchvector) - 30 * frametime;
 784                 if (f > 0)
 785                         self.punchvector = normalize(self.punchvector) * f;
 786                 else
 787                         self.punchvector = '0 0 0';
 788         }
 789
 790         if (IS_BOT_CLIENT(self))
 791         {
 792                 if(playerdemo_read())
 793                         return;
 794                 bot_think();
 795         }
 796
 797         self.items &= ~IT_USING_JETPACK;
 798
 799         if(IS_PLAYER(self))
 800         {
 801                 if(self.race_penalty)
 802                         if(time > self.race_penalty)
 803                                 self.race_penalty = 0;
 804
 805                 not_allowed_to_move = 0;
 806                 if(self.race_penalty)
 807                         not_allowed_to_move = 1;
 808                 if(!autocvar_sv_ready_restart_after_countdown)
 809                 if(time < game_starttime)
 810                         not_allowed_to_move = 1;
 811
 812                 if(not_allowed_to_move)
 813                 {
 814                         self.velocity = '0 0 0';
 815                         self.movetype = MOVETYPE_NONE;
 816                         self.disableclientprediction = 2;
 817                 }
 818                 else if(self.disableclientprediction == 2)
 819                 {
 820                         if(self.movetype == MOVETYPE_NONE)
 821                                 self.movetype = MOVETYPE_WALK;
 822                         self.disableclientprediction = 0;
 823                 }
 824         }
 825
 826         if (self.movetype == MOVETYPE_NONE)
 827                 return;
 828
 829         // when we get here, disableclientprediction cannot be 2
 830         self.disableclientprediction = 0;
 831         if(time < self.ladder_time)
 832                 self.disableclientprediction = 1;
 833
 834         if(time < self.spider_slowness)
 835         {
 836                 self.stat_sv_maxspeed *= 0.5; // half speed while slow from spider
 837                 self.stat_sv_airspeedlimit_nonqw *= 0.5;
 838         }
 839
 840         if(self.frozen)
 841         {
 842                 if(autocvar_sv_dodging_frozen && IS_REAL_CLIENT(self))
 843                 {
 844                         self.movement_x = bound(-5, self.movement_x, 5);
 845                         self.movement_y = bound(-5, self.movement_y, 5);
 846                         self.movement_z = bound(-5, self.movement_z, 5);
 847                 }
 848                 else
 849                         self.movement = '0 0 0';
 850                 self.disableclientprediction = 1;
 851
 852                 vector midpoint = ((self.absmin + self.absmax) * 0.5);
 853                 if(pointcontents(midpoint) == CONTENT_WATER)
 854                 {
 855                         self.velocity = self.velocity * 0.5;
 856
 857                         if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 858                                 { self.velocity_z = 200; }
 859                 }
 860         }
 861
 862         MUTATOR_CALLHOOK(PlayerPhysics);
 863
 864         if(self.player_blocked)
 865         {
 866                 self.movement = '0 0 0';
 867                 self.disableclientprediction = 1;
 868         }
 869
 870         maxspd_mod = 1;
 871
 872         swampspd_mod = 1;
 873         if(self.in_swamp) {
 874                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 875         }
 876
 877         // conveyors: first fix velocity
 878         if(self.conveyor.state)
 879                 self.velocity -= self.conveyor.movedir;
 880
 881         if (!IS_PLAYER(self))
 882         {
 883                 maxspd_mod = autocvar_sv_spectator_speed_multiplier;
 884                 if(!self.spectatorspeed)
 885                         self.spectatorspeed = maxspd_mod;
 886                 if(self.impulse && self.impulse <= 19 || (self.impulse >= 200 && self.impulse <= 209) || (self.impulse >= 220 && self.impulse <= 229))
 887                 {
 888                         if(self.lastclassname != "player")
 889                         {
 890                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209))
 891                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 892                                 else if(self.impulse == 11)
 893                                         self.spectatorspeed = maxspd_mod;
 894                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229))
 895                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 896                                 else if(self.impulse >= 1 && self.impulse <= 9)
 897                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 898                         } // otherwise just clear
 899                         self.impulse = 0;
 900                 }
 901                 maxspd_mod = self.spectatorspeed;
 902         }
 903
 904         spd = max(self.stat_sv_maxspeed, self.stat_sv_maxairspeed) * maxspd_mod * swampspd_mod;
 905         if(self.speed != spd)
 906         {
 907                 self.speed = spd;
 908                 temps = ftos(spd);
 909                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 910                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 911                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 912                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 913         }
 914
 915         maxspd_mod *= swampspd_mod; // only one common speed modder please!
 916         swampspd_mod = 1;
 917
 918         // if dead, behave differently
 919         if (self.deadflag)
 920                 goto end;
 921
 922         if (!self.fixangle && !g_bugrigs)
 923         {
 924                 self.angles_x = 0;
 925                 self.angles_y = self.v_angle_y;
 926                 self.angles_z = 0;
 927         }
 928
 929         if(self.flags & FL_ONGROUND)
 930         if(IS_PLAYER(self)) // no fall sounds for observers thank you very much
 931         if(self.wasFlying)
 932         {
 933                 self.wasFlying = 0;
 934
 935                 if(self.waterlevel < WATERLEVEL_SWIMMING)
 936                 if(time >= self.ladder_time)
 937                 if (!self.hook)
 938                 {
 939                         self.nextstep = time + 0.3 + random() * 0.1;
 940                         trace_dphitq3surfaceflags = 0;
 941                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 942                         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS))
 943                         {
 944                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 945                                         GlobalSound(globalsound_metalfall, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 946                                 else
 947                                         GlobalSound(globalsound_fall, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 948                         }
 949                 }
 950         }
 951
 952         if(IsFlying(self))
 953                 self.wasFlying = 1;
 954
 955         if(IS_PLAYER(self))
 956                 CheckPlayerJump();
 957
 958         if (self.flags & FL_WATERJUMP )
 959         {
 960                 self.velocity_x = self.movedir_x;
 961                 self.velocity_y = self.movedir_y;
 962                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
 963                 {
 964                         self.flags &= ~FL_WATERJUMP;
 965                         self.teleport_time = 0;
 966                 }
 967         }
 968         else if (g_bugrigs && IS_PLAYER(self))
 969         {
 970                 RaceCarPhysics();
 971         }
 972         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY || self.movetype == MOVETYPE_FLY_WORLDONLY)
 973         {
 974                 // noclipping or flying
 975                 self.flags &= ~FL_ONGROUND;
 976
 977                 self.velocity = self.velocity * (1 - frametime * self.stat_sv_friction);
 978                 makevectors(self.v_angle);
 979                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 980                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 981                 // acceleration
 982                 wishdir = normalize(wishvel);
 983                 wishspeed = vlen(wishvel);
 984                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
 985                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
 986                 if (time >= self.teleport_time)
 987                         PM_Accelerate(wishdir, wishspeed, wishspeed, self.stat_sv_accelerate*maxspd_mod, 1, 0, 0, 0);
 988         }
 989         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
 990         {
 991                 // swimming
 992                 self.flags &= ~FL_ONGROUND;
 993
 994                 makevectors(self.v_angle);
 995                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 996                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 997                 if (wishvel == '0 0 0')
 998                         wishvel = '0 0 -60'; // drift towards bottom
 999
1000                 wishdir = normalize(wishvel);
1001                 wishspeed = vlen(wishvel);
1002                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1003                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1004                 wishspeed = wishspeed * 0.7;
1005
1006                 // water friction
1007                 self.velocity = self.velocity * (1 - frametime * self.stat_sv_friction);
1008
1009                 // water acceleration
1010                 PM_Accelerate(wishdir, wishspeed, wishspeed, self.stat_sv_accelerate*maxspd_mod, 1, 0, 0, 0);
1011         }
1012         else if (time < self.ladder_time)
1013         {
1014                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
1015                 self.flags &= ~FL_ONGROUND;
1016
1017                 float g;
1018                 g = autocvar_sv_gravity * frametime;
1019                 if(self.gravity)
1020                         g *= self.gravity;
1021                 if(autocvar_sv_gameplayfix_gravityunaffectedbyticrate)
1022                 {
1023                         g *= 0.5;
1024                         self.velocity_z += g;
1025                 }
1026
1027                 self.velocity = self.velocity * (1 - frametime * self.stat_sv_friction);
1028                 makevectors(self.v_angle);
1029                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
1030                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
1031                 self.velocity_z += g;
1032                 if (self.ladder_entity.classname == "func_water")
1033                 {
1034                         f = vlen(wishvel);
1035                         if (f > self.ladder_entity.speed)
1036                                 wishvel = wishvel * (self.ladder_entity.speed / f);
1037
1038                         self.watertype = self.ladder_entity.skin;
1039                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
1040                         if ((self.origin_z + self.view_ofs_z) < f)
1041                                 self.waterlevel = WATERLEVEL_SUBMERGED;
1042                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
1043                                 self.waterlevel = WATERLEVEL_SWIMMING;
1044                         else if ((self.origin_z + self.mins_z + 1) < f)
1045                                 self.waterlevel = WATERLEVEL_WETFEET;
1046                         else
1047                         {
1048                                 self.waterlevel = WATERLEVEL_NONE;
1049                                 self.watertype = CONTENT_EMPTY;
1050                         }
1051                 }
1052                 // acceleration
1053                 wishdir = normalize(wishvel);
1054                 wishspeed = vlen(wishvel);
1055                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1056                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1057                 if (time >= self.teleport_time)
1058                 {
1059                         // water acceleration
1060                         PM_Accelerate(wishdir, wishspeed, wishspeed, self.stat_sv_accelerate*maxspd_mod, 1, 0, 0, 0);
1061                 }
1062         }
1063         else if ((self.items & IT_JETPACK) && self.BUTTON_HOOK && (!autocvar_g_jetpack_fuel || self.ammo_fuel >= 0.01 || self.items & IT_UNLIMITED_WEAPON_AMMO) && !self.frozen)
1064         {
1065                 //makevectors(self.v_angle_y * '0 1 0');
1066                 makevectors(self.v_angle);
1067                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1068                 // add remaining speed as Z component
1069                 maxairspd = self.stat_sv_maxairspeed*max(1, maxspd_mod);
1070                 // fix speedhacks :P
1071                 wishvel = normalize(wishvel) * min(vlen(wishvel) / maxairspd, 1);
1072                 // add the unused velocity as up component
1073                 wishvel_z = 0;
1074
1075                 // if(self.BUTTON_JUMP)
1076                         wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
1077
1078                 // it is now normalized, so...
1079                 float a_side, a_up, a_add, a_diff;
1080                 a_side = autocvar_g_jetpack_acceleration_side;
1081                 a_up = autocvar_g_jetpack_acceleration_up;
1082                 a_add = autocvar_g_jetpack_antigravity * autocvar_sv_gravity;
1083
1084                 wishvel_x *= a_side;
1085                 wishvel_y *= a_side;
1086                 wishvel_z *= a_up;
1087                 wishvel_z += a_add;
1088
1089                 float best;
1090                 best = 0;
1091                 //////////////////////////////////////////////////////////////////////////////////////
1092                 // finding the maximum over all vectors of above form
1093                 // with wishvel having an absolute value of 1
1094                 //////////////////////////////////////////////////////////////////////////////////////
1095                 // we're finding the maximum over
1096                 //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
1097                 // for z in the range from -1 to 1
1098                 //////////////////////////////////////////////////////////////////////////////////////
1099                 // maximum is EITHER attained at the single extreme point:
1100                 a_diff = a_side * a_side - a_up * a_up;
1101                 if(a_diff != 0)
1102                 {
1103                         f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
1104                         if(f > -1 && f < 1) // can it be attained?
1105                         {
1106                                 best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
1107                                 //print("middle\n");
1108                         }
1109                 }
1110                 // OR attained at z = 1:
1111                 f = (a_up + a_add) * (a_up + a_add);
1112                 if(f > best)
1113                 {
1114                         best = f;
1115                         //print("top\n");
1116                 }
1117                 // OR attained at z = -1:
1118                 f = (a_up - a_add) * (a_up - a_add);
1119                 if(f > best)
1120                 {
1121                         best = f;
1122                         //print("bottom\n");
1123                 }
1124                 best = sqrt(best);
1125                 //////////////////////////////////////////////////////////////////////////////////////
1126
1127                 //print("best possible acceleration: ", ftos(best), "\n");
1128
1129                 float fxy, fz;
1130                 fxy = bound(0, 1 - (self.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / autocvar_g_jetpack_maxspeed_side, 1);
1131                 if(wishvel_z - autocvar_sv_gravity > 0)
1132                         fz = bound(0, 1 - self.velocity_z / autocvar_g_jetpack_maxspeed_up, 1);
1133                 else
1134                         fz = bound(0, 1 + self.velocity_z / autocvar_g_jetpack_maxspeed_up, 1);
1135
1136                 float fvel;
1137                 fvel = vlen(wishvel);
1138                 wishvel_x *= fxy;
1139                 wishvel_y *= fxy;
1140                 wishvel_z = (wishvel_z - autocvar_sv_gravity) * fz + autocvar_sv_gravity;
1141
1142                 fvel = min(1, vlen(wishvel) / best);
1143                 if(autocvar_g_jetpack_fuel && !(self.items & IT_UNLIMITED_WEAPON_AMMO))
1144                         f = min(1, self.ammo_fuel / (autocvar_g_jetpack_fuel * frametime * fvel));
1145                 else
1146                         f = 1;
1147
1148                 //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
1149
1150                 if (f > 0 && wishvel != '0 0 0')
1151                 {
1152                         self.velocity = self.velocity + wishvel * f * frametime;
1153                         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1154                                 self.ammo_fuel -= autocvar_g_jetpack_fuel * frametime * fvel * f;
1155                         self.flags &= ~FL_ONGROUND;
1156                         self.items |= IT_USING_JETPACK;
1157
1158                         // jetpack also inhibits health regeneration, but only for 1 second
1159                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
1160                 }
1161         }
1162         else if (self.flags & FL_ONGROUND)
1163         {
1164                 // we get here if we ran out of ammo
1165                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32) && self.ammo_fuel < 0.01)
1166                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1167
1168                 // walking
1169                 makevectors(self.v_angle_y * '0 1 0');
1170                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1171
1172                 if(!(self.lastflags & FL_ONGROUND))
1173                 {
1174                         if(autocvar_speedmeter)
1175                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
1176                         if(self.lastground < time - 0.3)
1177                                 self.velocity = self.velocity * (1 - autocvar_sv_friction_on_land);
1178                         if(self.jumppadcount > 1)
1179                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
1180                         self.jumppadcount = 0;
1181                 }
1182
1183 #ifdef LETS_TEST_FTEQCC
1184                 if(self.velocity_x || self.velocity_y)
1185                 {
1186                         // good
1187                 }
1188                 else
1189                 {
1190                         if(self.velocity_x)
1191                                 checkclient();
1192                         if(self.velocity_y)
1193                                 checkclient();
1194                 }
1195 #endif
1196
1197                 v = self.velocity;
1198                 v_z = 0;
1199                 f = vlen(v);
1200                 if(f > 0)
1201                 {
1202                         if (f < self.stat_sv_stopspeed)
1203                                 f = 1 - frametime * (self.stat_sv_stopspeed / f) * self.stat_sv_friction;
1204                         else
1205                                 f = 1 - frametime * self.stat_sv_friction;
1206                         if (f > 0)
1207                                 self.velocity = self.velocity * f;
1208                         else
1209                                 self.velocity = '0 0 0';
1210                         /*
1211                            Mathematical analysis time!
1212
1213                            Our goal is to invert this mess.
1214
1215                            For the two cases we get:
1216                                 v = v0 * (1 - frametime * (autocvar_sv_stopspeed / v0) * autocvar_sv_friction)
1217                                   = v0 - frametime * autocvar_sv_stopspeed * autocvar_sv_friction
1218                                 v0 = v + frametime * autocvar_sv_stopspeed * autocvar_sv_friction
1219                            and
1220                                 v = v0 * (1 - frametime * autocvar_sv_friction)
1221                                 v0 = v / (1 - frametime * autocvar_sv_friction)
1222
1223                            These cases would be chosen ONLY if:
1224                                 v0 < autocvar_sv_stopspeed
1225                                 v + frametime * autocvar_sv_stopspeed * autocvar_sv_friction < autocvar_sv_stopspeed
1226                                 v < autocvar_sv_stopspeed * (1 - frametime * autocvar_sv_friction)
1227                            and, respectively:
1228                                 v0 >= autocvar_sv_stopspeed
1229                                 v / (1 - frametime * autocvar_sv_friction) >= autocvar_sv_stopspeed
1230                                 v >= autocvar_sv_stopspeed * (1 - frametime * autocvar_sv_friction)
1231                          */
1232                 }
1233
1234                 // acceleration
1235                 wishdir = normalize(wishvel);
1236                 wishspeed = vlen(wishvel);
1237                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1238                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1239                 if (self.crouch)
1240                         wishspeed = wishspeed * 0.5;
1241                 if (time >= self.teleport_time)
1242                         PM_Accelerate(wishdir, wishspeed, wishspeed, self.stat_sv_accelerate*maxspd_mod, 1, 0, 0, 0);
1243         }
1244         else
1245         {
1246                 float wishspeed0;
1247                 // we get here if we ran out of ammo
1248                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32) && self.ammo_fuel < 0.01)
1249                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1250
1251                 if(maxspd_mod < 1)
1252                 {
1253                         maxairspd = self.stat_sv_maxairspeed*maxspd_mod;
1254                         airaccel = self.stat_sv_airaccelerate*maxspd_mod;
1255                 }
1256                 else
1257                 {
1258                         maxairspd = self.stat_sv_maxairspeed;
1259                         airaccel = self.stat_sv_airaccelerate;
1260                 }
1261                 // airborn
1262                 makevectors(self.v_angle_y * '0 1 0');
1263                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1264                 // acceleration
1265                 wishdir = normalize(wishvel);
1266                 wishspeed = wishspeed0 = vlen(wishvel);
1267                 if (wishspeed0 > self.stat_sv_maxspeed*maxspd_mod)
1268                         wishspeed0 = self.stat_sv_maxspeed*maxspd_mod;
1269                 if (wishspeed > maxairspd)
1270                         wishspeed = maxairspd;
1271                 if (self.crouch)
1272                         wishspeed = wishspeed * 0.5;
1273                 if (time >= self.teleport_time)
1274                 {
1275                         float accelerating;
1276                         float wishspeed2;
1277                         float airaccelqw;
1278                         float strafity;
1279
1280                         airaccelqw = self.stat_sv_airaccel_qw;
1281                         accelerating = (self.velocity * wishdir > 0);
1282                         wishspeed2 = wishspeed;
1283
1284                         // CPM
1285                         if(self.stat_sv_airstopaccelerate)
1286                         {
1287                                 vector curdir;
1288                                 curdir = self.velocity;
1289                                 curdir_z = 0;
1290                                 curdir = normalize(curdir);
1291                                 airaccel = airaccel + (self.stat_sv_airstopaccelerate*maxspd_mod - airaccel) * max(0, -(curdir * wishdir));
1292                         }
1293                         // note that for straight forward jumping:
1294                         // step = accel * frametime * wishspeed0;
1295                         // accel  = bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
1296                         // -->
1297                         // dv/dt = accel * maxspeed (when slow)
1298                         // dv/dt = accel * maxspeed * (1 - accelqw) (when fast)
1299                         // log dv/dt = logaccel + logmaxspeed (when slow)
1300                         // log dv/dt = logaccel + logmaxspeed + log(1 - accelqw) (when fast)
1301                         strafity = IsMoveInDirection(self.movement, -90) + IsMoveInDirection(self.movement, +90); // if one is nonzero, other is always zero
1302                         if(self.stat_sv_maxairstrafespeed)
1303                                 wishspeed = min(wishspeed, GeomLerp(self.stat_sv_maxairspeed*maxspd_mod, strafity, self.stat_sv_maxairstrafespeed*maxspd_mod));
1304                         if(self.stat_sv_airstrafeaccelerate)
1305                                 airaccel = GeomLerp(airaccel, strafity, self.stat_sv_airstrafeaccelerate*maxspd_mod);
1306                         if(self.stat_sv_airstrafeaccel_qw)
1307                                 airaccelqw = copysign(1-GeomLerp(1-fabs(self.stat_sv_airaccel_qw), strafity, 1-fabs(self.stat_sv_airstrafeaccel_qw)), ((strafity > 0.5) ? self.stat_sv_airstrafeaccel_qw : self.stat_sv_airaccel_qw));
1308                         // !CPM
1309
1310                         if(self.stat_sv_warsowbunny_turnaccel && accelerating && self.movement_y == 0 && self.movement_x != 0)
1311                                 PM_AirAccelerate(wishdir, wishspeed);
1312                         else
1313                                 PM_Accelerate(wishdir, wishspeed, wishspeed0, airaccel, airaccelqw, self.stat_sv_airaccel_qw_stretchfactor, self.stat_sv_airaccel_sideways_friction / maxairspd, self.stat_sv_airspeedlimit_nonqw);
1314
1315                         if(self.stat_sv_aircontrol)
1316                                 CPM_PM_Aircontrol(wishdir, wishspeed2);
1317                 }
1318         }
1319
1320         if((g_cts || g_race) && !IS_OBSERVER(self))
1321         {
1322                 if(vlen(self.velocity - self.velocity_z * '0 0 1') > speedaward_speed)
1323                 {
1324                         speedaward_speed = vlen(self.velocity - self.velocity_z * '0 0 1');
1325                         speedaward_holder = self.netname;
1326                         speedaward_uid = self.crypto_idfp;
1327                         speedaward_lastupdate = time;
1328                 }
1329                 if(speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1)
1330                 {
1331                         string rr = (g_cts) ? CTS_RECORD : RACE_RECORD;
1332                         race_send_speedaward(MSG_ALL);
1333                         speedaward_lastsent = speedaward_speed;
1334                         if (speedaward_speed > speedaward_alltimebest && speedaward_uid != "")
1335                         {
1336                                 speedaward_alltimebest = speedaward_speed;
1337                                 speedaward_alltimebest_holder = speedaward_holder;
1338                                 speedaward_alltimebest_uid = speedaward_uid;
1339                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
1340                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp"), speedaward_alltimebest_uid);
1341                                 race_send_speedaward_alltimebest(MSG_ALL);
1342                         }
1343                 }
1344         }
1345
1346         float xyspeed;
1347         xyspeed = vlen('1 0 0' * self.velocity_x + '0 1 0' * self.velocity_y);
1348         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge && autocvar_g_balance_nex_charge_velocity_rate && xyspeed > autocvar_g_balance_nex_charge_minspeed)
1349         {
1350                 // add a maximum of charge_velocity_rate when going fast (f = 1), gradually increasing from minspeed (f = 0) to maxspeed
1351                 xyspeed = min(xyspeed, autocvar_g_balance_nex_charge_maxspeed);
1352                 f = (xyspeed - autocvar_g_balance_nex_charge_minspeed) / (autocvar_g_balance_nex_charge_maxspeed - autocvar_g_balance_nex_charge_minspeed);
1353                 // add the extra charge
1354                 self.nex_charge = min(1, self.nex_charge + autocvar_g_balance_nex_charge_velocity_rate * f * frametime);
1355         }
1356 :end
1357         if(self.flags & FL_ONGROUND)
1358                 self.lastground = time;
1359
1360         // conveyors: then break velocity again
1361         if(self.conveyor.state)
1362                 self.velocity += self.conveyor.movedir;
1363
1364         self.lastflags = self.flags;
1365         self.lastclassname = self.classname;
1366 }