qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         minstagib_stop_countdown(self);
 408
 409         Portal_ClearAll(self);
 410
 411         if(self.alivetime)
 412         {
 413                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 414                 self.alivetime = 0;
 415         }
 416
 417         if(self.vehicle)
 418             vehicles_exit(VHEF_RELESE);
 419
 420         if(self.flagcarried)
 421                 DropFlag(self.flagcarried, world, world);
 422
 423         WaypointSprite_PlayerDead();
 424
 425         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 426                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 427
 428         if(self.killcount != -666) {
 429                 if(g_lms) {
 430                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 431                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 432                         else
 433                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 434                 } else
 435                         bprint ("^4", self.netname, "^4 is spectating now\n");
 436
 437                 if(self.just_joined == FALSE) {
 438                         LogTeamchange(self.playerid, -1, 4);
 439                 } else
 440                         self.just_joined = FALSE;
 441         }
 442
 443         PlayerScore_Clear(self); // clear scores when needed
 444
 445         accuracy_resend(self);
 446
 447         self.spectatortime = time;
 448
 449         self.classname = "observer";
 450         self.iscreature = FALSE;
 451         self.damagedbycontents = FALSE;
 452         self.health = -666;
 453         self.takedamage = DAMAGE_NO;
 454         self.solid = SOLID_NOT;
 455         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 456         self.flags = FL_CLIENT | FL_NOTARGET;
 457         self.armorvalue = 666;
 458         self.effects = 0;
 459         self.armorvalue = autocvar_g_balance_armor_start;
 460         self.pauserotarmor_finished = 0;
 461         self.pauserothealth_finished = 0;
 462         self.pauseregen_finished = 0;
 463         self.damageforcescale = 0;
 464         self.death_time = 0;
 465         self.respawn_time = 0;
 466         self.alpha = 0;
 467         self.scale = 0;
 468         self.fade_time = 0;
 469         self.pain_frame = 0;
 470         self.pain_finished = 0;
 471         self.strength_finished = 0;
 472         self.invincible_finished = 0;
 473         self.superweapons_finished = 0;
 474         self.pushltime = 0;
 475         self.think = SUB_Null;
 476         self.nextthink = 0;
 477         self.hook_time = 0;
 478         self.runes = 0;
 479         self.deadflag = DEAD_NO;
 480         self.angles = spot.angles;
 481         self.angles_z = 0;
 482         self.fixangle = TRUE;
 483         self.crouch = FALSE;
 484
 485         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 486         self.prevorigin = self.origin;
 487         self.items = 0;
 488         WEPSET_CLEAR_E(self);
 489         self.model = "";
 490         FixPlayermodel();
 491         setmodel(self, "null");
 492         self.drawonlytoclient = self;
 493
 494         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 495         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 496
 497         self.weapon = 0;
 498         self.weaponname = "";
 499         self.switchingweapon = 0;
 500         self.weaponmodel = "";
 501         self.weaponentity = world;
 502         self.exteriorweaponentity = world;
 503         self.killcount = -666;
 504         self.velocity = '0 0 0';
 505         self.avelocity = '0 0 0';
 506         self.punchangle = '0 0 0';
 507         self.punchvector = '0 0 0';
 508         self.oldvelocity = self.velocity;
 509         self.fire_endtime = -1;
 510
 511         if(g_arena)
 512         {
 513                 if(self.version_mismatch)
 514                 {
 515                         Spawnqueue_Unmark(self);
 516                         Spawnqueue_Remove(self);
 517                 }
 518                 else
 519                 {
 520                         Spawnqueue_Insert(self);
 521                 }
 522         }
 523         else if(g_lms)
 524         {
 525                 // Only if the player cannot play at all
 526                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 527                         self.frags = FRAGS_SPECTATOR;
 528                 else
 529                         self.frags = FRAGS_LMS_LOSER;
 530         }
 531         else if(g_ca)
 532         {
 533                 if(self.caplayer)
 534                         self.frags = FRAGS_LMS_LOSER;
 535                 else
 536                         self.frags = FRAGS_SPECTATOR;
 537         }
 538         else
 539                 self.frags = FRAGS_SPECTATOR;
 540 }
 541
 542 .float model_randomizer;
 543 void FixPlayermodel()
 544 {
 545         string defaultmodel;
 546         float defaultskin, chmdl, oldskin, n, i;
 547         vector m1, m2;
 548
 549         defaultmodel = "";
 550         defaultskin = 0;
 551         chmdl = FALSE;
 552
 553         if(autocvar_sv_defaultcharacter == 1)
 554         {
 555                 if(teamplay)
 556                 {
 557                         string s;
 558                         s = Team_ColorNameLowerCase(self.team);
 559                         if(s != "neutral")
 560                         {
 561                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 562                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 563                         }
 564                 }
 565
 566                 if(defaultmodel == "")
 567                 {
 568                         defaultmodel = autocvar_sv_defaultplayermodel;
 569                         defaultskin = autocvar_sv_defaultplayerskin;
 570                 }
 571
 572                 n = tokenize_console(defaultmodel);
 573                 if(n > 0)
 574                         defaultmodel = argv(floor(n * self.model_randomizer));
 575
 576                 i = strstrofs(defaultmodel, ":", 0);
 577                 if(i >= 0)
 578                 {
 579                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 580                         defaultmodel = substring(defaultmodel, 0, i);
 581                 }
 582         }
 583
 584         if(defaultmodel != "")
 585         {
 586                 if (defaultmodel != self.model)
 587                 {
 588                         m1 = self.mins;
 589                         m2 = self.maxs;
 590                         setplayermodel (self, defaultmodel);
 591                         setsize (self, m1, m2);
 592                         chmdl = TRUE;
 593                 }
 594
 595                 oldskin = self.skin;
 596                 self.skin = defaultskin;
 597         } else {
 598                 if (self.playermodel != self.model || self.playermodel == "")
 599                 {
 600                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 601                         m1 = self.mins;
 602                         m2 = self.maxs;
 603                         setplayermodel (self, self.playermodel);
 604                         setsize (self, m1, m2);
 605                         chmdl = TRUE;
 606                 }
 607
 608                 oldskin = self.skin;
 609                 self.skin = stof(self.playerskin);
 610         }
 611
 612         if(chmdl || oldskin != self.skin)
 613                 self.species = player_getspecies(); // model or skin has changed
 614
 615         if(!teamplay)
 616                 if(strlen(autocvar_sv_defaultplayercolors))
 617                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 618                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 619 }
 620
 621 void PlayerTouchExplode(entity p1, entity p2)
 622 {
 623         vector org;
 624         org = (p1.origin + p2.origin) * 0.5;
 625         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 626
 627         te_explosion(org);
 628
 629         entity e;
 630         e = spawn();
 631         setorigin(e, org);
 632         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 633         remove(e);
 634 }
 635
 636 /*
 637 =============
 638 PutClientInServer
 639
 640 Called when a client spawns in the server
 641 =============
 642 */
 643 //void() ctf_playerchanged;
 644
 645 void PutClientInServer (void)
 646 {
 647         if(clienttype(self) == CLIENTTYPE_BOT)
 648         {
 649                 self.classname = "player";
 650                 if(g_ca)
 651                         self.caplayer = 1;
 652         }
 653         else if(clienttype(self) == CLIENTTYPE_REAL)
 654         {
 655                 msg_entity = self;
 656                 WriteByte(MSG_ONE, SVC_SETVIEW);
 657                 WriteEntity(MSG_ONE, self);
 658         }
 659
 660         // reset player keys
 661         self.itemkeys = 0;
 662
 663         // player is dead and becomes observer
 664         // FIXME fix LMS scoring for new system
 665         if(g_lms)
 666         {
 667                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 668                         self.classname = "observer";
 669         }
 670
 671         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
 672                 self.classname = "observer";
 673
 674         if(gameover)
 675                 self.classname = "observer";
 676
 677         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 678                 entity spot, oldself;
 679                 float j;
 680
 681                 accuracy_resend(self);
 682
 683                 if(self.team < 0)
 684                         JoinBestTeam(self, FALSE, TRUE);
 685
 686                 race_PreSpawn();
 687
 688                 spot = SelectSpawnPoint (FALSE);
 689                 if(!spot)
 690                 {
 691                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 692                         return; // spawn failed
 693                 }
 694
 695                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 696
 697                 self.classname = "player";
 698                 self.wasplayer = TRUE;
 699                 self.iscreature = TRUE;
 700                 self.damagedbycontents = TRUE;
 701                 self.movetype = MOVETYPE_WALK;
 702                 self.solid = SOLID_SLIDEBOX;
 703                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 704                 if(autocvar_g_playerclip_collisions)
 705                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 706                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 707                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 708                 self.frags = FRAGS_PLAYER;
 709                 if(INDEPENDENT_PLAYERS)
 710                         MAKE_INDEPENDENT_PLAYER(self);
 711                 self.flags = FL_CLIENT;
 712                 if(autocvar__notarget)
 713                         self.flags |= FL_NOTARGET;
 714                 self.takedamage = DAMAGE_AIM;
 715                 if(g_minstagib)
 716                         self.effects = EF_FULLBRIGHT;
 717                 else
 718                         self.effects = 0;
 719                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 720                 self.air_finished = time + 12;
 721                 self.dmg = 2;
 722                 if(autocvar_g_balance_nex_charge)
 723                 {
 724                         if(autocvar_g_balance_nex_secondary_chargepool)
 725                                 self.nex_chargepool_ammo = 1;
 726                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 727                 }
 728
 729                 if(inWarmupStage)
 730                 {
 731                         self.ammo_shells = warmup_start_ammo_shells;
 732                         self.ammo_nails = warmup_start_ammo_nails;
 733                         self.ammo_rockets = warmup_start_ammo_rockets;
 734                         self.ammo_cells = warmup_start_ammo_cells;
 735                         self.ammo_fuel = warmup_start_ammo_fuel;
 736                         self.health = warmup_start_health;
 737                         self.armorvalue = warmup_start_armorvalue;
 738                         WEPSET_COPY_EA(self, warmup_start_weapons);
 739                 }
 740                 else
 741                 {
 742                         self.ammo_shells = start_ammo_shells;
 743                         self.ammo_nails = start_ammo_nails;
 744                         self.ammo_rockets = start_ammo_rockets;
 745                         self.ammo_cells = start_ammo_cells;
 746                         self.ammo_fuel = start_ammo_fuel;
 747                         self.health = start_health;
 748                         self.armorvalue = start_armorvalue;
 749                         WEPSET_COPY_EA(self, start_weapons);
 750                 }
 751
 752                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 753                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 754                 else
 755                         self.superweapons_finished = 0;
 756
 757                 if(g_weaponarena_random)
 758                 {
 759                         if(g_weaponarena_random_with_laser)
 760                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 761                         W_RandomWeapons(self, g_weaponarena_random);
 762                         if(g_weaponarena_random_with_laser)
 763                                 WEPSET_OR_EW(self, WEP_LASER);
 764                 }
 765
 766                 self.items = start_items;
 767
 768                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 769                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 770                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 771                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 772                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 773                 //extend the pause of rotting if client was reset at the beginning of the countdown
 774                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 775                         self.spawnshieldtime += game_starttime - time;
 776                         self.pauserotarmor_finished += game_starttime - time;
 777                         self.pauserothealth_finished += game_starttime - time;
 778                         self.pauseregen_finished += game_starttime - time;
 779                 }
 780                 self.damageforcescale = 2;
 781                 self.death_time = 0;
 782                 self.respawn_time = 0;
 783                 self.scale = 0;
 784                 self.fade_time = 0;
 785                 self.pain_frame = 0;
 786                 self.pain_finished = 0;
 787                 self.strength_finished = 0;
 788                 self.invincible_finished = 0;
 789                 self.pushltime = 0;
 790                 // players have no think function
 791                 self.think = SUB_Null;
 792                 self.nextthink = 0;
 793                 self.hook_time = 0;
 794                 self.dmg_team = 0;
 795                 self.ballistics_density = autocvar_g_ballistics_density_player;
 796
 797                 self.metertime = 0;
 798
 799                 self.runes = 0;
 800
 801                 self.deadflag = DEAD_NO;
 802
 803                 self.angles = spot.angles;
 804
 805                 self.angles_z = 0; // never spawn tilted even if the spot says to
 806                 self.fixangle = TRUE; // turn this way immediately
 807                 self.velocity = '0 0 0';
 808                 self.avelocity = '0 0 0';
 809                 self.punchangle = '0 0 0';
 810                 self.punchvector = '0 0 0';
 811                 self.oldvelocity = self.velocity;
 812                 self.fire_endtime = -1;
 813
 814                 msg_entity = self;
 815                 WRITESPECTATABLE_MSG_ONE({
 816                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 817                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 818                 });
 819
 820                 self.model = "";
 821                 FixPlayermodel();
 822                 self.drawonlytoclient = world;
 823
 824                 self.crouch = FALSE;
 825                 self.view_ofs = PL_VIEW_OFS;
 826                 setsize (self, PL_MIN, PL_MAX);
 827                 self.spawnorigin = spot.origin;
 828                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 829                 // don't reset back to last position, even if new position is stuck in solid
 830                 self.oldorigin = self.origin;
 831                 self.prevorigin = self.origin;
 832                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 833                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 834         self.hud = HUD_NORMAL;
 835
 836                 if(g_arena)
 837                 {
 838                         Spawnqueue_Remove(self);
 839                         Spawnqueue_Mark(self);
 840                 }
 841                 else if(g_ca)
 842                         self.caplayer = 1;
 843
 844                 self.event_damage = PlayerDamage;
 845
 846                 self.bot_attack = TRUE;
 847
 848                 self.statdraintime = time + 5;
 849                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 850
 851                 if(self.killcount == -666) {
 852                         PlayerScore_Clear(self);
 853                         self.killcount = 0;
 854                 }
 855
 856                 CL_SpawnWeaponentity();
 857                 self.alpha = default_player_alpha;
 858                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 859                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 860
 861                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 862                 self.lms_traveled_distance = 0;
 863                 self.speedrunning = FALSE;
 864
 865                 race_PostSpawn(spot);
 866
 867                 //stuffcmd(self, "chase_active 0");
 868                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 869
 870                 if(g_assault) {
 871                         if(self.team == assault_attacker_team)
 872                                 centerprint(self, "You are attacking!");
 873                         else
 874                                 centerprint(self, "You are defending!");
 875                 }
 876
 877                 target_voicescript_clear(self);
 878
 879                 // reset fields the weapons may use
 880                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 881                 {
 882                         weapon_action(j, WR_RESETPLAYER);
 883
 884                         // all weapons must be fully loaded when we spawn
 885                         entity e;
 886                         e = get_weaponinfo(j);
 887                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 888                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 889                 }
 890
 891                 oldself = self;
 892                 self = spot;
 893                         activator = oldself;
 894                                 string s;
 895                                 s = self.target;
 896                                 self.target = string_null;
 897                                 SUB_UseTargets();
 898                                 self.target = s;
 899                         activator = world;
 900                 self = oldself;
 901
 902                 spawn_spot = spot;
 903                 MUTATOR_CALLHOOK(PlayerSpawn);
 904
 905                 if(autocvar_spawn_debug)
 906                 {
 907                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 908                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 909                 }
 910
 911                 self.switchweapon = w_getbestweapon(self);
 912                 self.cnt = -1; // W_LastWeapon will not complain
 913                 self.weapon = 0;
 914                 self.weaponname = "";
 915                 self.switchingweapon = 0;
 916
 917                 if(!self.alivetime)
 918                         self.alivetime = time;
 919
 920                 antilag_clear(self);
 921
 922                 if (autocvar_g_spawnsound)
 923                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 924         } else if(self.classname == "observer") {
 925                 PutObserverInServer ();
 926         }
 927
 928         //if(g_ctf)
 929         //      ctf_playerchanged();
 930 }
 931
 932 .float ebouncefactor, ebouncestop; // electro's values
 933 // TODO do we need all these fields, or should we stop autodetecting runtime
 934 // changes and just have a console command to update this?
 935 float ClientInit_SendEntity(entity to, float sf)
 936 {
 937         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 938         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 939         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 940         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 941         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 942         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 943         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 944         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 945         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 946         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 947
 948         if(sv_foginterval && world.fog != "")
 949                 WriteString(MSG_ENTITY, world.fog);
 950         else
 951                 WriteString(MSG_ENTITY, "");
 952         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 953         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 954         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 955         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 956         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 957         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 958         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 959         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 960         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 961         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 962         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 963         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 964         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 965         return TRUE;
 966 }
 967
 968 void ClientInit_CheckUpdate()
 969 {
 970         self.nextthink = time;
 971         if(self.count != autocvar_g_balance_armor_blockpercent)
 972         {
 973                 self.count = autocvar_g_balance_armor_blockpercent;
 974                 self.SendFlags |= 1;
 975         }
 976         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 977         {
 978                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 979                 self.SendFlags |= 1;
 980         }
 981         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 982         {
 983                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 984                 self.SendFlags |= 1;
 985         }
 986         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 987         {
 988                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 989                 self.SendFlags |= 1;
 990         }
 991         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 992         {
 993                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 994                 self.SendFlags |= 1;
 995         }
 996         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 997         {
 998                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 999                 self.SendFlags |= 1;
1000         }
1001 }
1002
1003 void ClientInit_Spawn()
1004 {
1005         entity o;
1006         entity e;
1007         e = spawn();
1008         e.classname = "clientinit";
1009         e.think = ClientInit_CheckUpdate;
1010         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1011
1012         o = self;
1013         self = e;
1014         ClientInit_CheckUpdate();
1015         self = o;
1016 }
1017
1018 /*
1019 =============
1020 SetNewParms
1021 =============
1022 */
1023 void SetNewParms (void)
1024 {
1025         // initialize parms for a new player
1026         parm1 = -(86400 * 366);
1027 }
1028
1029 /*
1030 =============
1031 SetChangeParms
1032 =============
1033 */
1034 void SetChangeParms (void)
1035 {
1036         // save parms for level change
1037         parm1 = self.parm_idlesince - time;
1038 }
1039
1040 /*
1041 =============
1042 DecodeLevelParms
1043 =============
1044 */
1045 void DecodeLevelParms (void)
1046 {
1047         // load parms
1048         self.parm_idlesince = parm1;
1049         if(self.parm_idlesince == -(86400 * 366))
1050                 self.parm_idlesince = time;
1051
1052         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1053         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1054 }
1055
1056 /*
1057 =============
1058 ClientKill
1059
1060 Called when a client types 'kill' in the console
1061 =============
1062 */
1063
1064 .float clientkill_nexttime;
1065 void ClientKill_Now_TeamChange()
1066 {
1067         if(self.killindicator_teamchange == -1)
1068         {
1069                 JoinBestTeam( self, FALSE, TRUE );
1070         }
1071         else if(self.killindicator_teamchange == -2)
1072         {
1073                 if(g_ca)
1074                         self.caplayer = 0;
1075                 if(blockSpectators)
1076                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1077                 PutObserverInServer();
1078         }
1079         else
1080                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1081 }
1082
1083 void ClientKill_Now()
1084 {
1085         if(self.vehicle)
1086         {
1087             vehicles_exit(VHEF_RELESE);
1088             if(!self.killindicator_teamchange)
1089             {
1090             self.vehicle_health = -1;
1091             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1092             }
1093         }
1094
1095         if(self.killindicator && !wasfreed(self.killindicator))
1096                 remove(self.killindicator);
1097
1098         self.killindicator = world;
1099
1100         if(self.killindicator_teamchange)
1101                 ClientKill_Now_TeamChange();
1102
1103         // in any case:
1104         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1105
1106         // now I am sure the player IS dead
1107 }
1108 void KillIndicator_Think()
1109 {
1110         if (gameover)
1111         {
1112                 self.owner.killindicator = world;
1113                 remove(self);
1114                 return;
1115         }
1116
1117         if (self.owner.alpha < 0)
1118         {
1119                 self.owner.killindicator = world;
1120                 remove(self);
1121                 return;
1122         }
1123
1124         if(self.cnt <= 0)
1125         {
1126                 self = self.owner;
1127                 ClientKill_Now(); // no oldself needed
1128                 return;
1129         }
1130     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1131     {
1132         self.nextthink = time + 1;
1133         self.cnt -= 1;
1134     }
1135         else
1136         {
1137                 if(self.cnt <= 10)
1138                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1139                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1140                 {
1141                         if(self.cnt <= 10)
1142                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1143                 }
1144                 self.nextthink = time + 1;
1145                 self.cnt -= 1;
1146         }
1147 }
1148
1149 float clientkilltime;
1150 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1151 {
1152         float killtime;
1153         float starttime;
1154         entity e;
1155
1156         if (gameover)
1157                 return;
1158
1159         killtime = autocvar_g_balance_kill_delay;
1160
1161         if(g_race_qualifying || g_cts)
1162                 killtime = 0;
1163
1164     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1165     {
1166                 remove(self.killindicator);
1167                 self.killindicator = world;
1168
1169         ClientKill_Now(); // allow instant kill in this case
1170         return;
1171     }
1172
1173         self.killindicator_teamchange = targetteam;
1174
1175     if(!self.killindicator)
1176         {
1177                 if(self.deadflag == DEAD_NO)
1178                 {
1179                         killtime = max(killtime, self.clientkill_nexttime - time);
1180                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1181                 }
1182
1183                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1184                 {
1185                         ClientKill_Now();
1186                 }
1187                 else
1188                 {
1189                         starttime = max(time, clientkilltime);
1190
1191                         self.killindicator = spawn();
1192                         self.killindicator.owner = self;
1193                         self.killindicator.scale = 0.5;
1194                         setattachment(self.killindicator, self, "");
1195                         setorigin(self.killindicator, '0 0 52');
1196                         self.killindicator.think = KillIndicator_Think;
1197                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1198                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1199                         self.killindicator.cnt = ceil(killtime);
1200                         self.killindicator.count = bound(0, ceil(killtime), 10);
1201                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1202
1203                         for(e = world; (e = find(e, classname, "body")) != world; )
1204                         {
1205                                 if(e.enemy != self)
1206                                         continue;
1207                                 e.killindicator = spawn();
1208                                 e.killindicator.owner = e;
1209                                 e.killindicator.scale = 0.5;
1210                                 setattachment(e.killindicator, e, "");
1211                                 setorigin(e.killindicator, '0 0 52');
1212                                 e.killindicator.think = KillIndicator_Think;
1213                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1214                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1215                                 e.killindicator.cnt = ceil(killtime);
1216                         }
1217                         self.lip = 0;
1218                 }
1219         }
1220         if(self.killindicator)
1221         {
1222                 if(targetteam == 0) // just die
1223                 {
1224                         self.killindicator.colormod = '0 0 0';
1225                         if(clienttype(self) == CLIENTTYPE_REAL)
1226                         if(self.killindicator.cnt > 0)
1227                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1228                 }
1229                 else if(targetteam == -1) // auto
1230                 {
1231                         self.killindicator.colormod = '0 1 0';
1232                         if(clienttype(self) == CLIENTTYPE_REAL)
1233                         if(self.killindicator.cnt > 0)
1234                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1235                 }
1236                 else if(targetteam == -2) // spectate
1237                 {
1238                         self.killindicator.colormod = '0.5 0.5 0.5';
1239                         if(clienttype(self) == CLIENTTYPE_REAL)
1240                         if(self.killindicator.cnt > 0)
1241                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1242                 }
1243                 else
1244                 {
1245                         self.killindicator.colormod = TeamColor(targetteam);
1246                         if(clienttype(self) == CLIENTTYPE_REAL)
1247                         if(self.killindicator.cnt > 0)
1248                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1249                 }
1250         }
1251
1252 }
1253
1254 void ClientKill (void)
1255 {
1256         if (gameover)
1257                 return;
1258
1259         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1260         {
1261                 // do nothing
1262         }
1263     else if(self.freezetag_frozen)
1264     {
1265         // do nothing
1266     }
1267         else
1268                 ClientKill_TeamChange(0);
1269 }
1270
1271 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1272 {
1273     e.killindicator = spawn();
1274     e.killindicator.owner = e;
1275     e.killindicator.think = KillIndicator_Think;
1276     e.killindicator.nextthink = time + (e.lip) * 0.05;
1277     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1278     e.killindicator.health = 1; // this is used to indicate that it should be silent
1279     e.lip = 0;
1280 }
1281
1282 void FixClientCvars(entity e)
1283 {
1284         // send prediction settings to the client
1285         stuffcmd(e, "\nin_bindmap 0 0\n");
1286         if(g_race || g_cts)
1287                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1288         if(autocvar_g_antilag == 3) // client side hitscan
1289                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1290         if(sv_gentle)
1291                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1292         /*
1293          * we no longer need to stuff this. Remove this comment block if you feel
1294          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1295         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1296         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1297         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1298         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1299         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1300         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1301         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1302         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1303         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1304         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1305         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1306         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1307         stuffcmd(e, "cl_movement_edgefriction 1\n");
1308          */
1309 }
1310
1311 float PlayerInIDList(entity p, string idlist)
1312 {
1313         float n, i;
1314         string s;
1315
1316         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1317         if not(p.crypto_idfp)
1318                 return 0;
1319
1320         // this function allows abbreviated player IDs too!
1321         n = tokenize_console(idlist);
1322         for(i = 0; i < n; ++i)
1323         {
1324                 s = argv(i);
1325                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1326                         return 1;
1327         }
1328
1329         return 0;
1330 }
1331
1332 /*
1333 =============
1334 ClientConnect
1335
1336 Called when a client connects to the server
1337 =============
1338 */
1339 //void ctf_clientconnect();
1340 string ColoredTeamName(float t);
1341 void DecodeLevelParms (void);
1342 //void dom_player_join_team(entity pl);
1343 void set_dom_state(entity e);
1344 void ClientConnect (void)
1345 {
1346         float t;
1347
1348         if(self.flags & FL_CLIENT)
1349         {
1350                 print("Warning: ClientConnect, but already connected!\n");
1351                 return;
1352         }
1353
1354         if(Ban_MaybeEnforceBanOnce(self))
1355                 return;
1356
1357         DecodeLevelParms();
1358
1359 #ifdef WATERMARK
1360         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1361 #endif
1362
1363         self.classname = "player_joining";
1364
1365         self.flags = FL_CLIENT;
1366         self.version_nagtime = time + 10 + random() * 10;
1367
1368         if(player_count<0)
1369         {
1370                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1371                 player_count = 0;
1372         }
1373
1374         PlayerScore_Attach(self);
1375         ClientData_Attach();
1376         accuracy_init(self);
1377
1378         bot_clientconnect();
1379
1380         playerdemo_init();
1381
1382         anticheat_init();
1383
1384         race_PreSpawnObserver();
1385
1386         //if(g_domination)
1387         //      dom_player_join_team(self);
1388
1389         // identify the right forced team
1390         if(autocvar_g_campaign)
1391         {
1392                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1393                 {
1394                         switch(autocvar_g_campaign_forceteam)
1395                         {
1396                                 case 1: self.team_forced = COLOR_TEAM1; break;
1397                                 case 2: self.team_forced = COLOR_TEAM2; break;
1398                                 case 3: self.team_forced = COLOR_TEAM3; break;
1399                                 case 4: self.team_forced = COLOR_TEAM4; break;
1400                                 default: self.team_forced = 0;
1401                         }
1402                 }
1403         }
1404         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1405                 self.team_forced = COLOR_TEAM1;
1406         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1407                 self.team_forced = COLOR_TEAM2;
1408         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1409                 self.team_forced = COLOR_TEAM3;
1410         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1411                 self.team_forced = COLOR_TEAM4;
1412         else if(autocvar_g_forced_team_otherwise == "red")
1413                 self.team_forced = COLOR_TEAM1;
1414         else if(autocvar_g_forced_team_otherwise == "blue")
1415                 self.team_forced = COLOR_TEAM2;
1416         else if(autocvar_g_forced_team_otherwise == "yellow")
1417                 self.team_forced = COLOR_TEAM3;
1418         else if(autocvar_g_forced_team_otherwise == "pink")
1419                 self.team_forced = COLOR_TEAM4;
1420         else if(autocvar_g_forced_team_otherwise == "spectate")
1421                 self.team_forced = -1;
1422         else if(autocvar_g_forced_team_otherwise == "spectator")
1423                 self.team_forced = -1;
1424         else
1425                 self.team_forced = 0;
1426
1427         if(!teamplay)
1428                 if(self.team_forced > 0)
1429                         self.team_forced = 0;
1430
1431         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1432
1433         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1434                 self.classname = "observer";
1435         } else {
1436                 if(teamplay)
1437                 {
1438                         if(autocvar_g_balance_teams)
1439                         {
1440                                 self.classname = "player";
1441                                 campaign_bots_may_start = 1;
1442                         }
1443                         else
1444                         {
1445                                 self.classname = "observer"; // do it anyway
1446                         }
1447                 }
1448                 else
1449                 {
1450                         self.classname = "player";
1451                         campaign_bots_may_start = 1;
1452                 }
1453         }
1454
1455         self.playerid = (playerid_last = playerid_last + 1);
1456
1457         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1458
1459     if(clienttype(self) == CLIENTTYPE_BOT)
1460         PlayerStats_AddPlayer(self);
1461
1462         if(autocvar_sv_eventlog)
1463                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1464
1465         LogTeamchange(self.playerid, self.team, 1);
1466
1467         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1468
1469         self.netname_previous = strzone(self.netname);
1470
1471         bprint("^4", self.netname, "^4 connected");
1472
1473         if(self.classname != "observer" && (g_domination || g_ctf))
1474                 bprint(" and joined the ", ColoredTeamName(self.team));
1475
1476         bprint("\n");
1477
1478         stuffcmd(self, strcat(clientstuff, "\n"));
1479         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1480
1481         FixClientCvars(self);
1482
1483         // spawnfunc_waypoint sprites
1484         WaypointSprite_InitClient(self);
1485
1486         // Wazat's grappling hook
1487         SetGrappleHookBindings();
1488
1489         // get version info from player
1490         stuffcmd(self, "cmd clientversion $gameversion\n");
1491
1492         // get other cvars from player
1493         GetCvars(0);
1494
1495         // notify about available teams
1496         if(teamplay)
1497         {
1498                 CheckAllowedTeams(self);
1499                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1500                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1501         }
1502         else
1503                 stuffcmd(self, "set _teams_available 0\n");
1504
1505         if(g_arena || g_ca)
1506         {
1507                 self.classname = "observer";
1508                 if(g_arena)
1509                         Spawnqueue_Insert(self);
1510         }
1511         /*else if(g_ctf)
1512         {
1513                 ctf_clientconnect();
1514         }*/
1515
1516         attach_entcs();
1517
1518         bot_relinkplayerlist();
1519
1520         self.spectatortime = time;
1521         if(blockSpectators)
1522         {
1523                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1524         }
1525
1526         self.jointime = time;
1527         self.allowed_timeouts = autocvar_sv_timeout_number;
1528
1529         if(clienttype(self) == CLIENTTYPE_REAL)
1530         {
1531                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1532                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1533         }
1534
1535         if(g_lms)
1536         {
1537                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1538                 {
1539                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1540                         self.frags = FRAGS_SPECTATOR;
1541                 }
1542         }
1543
1544         if(!sv_foginterval && world.fog != "")
1545                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1546
1547         SoundEntity_Attach(self);
1548
1549         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1550         {
1551                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1552                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1553         }
1554         else
1555                 self.hitplotfh = -1;
1556
1557         if(g_race || g_cts) {
1558                 string rr;
1559                 if(g_cts)
1560                         rr = CTS_RECORD;
1561                 else
1562                         rr = RACE_RECORD;
1563
1564                 msg_entity = self;
1565                 race_send_recordtime(MSG_ONE);
1566                 race_send_speedaward(MSG_ONE);
1567
1568                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1569                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1570                 race_send_speedaward_alltimebest(MSG_ONE);
1571
1572                 float i;
1573                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1574                         race_SendRankings(i, 0, 0, MSG_ONE);
1575                 }
1576         }
1577         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1578                 send_CSQC_teamnagger();
1579
1580         if (g_domination)
1581                 set_dom_state(self);
1582
1583         CheatInitClient();
1584
1585         if(!autocvar_g_campaign)
1586                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1587
1588         CSQCMODEL_AUTOINIT();
1589
1590         self.model_randomizer = random();
1591
1592     if(clienttype(self) != CLIENTTYPE_REAL)
1593         return;
1594
1595     sv_notice_join();
1596 }
1597 /*
1598 =============
1599 ClientDisconnect
1600
1601 Called when a client disconnects from the server
1602 =============
1603 */
1604 .entity chatbubbleentity;
1605 void ReadyCount();
1606 void ClientDisconnect (void)
1607 {
1608         if(self.vehicle)
1609             vehicles_exit(VHEF_RELESE);
1610
1611         if not(self.flags & FL_CLIENT)
1612         {
1613                 print("Warning: ClientDisconnect without ClientConnect\n");
1614                 return;
1615         }
1616
1617         PlayerStats_AddGlobalInfo(self);
1618
1619         CheatShutdownClient();
1620
1621         if(self.hitplotfh >= 0)
1622         {
1623                 fclose(self.hitplotfh);
1624                 self.hitplotfh = -1;
1625         }
1626
1627         anticheat_report();
1628         anticheat_shutdown();
1629
1630         playerdemo_shutdown();
1631
1632         bot_clientdisconnect();
1633
1634         if(self.entcs)
1635                 detach_entcs();
1636
1637         if(autocvar_sv_eventlog)
1638                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1639         bprint ("^4",self.netname);
1640         bprint ("^4 disconnected\n");
1641
1642         SoundEntity_Detach(self);
1643
1644         DropAllRunes(self);
1645         MUTATOR_CALLHOOK(ClientDisconnect);
1646
1647         Portal_ClearAll(self);
1648
1649         RemoveGrapplingHook(self);
1650         if(self.flagcarried)
1651                 DropFlag(self.flagcarried, world, world);
1652
1653         // Here, everything has been done that requires this player to be a client.
1654
1655         self.flags &~= FL_CLIENT;
1656
1657         if (self.chatbubbleentity)
1658                 remove (self.chatbubbleentity);
1659
1660         if (self.killindicator)
1661                 remove (self.killindicator);
1662
1663         WaypointSprite_PlayerGone();
1664
1665         bot_relinkplayerlist();
1666
1667         if(g_arena)
1668         {
1669                 Spawnqueue_Unmark(self);
1670                 Spawnqueue_Remove(self);
1671         }
1672
1673         accuracy_free(self);
1674         ClientData_Detach();
1675         PlayerScore_Detach(self);
1676
1677         if(self.netname_previous)
1678                 strunzone(self.netname_previous);
1679         if(self.clientstatus)
1680                 strunzone(self.clientstatus);
1681         if(self.weaponorder_byimpulse)
1682                 strunzone(self.weaponorder_byimpulse);
1683
1684         ClearPlayerSounds();
1685
1686         if(self.personal)
1687                 remove(self.personal);
1688
1689         self.playerid = 0;
1690         ReadyCount();
1691
1692         // free cvars
1693         GetCvars(-1);
1694 }
1695
1696 .float BUTTON_CHAT;
1697 void ChatBubbleThink()
1698 {
1699         self.nextthink = time;
1700         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1701         {
1702                 if(self.owner) // but why can that ever be world?
1703                         self.owner.chatbubbleentity = world;
1704                 remove(self);
1705                 return;
1706         }
1707         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1708 #ifdef TETRIS
1709                 || self.owner.tetris_on
1710 #endif
1711         )
1712                 self.model = self.mdl;
1713         else
1714                 self.model = "";
1715 }
1716
1717 void UpdateChatBubble()
1718 {
1719         if (self.alpha < 0)
1720                 return;
1721         // spawn a chatbubble entity if needed
1722         if (!self.chatbubbleentity)
1723         {
1724                 self.chatbubbleentity = spawn();
1725                 self.chatbubbleentity.owner = self;
1726                 self.chatbubbleentity.exteriormodeltoclient = self;
1727                 self.chatbubbleentity.think = ChatBubbleThink;
1728                 self.chatbubbleentity.nextthink = time;
1729                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1730                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1731                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1732                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1733                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1734                 self.chatbubbleentity.model = "";
1735                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1736         }
1737 }
1738
1739
1740 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1741 // added to the model skins
1742 /*void UpdateColorModHack()
1743 {
1744         float c;
1745         c = self.clientcolors & 15;
1746         // LordHavoc: only bothering to support white, green, red, yellow, blue
1747              if (!teamplay) self.colormod = '0 0 0';
1748         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1749         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1750         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1751         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1752         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1753         else self.colormod = '1 1 1';
1754 }*/
1755
1756 void respawn(void)
1757 {
1758         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1759         {
1760                 self.solid = SOLID_NOT;
1761                 self.takedamage = DAMAGE_NO;
1762                 self.movetype = MOVETYPE_FLY;
1763                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1764                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1765                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1766                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1767                 if(autocvar_g_respawn_ghosts_maxtime)
1768                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1769         }
1770
1771         CopyBody(1);
1772
1773         self.effects |= EF_NODRAW; // prevent another CopyBody
1774         PutClientInServer();
1775 }
1776
1777 void play_countdown(float finished, string samp)
1778 {
1779         if(clienttype(self) == CLIENTTYPE_REAL)
1780                 if(floor(finished - time - frametime) != floor(finished - time))
1781                         if(finished - time < 6)
1782                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1783 }
1784
1785 void player_powerups (void)
1786 {
1787         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1788         olditems = self.items;
1789
1790         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1791         {
1792                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1793                 self.modelflags |= MF_ROCKET;
1794         }
1795         else
1796         {
1797                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1798                 self.modelflags &~= MF_ROCKET;
1799         }
1800
1801         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1802
1803         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1804                 return;
1805
1806         Fire_ApplyDamage(self);
1807         Fire_ApplyEffect(self);
1808
1809         if (g_minstagib)
1810         {
1811                 self.effects |= EF_FULLBRIGHT;
1812
1813                 if (self.items & IT_STRENGTH)
1814                 {
1815                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1816                         if (time > self.strength_finished)
1817                         {
1818                                 self.alpha = default_player_alpha;
1819                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1820                                 self.items &~= IT_STRENGTH;
1821                                 sprint(self, "^3Invisibility has worn off\n");
1822                         }
1823                 }
1824                 else
1825                 {
1826                         if (time < self.strength_finished)
1827                         {
1828                                 self.alpha = g_minstagib_invis_alpha;
1829                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1830                                 self.items |= IT_STRENGTH;
1831                                 sprint(self, "^3You are invisible\n");
1832                         }
1833                 }
1834
1835                 if (self.items & IT_INVINCIBLE)
1836                 {
1837                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1838                         if (time > self.invincible_finished)
1839                         {
1840                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1841                                 sprint(self, "^3Speed has worn off\n");
1842                         }
1843                 }
1844                 else
1845                 {
1846                         if (time < self.invincible_finished)
1847                         {
1848                                 self.items = self.items | IT_INVINCIBLE;
1849                                 sprint(self, "^3You are on speed\n");
1850                         }
1851                 }
1852         }
1853         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1854         {
1855                 if (self.items & IT_STRENGTH)
1856                 {
1857                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1858                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1859                         if (time > self.strength_finished)
1860                         {
1861                                 self.items = self.items - (self.items & IT_STRENGTH);
1862                                 sprint(self, "^3Strength has worn off\n");
1863                         }
1864                 }
1865                 else
1866                 {
1867                         if (time < self.strength_finished)
1868                         {
1869                                 self.items = self.items | IT_STRENGTH;
1870                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1871                         }
1872                 }
1873                 if (self.items & IT_INVINCIBLE)
1874                 {
1875                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1876                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1877                         if (time > self.invincible_finished)
1878                         {
1879                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1880                                 sprint(self, "^3Shield has worn off\n");
1881                         }
1882                 }
1883                 else
1884                 {
1885                         if (time < self.invincible_finished)
1886                         {
1887                                 self.items = self.items | IT_INVINCIBLE;
1888                                 sprint(self, "^3Shield surrounds you\n");
1889                         }
1890                 }
1891                 if (self.items & IT_SUPERWEAPON)
1892                 {
1893                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1894                         {
1895                                 self.superweapons_finished = 0;
1896                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1897                                 sprint(self, "^3Superweapons have been lost\n");
1898                         }
1899                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1900                         {
1901                                 // don't let them run out
1902                         }
1903                         else
1904                         {
1905                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1906                                 if (time > self.superweapons_finished)
1907                                 {
1908                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1909                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1910                                         sprint(self, "^3Superweapons have broken down\n");
1911                                 }
1912                         }
1913                 }
1914                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1915                 {
1916                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1917                         {
1918                                 self.items = self.items | IT_SUPERWEAPON;
1919                                 sprint(self, "^3You now have a superweapon\n");
1920                         }
1921                         else
1922                         {
1923                                 self.superweapons_finished = 0;
1924                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1925                         }
1926                 }
1927                 else
1928                 {
1929                         self.superweapons_finished = 0;
1930                 }
1931         }
1932
1933         if(autocvar_g_nodepthtestplayers)
1934                 self.effects = self.effects | EF_NODEPTHTEST;
1935
1936         if(autocvar_g_fullbrightplayers)
1937                 self.effects = self.effects | EF_FULLBRIGHT;
1938
1939         // midair gamemode: damage only while in the air
1940         // if in midair mode, being on ground grants temporary invulnerability
1941         // (this is so that multishot weapon don't clear the ground flag on the
1942         // first damage in the frame, leaving the player vulnerable to the
1943         // remaining hits in the same frame)
1944         if (self.flags & FL_ONGROUND)
1945         if (g_midair)
1946                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1947
1948         if (time >= game_starttime)
1949         if (time < self.spawnshieldtime)
1950                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1951
1952         MUTATOR_CALLHOOK(PlayerPowerups);
1953 }
1954
1955 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1956 {
1957         if(current > stable)
1958                 return current;
1959         else if(current > stable - 0.25) // when close enough, "snap"
1960                 return stable;
1961         else
1962                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1963 }
1964
1965 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1966 {
1967         if(current < stable)
1968                 return current;
1969         else if(current < stable + 0.25) // when close enough, "snap"
1970                 return stable;
1971         else
1972                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1973 }
1974
1975 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1976 {
1977         if(current > rotstable)
1978         {
1979                 if(rotframetime > 0)
1980                 {
1981                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1982                         current = max(rotstable, current - rotlinear * rotframetime);
1983                 }
1984         }
1985         else if(current < regenstable)
1986         {
1987                 if(regenframetime > 0)
1988                 {
1989                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1990                         current = min(regenstable, current + regenlinear * regenframetime);
1991                 }
1992         }
1993
1994         if(current > limit)
1995                 current = limit;
1996
1997         return current;
1998 }
1999
2000 void player_regen (void)
2001 {
2002         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2003         maxh = autocvar_g_balance_health_rotstable;
2004         maxa = autocvar_g_balance_armor_rotstable;
2005         maxf = autocvar_g_balance_fuel_rotstable;
2006         minh = autocvar_g_balance_health_regenstable;
2007         mina = autocvar_g_balance_armor_regenstable;
2008         minf = autocvar_g_balance_fuel_regenstable;
2009         limith = autocvar_g_balance_health_limit;
2010         limita = autocvar_g_balance_armor_limit;
2011         limitf = autocvar_g_balance_fuel_limit;
2012
2013         max_mod = regen_mod = rot_mod = limit_mod = 1;
2014
2015         if (self.runes & RUNE_REGEN)
2016         {
2017                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2018                 {
2019                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2020                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2021                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2022                 }
2023                 else
2024                 {
2025                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2026                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2027                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2028                 }
2029         }
2030         else if (self.runes & CURSE_VENOM)
2031         {
2032                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2033                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2034                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2035                 else
2036                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2037                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2038                 //if (!self.runes & RUNE_REGEN)
2039                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2040         }
2041         maxh = maxh * max_mod;
2042         //maxa = maxa * max_mod;
2043         //maxf = maxf * max_mod;
2044         minh = minh * max_mod;
2045         //mina = mina * max_mod;
2046         //minf = minf * max_mod;
2047         limith = limith * limit_mod;
2048         limita = limita * limit_mod;
2049         //limitf = limitf * limit_mod;
2050
2051         if(g_lms && g_ca)
2052                 rot_mod = 0;
2053
2054         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2055         {
2056                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2057                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2058
2059                 // if player rotted to death...  die!
2060                 if(self.health < 1)
2061                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2062         }
2063
2064         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2065                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2066 }
2067
2068 float zoomstate_set;
2069 void SetZoomState(float z)
2070 {
2071         if(z != self.zoomstate)
2072         {
2073                 self.zoomstate = z;
2074                 ClientData_Touch(self);
2075         }
2076         zoomstate_set = 1;
2077 }
2078
2079 void GetPressedKeys(void) {
2080         MUTATOR_CALLHOOK(GetPressedKeys);
2081         if (self.movement_x > 0) // get if movement keys are pressed
2082         {       // forward key pressed
2083                 self.pressedkeys |= KEY_FORWARD;
2084                 self.pressedkeys &~= KEY_BACKWARD;
2085         }
2086         else if (self.movement_x < 0)
2087         {       // backward key pressed
2088                 self.pressedkeys |= KEY_BACKWARD;
2089                 self.pressedkeys &~= KEY_FORWARD;
2090         }
2091         else
2092         {       // no x input
2093                 self.pressedkeys &~= KEY_FORWARD;
2094                 self.pressedkeys &~= KEY_BACKWARD;
2095         }
2096
2097         if (self.movement_y > 0)
2098         {       // right key pressed
2099                 self.pressedkeys |= KEY_RIGHT;
2100                 self.pressedkeys &~= KEY_LEFT;
2101         }
2102         else if (self.movement_y < 0)
2103         {       // left key pressed
2104                 self.pressedkeys |= KEY_LEFT;
2105                 self.pressedkeys &~= KEY_RIGHT;
2106         }
2107         else
2108         {       // no y input
2109                 self.pressedkeys &~= KEY_RIGHT;
2110                 self.pressedkeys &~= KEY_LEFT;
2111         }
2112
2113         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2114                 self.pressedkeys |= KEY_JUMP;
2115         else
2116                 self.pressedkeys &~= KEY_JUMP;
2117         if (self.BUTTON_CROUCH)
2118                 self.pressedkeys |= KEY_CROUCH;
2119         else
2120                 self.pressedkeys &~= KEY_CROUCH;
2121
2122         if (self.BUTTON_ATCK)
2123                 self.pressedkeys |= KEY_ATCK;
2124         else
2125                 self.pressedkeys &~= KEY_ATCK;
2126         if (self.BUTTON_ATCK2)
2127                 self.pressedkeys |= KEY_ATCK2;
2128         else
2129                 self.pressedkeys &~= KEY_ATCK2;
2130 }
2131
2132 /*
2133 ======================
2134 spectate mode routines
2135 ======================
2136 */
2137
2138 void SpectateCopy(entity spectatee) {
2139         other = spectatee;
2140         MUTATOR_CALLHOOK(SpectateCopy);
2141         self.armortype = spectatee.armortype;
2142         self.armorvalue = spectatee.armorvalue;
2143         self.ammo_cells = spectatee.ammo_cells;
2144         self.ammo_shells = spectatee.ammo_shells;
2145         self.ammo_nails = spectatee.ammo_nails;
2146         self.ammo_rockets = spectatee.ammo_rockets;
2147         self.ammo_fuel = spectatee.ammo_fuel;
2148         self.clip_load = spectatee.clip_load;
2149         self.clip_size = spectatee.clip_size;
2150         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2151         self.health = spectatee.health;
2152         self.impulse = 0;
2153         self.items = spectatee.items;
2154         self.last_pickup = spectatee.last_pickup;
2155         self.hit_time = spectatee.hit_time;
2156         self.metertime = spectatee.metertime;
2157         self.strength_finished = spectatee.strength_finished;
2158         self.invincible_finished = spectatee.invincible_finished;
2159         self.pressedkeys = spectatee.pressedkeys;
2160         WEPSET_COPY_EE(self, spectatee);
2161         self.switchweapon = spectatee.switchweapon;
2162         self.switchingweapon = spectatee.switchingweapon;
2163         self.weapon = spectatee.weapon;
2164         self.nex_charge = spectatee.nex_charge;
2165         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2166         self.hagar_load = spectatee.hagar_load;
2167         self.minelayer_mines = spectatee.minelayer_mines;
2168         self.punchangle = spectatee.punchangle;
2169         self.view_ofs = spectatee.view_ofs;
2170         self.velocity = spectatee.velocity;
2171         self.dmg_take = spectatee.dmg_take;
2172         self.dmg_save = spectatee.dmg_save;
2173         self.dmg_inflictor = spectatee.dmg_inflictor;
2174         self.v_angle = spectatee.v_angle;
2175         self.angles = spectatee.v_angle;
2176         if(!self.BUTTON_USE)
2177                 self.fixangle = TRUE;
2178         setorigin(self, spectatee.origin);
2179         setsize(self, spectatee.mins, spectatee.maxs);
2180         SetZoomState(spectatee.zoomstate);
2181
2182     anticheat_spectatecopy(spectatee);
2183         self.hud = spectatee.hud;
2184         if(spectatee.vehicle)
2185     {
2186         self.fixangle = FALSE;
2187         //self.velocity = spectatee.vehicle.velocity;
2188         self.vehicle_health = spectatee.vehicle_health;
2189         self.vehicle_shield = spectatee.vehicle_shield;
2190         self.vehicle_energy = spectatee.vehicle_energy;
2191         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2192         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2193         self.vehicle_reload1 = spectatee.vehicle_reload1;
2194         self.vehicle_reload2 = spectatee.vehicle_reload2;
2195
2196         msg_entity = self;
2197
2198         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2199             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2200             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2201             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2202
2203         //WriteByte (MSG_ONE, SVC_SETVIEW);
2204         //    WriteEntity(MSG_ONE, self);
2205         //makevectors(spectatee.v_angle);
2206         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2207     }
2208 }
2209
2210 float SpectateUpdate() {
2211         if(!self.enemy)
2212             return 0;
2213
2214         if (self == self.enemy)
2215                 return 0;
2216
2217         if(self.enemy.classname != "player")
2218                 return 0;
2219
2220         SpectateCopy(self.enemy);
2221
2222         return 1;
2223 }
2224
2225
2226 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2227 entity CA_SpectateNext(entity start) {
2228         if (start.team == self.team) {
2229                 return start;
2230         }
2231
2232         other = start;
2233         // continue from current player
2234         while(other && other.team != self.team) {
2235                 other = find(other, classname, "player");
2236         }
2237
2238         if (!other) {
2239                 // restart from begining
2240                 other = find(other, classname, "player");
2241                 while(other && other.team != self.team) {
2242                         other = find(other, classname, "player");
2243                 }
2244         }
2245
2246         return other;
2247 }
2248
2249 float SpectateNext() {
2250         other = find(self.enemy, classname, "player");
2251         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2252                 // CA and ca players when spectating enemies is forbidden
2253                 other = CA_SpectateNext(other);
2254         } else {
2255                 // other modes and ca spectators or spectating enemies is allowed
2256                 if (!other)
2257                         other = find(other, classname, "player");
2258         }
2259
2260         if (other)
2261                 self.enemy = other;
2262
2263         if(self.enemy.classname == "player") {
2264             /*if(self.enemy.vehicle)
2265             {
2266
2267             msg_entity = self;
2268             WriteByte(MSG_ONE, SVC_SETVIEW);
2269             WriteEntity(MSG_ONE, self.enemy);
2270             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2271
2272             self.movetype = MOVETYPE_NONE;
2273             accuracy_resend(self);
2274             }
2275             else
2276             {*/
2277             msg_entity = self;
2278             WriteByte(MSG_ONE, SVC_SETVIEW);
2279             WriteEntity(MSG_ONE, self.enemy);
2280             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2281             self.movetype = MOVETYPE_NONE;
2282             accuracy_resend(self);
2283
2284             if(!SpectateUpdate())
2285                 PutObserverInServer();
2286         //}
2287         return 1;
2288         } else {
2289                 return 0;
2290         }
2291 }
2292
2293 /*
2294 =============
2295 ShowRespawnCountdown()
2296
2297 Update a respawn countdown display.
2298 =============
2299 */
2300 void ShowRespawnCountdown()
2301 {
2302         float number;
2303         if(self.deadflag == DEAD_NO) // just respawned?
2304                 return;
2305         else
2306         {
2307                 number = ceil(self.respawn_time - time);
2308                 if(number <= 0)
2309                         return;
2310                 if(number <= self.respawn_countdown)
2311                 {
2312                         self.respawn_countdown = number - 1;
2313                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2314                                 AnnounceTo(self, strcat(ftos(number), ""));
2315                 }
2316         }
2317 }
2318
2319 .float prevent_join_msgtime;
2320 void LeaveSpectatorMode()
2321 {
2322         if(nJoinAllowed(self)) {
2323                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2324                         self.classname = "player";
2325
2326                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2327                                 JoinBestTeam(self, FALSE, TRUE);
2328
2329                         if(autocvar_g_campaign)
2330                                 campaign_bots_may_start = 1;
2331
2332                         PutClientInServer();
2333
2334                         if(self.classname == "player")
2335                                 bprint ("^4", self.netname, "^4 is playing now\n");
2336
2337                         if(!autocvar_g_campaign)
2338                         if (time < self.jointime + autocvar_welcome_message_time)
2339                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2340
2341                         if (self.prevent_join_msgtime)
2342                         {
2343                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2344                                 self.prevent_join_msgtime = 0;
2345                         }
2346
2347                         return;
2348                 } else {
2349                         if (g_ca && self.caplayer) {
2350                         }       // do nothing
2351                         else
2352                                 stuffcmd(self,"menu_showteamselect\n");
2353                         return;
2354                 }
2355         }
2356         else {
2357                 //player may not join because of g_maxplayers is set
2358                 if (time - self.prevent_join_msgtime > 2)
2359                 {
2360                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2361                         self.prevent_join_msgtime = time;
2362                 }
2363         }
2364 }
2365
2366 /**
2367  * Determines whether the player is allowed to join. This depends on cvar
2368  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2369  * it checks whether the number of currently playing players exceeds g_maxplayers.
2370  * @return int number of free slots for players, 0 if none
2371  */
2372 float nJoinAllowed(entity ignore) {
2373         if(!ignore)
2374         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2375         // so report 0 free slots if restricted
2376         {
2377                 if(autocvar_g_forced_team_otherwise == "spectate")
2378                         return 0;
2379                 if(autocvar_g_forced_team_otherwise == "spectator")
2380                         return 0;
2381         }
2382
2383         if(self.team_forced < 0)
2384                 return 0; // forced spectators can never join
2385
2386         // TODO simplify this
2387         entity e;
2388         float totalClients = 0;
2389         FOR_EACH_CLIENT(e)
2390                 if(e != ignore)
2391                         totalClients += 1;
2392
2393         if (!autocvar_g_maxplayers)
2394                 return maxclients - totalClients;
2395
2396         float currentlyPlaying = 0;
2397         FOR_EACH_REALPLAYER(e)
2398                 currentlyPlaying += 1;
2399
2400         if(currentlyPlaying < autocvar_g_maxplayers)
2401                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2402
2403         return 0;
2404 }
2405
2406 /**
2407  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2408  * g_maxplayers_spectator_blocktime seconds
2409  */
2410 void checkSpectatorBlock() {
2411         if(self.classname == "spectator" || self.classname == "observer") {
2412                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2413                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2414                         dropclient(self);
2415                 }
2416         }
2417 }
2418
2419 .float motd_actived_time; // used for both motd and campaign_message
2420 void PrintWelcomeMessage()
2421 {
2422         if (self.motd_actived_time == 0) { // is there already a message showing?
2423                 if (autocvar_g_campaign) {
2424                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2425                                 self.motd_actived_time = time;
2426                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2427                         }
2428                 } else {
2429                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2430                                 self.motd_actived_time = time;
2431                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2432                         }
2433                 }
2434         } else { // showing MOTD or campaign message
2435                 if (autocvar_g_campaign) {
2436                         if (self.BUTTON_INFO)
2437                                 self.motd_actived_time = time;
2438                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2439                                 self.motd_actived_time = 0;
2440                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2441                         }
2442                 } else {
2443                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2444                                 if (self.BUTTON_INFO)
2445                                         self.motd_actived_time = time;
2446                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2447                                         self.motd_actived_time = 0;
2448                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2449                                 }
2450                         }
2451                 }
2452         }
2453 }
2454
2455 void ObserverThink()
2456 {
2457         float prefered_movetype;
2458         if (self.flags & FL_JUMPRELEASED) {
2459                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2460                         self.flags &~= FL_JUMPRELEASED;
2461                         self.flags |= FL_SPAWNING;
2462                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2463                         self.flags &~= FL_JUMPRELEASED;
2464                         if(SpectateNext() == 1) {
2465                                 self.classname = "spectator";
2466                         }
2467                 } else {
2468                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2469                         if (self.movetype != prefered_movetype)
2470                                 self.movetype = prefered_movetype;
2471                 }
2472         } else {
2473                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2474                         self.flags |= FL_JUMPRELEASED;
2475                         if(self.flags & FL_SPAWNING)
2476                         {
2477                                 self.flags &~= FL_SPAWNING;
2478                                 LeaveSpectatorMode();
2479                                 return;
2480                         }
2481                 }
2482         }
2483
2484         PrintWelcomeMessage();
2485 }
2486
2487 void SpectatorThink()
2488 {
2489         if (self.flags & FL_JUMPRELEASED) {
2490                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2491                         self.flags &~= FL_JUMPRELEASED;
2492                         self.flags |= FL_SPAWNING;
2493                 } else if(self.BUTTON_ATCK) {
2494                         self.flags &~= FL_JUMPRELEASED;
2495                         if(SpectateNext() == 1) {
2496                                 self.classname = "spectator";
2497                         } else {
2498                                 self.classname = "observer";
2499                                 PutClientInServer();
2500                         }
2501                 } else if (self.BUTTON_ATCK2) {
2502                         self.flags &~= FL_JUMPRELEASED;
2503                         self.classname = "observer";
2504                         PutClientInServer();
2505                 } else {
2506                         if(!SpectateUpdate())
2507                                 PutObserverInServer();
2508                 }
2509         } else {
2510                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2511                         self.flags |= FL_JUMPRELEASED;
2512                         if(self.flags & FL_SPAWNING)
2513                         {
2514                                 self.flags &~= FL_SPAWNING;
2515                                 LeaveSpectatorMode();
2516                                 return;
2517                         }
2518                 }
2519                 if(!SpectateUpdate())
2520                         PutObserverInServer();
2521         }
2522
2523         PrintWelcomeMessage();
2524         self.flags |= FL_CLIENT | FL_NOTARGET;
2525 }
2526
2527 float ctf_usekey();
2528 void PlayerUseKey()
2529 {
2530         if(self.classname != "player")
2531                 return;
2532
2533         if(self.vehicle)
2534         {
2535         vehicles_exit(VHEF_NORMAL);
2536         return;
2537         }
2538
2539         // a use key was pressed; call handlers
2540         if(ctf_usekey())
2541                 return;
2542
2543         MUTATOR_CALLHOOK(PlayerUseKey);
2544 }
2545
2546 .float touchexplode_time;
2547
2548 /*
2549 =============
2550 PlayerPreThink
2551
2552 Called every frame for each client before the physics are run
2553 =============
2554 */
2555 .float usekeypressed;
2556 void() ctf_setstatus;
2557 void() nexball_setstatus;
2558 .float items_added;
2559 void PlayerPreThink (void)
2560 {
2561         WarpZone_PlayerPhysics_FixVAngle();
2562
2563         self.stat_game_starttime = game_starttime;
2564         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2565         self.stat_leadlimit = autocvar_leadlimit;
2566
2567         if(frametime)
2568         {
2569                 // physics frames: update anticheat stuff
2570                 anticheat_prethink();
2571         }
2572
2573         if(blockSpectators && frametime)
2574                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2575                 checkSpectatorBlock();
2576
2577         zoomstate_set = 0;
2578
2579         if(self.netname_previous != self.netname)
2580         {
2581                 if(autocvar_sv_eventlog)
2582                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2583                 if(self.netname_previous)
2584                         strunzone(self.netname_previous);
2585                 self.netname_previous = strzone(self.netname);
2586         }
2587
2588         // version nagging
2589         if(self.version_nagtime)
2590                 if(self.cvar_g_xonoticversion)
2591                         if(time > self.version_nagtime)
2592                         {
2593                                 // don't notify git users
2594                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2595                                 {
2596                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2597                                         {
2598                                                 // notify release users if connecting to git
2599                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2600                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2601                                         }
2602                                         else
2603                                         {
2604                                                 float r;
2605                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2606                                                 if(r < 0)
2607                                                 {
2608                                                         // give users new version
2609                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2610                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2611                                                 }
2612                                                 else if(r > 0)
2613                                                 {
2614                                                         // notify users about old server version
2615                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2616                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2617                                                 }
2618                                         }
2619                                 }
2620                                 self.version_nagtime = 0;
2621                         }
2622
2623         // GOD MODE info
2624         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2625         {
2626                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2627                 self.max_armorvalue = 0;
2628         }
2629
2630 #ifdef TETRIS
2631         if (TetrisPreFrame())
2632                 return;
2633 #endif
2634
2635         MUTATOR_CALLHOOK(PlayerPreThink);
2636
2637         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2638         {
2639                 if(self.BUTTON_USE && !self.usekeypressed)
2640                         PlayerUseKey();
2641                 self.usekeypressed = self.BUTTON_USE;
2642         }
2643
2644         PrintWelcomeMessage();
2645
2646         if(self.classname == "player") {
2647 //              if(self.netname == "Wazat")
2648 //                      bprint(self.classname, "\n");
2649
2650                 CheckRules_Player();
2651
2652                 if (intermission_running)
2653                 {
2654                         IntermissionThink ();   // otherwise a button could be missed between
2655                         return;                                 // the think tics
2656                 }
2657
2658                 //don't allow the player to turn around while game is paused!
2659                 if(timeout_status == TIMEOUT_ACTIVE) {
2660                         // FIXME turn this into CSQC stuff
2661                         self.v_angle = self.lastV_angle;
2662                         self.angles = self.lastV_angle;
2663                         self.fixangle = TRUE;
2664                 }
2665
2666                 if(frametime)
2667                 {
2668 #ifndef NO_LEGACY_NETWORKING
2669                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2670 #endif
2671
2672                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2673                         {
2674                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2675                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2676                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2677
2678                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2679                                 {
2680                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2681                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2682                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2683                                 }
2684                         }
2685                         else
2686                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2687
2688                         player_powerups();
2689                 }
2690
2691                 if (g_minstagib)
2692                         minstagib_ammocheck();
2693
2694                 if (self.deadflag != DEAD_NO)
2695                 {
2696                         float button_pressed, force_respawn;
2697                         if(self.personal && g_race_qualifying)
2698                         {
2699                                 if(time > self.respawn_time)
2700                                 {
2701                                         self.respawn_time = time + 1; // only retry once a second
2702                                         respawn();
2703                                         self.impulse = 141;
2704                                 }
2705                         }
2706                         else
2707                         {
2708                                 if(frametime)
2709                                         player_anim();
2710                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2711                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2712                                 if (self.deadflag == DEAD_DYING)
2713                                 {
2714                                         if(force_respawn)
2715                                                 self.deadflag = DEAD_RESPAWNING;
2716                                         else if(!button_pressed)
2717                                                 self.deadflag = DEAD_DEAD;
2718                                 }
2719                                 else if (self.deadflag == DEAD_DEAD)
2720                                 {
2721                                         if(button_pressed)
2722                                                 self.deadflag = DEAD_RESPAWNABLE;
2723                                 }
2724                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2725                                 {
2726                                         if(!button_pressed)
2727                                                 self.deadflag = DEAD_RESPAWNING;
2728                                 }
2729                                 else if (self.deadflag == DEAD_RESPAWNING)
2730                                 {
2731                                         if(time > self.respawn_time)
2732                                         {
2733                                                 self.respawn_time = time + 1; // only retry once a second
2734                                                 respawn();
2735                                         }
2736                                 }
2737                                 ShowRespawnCountdown();
2738                         }
2739                         return;
2740                 }
2741                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2742                 // so (self.deadflag == DEAD_NO) is always true in the code below
2743
2744                 if(g_touchexplode)
2745                 if(time > self.touchexplode_time)
2746                 if(self.classname == "player")
2747                 if(self.deadflag == DEAD_NO)
2748                 if not(IS_INDEPENDENT_PLAYER(self))
2749                 FOR_EACH_PLAYER(other) if(self != other)
2750                 {
2751                         if(time > other.touchexplode_time)
2752                         if(other.deadflag == DEAD_NO)
2753                         if not(IS_INDEPENDENT_PLAYER(other))
2754                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2755                         {
2756                                 PlayerTouchExplode(self, other);
2757                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2758                         }
2759                 }
2760
2761                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2762                 {
2763                         vector dist;
2764
2765                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2766                         dist = self.prevorigin - self.origin;
2767                         dist_z = 0;
2768                         self.lms_traveled_distance += fabs(vlen(dist));
2769
2770                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2771                         {
2772                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2773                                 self.lms_traveled_distance = 0;
2774                         }
2775
2776                         if(time > self.lms_nextcheck)
2777                         {
2778                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2779                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2780                                 {
2781                                         centerprint(self, autocvar_g_lms_campcheck_message);
2782                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2783                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2784                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2785                                 }
2786                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2787                                 self.lms_traveled_distance = 0;
2788                         }
2789                 }
2790
2791                 self.prevorigin = self.origin;
2792
2793                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x) // prevent crouching if using melee attack
2794                 {
2795                         if (!self.crouch)
2796                         {
2797                                 self.crouch = TRUE;
2798                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2799                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2800                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2801                         }
2802                 }
2803                 else
2804                 {
2805                         if (self.crouch)
2806                         {
2807                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2808                                 if (!trace_startsolid)
2809                                 {
2810                                         self.crouch = FALSE;
2811                                         self.view_ofs = PL_VIEW_OFS;
2812                                         setsize (self, PL_MIN, PL_MAX);
2813                                 }
2814                         }
2815                 }
2816
2817                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2818                 {
2819                         if(self.bloodloss_timer < time)
2820                         {
2821                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2822                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2823                         }
2824                 }
2825
2826                 FixPlayermodel();
2827
2828                 GrapplingHookFrame();
2829
2830                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2831                 //if(frametime)
2832                 {
2833                         self.items &~= self.items_added;
2834
2835                         W_WeaponFrame();
2836
2837                         self.items_added = 0;
2838                         if(self.items & IT_JETPACK)
2839                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2840                                         self.items_added |= IT_FUEL;
2841
2842                         self.items |= self.items_added;
2843                 }
2844
2845                 player_regen();
2846
2847                 // rot nex charge to the charge limit
2848                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2849                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2850
2851                 if(frametime)
2852                         player_anim();
2853
2854                 if(g_ctf)
2855                         ctf_setstatus();
2856
2857                 if(g_nexball)
2858                         nexball_setstatus();
2859
2860                 // secret status
2861                 secrets_setstatus();
2862
2863                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2864
2865                 //self.angles_y=self.v_angle_y + 90;   // temp
2866         } else if(gameover) {
2867                 if (intermission_running)
2868                         IntermissionThink ();   // otherwise a button could be missed between
2869                 return;
2870         } else if(self.classname == "observer") {
2871                 ObserverThink();
2872         } else if(self.classname == "spectator") {
2873                 SpectatorThink();
2874         }
2875
2876         if(!zoomstate_set)
2877                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2878
2879         float oldspectatee_status;
2880         oldspectatee_status = self.spectatee_status;
2881         if(self.classname == "spectator")
2882                 self.spectatee_status = num_for_edict(self.enemy);
2883         else if(self.classname == "observer")
2884                 self.spectatee_status = num_for_edict(self);
2885         else
2886                 self.spectatee_status = 0;
2887         if(self.spectatee_status != oldspectatee_status)
2888         {
2889                 ClientData_Touch(self);
2890                 if(g_race || g_cts)
2891                         race_InitSpectator();
2892         }
2893
2894         if(self.teamkill_soundtime)
2895         if(time > self.teamkill_soundtime)
2896         {
2897                 self.teamkill_soundtime = 0;
2898
2899                 entity oldpusher, oldself;
2900
2901                 oldself = self; self = self.teamkill_soundsource;
2902                 oldpusher = self.pusher; self.pusher = oldself;
2903
2904                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2905
2906                 self.pusher = oldpusher;
2907                 self = oldself;
2908         }
2909
2910         if(self.taunt_soundtime)
2911         if(time > self.taunt_soundtime)
2912         {
2913                 self.taunt_soundtime = 0;
2914                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2915         }
2916
2917         target_voicescript_next(self);
2918
2919         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2920         if(!self.weapon)
2921                 self.clip_load = self.clip_size = 0;
2922 }
2923
2924 float isInvisibleString(string s)
2925 {
2926         float i, n, c;
2927         s = strdecolorize(s);
2928         for((i = 0), (n = strlen(s)); i < n; ++i)
2929         {
2930                 c = str2chr(s, i);
2931                 switch(c)
2932                 {
2933                         case 0:
2934                         case 32: // space
2935                                 break;
2936                         case 192: // charmap space
2937                                 if (!autocvar_utf8_enable)
2938                                         break;
2939                                 return FALSE;
2940                         case 160: // space in unicode fonts
2941                         case 0xE000 + 192: // utf8 charmap space
2942                                 if (autocvar_utf8_enable)
2943                                         break;
2944                         default:
2945                                 return FALSE;
2946                 }
2947         }
2948         return TRUE;
2949 }
2950
2951 /*
2952 =============
2953 PlayerPostThink
2954
2955 Called every frame for each client after the physics are run
2956 =============
2957 */
2958 .float idlekick_lasttimeleft;
2959 .entity showheadshotbbox;
2960 void showheadshotbbox_think()
2961 {
2962         if(self.owner.showheadshotbbox != self)
2963         {
2964                 remove(self);
2965                 return;
2966         }
2967         self.nextthink = time;
2968         setorigin(self, self.owner.origin);
2969         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2970 }
2971 void PlayerPostThink (void)
2972 {
2973         // Savage: Check for nameless players
2974         if (isInvisibleString(self.netname)) {
2975                 self.netname = "Player";
2976                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2977         }
2978
2979         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2980         {
2981                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2982                 {
2983                         if(self.idlekick_lasttimeleft)
2984                         {
2985                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2986                                 self.idlekick_lasttimeleft = 0;
2987                         }
2988                 }
2989                 else
2990                 {
2991                         float timeleft;
2992                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2993                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2994                         {
2995                                 if(!self.idlekick_lasttimeleft)
2996                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
2997                         }
2998                         if(timeleft <= 0)
2999                         {
3000                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
3001                                 AnnounceTo(self, "terminated");
3002                                 dropclient(self);
3003                                 return;
3004                         }
3005                         else if(timeleft <= 10)
3006                         {
3007                                 if(timeleft != self.idlekick_lasttimeleft)
3008                                         AnnounceTo(self, ftos(timeleft));
3009                                 self.idlekick_lasttimeleft = timeleft;
3010                         }
3011                 }
3012         }
3013
3014 #ifdef TETRIS
3015         if(self.impulse == 100)
3016                 ImpulseCommands();
3017         if (!TetrisPostFrame())
3018         {
3019 #endif
3020
3021         CheatFrame();
3022
3023         //CheckPlayerJump();
3024
3025         if(self.classname == "player") {
3026                 CheckRules_Player();
3027                 UpdateChatBubble();
3028                 if (self.impulse)
3029                         ImpulseCommands();
3030                 if (intermission_running)
3031                         return;         // intermission or finale
3032                 GetPressedKeys();
3033         } else if (self.classname == "observer") {
3034                 //do nothing
3035         } else if (self.classname == "spectator") {
3036                 //do nothing
3037         }
3038
3039 #ifdef TETRIS
3040         }
3041 #endif
3042
3043         /*
3044         float i;
3045         for(i = 0; i < 1000; ++i)
3046         {
3047                 vector end;
3048                 end = self.origin + '0 0 1024' + 512 * randomvec();
3049                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3050                 if(trace_fraction < 1)
3051                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3052                 {
3053                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3054                         break;
3055                 }
3056         }
3057         */
3058
3059         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3060
3061         if(self.waypointsprite_attachedforcarrier)
3062                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3063
3064         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3065         {
3066                 if(!self.showheadshotbbox)
3067                 {
3068                         self.showheadshotbbox = spawn();
3069                         self.showheadshotbbox.classname = "headshotbbox";
3070                         self.showheadshotbbox.owner = self;
3071                         self.showheadshotbbox.think = showheadshotbbox_think;
3072                         self.showheadshotbbox.nextthink = time;
3073                         self = self.showheadshotbbox;
3074                         self.think();
3075                         self = self.owner;
3076                 }
3077         }
3078         else
3079         {
3080                 if(self.showheadshotbbox)
3081                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3082                 remove(self.showheadshotbbox);
3083         }
3084
3085         playerdemo_write();
3086
3087         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3088         {
3089                 if(!self.stored_netname)
3090                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3091                 if(self.stored_netname != self.netname)
3092                 {
3093                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3094                         strunzone(self.stored_netname);
3095                         self.stored_netname = strzone(self.netname);
3096                 }
3097         }
3098
3099         /*
3100         if(g_race)
3101                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3102         */
3103
3104         CSQCMODEL_AUTOUPDATE();
3105 }