qcsrc/server/cl_client.qc

   1 void send_CSQC_teamnagger() {
   2         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   3         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   4 }
   5
   6 float ClientData_Send(entity to, float sf)
   7 {
   8         if(to != self.owner)
   9         {
  10                 error("wtf");
  11                 return FALSE;
  12         }
  13
  14         entity e;
  15
  16         e = to;
  17         if(IS_SPEC(to))
  18                 e = to.enemy;
  19
  20         sf = 0;
  21
  22         if(e.race_completed)
  23                 sf |= 1; // forced scoreboard
  24         if(to.spectatee_status)
  25                 sf |= 2; // spectator ent number follows
  26         if(e.zoomstate)
  27                 sf |= 4; // zoomed
  28         if(e.porto_v_angle_held)
  29                 sf |= 8; // angles held
  30
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  32         WriteByte(MSG_ENTITY, sf);
  33
  34         if(sf & 2)
  35                 WriteByte(MSG_ENTITY, to.spectatee_status);
  36
  37         if(sf & 8)
  38         {
  39                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  40                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  41         }
  42
  43         return TRUE;
  44 }
  45
  46 void ClientData_Attach()
  47 {
  48         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  49         self.clientdata.drawonlytoclient = self;
  50         self.clientdata.owner = self;
  51 }
  52
  53 void ClientData_Detach()
  54 {
  55         remove(self.clientdata);
  56         self.clientdata = world;
  57 }
  58
  59 void ClientData_Touch(entity e)
  60 {
  61         e.clientdata.SendFlags = 1;
  62
  63         // make it spectatable
  64         entity e2;
  65         FOR_EACH_REALCLIENT(e2)
  66         {
  67                 if(e2 != e)
  68                         if(IS_SPEC(e2))
  69                                 if(e2.enemy == e)
  70                                         e2.clientdata.SendFlags = 1;
  71         }
  72 }
  73
  74 .string netname_previous;
  75
  76
  77 /*
  78 =============
  79 CheckPlayerModel
  80
  81 Checks if the argument string can be a valid playermodel.
  82 Returns a valid one in doubt.
  83 =============
  84 */
  85 string FallbackPlayerModel;
  86 string CheckPlayerModel(string plyermodel) {
  87         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  88         {
  89                 // note: we cannot summon Don Strunzone here, some player may
  90                 // still have the model string set. In case anyone manages how
  91                 // to change a cvar default, we'll have a small leak here.
  92                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  93         }
  94         // only in right path
  95         if( substring(plyermodel,0,14) != "models/player/")
  96                 return FallbackPlayerModel;
  97         // only good file extensions
  98         if(substring(plyermodel,-4,4) != ".zym")
  99         if(substring(plyermodel,-4,4) != ".dpm")
 100         if(substring(plyermodel,-4,4) != ".iqm")
 101         if(substring(plyermodel,-4,4) != ".md3")
 102         if(substring(plyermodel,-4,4) != ".psk")
 103                 return FallbackPlayerModel;
 104         // forbid the LOD models
 105         if(substring(plyermodel, -9,5) == "_lod1")
 106                 return FallbackPlayerModel;
 107         if(substring(plyermodel, -9,5) == "_lod2")
 108                 return FallbackPlayerModel;
 109         if(plyermodel != strtolower(plyermodel))
 110                 return FallbackPlayerModel;
 111         // also, restrict to server models
 112         if(autocvar_sv_servermodelsonly)
 113         {
 114                 if(!fexists(plyermodel))
 115                         return FallbackPlayerModel;
 116         }
 117         return plyermodel;
 118 }
 119
 120 void setplayermodel(entity e, string modelname)
 121 {
 122         precache_model(modelname);
 123         setmodel(e, modelname);
 124         player_setupanimsformodel();
 125         UpdatePlayerSounds();
 126 }
 127
 128 /*
 129 =============
 130 PutObserverInServer
 131
 132 putting a client as observer in the server
 133 =============
 134 */
 135 void FixPlayermodel();
 136 void PutObserverInServer (void)
 137 {
 138         entity  spot;
 139     self.hud = HUD_NORMAL;
 140
 141         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 142
 143         spot = SelectSpawnPoint (TRUE);
 144         if(!spot)
 145                 error("No spawnpoints for observers?!?\n");
 146         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 147
 148         if(IS_REAL_CLIENT(self))
 149         {
 150                 msg_entity = self;
 151                 WriteByte(MSG_ONE, SVC_SETVIEW);
 152                 WriteEntity(MSG_ONE, self);
 153         }
 154
 155         self.frags = FRAGS_SPECTATOR;
 156
 157         MUTATOR_CALLHOOK(MakePlayerObserver);
 158
 159         Portal_ClearAll(self);
 160
 161         Unfreeze(self);
 162
 163         if(self.alivetime)
 164         {
 165                 if(!warmup_stage)
 166                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 167                 self.alivetime = 0;
 168         }
 169
 170         if(self.vehicle)
 171                 vehicles_exit(VHEF_RELESE);
 172
 173         WaypointSprite_PlayerDead();
 174
 175         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 176                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 177
 178         if(self.killcount != -666)
 179         {
 180                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 181                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 182                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 183
 184                 if(self.just_joined == FALSE) {
 185                         LogTeamchange(self.playerid, -1, 4);
 186                 } else
 187                         self.just_joined = FALSE;
 188         }
 189
 190         PlayerScore_Clear(self); // clear scores when needed
 191
 192         accuracy_resend(self);
 193
 194         self.spectatortime = time;
 195
 196         self.classname = "observer";
 197         self.iscreature = FALSE;
 198         self.teleportable = TELEPORT_SIMPLE;
 199         self.damagedbycontents = FALSE;
 200         self.health = -666;
 201         self.takedamage = DAMAGE_NO;
 202         self.solid = SOLID_NOT;
 203         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 204         self.flags = FL_CLIENT | FL_NOTARGET;
 205         self.armorvalue = 666;
 206         self.effects = 0;
 207         self.armorvalue = autocvar_g_balance_armor_start;
 208         self.pauserotarmor_finished = 0;
 209         self.pauserothealth_finished = 0;
 210         self.pauseregen_finished = 0;
 211         self.damageforcescale = 0;
 212         self.death_time = 0;
 213         self.respawn_flags = 0;
 214         self.respawn_time = 0;
 215         self.stat_respawn_time = 0;
 216         self.alpha = 0;
 217         self.scale = 0;
 218         self.fade_time = 0;
 219         self.pain_frame = 0;
 220         self.pain_finished = 0;
 221         self.strength_finished = 0;
 222         self.invincible_finished = 0;
 223         self.superweapons_finished = 0;
 224         self.pushltime = 0;
 225         self.istypefrag = 0;
 226         self.think = func_null;
 227         self.nextthink = 0;
 228         self.hook_time = 0;
 229         self.deadflag = DEAD_NO;
 230         self.angles = spot.angles;
 231         self.angles_z = 0;
 232         self.fixangle = TRUE;
 233         self.crouch = FALSE;
 234         self.revival_time = 0;
 235
 236         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 237         self.prevorigin = self.origin;
 238         self.items = 0;
 239         self.weapons = '0 0 0';
 240         self.model = "";
 241         FixPlayermodel();
 242         setmodel(self, "null");
 243         self.drawonlytoclient = self;
 244
 245         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 246         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 247
 248         self.weapon = 0;
 249         self.weaponname = "";
 250         self.switchingweapon = 0;
 251         self.weaponmodel = "";
 252         self.weaponentity = world;
 253         self.exteriorweaponentity = world;
 254         self.killcount = -666;
 255         self.velocity = '0 0 0';
 256         self.avelocity = '0 0 0';
 257         self.punchangle = '0 0 0';
 258         self.punchvector = '0 0 0';
 259         self.oldvelocity = self.velocity;
 260         self.fire_endtime = -1;
 261 }
 262
 263 .float model_randomizer;
 264 void FixPlayermodel()
 265 {
 266         string defaultmodel;
 267         float defaultskin, chmdl, oldskin, n, i;
 268         vector m1, m2;
 269
 270         defaultmodel = "";
 271         defaultskin = 0;
 272         chmdl = FALSE;
 273
 274         if(autocvar_sv_defaultcharacter == 1)
 275         {
 276                 if(teamplay)
 277                 {
 278                         string s;
 279                         s = Static_Team_ColorName_Lower(self.team);
 280                         if(s != "neutral")
 281                         {
 282                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 283                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 284                         }
 285                 }
 286
 287                 if(defaultmodel == "")
 288                 {
 289                         defaultmodel = autocvar_sv_defaultplayermodel;
 290                         defaultskin = autocvar_sv_defaultplayerskin;
 291                 }
 292
 293                 n = tokenize_console(defaultmodel);
 294                 if(n > 0)
 295                 {
 296                         defaultmodel = argv(floor(n * self.model_randomizer));
 297                         // However, do NOT randomize if the player-selected model is in the list.
 298                         for (i = 0; i < n; ++i)
 299                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 300                                         defaultmodel = argv(i);
 301                 }
 302
 303                 i = strstrofs(defaultmodel, ":", 0);
 304                 if(i >= 0)
 305                 {
 306                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 307                         defaultmodel = substring(defaultmodel, 0, i);
 308                 }
 309         }
 310
 311         if(defaultmodel != "")
 312         {
 313                 if (defaultmodel != self.model)
 314                 {
 315                         m1 = self.mins;
 316                         m2 = self.maxs;
 317                         setplayermodel (self, defaultmodel);
 318                         setsize (self, m1, m2);
 319                         chmdl = TRUE;
 320                 }
 321
 322                 oldskin = self.skin;
 323                 self.skin = defaultskin;
 324         } else {
 325                 if (self.playermodel != self.model || self.playermodel == "")
 326                 {
 327                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 328                         m1 = self.mins;
 329                         m2 = self.maxs;
 330                         setplayermodel (self, self.playermodel);
 331                         setsize (self, m1, m2);
 332                         chmdl = TRUE;
 333                 }
 334
 335                 oldskin = self.skin;
 336                 self.skin = stof(self.playerskin);
 337         }
 338
 339         if(chmdl || oldskin != self.skin) // model or skin has changed
 340         {
 341                 self.species = player_getspecies(); // update species
 342                 UpdatePlayerSounds(); // update skin sounds
 343         }
 344
 345         if(!teamplay)
 346                 if(strlen(autocvar_sv_defaultplayercolors))
 347                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 348                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 349 }
 350
 351 /*
 352 =============
 353 PutClientInServer
 354
 355 Called when a client spawns in the server
 356 =============
 357 */
 358 void PutClientInServer (void)
 359 {
 360         if(IS_BOT_CLIENT(self))
 361                 self.classname = "player";
 362         else if(IS_REAL_CLIENT(self))
 363         {
 364                 msg_entity = self;
 365                 WriteByte(MSG_ONE, SVC_SETVIEW);
 366                 WriteEntity(MSG_ONE, self);
 367         }
 368
 369         // reset player keys
 370         self.itemkeys = 0;
 371
 372         MUTATOR_CALLHOOK(PutClientInServer);
 373
 374         if(gameover)
 375                 self.classname = "observer";
 376
 377         if(IS_PLAYER(self))
 378         {
 379                 entity spot, oldself;
 380                 float j;
 381
 382                 accuracy_resend(self);
 383
 384                 if(self.team < 0)
 385                         JoinBestTeam(self, FALSE, TRUE);
 386
 387                 spot = SelectSpawnPoint (FALSE);
 388                 if(!spot)
 389                 {
 390                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 391                         return; // spawn failed
 392                 }
 393
 394                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 395
 396                 if(self.vehicle)
 397                         vehicles_exit(VHEF_RELESE);
 398
 399                 self.classname = "player";
 400                 self.wasplayer = TRUE;
 401                 self.iscreature = TRUE;
 402                 self.teleportable = TELEPORT_NORMAL;
 403                 self.damagedbycontents = TRUE;
 404                 self.movetype = MOVETYPE_WALK;
 405                 self.solid = SOLID_SLIDEBOX;
 406                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 407                 if(autocvar_g_playerclip_collisions)
 408                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 409                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 410                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 411                 self.frags = FRAGS_PLAYER;
 412                 if(INDEPENDENT_PLAYERS)
 413                         MAKE_INDEPENDENT_PLAYER(self);
 414                 self.flags = FL_CLIENT;
 415                 if(autocvar__notarget)
 416                         self.flags |= FL_NOTARGET;
 417                 self.takedamage = DAMAGE_AIM;
 418                 self.effects = 0;
 419                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 420                 self.air_finished = time + 12;
 421                 self.dmg = 2;
 422                 if(autocvar_g_balance_nex_charge)
 423                 {
 424                         if(autocvar_g_balance_nex_secondary_chargepool)
 425                                 self.nex_chargepool_ammo = 1;
 426                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 427                 }
 428
 429                 if(warmup_stage)
 430                 {
 431                         self.ammo_shells = warmup_start_ammo_shells;
 432                         self.ammo_nails = warmup_start_ammo_nails;
 433                         self.ammo_rockets = warmup_start_ammo_rockets;
 434                         self.ammo_cells = warmup_start_ammo_cells;
 435                         self.ammo_fuel = warmup_start_ammo_fuel;
 436                         self.health = warmup_start_health;
 437                         self.armorvalue = warmup_start_armorvalue;
 438                         self.weapons = WARMUP_START_WEAPONS;
 439                 }
 440                 else
 441                 {
 442                         self.ammo_shells = start_ammo_shells;
 443                         self.ammo_nails = start_ammo_nails;
 444                         self.ammo_rockets = start_ammo_rockets;
 445                         self.ammo_cells = start_ammo_cells;
 446                         self.ammo_fuel = start_ammo_fuel;
 447                         self.health = start_health;
 448                         self.armorvalue = start_armorvalue;
 449                         self.weapons = start_weapons;
 450                 }
 451
 452                 if(self.weapons & WEPSET_SUPERWEAPONS)
 453                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 454                 else
 455                         self.superweapons_finished = 0;
 456
 457                 if(g_weaponarena_random)
 458                 {
 459                         if(g_weaponarena_random_with_laser)
 460                                 self.weapons &= ~WEPSET_LASER;
 461                         W_RandomWeapons(self, g_weaponarena_random);
 462                         if(g_weaponarena_random_with_laser)
 463                                 self.weapons |= WEPSET_LASER;
 464                 }
 465
 466                 self.items = start_items;
 467
 468                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 469                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 470                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 471                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 472                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 473                 //extend the pause of rotting if client was reset at the beginning of the countdown
 474                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 475                         self.spawnshieldtime += game_starttime - time;
 476                         self.pauserotarmor_finished += game_starttime - time;
 477                         self.pauserothealth_finished += game_starttime - time;
 478                         self.pauseregen_finished += game_starttime - time;
 479                 }
 480                 self.damageforcescale = 2;
 481                 self.death_time = 0;
 482                 self.respawn_flags = 0;
 483                 self.respawn_time = 0;
 484                 self.stat_respawn_time = 0;
 485                 self.scale = 0;
 486                 self.fade_time = 0;
 487                 self.pain_frame = 0;
 488                 self.pain_finished = 0;
 489                 self.strength_finished = 0;
 490                 self.invincible_finished = 0;
 491                 self.pushltime = 0;
 492                 // players have no think function
 493                 self.think = func_null;
 494                 self.nextthink = 0;
 495                 self.hook_time = 0;
 496                 self.dmg_team = 0;
 497                 self.ballistics_density = autocvar_g_ballistics_density_player;
 498
 499                 self.metertime = 0;
 500
 501                 self.deadflag = DEAD_NO;
 502
 503                 self.angles = spot.angles;
 504
 505                 self.angles_z = 0; // never spawn tilted even if the spot says to
 506                 if(IS_BOT_CLIENT(self))
 507                         self.v_angle = self.angles;
 508                 self.fixangle = TRUE; // turn this way immediately
 509                 self.velocity = '0 0 0';
 510                 self.avelocity = '0 0 0';
 511                 self.punchangle = '0 0 0';
 512                 self.punchvector = '0 0 0';
 513                 self.oldvelocity = self.velocity;
 514                 self.fire_endtime = -1;
 515                 self.revival_time = 0;
 516
 517                 entity spawnevent = spawn();
 518                 spawnevent.owner = self;
 519                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 520
 521                 // Cut off any still running player sounds.
 522                 stopsound(self, CH_PLAYER_SINGLE);
 523
 524                 self.model = "";
 525                 FixPlayermodel();
 526                 self.drawonlytoclient = world;
 527
 528                 self.crouch = FALSE;
 529                 self.view_ofs = PL_VIEW_OFS;
 530                 setsize (self, PL_MIN, PL_MAX);
 531                 self.spawnorigin = spot.origin;
 532                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 533                 // don't reset back to last position, even if new position is stuck in solid
 534                 self.oldorigin = self.origin;
 535                 self.prevorigin = self.origin;
 536                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 537                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 538         self.hud = HUD_NORMAL;
 539
 540                 self.event_damage = PlayerDamage;
 541
 542                 self.bot_attack = TRUE;
 543                 self.monster_attack = TRUE;
 544
 545                 self.spider_slowness = 0;
 546
 547                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 548
 549                 if(self.killcount == -666) {
 550                         PlayerScore_Clear(self);
 551                         self.killcount = 0;
 552                 }
 553
 554                 CL_SpawnWeaponentity();
 555                 self.alpha = default_player_alpha;
 556                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 557                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 558
 559                 self.speedrunning = FALSE;
 560
 561                 //stuffcmd(self, "chase_active 0");
 562                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 563
 564                 target_voicescript_clear(self);
 565
 566                 // reset fields the weapons may use
 567                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 568                 {
 569                         weapon_action(j, WR_RESETPLAYER);
 570
 571                         // all weapons must be fully loaded when we spawn
 572                         entity e;
 573                         e = get_weaponinfo(j);
 574                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 575                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 576                 }
 577
 578                 oldself = self;
 579                 self = spot;
 580                         activator = oldself;
 581                                 string s;
 582                                 s = self.target;
 583                                 self.target = string_null;
 584                                 SUB_UseTargets();
 585                                 self.target = s;
 586                         activator = world;
 587                 self = oldself;
 588
 589                 Unfreeze(self);
 590
 591                 spawn_spot = spot;
 592                 MUTATOR_CALLHOOK(PlayerSpawn);
 593
 594                 if(autocvar_spawn_debug)
 595                 {
 596                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 597                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 598                 }
 599
 600                 self.switchweapon = w_getbestweapon(self);
 601                 self.cnt = -1; // W_LastWeapon will not complain
 602                 self.weapon = 0;
 603                 self.weaponname = "";
 604                 self.switchingweapon = 0;
 605
 606                 if(!warmup_stage)
 607                         if(!self.alivetime)
 608                                 self.alivetime = time;
 609
 610                 antilag_clear(self);
 611         }
 612         else if(IS_OBSERVER(self))
 613         {
 614                 PutObserverInServer ();
 615         }
 616 }
 617
 618 .float ebouncefactor, ebouncestop; // electro's values
 619 // TODO do we need all these fields, or should we stop autodetecting runtime
 620 // changes and just have a console command to update this?
 621 float ClientInit_SendEntity(entity to, float sf)
 622 {
 623         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 624         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 625         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 626         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 627         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 628         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 629         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 630         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 631         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 632         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 633         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 634         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 635         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 636         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 637         if(sv_foginterval && world.fog != "")
 638                 WriteString(MSG_ENTITY, world.fog);
 639         else
 640                 WriteString(MSG_ENTITY, "");
 641         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 642         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 643         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 644         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 645         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 646         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 647         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 648         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 649         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 650         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 651         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 652         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 653         return TRUE;
 654 }
 655
 656 void ClientInit_CheckUpdate()
 657 {
 658         self.nextthink = time;
 659         if(self.count != autocvar_g_balance_armor_blockpercent)
 660         {
 661                 self.count = autocvar_g_balance_armor_blockpercent;
 662                 self.SendFlags |= 1;
 663         }
 664         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 665         {
 666                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 667                 self.SendFlags |= 1;
 668         }
 669         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 670         {
 671                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 672                 self.SendFlags |= 1;
 673         }
 674         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 675         {
 676                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 677                 self.SendFlags |= 1;
 678         }
 679         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 680         {
 681                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 682                 self.SendFlags |= 1;
 683         }
 684 }
 685
 686 void ClientInit_Spawn()
 687 {
 688         entity o;
 689         entity e;
 690         e = spawn();
 691         e.classname = "clientinit";
 692         e.think = ClientInit_CheckUpdate;
 693         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 694
 695         o = self;
 696         self = e;
 697         ClientInit_CheckUpdate();
 698         self = o;
 699 }
 700
 701 /*
 702 =============
 703 SetNewParms
 704 =============
 705 */
 706 void SetNewParms (void)
 707 {
 708         // initialize parms for a new player
 709         parm1 = -(86400 * 366);
 710 }
 711
 712 /*
 713 =============
 714 SetChangeParms
 715 =============
 716 */
 717 void SetChangeParms (void)
 718 {
 719         // save parms for level change
 720         parm1 = self.parm_idlesince - time;
 721 }
 722
 723 /*
 724 =============
 725 DecodeLevelParms
 726 =============
 727 */
 728 void DecodeLevelParms (void)
 729 {
 730         // load parms
 731         self.parm_idlesince = parm1;
 732         if(self.parm_idlesince == -(86400 * 366))
 733                 self.parm_idlesince = time;
 734
 735         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 736         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 737 }
 738
 739 /*
 740 =============
 741 ClientKill
 742
 743 Called when a client types 'kill' in the console
 744 =============
 745 */
 746
 747 .float clientkill_nexttime;
 748 void ClientKill_Now_TeamChange()
 749 {
 750         if(self.killindicator_teamchange == -1)
 751         {
 752                 JoinBestTeam( self, FALSE, TRUE );
 753         }
 754         else if(self.killindicator_teamchange == -2)
 755         {
 756                 if(blockSpectators)
 757                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 758                 PutObserverInServer();
 759         }
 760         else
 761                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 762         self.killindicator_teamchange = 0;
 763 }
 764
 765 void ClientKill_Now()
 766 {
 767         if(self.vehicle)
 768         {
 769             vehicles_exit(VHEF_RELESE);
 770             if(!self.killindicator_teamchange)
 771             {
 772             self.vehicle_health = -1;
 773             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 774             }
 775         }
 776
 777         if(self.killindicator && !wasfreed(self.killindicator))
 778                 remove(self.killindicator);
 779
 780         self.killindicator = world;
 781
 782         if(self.killindicator_teamchange)
 783                 ClientKill_Now_TeamChange();
 784
 785         // in any case:
 786         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 787
 788         // now I am sure the player IS dead
 789 }
 790 void KillIndicator_Think()
 791 {
 792         if (gameover)
 793         {
 794                 self.owner.killindicator = world;
 795                 remove(self);
 796                 return;
 797         }
 798
 799         if (self.owner.alpha < 0 && !self.owner.vehicle)
 800         {
 801                 self.owner.killindicator = world;
 802                 remove(self);
 803                 return;
 804         }
 805
 806         if(self.cnt <= 0)
 807         {
 808                 self = self.owner;
 809                 ClientKill_Now(); // no oldself needed
 810                 return;
 811         }
 812     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 813     {
 814         self.nextthink = time + 1;
 815         self.cnt -= 1;
 816     }
 817         else
 818         {
 819                 if(self.cnt <= 10)
 820                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 821                 if(IS_REAL_CLIENT(self.owner))
 822                 {
 823                         if(self.cnt <= 10)
 824                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 825                 }
 826                 self.nextthink = time + 1;
 827                 self.cnt -= 1;
 828         }
 829 }
 830
 831 float clientkilltime;
 832 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 833 {
 834         float killtime;
 835         float starttime;
 836         entity e;
 837
 838         if (gameover)
 839                 return;
 840
 841         killtime = autocvar_g_balance_kill_delay;
 842
 843         if(g_race_qualifying || g_cts)
 844                 killtime = 0;
 845
 846     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 847     {
 848                 remove(self.killindicator);
 849                 self.killindicator = world;
 850
 851         ClientKill_Now(); // allow instant kill in this case
 852         return;
 853     }
 854
 855         self.killindicator_teamchange = targetteam;
 856
 857     if(!self.killindicator)
 858         {
 859                 if(self.deadflag == DEAD_NO)
 860                 {
 861                         killtime = max(killtime, self.clientkill_nexttime - time);
 862                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 863                 }
 864
 865                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 866                 {
 867                         ClientKill_Now();
 868                 }
 869                 else
 870                 {
 871                         starttime = max(time, clientkilltime);
 872
 873                         self.killindicator = spawn();
 874                         self.killindicator.owner = self;
 875                         self.killindicator.scale = 0.5;
 876                         setattachment(self.killindicator, self, "");
 877                         setorigin(self.killindicator, '0 0 52');
 878                         self.killindicator.think = KillIndicator_Think;
 879                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 880                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 881                         self.killindicator.cnt = ceil(killtime);
 882                         self.killindicator.count = bound(0, ceil(killtime), 10);
 883                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 884
 885                         for(e = world; (e = find(e, classname, "body")) != world; )
 886                         {
 887                                 if(e.enemy != self)
 888                                         continue;
 889                                 e.killindicator = spawn();
 890                                 e.killindicator.owner = e;
 891                                 e.killindicator.scale = 0.5;
 892                                 setattachment(e.killindicator, e, "");
 893                                 setorigin(e.killindicator, '0 0 52');
 894                                 e.killindicator.think = KillIndicator_Think;
 895                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 896                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 897                                 e.killindicator.cnt = ceil(killtime);
 898                         }
 899                         self.lip = 0;
 900                 }
 901         }
 902         if(self.killindicator)
 903         {
 904                 if(targetteam == 0) // just die
 905                 {
 906                         self.killindicator.colormod = '0 0 0';
 907                         if(IS_REAL_CLIENT(self))
 908                         if(self.killindicator.cnt > 0)
 909                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 910                 }
 911                 else if(targetteam == -1) // auto
 912                 {
 913                         self.killindicator.colormod = '0 1 0';
 914                         if(IS_REAL_CLIENT(self))
 915                         if(self.killindicator.cnt > 0)
 916                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 917                 }
 918                 else if(targetteam == -2) // spectate
 919                 {
 920                         self.killindicator.colormod = '0.5 0.5 0.5';
 921                         if(IS_REAL_CLIENT(self))
 922                         if(self.killindicator.cnt > 0)
 923                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 924                 }
 925                 else
 926                 {
 927                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 928                         if(IS_REAL_CLIENT(self))
 929                         if(self.killindicator.cnt > 0)
 930                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 931                 }
 932         }
 933
 934 }
 935
 936 void ClientKill (void)
 937 {
 938         if(gameover) return;
 939         if(self.player_blocked) return;
 940         if(self.frozen) return;
 941
 942         ClientKill_TeamChange(0);
 943 }
 944
 945 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 946 {
 947     e.killindicator = spawn();
 948     e.killindicator.owner = e;
 949     e.killindicator.think = KillIndicator_Think;
 950     e.killindicator.nextthink = time + (e.lip) * 0.05;
 951     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 952     e.killindicator.health = 1; // this is used to indicate that it should be silent
 953     e.lip = 0;
 954 }
 955
 956 void FixClientCvars(entity e)
 957 {
 958         // send prediction settings to the client
 959         stuffcmd(e, "\nin_bindmap 0 0\n");
 960         if(g_race || g_cts)
 961                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 962         if(autocvar_g_antilag == 3) // client side hitscan
 963                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 964         if(autocvar_sv_gentle)
 965                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 966         /*
 967          * we no longer need to stuff this. Remove this comment block if you feel
 968          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 969         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 970         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 971         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 972         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 973         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 974         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 975         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 976         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 977         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 978         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 979         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 980         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 981         stuffcmd(e, "cl_movement_edgefriction 1\n");
 982          */
 983 }
 984
 985 float PlayerInIDList(entity p, string idlist)
 986 {
 987         float n, i;
 988         string s;
 989
 990         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 991         if (!p.crypto_idfp)
 992                 return 0;
 993
 994         // this function allows abbreviated player IDs too!
 995         n = tokenize_console(idlist);
 996         for(i = 0; i < n; ++i)
 997         {
 998                 s = argv(i);
 999                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1000                         return 1;
1001         }
1002
1003         return 0;
1004 }
1005
1006 /*
1007 =============
1008 ClientConnect
1009
1010 Called when a client connects to the server
1011 =============
1012 */
1013 void DecodeLevelParms (void);
1014 //void dom_player_join_team(entity pl);
1015 void set_dom_state(entity e);
1016 void ClientConnect (void)
1017 {
1018         float t;
1019
1020         if(IS_CLIENT(self))
1021         {
1022                 print("Warning: ClientConnect, but already connected!\n");
1023                 return;
1024         }
1025
1026         if(Ban_MaybeEnforceBanOnce(self))
1027                 return;
1028
1029         DecodeLevelParms();
1030
1031 #ifdef WATERMARK
1032         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1033 #endif
1034
1035         self.classname = "player_joining";
1036
1037         self.flags = FL_CLIENT;
1038         self.version_nagtime = time + 10 + random() * 10;
1039
1040         if(player_count<0)
1041         {
1042                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1043                 player_count = 0;
1044         }
1045
1046         PlayerScore_Attach(self);
1047         ClientData_Attach();
1048         accuracy_init(self);
1049
1050         bot_clientconnect();
1051
1052         playerdemo_init();
1053
1054         anticheat_init();
1055
1056         // identify the right forced team
1057         if(autocvar_g_campaign)
1058         {
1059                 if(IS_REAL_CLIENT(self)) // only players, not bots
1060                 {
1061                         switch(autocvar_g_campaign_forceteam)
1062                         {
1063                                 case 1: self.team_forced = NUM_TEAM_1; break;
1064                                 case 2: self.team_forced = NUM_TEAM_2; break;
1065                                 case 3: self.team_forced = NUM_TEAM_3; break;
1066                                 case 4: self.team_forced = NUM_TEAM_4; break;
1067                                 default: self.team_forced = 0;
1068                         }
1069                 }
1070         }
1071         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1072                 self.team_forced = NUM_TEAM_1;
1073         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1074                 self.team_forced = NUM_TEAM_2;
1075         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1076                 self.team_forced = NUM_TEAM_3;
1077         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1078                 self.team_forced = NUM_TEAM_4;
1079         else if(autocvar_g_forced_team_otherwise == "red")
1080                 self.team_forced = NUM_TEAM_1;
1081         else if(autocvar_g_forced_team_otherwise == "blue")
1082                 self.team_forced = NUM_TEAM_2;
1083         else if(autocvar_g_forced_team_otherwise == "yellow")
1084                 self.team_forced = NUM_TEAM_3;
1085         else if(autocvar_g_forced_team_otherwise == "pink")
1086                 self.team_forced = NUM_TEAM_4;
1087         else if(autocvar_g_forced_team_otherwise == "spectate")
1088                 self.team_forced = -1;
1089         else if(autocvar_g_forced_team_otherwise == "spectator")
1090                 self.team_forced = -1;
1091         else
1092                 self.team_forced = 0;
1093
1094         if(!teamplay)
1095                 if(self.team_forced > 0)
1096                         self.team_forced = 0;
1097
1098         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1099
1100         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1101                 self.classname = "observer";
1102         } else {
1103                 if(teamplay)
1104                 {
1105                         if(autocvar_g_balance_teams)
1106                         {
1107                                 self.classname = "player";
1108                                 campaign_bots_may_start = 1;
1109                         }
1110                         else
1111                         {
1112                                 self.classname = "observer"; // do it anyway
1113                         }
1114                 }
1115                 else
1116                 {
1117                         self.classname = "player";
1118                         campaign_bots_may_start = 1;
1119                 }
1120         }
1121
1122         self.playerid = (playerid_last = playerid_last + 1);
1123
1124         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1125
1126     if(IS_BOT_CLIENT(self))
1127         PlayerStats_AddPlayer(self);
1128
1129         if(autocvar_sv_eventlog)
1130                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1131
1132         LogTeamchange(self.playerid, self.team, 1);
1133
1134         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1135
1136         self.netname_previous = strzone(self.netname);
1137
1138         if(IS_PLAYER(self) && teamplay)
1139                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1140         else
1141                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1142
1143         stuffcmd(self, strcat(clientstuff, "\n"));
1144         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1145
1146         FixClientCvars(self);
1147
1148         // spawnfunc_waypoint sprites
1149         WaypointSprite_InitClient(self);
1150
1151         // Wazat's grappling hook
1152         SetGrappleHookBindings();
1153
1154         // get version info from player
1155         stuffcmd(self, "cmd clientversion $gameversion\n");
1156
1157         // get other cvars from player
1158         GetCvars(0);
1159
1160         // notify about available teams
1161         if(teamplay)
1162         {
1163                 CheckAllowedTeams(self);
1164                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1165                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1166         }
1167         else
1168                 stuffcmd(self, "set _teams_available 0\n");
1169
1170         attach_entcs();
1171
1172         bot_relinkplayerlist();
1173
1174         self.spectatortime = time;
1175         if(blockSpectators)
1176         {
1177                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1178         }
1179
1180         self.jointime = time;
1181         self.allowed_timeouts = autocvar_sv_timeout_number;
1182
1183         if(IS_REAL_CLIENT(self))
1184         {
1185                 if(!autocvar_g_campaign)
1186                 {
1187                         self.motd_actived_time = -1;
1188                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1189                 }
1190
1191                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1192                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1193         }
1194
1195         if(!sv_foginterval && world.fog != "")
1196                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1197
1198         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1199         {
1200                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1201                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1202         }
1203         else
1204                 self.hitplotfh = -1;
1205
1206         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1207                 send_CSQC_teamnagger();
1208
1209         CheatInitClient();
1210
1211         CSQCMODEL_AUTOINIT();
1212
1213         self.model_randomizer = random();
1214
1215         if(IS_REAL_CLIENT(self))
1216                 sv_notice_join();
1217
1218         MUTATOR_CALLHOOK(ClientConnect);
1219 }
1220 /*
1221 =============
1222 ClientDisconnect
1223
1224 Called when a client disconnects from the server
1225 =============
1226 */
1227 .entity chatbubbleentity;
1228 void ReadyCount();
1229 void ClientDisconnect (void)
1230 {
1231         if(self.vehicle)
1232             vehicles_exit(VHEF_RELESE);
1233
1234         if (!IS_CLIENT(self))
1235         {
1236                 print("Warning: ClientDisconnect without ClientConnect\n");
1237                 return;
1238         }
1239
1240         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1241
1242         PlayerStats_AddGlobalInfo(self);
1243
1244         CheatShutdownClient();
1245
1246         if(self.hitplotfh >= 0)
1247         {
1248                 fclose(self.hitplotfh);
1249                 self.hitplotfh = -1;
1250         }
1251
1252         anticheat_report();
1253         anticheat_shutdown();
1254
1255         playerdemo_shutdown();
1256
1257         bot_clientdisconnect();
1258
1259         if(self.entcs)
1260                 detach_entcs();
1261
1262         if(autocvar_sv_eventlog)
1263                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1264
1265         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1266
1267         MUTATOR_CALLHOOK(ClientDisconnect);
1268
1269         Portal_ClearAll(self);
1270
1271         Unfreeze(self);
1272
1273         RemoveGrapplingHook(self);
1274
1275         // Here, everything has been done that requires this player to be a client.
1276
1277         self.flags &= ~FL_CLIENT;
1278
1279         if (self.chatbubbleentity)
1280                 remove (self.chatbubbleentity);
1281
1282         if (self.killindicator)
1283                 remove (self.killindicator);
1284
1285         WaypointSprite_PlayerGone();
1286
1287         bot_relinkplayerlist();
1288
1289         accuracy_free(self);
1290         ClientData_Detach();
1291         PlayerScore_Detach(self);
1292
1293         if(self.netname_previous)
1294                 strunzone(self.netname_previous);
1295         if(self.clientstatus)
1296                 strunzone(self.clientstatus);
1297         if(self.weaponorder_byimpulse)
1298                 strunzone(self.weaponorder_byimpulse);
1299
1300         ClearPlayerSounds();
1301
1302         if(self.personal)
1303                 remove(self.personal);
1304
1305         self.playerid = 0;
1306         ReadyCount();
1307
1308         // free cvars
1309         GetCvars(-1);
1310 }
1311
1312 .float BUTTON_CHAT;
1313 void ChatBubbleThink()
1314 {
1315         self.nextthink = time;
1316         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1317         {
1318                 if(self.owner) // but why can that ever be world?
1319                         self.owner.chatbubbleentity = world;
1320                 remove(self);
1321                 return;
1322         }
1323         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1324 #ifdef TETRIS
1325                 || self.owner.tetris_on
1326 #endif
1327         )
1328                 self.model = self.mdl;
1329         else
1330                 self.model = "";
1331 }
1332
1333 void UpdateChatBubble()
1334 {
1335         if (self.alpha < 0)
1336                 return;
1337         // spawn a chatbubble entity if needed
1338         if (!self.chatbubbleentity)
1339         {
1340                 self.chatbubbleentity = spawn();
1341                 self.chatbubbleentity.owner = self;
1342                 self.chatbubbleentity.exteriormodeltoclient = self;
1343                 self.chatbubbleentity.think = ChatBubbleThink;
1344                 self.chatbubbleentity.nextthink = time;
1345                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1346                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1347                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1348                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1349                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1350                 self.chatbubbleentity.model = "";
1351                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1352         }
1353 }
1354
1355
1356 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1357 // added to the model skins
1358 /*void UpdateColorModHack()
1359 {
1360         float c;
1361         c = self.clientcolors & 15;
1362         // LordHavoc: only bothering to support white, green, red, yellow, blue
1363              if (!teamplay) self.colormod = '0 0 0';
1364         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1365         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1366         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1367         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1368         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1369         else self.colormod = '1 1 1';
1370 }*/
1371
1372 void respawn(void)
1373 {
1374         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1375         {
1376                 self.solid = SOLID_NOT;
1377                 self.takedamage = DAMAGE_NO;
1378                 self.movetype = MOVETYPE_FLY;
1379                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1380                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1381                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1382                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1383                 if(autocvar_g_respawn_ghosts_maxtime)
1384                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1385         }
1386
1387         CopyBody(1);
1388
1389         self.effects |= EF_NODRAW; // prevent another CopyBody
1390         PutClientInServer();
1391 }
1392
1393 void play_countdown(float finished, string samp)
1394 {
1395         if(IS_REAL_CLIENT(self))
1396                 if(floor(finished - time - frametime) != floor(finished - time))
1397                         if(finished - time < 6)
1398                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1399 }
1400
1401 void player_powerups (void)
1402 {
1403         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1404         olditems = self.items;
1405
1406         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1407                 self.modelflags |= MF_ROCKET;
1408         else
1409                 self.modelflags &= ~MF_ROCKET;
1410
1411         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1412
1413         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1414                 return;
1415
1416         Fire_ApplyDamage(self);
1417         Fire_ApplyEffect(self);
1418
1419         if (!g_instagib)
1420         {
1421                 if (self.items & IT_STRENGTH)
1422                 {
1423                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1424                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1425                         if (time > self.strength_finished)
1426                         {
1427                                 self.items = self.items - (self.items & IT_STRENGTH);
1428                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1429                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1430                         }
1431                 }
1432                 else
1433                 {
1434                         if (time < self.strength_finished)
1435                         {
1436                                 self.items = self.items | IT_STRENGTH;
1437                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1438                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1439                         }
1440                 }
1441                 if (self.items & IT_INVINCIBLE)
1442                 {
1443                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1444                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1445                         if (time > self.invincible_finished)
1446                         {
1447                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1448                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1449                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1450                         }
1451                 }
1452                 else
1453                 {
1454                         if (time < self.invincible_finished)
1455                         {
1456                                 self.items = self.items | IT_INVINCIBLE;
1457                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1458                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1459                         }
1460                 }
1461                 if (self.items & IT_SUPERWEAPON)
1462                 {
1463                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1464                         {
1465                                 self.superweapons_finished = 0;
1466                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1467                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1468                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1469                         }
1470                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1471                         {
1472                                 // don't let them run out
1473                         }
1474                         else
1475                         {
1476                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1477                                 if (time > self.superweapons_finished)
1478                                 {
1479                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1480                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1481                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1482                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1483                                 }
1484                         }
1485                 }
1486                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1487                 {
1488                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1489                         {
1490                                 self.items = self.items | IT_SUPERWEAPON;
1491                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1492                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1493                         }
1494                         else
1495                         {
1496                                 self.superweapons_finished = 0;
1497                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1498                         }
1499                 }
1500                 else
1501                 {
1502                         self.superweapons_finished = 0;
1503                 }
1504         }
1505
1506         if(autocvar_g_nodepthtestplayers)
1507                 self.effects = self.effects | EF_NODEPTHTEST;
1508
1509         if(autocvar_g_fullbrightplayers)
1510                 self.effects = self.effects | EF_FULLBRIGHT;
1511
1512         if (time >= game_starttime)
1513         if (time < self.spawnshieldtime)
1514                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1515
1516         MUTATOR_CALLHOOK(PlayerPowerups);
1517 }
1518
1519 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1520 {
1521         if(current > stable)
1522                 return current;
1523         else if(current > stable - 0.25) // when close enough, "snap"
1524                 return stable;
1525         else
1526                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1527 }
1528
1529 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1530 {
1531         if(current < stable)
1532                 return current;
1533         else if(current < stable + 0.25) // when close enough, "snap"
1534                 return stable;
1535         else
1536                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1537 }
1538
1539 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1540 {
1541         if(current > rotstable)
1542         {
1543                 if(rotframetime > 0)
1544                 {
1545                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1546                         current = max(rotstable, current - rotlinear * rotframetime);
1547                 }
1548         }
1549         else if(current < regenstable)
1550         {
1551                 if(regenframetime > 0)
1552                 {
1553                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1554                         current = min(regenstable, current + regenlinear * regenframetime);
1555                 }
1556         }
1557
1558         if(current > limit)
1559                 current = limit;
1560
1561         return current;
1562 }
1563
1564 void player_regen (void)
1565 {
1566         float max_mod, regen_mod, rot_mod, limit_mod;
1567         max_mod = regen_mod = rot_mod = limit_mod = 1;
1568         regen_mod_max = max_mod;
1569         regen_mod_regen = regen_mod;
1570         regen_mod_rot = rot_mod;
1571         regen_mod_limit = limit_mod;
1572         if(!MUTATOR_CALLHOOK(PlayerRegen))
1573         if(!self.frozen)
1574         {
1575                 float minh, mina, maxh, maxa, limith, limita;
1576                 maxh = autocvar_g_balance_health_rotstable;
1577                 maxa = autocvar_g_balance_armor_rotstable;
1578                 minh = autocvar_g_balance_health_regenstable;
1579                 mina = autocvar_g_balance_armor_regenstable;
1580                 limith = autocvar_g_balance_health_limit;
1581                 limita = autocvar_g_balance_armor_limit;
1582
1583                 max_mod = regen_mod_max;
1584                 regen_mod = regen_mod_regen;
1585                 rot_mod = regen_mod_rot;
1586                 limit_mod = regen_mod_limit;
1587
1588                 maxh = maxh * max_mod;
1589                 minh = minh * max_mod;
1590                 limith = limith * limit_mod;
1591                 limita = limita * limit_mod;
1592
1593                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1594                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1595         }
1596
1597         // if player rotted to death...  die!
1598         // check this outside above checks, as player may still be able to rot to death
1599         if(self.health < 1)
1600                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1601
1602         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1603         {
1604                 float minf, maxf, limitf;
1605
1606                 maxf = autocvar_g_balance_fuel_rotstable;
1607                 minf = autocvar_g_balance_fuel_regenstable;
1608                 limitf = autocvar_g_balance_fuel_limit;
1609
1610                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1611         }
1612 }
1613
1614 float zoomstate_set;
1615 void SetZoomState(float z)
1616 {
1617         if(z != self.zoomstate)
1618         {
1619                 self.zoomstate = z;
1620                 ClientData_Touch(self);
1621         }
1622         zoomstate_set = 1;
1623 }
1624
1625 void GetPressedKeys(void) {
1626         MUTATOR_CALLHOOK(GetPressedKeys);
1627         if (self.movement_x > 0) // get if movement keys are pressed
1628         {       // forward key pressed
1629                 self.pressedkeys |= KEY_FORWARD;
1630                 self.pressedkeys &= ~KEY_BACKWARD;
1631         }
1632         else if (self.movement_x < 0)
1633         {       // backward key pressed
1634                 self.pressedkeys |= KEY_BACKWARD;
1635                 self.pressedkeys &= ~KEY_FORWARD;
1636         }
1637         else
1638         {       // no x input
1639                 self.pressedkeys &= ~KEY_FORWARD;
1640                 self.pressedkeys &= ~KEY_BACKWARD;
1641         }
1642
1643         if (self.movement_y > 0)
1644         {       // right key pressed
1645                 self.pressedkeys |= KEY_RIGHT;
1646                 self.pressedkeys &= ~KEY_LEFT;
1647         }
1648         else if (self.movement_y < 0)
1649         {       // left key pressed
1650                 self.pressedkeys |= KEY_LEFT;
1651                 self.pressedkeys &= ~KEY_RIGHT;
1652         }
1653         else
1654         {       // no y input
1655                 self.pressedkeys &= ~KEY_RIGHT;
1656                 self.pressedkeys &= ~KEY_LEFT;
1657         }
1658
1659         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1660                 self.pressedkeys |= KEY_JUMP;
1661         else
1662                 self.pressedkeys &= ~KEY_JUMP;
1663         if (self.BUTTON_CROUCH)
1664                 self.pressedkeys |= KEY_CROUCH;
1665         else
1666                 self.pressedkeys &= ~KEY_CROUCH;
1667
1668         if (self.BUTTON_ATCK)
1669                 self.pressedkeys |= KEY_ATCK;
1670         else
1671                 self.pressedkeys &= ~KEY_ATCK;
1672         if (self.BUTTON_ATCK2)
1673                 self.pressedkeys |= KEY_ATCK2;
1674         else
1675                 self.pressedkeys &= ~KEY_ATCK2;
1676 }
1677
1678 /*
1679 ======================
1680 spectate mode routines
1681 ======================
1682 */
1683
1684 void SpectateCopy(entity spectatee) {
1685         other = spectatee;
1686         MUTATOR_CALLHOOK(SpectateCopy);
1687         self.armortype = spectatee.armortype;
1688         self.armorvalue = spectatee.armorvalue;
1689         self.ammo_cells = spectatee.ammo_cells;
1690         self.ammo_shells = spectatee.ammo_shells;
1691         self.ammo_nails = spectatee.ammo_nails;
1692         self.ammo_rockets = spectatee.ammo_rockets;
1693         self.ammo_fuel = spectatee.ammo_fuel;
1694         self.clip_load = spectatee.clip_load;
1695         self.clip_size = spectatee.clip_size;
1696         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1697         self.health = spectatee.health;
1698         self.impulse = 0;
1699         self.items = spectatee.items;
1700         self.last_pickup = spectatee.last_pickup;
1701         self.hit_time = spectatee.hit_time;
1702         self.metertime = spectatee.metertime;
1703         self.strength_finished = spectatee.strength_finished;
1704         self.invincible_finished = spectatee.invincible_finished;
1705         self.pressedkeys = spectatee.pressedkeys;
1706         self.weapons = spectatee.weapons;
1707         self.switchweapon = spectatee.switchweapon;
1708         self.switchingweapon = spectatee.switchingweapon;
1709         self.weapon = spectatee.weapon;
1710         self.nex_charge = spectatee.nex_charge;
1711         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1712         self.hagar_load = spectatee.hagar_load;
1713         self.minelayer_mines = spectatee.minelayer_mines;
1714         self.punchangle = spectatee.punchangle;
1715         self.view_ofs = spectatee.view_ofs;
1716         self.velocity = spectatee.velocity;
1717         self.dmg_take = spectatee.dmg_take;
1718         self.dmg_save = spectatee.dmg_save;
1719         self.dmg_inflictor = spectatee.dmg_inflictor;
1720         self.v_angle = spectatee.v_angle;
1721         self.angles = spectatee.v_angle;
1722         self.frozen = spectatee.frozen;
1723         self.revive_progress = spectatee.revive_progress;
1724         if(!self.BUTTON_USE)
1725                 self.fixangle = TRUE;
1726         setorigin(self, spectatee.origin);
1727         setsize(self, spectatee.mins, spectatee.maxs);
1728         SetZoomState(spectatee.zoomstate);
1729
1730     anticheat_spectatecopy(spectatee);
1731         self.hud = spectatee.hud;
1732         if(spectatee.vehicle)
1733     {
1734         self.fixangle = FALSE;
1735         //self.velocity = spectatee.vehicle.velocity;
1736         self.vehicle_health = spectatee.vehicle_health;
1737         self.vehicle_shield = spectatee.vehicle_shield;
1738         self.vehicle_energy = spectatee.vehicle_energy;
1739         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1740         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1741         self.vehicle_reload1 = spectatee.vehicle_reload1;
1742         self.vehicle_reload2 = spectatee.vehicle_reload2;
1743
1744         msg_entity = self;
1745
1746         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1747             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1748             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1749             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1750
1751         //WriteByte (MSG_ONE, SVC_SETVIEW);
1752         //    WriteEntity(MSG_ONE, self);
1753         //makevectors(spectatee.v_angle);
1754         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1755     }
1756 }
1757
1758 float SpectateUpdate() {
1759         if(!self.enemy)
1760             return 0;
1761
1762         if (self == self.enemy)
1763                 return 0;
1764
1765         if (!IS_PLAYER(self.enemy))
1766                 return 0;
1767
1768         SpectateCopy(self.enemy);
1769
1770         return 1;
1771 }
1772
1773
1774 float SpectateSet()
1775 {
1776         if(self.enemy.classname != "player")
1777                 return FALSE;
1778         /*if(self.enemy.vehicle)
1779         {
1780
1781                 msg_entity = self;
1782                 WriteByte(MSG_ONE, SVC_SETVIEW);
1783                 WriteEntity(MSG_ONE, self.enemy);
1784                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1785
1786                 self.movetype = MOVETYPE_NONE;
1787                 accuracy_resend(self);
1788         }
1789         else
1790         {*/
1791                 msg_entity = self;
1792                 WriteByte(MSG_ONE, SVC_SETVIEW);
1793                 WriteEntity(MSG_ONE, self.enemy);
1794                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1795                 self.movetype = MOVETYPE_NONE;
1796                 accuracy_resend(self);
1797
1798                 if(!SpectateUpdate())
1799                         PutObserverInServer();
1800         //}
1801         return TRUE;
1802 }
1803
1804 float Spectate(entity pl)
1805 {
1806         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1807         if(pl.team != self.team)
1808                 return 0;
1809
1810         self.enemy = pl;
1811         return SpectateSet();
1812 }
1813
1814 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1815 entity CA_SpectateNext(entity start) {
1816         if (start.team == self.team) {
1817                 return start;
1818         }
1819
1820         other = start;
1821         // continue from current player
1822         while(other && other.team != self.team) {
1823                 other = find(other, classname, "player");
1824         }
1825
1826         if (!other) {
1827                 // restart from begining
1828                 other = find(other, classname, "player");
1829                 while(other && other.team != self.team) {
1830                         other = find(other, classname, "player");
1831                 }
1832         }
1833
1834         return other;
1835 }
1836
1837 float SpectateNext()
1838 {
1839         other = find(self.enemy, classname, "player");
1840
1841         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1842                 // CA and ca players when spectating enemies is forbidden
1843                 other = CA_SpectateNext(other);
1844         } else {
1845                 // other modes and ca spectators or spectating enemies is allowed
1846                 if (!other)
1847                         other = find(other, classname, "player");
1848         }
1849
1850         if (other)
1851                 self.enemy = other;
1852
1853         return SpectateSet();
1854 }
1855
1856 float SpectatePrev()
1857 {
1858         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1859         other = findchain(classname, "player");
1860         if (!other) // no player
1861                 return FALSE;
1862
1863         entity first = other;
1864         // skip players until current spectated player
1865         if(self.enemy)
1866         while(other && other != self.enemy)
1867                 other = other.chain;
1868
1869         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1870         {
1871                 do { other = other.chain; }
1872                 while(other && other.team != self.team);
1873
1874                 if (!other)
1875                 {
1876                         other = first;
1877                         while(other.team != self.team)
1878                                 other = other.chain;
1879                         if(other == self.enemy)
1880                                 return TRUE;
1881                 }
1882         }
1883         else
1884         {
1885                 if(other.chain)
1886                         other = other.chain;
1887                 else
1888                         other = first;
1889         }
1890         self.enemy = other;
1891         return SpectateSet();
1892 }
1893
1894 /*
1895 =============
1896 ShowRespawnCountdown()
1897
1898 Update a respawn countdown display.
1899 =============
1900 */
1901 void ShowRespawnCountdown()
1902 {
1903         float number;
1904         if(self.deadflag == DEAD_NO) // just respawned?
1905                 return;
1906         else
1907         {
1908                 number = ceil(self.respawn_time - time);
1909                 if(number <= 0)
1910                         return;
1911                 if(number <= self.respawn_countdown)
1912                 {
1913                         self.respawn_countdown = number - 1;
1914                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1915                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1916                 }
1917         }
1918 }
1919
1920 void LeaveSpectatorMode()
1921 {
1922         if(self.caplayer)
1923                 return;
1924         if(nJoinAllowed(self))
1925         {
1926                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1927                 {
1928                         self.classname = "player";
1929                         nades_RemoveBonus(self);
1930
1931                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1932                                 { JoinBestTeam(self, FALSE, TRUE); }
1933
1934                         if(autocvar_g_campaign)
1935                                 { campaign_bots_may_start = 1; }
1936
1937                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1938
1939                         PutClientInServer();
1940
1941                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1942                 }
1943                 else
1944                         stuffcmd(self, "menu_showteamselect\n");
1945         }
1946         else
1947         {
1948                 // Player may not join because g_maxplayers is set
1949                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1950         }
1951 }
1952
1953 /**
1954  * Determines whether the player is allowed to join. This depends on cvar
1955  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1956  * it checks whether the number of currently playing players exceeds g_maxplayers.
1957  * @return int number of free slots for players, 0 if none
1958  */
1959 float nJoinAllowed(entity ignore) {
1960         if(!ignore)
1961         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1962         // so report 0 free slots if restricted
1963         {
1964                 if(autocvar_g_forced_team_otherwise == "spectate")
1965                         return 0;
1966                 if(autocvar_g_forced_team_otherwise == "spectator")
1967                         return 0;
1968         }
1969
1970         if(self.team_forced < 0)
1971                 return 0; // forced spectators can never join
1972
1973         // TODO simplify this
1974         entity e;
1975         float totalClients = 0;
1976         FOR_EACH_CLIENT(e)
1977                 if(e != ignore)
1978                         totalClients += 1;
1979
1980         if (!autocvar_g_maxplayers)
1981                 return maxclients - totalClients;
1982
1983         float currentlyPlaying = 0;
1984         FOR_EACH_REALCLIENT(e)
1985                 if(IS_PLAYER(e) || e.caplayer == 1)
1986                         currentlyPlaying += 1;
1987
1988         if(currentlyPlaying < autocvar_g_maxplayers)
1989                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1990
1991         return 0;
1992 }
1993
1994 /**
1995  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1996  * g_maxplayers_spectator_blocktime seconds
1997  */
1998 void checkSpectatorBlock() {
1999         if(IS_SPEC(self) || IS_OBSERVER(self)) {
2000                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2001                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2002                         dropclient(self);
2003                 }
2004         }
2005 }
2006
2007 void PrintWelcomeMessage()
2008 {
2009         if(self.motd_actived_time == 0)
2010         {
2011                 if (autocvar_g_campaign) {
2012                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2013                                 self.motd_actived_time = time;
2014                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2015                         }
2016                 } else {
2017                         if (self.BUTTON_INFO) {
2018                                 self.motd_actived_time = time;
2019                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2020                         }
2021                 }
2022         }
2023         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2024         {
2025                 if (autocvar_g_campaign) {
2026                         if (self.BUTTON_INFO)
2027                                 self.motd_actived_time = time;
2028                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2029                                 self.motd_actived_time = 0;
2030                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2031                         }
2032                 } else {
2033                         if (self.BUTTON_INFO)
2034                                 self.motd_actived_time = time;
2035                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2036                                 self.motd_actived_time = 0;
2037                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2038                         }
2039                 }
2040         }
2041         else //if(self.motd_actived_time < 0) // just connected, motd is active
2042         {
2043                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2044                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2045                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2046                 {
2047                         // instanctly hide MOTD
2048                         self.motd_actived_time = 0;
2049                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2050                 }
2051         }
2052 }
2053
2054 void ObserverThink()
2055 {
2056         float prefered_movetype;
2057         if (self.flags & FL_JUMPRELEASED) {
2058                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2059                         self.flags &= ~FL_JUMPRELEASED;
2060                         self.flags |= FL_SPAWNING;
2061                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2062                         self.flags &= ~FL_JUMPRELEASED;
2063                         if(SpectateNext()) {
2064                                 self.classname = "spectator";
2065                         }
2066                 } else {
2067                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2068                         if (self.movetype != prefered_movetype)
2069                                 self.movetype = prefered_movetype;
2070                 }
2071         } else {
2072                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2073                         self.flags |= FL_JUMPRELEASED;
2074                         if(self.flags & FL_SPAWNING)
2075                         {
2076                                 self.flags &= ~FL_SPAWNING;
2077                                 LeaveSpectatorMode();
2078                                 return;
2079                         }
2080                 }
2081         }
2082 }
2083
2084 void SpectatorThink()
2085 {
2086         if (self.flags & FL_JUMPRELEASED) {
2087                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2088                         self.flags &= ~FL_JUMPRELEASED;
2089                         self.flags |= FL_SPAWNING;
2090                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2091                         self.flags &= ~FL_JUMPRELEASED;
2092                         if(SpectateNext()) {
2093                                 self.classname = "spectator";
2094                         } else {
2095                                 self.classname = "observer";
2096                                 PutClientInServer();
2097                         }
2098                         self.impulse = 0;
2099                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2100                         self.flags &= ~FL_JUMPRELEASED;
2101                         if(SpectatePrev()) {
2102                                 self.classname = "spectator";
2103                         } else {
2104                                 self.classname = "observer";
2105                                 PutClientInServer();
2106                         }
2107                         self.impulse = 0;
2108                 } else if (self.BUTTON_ATCK2) {
2109                         self.flags &= ~FL_JUMPRELEASED;
2110                         self.classname = "observer";
2111                         PutClientInServer();
2112                 } else {
2113                         if(!SpectateUpdate())
2114                                 PutObserverInServer();
2115                 }
2116         } else {
2117                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2118                         self.flags |= FL_JUMPRELEASED;
2119                         if(self.flags & FL_SPAWNING)
2120                         {
2121                                 self.flags &= ~FL_SPAWNING;
2122                                 LeaveSpectatorMode();
2123                                 return;
2124                         }
2125                 }
2126                 if(!SpectateUpdate())
2127                         PutObserverInServer();
2128         }
2129
2130         self.flags |= FL_CLIENT | FL_NOTARGET;
2131 }
2132
2133 void PlayerUseKey()
2134 {
2135         if (!IS_PLAYER(self))
2136                 return;
2137
2138         if(self.vehicle)
2139         {
2140         vehicles_exit(VHEF_NORMAL);
2141         return;
2142         }
2143
2144         // a use key was pressed; call handlers
2145         MUTATOR_CALLHOOK(PlayerUseKey);
2146 }
2147
2148 /*
2149 =============
2150 PlayerPreThink
2151
2152 Called every frame for each client before the physics are run
2153 =============
2154 */
2155 .float usekeypressed;
2156 void() nexball_setstatus;
2157 .float items_added;
2158 void PlayerPreThink (void)
2159 {
2160         WarpZone_PlayerPhysics_FixVAngle();
2161
2162         self.stat_game_starttime = game_starttime;
2163         self.stat_round_starttime = round_starttime;
2164         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2165         self.stat_leadlimit = autocvar_leadlimit;
2166
2167         if(frametime)
2168         {
2169                 // physics frames: update anticheat stuff
2170                 anticheat_prethink();
2171         }
2172
2173         if(blockSpectators && frametime)
2174                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2175                 checkSpectatorBlock();
2176
2177         zoomstate_set = 0;
2178
2179         if(self.netname_previous != self.netname)
2180         {
2181                 if(autocvar_sv_eventlog)
2182                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2183                 if(self.netname_previous)
2184                         strunzone(self.netname_previous);
2185                 self.netname_previous = strzone(self.netname);
2186         }
2187
2188         // version nagging
2189         if(self.version_nagtime)
2190                 if(self.cvar_g_xonoticversion)
2191                         if(time > self.version_nagtime)
2192                         {
2193                                 // don't notify git users
2194                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2195                                 {
2196                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2197                                         {
2198                                                 // notify release users if connecting to git
2199                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2200                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2201                                         }
2202                                         else
2203                                         {
2204                                                 float r;
2205                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2206                                                 if(r < 0)
2207                                                 {
2208                                                         // give users new version
2209                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2210                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2211                                                 }
2212                                                 else if(r > 0)
2213                                                 {
2214                                                         // notify users about old server version
2215                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2216                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2217                                                 }
2218                                         }
2219                                 }
2220                                 self.version_nagtime = 0;
2221                         }
2222
2223         // GOD MODE info
2224         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2225         {
2226                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2227                 self.max_armorvalue = 0;
2228         }
2229
2230 #ifdef TETRIS
2231         if (TetrisPreFrame())
2232                 return;
2233 #endif
2234
2235         if(self.frozen == 2)
2236         {
2237                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2238                 self.health = max(1, self.revive_progress * start_health);
2239                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2240
2241                 if(self.revive_progress >= 1)
2242                         Unfreeze(self);
2243         }
2244         else if(self.frozen == 3)
2245         {
2246                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2247                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2248
2249                 if(self.health < 1)
2250                 {
2251                         if(self.vehicle)
2252                                 vehicles_exit(VHEF_RELESE);
2253                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2254                 }
2255                 else if ( self.revive_progress <= 0 )
2256                         Unfreeze(self);
2257         }
2258
2259         MUTATOR_CALLHOOK(PlayerPreThink);
2260
2261         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2262         {
2263                 if(self.BUTTON_USE && !self.usekeypressed)
2264                         PlayerUseKey();
2265                 self.usekeypressed = self.BUTTON_USE;
2266         }
2267
2268         if(IS_REAL_CLIENT(self))
2269                 PrintWelcomeMessage();
2270
2271         if(IS_PLAYER(self))
2272         {
2273
2274                 CheckRules_Player();
2275
2276                 if (intermission_running)
2277                 {
2278                         IntermissionThink ();   // otherwise a button could be missed between
2279                         return;                                 // the think tics
2280                 }
2281
2282                 //don't allow the player to turn around while game is paused!
2283                 if(timeout_status == TIMEOUT_ACTIVE) {
2284                         // FIXME turn this into CSQC stuff
2285                         self.v_angle = self.lastV_angle;
2286                         self.angles = self.lastV_angle;
2287                         self.fixangle = TRUE;
2288                 }
2289
2290                 if(frametime)
2291                 {
2292                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2293                         {
2294                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2295                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2296                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2297
2298                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2299                                 {
2300                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2301                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2302                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2303                                 }
2304                         }
2305                         else
2306                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2307
2308                         player_powerups();
2309                 }
2310
2311                 if (self.deadflag != DEAD_NO)
2312                 {
2313                         if(self.personal && g_race_qualifying)
2314                         {
2315                                 if(time > self.respawn_time)
2316                                 {
2317                                         self.respawn_time = time + 1; // only retry once a second
2318                                         self.stat_respawn_time = self.respawn_time;
2319                                         respawn();
2320                                         self.impulse = 141;
2321                                 }
2322                         }
2323                         else
2324                         {
2325                                 float button_pressed;
2326                                 if(frametime)
2327                                         player_anim();
2328                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2329
2330                                 if (self.deadflag == DEAD_DYING)
2331                                 {
2332                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2333                                                 self.deadflag = DEAD_RESPAWNING;
2334                                         else if(!button_pressed)
2335                                                 self.deadflag = DEAD_DEAD;
2336                                 }
2337                                 else if (self.deadflag == DEAD_DEAD)
2338                                 {
2339                                         if(button_pressed)
2340                                                 self.deadflag = DEAD_RESPAWNABLE;
2341                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2342                                                 self.deadflag = DEAD_RESPAWNING;
2343                                 }
2344                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2345                                 {
2346                                         if(!button_pressed)
2347                                                 self.deadflag = DEAD_RESPAWNING;
2348                                 }
2349                                 else if (self.deadflag == DEAD_RESPAWNING)
2350                                 {
2351                                         if(time > self.respawn_time)
2352                                         {
2353                                                 self.respawn_time = time + 1; // only retry once a second
2354                                                 self.respawn_time_max = self.respawn_time;
2355                                                 respawn();
2356                                         }
2357                                 }
2358
2359                                 ShowRespawnCountdown();
2360
2361                                 if(self.respawn_flags & RESPAWN_SILENT)
2362                                         self.stat_respawn_time = 0;
2363                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2364                                         self.stat_respawn_time = self.respawn_time_max;
2365                                 else
2366                                         self.stat_respawn_time = self.respawn_time;
2367                         }
2368
2369                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2370                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2371                                 self.stat_respawn_time *= -1;
2372
2373                         return;
2374                 }
2375
2376                 self.prevorigin = self.origin;
2377
2378                 float do_crouch = self.BUTTON_CROUCH;
2379                 if(self.hook.state)
2380                         do_crouch = 0;
2381                 if(self.vehicle)
2382                         do_crouch = 0;
2383                 if(self.frozen)
2384                         do_crouch = 0;
2385                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2386                         do_crouch = 0;
2387
2388                 if (do_crouch)
2389                 {
2390                         if (!self.crouch)
2391                         {
2392                                 self.crouch = TRUE;
2393                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2394                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2395                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2396                         }
2397                 }
2398                 else
2399                 {
2400                         if (self.crouch)
2401                         {
2402                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2403                                 if (!trace_startsolid)
2404                                 {
2405                                         self.crouch = FALSE;
2406                                         self.view_ofs = PL_VIEW_OFS;
2407                                         setsize (self, PL_MIN, PL_MAX);
2408                                 }
2409                         }
2410                 }
2411
2412                 FixPlayermodel();
2413
2414                 GrapplingHookFrame();
2415
2416                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2417                 //if(frametime)
2418                 {
2419                         self.items &= ~self.items_added;
2420
2421                         W_WeaponFrame();
2422
2423                         self.items_added = 0;
2424                         if(self.items & IT_JETPACK)
2425                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2426                                         self.items_added |= IT_FUEL;
2427
2428                         self.items |= self.items_added;
2429                 }
2430
2431                 player_regen();
2432
2433                 // rot nex charge to the charge limit
2434                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2435                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2436
2437                 if(frametime)
2438                         player_anim();
2439
2440                 // secret status
2441                 secrets_setstatus();
2442
2443                 // monsters status
2444                 monsters_setstatus();
2445
2446                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2447
2448                 //self.angles_y=self.v_angle_y + 90;   // temp
2449         } else if(gameover) {
2450                 if (intermission_running)
2451                         IntermissionThink ();   // otherwise a button could be missed between
2452                 return;
2453         } else if(IS_OBSERVER(self)) {
2454                 ObserverThink();
2455         } else if(IS_SPEC(self)) {
2456                 SpectatorThink();
2457         }
2458
2459         if(!zoomstate_set)
2460                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2461
2462         float oldspectatee_status;
2463         oldspectatee_status = self.spectatee_status;
2464         if(IS_SPEC(self))
2465                 self.spectatee_status = num_for_edict(self.enemy);
2466         else if(IS_OBSERVER(self))
2467                 self.spectatee_status = num_for_edict(self);
2468         else
2469                 self.spectatee_status = 0;
2470         if(self.spectatee_status != oldspectatee_status)
2471         {
2472                 ClientData_Touch(self);
2473         }
2474
2475         if(self.teamkill_soundtime)
2476         if(time > self.teamkill_soundtime)
2477         {
2478                 self.teamkill_soundtime = 0;
2479
2480                 entity oldpusher, oldself;
2481
2482                 oldself = self; self = self.teamkill_soundsource;
2483                 oldpusher = self.pusher; self.pusher = oldself;
2484
2485                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2486
2487                 self.pusher = oldpusher;
2488                 self = oldself;
2489         }
2490
2491         if(self.taunt_soundtime)
2492         if(time > self.taunt_soundtime)
2493         {
2494                 self.taunt_soundtime = 0;
2495                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2496         }
2497
2498         target_voicescript_next(self);
2499
2500         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2501         if(!self.weapon)
2502                 self.clip_load = self.clip_size = 0;
2503 }
2504
2505 float isInvisibleString(string s)
2506 {
2507         float i, n, c;
2508         s = strdecolorize(s);
2509         for((i = 0), (n = strlen(s)); i < n; ++i)
2510         {
2511                 c = str2chr(s, i);
2512                 switch(c)
2513                 {
2514                         case 0:
2515                         case 32: // space
2516                                 break;
2517                         case 192: // charmap space
2518                                 if (!autocvar_utf8_enable)
2519                                         break;
2520                                 return FALSE;
2521                         case 160: // space in unicode fonts
2522                         case 0xE000 + 192: // utf8 charmap space
2523                                 if (autocvar_utf8_enable)
2524                                         break;
2525                         default:
2526                                 return FALSE;
2527                 }
2528         }
2529         return TRUE;
2530 }
2531
2532 /*
2533 =============
2534 PlayerPostThink
2535
2536 Called every frame for each client after the physics are run
2537 =============
2538 */
2539 .float idlekick_lasttimeleft;
2540 void PlayerPostThink (void)
2541 {
2542         // Savage: Check for nameless players
2543         if (isInvisibleString(self.netname)) {
2544                 self.netname = "Player";
2545                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2546         }
2547
2548         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2549         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2550         {
2551                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2552                 {
2553                         if(self.idlekick_lasttimeleft)
2554                         {
2555                                 self.idlekick_lasttimeleft = 0;
2556                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2557                         }
2558                 }
2559                 else
2560                 {
2561                         float timeleft;
2562                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2563                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2564                         {
2565                                 if(!self.idlekick_lasttimeleft)
2566                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2567                         }
2568                         if(timeleft <= 0)
2569                         {
2570                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2571                                 dropclient(self);
2572                                 return;
2573                         }
2574                         else if(timeleft <= 10)
2575                         {
2576                                 if(timeleft != self.idlekick_lasttimeleft)
2577                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2578                                 self.idlekick_lasttimeleft = timeleft;
2579                         }
2580                 }
2581         }
2582
2583 #ifdef TETRIS
2584         if(self.impulse == 100)
2585                 ImpulseCommands();
2586         if (!TetrisPostFrame())
2587         {
2588 #endif
2589
2590         CheatFrame();
2591
2592         //CheckPlayerJump();
2593
2594         if(IS_PLAYER(self)) {
2595                 CheckRules_Player();
2596                 UpdateChatBubble();
2597                 if (self.impulse)
2598                         ImpulseCommands();
2599                 if (intermission_running)
2600                         return;         // intermission or finale
2601                 GetPressedKeys();
2602         }
2603
2604 #ifdef TETRIS
2605         }
2606 #endif
2607
2608         /*
2609         float i;
2610         for(i = 0; i < 1000; ++i)
2611         {
2612                 vector end;
2613                 end = self.origin + '0 0 1024' + 512 * randomvec();
2614                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2615                 if(trace_fraction < 1)
2616                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2617                 {
2618                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2619                         break;
2620                 }
2621         }
2622         */
2623
2624         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2625
2626         if(self.waypointsprite_attachedforcarrier)
2627                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2628
2629         playerdemo_write();
2630
2631         CSQCMODEL_AUTOUPDATE();
2632 }