qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         if (g_minstagib)
 408                 minstagib_stop_countdown();
 409
 410         Portal_ClearAll(self);
 411
 412         if(self.alivetime)
 413         {
 414                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 415                 self.alivetime = 0;
 416         }
 417
 418         if(self.vehicle)
 419             vehicles_exit(VHEF_RELESE);
 420
 421         if(self.flagcarried)
 422                 DropFlag(self.flagcarried, world, world);
 423
 424         if(self.ballcarried && g_nexball)
 425                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 426
 427         WaypointSprite_PlayerDead();
 428
 429         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 430                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 431
 432         if(self.killcount != -666) {
 433                 if(g_lms) {
 434                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 435                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 436                         else
 437                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 438                 } else
 439                         bprint ("^4", self.netname, "^4 is spectating now\n");
 440
 441                 if(self.just_joined == FALSE) {
 442                         LogTeamchange(self.playerid, -1, 4);
 443                 } else
 444                         self.just_joined = FALSE;
 445         }
 446
 447         PlayerScore_Clear(self); // clear scores when needed
 448
 449         accuracy_resend(self);
 450
 451         self.spectatortime = time;
 452
 453         self.classname = "observer";
 454         self.iscreature = FALSE;
 455         self.damagedbycontents = FALSE;
 456         self.health = -666;
 457         self.takedamage = DAMAGE_NO;
 458         self.solid = SOLID_NOT;
 459         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 460         self.flags = FL_CLIENT | FL_NOTARGET;
 461         self.armorvalue = 666;
 462         self.effects = 0;
 463         self.armorvalue = autocvar_g_balance_armor_start;
 464         self.pauserotarmor_finished = 0;
 465         self.pauserothealth_finished = 0;
 466         self.pauseregen_finished = 0;
 467         self.damageforcescale = 0;
 468         self.death_time = 0;
 469         self.alpha = 0;
 470         self.scale = 0;
 471         self.fade_time = 0;
 472         self.pain_frame = 0;
 473         self.pain_finished = 0;
 474         self.strength_finished = 0;
 475         self.invincible_finished = 0;
 476         self.pushltime = 0;
 477         self.think = SUB_Null;
 478         self.nextthink = 0;
 479         self.hook_time = 0;
 480         self.runes = 0;
 481         self.deadflag = DEAD_NO;
 482         self.angles = spot.angles;
 483         self.angles_z = 0;
 484         self.fixangle = TRUE;
 485         self.crouch = FALSE;
 486
 487         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 488         self.prevorigin = self.origin;
 489         self.items = 0;
 490         self.weapons = 0;
 491         self.model = "";
 492         FixPlayermodel();
 493         setmodel(self, "null");
 494         self.drawonlytoclient = self;
 495
 496         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 497         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 498
 499         self.weapon = 0;
 500         self.weaponname = "";
 501         self.switchingweapon = 0;
 502         self.weaponmodel = "";
 503         self.weaponentity = world;
 504         self.exteriorweaponentity = world;
 505         self.killcount = -666;
 506         self.velocity = '0 0 0';
 507         self.avelocity = '0 0 0';
 508         self.punchangle = '0 0 0';
 509         self.punchvector = '0 0 0';
 510         self.oldvelocity = self.velocity;
 511         self.fire_endtime = -1;
 512
 513         if(g_arena)
 514         {
 515                 if(self.version_mismatch)
 516                 {
 517                         Spawnqueue_Unmark(self);
 518                         Spawnqueue_Remove(self);
 519                 }
 520                 else
 521                 {
 522                         Spawnqueue_Insert(self);
 523                 }
 524         }
 525         else if(g_lms)
 526         {
 527                 // Only if the player cannot play at all
 528                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 529                         self.frags = FRAGS_SPECTATOR;
 530                 else
 531                         self.frags = FRAGS_LMS_LOSER;
 532         }
 533         else if(g_ca)
 534         {
 535                 if(self.caplayer)
 536                         self.frags = FRAGS_LMS_LOSER;
 537                 else
 538                         self.frags = FRAGS_SPECTATOR;
 539         }
 540         else
 541                 self.frags = FRAGS_SPECTATOR;
 542 }
 543
 544 .float model_randomizer;
 545 void FixPlayermodel()
 546 {
 547         string defaultmodel;
 548         float defaultskin, chmdl, oldskin, n, i;
 549         vector m1, m2;
 550
 551         defaultmodel = "";
 552
 553         if(autocvar_sv_defaultcharacter == 1)
 554         {
 555                 defaultskin = 0;
 556
 557                 if(teamplay)
 558                 {
 559                         string s;
 560                         s = Team_ColorNameLowerCase(self.team);
 561                         if(s != "neutral")
 562                         {
 563                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 564                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 565                         }
 566                 }
 567
 568                 if(defaultmodel == "")
 569                 {
 570                         defaultmodel = autocvar_sv_defaultplayermodel;
 571                         defaultskin = autocvar_sv_defaultplayerskin;
 572                 }
 573
 574                 n = tokenize_console(defaultmodel);
 575                 if(n > 0)
 576                         defaultmodel = argv(floor(n * self.model_randomizer));
 577
 578                 i = strstrofs(defaultmodel, ":", 0);
 579                 if(i >= 0)
 580                 {
 581                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 582                         defaultmodel = substring(defaultmodel, 0, i);
 583                 }
 584         }
 585
 586         if(defaultmodel != "")
 587         {
 588                 if (defaultmodel != self.model)
 589                 {
 590                         m1 = self.mins;
 591                         m2 = self.maxs;
 592                         setplayermodel (self, defaultmodel);
 593                         setsize (self, m1, m2);
 594                         chmdl = TRUE;
 595                 }
 596
 597                 oldskin = self.skin;
 598                 self.skin = defaultskin;
 599         } else {
 600                 if (self.playermodel != self.model || self.playermodel == "")
 601                 {
 602                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 603                         m1 = self.mins;
 604                         m2 = self.maxs;
 605                         setplayermodel (self, self.playermodel);
 606                         setsize (self, m1, m2);
 607                         chmdl = TRUE;
 608                 }
 609
 610                 oldskin = self.skin;
 611                 self.skin = stof(self.playerskin);
 612         }
 613
 614         if(chmdl || oldskin != self.skin)
 615                 self.species = player_getspecies(); // model or skin has changed
 616
 617         if(!teamplay)
 618                 if(strlen(autocvar_sv_defaultplayercolors))
 619                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 620                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 621 }
 622
 623 void PlayerTouchExplode(entity p1, entity p2)
 624 {
 625         vector org;
 626         org = (p1.origin + p2.origin) * 0.5;
 627         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 628
 629         te_explosion(org);
 630
 631         entity e;
 632         e = spawn();
 633         setorigin(e, org);
 634         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 635         remove(e);
 636 }
 637
 638 /*
 639 =============
 640 PutClientInServer
 641
 642 Called when a client spawns in the server
 643 =============
 644 */
 645 //void() ctf_playerchanged;
 646 void PutClientInServer (void)
 647 {
 648         if(clienttype(self) == CLIENTTYPE_BOT)
 649         {
 650                 self.classname = "player";
 651         }
 652         else if(clienttype(self) == CLIENTTYPE_REAL)
 653         {
 654                 msg_entity = self;
 655                 WriteByte(MSG_ONE, SVC_SETVIEW);
 656                 WriteEntity(MSG_ONE, self);
 657         }
 658
 659         // reset player keys
 660         self.itemkeys = 0;
 661
 662         // player is dead and becomes observer
 663         // FIXME fix LMS scoring for new system
 664         if(g_lms)
 665         {
 666                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 667                         self.classname = "observer";
 668         }
 669
 670         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
 671                 self.classname = "observer";
 672
 673         if(gameover)
 674                 self.classname = "observer";
 675
 676         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 677                 entity spot, oldself;
 678                 float j;
 679
 680                 accuracy_resend(self);
 681
 682                 if(self.team < 0)
 683                         JoinBestTeam(self, FALSE, TRUE);
 684
 685                 race_PreSpawn();
 686
 687                 spot = SelectSpawnPoint (FALSE);
 688                 if(!spot)
 689                 {
 690                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 691                         return; // spawn failed
 692                 }
 693
 694                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 695
 696                 self.classname = "player";
 697                 self.wasplayer = TRUE;
 698                 self.iscreature = TRUE;
 699                 self.damagedbycontents = TRUE;
 700                 self.movetype = MOVETYPE_WALK;
 701                 self.solid = SOLID_SLIDEBOX;
 702                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 703                 if(autocvar_g_playerclip_collisions)
 704                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 705                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 706                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 707                 self.frags = FRAGS_PLAYER;
 708                 if(INDEPENDENT_PLAYERS)
 709                         MAKE_INDEPENDENT_PLAYER(self);
 710                 self.flags = FL_CLIENT;
 711                 if(autocvar__notarget)
 712                         self.flags |= FL_NOTARGET;
 713                 self.takedamage = DAMAGE_AIM;
 714                 if(g_minstagib)
 715                         self.effects = EF_FULLBRIGHT;
 716                 else
 717                         self.effects = 0;
 718                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 719                 self.air_finished = time + 12;
 720                 self.dmg = 2;
 721                 if(autocvar_g_balance_nex_charge)
 722                 {
 723                         if(autocvar_g_balance_nex_secondary_chargepool)
 724                                 self.nex_chargepool_ammo = 1;
 725                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 726                 }
 727
 728                 if(inWarmupStage)
 729                 {
 730                         self.ammo_shells = warmup_start_ammo_shells;
 731                         self.ammo_nails = warmup_start_ammo_nails;
 732                         self.ammo_rockets = warmup_start_ammo_rockets;
 733                         self.ammo_cells = warmup_start_ammo_cells;
 734                         self.ammo_fuel = warmup_start_ammo_fuel;
 735                         self.health = warmup_start_health;
 736                         self.armorvalue = warmup_start_armorvalue;
 737                         self.weapons = warmup_start_weapons;
 738                 }
 739                 else
 740                 {
 741                         self.ammo_shells = start_ammo_shells;
 742                         self.ammo_nails = start_ammo_nails;
 743                         self.ammo_rockets = start_ammo_rockets;
 744                         self.ammo_cells = start_ammo_cells;
 745                         self.ammo_fuel = start_ammo_fuel;
 746                         self.health = start_health;
 747                         self.armorvalue = start_armorvalue;
 748                         self.weapons = start_weapons;
 749                 }
 750
 751                 if(g_weaponarena_random)
 752                 {
 753                         if(g_weaponarena_random_with_laser)
 754                                 self.weapons &~= WEPBIT_LASER;
 755                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 756                         if(g_weaponarena_random_with_laser)
 757                                 self.weapons |= WEPBIT_LASER;
 758                 }
 759
 760                 self.items = start_items;
 761
 762                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 763                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 764                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 765                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 766                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 767                 //extend the pause of rotting if client was reset at the beginning of the countdown
 768                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 769                         self.spawnshieldtime += game_starttime - time;
 770                         self.pauserotarmor_finished += game_starttime - time;
 771                         self.pauserothealth_finished += game_starttime - time;
 772                         self.pauseregen_finished += game_starttime - time;
 773                 }
 774                 self.damageforcescale = 2;
 775                 self.death_time = 0;
 776                 self.scale = 0;
 777                 self.fade_time = 0;
 778                 self.pain_frame = 0;
 779                 self.pain_finished = 0;
 780                 self.strength_finished = 0;
 781                 self.invincible_finished = 0;
 782                 self.pushltime = 0;
 783                 // players have no think function
 784                 self.think = SUB_Null;
 785                 self.nextthink = 0;
 786                 self.hook_time = 0;
 787                 self.dmg_team = 0;
 788                 self.ballistics_density = autocvar_g_ballistics_density_player;
 789
 790                 self.metertime = 0;
 791
 792                 self.runes = 0;
 793
 794                 self.deadflag = DEAD_NO;
 795
 796                 self.angles = spot.angles;
 797
 798                 self.angles_z = 0; // never spawn tilted even if the spot says to
 799                 self.fixangle = TRUE; // turn this way immediately
 800                 self.velocity = '0 0 0';
 801                 self.avelocity = '0 0 0';
 802                 self.punchangle = '0 0 0';
 803                 self.punchvector = '0 0 0';
 804                 self.oldvelocity = self.velocity;
 805                 self.fire_endtime = -1;
 806
 807                 msg_entity = self;
 808                 WRITESPECTATABLE_MSG_ONE({
 809                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 810                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 811                 });
 812
 813                 self.model = "";
 814                 FixPlayermodel();
 815                 self.drawonlytoclient = world;
 816
 817                 self.crouch = FALSE;
 818                 self.view_ofs = PL_VIEW_OFS;
 819                 setsize (self, PL_MIN, PL_MAX);
 820                 self.spawnorigin = spot.origin;
 821                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 822                 // don't reset back to last position, even if new position is stuck in solid
 823                 self.oldorigin = self.origin;
 824                 self.prevorigin = self.origin;
 825                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 826                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 827         self.hud = HUD_NORMAL;
 828
 829                 if(g_arena)
 830                 {
 831                         Spawnqueue_Remove(self);
 832                         Spawnqueue_Mark(self);
 833                 }
 834                 else if(g_ca)
 835                         self.caplayer = 1;
 836
 837                 self.event_damage = PlayerDamage;
 838
 839                 self.bot_attack = TRUE;
 840
 841                 self.statdraintime = time + 5;
 842                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 843
 844                 if(self.killcount == -666) {
 845                         PlayerScore_Clear(self);
 846                         self.killcount = 0;
 847                 }
 848
 849                 CL_SpawnWeaponentity();
 850                 self.alpha = default_player_alpha;
 851                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 852                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 853
 854                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 855                 self.lms_traveled_distance = 0;
 856                 self.speedrunning = FALSE;
 857
 858                 race_PostSpawn(spot);
 859
 860                 //stuffcmd(self, "chase_active 0");
 861                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 862
 863                 if (autocvar_g_spawnsound)
 864                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 865
 866                 if(g_assault) {
 867                         if(self.team == assault_attacker_team)
 868                                 centerprint(self, "You are attacking!");
 869                         else
 870                                 centerprint(self, "You are defending!");
 871                 }
 872
 873                 target_voicescript_clear(self);
 874
 875                 // reset fields the weapons may use
 876                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 877                 {
 878                         weapon_action(j, WR_RESETPLAYER);
 879
 880                         // all weapons must be fully loaded when we spawn
 881                         entity e;
 882                         e = get_weaponinfo(j);
 883                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 884                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 885                 }
 886
 887                 oldself = self;
 888                 self = spot;
 889                         activator = oldself;
 890                                 string s;
 891                                 s = self.target;
 892                                 self.target = string_null;
 893                                 SUB_UseTargets();
 894                                 self.target = s;
 895                         activator = world;
 896                 self = oldself;
 897
 898                 spawn_spot = spot;
 899                 MUTATOR_CALLHOOK(PlayerSpawn);
 900
 901                 if(autocvar_spawn_debug)
 902                 {
 903                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 904                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 905                 }
 906
 907                 self.switchweapon = w_getbestweapon(self);
 908                 self.cnt = -1; // W_LastWeapon will not complain
 909                 self.weapon = 0;
 910                 self.weaponname = "";
 911                 self.switchingweapon = 0;
 912
 913                 if(!self.alivetime)
 914                         self.alivetime = time;
 915
 916                 antilag_clear(self);
 917         } else if(self.classname == "observer") {
 918                 PutObserverInServer ();
 919         }
 920
 921         //if(g_ctf)
 922         //      ctf_playerchanged();
 923 }
 924
 925 .float ebouncefactor, ebouncestop; // electro's values
 926 // TODO do we need all these fields, or should we stop autodetecting runtime
 927 // changes and just have a console command to update this?
 928 float ClientInit_SendEntity(entity to, float sf)
 929 {
 930         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 931         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 932         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 933         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 934         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 935         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 936         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 937         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 938         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 939         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 940         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 941         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 942         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 943         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 944         if(sv_foginterval && world.fog != "")
 945                 WriteString(MSG_ENTITY, world.fog);
 946         else
 947                 WriteString(MSG_ENTITY, "");
 948         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 949         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 950         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 951         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 952         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 953         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 954         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 955         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 956         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 957         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 958         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 959         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 960         return TRUE;
 961 }
 962
 963 void ClientInit_CheckUpdate()
 964 {
 965         self.nextthink = time;
 966         if(self.count != autocvar_g_balance_armor_blockpercent)
 967         {
 968                 self.count = autocvar_g_balance_armor_blockpercent;
 969                 self.SendFlags |= 1;
 970         }
 971         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 972         {
 973                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 974                 self.SendFlags |= 1;
 975         }
 976         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 977         {
 978                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 979                 self.SendFlags |= 1;
 980         }
 981         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 982         {
 983                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 984                 self.SendFlags |= 1;
 985         }
 986         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 987         {
 988                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 989                 self.SendFlags |= 1;
 990         }
 991         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 992         {
 993                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 994                 self.SendFlags |= 1;
 995         }
 996 }
 997
 998 void ClientInit_Spawn()
 999 {
1000         entity o;
1001         entity e;
1002         e = spawn();
1003         e.classname = "clientinit";
1004         e.think = ClientInit_CheckUpdate;
1005         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1006
1007         o = self;
1008         self = e;
1009         ClientInit_CheckUpdate();
1010         self = o;
1011 }
1012
1013 /*
1014 =============
1015 SetNewParms
1016 =============
1017 */
1018 void SetNewParms (void)
1019 {
1020         // initialize parms for a new player
1021         parm1 = -(86400 * 366);
1022 }
1023
1024 /*
1025 =============
1026 SetChangeParms
1027 =============
1028 */
1029 void SetChangeParms (void)
1030 {
1031         // save parms for level change
1032         parm1 = self.parm_idlesince - time;
1033 }
1034
1035 /*
1036 =============
1037 DecodeLevelParms
1038 =============
1039 */
1040 void DecodeLevelParms (void)
1041 {
1042         // load parms
1043         self.parm_idlesince = parm1;
1044         if(self.parm_idlesince == -(86400 * 366))
1045                 self.parm_idlesince = time;
1046
1047         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1048         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1049 }
1050
1051 /*
1052 =============
1053 ClientKill
1054
1055 Called when a client types 'kill' in the console
1056 =============
1057 */
1058
1059 .float clientkill_nexttime;
1060 void ClientKill_Now_TeamChange()
1061 {
1062         if(self.killindicator_teamchange == -1)
1063         {
1064                 self.team = -1;
1065                 JoinBestTeam( self, FALSE, FALSE );
1066         }
1067         else if(self.killindicator_teamchange == -2)
1068         {
1069                 if(g_ca)
1070                         self.caplayer = 0;
1071                 if(blockSpectators)
1072                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1073                 PutObserverInServer();
1074         }
1075         else
1076                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1077 }
1078
1079 void ClientKill_Now()
1080 {
1081         if(self.vehicle)
1082         {
1083             vehicles_exit(VHEF_RELESE);
1084             if(!self.killindicator_teamchange)
1085             {
1086             self.vehicle_health = -1;
1087             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1088             }
1089         }
1090
1091         if(self.killindicator && !wasfreed(self.killindicator))
1092                 remove(self.killindicator);
1093
1094         self.killindicator = world;
1095
1096         if(self.killindicator_teamchange)
1097                 ClientKill_Now_TeamChange();
1098
1099         // in any case:
1100         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1101
1102         // now I am sure the player IS dead
1103 }
1104 void KillIndicator_Think()
1105 {
1106         if (gameover)
1107         {
1108                 self.owner.killindicator = world;
1109                 remove(self);
1110                 return;
1111         }
1112
1113         if (self.owner.alpha < 0)
1114         {
1115                 self.owner.killindicator = world;
1116                 remove(self);
1117                 return;
1118         }
1119
1120         if(self.cnt <= 0)
1121         {
1122                 self = self.owner;
1123                 ClientKill_Now(); // no oldself needed
1124                 return;
1125         }
1126     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1127     {
1128         self.nextthink = time + 1;
1129         self.cnt -= 1;
1130     }
1131         else
1132         {
1133                 if(self.cnt <= 10)
1134                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1135                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1136                 {
1137                         if(self.cnt <= 10)
1138                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1139                 }
1140                 self.nextthink = time + 1;
1141                 self.cnt -= 1;
1142         }
1143 }
1144
1145 float clientkilltime;
1146 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1147 {
1148         float killtime;
1149         float starttime;
1150         entity e;
1151
1152         if (gameover)
1153                 return;
1154
1155         killtime = autocvar_g_balance_kill_delay;
1156
1157         if(g_race_qualifying || g_cts)
1158                 killtime = 0;
1159
1160     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1161     {
1162                 remove(self.killindicator);
1163                 self.killindicator = world;
1164
1165         ClientKill_Now(); // allow instant kill in this case
1166         return;
1167     }
1168
1169         self.killindicator_teamchange = targetteam;
1170
1171     if(!self.killindicator)
1172         {
1173                 if(self.deadflag == DEAD_NO)
1174                 {
1175                         killtime = max(killtime, self.clientkill_nexttime - time);
1176                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1177                 }
1178
1179                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1180                 {
1181                         ClientKill_Now();
1182                 }
1183                 else
1184                 {
1185                         starttime = max(time, clientkilltime);
1186
1187                         self.killindicator = spawn();
1188                         self.killindicator.owner = self;
1189                         self.killindicator.scale = 0.5;
1190                         setattachment(self.killindicator, self, "");
1191                         setorigin(self.killindicator, '0 0 52');
1192                         self.killindicator.think = KillIndicator_Think;
1193                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1194                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1195                         self.killindicator.cnt = ceil(killtime);
1196                         self.killindicator.count = bound(0, ceil(killtime), 10);
1197                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1198
1199                         for(e = world; (e = find(e, classname, "body")) != world; )
1200                         {
1201                                 if(e.enemy != self)
1202                                         continue;
1203                                 e.killindicator = spawn();
1204                                 e.killindicator.owner = e;
1205                                 e.killindicator.scale = 0.5;
1206                                 setattachment(e.killindicator, e, "");
1207                                 setorigin(e.killindicator, '0 0 52');
1208                                 e.killindicator.think = KillIndicator_Think;
1209                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1210                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1211                                 e.killindicator.cnt = ceil(killtime);
1212                         }
1213                         self.lip = 0;
1214                 }
1215         }
1216         if(self.killindicator)
1217         {
1218                 if(targetteam == 0) // just die
1219                 {
1220                         self.killindicator.colormod = '0 0 0';
1221                         if(clienttype(self) == CLIENTTYPE_REAL)
1222                         if(self.killindicator.cnt > 0)
1223                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1224                 }
1225                 else if(targetteam == -1) // auto
1226                 {
1227                         self.killindicator.colormod = '0 1 0';
1228                         if(clienttype(self) == CLIENTTYPE_REAL)
1229                         if(self.killindicator.cnt > 0)
1230                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1231                 }
1232                 else if(targetteam == -2) // spectate
1233                 {
1234                         self.killindicator.colormod = '0.5 0.5 0.5';
1235                         if(clienttype(self) == CLIENTTYPE_REAL)
1236                         if(self.killindicator.cnt > 0)
1237                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1238                 }
1239                 else
1240                 {
1241                         self.killindicator.colormod = TeamColor(targetteam);
1242                         if(clienttype(self) == CLIENTTYPE_REAL)
1243                         if(self.killindicator.cnt > 0)
1244                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1245                 }
1246         }
1247
1248 }
1249
1250 void ClientKill (void)
1251 {
1252         if (gameover)
1253                 return;
1254
1255         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1256         {
1257                 // do nothing
1258         }
1259     else if(self.freezetag_frozen)
1260     {
1261         // do nothing
1262     }
1263         else
1264                 ClientKill_TeamChange(0);
1265 }
1266
1267 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1268 {
1269     e.killindicator = spawn();
1270     e.killindicator.owner = e;
1271     e.killindicator.think = KillIndicator_Think;
1272     e.killindicator.nextthink = time + (e.lip) * 0.05;
1273     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1274     e.killindicator.health = 1; // this is used to indicate that it should be silent
1275     e.lip = 0;
1276 }
1277
1278 void FixClientCvars(entity e)
1279 {
1280         // send prediction settings to the client
1281         stuffcmd(e, "\nin_bindmap 0 0\n");
1282         if(g_race || g_cts)
1283                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1284         if(autocvar_g_antilag == 3) // client side hitscan
1285                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1286         if(sv_gentle)
1287                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1288         /*
1289          * we no longer need to stuff this. Remove this comment block if you feel
1290          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1291         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1292         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1293         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1294         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1295         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1296         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1297         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1298         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1299         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1300         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1301         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1302         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1303         stuffcmd(e, "cl_movement_edgefriction 1\n");
1304          */
1305 }
1306
1307 float PlayerInIDList(entity p, string idlist)
1308 {
1309         float n, i;
1310         string s;
1311
1312         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1313         if not(p.crypto_idfp)
1314                 return 0;
1315
1316         // this function allows abbreviated player IDs too!
1317         n = tokenize_console(idlist);
1318         for(i = 0; i < n; ++i)
1319         {
1320                 s = argv(i);
1321                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1322                         return 1;
1323         }
1324
1325         return 0;
1326 }
1327
1328 /*
1329 =============
1330 ClientConnect
1331
1332 Called when a client connects to the server
1333 =============
1334 */
1335 //void ctf_clientconnect();
1336 string ColoredTeamName(float t);
1337 void DecodeLevelParms (void);
1338 //void dom_player_join_team(entity pl);
1339 void set_dom_state(entity e);
1340 void ClientConnect (void)
1341 {
1342         float t;
1343
1344         if(self.flags & FL_CLIENT)
1345         {
1346                 print("Warning: ClientConnect, but already connected!\n");
1347                 return;
1348         }
1349
1350         if(Ban_MaybeEnforceBan(self))
1351                 return;
1352
1353         DecodeLevelParms();
1354
1355 #ifdef WATERMARK
1356         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1357 #endif
1358
1359         self.classname = "player_joining";
1360
1361         self.flags = FL_CLIENT;
1362         self.version_nagtime = time + 10 + random() * 10;
1363
1364         if(player_count<0)
1365         {
1366                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1367                 player_count = 0;
1368         }
1369
1370         PlayerScore_Attach(self);
1371         ClientData_Attach();
1372         accuracy_init(self);
1373
1374         bot_clientconnect();
1375
1376         playerdemo_init();
1377
1378         anticheat_init();
1379
1380         race_PreSpawnObserver();
1381
1382         //if(g_domination)
1383         //      dom_player_join_team(self);
1384
1385         // identify the right forced team
1386         if(autocvar_g_campaign)
1387         {
1388                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1389                 {
1390                         switch(autocvar_g_campaign_forceteam)
1391                         {
1392                                 case 1: self.team_forced = COLOR_TEAM1; break;
1393                                 case 2: self.team_forced = COLOR_TEAM2; break;
1394                                 case 3: self.team_forced = COLOR_TEAM3; break;
1395                                 case 4: self.team_forced = COLOR_TEAM4; break;
1396                                 default: self.team_forced = 0;
1397                         }
1398                 }
1399         }
1400         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1401                 self.team_forced = COLOR_TEAM1;
1402         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1403                 self.team_forced = COLOR_TEAM2;
1404         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1405                 self.team_forced = COLOR_TEAM3;
1406         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1407                 self.team_forced = COLOR_TEAM4;
1408         else if(autocvar_g_forced_team_otherwise == "red")
1409                 self.team_forced = COLOR_TEAM1;
1410         else if(autocvar_g_forced_team_otherwise == "blue")
1411                 self.team_forced = COLOR_TEAM2;
1412         else if(autocvar_g_forced_team_otherwise == "yellow")
1413                 self.team_forced = COLOR_TEAM3;
1414         else if(autocvar_g_forced_team_otherwise == "pink")
1415                 self.team_forced = COLOR_TEAM4;
1416         else if(autocvar_g_forced_team_otherwise == "spectate")
1417                 self.team_forced = -1;
1418         else if(autocvar_g_forced_team_otherwise == "spectator")
1419                 self.team_forced = -1;
1420         else
1421                 self.team_forced = 0;
1422
1423         if(!teamplay)
1424                 if(self.team_forced > 0)
1425                         self.team_forced = 0;
1426
1427         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1428
1429         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1430                 self.classname = "observer";
1431         } else {
1432                 if(teamplay)
1433                 {
1434                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1435                         {
1436                                 self.classname = "player";
1437                                 campaign_bots_may_start = 1;
1438                         }
1439                         else
1440                         {
1441                                 self.classname = "observer"; // do it anyway
1442                         }
1443                 }
1444                 else
1445                 {
1446                         self.classname = "player";
1447                         campaign_bots_may_start = 1;
1448                 }
1449         }
1450
1451         self.playerid = (playerid_last = playerid_last + 1);
1452
1453         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1454
1455     if(clienttype(self) == CLIENTTYPE_BOT)
1456         PlayerStats_AddPlayer(self);
1457
1458         if(autocvar_sv_eventlog)
1459                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1460
1461         LogTeamchange(self.playerid, self.team, 1);
1462
1463         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1464
1465         self.netname_previous = strzone(self.netname);
1466
1467         bprint("^4", self.netname, "^4 connected");
1468
1469         if(self.classname != "observer" && (g_domination || g_ctf))
1470                 bprint(" and joined the ", ColoredTeamName(self.team));
1471
1472         bprint("\n");
1473
1474         stuffcmd(self, strcat(clientstuff, "\n"));
1475         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1476
1477         FixClientCvars(self);
1478
1479         // spawnfunc_waypoint sprites
1480         WaypointSprite_InitClient(self);
1481
1482         // Wazat's grappling hook
1483         SetGrappleHookBindings();
1484
1485         // get version info from player
1486         stuffcmd(self, "cmd clientversion $gameversion\n");
1487
1488         // get other cvars from player
1489         GetCvars(0);
1490
1491         // notify about available teams
1492         if(teamplay)
1493         {
1494                 CheckAllowedTeams(self);
1495                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1496                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1497         }
1498         else
1499                 stuffcmd(self, "set _teams_available 0\n");
1500
1501         if(g_arena || g_ca)
1502         {
1503                 self.classname = "observer";
1504                 if(g_arena)
1505                         Spawnqueue_Insert(self);
1506         }
1507         /*else if(g_ctf)
1508         {
1509                 ctf_clientconnect();
1510         }*/
1511
1512         attach_entcs();
1513
1514         bot_relinkplayerlist();
1515
1516         self.spectatortime = time;
1517         if(blockSpectators)
1518         {
1519                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1520         }
1521
1522         self.jointime = time;
1523         self.allowed_timeouts = autocvar_sv_timeout_number;
1524
1525         if(clienttype(self) == CLIENTTYPE_REAL)
1526         {
1527                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1528                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1529         }
1530
1531         if(g_lms)
1532         {
1533                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1534                 {
1535                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1536                         self.frags = FRAGS_SPECTATOR;
1537                 }
1538         }
1539
1540         if(!sv_foginterval && world.fog != "")
1541                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1542
1543         SoundEntity_Attach(self);
1544
1545         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1546         {
1547                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1548                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1549         }
1550         else
1551                 self.hitplotfh = -1;
1552
1553         if(g_race || g_cts) {
1554                 string rr;
1555                 if(g_cts)
1556                         rr = CTS_RECORD;
1557                 else
1558                         rr = RACE_RECORD;
1559                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1560
1561                 msg_entity = self;
1562                 race_send_recordtime(MSG_ONE);
1563                 race_send_speedaward(MSG_ONE);
1564
1565                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1566                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1567                 race_send_speedaward_alltimebest(MSG_ONE);
1568
1569                 float i;
1570                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1571                         race_SendRankings(i, 0, 0, MSG_ONE);
1572                 }
1573         }
1574         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1575                 send_CSQC_teamnagger();
1576
1577         if (g_domination)
1578                 set_dom_state(self);
1579
1580         CheatInitClient();
1581
1582         if(!autocvar_g_campaign)
1583                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1584
1585         CSQCMODEL_AUTOINIT();
1586
1587         self.model_randomizer = random();
1588 }
1589
1590 /*
1591 =============
1592 ClientDisconnect
1593
1594 Called when a client disconnects from the server
1595 =============
1596 */
1597 .entity chatbubbleentity;
1598 void ReadyCount();
1599 void ClientDisconnect (void)
1600 {
1601         if(self.vehicle)
1602             vehicles_exit(VHEF_RELESE);
1603
1604         if not(self.flags & FL_CLIENT)
1605         {
1606                 print("Warning: ClientDisconnect without ClientConnect\n");
1607                 return;
1608         }
1609
1610         PlayerStats_AddGlobalInfo(self);
1611
1612         CheatShutdownClient();
1613
1614         if(self.hitplotfh >= 0)
1615         {
1616                 fclose(self.hitplotfh);
1617                 self.hitplotfh = -1;
1618         }
1619
1620         anticheat_report();
1621         anticheat_shutdown();
1622
1623         playerdemo_shutdown();
1624
1625         bot_clientdisconnect();
1626
1627         if(self.entcs)
1628                 detach_entcs();
1629
1630         if(autocvar_sv_eventlog)
1631                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1632         bprint ("^4",self.netname);
1633         bprint ("^4 disconnected\n");
1634
1635         SoundEntity_Detach(self);
1636
1637         DropAllRunes(self);
1638         MUTATOR_CALLHOOK(ClientDisconnect);
1639
1640         Portal_ClearAll(self);
1641
1642         RemoveGrapplingHook(self);
1643         if(self.flagcarried)
1644                 DropFlag(self.flagcarried, world, world);
1645         if(self.ballcarried && g_nexball)
1646                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1647
1648         // Here, everything has been done that requires this player to be a client.
1649
1650         self.flags &~= FL_CLIENT;
1651
1652         if (self.chatbubbleentity)
1653                 remove (self.chatbubbleentity);
1654
1655         if (self.killindicator)
1656                 remove (self.killindicator);
1657
1658         WaypointSprite_PlayerGone();
1659
1660         bot_relinkplayerlist();
1661
1662         if(g_arena)
1663         {
1664                 Spawnqueue_Unmark(self);
1665                 Spawnqueue_Remove(self);
1666         }
1667
1668         accuracy_free(self);
1669         ClientData_Detach();
1670         PlayerScore_Detach(self);
1671
1672         if(self.netname_previous)
1673                 strunzone(self.netname_previous);
1674         if(self.clientstatus)
1675                 strunzone(self.clientstatus);
1676         if(self.weaponorder_byimpulse)
1677                 strunzone(self.weaponorder_byimpulse);
1678
1679         ClearPlayerSounds();
1680
1681         if(self.personal)
1682                 remove(self.personal);
1683
1684         self.playerid = 0;
1685         ReadyCount();
1686
1687         // free cvars
1688         GetCvars(-1);
1689 }
1690
1691 .float BUTTON_CHAT;
1692 void ChatBubbleThink()
1693 {
1694         self.nextthink = time;
1695         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1696         {
1697                 if(self.owner) // but why can that ever be world?
1698                         self.owner.chatbubbleentity = world;
1699                 remove(self);
1700                 return;
1701         }
1702         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1703 #ifdef TETRIS
1704                 || self.owner.tetris_on
1705 #endif
1706         )
1707                 self.model = self.mdl;
1708         else
1709                 self.model = "";
1710 }
1711
1712 void UpdateChatBubble()
1713 {
1714         if (self.alpha < 0)
1715                 return;
1716         // spawn a chatbubble entity if needed
1717         if (!self.chatbubbleentity)
1718         {
1719                 self.chatbubbleentity = spawn();
1720                 self.chatbubbleentity.owner = self;
1721                 self.chatbubbleentity.exteriormodeltoclient = self;
1722                 self.chatbubbleentity.think = ChatBubbleThink;
1723                 self.chatbubbleentity.nextthink = time;
1724                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1725                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1726                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1727                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1728                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1729                 self.chatbubbleentity.model = "";
1730                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1731         }
1732 }
1733
1734
1735 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1736 // added to the model skins
1737 /*void UpdateColorModHack()
1738 {
1739         float c;
1740         c = self.clientcolors & 15;
1741         // LordHavoc: only bothering to support white, green, red, yellow, blue
1742              if (!teamplay) self.colormod = '0 0 0';
1743         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1744         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1745         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1746         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1747         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1748         else self.colormod = '1 1 1';
1749 }*/
1750
1751 .float oldcolormap;
1752 void respawn(void)
1753 {
1754         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1755         {
1756                 self.solid = SOLID_NOT;
1757                 self.takedamage = DAMAGE_NO;
1758                 self.movetype = MOVETYPE_FLY;
1759                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1760                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1761                 self.effects |= EF_ADDITIVE;
1762                 self.oldcolormap = self.colormap;
1763                 self.colormap = 0; // this originally was 512, but raises a warning in the engine, so get rid of it
1764                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1765                 if(autocvar_g_respawn_ghosts_maxtime)
1766                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1767         }
1768
1769         CopyBody(1);
1770         self.effects |= EF_NODRAW; // prevent another CopyBody
1771         if(self.oldcolormap)
1772         {
1773                 self.colormap = self.oldcolormap;
1774                 self.oldcolormap = 0;
1775         }
1776         PutClientInServer();
1777 }
1778
1779 void play_countdown(float finished, string samp)
1780 {
1781         if(clienttype(self) == CLIENTTYPE_REAL)
1782                 if(floor(finished - time - frametime) != floor(finished - time))
1783                         if(finished - time < 6)
1784                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1785 }
1786
1787 void player_powerups (void)
1788 {
1789         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1790         olditems = self.items;
1791
1792         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1793         {
1794                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1795                 self.modelflags |= MF_ROCKET;
1796         }
1797         else
1798         {
1799                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1800                 self.modelflags &~= MF_ROCKET;
1801         }
1802
1803         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1804
1805         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1806                 return;
1807
1808         Fire_ApplyDamage(self);
1809         Fire_ApplyEffect(self);
1810
1811         if (g_minstagib)
1812         {
1813                 self.effects |= EF_FULLBRIGHT;
1814
1815                 if (self.items & IT_STRENGTH)
1816                 {
1817                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1818                         if (time > self.strength_finished)
1819                         {
1820                                 self.alpha = default_player_alpha;
1821                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1822                                 self.items &~= IT_STRENGTH;
1823                                 sprint(self, "^3Invisibility has worn off\n");
1824                         }
1825                 }
1826                 else
1827                 {
1828                         if (time < self.strength_finished)
1829                         {
1830                                 self.alpha = g_minstagib_invis_alpha;
1831                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1832                                 self.items |= IT_STRENGTH;
1833                                 sprint(self, "^3You are invisible\n");
1834                         }
1835                 }
1836
1837                 if (self.items & IT_INVINCIBLE)
1838                 {
1839                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1840                         if (time > self.invincible_finished)
1841                         {
1842                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1843                                 sprint(self, "^3Speed has worn off\n");
1844                         }
1845                 }
1846                 else
1847                 {
1848                         if (time < self.invincible_finished)
1849                         {
1850                                 self.items = self.items | IT_INVINCIBLE;
1851                                 sprint(self, "^3You are on speed\n");
1852                         }
1853                 }
1854         }
1855         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1856         {
1857                 if (self.items & IT_STRENGTH)
1858                 {
1859                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1860                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1861                         if (time > self.strength_finished)
1862                         {
1863                                 self.items = self.items - (self.items & IT_STRENGTH);
1864                                 sprint(self, "^3Strength has worn off\n");
1865                         }
1866                 }
1867                 else
1868                 {
1869                         if (time < self.strength_finished)
1870                         {
1871                                 self.items = self.items | IT_STRENGTH;
1872                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1873                         }
1874                 }
1875                 if (self.items & IT_INVINCIBLE)
1876                 {
1877                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1878                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1879                         if (time > self.invincible_finished)
1880                         {
1881                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1882                                 sprint(self, "^3Shield has worn off\n");
1883                         }
1884                 }
1885                 else
1886                 {
1887                         if (time < self.invincible_finished)
1888                         {
1889                                 self.items = self.items | IT_INVINCIBLE;
1890                                 sprint(self, "^3Shield surrounds you\n");
1891                         }
1892                 }
1893         }
1894
1895         if(autocvar_g_nodepthtestplayers)
1896                 self.effects = self.effects | EF_NODEPTHTEST;
1897
1898         if(autocvar_g_fullbrightplayers)
1899                 self.effects = self.effects | EF_FULLBRIGHT;
1900
1901         // midair gamemode: damage only while in the air
1902         // if in midair mode, being on ground grants temporary invulnerability
1903         // (this is so that multishot weapon don't clear the ground flag on the
1904         // first damage in the frame, leaving the player vulnerable to the
1905         // remaining hits in the same frame)
1906         if (self.flags & FL_ONGROUND)
1907         if (g_midair)
1908                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1909
1910         if (time >= game_starttime)
1911         if (time < self.spawnshieldtime)
1912                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1913
1914         MUTATOR_CALLHOOK(PlayerPowerups);
1915 }
1916
1917 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1918 {
1919         if(current > stable)
1920                 return current;
1921         else if(current > stable - 0.25) // when close enough, "snap"
1922                 return stable;
1923         else
1924                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1925 }
1926
1927 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1928 {
1929         if(current < stable)
1930                 return current;
1931         else if(current < stable + 0.25) // when close enough, "snap"
1932                 return stable;
1933         else
1934                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1935 }
1936
1937 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1938 {
1939         if(current > rotstable)
1940         {
1941                 if(rotframetime > 0)
1942                 {
1943                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1944                         current = max(rotstable, current - rotlinear * rotframetime);
1945                 }
1946         }
1947         else if(current < regenstable)
1948         {
1949                 if(regenframetime > 0)
1950                 {
1951                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1952                         current = min(regenstable, current + regenlinear * regenframetime);
1953                 }
1954         }
1955
1956         if(current > limit)
1957                 current = limit;
1958
1959         return current;
1960 }
1961
1962 void player_regen (void)
1963 {
1964         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1965         maxh = autocvar_g_balance_health_rotstable;
1966         maxa = autocvar_g_balance_armor_rotstable;
1967         maxf = autocvar_g_balance_fuel_rotstable;
1968         minh = autocvar_g_balance_health_regenstable;
1969         mina = autocvar_g_balance_armor_regenstable;
1970         minf = autocvar_g_balance_fuel_regenstable;
1971         limith = autocvar_g_balance_health_limit;
1972         limita = autocvar_g_balance_armor_limit;
1973         limitf = autocvar_g_balance_fuel_limit;
1974
1975         max_mod = regen_mod = rot_mod = limit_mod = 1;
1976
1977         if (self.runes & RUNE_REGEN)
1978         {
1979                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1980                 {
1981                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
1982                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
1983                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
1984                 }
1985                 else
1986                 {
1987                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
1988                         max_mod = autocvar_g_balance_rune_regen_hpmod;
1989                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
1990                 }
1991         }
1992         else if (self.runes & CURSE_VENOM)
1993         {
1994                 max_mod = autocvar_g_balance_curse_venom_hpmod;
1995                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1996                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
1997                 else
1998                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
1999                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2000                 //if (!self.runes & RUNE_REGEN)
2001                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2002         }
2003         maxh = maxh * max_mod;
2004         //maxa = maxa * max_mod;
2005         //maxf = maxf * max_mod;
2006         minh = minh * max_mod;
2007         //mina = mina * max_mod;
2008         //minf = minf * max_mod;
2009         limith = limith * limit_mod;
2010         limita = limita * limit_mod;
2011         //limitf = limitf * limit_mod;
2012
2013         if(g_lms && g_ca)
2014                 rot_mod = 0;
2015
2016         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2017         {
2018                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2019                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2020
2021                 // if player rotted to death...  die!
2022                 if(self.health < 1)
2023                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2024         }
2025
2026         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2027                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2028 }
2029
2030 float zoomstate_set;
2031 void SetZoomState(float z)
2032 {
2033         if(z != self.zoomstate)
2034         {
2035                 self.zoomstate = z;
2036                 ClientData_Touch(self);
2037         }
2038         zoomstate_set = 1;
2039 }
2040
2041 void GetPressedKeys(void) {
2042         MUTATOR_CALLHOOK(GetPressedKeys);
2043         if (self.movement_x > 0) // get if movement keys are pressed
2044         {       // forward key pressed
2045                 self.pressedkeys |= KEY_FORWARD;
2046                 self.pressedkeys &~= KEY_BACKWARD;
2047         }
2048         else if (self.movement_x < 0)
2049         {       // backward key pressed
2050                 self.pressedkeys |= KEY_BACKWARD;
2051                 self.pressedkeys &~= KEY_FORWARD;
2052         }
2053         else
2054         {       // no x input
2055                 self.pressedkeys &~= KEY_FORWARD;
2056                 self.pressedkeys &~= KEY_BACKWARD;
2057         }
2058
2059         if (self.movement_y > 0)
2060         {       // right key pressed
2061                 self.pressedkeys |= KEY_RIGHT;
2062                 self.pressedkeys &~= KEY_LEFT;
2063         }
2064         else if (self.movement_y < 0)
2065         {       // left key pressed
2066                 self.pressedkeys |= KEY_LEFT;
2067                 self.pressedkeys &~= KEY_RIGHT;
2068         }
2069         else
2070         {       // no y input
2071                 self.pressedkeys &~= KEY_RIGHT;
2072                 self.pressedkeys &~= KEY_LEFT;
2073         }
2074
2075         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2076                 self.pressedkeys |= KEY_JUMP;
2077         else
2078                 self.pressedkeys &~= KEY_JUMP;
2079         if (self.BUTTON_CROUCH)
2080                 self.pressedkeys |= KEY_CROUCH;
2081         else
2082                 self.pressedkeys &~= KEY_CROUCH;
2083 }
2084
2085 /*
2086 ======================
2087 spectate mode routines
2088 ======================
2089 */
2090
2091 void SpectateCopy(entity spectatee) {
2092         other = spectatee;
2093         MUTATOR_CALLHOOK(SpectateCopy);
2094         self.armortype = spectatee.armortype;
2095         self.armorvalue = spectatee.armorvalue;
2096         self.ammo_cells = spectatee.ammo_cells;
2097         self.ammo_shells = spectatee.ammo_shells;
2098         self.ammo_nails = spectatee.ammo_nails;
2099         self.ammo_rockets = spectatee.ammo_rockets;
2100         self.ammo_fuel = spectatee.ammo_fuel;
2101         self.clip_load = spectatee.clip_load;
2102         self.clip_size = spectatee.clip_size;
2103         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2104         self.health = spectatee.health;
2105         self.impulse = 0;
2106         self.items = spectatee.items;
2107         self.last_pickup = spectatee.last_pickup;
2108         self.hit_time = spectatee.hit_time;
2109         self.metertime = spectatee.metertime;
2110         self.strength_finished = spectatee.strength_finished;
2111         self.invincible_finished = spectatee.invincible_finished;
2112         self.pressedkeys = spectatee.pressedkeys;
2113         self.weapons = spectatee.weapons;
2114         self.switchweapon = spectatee.switchweapon;
2115         self.switchingweapon = spectatee.switchingweapon;
2116         self.weapon = spectatee.weapon;
2117         self.nex_charge = spectatee.nex_charge;
2118         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2119         self.hagar_load = spectatee.hagar_load;
2120         self.minelayer_mines = spectatee.minelayer_mines;
2121         self.punchangle = spectatee.punchangle;
2122         self.view_ofs = spectatee.view_ofs;
2123         self.v_angle = spectatee.v_angle;
2124         self.velocity = spectatee.velocity;
2125         self.dmg_take = spectatee.dmg_take;
2126         self.dmg_save = spectatee.dmg_save;
2127         self.dmg_inflictor = spectatee.dmg_inflictor;
2128         self.angles = spectatee.v_angle;
2129         if(!self.BUTTON_USE)
2130                 self.fixangle = TRUE;
2131         setorigin(self, spectatee.origin);
2132         setsize(self, spectatee.mins, spectatee.maxs);
2133         SetZoomState(spectatee.zoomstate);
2134
2135         anticheat_spectatecopy(spectatee);
2136
2137         //self.vehicle = spectatee.vehicle;
2138
2139         self.hud = spectatee.hud;
2140         if(spectatee.vehicle)
2141     {
2142         setorigin(self, spectatee.origin);
2143         self.velocity = spectatee.vehicle.velocity;
2144         self.v_angle += spectatee.vehicle.angles;
2145         //self.v_angle_x *= -1;
2146         self.vehicle_health = spectatee.vehicle_health;
2147         self.vehicle_shield = spectatee.vehicle_shield;
2148         self.vehicle_energy = spectatee.vehicle_energy;
2149         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2150         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2151         self.vehicle_reload1 = spectatee.vehicle_reload1;
2152         self.vehicle_reload2 = spectatee.vehicle_reload2;
2153
2154         msg_entity = self;
2155         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2156         WriteEntity(MSG_ONE, spectatee);
2157         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2158     }
2159 }
2160
2161 float SpectateUpdate() {
2162         if(!self.enemy)
2163             return 0;
2164
2165         if (self == self.enemy)
2166                 return 0;
2167
2168         if(self.enemy.classname != "player")
2169                 return 0;
2170
2171         SpectateCopy(self.enemy);
2172
2173         return 1;
2174 }
2175
2176
2177 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2178 entity CA_SpectateNext(entity start) {
2179         if (start.team == self.team) {
2180                 return start;
2181         }
2182
2183         other = start;
2184         // continue from current player
2185         while(other && other.team != self.team) {
2186                 other = find(other, classname, "player");
2187         }
2188
2189         if (!other) {
2190                 // restart from begining
2191                 other = find(other, classname, "player");
2192                 while(other && other.team != self.team) {
2193                         other = find(other, classname, "player");
2194                 }
2195         }
2196
2197         return other;
2198 }
2199
2200 float SpectateNext() {
2201         other = find(self.enemy, classname, "player");
2202         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2203                 // CA and ca players when spectating enemies is forbidden
2204                 other = CA_SpectateNext(other);
2205         } else {
2206                 // other modes and ca spectators or spectating enemies is allowed
2207                 if (!other)
2208                         other = find(other, classname, "player");
2209         }
2210
2211         if (other)
2212                 self.enemy = other;
2213
2214         if(self.enemy.classname == "player") {
2215             if(self.enemy.vehicle)
2216             {
2217             msg_entity = self;
2218             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2219             WriteEntity(MSG_ONE, self.enemy);
2220             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2221             self.movetype = MOVETYPE_NONE;
2222             accuracy_resend(self);
2223             }
2224             else
2225             {
2226             msg_entity = self;
2227             WriteByte(MSG_ONE, SVC_SETVIEW);
2228             WriteEntity(MSG_ONE, self.enemy);
2229             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2230             self.movetype = MOVETYPE_NONE;
2231             accuracy_resend(self);
2232
2233             if(!SpectateUpdate())
2234                 PutObserverInServer();
2235         }
2236         return 1;
2237         } else {
2238                 return 0;
2239         }
2240 }
2241
2242 /*
2243 =============
2244 ShowRespawnCountdown()
2245
2246 Update a respawn countdown display.
2247 =============
2248 */
2249 void ShowRespawnCountdown()
2250 {
2251         float number;
2252         if(self.deadflag == DEAD_NO) // just respawned?
2253                 return;
2254         else
2255         {
2256                 number = ceil(self.death_time - time);
2257                 if(number <= 0)
2258                         return;
2259                 if(number <= self.respawn_countdown)
2260                 {
2261                         self.respawn_countdown = number - 1;
2262                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2263                                 AnnounceTo(self, strcat(ftos(number), ""));
2264                 }
2265         }
2266 }
2267
2268 .float prevent_join_msgtime;
2269 void LeaveSpectatorMode()
2270 {
2271         if(nJoinAllowed(1)) {
2272                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2273                         self.classname = "player";
2274
2275                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2276                                 JoinBestTeam(self, FALSE, TRUE);
2277
2278                         if(autocvar_g_campaign)
2279                                 campaign_bots_may_start = 1;
2280
2281                         PutClientInServer();
2282
2283                         if(self.classname == "player")
2284                                 bprint ("^4", self.netname, "^4 is playing now\n");
2285
2286                         if(!autocvar_g_campaign)
2287                         if (time < self.jointime + autocvar_welcome_message_time)
2288                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2289
2290                         if (self.prevent_join_msgtime)
2291                         {
2292                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2293                                 self.prevent_join_msgtime = 0;
2294                         }
2295
2296                         return;
2297                 } else {
2298                         if (g_ca && self.caplayer) {
2299                         }       // do nothing
2300                         else
2301                                 stuffcmd(self,"menu_showteamselect\n");
2302                         return;
2303                 }
2304         }
2305         else {
2306                 //player may not join because of g_maxplayers is set
2307                 if (time - self.prevent_join_msgtime > 2)
2308                 {
2309                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2310                         self.prevent_join_msgtime = time;
2311                 }
2312         }
2313 }
2314
2315 /**
2316  * Determines whether the player is allowed to join. This depends on cvar
2317  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2318  * it checks whether the number of currently playing players exceeds g_maxplayers.
2319  * @return int number of free slots for players, 0 if none
2320  */
2321 float nJoinAllowed(float includeMe) {
2322         if(self.team_forced < 0)
2323                 return FALSE; // forced spectators can never join
2324
2325         // TODO simplify this
2326         entity e;
2327
2328         float totalClients;
2329         FOR_EACH_CLIENT(e)
2330                 totalClients += 1;
2331
2332         if (!autocvar_g_maxplayers)
2333                 return maxclients - totalClients + includeMe;
2334
2335         float currentlyPlaying;
2336         FOR_EACH_REALPLAYER(e)
2337                 currentlyPlaying += 1;
2338
2339         if(currentlyPlaying < autocvar_g_maxplayers)
2340                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2341
2342         return 0;
2343 }
2344
2345 /**
2346  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2347  * g_maxplayers_spectator_blocktime seconds
2348  */
2349 void checkSpectatorBlock() {
2350         if(self.classname == "spectator" || self.classname == "observer") {
2351                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2352                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2353                         dropclient(self);
2354                 }
2355         }
2356 }
2357
2358 .float motd_actived_time; // used for both motd and campaign_message
2359 void PrintWelcomeMessage()
2360 {
2361         if (self.motd_actived_time == 0) { // is there already a message showing?
2362                 if (autocvar_g_campaign) {
2363                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2364                                 self.motd_actived_time = time;
2365                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2366                         }
2367                 } else {
2368                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2369                                 self.motd_actived_time = time;
2370                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2371                         }
2372                 }
2373         } else { // showing MOTD or campaign message
2374                 if (autocvar_g_campaign) {
2375                         if (self.BUTTON_INFO)
2376                                 self.motd_actived_time = time;
2377                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2378                                 self.motd_actived_time = 0;
2379                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2380                         }
2381                 } else {
2382                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2383                                 if (self.BUTTON_INFO)
2384                                         self.motd_actived_time = time;
2385                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2386                                         self.motd_actived_time = 0;
2387                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2388                                 }
2389                         }
2390                 }
2391         }
2392 }
2393
2394 void ObserverThink()
2395 {
2396         float prefered_movetype;
2397         if (self.flags & FL_JUMPRELEASED) {
2398                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2399                         self.flags &~= FL_JUMPRELEASED;
2400                         self.flags |= FL_SPAWNING;
2401                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2402                         self.flags &~= FL_JUMPRELEASED;
2403                         if(SpectateNext() == 1) {
2404                                 self.classname = "spectator";
2405                         }
2406                 } else {
2407                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2408                         if (self.movetype != prefered_movetype)
2409                                 self.movetype = prefered_movetype;
2410                 }
2411         } else {
2412                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2413                         self.flags |= FL_JUMPRELEASED;
2414                         if(self.flags & FL_SPAWNING)
2415                         {
2416                                 self.flags &~= FL_SPAWNING;
2417                                 LeaveSpectatorMode();
2418                                 return;
2419                         }
2420                 }
2421         }
2422
2423         PrintWelcomeMessage();
2424 }
2425
2426 void SpectatorThink()
2427 {
2428         if (self.flags & FL_JUMPRELEASED) {
2429                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2430                         self.flags &~= FL_JUMPRELEASED;
2431                         self.flags |= FL_SPAWNING;
2432                 } else if(self.BUTTON_ATCK) {
2433                         self.flags &~= FL_JUMPRELEASED;
2434                         if(SpectateNext() == 1) {
2435                                 self.classname = "spectator";
2436                         } else {
2437                                 self.classname = "observer";
2438                                 PutClientInServer();
2439                         }
2440                 } else if (self.BUTTON_ATCK2) {
2441                         self.flags &~= FL_JUMPRELEASED;
2442                         self.classname = "observer";
2443                         PutClientInServer();
2444                 } else {
2445                         if(!SpectateUpdate())
2446                                 PutObserverInServer();
2447                 }
2448         } else {
2449                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2450                         self.flags |= FL_JUMPRELEASED;
2451                         if(self.flags & FL_SPAWNING)
2452                         {
2453                                 self.flags &~= FL_SPAWNING;
2454                                 LeaveSpectatorMode();
2455                                 return;
2456                         }
2457                 }
2458                 if(!SpectateUpdate())
2459                         PutObserverInServer();
2460         }
2461
2462         PrintWelcomeMessage();
2463         self.flags |= FL_CLIENT | FL_NOTARGET;
2464 }
2465
2466 float ctf_usekey();
2467 void PlayerUseKey()
2468 {
2469         if(self.classname != "player")
2470                 return;
2471
2472         if(self.vehicle)
2473         {
2474         vehicles_exit(VHEF_NORMAL);
2475         return;
2476         }
2477
2478         // a use key was pressed; call handlers
2479         if(ctf_usekey())
2480                 return;
2481
2482         MUTATOR_CALLHOOK(PlayerUseKey);
2483 }
2484
2485 .float touchexplode_time;
2486
2487 /*
2488 =============
2489 PlayerPreThink
2490
2491 Called every frame for each client before the physics are run
2492 =============
2493 */
2494 .float usekeypressed;
2495 void() ctf_setstatus;
2496 void() nexball_setstatus;
2497 .float items_added;
2498 void PlayerPreThink (void)
2499 {
2500         WarpZone_PlayerPhysics_FixVAngle();
2501
2502         self.stat_game_starttime = game_starttime;
2503         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2504         self.stat_leadlimit = autocvar_leadlimit;
2505
2506         if(frametime)
2507         {
2508                 // physics frames: update anticheat stuff
2509                 anticheat_prethink();
2510         }
2511
2512         if(blockSpectators && frametime)
2513                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2514                 checkSpectatorBlock();
2515
2516         zoomstate_set = 0;
2517
2518         if(self.netname_previous != self.netname)
2519         {
2520                 if(autocvar_sv_eventlog)
2521                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2522                 if(self.netname_previous)
2523                         strunzone(self.netname_previous);
2524                 self.netname_previous = strzone(self.netname);
2525         }
2526
2527         // version nagging
2528         if(self.version_nagtime)
2529                 if(self.cvar_g_xonoticversion)
2530                         if(time > self.version_nagtime)
2531                         {
2532                                 // don't notify git users
2533                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2534                                 {
2535                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2536                                         {
2537                                                 // notify release users if connecting to git
2538                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2539                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2540                                         }
2541                                         else
2542                                         {
2543                                                 float r;
2544                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2545                                                 if(r < 0)
2546                                                 {
2547                                                         // give users new version
2548                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2549                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2550                                                 }
2551                                                 else if(r > 0)
2552                                                 {
2553                                                         // notify users about old server version
2554                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2555                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2556                                                 }
2557                                         }
2558                                 }
2559                                 self.version_nagtime = 0;
2560                         }
2561
2562         // GOD MODE info
2563         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2564         {
2565                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2566                 self.max_armorvalue = 0;
2567         }
2568
2569 #ifdef TETRIS
2570         if (TetrisPreFrame())
2571                 return;
2572 #endif
2573
2574         MUTATOR_CALLHOOK(PlayerPreThink);
2575
2576         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2577         {
2578                 if(self.BUTTON_USE && !self.usekeypressed)
2579                         PlayerUseKey();
2580                 self.usekeypressed = self.BUTTON_USE;
2581         }
2582
2583         PrintWelcomeMessage();
2584
2585         if(self.classname == "player") {
2586 //              if(self.netname == "Wazat")
2587 //                      bprint(self.classname, "\n");
2588
2589                 CheckRules_Player();
2590
2591                 if (intermission_running)
2592                 {
2593                         IntermissionThink ();   // otherwise a button could be missed between
2594                         return;                                 // the think tics
2595                 }
2596
2597                 //don't allow the player to turn around while game is paused!
2598                 if(timeout_status == TIMEOUT_ACTIVE) {
2599                         // FIXME turn this into CSQC stuff
2600                         self.v_angle = self.lastV_angle;
2601                         self.angles = self.lastV_angle;
2602                         self.fixangle = TRUE;
2603                 }
2604
2605                 if(frametime)
2606                 {
2607 #ifndef NO_LEGACY_NETWORKING
2608                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2609 #endif
2610
2611                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2612                         {
2613                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2614                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2615                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2616
2617                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2618                                 {
2619                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2620                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2621                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2622                                 }
2623                         }
2624                         else
2625                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2626
2627                         player_powerups();
2628                 }
2629
2630                 if (g_minstagib)
2631                         minstagib_ammocheck();
2632
2633                 if (self.deadflag != DEAD_NO)
2634                 {
2635                         float button_pressed, force_respawn;
2636                         if(self.personal && g_race_qualifying)
2637                         {
2638                                 if(time > self.death_time)
2639                                 {
2640                                         self.death_time = time + 1; // only retry once a second
2641                                         respawn();
2642                                         self.impulse = 141;
2643                                 }
2644                         }
2645                         else
2646                         {
2647                                 if(frametime)
2648                                         player_anim();
2649                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2650                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2651                                 if (self.deadflag == DEAD_DYING)
2652                                 {
2653                                         if(force_respawn)
2654                                                 self.deadflag = DEAD_RESPAWNING;
2655                                         else if(!button_pressed)
2656                                                 self.deadflag = DEAD_DEAD;
2657                                 }
2658                                 else if (self.deadflag == DEAD_DEAD)
2659                                 {
2660                                         if(button_pressed)
2661                                                 self.deadflag = DEAD_RESPAWNABLE;
2662                                 }
2663                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2664                                 {
2665                                         if(!button_pressed)
2666                                                 self.deadflag = DEAD_RESPAWNING;
2667                                 }
2668                                 else if (self.deadflag == DEAD_RESPAWNING)
2669                                 {
2670                                         if(time > self.death_time)
2671                                         {
2672                                                 self.death_time = time + 1; // only retry once a second
2673                                                 respawn();
2674                                         }
2675                                 }
2676                                 ShowRespawnCountdown();
2677                         }
2678                         return;
2679                 }
2680                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2681                 // so (self.deadflag == DEAD_NO) is always true in the code below
2682
2683                 if(g_touchexplode)
2684                 if(time > self.touchexplode_time)
2685                 if(self.classname == "player")
2686                 if(self.deadflag == DEAD_NO)
2687                 if not(IS_INDEPENDENT_PLAYER(self))
2688                 FOR_EACH_PLAYER(other) if(self != other)
2689                 {
2690                         if(time > other.touchexplode_time)
2691                         if(other.deadflag == DEAD_NO)
2692                         if not(IS_INDEPENDENT_PLAYER(other))
2693                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2694                         {
2695                                 PlayerTouchExplode(self, other);
2696                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2697                         }
2698                 }
2699
2700                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2701                 {
2702                         vector dist;
2703
2704                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2705                         dist = self.prevorigin - self.origin;
2706                         dist_z = 0;
2707                         self.lms_traveled_distance += fabs(vlen(dist));
2708
2709                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2710                         {
2711                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2712                                 self.lms_traveled_distance = 0;
2713                         }
2714
2715                         if(time > self.lms_nextcheck)
2716                         {
2717                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2718                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2719                                 {
2720                                         centerprint(self, autocvar_g_lms_campcheck_message);
2721                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2722                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2723                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2724                                 }
2725                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2726                                 self.lms_traveled_distance = 0;
2727                         }
2728                 }
2729
2730                 self.prevorigin = self.origin;
2731
2732                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x) // prevent crouching if using melee attack
2733                 {
2734                         if (!self.crouch)
2735                         {
2736                                 self.crouch = TRUE;
2737                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2738                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2739                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2740                         }
2741                 }
2742                 else
2743                 {
2744                         if (self.crouch)
2745                         {
2746                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2747                                 if (!trace_startsolid)
2748                                 {
2749                                         self.crouch = FALSE;
2750                                         self.view_ofs = PL_VIEW_OFS;
2751                                         setsize (self, PL_MIN, PL_MAX);
2752                                 }
2753                         }
2754                 }
2755
2756                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2757                 {
2758                         if(self.bloodloss_timer < time)
2759                         {
2760                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2761                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2762                         }
2763                 }
2764
2765                 FixPlayermodel();
2766
2767                 GrapplingHookFrame();
2768
2769                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2770                 //if(frametime)
2771                 {
2772                         self.items &~= self.items_added;
2773
2774                         W_WeaponFrame();
2775
2776                         self.items_added = 0;
2777                         if(self.items & IT_JETPACK)
2778                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2779                                         self.items_added |= IT_FUEL;
2780
2781                         self.items |= self.items_added;
2782                 }
2783
2784                 player_regen();
2785
2786                 // rot nex charge to the charge limit
2787                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2788                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2789
2790                 if(frametime)
2791                         player_anim();
2792
2793                 if(g_ctf)
2794                         ctf_setstatus();
2795
2796                 if(g_nexball)
2797                         nexball_setstatus();
2798
2799                 // secret status
2800                 secrets_setstatus();
2801
2802                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2803
2804                 //self.angles_y=self.v_angle_y + 90;   // temp
2805         } else if(gameover) {
2806                 if (intermission_running)
2807                         IntermissionThink ();   // otherwise a button could be missed between
2808                 return;
2809         } else if(self.classname == "observer") {
2810                 ObserverThink();
2811         } else if(self.classname == "spectator") {
2812                 SpectatorThink();
2813         }
2814
2815         if(!zoomstate_set)
2816                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2817
2818         float oldspectatee_status;
2819         oldspectatee_status = self.spectatee_status;
2820         if(self.classname == "spectator")
2821                 self.spectatee_status = num_for_edict(self.enemy);
2822         else if(self.classname == "observer")
2823                 self.spectatee_status = num_for_edict(self);
2824         else
2825                 self.spectatee_status = 0;
2826         if(self.spectatee_status != oldspectatee_status)
2827         {
2828                 ClientData_Touch(self);
2829                 if(g_race || g_cts)
2830                         race_InitSpectator();
2831         }
2832
2833         if(self.teamkill_soundtime)
2834         if(time > self.teamkill_soundtime)
2835         {
2836                 self.teamkill_soundtime = 0;
2837
2838                 entity oldpusher, oldself;
2839
2840                 oldself = self; self = self.teamkill_soundsource;
2841                 oldpusher = self.pusher; self.pusher = oldself;
2842
2843                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2844
2845                 self.pusher = oldpusher;
2846                 self = oldself;
2847         }
2848
2849         if(self.taunt_soundtime)
2850         if(time > self.taunt_soundtime)
2851         {
2852                 self.taunt_soundtime = 0;
2853                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2854         }
2855
2856         target_voicescript_next(self);
2857
2858         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2859         if(!self.weapon)
2860                 self.clip_load = self.clip_size = 0;
2861 }
2862
2863 float isInvisibleString(string s)
2864 {
2865         float i, n, c;
2866         s = strdecolorize(s);
2867         for((i = 0), (n = strlen(s)); i < n; ++i)
2868         {
2869                 c = str2chr(s, i);
2870                 switch(c)
2871                 {
2872                         case 0:
2873                         case 32: // space
2874                                 break;
2875                         case 192: // charmap space
2876                                 if (!autocvar_utf8_enable)
2877                                         break;
2878                                 return FALSE;
2879                         case 160: // space in unicode fonts
2880                         case 0xE000 + 192: // utf8 charmap space
2881                                 if (autocvar_utf8_enable)
2882                                         break;
2883                         default:
2884                                 return FALSE;
2885                 }
2886         }
2887         return TRUE;
2888 }
2889
2890 /*
2891 =============
2892 PlayerPostThink
2893
2894 Called every frame for each client after the physics are run
2895 =============
2896 */
2897 .float idlekick_lasttimeleft;
2898 .entity showheadshotbbox;
2899 void showheadshotbbox_think()
2900 {
2901         if(self.owner.showheadshotbbox != self)
2902         {
2903                 remove(self);
2904                 return;
2905         }
2906         self.nextthink = time;
2907         setorigin(self, self.owner.origin);
2908         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2909 }
2910 void PlayerPostThink (void)
2911 {
2912         // Savage: Check for nameless players
2913         if (isInvisibleString(self.netname)) {
2914                 self.netname = "Player";
2915                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2916         }
2917
2918         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2919         {
2920                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2921                 {
2922                         if(self.idlekick_lasttimeleft)
2923                         {
2924                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2925                                 self.idlekick_lasttimeleft = 0;
2926                         }
2927                 }
2928                 else
2929                 {
2930                         float timeleft;
2931                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2932                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2933                         {
2934                                 if(!self.idlekick_lasttimeleft)
2935                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
2936                         }
2937                         if(timeleft <= 0)
2938                         {
2939                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
2940                                 AnnounceTo(self, "terminated");
2941                                 dropclient(self);
2942                                 return;
2943                         }
2944                         else if(timeleft <= 10)
2945                         {
2946                                 if(timeleft != self.idlekick_lasttimeleft)
2947                                         AnnounceTo(self, ftos(timeleft));
2948                                 self.idlekick_lasttimeleft = timeleft;
2949                         }
2950                 }
2951         }
2952
2953 #ifdef TETRIS
2954         if(self.impulse == 100)
2955                 ImpulseCommands();
2956         if (!TetrisPostFrame())
2957         {
2958 #endif
2959
2960         CheatFrame();
2961
2962         //CheckPlayerJump();
2963
2964         if(self.classname == "player") {
2965                 CheckRules_Player();
2966                 UpdateChatBubble();
2967                 if (self.impulse)
2968                         ImpulseCommands();
2969                 if (intermission_running)
2970                         return;         // intermission or finale
2971                 GetPressedKeys();
2972         } else if (self.classname == "observer") {
2973                 //do nothing
2974         } else if (self.classname == "spectator") {
2975                 //do nothing
2976         }
2977
2978 #ifdef TETRIS
2979         }
2980 #endif
2981
2982         /*
2983         float i;
2984         for(i = 0; i < 1000; ++i)
2985         {
2986                 vector end;
2987                 end = self.origin + '0 0 1024' + 512 * randomvec();
2988                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2989                 if(trace_fraction < 1)
2990                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2991                 {
2992                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2993                         break;
2994                 }
2995         }
2996         */
2997
2998         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2999
3000         if(self.waypointsprite_attachedforcarrier)
3001                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3002
3003         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3004         {
3005                 if(!self.showheadshotbbox)
3006                 {
3007                         self.showheadshotbbox = spawn();
3008                         self.showheadshotbbox.classname = "headshotbbox";
3009                         self.showheadshotbbox.owner = self;
3010                         self.showheadshotbbox.think = showheadshotbbox_think;
3011                         self.showheadshotbbox.nextthink = time;
3012                         self = self.showheadshotbbox;
3013                         self.think();
3014                         self = self.owner;
3015                 }
3016         }
3017         else
3018         {
3019                 if(self.showheadshotbbox)
3020                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3021                 remove(self.showheadshotbbox);
3022         }
3023
3024         playerdemo_write();
3025
3026         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3027         {
3028                 if(!self.stored_netname)
3029                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3030                 if(self.stored_netname != self.netname)
3031                 {
3032                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3033                         strunzone(self.stored_netname);
3034                         self.stored_netname = strzone(self.netname);
3035                 }
3036         }
3037
3038         /*
3039         if(g_race)
3040                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3041         */
3042
3043         CSQCMODEL_AUTOUPDATE();
3044 }