qcsrc/server/cl_client.qc

   1 #include "waypointsprites.qh"
   2
   3 #include "cl_impulse.qh"
   4 #include "cl_player.qh"
   5 #include "ent_cs.qh"
   6 #include "g_subs.qh"
   7 #include "ipban.qh"
   8 #include "miscfunctions.qh"
   9 #include "portals.qh"
  10 #include "teamplay.qh"
  11 #include "playerdemo.qh"
  12 #include "secret.qh"
  13
  14 #include "bot/bot.qh"
  15 #include "bot/navigation.qh"
  16
  17 #include "weapons/hitplot.qh"
  18 #include "weapons/weaponsystem.qh"
  19
  20 #include "../common/net_notice.qh"
  21 #include "../common/physics.qh"
  22
  23 #include "../common/monsters/sv_monsters.qh"
  24
  25 #include "../warpzonelib/server.qh"
  26
  27 float c1, c2, c3, c4;
  28
  29 void send_CSQC_teamnagger() {
  30         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  31         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  32 }
  33
  34 float ClientData_Send(entity to, int sf)
  35 {
  36         if(to != self.owner)
  37         {
  38                 error("wtf");
  39                 return false;
  40         }
  41
  42         entity e;
  43
  44         e = to;
  45         if(IS_SPEC(to))
  46                 e = to.enemy;
  47
  48         sf = 0;
  49
  50         if(e.race_completed)
  51                 sf |= 1; // forced scoreboard
  52         if(to.spectatee_status)
  53                 sf |= 2; // spectator ent number follows
  54         if(e.zoomstate)
  55                 sf |= 4; // zoomed
  56         if(e.porto_v_angle_held)
  57                 sf |= 8; // angles held
  58
  59         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  60         WriteByte(MSG_ENTITY, sf);
  61
  62         if(sf & 2)
  63                 WriteByte(MSG_ENTITY, to.spectatee_status);
  64
  65         if(sf & 8)
  66         {
  67                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  68                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  69         }
  70
  71         return true;
  72 }
  73
  74 void ClientData_Attach()
  75 {
  76         Net_LinkEntity(self.clientdata = spawn(), false, 0, ClientData_Send);
  77         self.clientdata.drawonlytoclient = self;
  78         self.clientdata.owner = self;
  79 }
  80
  81 void ClientData_Detach()
  82 {
  83         remove(self.clientdata);
  84         self.clientdata = world;
  85 }
  86
  87 void ClientData_Touch(entity e)
  88 {
  89         e.clientdata.SendFlags = 1;
  90
  91         // make it spectatable
  92         entity e2;
  93         FOR_EACH_REALCLIENT(e2)
  94         {
  95                 if(e2 != e)
  96                         if(IS_SPEC(e2))
  97                                 if(e2.enemy == e)
  98                                         e2.clientdata.SendFlags = 1;
  99         }
 100 }
 101
 102 .string netname_previous;
 103
 104 void SetSpectator(entity player, entity spectatee);
 105
 106
 107 /*
 108 =============
 109 CheckPlayerModel
 110
 111 Checks if the argument string can be a valid playermodel.
 112 Returns a valid one in doubt.
 113 =============
 114 */
 115 string FallbackPlayerModel;
 116 string CheckPlayerModel(string plyermodel) {
 117         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 118         {
 119                 // note: we cannot summon Don Strunzone here, some player may
 120                 // still have the model string set. In case anyone manages how
 121                 // to change a cvar default, we'll have a small leak here.
 122                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 123         }
 124         // only in right path
 125         if( substring(plyermodel,0,14) != "models/player/")
 126                 return FallbackPlayerModel;
 127         // only good file extensions
 128         if(substring(plyermodel,-4,4) != ".zym")
 129         if(substring(plyermodel,-4,4) != ".dpm")
 130         if(substring(plyermodel,-4,4) != ".iqm")
 131         if(substring(plyermodel,-4,4) != ".md3")
 132         if(substring(plyermodel,-4,4) != ".psk")
 133                 return FallbackPlayerModel;
 134         // forbid the LOD models
 135         if(substring(plyermodel, -9,5) == "_lod1")
 136                 return FallbackPlayerModel;
 137         if(substring(plyermodel, -9,5) == "_lod2")
 138                 return FallbackPlayerModel;
 139         if(plyermodel != strtolower(plyermodel))
 140                 return FallbackPlayerModel;
 141         // also, restrict to server models
 142         if(autocvar_sv_servermodelsonly)
 143         {
 144                 if(!fexists(plyermodel))
 145                         return FallbackPlayerModel;
 146         }
 147         return plyermodel;
 148 }
 149
 150 void setplayermodel(entity e, string modelname)
 151 {
 152         precache_model(modelname);
 153         setmodel(e, modelname);
 154         player_setupanimsformodel();
 155         UpdatePlayerSounds();
 156 }
 157
 158 /*
 159 =============
 160 PutObserverInServer
 161
 162 putting a client as observer in the server
 163 =============
 164 */
 165 void FixPlayermodel();
 166 void PutObserverInServer (void)
 167 {
 168         entity  spot;
 169     self.hud = HUD_NORMAL;
 170
 171         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 172
 173         spot = SelectSpawnPoint (true);
 174         if(!spot)
 175                 error("No spawnpoints for observers?!?\n");
 176         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 177
 178         if(IS_REAL_CLIENT(self))
 179         {
 180                 msg_entity = self;
 181                 WriteByte(MSG_ONE, SVC_SETVIEW);
 182                 WriteEntity(MSG_ONE, self);
 183         }
 184
 185         self.frags = FRAGS_SPECTATOR;
 186
 187         MUTATOR_CALLHOOK(MakePlayerObserver);
 188
 189         Portal_ClearAll(self);
 190
 191         Unfreeze(self);
 192
 193         if(self.alivetime)
 194         {
 195                 if(!warmup_stage)
 196                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 197                 self.alivetime = 0;
 198         }
 199
 200         if(self.vehicle)
 201                 vehicles_exit(VHEF_RELESE);
 202
 203         WaypointSprite_PlayerDead();
 204
 205         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 206                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 207
 208         if(self.killcount != -666)
 209         {
 210                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 211                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 212                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 213
 214                 if(self.just_joined == false) {
 215                         LogTeamchange(self.playerid, -1, 4);
 216                 } else
 217                         self.just_joined = false;
 218         }
 219
 220         PlayerScore_Clear(self); // clear scores when needed
 221
 222         accuracy_resend(self);
 223
 224         self.spectatortime = time;
 225
 226         self.classname = "observer";
 227         self.iscreature = false;
 228         self.teleportable = TELEPORT_SIMPLE;
 229         self.damagedbycontents = false;
 230         self.health = -666;
 231         self.takedamage = DAMAGE_NO;
 232         self.solid = SOLID_NOT;
 233         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 234         self.flags = FL_CLIENT | FL_NOTARGET;
 235         self.armorvalue = 666;
 236         self.effects = 0;
 237         self.armorvalue = autocvar_g_balance_armor_start;
 238         self.pauserotarmor_finished = 0;
 239         self.pauserothealth_finished = 0;
 240         self.pauseregen_finished = 0;
 241         self.damageforcescale = 0;
 242         self.death_time = 0;
 243         self.respawn_flags = 0;
 244         self.respawn_time = 0;
 245         self.stat_respawn_time = 0;
 246         self.alpha = 0;
 247         self.scale = 0;
 248         self.fade_time = 0;
 249         self.pain_frame = 0;
 250         self.pain_finished = 0;
 251         self.strength_finished = 0;
 252         self.invincible_finished = 0;
 253         self.superweapons_finished = 0;
 254         self.pushltime = 0;
 255         self.istypefrag = 0;
 256         self.think = func_null;
 257         self.nextthink = 0;
 258         self.hook_time = 0;
 259         self.deadflag = DEAD_NO;
 260         self.angles = spot.angles;
 261         self.angles_z = 0;
 262         self.fixangle = true;
 263         self.crouch = false;
 264         self.revival_time = 0;
 265
 266         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 267         self.prevorigin = self.origin;
 268         self.items = 0;
 269         self.weapons = '0 0 0';
 270         self.model = "";
 271         FixPlayermodel();
 272         setmodel(self, "null");
 273         self.drawonlytoclient = self;
 274
 275         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 276         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 277
 278         self.weapon = 0;
 279         self.weaponname = "";
 280         self.switchingweapon = 0;
 281         self.weaponmodel = "";
 282         self.weaponentity = world;
 283         self.exteriorweaponentity = world;
 284         self.killcount = -666;
 285         self.velocity = '0 0 0';
 286         self.avelocity = '0 0 0';
 287         self.punchangle = '0 0 0';
 288         self.punchvector = '0 0 0';
 289         self.oldvelocity = self.velocity;
 290         self.fire_endtime = -1;
 291         self.event_damage = func_null;
 292 }
 293
 294 .float model_randomizer;
 295 void FixPlayermodel()
 296 {
 297         string defaultmodel;
 298         float defaultskin, chmdl, oldskin, n, i;
 299         vector m1, m2;
 300
 301         defaultmodel = "";
 302         defaultskin = 0;
 303         chmdl = false;
 304
 305         if(autocvar_sv_defaultcharacter == 1)
 306         {
 307                 if(teamplay)
 308                 {
 309                         string s;
 310                         s = Static_Team_ColorName_Lower(self.team);
 311                         if(s != "neutral")
 312                         {
 313                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 314                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 315                         }
 316                 }
 317
 318                 if(defaultmodel == "")
 319                 {
 320                         defaultmodel = autocvar_sv_defaultplayermodel;
 321                         defaultskin = autocvar_sv_defaultplayerskin;
 322                 }
 323
 324                 n = tokenize_console(defaultmodel);
 325                 if(n > 0)
 326                 {
 327                         defaultmodel = argv(floor(n * self.model_randomizer));
 328                         // However, do NOT randomize if the player-selected model is in the list.
 329                         for (i = 0; i < n; ++i)
 330                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 331                                         defaultmodel = argv(i);
 332                 }
 333
 334                 i = strstrofs(defaultmodel, ":", 0);
 335                 if(i >= 0)
 336                 {
 337                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 338                         defaultmodel = substring(defaultmodel, 0, i);
 339                 }
 340         }
 341
 342         if(defaultmodel != "")
 343         {
 344                 if (defaultmodel != self.model)
 345                 {
 346                         m1 = self.mins;
 347                         m2 = self.maxs;
 348                         setplayermodel (self, defaultmodel);
 349                         setsize (self, m1, m2);
 350                         chmdl = true;
 351                 }
 352
 353                 oldskin = self.skin;
 354                 self.skin = defaultskin;
 355         } else {
 356                 if (self.playermodel != self.model || self.playermodel == "")
 357                 {
 358                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 359                         m1 = self.mins;
 360                         m2 = self.maxs;
 361                         setplayermodel (self, self.playermodel);
 362                         setsize (self, m1, m2);
 363                         chmdl = true;
 364                 }
 365
 366                 oldskin = self.skin;
 367                 self.skin = stof(self.playerskin);
 368         }
 369
 370         if(chmdl || oldskin != self.skin) // model or skin has changed
 371         {
 372                 self.species = player_getspecies(); // update species
 373                 UpdatePlayerSounds(); // update skin sounds
 374         }
 375
 376         if(!teamplay)
 377                 if(strlen(autocvar_sv_defaultplayercolors))
 378                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 379                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 380 }
 381
 382 /*
 383 =============
 384 PutClientInServer
 385
 386 Called when a client spawns in the server
 387 =============
 388 */
 389 void PutClientInServer (void)
 390 {
 391         if(IS_BOT_CLIENT(self))
 392                 self.classname = "player";
 393         else if(IS_REAL_CLIENT(self))
 394         {
 395                 msg_entity = self;
 396                 WriteByte(MSG_ONE, SVC_SETVIEW);
 397                 WriteEntity(MSG_ONE, self);
 398         }
 399
 400         SetSpectator(self, world);
 401
 402         // reset player keys
 403         self.itemkeys = 0;
 404
 405         MUTATOR_CALLHOOK(PutClientInServer);
 406
 407         if(gameover)
 408                 self.classname = "observer";
 409
 410         if(IS_PLAYER(self))
 411         {
 412                 entity spot, oldself;
 413                 float j;
 414
 415                 accuracy_resend(self);
 416
 417                 if(self.team < 0)
 418                         JoinBestTeam(self, false, true);
 419
 420                 spot = SelectSpawnPoint (false);
 421                 if(!spot)
 422                 {
 423                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 424                         return; // spawn failed
 425                 }
 426
 427                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 428
 429                 if(self.vehicle)
 430                         vehicles_exit(VHEF_RELESE);
 431
 432                 self.classname = "player";
 433                 self.wasplayer = true;
 434                 self.iscreature = true;
 435                 self.teleportable = TELEPORT_NORMAL;
 436                 self.damagedbycontents = true;
 437                 self.movetype = MOVETYPE_WALK;
 438                 self.solid = SOLID_SLIDEBOX;
 439                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 440                 if(autocvar_g_playerclip_collisions)
 441                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 442                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 443                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 444                 self.frags = FRAGS_PLAYER;
 445                 if(INDEPENDENT_PLAYERS)
 446                         MAKE_INDEPENDENT_PLAYER(self);
 447                 self.flags = FL_CLIENT;
 448                 if(autocvar__notarget)
 449                         self.flags |= FL_NOTARGET;
 450                 self.takedamage = DAMAGE_AIM;
 451                 self.effects = 0;
 452                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 453                 self.air_finished = time + 12;
 454                 self.dmg = 2;
 455                 if(WEP_CVAR(vortex, charge))
 456                 {
 457                         if(WEP_CVAR_SEC(vortex, chargepool))
 458                                 self.vortex_chargepool_ammo = 1;
 459                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 460                 }
 461
 462                 if(warmup_stage)
 463                 {
 464                         self.ammo_shells = warmup_start_ammo_shells;
 465                         self.ammo_nails = warmup_start_ammo_nails;
 466                         self.ammo_rockets = warmup_start_ammo_rockets;
 467                         self.ammo_cells = warmup_start_ammo_cells;
 468                         self.ammo_plasma = warmup_start_ammo_plasma;
 469                         self.ammo_fuel = warmup_start_ammo_fuel;
 470                         self.health = warmup_start_health;
 471                         self.armorvalue = warmup_start_armorvalue;
 472                         self.weapons = WARMUP_START_WEAPONS;
 473                 }
 474                 else
 475                 {
 476                         self.ammo_shells = start_ammo_shells;
 477                         self.ammo_nails = start_ammo_nails;
 478                         self.ammo_rockets = start_ammo_rockets;
 479                         self.ammo_cells = start_ammo_cells;
 480                         self.ammo_plasma = start_ammo_plasma;
 481                         self.ammo_fuel = start_ammo_fuel;
 482                         self.health = start_health;
 483                         self.armorvalue = start_armorvalue;
 484                         self.weapons = start_weapons;
 485                 }
 486
 487                 if(self.weapons & WEPSET_SUPERWEAPONS)
 488                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 489                 else
 490                         self.superweapons_finished = 0;
 491
 492                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 493                 {
 494                         if(g_weaponarena_random_with_blaster)
 495                                 self.weapons &= ~WEPSET_BLASTER;
 496                         W_RandomWeapons(self, g_weaponarena_random);
 497                         if(g_weaponarena_random_with_blaster)
 498                                 self.weapons |= WEPSET_BLASTER;
 499                 }
 500
 501                 self.items = start_items;
 502
 503                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 504                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 505                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 506                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 507                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 508                 //extend the pause of rotting if client was reset at the beginning of the countdown
 509                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 510                         self.spawnshieldtime += game_starttime - time;
 511                         self.pauserotarmor_finished += game_starttime - time;
 512                         self.pauserothealth_finished += game_starttime - time;
 513                         self.pauseregen_finished += game_starttime - time;
 514                 }
 515                 self.damageforcescale = 2;
 516                 self.death_time = 0;
 517                 self.respawn_flags = 0;
 518                 self.respawn_time = 0;
 519                 self.stat_respawn_time = 0;
 520                 self.scale = 0;
 521                 self.fade_time = 0;
 522                 self.pain_frame = 0;
 523                 self.pain_finished = 0;
 524                 self.strength_finished = 0;
 525                 self.invincible_finished = 0;
 526                 self.pushltime = 0;
 527                 // players have no think function
 528                 self.think = func_null;
 529                 self.nextthink = 0;
 530                 self.hook_time = 0;
 531                 self.dmg_team = 0;
 532                 self.ballistics_density = autocvar_g_ballistics_density_player;
 533
 534                 self.metertime = 0;
 535
 536                 self.deadflag = DEAD_NO;
 537
 538                 self.angles = spot.angles;
 539
 540                 self.angles_z = 0; // never spawn tilted even if the spot says to
 541                 if(IS_BOT_CLIENT(self))
 542                         self.v_angle = self.angles;
 543                 self.fixangle = true; // turn this way immediately
 544                 self.velocity = '0 0 0';
 545                 self.avelocity = '0 0 0';
 546                 self.punchangle = '0 0 0';
 547                 self.punchvector = '0 0 0';
 548                 self.oldvelocity = self.velocity;
 549                 self.fire_endtime = -1;
 550                 self.revival_time = 0;
 551
 552                 entity spawnevent = spawn();
 553                 spawnevent.owner = self;
 554                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 555
 556                 // Cut off any still running player sounds.
 557                 stopsound(self, CH_PLAYER_SINGLE);
 558
 559                 self.model = "";
 560                 FixPlayermodel();
 561                 self.drawonlytoclient = world;
 562
 563                 self.crouch = false;
 564                 self.view_ofs = PL_VIEW_OFS;
 565                 setsize (self, PL_MIN, PL_MAX);
 566                 self.spawnorigin = spot.origin;
 567                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins.z - 24));
 568                 // don't reset back to last position, even if new position is stuck in solid
 569                 self.oldorigin = self.origin;
 570                 self.prevorigin = self.origin;
 571                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 572                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 573         self.hud = HUD_NORMAL;
 574
 575                 self.event_damage = PlayerDamage;
 576
 577                 self.bot_attack = true;
 578                 self.monster_attack = true;
 579
 580                 self.spider_slowness = 0;
 581
 582                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 583
 584                 if(self.killcount == -666) {
 585                         PlayerScore_Clear(self);
 586                         self.killcount = 0;
 587                 }
 588
 589                 CL_SpawnWeaponentity();
 590                 self.alpha = default_player_alpha;
 591                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 592                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 593
 594                 self.speedrunning = false;
 595
 596                 //stuffcmd(self, "chase_active 0");
 597                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 598
 599                 target_voicescript_clear(self);
 600
 601                 // reset fields the weapons may use
 602                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 603                 {
 604                         WEP_ACTION(j, WR_RESETPLAYER);
 605
 606                         // all weapons must be fully loaded when we spawn
 607                         entity e = get_weaponinfo(j);
 608                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 609                                 self.(weapon_load[j]) = e.reloading_ammo;
 610                 }
 611
 612                 oldself = self;
 613                 self = spot;
 614                         activator = oldself;
 615                                 string s;
 616                                 s = self.target;
 617                                 self.target = string_null;
 618                                 SUB_UseTargets();
 619                                 self.target = s;
 620                         activator = world;
 621                 self = oldself;
 622
 623                 Unfreeze(self);
 624
 625                 spawn_spot = spot;
 626                 MUTATOR_CALLHOOK(PlayerSpawn);
 627
 628                 if(autocvar_spawn_debug)
 629                 {
 630                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 631                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 632                 }
 633
 634                 self.switchweapon = w_getbestweapon(self);
 635                 self.cnt = -1; // W_LastWeapon will not complain
 636                 self.weapon = 0;
 637                 self.weaponname = "";
 638                 self.switchingweapon = 0;
 639
 640                 if(!warmup_stage)
 641                         if(!self.alivetime)
 642                                 self.alivetime = time;
 643
 644                 antilag_clear(self);
 645         }
 646         else if(IS_OBSERVER(self))
 647         {
 648                 PutObserverInServer ();
 649         }
 650 }
 651
 652 .float ebouncefactor, ebouncestop; // electro's values
 653 // TODO do we need all these fields, or should we stop autodetecting runtime
 654 // changes and just have a console command to update this?
 655 float ClientInit_SendEntity(entity to, float sf)
 656 {
 657         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 658         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 659         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 660         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 661         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 662         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 663         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 664         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 665         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 666         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 667
 668         if(sv_foginterval && world.fog != "")
 669                 WriteString(MSG_ENTITY, world.fog);
 670         else
 671                 WriteString(MSG_ENTITY, "");
 672         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 673         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 674         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 675         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 676         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 677         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 678         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 679         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 680         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 681         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 682         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 683         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 684         return true;
 685 }
 686
 687 void ClientInit_CheckUpdate()
 688 {
 689         self.nextthink = time;
 690         if(self.count != autocvar_g_balance_armor_blockpercent)
 691         {
 692                 self.count = autocvar_g_balance_armor_blockpercent;
 693                 self.SendFlags |= 1;
 694         }
 695         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 696         {
 697                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 698                 self.SendFlags |= 1;
 699         }
 700         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 701         {
 702                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 703                 self.SendFlags |= 1;
 704         }
 705         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 706         {
 707                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 708                 self.SendFlags |= 1;
 709         }
 710         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 711         {
 712                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 713                 self.SendFlags |= 1;
 714         }
 715 }
 716
 717 void ClientInit_Spawn()
 718 {
 719         entity o;
 720         entity e;
 721         e = spawn();
 722         e.classname = "clientinit";
 723         e.think = ClientInit_CheckUpdate;
 724         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 725
 726         o = self;
 727         self = e;
 728         ClientInit_CheckUpdate();
 729         self = o;
 730 }
 731
 732 /*
 733 =============
 734 SetNewParms
 735 =============
 736 */
 737 void SetNewParms (void)
 738 {
 739         // initialize parms for a new player
 740         parm1 = -(86400 * 366);
 741 }
 742
 743 /*
 744 =============
 745 SetChangeParms
 746 =============
 747 */
 748 void SetChangeParms (void)
 749 {
 750         // save parms for level change
 751         parm1 = self.parm_idlesince - time;
 752 }
 753
 754 /*
 755 =============
 756 DecodeLevelParms
 757 =============
 758 */
 759 void DecodeLevelParms (void)
 760 {
 761         // load parms
 762         self.parm_idlesince = parm1;
 763         if(self.parm_idlesince == -(86400 * 366))
 764                 self.parm_idlesince = time;
 765
 766         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 767         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 768 }
 769
 770 /*
 771 =============
 772 ClientKill
 773
 774 Called when a client types 'kill' in the console
 775 =============
 776 */
 777
 778 .float clientkill_nexttime;
 779 void ClientKill_Now_TeamChange()
 780 {
 781         if(self.killindicator_teamchange == -1)
 782         {
 783                 JoinBestTeam( self, false, true );
 784         }
 785         else if(self.killindicator_teamchange == -2)
 786         {
 787                 if(blockSpectators)
 788                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 789                 PutObserverInServer();
 790         }
 791         else
 792                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 793         self.killindicator_teamchange = 0;
 794 }
 795
 796 void ClientKill_Now()
 797 {
 798         if(self.vehicle)
 799         {
 800             vehicles_exit(VHEF_RELESE);
 801             if(!self.killindicator_teamchange)
 802             {
 803             self.vehicle_health = -1;
 804             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 805             }
 806         }
 807
 808         if(self.killindicator && !wasfreed(self.killindicator))
 809                 remove(self.killindicator);
 810
 811         self.killindicator = world;
 812
 813         if(self.killindicator_teamchange)
 814                 ClientKill_Now_TeamChange();
 815
 816         if(IS_PLAYER(self))
 817                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 818
 819         // now I am sure the player IS dead
 820 }
 821 void KillIndicator_Think()
 822 {
 823         if (gameover)
 824         {
 825                 self.owner.killindicator = world;
 826                 remove(self);
 827                 return;
 828         }
 829
 830         if (self.owner.alpha < 0 && !self.owner.vehicle)
 831         {
 832                 self.owner.killindicator = world;
 833                 remove(self);
 834                 return;
 835         }
 836
 837         if(self.cnt <= 0)
 838         {
 839                 self = self.owner;
 840                 ClientKill_Now(); // no oldself needed
 841                 return;
 842         }
 843     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 844     {
 845         self.nextthink = time + 1;
 846         self.cnt -= 1;
 847     }
 848         else
 849         {
 850                 if(self.cnt <= 10)
 851                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 852                 if(IS_REAL_CLIENT(self.owner))
 853                 {
 854                         if(self.cnt <= 10)
 855                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 856                 }
 857                 self.nextthink = time + 1;
 858                 self.cnt -= 1;
 859         }
 860 }
 861
 862 float clientkilltime;
 863 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 864 {
 865         float killtime;
 866         float starttime;
 867         entity e;
 868
 869         if (gameover)
 870                 return;
 871
 872         killtime = autocvar_g_balance_kill_delay;
 873
 874         if(g_race_qualifying || g_cts)
 875                 killtime = 0;
 876
 877     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 878     {
 879                 remove(self.killindicator);
 880                 self.killindicator = world;
 881
 882         ClientKill_Now(); // allow instant kill in this case
 883         return;
 884     }
 885
 886         self.killindicator_teamchange = targetteam;
 887
 888     if(!self.killindicator)
 889         {
 890                 if(self.deadflag == DEAD_NO)
 891                 {
 892                         killtime = max(killtime, self.clientkill_nexttime - time);
 893                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 894                 }
 895
 896                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 897                 {
 898                         ClientKill_Now();
 899                 }
 900                 else
 901                 {
 902                         starttime = max(time, clientkilltime);
 903
 904                         self.killindicator = spawn();
 905                         self.killindicator.owner = self;
 906                         self.killindicator.scale = 0.5;
 907                         setattachment(self.killindicator, self, "");
 908                         setorigin(self.killindicator, '0 0 52');
 909                         self.killindicator.think = KillIndicator_Think;
 910                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 911                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 912                         self.killindicator.cnt = ceil(killtime);
 913                         self.killindicator.count = bound(0, ceil(killtime), 10);
 914                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 915
 916                         for(e = world; (e = find(e, classname, "body")) != world; )
 917                         {
 918                                 if(e.enemy != self)
 919                                         continue;
 920                                 e.killindicator = spawn();
 921                                 e.killindicator.owner = e;
 922                                 e.killindicator.scale = 0.5;
 923                                 setattachment(e.killindicator, e, "");
 924                                 setorigin(e.killindicator, '0 0 52');
 925                                 e.killindicator.think = KillIndicator_Think;
 926                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 927                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 928                                 e.killindicator.cnt = ceil(killtime);
 929                         }
 930                         self.lip = 0;
 931                 }
 932         }
 933         if(self.killindicator)
 934         {
 935                 if(targetteam == 0) // just die
 936                 {
 937                         self.killindicator.colormod = '0 0 0';
 938                         if(IS_REAL_CLIENT(self))
 939                         if(self.killindicator.cnt > 0)
 940                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 941                 }
 942                 else if(targetteam == -1) // auto
 943                 {
 944                         self.killindicator.colormod = '0 1 0';
 945                         if(IS_REAL_CLIENT(self))
 946                         if(self.killindicator.cnt > 0)
 947                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 948                 }
 949                 else if(targetteam == -2) // spectate
 950                 {
 951                         self.killindicator.colormod = '0.5 0.5 0.5';
 952                         if(IS_REAL_CLIENT(self))
 953                         if(self.killindicator.cnt > 0)
 954                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 955                 }
 956                 else
 957                 {
 958                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 959                         if(IS_REAL_CLIENT(self))
 960                         if(self.killindicator.cnt > 0)
 961                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 962                 }
 963         }
 964
 965 }
 966
 967 void ClientKill (void)
 968 {
 969         if(gameover) return;
 970         if(self.player_blocked) return;
 971         if(self.frozen) return;
 972
 973         ClientKill_TeamChange(0);
 974 }
 975
 976 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 977 {
 978     e.killindicator = spawn();
 979     e.killindicator.owner = e;
 980     e.killindicator.think = KillIndicator_Think;
 981     e.killindicator.nextthink = time + (e.lip) * 0.05;
 982     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 983     e.killindicator.health = 1; // this is used to indicate that it should be silent
 984     e.lip = 0;
 985 }
 986
 987 void FixClientCvars(entity e)
 988 {
 989         // send prediction settings to the client
 990         stuffcmd(e, "\nin_bindmap 0 0\n");
 991         if(g_race || g_cts)
 992                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 993         if(autocvar_g_antilag == 3) // client side hitscan
 994                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 995         if(autocvar_sv_gentle)
 996                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 997 }
 998
 999 float PlayerInIDList(entity p, string idlist)
