qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         if (g_minstagib)
 408                 minstagib_stop_countdown();
 409
 410         Portal_ClearAll(self);
 411
 412         if(self.alivetime)
 413         {
 414                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 415                 self.alivetime = 0;
 416         }
 417
 418         if(self.vehicle)
 419             vehicles_exit(VHEF_RELESE);
 420
 421         if(self.flagcarried)
 422                 DropFlag(self.flagcarried, world, world);
 423
 424         WaypointSprite_PlayerDead();
 425
 426         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 427                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 428
 429         if(self.killcount != -666) {
 430                 if(g_lms) {
 431                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 432                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 433                         else
 434                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 435                 } else
 436                         bprint ("^4", self.netname, "^4 is spectating now\n");
 437
 438                 if(self.just_joined == FALSE) {
 439                         LogTeamchange(self.playerid, -1, 4);
 440                 } else
 441                         self.just_joined = FALSE;
 442         }
 443
 444         PlayerScore_Clear(self); // clear scores when needed
 445
 446         accuracy_resend(self);
 447
 448         self.spectatortime = time;
 449
 450         self.classname = "observer";
 451         self.iscreature = FALSE;
 452         self.damagedbycontents = FALSE;
 453         self.health = -666;
 454         self.takedamage = DAMAGE_NO;
 455         self.solid = SOLID_NOT;
 456         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 457         self.flags = FL_CLIENT | FL_NOTARGET;
 458         self.armorvalue = 666;
 459         self.effects = 0;
 460         self.armorvalue = autocvar_g_balance_armor_start;
 461         self.pauserotarmor_finished = 0;
 462         self.pauserothealth_finished = 0;
 463         self.pauseregen_finished = 0;
 464         self.damageforcescale = 0;
 465         self.death_time = 0;
 466         self.respawn_time = 0;
 467         self.alpha = 0;
 468         self.scale = 0;
 469         self.fade_time = 0;
 470         self.pain_frame = 0;
 471         self.pain_finished = 0;
 472         self.strength_finished = 0;
 473         self.invincible_finished = 0;
 474         self.superweapons_finished = 0;
 475         self.pushltime = 0;
 476         self.think = SUB_Null;
 477         self.nextthink = 0;
 478         self.hook_time = 0;
 479         self.runes = 0;
 480         self.deadflag = DEAD_NO;
 481         self.angles = spot.angles;
 482         self.angles_z = 0;
 483         self.fixangle = TRUE;
 484         self.crouch = FALSE;
 485
 486         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 487         self.prevorigin = self.origin;
 488         self.items = 0;
 489         self.weapons = 0;
 490         self.model = "";
 491         FixPlayermodel();
 492         setmodel(self, "null");
 493         self.drawonlytoclient = self;
 494
 495         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 496         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 497
 498         self.weapon = 0;
 499         self.weaponname = "";
 500         self.switchingweapon = 0;
 501         self.weaponmodel = "";
 502         self.weaponentity = world;
 503         self.exteriorweaponentity = world;
 504         self.killcount = -666;
 505         self.velocity = '0 0 0';
 506         self.avelocity = '0 0 0';
 507         self.punchangle = '0 0 0';
 508         self.punchvector = '0 0 0';
 509         self.oldvelocity = self.velocity;
 510         self.fire_endtime = -1;
 511
 512         if(g_arena)
 513         {
 514                 if(self.version_mismatch)
 515                 {
 516                         Spawnqueue_Unmark(self);
 517                         Spawnqueue_Remove(self);
 518                 }
 519                 else
 520                 {
 521                         Spawnqueue_Insert(self);
 522                 }
 523         }
 524         else if(g_lms)
 525         {
 526                 // Only if the player cannot play at all
 527                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 528                         self.frags = FRAGS_SPECTATOR;
 529                 else
 530                         self.frags = FRAGS_LMS_LOSER;
 531         }
 532         else if(g_ca)
 533         {
 534                 if(self.caplayer)
 535                         self.frags = FRAGS_LMS_LOSER;
 536                 else
 537                         self.frags = FRAGS_SPECTATOR;
 538         }
 539         else
 540                 self.frags = FRAGS_SPECTATOR;
 541 }
 542
 543 .float model_randomizer;
 544 void FixPlayermodel()
 545 {
 546         string defaultmodel;
 547         float defaultskin, chmdl, oldskin, n, i;
 548         vector m1, m2;
 549
 550         defaultmodel = "";
 551
 552         if(autocvar_sv_defaultcharacter == 1)
 553         {
 554                 defaultskin = 0;
 555
 556                 if(teamplay)
 557                 {
 558                         string s;
 559                         s = Team_ColorNameLowerCase(self.team);
 560                         if(s != "neutral")
 561                         {
 562                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 563                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 564                         }
 565                 }
 566
 567                 if(defaultmodel == "")
 568                 {
 569                         defaultmodel = autocvar_sv_defaultplayermodel;
 570                         defaultskin = autocvar_sv_defaultplayerskin;
 571                 }
 572
 573                 n = tokenize_console(defaultmodel);
 574                 if(n > 0)
 575                         defaultmodel = argv(floor(n * self.model_randomizer));
 576
 577                 i = strstrofs(defaultmodel, ":", 0);
 578                 if(i >= 0)
 579                 {
 580                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 581                         defaultmodel = substring(defaultmodel, 0, i);
 582                 }
 583         }
 584
 585         if(defaultmodel != "")
 586         {
 587                 if (defaultmodel != self.model)
 588                 {
 589                         m1 = self.mins;
 590                         m2 = self.maxs;
 591                         setplayermodel (self, defaultmodel);
 592                         setsize (self, m1, m2);
 593                         chmdl = TRUE;
 594                 }
 595
 596                 oldskin = self.skin;
 597                 self.skin = defaultskin;
 598         } else {
 599                 if (self.playermodel != self.model || self.playermodel == "")
 600                 {
 601                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 602                         m1 = self.mins;
 603                         m2 = self.maxs;
 604                         setplayermodel (self, self.playermodel);
 605                         setsize (self, m1, m2);
 606                         chmdl = TRUE;
 607                 }
 608
 609                 oldskin = self.skin;
 610                 self.skin = stof(self.playerskin);
 611         }
 612
 613         if(chmdl || oldskin != self.skin)
 614                 self.species = player_getspecies(); // model or skin has changed
 615
 616         if(!teamplay)
 617                 if(strlen(autocvar_sv_defaultplayercolors))
 618                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 619                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 620 }
 621
 622 void PlayerTouchExplode(entity p1, entity p2)
 623 {
 624         vector org;
 625         org = (p1.origin + p2.origin) * 0.5;
 626         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 627
 628         te_explosion(org);
 629
 630         entity e;
 631         e = spawn();
 632         setorigin(e, org);
 633         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 634         remove(e);
 635 }
 636
 637 /*
 638 =============
 639 PutClientInServer
 640
 641 Called when a client spawns in the server
 642 =============
 643 */
 644 //void() ctf_playerchanged;
 645
 646 void PutClientInServer (void)
 647 {
 648         if(clienttype(self) == CLIENTTYPE_BOT)
 649         {
 650                 self.classname = "player";
 651                 if(g_ca)
 652                         self.caplayer = 1;
 653         }
 654         else if(clienttype(self) == CLIENTTYPE_REAL)
 655         {
 656                 msg_entity = self;
 657                 WriteByte(MSG_ONE, SVC_SETVIEW);
 658                 WriteEntity(MSG_ONE, self);
 659         }
 660
 661         // reset player keys
 662         self.itemkeys = 0;
 663
 664         // player is dead and becomes observer
 665         // FIXME fix LMS scoring for new system
 666         if(g_lms)
 667         {
 668                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 669                         self.classname = "observer";
 670         }
 671
 672         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
 673                 self.classname = "observer";
 674
 675         if(gameover)
 676                 self.classname = "observer";
 677
 678         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 679                 entity spot, oldself;
 680                 float j;
 681
 682                 accuracy_resend(self);
 683
 684                 if(self.team < 0)
 685                         JoinBestTeam(self, FALSE, TRUE);
 686
 687                 race_PreSpawn();
 688
 689                 spot = SelectSpawnPoint (FALSE);
 690                 if(!spot)
 691                 {
 692                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 693                         return; // spawn failed
 694                 }
 695
 696                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 697
 698                 self.classname = "player";
 699                 self.wasplayer = TRUE;
 700                 self.iscreature = TRUE;
 701                 self.damagedbycontents = TRUE;
 702                 self.movetype = MOVETYPE_WALK;
 703                 self.solid = SOLID_SLIDEBOX;
 704                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 705                 if(autocvar_g_playerclip_collisions)
 706                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 707                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 708                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 709                 self.frags = FRAGS_PLAYER;
 710                 if(INDEPENDENT_PLAYERS)
 711                         MAKE_INDEPENDENT_PLAYER(self);
 712                 self.flags = FL_CLIENT;
 713                 if(autocvar__notarget)
 714                         self.flags |= FL_NOTARGET;
 715                 self.takedamage = DAMAGE_AIM;
 716                 if(g_minstagib)
 717                         self.effects = EF_FULLBRIGHT;
 718                 else
 719                         self.effects = 0;
 720                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 721                 self.air_finished = time + 12;
 722                 self.dmg = 2;
 723                 if(autocvar_g_balance_nex_charge)
 724                 {
 725                         if(autocvar_g_balance_nex_secondary_chargepool)
 726                                 self.nex_chargepool_ammo = 1;
 727                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 728                 }
 729
 730                 if(inWarmupStage)
 731                 {
 732                         self.ammo_shells = warmup_start_ammo_shells;
 733                         self.ammo_nails = warmup_start_ammo_nails;
 734                         self.ammo_rockets = warmup_start_ammo_rockets;
 735                         self.ammo_cells = warmup_start_ammo_cells;
 736                         self.ammo_fuel = warmup_start_ammo_fuel;
 737                         self.health = warmup_start_health;
 738                         self.armorvalue = warmup_start_armorvalue;
 739                         self.weapons = warmup_start_weapons;
 740                 }
 741                 else
 742                 {
 743                         self.ammo_shells = start_ammo_shells;
 744                         self.ammo_nails = start_ammo_nails;
 745                         self.ammo_rockets = start_ammo_rockets;
 746                         self.ammo_cells = start_ammo_cells;
 747                         self.ammo_fuel = start_ammo_fuel;
 748                         self.health = start_health;
 749                         self.armorvalue = start_armorvalue;
 750                         self.weapons = start_weapons;
 751                 }
 752
 753                 if(self.weapons & WEPBIT_SUPERWEAPONS) // exception for minstagib, as minstanex is a superweapon
 754                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 755                 else
 756                         self.superweapons_finished = 0;
 757
 758                 if(g_weaponarena_random)
 759                 {
 760                         if(g_weaponarena_random_with_laser)
 761                                 self.weapons &~= WEPBIT_LASER;
 762                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 763                         if(g_weaponarena_random_with_laser)
 764                                 self.weapons |= WEPBIT_LASER;
 765                 }
 766
 767                 self.items = start_items;
 768
 769                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 770                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 771                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 772                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 773                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 774                 //extend the pause of rotting if client was reset at the beginning of the countdown
 775                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 776                         self.spawnshieldtime += game_starttime - time;
 777                         self.pauserotarmor_finished += game_starttime - time;
 778                         self.pauserothealth_finished += game_starttime - time;
 779                         self.pauseregen_finished += game_starttime - time;
 780                 }
 781                 self.damageforcescale = 2;
 782                 self.death_time = 0;
 783                 self.respawn_time = 0;
 784                 self.scale = 0;
 785                 self.fade_time = 0;
 786                 self.pain_frame = 0;
 787                 self.pain_finished = 0;
 788                 self.strength_finished = 0;
 789                 self.invincible_finished = 0;
 790                 self.pushltime = 0;
 791                 // players have no think function
 792                 self.think = SUB_Null;
 793                 self.nextthink = 0;
 794                 self.hook_time = 0;
 795                 self.dmg_team = 0;
 796                 self.ballistics_density = autocvar_g_ballistics_density_player;
 797
 798                 self.metertime = 0;
 799
 800                 self.runes = 0;
 801
 802                 self.deadflag = DEAD_NO;
 803
 804                 self.angles = spot.angles;
 805
 806                 self.angles_z = 0; // never spawn tilted even if the spot says to
 807                 self.fixangle = TRUE; // turn this way immediately
 808                 self.velocity = '0 0 0';
 809                 self.avelocity = '0 0 0';
 810                 self.punchangle = '0 0 0';
 811                 self.punchvector = '0 0 0';
 812                 self.oldvelocity = self.velocity;
 813                 self.fire_endtime = -1;
 814
 815                 msg_entity = self;
 816                 WRITESPECTATABLE_MSG_ONE({
 817                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 818                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 819                 });
 820
 821                 self.model = "";
 822                 FixPlayermodel();
 823                 self.drawonlytoclient = world;
 824
 825                 self.crouch = FALSE;
 826                 self.view_ofs = PL_VIEW_OFS;
 827                 setsize (self, PL_MIN, PL_MAX);
 828                 self.spawnorigin = spot.origin;
 829                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 830                 // don't reset back to last position, even if new position is stuck in solid
 831                 self.oldorigin = self.origin;
 832                 self.prevorigin = self.origin;
 833                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 834                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 835         self.hud = HUD_NORMAL;
 836
 837                 if(g_arena)
 838                 {
 839                         Spawnqueue_Remove(self);
 840                         Spawnqueue_Mark(self);
 841                 }
 842                 else if(g_ca)
 843                         self.caplayer = 1;
 844
 845                 self.event_damage = PlayerDamage;
 846
 847                 self.bot_attack = TRUE;
 848
 849                 self.statdraintime = time + 5;
 850                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 851
 852                 if(self.killcount == -666) {
 853                         PlayerScore_Clear(self);
 854                         self.killcount = 0;
 855                 }
 856
 857                 CL_SpawnWeaponentity();
 858                 self.alpha = default_player_alpha;
 859                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 860                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 861
 862                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 863                 self.lms_traveled_distance = 0;
 864                 self.speedrunning = FALSE;
 865
 866                 race_PostSpawn(spot);
 867
 868                 //stuffcmd(self, "chase_active 0");
 869                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 870
 871                 if (autocvar_g_spawnsound)
 872                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 873
 874                 if(g_assault) {
 875                         if(self.team == assault_attacker_team)
 876                                 centerprint(self, "You are attacking!");
 877                         else
 878                                 centerprint(self, "You are defending!");
 879                 }
 880
 881                 target_voicescript_clear(self);
 882
 883                 // reset fields the weapons may use
 884                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 885                 {
 886                         weapon_action(j, WR_RESETPLAYER);
 887
 888                         // all weapons must be fully loaded when we spawn
 889                         entity e;
 890                         e = get_weaponinfo(j);
 891                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 892                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 893                 }
 894
 895                 oldself = self;
 896                 self = spot;
 897                         activator = oldself;
 898                                 string s;
 899                                 s = self.target;
 900                                 self.target = string_null;
 901                                 SUB_UseTargets();
 902                                 self.target = s;
 903                         activator = world;
 904                 self = oldself;
 905
 906                 spawn_spot = spot;
 907                 MUTATOR_CALLHOOK(PlayerSpawn);
 908
 909                 if(autocvar_spawn_debug)
 910                 {
 911                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 912                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 913                 }
 914
 915                 self.switchweapon = w_getbestweapon(self);
 916                 self.cnt = -1; // W_LastWeapon will not complain
 917                 self.weapon = 0;
 918                 self.weaponname = "";
 919                 self.switchingweapon = 0;
 920
 921                 if(!self.alivetime)
 922                         self.alivetime = time;
 923
 924                 antilag_clear(self);
 925         } else if(self.classname == "observer") {
 926                 PutObserverInServer ();
 927         }
 928
 929         //if(g_ctf)
 930         //      ctf_playerchanged();
 931 }
 932
 933 .float ebouncefactor, ebouncestop; // electro's values
 934 // TODO do we need all these fields, or should we stop autodetecting runtime
 935 // changes and just have a console command to update this?
 936 float ClientInit_SendEntity(entity to, float sf)
 937 {
 938         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 939         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 940         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 941         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 942         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 943         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 944         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 945         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 946         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 947         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 948         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 949         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 950         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 951         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 952         if(sv_foginterval && world.fog != "")
 953                 WriteString(MSG_ENTITY, world.fog);
 954         else
 955                 WriteString(MSG_ENTITY, "");
 956         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 957         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 958         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 959         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 960         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 961         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 962         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 963         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 964         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 965         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 966         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 967         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 968         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 969         return TRUE;
 970 }
 971
 972 void ClientInit_CheckUpdate()
 973 {
 974         self.nextthink = time;
 975         if(self.count != autocvar_g_balance_armor_blockpercent)
 976         {
 977                 self.count = autocvar_g_balance_armor_blockpercent;
 978                 self.SendFlags |= 1;
 979         }
 980         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 981         {
 982                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 983                 self.SendFlags |= 1;
 984         }
 985         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 986         {
 987                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 988                 self.SendFlags |= 1;
 989         }
 990         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 991         {
 992                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 993                 self.SendFlags |= 1;
 994         }
 995         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 996         {
 997                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 998                 self.SendFlags |= 1;
 999         }
1000         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1001         {
1002                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1003                 self.SendFlags |= 1;
1004         }
1005 }
1006
1007 void ClientInit_Spawn()
1008 {
1009         entity o;
1010         entity e;
1011         e = spawn();
1012         e.classname = "clientinit";
1013         e.think = ClientInit_CheckUpdate;
1014         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1015
1016         o = self;
1017         self = e;
1018         ClientInit_CheckUpdate();
1019         self = o;
1020 }
1021
1022 /*
1023 =============
1024 SetNewParms
1025 =============
1026 */
1027 void SetNewParms (void)
1028 {
1029         // initialize parms for a new player
1030         parm1 = -(86400 * 366);
1031 }
1032
1033 /*
1034 =============
1035 SetChangeParms
1036 =============
1037 */
1038 void SetChangeParms (void)
1039 {
1040         // save parms for level change
1041         parm1 = self.parm_idlesince - time;
1042 }
1043
1044 /*
1045 =============
1046 DecodeLevelParms
1047 =============
1048 */
1049 void DecodeLevelParms (void)
1050 {
1051         // load parms
1052         self.parm_idlesince = parm1;
1053         if(self.parm_idlesince == -(86400 * 366))
1054                 self.parm_idlesince = time;
1055
1056         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1057         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1058 }
1059
1060 /*
1061 =============
1062 ClientKill
1063
1064 Called when a client types 'kill' in the console
1065 =============
1066 */
1067
1068 .float clientkill_nexttime;
1069 void ClientKill_Now_TeamChange()
1070 {
1071         if(self.killindicator_teamchange == -1)
1072         {
1073                 self.team = -1;
1074                 JoinBestTeam( self, FALSE, FALSE );
1075         }
1076         else if(self.killindicator_teamchange == -2)
1077         {
1078                 if(g_ca)
1079                         self.caplayer = 0;
1080                 if(blockSpectators)
1081                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1082                 PutObserverInServer();
1083         }
1084         else
1085                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1086 }
1087
1088 void ClientKill_Now()
1089 {
1090         if(self.vehicle)
1091         {
1092             vehicles_exit(VHEF_RELESE);
1093             if(!self.killindicator_teamchange)
1094             {
1095             self.vehicle_health = -1;
1096             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1097             }
1098         }
1099
1100         if(self.killindicator && !wasfreed(self.killindicator))
1101                 remove(self.killindicator);
1102
1103         self.killindicator = world;
1104
1105         if(self.killindicator_teamchange)
1106                 ClientKill_Now_TeamChange();
1107
1108         // in any case:
1109         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1110
1111         // now I am sure the player IS dead
1112 }
1113 void KillIndicator_Think()
1114 {
1115         if (gameover)
1116         {
1117                 self.owner.killindicator = world;
1118                 remove(self);
1119                 return;
1120         }
1121
1122         if (self.owner.alpha < 0)
1123         {
1124                 self.owner.killindicator = world;
1125                 remove(self);
1126                 return;
1127         }
1128
1129         if(self.cnt <= 0)
1130         {
1131                 self = self.owner;
1132                 ClientKill_Now(); // no oldself needed
1133                 return;
1134         }
1135     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1136     {
1137         self.nextthink = time + 1;
1138         self.cnt -= 1;
1139     }
1140         else
1141         {
1142                 if(self.cnt <= 10)
1143                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1144                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1145                 {
1146                         if(self.cnt <= 10)
1147                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1148                 }
1149                 self.nextthink = time + 1;
1150                 self.cnt -= 1;
1151         }
1152 }
1153
1154 float clientkilltime;
1155 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1156 {
1157         float killtime;
1158         float starttime;
1159         entity e;
1160
1161         if (gameover)
1162                 return;
1163
1164         killtime = autocvar_g_balance_kill_delay;
1165
1166         if(g_race_qualifying || g_cts)
1167                 killtime = 0;
1168
1169     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1170     {
1171                 remove(self.killindicator);
1172                 self.killindicator = world;
1173
1174         ClientKill_Now(); // allow instant kill in this case
1175         return;
1176     }
1177
1178         self.killindicator_teamchange = targetteam;
1179
1180     if(!self.killindicator)
1181         {
1182                 if(self.deadflag == DEAD_NO)
1183                 {
1184                         killtime = max(killtime, self.clientkill_nexttime - time);
1185                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1186                 }
1187
1188                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1189                 {
1190                         ClientKill_Now();
1191                 }
1192                 else
1193                 {
1194                         starttime = max(time, clientkilltime);
1195
1196                         self.killindicator = spawn();
1197                         self.killindicator.owner = self;
1198                         self.killindicator.scale = 0.5;
1199                         setattachment(self.killindicator, self, "");
1200                         setorigin(self.killindicator, '0 0 52');
1201                         self.killindicator.think = KillIndicator_Think;
1202                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1203                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1204                         self.killindicator.cnt = ceil(killtime);
1205                         self.killindicator.count = bound(0, ceil(killtime), 10);
1206                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1207
1208                         for(e = world; (e = find(e, classname, "body")) != world; )
1209                         {
1210                                 if(e.enemy != self)
1211                                         continue;
1212                                 e.killindicator = spawn();
1213                                 e.killindicator.owner = e;
1214                                 e.killindicator.scale = 0.5;
1215                                 setattachment(e.killindicator, e, "");
1216                                 setorigin(e.killindicator, '0 0 52');
1217                                 e.killindicator.think = KillIndicator_Think;
1218                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1219                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1220                                 e.killindicator.cnt = ceil(killtime);
1221                         }
1222                         self.lip = 0;
1223                 }
1224         }
1225         if(self.killindicator)
1226         {
1227                 if(targetteam == 0) // just die
1228                 {
1229                         self.killindicator.colormod = '0 0 0';
1230                         if(clienttype(self) == CLIENTTYPE_REAL)
1231                         if(self.killindicator.cnt > 0)
1232                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1233                 }
1234                 else if(targetteam == -1) // auto
1235                 {
1236                         self.killindicator.colormod = '0 1 0';
1237                         if(clienttype(self) == CLIENTTYPE_REAL)
1238                         if(self.killindicator.cnt > 0)
1239                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1240                 }
1241                 else if(targetteam == -2) // spectate
1242                 {
1243                         self.killindicator.colormod = '0.5 0.5 0.5';
1244                         if(clienttype(self) == CLIENTTYPE_REAL)
1245                         if(self.killindicator.cnt > 0)
1246                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1247                 }
1248                 else
1249                 {
1250                         self.killindicator.colormod = TeamColor(targetteam);
1251                         if(clienttype(self) == CLIENTTYPE_REAL)
1252                         if(self.killindicator.cnt > 0)
1253                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1254                 }
1255         }
1256
1257 }
1258
1259 void ClientKill (void)
1260 {
1261         if (gameover)
1262                 return;
1263
1264         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1265         {
1266                 // do nothing
1267         }
1268     else if(self.freezetag_frozen)
1269     {
1270         // do nothing
1271     }
1272         else
1273                 ClientKill_TeamChange(0);
1274 }
1275
1276 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1277 {
1278     e.killindicator = spawn();
1279     e.killindicator.owner = e;
1280     e.killindicator.think = KillIndicator_Think;
1281     e.killindicator.nextthink = time + (e.lip) * 0.05;
1282     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1283     e.killindicator.health = 1; // this is used to indicate that it should be silent
1284     e.lip = 0;
1285 }
1286
1287 void FixClientCvars(entity e)
1288 {
1289         // send prediction settings to the client
1290         stuffcmd(e, "\nin_bindmap 0 0\n");
1291         if(g_race || g_cts)
1292                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1293         if(autocvar_g_antilag == 3) // client side hitscan
1294                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1295         if(sv_gentle)
1296                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1297         /*
1298          * we no longer need to stuff this. Remove this comment block if you feel
1299          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1300         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1301         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1302         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1303         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1304         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1305         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1306         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1307         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1308         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1309         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1310         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1311         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1312         stuffcmd(e, "cl_movement_edgefriction 1\n");
1313          */
1314 }
1315
1316 float PlayerInIDList(entity p, string idlist)
1317 {
1318         float n, i;
1319         string s;
1320
1321         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1322         if not(p.crypto_idfp)
1323                 return 0;
1324
1325         // this function allows abbreviated player IDs too!
1326         n = tokenize_console(idlist);
1327         for(i = 0; i < n; ++i)
1328         {
1329                 s = argv(i);
1330                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1331                         return 1;
1332         }
1333
1334         return 0;
1335 }
1336
1337 /*
1338 =============
1339 ClientConnect
1340
1341 Called when a client connects to the server
1342 =============
1343 */
1344 //void ctf_clientconnect();
1345 string ColoredTeamName(float t);
1346 void DecodeLevelParms (void);
1347 //void dom_player_join_team(entity pl);
1348 void set_dom_state(entity e);
1349 void ClientConnect (void)
1350 {
1351         float t;
1352
1353         if(self.flags & FL_CLIENT)
1354         {
1355                 print("Warning: ClientConnect, but already connected!\n");
1356                 return;
1357         }
1358
1359         if(Ban_MaybeEnforceBan(self))
1360                 return;
1361
1362         DecodeLevelParms();
1363
1364 #ifdef WATERMARK
1365         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1366 #endif
1367
1368         self.classname = "player_joining";
1369
1370         self.flags = FL_CLIENT;
1371         self.version_nagtime = time + 10 + random() * 10;
1372
1373         if(player_count<0)
1374         {
1375                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1376                 player_count = 0;
1377         }
1378
1379         PlayerScore_Attach(self);
1380         ClientData_Attach();
1381         accuracy_init(self);
1382
1383         bot_clientconnect();
1384
1385         playerdemo_init();
1386
1387         anticheat_init();
1388
1389         race_PreSpawnObserver();
1390
1391         //if(g_domination)
1392         //      dom_player_join_team(self);
1393
1394         // identify the right forced team
1395         if(autocvar_g_campaign)
1396         {
1397                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1398                 {
1399                         switch(autocvar_g_campaign_forceteam)
1400                         {
1401                                 case 1: self.team_forced = COLOR_TEAM1; break;
1402                                 case 2: self.team_forced = COLOR_TEAM2; break;
1403                                 case 3: self.team_forced = COLOR_TEAM3; break;
1404                                 case 4: self.team_forced = COLOR_TEAM4; break;
1405                                 default: self.team_forced = 0;
1406                         }
1407                 }
1408         }
1409         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1410                 self.team_forced = COLOR_TEAM1;
1411         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1412                 self.team_forced = COLOR_TEAM2;
1413         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1414                 self.team_forced = COLOR_TEAM3;
1415         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1416                 self.team_forced = COLOR_TEAM4;
1417         else if(autocvar_g_forced_team_otherwise == "red")
1418                 self.team_forced = COLOR_TEAM1;
1419         else if(autocvar_g_forced_team_otherwise == "blue")
1420                 self.team_forced = COLOR_TEAM2;
1421         else if(autocvar_g_forced_team_otherwise == "yellow")
1422                 self.team_forced = COLOR_TEAM3;
1423         else if(autocvar_g_forced_team_otherwise == "pink")
1424                 self.team_forced = COLOR_TEAM4;
1425         else if(autocvar_g_forced_team_otherwise == "spectate")
1426                 self.team_forced = -1;
1427         else if(autocvar_g_forced_team_otherwise == "spectator")
1428                 self.team_forced = -1;
1429         else
1430                 self.team_forced = 0;
1431
1432         if(!teamplay)
1433                 if(self.team_forced > 0)
1434                         self.team_forced = 0;
1435
1436         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1437
1438         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1439                 self.classname = "observer";
1440         } else {
1441                 if(teamplay)
1442                 {
1443                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1444                         {
1445                                 self.classname = "player";
1446                                 campaign_bots_may_start = 1;
1447                         }
1448                         else
1449                         {
1450                                 self.classname = "observer"; // do it anyway
1451                         }
1452                 }
1453                 else
1454                 {
1455                         self.classname = "player";
1456                         campaign_bots_may_start = 1;
1457                 }
1458         }
1459
1460         self.playerid = (playerid_last = playerid_last + 1);
1461
1462         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1463
1464     if(clienttype(self) == CLIENTTYPE_BOT)
1465         PlayerStats_AddPlayer(self);
1466
1467         if(autocvar_sv_eventlog)
1468                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1469
1470         LogTeamchange(self.playerid, self.team, 1);
1471
1472         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1473
1474         self.netname_previous = strzone(self.netname);
1475
1476         bprint("^4", self.netname, "^4 connected");
1477
1478         if(self.classname != "observer" && (g_domination || g_ctf))
1479                 bprint(" and joined the ", ColoredTeamName(self.team));
1480
1481         bprint("\n");
1482
1483         stuffcmd(self, strcat(clientstuff, "\n"));
1484         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1485
1486         FixClientCvars(self);
1487
1488         // spawnfunc_waypoint sprites
1489         WaypointSprite_InitClient(self);
1490
1491         // Wazat's grappling hook
1492         SetGrappleHookBindings();
1493
1494         // get version info from player
1495         stuffcmd(self, "cmd clientversion $gameversion\n");
1496
1497         // get other cvars from player
1498         GetCvars(0);
1499
1500         // notify about available teams
1501         if(teamplay)
1502         {
1503                 CheckAllowedTeams(self);
1504                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1505                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1506         }
1507         else
1508                 stuffcmd(self, "set _teams_available 0\n");
1509
1510         if(g_arena || g_ca)
1511         {
1512                 self.classname = "observer";
1513                 if(g_arena)
1514                         Spawnqueue_Insert(self);
1515         }
1516         /*else if(g_ctf)
1517         {
1518                 ctf_clientconnect();
1519         }*/
1520
1521         attach_entcs();
1522
1523         bot_relinkplayerlist();
1524
1525         self.spectatortime = time;
1526         if(blockSpectators)
1527         {
1528                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1529         }
1530
1531         self.jointime = time;
1532         self.allowed_timeouts = autocvar_sv_timeout_number;
1533
1534         if(clienttype(self) == CLIENTTYPE_REAL)
1535         {
1536                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1537                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1538         }
1539
1540         if(g_lms)
1541         {
1542                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1543                 {
1544                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1545                         self.frags = FRAGS_SPECTATOR;
1546                 }
1547         }
1548
1549         if(!sv_foginterval && world.fog != "")
1550                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1551
1552         SoundEntity_Attach(self);
1553
1554         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1555         {
1556                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1557                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1558         }
1559         else
1560                 self.hitplotfh = -1;
1561
1562         if(g_race || g_cts) {
1563                 string rr;
1564                 if(g_cts)
1565                         rr = CTS_RECORD;
1566                 else
1567                         rr = RACE_RECORD;
1568                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1569
1570                 msg_entity = self;
1571                 race_send_recordtime(MSG_ONE);
1572                 race_send_speedaward(MSG_ONE);
1573
1574                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1575                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1576                 race_send_speedaward_alltimebest(MSG_ONE);
1577
1578                 float i;
1579                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1580                         race_SendRankings(i, 0, 0, MSG_ONE);
1581                 }
1582         }
1583         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1584                 send_CSQC_teamnagger();
1585
1586         if (g_domination)
1587                 set_dom_state(self);
1588
1589         CheatInitClient();
1590
1591         if(!autocvar_g_campaign)
1592                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1593
1594         CSQCMODEL_AUTOINIT();
1595
1596         self.model_randomizer = random();
1597
1598     if(clienttype(self) != CLIENTTYPE_REAL)
1599         return;
1600
1601     sv_notice_join();
1602 }
1603 /*
1604 =============
1605 ClientDisconnect
1606
1607 Called when a client disconnects from the server
1608 =============
1609 */
1610 .entity chatbubbleentity;
1611 void ReadyCount();
1612 void ClientDisconnect (void)
1613 {
1614         if(self.vehicle)
1615             vehicles_exit(VHEF_RELESE);
1616
1617         if not(self.flags & FL_CLIENT)
1618         {
1619                 print("Warning: ClientDisconnect without ClientConnect\n");
1620                 return;
1621         }
1622
1623         PlayerStats_AddGlobalInfo(self);
1624
1625         CheatShutdownClient();
1626
1627         if(self.hitplotfh >= 0)
1628         {
1629                 fclose(self.hitplotfh);
1630                 self.hitplotfh = -1;
1631         }
1632
1633         anticheat_report();
1634         anticheat_shutdown();
1635
1636         playerdemo_shutdown();
1637
1638         bot_clientdisconnect();
1639
1640         if(self.entcs)
1641                 detach_entcs();
1642
1643         if(autocvar_sv_eventlog)
1644                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1645         bprint ("^4",self.netname);
1646         bprint ("^4 disconnected\n");
1647
1648         SoundEntity_Detach(self);
1649
1650         DropAllRunes(self);
1651         MUTATOR_CALLHOOK(ClientDisconnect);
1652
1653         Portal_ClearAll(self);
1654
1655         RemoveGrapplingHook(self);
1656         if(self.flagcarried)
1657                 DropFlag(self.flagcarried, world, world);
1658
1659         // Here, everything has been done that requires this player to be a client.
1660
1661         self.flags &~= FL_CLIENT;
1662
1663         if (self.chatbubbleentity)
1664                 remove (self.chatbubbleentity);
1665
1666         if (self.killindicator)
1667                 remove (self.killindicator);
1668
1669         WaypointSprite_PlayerGone();
1670
1671         bot_relinkplayerlist();
1672
1673         if(g_arena)
1674         {
1675                 Spawnqueue_Unmark(self);
1676                 Spawnqueue_Remove(self);
1677         }
1678
1679         accuracy_free(self);
1680         ClientData_Detach();
1681         PlayerScore_Detach(self);
1682
1683         if(self.netname_previous)
1684                 strunzone(self.netname_previous);
1685         if(self.clientstatus)
1686                 strunzone(self.clientstatus);
1687         if(self.weaponorder_byimpulse)
1688                 strunzone(self.weaponorder_byimpulse);
1689
1690         ClearPlayerSounds();
1691
1692         if(self.personal)
1693                 remove(self.personal);
1694
1695         self.playerid = 0;
1696         ReadyCount();
1697
1698         // free cvars
1699         GetCvars(-1);
1700 }
1701
1702 .float BUTTON_CHAT;
1703 void ChatBubbleThink()
1704 {
1705         self.nextthink = time;
1706         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1707         {
1708                 if(self.owner) // but why can that ever be world?
1709                         self.owner.chatbubbleentity = world;
1710                 remove(self);
1711                 return;
1712         }
1713         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1714 #ifdef TETRIS
1715                 || self.owner.tetris_on
1716 #endif
1717         )
1718                 self.model = self.mdl;
1719         else
1720                 self.model = "";
1721 }
1722
1723 void UpdateChatBubble()
1724 {
1725         if (self.alpha < 0)
1726                 return;
1727         // spawn a chatbubble entity if needed
1728         if (!self.chatbubbleentity)
1729         {
1730                 self.chatbubbleentity = spawn();
1731                 self.chatbubbleentity.owner = self;
1732                 self.chatbubbleentity.exteriormodeltoclient = self;
1733                 self.chatbubbleentity.think = ChatBubbleThink;
1734                 self.chatbubbleentity.nextthink = time;
1735                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1736                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1737                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1738                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1739                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1740                 self.chatbubbleentity.model = "";
1741                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1742         }
1743 }
1744
1745
1746 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1747 // added to the model skins
1748 /*void UpdateColorModHack()
1749 {
1750         float c;
1751         c = self.clientcolors & 15;
1752         // LordHavoc: only bothering to support white, green, red, yellow, blue
1753              if (!teamplay) self.colormod = '0 0 0';
1754         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1755         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1756         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1757         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1758         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1759         else self.colormod = '1 1 1';
1760 }*/
1761
1762 void respawn(void)
1763 {
1764         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1765         {
1766                 self.solid = SOLID_NOT;
1767                 self.takedamage = DAMAGE_NO;
1768                 self.movetype = MOVETYPE_FLY;
1769                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1770                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1771                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1772                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1773                 if(autocvar_g_respawn_ghosts_maxtime)
1774                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1775         }
1776
1777         CopyBody(1);
1778
1779         self.effects |= EF_NODRAW; // prevent another CopyBody
1780         PutClientInServer();
1781 }
1782
1783 void play_countdown(float finished, string samp)
1784 {
1785         if(clienttype(self) == CLIENTTYPE_REAL)
1786                 if(floor(finished - time - frametime) != floor(finished - time))
1787                         if(finished - time < 6)
1788                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1789 }
1790
1791 void player_powerups (void)
1792 {
1793         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1794         olditems = self.items;
1795
1796         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1797         {
1798                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1799                 self.modelflags |= MF_ROCKET;
1800         }
1801         else
1802         {
1803                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1804                 self.modelflags &~= MF_ROCKET;
1805         }
1806
1807         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1808
1809         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1810                 return;
1811
1812         Fire_ApplyDamage(self);
1813         Fire_ApplyEffect(self);
1814
1815         if (g_minstagib)
1816         {
1817                 self.effects |= EF_FULLBRIGHT;
1818
1819                 if (self.items & IT_STRENGTH)
1820                 {
1821                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1822                         if (time > self.strength_finished)
1823                         {
1824                                 self.alpha = default_player_alpha;
1825                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1826                                 self.items &~= IT_STRENGTH;
1827                                 sprint(self, "^3Invisibility has worn off\n");
1828                         }
1829                 }
1830                 else
1831                 {
1832                         if (time < self.strength_finished)
1833                         {
1834                                 self.alpha = g_minstagib_invis_alpha;
1835                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1836                                 self.items |= IT_STRENGTH;
1837                                 sprint(self, "^3You are invisible\n");
1838                         }
1839                 }
1840
1841                 if (self.items & IT_INVINCIBLE)
1842                 {
1843                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1844                         if (time > self.invincible_finished)
1845                         {
1846                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1847                                 sprint(self, "^3Speed has worn off\n");
1848                         }
1849                 }
1850                 else
1851                 {
1852                         if (time < self.invincible_finished)
1853                         {
1854                                 self.items = self.items | IT_INVINCIBLE;
1855                                 sprint(self, "^3You are on speed\n");
1856                         }
1857                 }
1858         }
1859         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1860         {
1861                 if (self.items & IT_STRENGTH)
1862                 {
1863                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1864                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1865                         if (time > self.strength_finished)
1866                         {
1867                                 self.items = self.items - (self.items & IT_STRENGTH);
1868                                 sprint(self, "^3Strength has worn off\n");
1869                         }
1870                 }
1871                 else
1872                 {
1873                         if (time < self.strength_finished)
1874                         {
1875                                 self.items = self.items | IT_STRENGTH;
1876                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1877                         }
1878                 }
1879                 if (self.items & IT_INVINCIBLE)
1880                 {
1881                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1882                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1883                         if (time > self.invincible_finished)
1884                         {
1885                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1886                                 sprint(self, "^3Shield has worn off\n");
1887                         }
1888                 }
1889                 else
1890                 {
1891                         if (time < self.invincible_finished)
1892                         {
1893                                 self.items = self.items | IT_INVINCIBLE;
1894                                 sprint(self, "^3Shield surrounds you\n");
1895                         }
1896                 }
1897                 if (self.items & IT_SUPERWEAPON)
1898                 {
1899                         //if(W_WeaponBit(self.weapon) & WEPBIT_SUPERWEAPONS)
1900                         //      self.effects = self.effects | EF_RED;
1901                         if (!(self.weapons & WEPBIT_SUPERWEAPONS))
1902                         {
1903                                 self.superweapons_finished = 0;
1904                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1905                                 sprint(self, "^3Superweapons have been lost\n");
1906                         }
1907                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1908                         {
1909                                 // don't let them run out
1910                         }
1911                         else
1912                         {
1913                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1914                                 if (time > self.superweapons_finished)
1915                                 {
1916                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1917                                         self.weapons &~= WEPBIT_SUPERWEAPONS;
1918                                         sprint(self, "^3Superweapons have broken down\n");
1919                                 }
1920                         }
1921                 }
1922                 else if(self.weapons & WEPBIT_SUPERWEAPONS)
1923                 {
1924                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1925                         {
1926                                 self.items = self.items | IT_SUPERWEAPON;
1927                                 sprint(self, "^3You now have a superweapon\n");
1928                         }
1929                         else
1930                         {
1931                                 self.superweapons_finished = 0;
1932                                 self.weapons &~= WEPBIT_SUPERWEAPONS; // just in case
1933                         }
1934                 }
1935                 else
1936                 {
1937                         self.superweapons_finished = 0;
1938                 }
1939         }
1940
1941         if(autocvar_g_nodepthtestplayers)
1942                 self.effects = self.effects | EF_NODEPTHTEST;
1943
1944         if(autocvar_g_fullbrightplayers)
1945                 self.effects = self.effects | EF_FULLBRIGHT;
1946
1947         // midair gamemode: damage only while in the air
1948         // if in midair mode, being on ground grants temporary invulnerability
1949         // (this is so that multishot weapon don't clear the ground flag on the
1950         // first damage in the frame, leaving the player vulnerable to the
1951         // remaining hits in the same frame)
1952         if (self.flags & FL_ONGROUND)
1953         if (g_midair)
1954                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1955
1956         if (time >= game_starttime)
1957         if (time < self.spawnshieldtime)
1958                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1959
1960         MUTATOR_CALLHOOK(PlayerPowerups);
1961 }
1962
1963 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1964 {
1965         if(current > stable)
1966                 return current;
1967         else if(current > stable - 0.25) // when close enough, "snap"
1968                 return stable;
1969         else
1970                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1971 }
1972
1973 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1974 {
1975         if(current < stable)
1976                 return current;
1977         else if(current < stable + 0.25) // when close enough, "snap"
1978                 return stable;
1979         else
1980                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1981 }
1982
1983 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1984 {
1985         if(current > rotstable)
1986         {
1987                 if(rotframetime > 0)
1988                 {
1989                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1990                         current = max(rotstable, current - rotlinear * rotframetime);
1991                 }
1992         }
1993         else if(current < regenstable)
1994         {
1995                 if(regenframetime > 0)
1996                 {
1997                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1998                         current = min(regenstable, current + regenlinear * regenframetime);
1999                 }
2000         }
2001
2002         if(current > limit)
2003                 current = limit;
2004
2005         return current;
2006 }
2007
2008 void player_regen (void)
2009 {
2010         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2011         maxh = autocvar_g_balance_health_rotstable;
2012         maxa = autocvar_g_balance_armor_rotstable;
2013         maxf = autocvar_g_balance_fuel_rotstable;
2014         minh = autocvar_g_balance_health_regenstable;
2015         mina = autocvar_g_balance_armor_regenstable;
2016         minf = autocvar_g_balance_fuel_regenstable;
2017         limith = autocvar_g_balance_health_limit;
2018         limita = autocvar_g_balance_armor_limit;
2019         limitf = autocvar_g_balance_fuel_limit;
2020
2021         max_mod = regen_mod = rot_mod = limit_mod = 1;
2022
2023         if (self.runes & RUNE_REGEN)
2024         {
2025                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2026                 {
2027                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2028                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2029                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2030                 }
2031                 else
2032                 {
2033                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2034                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2035                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2036                 }
2037         }
2038         else if (self.runes & CURSE_VENOM)
2039         {
2040                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2041                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2042                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2043                 else
2044                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2045                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2046                 //if (!self.runes & RUNE_REGEN)
2047                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2048         }
2049         maxh = maxh * max_mod;
2050         //maxa = maxa * max_mod;
2051         //maxf = maxf * max_mod;
2052         minh = minh * max_mod;
2053         //mina = mina * max_mod;
2054         //minf = minf * max_mod;
2055         limith = limith * limit_mod;
2056         limita = limita * limit_mod;
2057         //limitf = limitf * limit_mod;
2058
2059         if(g_lms && g_ca)
2060                 rot_mod = 0;
2061
2062         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2063         {
2064                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2065                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2066
2067                 // if player rotted to death...  die!
2068                 if(self.health < 1)
2069                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2070         }
2071
2072         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2073                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2074 }
2075
2076 float zoomstate_set;
2077 void SetZoomState(float z)
2078 {
2079         if(z != self.zoomstate)
2080         {
2081                 self.zoomstate = z;
2082                 ClientData_Touch(self);
2083         }
2084         zoomstate_set = 1;
2085 }
2086
2087 void GetPressedKeys(void) {
2088         MUTATOR_CALLHOOK(GetPressedKeys);
2089         if (self.movement_x > 0) // get if movement keys are pressed
2090         {       // forward key pressed
2091                 self.pressedkeys |= KEY_FORWARD;
2092                 self.pressedkeys &~= KEY_BACKWARD;
2093         }
2094         else if (self.movement_x < 0)
2095         {       // backward key pressed
2096                 self.pressedkeys |= KEY_BACKWARD;
2097                 self.pressedkeys &~= KEY_FORWARD;
2098         }
2099         else
2100         {       // no x input
2101                 self.pressedkeys &~= KEY_FORWARD;
2102                 self.pressedkeys &~= KEY_BACKWARD;
2103         }
2104
2105         if (self.movement_y > 0)
2106         {       // right key pressed
2107                 self.pressedkeys |= KEY_RIGHT;
2108                 self.pressedkeys &~= KEY_LEFT;
2109         }
2110         else if (self.movement_y < 0)
2111         {       // left key pressed
2112                 self.pressedkeys |= KEY_LEFT;
2113                 self.pressedkeys &~= KEY_RIGHT;
2114         }
2115         else
2116         {       // no y input
2117                 self.pressedkeys &~= KEY_RIGHT;
2118                 self.pressedkeys &~= KEY_LEFT;
2119         }
2120
2121         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2122                 self.pressedkeys |= KEY_JUMP;
2123         else
2124                 self.pressedkeys &~= KEY_JUMP;
2125         if (self.BUTTON_CROUCH)
2126                 self.pressedkeys |= KEY_CROUCH;
2127         else
2128                 self.pressedkeys &~= KEY_CROUCH;
2129 }
2130
2131 /*
2132 ======================
2133 spectate mode routines
2134 ======================
2135 */
2136
2137 void SpectateCopy(entity spectatee) {
2138         other = spectatee;
2139         MUTATOR_CALLHOOK(SpectateCopy);
2140         self.armortype = spectatee.armortype;
2141         self.armorvalue = spectatee.armorvalue;
2142         self.ammo_cells = spectatee.ammo_cells;
2143         self.ammo_shells = spectatee.ammo_shells;
2144         self.ammo_nails = spectatee.ammo_nails;
2145         self.ammo_rockets = spectatee.ammo_rockets;
2146         self.ammo_fuel = spectatee.ammo_fuel;
2147         self.clip_load = spectatee.clip_load;
2148         self.clip_size = spectatee.clip_size;
2149         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2150         self.health = spectatee.health;
2151         self.impulse = 0;
2152         self.items = spectatee.items;
2153         self.last_pickup = spectatee.last_pickup;
2154         self.hit_time = spectatee.hit_time;
2155         self.metertime = spectatee.metertime;
2156         self.strength_finished = spectatee.strength_finished;
2157         self.invincible_finished = spectatee.invincible_finished;
2158         self.pressedkeys = spectatee.pressedkeys;
2159         self.weapons = spectatee.weapons;
2160         self.switchweapon = spectatee.switchweapon;
2161         self.switchingweapon = spectatee.switchingweapon;
2162         self.weapon = spectatee.weapon;
2163         self.nex_charge = spectatee.nex_charge;
2164         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2165         self.hagar_load = spectatee.hagar_load;
2166         self.minelayer_mines = spectatee.minelayer_mines;
2167         self.punchangle = spectatee.punchangle;
2168         self.view_ofs = spectatee.view_ofs;
2169         self.v_angle = spectatee.v_angle;
2170         self.velocity = spectatee.velocity;
2171         self.dmg_take = spectatee.dmg_take;
2172         self.dmg_save = spectatee.dmg_save;
2173         self.dmg_inflictor = spectatee.dmg_inflictor;
2174         self.angles = spectatee.v_angle;
2175         if(!self.BUTTON_USE)
2176                 self.fixangle = TRUE;
2177         setorigin(self, spectatee.origin);
2178         setsize(self, spectatee.mins, spectatee.maxs);
2179         SetZoomState(spectatee.zoomstate);
2180
2181         anticheat_spectatecopy(spectatee);
2182
2183         //self.vehicle = spectatee.vehicle;
2184
2185         self.hud = spectatee.hud;
2186         if(spectatee.vehicle)
2187     {
2188         setorigin(self, spectatee.origin);
2189         self.velocity = spectatee.vehicle.velocity;
2190         self.v_angle += spectatee.vehicle.angles;
2191         //self.v_angle_x *= -1;
2192         self.vehicle_health = spectatee.vehicle_health;
2193         self.vehicle_shield = spectatee.vehicle_shield;
2194         self.vehicle_energy = spectatee.vehicle_energy;
2195         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2196         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2197         self.vehicle_reload1 = spectatee.vehicle_reload1;
2198         self.vehicle_reload2 = spectatee.vehicle_reload2;
2199
2200         msg_entity = self;
2201         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2202         WriteEntity(MSG_ONE, spectatee);
2203         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2204     }
2205 }
2206
2207 float SpectateUpdate() {
2208         if(!self.enemy)
2209             return 0;
2210
2211         if (self == self.enemy)
2212                 return 0;
2213
2214         if(self.enemy.classname != "player")
2215                 return 0;
2216
2217         SpectateCopy(self.enemy);
2218
2219         return 1;
2220 }
2221
2222
2223 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2224 entity CA_SpectateNext(entity start) {
2225         if (start.team == self.team) {
2226                 return start;
2227         }
2228
2229         other = start;
2230         // continue from current player
2231         while(other && other.team != self.team) {
2232                 other = find(other, classname, "player");
2233         }
2234
2235         if (!other) {
2236                 // restart from begining
2237                 other = find(other, classname, "player");
2238                 while(other && other.team != self.team) {
2239                         other = find(other, classname, "player");
2240                 }
2241         }
2242
2243         return other;
2244 }
2245
2246 float SpectateNext() {
2247         other = find(self.enemy, classname, "player");
2248         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2249                 // CA and ca players when spectating enemies is forbidden
2250                 other = CA_SpectateNext(other);
2251         } else {
2252                 // other modes and ca spectators or spectating enemies is allowed
2253                 if (!other)
2254                         other = find(other, classname, "player");
2255         }
2256
2257         if (other)
2258                 self.enemy = other;
2259
2260         if(self.enemy.classname == "player") {
2261             if(self.enemy.vehicle)
2262             {
2263             msg_entity = self;
2264             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2265             WriteEntity(MSG_ONE, self.enemy);
2266             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2267             self.movetype = MOVETYPE_NONE;
2268             accuracy_resend(self);
2269             }
2270             else
2271             {
2272             msg_entity = self;
2273             WriteByte(MSG_ONE, SVC_SETVIEW);
2274             WriteEntity(MSG_ONE, self.enemy);
2275             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2276             self.movetype = MOVETYPE_NONE;
2277             accuracy_resend(self);
2278
2279             if(!SpectateUpdate())
2280                 PutObserverInServer();
2281         }
2282         return 1;
2283         } else {
2284                 return 0;
2285         }
2286 }
2287
2288 /*
2289 =============
2290 ShowRespawnCountdown()
2291
2292 Update a respawn countdown display.
2293 =============
2294 */
2295 void ShowRespawnCountdown()
2296 {
2297         float number;
2298         if(self.deadflag == DEAD_NO) // just respawned?
2299                 return;
2300         else
2301         {
2302                 number = ceil(self.respawn_time - time);
2303                 if(number <= 0)
2304                         return;
2305                 if(number <= self.respawn_countdown)
2306                 {
2307                         self.respawn_countdown = number - 1;
2308                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2309                                 AnnounceTo(self, strcat(ftos(number), ""));
2310                 }
2311         }
2312 }
2313
2314 .float prevent_join_msgtime;
2315 void LeaveSpectatorMode()
2316 {
2317         if(nJoinAllowed(self)) {
2318                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2319                         self.classname = "player";
2320
2321                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2322                                 JoinBestTeam(self, FALSE, TRUE);
2323
2324                         if(autocvar_g_campaign)
2325                                 campaign_bots_may_start = 1;
2326
2327                         PutClientInServer();
2328
2329                         if(self.classname == "player")
2330                                 bprint ("^4", self.netname, "^4 is playing now\n");
2331
2332                         if(!autocvar_g_campaign)
2333                         if (time < self.jointime + autocvar_welcome_message_time)
2334                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2335
2336                         if (self.prevent_join_msgtime)
2337                         {
2338                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2339                                 self.prevent_join_msgtime = 0;
2340                         }
2341
2342                         return;
2343                 } else {
2344                         if (g_ca && self.caplayer) {
2345                         }       // do nothing
2346                         else
2347                                 stuffcmd(self,"menu_showteamselect\n");
2348                         return;
2349                 }
2350         }
2351         else {
2352                 //player may not join because of g_maxplayers is set
2353                 if (time - self.prevent_join_msgtime > 2)
2354                 {
2355                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2356                         self.prevent_join_msgtime = time;
2357                 }
2358         }
2359 }
2360
2361 /**
2362  * Determines whether the player is allowed to join. This depends on cvar
2363  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2364  * it checks whether the number of currently playing players exceeds g_maxplayers.
2365  * @return int number of free slots for players, 0 if none
2366  */
2367 float nJoinAllowed(entity ignore) {
2368         if(!ignore)
2369         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2370         // so report 0 free slots if restricted
2371         {
2372                 if(autocvar_g_forced_team_otherwise == "spectate")
2373                         return 0;
2374                 if(autocvar_g_forced_team_otherwise == "spectator")
2375                         return 0;
2376         }
2377
2378         if(self.team_forced < 0)
2379                 return 0; // forced spectators can never join
2380
2381         // TODO simplify this
2382         entity e;
2383         float totalClients;
2384         FOR_EACH_CLIENT(e)
2385                 if(e != ignore)
2386                         totalClients += 1;
2387
2388         if (!autocvar_g_maxplayers)
2389                 return maxclients - totalClients;
2390
2391         float currentlyPlaying;
2392         FOR_EACH_REALPLAYER(e)
2393                 currentlyPlaying += 1;
2394
2395         if(currentlyPlaying < autocvar_g_maxplayers)
2396                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2397
2398         return 0;
2399 }
2400
2401 /**
2402  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2403  * g_maxplayers_spectator_blocktime seconds
2404  */
2405 void checkSpectatorBlock() {
2406         if(self.classname == "spectator" || self.classname == "observer") {
2407                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2408                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2409                         dropclient(self);
2410                 }
2411         }
2412 }
2413
2414 .float motd_actived_time; // used for both motd and campaign_message
2415 void PrintWelcomeMessage()
2416 {
2417         if (self.motd_actived_time == 0) { // is there already a message showing?
2418                 if (autocvar_g_campaign) {
2419                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2420                                 self.motd_actived_time = time;
2421                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2422                         }
2423                 } else {
2424                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2425                                 self.motd_actived_time = time;
2426                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2427                         }
2428                 }
2429         } else { // showing MOTD or campaign message
2430                 if (autocvar_g_campaign) {
2431                         if (self.BUTTON_INFO)
2432                                 self.motd_actived_time = time;
2433                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2434                                 self.motd_actived_time = 0;
2435                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2436                         }
2437                 } else {
2438                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2439                                 if (self.BUTTON_INFO)
2440                                         self.motd_actived_time = time;
2441                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2442                                         self.motd_actived_time = 0;
2443                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2444                                 }
2445                         }
2446                 }
2447         }
2448 }
2449
2450 void ObserverThink()
2451 {
2452         float prefered_movetype;
2453         if (self.flags & FL_JUMPRELEASED) {
2454                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2455                         self.flags &~= FL_JUMPRELEASED;
2456                         self.flags |= FL_SPAWNING;
2457                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2458                         self.flags &~= FL_JUMPRELEASED;
2459                         if(SpectateNext() == 1) {
2460                                 self.classname = "spectator";
2461                         }
2462                 } else {
2463                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2464                         if (self.movetype != prefered_movetype)
2465                                 self.movetype = prefered_movetype;
2466                 }
2467         } else {
2468                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2469                         self.flags |= FL_JUMPRELEASED;
2470                         if(self.flags & FL_SPAWNING)
2471                         {
2472                                 self.flags &~= FL_SPAWNING;
2473                                 LeaveSpectatorMode();
2474                                 return;
2475                         }
2476                 }
2477         }
2478
2479         PrintWelcomeMessage();
2480 }
2481
2482 void SpectatorThink()
2483 {
2484         if (self.flags & FL_JUMPRELEASED) {
2485                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2486                         self.flags &~= FL_JUMPRELEASED;
2487                         self.flags |= FL_SPAWNING;
2488                 } else if(self.BUTTON_ATCK) {
2489                         self.flags &~= FL_JUMPRELEASED;
2490                         if(SpectateNext() == 1) {
2491                                 self.classname = "spectator";
2492                         } else {
2493                                 self.classname = "observer";
2494                                 PutClientInServer();
2495                         }
2496                 } else if (self.BUTTON_ATCK2) {
2497                         self.flags &~= FL_JUMPRELEASED;
2498                         self.classname = "observer";
2499                         PutClientInServer();
2500                 } else {
2501                         if(!SpectateUpdate())
2502                                 PutObserverInServer();
2503                 }
2504         } else {
2505                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2506                         self.flags |= FL_JUMPRELEASED;
2507                         if(self.flags & FL_SPAWNING)
2508                         {
2509                                 self.flags &~= FL_SPAWNING;
2510                                 LeaveSpectatorMode();
2511                                 return;
2512                         }
2513                 }
2514                 if(!SpectateUpdate())
2515                         PutObserverInServer();
2516         }
2517
2518         PrintWelcomeMessage();
2519         self.flags |= FL_CLIENT | FL_NOTARGET;
2520 }
2521
2522 float ctf_usekey();
2523 void PlayerUseKey()
2524 {
2525         if(self.classname != "player")
2526                 return;
2527
2528         if(self.vehicle)
2529         {
2530         vehicles_exit(VHEF_NORMAL);
2531         return;
2532         }
2533
2534         // a use key was pressed; call handlers
2535         if(ctf_usekey())
2536                 return;
2537
2538         MUTATOR_CALLHOOK(PlayerUseKey);
2539 }
2540
2541 .float touchexplode_time;
2542
2543 /*
2544 =============
2545 PlayerPreThink
2546
2547 Called every frame for each client before the physics are run
2548 =============
2549 */
2550 .float usekeypressed;
2551 void() ctf_setstatus;
2552 void() nexball_setstatus;
2553 .float items_added;
2554 void PlayerPreThink (void)
2555 {
2556         WarpZone_PlayerPhysics_FixVAngle();
2557
2558         self.stat_game_starttime = game_starttime;
2559         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2560         self.stat_leadlimit = autocvar_leadlimit;
2561
2562         if(frametime)
2563         {
2564                 // physics frames: update anticheat stuff
2565                 anticheat_prethink();
2566         }
2567
2568         if(blockSpectators && frametime)
2569                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2570                 checkSpectatorBlock();
2571
2572         zoomstate_set = 0;
2573
2574         if(self.netname_previous != self.netname)
2575         {
2576                 if(autocvar_sv_eventlog)
2577                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2578                 if(self.netname_previous)
2579                         strunzone(self.netname_previous);
2580                 self.netname_previous = strzone(self.netname);
2581         }
2582
2583         // version nagging
2584         if(self.version_nagtime)
2585                 if(self.cvar_g_xonoticversion)
2586                         if(time > self.version_nagtime)
2587                         {
2588                                 // don't notify git users
2589                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2590                                 {
2591                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2592                                         {
2593                                                 // notify release users if connecting to git
2594                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2595                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2596                                         }
2597                                         else
2598                                         {
2599                                                 float r;
2600                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2601                                                 if(r < 0)
2602                                                 {
2603                                                         // give users new version
2604                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2605                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2606                                                 }
2607                                                 else if(r > 0)
2608                                                 {
2609                                                         // notify users about old server version
2610                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2611                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2612                                                 }
2613                                         }
2614                                 }
2615                                 self.version_nagtime = 0;
2616                         }
2617
2618         // GOD MODE info
2619         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2620         {
2621                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2622                 self.max_armorvalue = 0;
2623         }
2624
2625 #ifdef TETRIS
2626         if (TetrisPreFrame())
2627                 return;
2628 #endif
2629
2630         MUTATOR_CALLHOOK(PlayerPreThink);
2631
2632         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2633         {
2634                 if(self.BUTTON_USE && !self.usekeypressed)
2635                         PlayerUseKey();
2636                 self.usekeypressed = self.BUTTON_USE;
2637         }
2638
2639         PrintWelcomeMessage();
2640
2641         if(self.classname == "player") {
2642 //              if(self.netname == "Wazat")
2643 //                      bprint(self.classname, "\n");
2644
2645                 CheckRules_Player();
2646
2647                 if (intermission_running)
2648                 {
2649                         IntermissionThink ();   // otherwise a button could be missed between
2650                         return;                                 // the think tics
2651                 }
2652
2653                 //don't allow the player to turn around while game is paused!
2654                 if(timeout_status == TIMEOUT_ACTIVE) {
2655                         // FIXME turn this into CSQC stuff
2656                         self.v_angle = self.lastV_angle;
2657                         self.angles = self.lastV_angle;
2658                         self.fixangle = TRUE;
2659                 }
2660
2661                 if(frametime)
2662                 {
2663 #ifndef NO_LEGACY_NETWORKING
2664                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2665 #endif
2666
2667                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2668                         {
2669                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2670                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2671                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2672
2673                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2674                                 {
2675                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2676                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2677                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2678                                 }
2679                         }
2680                         else
2681                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2682
2683                         player_powerups();
2684                 }
2685
2686                 if (g_minstagib)
2687                         minstagib_ammocheck();
2688
2689                 if (self.deadflag != DEAD_NO)
2690                 {
2691                         float button_pressed, force_respawn;
2692                         if(self.personal && g_race_qualifying)
2693                         {
2694                                 if(time > self.respawn_time)
2695                                 {
2696                                         self.respawn_time = time + 1; // only retry once a second
2697                                         respawn();
2698                                         self.impulse = 141;
2699                                 }
2700                         }
2701                         else
2702                         {
2703                                 if(frametime)
2704                                         player_anim();
2705                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2706                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2707                                 if (self.deadflag == DEAD_DYING)
2708                                 {
2709                                         if(force_respawn)
2710                                                 self.deadflag = DEAD_RESPAWNING;
2711                                         else if(!button_pressed)
2712                                                 self.deadflag = DEAD_DEAD;
2713                                 }
2714                                 else if (self.deadflag == DEAD_DEAD)
2715                                 {
2716                                         if(button_pressed)
2717                                                 self.deadflag = DEAD_RESPAWNABLE;
2718                                 }
2719                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2720                                 {
2721                                         if(!button_pressed)
2722                                                 self.deadflag = DEAD_RESPAWNING;
2723                                 }
2724                                 else if (self.deadflag == DEAD_RESPAWNING)
2725                                 {
2726                                         if(time > self.respawn_time)
2727                                         {
2728                                                 self.respawn_time = time + 1; // only retry once a second
2729                                                 respawn();
2730                                         }
2731                                 }
2732                                 ShowRespawnCountdown();
2733                         }
2734                         return;
2735                 }
2736                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2737                 // so (self.deadflag == DEAD_NO) is always true in the code below
2738
2739                 if(g_touchexplode)
2740                 if(time > self.touchexplode_time)
2741                 if(self.classname == "player")
2742                 if(self.deadflag == DEAD_NO)
2743                 if not(IS_INDEPENDENT_PLAYER(self))
2744                 FOR_EACH_PLAYER(other) if(self != other)
2745                 {
2746                         if(time > other.touchexplode_time)
2747                         if(other.deadflag == DEAD_NO)
2748                         if not(IS_INDEPENDENT_PLAYER(other))
2749                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2750                         {
2751                                 PlayerTouchExplode(self, other);
2752                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2753                         }
2754                 }
2755
2756                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2757                 {
2758                         vector dist;
2759
2760                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2761                         dist = self.prevorigin - self.origin;
2762                         dist_z = 0;
2763                         self.lms_traveled_distance += fabs(vlen(dist));
2764
2765                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2766                         {
2767                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2768                                 self.lms_traveled_distance = 0;
2769                         }
2770
2771                         if(time > self.lms_nextcheck)
2772                         {
2773                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2774                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2775                                 {
2776                                         centerprint(self, autocvar_g_lms_campcheck_message);
2777                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2778                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2779                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2780                                 }
2781                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2782                                 self.lms_traveled_distance = 0;
2783                         }
2784                 }
2785
2786                 self.prevorigin = self.origin;
2787
2788                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x) // prevent crouching if using melee attack
2789                 {
2790                         if (!self.crouch)
2791                         {
2792                                 self.crouch = TRUE;
2793                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2794                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2795                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2796                         }
2797                 }
2798                 else
2799                 {
2800                         if (self.crouch)
2801                         {
2802                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2803                                 if (!trace_startsolid)
2804                                 {
2805                                         self.crouch = FALSE;
2806                                         self.view_ofs = PL_VIEW_OFS;
2807                                         setsize (self, PL_MIN, PL_MAX);
2808                                 }
2809                         }
2810                 }
2811
2812                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2813                 {
2814                         if(self.bloodloss_timer < time)
2815                         {
2816                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2817                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2818                         }
2819                 }
2820
2821                 FixPlayermodel();
2822
2823                 GrapplingHookFrame();
2824
2825                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2826                 //if(frametime)
2827                 {
2828                         self.items &~= self.items_added;
2829
2830                         W_WeaponFrame();
2831
2832                         self.items_added = 0;
2833                         if(self.items & IT_JETPACK)
2834                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2835                                         self.items_added |= IT_FUEL;
2836
2837                         self.items |= self.items_added;
2838                 }
2839
2840                 player_regen();
2841
2842                 // rot nex charge to the charge limit
2843                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2844                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2845
2846                 if(frametime)
2847                         player_anim();
2848
2849                 if(g_ctf)
2850                         ctf_setstatus();
2851
2852                 if(g_nexball)
2853                         nexball_setstatus();
2854
2855                 // secret status
2856                 secrets_setstatus();
2857
2858                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2859
2860                 //self.angles_y=self.v_angle_y + 90;   // temp
2861         } else if(gameover) {
2862                 if (intermission_running)
2863                         IntermissionThink ();   // otherwise a button could be missed between
2864                 return;
2865         } else if(self.classname == "observer") {
2866                 ObserverThink();
2867         } else if(self.classname == "spectator") {
2868                 SpectatorThink();
2869         }
2870
2871         if(!zoomstate_set)
2872                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2873
2874         float oldspectatee_status;
2875         oldspectatee_status = self.spectatee_status;
2876         if(self.classname == "spectator")
2877                 self.spectatee_status = num_for_edict(self.enemy);
2878         else if(self.classname == "observer")
2879                 self.spectatee_status = num_for_edict(self);
2880         else
2881                 self.spectatee_status = 0;
2882         if(self.spectatee_status != oldspectatee_status)
2883         {
2884                 ClientData_Touch(self);
2885                 if(g_race || g_cts)
2886                         race_InitSpectator();
2887         }
2888
2889         if(self.teamkill_soundtime)
2890         if(time > self.teamkill_soundtime)
2891         {
2892                 self.teamkill_soundtime = 0;
2893
2894                 entity oldpusher, oldself;
2895
2896                 oldself = self; self = self.teamkill_soundsource;
2897                 oldpusher = self.pusher; self.pusher = oldself;
2898
2899                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2900
2901                 self.pusher = oldpusher;
2902                 self = oldself;
2903         }
2904
2905         if(self.taunt_soundtime)
2906         if(time > self.taunt_soundtime)
2907         {
2908                 self.taunt_soundtime = 0;
2909                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2910         }
2911
2912         target_voicescript_next(self);
2913
2914         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2915         if(!self.weapon)
2916                 self.clip_load = self.clip_size = 0;
2917 }
2918
2919 float isInvisibleString(string s)
2920 {
2921         float i, n, c;
2922         s = strdecolorize(s);
2923         for((i = 0), (n = strlen(s)); i < n; ++i)
2924         {
2925                 c = str2chr(s, i);
2926                 switch(c)
2927                 {
2928                         case 0:
2929                         case 32: // space
2930                                 break;
2931                         case 192: // charmap space
2932                                 if (!autocvar_utf8_enable)
2933                                         break;
2934                                 return FALSE;
2935                         case 160: // space in unicode fonts
2936                         case 0xE000 + 192: // utf8 charmap space
2937                                 if (autocvar_utf8_enable)
2938                                         break;
2939                         default:
2940                                 return FALSE;
2941                 }
2942         }
2943         return TRUE;
2944 }
2945
2946 /*
2947 =============
2948 PlayerPostThink
2949
2950 Called every frame for each client after the physics are run
2951 =============
2952 */
2953 .float idlekick_lasttimeleft;
2954 .entity showheadshotbbox;
2955 void showheadshotbbox_think()
2956 {
2957         if(self.owner.showheadshotbbox != self)
2958         {
2959                 remove(self);
2960                 return;
2961         }
2962         self.nextthink = time;
2963         setorigin(self, self.owner.origin);
2964         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2965 }
2966 void PlayerPostThink (void)
2967 {
2968         // Savage: Check for nameless players
2969         if (isInvisibleString(self.netname)) {
2970                 self.netname = "Player";
2971                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2972         }
2973
2974         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2975         {
2976                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2977                 {
2978                         if(self.idlekick_lasttimeleft)
2979                         {
2980                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2981                                 self.idlekick_lasttimeleft = 0;
2982                         }
2983                 }
2984                 else
2985                 {
2986                         float timeleft;
2987                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2988                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2989                         {
2990                                 if(!self.idlekick_lasttimeleft)
2991                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
2992                         }
2993                         if(timeleft <= 0)
2994                         {
2995                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
2996                                 AnnounceTo(self, "terminated");
2997                                 dropclient(self);
2998                                 return;
2999                         }
3000                         else if(timeleft <= 10)
3001                         {
3002                                 if(timeleft != self.idlekick_lasttimeleft)
3003                                         AnnounceTo(self, ftos(timeleft));
3004                                 self.idlekick_lasttimeleft = timeleft;
3005                         }
3006                 }
3007         }
3008
3009 #ifdef TETRIS
3010         if(self.impulse == 100)
3011                 ImpulseCommands();
3012         if (!TetrisPostFrame())
3013         {
3014 #endif
3015
3016         CheatFrame();
3017
3018         //CheckPlayerJump();
3019
3020         if(self.classname == "player") {
3021                 CheckRules_Player();
3022                 UpdateChatBubble();
3023                 if (self.impulse)
3024                         ImpulseCommands();
3025                 if (intermission_running)
3026                         return;         // intermission or finale
3027                 GetPressedKeys();
3028         } else if (self.classname == "observer") {
3029                 //do nothing
3030         } else if (self.classname == "spectator") {
3031                 //do nothing
3032         }
3033
3034 #ifdef TETRIS
3035         }
3036 #endif
3037
3038         /*
3039         float i;
3040         for(i = 0; i < 1000; ++i)
3041         {
3042                 vector end;
3043                 end = self.origin + '0 0 1024' + 512 * randomvec();
3044                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3045                 if(trace_fraction < 1)
3046                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3047                 {
3048                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3049                         break;
3050                 }
3051         }
3052         */
3053
3054         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3055
3056         if(self.waypointsprite_attachedforcarrier)
3057                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3058
3059         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3060         {
3061                 if(!self.showheadshotbbox)
3062                 {
3063                         self.showheadshotbbox = spawn();
3064                         self.showheadshotbbox.classname = "headshotbbox";
3065                         self.showheadshotbbox.owner = self;
3066                         self.showheadshotbbox.think = showheadshotbbox_think;
3067                         self.showheadshotbbox.nextthink = time;
3068                         self = self.showheadshotbbox;
3069                         self.think();
3070                         self = self.owner;
3071                 }
3072         }
3073         else
3074         {
3075                 if(self.showheadshotbbox)
3076                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3077                 remove(self.showheadshotbbox);
3078         }
3079
3080         playerdemo_write();
3081
3082         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3083         {
3084                 if(!self.stored_netname)
3085                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3086                 if(self.stored_netname != self.netname)
3087                 {
3088                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3089                         strunzone(self.stored_netname);
3090                         self.stored_netname = strzone(self.netname);
3091                 }
3092         }
3093
3094         /*
3095         if(g_race)
3096                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3097         */
3098
3099         CSQCMODEL_AUTOUPDATE();
3100 }