qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teams_matter)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck)
 136         if(spot.team != teamcheck)
 137                 return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         teamcheck = 0;
 329
 330         if(!anypoint && have_team_spawns > 0)
 331                 teamcheck = self.team;
 332
 333         // get the list of players
 334         playerlist = findchain(classname, "player");
 335         // get the entire list of spots
 336         firstspot = findchain(classname, "info_player_deathmatch");
 337         // filter out the bad ones
 338         // (note this returns the original list if none survived)
 339         if(anypoint)
 340         {
 341                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 342         }
 343         else
 344         {
 345                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 346                 if(!firstspot_new)
 347                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 348                 firstspot = firstspot_new;
 349
 350                 // there is 50/50 chance of choosing a random spot or the furthest spot
 351                 // (this means that roughly every other spawn will be furthest, so you
 352                 // usually won't get fragged at spawn twice in a row)
 353                 if (arena_roundbased && !g_ca)
 354                 {
 355                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 356                         if(firstspot_new)
 357                                 firstspot = firstspot_new;
 358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 359                 }
 360                 else if (random() > autocvar_g_spawn_furthest)
 361                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362                 else
 363                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 364         }
 365
 366         if(autocvar_spawn_debugview)
 367         {
 368                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 369
 370                 entity e;
 371                 if(teamcheck)
 372                         for(e = firstspot; e; e = e.chain)
 373                                 if(e.team != teamcheck)
 374                                         error("invalid spawn found");
 375         }
 376
 377         if (!spot)
 378         {
 379                 if(autocvar_spawn_debug)
 380                         GotoNextMap();
 381                 else
 382                 {
 383                         if(some_spawn_has_been_used)
 384                                 return world; // team can't spawn any more, because of actions of other team
 385                         else
 386                                 error("Cannot find a spawn point - please fix the map!");
 387                 }
 388         }
 389
 390         return spot;
 391 }
 392
 393 /*
 394 =============
 395 CheckPlayerModel
 396
 397 Checks if the argument string can be a valid playermodel.
 398 Returns a valid one in doubt.
 399 =============
 400 */
 401 string FallbackPlayerModel;
 402 string CheckPlayerModel(string plyermodel) {
 403         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 404         {
 405                 // note: we cannot summon Don Strunzone here, some player may
 406                 // still have the model string set. In case anyone manages how
 407                 // to change a cvar default, we'll have a small leak here.
 408                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 409         }
 410         if(strlen(plyermodel) < 4)
 411                 return FallbackPlayerModel;
 412         if( substring(plyermodel,0,14) != "models/player/")
 413                 return FallbackPlayerModel;
 414         else if(autocvar_sv_servermodelsonly)
 415         {
 416                 if(substring(plyermodel,-4,4) != ".zym")
 417                 if(substring(plyermodel,-4,4) != ".dpm")
 418                 if(substring(plyermodel,-4,4) != ".iqm")
 419                 if(substring(plyermodel,-4,4) != ".md3")
 420                 if(substring(plyermodel,-4,4) != ".psk")
 421                         return FallbackPlayerModel;
 422                 // forbid the LOD models
 423                 if(substring(plyermodel, -9,5) == "_lod1")
 424                         return FallbackPlayerModel;
 425                 if(substring(plyermodel, -9,5) == "_lod2")
 426                         return FallbackPlayerModel;
 427                 if(plyermodel != strtolower(plyermodel))
 428                         return FallbackPlayerModel;
 429                 if(!fexists(plyermodel))
 430                         return FallbackPlayerModel;
 431         }
 432         return plyermodel;
 433 }
 434
 435 /*
 436 =============
 437 Client_customizeentityforclient
 438
 439 LOD reduction
 440 =============
 441 */
 442 void Client_uncustomizeentityforclient()
 443 {
 444         if(self.modelindex == 0) // no need to uncustomize then
 445                 return;
 446         self.modelindex = self.modelindex_lod0;
 447         self.skin = self.skinindex;
 448 }
 449
 450 float Client_customizeentityforclient()
 451 {
 452         entity modelsource;
 453
 454         if(self.modelindex == 0)
 455                 return TRUE;
 456
 457         // forcemodel stuff
 458
 459 #ifdef PROFILING
 460         float t0;
 461         t0 = gettime(GETTIME_HIRES); // reference
 462 #endif
 463
 464         modelsource = self;
 465
 466 #ifdef ALLOW_FORCEMODELS
 467         if(other.cvar_cl_forceplayermodelsfromxonotic)
 468                 if not(self.modelindex_lod0_from_xonotic)
 469                         modelsource = other;
 470         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 471                 modelsource = other;
 472 #endif
 473
 474         self.skin = modelsource.skinindex;
 475
 476 #if 0
 477         if(modelsource == self)
 478                 self.skin = modelsource.skinindex;
 479         else
 480                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 481 #endif
 482
 483         // self: me
 484         // other: the player viewing me
 485         float distance;
 486         float f;
 487
 488         if(other.cvar_cl_playerdetailreduction <= 0)
 489         {
 490                 if(other.cvar_cl_playerdetailreduction <= -2)
 491                         self.modelindex = modelsource.modelindex_lod2;
 492                 else if(other.cvar_cl_playerdetailreduction <= -1)
 493                         self.modelindex = modelsource.modelindex_lod1;
 494                 else
 495                         self.modelindex = modelsource.modelindex_lod0;
 496         }
 497         else
 498         {
 499                 distance = vlen(self.origin - other.origin);
 500                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 501                 if(f > sv_loddistance2)
 502                         self.modelindex = modelsource.modelindex_lod2;
 503                 else if(f > sv_loddistance1)
 504                         self.modelindex = modelsource.modelindex_lod1;
 505                 else
 506                         self.modelindex = modelsource.modelindex_lod0;
 507         }
 508
 509 #ifdef PROFILING
 510         float t1;
 511         t1 = gettime(GETTIME_HIRES); // reference
 512         client_cefc_accumulator += (t1 - t0);
 513 #endif
 514
 515         return TRUE;
 516 }
 517
 518 void setmodel_lod(entity e, string modelname)
 519 {
 520         string s;
 521
 522         if(sv_loddistance1)
 523         {
 524                 // FIXME: this only supports 3-letter extensions
 525                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 526                 if(fexists(s))
 527                 {
 528                         setmodel(e, s); // players have high precision
 529                         self.modelindex_lod1 = self.modelindex;
 530                 }
 531                 else
 532                         self.modelindex_lod1 = -1;
 533
 534                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 535                 if(fexists(s))
 536                 {
 537                         setmodel(e, s); // players have high precision
 538                         self.modelindex_lod2 = self.modelindex;
 539                 }
 540                 else
 541                         self.modelindex_lod2 = -1;
 542
 543                 precache_model(modelname);
 544                 setmodel(e, modelname); // players have high precision
 545                 self.modelindex_lod0 = self.modelindex;
 546
 547                 if(self.modelindex_lod1 < 0)
 548                         self.modelindex_lod1 = self.modelindex;
 549
 550                 if(self.modelindex_lod2 < 0)
 551                         self.modelindex_lod2 = self.modelindex;
 552         }
 553         else
 554         {
 555                 precache_model(modelname);
 556                 setmodel(e, modelname); // players have high precision
 557                 self.modelindex_lod0 = self.modelindex;
 558                         // save it for possible player model forcing
 559         }
 560
 561         s = whichpack(self.model);
 562         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 563
 564         player_setupanimsformodel();
 565         UpdatePlayerSounds();
 566 }
 567
 568 /*
 569 =============
 570 PutObserverInServer
 571
 572 putting a client as observer in the server
 573 =============
 574 */
 575 void FixPlayermodel();
 576 void PutObserverInServer (void)
 577 {
 578         entity  spot;
 579
 580         race_PreSpawnObserver();
 581
 582         spot = SelectSpawnPoint (TRUE);
 583         if(!spot)
 584                 error("No spawnpoints for observers?!?\n");
 585         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 586
 587         if(clienttype(self) == CLIENTTYPE_REAL)
 588         {
 589                 msg_entity = self;
 590                 WriteByte(MSG_ONE, SVC_SETVIEW);
 591                 WriteEntity(MSG_ONE, self);
 592         }
 593
 594         DropAllRunes(self);
 595         MUTATOR_CALLHOOK(MakePlayerObserver);
 596
 597         Portal_ClearAll(self);
 598
 599         if(self.alivetime)
 600         {
 601                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 602                 self.alivetime = 0;
 603         }
 604
 605         if(self.flagcarried)
 606                 DropFlag(self.flagcarried, world, world);
 607
 608         if(self.ballcarried && g_nexball)
 609                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 610
 611         WaypointSprite_PlayerDead();
 612
 613         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 614                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 615
 616         if(self.killcount != -666) {
 617                 if(g_lms) {
 618                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 619                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 620                         else
 621                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 622                 } else
 623                         bprint ("^4", self.netname, "^4 is spectating now\n");
 624
 625                 if(self.just_joined == FALSE) {
 626                         LogTeamchange(self.playerid, -1, 4);
 627                 } else
 628                         self.just_joined = FALSE;
 629         }
 630
 631         PlayerScore_Clear(self); // clear scores when needed
 632
 633         accuracy_resend(self);
 634
 635         self.spectatortime = time;
 636
 637         self.classname = "observer";
 638         self.iscreature = FALSE;
 639         self.health = -666;
 640         self.takedamage = DAMAGE_NO;
 641         self.solid = SOLID_NOT;
 642         self.movetype = MOVETYPE_NOCLIP;
 643         self.flags = FL_CLIENT | FL_NOTARGET;
 644         self.armorvalue = 666;
 645         self.effects = 0;
 646         self.armorvalue = autocvar_g_balance_armor_start;
 647         self.pauserotarmor_finished = 0;
 648         self.pauserothealth_finished = 0;
 649         self.pauseregen_finished = 0;
 650         self.damageforcescale = 0;
 651         self.death_time = 0;
 652         self.dead_frame = 0;
 653         self.alpha = 0;
 654         self.scale = 0;
 655         self.fade_time = 0;
 656         self.pain_frame = 0;
 657         self.pain_finished = 0;
 658         self.strength_finished = 0;
 659         self.invincible_finished = 0;
 660         self.pushltime = 0;
 661         self.think = SUB_Null;
 662         self.nextthink = 0;
 663         self.hook_time = 0;
 664         self.runes = 0;
 665         self.deadflag = DEAD_NO;
 666         self.angles = spot.angles;
 667         self.angles_z = 0;
 668         self.fixangle = TRUE;
 669         self.crouch = FALSE;
 670
 671         self.view_ofs = PL_VIEW_OFS;
 672         setorigin (self, spot.origin);
 673         setsize (self, '0 0 0', '0 0 0');
 674         self.prevorigin = self.origin;
 675         self.items = 0;
 676         self.weapons = 0;
 677         self.model = "";
 678         FixPlayermodel();
 679         self.model = "";
 680         self.modelindex = 0;
 681         self.weapon = 0;
 682         self.weaponmodel = "";
 683         self.weaponentity = world;
 684         self.exteriorweaponentity = world;
 685         self.killcount = -666;
 686         self.velocity = '0 0 0';
 687         self.avelocity = '0 0 0';
 688         self.punchangle = '0 0 0';
 689         self.punchvector = '0 0 0';
 690         self.oldvelocity = self.velocity;
 691         self.fire_endtime = -1;
 692
 693         if(sv_loddistance1)
 694                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 695
 696         if(g_arena)
 697         {
 698                 if(self.version_mismatch)
 699                 {
 700                         Spawnqueue_Unmark(self);
 701                         Spawnqueue_Remove(self);
 702                 }
 703                 else
 704                 {
 705                         Spawnqueue_Insert(self);
 706                 }
 707         }
 708         else if(g_lms)
 709         {
 710                 // Only if the player cannot play at all
 711                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 712                         self.frags = FRAGS_SPECTATOR;
 713                 else
 714                         self.frags = FRAGS_LMS_LOSER;
 715         }
 716         else
 717                 self.frags = FRAGS_SPECTATOR;
 718 }
 719
 720 void FixPlayermodel()
 721 {
 722         local string defaultmodel;
 723         local float defaultskin, chmdl, oldskin;
 724         local vector m1, m2;
 725
 726         defaultmodel = "";
 727
 728         if(autocvar_sv_defaultcharacter == 1) {
 729                 defaultskin = 0;
 730
 731                 if(teams_matter)
 732                 {
 733                         string s;
 734                         s = Team_ColorNameLowerCase(self.team);
 735                         if(s != "neutral")
 736                         {
 737                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 738                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 739                         }
 740                 }
 741
 742                 if(defaultmodel == "")
 743                 {
 744                         defaultmodel = autocvar_sv_defaultplayermodel;
 745                         defaultskin = autocvar_sv_defaultplayerskin;
 746                 }
 747         }
 748
 749         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 750         {
 751                 if(self.model != "")
 752                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 753                 self.model = ""; // force the != checks to return true
 754         }
 755
 756         if(defaultmodel != "")
 757         {
 758                 if (defaultmodel != self.model)
 759                 {
 760                         m1 = self.mins;
 761                         m2 = self.maxs;
 762                         setmodel_lod (self, defaultmodel);
 763                         setsize (self, m1, m2);
 764                         chmdl = TRUE;
 765                 }
 766
 767                 oldskin = self.skinindex;
 768                 self.skinindex = defaultskin;
 769         } else {
 770                 if (self.playermodel != self.model || self.playermodel == "")
 771                 {
 772                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 773                         m1 = self.mins;
 774                         m2 = self.maxs;
 775                         setmodel_lod (self, self.playermodel);
 776                         setsize (self, m1, m2);
 777                         chmdl = TRUE;
 778                 }
 779
 780                 oldskin = self.skinindex;
 781                 self.skinindex = stof(self.playerskin);
 782         }
 783
 784         if(chmdl || oldskin != self.skinindex)
 785                 self.species = player_getspecies(); // model or skin has changed
 786
 787         if(!teams_matter)
 788                 if(strlen(autocvar_sv_defaultplayercolors))
 789                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 790                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 791 }
 792
 793 void PlayerTouchExplode(entity p1, entity p2)
 794 {
 795         vector org;
 796         org = (p1.origin + p2.origin) * 0.5;
 797         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 798
 799         te_explosion(org);
 800
 801         entity e;
 802         e = spawn();
 803         setorigin(e, org);
 804         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 805         remove(e);
 806 }
 807
 808 /*
 809 =============
 810 PutClientInServer
 811
 812 Called when a client spawns in the server
 813 =============
 814 */
 815 //void() ctf_playerchanged;
 816 void PutClientInServer (void)
 817 {
 818         if(clienttype(self) == CLIENTTYPE_BOT)
 819         {
 820                 self.classname = "player";
 821         }
 822         else if(clienttype(self) == CLIENTTYPE_REAL)
 823         {
 824                 msg_entity = self;
 825                 WriteByte(MSG_ONE, SVC_SETVIEW);
 826                 WriteEntity(MSG_ONE, self);
 827         }
 828
 829         // player is dead and becomes observer
 830         // FIXME fix LMS scoring for new system
 831         if(g_lms)
 832         {
 833                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 834                         self.classname = "observer";
 835         }
 836
 837         if(g_arena || (g_ca && !allowed_to_spawn))
 838         if(!self.spawned)
 839                 self.classname = "observer";
 840
 841         if(gameover)
 842                 self.classname = "observer";
 843
 844         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 845                 entity spot, oldself;
 846                 float j;
 847
 848                 accuracy_resend(self);
 849
 850                 if(self.team < 0)
 851                         JoinBestTeam(self, FALSE, TRUE);
 852
 853                 race_PreSpawn();
 854
 855                 spot = SelectSpawnPoint (FALSE);
 856                 if(!spot)
 857                 {
 858                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 859                         return; // spawn failed
 860                 }
 861
 862                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 863
 864                 self.classname = "player";
 865                 self.wasplayer = TRUE;
 866                 self.iscreature = TRUE;
 867                 self.movetype = MOVETYPE_WALK;
 868                 self.solid = SOLID_SLIDEBOX;
 869                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 870                 if(autocvar_g_playerclip_collisions)
 871                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 872                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 873                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 874                 self.frags = FRAGS_PLAYER;
 875                 if(independent_players)
 876                         MAKE_INDEPENDENT_PLAYER(self);
 877                 self.flags = FL_CLIENT;
 878                 self.takedamage = DAMAGE_AIM;
 879                 if(g_minstagib)
 880                         self.effects = EF_FULLBRIGHT;
 881                 else
 882                         self.effects = 0;
 883                 self.air_finished = time + 12;
 884                 self.dmg = 2;
 885                 if(autocvar_g_balance_nex_charge)
 886                 {
 887                         if(autocvar_g_balance_nex_secondary_chargepool)
 888                                 self.nex_chargepool_ammo = 1;
 889                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 890                 }
 891
 892                 if(inWarmupStage)
 893                 {
 894                         self.ammo_shells = warmup_start_ammo_shells;
 895                         self.ammo_nails = warmup_start_ammo_nails;
 896                         self.ammo_rockets = warmup_start_ammo_rockets;
 897                         self.ammo_cells = warmup_start_ammo_cells;
 898                         self.ammo_fuel = warmup_start_ammo_fuel;
 899                         self.health = warmup_start_health;
 900                         self.armorvalue = warmup_start_armorvalue;
 901                         self.weapons = warmup_start_weapons;
 902                 }
 903                 else
 904                 {
 905                         self.ammo_shells = start_ammo_shells;
 906                         self.ammo_nails = start_ammo_nails;
 907                         self.ammo_rockets = start_ammo_rockets;
 908                         self.ammo_cells = start_ammo_cells;
 909                         self.ammo_fuel = start_ammo_fuel;
 910                         self.health = start_health;
 911                         self.armorvalue = start_armorvalue;
 912                         self.weapons = start_weapons;
 913                 }
 914
 915                 if(g_weaponarena_random)
 916                 {
 917                         if(g_weaponarena_random_with_laser)
 918                                 self.weapons &~= WEPBIT_LASER;
 919                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 920                         if(g_weaponarena_random_with_laser)
 921                                 self.weapons |= WEPBIT_LASER;
 922                 }
 923
 924                 self.items = start_items;
 925                 self.jump_interval = time;
 926
 927                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 928                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 929                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 930                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 931                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 932                 //extend the pause of rotting if client was reset at the beginning of the countdown
 933                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 934                         self.spawnshieldtime += game_starttime - time;
 935                         self.pauserotarmor_finished += game_starttime - time;
 936                         self.pauserothealth_finished += game_starttime - time;
 937                         self.pauseregen_finished += game_starttime - time;
 938                 }
 939                 self.damageforcescale = 2;
 940                 self.death_time = 0;
 941                 self.dead_frame = 0;
 942                 self.alpha = 0;
 943                 self.scale = 0;
 944                 self.fade_time = 0;
 945                 self.pain_frame = 0;
 946                 self.pain_finished = 0;
 947                 self.strength_finished = 0;
 948                 self.invincible_finished = 0;
 949                 self.pushltime = 0;
 950                 // players have no think function
 951                 self.think = SUB_Null;
 952                 self.nextthink = 0;
 953                 self.hook_time = 0;
 954                 self.dmg_team = 0;
 955                 self.ballistics_density = autocvar_g_ballistics_density_player;
 956
 957                 self.metertime = 0;
 958
 959                 self.runes = 0;
 960
 961                 self.deadflag = DEAD_NO;
 962
 963                 self.angles = spot.angles;
 964
 965                 self.angles_z = 0; // never spawn tilted even if the spot says to
 966                 self.fixangle = TRUE; // turn this way immediately
 967                 self.velocity = '0 0 0';
 968                 self.avelocity = '0 0 0';
 969                 self.punchangle = '0 0 0';
 970                 self.punchvector = '0 0 0';
 971                 self.oldvelocity = self.velocity;
 972                 self.fire_endtime = -1;
 973
 974                 msg_entity = self;
 975                 WRITESPECTATABLE_MSG_ONE({
 976                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 977                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 978                 });
 979
 980                 if(sv_loddistance1)
 981                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 982
 983                 self.model = "";
 984                 FixPlayermodel();
 985
 986                 self.crouch = FALSE;
 987                 self.view_ofs = PL_VIEW_OFS;
 988                 setsize (self, PL_MIN, PL_MAX);
 989                 self.spawnorigin = spot.origin;
 990                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 991                 // don't reset back to last position, even if new position is stuck in solid
 992                 self.oldorigin = self.origin;
 993                 self.prevorigin = self.origin;
 994                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 995
 996                 if(g_arena)
 997                 {
 998                         Spawnqueue_Remove(self);
 999                         Spawnqueue_Mark(self);
1000                 }
1001
1002                 else if(g_ca)
1003                         self.caplayer = 1;
1004
1005                 self.event_damage = PlayerDamage;
1006
1007                 self.bot_attack = TRUE;
1008
1009                 self.statdraintime = time + 5;
1010                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1011
1012                 if(self.killcount == -666) {
1013                         PlayerScore_Clear(self);
1014                         self.killcount = 0;
1015                 }
1016
1017                 self.cnt = WEP_LASER;
1018
1019                 CL_SpawnWeaponentity();
1020                 self.alpha = default_player_alpha;
1021                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1022                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1023
1024                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1025                 self.lms_traveled_distance = 0;
1026                 self.speedrunning = FALSE;
1027
1028                 race_PostSpawn(spot);
1029
1030                 if(autocvar_spawn_debug)
1031                 {
1032                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1033                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1034                 }
1035
1036                 //stuffcmd(self, "chase_active 0");
1037                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1038
1039                 if (autocvar_g_spawnsound)
1040                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1041
1042                 if(g_assault) {
1043                         if(self.team == assault_attacker_team)
1044                                 centerprint(self, "You are attacking!");
1045                         else
1046                                 centerprint(self, "You are defending!");
1047                 }
1048
1049                 target_voicescript_clear(self);
1050
1051                 // reset fields the weapons may use
1052                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1053                 {
1054                         weapon_action(j, WR_RESETPLAYER);
1055
1056                         // all weapons must be fully loaded when we spawn
1057                         entity e;
1058                         e = get_weaponinfo(j);
1059                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1060                                 self.weapon_load[j] = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1061                 }
1062
1063                 oldself = self;
1064                 self = spot;
1065                         activator = oldself;
1066                                 SUB_UseTargets();
1067                         activator = world;
1068                 self = oldself;
1069
1070                 MUTATOR_CALLHOOK(PlayerSpawn);
1071
1072                 self.switchweapon = w_getbestweapon(self);
1073                 self.cnt = self.switchweapon;
1074                 self.weapon = 0;
1075
1076                 if(!self.alivetime)
1077                         self.alivetime = time;
1078         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1079                 PutObserverInServer ();
1080         }
1081
1082         //if(g_ctf)
1083         //      ctf_playerchanged();
1084 }
1085
1086 .float ebouncefactor, ebouncestop; // electro's values
1087 // TODO do we need all these fields, or should we stop autodetecting runtime
1088 // changes and just have a console command to update this?
1089 float ClientInit_SendEntity(entity to, float sf)
1090 {
1091         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1092         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1093         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1094         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1095         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1096         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1097         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1098         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1099         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1100         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1101         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1102         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1103         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1104         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1105         if(sv_foginterval && world.fog != "")
1106                 WriteString(MSG_ENTITY, world.fog);
1107         else
1108                 WriteString(MSG_ENTITY, "");
1109         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1110         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1111         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1112         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1113         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1114         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1115         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1116         WriteByte(MSG_ENTITY, autocvar_g_balance_sniperrifle_secondary); // client has to know if it should zoom or not
1117         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1118         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1119         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1120         return TRUE;
1121 }
1122
1123 void ClientInit_CheckUpdate()
1124 {
1125         self.nextthink = time;
1126         if(self.count != autocvar_g_balance_armor_blockpercent)
1127         {
1128                 self.count = autocvar_g_balance_armor_blockpercent;
1129                 self.SendFlags |= 1;
1130         }
1131         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1132         {
1133                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1134                 self.SendFlags |= 1;
1135         }
1136         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1137         {
1138                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1139                 self.SendFlags |= 1;
1140         }
1141         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1142         {
1143                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1144                 self.SendFlags |= 1;
1145         }
1146         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1147         {
1148                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1149                 self.SendFlags |= 1;
1150         }
1151         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1152         {
1153                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1154                 self.SendFlags |= 1;
1155         }
1156 }
1157
1158 void ClientInit_Spawn()
1159 {
1160         entity o;
1161         entity e;
1162         e = spawn();
1163         e.classname = "clientinit";
1164         e.think = ClientInit_CheckUpdate;
1165         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1166
1167         o = self;
1168         self = e;
1169         ClientInit_CheckUpdate();
1170         self = o;
1171 }
1172
1173 /*
1174 =============
1175 SetNewParms
1176 =============
1177 */
1178 void SetNewParms (void)
1179 {
1180         // initialize parms for a new player
1181         parm1 = -(86400 * 366);
1182 }
1183
1184 /*
1185 =============
1186 SetChangeParms
1187 =============
1188 */
1189 void SetChangeParms (void)
1190 {
1191         // save parms for level change
1192         parm1 = self.parm_idlesince - time;
1193 }
1194
1195 /*
1196 =============
1197 DecodeLevelParms
1198 =============
1199 */
1200 void DecodeLevelParms (void)
1201 {
1202         // load parms
1203         self.parm_idlesince = parm1;
1204         if(self.parm_idlesince == -(86400 * 366))
1205                 self.parm_idlesince = time;
1206
1207         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1208         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1209 }
1210
1211 /*
1212 =============
1213 ClientKill
1214
1215 Called when a client types 'kill' in the console
1216 =============
1217 */
1218
1219 .float clientkill_nexttime;
1220 void ClientKill_Now_TeamChange()
1221 {
1222         if(self.killindicator_teamchange == -1)
1223         {
1224                 self.team = -1;
1225                 JoinBestTeam( self, FALSE, FALSE );
1226         }
1227         else if(self.killindicator_teamchange == -2)
1228         {
1229                 if(g_ca)
1230                         self.caplayer = 0;
1231                 if(blockSpectators)
1232                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1233                 PutObserverInServer();
1234         }
1235         else
1236                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1237 }
1238
1239 void ClientKill_Now()
1240 {
1241         remove(self.killindicator);
1242         self.killindicator = world;
1243
1244         if(self.killindicator_teamchange)
1245                 ClientKill_Now_TeamChange();
1246
1247         // in any case:
1248         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1249
1250         // now I am sure the player IS dead
1251 }
1252 void KillIndicator_Think()
1253 {
1254         if (!self.owner.modelindex)
1255         {
1256                 self.owner.killindicator = world;
1257                 remove(self);
1258                 return;
1259         }
1260
1261         if(self.cnt <= 0)
1262         {
1263                 self = self.owner;
1264                 ClientKill_Now(); // no oldself needed
1265                 return;
1266         }
1267     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1268     {
1269         self.nextthink = time + 1;
1270         self.cnt -= 1;
1271     }
1272         else
1273         {
1274                 if(self.cnt <= 10)
1275                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1276                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1277                 {
1278                         if(self.cnt <= 10)
1279                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1280                         if(self.owner.killindicator_teamchange)
1281                         {
1282                                 if(self.owner.killindicator_teamchange == -1)
1283                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1284                                 else if(self.owner.killindicator_teamchange == -2)
1285                                         centerprint(self.owner, strcat("Spectating in ", ftos(self.cnt), " seconds"));
1286                                 else
1287                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1288                         }
1289                         else
1290                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1291                 }
1292                 self.nextthink = time + 1;
1293                 self.cnt -= 1;
1294         }
1295 }
1296
1297 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1298 {
1299         float killtime;
1300         entity e;
1301         killtime = autocvar_g_balance_kill_delay;
1302
1303         if(g_race_qualifying || g_cts)
1304                 killtime = 0;
1305
1306     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1307     {
1308                 remove(self.killindicator);
1309                 self.killindicator = world;
1310
1311         ClientKill_Now(); // allow instant kill in this case
1312         return;
1313     }
1314
1315         self.killindicator_teamchange = targetteam;
1316
1317     if(!self.killindicator)
1318         {
1319                 if(self.modelindex && self.deadflag == DEAD_NO)
1320                 {
1321                         killtime = max(killtime, self.clientkill_nexttime - time);
1322                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1323                 }
1324
1325                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1326                 {
1327                         ClientKill_Now();
1328                 }
1329                 else
1330                 {
1331                         self.killindicator = spawn();
1332                         self.killindicator.owner = self;
1333                         self.killindicator.scale = 0.5;
1334                         setattachment(self.killindicator, self, "");
1335                         setorigin(self.killindicator, '0 0 52');
1336                         self.killindicator.think = KillIndicator_Think;
1337                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1338                         self.killindicator.cnt = ceil(killtime);
1339                         self.killindicator.count = bound(0, ceil(killtime), 10);
1340                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1341
1342                         for(e = world; (e = find(e, classname, "body")) != world; )
1343                         {
1344                                 if(e.enemy != self)
1345                                         continue;
1346                                 e.killindicator = spawn();
1347                                 e.killindicator.owner = e;
1348                                 e.killindicator.scale = 0.5;
1349                                 setattachment(e.killindicator, e, "");
1350                                 setorigin(e.killindicator, '0 0 52');
1351                                 e.killindicator.think = KillIndicator_Think;
1352                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1353                                 e.killindicator.cnt = ceil(killtime);
1354                         }
1355                         self.lip = 0;
1356                 }
1357         }
1358         if(self.killindicator)
1359         {
1360                 if(targetteam == 0) // just die
1361                         self.killindicator.colormod = '0 0 0';
1362                 else if(targetteam == -1) // auto
1363                         self.killindicator.colormod = '0 1 0';
1364                 else if(targetteam == -2) // spectate
1365                         self.killindicator.colormod = '0.5 0.5 0.5';
1366                 else
1367                         self.killindicator.colormod = TeamColor(targetteam);
1368         }
1369 }
1370
1371 void ClientKill (void)
1372 {
1373         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1374         {
1375                 // do nothing
1376         }
1377     else if(self.freezetag_frozen)
1378     {
1379         // do nothing
1380     }
1381         else
1382                 ClientKill_TeamChange(0);
1383 }
1384
1385 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1386 {
1387     e.killindicator = spawn();
1388     e.killindicator.owner = e;
1389     e.killindicator.think = KillIndicator_Think;
1390     e.killindicator.nextthink = time + (e.lip) * 0.05;
1391     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1392     e.killindicator.health = 1; // this is used to indicate that it should be silent
1393     e.lip = 0;
1394 }
1395
1396 void DoTeamChange(float destteam)
1397 {
1398         float t, c0;
1399         if(!teams_matter)
1400         {
1401                 if(destteam >= 0)
1402                         SetPlayerColors(self, destteam);
1403                 return;
1404         }
1405         if(self.classname == "player")
1406         if(destteam == -1)
1407         {
1408                 CheckAllowedTeams(self);
1409                 t = FindSmallestTeam(self, TRUE);
1410                 switch(self.team)
1411                 {
1412                         case COLOR_TEAM1: c0 = c1; break;
1413                         case COLOR_TEAM2: c0 = c2; break;
1414                         case COLOR_TEAM3: c0 = c3; break;
1415                         case COLOR_TEAM4: c0 = c4; break;
1416                         default:          c0 = 999;
1417                 }
1418                 switch(t)
1419                 {
1420                         case 1:
1421                                 if(c0 > c1)
1422                                         destteam = COLOR_TEAM1;
1423                                 break;
1424                         case 2:
1425                                 if(c0 > c2)
1426                                         destteam = COLOR_TEAM2;
1427                                 break;
1428                         case 3:
1429                                 if(c0 > c3)
1430                                         destteam = COLOR_TEAM3;
1431                                 break;
1432                         case 4:
1433                                 if(c0 > c4)
1434                                         destteam = COLOR_TEAM4;
1435                                 break;
1436                 }
1437                 if(destteam == -1)
1438                         return;
1439         }
1440         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1441                 return;
1442         ClientKill_TeamChange(destteam);
1443 }
1444
1445 void FixClientCvars(entity e)
1446 {
1447         // send prediction settings to the client
1448         stuffcmd(e, "\nin_bindmap 0 0\n");
1449         if(g_race || g_cts)
1450                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1451         if(autocvar_g_antilag == 3) // client side hitscan
1452                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1453         if(sv_gentle)
1454                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1455         /*
1456          * we no longer need to stuff this. Remove this comment block if you feel
1457          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1458         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1459         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1460         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1461         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1462         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1463         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1464         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1465         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1466         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1467         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1468         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1469         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1470         stuffcmd(e, "cl_movement_edgefriction 1\n");
1471          */
1472 }
1473
1474 float PlayerInIDList(entity p, string idlist)
1475 {
1476         float n, i;
1477         string s;
1478
1479         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1480         if not(p.crypto_idfp)
1481                 return 0;
1482
1483         // this function allows abbreviated player IDs too!
1484         n = tokenize_console(idlist);
1485         for(i = 0; i < n; ++i)
1486         {
1487                 s = argv(i);
1488                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1489                         return 1;
1490         }
1491
1492         return 0;
1493 }
1494
1495 /*
1496 =============
1497 ClientConnect
1498
1499 Called when a client connects to the server
1500 =============
1501 */
1502 //void ctf_clientconnect();
1503 string ColoredTeamName(float t);
1504 void DecodeLevelParms (void);
1505 //void dom_player_join_team(entity pl);
1506 void set_dom_state(void);
1507 void ClientConnect (void)
1508 {
1509         float t;
1510
1511         if(self.flags & FL_CLIENT)
1512         {
1513                 print("Warning: ClientConnect, but already connected!\n");
1514                 return;
1515         }
1516
1517         if(Ban_MaybeEnforceBan(self))
1518                 return;
1519
1520         DecodeLevelParms();
1521
1522 #ifdef WATERMARK
1523         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1524 #endif
1525
1526         self.classname = "player_joining";
1527
1528         self.flags = FL_CLIENT;
1529         self.version_nagtime = time + 10 + random() * 10;
1530
1531         if(player_count<0)
1532         {
1533                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1534                 player_count = 0;
1535         }
1536
1537         PlayerScore_Attach(self);
1538         ClientData_Attach();
1539         accuracy_init(self);
1540
1541         bot_clientconnect();
1542
1543         playerdemo_init();
1544
1545         anticheat_init();
1546
1547         race_PreSpawnObserver();
1548
1549         //if(g_domination)
1550         //      dom_player_join_team(self);
1551
1552         // identify the right forced team
1553         if(autocvar_g_campaign)
1554         {
1555                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1556                 {
1557                         switch(autocvar_g_campaign_forceteam)
1558                         {
1559                                 case 1: self.team_forced = COLOR_TEAM1; break;
1560                                 case 2: self.team_forced = COLOR_TEAM2; break;
1561                                 case 3: self.team_forced = COLOR_TEAM3; break;
1562                                 case 4: self.team_forced = COLOR_TEAM4; break;
1563                                 default: self.team_forced = 0;
1564                         }
1565                 }
1566         }
1567         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1568                 self.team_forced = COLOR_TEAM1;
1569         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1570                 self.team_forced = COLOR_TEAM2;
1571         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1572                 self.team_forced = COLOR_TEAM3;
1573         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1574                 self.team_forced = COLOR_TEAM4;
1575         else if(autocvar_g_forced_team_otherwise == "red")
1576                 self.team_forced = COLOR_TEAM1;
1577         else if(autocvar_g_forced_team_otherwise == "blue")
1578                 self.team_forced = COLOR_TEAM2;
1579         else if(autocvar_g_forced_team_otherwise == "yellow")
1580                 self.team_forced = COLOR_TEAM3;
1581         else if(autocvar_g_forced_team_otherwise == "pink")
1582                 self.team_forced = COLOR_TEAM4;
1583         else if(autocvar_g_forced_team_otherwise == "spectate")
1584                 self.team_forced = -1;
1585         else if(autocvar_g_forced_team_otherwise == "spectator")
1586                 self.team_forced = -1;
1587         else
1588                 self.team_forced = 0;
1589
1590         if(!teams_matter)
1591                 if(self.team_forced > 0)
1592                         self.team_forced = 0;
1593
1594         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1595
1596         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1597                 self.classname = "observer";
1598         } else {
1599                 if(teams_matter)
1600                 {
1601                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1602                         {
1603                                 self.classname = "player";
1604                                 campaign_bots_may_start = 1;
1605                         }
1606                         else
1607                         {
1608                                 self.classname = "observer"; // do it anyway
1609                         }
1610                 }
1611                 else
1612                 {
1613                         self.classname = "player";
1614                         campaign_bots_may_start = 1;
1615                 }
1616         }
1617
1618         self.playerid = (playerid_last = playerid_last + 1);
1619
1620         if(autocvar_sv_eventlog)
1621                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1622
1623         LogTeamchange(self.playerid, self.team, 1);
1624
1625         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1626
1627         self.netname_previous = strzone(self.netname);
1628
1629         bprint("^4", self.netname, "^4 connected");
1630
1631         if(self.classname != "observer" && (g_domination || g_ctf))
1632                 bprint(" and joined the ", ColoredTeamName(self.team));
1633
1634         bprint("\n");
1635
1636         self.welcomemessage_time = 0;
1637
1638         stuffcmd(self, strcat(clientstuff, "\n"));
1639         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1640         stuffcmd(self, "cl_particles_reloadeffects\n");
1641
1642         FixClientCvars(self);
1643
1644         // spawnfunc_waypoint sprites
1645         WaypointSprite_InitClient(self);
1646
1647         // Wazat's grappling hook
1648         SetGrappleHookBindings();
1649
1650         // get autoswitch state from player when he toggles it
1651         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1652
1653         // get version info from player
1654         stuffcmd(self, "cmd clientversion $gameversion\n");
1655
1656         // get other cvars from player
1657         GetCvars(0);
1658
1659         // notify about available teams
1660         if(teams_matter)
1661         {
1662                 CheckAllowedTeams(self);
1663                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1664                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1665         }
1666         else
1667                 stuffcmd(self, "set _teams_available 0\n");
1668
1669         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1670
1671         if(g_arena || g_ca)
1672         {
1673                 self.classname = "observer";
1674                 if(g_arena)
1675                         Spawnqueue_Insert(self);
1676         }
1677         /*else if(g_ctf)
1678         {
1679                 ctf_clientconnect();
1680         }*/
1681
1682         if(teams_matter || radar_showennemies)
1683                 attach_entcs();
1684
1685         bot_relinkplayerlist();
1686
1687         self.spectatortime = time;
1688         if(blockSpectators)
1689         {
1690                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1691         }
1692
1693         self.jointime = time;
1694         self.allowedTimeouts = autocvar_sv_timeout_number;
1695
1696         if(clienttype(self) == CLIENTTYPE_REAL)
1697         {
1698                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1699                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1700         }
1701
1702         if(g_lms)
1703         {
1704                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1705                 {
1706                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1707                         self.frags = FRAGS_SPECTATOR;
1708                 }
1709         }
1710
1711         if(!sv_foginterval && world.fog != "")
1712                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1713
1714         SoundEntity_Attach(self);
1715
1716         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1717         {
1718                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1719                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1720         }
1721         else
1722                 self.hitplotfh = -1;
1723
1724         if(g_race || g_cts) {
1725                 string rr;
1726                 if(g_cts)
1727                         rr = CTS_RECORD;
1728                 else
1729                         rr = RACE_RECORD;
1730                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1731
1732                 msg_entity = self;
1733                 race_send_recordtime(MSG_ONE);
1734                 race_send_speedaward(MSG_ONE);
1735
1736                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1737                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1738                 race_send_speedaward_alltimebest(MSG_ONE);
1739
1740                 float i;
1741                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1742                         race_SendRankings(i, 0, 0, MSG_ONE);
1743                 }
1744         }
1745         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1746                 send_CSQC_teamnagger();
1747
1748         if (g_domination)
1749                 set_dom_state();
1750
1751         CheatInitClient();
1752
1753         PlayerStats_AddPlayer(self);
1754 }
1755
1756 /*
1757 =============
1758 ClientDisconnect
1759
1760 Called when a client disconnects from the server
1761 =============
1762 */
1763 .entity chatbubbleentity;
1764 .entity teambubbleentity;
1765 void ReadyCount();
1766 void ClientDisconnect (void)
1767 {
1768         if not(self.flags & FL_CLIENT)
1769         {
1770                 print("Warning: ClientDisconnect without ClientConnect\n");
1771                 return;
1772         }
1773
1774         PlayerStats_AddGlobalInfo(self);
1775
1776         CheatShutdownClient();
1777
1778         if(self.hitplotfh >= 0)
1779         {
1780                 fclose(self.hitplotfh);
1781                 self.hitplotfh = -1;
1782         }
1783
1784         anticheat_report();
1785         anticheat_shutdown();
1786
1787         playerdemo_shutdown();
1788
1789         bot_clientdisconnect();
1790
1791         if(self.entcs)
1792                 detach_entcs();
1793
1794         if(autocvar_sv_eventlog)
1795                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1796         bprint ("^4",self.netname);
1797         bprint ("^4 disconnected\n");
1798
1799         SoundEntity_Detach(self);
1800
1801         DropAllRunes(self);
1802         MUTATOR_CALLHOOK(ClientDisconnect);
1803
1804         Portal_ClearAll(self);
1805
1806         if(self.flagcarried)
1807                 DropFlag(self.flagcarried, world, world);
1808         if(self.ballcarried && g_nexball)
1809                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1810
1811         // Here, everything has been done that requires this player to be a client.
1812
1813         self.flags &~= FL_CLIENT;
1814
1815         if (self.chatbubbleentity)
1816                 remove (self.chatbubbleentity);
1817
1818         if (self.teambubbleentity)
1819                 remove (self.teambubbleentity);
1820
1821         if (self.killindicator)
1822                 remove (self.killindicator);
1823
1824         WaypointSprite_PlayerGone();
1825
1826         bot_relinkplayerlist();
1827
1828         if(g_arena)
1829         {
1830                 Spawnqueue_Unmark(self);
1831                 Spawnqueue_Remove(self);
1832         }
1833
1834         accuracy_free(self);
1835         ClientData_Detach();
1836         PlayerScore_Detach(self);
1837
1838         if(self.netname_previous)
1839                 strunzone(self.netname_previous);
1840         if(self.clientstatus)
1841                 strunzone(self.clientstatus);
1842         if(self.weaponorder_byimpulse)
1843                 strunzone(self.weaponorder_byimpulse);
1844
1845         ClearPlayerSounds();
1846
1847         if(self.personal)
1848                 remove(self.personal);
1849
1850         self.playerid = 0;
1851         ReadyCount();
1852
1853         // free cvars
1854         GetCvars(-1);
1855 }
1856
1857 .float BUTTON_CHAT;
1858 void ChatBubbleThink()
1859 {
1860         self.nextthink = time;
1861         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1862         {
1863                 if(self.owner) // but why can that ever be world?
1864                         self.owner.chatbubbleentity = world;
1865                 remove(self);
1866                 return;
1867         }
1868         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1869 #ifdef TETRIS
1870                 || self.owner.tetris_on
1871 #endif
1872         )
1873                 self.model = self.mdl;
1874         else
1875                 self.model = "";
1876 };
1877
1878 void UpdateChatBubble()
1879 {
1880         if (!self.modelindex)
1881                 return;
1882         // spawn a chatbubble entity if needed
1883         if (!self.chatbubbleentity)
1884         {
1885                 self.chatbubbleentity = spawn();
1886                 self.chatbubbleentity.owner = self;
1887                 self.chatbubbleentity.exteriormodeltoclient = self;
1888                 self.chatbubbleentity.think = ChatBubbleThink;
1889                 self.chatbubbleentity.nextthink = time;
1890                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1891                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1892                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1893                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1894                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1895                 self.chatbubbleentity.model = "";
1896                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1897         }
1898 }
1899
1900
1901 void TeamBubbleThink()
1902 {
1903         self.nextthink = time;
1904         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1905         {
1906                 if(self.owner) // but why can that ever be world?
1907                         self.owner.teambubbleentity = world;
1908                 remove(self);
1909                 return;
1910         }
1911 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1912         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1913                 self.model = "";
1914         else
1915                 self.model = self.mdl;
1916
1917 };
1918
1919 float TeamBubble_customizeentityforclient()
1920 {
1921         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1922 }
1923
1924 void UpdateTeamBubble()
1925 {
1926         if (!self.modelindex || !teams_matter)
1927                 return;
1928         // spawn a teambubble entity if needed
1929         if (!self.teambubbleentity && teams_matter)
1930         {
1931                 self.teambubbleentity = spawn();
1932                 self.teambubbleentity.owner = self;
1933                 self.teambubbleentity.exteriormodeltoclient = self;
1934                 self.teambubbleentity.think = TeamBubbleThink;
1935                 self.teambubbleentity.nextthink = time;
1936                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1937 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1938                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1939                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1940                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1941                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1942                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1943                 self.teambubbleentity.effects = EF_LOWPRECISION;
1944         }
1945 }
1946
1947 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1948 // added to the model skins
1949 /*void UpdateColorModHack()
1950 {
1951         local float c;
1952         c = self.clientcolors & 15;
1953         // LordHavoc: only bothering to support white, green, red, yellow, blue
1954              if (!teams_matter) self.colormod = '0 0 0';
1955         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1956         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1957         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1958         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1959         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1960         else self.colormod = '1 1 1';
1961 };*/
1962
1963 .float oldcolormap;
1964 void respawn(void)
1965 {
1966         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1967         {
1968                 self.solid = SOLID_NOT;
1969                 self.takedamage = DAMAGE_NO;
1970                 self.movetype = MOVETYPE_FLY;
1971                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1972                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1973                 self.effects |= EF_ADDITIVE;
1974                 self.oldcolormap = self.colormap;
1975                 self.colormap = 512;
1976                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1977                 if(autocvar_g_respawn_ghosts_maxtime)
1978                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1979         }
1980
1981         CopyBody(1);
1982         self.effects |= EF_NODRAW; // prevent another CopyBody
1983         if(self.oldcolormap)
1984         {
1985                 self.colormap = self.oldcolormap;
1986                 self.oldcolormap = 0;
1987         }
1988         PutClientInServer();
1989 }
1990
1991 void play_countdown(float finished, string samp)
1992 {
1993         if(clienttype(self) == CLIENTTYPE_REAL)
1994                 if(floor(finished - time - frametime) != floor(finished - time))
1995                         if(finished - time < 6)
1996                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1997 }
1998
1999 /**
2000  * When sv_timeout is used this function returs strings like
2001  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
2002  * Called by centerprint functions
2003  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
2004  */
2005 string getTimeoutText(float addOneSecond) {
2006         if (!autocvar_sv_timeout || !timeoutStatus)
2007                 return "";
2008
2009         local string retStr;
2010         if (timeoutStatus == 1) {
2011                 if (addOneSecond == 1) {
2012                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
2013                 }
2014                 else {
2015                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
2016                 }
2017                 return retStr;
2018         }
2019         else if (timeoutStatus == 2) {
2020                 if (addOneSecond) {
2021                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
2022                         //don't show messages like "Timeout ends in 0 seconds"...
2023                         if ((remainingTimeoutTime + 1) > 0)
2024                                 return retStr;
2025                         else
2026                                 return "";
2027                 }
2028                 else {
2029                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
2030                         //don't show messages like "Timeout ends in 0 seconds"...
2031                         if (remainingTimeoutTime > 0)
2032                                 return retStr;
2033                         else
2034                                 return "";
2035                 }
2036         }
2037         else return "";
2038 }
2039
2040 void player_powerups (void)
2041 {
2042         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2043         olditems = self.items;
2044
2045         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2046         {
2047                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2048                 self.modelflags |= MF_ROCKET;
2049         }
2050         else
2051         {
2052                 SoundEntity_StopSound(self, CHAN_PLAYER);
2053                 self.modelflags &~= MF_ROCKET;
2054         }
2055
2056         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2057
2058         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2059                 return;
2060
2061         Fire_ApplyDamage(self);
2062         Fire_ApplyEffect(self);
2063
2064         if (g_minstagib)
2065         {
2066                 self.effects |= EF_FULLBRIGHT;
2067
2068                 if (self.items & IT_STRENGTH)
2069                 {
2070                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2071                         if (time > self.strength_finished)
2072                         {
2073                                 self.alpha = default_player_alpha;
2074                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2075                                 self.items &~= IT_STRENGTH;
2076                                 sprint(self, "^3Invisibility has worn off\n");
2077                         }
2078                 }
2079                 else
2080                 {
2081                         if (time < self.strength_finished)
2082                         {
2083                                 self.alpha = g_minstagib_invis_alpha;
2084                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2085                                 self.items |= IT_STRENGTH;
2086                                 sprint(self, "^3You are invisible\n");
2087                         }
2088                 }
2089
2090                 if (self.items & IT_INVINCIBLE)
2091                 {
2092                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2093                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2094                         {
2095                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2096                                 sprint(self, "^3Speed has worn off\n");
2097                         }
2098                 }
2099                 else
2100                 {
2101                         if (time < self.invincible_finished)
2102                         {
2103                                 self.items = self.items | IT_INVINCIBLE;
2104                                 sprint(self, "^3You are on speed\n");
2105                         }
2106                 }
2107         }
2108         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2109         {
2110                 if (self.items & IT_STRENGTH)
2111                 {
2112                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2113                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2114                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2115                         {
2116                                 self.items = self.items - (self.items & IT_STRENGTH);
2117                                 sprint(self, "^3Strength has worn off\n");
2118                         }
2119                 }
2120                 else
2121                 {
2122                         if (time < self.strength_finished)
2123                         {
2124                                 self.items = self.items | IT_STRENGTH;
2125                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2126                         }
2127                 }
2128                 if (self.items & IT_INVINCIBLE)
2129                 {
2130                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2131                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2132                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2133                         {
2134                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2135                                 sprint(self, "^3Shield has worn off\n");
2136                         }
2137                 }
2138                 else
2139                 {
2140                         if (time < self.invincible_finished)
2141                         {
2142                                 self.items = self.items | IT_INVINCIBLE;
2143                                 sprint(self, "^3Shield surrounds you\n");
2144                         }
2145                 }
2146
2147                 if(autocvar_g_nodepthtestplayers)
2148                         self.effects = self.effects | EF_NODEPTHTEST;
2149
2150                 if(autocvar_g_fullbrightplayers)
2151                         self.effects = self.effects | EF_FULLBRIGHT;
2152
2153                 // midair gamemode: damage only while in the air
2154                 // if in midair mode, being on ground grants temporary invulnerability
2155                 // (this is so that multishot weapon don't clear the ground flag on the
2156                 // first damage in the frame, leaving the player vulnerable to the
2157                 // remaining hits in the same frame)
2158                 if (self.flags & FL_ONGROUND)
2159                 if (g_midair)
2160                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2161
2162                 if (time >= game_starttime)
2163                 if (time < self.spawnshieldtime)
2164                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2165         }
2166
2167         MUTATOR_CALLHOOK(PlayerPowerups);
2168 }
2169
2170 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2171 {
2172         if(current > stable)
2173                 return current;
2174         else if(current > stable - 0.25) // when close enough, "snap"
2175                 return stable;
2176         else
2177                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2178 }
2179
2180 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2181 {
2182         if(current < stable)
2183                 return current;
2184         else if(current < stable + 0.25) // when close enough, "snap"
2185                 return stable;
2186         else
2187                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2188 }
2189
2190 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2191 {
2192         if(current > rotstable)
2193         {
2194                 if(rotframetime > 0)
2195                 {
2196                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2197                         current = max(rotstable, current - rotlinear * rotframetime);
2198                 }
2199         }
2200         else if(current < regenstable)
2201         {
2202                 if(regenframetime > 0)
2203                 {
2204                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2205                         current = min(regenstable, current + regenlinear * regenframetime);
2206                 }
2207         }
2208
2209         if(current > limit)
2210                 current = limit;
2211
2212         return current;
2213 }
2214
2215 void player_regen (void)
2216 {
2217         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2218         maxh = autocvar_g_balance_health_rotstable;
2219         maxa = autocvar_g_balance_armor_rotstable;
2220         maxf = autocvar_g_balance_fuel_rotstable;
2221         minh = autocvar_g_balance_health_regenstable;
2222         mina = autocvar_g_balance_armor_regenstable;
2223         minf = autocvar_g_balance_fuel_regenstable;
2224         limith = autocvar_g_balance_health_limit;
2225         limita = autocvar_g_balance_armor_limit;
2226         limitf = autocvar_g_balance_fuel_limit;
2227
2228         max_mod = regen_mod = rot_mod = limit_mod = 1;
2229
2230         if (self.runes & RUNE_REGEN)
2231         {
2232                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2233                 {
2234                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2235                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2236                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2237                 }
2238                 else
2239                 {
2240                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2241                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2242                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2243                 }
2244         }
2245         else if (self.runes & CURSE_VENOM)
2246         {
2247                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2248                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2249                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2250                 else
2251                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2252                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2253                 //if (!self.runes & RUNE_REGEN)
2254                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2255         }
2256         maxh = maxh * max_mod;
2257         //maxa = maxa * max_mod;
2258         //maxf = maxf * max_mod;
2259         minh = minh * max_mod;
2260         //mina = mina * max_mod;
2261         //minf = minf * max_mod;
2262         limith = limith * limit_mod;
2263         limita = limita * limit_mod;
2264         //limitf = limitf * limit_mod;
2265
2266         if(g_lms && g_ca)
2267                 rot_mod = 0;
2268
2269         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2270         {
2271                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2272                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2273
2274                 // if player rotted to death...  die!
2275                 if(self.health < 1)
2276                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2277         }
2278
2279         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2280                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2281 }
2282
2283 float zoomstate_set;
2284 void SetZoomState(float z)
2285 {
2286         if(z != self.zoomstate)
2287         {
2288                 self.zoomstate = z;
2289                 ClientData_Touch(self);
2290         }
2291         zoomstate_set = 1;
2292 }
2293
2294 void GetPressedKeys(void) {
2295         MUTATOR_CALLHOOK(GetPressedKeys);
2296         if (self.movement_x > 0) // get if movement keys are pressed
2297         {       // forward key pressed
2298                 self.pressedkeys |= KEY_FORWARD;
2299                 self.pressedkeys &~= KEY_BACKWARD;
2300         }
2301         else if (self.movement_x < 0)
2302         {       // backward key pressed
2303                 self.pressedkeys |= KEY_BACKWARD;
2304                 self.pressedkeys &~= KEY_FORWARD;
2305         }
2306         else
2307         {       // no x input
2308                 self.pressedkeys &~= KEY_FORWARD;
2309                 self.pressedkeys &~= KEY_BACKWARD;
2310         }
2311
2312         if (self.movement_y > 0)
2313         {       // right key pressed
2314                 self.pressedkeys |= KEY_RIGHT;
2315                 self.pressedkeys &~= KEY_LEFT;
2316         }
2317         else if (self.movement_y < 0)
2318         {       // left key pressed
2319                 self.pressedkeys |= KEY_LEFT;
2320                 self.pressedkeys &~= KEY_RIGHT;
2321         }
2322         else
2323         {       // no y input
2324                 self.pressedkeys &~= KEY_RIGHT;
2325                 self.pressedkeys &~= KEY_LEFT;
2326         }
2327
2328         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2329                 self.pressedkeys |= KEY_JUMP;
2330         else
2331                 self.pressedkeys &~= KEY_JUMP;
2332         if (self.BUTTON_CROUCH)
2333                 self.pressedkeys |= KEY_CROUCH;
2334         else
2335                 self.pressedkeys &~= KEY_CROUCH;
2336 }
2337
2338 /*
2339 ======================
2340 spectate mode routines
2341 ======================
2342 */
2343
2344 void SpectateCopy(entity spectatee) {
2345         other = spectatee;
2346         MUTATOR_CALLHOOK(SpectateCopy);
2347         self.armortype = spectatee.armortype;
2348         self.armorvalue = spectatee.armorvalue;
2349         self.ammo_cells = spectatee.ammo_cells;
2350         self.ammo_shells = spectatee.ammo_shells;
2351         self.ammo_nails = spectatee.ammo_nails;
2352         self.ammo_rockets = spectatee.ammo_rockets;
2353         self.ammo_fuel = spectatee.ammo_fuel;
2354         self.clip_load = spectatee.clip_load;
2355         self.clip_size = spectatee.clip_size;
2356         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2357         self.health = spectatee.health;
2358         self.impulse = 0;
2359         self.items = spectatee.items;
2360         self.last_pickup = spectatee.last_pickup;
2361         self.hit_time = spectatee.hit_time;
2362         self.metertime = spectatee.metertime;
2363         self.strength_finished = spectatee.strength_finished;
2364         self.invincible_finished = spectatee.invincible_finished;
2365         self.pressedkeys = spectatee.pressedkeys;
2366         self.weapons = spectatee.weapons;
2367         self.switchweapon = spectatee.switchweapon;
2368         self.weapon = spectatee.weapon;
2369         self.nex_charge = spectatee.nex_charge;
2370         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2371         self.minelayer_mines = spectatee.minelayer_mines;
2372         self.punchangle = spectatee.punchangle;
2373         self.view_ofs = spectatee.view_ofs;
2374         self.v_angle = spectatee.v_angle;
2375         self.velocity = spectatee.velocity;
2376         self.dmg_take = spectatee.dmg_take;
2377         self.dmg_save = spectatee.dmg_save;
2378         self.dmg_inflictor = spectatee.dmg_inflictor;
2379         self.angles = spectatee.v_angle;
2380         self.fixangle = TRUE;
2381         setorigin(self, spectatee.origin);
2382         setsize(self, spectatee.mins, spectatee.maxs);
2383         SetZoomState(spectatee.zoomstate);
2384
2385         anticheat_spectatecopy(spectatee);
2386 }
2387
2388 float SpectateUpdate() {
2389         if(!self.enemy)
2390                 return 0;
2391
2392         if (self == self.enemy)
2393                 return 0;
2394
2395         if(self.enemy.classname != "player")
2396                 return 0;
2397
2398         SpectateCopy(self.enemy);
2399
2400         return 1;
2401 }
2402
2403 float SpectateNext() {
2404         other = find(self.enemy, classname, "player");
2405
2406         if (!other)
2407                 other = find(other, classname, "player");
2408
2409         if (other)
2410                 self.enemy = other;
2411
2412         if(self.enemy.classname == "player") {
2413                 msg_entity = self;
2414                 WriteByte(MSG_ONE, SVC_SETVIEW);
2415                 WriteEntity(MSG_ONE, self.enemy);
2416                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2417                 self.movetype = MOVETYPE_NONE;
2418                 accuracy_resend(self);
2419
2420                 if(!SpectateUpdate())
2421                         PutObserverInServer();
2422
2423                 return 1;
2424         } else {
2425                 return 0;
2426         }
2427 }
2428
2429 /*
2430 =============
2431 ShowRespawnCountdown()
2432
2433 Update a respawn countdown display.
2434 =============
2435 */
2436 void ShowRespawnCountdown()
2437 {
2438         float number;
2439         if(self.deadflag == DEAD_NO) // just respawned?
2440                 return;
2441         else
2442         {
2443                 number = ceil(self.death_time - time);
2444                 if(number <= 0)
2445                         return;
2446                 if(number <= self.respawn_countdown)
2447                 {
2448                         self.respawn_countdown = number - 1;
2449                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2450                                 AnnounceTo(self, strcat(ftos(number), ""));
2451                 }
2452         }
2453 }
2454
2455 void LeaveSpectatorMode()
2456 {
2457         if(nJoinAllowed(1)) {
2458                 if(!teams_matter || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2459                         self.classname = "player";
2460
2461                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2462                                 JoinBestTeam(self, FALSE, TRUE);
2463
2464                         if(autocvar_g_campaign)
2465                                 campaign_bots_may_start = 1;
2466
2467                         PutClientInServer();
2468
2469                         if(self.classname == "player")
2470                                 bprint ("^4", self.netname, "^4 is playing now\n");
2471
2472                         if(!autocvar_g_campaign)
2473                                 centerprint(self,""); // clear MOTD
2474
2475                         return;
2476                 } else {
2477                         if (g_ca && self.caplayer) {
2478                         }       // do nothing
2479                         else
2480                                 stuffcmd(self,"menu_showteamselect\n");
2481                         return;
2482                 }
2483         }
2484         else {
2485                 //player may not join because of g_maxplayers is set
2486                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2487         }
2488 }
2489
2490 /**
2491  * Determines whether the player is allowed to join. This depends on cvar
2492  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2493  * it checks whether the number of currently playing players exceeds g_maxplayers.
2494  * @return int number of free slots for players, 0 if none
2495  */
2496 float nJoinAllowed(float includeMe) {
2497         if(self.team_forced < 0)
2498                 return FALSE; // forced spectators can never join
2499
2500         // TODO simplify this
2501         local entity e;
2502
2503         local float totalClients;
2504         FOR_EACH_CLIENT(e)
2505                 totalClients += 1;
2506
2507         if (!autocvar_g_maxplayers)
2508                 return maxclients - totalClients + includeMe;
2509
2510         local float currentlyPlaying;
2511         FOR_EACH_REALPLAYER(e)
2512                 currentlyPlaying += 1;
2513
2514         if(currentlyPlaying < autocvar_g_maxplayers)
2515                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2516
2517         return 0;
2518 }
2519
2520 /**
2521  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2522  * g_maxplayers_spectator_blocktime seconds
2523  */
2524 void checkSpectatorBlock() {
2525         if(self.classname == "spectator" || self.classname == "observer") {
2526                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2527                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2528                         dropclient(self);
2529                 }
2530         }
2531 }
2532
2533 void ObserverThink()
2534 {
2535         if (self.flags & FL_JUMPRELEASED) {
2536                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2537                         self.welcomemessage_time = 0;
2538                         self.flags &~= FL_JUMPRELEASED;
2539                         self.flags |= FL_SPAWNING;
2540                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2541                         self.welcomemessage_time = 0;
2542                         self.flags &~= FL_JUMPRELEASED;
2543                         if(SpectateNext() == 1) {
2544                                 self.classname = "spectator";
2545                         }
2546                 }
2547         } else {
2548                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2549                         self.flags |= FL_JUMPRELEASED;
2550                         if(self.flags & FL_SPAWNING)
2551                         {
2552                                 self.flags &~= FL_SPAWNING;
2553                                 LeaveSpectatorMode();
2554                                 return;
2555                         }
2556                 }
2557         }
2558         PrintWelcomeMessage(self);
2559 }
2560
2561 void SpectatorThink()
2562 {
2563         if (self.flags & FL_JUMPRELEASED) {
2564                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2565                         self.welcomemessage_time = 0;
2566                         self.flags &~= FL_JUMPRELEASED;
2567                         self.flags |= FL_SPAWNING;
2568                 } else if(self.BUTTON_ATCK) {
2569                         self.welcomemessage_time = 0;
2570                         self.flags &~= FL_JUMPRELEASED;
2571                         if(SpectateNext() == 1) {
2572                                 self.classname = "spectator";
2573                         } else {
2574                                 self.classname = "observer";
2575                                 PutClientInServer();
2576                         }
2577                 } else if (self.BUTTON_ATCK2) {
2578                         self.welcomemessage_time = 0;
2579                         self.flags &~= FL_JUMPRELEASED;
2580                         self.classname = "observer";
2581                         PutClientInServer();
2582                 } else {
2583                         if(!SpectateUpdate())
2584                                 PutObserverInServer();
2585                 }
2586         } else {
2587                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2588                         self.flags |= FL_JUMPRELEASED;
2589                         if(self.flags & FL_SPAWNING)
2590                         {
2591                                 self.flags &~= FL_SPAWNING;
2592                                 LeaveSpectatorMode();
2593                                 return;
2594                         }
2595                 }
2596         }
2597
2598         PrintWelcomeMessage(self);
2599         self.flags |= FL_CLIENT | FL_NOTARGET;
2600 }
2601
2602 .float touchexplode_time;
2603
2604 /*
2605 =============
2606 PlayerPreThink
2607
2608 Called every frame for each client before the physics are run
2609 =============
2610 */
2611 void() ctf_setstatus;
2612 void() nexball_setstatus;
2613 .float items_added;
2614 void PlayerPreThink (void)
2615 {
2616         self.stat_game_starttime = game_starttime;
2617         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2618         self.stat_leadlimit = autocvar_leadlimit;
2619
2620         if(frametime)
2621         {
2622                 // physics frames: update anticheat stuff
2623                 anticheat_prethink();
2624         }
2625
2626         if(blockSpectators && frametime)
2627                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2628                 checkSpectatorBlock();
2629
2630         zoomstate_set = 0;
2631
2632         if(self.netname_previous != self.netname)
2633         {
2634                 if(autocvar_sv_eventlog)
2635                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2636                 if(self.netname_previous)
2637                         strunzone(self.netname_previous);
2638                 self.netname_previous = strzone(self.netname);
2639         }
2640
2641         // version nagging
2642         if(self.version_nagtime)
2643                 if(self.cvar_g_xonoticversion)
2644                         if(time > self.version_nagtime)
2645                         {
2646                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2647                                 {
2648                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2649                                         {
2650                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2651                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2652                                         }
2653                                         else
2654                                         {
2655                                                 float r;
2656                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2657                                                 if(r < 0)
2658                                                 {
2659                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2660                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2661                                                 }
2662                                                 else if(r > 0)
2663                                                 {
2664                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2665                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2666                                                 }
2667                                         }
2668                                 }
2669                                 self.version_nagtime = 0;
2670                         }
2671
2672         // GOD MODE info
2673         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2674         {
2675                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2676                 self.max_armorvalue = 0;
2677         }
2678
2679 #ifdef TETRIS
2680         if (TetrisPreFrame())
2681                 return;
2682 #endif
2683
2684         MUTATOR_CALLHOOK(PlayerPreThink);
2685
2686         if(self.classname == "player") {
2687 //              if(self.netname == "Wazat")
2688 //                      bprint(self.classname, "\n");
2689
2690                 CheckRules_Player();
2691
2692                 PrintWelcomeMessage(self);
2693
2694                 if (intermission_running)
2695                 {
2696                         IntermissionThink ();   // otherwise a button could be missed between
2697                         return;                                 // the think tics
2698                 }
2699
2700                 if(self.teleport_time)
2701                 if(time > self.teleport_time)
2702                 {
2703                         self.teleport_time = 0;
2704                         self.effects = self.effects - (self.effects & EF_NODRAW);
2705                 }
2706
2707                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2708                         UpdateSelectedPlayer();
2709
2710                 //don't allow the player to turn around while game is paused!
2711                 if(timeoutStatus == 2) {
2712                         self.v_angle = self.lastV_angle;
2713                         self.angles = self.lastV_angle;
2714                         self.fixangle = TRUE;
2715                 }
2716
2717                 if(frametime)
2718                 {
2719                         if(self.health <= 0 && autocvar_g_deathglow)
2720                         {
2721                                 if(self.glowmod_x > 0)
2722                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2723                                 else
2724                                         self.glowmod_x = -1;
2725                                 if(self.glowmod_y > 0)
2726                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2727                                 else
2728                                         self.glowmod_y = -1;
2729                                 if(self.glowmod_z > 0)
2730                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2731                                 else
2732                                         self.glowmod_z = -1;
2733                         }
2734                         else
2735                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2736                         player_powerups();
2737                 }
2738
2739                 if (self.deadflag != DEAD_NO)
2740                 {
2741                         float button_pressed, force_respawn;
2742                         if(self.personal && g_race_qualifying)
2743                         {
2744                                 if(time > self.death_time)
2745                                 {
2746                                         self.death_time = time + 1; // only retry once a second
2747                                         respawn();
2748                                         self.impulse = 141;
2749                                 }
2750                         }
2751                         else
2752                         {
2753                                 if(frametime)
2754                                         player_anim();
2755                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2756                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2757                                 if (self.deadflag == DEAD_DYING)
2758                                 {
2759                                         if(force_respawn)
2760                                                 self.deadflag = DEAD_RESPAWNING;
2761                                         else if(!button_pressed)
2762                                                 self.deadflag = DEAD_DEAD;
2763                                 }
2764                                 else if (self.deadflag == DEAD_DEAD)
2765                                 {
2766                                         if(button_pressed)
2767                                                 self.deadflag = DEAD_RESPAWNABLE;
2768                                 }
2769                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2770                                 {
2771                                         if(!button_pressed)
2772                                                 self.deadflag = DEAD_RESPAWNING;
2773                                 }
2774                                 else if (self.deadflag == DEAD_RESPAWNING)
2775                                 {
2776                                         if(time > self.death_time)
2777                                         {
2778                                                 self.death_time = time + 1; // only retry once a second
2779                                                 respawn();
2780                                         }
2781                                 }
2782                                 ShowRespawnCountdown();
2783                         }
2784                         return;
2785                 }
2786
2787                 if(g_touchexplode)
2788                 if(time > self.touchexplode_time)
2789                 if(self.classname == "player")
2790                 if(self.deadflag == DEAD_NO)
2791                 if not(IS_INDEPENDENT_PLAYER(self))
2792                 FOR_EACH_PLAYER(other) if(self != other)
2793                 {
2794                         if(time > other.touchexplode_time)
2795                         if(other.deadflag == DEAD_NO)
2796                         if not(IS_INDEPENDENT_PLAYER(other))
2797                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2798                         {
2799                                 PlayerTouchExplode(self, other);
2800                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2801                         }
2802                 }
2803
2804                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2805                 {
2806                         vector dist;
2807
2808                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2809                         dist = self.prevorigin - self.origin;
2810                         dist_z = 0;
2811                         self.lms_traveled_distance += fabs(vlen(dist));
2812
2813                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2814                         {
2815                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2816                                 self.lms_traveled_distance = 0;
2817                         }
2818
2819                         if(time > self.lms_nextcheck)
2820                         {
2821                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2822                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2823                                 {
2824                                         centerprint(self, autocvar_g_lms_campcheck_message);
2825                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2826                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2827                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2828                                 }
2829                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2830                                 self.lms_traveled_distance = 0;
2831                         }
2832                 }
2833
2834                 self.prevorigin = self.origin;
2835
2836                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2837                 {
2838                         if (!self.crouch)
2839                         {
2840                                 self.crouch = TRUE;
2841                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2842                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2843                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2844                         }
2845                 }
2846                 else
2847                 {
2848                         if (self.crouch)
2849                         {
2850                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2851                                 if (!trace_startsolid)
2852                                 {
2853                                         self.crouch = FALSE;
2854                                         self.view_ofs = PL_VIEW_OFS;
2855                                         setsize (self, PL_MIN, PL_MAX);
2856                                 }
2857                         }
2858                 }
2859
2860                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2861                 {
2862                         if(self.bloodloss_timer < time)
2863                         {
2864                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2865                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2866                         }
2867                 }
2868
2869                 FixPlayermodel();
2870
2871                 GrapplingHookFrame();
2872
2873                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2874                 //if(frametime)
2875                 {
2876                         self.items &~= self.items_added;
2877
2878                         W_WeaponFrame();
2879
2880                         self.items_added = 0;
2881                         if(self.items & IT_JETPACK)
2882                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2883                                         self.items_added |= IT_FUEL;
2884
2885                         self.items |= self.items_added;
2886                 }
2887
2888                 player_regen();
2889
2890                 // rot nex charge to the charge limit
2891                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2892                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2893
2894                 if(frametime)
2895                         player_anim();
2896
2897                 if (g_minstagib)
2898                         minstagib_ammocheck();
2899
2900                 if(g_ctf)
2901                         ctf_setstatus();
2902
2903                 if(g_nexball)
2904                         nexball_setstatus();
2905
2906                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2907
2908                 //self.angles_y=self.v_angle_y + 90;   // temp
2909         } else if(gameover) {
2910                 if (intermission_running)
2911                         IntermissionThink ();   // otherwise a button could be missed between
2912                 return;
2913         } else if(self.classname == "observer") {
2914                 ObserverThink();
2915         } else if(self.classname == "spectator") {
2916                 SpectatorThink();
2917         }
2918
2919         if(!zoomstate_set)
2920                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_SNIPERRIFLE && autocvar_g_balance_sniperrifle_secondary == 0));
2921
2922         float oldspectatee_status;
2923         oldspectatee_status = self.spectatee_status;
2924         if(self.classname == "spectator")
2925                 self.spectatee_status = num_for_edict(self.enemy);
2926         else if(self.classname == "observer")
2927                 self.spectatee_status = num_for_edict(self);
2928         else
2929                 self.spectatee_status = 0;
2930         if(self.spectatee_status != oldspectatee_status)
2931         {
2932                 ClientData_Touch(self);
2933                 if(g_race || g_cts)
2934                         race_InitSpectator();
2935         }
2936
2937         if(self.teamkill_soundtime)
2938         if(time > self.teamkill_soundtime)
2939         {
2940                 self.teamkill_soundtime = 0;
2941
2942                 entity oldpusher, oldself;
2943
2944                 oldself = self; self = self.teamkill_soundsource;
2945                 oldpusher = self.pusher; self.pusher = oldself;
2946
2947                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2948
2949                 self.pusher = oldpusher;
2950                 self = oldself;
2951         }
2952
2953         if(self.taunt_soundtime)
2954         if(time > self.taunt_soundtime)
2955         {
2956                 self.taunt_soundtime = 0;
2957                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2958         }
2959
2960         target_voicescript_next(self);
2961
2962         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2963         if(!self.weapon)
2964                 self.clip_load = self.clip_size = 0;
2965 }
2966
2967 float isInvisibleString(string s)
2968 {
2969         float i, n, c;
2970         s = strdecolorize(s);
2971         for((i = 0), (n = strlen(s)); i < n; ++i)
2972         {
2973                 c = str2chr(s, i);
2974                 switch(c)
2975                 {
2976                         case 0:
2977                         case 32: // space
2978                                 break;
2979                         case 192: // charmap space
2980                                 if (!autocvar_utf8_enable)
2981                                         break;
2982                                 return FALSE;
2983                         case 160: // space in unicode fonts
2984                         case 0xE000 + 192: // utf8 charmap space
2985                                 if (autocvar_utf8_enable)
2986                                         break;
2987                         default:
2988                                 return FALSE;
2989                 }
2990         }
2991         return TRUE;
2992 }
2993
2994 /*
2995 =============
2996 PlayerPostThink
2997
2998 Called every frame for each client after the physics are run
2999 =============
3000 */
3001 .float idlekick_lasttimeleft;
3002 .entity showheadshotbbox;
3003 void showheadshotbbox_think()
3004 {
3005         if(self.owner.showheadshotbbox != self)
3006         {
3007                 remove(self);
3008                 return;
3009         }
3010         self.nextthink = time;
3011         setorigin(self, self.owner.origin);
3012         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3013 }
3014 void PlayerPostThink (void)
3015 {
3016         // Savage: Check for nameless players
3017         if (isInvisibleString(self.netname)) {
3018                 self.netname = "Player";
3019                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3020         }
3021
3022         if(sv_maxidle && frametime)
3023         {
3024                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3025                 float timeleft;
3026                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3027                 if(timeleft <= 0)
3028                 {
3029                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3030                         AnnounceTo(self, "terminated");
3031                         dropclient(self);
3032                         return;
3033                 }
3034                 else if(timeleft <= 10)
3035                 {
3036                         if(timeleft != self.idlekick_lasttimeleft)
3037                         {
3038                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
3039                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3040                         }
3041                 }
3042                 else
3043                 {
3044                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
3045                 }
3046                 self.idlekick_lasttimeleft = timeleft;
3047         }
3048
3049 #ifdef TETRIS
3050         if(self.impulse == 100)
3051                 ImpulseCommands();
3052         if (TetrisPostFrame())
3053                 return;
3054 #endif
3055
3056         CheatFrame();
3057
3058         if(self.classname == "player") {
3059                 CheckRules_Player();
3060                 UpdateChatBubble();
3061                 UpdateTeamBubble();
3062                 if (self.impulse)
3063                         ImpulseCommands();
3064                 if (intermission_running)
3065                         return;         // intermission or finale
3066                 GetPressedKeys();
3067         } else if (self.classname == "observer") {
3068                 //do nothing
3069         } else if (self.classname == "spectator") {
3070                 //do nothing
3071         }
3072
3073         /*
3074         float i;
3075         for(i = 0; i < 1000; ++i)
3076         {
3077                 vector end;
3078                 end = self.origin + '0 0 1024' + 512 * randomvec();
3079                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3080                 if(trace_fraction < 1)
3081                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3082                 {
3083                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3084                         break;
3085                 }
3086         }
3087         */
3088
3089         Arena_Warmup();
3090
3091         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3092
3093         if(self.waypointsprite_attachedforcarrier)
3094                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3095
3096         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3097         {
3098                 if(!self.showheadshotbbox)
3099                 {
3100                         self.showheadshotbbox = spawn();
3101                         self.showheadshotbbox.classname = "headshotbbox";
3102                         self.showheadshotbbox.owner = self;
3103                         self.showheadshotbbox.think = showheadshotbbox_think;
3104                         self.showheadshotbbox.nextthink = time;
3105                         self = self.showheadshotbbox;
3106                         self.think();
3107                         self = self.owner;
3108                 }
3109         }
3110         else
3111         {
3112                 if(self.showheadshotbbox)
3113                         remove(self.showheadshotbbox);
3114         }
3115
3116         playerdemo_write();
3117
3118         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3119         {
3120                 if(!self.stored_netname)
3121                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3122                 if(self.stored_netname != self.netname)
3123                 {
3124                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3125                         strunzone(self.stored_netname);
3126                         self.stored_netname = strzone(self.netname);
3127                 }
3128         }
3129
3130         /*
3131         if(g_race)
3132                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3133         */
3134 }