qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         minstagib_stop_countdown(self);
 408
 409         Portal_ClearAll(self);
 410
 411         if(self.alivetime)
 412         {
 413                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 414                 self.alivetime = 0;
 415         }
 416
 417         if(self.vehicle)
 418             vehicles_exit(VHEF_RELESE);
 419
 420         if(self.flagcarried)
 421                 DropFlag(self.flagcarried, world, world);
 422
 423         WaypointSprite_PlayerDead();
 424
 425         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 426                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 427
 428         if(self.killcount != -666) {
 429                 if(g_lms) {
 430                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 431                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 432                         else
 433                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 434                 } else
 435                         bprint ("^4", self.netname, "^4 is spectating now\n");
 436
 437                 if(self.just_joined == FALSE) {
 438                         LogTeamchange(self.playerid, -1, 4);
 439                 } else
 440                         self.just_joined = FALSE;
 441         }
 442
 443         PlayerScore_Clear(self); // clear scores when needed
 444
 445         accuracy_resend(self);
 446
 447         self.spectatortime = time;
 448
 449         self.classname = "observer";
 450         self.iscreature = FALSE;
 451         self.damagedbycontents = FALSE;
 452         self.health = -666;
 453         self.takedamage = DAMAGE_NO;
 454         self.solid = SOLID_NOT;
 455         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 456         self.flags = FL_CLIENT | FL_NOTARGET;
 457         self.armorvalue = 666;
 458         self.effects = 0;
 459         self.armorvalue = autocvar_g_balance_armor_start;
 460         self.pauserotarmor_finished = 0;
 461         self.pauserothealth_finished = 0;
 462         self.pauseregen_finished = 0;
 463         self.damageforcescale = 0;
 464         self.death_time = 0;
 465         self.respawn_time = 0;
 466         self.alpha = 0;
 467         self.scale = 0;
 468         self.fade_time = 0;
 469         self.pain_frame = 0;
 470         self.pain_finished = 0;
 471         self.strength_finished = 0;
 472         self.invincible_finished = 0;
 473         self.superweapons_finished = 0;
 474         self.pushltime = 0;
 475         self.istypefrag = 0;
 476         self.think = SUB_Null;
 477         self.nextthink = 0;
 478         self.hook_time = 0;
 479         self.runes = 0;
 480         self.deadflag = DEAD_NO;
 481         self.angles = spot.angles;
 482         self.angles_z = 0;
 483         self.fixangle = TRUE;
 484         self.crouch = FALSE;
 485
 486         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 487         self.prevorigin = self.origin;
 488         self.items = 0;
 489         WEPSET_CLEAR_E(self);
 490         self.model = "";
 491         FixPlayermodel();
 492         setmodel(self, "null");
 493         self.drawonlytoclient = self;
 494
 495         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 496         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 497
 498         self.weapon = 0;
 499         self.weaponname = "";
 500         self.switchingweapon = 0;
 501         self.weaponmodel = "";
 502         self.weaponentity = world;
 503         self.exteriorweaponentity = world;
 504         self.killcount = -666;
 505         self.velocity = '0 0 0';
 506         self.avelocity = '0 0 0';
 507         self.punchangle = '0 0 0';
 508         self.punchvector = '0 0 0';
 509         self.oldvelocity = self.velocity;
 510         self.fire_endtime = -1;
 511
 512         if(g_arena)
 513         {
 514                 if(self.version_mismatch)
 515                 {
 516                         Spawnqueue_Unmark(self);
 517                         Spawnqueue_Remove(self);
 518                 }
 519                 else
 520                 {
 521                         Spawnqueue_Insert(self);
 522                 }
 523         }
 524         else if(g_lms)
 525         {
 526                 // Only if the player cannot play at all
 527                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 528                         self.frags = FRAGS_SPECTATOR;
 529                 else
 530                         self.frags = FRAGS_LMS_LOSER;
 531         }
 532         else if(g_ca)
 533         {
 534                 if(self.caplayer)
 535                         self.frags = FRAGS_LMS_LOSER;
 536                 else
 537                         self.frags = FRAGS_SPECTATOR;
 538         }
 539         else
 540                 self.frags = FRAGS_SPECTATOR;
 541 }
 542
 543 .float model_randomizer;
 544 void FixPlayermodel()
 545 {
 546         string defaultmodel;
 547         float defaultskin, chmdl, oldskin, n, i;
 548         vector m1, m2;
 549
 550         defaultmodel = "";
 551         defaultskin = 0;
 552         chmdl = FALSE;
 553
 554         if(autocvar_sv_defaultcharacter == 1)
 555         {
 556                 if(teamplay)
 557                 {
 558                         string s;
 559                         s = Team_ColorNameLowerCase(self.team);
 560                         if(s != "neutral")
 561                         {
 562                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 563                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 564                         }
 565                 }
 566
 567                 if(defaultmodel == "")
 568                 {
 569                         defaultmodel = autocvar_sv_defaultplayermodel;
 570                         defaultskin = autocvar_sv_defaultplayerskin;
 571                 }
 572
 573                 n = tokenize_console(defaultmodel);
 574                 if(n > 0)
 575                         defaultmodel = argv(floor(n * self.model_randomizer));
 576
 577                 i = strstrofs(defaultmodel, ":", 0);
 578                 if(i >= 0)
 579                 {
 580                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 581                         defaultmodel = substring(defaultmodel, 0, i);
 582                 }
 583         }
 584
 585         if(defaultmodel != "")
 586         {
 587                 if (defaultmodel != self.model)
 588                 {
 589                         m1 = self.mins;
 590                         m2 = self.maxs;
 591                         setplayermodel (self, defaultmodel);
 592                         setsize (self, m1, m2);
 593                         chmdl = TRUE;
 594                 }
 595
 596                 oldskin = self.skin;
 597                 self.skin = defaultskin;
 598         } else {
 599                 if (self.playermodel != self.model || self.playermodel == "")
 600                 {
 601                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 602                         m1 = self.mins;
 603                         m2 = self.maxs;
 604                         setplayermodel (self, self.playermodel);
 605                         setsize (self, m1, m2);
 606                         chmdl = TRUE;
 607                 }
 608
 609                 oldskin = self.skin;
 610                 self.skin = stof(self.playerskin);
 611         }
 612
 613         if(chmdl || oldskin != self.skin)
 614                 self.species = player_getspecies(); // model or skin has changed
 615
 616         if(!teamplay)
 617                 if(strlen(autocvar_sv_defaultplayercolors))
 618                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 619                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 620 }
 621
 622 void PlayerTouchExplode(entity p1, entity p2)
 623 {
 624         vector org;
 625         org = (p1.origin + p2.origin) * 0.5;
 626         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 627
 628         te_explosion(org);
 629
 630         entity e;
 631         e = spawn();
 632         setorigin(e, org);
 633         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 634         remove(e);
 635 }
 636
 637 /*
 638 =============
 639 PutClientInServer
 640
 641 Called when a client spawns in the server
 642 =============
 643 */
 644 //void() ctf_playerchanged;
 645
 646 void PutClientInServer (void)
 647 {
 648         if(clienttype(self) == CLIENTTYPE_BOT)
 649         {
 650                 self.classname = "player";
 651                 if(g_ca)
 652                         self.caplayer = 1;
 653         }
 654         else if(clienttype(self) == CLIENTTYPE_REAL)
 655         {
 656                 msg_entity = self;
 657                 WriteByte(MSG_ONE, SVC_SETVIEW);
 658                 WriteEntity(MSG_ONE, self);
 659         }
 660
 661         // reset player keys
 662         self.itemkeys = 0;
 663
 664         // player is dead and becomes observer
 665         // FIXME fix LMS scoring for new system
 666         if(g_lms)
 667         {
 668                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 669                         self.classname = "observer";
 670         }
 671
 672         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
 673                 self.classname = "observer";
 674
 675         if(gameover)
 676                 self.classname = "observer";
 677
 678         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 679                 entity spot, oldself;
 680                 float j;
 681
 682                 accuracy_resend(self);
 683
 684                 if(self.team < 0)
 685                         JoinBestTeam(self, FALSE, TRUE);
 686
 687                 race_PreSpawn();
 688
 689                 spot = SelectSpawnPoint (FALSE);
 690                 if(!spot)
 691                 {
 692                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 693                         return; // spawn failed
 694                 }
 695
 696                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 697
 698                 self.classname = "player";
 699                 self.wasplayer = TRUE;
 700                 self.iscreature = TRUE;
 701                 self.damagedbycontents = TRUE;
 702                 self.movetype = MOVETYPE_WALK;
 703                 self.solid = SOLID_SLIDEBOX;
 704                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 705                 if(autocvar_g_playerclip_collisions)
 706                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 707                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 708                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 709                 self.frags = FRAGS_PLAYER;
 710                 if(INDEPENDENT_PLAYERS)
 711                         MAKE_INDEPENDENT_PLAYER(self);
 712                 self.flags = FL_CLIENT;
 713                 if(autocvar__notarget)
 714                         self.flags |= FL_NOTARGET;
 715                 self.takedamage = DAMAGE_AIM;
 716                 if(g_minstagib)
 717                         self.effects = EF_FULLBRIGHT;
 718                 else
 719                         self.effects = 0;
 720                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 721                 self.air_finished = time + 12;
 722                 self.dmg = 2;
 723                 if(autocvar_g_balance_nex_charge)
 724                 {
 725                         if(autocvar_g_balance_nex_secondary_chargepool)
 726                                 self.nex_chargepool_ammo = 1;
 727                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 728                 }
 729
 730                 if(inWarmupStage)
 731                 {
 732                         self.ammo_shells = warmup_start_ammo_shells;
 733                         self.ammo_nails = warmup_start_ammo_nails;
 734                         self.ammo_rockets = warmup_start_ammo_rockets;
 735                         self.ammo_cells = warmup_start_ammo_cells;
 736                         self.ammo_fuel = warmup_start_ammo_fuel;
 737                         self.health = warmup_start_health;
 738                         self.armorvalue = warmup_start_armorvalue;
 739                         WEPSET_COPY_EA(self, warmup_start_weapons);
 740                 }
 741                 else
 742                 {
 743                         self.ammo_shells = start_ammo_shells;
 744                         self.ammo_nails = start_ammo_nails;
 745                         self.ammo_rockets = start_ammo_rockets;
 746                         self.ammo_cells = start_ammo_cells;
 747                         self.ammo_fuel = start_ammo_fuel;
 748                         self.health = start_health;
 749                         self.armorvalue = start_armorvalue;
 750                         WEPSET_COPY_EA(self, start_weapons);
 751                 }
 752
 753                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 754                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 755                 else
 756                         self.superweapons_finished = 0;
 757
 758                 if(g_weaponarena_random)
 759                 {
 760                         if(g_weaponarena_random_with_laser)
 761                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 762                         W_RandomWeapons(self, g_weaponarena_random);
 763                         if(g_weaponarena_random_with_laser)
 764                                 WEPSET_OR_EW(self, WEP_LASER);
 765                 }
 766
 767                 self.items = start_items;
 768
 769                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 770                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 771                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 772                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 773                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 774                 //extend the pause of rotting if client was reset at the beginning of the countdown
 775                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 776                         self.spawnshieldtime += game_starttime - time;
 777                         self.pauserotarmor_finished += game_starttime - time;
 778                         self.pauserothealth_finished += game_starttime - time;
 779                         self.pauseregen_finished += game_starttime - time;
 780                 }
 781                 self.damageforcescale = 2;
 782                 self.death_time = 0;
 783                 self.respawn_time = 0;
 784                 self.scale = 0;
 785                 self.fade_time = 0;
 786                 self.pain_frame = 0;
 787                 self.pain_finished = 0;
 788                 self.strength_finished = 0;
 789                 self.invincible_finished = 0;
 790                 self.pushltime = 0;
 791                 // players have no think function
 792                 self.think = SUB_Null;
 793                 self.nextthink = 0;
 794                 self.hook_time = 0;
 795                 self.dmg_team = 0;
 796                 self.ballistics_density = autocvar_g_ballistics_density_player;
 797
 798                 self.metertime = 0;
 799
 800                 self.runes = 0;
 801
 802                 self.deadflag = DEAD_NO;
 803
 804                 self.angles = spot.angles;
 805
 806                 self.angles_z = 0; // never spawn tilted even if the spot says to
 807                 self.fixangle = TRUE; // turn this way immediately
 808                 self.velocity = '0 0 0';
 809                 self.avelocity = '0 0 0';
 810                 self.punchangle = '0 0 0';
 811                 self.punchvector = '0 0 0';
 812                 self.oldvelocity = self.velocity;
 813                 self.fire_endtime = -1;
 814
 815                 msg_entity = self;
 816                 WRITESPECTATABLE_MSG_ONE({
 817                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 818                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 819                 });
 820
 821                 self.model = "";
 822                 FixPlayermodel();
 823                 self.drawonlytoclient = world;
 824
 825                 self.crouch = FALSE;
 826                 self.view_ofs = PL_VIEW_OFS;
 827                 setsize (self, PL_MIN, PL_MAX);
 828                 self.spawnorigin = spot.origin;
 829                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 830                 // don't reset back to last position, even if new position is stuck in solid
 831                 self.oldorigin = self.origin;
 832                 self.prevorigin = self.origin;
 833                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 834                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 835         self.hud = HUD_NORMAL;
 836
 837                 if(g_arena)
 838                 {
 839                         Spawnqueue_Remove(self);
 840                         Spawnqueue_Mark(self);
 841                 }
 842                 else if(g_ca)
 843                         self.caplayer = 1;
 844
 845                 self.event_damage = PlayerDamage;
 846
 847                 self.bot_attack = TRUE;
 848
 849                 self.statdraintime = time + 5;
 850                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 851
 852                 if(self.killcount == -666) {
 853                         PlayerScore_Clear(self);
 854                         self.killcount = 0;
 855                 }
 856
 857                 CL_SpawnWeaponentity();
 858                 self.alpha = default_player_alpha;
 859                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 860                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 861
 862                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 863                 self.lms_traveled_distance = 0;
 864                 self.speedrunning = FALSE;
 865
 866                 race_PostSpawn(spot);
 867
 868                 //stuffcmd(self, "chase_active 0");
 869                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 870
 871                 if(g_assault) {
 872                         if(self.team == assault_attacker_team)
 873                                 centerprint(self, "You are attacking!");
 874                         else
 875                                 centerprint(self, "You are defending!");
 876                 }
 877
 878                 target_voicescript_clear(self);
 879
 880                 // reset fields the weapons may use
 881                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 882                 {
 883                         weapon_action(j, WR_RESETPLAYER);
 884
 885                         // all weapons must be fully loaded when we spawn
 886                         entity e;
 887                         e = get_weaponinfo(j);
 888                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 889                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 890                 }
 891
 892                 oldself = self;
 893                 self = spot;
 894                         activator = oldself;
 895                                 string s;
 896                                 s = self.target;
 897                                 self.target = string_null;
 898                                 SUB_UseTargets();
 899                                 self.target = s;
 900                         activator = world;
 901                 self = oldself;
 902
 903                 spawn_spot = spot;
 904                 MUTATOR_CALLHOOK(PlayerSpawn);
 905
 906                 if(autocvar_spawn_debug)
 907                 {
 908                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 909                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 910                 }
 911
 912                 self.switchweapon = w_getbestweapon(self);
 913                 self.cnt = -1; // W_LastWeapon will not complain
 914                 self.weapon = 0;
 915                 self.weaponname = "";
 916                 self.switchingweapon = 0;
 917
 918                 if(!self.alivetime)
 919                         self.alivetime = time;
 920
 921                 antilag_clear(self);
 922
 923                 if (autocvar_g_spawnsound)
 924                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 925         } else if(self.classname == "observer") {
 926                 PutObserverInServer ();
 927         }
 928
 929         //if(g_ctf)
 930         //      ctf_playerchanged();
 931 }
 932
 933 .float ebouncefactor, ebouncestop; // electro's values
 934 // TODO do we need all these fields, or should we stop autodetecting runtime
 935 // changes and just have a console command to update this?
 936 float ClientInit_SendEntity(entity to, float sf)
 937 {
 938         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 939         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 940         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 941         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 942         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 943         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 944         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 945         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 946         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 947         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 948
 949         if(sv_foginterval && world.fog != "")
 950                 WriteString(MSG_ENTITY, world.fog);
 951         else
 952                 WriteString(MSG_ENTITY, "");
 953         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 954         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 955         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 956         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 957         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 958         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 959         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 960         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 961         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 962         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 963         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 964         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 965         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 966         return TRUE;
 967 }
 968
 969 void ClientInit_CheckUpdate()
 970 {
 971         self.nextthink = time;
 972         if(self.count != autocvar_g_balance_armor_blockpercent)
 973         {
 974                 self.count = autocvar_g_balance_armor_blockpercent;
 975                 self.SendFlags |= 1;
 976         }
 977         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 978         {
 979                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 980                 self.SendFlags |= 1;
 981         }
 982         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 983         {
 984                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 985                 self.SendFlags |= 1;
 986         }
 987         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 988         {
 989                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 990                 self.SendFlags |= 1;
 991         }
 992         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 993         {
 994                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 995                 self.SendFlags |= 1;
 996         }
 997         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 998         {
 999                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1000                 self.SendFlags |= 1;
1001         }
1002 }
1003
1004 void ClientInit_Spawn()
1005 {
1006         entity o;
1007         entity e;
1008         e = spawn();
1009         e.classname = "clientinit";
1010         e.think = ClientInit_CheckUpdate;
1011         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1012
1013         o = self;
1014         self = e;
1015         ClientInit_CheckUpdate();
1016         self = o;
1017 }
1018
1019 /*
1020 =============
1021 SetNewParms
1022 =============
1023 */
1024 void SetNewParms (void)
1025 {
1026         // initialize parms for a new player
1027         parm1 = -(86400 * 366);
1028 }
1029
1030 /*
1031 =============
1032 SetChangeParms
1033 =============
1034 */
1035 void SetChangeParms (void)
1036 {
1037         // save parms for level change
1038         parm1 = self.parm_idlesince - time;
1039 }
1040
1041 /*
1042 =============
1043 DecodeLevelParms
1044 =============
1045 */
1046 void DecodeLevelParms (void)
1047 {
1048         // load parms
1049         self.parm_idlesince = parm1;
1050         if(self.parm_idlesince == -(86400 * 366))
1051                 self.parm_idlesince = time;
1052
1053         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1054         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1055 }
1056
1057 /*
1058 =============
1059 ClientKill
1060
1061 Called when a client types 'kill' in the console
1062 =============
1063 */
1064
1065 .float clientkill_nexttime;
1066 void ClientKill_Now_TeamChange()
1067 {
1068         if(self.killindicator_teamchange == -1)
1069         {
1070                 JoinBestTeam( self, FALSE, TRUE );
1071         }
1072         else if(self.killindicator_teamchange == -2)
1073         {
1074                 if(g_ca)
1075                         self.caplayer = 0;
1076                 if(blockSpectators)
1077                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1078                 PutObserverInServer();
1079         }
1080         else
1081                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1082 }
1083
1084 void ClientKill_Now()
1085 {
1086         if(self.vehicle)
1087         {
1088             vehicles_exit(VHEF_RELESE);
1089             if(!self.killindicator_teamchange)
1090             {
1091             self.vehicle_health = -1;
1092             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1093             }
1094         }
1095
1096         if(self.killindicator && !wasfreed(self.killindicator))
1097                 remove(self.killindicator);
1098
1099         self.killindicator = world;
1100
1101         if(self.killindicator_teamchange)
1102                 ClientKill_Now_TeamChange();
1103
1104         // in any case:
1105         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1106
1107         // now I am sure the player IS dead
1108 }
1109 void KillIndicator_Think()
1110 {
1111         if (gameover)
1112         {
1113                 self.owner.killindicator = world;
1114                 remove(self);
1115                 return;
1116         }
1117
1118         if (self.owner.alpha < 0)
1119         {
1120                 self.owner.killindicator = world;
1121                 remove(self);
1122                 return;
1123         }
1124
1125         if(self.cnt <= 0)
1126         {
1127                 self = self.owner;
1128                 ClientKill_Now(); // no oldself needed
1129                 return;
1130         }
1131     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1132     {
1133         self.nextthink = time + 1;
1134         self.cnt -= 1;
1135     }
1136         else
1137         {
1138                 if(self.cnt <= 10)
1139                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1140                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1141                 {
1142                         if(self.cnt <= 10)
1143                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1144                 }
1145                 self.nextthink = time + 1;
1146                 self.cnt -= 1;
1147         }
1148 }
1149
1150 float clientkilltime;
1151 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1152 {
1153         float killtime;
1154         float starttime;
1155         entity e;
1156
1157         if (gameover)
1158                 return;
1159
1160         killtime = autocvar_g_balance_kill_delay;
1161
1162         if(g_race_qualifying || g_cts)
1163                 killtime = 0;
1164
1165     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1166     {
1167                 remove(self.killindicator);
1168                 self.killindicator = world;
1169
1170         ClientKill_Now(); // allow instant kill in this case
1171         return;
1172     }
1173
1174         self.killindicator_teamchange = targetteam;
1175
1176     if(!self.killindicator)
1177         {
1178                 if(self.deadflag == DEAD_NO)
1179                 {
1180                         killtime = max(killtime, self.clientkill_nexttime - time);
1181                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1182                 }
1183
1184                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1185                 {
1186                         ClientKill_Now();
1187                 }
1188                 else
1189                 {
1190                         starttime = max(time, clientkilltime);
1191
1192                         self.killindicator = spawn();
1193                         self.killindicator.owner = self;
1194                         self.killindicator.scale = 0.5;
1195                         setattachment(self.killindicator, self, "");
1196                         setorigin(self.killindicator, '0 0 52');
1197                         self.killindicator.think = KillIndicator_Think;
1198                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1199                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1200                         self.killindicator.cnt = ceil(killtime);
1201                         self.killindicator.count = bound(0, ceil(killtime), 10);
1202                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1203
1204                         for(e = world; (e = find(e, classname, "body")) != world; )
1205                         {
1206                                 if(e.enemy != self)
1207                                         continue;
1208                                 e.killindicator = spawn();
1209                                 e.killindicator.owner = e;
1210                                 e.killindicator.scale = 0.5;
1211                                 setattachment(e.killindicator, e, "");
1212                                 setorigin(e.killindicator, '0 0 52');
1213                                 e.killindicator.think = KillIndicator_Think;
1214                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1215                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1216                                 e.killindicator.cnt = ceil(killtime);
1217                         }
1218                         self.lip = 0;
1219                 }
1220         }
1221         if(self.killindicator)
1222         {
1223                 if(targetteam == 0) // just die
1224                 {
1225                         self.killindicator.colormod = '0 0 0';
1226                         if(clienttype(self) == CLIENTTYPE_REAL)
1227                         if(self.killindicator.cnt > 0)
1228                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1229                 }
1230                 else if(targetteam == -1) // auto
1231                 {
1232                         self.killindicator.colormod = '0 1 0';
1233                         if(clienttype(self) == CLIENTTYPE_REAL)
1234                         if(self.killindicator.cnt > 0)
1235                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1236                 }
1237                 else if(targetteam == -2) // spectate
1238                 {
1239                         self.killindicator.colormod = '0.5 0.5 0.5';
1240                         if(clienttype(self) == CLIENTTYPE_REAL)
1241                         if(self.killindicator.cnt > 0)
1242                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1243                 }
1244                 else
1245                 {
1246                         self.killindicator.colormod = TeamColor(targetteam);
1247                         if(clienttype(self) == CLIENTTYPE_REAL)
1248                         if(self.killindicator.cnt > 0)
1249                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1250                 }
1251         }
1252
1253 }
1254
1255 void ClientKill (void)
1256 {
1257         if (gameover)
1258                 return;
1259
1260         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1261         {
1262                 // do nothing
1263         }
1264     else if(self.freezetag_frozen)
1265     {
1266         // do nothing
1267     }
1268         else
1269                 ClientKill_TeamChange(0);
1270 }
1271
1272 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1273 {
1274     e.killindicator = spawn();
1275     e.killindicator.owner = e;
1276     e.killindicator.think = KillIndicator_Think;
1277     e.killindicator.nextthink = time + (e.lip) * 0.05;
1278     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1279     e.killindicator.health = 1; // this is used to indicate that it should be silent
1280     e.lip = 0;
1281 }
1282
1283 void FixClientCvars(entity e)
1284 {
1285         // send prediction settings to the client
1286         stuffcmd(e, "\nin_bindmap 0 0\n");
1287         if(g_race || g_cts)
1288                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1289         if(autocvar_g_antilag == 3) // client side hitscan
1290                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1291         if(sv_gentle)
1292                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1293         /*
1294          * we no longer need to stuff this. Remove this comment block if you feel
1295          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1296         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1297         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1298         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1299         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1300         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1301         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1302         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1303         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1304         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1305         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1306         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1307         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1308         stuffcmd(e, "cl_movement_edgefriction 1\n");
1309          */
1310 }
1311
1312 float PlayerInIDList(entity p, string idlist)
1313 {
1314         float n, i;
1315         string s;
1316
1317         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1318         if not(p.crypto_idfp)
1319                 return 0;
1320
1321         // this function allows abbreviated player IDs too!
1322         n = tokenize_console(idlist);
1323         for(i = 0; i < n; ++i)
1324         {
1325                 s = argv(i);
1326                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1327                         return 1;
1328         }
1329
1330         return 0;
1331 }
1332
1333 /*
1334 =============
1335 ClientConnect
1336
1337 Called when a client connects to the server
1338 =============
1339 */
1340 //void ctf_clientconnect();
1341 string ColoredTeamName(float t);
1342 void DecodeLevelParms (void);
1343 //void dom_player_join_team(entity pl);
1344 void set_dom_state(entity e);
1345 void ClientConnect (void)
1346 {
1347         float t;
1348
1349         if(self.flags & FL_CLIENT)
1350         {
1351                 print("Warning: ClientConnect, but already connected!\n");
1352                 return;
1353         }
1354
1355         if(Ban_MaybeEnforceBanOnce(self))
1356                 return;
1357
1358         DecodeLevelParms();
1359
1360 #ifdef WATERMARK
1361         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1362 #endif
1363
1364         self.classname = "player_joining";
1365
1366         self.flags = FL_CLIENT;
1367         self.version_nagtime = time + 10 + random() * 10;
1368
1369         if(player_count<0)
1370         {
1371                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1372                 player_count = 0;
1373         }
1374
1375         PlayerScore_Attach(self);
1376         ClientData_Attach();
1377         accuracy_init(self);
1378
1379         bot_clientconnect();
1380
1381         playerdemo_init();
1382
1383         anticheat_init();
1384
1385         race_PreSpawnObserver();
1386
1387         //if(g_domination)
1388         //      dom_player_join_team(self);
1389
1390         // identify the right forced team
1391         if(autocvar_g_campaign)
1392         {
1393                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1394                 {
1395                         switch(autocvar_g_campaign_forceteam)
1396                         {
1397                                 case 1: self.team_forced = COLOR_TEAM1; break;
1398                                 case 2: self.team_forced = COLOR_TEAM2; break;
1399                                 case 3: self.team_forced = COLOR_TEAM3; break;
1400                                 case 4: self.team_forced = COLOR_TEAM4; break;
1401                                 default: self.team_forced = 0;
1402                         }
1403                 }
1404         }
1405         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1406                 self.team_forced = COLOR_TEAM1;
1407         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1408                 self.team_forced = COLOR_TEAM2;
1409         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1410                 self.team_forced = COLOR_TEAM3;
1411         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1412                 self.team_forced = COLOR_TEAM4;
1413         else if(autocvar_g_forced_team_otherwise == "red")
1414                 self.team_forced = COLOR_TEAM1;
1415         else if(autocvar_g_forced_team_otherwise == "blue")
1416                 self.team_forced = COLOR_TEAM2;
1417         else if(autocvar_g_forced_team_otherwise == "yellow")
1418                 self.team_forced = COLOR_TEAM3;
1419         else if(autocvar_g_forced_team_otherwise == "pink")
1420                 self.team_forced = COLOR_TEAM4;
1421         else if(autocvar_g_forced_team_otherwise == "spectate")
1422                 self.team_forced = -1;
1423         else if(autocvar_g_forced_team_otherwise == "spectator")
1424                 self.team_forced = -1;
1425         else
1426                 self.team_forced = 0;
1427
1428         if(!teamplay)
1429                 if(self.team_forced > 0)
1430                         self.team_forced = 0;
1431
1432         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1433
1434         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1435                 self.classname = "observer";
1436         } else {
1437                 if(teamplay)
1438                 {
1439                         if(autocvar_g_balance_teams)
1440                         {
1441                                 self.classname = "player";
1442                                 campaign_bots_may_start = 1;
1443                         }
1444                         else
1445                         {
1446                                 self.classname = "observer"; // do it anyway
1447                         }
1448                 }
1449                 else
1450                 {
1451                         self.classname = "player";
1452                         campaign_bots_may_start = 1;
1453                 }
1454         }
1455
1456         self.playerid = (playerid_last = playerid_last + 1);
1457
1458         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1459
1460     if(clienttype(self) == CLIENTTYPE_BOT)
1461         PlayerStats_AddPlayer(self);
1462
1463         if(autocvar_sv_eventlog)
1464                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1465
1466         LogTeamchange(self.playerid, self.team, 1);
1467
1468         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1469
1470         self.netname_previous = strzone(self.netname);
1471
1472         bprint("^4", self.netname, "^4 connected");
1473
1474         if(self.classname != "observer" && (g_domination || g_ctf))
1475                 bprint(" and joined the ", ColoredTeamName(self.team));
1476
1477         bprint("\n");
1478
1479         stuffcmd(self, strcat(clientstuff, "\n"));
1480         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1481
1482         FixClientCvars(self);
1483
1484         // spawnfunc_waypoint sprites
1485         WaypointSprite_InitClient(self);
1486
1487         // Wazat's grappling hook
1488         SetGrappleHookBindings();
1489
1490         // get version info from player
1491         stuffcmd(self, "cmd clientversion $gameversion\n");
1492
1493         // get other cvars from player
1494         GetCvars(0);
1495
1496         // notify about available teams
1497         if(teamplay)
1498         {
1499                 CheckAllowedTeams(self);
1500                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1501                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1502         }
1503         else
1504                 stuffcmd(self, "set _teams_available 0\n");
1505
1506         if(g_arena || g_ca)
1507         {
1508                 self.classname = "observer";
1509                 if(g_arena)
1510                         Spawnqueue_Insert(self);
1511         }
1512         /*else if(g_ctf)
1513         {
1514                 ctf_clientconnect();
1515         }*/
1516
1517         attach_entcs();
1518
1519         bot_relinkplayerlist();
1520
1521         self.spectatortime = time;
1522         if(blockSpectators)
1523         {
1524                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1525         }
1526
1527         self.jointime = time;
1528         self.allowed_timeouts = autocvar_sv_timeout_number;
1529
1530         if(clienttype(self) == CLIENTTYPE_REAL)
1531         {
1532                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1533                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1534         }
1535
1536         if(g_lms)
1537         {
1538                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1539                 {
1540                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1541                         self.frags = FRAGS_SPECTATOR;
1542                 }
1543         }
1544
1545         if(!sv_foginterval && world.fog != "")
1546                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1547
1548         SoundEntity_Attach(self);
1549
1550         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1551         {
1552                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1553                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1554         }
1555         else
1556                 self.hitplotfh = -1;
1557
1558         if(g_race || g_cts) {
1559                 string rr;
1560                 if(g_cts)
1561                         rr = CTS_RECORD;
1562                 else
1563                         rr = RACE_RECORD;
1564
1565                 msg_entity = self;
1566                 race_send_recordtime(MSG_ONE);
1567                 race_send_speedaward(MSG_ONE);
1568
1569                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1570                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1571                 race_send_speedaward_alltimebest(MSG_ONE);
1572
1573                 float i;
1574                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1575                         race_SendRankings(i, 0, 0, MSG_ONE);
1576                 }
1577         }
1578         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1579                 send_CSQC_teamnagger();
1580
1581         if (g_domination)
1582                 set_dom_state(self);
1583
1584         CheatInitClient();
1585
1586         if(!autocvar_g_campaign)
1587                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1588
1589         CSQCMODEL_AUTOINIT();
1590
1591         self.model_randomizer = random();
1592
1593     if(clienttype(self) != CLIENTTYPE_REAL)
1594         return;
1595
1596     sv_notice_join();
1597 }
1598 /*
1599 =============
1600 ClientDisconnect
1601
1602 Called when a client disconnects from the server
1603 =============
1604 */
1605 .entity chatbubbleentity;
1606 void ReadyCount();
1607 void ClientDisconnect (void)
1608 {
1609         if(self.vehicle)
1610             vehicles_exit(VHEF_RELESE);
1611
1612         if not(self.flags & FL_CLIENT)
1613         {
1614                 print("Warning: ClientDisconnect without ClientConnect\n");
1615                 return;
1616         }
1617
1618         PlayerStats_AddGlobalInfo(self);
1619
1620         CheatShutdownClient();
1621
1622         if(self.hitplotfh >= 0)
1623         {
1624                 fclose(self.hitplotfh);
1625                 self.hitplotfh = -1;
1626         }
1627
1628         anticheat_report();
1629         anticheat_shutdown();
1630
1631         playerdemo_shutdown();
1632
1633         bot_clientdisconnect();
1634
1635         if(self.entcs)
1636                 detach_entcs();
1637
1638         if(autocvar_sv_eventlog)
1639                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1640         bprint ("^4",self.netname);
1641         bprint ("^4 disconnected\n");
1642
1643         SoundEntity_Detach(self);
1644
1645         DropAllRunes(self);
1646         MUTATOR_CALLHOOK(ClientDisconnect);
1647
1648         Portal_ClearAll(self);
1649
1650         RemoveGrapplingHook(self);
1651         if(self.flagcarried)
1652                 DropFlag(self.flagcarried, world, world);
1653
1654         // Here, everything has been done that requires this player to be a client.
1655
1656         self.flags &~= FL_CLIENT;
1657
1658         if (self.chatbubbleentity)
1659                 remove (self.chatbubbleentity);
1660
1661         if (self.killindicator)
1662                 remove (self.killindicator);
1663
1664         WaypointSprite_PlayerGone();
1665
1666         bot_relinkplayerlist();
1667
1668         if(g_arena)
1669         {
1670                 Spawnqueue_Unmark(self);
1671                 Spawnqueue_Remove(self);
1672         }
1673
1674         accuracy_free(self);
1675         ClientData_Detach();
1676         PlayerScore_Detach(self);
1677
1678         if(self.netname_previous)
1679                 strunzone(self.netname_previous);
1680         if(self.clientstatus)
1681                 strunzone(self.clientstatus);
1682         if(self.weaponorder_byimpulse)
1683                 strunzone(self.weaponorder_byimpulse);
1684
1685         ClearPlayerSounds();
1686
1687         if(self.personal)
1688                 remove(self.personal);
1689
1690         self.playerid = 0;
1691         ReadyCount();
1692
1693         // free cvars
1694         GetCvars(-1);
1695 }
1696
1697 .float BUTTON_CHAT;
1698 void ChatBubbleThink()
1699 {
1700         self.nextthink = time;
1701         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1702         {
1703                 if(self.owner) // but why can that ever be world?
1704                         self.owner.chatbubbleentity = world;
1705                 remove(self);
1706                 return;
1707         }
1708         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1709 #ifdef TETRIS
1710                 || self.owner.tetris_on
1711 #endif
1712         )
1713                 self.model = self.mdl;
1714         else
1715                 self.model = "";
1716 }
1717
1718 void UpdateChatBubble()
1719 {
1720         if (self.alpha < 0)
1721                 return;
1722         // spawn a chatbubble entity if needed
1723         if (!self.chatbubbleentity)
1724         {
1725                 self.chatbubbleentity = spawn();
1726                 self.chatbubbleentity.owner = self;
1727                 self.chatbubbleentity.exteriormodeltoclient = self;
1728                 self.chatbubbleentity.think = ChatBubbleThink;
1729                 self.chatbubbleentity.nextthink = time;
1730                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1731                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1732                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1733                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1734                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1735                 self.chatbubbleentity.model = "";
1736                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1737         }
1738 }
1739
1740
1741 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1742 // added to the model skins
1743 /*void UpdateColorModHack()
1744 {
1745         float c;
1746         c = self.clientcolors & 15;
1747         // LordHavoc: only bothering to support white, green, red, yellow, blue
1748              if (!teamplay) self.colormod = '0 0 0';
1749         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1750         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1751         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1752         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1753         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1754         else self.colormod = '1 1 1';
1755 }*/
1756
1757 void respawn(void)
1758 {
1759         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1760         {
1761                 self.solid = SOLID_NOT;
1762                 self.takedamage = DAMAGE_NO;
1763                 self.movetype = MOVETYPE_FLY;
1764                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1765                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1766                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1767                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1768                 if(autocvar_g_respawn_ghosts_maxtime)
1769                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1770         }
1771
1772         CopyBody(1);
1773
1774         self.effects |= EF_NODRAW; // prevent another CopyBody
1775         PutClientInServer();
1776 }
1777
1778 void play_countdown(float finished, string samp)
1779 {
1780         if(clienttype(self) == CLIENTTYPE_REAL)
1781                 if(floor(finished - time - frametime) != floor(finished - time))
1782                         if(finished - time < 6)
1783                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1784 }
1785
1786 void player_powerups (void)
1787 {
1788         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1789         olditems = self.items;
1790
1791         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1792         {
1793                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1794                 self.modelflags |= MF_ROCKET;
1795         }
1796         else
1797         {
1798                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1799                 self.modelflags &~= MF_ROCKET;
1800         }
1801
1802         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1803
1804         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1805                 return;
1806
1807         Fire_ApplyDamage(self);
1808         Fire_ApplyEffect(self);
1809
1810         if (g_minstagib)
1811         {
1812                 self.effects |= EF_FULLBRIGHT;
1813
1814                 if (self.items & IT_STRENGTH)
1815                 {
1816                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1817                         if (time > self.strength_finished)
1818                         {
1819                                 self.alpha = default_player_alpha;
1820                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1821                                 self.items &~= IT_STRENGTH;
1822                                 sprint(self, "^3Invisibility has worn off\n");
1823                         }
1824                 }
1825                 else
1826                 {
1827                         if (time < self.strength_finished)
1828                         {
1829                                 self.alpha = g_minstagib_invis_alpha;
1830                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1831                                 self.items |= IT_STRENGTH;
1832                                 sprint(self, "^3You are invisible\n");
1833                         }
1834                 }
1835
1836                 if (self.items & IT_INVINCIBLE)
1837                 {
1838                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1839                         if (time > self.invincible_finished)
1840                         {
1841                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1842                                 sprint(self, "^3Speed has worn off\n");
1843                         }
1844                 }
1845                 else
1846                 {
1847                         if (time < self.invincible_finished)
1848                         {
1849                                 self.items = self.items | IT_INVINCIBLE;
1850                                 sprint(self, "^3You are on speed\n");
1851                         }
1852                 }
1853         }
1854         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1855         {
1856                 if (self.items & IT_STRENGTH)
1857                 {
1858                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1859                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1860                         if (time > self.strength_finished)
1861                         {
1862                                 self.items = self.items - (self.items & IT_STRENGTH);
1863                                 sprint(self, "^3Strength has worn off\n");
1864                         }
1865                 }
1866                 else
1867                 {
1868                         if (time < self.strength_finished)
1869                         {
1870                                 self.items = self.items | IT_STRENGTH;
1871                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1872                         }
1873                 }
1874                 if (self.items & IT_INVINCIBLE)
1875                 {
1876                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1877                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1878                         if (time > self.invincible_finished)
1879                         {
1880                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1881                                 sprint(self, "^3Shield has worn off\n");
1882                         }
1883                 }
1884                 else
1885                 {
1886                         if (time < self.invincible_finished)
1887                         {
1888                                 self.items = self.items | IT_INVINCIBLE;
1889                                 sprint(self, "^3Shield surrounds you\n");
1890                         }
1891                 }
1892                 if (self.items & IT_SUPERWEAPON)
1893                 {
1894                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1895                         {
1896                                 self.superweapons_finished = 0;
1897                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1898                                 sprint(self, "^3Superweapons have been lost\n");
1899                         }
1900                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1901                         {
1902                                 // don't let them run out
1903                         }
1904                         else
1905                         {
1906                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1907                                 if (time > self.superweapons_finished)
1908                                 {
1909                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1910                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1911                                         sprint(self, "^3Superweapons have broken down\n");
1912                                 }
1913                         }
1914                 }
1915                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1916                 {
1917                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1918                         {
1919                                 self.items = self.items | IT_SUPERWEAPON;
1920                                 sprint(self, "^3You now have a superweapon\n");
1921                         }
1922                         else
1923                         {
1924                                 self.superweapons_finished = 0;
1925                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1926                         }
1927                 }
1928                 else
1929                 {
1930                         self.superweapons_finished = 0;
1931                 }
1932         }
1933
1934         if(autocvar_g_nodepthtestplayers)
1935                 self.effects = self.effects | EF_NODEPTHTEST;
1936
1937         if(autocvar_g_fullbrightplayers)
1938                 self.effects = self.effects | EF_FULLBRIGHT;
1939
1940         // midair gamemode: damage only while in the air
1941         // if in midair mode, being on ground grants temporary invulnerability
1942         // (this is so that multishot weapon don't clear the ground flag on the
1943         // first damage in the frame, leaving the player vulnerable to the
1944         // remaining hits in the same frame)
1945         if (self.flags & FL_ONGROUND)
1946         if (g_midair)
1947                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1948
1949         if (time >= game_starttime)
1950         if (time < self.spawnshieldtime)
1951                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1952
1953         MUTATOR_CALLHOOK(PlayerPowerups);
1954 }
1955
1956 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1957 {
1958         if(current > stable)
1959                 return current;
1960         else if(current > stable - 0.25) // when close enough, "snap"
1961                 return stable;
1962         else
1963                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1964 }
1965
1966 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1967 {
1968         if(current < stable)
1969                 return current;
1970         else if(current < stable + 0.25) // when close enough, "snap"
1971                 return stable;
1972         else
1973                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1974 }
1975
1976 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1977 {
1978         if(current > rotstable)
1979         {
1980                 if(rotframetime > 0)
1981                 {
1982                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1983                         current = max(rotstable, current - rotlinear * rotframetime);
1984                 }
1985         }
1986         else if(current < regenstable)
1987         {
1988                 if(regenframetime > 0)
1989                 {
1990                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1991                         current = min(regenstable, current + regenlinear * regenframetime);
1992                 }
1993         }
1994
1995         if(current > limit)
1996                 current = limit;
1997
1998         return current;
1999 }
2000
2001 void player_regen (void)
2002 {
2003         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2004         maxh = autocvar_g_balance_health_rotstable;
2005         maxa = autocvar_g_balance_armor_rotstable;
2006         maxf = autocvar_g_balance_fuel_rotstable;
2007         minh = autocvar_g_balance_health_regenstable;
2008         mina = autocvar_g_balance_armor_regenstable;
2009         minf = autocvar_g_balance_fuel_regenstable;
2010         limith = autocvar_g_balance_health_limit;
2011         limita = autocvar_g_balance_armor_limit;
2012         limitf = autocvar_g_balance_fuel_limit;
2013
2014         max_mod = regen_mod = rot_mod = limit_mod = 1;
2015
2016         if (self.runes & RUNE_REGEN)
2017         {
2018                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2019                 {
2020                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2021                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2022                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2023                 }
2024                 else
2025                 {
2026                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2027                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2028                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2029                 }
2030         }
2031         else if (self.runes & CURSE_VENOM)
2032         {
2033                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2034                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2035                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2036                 else
2037                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2038                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2039                 //if (!self.runes & RUNE_REGEN)
2040                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2041         }
2042         maxh = maxh * max_mod;
2043         //maxa = maxa * max_mod;
2044         //maxf = maxf * max_mod;
2045         minh = minh * max_mod;
2046         //mina = mina * max_mod;
2047         //minf = minf * max_mod;
2048         limith = limith * limit_mod;
2049         limita = limita * limit_mod;
2050         //limitf = limitf * limit_mod;
2051
2052         if(g_lms && g_ca)
2053                 rot_mod = 0;
2054
2055         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2056         {
2057                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2058                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2059
2060                 // if player rotted to death...  die!
2061                 if(self.health < 1)
2062                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2063         }
2064
2065         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2066                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2067 }
2068
2069 float zoomstate_set;
2070 void SetZoomState(float z)
2071 {
2072         if(z != self.zoomstate)
2073         {
2074                 self.zoomstate = z;
2075                 ClientData_Touch(self);
2076         }
2077         zoomstate_set = 1;
2078 }
2079
2080 void GetPressedKeys(void) {
2081         MUTATOR_CALLHOOK(GetPressedKeys);
2082         if (self.movement_x > 0) // get if movement keys are pressed
2083         {       // forward key pressed
2084                 self.pressedkeys |= KEY_FORWARD;
2085                 self.pressedkeys &~= KEY_BACKWARD;
2086         }
2087         else if (self.movement_x < 0)
2088         {       // backward key pressed
2089                 self.pressedkeys |= KEY_BACKWARD;
2090                 self.pressedkeys &~= KEY_FORWARD;
2091         }
2092         else
2093         {       // no x input
2094                 self.pressedkeys &~= KEY_FORWARD;
2095                 self.pressedkeys &~= KEY_BACKWARD;
2096         }
2097
2098         if (self.movement_y > 0)
2099         {       // right key pressed
2100                 self.pressedkeys |= KEY_RIGHT;
2101                 self.pressedkeys &~= KEY_LEFT;
2102         }
2103         else if (self.movement_y < 0)
2104         {       // left key pressed
2105                 self.pressedkeys |= KEY_LEFT;
2106                 self.pressedkeys &~= KEY_RIGHT;
2107         }
2108         else
2109         {       // no y input
2110                 self.pressedkeys &~= KEY_RIGHT;
2111                 self.pressedkeys &~= KEY_LEFT;
2112         }
2113
2114         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2115                 self.pressedkeys |= KEY_JUMP;
2116         else
2117                 self.pressedkeys &~= KEY_JUMP;
2118         if (self.BUTTON_CROUCH)
2119                 self.pressedkeys |= KEY_CROUCH;
2120         else
2121                 self.pressedkeys &~= KEY_CROUCH;
2122
2123         if (self.BUTTON_ATCK)
2124                 self.pressedkeys |= KEY_ATCK;
2125         else
2126                 self.pressedkeys &~= KEY_ATCK;
2127         if (self.BUTTON_ATCK2)
2128                 self.pressedkeys |= KEY_ATCK2;
2129         else
2130                 self.pressedkeys &~= KEY_ATCK2;
2131 }
2132
2133 /*
2134 ======================
2135 spectate mode routines
2136 ======================
2137 */
2138
2139 void SpectateCopy(entity spectatee) {
2140         other = spectatee;
2141         MUTATOR_CALLHOOK(SpectateCopy);
2142         self.armortype = spectatee.armortype;
2143         self.armorvalue = spectatee.armorvalue;
2144         self.ammo_cells = spectatee.ammo_cells;
2145         self.ammo_shells = spectatee.ammo_shells;
2146         self.ammo_nails = spectatee.ammo_nails;
2147         self.ammo_rockets = spectatee.ammo_rockets;
2148         self.ammo_fuel = spectatee.ammo_fuel;
2149         self.clip_load = spectatee.clip_load;
2150         self.clip_size = spectatee.clip_size;
2151         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2152         self.health = spectatee.health;
2153         self.impulse = 0;
2154         self.items = spectatee.items;
2155         self.last_pickup = spectatee.last_pickup;
2156         self.hit_time = spectatee.hit_time;
2157         self.metertime = spectatee.metertime;
2158         self.strength_finished = spectatee.strength_finished;
2159         self.invincible_finished = spectatee.invincible_finished;
2160         self.pressedkeys = spectatee.pressedkeys;
2161         WEPSET_COPY_EE(self, spectatee);
2162         self.switchweapon = spectatee.switchweapon;
2163         self.switchingweapon = spectatee.switchingweapon;
2164         self.weapon = spectatee.weapon;
2165         self.nex_charge = spectatee.nex_charge;
2166         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2167         self.hagar_load = spectatee.hagar_load;
2168         self.minelayer_mines = spectatee.minelayer_mines;
2169         self.punchangle = spectatee.punchangle;
2170         self.view_ofs = spectatee.view_ofs;
2171         self.velocity = spectatee.velocity;
2172         self.dmg_take = spectatee.dmg_take;
2173         self.dmg_save = spectatee.dmg_save;
2174         self.dmg_inflictor = spectatee.dmg_inflictor;
2175         self.v_angle = spectatee.v_angle;
2176         self.angles = spectatee.v_angle;
2177         if(!self.BUTTON_USE)
2178                 self.fixangle = TRUE;
2179         setorigin(self, spectatee.origin);
2180         setsize(self, spectatee.mins, spectatee.maxs);
2181         SetZoomState(spectatee.zoomstate);
2182
2183     anticheat_spectatecopy(spectatee);
2184         self.hud = spectatee.hud;
2185         if(spectatee.vehicle)
2186     {
2187         self.fixangle = FALSE;
2188         //self.velocity = spectatee.vehicle.velocity;
2189         self.vehicle_health = spectatee.vehicle_health;
2190         self.vehicle_shield = spectatee.vehicle_shield;
2191         self.vehicle_energy = spectatee.vehicle_energy;
2192         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2193         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2194         self.vehicle_reload1 = spectatee.vehicle_reload1;
2195         self.vehicle_reload2 = spectatee.vehicle_reload2;
2196
2197         msg_entity = self;
2198
2199         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2200             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2201             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2202             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2203
2204         //WriteByte (MSG_ONE, SVC_SETVIEW);
2205         //    WriteEntity(MSG_ONE, self);
2206         //makevectors(spectatee.v_angle);
2207         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2208     }
2209 }
2210
2211 float SpectateUpdate() {
2212         if(!self.enemy)
2213             return 0;
2214
2215         if (self == self.enemy)
2216                 return 0;
2217
2218         if(self.enemy.classname != "player")
2219                 return 0;
2220
2221         SpectateCopy(self.enemy);
2222
2223         return 1;
2224 }
2225
2226
2227 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2228 entity CA_SpectateNext(entity start) {
2229         if (start.team == self.team) {
2230                 return start;
2231         }
2232
2233         other = start;
2234         // continue from current player
2235         while(other && other.team != self.team) {
2236                 other = find(other, classname, "player");
2237         }
2238
2239         if (!other) {
2240                 // restart from begining
2241                 other = find(other, classname, "player");
2242                 while(other && other.team != self.team) {
2243                         other = find(other, classname, "player");
2244                 }
2245         }
2246
2247         return other;
2248 }
2249
2250 float SpectateNext(entity _prefer) {
2251
2252         if(_prefer)
2253                 other = _prefer;
2254         else
2255                 other = find(self.enemy, classname, "player");
2256
2257         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2258                 // CA and ca players when spectating enemies is forbidden
2259                 other = CA_SpectateNext(other);
2260         } else {
2261                 // other modes and ca spectators or spectating enemies is allowed
2262                 if (!other)
2263                         other = find(other, classname, "player");
2264         }
2265
2266         if (other)
2267                 self.enemy = other;
2268
2269         if(self.enemy.classname == "player") {
2270             /*if(self.enemy.vehicle)
2271             {
2272
2273             msg_entity = self;
2274             WriteByte(MSG_ONE, SVC_SETVIEW);
2275             WriteEntity(MSG_ONE, self.enemy);
2276             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2277
2278             self.movetype = MOVETYPE_NONE;
2279             accuracy_resend(self);
2280             }
2281             else
2282             {*/
2283             msg_entity = self;
2284             WriteByte(MSG_ONE, SVC_SETVIEW);
2285             WriteEntity(MSG_ONE, self.enemy);
2286             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2287             self.movetype = MOVETYPE_NONE;
2288             accuracy_resend(self);
2289
2290             if(!SpectateUpdate())
2291                 PutObserverInServer();
2292         //}
2293         return 1;
2294         } else {
2295                 return 0;
2296         }
2297 }
2298
2299 /*
2300 =============
2301 ShowRespawnCountdown()
2302
2303 Update a respawn countdown display.
2304 =============
2305 */
2306 void ShowRespawnCountdown()
2307 {
2308         float number;
2309         if(self.deadflag == DEAD_NO) // just respawned?
2310                 return;
2311         else
2312         {
2313                 number = ceil(self.respawn_time - time);
2314                 if(number <= 0)
2315                         return;
2316                 if(number <= self.respawn_countdown)
2317                 {
2318                         self.respawn_countdown = number - 1;
2319                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2320                                 AnnounceTo(self, strcat(ftos(number), ""));
2321                 }
2322         }
2323 }
2324
2325 .float prevent_join_msgtime;
2326 void LeaveSpectatorMode()
2327 {
2328         if(nJoinAllowed(self)) {
2329                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2330                         self.classname = "player";
2331
2332                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2333                                 JoinBestTeam(self, FALSE, TRUE);
2334
2335                         if(autocvar_g_campaign)
2336                                 campaign_bots_may_start = 1;
2337
2338                         PutClientInServer();
2339
2340                         if(self.classname == "player")
2341                                 bprint ("^4", self.netname, "^4 is playing now\n");
2342
2343                         if(!autocvar_g_campaign)
2344                         if (time < self.jointime + autocvar_welcome_message_time)
2345                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2346
2347                         if (self.prevent_join_msgtime)
2348                         {
2349                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2350                                 self.prevent_join_msgtime = 0;
2351                         }
2352
2353                         return;
2354                 } else {
2355                         if (g_ca && self.caplayer) {
2356                         }       // do nothing
2357                         else
2358                                 stuffcmd(self,"menu_showteamselect\n");
2359                         return;
2360                 }
2361         }
2362         else {
2363                 //player may not join because of g_maxplayers is set
2364                 if (time - self.prevent_join_msgtime > 2)
2365                 {
2366                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2367                         self.prevent_join_msgtime = time;
2368                 }
2369         }
2370 }
2371
2372 /**
2373  * Determines whether the player is allowed to join. This depends on cvar
2374  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2375  * it checks whether the number of currently playing players exceeds g_maxplayers.
2376  * @return int number of free slots for players, 0 if none
2377  */
2378 float nJoinAllowed(entity ignore) {
2379         if(!ignore)
2380         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2381         // so report 0 free slots if restricted
2382         {
2383                 if(autocvar_g_forced_team_otherwise == "spectate")
2384                         return 0;
2385                 if(autocvar_g_forced_team_otherwise == "spectator")
2386                         return 0;
2387         }
2388
2389         if(self.team_forced < 0)
2390                 return 0; // forced spectators can never join
2391
2392         // TODO simplify this
2393         entity e;
2394         float totalClients = 0;
2395         FOR_EACH_CLIENT(e)
2396                 if(e != ignore)
2397                         totalClients += 1;
2398
2399         if (!autocvar_g_maxplayers)
2400                 return maxclients - totalClients;
2401
2402         float currentlyPlaying = 0;
2403         FOR_EACH_REALPLAYER(e)
2404                 currentlyPlaying += 1;
2405
2406         if(currentlyPlaying < autocvar_g_maxplayers)
2407                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2408
2409         return 0;
2410 }
2411
2412 /**
2413  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2414  * g_maxplayers_spectator_blocktime seconds
2415  */
2416 void checkSpectatorBlock() {
2417         if(self.classname == "spectator" || self.classname == "observer") {
2418                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2419                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2420                         dropclient(self);
2421                 }
2422         }
2423 }
2424
2425 .float motd_actived_time; // used for both motd and campaign_message
2426 void PrintWelcomeMessage()
2427 {
2428         if (self.motd_actived_time == 0) { // is there already a message showing?
2429                 if (autocvar_g_campaign) {
2430                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2431                                 self.motd_actived_time = time;
2432                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2433                         }
2434                 } else {
2435                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2436                                 self.motd_actived_time = time;
2437                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2438                         }
2439                 }
2440         } else { // showing MOTD or campaign message
2441                 if (autocvar_g_campaign) {
2442                         if (self.BUTTON_INFO)
2443                                 self.motd_actived_time = time;
2444                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2445                                 self.motd_actived_time = 0;
2446                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2447                         }
2448                 } else {
2449                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2450                                 if (self.BUTTON_INFO)
2451                                         self.motd_actived_time = time;
2452                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2453                                         self.motd_actived_time = 0;
2454                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2455                                 }
2456                         }
2457                 }
2458         }
2459 }
2460
2461 void ObserverThink()
2462 {
2463         float prefered_movetype;
2464         if (self.flags & FL_JUMPRELEASED) {
2465                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2466                         self.flags &~= FL_JUMPRELEASED;
2467                         self.flags |= FL_SPAWNING;
2468                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2469                         self.flags &~= FL_JUMPRELEASED;
2470                         if(SpectateNext(world) == 1) {
2471                                 self.classname = "spectator";
2472                         }
2473                 } else {
2474                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2475                         if (self.movetype != prefered_movetype)
2476                                 self.movetype = prefered_movetype;
2477                 }
2478         } else {
2479                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2480                         self.flags |= FL_JUMPRELEASED;
2481                         if(self.flags & FL_SPAWNING)
2482                         {
2483                                 self.flags &~= FL_SPAWNING;
2484                                 LeaveSpectatorMode();
2485                                 return;
2486                         }
2487                 }
2488         }
2489
2490         PrintWelcomeMessage();
2491 }
2492
2493 void SpectatorThink()
2494 {
2495         if (self.flags & FL_JUMPRELEASED) {
2496                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2497                         self.flags &~= FL_JUMPRELEASED;
2498                         self.flags |= FL_SPAWNING;
2499                 } else if(self.BUTTON_ATCK) {
2500                         self.flags &~= FL_JUMPRELEASED;
2501                         if(SpectateNext(world) == 1) {
2502                                 self.classname = "spectator";
2503                         } else {
2504                                 self.classname = "observer";
2505                                 PutClientInServer();
2506                         }
2507                 } else if (self.BUTTON_ATCK2) {
2508                         self.flags &~= FL_JUMPRELEASED;
2509                         self.classname = "observer";
2510                         PutClientInServer();
2511                 } else {
2512                         if(!SpectateUpdate())
2513                                 PutObserverInServer();
2514                 }
2515         } else {
2516                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2517                         self.flags |= FL_JUMPRELEASED;
2518                         if(self.flags & FL_SPAWNING)
2519                         {
2520                                 self.flags &~= FL_SPAWNING;
2521                                 LeaveSpectatorMode();
2522                                 return;
2523                         }
2524                 }
2525                 if(!SpectateUpdate())
2526                         PutObserverInServer();
2527         }
2528
2529         PrintWelcomeMessage();
2530         self.flags |= FL_CLIENT | FL_NOTARGET;
2531 }
2532
2533 float ctf_usekey();
2534 void PlayerUseKey()
2535 {
2536         if(self.classname != "player")
2537                 return;
2538
2539         if(self.vehicle)
2540         {
2541         vehicles_exit(VHEF_NORMAL);
2542         return;
2543         }
2544
2545         // a use key was pressed; call handlers
2546         if(ctf_usekey())
2547                 return;
2548
2549         MUTATOR_CALLHOOK(PlayerUseKey);
2550 }
2551
2552 .float touchexplode_time;
2553
2554 /*
2555 =============
2556 PlayerPreThink
2557
2558 Called every frame for each client before the physics are run
2559 =============
2560 */
2561 .float usekeypressed;
2562 void() ctf_setstatus;
2563 void() nexball_setstatus;
2564 .float items_added;
2565 void PlayerPreThink (void)
2566 {
2567         WarpZone_PlayerPhysics_FixVAngle();
2568
2569         self.stat_game_starttime = game_starttime;
2570         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2571         self.stat_leadlimit = autocvar_leadlimit;
2572
2573         if(frametime)
2574         {
2575                 // physics frames: update anticheat stuff
2576                 anticheat_prethink();
2577         }
2578
2579         if(blockSpectators && frametime)
2580                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2581                 checkSpectatorBlock();
2582
2583         zoomstate_set = 0;
2584
2585         if(self.netname_previous != self.netname)
2586         {
2587                 if(autocvar_sv_eventlog)
2588                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2589                 if(self.netname_previous)
2590                         strunzone(self.netname_previous);
2591                 self.netname_previous = strzone(self.netname);
2592         }
2593
2594         // version nagging
2595         if(self.version_nagtime)
2596                 if(self.cvar_g_xonoticversion)
2597                         if(time > self.version_nagtime)
2598                         {
2599                                 // don't notify git users
2600                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2601                                 {
2602                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2603                                         {
2604                                                 // notify release users if connecting to git
2605                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2606                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2607                                         }
2608                                         else
2609                                         {
2610                                                 float r;
2611                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2612                                                 if(r < 0)
2613                                                 {
2614                                                         // give users new version
2615                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2616                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2617                                                 }
2618                                                 else if(r > 0)
2619                                                 {
2620                                                         // notify users about old server version
2621                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2622                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2623                                                 }
2624                                         }
2625                                 }
2626                                 self.version_nagtime = 0;
2627                         }
2628
2629         // GOD MODE info
2630         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2631         {
2632                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2633                 self.max_armorvalue = 0;
2634         }
2635
2636 #ifdef TETRIS
2637         if (TetrisPreFrame())
2638                 return;
2639 #endif
2640
2641         MUTATOR_CALLHOOK(PlayerPreThink);
2642
2643         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2644         {
2645                 if(self.BUTTON_USE && !self.usekeypressed)
2646                         PlayerUseKey();
2647                 self.usekeypressed = self.BUTTON_USE;
2648         }
2649
2650         PrintWelcomeMessage();
2651
2652         if(self.classname == "player") {
2653 //              if(self.netname == "Wazat")
2654 //                      bprint(self.classname, "\n");
2655
2656                 CheckRules_Player();
2657
2658                 if (intermission_running)
2659                 {
2660                         IntermissionThink ();   // otherwise a button could be missed between
2661                         return;                                 // the think tics
2662                 }
2663
2664                 //don't allow the player to turn around while game is paused!
2665                 if(timeout_status == TIMEOUT_ACTIVE) {
2666                         // FIXME turn this into CSQC stuff
2667                         self.v_angle = self.lastV_angle;
2668                         self.angles = self.lastV_angle;
2669                         self.fixangle = TRUE;
2670                 }
2671
2672                 if(frametime)
2673                 {
2674 #ifndef NO_LEGACY_NETWORKING
2675                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2676 #endif
2677
2678                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2679                         {
2680                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2681                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2682                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2683
2684                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2685                                 {
2686                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2687                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2688                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2689                                 }
2690                         }
2691                         else
2692                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2693
2694                         player_powerups();
2695                 }
2696
2697                 if (g_minstagib)
2698                         minstagib_ammocheck();
2699
2700                 if (self.deadflag != DEAD_NO)
2701                 {
2702                         float button_pressed, force_respawn;
2703                         if(self.personal && g_race_qualifying)
2704                         {
2705                                 if(time > self.respawn_time)
2706                                 {
2707                                         self.respawn_time = time + 1; // only retry once a second
2708                                         respawn();
2709                                         self.impulse = 141;
2710                                 }
2711                         }
2712                         else
2713                         {
2714                                 if(frametime)
2715                                         player_anim();
2716                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2717                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2718                                 if (self.deadflag == DEAD_DYING)
2719                                 {
2720                                         if(force_respawn)
2721                                                 self.deadflag = DEAD_RESPAWNING;
2722                                         else if(!button_pressed)
2723                                                 self.deadflag = DEAD_DEAD;
2724                                 }
2725                                 else if (self.deadflag == DEAD_DEAD)
2726                                 {
2727                                         if(button_pressed)
2728                                                 self.deadflag = DEAD_RESPAWNABLE;
2729                                 }
2730                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2731                                 {
2732                                         if(!button_pressed)
2733                                                 self.deadflag = DEAD_RESPAWNING;
2734                                 }
2735                                 else if (self.deadflag == DEAD_RESPAWNING)
2736                                 {
2737                                         if(time > self.respawn_time)
2738                                         {
2739                                                 self.respawn_time = time + 1; // only retry once a second
2740                                                 respawn();
2741                                         }
2742                                 }
2743                                 ShowRespawnCountdown();
2744                         }
2745                         return;
2746                 }
2747                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2748                 // so (self.deadflag == DEAD_NO) is always true in the code below
2749
2750                 if(g_touchexplode)
2751                 if(time > self.touchexplode_time)
2752                 if(self.classname == "player")
2753                 if(self.deadflag == DEAD_NO)
2754                 if not(IS_INDEPENDENT_PLAYER(self))
2755                 FOR_EACH_PLAYER(other) if(self != other)
2756                 {
2757                         if(time > other.touchexplode_time)
2758                         if(other.deadflag == DEAD_NO)
2759                         if not(IS_INDEPENDENT_PLAYER(other))
2760                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2761                         {
2762                                 PlayerTouchExplode(self, other);
2763                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2764                         }
2765                 }
2766
2767                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2768                 {
2769                         vector dist;
2770
2771                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2772                         dist = self.prevorigin - self.origin;
2773                         dist_z = 0;
2774                         self.lms_traveled_distance += fabs(vlen(dist));
2775
2776                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2777                         {
2778                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2779                                 self.lms_traveled_distance = 0;
2780                         }
2781
2782                         if(time > self.lms_nextcheck)
2783                         {
2784                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2785                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2786                                 {
2787                                         centerprint(self, autocvar_g_lms_campcheck_message);
2788                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2789                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2790                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2791                                 }
2792                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2793                                 self.lms_traveled_distance = 0;
2794                         }
2795                 }
2796
2797                 self.prevorigin = self.origin;
2798
2799                 if (!self.vehicle)
2800                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x) // prevent crouching if using melee attack
2801                 {
2802                         if (!self.crouch)
2803                         {
2804                                 self.crouch = TRUE;
2805                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2806                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2807                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2808                         }
2809                 }
2810                 else
2811                 {
2812                         if (self.crouch)
2813                         {
2814                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2815                                 if (!trace_startsolid)
2816                                 {
2817                                         self.crouch = FALSE;
2818                                         self.view_ofs = PL_VIEW_OFS;
2819                                         setsize (self, PL_MIN, PL_MAX);
2820                                 }
2821                         }
2822                 }
2823
2824                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2825                 {
2826                         if(self.bloodloss_timer < time)
2827                         {
2828                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2829                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2830                         }
2831                 }
2832
2833                 FixPlayermodel();
2834
2835                 GrapplingHookFrame();
2836
2837                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2838                 //if(frametime)
2839                 {
2840                         self.items &~= self.items_added;
2841
2842                         W_WeaponFrame();
2843
2844                         self.items_added = 0;
2845                         if(self.items & IT_JETPACK)
2846                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2847                                         self.items_added |= IT_FUEL;
2848
2849                         self.items |= self.items_added;
2850                 }
2851
2852                 player_regen();
2853
2854                 // rot nex charge to the charge limit
2855                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2856                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2857
2858                 if(frametime)
2859                         player_anim();
2860
2861                 if(g_ctf)
2862                         ctf_setstatus();
2863
2864                 if(g_nexball)
2865                         nexball_setstatus();
2866
2867                 // secret status
2868                 secrets_setstatus();
2869
2870                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2871
2872                 //self.angles_y=self.v_angle_y + 90;   // temp
2873         } else if(gameover) {
2874                 if (intermission_running)
2875                         IntermissionThink ();   // otherwise a button could be missed between
2876                 return;
2877         } else if(self.classname == "observer") {
2878                 ObserverThink();
2879         } else if(self.classname == "spectator") {
2880                 SpectatorThink();
2881         }
2882
2883         if(!zoomstate_set)
2884                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2885
2886         float oldspectatee_status;
2887         oldspectatee_status = self.spectatee_status;
2888         if(self.classname == "spectator")
2889                 self.spectatee_status = num_for_edict(self.enemy);
2890         else if(self.classname == "observer")
2891                 self.spectatee_status = num_for_edict(self);
2892         else
2893                 self.spectatee_status = 0;
2894         if(self.spectatee_status != oldspectatee_status)
2895         {
2896                 ClientData_Touch(self);
2897                 if(g_race || g_cts)
2898                         race_InitSpectator();
2899         }
2900
2901         if(self.teamkill_soundtime)
2902         if(time > self.teamkill_soundtime)
2903         {
2904                 self.teamkill_soundtime = 0;
2905
2906                 entity oldpusher, oldself;
2907
2908                 oldself = self; self = self.teamkill_soundsource;
2909                 oldpusher = self.pusher; self.pusher = oldself;
2910
2911                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2912
2913                 self.pusher = oldpusher;
2914                 self = oldself;
2915         }
2916
2917         if(self.taunt_soundtime)
2918         if(time > self.taunt_soundtime)
2919         {
2920                 self.taunt_soundtime = 0;
2921                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2922         }
2923
2924         target_voicescript_next(self);
2925
2926         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2927         if(!self.weapon)
2928                 self.clip_load = self.clip_size = 0;
2929 }
2930
2931 float isInvisibleString(string s)
2932 {
2933         float i, n, c;
2934         s = strdecolorize(s);
2935         for((i = 0), (n = strlen(s)); i < n; ++i)
2936         {
2937                 c = str2chr(s, i);
2938                 switch(c)
2939                 {
2940                         case 0:
2941                         case 32: // space
2942                                 break;
2943                         case 192: // charmap space
2944                                 if (!autocvar_utf8_enable)
2945                                         break;
2946                                 return FALSE;
2947                         case 160: // space in unicode fonts
2948                         case 0xE000 + 192: // utf8 charmap space
2949                                 if (autocvar_utf8_enable)
2950                                         break;
2951                         default:
2952                                 return FALSE;
2953                 }
2954         }
2955         return TRUE;
2956 }
2957
2958 /*
2959 =============
2960 PlayerPostThink
2961
2962 Called every frame for each client after the physics are run
2963 =============
2964 */
2965 .float idlekick_lasttimeleft;
2966 .entity showheadshotbbox;
2967 void showheadshotbbox_think()
2968 {
2969         if(self.owner.showheadshotbbox != self)
2970         {
2971                 remove(self);
2972                 return;
2973         }
2974         self.nextthink = time;
2975         setorigin(self, self.owner.origin);
2976         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2977 }
2978 void PlayerPostThink (void)
2979 {
2980         // Savage: Check for nameless players
2981         if (isInvisibleString(self.netname)) {
2982                 self.netname = "Player";
2983                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2984         }
2985
2986         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2987         {
2988                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2989                 {
2990                         if(self.idlekick_lasttimeleft)
2991                         {
2992                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2993                                 self.idlekick_lasttimeleft = 0;
2994                         }
2995                 }
2996                 else
2997                 {
2998                         float timeleft;
2999                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3000                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
3001                         {
3002                                 if(!self.idlekick_lasttimeleft)
3003                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
3004                         }
3005                         if(timeleft <= 0)
3006                         {
3007                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
3008                                 AnnounceTo(self, "terminated");
3009                                 dropclient(self);
3010                                 return;
3011                         }
3012                         else if(timeleft <= 10)
3013                         {
3014                                 if(timeleft != self.idlekick_lasttimeleft)
3015                                         AnnounceTo(self, ftos(timeleft));
3016                                 self.idlekick_lasttimeleft = timeleft;
3017                         }
3018                 }
3019         }
3020
3021 #ifdef TETRIS
3022         if(self.impulse == 100)
3023                 ImpulseCommands();
3024         if (!TetrisPostFrame())
3025         {
3026 #endif
3027
3028         CheatFrame();
3029
3030         //CheckPlayerJump();
3031
3032         if(self.classname == "player") {
3033                 CheckRules_Player();
3034                 UpdateChatBubble();
3035                 if (self.impulse)
3036                         ImpulseCommands();
3037                 if (intermission_running)
3038                         return;         // intermission or finale
3039                 GetPressedKeys();
3040         } else if (self.classname == "observer") {
3041                 //do nothing
3042         } else if (self.classname == "spectator") {
3043                 //do nothing
3044         }
3045
3046 #ifdef TETRIS
3047         }
3048 #endif
3049
3050         /*
3051         float i;
3052         for(i = 0; i < 1000; ++i)
3053         {
3054                 vector end;
3055                 end = self.origin + '0 0 1024' + 512 * randomvec();
3056                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3057                 if(trace_fraction < 1)
3058                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3059                 {
3060                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3061                         break;
3062                 }
3063         }
3064         */
3065
3066         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3067
3068         if(self.waypointsprite_attachedforcarrier)
3069                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3070
3071         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3072         {
3073                 if(!self.showheadshotbbox)
3074                 {
3075                         self.showheadshotbbox = spawn();
3076                         self.showheadshotbbox.classname = "headshotbbox";
3077                         self.showheadshotbbox.owner = self;
3078                         self.showheadshotbbox.think = showheadshotbbox_think;
3079                         self.showheadshotbbox.nextthink = time;
3080                         self = self.showheadshotbbox;
3081                         self.think();
3082                         self = self.owner;
3083                 }
3084         }
3085         else
3086         {
3087                 if(self.showheadshotbbox)
3088                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3089                 remove(self.showheadshotbbox);
3090         }
3091
3092         playerdemo_write();
3093
3094         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3095         {
3096                 if(!self.stored_netname)
3097                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3098                 if(self.stored_netname != self.netname)
3099                 {
3100                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3101                         strunzone(self.stored_netname);
3102                         self.stored_netname = strzone(self.netname);
3103                 }
3104         }
3105
3106         /*
3107         if(g_race)
3108                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3109         */
3110
3111         CSQCMODEL_AUTOUPDATE();
3112 }