1000 {
1001         float n, i;
1002         string s;
1003
1004         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1005         if (!p.crypto_idfp)
1006                 return 0;
1007
1008         // this function allows abbreviated player IDs too!
1009         n = tokenize_console(idlist);
1010         for(i = 0; i < n; ++i)
1011         {
1012                 s = argv(i);
1013                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1014                         return 1;
1015         }
1016
1017         return 0;
1018 }
1019
1020 #ifdef DP_EXT_PRECONNECT
1021 /*
1022 =============
1023 ClientPreConnect
1024
1025 Called once (not at each match start) when a client begins a connection to the server
1026 =============
1027 */
1028 void ClientPreConnect (void)
1029 {
1030         if(autocvar_sv_eventlog)
1031         {
1032                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1033                         self.playerid,
1034                         num_for_edict(self),
1035                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
1036                 ));
1037         }
1038 }
1039 #endif
1040
1041 /*
1042 =============
1043 ClientConnect
1044
1045 Called when a client connects to the server
1046 =============
1047 */
1048 void DecodeLevelParms (void);
1049 //void dom_player_join_team(entity pl);
1050 void set_dom_state(entity e);
1051 void ClientConnect (void)
1052 {
1053         float t;
1054
1055         if(IS_CLIENT(self))
1056         {
1057                 print("Warning: ClientConnect, but already connected!\n");
1058                 return;
1059         }
1060
1061         if(Ban_MaybeEnforceBanOnce(self))
1062                 return;
1063
1064         DecodeLevelParms();
1065
1066 #ifdef WATERMARK
1067         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1068 #endif
1069
1070         self.classname = "player_joining";
1071
1072         self.flags = FL_CLIENT;
1073         self.version_nagtime = time + 10 + random() * 10;
1074
1075         if(player_count<0)
1076         {
1077                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1078                 player_count = 0;
1079         }
1080
1081         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1082
1083         PlayerScore_Attach(self);
1084         ClientData_Attach();
1085         accuracy_init(self);
1086
1087         bot_clientconnect();
1088
1089         playerdemo_init();
1090
1091         anticheat_init();
1092
1093         // identify the right forced team
1094         if(autocvar_g_campaign)
1095         {
1096                 if(IS_REAL_CLIENT(self)) // only players, not bots
1097                 {
1098                         switch(autocvar_g_campaign_forceteam)
1099                         {
1100                                 case 1: self.team_forced = NUM_TEAM_1; break;
1101                                 case 2: self.team_forced = NUM_TEAM_2; break;
1102                                 case 3: self.team_forced = NUM_TEAM_3; break;
1103                                 case 4: self.team_forced = NUM_TEAM_4; break;
1104                                 default: self.team_forced = 0;
1105                         }
1106                 }
1107         }
1108         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1109                 self.team_forced = NUM_TEAM_1;
1110         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1111                 self.team_forced = NUM_TEAM_2;
1112         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1113                 self.team_forced = NUM_TEAM_3;
1114         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1115                 self.team_forced = NUM_TEAM_4;
1116         else if(autocvar_g_forced_team_otherwise == "red")
1117                 self.team_forced = NUM_TEAM_1;
1118         else if(autocvar_g_forced_team_otherwise == "blue")
1119                 self.team_forced = NUM_TEAM_2;
1120         else if(autocvar_g_forced_team_otherwise == "yellow")
1121                 self.team_forced = NUM_TEAM_3;
1122         else if(autocvar_g_forced_team_otherwise == "pink")
1123                 self.team_forced = NUM_TEAM_4;
1124         else if(autocvar_g_forced_team_otherwise == "spectate")
1125                 self.team_forced = -1;
1126         else if(autocvar_g_forced_team_otherwise == "spectator")
1127                 self.team_forced = -1;
1128         else
1129                 self.team_forced = 0;
1130
1131         if(!teamplay)
1132                 if(self.team_forced > 0)
1133                         self.team_forced = 0;
1134
1135         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1136
1137         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1138                 self.classname = "observer";
1139         } else {
1140                 if(teamplay)
1141                 {
1142                         if(autocvar_g_balance_teams)
1143                         {
1144                                 self.classname = "player";
1145                                 campaign_bots_may_start = 1;
1146                         }
1147                         else
1148                         {
1149                                 self.classname = "observer"; // do it anyway
1150                         }
1151                 }
1152                 else
1153                 {
1154                         self.classname = "player";
1155                         campaign_bots_may_start = 1;
1156                 }
1157         }
1158
1159         self.playerid = (playerid_last = playerid_last + 1);
1160
1161         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1162
1163     if(IS_BOT_CLIENT(self))
1164         PlayerStats_GameReport_AddPlayer(self);
1165
1166         if(autocvar_sv_eventlog)
1167                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1168
1169         LogTeamchange(self.playerid, self.team, 1);
1170
1171         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1172
1173         self.netname_previous = strzone(self.netname);
1174
1175         if(IS_PLAYER(self) && teamplay)
1176                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1177         else
1178                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1179
1180         stuffcmd(self, strcat(clientstuff, "\n"));
1181         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1182
1183         FixClientCvars(self);
1184
1185         // spawnfunc_waypoint sprites
1186         WaypointSprite_InitClient(self);
1187
1188         // Wazat's grappling hook
1189         SetGrappleHookBindings();
1190
1191         // Jetpack binds
1192         stuffcmd(self, "alias +jetpack +button10\n");
1193         stuffcmd(self, "alias -jetpack -button10\n");
1194
1195         // get version info from player
1196         stuffcmd(self, "cmd clientversion $gameversion\n");
1197
1198         // get other cvars from player
1199         GetCvars(0);
1200
1201         // notify about available teams
1202         if(teamplay)
1203         {
1204                 CheckAllowedTeams(self);
1205                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1206                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1207         }
1208         else
1209                 stuffcmd(self, "set _teams_available 0\n");
1210
1211         attach_entcs();
1212
1213         bot_relinkplayerlist();
1214
1215         self.spectatortime = time;
1216         if(blockSpectators)
1217         {
1218                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1219         }
1220
1221         self.jointime = time;
1222         self.allowed_timeouts = autocvar_sv_timeout_number;
1223
1224         if(IS_REAL_CLIENT(self))
1225         {
1226                 if(!autocvar_g_campaign)
1227                 {
1228                         self.motd_actived_time = -1;
1229                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1230                 }
1231
1232                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1233                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1234         }
1235
1236         if(!sv_foginterval && world.fog != "")
1237                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1238
1239         W_HitPlotOpen(self);
1240
1241         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1242                 send_CSQC_teamnagger();
1243
1244         CheatInitClient();
1245
1246         CSQCMODEL_AUTOINIT();
1247
1248         self.model_randomizer = random();
1249
1250         if(IS_REAL_CLIENT(self))
1251                 sv_notice_join();
1252
1253         MUTATOR_CALLHOOK(ClientConnect);
1254 }
1255 /*
1256 =============
1257 ClientDisconnect
1258
1259 Called when a client disconnects from the server
1260 =============
1261 */
1262 .entity chatbubbleentity;
1263 void ReadyCount();
1264 void ClientDisconnect (void)
1265 {
1266         if(self.vehicle)
1267             vehicles_exit(VHEF_RELESE);
1268
1269         if (!IS_CLIENT(self))
1270         {
1271                 print("Warning: ClientDisconnect without ClientConnect\n");
1272                 return;
1273         }
1274
1275         PlayerStats_GameReport_FinalizePlayer(self);
1276
1277         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1278
1279         CheatShutdownClient();
1280
1281         W_HitPlotClose(self);
1282
1283         anticheat_report();
1284         anticheat_shutdown();
1285
1286         playerdemo_shutdown();
1287
1288         bot_clientdisconnect();
1289
1290         if(self.entcs)
1291                 detach_entcs();
1292
1293         if(autocvar_sv_eventlog)
1294                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1295
1296         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1297
1298         MUTATOR_CALLHOOK(ClientDisconnect);
1299
1300         Portal_ClearAll(self);
1301
1302         Unfreeze(self);
1303
1304         RemoveGrapplingHook(self);
1305
1306         // Here, everything has been done that requires this player to be a client.
1307
1308         self.flags &= ~FL_CLIENT;
1309
1310         if (self.chatbubbleentity)
1311                 remove (self.chatbubbleentity);
1312
1313         if (self.killindicator)
1314                 remove (self.killindicator);
1315
1316         WaypointSprite_PlayerGone();
1317
1318         bot_relinkplayerlist();
1319
1320         accuracy_free(self);
1321         ClientData_Detach();
1322         PlayerScore_Detach(self);
1323
1324         if(self.netname_previous)
1325                 strunzone(self.netname_previous);
1326         if(self.clientstatus)
1327                 strunzone(self.clientstatus);
1328         if(self.weaponorder_byimpulse)
1329                 strunzone(self.weaponorder_byimpulse);
1330
1331         ClearPlayerSounds();
1332
1333         if(self.personal)
1334                 remove(self.personal);
1335
1336         self.playerid = 0;
1337         ReadyCount();
1338
1339         // free cvars
1340         GetCvars(-1);
1341 }
1342
1343 .float BUTTON_CHAT;
1344 void ChatBubbleThink()
1345 {
1346         self.nextthink = time;
1347         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1348         {
1349                 if(self.owner) // but why can that ever be world?
1350                         self.owner.chatbubbleentity = world;
1351                 remove(self);
1352                 return;
1353         }
1354         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1355 #ifdef TETRIS
1356                 || self.owner.tetris_on
1357 #endif
1358         )
1359                 self.model = self.mdl;
1360         else
1361                 self.model = "";
1362 }
1363
1364 void UpdateChatBubble()
1365 {
1366         if (self.alpha < 0)
1367                 return;
1368         // spawn a chatbubble entity if needed
1369         if (!self.chatbubbleentity)
1370         {
1371                 self.chatbubbleentity = spawn();
1372                 self.chatbubbleentity.owner = self;
1373                 self.chatbubbleentity.exteriormodeltoclient = self;
1374                 self.chatbubbleentity.think = ChatBubbleThink;
1375                 self.chatbubbleentity.nextthink = time;
1376                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1377                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1378                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs.z * '0 0 1');
1379                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1380                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1381                 self.chatbubbleentity.model = "";
1382                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1383         }
1384 }
1385
1386
1387 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1388 // added to the model skins
1389 /*void UpdateColorModHack()
1390 {
1391         float c;
1392         c = self.clientcolors & 15;
1393         // LordHavoc: only bothering to support white, green, red, yellow, blue
1394              if (!teamplay) self.colormod = '0 0 0';
1395         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1396         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1397         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1398         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1399         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1400         else self.colormod = '1 1 1';
1401 }*/
1402
1403 void respawn(void)
1404 {
1405         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1406         {
1407                 self.solid = SOLID_NOT;
1408                 self.takedamage = DAMAGE_NO;
1409                 self.movetype = MOVETYPE_FLY;
1410                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1411                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1412                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1413                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1414                 if(autocvar_g_respawn_ghosts_maxtime)
1415                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1416         }
1417
1418         CopyBody(1);
1419
1420         self.effects |= EF_NODRAW; // prevent another CopyBody
1421         PutClientInServer();
1422 }
1423
1424 void play_countdown(float finished, string samp)
1425 {
1426         if(IS_REAL_CLIENT(self))
1427                 if(floor(finished - time - frametime) != floor(finished - time))
1428                         if(finished - time < 6)
1429                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1430 }
1431
1432 void player_powerups (void)
1433 {
1434         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1435         olditems = self.items;
1436
1437         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1438                 self.modelflags |= MF_ROCKET;
1439         else
1440                 self.modelflags &= ~MF_ROCKET;
1441
1442         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1443
1444         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1445                 return;
1446
1447         Fire_ApplyDamage(self);
1448         Fire_ApplyEffect(self);
1449
1450         if (!g_instagib)
1451         {
1452                 if (self.items & IT_STRENGTH)
1453                 {
1454                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1455                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1456                         if (time > self.strength_finished)
1457                         {
1458                                 self.items = self.items - (self.items & IT_STRENGTH);
1459                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1460                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1461                         }
1462                 }
1463                 else
1464                 {
1465                         if (time < self.strength_finished)
1466                         {
1467                                 self.items = self.items | IT_STRENGTH;
1468                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1469                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1470                         }
1471                 }
1472                 if (self.items & IT_INVINCIBLE)
1473                 {
1474                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1475                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1476                         if (time > self.invincible_finished)
1477                         {
1478                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1479                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1480                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1481                         }
1482                 }
1483                 else
1484                 {
1485                         if (time < self.invincible_finished)
1486                         {
1487                                 self.items = self.items | IT_INVINCIBLE;
1488                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1489                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1490                         }
1491                 }
1492                 if (self.items & IT_SUPERWEAPON)
1493                 {
1494                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1495                         {
1496                                 self.superweapons_finished = 0;
1497                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1498                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1499                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1500                         }
1501                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1502                         {
1503                                 // don't let them run out
1504                         }
1505                         else
1506                         {
1507                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1508                                 if (time > self.superweapons_finished)
1509                                 {
1510                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1511                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1512                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1513                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1514                                 }
1515                         }
1516                 }
1517                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1518                 {
1519                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1520                         {
1521                                 self.items = self.items | IT_SUPERWEAPON;
1522                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1523                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1524                         }
1525                         else
1526                         {
1527                                 self.superweapons_finished = 0;
1528                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1529                         }
1530                 }
1531                 else
1532                 {
1533                         self.superweapons_finished = 0;
1534                 }
1535         }
1536
1537         if(autocvar_g_nodepthtestplayers)
1538                 self.effects = self.effects | EF_NODEPTHTEST;
1539
1540         if(autocvar_g_fullbrightplayers)
1541                 self.effects = self.effects | EF_FULLBRIGHT;
1542
1543         if (time >= game_starttime)
1544         if (time < self.spawnshieldtime)
1545                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1546
1547         MUTATOR_CALLHOOK(PlayerPowerups);
1548 }
1549
1550 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1551 {
1552         if(current > stable)
1553                 return current;
1554         else if(current > stable - 0.25) // when close enough, "snap"
1555                 return stable;
1556         else
1557                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1558 }
1559
1560 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1561 {
1562         if(current < stable)
1563                 return current;
1564         else if(current < stable + 0.25) // when close enough, "snap"
1565                 return stable;
1566         else
1567                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1568 }
1569
1570 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1571 {
1572         if(current > rotstable)
1573         {
1574                 if(rotframetime > 0)
1575                 {
1576                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1577                         current = max(rotstable, current - rotlinear * rotframetime);
1578                 }
1579         }
1580         else if(current < regenstable)
1581         {
1582                 if(regenframetime > 0)
1583                 {
1584                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1585                         current = min(regenstable, current + regenlinear * regenframetime);
1586                 }
1587         }
1588
1589         if(current > limit)
1590                 current = limit;
1591
1592         return current;
1593 }
1594
1595 void player_regen (void)
1596 {
1597         float max_mod, regen_mod, rot_mod, limit_mod;
1598         max_mod = regen_mod = rot_mod = limit_mod = 1;
1599         regen_mod_max = max_mod;
1600         regen_mod_regen = regen_mod;
1601         regen_mod_rot = rot_mod;
1602         regen_mod_limit = limit_mod;
1603         if(!MUTATOR_CALLHOOK(PlayerRegen))
1604         if(!self.frozen)
1605         {
1606                 float minh, mina, maxh, maxa, limith, limita;
1607                 maxh = autocvar_g_balance_health_rotstable;
1608                 maxa = autocvar_g_balance_armor_rotstable;
1609                 minh = autocvar_g_balance_health_regenstable;
1610                 mina = autocvar_g_balance_armor_regenstable;
1611                 limith = autocvar_g_balance_health_limit;
1612                 limita = autocvar_g_balance_armor_limit;
1613
1614                 max_mod = regen_mod_max;
1615                 regen_mod = regen_mod_regen;
1616                 rot_mod = regen_mod_rot;
1617                 limit_mod = regen_mod_limit;
1618
1619                 maxh = maxh * max_mod;
1620                 minh = minh * max_mod;
1621                 limith = limith * limit_mod;
1622                 limita = limita * limit_mod;
1623
1624                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1625                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1626         }
1627
1628         // if player rotted to death...  die!
1629         // check this outside above checks, as player may still be able to rot to death
1630         if(self.health < 1)
1631                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1632
1633         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1634         {
1635                 float minf, maxf, limitf;
1636
1637                 maxf = autocvar_g_balance_fuel_rotstable;
1638                 minf = autocvar_g_balance_fuel_regenstable;
1639                 limitf = autocvar_g_balance_fuel_limit;
1640
1641                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1642         }
1643 }
1644
1645 float zoomstate_set;
1646 void SetZoomState(float z)
1647 {
1648         if(z != self.zoomstate)
1649         {
1650                 self.zoomstate = z;
1651                 ClientData_Touch(self);
1652         }
1653         zoomstate_set = 1;
1654 }
1655
1656 void GetPressedKeys(void) {
1657         MUTATOR_CALLHOOK(GetPressedKeys);
1658         #define X(var,bit,flag) (flag ? var |= bit : var &= ~bit)
1659         X(self.pressedkeys, KEY_FORWARD,        PHYS_INPUT_MOVEVALUES(self)_x > 0);
1660         X(self.pressedkeys, KEY_BACKWARD,       PHYS_INPUT_MOVEVALUES(self)_x < 0);
1661         X(self.pressedkeys, KEY_RIGHT,          PHYS_INPUT_MOVEVALUES(self)_y > 0);
1662         X(self.pressedkeys, KEY_LEFT,           PHYS_INPUT_MOVEVALUES(self)_y < 0);
1663
1664         X(self.pressedkeys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(self));
1665         X(self.pressedkeys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(self));
1666         X(self.pressedkeys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(self));
1667         X(self.pressedkeys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(self));
1668         #undef X
1669 }
1670
1671 /*
1672 ======================
1673 spectate mode routines
1674 ======================
1675 */
1676
1677 void SpectateCopy(entity spectatee) {
1678         other = spectatee;
1679         MUTATOR_CALLHOOK(SpectateCopy);
1680         self.armortype = spectatee.armortype;
1681         self.armorvalue = spectatee.armorvalue;
1682         self.ammo_cells = spectatee.ammo_cells;
1683         self.ammo_plasma = spectatee.ammo_plasma;
1684         self.ammo_shells = spectatee.ammo_shells;
1685         self.ammo_nails = spectatee.ammo_nails;
1686         self.ammo_rockets = spectatee.ammo_rockets;
1687         self.ammo_fuel = spectatee.ammo_fuel;
1688         self.clip_load = spectatee.clip_load;
1689         self.clip_size = spectatee.clip_size;
1690         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1691         self.health = spectatee.health;
1692         self.impulse = 0;
1693         self.items = spectatee.items;
1694         self.last_pickup = spectatee.last_pickup;
1695         self.hit_time = spectatee.hit_time;
1696         self.metertime = spectatee.metertime;
1697         self.strength_finished = spectatee.strength_finished;
1698         self.invincible_finished = spectatee.invincible_finished;
1699         self.pressedkeys = spectatee.pressedkeys;
1700         self.weapons = spectatee.weapons;
1701         self.switchweapon = spectatee.switchweapon;
1702         self.switchingweapon = spectatee.switchingweapon;
1703         self.weapon = spectatee.weapon;
1704         self.vortex_charge = spectatee.vortex_charge;
1705         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1706         self.hagar_load = spectatee.hagar_load;
1707         self.arc_heat_percent = spectatee.arc_heat_percent;
1708         self.minelayer_mines = spectatee.minelayer_mines;
1709         self.punchangle = spectatee.punchangle;
1710         self.view_ofs = spectatee.view_ofs;
1711         self.velocity = spectatee.velocity;
1712         self.dmg_take = spectatee.dmg_take;
1713         self.dmg_save = spectatee.dmg_save;
1714         self.dmg_inflictor = spectatee.dmg_inflictor;
1715         self.v_angle = spectatee.v_angle;
1716         self.angles = spectatee.v_angle;
1717         self.frozen = spectatee.frozen;
1718         self.revive_progress = spectatee.revive_progress;
1719         if(!self.BUTTON_USE)
1720                 self.fixangle = true;
1721         setorigin(self, spectatee.origin);
1722         setsize(self, spectatee.mins, spectatee.maxs);
1723         SetZoomState(spectatee.zoomstate);
1724
1725     anticheat_spectatecopy(spectatee);
1726         self.hud = spectatee.hud;
1727         if(spectatee.vehicle)
1728     {
1729         self.fixangle = false;
1730         //self.velocity = spectatee.vehicle.velocity;
1731         self.vehicle_health = spectatee.vehicle_health;
1732         self.vehicle_shield = spectatee.vehicle_shield;
1733         self.vehicle_energy = spectatee.vehicle_energy;
1734         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1735         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1736         self.vehicle_reload1 = spectatee.vehicle_reload1;
1737         self.vehicle_reload2 = spectatee.vehicle_reload2;
1738
1739         msg_entity = self;
1740
1741         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1742             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1743             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1744             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1745
1746         //WriteByte (MSG_ONE, SVC_SETVIEW);
1747         //    WriteEntity(MSG_ONE, self);
1748         //makevectors(spectatee.v_angle);
1749         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1750     }
1751 }
1752
1753 float SpectateUpdate()
1754 {
1755         if(!self.enemy)
1756             return 0;
1757
1758         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1759         {
1760                 SetSpectator(self, world);
1761                 return 0;
1762         }
1763
1764         SpectateCopy(self.enemy);
1765
1766         return 1;
1767 }
1768
1769 float SpectateSet()
1770 {
1771         if(self.enemy.classname != "player")
1772                 return false;
1773         /*if(self.enemy.vehicle)
1774         {
1775
1776                 msg_entity = self;
1777                 WriteByte(MSG_ONE, SVC_SETVIEW);
1778                 WriteEntity(MSG_ONE, self.enemy);
1779                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1780
1781                 self.movetype = MOVETYPE_NONE;
1782                 accuracy_resend(self);
1783         }
1784         else
1785         {*/
1786                 msg_entity = self;
1787                 WriteByte(MSG_ONE, SVC_SETVIEW);
1788                 WriteEntity(MSG_ONE, self.enemy);
1789                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1790                 self.movetype = MOVETYPE_NONE;
1791                 accuracy_resend(self);
1792
1793                 if(!SpectateUpdate())
1794                         PutObserverInServer();
1795         //}
1796         return true;
1797 }
1798
1799 void SetSpectator(entity player, entity spectatee)
1800 {
1801         entity old_spectatee = player.enemy;
1802
1803         player.enemy = spectatee;
1804
1805         // WEAPONTODO
1806         // these are required to fix the spectator bug with arc
1807         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1808         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1809 }
1810
1811 float Spectate(entity pl)
1812 {
1813         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1814         if(pl.team != self.team)
1815                 return 0;
1816
1817         SetSpectator(self, pl);
1818         return SpectateSet();
1819 }
1820
1821 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1822 entity CA_SpectateNext(entity start) {
1823         if (start.team == self.team) {
1824                 return start;
1825         }
1826
1827         other = start;
1828         // continue from current player
1829         while(other && other.team != self.team) {
1830                 other = find(other, classname, "player");
1831         }
1832
1833         if (!other) {
1834                 // restart from begining
1835                 other = find(other, classname, "player");
1836                 while(other && other.team != self.team) {
1837                         other = find(other, classname, "player");
1838                 }
1839         }
1840
1841         return other;
1842 }
1843
1844 float SpectateNext()
1845 {
1846         other = find(self.enemy, classname, "player");
1847
1848         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1849                 // CA and ca players when spectating enemies is forbidden
1850                 other = CA_SpectateNext(other);
1851         } else {
1852                 // other modes and ca spectators or spectating enemies is allowed
1853                 if (!other)
1854                         other = find(other, classname, "player");
1855         }
1856
1857         if(other) { SetSpectator(self, other); }
1858
1859         return SpectateSet();
1860 }
1861
1862 float SpectatePrev()
1863 {
1864         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1865         other = findchain(classname, "player");
1866         if (!other) // no player
1867                 return false;
1868
1869         entity first = other;
1870         // skip players until current spectated player
1871         if(self.enemy)
1872         while(other && other != self.enemy)
1873                 other = other.chain;
1874
1875         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1876         {
1877                 do { other = other.chain; }
1878                 while(other && other.team != self.team);
1879
1880                 if (!other)
1881                 {
1882                         other = first;
1883                         while(other.team != self.team)
1884                                 other = other.chain;
1885                         if(other == self.enemy)
1886                                 return true;
1887                 }
1888         }
1889         else
1890         {
1891                 if(other.chain)
1892                         other = other.chain;
1893                 else
1894                         other = first;
1895         }
1896         SetSpectator(self, other);
1897         return SpectateSet();
1898 }
1899
1900 /*
1901 =============
1902 ShowRespawnCountdown()
1903
1904 Update a respawn countdown display.
1905 =============
1906 */
1907 void ShowRespawnCountdown()
1908 {
1909         float number;
1910         if(self.deadflag == DEAD_NO) // just respawned?
1911                 return;
1912         else
1913         {
1914                 number = ceil(self.respawn_time - time);
1915                 if(number <= 0)
1916                         return;
1917                 if(number <= self.respawn_countdown)
1918                 {
1919                         self.respawn_countdown = number - 1;
1920                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1921                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1922                 }
1923         }
1924 }
1925
1926 void LeaveSpectatorMode()
1927 {
1928         if(self.caplayer)
1929                 return;
1930         if(nJoinAllowed(self))
1931         {
1932                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1933                 {
1934                         self.classname = "player";
1935                         nades_RemoveBonus(self);
1936
1937                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1938                                 { JoinBestTeam(self, false, true); }
1939
1940                         if(autocvar_g_campaign)
1941                                 { campaign_bots_may_start = 1; }
1942
1943                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1944
1945                         PutClientInServer();
1946
1947                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1948                 }
1949                 else
1950                         stuffcmd(self, "menu_showteamselect\n");
1951         }
1952         else
1953         {
1954                 // Player may not join because g_maxplayers is set
1955                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1956         }
1957 }
1958
1959 /**
1960  * Determines whether the player is allowed to join. This depends on cvar
1961  * g_maxplayers, if it isn't used this function always return true, otherwise
1962  * it checks whether the number of currently playing players exceeds g_maxplayers.
1963  * @return int number of free slots for players, 0 if none
1964  */
1965 float nJoinAllowed(entity ignore) {
1966         if(!ignore)
1967         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1968         // so report 0 free slots if restricted
1969         {
1970                 if(autocvar_g_forced_team_otherwise == "spectate")
1971                         return 0;
1972                 if(autocvar_g_forced_team_otherwise == "spectator")
1973                         return 0;
1974         }
1975
1976         if(self.team_forced < 0)
1977                 return 0; // forced spectators can never join
1978
1979         // TODO simplify this
1980         entity e;
1981         float totalClients = 0;
1982         FOR_EACH_CLIENT(e)
1983                 if(e != ignore)
1984                         totalClients += 1;
1985
1986         if (!autocvar_g_maxplayers)
1987                 return maxclients - totalClients;
1988
1989         float currentlyPlaying = 0;
1990         FOR_EACH_REALCLIENT(e)
1991                 if(IS_PLAYER(e) || e.caplayer)
1992                         currentlyPlaying += 1;
1993
1994         if(currentlyPlaying < autocvar_g_maxplayers)
1995                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1996
1997         return 0;
1998 }
1999
2000 /**
2001  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2002  * g_maxplayers_spectator_blocktime seconds
2003  */
2004 void checkSpectatorBlock() {
2005         if(IS_SPEC(self) || IS_OBSERVER(self))
2006         if(!self.caplayer)
2007         if(IS_REAL_CLIENT(self))
2008         {
2009                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2010                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2011                         dropclient(self);
2012                 }
2013         }
2014 }
2015
2016 void PrintWelcomeMessage()
2017 {
2018         if(self.motd_actived_time == 0)
2019         {
2020                 if (autocvar_g_campaign) {
2021                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2022                                 self.motd_actived_time = time;
2023                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2024                         }
2025                 } else {
2026                         if (self.BUTTON_INFO) {
2027                                 self.motd_actived_time = time;
2028                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2029                         }
2030                 }
2031         }
2032         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2033         {
2034                 if (autocvar_g_campaign) {
2035                         if (self.BUTTON_INFO)
2036                                 self.motd_actived_time = time;
2037                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2038                                 self.motd_actived_time = 0;
2039                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2040                         }
2041                 } else {
2042                         if (self.BUTTON_INFO)
2043                                 self.motd_actived_time = time;
2044                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2045                                 self.motd_actived_time = 0;
2046                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2047                         }
2048                 }
2049         }
2050         else //if(self.motd_actived_time < 0) // just connected, motd is active
2051         {
2052                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2053                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2054                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2055                 {
2056                         // instanctly hide MOTD
2057                         self.motd_actived_time = 0;
2058                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2059                 }
2060         }
2061 }
2062
2063 void ObserverThink()
2064 {
2065         float prefered_movetype;
2066         if (self.flags & FL_JUMPRELEASED) {
2067                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2068                         self.flags &= ~FL_JUMPRELEASED;
2069                         self.flags |= FL_SPAWNING;
2070                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2071                         self.flags &= ~FL_JUMPRELEASED;
2072                         if(SpectateNext()) {
2073                                 self.classname = "spectator";
2074                         }
2075                 } else {
2076                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2077                         if (self.movetype != prefered_movetype)
2078                                 self.movetype = prefered_movetype;
2079                 }
2080         } else {
2081                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2082                         self.flags |= FL_JUMPRELEASED;
2083                         if(self.flags & FL_SPAWNING)
2084                         {
2085                                 self.flags &= ~FL_SPAWNING;
2086                                 LeaveSpectatorMode();
2087                                 return;
2088                         }
2089                 }
2090         }
2091 }
2092
2093 void SpectatorThink()
2094 {
2095         if (self.flags & FL_JUMPRELEASED) {
2096                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2097                         self.flags &= ~FL_JUMPRELEASED;
2098                         self.flags |= FL_SPAWNING;
2099                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2100                         self.flags &= ~FL_JUMPRELEASED;
2101                         if(SpectateNext()) {
2102                                 self.classname = "spectator";
2103                         } else {
2104                                 self.classname = "observer";
2105                                 PutClientInServer();
2106                         }
2107                         self.impulse = 0;
2108                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2109                         self.flags &= ~FL_JUMPRELEASED;
2110                         if(SpectatePrev()) {
2111                                 self.classname = "spectator";
2112                         } else {
2113                                 self.classname = "observer";
2114                                 PutClientInServer();
2115                         }
2116                         self.impulse = 0;
2117                 } else if (self.BUTTON_ATCK2) {
2118                         self.flags &= ~FL_JUMPRELEASED;
2119                         self.classname = "observer";
2120                         PutClientInServer();
2121                 } else {
2122                         if(!SpectateUpdate())
2123                                 PutObserverInServer();
2124                 }
2125         } else {
2126                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2127                         self.flags |= FL_JUMPRELEASED;
2128                         if(self.flags & FL_SPAWNING)
2129                         {
2130                                 self.flags &= ~FL_SPAWNING;
2131                                 LeaveSpectatorMode();
2132                                 return;
2133                         }
2134                 }
2135                 if(!SpectateUpdate())
2136                         PutObserverInServer();
2137         }
2138
2139         self.flags |= FL_CLIENT | FL_NOTARGET;
2140 }
2141
2142 void PlayerUseKey()
2143 {
2144         if (!IS_PLAYER(self))
2145                 return;
2146
2147         if(self.vehicle)
2148         {
2149         vehicles_exit(VHEF_NORMAL);
2150         return;
2151         }
2152
2153         // a use key was pressed; call handlers
2154         MUTATOR_CALLHOOK(PlayerUseKey);
2155 }
2156
2157 float isInvisibleString(string s)
2158 {
2159         float i, n, c;
2160         s = strdecolorize(s);
2161         for((i = 0), (n = strlen(s)); i < n; ++i)
2162         {
2163                 c = str2chr(s, i);
2164                 switch(c)
2165                 {
2166                         case 0:
2167                         case 32: // space
2168                                 break;
2169                         case 192: // charmap space
2170                                 if (!autocvar_utf8_enable)
2171                                         break;
2172                                 return false;
2173                         case 160: // space in unicode fonts
2174                         case 0xE000 + 192: // utf8 charmap space
2175                                 if (autocvar_utf8_enable)
2176                                         break;
2177                         default:
2178                                 return false;
2179                 }
2180         }
2181         return true;
2182 }
2183
2184 /*
2185 =============
2186 PlayerPreThink
2187
2188 Called every frame for each client before the physics are run
2189 =============
2190 */
2191 .float usekeypressed;
2192 void() nexball_setstatus;
2193 .int items_added;
2194 void PlayerPreThink (void)
2195 {
2196         WarpZone_PlayerPhysics_FixVAngle();
2197
2198         self.stat_game_starttime = game_starttime;
2199         self.stat_round_starttime = round_starttime;
2200         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2201         self.stat_leadlimit = autocvar_leadlimit;
2202
2203         if(frametime)
2204         {
2205                 // physics frames: update anticheat stuff
2206                 anticheat_prethink();
2207         }
2208
2209         if(blockSpectators && frametime)
2210                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2211                 checkSpectatorBlock();
2212
2213         zoomstate_set = 0;
2214
2215         // Savage: Check for nameless players
2216         if (isInvisibleString(self.netname)) {
2217                 string new_name = strzone(strcat("Player@", self.netaddress));
2218                 if(autocvar_sv_eventlog)
2219                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2220                 if(self.netname_previous)
2221                         strunzone(self.netname_previous);
2222                 self.netname_previous = strzone(new_name);
2223                 self.netname = self.netname_previous;
2224                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2225         } else if(self.netname_previous != self.netname) {
2226                 if(autocvar_sv_eventlog)
2227                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2228                 if(self.netname_previous)
2229                         strunzone(self.netname_previous);
2230                 self.netname_previous = strzone(self.netname);
2231         }
2232
2233         // version nagging
2234         if(self.version_nagtime)
2235                 if(self.cvar_g_xonoticversion)
2236                         if(time > self.version_nagtime)
2237                         {
2238                                 // don't notify git users
2239                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2240                                 {
2241                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2242                                         {
2243                                                 // notify release users if connecting to git
2244                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2245                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2246                                         }
2247                                         else
2248                                         {
2249                                                 float r;
2250                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2251                                                 if(r < 0)
2252                                                 {
2253                                                         // give users new version
2254                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2255                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2256                                                 }
2257                                                 else if(r > 0)
2258                                                 {
2259                                                         // notify users about old server version
2260                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2261                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2262                                                 }
2263                                         }
2264                                 }
2265                                 self.version_nagtime = 0;
2266                         }
2267
2268         // GOD MODE info
2269         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2270         {
2271                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2272                 self.max_armorvalue = 0;
2273         }
2274
2275 #ifdef TETRIS
2276         if (TetrisPreFrame())
2277                 return;
2278 #endif
2279
2280         if(self.frozen == 2)
2281         {
2282                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2283                 self.health = max(1, self.revive_progress * start_health);
2284                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2285
2286                 if(self.revive_progress >= 1)
2287                         Unfreeze(self);
2288         }
2289         else if(self.frozen == 3)
2290         {
2291                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2292                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2293
2294                 if(self.health < 1)
2295                 {
2296                         if(self.vehicle)
2297                                 vehicles_exit(VHEF_RELESE);
2298                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2299                 }
2300                 else if ( self.revive_progress <= 0 )
2301                         Unfreeze(self);
2302         }
2303
2304         MUTATOR_CALLHOOK(PlayerPreThink);
2305
2306         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2307         {
2308                 if(self.BUTTON_USE && !self.usekeypressed)
2309                         PlayerUseKey();
2310                 self.usekeypressed = self.BUTTON_USE;
2311         }
2312
2313         if(IS_REAL_CLIENT(self))
2314                 PrintWelcomeMessage();
2315
2316         if(IS_PLAYER(self))
2317         {
2318
2319                 CheckRules_Player();
2320
2321                 if (intermission_running)
2322                 {
2323                         IntermissionThink ();   // otherwise a button could be missed between
2324                         return;                                 // the think tics
2325                 }
2326
2327                 //don't allow the player to turn around while game is paused!
2328                 if(timeout_status == TIMEOUT_ACTIVE) {
2329                         // FIXME turn this into CSQC stuff
2330                         self.v_angle = self.lastV_angle;
2331                         self.angles = self.lastV_angle;
2332                         self.fixangle = true;
2333                 }
2334
2335                 if(frametime)
2336                 {
2337                         if(self.weapon == WEP_VORTEX && WEP_CVAR(vortex, charge))
2338                         {
2339                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2340                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2341                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2342
2343                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2344                                 {
2345                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2346                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2347                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2348                                 }
2349                         }
2350                         else
2351                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2352
2353                         player_powerups();
2354                 }
2355
2356                 if (self.deadflag != DEAD_NO)
2357                 {
2358                         if(self.personal && g_race_qualifying)
2359                         {
2360                                 if(time > self.respawn_time)
2361                                 {
2362                                         self.respawn_time = time + 1; // only retry once a second
2363                                         self.stat_respawn_time = self.respawn_time;
2364                                         respawn();
2365                                         self.impulse = 141;
2366                                 }
2367                         }
2368                         else
2369                         {
2370                                 float button_pressed;
2371                                 if(frametime)
2372                                         player_anim();
2373                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2374
2375                                 if (self.deadflag == DEAD_DYING)
2376                                 {
2377                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2378                                                 self.deadflag = DEAD_RESPAWNING;
2379                                         else if(!button_pressed)
2380                                                 self.deadflag = DEAD_DEAD;
2381                                 }
2382                                 else if (self.deadflag == DEAD_DEAD)
2383                                 {
2384                                         if(button_pressed)
2385                                                 self.deadflag = DEAD_RESPAWNABLE;
2386                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2387                                                 self.deadflag = DEAD_RESPAWNING;
2388                                 }
2389                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2390                                 {
2391                                         if(!button_pressed)
2392                                                 self.deadflag = DEAD_RESPAWNING;
2393                                 }
2394                                 else if (self.deadflag == DEAD_RESPAWNING)
2395                                 {
2396                                         if(time > self.respawn_time)
2397                                         {
2398                                                 self.respawn_time = time + 1; // only retry once a second
2399                                                 self.respawn_time_max = self.respawn_time;
2400                                                 respawn();
2401                                         }
2402                                 }
2403
2404                                 ShowRespawnCountdown();
2405
2406                                 if(self.respawn_flags & RESPAWN_SILENT)
2407                                         self.stat_respawn_time = 0;
2408                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2409                                         self.stat_respawn_time = self.respawn_time_max;
2410                                 else
2411                                         self.stat_respawn_time = self.respawn_time;
2412                         }
2413
2414                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2415                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2416                                 self.stat_respawn_time *= -1;
2417
2418                         return;
2419                 }
2420
2421                 self.prevorigin = self.origin;
2422
2423                 float do_crouch = self.BUTTON_CROUCH;
2424                 if(self.hook.state)
2425                         do_crouch = 0;
2426                 if(self.vehicle)
2427                         do_crouch = 0;
2428                 if(self.frozen)
2429                         do_crouch = 0;
2430
2431                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2432                 // It cannot be predicted by the engine!
2433                 if((self.weapon == WEP_SHOCKWAVE || self.weapon == WEP_SHOTGUN) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2434                         do_crouch = 0;
2435
2436                 if (do_crouch)
2437                 {
2438                         if (!self.crouch)
2439                         {
2440                                 self.crouch = true;
2441                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2442                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2443                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2444                         }
2445                 }
2446                 else
2447                 {
2448                         if (self.crouch)
2449                         {
2450                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, false, self);
2451                                 if (!trace_startsolid)
2452                                 {
2453                                         self.crouch = false;
2454                                         self.view_ofs = PL_VIEW_OFS;
2455                                         setsize (self, PL_MIN, PL_MAX);
2456                                 }
2457                         }
2458                 }
2459
2460                 FixPlayermodel();
2461
2462                 GrapplingHookFrame();
2463
2464                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2465                 //if(frametime)
2466                 {
2467                         self.items &= ~self.items_added;
2468
2469                         W_WeaponFrame();
2470
2471                         self.items_added = 0;
2472                         if(self.items & IT_JETPACK)
2473                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2474                                         self.items_added |= IT_FUEL;
2475
2476                         self.items |= self.items_added;
2477                 }
2478
2479                 player_regen();
2480
2481                 // WEAPONTODO: Add a weapon request for this
2482                 // rot vortex charge to the charge limit
2483                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2484                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2485
2486                 if(frametime)
2487                         player_anim();
2488
2489                 // secret status
2490                 secrets_setstatus();
2491
2492                 // monsters status
2493                 monsters_setstatus();
2494
2495                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2496
2497                 //self.angles_y=self.v_angle_y + 90;   // temp
2498         } else if(gameover) {
2499                 if (intermission_running)
2500                         IntermissionThink ();   // otherwise a button could be missed between
2501                 return;
2502         } else if(IS_OBSERVER(self)) {
2503                 ObserverThink();
2504         } else if(IS_SPEC(self)) {
2505                 SpectatorThink();
2506         }
2507
2508         // WEAPONTODO: Add weapon request for this
2509         if(!zoomstate_set)
2510                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2511
2512         float oldspectatee_status;
2513         oldspectatee_status = self.spectatee_status;
2514         if(IS_SPEC(self))
2515                 self.spectatee_status = num_for_edict(self.enemy);
2516         else if(IS_OBSERVER(self))
2517                 self.spectatee_status = num_for_edict(self);
2518         else
2519                 self.spectatee_status = 0;
2520         if(self.spectatee_status != oldspectatee_status)
2521         {
2522                 ClientData_Touch(self);
2523         }
2524
2525         if(self.teamkill_soundtime)
2526         if(time > self.teamkill_soundtime)
2527         {
2528                 self.teamkill_soundtime = 0;
2529
2530                 entity oldpusher, oldself;
2531
2532                 oldself = self; self = self.teamkill_soundsource;
2533                 oldpusher = self.pusher; self.pusher = oldself;
2534
2535                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2536
2537                 self.pusher = oldpusher;
2538                 self = oldself;
2539         }
2540
2541         if(self.taunt_soundtime)
2542         if(time > self.taunt_soundtime)
2543         {
2544                 self.taunt_soundtime = 0;
2545                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2546         }
2547
2548         target_voicescript_next(self);
2549
2550         // WEAPONTODO: Move into weaponsystem somehow
2551         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2552         if(!self.weapon)
2553                 self.clip_load = self.clip_size = 0;
2554 }
2555
2556 /*
2557 =============
2558 PlayerPostThink
2559
2560 Called every frame for each client after the physics are run
2561 =============
2562 */
2563 .float idlekick_lasttimeleft;
2564 void PlayerPostThink (void)
2565 {
2566         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2567         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2568         {
2569                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2570                 {
2571                         if(self.idlekick_lasttimeleft)
2572                         {
2573                                 self.idlekick_lasttimeleft = 0;
2574                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2575                         }
2576                 }
2577                 else
2578                 {
2579                         float timeleft;
2580                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2581                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2582                         {
2583                                 if(!self.idlekick_lasttimeleft)
2584                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2585                         }
2586                         if(timeleft <= 0)
2587                         {
2588                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2589                                 dropclient(self);
2590                                 return;
2591                         }
2592                         else if(timeleft <= 10)
2593                         {
2594                                 if(timeleft != self.idlekick_lasttimeleft)
2595                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2596                                 self.idlekick_lasttimeleft = timeleft;
2597                         }
2598                 }
2599         }
2600
2601 #ifdef TETRIS
2602         if(self.impulse == 100)
2603                 ImpulseCommands();
2604         if (!TetrisPostFrame())
2605         {
2606 #endif
2607
2608         CheatFrame();
2609
2610         //CheckPlayerJump();
2611
2612         if(IS_PLAYER(self)) {
2613                 CheckRules_Player();
2614                 UpdateChatBubble();
2615                 if (self.impulse)
2616                         ImpulseCommands();
2617                 if (intermission_running)
2618                         return;         // intermission or finale
2619                 GetPressedKeys();
2620         }
2621
2622 #ifdef TETRIS
2623         }
2624 #endif
2625
2626         /*
2627         float i;
2628         for(i = 0; i < 1000; ++i)
2629         {
2630                 vector end;
2631                 end = self.origin + '0 0 1024' + 512 * randomvec();
2632                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2633                 if(trace_fraction < 1)
2634                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2635                 {
2636                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2637                         break;
2638                 }
2639         }
2640         */
2641
2642         if(self.waypointsprite_attachedforcarrier)
2643                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2644
2645         playerdemo_write();
2646
2647         CSQCMODEL_AUTOUPDATE();
2648 }